CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2009,2010,2011,2012,2013,2014, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 cmake_minimum_required(VERSION 2.8.8)
  36 # When we require cmake >= 2.8.12, it will provide
  37 # CMAKE_MINIMUM_REQUIRED_VERSION automatically, but in the meantime we
  38 # need to set a variable, and it must have a different name.
  39 set(GMX_CMAKE_MINIMUM_REQUIRED_VERSION "2.8.8")
  40
  41 # CMake modules/macros are in a subdirectory to keep this file cleaner
  42 # This needs to be set before project() in order to pick up toolchain files
  43 list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake ${CMAKE_CURRENT_SOURCE_DIR}/cmake/Platform)
  44
  45 project(Gromacs)
  46
  47 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  48 set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  49 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
  50
  51 # Set up common version variables, as well as general information about
  52 # the build tree (whether the build is from a source package or from a git
  53 # repository).  Also declares a few functions that will be used for generating
  54 # version info files later.
  55 include(gmxVersionInfo)
  56
  57 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT AND UNIX)
  58     set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
  59 endif()
  60
  61 include(gmxBuildTypeReference)
  62 include(gmxBuildTypeProfile)
  63 include(gmxBuildTypeTSAN)
  64 include(gmxBuildTypeASAN)
  65 include(gmxBuildTypeReleaseWithAssert)
  66
  67 if(NOT CMAKE_BUILD_TYPE)
  68     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel Reference RelWithAssert Profile." FORCE)
  69     # There's no need to offer a user the choice of ThreadSanitizer
  70     # Set the possible values of build type for cmake-gui
  71     set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "Debug" "Release"
  72         "MinSizeRel" "RelWithDebInfo" "Reference" "RelWithAssert" "Profile")
  73 endif()
  74 if(CMAKE_CONFIGURATION_TYPES)
  75     # Add appropriate GROMACS-specific build types for the Visual
  76     # Studio generator (Debug, Release, MinSizeRel and RelWithDebInfo
  77     # are already present by default).
  78     list(APPEND CMAKE_CONFIGURATION_TYPES "RelWithAssert" "Reference")
  79     list(REMOVE_DUPLICATES CMAKE_CONFIGURATION_TYPES)
  80     set(CMAKE_CONFIGURATION_TYPES "${CMAKE_CONFIGURATION_TYPES}" CACHE STRING
  81         "List of configuration types"
  82         FORCE)
  83 endif()
  84 set(build_types_with_explicit_flags RELEASE DEBUG RELWITHDEBUGINFO RELWITHASSERT MINSIZEREL PROFILE)
  85
  86 set(CPACK_PACKAGE_NAME "gromacs")
  87 set(CPACK_PACKAGE_VERSION_MAJOR ${GMX_VERSION_MAJOR})
  88 set(CPACK_PACKAGE_VERSION_MINOR ${GMX_VERSION_MINOR})
  89 set(CPACK_PACKAGE_VERSION_PATCH ${GMX_VERSION_PATCH})
  90 set(CPACK_PACKAGE_VERSION       ${GMX_VERSION_STRING})
  91 set(CPACK_SOURCE_PACKAGE_FILE_NAME "${CPACK_PACKAGE_NAME}-${CPACK_PACKAGE_VERSION}")
  92 set(CPACK_PACKAGE_VENDOR "gromacs.org")
  93 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Gromacs - a toolkit for high-performance molecular simulation")
  94 set(CPACK_RESOURCE_FILE_WELCOME "${CMAKE_SOURCE_DIR}/admin/InstallWelcome.txt")
  95 # Its GPL/LGPL, so they do not have to agree to a license for mere usage, but some installers require this...
  96 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_SOURCE_DIR}/COPYING")
  97 set(CPACK_RESOURCE_FILE_README "${CMAKE_SOURCE_DIR}/admin/InstallInfo.txt")
  98 set(CPACK_SOURCE_IGNORE_FILES "\\\\.isreposource$;\\\\.git/;\\\\.gitignore$;\\\\.gitattributes;")
  99 set(CPACK_PROJECT_CONFIG_FILE "${CMAKE_SOURCE_DIR}/CPackInit.cmake")
 100 # CPack source archives include only the directories we list here.
 101 # This variable is a list of pairs of names of source and destination
 102 # directories. Most of these are used for content GROMACS generates as
 103 # part of the configuration or build.
 104 set(CPACK_SOURCE_INSTALLED_DIRECTORIES "${CMAKE_SOURCE_DIR};/;${CMAKE_BINARY_DIR}/src/programs/completion;src/programs/completion;${CMAKE_BINARY_DIR}/share/man/man1;share/man/man1;${CMAKE_BINARY_DIR}/share/man/man7;share/man/man7;${CMAKE_BINARY_DIR}/share/html/final;share/html/final;${CMAKE_BINARY_DIR}/install-guide/final;/")
 105 set(CPACK_PACKAGE_CONTACT "gmx-users@gromacs.org")
 106 set(CPACK_GMX_BUILD_HELP "${GMX_BUILD_HELP}") #Works even though GMX_BUILD_HELP is defined later because it is off by default.
 107
 108 #must come after all cpack settings!
 109 include(CPack)
 110
 111 # Set a default valgrind suppression file.
 112 # This unfortunately needs to duplicate information from CTest to work as
 113 # expected...
 114 set(MEMORYCHECK_SUPPRESSIONS_FILE
 115     "${CMAKE_SOURCE_DIR}/cmake/legacy_and_external.supp"
 116     CACHE FILEPATH
 117     "File that contains suppressions for the memory checker")
 118 include(CTest)
 119
 120 # Variables that accumulate stuff influencing the installed headers
 121 set(INSTALLED_HEADER_INCLUDE_DIRS "")
 122 set(INSTALLED_HEADER_DEFINITIONS "")
 123
 124 ########################################################################
 125 # Check and warn if cache generated on a different host is being reused
 126 ########################################################################
 127 if(CMAKE_HOST_UNIX)
 128     execute_process(COMMAND hostname
 129                     OUTPUT_VARIABLE TMP_HOSTNAME
 130                     OUTPUT_STRIP_TRAILING_WHITESPACE)
 131     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}")
 132         message(WARNING "
 133             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
 134             is being reused! This could lead to inconsitencies; therefore, it is
 135             recommended to regenerate the cache!")
 136     endif()
 137     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
 138             "Hostname of the machine where the cache was generated.")
 139 endif()
 140
 141 ########################################################################
 142 # User input options                                                   #
 143 ########################################################################
 144 include(gmxOptionUtilities)
 145
 146 set(CMAKE_PREFIX_PATH "" CACHE STRING "Extra locations to search for external libraries and tools (give directory without lib, bin, or include)")
 147
 148 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" OFF)
 149 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 150 option(GMX_THREAD_MPI  "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" ON)
 151 gmx_dependent_option(
 152     GMX_MPI_IN_PLACE
 153     "Enable MPI_IN_PLACE for MPIs that have it defined"
 154     ON
 155     GMX_MPI)
 156 mark_as_advanced(GMX_MPI_IN_PLACE)
 157 option(GMX_SOFTWARE_INVSQRT "Use GROMACS software 1/sqrt" ON)
 158 mark_as_advanced(GMX_SOFTWARE_INVSQRT)
 159 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 160 mark_as_advanced(GMX_FAHCORE)
 161
 162 option(GMX_COOL_QUOTES "Enable Gromacs cool quotes" ON)
 163 mark_as_advanced(GMX_COOL_QUOTES)
 164 gmx_add_cache_dependency(GMX_COOL_QUOTES BOOL "NOT GMX_FAHCORE" OFF)
 165
 166 # Decide on GPU settings based on user-settings and GPU/CUDA detection.
 167 # We support CUDA >=v4.0 on *nix, but <= v4.1 doesn't work with MSVC
 168 if(MSVC)
 169     set(REQUIRED_CUDA_VERSION 4.1)
 170 else()
 171     set(REQUIRED_CUDA_VERSION 4.0)
 172 endif()
 173 set(REQUIRED_CUDA_COMPUTE_CAPABILITY 2.0)
 174 include(gmxManageGPU)
 175
 176 # Detect the architecture the compiler is targetting, detect
 177 # SIMD instructions possibilities on that hardware, suggest SIMD instruction set
 178 # to use if none is specified, and populate the cache option for CPU
 179 # SIMD.
 180 include(gmxDetectTargetArchitecture)
 181 gmx_detect_target_architecture()
 182
 183 if(GMX_CPU_ACCELERATION)
 184     # Stay compatible with old Jenkins command line options for specific SIMD acceleration
 185     set(GMX_SIMD "${GMX_CPU_ACCELERATION}" CACHE STRING "SIMD instruction set level and compiler optimization" FORCE)
 186     message("You set GMX_CPU_ACCELERATION, which is deprecated, and will be removed in a later version of GROMACS. It is replaced by GMX_SIMD. For now, copying the value from GMX_CPU_ACCELERATION to GMX_SIMD.")
 187     # TODO remove all references to GMX_CPU_ACCELERATION in master branch
 188 endif()
 189
 190 if(NOT GMX_TARGET_MIC)
 191     include(gmxDetectSimd)
 192     gmx_detect_simd(GMX_SUGGESTED_SIMD)
 193 else()
 194     set(GMX_SUGGESTED_SIMD "None")
 195 endif()
 196
 197 gmx_option_multichoice(
 198     GMX_SIMD
 199     "SIMD instruction set for CPU kernels and compiler optimization"
 200     "${GMX_SUGGESTED_SIMD}"
 201     None SSE2 SSE4.1 AVX_128_FMA AVX_256 AVX2_256 IBM_QPX Sparc64_HPC_ACE Reference)
 202
 203 gmx_option_multichoice(
 204     GMX_FFT_LIBRARY
 205     "FFT library"
 206     "fftw3"
 207     fftw3 mkl "fftpack[built-in]")
 208 gmx_dependent_option(
 209     GMX_BUILD_OWN_FFTW
 210     "Download and build FFTW 3 during the GROMACS build process, rather than fall back on the really slow fftpack."
 211     OFF
 212     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 213 gmx_dependent_option(
 214     GMX_DISABLE_FFTW_MEASURE
 215     "Do not optimize FFTW setups (not needed with SSE)"
 216     OFF
 217     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 218 mark_as_advanced(GMX_BUILD_OWN_FFTW)
 219 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 220
 221 gmx_option_multichoice(
 222     GMX_QMMM_PROGRAM
 223     "QM package for QM/MM"
 224     None
 225     none gaussian mopac gamess orca)
 226
 227 gmx_dependent_cache_variable(GMX_SIMD_REF_FLOAT_WIDTH  "Reference SIMD single precision width" STRING "4" "GMX_SIMD STREQUAL REFERENCE")
 228 gmx_dependent_cache_variable(GMX_SIMD_REF_DOUBLE_WIDTH "Reference SIMD double precision width" STRING "2" "GMX_SIMD STREQUAL REFERENCE")
 229
 230 # This should be moved to a separate NBNXN cmake module when that code is cleaned up and modularized
 231
 232 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 233 mark_as_advanced(GMX_BROKEN_CALLOC)
 234 option(GMX_LOAD_PLUGINS "Compile with plugin support, needed to read VMD supported file formats" ON)
 235 mark_as_advanced(GMX_LOAD_PLUGINS)
 236
 237 option(GMX_GPU  "Enable GPU acceleration" ON)
 238 option(GMX_OPENMP "Enable OpenMP-based multithreading" ON)
 239
 240 option(GMX_USE_TNG "Use the TNG library for trajectory I/O" ON)
 241
 242 if(UNIX)
 243     option(GMX_SYMLINK_OLD_BINARY_NAMES "Create symbolic links for pre-5.0 binary names" ON)
 244 endif()
 245 option(GMX_BUILD_MDRUN_ONLY "Build and install only the mdrun binary" OFF)
 246
 247 option(GMX_CYCLE_SUBCOUNTERS "Enable cycle subcounters to get a more detailed cycle timings" OFF)
 248 mark_as_advanced(GMX_CYCLE_SUBCOUNTERS)
 249
 250 option(GMX_SKIP_DEFAULT_CFLAGS "Don't automatically add suggested/required Compiler flags." OFF)
 251 mark_as_advanced(GMX_SKIP_DEFAULT_CFLAGS)
 252
 253 option(GMX_BUILD_FOR_COVERAGE
 254        "Tune build for better code coverage metrics (e.g., disable asserts)"
 255        OFF)
 256 mark_as_advanced(GMX_BUILD_FOR_COVERAGE)
 257
 258
 259 ######################################################################
 260 # Detect OpenMP support
 261 ######################################################################
 262 # The OpenMP detection _must_ come before tests for other CFLAGS.
 263 include(gmxManageOpenMP)
 264
 265
 266
 267 ######################################################################
 268 # Compiler tests
 269 # These need to be done early (before further tests).
 270 #####################################################################
 271
 272 # The cmake/Check{C,CXX}CompilerFlag.cmake files in the GROMACS distribution
 273 # are used with permission from CMake v3.0.0 so that GROMACS can detect
 274 # invalid options with the Intel Compilers, and we have added a line
 275 # to detect warnings with the Fujitsu compilers on K computer.
 276 # CMake-3.0 also has a bug where the FAIL_REGEX pattern for AIX contains
 277 # a semicolon. Since this is also used as a separator in lists inside CMake,
 278 # that string ends up being split into two separate patterns, and the last
 279 # part is just a single word that also matches other messages. We solved this
 280 # by replacing the semicolon with a period that matches any character.
 281 #
 282 # These files should be removed from the source tree when a CMake version that
 283 # includes the features in question becomes required for building GROMACS.
 284 include(CheckCCompilerFlag)
 285 include(CheckCXXCompilerFlag)
 286
 287 include(gmxCFlags)
 288 gmx_c_flags()
 289
 290 # This variable should be used for additional compiler flags which are not
 291 # generated in gmxCFlags nor are SIMD or MPI related.
 292 set(EXTRA_C_FLAGS "")
 293 set(EXTRA_CXX_FLAGS "")
 294
 295 # Run through a number of tests for buggy compilers and other issues
 296 include(gmxTestCompilerProblems)
 297 gmx_test_compiler_problems()
 298 # GMX_SIMD will not be set automatically until the second
 299 # pass (which is not strictly guaranteed to occur), so putting this
 300 # check here among logically-related tests is inefficient, but the
 301 # potential loss is likely zero.
 302 if(GMX_SIMD STREQUAL "AVX_256"
 303         AND CMAKE_COMPILER_IS_GNUCC
 304         AND (C_COMPILER_VERSION VERSION_EQUAL "4.6.1"
 305             OR CXX_COMPILER_VERSION VERSION_EQUAL "4.6.1"))
 306     message(FATAL_ERROR "gcc 4.6.1 has buggy support for AVX, and GROMACS mdrun will not work. If you want simulation performance, use a more recent compiler. Otherwise, use GMX_SIMD=SSE4.1")
 307     # See http://gcc.gnu.org/bugzilla/show_bug.cgi?id=49002
 308 endif()
 309
 310
 311 if(GMX_DOUBLE)
 312     add_definitions(-DGMX_DOUBLE)
 313     list(APPEND INSTALLED_HEADER_DEFINITIONS "-DGMX_DOUBLE")
 314 endif()
 315 if(GMX_SOFTWARE_INVSQRT)
 316     list(APPEND INSTALLED_HEADER_DEFINITIONS "-DGMX_SOFTWARE_INVSQRT")
 317 endif()
 318
 319 if(WIN32 AND NOT CYGWIN)
 320     set(GMX_WSOCKLIB_PATH CACHE PATH "Path to winsock (wsock32.lib) library.")
 321     mark_as_advanced(GMX_WSOCKLIB_PATH)
 322     find_library(WSOCK32_LIBRARY NAMES wsock32 PATHS ${GMX_WSOCKLIB_PATH})
 323     if(WSOCK32_LIBRARY)
 324         list(APPEND GMX_EXTRA_LIBRARIES ${WSOCK32_LIBRARY})
 325         add_definitions(-DGMX_HAVE_WINSOCK)
 326     else()
 327         message(STATUS "No winsock found. Cannot use interactive molecular dynamics (IMD).")
 328     endif(WSOCK32_LIBRARY)
 329 endif()
 330
 331
 332
 333 ########################################################################
 334 # Basic system tests (standard libraries, headers, functions, types)   #
 335 ########################################################################
 336 include(CheckIncludeFiles)
 337 include(CheckIncludeFileCXX)
 338 check_include_files(unistd.h     HAVE_UNISTD_H)
 339 check_include_files(pwd.h        HAVE_PWD_H)
 340 check_include_files(dirent.h     HAVE_DIRENT_H)
 341 check_include_files(time.h       HAVE_TIME_H)
 342 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 343 check_include_files(io.h         HAVE_IO_H)
 344 check_include_files(sched.h      HAVE_SCHED_H)
 345
 346 check_include_files(regex.h      HAVE_POSIX_REGEX)
 347 check_include_file_cxx(regex     HAVE_CXX11_REGEX)
 348 # TODO: It could be nice to inform the user if no regex support is found,
 349 # as selections won't be fully functional.
 350
 351 include(CheckFunctionExists)
 352 check_function_exists(posix_memalign    HAVE_POSIX_MEMALIGN)
 353 check_function_exists(memalign          HAVE_MEMALIGN)
 354 check_function_exists(_aligned_malloc   HAVE__ALIGNED_MALLOC)
 355 check_function_exists(gettimeofday      HAVE_GETTIMEOFDAY)
 356 check_function_exists(fsync             HAVE_FSYNC)
 357 check_function_exists(_fileno           HAVE__FILENO)
 358 check_function_exists(fileno            HAVE_FILENO)
 359 check_function_exists(_commit           HAVE__COMMIT)
 360 check_function_exists(sigaction         HAVE_SIGACTION)
 361 check_function_exists(sysconf           HAVE_SYSCONF)
 362 check_function_exists(rsqrt             HAVE_RSQRT)
 363 check_function_exists(rsqrtf            HAVE_RSQRTF)
 364 check_function_exists(sqrtf             HAVE_SQRTF)
 365
 366 include(CheckLibraryExists)
 367 check_library_exists(m sqrt "" HAVE_LIBM)
 368 check_library_exists(rt clock_gettime "" HAVE_CLOCK_GETTIME)
 369
 370 include(TestSchedAffinity)
 371 test_sched_affinity(HAVE_SCHED_AFFINITY)
 372
 373 include(TestBigEndian)
 374 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 375
 376 # Management of GROMACS options for specific toolchains should go
 377 # here. Because the initial settings for some of the main options have
 378 # already happened, but things like library detection and MPI compiler
 379 # feature detection have not, the docstrings for any over-rides of
 380 # GROMACS defaults or user settings will make sense. Also, any
 381 # toolchain-related reasons for choosing whether to detect various
 382 # things can be sorted out now, before the detection takes place.
 383 if(${CMAKE_SYSTEM_NAME} MATCHES BlueGene)
 384     include(gmxManageBlueGene)
 385 endif()
 386
 387 ########################################################################
 388 #Process MPI settings
 389 ########################################################################
 390 include(gmxManageMPI)
 391
 392
 393 ########################################################################
 394 #Process shared/static library settings
 395 ########################################################################
 396 include(gmxManageSharedLibraries)
 397
 398
 399 ########################################################################
 400 # Find external packages                                               #
 401 ########################################################################
 402
 403 # Unconditionally find the package, as it is also required for unit
 404 # tests. This exports LIBXML2_FOUND, which we should not use because
 405 # it does not tell us that linking will succeed. Instead, we test that
 406 # next.
 407 if(DEFINED LIBXML2_LIBRARIES)
 408   set(LibXml2_FIND_QUIETLY TRUE)
 409 endif()
 410 find_package(LibXml2)
 411 include(gmxTestLibXml2)
 412 gmx_test_libxml2(HAVE_LIBXML2)
 413 option(GMX_XML "Use libxml2 to parse xml files (currently has no effect)" ${HAVE_LIBXML2})
 414 set(PKG_XML "")
 415 mark_as_advanced(GMX_XML)
 416 # Don't actually do anything, since libxml2 is currently not used by libgromacs
 417 #if(GMX_XML AND NOT HAVE_LIBXML2)
 418 #    message(FATAL_ERROR "libxml2 not found. Set GMX_XML=OFF to compile without XML support")
 419 #endif()
 420 #if(GMX_XML)
 421 #    include_directories(${LIBXML2_INCLUDE_DIR})
 422 #    set(PKG_XML libxml-2.0)
 423 #    set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 424 #endif()
 425
 426 option(GMX_EXTRAE "Add support for tracing using EXTRAE" OFF)
 427 mark_as_advanced(GMX_EXTRAE)
 428
 429 if (GMX_EXTRAE)
 430   find_package(EXTRAE)
 431   if(EXTRAE_FOUND)
 432     include_directories(${EXTRAE_INCLUDE_DIR})
 433     set(HAVE_EXTRAE 1)
 434   else()
 435     message(FATAL_ERROR "EXTRAE library was not found. Please add the correct path to CMAKE_PREFIX_PATH")
 436   endif()
 437 endif()
 438
 439 option(GMX_X11 "Use X window system" OFF)
 440 if (GMX_X11)
 441     find_package(X11)
 442     # X11 includes/libraries are only set in the ngmx subdirectory!
 443     if(NOT X11_FOUND)
 444         message(FATAL_ERROR
 445                 "X11 include files and/or libraries were not found. "
 446                 "Set GMX_X11=OFF to compile without X11 support. "
 447                 "gmx view will not be available.")
 448     endif()
 449     include_directories(${X11_INCLUDE_DIR})
 450 endif()
 451
 452 include(ThreadMPI)
 453 # Enable core threading facilities
 454 tmpi_enable_core("${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include")
 455 # Enable tMPI C++ support
 456 tmpi_enable_cxx()
 457 if(GMX_THREAD_MPI)
 458     # enable MPI functions
 459     tmpi_enable()
 460     set(GMX_MPI 1)
 461     set(MPI_IN_PLACE_EXISTS 1)
 462 endif()
 463 # If atomics are manually disabled a define is needed because atomics.h doesn't depend on config.h
 464 if (TMPI_ATOMICS_DISABLED)
 465    add_definitions(-DTMPI_ATOMICS_DISABLED)
 466 endif()
 467
 468 if(GMX_GPU)
 469     # now that we have detected the dependencies, do the second configure pass
 470     gmx_gpu_setup()
 471 endif()
 472
 473 if(CYGWIN)
 474     set(GMX_CYGWIN 1)
 475 endif()
 476
 477 if(WIN32 AND NOT CYGWIN)
 478     set(GMX_NATIVE_WINDOWS 1)
 479     # This makes windows.h not declare min/max as macros that would break
 480     # C++ code using std::min/std::max.
 481     add_definitions(-DNOMINMAX)
 482 endif()
 483
 484 # Detect boost unless GMX_EXTERNAL_BOOST is explicitly OFF
 485 # Used for default if GMX_EXTERNAL_BOOST is not defined (first CMake pass)
 486 if(NOT DEFINED GMX_EXTERNAL_BOOST OR GMX_EXTERNAL_BOOST)
 487     find_package(Boost 1.44.0)
 488     if(Boost_FOUND AND Boost_VERSION VERSION_LESS "104400")
 489         set(Boost_FOUND FALSE)
 490     endif()
 491     # Print the notification only on first run, when determining the default
 492     if(NOT DEFINED GMX_EXTERNAL_BOOST AND NOT Boost_FOUND)
 493         message("Boost >= 1.44 not found. Using minimal internal version. "
 494                 "This may cause trouble if you plan on compiling/linking other "
 495                 "software that uses Boost against Gromacs.")
 496     endif()
 497 endif()
 498 option(GMX_EXTERNAL_BOOST "Use external Boost instead of minimal built-in version"
 499        ${Boost_FOUND})
 500 if(GMX_EXTERNAL_BOOST AND NOT Boost_FOUND)
 501     message(FATAL_ERROR
 502         "Boost >= 1.44 not found. "
 503         "You can set GMX_EXTERNAL_BOOST=OFF to compile against minimal "
 504         "version of Boost included with Gromacs.")
 505 endif()
 506
 507 if(NOT DEFINED GMX_BUILD_UNITTESTS AND NOT HAVE_LIBXML2)
 508     message(WARNING "libxml2 not found. Will build GROMACS without unit-tests. This is not recommended, because the unit-tests help to verify that GROMACS functions correctly. Most likely you are missing the libxml2-dev(el) package. After you installed it, set GMX_BUILD_UNITTESTS=ON.")
 509 endif()
 510 option(GMX_BUILD_UNITTESTS "Build unit tests with BUILD_TESTING (uses Google C++ Testing and Mocking Frameworks, requires libxml2)" ${HAVE_LIBXML2})
 511 mark_as_advanced(GMX_BUILD_UNITTESTS)
 512 gmx_add_cache_dependency(GMX_BUILD_UNITTESTS BOOL BUILD_TESTING OFF)
 513 if (GMX_BUILD_UNITTESTS AND NOT HAVE_LIBXML2)
 514     message(FATAL_ERROR
 515         "Cannot build unit tests without libxml2. "
 516         "Either set GMX_BUILD_UNITTESTS=OFF or tell CMake how to find a working version of libxml2.")
 517 endif()
 518
 519 ########################################################################
 520 # Our own GROMACS tests
 521 ########################################################################
 522
 523 add_definitions( -DHAVE_CONFIG_H )
 524 include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src)
 525 include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include)
 526 # Required for config.h, maybe should only be set in src/CMakeLists.txt
 527 include_directories(BEFORE ${CMAKE_BINARY_DIR}/src)
 528
 529 include(gmxTestInlineASM)
 530 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 531
 532 include(gmxSetBuildInformation)
 533 gmx_set_build_information()
 534 # Turn on RDTSCP if:
 535 # - the build system's CPU supports it
 536 # - the acceleration is set to AVX as all AVX-capable CPUs support AVX (which
 537 #   at this point means that the user set it).
 538 # Note: it's better to not use the later set value of GMX_SIMD because
 539 # it reflects the system's capability of both compiling and running AVX code.
 540 # TODO: After merge with 5.0 one could implement a cache variable dependency
 541 # such that GMX_USE_RDTSCP can change if GMX_SIMD is changed to AVX
 542 # after the first cmake pass.
 543 if (BUILD_CPU_FEATURES MATCHES "rdtscp" OR GMX_SIMD MATCHES "AVX")
 544     set(GMX_USE_RDTSCP_DEFAULT_VALUE ON)
 545 else()
 546     set(GMX_USE_RDTSCP_DEFAULT_VALUE OFF)
 547 endif()
 548 option(GMX_USE_RDTSCP "Use RDTSCP for better CPU-based timers (available on recent x86 CPUs; might need to be off when compiling for heterogeneous environments)" ${GMX_USE_RDTSCP_DEFAULT_VALUE})
 549 mark_as_advanced(GMX_USE_RDTSCP)
 550 if(GMX_USE_RDTSCP)
 551     set(HAVE_RDTSCP 1)
 552 endif()
 553
 554 include(gmxTestFloatFormat)
 555 gmx_test_float_format(GMX_FLOAT_FORMAT_IEEE754
 556                       GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER
 557                       GMX_IEEE754_BIG_ENDIAN_WORD_ORDER)
 558
 559 include(gmxTestLargeFiles)
 560 gmx_test_large_files(GMX_LARGEFILES)
 561
 562 include(gmxTestSignal)
 563 gmx_test_sigusr1(HAVE_SIGUSR1)
 564
 565 include(gmxTestPipes)
 566 gmx_test_pipes(HAVE_PIPES)
 567
 568 include(gmxTestIsfinite)
 569 gmx_test_isfinite(HAVE_ISFINITE)
 570 gmx_test__isfinite(HAVE__ISFINITE)
 571 gmx_test__finite(HAVE__FINITE)
 572
 573 include(gmxTestCXX11)
 574 gmx_test_cxx11(GMX_CXX11_SUPPORTED GMX_CXX11_FLAGS)
 575 include(CMakeDependentOption)
 576 # nvcc does not support C++11 flags, so with GPUs we prefer to skip C++11 flags
 577 # entirely to keep the compilation environment uniform.
 578 cmake_dependent_option(GMX_CXX11
 579     "Use C++11 features"
 580     ON "GMX_CXX11_SUPPORTED AND NOT GMX_GPU" OFF)
 581 mark_as_advanced(GMX_CXX11)
 582 if(GMX_CXX11)
 583     set(EXTRA_CXX_FLAGS "${EXTRA_CXX_FLAGS} ${GMX_CXX11_FLAGS}")
 584 endif()
 585
 586
 587 include(gmxTestXDR)
 588 gmx_test_xdr(GMX_SYSTEM_XDR)
 589 if(NOT GMX_SYSTEM_XDR)
 590     set(GMX_INTERNAL_XDR 1)
 591 endif()
 592
 593
 594 ##################################################
 595 # Process SIMD instruction settings
 596 ##################################################
 597 # This checks what flags to add in order to
 598 # support the SIMD instructions we need, and sets
 599 # correct defines for the SIMD instructions supported.
 600 include(gmxTestSimd)
 601 gmx_test_simd()
 602
 603
 604 # Process QM/MM Settings
 605 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 606     set(GMX_QMMM_GAUSSIAN 1)
 607 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 608     set(GMX_QMMM_MOPAC 1)
 609 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 610     set(GMX_QMMM_GAMESS 1)
 611 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 612     set(GMX_QMMM_ORCA 1)
 613 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 614     # nothing to do
 615 else()
 616     gmx_invalid_option_value(GMX_QMMM_PROGRAM)
 617 endif()
 618
 619
 620 ##################################################
 621 # Process FFT library settings
 622 ##################################################
 623 include(gmxManageFFTLibraries)
 624
 625
 626 include(gmxManageLinearAlgebraLibraries)
 627
 628 # Whether GROMACS will really try to compile support for VMD plugins
 629 set(GMX_USE_PLUGINS OFF)
 630
 631 if(GMX_LOAD_PLUGINS)
 632   if(CYGWIN OR NOT WIN32)
 633     # Native Windows does not have, nor need dlopen
 634     # Note that WIN32 is set with Cygwin, but Cygwin needs dlopen to use plug-ins
 635     include(gmxTestdlopen)
 636     gmx_test_dlopen(HAVE_DLOPEN)
 637   endif()
 638
 639   # so, should we use plug-ins?
 640   if((WIN32 AND NOT CYGWIN) OR (HAVE_DLOPEN AND BUILD_SHARED_LIBS))
 641     if(NOT VMD_QUIETLY)
 642       MESSAGE(STATUS
 643           "Found the ability to use plug-ins when building shared libaries, "
 644           "so will compile to use plug-ins (e.g. to read VMD-supported file "
 645           "formats).")
 646     endif()
 647     if(NOT GMX_VMD_PLUGIN_PATH)
 648       find_package(VMD)
 649     endif()
 650     set(GMX_USE_PLUGINS ON)
 651     list(APPEND GMX_EXTRA_LIBRARIES ${CMAKE_DL_LIBS}) # magic cross-platform pre-set variable for dlopen library
 652     set(PKG_DL_LIBS "-l${CMAKE_DL_LIBS}")
 653   else()
 654     set(PKG_DL_LIBS)
 655   endif()
 656 endif()
 657 set(VMD_QUIETLY TRUE CACHE INTERNAL "")
 658
 659 # Link real-time library for POSIX timers. The check for clock_gettime
 660 # confirms the linkability of rt.
 661 if(HAVE_TIME_H AND HAVE_UNISTD_H AND HAVE_CLOCK_GETTIME)
 662     list(APPEND GMX_EXTRA_LIBRARIES rt)
 663 endif()
 664
 665 # Math and thread libraries must often come after all others when linking...
 666 if(HAVE_LIBM)
 667     list(APPEND GMX_EXTRA_LIBRARIES m)
 668 endif()
 669
 670 option(GMX_NACL "Configure for Native Client builds" OFF)
 671 if (GMX_NACL)
 672   list(APPEND GMX_EXTRA_LIBRARIES nosys)
 673   set(GMX_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -lnosys")
 674   set(GMX_NO_NICE 1)
 675   set(GMX_NO_RENAME 1)
 676 endif()
 677 mark_as_advanced(GMX_NACL)
 678
 679 if(GMX_FAHCORE)
 680   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 681       "Path to swindirect.h")
 682   include_directories(${COREWRAP_INCLUDE_DIR})
 683 endif()
 684
 685 option(GMX_BUILD_HELP "Build man pages, HTML help, and completions automatically (requires that compiled binaries can be executed on the build host)" OFF)
 686 mark_as_advanced(GMX_BUILD_HELP)
 687 if (GMX_BUILD_HELP AND SOURCE_IS_SOURCE_DISTRIBUTION AND
 688     "${CMAKE_CURRENT_SOURCE_DIR}" STREQUAL "${CMAKE_CURRENT_BINARY_DIR}")
 689
 690     message(FATAL_ERROR
 691         "Rebuilding HTML and man pages is not supported for in-source "
 692         "builds from a source distribution. "
 693         "Set GMX_BUILD_HELP=OFF or do an out-of-source build to proceed.")
 694 endif()
 695
 696 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 697 # these are set after everything else
 698 if (NOT GMX_SKIP_DEFAULT_CFLAGS)
 699     set(CMAKE_C_FLAGS "${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${CMAKE_C_FLAGS}")
 700     set(CMAKE_CXX_FLAGS "${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${CMAKE_CXX_FLAGS}")
 701     set(CMAKE_EXE_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}")
 702     set(CMAKE_SHARED_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS}")
 703 else()
 704     message("Recommended flags which are not added because GMX_SKIP_DEFAULT_CFLAGS=yes:")
 705     message("CMAKE_C_FLAGS: ${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${GMXC_CFLAGS}")
 706     message("CMAKE_C_FLAGS_RELEASE: ${GMXC_CFLAGS_RELEASE}")
 707     message("CMAKE_C_FLAGS_DEBUG: ${GMXC_CFLAGS_DEBUG}")
 708     message("CMAKE_CXX_FLAGS: ${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${GMXC_CXXFLAGS}")
 709     message("CMAKE_CXX_FLAGS_RELEASE: ${GMXC_CXXFLAGS_RELEASE}")
 710     message("CMAKE_CXX_FLAGS_DEBUG: ${GMXC_CXXFLAGS_DEBUG}")
 711     message("CMAKE_EXE_LINKER_FLAGS: ${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS}")
 712     message("CMAKE_SHARED_LINKER_FLAGS: ${MPI_LINKER_FLAGS}")
 713 endif()
 714
 715 if(NOT GMX_OPENMP)
 716     #Unset all OpenMP flags in case OpenMP was disabled either by the user
 717     #or because it was only partially detected (e.g. only for C but not C++ compiler)
 718     unset(OpenMP_C_FLAGS CACHE)
 719     unset(OpenMP_CXX_FLAGS CACHE)
 720 else()
 721     set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} ${OpenMP_LINKER_FLAGS})
 722     set(GMX_SHARED_LINKER_FLAGS ${GMX_SHARED_LINKER_FLAGS} ${OpenMP_SHARED_LINKER_FLAGS})
 723 endif()
 724
 725 ########################################################################
 726 # Specify install locations
 727 ########################################################################
 728 # Use GNUInstallDirs to set paths on multiarch systems.
 729 include(GNUInstallDirs)
 730
 731 # Customization for the installation tree paths.
 732 set(GMX_LIB_INSTALL_DIR ${CMAKE_INSTALL_LIBDIR} CACHE STRING
 733     "Library installation directory (default: ${CMAKE_INSTALL_LIBDIR})")
 734 set(GMX_DATA_INSTALL_DIR gromacs CACHE STRING
 735     "Data installation directory under share/ (default: gromacs)")
 736 mark_as_advanced(GMX_LIB_INSTALL_DIR GMX_DATA_INSTALL_DIR)
 737
 738 # These variables are used internally to provide a central location for
 739 # customizing the install locations.
 740 set(LIB_INSTALL_DIR       ${GMX_LIB_INSTALL_DIR})
 741 set(BIN_INSTALL_DIR       bin)
 742 set(DATA_INSTALL_DIR      share/${GMX_DATA_INSTALL_DIR})
 743 set(MAN_INSTALL_DIR       share/man)
 744 # If the nesting level wrt. the installation root is changed,
 745 # gromacs-config.cmake.cmakein needs to be adapted.
 746 set(CMAKE_INSTALL_DIR     share/cmake)
 747 # TODO: Make GMXRC adapt if this is changed
 748 set(PKGCONFIG_INSTALL_DIR ${LIB_INSTALL_DIR}/pkgconfig)
 749 set(INCL_INSTALL_DIR      include)
 750
 751 # These variables get written into config.h for use in finding the data
 752 # directories.
 753 set(GMXLIB_SEARCH_DIR share/${GMX_DATA_INSTALL_DIR}/top)
 754 set(GMXLIB_FALLBACK   ${CMAKE_INSTALL_PREFIX}/${DATA_INSTALL_DIR}/top)
 755
 756 list(APPEND INSTALLED_HEADER_INCLUDE_DIRS ${INCL_INSTALL_DIR})
 757
 758 # Binary and library suffix options
 759 include(gmxManageSuffixes)
 760
 761 ################################################################
 762 # Shared library load path settings
 763 ################################################################
 764 # CMake supports RPATH on OS X only from 2.8.12 upwards.
 765 # CMAKE_SYSTEM_VERSION > 8.0 matches OS X 10.5 and above, where RPATH support
 766 # was added.
 767 if((NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin") OR
 768    ((CMAKE_SYSTEM_VERSION VERSION_GREATER 8.0) AND (NOT CMAKE_VERSION VERSION_LESS 2.8.12)))
 769     # The build folder always has bin/ and lib/; if we are also going to
 770     # install to lib/, then the installation RPATH works also in the build
 771     # tree.  This makes installation slightly faster (no need to rewrite the
 772     # RPATHs), and makes the binaries in the build tree relocatable.
 773     if(GMX_LIB_INSTALL_DIR STREQUAL "lib")
 774         set(CMAKE_BUILD_WITH_INSTALL_RPATH TRUE)
 775     endif()
 776     # Set the RPATH as relative to the executable location to make the
 777     # binaries relocatable.
 778     if(NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin")
 779         set(CMAKE_INSTALL_RPATH "\$ORIGIN/../${GMX_LIB_INSTALL_DIR}")
 780     else()
 781         set(CMAKE_INSTALL_RPATH "@executable_path/../${GMX_LIB_INSTALL_DIR}")
 782     endif()
 783     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 784     set(CMAKE_MACOSX_RPATH 1)
 785 else()
 786     # We are on Darwin/OSX, and CMake cannot handle RPATHs automatically.
 787     if(CMAKE_SYSTEM_VERSION VERSION_GREATER 8.0)
 788         # Set the RPATH options manually.
 789         set(CMAKE_INSTALL_NAME_DIR "@rpath")
 790         set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} "-Wl,-rpath,@executable_path/../${GMX_LIB_INSTALL_DIR}")
 791     else()
 792         # Use the old INSTALL_NAME_DIR mechanism if RPATH is not supported.
 793         set(CMAKE_INSTALL_NAME_DIR "${CMAKE_INSTALL_PREFIX}/${LIB_INSTALL_DIR}")
 794     endif()
 795 endif()
 796
 797 #COPYING file: Only necessary for binary distributions.
 798 #Simpler to always install.
 799 install(FILES COPYING DESTINATION ${DATA_INSTALL_DIR} COMPONENT data)
 800
 801 if(GMX_EXTERNAL_BOOST)
 802     include_directories(${Boost_INCLUDE_DIRS})
 803     list(APPEND INSTALLED_HEADER_INCLUDE_DIRS ${Boost_INCLUDE_DIRS})
 804 else()
 805     include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src/external/boost)
 806     list(APPEND INSTALLED_HEADER_INCLUDE_DIRS ${INCL_INSTALL_DIR}/gromacs/external/boost)
 807     list(APPEND INSTALLED_HEADED_DEFINITIONS "-DBOOST_NO_TYPEID")
 808     # typeid not supported for minimal internal version
 809     # (would add significant amount of code)
 810     add_definitions(-DBOOST_NO_TYPEID)
 811     if (NOT GMX_BUILD_MDRUN_ONLY)
 812         install(DIRECTORY ${CMAKE_SOURCE_DIR}/src/external/boost/boost
 813                 DESTINATION ${INCL_INSTALL_DIR}/gromacs/external/boost
 814                 COMPONENT development)
 815     endif()
 816 endif()
 817
 818 if (GMX_BUILD_FOR_COVERAGE)
 819     # Code heavy with asserts makes conditional coverage close to useless metric,
 820     # as by design most of the false branches are impossible to trigger in
 821     # correctly functioning code.  And the benefit of testing those that could
 822     # be triggered by using an API against its specification isn't usually
 823     # worth the effort.
 824     add_definitions(-DNDEBUG -DBOOST_DISABLE_ASSERTS -DGMX_DISABLE_ASSERTS)
 825 endif()
 826
 827 if (BUILD_TESTING)
 828     # "tests" target builds all the separate test binaries.
 829     add_custom_target(tests)
 830     # "run-ctest" is an internal target that actually runs the tests.
 831     # This is necessary to be able to add separate targets that execute as part
 832     # of 'make check', but are ensured to be executed after the actual tests.
 833     add_custom_target(run-ctest
 834                       COMMAND ${CMAKE_CTEST_COMMAND} --output-on-failure
 835                       COMMENT "Running all tests"
 836                       VERBATIM)
 837     add_dependencies(run-ctest tests)
 838     # "check" target builds and runs all tests.
 839     add_custom_target(check DEPENDS run-ctest)
 840 endif()
 841
 842 if (NOT GMX_BUILD_MDRUN_ONLY)
 843     add_subdirectory(doxygen)
 844     add_subdirectory(install-guide)
 845     add_subdirectory(share)
 846     add_subdirectory(scripts)
 847 endif()
 848 add_subdirectory(src)
 849
 850 if (BUILD_TESTING)
 851     add_subdirectory(tests)
 852 endif()
 853
 854 # Issue a warning if NVIDIA GPUs were detected, but CUDA was not found.
 855 # Don't bother the user after the first configure pass.
 856 if ((CUDA_NOTFOUND_AUTO AND GMX_DETECT_GPU_AVAILABLE) AND NOT GMX_GPU_DETECTION_DONE)
 857     message(WARNING "${CUDA_NOTFOUND_MESSAGE}")
 858 endif()
 859 set(GMX_GPU_DETECTION_DONE TRUE CACHE INTERNAL "Whether GPU detection has already been done")
 860
 861 #######################
 862 ## uninstall target
 863 #######################
 864 CONFIGURE_FILE(   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 865                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
 866                   IMMEDIATE @ONLY)
 867 ###########################
 868 ADD_CUSTOM_TARGET(uninstall
 869                   "${CMAKE_COMMAND}" -P
 870                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
 871 ###########################
 872 set_directory_properties(PROPERTIES
 873             ADDITIONAL_MAKE_CLEAN_FILES "install_manifest.txt")
 874
 875 ########################################################################
 876 # Manual                                                               #
 877 ########################################################################
 878
 879 option(GMX_BUILD_MANUAL "Whether to try to configure to build the PDF manual" OFF)
 880 mark_as_advanced(GMX_BUILD_MANUAL)
 881 if(GMX_BUILD_MANUAL)
 882     # Make sure we only do detection of manual-building dependencies
 883     # when the user opted in for that.
 884     add_subdirectory(manual)
 885 endif()