CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2009,2010,2011,2012,2013,2014,2015,2016,2017,2018,2019, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 cmake_minimum_required(VERSION 3.9.6)
  36
  37 # CMake modules/macros are in a subdirectory to keep this file cleaner
  38 # This needs to be set before project() in order to pick up toolchain files
  39 list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake ${CMAKE_CURRENT_SOURCE_DIR}/cmake/Platform)
  40
  41 project(Gromacs)
  42
  43 set(CMAKE_CXX_STANDARD 14)
  44 set(CMAKE_CXX_STANDARD_REQUIRED ON)
  45 set(CMAKE_CXX_EXTENSIONS OFF)
  46
  47 include(gmxManageCcache)
  48
  49 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  50 set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  51 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
  52
  53 # Set up common version variables, as well as general information about
  54 # the build tree (whether the build is from a source package or from a git
  55 # repository).  Also declares a few functions that will be used for generating
  56 # version info files later.
  57 include(gmxBuildTreeInfo)
  58 include(gmxVersionInfo)
  59
  60 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT AND UNIX)
  61     set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
  62 endif()
  63 if("${CMAKE_INSTALL_PREFIX}" STREQUAL "${CMAKE_BINARY_DIR}")
  64     message(FATAL_ERROR "GROMACS cannot be installed into the build tree, choose a different location for CMAKE_INSTALL_PREFIX")
  65 endif()
  66
  67 include(gmxBuildTypeReference)
  68 include(gmxBuildTypeProfile)
  69 include(gmxBuildTypeTSAN)
  70 include(gmxBuildTypeASAN)
  71 include(gmxBuildTypeMSAN)
  72 include(gmxBuildTypeReleaseWithAssert)
  73
  74 if(NOT CMAKE_BUILD_TYPE)
  75     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel Reference RelWithAssert Profile TSAN ASAN MSAN." FORCE)
  76     # Set the possible values of build type for cmake-gui
  77     set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "Debug" "Release"
  78         "MinSizeRel" "RelWithDebInfo" "Reference" "RelWithAssert" "Profile" "TSAN" "ASAN" "MSAN")
  79 endif()
  80 if(CMAKE_CONFIGURATION_TYPES)
  81     # Add appropriate GROMACS-specific build types for the Visual
  82     # Studio generator (Debug, Release, MinSizeRel and RelWithDebInfo
  83     # are already present by default).
  84     list(APPEND CMAKE_CONFIGURATION_TYPES "RelWithAssert" "Reference")
  85     list(REMOVE_DUPLICATES CMAKE_CONFIGURATION_TYPES)
  86     set(CMAKE_CONFIGURATION_TYPES "${CMAKE_CONFIGURATION_TYPES}" CACHE STRING
  87         "List of configuration types"
  88         FORCE)
  89 endif()
  90 set(build_types_with_explicit_flags RELEASE DEBUG RELWITHDEBINFO RELWITHASSERT MINSIZEREL PROFILE)
  91
  92 set_property(GLOBAL PROPERTY FIND_LIBRARY_USE_LIB64_PATHS ON)
  93
  94 include(gmxCTestUtilities)
  95 gmx_ctest_init()
  96
  97 include(gmxCPackUtilities)
  98 gmx_cpack_init()
  99
 100 # Variables that accumulate stuff influencing the installed headers
 101 set(INSTALLED_HEADER_INCLUDE_DIRS "")
 102 set(INSTALLED_HEADER_DEFINITIONS "")
 103
 104 ########################################################################
 105 # Global non-cache variables for implementing the build system
 106 ########################################################################
 107
 108 # These variables collect libraries that GROMACS requires for
 109 # linking. They should be appended to with list(APPEND ${name}
 110 # new-library) calls. They are:
 111 #  - Libraries that are required for libgromacs (only)
 112 set(GMX_EXTRA_LIBRARIES "")
 113 #  - Libraries that are required for all code in the repository
 114 set(GMX_COMMON_LIBRARIES "")
 115 #  - Libraries that all code linked against libgromacs needs
 116 #    (i.e., something that is exposed in installed headers).
 117 set(GMX_PUBLIC_LIBRARIES "")
 118
 119 ########################################################################
 120 # Check and warn if cache generated on a different host is being reused
 121 ########################################################################
 122 if(CMAKE_HOST_UNIX)
 123     execute_process(COMMAND hostname
 124                     OUTPUT_VARIABLE TMP_HOSTNAME
 125                     OUTPUT_STRIP_TRAILING_WHITESPACE)
 126     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}")
 127         message(WARNING "
 128             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
 129             is being reused! This could lead to inconsistencies; therefore, it is
 130             recommended to regenerate the cache!")
 131     endif()
 132     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
 133             "Hostname of the machine where the cache was generated.")
 134 endif()
 135
 136 ########################################################################
 137 # Detect architecture before setting options so we can alter defaults
 138 ########################################################################
 139 # Detect the architecture the compiler is targetting, detect
 140 # SIMD instructions possibilities on that hardware, suggest SIMD instruction set
 141 # to use if none is specified, and populate the cache option for CPU
 142 # SIMD.
 143 include(gmxDetectTargetArchitecture)
 144 gmx_detect_target_architecture()
 145
 146 ########################################################################
 147 # User input options                                                   #
 148 ########################################################################
 149 include(gmxOptionUtilities)
 150
 151 set(CMAKE_PREFIX_PATH "" CACHE STRING "Extra locations to search for external libraries and tools (give directory without lib, bin, or include)")
 152
 153 # Fujitsu only has SIMD in double precision, so this will be faster
 154 gmx_set_boolean(GMX_DOUBLE_DEFAULT GMX_TARGET_FUJITSU_SPARC64)
 155 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" ${GMX_DOUBLE_DEFAULT})
 156 option(GMX_RELAXED_DOUBLE_PRECISION "Accept single precision 1/sqrt(x) when using Fujitsu HPC-ACE SIMD" OFF)
 157 mark_as_advanced(GMX_RELAXED_DOUBLE_PRECISION)
 158
 159 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 160 option(GMX_THREAD_MPI  "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" ON)
 161 gmx_dependent_option(
 162     GMX_MPI_IN_PLACE
 163     "Enable MPI_IN_PLACE for MPIs that have it defined"
 164     ON
 165     GMX_MPI)
 166 mark_as_advanced(GMX_MPI_IN_PLACE)
 167
 168 option(GMX_MIMIC "Enable MiMiC QM/MM interface (CPMD is required)" OFF)
 169
 170 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 171 mark_as_advanced(GMX_FAHCORE)
 172
 173 option(GMX_COOL_QUOTES "Enable GROMACS cool quotes" ON)
 174 mark_as_advanced(GMX_COOL_QUOTES)
 175 gmx_add_cache_dependency(GMX_COOL_QUOTES BOOL "NOT GMX_FAHCORE" OFF)
 176
 177 option(GMX_USE_OPENCL "Enable OpenCL acceleration" OFF)
 178
 179 # Decide on GPU settings based on user-settings and GPU/CUDA
 180 # detection. VS2017 requires CUDA 9.0, for the other arch/compilers
 181 # rest we require CUDA 8.0 or later (including for clang-CUDA)
 182 # because that is the earliest version that supports gcc 5.x
 183 if(MSVC)
 184     set(REQUIRED_CUDA_VERSION 9.0)
 185 else()
 186     set(REQUIRED_CUDA_VERSION 8.0)
 187 endif()
 188 set(REQUIRED_CUDA_COMPUTE_CAPABILITY 3.0)
 189
 190 # OpenCL required version: 1.2 or newer
 191 set(REQUIRED_OPENCL_MIN_VERSION_MAJOR 1)
 192 set(REQUIRED_OPENCL_MIN_VERSION_MINOR 2)
 193 set(REQUIRED_OPENCL_MIN_VERSION ${REQUIRED_OPENCL_MIN_VERSION_MAJOR}.${REQUIRED_OPENCL_MIN_VERSION_MINOR})
 194
 195 if(NOT GMX_USE_OPENCL)
 196     # CUDA detection is done only if GMX_USE_OPENCL is OFF.
 197     include(gmxManageGPU)
 198     set(GMX_USE_CUDA ${GMX_GPU})
 199     if(GMX_GPU)
 200         set(GMX_GPU_ACCELERATION_FRAMEWORK "GMX_GPU_CUDA")
 201     else()
 202         set(GMX_GPU_ACCELERATION_FRAMEWORK "GMX_GPU_NONE")
 203     endif()
 204 else()
 205     #Now the OpenCL path (for both AMD and NVIDIA)
 206     if(GMX_GPU)
 207         include(gmxManageOpenCL)
 208         set(GMX_GPU_ACCELERATION_FRAMEWORK "GMX_GPU_OPENCL")
 209     else()
 210         message(FATAL_ERROR "OpenCL requested but GPU option is not enabled (try -DGMX_GPU=on) ")
 211     endif()
 212 endif()
 213
 214 gmx_option_multichoice(
 215     GMX_SIMD
 216     "SIMD instruction set for CPU kernels and compiler optimization"
 217     "AUTO"
 218     AUTO None SSE2 SSE4.1 AVX_128_FMA AVX_256 AVX2_256 AVX2_128 AVX_512 AVX_512_KNL MIC ARM_NEON ARM_NEON_ASIMD IBM_VMX IBM_VSX Sparc64_HPC_ACE Reference)
 219
 220 if(GMX_TARGET_MIC)
 221     set(GMX_FFT_LIBRARY_DEFAULT "mkl")
 222 else()
 223     set(GMX_FFT_LIBRARY_DEFAULT "fftw3")
 224 endif()
 225
 226 gmx_option_multichoice(
 227     GMX_FFT_LIBRARY
 228     "FFT library"
 229     "${GMX_FFT_LIBRARY_DEFAULT}"
 230     fftw3 mkl "fftpack[built-in]")
 231 gmx_dependent_option(
 232     GMX_BUILD_OWN_FFTW
 233     "Download and build FFTW 3 during the GROMACS build process, rather than fall back on the really slow fftpack."
 234     OFF
 235     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 236 gmx_dependent_option(
 237     GMX_DISABLE_FFTW_MEASURE
 238     "Do not optimize FFTW setups (not needed with SSE)"
 239     OFF
 240     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 241 mark_as_advanced(GMX_BUILD_OWN_FFTW)
 242 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 243
 244 gmx_option_multichoice(
 245     GMX_QMMM_PROGRAM
 246     "QM package for QM/MM"
 247     None
 248     none gaussian mopac gamess orca)
 249
 250 gmx_dependent_cache_variable(GMX_SIMD_REF_FLOAT_WIDTH  "Reference SIMD single precision width" STRING "4" "GMX_SIMD STREQUAL REFERENCE")
 251 gmx_dependent_cache_variable(GMX_SIMD_REF_DOUBLE_WIDTH "Reference SIMD double precision width" STRING "2" "GMX_SIMD STREQUAL REFERENCE")
 252
 253 # This should be moved to a separate NBNXN cmake module when that code is cleaned up and modularized
 254
 255 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 256 mark_as_advanced(GMX_BROKEN_CALLOC)
 257
 258 option(GMX_OPENMP "Enable OpenMP-based multithreading" ON)
 259
 260 option(GMX_USE_TNG "Use the TNG library for trajectory I/O" ON)
 261
 262 option(GMX_BUILD_MDRUN_ONLY "Build and install only the mdrun binary" OFF)
 263
 264 option(GMX_CYCLE_SUBCOUNTERS "Enable cycle subcounters to get a more detailed cycle timings" OFF)
 265 mark_as_advanced(GMX_CYCLE_SUBCOUNTERS)
 266
 267 option(GMX_SKIP_DEFAULT_CFLAGS "Don't automatically add suggested/required Compiler flags." OFF)
 268 mark_as_advanced(GMX_SKIP_DEFAULT_CFLAGS)
 269
 270 option(GMX_BUILD_FOR_COVERAGE
 271        "Tune build for better code coverage metrics (e.g., disable asserts)"
 272        OFF)
 273 mark_as_advanced(GMX_BUILD_FOR_COVERAGE)
 274
 275 option(GMX_DEVELOPER_BUILD
 276     "Enable Developer convenience features: always build unit-tests"
 277     OFF)
 278 mark_as_advanced(GMX_DEVELOPER_BUILD)
 279
 280 gmx_set_boolean(GMX_COMPILER_WARNINGS_DEFAULT "NOT SOURCE_IS_SOURCE_DISTRIBUTION")
 281 option(GMX_COMPILER_WARNINGS
 282     "Enable a default set of compiler warnings"
 283     ${GMX_COMPILER_WARNINGS_DEFAULT})
 284 mark_as_advanced(GMX_COMPILER_WARNINGS)
 285 # Always turn on compiler warnings with a developer build.
 286 gmx_add_cache_dependency(GMX_COMPILER_WARNINGS BOOL "NOT GMX_DEVELOPER_BUILD" ON)
 287
 288 option(GMX_BUILD_SHARED_EXE
 289     "Build exectuables as shared binaries. If not set, this disables rpath and dynamic linker flags in an attempt to build a static binary, but this may require setting up the toolchain properly and making appropriate libraries available."
 290     ON)
 291 mark_as_advanced(GMX_BUILD_SHARED_EXE)
 292
 293 option(GMX_PHYSICAL_VALIDATION
 294        "Include physical validation tests in ctest environment. These can then be called using 'make check-phys' or
 295        'make check-all'. Warning: Running the physical validation tests takes significantly more time than other tests!"
 296        OFF)
 297 mark_as_advanced(GMX_PHYSICAL_VALIDATION)
 298
 299 ######################################################################
 300 # Detect OpenMP support
 301 ######################################################################
 302 # The OpenMP detection _must_ come before tests for other CFLAGS.
 303 include(gmxManageOpenMP)
 304
 305
 306
 307 ######################################################################
 308 # Compiler tests
 309 # These need to be done early (before further tests).
 310 #####################################################################
 311
 312 include(gmxCFlags)
 313 gmx_c_flags()
 314
 315 # This variable should be used for additional compiler flags which are not
 316 # generated in gmxCFlags nor are SIMD or MPI related.
 317 #
 318 # TODO These variables should be consolidated into
 319 # EXTRA_COMPILER_FLAGS so that we we don't perpetrate bugs where
 320 # things that work in C compilation (e.g. merging from old branches)
 321 # also work for C++ compilation.
 322 set(EXTRA_C_FLAGS "")
 323 set(EXTRA_CXX_FLAGS "")
 324
 325 # Run through a number of tests for buggy compilers and other issues
 326 include(gmxTestCompilerProblems)
 327 gmx_test_compiler_problems()
 328
 329 # Implement double-precision option. This is complicated because we
 330 # need installed headers to use the precision mode of the build that
 331 # produced the library, but cannot use config.h in that case. We also
 332 # want such variables to always have a definition, because #if is more
 333 # robust than #ifdef. So, we put this value on the compiler command
 334 # line in all cases.
 335 #
 336 # GMX_RELAXED_DOUBLE_PRECISION does not need to be handled here,
 337 # because no installed header needs it
 338 if(GMX_DOUBLE)
 339     set(GMX_DOUBLE_VALUE 1)
 340 else()
 341     set(GMX_DOUBLE_VALUE 0)
 342 endif()
 343 add_definitions(-DGMX_DOUBLE=${GMX_DOUBLE_VALUE})
 344 list(APPEND INSTALLED_HEADER_DEFINITIONS "-DGMX_DOUBLE=${GMX_DOUBLE_VALUE}")
 345
 346 if(WIN32)
 347     list(APPEND GMX_EXTRA_LIBRARIES "wsock32")
 348     add_definitions(-DGMX_HAVE_WINSOCK)
 349 endif()
 350
 351
 352
 353 ########################################################################
 354 # Basic system tests (standard libraries, headers, functions, types)   #
 355 ########################################################################
 356 include(CheckIncludeFiles)
 357 include(CheckIncludeFileCXX)
 358 check_include_files(unistd.h     HAVE_UNISTD_H)
 359 check_include_files(pwd.h        HAVE_PWD_H)
 360 check_include_files(dirent.h     HAVE_DIRENT_H)
 361 check_include_files(time.h       HAVE_TIME_H)
 362 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 363 check_include_files(io.h         HAVE_IO_H)
 364 check_include_files(sched.h      HAVE_SCHED_H)
 365
 366 include(CheckCXXSymbolExists)
 367 check_cxx_symbol_exists(gettimeofday      sys/time.h   HAVE_GETTIMEOFDAY)
 368 check_cxx_symbol_exists(sysconf           unistd.h     HAVE_SYSCONF)
 369 check_cxx_symbol_exists(nice              unistd.h     HAVE_NICE)
 370 check_cxx_symbol_exists(fsync             unistd.h     HAVE_FSYNC)
 371 check_cxx_symbol_exists(_fileno           stdio.h      HAVE__FILENO)
 372 check_cxx_symbol_exists(fileno            stdio.h      HAVE_FILENO)
 373 check_cxx_symbol_exists(_commit           io.h         HAVE__COMMIT)
 374 check_cxx_symbol_exists(sigaction         signal.h     HAVE_SIGACTION)
 375
 376 # We cannot check for the __builtins as symbols, but check if code compiles
 377 check_cxx_source_compiles("int main(){ return __builtin_clz(1);}"   HAVE_BUILTIN_CLZ)
 378 check_cxx_source_compiles("int main(){ return __builtin_clzll(1);}" HAVE_BUILTIN_CLZLL)
 379 if(MSVC)
 380     check_cxx_source_compiles("#include <intrin.h>\n int main(){unsigned long r;unsigned long i=1;_BitScanReverse(&r,i);return r;}" HAVE_BITSCANREVERSE)
 381     check_cxx_source_compiles("#include <intrin.h>\n int main(){unsigned long r;unsigned __int64 i=1;_BitScanReverse(&r,i);return r;}" HAVE_BITSCANREVERSE64)
 382 elseif(CMAKE_CXX_COMPILER_ID MATCHES "XL")
 383     check_cxx_source_compiles("int main(){ return __cntlz4(1);}" HAVE_CNTLZ4)
 384     check_cxx_source_compiles("int main(){ return __cntlz8(1);}" HAVE_CNTLZ8)
 385 endif()
 386
 387 include(CheckLibraryExists)
 388 find_library(HAVE_LIBM m)
 389 mark_as_advanced(HAVE_LIBM)
 390 check_library_exists(rt clock_gettime "" HAVE_CLOCK_GETTIME)
 391 check_library_exists(m feenableexcept "" HAVE_FEENABLEEXCEPT)
 392 check_library_exists(m fedisableexcept "" HAVE_FEDISABLEEXCEPT)
 393
 394 include(TestSchedAffinity)
 395 test_sched_affinity(HAVE_SCHED_AFFINITY)
 396
 397 # Aligned memory allocation. We need to check for both mm_malloc(),
 398 # posix_memalign(), memalign(), and on windows also _aligned_malloc()
 399 include(gmxTestMMMalloc)
 400 gmx_test_mm_malloc(HAVE__MM_MALLOC)
 401 check_cxx_symbol_exists(posix_memalign    stdlib.h     HAVE_POSIX_MEMALIGN)
 402 check_cxx_symbol_exists(memalign          stdlib.h     HAVE_MEMALIGN)
 403 if(MSVC)
 404     # No need to waste time on this test on platforms where it will never be true
 405     check_cxx_symbol_exists(_aligned_malloc   stdlib.h     HAVE__ALIGNED_MALLOC)
 406 endif()
 407
 408 include(TestBigEndian)
 409 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 410
 411 gmx_set_boolean(GMX_USE_NICE "HAVE_UNISTD_H AND HAVE_NICE")
 412
 413 # Management of GROMACS options for specific toolchains should go
 414 # here. Because the initial settings for some of the main options have
 415 # already happened, but things like library detection and MPI compiler
 416 # feature detection have not, the docstrings for any over-rides of
 417 # GROMACS defaults or user settings will make sense. Also, any
 418 # toolchain-related reasons for choosing whether to detect various
 419 # things can be sorted out now, before the detection takes place.
 420 if(GMX_TARGET_FUJITSU_SPARC64)
 421     include(gmxManageFujitsuSparc64)
 422 endif()
 423
 424 ########################################################################
 425 #Process MPI settings
 426 ########################################################################
 427 include(gmxManageMPI)
 428
 429 ########################################################################
 430 #Process MiMiC settings
 431 ########################################################################
 432 include(gmxManageMimic)
 433
 434 ########################################################################
 435 #Process shared/static library settings
 436 ########################################################################
 437 include(gmxManageSharedLibraries)
 438
 439
 440 ########################################################################
 441 # Find external packages                                               #
 442 ########################################################################
 443
 444 # Unconditionally find the package, as it is also required for unit
 445 # tests. This exports LIBXML2_FOUND, which we should not use because
 446 # it does not tell us that linking will succeed. Instead, we test that
 447 # next.
 448 #if(DEFINED LIBXML2_LIBRARIES)
 449 #  set(LibXml2_FIND_QUIETLY TRUE)
 450 #endif()
 451 #find_package(LibXml2)
 452 #include(gmxTestLibXml2)
 453 #gmx_test_libxml2(HAVE_LIBXML2)
 454 #option(GMX_XML "Use libxml2 to parse xml files (currently has no effect)" ${HAVE_LIBXML2})
 455 #set(PKG_XML "")
 456 #mark_as_advanced(GMX_XML)
 457 # Don't actually do anything, since libxml2 is currently not used by libgromacs
 458 #if(GMX_XML AND NOT HAVE_LIBXML2)
 459 #    message(FATAL_ERROR "libxml2 not found. Set GMX_XML=OFF to compile without XML support")
 460 #endif()
 461 #if(GMX_XML)
 462 #    include_directories(${LIBXML2_INCLUDE_DIR})
 463 #    set(PKG_XML libxml-2.0)
 464 #    set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 465 #endif()
 466
 467 gmx_option_trivalue(
 468     GMX_HWLOC
 469     "Use hwloc portable hardware locality library"
 470     "AUTO")
 471
 472 if (GMX_HWLOC)
 473     # Find quietly the second time.
 474     if(DEFINED HWLOC_LIBRARIES)
 475         set(Hwloc_FIND_QUIETLY TRUE)
 476     endif()
 477     find_package(Hwloc 1.5)
 478
 479     if (HWLOC_FOUND)
 480         if (HWLOC_LIBRARIES MATCHES ".a$")
 481             set(_STATIC_HWLOC TRUE)
 482         endif()
 483
 484         gmx_check_if_changed(HWLOC_FOUND_CHANGED HWLOC_FOUND)
 485         if (_STATIC_HWLOC AND HWLOC_FOUND_CHANGED)
 486             message(STATUS "Static hwloc library found, will not attempt using it as it could lead to link-time errors. To use the detected library, manually set GMX_HWLOC=ON and you will likely have to pass appropriate linker flags too to satisfy the link-time dependencies of your hwloc library. Try \"pkg-config --libs --static hwloc\" for suggestions on what you will need.")
 487             set(GMX_USE_HWLOC OFF)
 488         else()
 489             set(GMX_USE_HWLOC ON)
 490         endif()
 491
 492         if (GMX_USE_HWLOC)
 493             include_directories(SYSTEM ${HWLOC_INCLUDE_DIRS})
 494             list(APPEND GMX_EXTRA_LIBRARIES ${HWLOC_LIBRARIES})
 495         endif()
 496     elseif(GMX_HWLOC_FORCE)
 497         message(FATAL_ERROR "Hwloc package support required, but not found.")
 498     endif()
 499 endif()
 500
 501 option(GMX_EXTERNAL_TINYXML2 "Use external TinyXML-2 instead of compiling the version bundled with GROMACS." OFF)
 502 mark_as_advanced(GMX_EXTERNAL_TINYXML2)
 503 if(GMX_EXTERNAL_TINYXML2)
 504     # Find an external TinyXML-2 library.
 505     find_package(TinyXML-2 3.0.0)
 506     set(HAVE_TINYXML2 ${TinyXML2_FOUND})
 507     if(NOT HAVE_TINYXML2)
 508         message(FATAL_ERROR "External TinyXML-2 could not be found, please adjust your search paths")
 509     endif()
 510 endif()
 511
 512 option(GMX_EXTRAE "Add support for tracing using EXTRAE" OFF)
 513 mark_as_advanced(GMX_EXTRAE)
 514
 515 if (GMX_EXTRAE)
 516   find_package(EXTRAE)
 517   if(EXTRAE_FOUND)
 518     include_directories(SYSTEM ${EXTRAE_INCLUDE_DIR})
 519     set(HAVE_EXTRAE 1)
 520   else()
 521     message(FATAL_ERROR "EXTRAE library was not found. Please add the correct path to CMAKE_PREFIX_PATH")
 522   endif()
 523 endif()
 524
 525 option(GMX_X11 "Use X window system" OFF)
 526 if (GMX_X11)
 527     find_package(X11)
 528     # X11 includes/libraries are only set in the ngmx subdirectory!
 529     if(NOT X11_FOUND)
 530         message(FATAL_ERROR
 531                 "X11 include files and/or libraries were not found. "
 532                 "Set GMX_X11=OFF to compile without X11 support. "
 533                 "gmx view will not be available.")
 534     endif()
 535     include_directories(SYSTEM ${X11_INCLUDE_DIR})
 536 endif()
 537
 538 include(ThreadMPI)
 539 # Enable core threading facilities
 540 tmpi_enable_core("${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include")
 541 if(GMX_THREAD_MPI)
 542     # enable MPI functions
 543     tmpi_enable()
 544     set(MPI_IN_PLACE_EXISTS 1)
 545 endif()
 546 # If atomics are manually disabled a define is needed because atomics.h doesn't depend on config.h
 547 if (TMPI_ATOMICS_DISABLED)
 548    add_definitions(-DTMPI_ATOMICS_DISABLED)
 549 endif()
 550
 551 include(gmxManageTNG)
 552
 553 include(gmxManageLmfit)
 554
 555 if(GMX_GPU)
 556     # now that we have detected the dependencies, do the second configure pass
 557     gmx_gpu_setup()
 558     if (GMX_CLANG_CUDA)
 559         list(APPEND GMX_EXTRA_LIBRARIES ${GMX_CUDA_CLANG_LINK_LIBS})
 560         link_directories("${GMX_CUDA_CLANG_LINK_DIRS}")
 561     endif()
 562 endif()
 563
 564 if(CYGWIN)
 565     set(GMX_CYGWIN 1)
 566 endif()
 567
 568 if(WIN32)
 569     set(GMX_NATIVE_WINDOWS 1)
 570     # This makes windows.h not declare min/max as macros that would break
 571     # C++ code using std::min/std::max.
 572     add_definitions(-DNOMINMAX)
 573 endif()
 574
 575 if(CMAKE_SYSTEM_NAME STREQUAL "Darwin") #Work-around for cmake bug #10837
 576     if (CMAKE_COMPILER_IS_GNUCC OR CMAKE_C_COMPILER_ID MATCHES "Intel" OR CMAKE_C_COMPILER_ID MATCHES "Clang")
 577         set(CMAKE_INCLUDE_SYSTEM_FLAG_C "-isystem ")
 578     endif()
 579     if (CMAKE_COMPILER_IS_GNUCXX OR CMAKE_CXX_COMPILER_ID MATCHES "Intel" OR CMAKE_CXX_COMPILER_ID MATCHES "Clang")
 580         set(CMAKE_INCLUDE_SYSTEM_FLAG_CXX "-isystem ")
 581     endif()
 582 endif()
 583
 584 option(GMX_BUILD_UNITTESTS "Build unit tests with BUILD_TESTING" ON)
 585 mark_as_advanced(GMX_BUILD_UNITTESTS)
 586 gmx_add_cache_dependency(GMX_BUILD_UNITTESTS BOOL BUILD_TESTING OFF)
 587
 588 ########################################################################
 589 # Our own GROMACS tests
 590 ########################################################################
 591
 592 add_definitions( -DHAVE_CONFIG_H )
 593 include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src)
 594 # TODO required at high level because both libgromacs and progs/mdrun
 595 # require it, both for thread-MPI and its atomics and mutexes.
 596 include_directories(BEFORE SYSTEM ${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include)
 597 # Required for config.h, maybe should only be set in src/CMakeLists.txt
 598 include_directories(BEFORE ${CMAKE_BINARY_DIR}/src)
 599
 600 include(gmxTestInlineASM)
 601 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 602
 603 include(gmxSetBuildInformation)
 604 gmx_set_build_information()
 605
 606 gmx_option_multichoice(
 607     GMX_USE_RDTSCP
 608     "Use low-latency RDTSCP instruction for CPU-based timers for mdrun execution; might need to be off when compiling for heterogeneous environments)"
 609     "AUTO"
 610     OFF ON AUTO DETECT)
 611 mark_as_advanced(GMX_USE_RDTSCP)
 612
 613 macro(gmx_check_rdtscp)
 614     if (CPU_DETECTION_FEATURES MATCHES "rdtscp")
 615         set(HAVE_RDTSCP 1)
 616         set(RDTSCP_DETECTION_MESSAGE " - detected on the build host")
 617     else()
 618         set(RDTSCP_DETECTION_MESSAGE " - not detected on the build host")
 619     endif()
 620 endmacro()
 621
 622 set(HAVE_RDTSCP 0)
 623 if (GMX_USE_RDTSCP STREQUAL "ON")
 624     set(HAVE_RDTSCP 1)
 625 elseif(GMX_USE_RDTSCP STREQUAL "DETECT")
 626     gmx_check_rdtscp()
 627 elseif(GMX_USE_RDTSCP STREQUAL "AUTO")
 628     # If the user specified automated SIMD selection, that the choice
 629     # is made based on detection on the build host. If so, then RDTSCP
 630     # should be chosen the same way.
 631     #
 632     # If the user specified an AVX SIMD level (e.g. when
 633     # cross-compiling GROMACS) then they will get our best guess, ie
 634     # that in practice AVX mostly correlates with rdtscp (and anyway
 635     # is only relevant in rather old x86 hardware).
 636     if (GMX_SIMD STREQUAL "AUTO")
 637         gmx_check_rdtscp()
 638     elseif (GMX_SIMD MATCHES "AVX")
 639         set(HAVE_RDTSCP 1)
 640     endif()
 641 endif()
 642 gmx_check_if_changed(HAVE_RDTSCP_CHANGED HAVE_RDTSCP)
 643 if (HAVE_RDTSCP_CHANGED)
 644     if (HAVE_RDTSCP)
 645         message(STATUS "Enabling RDTSCP support${RDTSCP_DETECTION_MESSAGE}")
 646     else()
 647         message(STATUS "Disabling RDTSCP support${RDTSCP_DETECTION_MESSAGE}")
 648     endif()
 649 endif()
 650
 651 include(gmxTestLargeFiles)
 652 gmx_test_large_files(GMX_LARGEFILES)
 653
 654 include(gmxTestSignal)
 655 gmx_test_sigusr1(HAVE_SIGUSR1)
 656
 657 include(gmxTestPipes)
 658 gmx_test_pipes(HAVE_PIPES)
 659
 660 include(gmxTestXDR)
 661 gmx_test_xdr(GMX_SYSTEM_XDR)
 662 # Darwin has system XDR, but it uses a three-argument flavour of
 663 # xdrproc_t that it guarantees will still work if you pass the normal
 664 # two-argument xdr filters, but gcc 8 warns about the cast necessary
 665 # to do that, so it's simpler to just use our own XDR library.
 666 #
 667 # TODO It would be better to craft a cmake test which fails if such
 668 # XDR operations cause warnings, and succeeds otherwise, because it is
 669 # generally preferable to use system libraries where possible.
 670 if(NOT GMX_SYSTEM_XDR OR CMAKE_SYSTEM_NAME STREQUAL "Darwin")
 671     set(GMX_INTERNAL_XDR 1)
 672 endif()
 673
 674
 675 ##################################################
 676 # Process SIMD instruction settings
 677 ##################################################
 678 # This checks what flags to add in order to
 679 # support the SIMD instructions we need, it sets
 680 # correct defines for the SIMD instructions supported,
 681 # and adds advanced options to control accuracy
 682 # for SIMD math operations.
 683 include(gmxManageSimd)
 684 gmx_manage_simd()
 685
 686 include(gmxManageCycleCounters)
 687 gmx_manage_cycle_counters()
 688
 689 # Process QM/MM Settings
 690 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 691     set(GMX_QMMM_GAUSSIAN 1)
 692 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 693     set(GMX_QMMM_MOPAC 1)
 694 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 695     set(GMX_QMMM_GAMESS 1)
 696 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 697     set(GMX_QMMM_ORCA 1)
 698 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 699     # nothing to do
 700 else()
 701     gmx_invalid_option_value(GMX_QMMM_PROGRAM)
 702 endif()
 703
 704
 705 ##################################################
 706 # Process FFT library settings
 707 ##################################################
 708 include(gmxManageFFTLibraries)
 709
 710
 711 include(gmxManageLinearAlgebraLibraries)
 712
 713 include(gmxManagePluginSupport)
 714
 715 if (GMX_USE_PLUGINS)
 716     if(NOT GMX_VMD_PLUGIN_PATH)
 717         find_package(VMD)
 718     endif()
 719 endif()
 720
 721 # Link real-time library for POSIX timers. The check for clock_gettime
 722 # confirms the linkability of rt.
 723 if(HAVE_TIME_H AND HAVE_UNISTD_H AND HAVE_CLOCK_GETTIME)
 724     list(APPEND GMX_EXTRA_LIBRARIES rt)
 725 endif()
 726
 727 # Math and thread libraries must often come after all others when linking...
 728 if (HAVE_LIBM)
 729     list(APPEND GMX_PUBLIC_LIBRARIES m)
 730 endif()
 731
 732 option(GMX_NACL "Configure for Native Client builds" OFF)
 733 if (GMX_NACL)
 734   list(APPEND GMX_EXTRA_LIBRARIES nosys)
 735   set(GMX_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -lnosys")
 736   # TODO: Is this still necessary with the check for its presence?
 737   set(GMX_USE_NICE 0)
 738   set(GMX_NO_RENAME 1)
 739 endif()
 740 mark_as_advanced(GMX_NACL)
 741
 742 if(GMX_FAHCORE)
 743   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 744       "Path to swindirect.h")
 745   include_directories(${COREWRAP_INCLUDE_DIR})
 746 endif()
 747
 748 # Value of GMX_BUILD_HELP=AUTO tries to generate things, but will only
 749 # produce warnings if that fails.
 750 set(build_help_default AUTO)
 751 if (SOURCE_IS_SOURCE_DISTRIBUTION OR CMAKE_CROSSCOMPILING)
 752     set(build_help_default OFF)
 753 endif()
 754 gmx_option_trivalue(GMX_BUILD_HELP "Build completions automatically (requires that compiled binaries can be executed on the build host) and install man pages if built (requires building the 'man' target manually)" ${build_help_default})
 755 mark_as_advanced(GMX_BUILD_HELP)
 756 if (GMX_BUILD_HELP AND SOURCE_IS_SOURCE_DISTRIBUTION AND BUILD_IS_INSOURCE)
 757     message(FATAL_ERROR
 758         "Rebuilding shell completions or man pages is not supported for "
 759         "in-source builds from a source distribution. "
 760         "Set GMX_BUILD_HELP=OFF or do an out-of-source build to proceed.")
 761 endif()
 762
 763 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 764 # these are set after everything else
 765 if (NOT GMX_SKIP_DEFAULT_CFLAGS)
 766     set(CMAKE_C_FLAGS "${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${CMAKE_C_FLAGS}")
 767     set(CMAKE_CXX_FLAGS "${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${CMAKE_CXX_FLAGS}")
 768     set(CMAKE_EXE_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}")
 769     set(CMAKE_SHARED_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS}")
 770 else()
 771     message("Recommended flags which are not added because GMX_SKIP_DEFAULT_CFLAGS=yes:")
 772     message("CMAKE_C_FLAGS: ${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${GMXC_CFLAGS}")
 773     message("CMAKE_C_FLAGS_RELEASE: ${GMXC_CFLAGS_RELEASE}")
 774     message("CMAKE_C_FLAGS_DEBUG: ${GMXC_CFLAGS_DEBUG}")
 775     message("CMAKE_CXX_FLAGS: ${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${GMXC_CXXFLAGS}")
 776     message("CMAKE_CXX_FLAGS_RELEASE: ${GMXC_CXXFLAGS_RELEASE}")
 777     message("CMAKE_CXX_FLAGS_DEBUG: ${GMXC_CXXFLAGS_DEBUG}")
 778     message("CMAKE_EXE_LINKER_FLAGS: ${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS}")
 779     message("CMAKE_SHARED_LINKER_FLAGS: ${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS}")
 780 endif()
 781
 782 ########################################################################
 783 # Specify install locations
 784 ########################################################################
 785 # Use GNUInstallDirs to set paths on multiarch systems.
 786 include(GNUInstallDirs)
 787
 788 set(GMX_INSTALL_DATASUBDIR "gromacs" CACHE STRING "Subdirectory for GROMACS data under CMAKE_INSTALL_DATADIR")
 789 mark_as_advanced(GMX_INSTALL_DATASUBDIR)
 790
 791 # Internal convenience so we do not have to join two path segments in the code
 792 set(GMX_INSTALL_GMXDATADIR ${CMAKE_INSTALL_DATADIR}/${GMX_INSTALL_DATASUBDIR})
 793
 794 # If the nesting level wrt. the installation root is changed,
 795 # gromacs-config.cmake.cmakein needs to be adapted.
 796 set(GMX_INSTALL_CMAKEDIR  ${CMAKE_INSTALL_DATAROOTDIR}/cmake)
 797
 798 # TODO: Make GMXRC adapt if this is changed
 799 set(GMX_INSTALL_PKGCONFIGDIR ${CMAKE_INSTALL_LIBDIR}/pkgconfig)
 800 set(GMX_INSTALL_OCLDIR       ${GMX_INSTALL_GMXDATADIR}/opencl)
 801
 802 list(APPEND INSTALLED_HEADER_INCLUDE_DIRS ${CMAKE_INSTALL_INCLUDEDIR})
 803
 804 # Binary and library suffix options
 805 include(gmxManageSuffixes)
 806
 807 ################################################################
 808 # Shared library load path settings
 809 ################################################################
 810 if(NOT GMX_BUILD_SHARED_EXE)
 811     # No rpath
 812     set(CMAKE_SKIP_RPATH TRUE)
 813     set(CMAKE_EXE_LINK_DYNAMIC_C_FLAGS) # remove -Wl,-Bdynamic
 814     set(CMAKE_EXE_LINK_DYNAMIC_CXX_FLAGS)
 815 else()
 816     # The build folder always has bin/ and lib/; if we are also going to
 817     # install to lib/, then the installation RPATH works also in the build
 818     # tree.  This makes installation slightly faster (no need to rewrite the
 819     # RPATHs), and makes the binaries in the build tree relocatable.
 820     if(CMAKE_INSTALL_LIBDIR STREQUAL "lib")
 821         set(CMAKE_BUILD_WITH_INSTALL_RPATH TRUE)
 822         if(POLICY CMP0068)
 823             cmake_policy(SET CMP0068 NEW) # From CMake-3.9
 824             set(CMAKE_BUILD_WITH_INSTALL_NAME_DIR TRUE)
 825         endif()
 826     endif()
 827     # Set the RPATH as relative to the executable location to make the
 828     # binaries relocatable.
 829     if(CMAKE_SYSTEM_NAME STREQUAL "Darwin") #Assume OS X >=10.5
 830         set(CMAKE_INSTALL_RPATH "@loader_path/../${CMAKE_INSTALL_LIBDIR}")
 831         set(CMAKE_INSTALL_NAME_DIR ${CMAKE_INSTALL_RPATH})
 832     else()
 833         set(CMAKE_INSTALL_RPATH "\$ORIGIN/../${CMAKE_INSTALL_LIBDIR}")
 834     endif()
 835     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 836     set(CMAKE_MACOSX_RPATH 1)
 837 endif()
 838
 839 #COPYING file: Only necessary for binary distributions.
 840 #Simpler to always install.
 841 install(FILES COPYING DESTINATION ${GMX_INSTALL_GMXDATADIR} COMPONENT data)
 842
 843 if (GMX_BUILD_FOR_COVERAGE)
 844     # Code heavy with asserts makes conditional coverage close to useless metric,
 845     # as by design most of the false branches are impossible to trigger in
 846     # correctly functioning code.  And the benefit of testing those that could
 847     # be triggered by using an API against its specification isn't usually
 848     # worth the effort.
 849     add_definitions(-DNDEBUG -DGMX_DISABLE_ASSERTS)
 850 endif()
 851
 852 if (BUILD_TESTING)
 853     include(tests/CheckTarget.cmake)
 854 endif()
 855
 856 if (NOT GMX_BUILD_MDRUN_ONLY)
 857     find_package(ImageMagick QUIET COMPONENTS convert)
 858     include(gmxTestImageMagick)
 859     GMX_TEST_IMAGEMAGICK(IMAGE_CONVERT_POSSIBLE)
 860     add_subdirectory(docs)
 861     add_subdirectory(share)
 862     add_subdirectory(scripts)
 863 endif()
 864 add_subdirectory(src)
 865
 866 if (BUILD_TESTING)
 867     add_subdirectory(tests)
 868 endif()
 869
 870 gmx_cpack_write_config()
 871
 872 # Issue a warning if NVIDIA GPUs were detected, but CUDA was not found.
 873 # Don't bother the user after the first configure pass.
 874 if ((CUDA_NOTFOUND_AUTO AND GMX_DETECT_GPU_AVAILABLE) AND NOT GMX_GPU_DETECTION_DONE)
 875     message(WARNING "${CUDA_NOTFOUND_MESSAGE}")
 876 endif()
 877 set(GMX_GPU_DETECTION_DONE TRUE CACHE INTERNAL "Whether GPU detection has already been done")
 878
 879 #######################
 880 ## uninstall target
 881 #######################
 882 CONFIGURE_FILE(   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 883                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
 884                   IMMEDIATE @ONLY)
 885 ###########################
 886 ADD_CUSTOM_TARGET(uninstall
 887                   "${CMAKE_COMMAND}" -P
 888                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
 889 ###########################
 890 set_directory_properties(PROPERTIES
 891             ADDITIONAL_MAKE_CLEAN_FILES "install_manifest.txt")