CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2009,2010,2011,2012,2013,2014, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 cmake_minimum_required(VERSION 2.8.8)
  36 # When we require cmake >= 2.8.12, it will provide
  37 # CMAKE_MINIMUM_REQUIRED_VERSION automatically, but in the meantime we
  38 # need to set a variable, and it must have a different name.
  39 set(GMX_CMAKE_MINIMUM_REQUIRED_VERSION "2.8.8")
  40
  41 # CMake modules/macros are in a subdirectory to keep this file cleaner
  42 # This needs to be set before project() in order to pick up toolchain files
  43 list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake ${CMAKE_CURRENT_SOURCE_DIR}/cmake/Platform)
  44
  45 project(Gromacs)
  46
  47 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  48 set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  49 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
  50
  51 # Set up common version variables, as well as general information about
  52 # the build tree (whether the build is from a source package or from a git
  53 # repository).  Also declares a few functions that will be used for generating
  54 # version info files later.
  55 include(gmxVersionInfo)
  56
  57 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT AND UNIX)
  58     set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
  59 endif()
  60
  61 include(gmxBuildTypeReference)
  62 include(gmxBuildTypeProfile)
  63 include(gmxBuildTypeTSAN)
  64 include(gmxBuildTypeASAN)
  65 include(gmxBuildTypeReleaseWithAssert)
  66
  67 if(NOT CMAKE_BUILD_TYPE)
  68     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel Reference RelWithAssert Profile." FORCE)
  69     # There's no need to offer a user the choice of ThreadSanitizer
  70     # Set the possible values of build type for cmake-gui
  71     set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "Debug" "Release"
  72         "MinSizeRel" "RelWithDebInfo" "Reference" "RelWithAssert" "Profile")
  73 endif()
  74 if(CMAKE_CONFIGURATION_TYPES)
  75     # Add appropriate GROMACS-specific build types for the Visual
  76     # Studio generator (Debug, Release, MinSizeRel and RelWithDebInfo
  77     # are already present by default).
  78     list(APPEND CMAKE_CONFIGURATION_TYPES "RelWithAssert" "Reference")
  79     list(REMOVE_DUPLICATES CMAKE_CONFIGURATION_TYPES)
  80     set(CMAKE_CONFIGURATION_TYPES "${CMAKE_CONFIGURATION_TYPES}" CACHE STRING
  81         "List of configuration types"
  82         FORCE)
  83 endif()
  84 set(build_types_with_explicit_flags RELEASE DEBUG RELWITHDEBUGINFO RELWITHASSERT MINSIZEREL PROFILE)
  85
  86 set(CPACK_PACKAGE_NAME "gromacs")
  87 set(CPACK_PACKAGE_VERSION_MAJOR ${GMX_VERSION_MAJOR})
  88 set(CPACK_PACKAGE_VERSION_MINOR ${GMX_VERSION_MINOR})
  89 set(CPACK_PACKAGE_VERSION_PATCH ${GMX_VERSION_PATCH})
  90 set(CPACK_PACKAGE_VERSION       ${GMX_VERSION_STRING})
  91 set(CPACK_SOURCE_PACKAGE_FILE_NAME "${CPACK_PACKAGE_NAME}-${CPACK_PACKAGE_VERSION}")
  92 set(CPACK_PACKAGE_VENDOR "gromacs.org")
  93 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Gromacs - a toolkit for high-performance molecular simulation")
  94 set(CPACK_RESOURCE_FILE_WELCOME "${CMAKE_SOURCE_DIR}/admin/InstallWelcome.txt")
  95 # Its GPL/LGPL, so they do not have to agree to a license for mere usage, but some installers require this...
  96 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_SOURCE_DIR}/COPYING")
  97 set(CPACK_RESOURCE_FILE_README "${CMAKE_SOURCE_DIR}/admin/InstallInfo.txt")
  98 set(CPACK_SOURCE_IGNORE_FILES "\\\\.isreposource$;\\\\.git/;\\\\.gitignore$;\\\\.gitattributes;")
  99 set(CPACK_PROJECT_CONFIG_FILE "${CMAKE_SOURCE_DIR}/CPackInit.cmake")
 100 # CPack source archives include only the directories we list here.
 101 # This variable is a list of pairs of names of source and destination
 102 # directories. Most of these are used for content GROMACS generates as
 103 # part of the configuration or build.
 104 set(CPACK_SOURCE_INSTALLED_DIRECTORIES "${CMAKE_SOURCE_DIR};/;${CMAKE_BINARY_DIR}/src/programs/completion;src/programs/completion;${CMAKE_BINARY_DIR}/share/man/man1;share/man/man1;${CMAKE_BINARY_DIR}/share/man/man7;share/man/man7;${CMAKE_BINARY_DIR}/share/html/final;share/html/final;${CMAKE_BINARY_DIR}/install-guide/final;/")
 105 set(CPACK_PACKAGE_CONTACT "gmx-users@gromacs.org")
 106 set(CPACK_GMX_BUILD_HELP "${GMX_BUILD_HELP}") #Works even though GMX_BUILD_HELP is defined later because it is off by default.
 107
 108 #must come after all cpack settings!
 109 include(CPack)
 110
 111 # Set a default valgrind suppression file.
 112 # This unfortunately needs to duplicate information from CTest to work as
 113 # expected...
 114 set(MEMORYCHECK_SUPPRESSIONS_FILE
 115     "${CMAKE_SOURCE_DIR}/cmake/legacy_and_external.supp"
 116     CACHE FILEPATH
 117     "File that contains suppressions for the memory checker")
 118 include(CTest)
 119
 120 ########################################################################
 121 # Check and warn if cache generated on a different host is being reused
 122 ########################################################################
 123 if(CMAKE_HOST_UNIX)
 124     execute_process(COMMAND hostname
 125                     OUTPUT_VARIABLE TMP_HOSTNAME
 126                     OUTPUT_STRIP_TRAILING_WHITESPACE)
 127     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}")
 128         message(WARNING "
 129             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
 130             is being reused! This could lead to inconsitencies; therefore, it is
 131             recommended to regenerate the cache!")
 132     endif()
 133     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
 134             "Hostname of the machine where the cache was generated.")
 135 endif()
 136
 137 ########################################################################
 138 # User input options                                                   #
 139 ########################################################################
 140 include(gmxOptionUtilities)
 141
 142 set(CMAKE_PREFIX_PATH "" CACHE STRING "Extra locations to search for external libraries and tools (give directory without lib, bin, or include)")
 143
 144 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" OFF)
 145 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 146 option(GMX_THREAD_MPI  "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" ON)
 147 gmx_dependent_option(
 148     GMX_MPI_IN_PLACE
 149     "Enable MPI_IN_PLACE for MPIs that have it defined"
 150     ON
 151     GMX_MPI)
 152 mark_as_advanced(GMX_MPI_IN_PLACE)
 153 option(GMX_SOFTWARE_INVSQRT "Use GROMACS software 1/sqrt" ON)
 154 mark_as_advanced(GMX_SOFTWARE_INVSQRT)
 155 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 156 mark_as_advanced(GMX_FAHCORE)
 157
 158 option(GMX_COOL_QUOTES "Enable Gromacs cool quotes" ON)
 159 mark_as_advanced(GMX_COOL_QUOTES)
 160 gmx_add_cache_dependency(GMX_COOL_QUOTES BOOL "NOT GMX_FAHCORE" OFF)
 161
 162 # Decide on GPU settings based on user-settings and GPU/CUDA detection.
 163 # We support CUDA >=v4.0 on *nix, but <= v4.1 doesn't work with MSVC
 164 if(MSVC)
 165     set(REQUIRED_CUDA_VERSION 4.1)
 166 else()
 167     set(REQUIRED_CUDA_VERSION 4.0)
 168 endif()
 169 set(REQUIRED_CUDA_COMPUTE_CAPABILITY 2.0)
 170 include(gmxManageGPU)
 171
 172 # Detect the architecture the compiler is targetting, detect
 173 # SIMD instructions possibilities on that hardware, suggest SIMD instruction set
 174 # to use if none is specified, and populate the cache option for CPU
 175 # SIMD.
 176 include(gmxDetectTargetArchitecture)
 177 gmx_detect_target_architecture()
 178
 179 if(GMX_CPU_ACCELERATION)
 180     # Stay compatible with old Jenkins command line options for specific SIMD acceleration
 181     set(GMX_SIMD "${GMX_CPU_ACCELERATION}" CACHE STRING "SIMD instruction set level and compiler optimization" FORCE)
 182     message("You set GMX_CPU_ACCELERATION, which is deprecated, and will be removed in a later version of GROMACS. It is replaced by GMX_SIMD. For now, copying the value from GMX_CPU_ACCELERATION to GMX_SIMD.")
 183     # TODO remove all references to GMX_CPU_ACCELERATION in master branch
 184 endif()
 185
 186 if(NOT GMX_TARGET_MIC)
 187     include(gmxDetectSimd)
 188     gmx_detect_simd(GMX_SUGGESTED_SIMD)
 189 else()
 190     set(GMX_SUGGESTED_SIMD "None")
 191 endif()
 192
 193 gmx_option_multichoice(
 194     GMX_SIMD
 195     "SIMD instruction set for CPU kernels and compiler optimization"
 196     "${GMX_SUGGESTED_SIMD}"
 197     None SSE2 SSE4.1 AVX_128_FMA AVX_256 AVX2_256 IBM_QPX Sparc64_HPC_ACE Reference)
 198
 199 gmx_option_multichoice(
 200     GMX_FFT_LIBRARY
 201     "FFT library"
 202     "fftw3"
 203     fftw3 mkl "fftpack[built-in]")
 204 gmx_dependent_option(
 205     GMX_BUILD_OWN_FFTW
 206     "Download and build FFTW 3 during the GROMACS build process, rather than fall back on the really slow fftpack."
 207     OFF
 208     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 209 gmx_dependent_option(
 210     GMX_DISABLE_FFTW_MEASURE
 211     "Do not optimize FFTW setups (not needed with SSE)"
 212     OFF
 213     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 214 mark_as_advanced(GMX_BUILD_OWN_FFTW)
 215 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 216
 217 gmx_option_multichoice(
 218     GMX_QMMM_PROGRAM
 219     "QM package for QM/MM"
 220     None
 221     none gaussian mopac gamess orca)
 222
 223 gmx_dependent_cache_variable(GMX_SIMD_REF_FLOAT_WIDTH  "Reference SIMD single precision width" STRING "4" "GMX_SIMD STREQUAL REFERENCE")
 224 gmx_dependent_cache_variable(GMX_SIMD_REF_DOUBLE_WIDTH "Reference SIMD double precision width" STRING "2" "GMX_SIMD STREQUAL REFERENCE")
 225
 226 # This should be moved to a separate NBNXN cmake module when that code is cleaned up and modularized
 227
 228 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 229 mark_as_advanced(GMX_BROKEN_CALLOC)
 230 option(GMX_LOAD_PLUGINS "Compile with plugin support, needed to read VMD supported file formats" ON)
 231 mark_as_advanced(GMX_LOAD_PLUGINS)
 232
 233 option(GMX_GPU  "Enable GPU acceleration" ON)
 234 option(GMX_OPENMP "Enable OpenMP-based multithreading" ON)
 235
 236 option(GMX_USE_TNG "Use the TNG library for trajectory I/O" ON)
 237
 238 if(UNIX)
 239     option(GMX_SYMLINK_OLD_BINARY_NAMES "Create symbolic links for pre-5.0 binary names" ON)
 240 endif()
 241 option(GMX_BUILD_MDRUN_ONLY "Build and install only the mdrun binary" OFF)
 242
 243 option(GMX_CYCLE_SUBCOUNTERS "Enable cycle subcounters to get a more detailed cycle timings" OFF)
 244 mark_as_advanced(GMX_CYCLE_SUBCOUNTERS)
 245
 246 option(GMX_SKIP_DEFAULT_CFLAGS "Don't automatically add suggested/required Compiler flags." OFF)
 247 mark_as_advanced(GMX_SKIP_DEFAULT_CFLAGS)
 248
 249 option(GMX_BUILD_FOR_COVERAGE
 250        "Tune build for better code coverage metrics (e.g., disable asserts)"
 251        OFF)
 252 mark_as_advanced(GMX_BUILD_FOR_COVERAGE)
 253
 254
 255 ######################################################################
 256 # Detect OpenMP support
 257 ######################################################################
 258 # The OpenMP detection _must_ come before tests for other CFLAGS.
 259 include(gmxManageOpenMP)
 260
 261
 262
 263 ######################################################################
 264 # Compiler tests
 265 # These need to be done early (before further tests).
 266 #####################################################################
 267
 268 # The cmake/Check{C,CXX}CompilerFlag.cmake files in the GROMACS distribution
 269 # are used with permission from CMake v2.8.9 so that GROMACS can detect
 270 # invalid options with the Intel Compilers.
 271 # These files should be removed from the source tree when a CMake version that
 272 # includes the features in question becomes required for building GROMACS.
 273 include(CheckCCompilerFlag)
 274 include(CheckCXXCompilerFlag)
 275
 276
 277 include(gmxCFlags)
 278 gmx_c_flags()
 279
 280 # This variable should be used for additional compiler flags which are not
 281 # generated in gmxCFlags nor are SIMD or MPI related.
 282 set(EXTRA_C_FLAGS "")
 283 set(EXTRA_CXX_FLAGS "")
 284
 285 # Run through a number of tests for buggy compilers and other issues
 286 include(gmxTestCompilerProblems)
 287 gmx_test_compiler_problems()
 288 # GMX_SIMD will not be set automatically until the second
 289 # pass (which is not strictly guaranteed to occur), so putting this
 290 # check here among logically-related tests is inefficient, but the
 291 # potential loss is likely zero.
 292 if(GMX_SIMD STREQUAL "AVX_256"
 293         AND CMAKE_COMPILER_IS_GNUCC
 294         AND (C_COMPILER_VERSION VERSION_EQUAL "4.6.1"
 295             OR CXX_COMPILER_VERSION VERSION_EQUAL "4.6.1"))
 296     message(FATAL_ERROR "gcc 4.6.1 has buggy support for AVX, and GROMACS mdrun will not work. If you want simulation performance, use a more recent compiler. Otherwise, use GMX_SIMD=SSE4.1")
 297     # See http://gcc.gnu.org/bugzilla/show_bug.cgi?id=49002
 298 endif()
 299
 300
 301
 302 set(PKG_CFLAGS "")
 303 if(GMX_DOUBLE)
 304     add_definitions(-DGMX_DOUBLE)
 305     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_DOUBLE")
 306 endif()
 307 if(GMX_SOFTWARE_INVSQRT)
 308   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_SOFTWARE_INVSQRT")
 309 endif()
 310
 311 if(WIN32 AND NOT CYGWIN)
 312     set(GMX_WSOCKLIB_PATH CACHE PATH "Path to winsock (wsock32.lib) library.")
 313     mark_as_advanced(GMX_WSOCKLIB_PATH)
 314     find_library(WSOCK32_LIBRARY NAMES wsock32 PATHS ${GMX_WSOCKLIB_PATH})
 315     if(WSOCK32_LIBRARY)
 316         list(APPEND GMX_EXTRA_LIBRARIES ${WSOCK32_LIBRARY})
 317         add_definitions(-DGMX_HAVE_WINSOCK)
 318     else()
 319         message(STATUS "No winsock found. Cannot use interactive molecular dynamics (IMD).")
 320     endif(WSOCK32_LIBRARY)
 321 endif()
 322
 323
 324
 325 ########################################################################
 326 # Basic system tests (standard libraries, headers, functions, types)   #
 327 ########################################################################
 328 include(CheckIncludeFiles)
 329 include(CheckIncludeFileCXX)
 330 check_include_files(unistd.h     HAVE_UNISTD_H)
 331 check_include_files(pwd.h        HAVE_PWD_H)
 332 check_include_files(dirent.h     HAVE_DIRENT_H)
 333 check_include_files(time.h       HAVE_TIME_H)
 334 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 335 check_include_files(io.h         HAVE_IO_H)
 336 check_include_files(sched.h      HAVE_SCHED_H)
 337
 338 check_include_files(regex.h      HAVE_POSIX_REGEX)
 339 check_include_file_cxx(regex     HAVE_CXX11_REGEX)
 340 # TODO: It could be nice to inform the user if no regex support is found,
 341 # as selections won't be fully functional.
 342
 343 include(CheckFunctionExists)
 344 check_function_exists(posix_memalign    HAVE_POSIX_MEMALIGN)
 345 check_function_exists(memalign          HAVE_MEMALIGN)
 346 check_function_exists(_aligned_malloc   HAVE__ALIGNED_MALLOC)
 347 check_function_exists(gettimeofday      HAVE_GETTIMEOFDAY)
 348 check_function_exists(fsync             HAVE_FSYNC)
 349 check_function_exists(_fileno           HAVE__FILENO)
 350 check_function_exists(fileno            HAVE_FILENO)
 351 check_function_exists(_commit           HAVE__COMMIT)
 352 check_function_exists(sigaction         HAVE_SIGACTION)
 353 check_function_exists(sysconf           HAVE_SYSCONF)
 354 check_function_exists(sched_setaffinity HAVE_SCHED_SETAFFINITY)
 355 check_function_exists(sched_getaffinity HAVE_SCHED_GETAFFINITY)
 356 check_function_exists(rsqrt             HAVE_RSQRT)
 357 check_function_exists(rsqrtf            HAVE_RSQRTF)
 358 check_function_exists(sqrtf             HAVE_SQRTF)
 359
 360 include(CheckLibraryExists)
 361 check_library_exists(m sqrt "" HAVE_LIBM)
 362 check_library_exists(rt clock_gettime "" HAVE_CLOCK_GETTIME)
 363
 364 include(TestBigEndian)
 365 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 366
 367 # Management of GROMACS options for specific toolchains should go
 368 # here. Because the initial settings for some of the main options have
 369 # already happened, but things like library detection and MPI compiler
 370 # feature detection have not, the docstrings for any over-rides of
 371 # GROMACS defaults or user settings will make sense. Also, any
 372 # toolchain-related reasons for choosing whether to detect various
 373 # things can be sorted out now, before the detection takes place.
 374 if(${CMAKE_SYSTEM_NAME} MATCHES BlueGene)
 375     include(gmxManageBlueGene)
 376 endif()
 377
 378 ########################################################################
 379 #Process MPI settings
 380 ########################################################################
 381 include(gmxManageMPI)
 382
 383
 384 ########################################################################
 385 #Process shared/static library settings
 386 ########################################################################
 387 include(gmxManageSharedLibraries)
 388
 389
 390 ########################################################################
 391 # Find external packages                                               #
 392 ########################################################################
 393
 394 # Unconditionally find the package, as it is also required for unit
 395 # tests. This exports LIBXML2_FOUND, which we should not use because
 396 # it does not tell us that linking will succeed. Instead, we test that
 397 # next.
 398 if(DEFINED LIBXML2_LIBRARIES)
 399   set(LibXml2_FIND_QUIETLY TRUE)
 400 endif()
 401 find_package(LibXml2)
 402 include(gmxTestLibXml2)
 403 gmx_test_libxml2(HAVE_LIBXML2)
 404 option(GMX_XML "Use libxml2 to parse xml files (currently has no effect)" ${HAVE_LIBXML2})
 405 set(PKG_XML "")
 406 mark_as_advanced(GMX_XML)
 407 # Don't actually do anything, since libxml2 is currently not used by libgromacs
 408 #if(GMX_XML AND NOT HAVE_LIBXML2)
 409 #    message(FATAL_ERROR "libxml2 not found. Set GMX_XML=OFF to compile without XML support")
 410 #endif()
 411 #if(GMX_XML)
 412 #    include_directories(${LIBXML2_INCLUDE_DIR})
 413 #    set(PKG_XML libxml-2.0)
 414 #    set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 415 #endif()
 416
 417 option(GMX_EXTRAE "Add support for tracing using EXTRAE" OFF)
 418 mark_as_advanced(GMX_EXTRAE)
 419
 420 if (GMX_EXTRAE)
 421   find_package(EXTRAE)
 422   if(EXTRAE_FOUND)
 423     include_directories(${EXTRAE_INCLUDE_DIR})
 424     set(HAVE_EXTRAE 1)
 425   else()
 426     message(FATAL_ERROR "EXTRAE library was not found. Please add the correct path to CMAKE_PREFIX_PATH")
 427   endif()
 428 endif()
 429
 430 option(GMX_X11 "Use X window system" OFF)
 431 if (GMX_X11)
 432     find_package(X11)
 433     # X11 includes/libraries are only set in the ngmx subdirectory!
 434     if(NOT X11_FOUND)
 435         message(FATAL_ERROR
 436                 "X11 include files and/or libraries were not found. "
 437                 "Set GMX_X11=OFF to compile without X11 support. "
 438                 "gmx view will not be available.")
 439     endif()
 440     include_directories(${X11_INCLUDE_DIR})
 441 endif()
 442
 443 include(ThreadMPI)
 444 # Enable core threading facilities
 445 tmpi_enable_core("${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include")
 446 # Enable tMPI C++ support
 447 tmpi_enable_cxx()
 448 if(GMX_THREAD_MPI)
 449     # enable MPI functions
 450     tmpi_enable()
 451     set(GMX_MPI 1)
 452     set(MPI_IN_PLACE_EXISTS 1)
 453 endif()
 454 # If atomics are manually disabled a define is needed because atomics.h doesn't depend on config.h
 455 if (TMPI_ATOMICS_DISABLED)
 456    add_definitions(-DTMPI_ATOMICS_DISABLED)
 457 endif()
 458
 459 if(GMX_GPU)
 460     # now that we have detected the dependencies, do the second configure pass
 461     gmx_gpu_setup()
 462 endif()
 463
 464 if(CYGWIN)
 465     set(GMX_CYGWIN 1)
 466 endif()
 467
 468 if(WIN32 AND NOT CYGWIN)
 469     set(GMX_NATIVE_WINDOWS 1)
 470     # This makes windows.h not declare min/max as macros that would break
 471     # C++ code using std::min/std::max.
 472     add_definitions(-DNOMINMAX)
 473 endif()
 474
 475 # Detect boost unless GMX_EXTERNAL_BOOST is explicitly OFF
 476 # Used for default if GMX_EXTERNAL_BOOST is not defined (first CMake pass)
 477 if(NOT DEFINED GMX_EXTERNAL_BOOST OR GMX_EXTERNAL_BOOST)
 478     find_package(Boost 1.44.0)
 479     if(Boost_FOUND AND Boost_VERSION VERSION_LESS "104400")
 480         set(Boost_FOUND FALSE)
 481     endif()
 482     # Print the notification only on first run, when determining the default
 483     if(NOT DEFINED GMX_EXTERNAL_BOOST AND NOT Boost_FOUND)
 484         message("Boost >= 1.44 not found. Using minimal internal version. "
 485                 "This may cause trouble if you plan on compiling/linking other "
 486                 "software that uses Boost against Gromacs.")
 487     endif()
 488 endif()
 489 option(GMX_EXTERNAL_BOOST "Use external Boost instead of minimal built-in version"
 490        ${Boost_FOUND})
 491 if(GMX_EXTERNAL_BOOST AND NOT Boost_FOUND)
 492     message(FATAL_ERROR
 493         "Boost >= 1.44 not found. "
 494         "You can set GMX_EXTERNAL_BOOST=OFF to compile against minimal "
 495         "version of Boost included with Gromacs.")
 496 endif()
 497
 498 if(NOT DEFINED GMX_BUILD_UNITTESTS AND NOT HAVE_LIBXML2)
 499     message(WARNING "libxml2 not found. Will build GROMACS without unit-tests. This is not recommended, because the unit-tests help to verify that GROMACS functions correctly. Most likely you are missing the libxml2-dev(el) package. After you installed it, set GMX_BUILD_UNITTESTS=ON.")
 500 endif()
 501 option(GMX_BUILD_UNITTESTS "Build unit tests with BUILD_TESTING (uses Google C++ Testing and Mocking Frameworks, requires libxml2)" ${HAVE_LIBXML2})
 502 mark_as_advanced(GMX_BUILD_UNITTESTS)
 503 gmx_add_cache_dependency(GMX_BUILD_UNITTESTS BOOL BUILD_TESTING OFF)
 504 if (GMX_BUILD_UNITTESTS AND NOT HAVE_LIBXML2)
 505     message(FATAL_ERROR
 506         "Cannot build unit tests without libxml2. "
 507         "Either set GMX_BUILD_UNITTESTS=OFF or tell CMake how to find a working version of libxml2.")
 508 endif()
 509
 510 ########################################################################
 511 # Our own GROMACS tests
 512 ########################################################################
 513
 514 add_definitions( -DHAVE_CONFIG_H )
 515 include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src)
 516 include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include)
 517 # Required for config.h, maybe should only be set in src/CMakeLists.txt
 518 include_directories(BEFORE ${CMAKE_BINARY_DIR}/src)
 519 # Required for now to make old code compile
 520 include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src/gromacs/legacyheaders)
 521
 522 include(gmxTestInlineASM)
 523 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 524
 525 include(gmxSetBuildInformation)
 526 gmx_set_build_information()
 527 # Turn on RDTSCP if:
 528 # - the build system's CPU supports it
 529 # - the acceleration is set to AVX as all AVX-capable CPUs support AVX (which
 530 #   at this point means that the user set it).
 531 # Note: it's better to not use the later set value of GMX_SIMD because
 532 # it reflects the system's capability of both compiling and running AVX code.
 533 # TODO: After merge with 5.0 one could implement a cache variable dependency
 534 # such that GMX_USE_RDTSCP can change if GMX_SIMD is changed to AVX
 535 # after the first cmake pass.
 536 if (BUILD_CPU_FEATURES MATCHES "rdtscp" OR GMX_SIMD MATCHES "AVX")
 537     set(GMX_USE_RDTSCP_DEFAULT_VALUE ON)
 538 else()
 539     set(GMX_USE_RDTSCP_DEFAULT_VALUE OFF)
 540 endif()
 541 option(GMX_USE_RDTSCP "Use RDTSCP for better CPU-based timers (available on recent x86 CPUs; might need to be off when compiling for heterogeneous environments)" ${GMX_USE_RDTSCP_DEFAULT_VALUE})
 542 mark_as_advanced(GMX_USE_RDTSCP)
 543 if(GMX_USE_RDTSCP)
 544     set(HAVE_RDTSCP 1)
 545 endif()
 546
 547 include(gmxTestFloatFormat)
 548 gmx_test_float_format(GMX_FLOAT_FORMAT_IEEE754
 549                       GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER
 550                       GMX_IEEE754_BIG_ENDIAN_WORD_ORDER)
 551
 552 include(gmxTestLargeFiles)
 553 gmx_test_large_files(GMX_LARGEFILES)
 554
 555 include(gmxTestSignal)
 556 gmx_test_sigusr1(HAVE_SIGUSR1)
 557
 558 include(gmxTestPipes)
 559 gmx_test_pipes(HAVE_PIPES)
 560
 561 include(gmxTestIsfinite)
 562 gmx_test_isfinite(HAVE_ISFINITE)
 563 gmx_test__isfinite(HAVE__ISFINITE)
 564 gmx_test__finite(HAVE__FINITE)
 565
 566 include(gmxTestCXX11)
 567 gmx_test_cxx11(GMX_CXX11_SUPPORTED GMX_CXX11_FLAGS)
 568 include(CMakeDependentOption)
 569 # nvcc does not support C++11 flags, so with GPUs we prefer to skip C++11 flags
 570 # entirely to keep the compilation environment uniform.
 571 cmake_dependent_option(GMX_CXX11
 572     "Use C++11 features"
 573     ON "GMX_CXX11_SUPPORTED AND NOT GMX_GPU" OFF)
 574 mark_as_advanced(GMX_CXX11)
 575 if(GMX_CXX11)
 576     set(EXTRA_CXX_FLAGS "${EXTRA_CXX_FLAGS} ${GMX_CXX11_FLAGS}")
 577 endif()
 578
 579
 580 include(gmxTestXDR)
 581 gmx_test_xdr(GMX_SYSTEM_XDR)
 582 if(NOT GMX_SYSTEM_XDR)
 583     set(GMX_INTERNAL_XDR 1)
 584 endif()
 585
 586
 587 ##################################################
 588 # Process SIMD instruction settings
 589 ##################################################
 590 # This checks what flags to add in order to
 591 # support the SIMD instructions we need, and sets
 592 # correct defines for the SIMD instructions supported.
 593 include(gmxTestSimd)
 594 gmx_test_simd()
 595
 596
 597 # Process QM/MM Settings
 598 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 599     set(GMX_QMMM_GAUSSIAN 1)
 600 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 601     set(GMX_QMMM_MOPAC 1)
 602 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 603     set(GMX_QMMM_GAMESS 1)
 604 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 605     set(GMX_QMMM_ORCA 1)
 606 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 607     # nothing to do
 608 else()
 609     gmx_invalid_option_value(GMX_QMMM_PROGRAM)
 610 endif()
 611
 612
 613 ##################################################
 614 # Process FFT library settings
 615 ##################################################
 616 include(gmxManageFFTLibraries)
 617
 618
 619 include(gmxManageLinearAlgebraLibraries)
 620
 621 # Whether GROMACS will really try to compile support for VMD plugins
 622 set(GMX_USE_PLUGINS OFF)
 623
 624 if(GMX_LOAD_PLUGINS)
 625   if(CYGWIN OR NOT WIN32)
 626     # Native Windows does not have, nor need dlopen
 627     # Note that WIN32 is set with Cygwin, but Cygwin needs dlopen to use plug-ins
 628     include(gmxTestdlopen)
 629     gmx_test_dlopen(HAVE_DLOPEN)
 630   endif()
 631
 632   # so, should we use plug-ins?
 633   if((WIN32 AND NOT CYGWIN) OR (HAVE_DLOPEN AND BUILD_SHARED_LIBS))
 634     if(NOT VMD_QUIETLY)
 635       MESSAGE(STATUS
 636           "Found the ability to use plug-ins when building shared libaries, "
 637           "so will compile to use plug-ins (e.g. to read VMD-supported file "
 638           "formats).")
 639     endif()
 640     if(NOT GMX_VMD_PLUGIN_PATH)
 641       find_package(VMD)
 642     endif()
 643     set(GMX_USE_PLUGINS ON)
 644     list(APPEND GMX_EXTRA_LIBRARIES ${CMAKE_DL_LIBS}) # magic cross-platform pre-set variable for dlopen library
 645     set(PKG_DL_LIBS "-l${CMAKE_DL_LIBS}")
 646   else()
 647     set(PKG_DL_LIBS)
 648   endif()
 649 endif()
 650 set(VMD_QUIETLY TRUE CACHE INTERNAL "")
 651
 652 # Link real-time library for POSIX timers. The check for clock_gettime
 653 # confirms the linkability of rt.
 654 if(HAVE_TIME_H AND HAVE_UNISTD_H AND HAVE_CLOCK_GETTIME)
 655     list(APPEND GMX_EXTRA_LIBRARIES rt)
 656 endif()
 657
 658 # Math and thread libraries must often come after all others when linking...
 659 if(HAVE_LIBM)
 660     list(APPEND GMX_EXTRA_LIBRARIES m)
 661 endif()
 662
 663 option(GMX_NACL "Configure for Native Client builds" OFF)
 664 if (GMX_NACL)
 665   list(APPEND GMX_EXTRA_LIBRARIES nosys)
 666   set(GMX_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -lnosys")
 667   set(GMX_NO_NICE 1)
 668   set(GMX_NO_RENAME 1)
 669 endif()
 670 mark_as_advanced(GMX_NACL)
 671
 672 if(GMX_FAHCORE)
 673   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 674       "Path to swindirect.h")
 675   include_directories(${COREWRAP_INCLUDE_DIR})
 676 endif()
 677
 678 option(GMX_BUILD_HELP "Build man pages, HTML help, and completions automatically (requires that compiled binaries can be executed on the build host)" OFF)
 679 mark_as_advanced(GMX_BUILD_HELP)
 680 if (GMX_BUILD_HELP AND SOURCE_IS_SOURCE_DISTRIBUTION AND
 681     "${CMAKE_CURRENT_SOURCE_DIR}" STREQUAL "${CMAKE_CURRENT_BINARY_DIR}")
 682
 683     message(FATAL_ERROR
 684         "Rebuilding HTML and man pages is not supported for in-source "
 685         "builds from a source distribution. "
 686         "Set GMX_BUILD_HELP=OFF or do an out-of-source build to proceed.")
 687 endif()
 688
 689 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 690 # these are set after everything else
 691 if (NOT GMX_SKIP_DEFAULT_CFLAGS)
 692     set(CMAKE_C_FLAGS "${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${CMAKE_C_FLAGS}")
 693     set(CMAKE_CXX_FLAGS "${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${CMAKE_CXX_FLAGS}")
 694     set(CMAKE_EXE_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}")
 695     set(CMAKE_SHARED_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS}")
 696 else()
 697     message("Recommended flags which are not added because GMX_SKIP_DEFAULT_CFLAGS=yes:")
 698     message("CMAKE_C_FLAGS: ${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${GMXC_CFLAGS}")
 699     message("CMAKE_C_FLAGS_RELEASE: ${GMXC_CFLAGS_RELEASE}")
 700     message("CMAKE_C_FLAGS_DEBUG: ${GMXC_CFLAGS_DEBUG}")
 701     message("CMAKE_CXX_FLAGS: ${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${GMXC_CXXFLAGS}")
 702     message("CMAKE_CXX_FLAGS_RELEASE: ${GMXC_CXXFLAGS_RELEASE}")
 703     message("CMAKE_CXX_FLAGS_DEBUG: ${GMXC_CXXFLAGS_DEBUG}")
 704     message("CMAKE_EXE_LINKER_FLAGS: ${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS}")
 705     message("CMAKE_SHARED_LINKER_FLAGS: ${MPI_LINKER_FLAGS}")
 706 endif()
 707
 708 if(NOT GMX_OPENMP)
 709     #Unset all OpenMP flags in case OpenMP was disabled either by the user
 710     #or because it was only partially detected (e.g. only for C but not C++ compiler)
 711     unset(OpenMP_C_FLAGS CACHE)
 712     unset(OpenMP_CXX_FLAGS CACHE)
 713 else()
 714     set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} ${OpenMP_LINKER_FLAGS})
 715     set(GMX_SHARED_LINKER_FLAGS ${GMX_SHARED_LINKER_FLAGS} ${OpenMP_SHARED_LINKER_FLAGS})
 716 endif()
 717 set(PKG_CFLAGS "${PKG_CFLAGS} ${OpenMP_C_FLAGS}")
 718
 719 ########################################################################
 720 # Specify install locations
 721 ########################################################################
 722 # Use GNUInstallDirs to set paths on multiarch systems.
 723 include(GNUInstallDirs)
 724
 725 # Customization for the installation tree paths.
 726 set(GMX_LIB_INSTALL_DIR ${CMAKE_INSTALL_LIBDIR} CACHE STRING
 727     "Library installation directory (default: ${CMAKE_INSTALL_LIBDIR})")
 728 set(GMX_DATA_INSTALL_DIR gromacs CACHE STRING
 729     "Data installation directory under share/ (default: gromacs)")
 730 mark_as_advanced(GMX_LIB_INSTALL_DIR GMX_DATA_INSTALL_DIR)
 731
 732 # These variables are used internally to provide a central location for
 733 # customizing the install locations.
 734 set(LIB_INSTALL_DIR  ${GMX_LIB_INSTALL_DIR})
 735 set(BIN_INSTALL_DIR  bin)
 736 set(DATA_INSTALL_DIR share/${GMX_DATA_INSTALL_DIR})
 737 set(MAN_INSTALL_DIR  share/man)
 738 set(INCL_INSTALL_DIR include)
 739
 740 # These variables get written into config.h for use in finding the data
 741 # directories.
 742 set(GMXLIB_SEARCH_DIR share/${GMX_DATA_INSTALL_DIR}/top)
 743 set(GMXLIB_FALLBACK   ${CMAKE_INSTALL_PREFIX}/${DATA_INSTALL_DIR}/top)
 744
 745 # Binary and library suffix options
 746 include(gmxManageSuffixes)
 747
 748 ################################################################
 749 # Shared library load path settings
 750 ################################################################
 751 # CMake supports RPATH on OS X only from 2.8.12 upwards.
 752 # CMAKE_SYSTEM_VERSION > 8.0 matches OS X 10.5 and above, where RPATH support
 753 # was added.
 754 if((NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin") OR
 755    ((CMAKE_SYSTEM_VERSION VERSION_GREATER 8.0) AND (NOT CMAKE_VERSION VERSION_LESS 2.8.12)))
 756     # The build folder always has bin/ and lib/; if we are also going to
 757     # install to lib/, then the installation RPATH works also in the build
 758     # tree.  This makes installation slightly faster (no need to rewrite the
 759     # RPATHs), and makes the binaries in the build tree relocatable.
 760     if(GMX_LIB_INSTALL_DIR STREQUAL "lib")
 761         set(CMAKE_BUILD_WITH_INSTALL_RPATH TRUE)
 762     endif()
 763     # Set the RPATH as relative to the executable location to make the
 764     # binaries relocatable.
 765     if(NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin")
 766         set(CMAKE_INSTALL_RPATH "\$ORIGIN/../${GMX_LIB_INSTALL_DIR}")
 767     else()
 768         set(CMAKE_INSTALL_RPATH "@executable_path/../${GMX_LIB_INSTALL_DIR}")
 769     endif()
 770     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 771     set(CMAKE_MACOSX_RPATH 1)
 772 else()
 773     # We are on Darwin/OSX, and CMake cannot handle RPATHs automatically.
 774     if(CMAKE_SYSTEM_VERSION VERSION_GREATER 8.0)
 775         # Set the RPATH options manually.
 776         set(CMAKE_INSTALL_NAME_DIR "@rpath")
 777         set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} "-Wl,-rpath,@executable_path/../${GMX_LIB_INSTALL_DIR}")
 778     else()
 779         # Use the old INSTALL_NAME_DIR mechanism if RPATH is not supported.
 780         set(CMAKE_INSTALL_NAME_DIR "${CMAKE_INSTALL_PREFIX}/${LIB_INSTALL_DIR}")
 781     endif()
 782 endif()
 783
 784 #COPYING file: Only necessary for binary distributions.
 785 #Simpler to always install.
 786 install(FILES COPYING DESTINATION ${DATA_INSTALL_DIR} COMPONENT data)
 787
 788 if(GMX_EXTERNAL_BOOST)
 789     include_directories(${Boost_INCLUDE_DIRS})
 790     set(PKG_CFLAGS "${PKG_CFLAGS} -I${Boost_INCLUDE_DIRS}")
 791 else()
 792     include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src/external/boost)
 793     # typeid not supported for minimal internal version
 794     # (would add significant amount of code)
 795     add_definitions(-DBOOST_NO_TYPEID)
 796     # TODO: Propagate the above settings to the installed CMakeFiles.txt template
 797     # (from share/template/)
 798     set(PKG_CFLAGS "${PKG_CFLAGS} -DBOOST_NO_TYPEID -I${CMAKE_INSTALL_PREFIX}/${INCL_INSTALL_DIR}/gromacs/external/boost")
 799     if (NOT GMX_BUILD_MDRUN_ONLY)
 800         install(DIRECTORY ${CMAKE_SOURCE_DIR}/src/external/boost/boost
 801                 DESTINATION ${INCL_INSTALL_DIR}/gromacs/external/boost
 802                 COMPONENT development)
 803     endif()
 804 endif()
 805
 806 if (GMX_BUILD_FOR_COVERAGE)
 807     # Code heavy with asserts makes conditional coverage close to useless metric,
 808     # as by design most of the false branches are impossible to trigger in
 809     # correctly functioning code.  And the benefit of testing those that could
 810     # be triggered by using an API against its specification isn't usually
 811     # worth the effort.
 812     add_definitions(-DNDEBUG -DBOOST_DISABLE_ASSERTS -DGMX_DISABLE_ASSERTS)
 813 endif()
 814
 815 if (BUILD_TESTING)
 816     # "tests" target builds all the separate test binaries.
 817     add_custom_target(tests)
 818     # "run-ctest" is an internal target that actually runs the tests.
 819     # This is necessary to be able to add separate targets that execute as part
 820     # of 'make check', but are ensured to be executed after the actual tests.
 821     add_custom_target(run-ctest
 822                       COMMAND ${CMAKE_CTEST_COMMAND} --output-on-failure
 823                       COMMENT "Running all tests"
 824                       VERBATIM)
 825     add_dependencies(run-ctest tests)
 826     # "check" target builds and runs all tests.
 827     add_custom_target(check DEPENDS run-ctest)
 828 endif()
 829
 830 if (NOT GMX_BUILD_MDRUN_ONLY)
 831     add_subdirectory(doxygen)
 832     add_subdirectory(install-guide)
 833     add_subdirectory(share)
 834     add_subdirectory(scripts)
 835 endif()
 836 add_subdirectory(src)
 837
 838 if (BUILD_TESTING)
 839     add_subdirectory(tests)
 840 endif()
 841
 842 # Issue a warning if NVIDIA GPUs were detected, but CUDA was not found.
 843 # Don't bother the user after the first configure pass.
 844 if ((CUDA_NOTFOUND_AUTO AND GMX_DETECT_GPU_AVAILABLE) AND NOT GMX_GPU_DETECTION_DONE)
 845     message(WARNING "${CUDA_NOTFOUND_MESSAGE}")
 846 endif()
 847 set(GMX_GPU_DETECTION_DONE TRUE CACHE INTERNAL "Whether GPU detection has already been done")
 848
 849 #######################
 850 ## uninstall target
 851 #######################
 852 CONFIGURE_FILE(   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 853                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
 854                   IMMEDIATE @ONLY)
 855 ###########################
 856 ADD_CUSTOM_TARGET(uninstall
 857                   "${CMAKE_COMMAND}" -P
 858                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
 859 ###########################
 860 set_directory_properties(PROPERTIES
 861             ADDITIONAL_MAKE_CLEAN_FILES "install_manifest.txt")
 862
 863 ########################################################################
 864 # Manual                                                               #
 865 ########################################################################
 866
 867 option(GMX_BUILD_MANUAL "Whether to try to configure to build the PDF manual" OFF)
 868 mark_as_advanced(GMX_BUILD_MANUAL)
 869 if(GMX_BUILD_MANUAL)
 870     # Make sure we only do detection of manual-building dependencies
 871     # when the user opted in for that.
 872     add_subdirectory(manual)
 873 endif()