CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2009,2010,2011,2012,2013,2014,2015,2016,2017,2018, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 cmake_minimum_required(VERSION 3.4.3)
  36
  37 # CMake modules/macros are in a subdirectory to keep this file cleaner
  38 # This needs to be set before project() in order to pick up toolchain files
  39 list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake ${CMAKE_CURRENT_SOURCE_DIR}/cmake/Platform)
  40
  41 project(Gromacs)
  42
  43 # Use ccache if available to wrap CMAKE_C_COMPILER and CMAKE_CXX_COMPILER.
  44 # Reference https://ccache.samba.org
  45 option(ENABLE_CCACHE "Allow CMake to use ccache compiler wrappers if available." ON)
  46 # CMAKE_C_COMPILER and CMAKE_CXX_COMPILER do not change after this line.
  47 if(ENABLE_CCACHE)
  48     include(gmxCcache)
  49 endif()
  50
  51 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  52 set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  53 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
  54
  55 # Set up common version variables, as well as general information about
  56 # the build tree (whether the build is from a source package or from a git
  57 # repository).  Also declares a few functions that will be used for generating
  58 # version info files later.
  59 include(gmxBuildTreeInfo)
  60 include(gmxVersionInfo)
  61
  62 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT AND UNIX)
  63     set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
  64 endif()
  65 if("${CMAKE_INSTALL_PREFIX}" STREQUAL "${CMAKE_BINARY_DIR}")
  66     message(FATAL_ERROR "GROMACS cannot be installed into the build tree, choose a different location for CMAKE_INSTALL_PREFIX")
  67 endif()
  68
  69 include(gmxBuildTypeReference)
  70 include(gmxBuildTypeProfile)
  71 include(gmxBuildTypeTSAN)
  72 include(gmxBuildTypeASAN)
  73 include(gmxBuildTypeMSAN)
  74 include(gmxBuildTypeReleaseWithAssert)
  75
  76 if(NOT CMAKE_BUILD_TYPE)
  77     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel Reference RelWithAssert Profile TSAN ASAN MSAN." FORCE)
  78     # Set the possible values of build type for cmake-gui
  79     set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "Debug" "Release"
  80         "MinSizeRel" "RelWithDebInfo" "Reference" "RelWithAssert" "Profile" "TSAN" "ASAN" "MSAN")
  81 endif()
  82 if(CMAKE_CONFIGURATION_TYPES)
  83     # Add appropriate GROMACS-specific build types for the Visual
  84     # Studio generator (Debug, Release, MinSizeRel and RelWithDebInfo
  85     # are already present by default).
  86     list(APPEND CMAKE_CONFIGURATION_TYPES "RelWithAssert" "Reference")
  87     list(REMOVE_DUPLICATES CMAKE_CONFIGURATION_TYPES)
  88     set(CMAKE_CONFIGURATION_TYPES "${CMAKE_CONFIGURATION_TYPES}" CACHE STRING
  89         "List of configuration types"
  90         FORCE)
  91 endif()
  92 set(build_types_with_explicit_flags RELEASE DEBUG RELWITHDEBINFO RELWITHASSERT MINSIZEREL PROFILE)
  93
  94 set_property(GLOBAL PROPERTY FIND_LIBRARY_USE_LIB64_PATHS ON)
  95
  96 include(gmxCTestUtilities)
  97 gmx_ctest_init()
  98
  99 include(gmxCPackUtilities)
 100 gmx_cpack_init()
 101
 102 # Variables that accumulate stuff influencing the installed headers
 103 set(INSTALLED_HEADER_INCLUDE_DIRS "")
 104 set(INSTALLED_HEADER_DEFINITIONS "")
 105
 106 ########################################################################
 107 # Global non-cache variables for implementing the build system
 108 ########################################################################
 109
 110 # These variables collect libraries that GROMACS requires for
 111 # linking. They should be appended to with list(APPEND ${name}
 112 # new-library) calls. They are:
 113 #  - Libraries that are required for libgromacs (only)
 114 set(GMX_EXTRA_LIBRARIES "")
 115 #  - Libraries that are required for all code in the repository
 116 set(GMX_COMMON_LIBRARIES "")
 117 #  - Libraries that all code linked against libgromacs needs
 118 #    (i.e., something that is exposed in installed headers).
 119 set(GMX_PUBLIC_LIBRARIES "")
 120
 121 ########################################################################
 122 # Check and warn if cache generated on a different host is being reused
 123 ########################################################################
 124 if(CMAKE_HOST_UNIX)
 125     execute_process(COMMAND hostname
 126                     OUTPUT_VARIABLE TMP_HOSTNAME
 127                     OUTPUT_STRIP_TRAILING_WHITESPACE)
 128     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}")
 129         message(WARNING "
 130             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
 131             is being reused! This could lead to inconsistencies; therefore, it is
 132             recommended to regenerate the cache!")
 133     endif()
 134     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
 135             "Hostname of the machine where the cache was generated.")
 136 endif()
 137
 138 ########################################################################
 139 # Detect architecture before setting options so we can alter defaults
 140 ########################################################################
 141 # Detect the architecture the compiler is targetting, detect
 142 # SIMD instructions possibilities on that hardware, suggest SIMD instruction set
 143 # to use if none is specified, and populate the cache option for CPU
 144 # SIMD.
 145 include(gmxDetectTargetArchitecture)
 146 gmx_detect_target_architecture()
 147
 148 # Permit the user to specify a particular standard library, e.g. compiling
 149 # with "-stdlib=libc++" and linking with "-lc++abi -lc++" to get clang's libcxx.
 150 set(GMX_STDLIB_CXX_FLAGS "" CACHE STRING "Compiler flag for a C++ standard library flavour")
 151 set(GMX_STDLIB_LIBRARIES "" CACHE STRING "Linker libraries for a particular C++ standard library")
 152 mark_as_advanced(GMX_STDLIB_CXX_FLAGS)
 153 mark_as_advanced(GMX_STDLIB_LIBRARIES)
 154
 155 ########################################################################
 156 # Detect CXX11 support and flags
 157 ########################################################################
 158 # The cmake/Check{C,CXX}CompilerFlag.cmake files in the GROMACS distribution
 159 # are used with permission from CMake v3.0.0 so that GROMACS can detect
 160 # invalid options with the Intel Compilers, and we have added a line
 161 # to detect warnings with the Fujitsu compilers on K computer and ICC.
 162 # CMake-3.0 also has a bug where the FAIL_REGEX pattern for AIX contains
 163 # a semicolon. Since this is also used as a separator in lists inside CMake,
 164 # that string ends up being split into two separate patterns, and the last
 165 # part is just a single word that also matches other messages. We solved this
 166 # by replacing the semicolon with a period that matches any character.
 167 #
 168 # These files should be removed from the source tree when a CMake version that
 169 # includes the features in question becomes required for building GROMACS.
 170 include(CheckCCompilerFlag)
 171 include(CheckCXXCompilerFlag)
 172
 173 # This must come early, since some of our configuration flag tests
 174 # depend on being able to compile C++11 source files.
 175 include(gmxTestCXX11)
 176 gmx_test_cxx11(GMX_CXX11_FLAGS GMX_STDLIB_CXX_FLAGS GMX_STDLIB_LIBRARIES)
 177
 178 # Make sure all C++ code will be compiled in C++11 mode, with the
 179 # expected standard library.
 180 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${GMX_CXX11_FLAGS} ${GMX_STDLIB_CXX_FLAGS}")
 181
 182 ########################################################################
 183 # User input options                                                   #
 184 ########################################################################
 185 include(gmxOptionUtilities)
 186
 187 set(CMAKE_PREFIX_PATH "" CACHE STRING "Extra locations to search for external libraries and tools (give directory without lib, bin, or include)")
 188
 189 # Fujitsu only has SIMD in double precision, so this will be faster
 190 gmx_set_boolean(GMX_DOUBLE_DEFAULT GMX_TARGET_FUJITSU_SPARC64)
 191 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" ${GMX_DOUBLE_DEFAULT})
 192 option(GMX_RELAXED_DOUBLE_PRECISION "Accept single precision 1/sqrt(x) when using Fujitsu HPC-ACE SIMD" OFF)
 193 mark_as_advanced(GMX_RELAXED_DOUBLE_PRECISION)
 194
 195 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 196 option(GMX_THREAD_MPI  "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" ON)
 197 gmx_dependent_option(
 198     GMX_MPI_IN_PLACE
 199     "Enable MPI_IN_PLACE for MPIs that have it defined"
 200     ON
 201     GMX_MPI)
 202 mark_as_advanced(GMX_MPI_IN_PLACE)
 203 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 204 mark_as_advanced(GMX_FAHCORE)
 205
 206 option(GMX_COOL_QUOTES "Enable GROMACS cool quotes" ON)
 207 mark_as_advanced(GMX_COOL_QUOTES)
 208 gmx_add_cache_dependency(GMX_COOL_QUOTES BOOL "NOT GMX_FAHCORE" OFF)
 209
 210 option(GMX_USE_OPENCL "Enable OpenCL acceleration" OFF)
 211
 212 # Decide on GPU settings based on user-settings and GPU/CUDA
 213 # detection. VS2017 requires CUDA 9.0, for the other arch/compilers
 214 # rest we require CUDA 7.0 or later (including for clang-CUDA).
 215 if(MSVC)
 216     set(REQUIRED_CUDA_VERSION 9.0)
 217 else()
 218     set(REQUIRED_CUDA_VERSION 7.0)
 219 endif()
 220 set(REQUIRED_CUDA_COMPUTE_CAPABILITY 2.0)
 221
 222 # OpenCL required version: 1.2 or newer
 223 set(REQUIRED_OPENCL_MIN_VERSION 1.2)
 224
 225 if(NOT GMX_USE_OPENCL)
 226     # CUDA detection is done only if GMX_USE_OPENCL is OFF.
 227     include(gmxManageGPU)
 228     set(GMX_USE_CUDA ${GMX_GPU})
 229     if(GMX_GPU)
 230         set(GMX_GPU_ACCELERATION_FRAMEWORK "GMX_GPU_CUDA")
 231     else()
 232         set(GMX_GPU_ACCELERATION_FRAMEWORK "GMX_GPU_NONE")
 233     endif()
 234 else()
 235     #Now the OpenCL path (for both AMD and NVIDIA)
 236     if(GMX_GPU)
 237         include(gmxManageOpenCL)
 238         set(GMX_GPU_ACCELERATION_FRAMEWORK "GMX_GPU_OPENCL")
 239     else()
 240         message(FATAL_ERROR "OpenCL requested but GPU option is not enabled (try -DGMX_GPU=on) ")
 241     endif()
 242 endif()
 243
 244 gmx_option_multichoice(
 245     GMX_SIMD
 246     "SIMD instruction set for CPU kernels and compiler optimization"
 247     "AUTO"
 248     AUTO None SSE2 SSE4.1 AVX_128_FMA AVX_256 AVX2_256 AVX2_128 AVX_512 AVX_512_KNL MIC ARM_NEON ARM_NEON_ASIMD IBM_VMX IBM_VSX Sparc64_HPC_ACE Reference)
 249
 250 if(GMX_TARGET_MIC)
 251     set(GMX_FFT_LIBRARY_DEFAULT "mkl")
 252 else()
 253     set(GMX_FFT_LIBRARY_DEFAULT "fftw3")
 254 endif()
 255
 256 gmx_option_multichoice(
 257     GMX_FFT_LIBRARY
 258     "FFT library"
 259     "${GMX_FFT_LIBRARY_DEFAULT}"
 260     fftw3 mkl "fftpack[built-in]")
 261 gmx_dependent_option(
 262     GMX_BUILD_OWN_FFTW
 263     "Download and build FFTW 3 during the GROMACS build process, rather than fall back on the really slow fftpack."
 264     OFF
 265     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 266 gmx_dependent_option(
 267     GMX_DISABLE_FFTW_MEASURE
 268     "Do not optimize FFTW setups (not needed with SSE)"
 269     OFF
 270     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 271 mark_as_advanced(GMX_BUILD_OWN_FFTW)
 272 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 273
 274 gmx_option_multichoice(
 275     GMX_QMMM_PROGRAM
 276     "QM package for QM/MM"
 277     None
 278     none gaussian mopac gamess orca)
 279
 280 gmx_dependent_cache_variable(GMX_SIMD_REF_FLOAT_WIDTH  "Reference SIMD single precision width" STRING "4" "GMX_SIMD STREQUAL REFERENCE")
 281 gmx_dependent_cache_variable(GMX_SIMD_REF_DOUBLE_WIDTH "Reference SIMD double precision width" STRING "2" "GMX_SIMD STREQUAL REFERENCE")
 282
 283 # This should be moved to a separate NBNXN cmake module when that code is cleaned up and modularized
 284
 285 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 286 mark_as_advanced(GMX_BROKEN_CALLOC)
 287
 288 option(GMX_OPENMP "Enable OpenMP-based multithreading" ON)
 289
 290 option(GMX_USE_TNG "Use the TNG library for trajectory I/O" ON)
 291
 292 option(GMX_BUILD_MDRUN_ONLY "Build and install only the mdrun binary" OFF)
 293
 294 option(GMX_CYCLE_SUBCOUNTERS "Enable cycle subcounters to get a more detailed cycle timings" OFF)
 295 mark_as_advanced(GMX_CYCLE_SUBCOUNTERS)
 296
 297 option(GMX_SKIP_DEFAULT_CFLAGS "Don't automatically add suggested/required Compiler flags." OFF)
 298 mark_as_advanced(GMX_SKIP_DEFAULT_CFLAGS)
 299
 300 option(GMX_BUILD_FOR_COVERAGE
 301        "Tune build for better code coverage metrics (e.g., disable asserts)"
 302        OFF)
 303 mark_as_advanced(GMX_BUILD_FOR_COVERAGE)
 304
 305 option(GMX_DEVELOPER_BUILD
 306     "Enable Developer convenience features: always build unit-tests"
 307     OFF)
 308 mark_as_advanced(GMX_DEVELOPER_BUILD)
 309
 310 gmx_set_boolean(GMX_COMPILER_WARNINGS_DEFAULT "NOT SOURCE_IS_SOURCE_DISTRIBUTION")
 311 option(GMX_COMPILER_WARNINGS
 312     "Enable a default set of compiler warnings"
 313     ${GMX_COMPILER_WARNINGS_DEFAULT})
 314 mark_as_advanced(GMX_COMPILER_WARNINGS)
 315 # Always turn on compiler warnings with a developer build.
 316 gmx_add_cache_dependency(GMX_COMPILER_WARNINGS BOOL "NOT GMX_DEVELOPER_BUILD" ON)
 317
 318 option(GMX_BUILD_SHARED_EXE
 319     "Build exectuables as shared binaries. If not set, this disables rpath and dynamic linker flags in an attempt to build a static binary, but this may require setting up the toolchain properly and making appropriate libraries available."
 320     ON)
 321 mark_as_advanced(GMX_BUILD_SHARED_EXE)
 322
 323 option(GMX_PHYSICAL_VALIDATION
 324        "Include physical validation tests in ctest environment. These can then be called using 'make check-phys' or
 325        'make check-all'. Warning: Running the physical validation tests takes significantly more time than other tests!"
 326        OFF)
 327 mark_as_advanced(GMX_PHYSICAL_VALIDATION)
 328
 329 ######################################################################
 330 # Detect OpenMP support
 331 ######################################################################
 332 # The OpenMP detection _must_ come before tests for other CFLAGS.
 333 include(gmxManageOpenMP)
 334
 335
 336
 337 ######################################################################
 338 # Compiler tests
 339 # These need to be done early (before further tests).
 340 #####################################################################
 341
 342 include(gmxCFlags)
 343 gmx_c_flags()
 344
 345 # This variable should be used for additional compiler flags which are not
 346 # generated in gmxCFlags nor are SIMD or MPI related.
 347 #
 348 # TODO These variables should be consolidated into
 349 # EXTRA_COMPILER_FLAGS so that we we don't perpetrate bugs where
 350 # things that work in C compilation (e.g. merging from old branches)
 351 # also work for C++ compilation.
 352 set(EXTRA_C_FLAGS "")
 353 set(EXTRA_CXX_FLAGS "")
 354
 355 # Run through a number of tests for buggy compilers and other issues
 356 include(gmxTestCompilerProblems)
 357 gmx_test_compiler_problems()
 358
 359 # Implement double-precision option. This is complicated because we
 360 # need installed headers to use the precision mode of the build that
 361 # produced the library, but cannot use config.h in that case. We also
 362 # want such variables to always have a definition, because #if is more
 363 # robust than #ifdef. So, we put this value on the compiler command
 364 # line in all cases.
 365 #
 366 # GMX_RELAXED_DOUBLE_PRECISION does not need to be handled here,
 367 # because no installed header needs it
 368 if(GMX_DOUBLE)
 369     set(GMX_DOUBLE_VALUE 1)
 370 else()
 371     set(GMX_DOUBLE_VALUE 0)
 372 endif()
 373 add_definitions(-DGMX_DOUBLE=${GMX_DOUBLE_VALUE})
 374 list(APPEND INSTALLED_HEADER_DEFINITIONS "-DGMX_DOUBLE=${GMX_DOUBLE_VALUE}")
 375
 376 if(WIN32)
 377     list(APPEND GMX_EXTRA_LIBRARIES "wsock32")
 378     add_definitions(-DGMX_HAVE_WINSOCK)
 379 endif()
 380
 381
 382
 383 ########################################################################
 384 # Basic system tests (standard libraries, headers, functions, types)   #
 385 ########################################################################
 386 include(CheckIncludeFiles)
 387 include(CheckIncludeFileCXX)
 388 check_include_files(unistd.h     HAVE_UNISTD_H)
 389 check_include_files(pwd.h        HAVE_PWD_H)
 390 check_include_files(dirent.h     HAVE_DIRENT_H)
 391 check_include_files(time.h       HAVE_TIME_H)
 392 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 393 check_include_files(io.h         HAVE_IO_H)
 394 check_include_files(sched.h      HAVE_SCHED_H)
 395
 396 check_include_files(regex.h      HAVE_POSIX_REGEX)
 397 # TODO: It could be nice to inform the user if no regex support is found,
 398 # as selections won't be fully functional.
 399
 400 include(CheckCXXSymbolExists)
 401 check_cxx_symbol_exists(gettimeofday      sys/time.h   HAVE_GETTIMEOFDAY)
 402 check_cxx_symbol_exists(sysconf           unistd.h     HAVE_SYSCONF)
 403 check_cxx_symbol_exists(nice              unistd.h     HAVE_NICE)
 404 check_cxx_symbol_exists(fsync             unistd.h     HAVE_FSYNC)
 405 check_cxx_symbol_exists(_fileno           stdio.h      HAVE__FILENO)
 406 check_cxx_symbol_exists(fileno            stdio.h      HAVE_FILENO)
 407 check_cxx_symbol_exists(_commit           io.h         HAVE__COMMIT)
 408 check_cxx_symbol_exists(sigaction         signal.h     HAVE_SIGACTION)
 409
 410 # We cannot check for the __builtins as symbols, but check if code compiles
 411 check_cxx_source_compiles("int main(){ return __builtin_clz(1);}"   HAVE_BUILTIN_CLZ)
 412 check_cxx_source_compiles("int main(){ return __builtin_clzll(1);}" HAVE_BUILTIN_CLZLL)
 413 if(MSVC)
 414     check_cxx_source_compiles("#include <intrin.h>\n int main(){unsigned long r;unsigned long i=1;_BitScanReverse(&r,i);return r;}" HAVE_BITSCANREVERSE)
 415     check_cxx_source_compiles("#include <intrin.h>\n int main(){unsigned long r;unsigned __int64 i=1;_BitScanReverse(&r,i);return r;}" HAVE_BITSCANREVERSE64)
 416 elseif(CMAKE_CXX_COMPILER_ID MATCHES "XL")
 417     check_cxx_source_compiles("int main(){ return __cntlz4(1);}" HAVE_CNTLZ4)
 418     check_cxx_source_compiles("int main(){ return __cntlz8(1);}" HAVE_CNTLZ8)
 419 endif()
 420
 421 include(CheckLibraryExists)
 422 find_library(HAVE_LIBM m)
 423 mark_as_advanced(HAVE_LIBM)
 424 check_library_exists(rt clock_gettime "" HAVE_CLOCK_GETTIME)
 425 check_library_exists(m feenableexcept "" HAVE_FEENABLEEXCEPT)
 426 check_library_exists(m fedisableexcept "" HAVE_FEDISABLEEXCEPT)
 427
 428 include(TestSchedAffinity)
 429 test_sched_affinity(HAVE_SCHED_AFFINITY)
 430
 431 # Aligned memory allocation. We need to check for both mm_malloc(),
 432 # posix_memalign(), memalign(), and on windows also _aligned_malloc()
 433 include(gmxTestMMMalloc)
 434 gmx_test_mm_malloc(HAVE__MM_MALLOC)
 435 check_cxx_symbol_exists(posix_memalign    stdlib.h     HAVE_POSIX_MEMALIGN)
 436 check_cxx_symbol_exists(memalign          stdlib.h     HAVE_MEMALIGN)
 437 if(MSVC)
 438     # No need to waste time on this test on platforms where it will never be true
 439     check_cxx_symbol_exists(_aligned_malloc   stdlib.h     HAVE__ALIGNED_MALLOC)
 440 endif()
 441
 442 include(TestBigEndian)
 443 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 444
 445 gmx_set_boolean(GMX_USE_NICE "HAVE_UNISTD_H AND HAVE_NICE")
 446
 447 # Management of GROMACS options for specific toolchains should go
 448 # here. Because the initial settings for some of the main options have
 449 # already happened, but things like library detection and MPI compiler
 450 # feature detection have not, the docstrings for any over-rides of
 451 # GROMACS defaults or user settings will make sense. Also, any
 452 # toolchain-related reasons for choosing whether to detect various
 453 # things can be sorted out now, before the detection takes place.
 454 if(GMX_TARGET_FUJITSU_SPARC64)
 455     include(gmxManageFujitsuSparc64)
 456 endif()
 457
 458 ########################################################################
 459 #Process MPI settings
 460 ########################################################################
 461 include(gmxManageMPI)
 462
 463
 464 ########################################################################
 465 #Process shared/static library settings
 466 ########################################################################
 467 include(gmxManageSharedLibraries)
 468
 469
 470 ########################################################################
 471 # Find external packages                                               #
 472 ########################################################################
 473
 474 # Unconditionally find the package, as it is also required for unit
 475 # tests. This exports LIBXML2_FOUND, which we should not use because
 476 # it does not tell us that linking will succeed. Instead, we test that
 477 # next.
 478 #if(DEFINED LIBXML2_LIBRARIES)
 479 #  set(LibXml2_FIND_QUIETLY TRUE)
 480 #endif()
 481 #find_package(LibXml2)
 482 #include(gmxTestLibXml2)
 483 #gmx_test_libxml2(HAVE_LIBXML2)
 484 #option(GMX_XML "Use libxml2 to parse xml files (currently has no effect)" ${HAVE_LIBXML2})
 485 #set(PKG_XML "")
 486 #mark_as_advanced(GMX_XML)
 487 # Don't actually do anything, since libxml2 is currently not used by libgromacs
 488 #if(GMX_XML AND NOT HAVE_LIBXML2)
 489 #    message(FATAL_ERROR "libxml2 not found. Set GMX_XML=OFF to compile without XML support")
 490 #endif()
 491 #if(GMX_XML)
 492 #    include_directories(${LIBXML2_INCLUDE_DIR})
 493 #    set(PKG_XML libxml-2.0)
 494 #    set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 495 #endif()
 496
 497 gmx_option_trivalue(
 498     GMX_HWLOC
 499     "Use hwloc portable hardware locality library"
 500     "AUTO")
 501
 502 if (GMX_HWLOC)
 503     # Find quietly the second time.
 504     if(DEFINED HWLOC_LIBRARIES)
 505         set(Hwloc_FIND_QUIETLY TRUE)
 506     endif()
 507     find_package(Hwloc 1.5)
 508
 509     if (HWLOC_FOUND)
 510         if (HWLOC_LIBRARIES MATCHES ".a$")
 511             set(_STATIC_HWLOC TRUE)
 512         endif()
 513
 514         gmx_check_if_changed(HWLOC_FOUND_CHANGED HWLOC_FOUND)
 515         if (_STATIC_HWLOC AND HWLOC_FOUND_CHANGED)
 516             message(STATUS "Static hwloc library found, will not attempt using it as it could lead to link-time errors. To use the detected library, manually set GMX_HWLOC=ON and you will likely have to pass appropriate linker flags too to satisfy the link-time dependencies of your hwloc library. Try \"pkg-config --libs --static hwloc\" for suggestions on what you will need.")
 517             set(GMX_USE_HWLOC OFF)
 518         else()
 519             set(GMX_USE_HWLOC ON)
 520         endif()
 521
 522         if (GMX_USE_HWLOC)
 523             include_directories(SYSTEM ${HWLOC_INCLUDE_DIRS})
 524             list(APPEND GMX_EXTRA_LIBRARIES ${HWLOC_LIBRARIES})
 525         endif()
 526     elseif(GMX_HWLOC_FORCE)
 527         message(FATAL_ERROR "Hwloc package support required, but not found.")
 528     endif()
 529 endif()
 530
 531 option(GMX_EXTERNAL_TINYXML2 "Use external TinyXML-2 instead of compiling the version bundled with GROMACS." OFF)
 532 mark_as_advanced(GMX_EXTERNAL_TINYXML2)
 533 if(GMX_EXTERNAL_TINYXML2)
 534     # Find an external TinyXML-2 library.
 535     find_package(TinyXML-2 3.0.0)
 536     set(HAVE_TINYXML2 ${TinyXML2_FOUND})
 537     if(NOT HAVE_TINYXML2)
 538         message(FATAL_ERROR "External TinyXML-2 could not be found, please adjust your search paths")
 539     endif()
 540 endif()
 541
 542 option(GMX_EXTRAE "Add support for tracing using EXTRAE" OFF)
 543 mark_as_advanced(GMX_EXTRAE)
 544
 545 if (GMX_EXTRAE)
 546   find_package(EXTRAE)
 547   if(EXTRAE_FOUND)
 548     include_directories(SYSTEM ${EXTRAE_INCLUDE_DIR})
 549     set(HAVE_EXTRAE 1)
 550   else()
 551     message(FATAL_ERROR "EXTRAE library was not found. Please add the correct path to CMAKE_PREFIX_PATH")
 552   endif()
 553 endif()
 554
 555 option(GMX_X11 "Use X window system" OFF)
 556 if (GMX_X11)
 557     find_package(X11)
 558     # X11 includes/libraries are only set in the ngmx subdirectory!
 559     if(NOT X11_FOUND)
 560         message(FATAL_ERROR
 561                 "X11 include files and/or libraries were not found. "
 562                 "Set GMX_X11=OFF to compile without X11 support. "
 563                 "gmx view will not be available.")
 564     endif()
 565     include_directories(SYSTEM ${X11_INCLUDE_DIR})
 566 endif()
 567
 568 include(ThreadMPI)
 569 # Enable core threading facilities
 570 tmpi_enable_core("${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include")
 571 if(GMX_THREAD_MPI)
 572     # enable MPI functions
 573     tmpi_enable()
 574     set(MPI_IN_PLACE_EXISTS 1)
 575 endif()
 576 # If atomics are manually disabled a define is needed because atomics.h doesn't depend on config.h
 577 if (TMPI_ATOMICS_DISABLED)
 578    add_definitions(-DTMPI_ATOMICS_DISABLED)
 579 endif()
 580
 581 include(gmxManageTNG)
 582
 583 include(gmxManageLmfit)
 584
 585 if(GMX_GPU)
 586     # now that we have detected the dependencies, do the second configure pass
 587     gmx_gpu_setup()
 588     if (GMX_CLANG_CUDA)
 589         list(APPEND GMX_EXTRA_LIBRARIES ${GMX_CUDA_CLANG_LINK_LIBS})
 590         link_directories("${GMX_CUDA_CLANG_LINK_DIRS}")
 591     endif()
 592 endif()
 593
 594 if(CYGWIN)
 595     set(GMX_CYGWIN 1)
 596 endif()
 597
 598 if(WIN32)
 599     set(GMX_NATIVE_WINDOWS 1)
 600     # This makes windows.h not declare min/max as macros that would break
 601     # C++ code using std::min/std::max.
 602     add_definitions(-DNOMINMAX)
 603 endif()
 604
 605 if(CMAKE_SYSTEM_NAME STREQUAL "Darwin") #Work-around for cmake bug #10837
 606     if (CMAKE_COMPILER_IS_GNUCC OR CMAKE_C_COMPILER_ID MATCHES "Intel" OR CMAKE_C_COMPILER_ID MATCHES "Clang")
 607         set(CMAKE_INCLUDE_SYSTEM_FLAG_C "-isystem ")
 608     endif()
 609     if (CMAKE_COMPILER_IS_GNUCXX OR CMAKE_CXX_COMPILER_ID MATCHES "Intel" OR CMAKE_CXX_COMPILER_ID MATCHES "Clang")
 610         set(CMAKE_INCLUDE_SYSTEM_FLAG_CXX "-isystem ")
 611     endif()
 612 endif()
 613
 614 option(GMX_BUILD_UNITTESTS "Build unit tests with BUILD_TESTING" ON)
 615 mark_as_advanced(GMX_BUILD_UNITTESTS)
 616 gmx_add_cache_dependency(GMX_BUILD_UNITTESTS BOOL BUILD_TESTING OFF)
 617
 618 ########################################################################
 619 # Our own GROMACS tests
 620 ########################################################################
 621
 622 add_definitions( -DHAVE_CONFIG_H )
 623 include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src)
 624 # TODO required at high level because both libgromacs and progs/mdrun
 625 # require it, both for thread-MPI and its atomics and mutexes.
 626 include_directories(BEFORE SYSTEM ${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include)
 627 # Required for config.h, maybe should only be set in src/CMakeLists.txt
 628 include_directories(BEFORE ${CMAKE_BINARY_DIR}/src)
 629
 630 include(gmxTestInlineASM)
 631 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 632
 633 include(gmxSetBuildInformation)
 634 gmx_set_build_information()
 635
 636 gmx_option_multichoice(
 637     GMX_USE_RDTSCP
 638     "Use low-latency RDTSCP instruction for CPU-based timers for mdrun execution; might need to be off when compiling for heterogeneous environments)"
 639     "AUTO"
 640     OFF ON AUTO DETECT)
 641 mark_as_advanced(GMX_USE_RDTSCP)
 642
 643 macro(gmx_check_rdtscp)
 644     if (CPU_DETECTION_FEATURES MATCHES "rdtscp")
 645         set(HAVE_RDTSCP 1)
 646         set(RDTSCP_DETECTION_MESSAGE " - detected on the build host")
 647     else()
 648         set(RDTSCP_DETECTION_MESSAGE " - not detected on the build host")
 649     endif()
 650 endmacro()
 651
 652 set(HAVE_RDTSCP 0)
 653 if (GMX_USE_RDTSCP STREQUAL "ON")
 654     set(HAVE_RDTSCP 1)
 655 elseif(GMX_USE_RDTSCP STREQUAL "DETECT")
 656     gmx_check_rdtscp()
 657 elseif(GMX_USE_RDTSCP STREQUAL "AUTO")
 658     # If the user specified automated SIMD selection, that the choice
 659     # is made based on detection on the build host. If so, then RDTSCP
 660     # should be chosen the same way.
 661     #
 662     # If the user specified an AVX SIMD level (e.g. when
 663     # cross-compiling GROMACS) then they will get our best guess, ie
 664     # that in practice AVX mostly correlates with rdtscp (and anyway
 665     # is only relevant in rather old x86 hardware).
 666     if (GMX_SIMD STREQUAL "AUTO")
 667         gmx_check_rdtscp()
 668     elseif (GMX_SIMD MATCHES "AVX")
 669         set(HAVE_RDTSCP 1)
 670     endif()
 671 endif()
 672 gmx_check_if_changed(HAVE_RDTSCP_CHANGED HAVE_RDTSCP)
 673 if (HAVE_RDTSCP_CHANGED)
 674     if (HAVE_RDTSCP)
 675         message(STATUS "Enabling RDTSCP support${RDTSCP_DETECTION_MESSAGE}")
 676     else()
 677         message(STATUS "Disabling RDTSCP support${RDTSCP_DETECTION_MESSAGE}")
 678     endif()
 679 endif()
 680
 681 include(gmxTestLargeFiles)
 682 gmx_test_large_files(GMX_LARGEFILES)
 683
 684 include(gmxTestSignal)
 685 gmx_test_sigusr1(HAVE_SIGUSR1)
 686
 687 include(gmxTestPipes)
 688 gmx_test_pipes(HAVE_PIPES)
 689
 690 check_include_file_cxx(regex     HAVE_CXX11_REGEX)
 691
 692 include(gmxTestXDR)
 693 gmx_test_xdr(GMX_SYSTEM_XDR)
 694 if(NOT GMX_SYSTEM_XDR)
 695     set(GMX_INTERNAL_XDR 1)
 696 endif()
 697
 698
 699 ##################################################
 700 # Process SIMD instruction settings
 701 ##################################################
 702 # This checks what flags to add in order to
 703 # support the SIMD instructions we need, it sets
 704 # correct defines for the SIMD instructions supported,
 705 # and adds advanced options to control accuracy
 706 # for SIMD math operations.
 707 include(gmxManageSimd)
 708 gmx_manage_simd()
 709
 710 include(gmxManageCycleCounters)
 711 gmx_manage_cycle_counters()
 712
 713 # Process QM/MM Settings
 714 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 715     set(GMX_QMMM_GAUSSIAN 1)
 716 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 717     set(GMX_QMMM_MOPAC 1)
 718 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 719     set(GMX_QMMM_GAMESS 1)
 720 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 721     set(GMX_QMMM_ORCA 1)
 722 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 723     # nothing to do
 724 else()
 725     gmx_invalid_option_value(GMX_QMMM_PROGRAM)
 726 endif()
 727
 728
 729 ##################################################
 730 # Process FFT library settings
 731 ##################################################
 732 include(gmxManageFFTLibraries)
 733
 734
 735 include(gmxManageLinearAlgebraLibraries)
 736
 737 include(gmxManagePluginSupport)
 738
 739 if (GMX_USE_PLUGINS)
 740     if(NOT GMX_VMD_PLUGIN_PATH)
 741         find_package(VMD)
 742     endif()
 743 endif()
 744
 745 # Link real-time library for POSIX timers. The check for clock_gettime
 746 # confirms the linkability of rt.
 747 if(HAVE_TIME_H AND HAVE_UNISTD_H AND HAVE_CLOCK_GETTIME)
 748     list(APPEND GMX_EXTRA_LIBRARIES rt)
 749 endif()
 750
 751 # Math and thread libraries must often come after all others when linking...
 752 if (HAVE_LIBM)
 753     list(APPEND GMX_PUBLIC_LIBRARIES m)
 754 endif()
 755
 756 option(GMX_NACL "Configure for Native Client builds" OFF)
 757 if (GMX_NACL)
 758   list(APPEND GMX_EXTRA_LIBRARIES nosys)
 759   set(GMX_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -lnosys")
 760   # TODO: Is this still necessary with the check for its presence?
 761   set(GMX_USE_NICE 0)
 762   set(GMX_NO_RENAME 1)
 763 endif()
 764 mark_as_advanced(GMX_NACL)
 765
 766 if(GMX_FAHCORE)
 767   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 768       "Path to swindirect.h")
 769   include_directories(${COREWRAP_INCLUDE_DIR})
 770 endif()
 771
 772 # Value of GMX_BUILD_HELP=AUTO tries to generate things, but will only
 773 # produce warnings if that fails.
 774 set(build_help_default AUTO)
 775 if (SOURCE_IS_SOURCE_DISTRIBUTION OR CMAKE_CROSSCOMPILING)
 776     set(build_help_default OFF)
 777 endif()
 778 gmx_option_trivalue(GMX_BUILD_HELP "Build completions automatically (requires that compiled binaries can be executed on the build host) and install man pages if built (requires building the 'man' target manually)" ${build_help_default})
 779 mark_as_advanced(GMX_BUILD_HELP)
 780 if (GMX_BUILD_HELP AND SOURCE_IS_SOURCE_DISTRIBUTION AND BUILD_IS_INSOURCE)
 781     message(FATAL_ERROR
 782         "Rebuilding shell completions or man pages is not supported for "
 783         "in-source builds from a source distribution. "
 784         "Set GMX_BUILD_HELP=OFF or do an out-of-source build to proceed.")
 785 endif()
 786
 787 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 788 # these are set after everything else
 789 if (NOT GMX_SKIP_DEFAULT_CFLAGS)
 790     set(CMAKE_C_FLAGS "${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${CMAKE_C_FLAGS}")
 791     set(CMAKE_CXX_FLAGS "${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${CMAKE_CXX_FLAGS}")
 792     set(CMAKE_EXE_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}")
 793     set(CMAKE_SHARED_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS}")
 794 else()
 795     message("Recommended flags which are not added because GMX_SKIP_DEFAULT_CFLAGS=yes:")
 796     message("CMAKE_C_FLAGS: ${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${GMXC_CFLAGS}")
 797     message("CMAKE_C_FLAGS_RELEASE: ${GMXC_CFLAGS_RELEASE}")
 798     message("CMAKE_C_FLAGS_DEBUG: ${GMXC_CFLAGS_DEBUG}")
 799     message("CMAKE_CXX_FLAGS: ${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${GMXC_CXXFLAGS}")
 800     message("CMAKE_CXX_FLAGS_RELEASE: ${GMXC_CXXFLAGS_RELEASE}")
 801     message("CMAKE_CXX_FLAGS_DEBUG: ${GMXC_CXXFLAGS_DEBUG}")
 802     message("CMAKE_EXE_LINKER_FLAGS: ${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS}")
 803     message("CMAKE_SHARED_LINKER_FLAGS: ${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS}")
 804 endif()
 805
 806 if(NOT GMX_OPENMP)
 807     #Unset all OpenMP flags in case OpenMP was disabled either by the user
 808     #or because it was only partially detected (e.g. only for C but not C++ compiler)
 809     unset(OpenMP_C_FLAGS CACHE)
 810     unset(OpenMP_CXX_FLAGS CACHE)
 811 else()
 812     set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} ${OpenMP_LINKER_FLAGS})
 813     set(GMX_SHARED_LINKER_FLAGS ${GMX_SHARED_LINKER_FLAGS} ${OpenMP_SHARED_LINKER_FLAGS})
 814 endif()
 815
 816
 817 ########################################################################
 818 # Specify install locations
 819 ########################################################################
 820 # Use GNUInstallDirs to set paths on multiarch systems.
 821 include(GNUInstallDirs)
 822
 823 set(GMX_INSTALL_DATASUBDIR "gromacs" CACHE STRING "Subdirectory for GROMACS data under CMAKE_INSTALL_DATADIR")
 824 mark_as_advanced(GMX_INSTALL_DATASUBDIR)
 825
 826 # Internal convenience so we do not have to join two path segments in the code
 827 set(GMX_INSTALL_GMXDATADIR ${CMAKE_INSTALL_DATADIR}/${GMX_INSTALL_DATASUBDIR})
 828
 829 # If the nesting level wrt. the installation root is changed,
 830 # gromacs-config.cmake.cmakein needs to be adapted.
 831 set(GMX_INSTALL_CMAKEDIR  ${CMAKE_INSTALL_DATAROOTDIR}/cmake)
 832
 833 # TODO: Make GMXRC adapt if this is changed
 834 set(GMX_INSTALL_PKGCONFIGDIR ${CMAKE_INSTALL_LIBDIR}/pkgconfig)
 835 set(GMX_INSTALL_OCLDIR       ${GMX_INSTALL_GMXDATADIR}/opencl)
 836
 837 list(APPEND INSTALLED_HEADER_INCLUDE_DIRS ${CMAKE_INSTALL_INCLUDEDIR})
 838
 839 # Binary and library suffix options
 840 include(gmxManageSuffixes)
 841
 842 ################################################################
 843 # Shared library load path settings
 844 ################################################################
 845 if(NOT GMX_BUILD_SHARED_EXE)
 846     # No rpath
 847     set(CMAKE_SKIP_RPATH TRUE)
 848     set(CMAKE_EXE_LINK_DYNAMIC_C_FLAGS) # remove -Wl,-Bdynamic
 849     set(CMAKE_EXE_LINK_DYNAMIC_CXX_FLAGS)
 850 else()
 851     # The build folder always has bin/ and lib/; if we are also going to
 852     # install to lib/, then the installation RPATH works also in the build
 853     # tree.  This makes installation slightly faster (no need to rewrite the
 854     # RPATHs), and makes the binaries in the build tree relocatable.
 855     if(CMAKE_INSTALL_LIBDIR STREQUAL "lib")
 856         set(CMAKE_BUILD_WITH_INSTALL_RPATH TRUE)
 857         if(POLICY CMP0068)
 858             cmake_policy(SET CMP0068 NEW) # From CMake-3.9
 859             set(CMAKE_BUILD_WITH_INSTALL_NAME_DIR TRUE)
 860         endif()
 861     endif()
 862     # Set the RPATH as relative to the executable location to make the
 863     # binaries relocatable.
 864     if(CMAKE_SYSTEM_NAME STREQUAL "Darwin") #Assume OS X >=10.5
 865         set(CMAKE_INSTALL_RPATH "@loader_path/../${CMAKE_INSTALL_LIBDIR}")
 866         set(CMAKE_INSTALL_NAME_DIR ${CMAKE_INSTALL_RPATH})
 867     else()
 868         set(CMAKE_INSTALL_RPATH "\$ORIGIN/../${CMAKE_INSTALL_LIBDIR}")
 869     endif()
 870     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 871     set(CMAKE_MACOSX_RPATH 1)
 872 endif()
 873
 874 #COPYING file: Only necessary for binary distributions.
 875 #Simpler to always install.
 876 install(FILES COPYING DESTINATION ${GMX_INSTALL_GMXDATADIR} COMPONENT data)
 877
 878 if (GMX_BUILD_FOR_COVERAGE)
 879     # Code heavy with asserts makes conditional coverage close to useless metric,
 880     # as by design most of the false branches are impossible to trigger in
 881     # correctly functioning code.  And the benefit of testing those that could
 882     # be triggered by using an API against its specification isn't usually
 883     # worth the effort.
 884     add_definitions(-DNDEBUG -DGMX_DISABLE_ASSERTS)
 885 endif()
 886
 887 if (BUILD_TESTING)
 888     include(tests/CheckTarget.cmake)
 889 endif()
 890
 891 if (NOT GMX_BUILD_MDRUN_ONLY)
 892     add_subdirectory(docs)
 893     add_subdirectory(share)
 894     add_subdirectory(scripts)
 895 endif()
 896 add_subdirectory(src)
 897
 898 if (BUILD_TESTING)
 899     add_subdirectory(tests)
 900 endif()
 901
 902 gmx_cpack_write_config()
 903
 904 # Issue a warning if NVIDIA GPUs were detected, but CUDA was not found.
 905 # Don't bother the user after the first configure pass.
 906 if ((CUDA_NOTFOUND_AUTO AND GMX_DETECT_GPU_AVAILABLE) AND NOT GMX_GPU_DETECTION_DONE)
 907     message(WARNING "${CUDA_NOTFOUND_MESSAGE}")
 908 endif()
 909 set(GMX_GPU_DETECTION_DONE TRUE CACHE INTERNAL "Whether GPU detection has already been done")
 910
 911 #######################
 912 ## uninstall target
 913 #######################
 914 CONFIGURE_FILE(   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 915                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
 916                   IMMEDIATE @ONLY)
 917 ###########################
 918 ADD_CUSTOM_TARGET(uninstall
 919                   "${CMAKE_COMMAND}" -P
 920                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
 921 ###########################
 922 set_directory_properties(PROPERTIES
 923             ADDITIONAL_MAKE_CLEAN_FILES "install_manifest.txt")