CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2009,2010,2011,2012,2013,2014, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 cmake_minimum_required(VERSION 2.8.8)
  36
  37 # CMake modules/macros are in a subdirectory to keep this file cleaner
  38 # This needs to be set before project() in order to pick up toolchain files
  39 list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake ${CMAKE_CURRENT_SOURCE_DIR}/cmake/Platform)
  40
  41 project(Gromacs)
  42
  43 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  44 set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  45 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
  46
  47 # PROJECT_VERSION should have the following structure:
  48 # VERSION-dev[-SUFFIX] where the VERSION should have the for: vMajor.vMinor.vPatch
  49 #
  50 # The "-dev" suffix is important to keep because it makes possible to distinguish
  51 # between a build from official release and a build from git release branch on a
  52 # machine with no git.
  53 #
  54 # NOTE: when releasing the "-dev" suffix needs to be stripped off!
  55 # REGRESSIONTEST_VERSION and REGRESSIONTEST_BRANCH should always be
  56 # defined.
  57 set(PROJECT_VERSION "5.0-rc1-dev")
  58 # If this is a released tarball, "-dev" will not be present in
  59 # PROJECT_VERSION, and REGRESSIONTEST_VERSION specifies the version
  60 # number of the regressiontest tarball against which the code tarball
  61 # can be tested. This will be the version of the last patch release.
  62 set(REGRESSIONTEST_VERSION "5.0-rc1")
  63 # If this is not a released tarball, "-dev" will be present in
  64 # PROJECT_VERSION, and REGRESSIONTEST_BRANCH specifies the name of the
  65 # gerrit.gromacs.org branch whose HEAD can test this code, *if* this
  66 # code contains all recent fixes from the corresponding code branch.
  67 set(REGRESSIONTEST_BRANCH "refs/heads/release-5-0")
  68
  69 set(CUSTOM_VERSION_STRING ""
  70     CACHE STRING "Custom version string (if empty, use hard-coded default)")
  71 mark_as_advanced(CUSTOM_VERSION_STRING)
  72 if (CUSTOM_VERSION_STRING)
  73     set(PROJECT_VERSION ${CUSTOM_VERSION_STRING})
  74 endif()
  75 set(LIBRARY_SOVERSION 0)
  76 set(LIBRARY_VERSION ${LIBRARY_SOVERSION}.0.0)
  77 # It is a bit irritating, but this has to be set separately for now!
  78 SET(CPACK_PACKAGE_VERSION_MAJOR "5")
  79 SET(CPACK_PACKAGE_VERSION_MINOR "0")
  80 #SET(CPACK_PACKAGE_VERSION_PATCH "0")
  81
  82 # The numerical gromacs version. It is 40600 for 4.6.0.
  83 # The #define GMX_VERSION in gromacs/version.h is set to this value.
  84 math(EXPR NUM_VERSION
  85     "${CPACK_PACKAGE_VERSION_MAJOR}*10000 + ${CPACK_PACKAGE_VERSION_MINOR}*100")
  86 if(CPACK_PACKAGE_VERSION_PATCH)
  87     math(EXPR NUM_VERSION
  88          "${NUM_VERSION} + ${CPACK_PACKAGE_VERSION_PATCH}")
  89 endif()
  90
  91 # The API version tracks the numerical Gromacs version (for now).
  92 # It is potentially different from the Gromacs version in the future, if
  93 # the programs/libraries diverge from the presumably more stable API.
  94 # The #define GMX_API_VERSION in version.h is set to this value to
  95 # provide backward compatibility of software written against the Gromacs API.
  96 set(API_VERSION ${NUM_VERSION})
  97
  98 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT AND UNIX)
  99     set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
 100 endif()
 101
 102 set(GMX_INSTALL_PREFIX "" CACHE STRING "Prefix gets appended to CMAKE_INSTALL_PREFIX. For cpack it sets the root folder of the archive.")
 103 mark_as_advanced(GMX_INSTALL_PREFIX)
 104
 105 include(gmxBuildTypeReference)
 106 include(gmxBuildTypeThreadSanitizer)
 107 include(gmxBuildTypeReleaseWithAssert)
 108
 109 if(NOT CMAKE_BUILD_TYPE)
 110     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel Reference RelWithAssert." FORCE)
 111     # There's no need to offer a user the choice of ThreadSanitizer
 112     # Set the possible values of build type for cmake-gui
 113     set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "Debug" "Release"
 114         "MinSizeRel" "RelWithDebInfo" "Reference" "RelWithAssert")
 115 endif()
 116 if(CMAKE_CONFIGURATION_TYPES)
 117     # Add appropriate GROMACS-specific build types for the Visual
 118     # Studio generator (Debug, Release, MinSizeRel and RelWithDebInfo
 119     # are already present by default).
 120     list(APPEND CMAKE_CONFIGURATION_TYPES "RelWithAssert" "Reference")
 121     list(REMOVE_DUPLICATES CMAKE_CONFIGURATION_TYPES)
 122     set(CMAKE_CONFIGURATION_TYPES "${CMAKE_CONFIGURATION_TYPES}" CACHE STRING
 123         "List of configuration types"
 124         FORCE)
 125 endif()
 126 set(build_types_with_explicit_flags RELEASE DEBUG RELWITHDEBUGINFO RELWITHASSERT MINSIZEREL)
 127
 128 enable_language(C)
 129 enable_language(CXX)
 130
 131 set(CPACK_PACKAGE_VERSION ${PROJECT_VERSION})
 132 set(CPACK_PACKAGE_VENDOR "gromacs.org")
 133 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Gromacs - a toolkit for high-performance molecular simulation")
 134 set(CPACK_RESOURCE_FILE_WELCOME "${CMAKE_SOURCE_DIR}/admin/InstallWelcome.txt")
 135 # Its GPL/LGPL, so they do not have to agree to a license for mere usage, but some installers require this...
 136 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_SOURCE_DIR}/COPYING")
 137 set(CPACK_RESOURCE_FILE_README "${CMAKE_SOURCE_DIR}/admin/InstallInfo.txt")
 138 set(CPACK_SOURCE_IGNORE_FILES "\\\\.isreposource$;\\\\.git/;\\\\.gitignore$")
 139 set(CPACK_PROJECT_CONFIG_FILE "${CMAKE_SOURCE_DIR}/CPackInit.cmake")
 140 set(CPACK_SOURCE_INSTALLED_DIRECTORIES "${CMAKE_SOURCE_DIR};/;${CMAKE_BINARY_DIR}/src/programs/completion;src/programs/completion;${CMAKE_BINARY_DIR}/share/man/man1;share/man/man1;${CMAKE_BINARY_DIR}/share/man/man7;share/man/man7;${CMAKE_BINARY_DIR}/share/html/final;share/html/final")
 141 set(CPACK_PACKAGE_CONTACT "gmx-users@gromacs.org")
 142
 143 #must come after all cpack settings!
 144 include(CPack)
 145
 146 # Set a default valgrind suppression file.
 147 # This unfortunately needs to duplicate information from CTest to work as
 148 # expected...
 149 set(MEMORYCHECK_SUPPRESSIONS_FILE
 150     "${CMAKE_SOURCE_DIR}/cmake/legacy_and_external.supp"
 151     CACHE FILEPATH
 152     "File that contains suppressions for the memory checker")
 153 include(CTest)
 154
 155 set(SOURCE_IS_GIT_REPOSITORY OFF)
 156 set(SOURCE_IS_SOURCE_DISTRIBUTION OFF)
 157 if(EXISTS "${CMAKE_SOURCE_DIR}/.git")
 158     set(SOURCE_IS_GIT_REPOSITORY ON)
 159 endif()
 160 if(NOT EXISTS "${CMAKE_SOURCE_DIR}/admin/.isreposource")
 161     set(SOURCE_IS_SOURCE_DISTRIBUTION ON)
 162 endif()
 163
 164 ########################################################################
 165 # Check and warn if cache generated on a different host is being reused
 166 ########################################################################
 167 if(CMAKE_HOST_UNIX)
 168     execute_process(COMMAND hostname
 169                     OUTPUT_VARIABLE TMP_HOSTNAME
 170                     OUTPUT_STRIP_TRAILING_WHITESPACE)
 171     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}")
 172         message(WARNING "
 173             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
 174             is being reused! This could lead to inconsitencies; therefore, it is
 175             recommended to regenerate the cache!")
 176     endif()
 177     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
 178             "Hostname of the machine where the cache was generated.")
 179 endif()
 180
 181 ########################################################################
 182 # User input options                                                   #
 183 ########################################################################
 184 include(gmxOptionUtilities)
 185
 186 set(CMAKE_PREFIX_PATH "" CACHE STRING "Extra locations to search for external libraries and tools (give directory without lib, bin, or include)")
 187
 188 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" OFF)
 189 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 190 option(GMX_THREAD_MPI  "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" ON)
 191 gmx_dependent_option(
 192     GMX_MPI_IN_PLACE
 193     "Enable MPI_IN_PLACE for MPIs that have it defined"
 194     ON
 195     GMX_MPI)
 196 mark_as_advanced(GMX_MPI_IN_PLACE)
 197 option(GMX_SOFTWARE_INVSQRT "Use GROMACS software 1/sqrt" ON)
 198 mark_as_advanced(GMX_SOFTWARE_INVSQRT)
 199 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 200 mark_as_advanced(GMX_FAHCORE)
 201
 202 option(GMX_COOL_QUOTES "Enable Gromacs cool quotes" ON)
 203 mark_as_advanced(GMX_COOL_QUOTES)
 204 gmx_add_cache_dependency(GMX_COOL_QUOTES BOOL "NOT GMX_FAHCORE" OFF)
 205
 206 # decide on GPU settings based on user-settings and GPU/CUDA detection
 207 include(gmxManageGPU)
 208
 209 # Detect the architecture the compiler is targetting, detect
 210 # SIMD instructions possibilities on that hardware, suggest SIMD instruction set
 211 # to use if none is specified, and populate the cache option for CPU
 212 # SIMD.
 213 include(gmxDetectTargetArchitecture)
 214 gmx_detect_target_architecture()
 215
 216 if(GMX_CPU_ACCELERATION)
 217     # Stay compatible with old Jenkins command line options for specific SIMD acceleration
 218     set(GMX_SIMD "${GMX_CPU_ACCELERATION}" CACHE STRING "SIMD instruction set level and compiler optimization" FORCE)
 219 endif()
 220
 221 if(NOT GMX_TARGET_MIC)
 222     include(gmxDetectSimd)
 223     gmx_detect_simd(GMX_SUGGESTED_SIMD)
 224 else()
 225     set(GMX_SUGGESTED_SIMD "None")
 226 endif()
 227
 228 gmx_option_multichoice(
 229     GMX_SIMD
 230     "SIMD instruction set for CPU kernels and compiler optimization"
 231     "${GMX_SUGGESTED_SIMD}"
 232     None SSE2 SSE4.1 AVX_128_FMA AVX_256 AVX2_256 IBM_QPX Sparc64_HPC_ACE Reference)
 233
 234 gmx_option_multichoice(
 235     GMX_FFT_LIBRARY
 236     "FFT library"
 237     "fftw3"
 238     fftw3 mkl "fftpack[built-in]")
 239 gmx_dependent_option(
 240     GMX_BUILD_OWN_FFTW
 241     "Download and build FFTW 3 during the GROMACS build process, rather than fall back on the really slow fftpack."
 242     OFF
 243     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 244 gmx_dependent_option(
 245     GMX_DISABLE_FFTW_MEASURE
 246     "Do not optimize FFTW setups (not needed with SSE)"
 247     OFF
 248     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 249 mark_as_advanced(GMX_BUILD_OWN_FFTW)
 250 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 251
 252 gmx_option_multichoice(
 253     GMX_QMMM_PROGRAM
 254     "QM package for QM/MM"
 255     None
 256     none gaussian mopac gamess orca)
 257
 258 gmx_dependent_cache_variable(GMX_SIMD_REF_FLOAT_WIDTH  "Reference SIMD single precision width" STRING "4" "GMX_SIMD STREQUAL REFERENCE")
 259 gmx_dependent_cache_variable(GMX_SIMD_REF_DOUBLE_WIDTH "Reference SIMD double precision width" STRING "2" "GMX_SIMD STREQUAL REFERENCE")
 260
 261 # This should be moved to a separate NBNXN cmake module when that code is cleaned up and modularized
 262
 263 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 264 mark_as_advanced(GMX_BROKEN_CALLOC)
 265 option(GMX_LOAD_PLUGINS "Compile with plugin support, needed to read VMD supported file formats" ON)
 266 mark_as_advanced(GMX_LOAD_PLUGINS)
 267
 268 option(GMX_GPU  "Enable GPU acceleration" ON)
 269 option(GMX_OPENMP "Enable OpenMP-based multithreading" ON)
 270
 271 option(GMX_USE_TNG "Use the TNG library for trajectory I/O" ON)
 272
 273 option(GMX_GIT_VERSION_INFO "Generate git version information" ${SOURCE_IS_GIT_REPOSITORY})
 274 mark_as_advanced(GMX_GIT_VERSION_INFO)
 275
 276 if(UNIX)
 277     option(GMX_SYMLINK_OLD_BINARY_NAMES "Create symbolic links for pre-5.0 binary names" ON)
 278 endif()
 279 option(GMX_BUILD_MDRUN_ONLY "Build and install only the mdrun binary" OFF)
 280
 281 option(GMX_CYCLE_SUBCOUNTERS "Enable cycle subcounters to get a more detailed cycle timings" OFF)
 282 mark_as_advanced(GMX_CYCLE_SUBCOUNTERS)
 283
 284 option(GMX_SKIP_DEFAULT_CFLAGS "Don't automatically add suggested/required Compiler flags." OFF)
 285 mark_as_advanced(GMX_SKIP_DEFAULT_CFLAGS)
 286
 287 option(GMX_BUILD_FOR_COVERAGE
 288        "Tune build for better code coverage metrics (e.g., disable asserts)"
 289        OFF)
 290 mark_as_advanced(GMX_BUILD_FOR_COVERAGE)
 291
 292
 293 ######################################################################
 294 # Detect OpenMP support
 295 ######################################################################
 296 # The OpenMP detection _must_ come before tests for other CFLAGS.
 297 include(gmxManageOpenMP)
 298
 299
 300
 301 ######################################################################
 302 # Compiler tests
 303 # These need to be done early (before further tests).
 304 #####################################################################
 305
 306 # The cmake/Check{C,CXX}CompilerFlag.cmake files in the GROMACS distribution
 307 # are used with permission from CMake v2.8.9 so that GROMACS can detect
 308 # invalid options with the Intel Compilers.
 309 # These files should be removed from the source tree when a CMake version that
 310 # includes the features in question becomes required for building GROMACS.
 311 include(CheckCCompilerFlag)
 312 include(CheckCXXCompilerFlag)
 313
 314
 315 include(gmxCFlags)
 316 gmx_c_flags()
 317
 318 # This variable should be used for additional compiler flags which are not
 319 # generated in gmxCFlags nor are SIMD or MPI related.
 320 set(EXTRA_C_FLAGS "")
 321 set(EXTRA_CXX_FLAGS "")
 322
 323 # Run through a number of tests for buggy compilers and other issues
 324 include(gmxTestCompilerProblems)
 325 gmx_test_compiler_problems()
 326 # GMX_SIMD will not be set automatically until the second
 327 # pass (which is not strictly guaranteed to occur), so putting this
 328 # check here among logically-related tests is inefficient, but the
 329 # potential loss is likely zero.
 330 if(GMX_SIMD STREQUAL "AVX_256"
 331         AND CMAKE_COMPILER_IS_GNUCC
 332         AND (C_COMPILER_VERSION VERSION_EQUAL "4.6.1"
 333             OR CXX_COMPILER_VERSION VERSION_EQUAL "4.6.1"))
 334     message(FATAL_ERROR "gcc 4.6.1 has buggy support for AVX, and GROMACS mdrun will not work. If you want simulation performance, use a more recent compiler. Otherwise, use GMX_SIMD=SSE4.1")
 335     # See http://gcc.gnu.org/bugzilla/show_bug.cgi?id=49002
 336 endif()
 337
 338
 339
 340 set(PKG_CFLAGS "")
 341 if(GMX_DOUBLE)
 342     add_definitions(-DGMX_DOUBLE)
 343     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_DOUBLE")
 344 endif()
 345 if(GMX_SOFTWARE_INVSQRT)
 346   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_SOFTWARE_INVSQRT")
 347 endif()
 348
 349 if(WIN32 AND NOT CYGWIN)
 350     set(GMX_WSOCKLIB_PATH CACHE PATH "Path to winsock (wsock32.lib) library.")
 351     mark_as_advanced(GMX_WSOCKLIB_PATH)
 352     find_library(WSOCK32_LIBRARY NAMES wsock32 PATHS ${GMX_WSOCKLIB_PATH})
 353     if(WSOCK32_LIBRARY)
 354         list(APPEND GMX_EXTRA_LIBRARIES ${WSOCK32_LIBRARY})
 355         add_definitions(-DGMX_HAVE_WINSOCK)
 356     else()
 357         message(STATUS "No winsock found. Cannot use interactive molecular dynamics (IMD).")
 358     endif(WSOCK32_LIBRARY)
 359 endif()
 360
 361
 362
 363 ########################################################################
 364 # Basic system tests (standard libraries, headers, functions, types)   #
 365 ########################################################################
 366 include(CheckIncludeFiles)
 367 include(CheckIncludeFileCXX)
 368 check_include_files(unistd.h     HAVE_UNISTD_H)
 369 check_include_files(pwd.h        HAVE_PWD_H)
 370 check_include_files(dirent.h     HAVE_DIRENT_H)
 371 check_include_files(time.h       HAVE_TIME_H)
 372 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 373 check_include_files(io.h         HAVE_IO_H)
 374 check_include_files(sched.h      HAVE_SCHED_H)
 375
 376 check_include_files(regex.h      HAVE_POSIX_REGEX)
 377 check_include_file_cxx(regex     HAVE_CXX11_REGEX)
 378 # TODO: It could be nice to inform the user if no regex support is found,
 379 # as selections won't be fully functional.
 380
 381 include(CheckFunctionExists)
 382 check_function_exists(posix_memalign    HAVE_POSIX_MEMALIGN)
 383 check_function_exists(memalign          HAVE_MEMALIGN)
 384 check_function_exists(_aligned_malloc   HAVE__ALIGNED_MALLOC)
 385 check_function_exists(gettimeofday      HAVE_GETTIMEOFDAY)
 386 check_function_exists(fsync             HAVE_FSYNC)
 387 check_function_exists(_fileno           HAVE__FILENO)
 388 check_function_exists(fileno            HAVE_FILENO)
 389 check_function_exists(_commit           HAVE__COMMIT)
 390 check_function_exists(sigaction         HAVE_SIGACTION)
 391 check_function_exists(sysconf           HAVE_SYSCONF)
 392 check_function_exists(sched_setaffinity HAVE_SCHED_SETAFFINITY)
 393 check_function_exists(sched_getaffinity HAVE_SCHED_GETAFFINITY)
 394 check_function_exists(rsqrt             HAVE_RSQRT)
 395 check_function_exists(rsqrtf            HAVE_RSQRTF)
 396 check_function_exists(sqrtf             HAVE_SQRTF)
 397
 398 include(CheckLibraryExists)
 399 check_library_exists(m sqrt "" HAVE_LIBM)
 400 check_library_exists(rt clock_gettime "" HAVE_CLOCK_GETTIME)
 401
 402 include(TestBigEndian)
 403 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 404
 405 # Management of GROMACS options for specific toolchains should go
 406 # here. Because the initial settings for some of the main options have
 407 # already happened, but things like library detection and MPI compiler
 408 # feature detection have not, the docstrings for any over-rides of
 409 # GROMACS defaults or user settings will make sense. Also, any
 410 # toolchain-related reasons for choosing whether to detect various
 411 # things can be sorted out now, before the detection takes place.
 412 if(${CMAKE_SYSTEM_NAME} MATCHES BlueGene)
 413     include(gmxManageBlueGene)
 414 endif()
 415
 416 ########################################################################
 417 #Process MPI settings
 418 ########################################################################
 419 include(gmxManageMPI)
 420
 421
 422 ########################################################################
 423 #Process shared/static library settings
 424 ########################################################################
 425 include(gmxManageSharedLibraries)
 426
 427
 428 ########################################################################
 429 # Find external packages                                               #
 430 ########################################################################
 431
 432 # Unconditionally find the package, as it is also required for unit
 433 # tests. This exports LIBXML2_FOUND, which we should not use because
 434 # it does not tell us that linking will succeed. Instead, we test that
 435 # next.
 436 find_package(LibXml2)
 437 include(gmxTestLibXml2)
 438 gmx_test_libxml2(HAVE_LIBXML2)
 439 option(GMX_XML "Use libxml2 to parse xml files (currently has no effect)" ${HAVE_LIBXML2})
 440 set(PKG_XML "")
 441 mark_as_advanced(GMX_XML)
 442 # Don't actually do anything, since libxml2 is currently not used by libgromacs
 443 #if(GMX_XML AND NOT HAVE_LIBXML2)
 444 #    message(FATAL_ERROR "libxml2 not found. Set GMX_XML=OFF to compile without XML support")
 445 #endif()
 446 #if(GMX_XML)
 447 #    include_directories(${LIBXML2_INCLUDE_DIR})
 448 #    set(PKG_XML libxml-2.0)
 449 #    set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 450 #endif()
 451
 452 option(GMX_EXTRAE "Add support for tracing using EXTRAE" OFF)
 453 mark_as_advanced(GMX_EXTRAE)
 454
 455 if (GMX_EXTRAE)
 456   find_package(EXTRAE)
 457   if(EXTRAE_FOUND)
 458     include_directories(${EXTRAE_INCLUDE_DIR})
 459     set(HAVE_EXTRAE 1)
 460   else()
 461     message(FATAL_ERROR "EXTRAE library was not found. Please add the correct path to CMAKE_PREFIX_PATH")
 462   endif()
 463 endif()
 464
 465 option(GMX_X11 "Use X window system" OFF)
 466 if (GMX_X11)
 467     find_package(X11)
 468     # X11 includes/libraries are only set in the ngmx subdirectory!
 469     if(NOT X11_FOUND)
 470         message(FATAL_ERROR
 471                 "X11 include files and/or libraries were not found. "
 472                 "Set GMX_X11=OFF to compile without X11 support. "
 473                 "gmx view will not be available.")
 474     endif()
 475     include_directories(${X11_INCLUDE_DIR})
 476 endif()
 477
 478 include(ThreadMPI)
 479 # Enable core threading facilities
 480 tmpi_enable_core("${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include")
 481 # Enable tMPI C++ support
 482 tmpi_enable_cxx()
 483 if(GMX_THREAD_MPI)
 484     # enable MPI functions
 485     tmpi_enable()
 486     set(GMX_MPI 1)
 487     set(MPI_IN_PLACE_EXISTS 1)
 488 endif()
 489 # If atomics are manually disabled a define is needed because atomics.h doesn't depend on config.h
 490 if (TMPI_ATOMICS_DISABLED)
 491    add_definitions(-DTMPI_ATOMICS_DISABLED)
 492 endif()
 493
 494 if(GMX_GPU)
 495     # now that we have detected the dependencies, do the second configure pass
 496     gmx_gpu_setup()
 497 endif()
 498
 499 if(CYGWIN)
 500     set(GMX_CYGWIN 1)
 501 endif()
 502
 503 if(WIN32 AND NOT CYGWIN)
 504     set(GMX_NATIVE_WINDOWS 1)
 505     # This makes windows.h not declare min/max as macros that would break
 506     # C++ code using std::min/std::max.
 507     add_definitions(-DNOMINMAX)
 508 endif()
 509
 510 # only bother with finding git and using version.h if the source is a git repo
 511 if(GMX_GIT_VERSION_INFO)
 512     if (NOT SOURCE_IS_GIT_REPOSITORY)
 513         message(FATAL_ERROR
 514             "Cannot generate git version information from source tree not under git. "
 515             "Set GMX_GIT_VERSION_INFO=OFF to proceed.")
 516     endif()
 517     # We need at least git v1.5.3 be able to parse git's date output. If not
 518     # found or the version is too small, we can't generate version information.
 519     find_package(Git)
 520
 521     if(NOT GIT_FOUND OR GIT_VERSION_STRING VERSION_LESS "1.5.3")
 522         message(FATAL_ERROR
 523             "No compatible git version found (>= 1.5.3 required). "
 524             "Won't be able to generate development version information. "
 525             "Set GMX_GIT_VERSION_INFO=OFF to proceed.")
 526     endif()
 527 endif()
 528
 529 # Detect boost unless GMX_EXTERNAL_BOOST is explicitly OFF
 530 # Used for default if GMX_EXTERNAL_BOOST is not defined (first CMake pass)
 531 if(NOT DEFINED GMX_EXTERNAL_BOOST OR GMX_EXTERNAL_BOOST)
 532     find_package(Boost 1.44.0)
 533     if(Boost_FOUND AND Boost_VERSION VERSION_LESS "104400")
 534         set(Boost_FOUND FALSE)
 535     endif()
 536     # Print the notification only on first run, when determining the default
 537     if(NOT DEFINED GMX_EXTERNAL_BOOST AND NOT Boost_FOUND)
 538         message("Boost >= 1.44 not found. Using minimal internal version. "
 539                 "This may cause trouble if you plan on compiling/linking other "
 540                 "software that uses Boost against Gromacs.")
 541     endif()
 542 endif()
 543 option(GMX_EXTERNAL_BOOST "Use external Boost instead of minimal built-in version"
 544        ${Boost_FOUND})
 545 if(GMX_EXTERNAL_BOOST AND NOT Boost_FOUND)
 546     message(FATAL_ERROR
 547         "Boost >= 1.44 not found. "
 548         "You can set GMX_EXTERNAL_BOOST=OFF to compile against minimal "
 549         "version of Boost included with Gromacs.")
 550 endif()
 551
 552 option(GMX_BUILD_UNITTESTS "Build unit tests with BUILD_TESTING (uses Google C++ Testing and Mocking Frameworks, requires libxml2)" ${HAVE_LIBXML2})
 553 mark_as_advanced(GMX_BUILD_UNITTESTS)
 554 gmx_add_cache_dependency(GMX_BUILD_UNITTESTS BOOL BUILD_TESTING OFF)
 555 if (GMX_BUILD_UNITTESTS AND NOT HAVE_LIBXML2)
 556     message(FATAL_ERROR
 557         "Cannot build unit tests without libxml2. "
 558         "Either set GMX_BUILD_UNITTESTS=OFF or tell CMake how to find a working version of libxml2.")
 559 endif()
 560
 561 ########################################################################
 562 # Generate development version info for cache
 563 ########################################################################
 564 # set(GEN_VERSION_INFO_INTERNAL "ON")
 565 # include(gmxGenerateVersionString)
 566
 567 ########################################################################
 568 # Our own GROMACS tests
 569 ########################################################################
 570
 571 add_definitions( -DHAVE_CONFIG_H )
 572 include_directories(${CMAKE_SOURCE_DIR}/src)
 573 include_directories(${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include)
 574 # Required for config.h, maybe should only be set in src/CMakeLists.txt
 575 include_directories(${CMAKE_BINARY_DIR}/src)
 576 # Required for gmx_header_config_gen.h to be found before installation
 577 include_directories(${CMAKE_BINARY_DIR}/src/gromacs/utility)
 578 # Required for now to make old code compile
 579 include_directories(${CMAKE_SOURCE_DIR}/src/gromacs/legacyheaders)
 580
 581 include(gmxTestInlineASM)
 582 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 583
 584 include(gmxSetBuildInformation)
 585 gmx_set_build_information()
 586 # Turn on RDTSCP if:
 587 # - the build system's CPU supports it
 588 # - the acceleration is set to AVX as all AVX-capable CPUs support AVX (which
 589 #   at this point means that the user set it).
 590 # Note: it's better to not use the later set value of GMX_SIMD because
 591 # it reflects the system's capability of both compiling and running AVX code.
 592 # TODO: After merge with 5.0 one could implement a cache variable dependency
 593 # such that GMX_USE_RDTSCP can change if GMX_CPU_ACCELERATION is changed to AVX
 594 # after the first cmake pass.
 595 if (BUILD_CPU_FEATURES MATCHES "rdtscp" OR GMX_SIMD MATCHES "AVX")
 596     set(GMX_USE_RDTSCP_DEFAULT_VALUE ON)
 597 else()
 598     set(GMX_USE_RDTSCP_DEFAULT_VALUE OFF)
 599 endif()
 600 option(GMX_USE_RDTSCP "Use RDTSCP for better CPU-based timers (available on recent x86 CPUs; might need to be off when compiling for heterogeneous environments)" ${GMX_USE_RDTSCP_DEFAULT_VALUE})
 601 mark_as_advanced(GMX_USE_RDTSCP)
 602 if(GMX_USE_RDTSCP)
 603     set(HAVE_RDTSCP 1)
 604 endif()
 605
 606 include(gmxTestFloatFormat)
 607 gmx_test_float_format(GMX_FLOAT_FORMAT_IEEE754
 608                       GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER
 609                       GMX_IEEE754_BIG_ENDIAN_WORD_ORDER)
 610
 611 include(gmxTestLargeFiles)
 612 gmx_test_large_files(GMX_LARGEFILES)
 613
 614 include(gmxTestSignal)
 615 gmx_test_sigusr1(HAVE_SIGUSR1)
 616
 617 include(gmxTestPipes)
 618 gmx_test_pipes(HAVE_PIPES)
 619
 620 include(gmxTestIsfinite)
 621 gmx_test_isfinite(HAVE_ISFINITE)
 622 gmx_test__isfinite(HAVE__ISFINITE)
 623 gmx_test__finite(HAVE__FINITE)
 624
 625 include(gmxTestCXX11)
 626 gmx_test_cxx11(GMX_CXX11_SUPPORTED GMX_CXX11_FLAGS)
 627 include(CMakeDependentOption)
 628 # nvcc does not support C++11 flags, so with GPUs we prefer to skip C++11 flags
 629 # entirely to keep the compilation environment uniform.
 630 cmake_dependent_option(GMX_CXX11
 631     "Use C++11 features"
 632     ON "GMX_CXX11_SUPPORTED AND NOT GMX_GPU" OFF)
 633 mark_as_advanced(GMX_CXX11)
 634 if(GMX_CXX11)
 635     set(EXTRA_CXX_FLAGS "${EXTRA_CXX_FLAGS} ${GMX_CXX11_FLAGS}")
 636 endif()
 637
 638
 639 include(gmxTestXDR)
 640 gmx_test_xdr(GMX_SYSTEM_XDR)
 641 if(NOT GMX_SYSTEM_XDR)
 642     set(GMX_INTERNAL_XDR 1)
 643 endif()
 644
 645
 646 ##################################################
 647 # Process SIMD instruction settings
 648 ##################################################
 649 # This checks what flags to add in order to
 650 # support the SIMD instructions we need, and sets
 651 # correct defines for the SIMD instructions supported.
 652 include(gmxTestSimd)
 653 gmx_test_simd()
 654
 655
 656 # Process QM/MM Settings
 657 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 658     set(GMX_QMMM_GAUSSIAN 1)
 659 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 660     set(GMX_QMMM_MOPAC 1)
 661 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 662     set(GMX_QMMM_GAMESS 1)
 663 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 664     set(GMX_QMMM_ORCA 1)
 665 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 666     # nothing to do
 667 else()
 668     gmx_invalid_option_value(GMX_QMMM_PROGRAM)
 669 endif()
 670
 671
 672 ##################################################
 673 # Process FFT library settings
 674 ##################################################
 675 include(gmxManageFFTLibraries)
 676
 677
 678 include(gmxManageLinearAlgebraLibraries)
 679
 680 # Whether GROMACS will really try to compile support for VMD plugins
 681 set(GMX_USE_PLUGINS OFF)
 682
 683 if(GMX_LOAD_PLUGINS)
 684   if(CYGWIN OR NOT WIN32)
 685     # Native Windows does not have, nor need dlopen
 686     # Note that WIN32 is set with Cygwin, but Cygwin needs dlopen to use plug-ins
 687     include(gmxTestdlopen)
 688     gmx_test_dlopen(HAVE_DLOPEN)
 689   endif()
 690
 691   # so, should we use plug-ins?
 692   if((WIN32 AND NOT CYGWIN) OR (HAVE_DLOPEN AND BUILD_SHARED_LIBS))
 693     if(NOT VMD_QUIETLY)
 694       MESSAGE(STATUS
 695           "Found the ability to use plug-ins when building shared libaries, "
 696           "so will compile to use plug-ins (e.g. to read VMD-supported file "
 697           "formats).")
 698     endif()
 699     if(NOT GMX_VMD_PLUGIN_PATH)
 700       find_package(VMD)
 701     endif()
 702     set(GMX_USE_PLUGINS ON)
 703     list(APPEND GMX_EXTRA_LIBRARIES ${CMAKE_DL_LIBS}) # magic cross-platform pre-set variable for dlopen library
 704     set(PKG_DL_LIBS "-l${CMAKE_DL_LIBS}")
 705   else()
 706     set(PKG_DL_LIBS)
 707   endif()
 708 endif()
 709 set(VMD_QUIETLY TRUE CACHE INTERNAL "")
 710
 711 # Link real-time library for POSIX timers. The check for clock_gettime
 712 # confirms the linkability of rt.
 713 if(HAVE_TIME_H AND HAVE_UNISTD_H AND HAVE_CLOCK_GETTIME)
 714     list(APPEND GMX_EXTRA_LIBRARIES rt)
 715 endif()
 716
 717 # Math and thread libraries must often come after all others when linking...
 718 if(HAVE_LIBM)
 719     list(APPEND GMX_EXTRA_LIBRARIES m)
 720 endif()
 721
 722 option(GMX_NACL "Configure for Native Client builds" OFF)
 723 if (GMX_NACL)
 724   list(APPEND GMX_EXTRA_LIBRARIES nosys)
 725   set(GMX_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -lnosys")
 726   set(GMX_NO_NICE 1)
 727   set(GMX_NO_RENAME 1)
 728 endif()
 729 mark_as_advanced(GMX_NACL)
 730
 731 if(GMX_FAHCORE)
 732   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 733       "Path to swindirect.h")
 734   include_directories(${COREWRAP_INCLUDE_DIR})
 735 endif()
 736
 737 option(GMX_BUILD_HELP "Build man pages, HTML help, and completions automatically (requires that compiled binaries can be executed on the build host)" OFF)
 738 mark_as_advanced(GMX_BUILD_HELP)
 739 if (GMX_BUILD_HELP AND SOURCE_IS_SOURCE_DISTRIBUTION AND
 740     "${CMAKE_CURRENT_SOURCE_DIR}" STREQUAL "${CMAKE_CURRENT_BINARY_DIR}")
 741
 742     message(FATAL_ERROR
 743         "Rebuilding HTML and man pages is not supported for in-source "
 744         "builds from a source distribution. "
 745         "Set GMX_BUILD_HELP=OFF or do an out-of-source build to proceed.")
 746 endif()
 747
 748 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 749 # these are set after everything else
 750 if (NOT GMX_SKIP_DEFAULT_CFLAGS)
 751     set(CMAKE_C_FLAGS "${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${CMAKE_C_FLAGS}")
 752     set(CMAKE_CXX_FLAGS "${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${CMAKE_CXX_FLAGS}")
 753     set(CMAKE_EXE_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}")
 754     set(CMAKE_SHARED_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS}")
 755 else()
 756     message("Recommended flags which are not added because GMX_SKIP_DEFAULT_CFLAGS=yes:")
 757     message("CMAKE_C_FLAGS: ${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${GMXC_CFLAGS}")
 758     message("CMAKE_C_FLAGS_RELEASE: ${GMXC_CFLAGS_RELEASE}")
 759     message("CMAKE_C_FLAGS_DEBUG: ${GMXC_CFLAGS_DEBUG}")
 760     message("CMAKE_CXX_FLAGS: ${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${GMXC_CXXFLAGS}")
 761     message("CMAKE_CXX_FLAGS_RELEASE: ${GMXC_CXXFLAGS_RELEASE}")
 762     message("CMAKE_CXX_FLAGS_DEBUG: ${GMXC_CXXFLAGS_DEBUG}")
 763     message("CMAKE_EXE_LINKER_FLAGS: ${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS}")
 764     message("CMAKE_SHARED_LINKER_FLAGS: ${MPI_LINKER_FLAGS}")
 765 endif()
 766
 767 if(NOT GMX_OPENMP)
 768     #Unset all OpenMP flags in case OpenMP was disabled either by the user
 769     #or because it was only partially detected (e.g. only for C but not C++ compiler)
 770     unset(OpenMP_C_FLAGS CACHE)
 771     unset(OpenMP_CXX_FLAGS CACHE)
 772 else()
 773     set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} ${OpenMP_LINKER_FLAGS})
 774     set(GMX_SHARED_LINKER_FLAGS ${GMX_SHARED_LINKER_FLAGS} ${OpenMP_SHARED_LINKER_FLAGS})
 775 endif()
 776 set(PKG_CFLAGS "${PKG_CFLAGS} ${OpenMP_C_FLAGS}")
 777
 778 ########################################################################
 779 # Specify install locations
 780 ########################################################################
 781 set(GMX_LIB_INSTALL_DIR lib CACHE STRING
 782     "Library installation directory (default: lib)")
 783 set(GMX_DATA_INSTALL_DIR gromacs CACHE STRING
 784     "Data installation directory under share/ (default: gromacs)")
 785 mark_as_advanced(GMX_LIB_INSTALL_DIR GMX_DATA_INSTALL_DIR)
 786
 787 set(LIB_INSTALL_DIR  ${GMX_INSTALL_PREFIX}${GMX_LIB_INSTALL_DIR})
 788 set(BIN_INSTALL_DIR  ${GMX_INSTALL_PREFIX}bin)
 789 set(DATA_INSTALL_DIR ${GMX_INSTALL_PREFIX}share/${GMX_DATA_INSTALL_DIR})
 790 set(MAN_INSTALL_DIR  ${GMX_INSTALL_PREFIX}share/man)
 791 set(INCL_INSTALL_DIR ${GMX_INSTALL_PREFIX}include)
 792
 793 set(GMXLIB_SEARCH_DIR share/${GMX_DATA_INSTALL_DIR}/top)
 794 set(GMXLIB_FALLBACK   ${CMAKE_INSTALL_PREFIX}/${DATA_INSTALL_DIR}/top)
 795
 796 # Binary and library suffix options
 797 include(gmxManageSuffixes)
 798
 799 ##################################################################
 800 # Shared library settings
 801 ##################################################################
 802 if(NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin")
 803     if(GMX_LIB_INSTALL_DIR STREQUAL "lib")
 804         set(CMAKE_BUILD_WITH_INSTALL_RPATH TRUE)
 805     endif()
 806     set(CMAKE_INSTALL_RPATH "\$ORIGIN/../${GMX_LIB_INSTALL_DIR}")
 807     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 808 else()
 809     if(CMAKE_SYSTEM_VERSION VERSION_GREATER 8.0) #rpath supported for >10.4
 810         set(CMAKE_INSTALL_NAME_DIR "@rpath")
 811         set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} "-Wl,-rpath,@executable_path/../${GMX_LIB_INSTALL_DIR}")
 812     else()
 813         set(CMAKE_INSTALL_NAME_DIR "${CMAKE_INSTALL_PREFIX}/${LIB_INSTALL_DIR}")
 814     endif()
 815 endif()
 816
 817 #COPYING file: Only necessary for binary distributions.
 818 #Simpler to always install.
 819 install(FILES COPYING DESTINATION ${DATA_INSTALL_DIR} COMPONENT data)
 820
 821 if(GMX_EXTERNAL_BOOST)
 822     include_directories(${Boost_INCLUDE_DIRS})
 823     set(PKG_CFLAGS "${PKG_CFLAGS} -I${Boost_INCLUDE_DIRS}")
 824 else()
 825     include_directories(${CMAKE_SOURCE_DIR}/src/external/boost)
 826     # typeid not supported for minimal internal version
 827     # (would add significant amount of code)
 828     add_definitions(-DBOOST_NO_TYPEID)
 829     # TODO: Propagate the above settings to the installed CMakeFiles.txt template
 830     # (from share/template/)
 831     set(PKG_CFLAGS "${PKG_CFLAGS} -DBOOST_NO_TYPEID -I${CMAKE_INSTALL_PREFIX}/${INCL_INSTALL_DIR}/gromacs/external/boost")
 832     if (NOT GMX_BUILD_MDRUN_ONLY)
 833         install(DIRECTORY ${CMAKE_SOURCE_DIR}/src/external/boost/boost
 834                 DESTINATION ${INCL_INSTALL_DIR}/gromacs/external/boost
 835                 COMPONENT development)
 836     endif()
 837 endif()
 838
 839 if(GMX_USE_TNG)
 840     find_package(ZLIB QUIET)
 841     include(gmxTestZLib)
 842     gmx_test_zlib(HAVE_ZLIB)
 843     set(TNG_BUILD_WITH_ZLIB ${HAVE_ZLIB} CACHE BOOL  "Build TNG with zlib compression")
 844     set(TNG_BUILD_FORTRAN OFF CACHE BOOL "Build Fortran compatible TNG library and examples for testing")
 845     set(TNG_BUILD_EXAMPLES OFF CACHE BOOL "Build examples showing usage of the TNG API")
 846     set(TNG_BUILD_COMPRESSION_TESTS OFF CACHE BOOL "Build tests of the TNG compression library")
 847     set(TNG_BUILD_DOCUMENTATION OFF CACHE BOOL "Use Doxygen to create the HTML based TNG API documentation")
 848     set(TNG_BUILD_TEST OFF CACHE BOOL "Build TNG testing binary.")
 849     add_subdirectory(${CMAKE_SOURCE_DIR}/src/external/tng_io)
 850     set(GMX_TNG_LIBRARIES tng_io)
 851 endif()
 852 mark_as_advanced(TNG_BUILD_FORTRAN)
 853 mark_as_advanced(TNG_BUILD_EXAMPLES)
 854 mark_as_advanced(TNG_BUILD_COMPRESSION_TESTS)
 855 mark_as_advanced(TNG_BUILD_DOCUMENTATION)
 856 mark_as_advanced(TNG_BUILD_TEST)
 857 mark_as_advanced(TNG_EXAMPLE_FILES_DIR)
 858
 859 if (GMX_BUILD_FOR_COVERAGE)
 860     # Code heavy with asserts makes conditional coverage close to useless metric,
 861     # as by design most of the false branches are impossible to trigger in
 862     # correctly functioning code.  And the benefit of testing those that could
 863     # be triggered by using an API against its specification isn't usually
 864     # worth the effort.
 865     add_definitions(-DNDEBUG -DBOOST_DISABLE_ASSERTS -DGMX_DISABLE_ASSERTS)
 866 endif()
 867
 868 if (BUILD_TESTING)
 869     # "tests" target builds all the separate test binaries.
 870     add_custom_target(tests)
 871     # "run-ctest" is an internal target that actually runs the tests.
 872     # This is necessary to be able to add separate targets that execute as part
 873     # of 'make check', but are ensured to be executed after the actual tests.
 874     add_custom_target(run-ctest
 875                       COMMAND ${CMAKE_CTEST_COMMAND} --output-on-failure
 876                       COMMENT "Running all tests"
 877                       VERBATIM)
 878     add_dependencies(run-ctest tests)
 879     # "check" target builds and runs all tests.
 880     add_custom_target(check DEPENDS run-ctest)
 881 endif()
 882
 883 if (NOT GMX_BUILD_MDRUN_ONLY)
 884     add_subdirectory(doxygen)
 885     add_subdirectory(share)
 886     add_subdirectory(scripts)
 887 endif()
 888 add_subdirectory(src)
 889
 890 if (BUILD_TESTING)
 891     add_subdirectory(tests)
 892 endif()
 893
 894 # Issue a warning if NVIDIA GPUs were detected, but CUDA was not found.
 895 # Don't bother the user after the first configure pass.
 896 if ((CUDA_NOTFOUND_AUTO AND GMX_DETECT_GPU_AVAILABLE) AND NOT GMX_GPU_DETECTION_DONE)
 897     message(WARNING "${CUDA_NOTFOUND_MESSAGE}")
 898 endif()
 899 set(GMX_GPU_DETECTION_DONE TRUE CACHE INTERNAL "Whether GPU detection has already been done")
 900
 901 #######################
 902 ## uninstall target
 903 #######################
 904     CONFIGURE_FILE(
 905                    "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 906                    "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
 907                    IMMEDIATE @ONLY)
 908 ###########################
 909 ADD_CUSTOM_TARGET(uninstall
 910                   "${CMAKE_COMMAND}" -P
 911                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
 912 ###########################
 913
 914 ########################################################################
 915 # Manual                                                               #
 916 ########################################################################
 917
 918 option(GMX_BUILD_MANUAL "Whether to try to configure to build the PDF manual" OFF)
 919 mark_as_advanced(GMX_BUILD_MANUAL)
 920 if(GMX_BUILD_MANUAL)
 921     # Make sure we only do detection of manual-building dependencies
 922     # when the user opted in for that.
 923     add_subdirectory(manual)
 924 endif()