CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.6)
   2
   3 project(Gromacs)
   4 include(Dart)
   5 # PROJECT_VERSION should have the following structure:
   6 # VERSION[-dev-SUFFIX] where the VERSION can have any form and the suffix
   7 set(PROJECT_VERSION "4.5.1")
   8 set(CUSTOM_VERSION_STRING ""
   9     CACHE STRING "Custom version string (if empty, use hard-coded default)")
  10 mark_as_advanced(CUSTOM_VERSION_STRING)
  11 if (CUSTOM_VERSION_STRING)
  12     set(PROJECT_VERSION ${CUSTOM_VERSION_STRING})
  13 endif (CUSTOM_VERSION_STRING)
  14 set(SOVERSION 6)
  15 # It is a bit irritating, but this has to be set separately for now!
  16 SET(CPACK_PACKAGE_VERSION_MAJOR "4")
  17 SET(CPACK_PACKAGE_VERSION_MINOR "5")
  18 SET(CPACK_PACKAGE_VERSION_PATCH "1")
  19
  20
  21 # Cmake modules/macros are in a subdirectory to keep this file cleaner
  22 set(CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake)
  23
  24 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
  25 set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "" FORCE)
  26 endif()
  27
  28 if(NOT CMAKE_BUILD_TYPE)
  29     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel." FORCE)
  30 endif(NOT CMAKE_BUILD_TYPE)
  31
  32 enable_language(C)
  33
  34 set(CPACK_PACKAGE_VERSION ${PROJECT_VERSION})
  35 set(CPACK_PACKAGE_VENDOR "gromacs.org")
  36 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Gromacs - a toolkit for high-performance molecular simulation")
  37 set(CPACK_SET_DESTDIR "ON")
  38 set(CPACK_INCLUDE_TOPLEVEL_DIRECTORY 0)
  39 set(CPACK_RESOURCE_FILE_WELCOME "${CMAKE_SOURCE_DIR}/admin/InstallWelcome.txt")
  40 # Its GPL/LGPL, so they do not have to agree to a license for mere usage, but some installers require this...
  41 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_SOURCE_DIR}/admin/InstallLicense.txt")
  42 set(CPACK_RESOURCE_FILE_README "${CMAKE_SOURCE_DIR}/admin/InstallInfo.txt")
  43
  44 #must come after all cpack settings!
  45 include(CPack)
  46
  47
  48 ########################################################################
  49 # Fix stupid flags on MSVC
  50 ########################################################################
  51 SET(SHARED_LIBS_DEFAULT ON)
  52 IF(CMAKE_GENERATOR MATCHES "Visual Studio")
  53     STRING(REPLACE /MD /MT CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE})
  54     SET(CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE} CACHE STRING "" FORCE)
  55     STRING(REPLACE /MD /MT CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG})
  56     SET(CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG} CACHE STRING "" FORCE)
  57     SET(SHARED_LIBS_DEFAULT OFF)
  58 ENDIF(CMAKE_GENERATOR MATCHES "Visual Studio")
  59
  60 set(GMX_EXTRA_LIBRARIES)
  61
  62
  63
  64 ######################################################################
  65 # compiler tests
  66 # these need ot be done early (before further tests).
  67 #####################################################################
  68
  69 include(CheckCCompilerFlag)
  70 include(CheckCXXCompilerFlag)
  71
  72 include(gmxCFlags)
  73 gmx_c_flags()
  74
  75 ########################################################################
  76 # User input options                                                   #
  77 ########################################################################
  78 option(GMX_DOUBLE "Use double precision" OFF)
  79 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
  80 option(GMX_THREADS    "Build a parallel (thread-based) version of GROMACS)" ON)
  81 option(GMX_SOFTWARE_INVSQRT "Use GROMACS software 1/sqrt" ON)
  82 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
  83 option(GMX_OPENMM "Accelerated execution on GPUs through the OpenMM library" OFF)
  84 set(GMX_ACCELERATION "auto"
  85     CACHE STRING "Accelerated kernels. Pick one of: none, SSE, BlueGene, Power6, ia64, altivec")
  86
  87 set(GMX_FFT_LIBRARY "fftw3"
  88     CACHE STRING "FFT library choices: fftw3,fftw2,mkl,fftpack[built-in]")
  89 option(GMX_DISABLE_FFTW_MEASURE
  90        "Do not optimize FFTW setups (not needed with SSE)" OFF)
  91 set(GMX_QMMM_PROGRAM "none"
  92     CACHE STRING "QM package choices: none,gaussian,mopac,gamess,orca")
  93 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
  94 option(BUILD_SHARED_LIBS "Enable shared libraries (can be problematic with MPI, Windows)" ${SHARED_LIBS_DEFAULT})
  95 option(GMX_MPI_IN_PLACE "Enable MPI_IN_PLACE for MPIs that have it defined" ON)
  96 option(GMX_DLOPEN "Compile with dlopen, needed to read VMD supported file formats" ON)
  97 mark_as_advanced(GMX_MPI_IN_PLACE)
  98
  99
 100 option(GMX_IA32_ASM "Add SSE assembly files for IA32" OFF)
 101 option(GMX_X86_64_ASM "Add SSE assembly files for X86_64" OFF)
 102
 103 option(USE_VERSION_H "Generate development version string/information" ON)
 104 mark_as_advanced(USE_VERSION_H)
 105
 106 option(GMX_DEFAULT_SUFFIX "Use default GROMACS suffixes" ON)
 107 set(GMX_BINARY_SUFFIX "" CACHE STRING "Suffix for GROMACS binaries (default: _d for double).")
 108 set(GMX_LIBS_SUFFIX ""
 109   CACHE STRING "Suffix for GROMACS libs (default: _d for double, _mpi for mpi, _mpi_d for mpi and double).")
 110 if (GMX_DEFAULT_SUFFIX)
 111   if (GMX_MPI)
 112     set(GMX_LIBS_SUFFIX "_mpi")
 113   endif(GMX_MPI)
 114   if (GMX_DOUBLE)
 115     set (GMX_BINARY_SUFFIX "_d")
 116     set (GMX_LIBS_SUFFIX "${GMX_LIBS_SUFFIX}_d")
 117   endif(GMX_DOUBLE)
 118 endif(GMX_DEFAULT_SUFFIX)
 119
 120 set(PKG_CFLAGS "")
 121 if(GMX_DOUBLE)
 122   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_DOUBLE")
 123 endif(GMX_DOUBLE)
 124 if(GMX_SOFTWARE_INVSQRT)
 125   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_SOFTWARE_INVSQRT")
 126 endif(GMX_SOFTWARE_INVSQRT)
 127
 128 ########################################################################
 129 #Process MPI settings
 130 ########################################################################
 131 if(GMX_MPI)
 132         MESSAGE(WARNING "
 133             There are known problems with some MPI implementations:
 134                      OpenMPI version < 1.4.1
 135                      MVAPICH2 version <= 1.4.1                               *")
 136     if(GMX_THREADS)
 137         #message(FATAL_ERROR "Thread-based parallelization conflicts with MPI.")
 138         set(GMX_THREADS OFF CACHE BOOL
 139             "Thread-based parallelization conflicts with MPI." FORCE)
 140     endif(GMX_THREADS)
 141     find_package(MPI)
 142     if(MPI_FOUND)
 143         set(GROMACS_C_FLAGS ${GROMACS_FLAGS} ${MPI_COMPILE_FLAGS})
 144         set(GROMACS_LINKER_FLAGS ${GROMACS_LINKER_FLAGS} ${MPI_LINK_FLAGS})
 145
 146         include_directories(${MPI_INCLUDE_PATH})
 147         list(APPEND GMX_EXTRA_LIBRARIES ${MPI_LIBRARIES})
 148         add_definitions( -DMPI ) #for FAHCORE
 149         include(gmxTestMPI_IN_PLACE)
 150         if (GMX_MPI_IN_PLACE)
 151             gmx_test_mpi_in_place(MPI_IN_PLACE_EXISTS)
 152         endif (GMX_MPI_IN_PLACE)
 153     else(MPI_FOUND)
 154         message(FATAL_ERROR "MPI support requested, but no MPI compiler found.")
 155     endif(MPI_FOUND)
 156     include(gmxTestCatamount)
 157     gmx_test_catamount(GMX_CRAY_XT3)
 158     if(GMX_CRAY_XT3)
 159         set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_CRAY_XT3")
 160         set(GMX_NO_SYSTEM 1)
 161         set(GMX_NO_NICE 1)
 162     endif(GMX_CRAY_XT3)
 163     set(GMX_LIB_MPI 1)
 164     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_LIB_MPI")
 165 endif(GMX_MPI)
 166
 167
 168 #######################################################################
 169 # Check for options incompatible with OpenMM build                    #
 170 #######################################################################
 171 if(GMX_OPENMM)
 172     cmake_minimum_required(VERSION 2.6.4)
 173     # we'll use the built-in fft to avoid unnecessary dependencies
 174     message(STATUS "No external FFT libraries needed for the OpenMM build, using fftpack!")
 175     set (GMX_FFT_LIBRARY "fftpack" CACHE STRING
 176                 "No external FFT libraries needed for the OpenMM build, using fftpack!" FORCE)
 177     if(GMX_MPI)
 178         message(FATAL_ERROR "The OpenMM build is not compatible with MPI!")
 179     endif(GMX_MPI)
 180     if(GMX_THREADS)
 181         message(STATUS "Threads not compatible with OpenMM build, disabled!")
 182         set(GMX_THREADS OFF CACHE BOOL
 183                 "Threads not compatible with OpenMM build, disabled!" FORCE)
 184     endif(GMX_THREADS)
 185     if(GMX_SOFTWARE_INVSQRT)
 186         set(GMX_SOFTWARE_INVSQRT OFF FORCE)
 187     endif(GMX_SOFTWARE_INVSQRT)
 188     if(NOT GMX_ACCELERATION MATCHES "^(none|None|NONE)")
 189         message(WARNING "CPU-based acceleration turned off, OpenMM does not support/need any!")
 190         unset(GMX_ACCELERATION CACHE)
 191         set(GMX_ACCELERATION "none" CACHE STRING
 192                 "CPU-based acceleration turned off, OpenMM does not support/need any!" FORCE)
 193     endif()
 194     if(GMX_FAHCORE)
 195         message(FATAL_ERROR "The OpenMM build does not support FAH build!")
 196     endif(GMX_FAHCORE)
 197 endif(GMX_OPENMM)
 198
 199
 200 ########################################################################
 201 # Basic system tests (standard libraries, headers, functions, types)   #
 202 ########################################################################
 203 include(CheckIncludeFiles)
 204 check_include_files(string.h     HAVE_STRING_H)
 205 check_include_files(math.h       HAVE_MATH_H)
 206 check_include_files(limits.h     HAVE_LIMITS_H)
 207 check_include_files(memory.h     HAVE_MEMORY_H)
 208 check_include_files(unistd.h     HAVE_UNISTD_H)
 209 check_include_files(pwd.h        HAVE_PWD_H)
 210 check_include_files(stdint.h     HAVE_STDINT_H)
 211 check_include_files(stdlib.h     HAVE_STDLIB_H)
 212 check_include_files(pthread.h    HAVE_PTHREAD_H)
 213 check_include_files(dirent.h     HAVE_DIRENT_H)
 214 check_include_files(inttypes.h   HAVE_INTTYPES_H)
 215 check_include_files(regex.h      HAVE_REGEX_H)
 216 check_include_files(sys/types.h  HAVE_SYS_TYPES_H)
 217 check_include_files(sys/stat.h   HAVE_SYS_STAT_H)
 218 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 219 check_include_files(rpc/rpc.h    HAVE_RPC_RPC_H)
 220 check_include_files("rpc/rpc.h;rpc/xdr.h"    HAVE_RPC_XDR_H)
 221 # SSE support
 222 check_include_files(xmmintrin.h  HAVE_XMMINTRIN_H)
 223 check_include_files(emmintrin.h  HAVE_EMMINTRIN_H)
 224 check_include_files(pmmintrin.h  HAVE_PMMINTRIN_H)
 225 check_include_files(smmintrin.h  HAVE_SMMINTRIN_H)
 226 check_include_files(io.h                 HAVE_IO_H)
 227
 228
 229 include(CheckFunctionExists)
 230 check_function_exists(strcasecmp        HAVE_STRCASECMP)
 231 check_function_exists(strdup            HAVE_STRDUP)
 232 check_function_exists(vprintf           HAVE_VPRINTF)
 233 check_function_exists(memcmp            HAVE_MEMCMP)
 234 check_function_exists(posix_memalign    HAVE_POSIX_MEMALIGN)
 235 check_function_exists(memalign          HAVE_MEMALIGN)
 236 check_function_exists(_aligned_malloc   HAVE__ALIGNED_MALLOC)
 237 check_function_exists(gettimeofday      HAVE_GETTIMEOFDAY)
 238 check_function_exists(isnan             HAVE_ISNAN)
 239 check_function_exists(_isnan            HAVE__ISNAN)
 240 check_function_exists(isfinite          HAVE_ISFINITE)
 241 check_function_exists(_isfinite         HAVE__ISFINITE)
 242 check_function_exists(fsync             HAVE_FSYNC)
 243 check_function_exists(_fileno           HAVE__FILENO)
 244 check_function_exists(fileno            HAVE_FILENO)
 245 check_function_exists(_commit           HAVE__COMMIT)
 246
 247 include(CheckLibraryExists)
 248 check_library_exists(m sqrt "" HAVE_LIBM)
 249 check_library_exists(m cbrt "" HAVE_CBRT)
 250
 251
 252 include(CheckTypeSize)
 253
 254 check_type_size("bool"          SIZEOF_BOOL) # will also set HAVE_BOOL
 255 check_type_size("int"           SIZEOF_INT)
 256 check_type_size("long int"      SIZEOF_LONG_INT)
 257 check_type_size("long long int" SIZEOF_LONG_LONG_INT)
 258 check_type_size("off_t"         SIZEOF_OFF_T)
 259 check_type_size("void *"        SIZEOF_VOIDP)
 260
 261 if (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 262     set(GMX_64_BIT TRUE)
 263 else (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 264     set(GMX_64_BIT FALSE)
 265 endif (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 266
 267 # Check for some basic types that we *need*, so set these to int if they are not present
 268 check_type_size(uid_t uid_t)
 269 if(NOT uid_t)
 270   set(uid_t int)
 271 else(NOT uid_t)
 272   set(uid_t 0)
 273 endif(NOT uid_t)
 274
 275 check_type_size(gid_t gid_t)
 276 if(NOT gid_t)
 277   set(gid_t 1)
 278 else(NOT gid_t)
 279   set(gid_t 0)
 280 endif(NOT gid_t)
 281
 282 check_type_size(size_t size_t)
 283 if(NOT size_t)
 284   set(size_t int)
 285 else(NOT size_t)
 286   set(size_t 0)
 287 endif(NOT size_t)
 288
 289 check_type_size(off_t off_t)
 290 if(NOT off_t)
 291   set(off_t int)
 292 else(NOT off_t)
 293   set(off_t 0)
 294 endif(NOT off_t)
 295
 296 include(TestBigEndian)
 297 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 298
 299
 300
 301
 302 ########################################################################
 303 # Find external packages                                               #
 304 ########################################################################
 305
 306 find_package(LibXml2)
 307 set(PKG_XML "")
 308 if(LIBXML2_FOUND)
 309     include_directories(${LIBXML2_INCLUDE_DIR})
 310     set(PKG_XML libxml-2.0)
 311     set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 312     set(HAVE_LIBXML2 1)
 313 endif(LIBXML2_FOUND)
 314
 315 option(GMX_X11 "Use X window system" OFF)
 316 if (GMX_X11)
 317         find_package(X11)
 318         # X11 includes/libraries are only set in the ngmx subdirectory!
 319         if(X11_FOUND)
 320         set(HAVE_X11 1)
 321         endif(X11_FOUND)
 322 endif(GMX_X11)
 323
 324 if(GMX_THREADS)
 325     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_THREADS")
 326     include(ThreadMPI)
 327     set(THREAD_MPI_LIB thread_mpi)
 328     set(GMX_MPI 1)
 329     string(TOUPPER ${GMX_FFT_LIBRARY} ${GMX_FFT_LIBRARY})
 330     if(${GMX_FFT_LIBRARY} STREQUAL "FFTW2")
 331         message(FATAL_ERROR "FFTW2 can't be used with threads. Try fftw3 or mkl.")
 332     endif()
 333 endif(GMX_THREADS)
 334
 335 if(GMX_OPENMM)
 336     set(CUDA_BUILD_EMULATION OFF)
 337     find_package(CUDA 3.1 REQUIRED)
 338     add_definitions(-DGMX_OPENMM)
 339     if(CMAKE_BUILD_TYPE STREQUAL "DEBUG")
 340         set(CUDA_VERBOSE_BUILD ON)
 341     endif()
 342     find_package(OpenMM)
 343 endif(GMX_OPENMM)
 344
 345 if(APPLE)
 346    find_library(ACCELERATE_FRAMEWORK Accelerate)
 347    list(APPEND GMX_EXTRA_LIBRARIES ${ACCELERATE_FRAMEWORK})
 348 endif(APPLE)
 349
 350 # only bother with finding git and using version.h if the source is a git repo
 351 if(EXISTS "${CMAKE_SOURCE_DIR}/.git")
 352     if(USE_VERSION_H)
 353         # We need at least git v1.5.1 be able to parse git's date output. If not
 354         # fund or the version is too small, we can't generate version information.
 355         find_package(Git 1.5.1)
 356         # this should at some point become VERSION_LESS
 357         if(NOT Git_FOUND OR Git_VERSION STRLESS "1.5.1")
 358             message("No compatible git version found, won't be able to generate proper development version information.")
 359         endif()
 360     endif()
 361 else()
 362     set(USE_VERSION_H OFF)
 363 endif()
 364
 365 if (GMX_DLOPEN)
 366     list(APPEND GMX_EXTRA_LIBRARIES ${CMAKE_DL_LIBS})
 367 endif (GMX_DLOPEN)
 368
 369 ########################################################################
 370 # Generate development version info for cache
 371 ########################################################################
 372 # set(GEN_VERSION_INFO_INTERNAL "ON")
 373 # include(gmxGenerateVersionString)
 374
 375 ########################################################################
 376 # Our own GROMACS tests
 377 ########################################################################
 378
 379 add_definitions( -DHAVE_CONFIG_H )
 380 include_directories(${CMAKE_BINARY_DIR}/src)
 381 include_directories(${CMAKE_SOURCE_DIR}/include)
 382
 383 include(gmxCheckBuildUserTime)
 384 gmx_check_build_user_time(BUILD_TIME BUILD_USER BUILD_MACHINE)
 385
 386 include(gmxTestFloatFormat)
 387 gmx_test_float_format(GMX_FLOAT_FORMAT_IEEE754
 388                       GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER
 389                       GMX_IEEE754_BIG_ENDIAN_WORD_ORDER)
 390
 391 include(gmxTestLargeFiles)
 392 gmx_test_large_files(GMX_LARGEFILES)
 393 check_function_exists(fseeko     HAVE_FSEEKO)
 394
 395 include(gmxTestSignal)
 396 gmx_test_retsigtype(RETSIGTYPE)
 397 gmx_test_sigusr1(HAVE_SIGUSR1)
 398
 399 include(gmxTestInline)
 400 gmx_test_inline(INLINE_KEYWORD)
 401
 402 include(gmxTestRestrict)
 403 gmx_test_inline(RESTRICT_KEYWORD)
 404
 405 include(gmxTestPipes)
 406 gmx_test_pipes(HAVE_PIPES)
 407
 408 include(gmxTestInlineASM)
 409 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 410 gmx_test_inline_asm_msvc_x86(GMX_X86_MSVC_INLINE_ASM)
 411
 412 # turn on SSE if supported with reasonable defaults.
 413 if (${GMX_ACCELERATION} STREQUAL "auto" AND NOT GMX_OPENMM)
 414   if(CMAKE_SYSTEM_PROCESSOR MATCHES "^(i.86|x86|x64|x86_64|AMD64|amd64)")
 415
 416     set(GMX_ACCELERATION "SSE" CACHE STRING "Accelerated kernels. Pick one of: none, SSE, BlueGene, Power6, ia64, altivec" FORCE)
 417
 418     if (GMX_64_BIT)
 419       set(GMX_X86_64_ASM ON CACHE BOOL "Add SSE assembly files for x86_64" FORCE)
 420     else (GMX_64_BIT)
 421       set(GMX_IA32_ASM ON CACHE BOOL "Add SSE assembly files for i386" FORCE)
 422     endif (GMX_64_BIT)
 423
 424     # Determine the assembler/compiler to use
 425   else()
 426     set(GMX_ACCELERATION "none" CACHE STRING "Accelerated kernels. Pick one of: none, SSE, BlueGene, Power6, ia64, altivec" FORCE)
 427   endif()
 428 endif (${GMX_ACCELERATION} STREQUAL "auto" AND NOT GMX_OPENMM)
 429
 430
 431 include(gmxTestXDR)
 432 gmx_test_xdr(GMX_SYSTEM_XDR)
 433 if(NOT GMX_SYSTEM_XDR)
 434     set(GMX_INTERNAL_XDR 1)
 435     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_INTERNAL_XDR")
 436 endif(NOT GMX_SYSTEM_XDR)
 437
 438 if(GMX_FORTRAN OR GMX_POWER6)
 439     enable_language(Fortran)
 440     include(FortranCInterface)
 441     discover_fortran_mangling(prefix isupper suffix extra_under_score found)
 442     if(extra_under_score)
 443         set(extrasuffix "_")
 444     endif(extra_under_score)
 445
 446     if(isupper)
 447         set(F77_FUNCDEF   "${prefix} ## NAME ## ${suffix}")
 448         set(F77_FUNCDEF_  "${prefix} ## NAME ## ${suffix}${extrasuffix}")
 449     else(isupper)
 450         set(F77_FUNCDEF   "${prefix} ## name ## ${suffix}")
 451         set(F77_FUNCDEF_  "${prefix} ## name ## ${suffix}${extrasuffix}")
 452     endif(isupper)
 453 else(GMX_FORTRAN OR GMX_POWER6)
 454         set(F77_FUNCDEF   "name ## _")
 455         set(F77_FUNCDEF_  "name ## _")
 456 endif(GMX_FORTRAN OR GMX_POWER6)
 457
 458
 459 # Process nonbonded accelerated kernels settings
 460 string(TOUPPER ${GMX_ACCELERATION} ${GMX_ACCELERATION})
 461 if(${GMX_ACCELERATION} STREQUAL "NONE")
 462   # nothing to do
 463 elseif(${GMX_ACCELERATION} STREQUAL "SSE")
 464
 465     if(CMAKE_GENERATOR MATCHES "Visual Studio")
 466       option(GMX_ASM_USEASM-NASM "Use Nasm for assembly instead of compiler (necessary on windows)" ON)
 467     else(CMAKE_GENERATOR MATCHES "Visual Studio")
 468       option(GMX_ASM_USEASM-NASM "Use Nasm for assembly instead of compiler (necessary on windows)" OFF)
 469     endif(CMAKE_GENERATOR MATCHES "Visual Studio")
 470     if (NOT GMX_64_BIT)
 471         # for 32-bit compiles, we might need to turn on sse
 472         CHECK_C_COMPILER_FLAG("-msse2" XFLAGS_SSE)
 473         if (XFLAGS_SSE)
 474             set(GROMACS_C_FLAGS "-msse2 ${GROMACS_C_FLAGS}")
 475         endif (XFLAGS_SSE)
 476         CHECK_CXX_COMPILER_FLAG("-msse2" XXFLAGS_SSE)
 477         if (XXFLAGS_SSE)
 478             set(GROMACS_CXX_FLAGS "-msse2 ${GROMACS_CXX_FLAGS}")
 479         endif (XXFLAGS_SSE)
 480     endif (NOT GMX_64_BIT)
 481
 482     if(GMX_IA32_ASM)
 483       if(GMX_DOUBLE)
 484         set(GMX_IA32_SSE2 1)
 485       else()
 486         set(GMX_IA32_SSE 1)
 487       endif()
 488     elseif(GMX_X86_64_ASM)
 489       if(GMX_DOUBLE)
 490         set(GMX_X86_64_SSE2 1)
 491       else()
 492         set(GMX_X86_64_SSE 1)
 493       endif()
 494     endif()
 495
 496 #    if(HAVE_PMMINTRIN_H)
 497 #        set(GMX_SSE3 1)
 498 #    endif(HAVE_PMMINTRIN_H)
 499 #    if(HAVE_SMMINTRIN_H)
 500 #        set(GMX_SSE4_1 1)
 501 #    endif(HAVE_SMMINTRIN_H)
 502
 503 elseif(${GMX_ACCELERATION} STREQUAL "FORTRAN")
 504     set(GMX_FORTRAN 1)
 505 elseif(${GMX_ACCELERATION} STREQUAL "BLUEGENE")
 506     set(GMX_BLUEGENE 1)
 507 elseif(${GMX_ACCELERATION} STREQUAL "POWER6")
 508     set(GMX_POWER6 1)
 509 elseif(${GMX_ACCELERATION} STREQUAL "IA64")
 510     set(GMX_IA64_ASM 1)
 511     set(DISABLE_WATERWATER_NLIST 1)
 512     set(DISABLE_WATER_NLIST 1)
 513 elseif(${GMX_ACCELERATION} STREQUAL "ALTIVEC")
 514     check_include_files(altivec.h HAVE_ALTIVEC_H)
 515     if(HAVE_ALTIVEC_H)
 516         set(GMX_PPC_ALTIVEC 1)
 517     endif(HAVE_ALTIVEC_H)
 518 else(${GMX_ACCELERATION} STREQUAL "NONE")
 519     MESSAGE(FATAL_ERROR "Unrecognized option for accelerated kernels: ${GMX_ACCELERATION}. Pick one of none, SSE, Fortran, BlueGene, Power6, ia64, altivec")
 520 endif(${GMX_ACCELERATION} STREQUAL "NONE")
 521
 522
 523
 524
 525
 526
 527
 528 # Process QM/MM Settings
 529 string(TOUPPER ${GMX_QMMM_PROGRAM} ${GMX_QMMM_PROGRAM})
 530 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 531     set(GMX_QMMM_GAUSSIAN 1)
 532 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 533     set(GMX_QMMM_MOPAC 1)
 534 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 535     set(GMX_QMMM_GAMESS 1)
 536 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 537     set(GMX_QMMM_ORCA 1)
 538 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 539     # nothing to do
 540 else(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 541     MESSAGE(FATAL_ERROR "Invalid QM/MM program option: ${GMX_QMMM_PROGRAM}. Choose one of: Gaussian, Mopac, Gamess, Orca, None")
 542 endif(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 543
 544 # Process FFT library settings - if not OpenMM build
 545 string(TOUPPER ${GMX_FFT_LIBRARY} ${GMX_FFT_LIBRARY})
 546 set(PKG_FFT "")
 547 set(PKG_FFT_LIBS "")
 548 if(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 549 #    MESSAGE(STATUS "Using external FFT library - fftw3")
 550     if(GMX_DOUBLE)
 551         find_package(FFTW3 REQUIRED)
 552                 include_directories(${FFTW3_INCLUDE_DIR})
 553         set(FFT_LIBRARIES ${FFTW3_LIBRARIES})
 554         set(PKG_FFT "fftw3")
 555     else(GMX_DOUBLE)
 556         find_package(FFTW3F REQUIRED)
 557         include_directories(${FFTW3F_INCLUDE_DIR})
 558         set(FFT_LIBRARIES ${FFTW3F_LIBRARIES})
 559         set(PKG_FFT "fftw3f")
 560     endif(GMX_DOUBLE)
 561
 562     if(NOT FFTW3_FOUND AND NOT FFTW3F_FOUND)
 563         MESSAGE(FATAL_ERROR "Cannot find fftw3 (with correct precision). Fix it, choose another FFT library, or use the Gromacs built-in fftpack (slower)!")
 564     endif(NOT FFTW3_FOUND AND NOT FFTW3F_FOUND)
 565
 566     set(GMX_FFT_FFTW3 1)
 567
 568 elseif(${GMX_FFT_LIBRARY} STREQUAL "FFTW2")
 569 #    MESSAGE(STATUS "Using external FFT library - fftw2")
 570     if(GMX_DOUBLE)
 571         find_package(FFTW2 REQUIRED)
 572     else(GMX_DOUBLE)
 573         find_package(FFTW2F REQUIRED)
 574     endif(GMX_DOUBLE)
 575
 576     if(NOT FFTW2_FOUND)
 577            MESSAGE(FATAL_ERROR "Cannot find fftw2 (with correct precision). Fix it, choose another FFT library, or use the Gromacs built-in fftpack (slower)!")
 578     endif(NOT FFTW2_FOUND)
 579     include_directories(${FFTW2_INCLUDE_DIR})
 580     set(FFT_LIBRARIES ${FFTW2_LIBRARIES})
 581     set(PKG_FFT_LIBS ${FFTW2_LIBRARIES})
 582
 583     if("${FFTW2_LIBRARIES}" MATCHES "dfftw")
 584         set(FFTW2_NAME_DFFTW 1)
 585     elseif("${FFTW2_LIBRARIES}" MATCHES "sfftw")
 586         set(FFTW2_NAME_SFFTW 1)
 587     else("${FFTW2_LIBRARIES}" MATCHES "dfftw")
 588         set(FFTW2_NAME_FFTW 1)
 589     endif("${FFTW2_LIBRARIES}" MATCHES "dfftw")
 590
 591     set(GMX_FFT_FFTW2 1)
 592 elseif(${GMX_FFT_LIBRARY} STREQUAL "MKL")
 593 #    MESSAGE(STATUS "Using external FFT library - Intel MKL")
 594     find_package(MKL REQUIRED)
 595     include_directories(${MKL_INCLUDE_DIR})
 596     set(FFT_LIBRARIES ${MKL_LIBRARIES})
 597     set(PKG_FFT_LIBS ${MKL_LIBRARIES})
 598
 599     set(GMX_FFT_MKL 1)
 600     set(HAVE_MKL 1)
 601
 602 #elseif(${GMX_FFT_LIBRARY} STREQUAL "ACML")
 603 #    MESSAGE(STATUS "Using external FFT library - AMD core math library")
 604 #    set(GMX_FFT_ACML 1)
 605 elseif(${GMX_FFT_LIBRARY} STREQUAL "FFTPACK")
 606     MESSAGE(STATUS "Using internal FFT library - fftpack")
 607     set(GMX_FFT_FFTPACK 1)
 608 else(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 609     MESSAGE(FATAL_ERROR "Invalid FFT library setting: ${GMX_FFT_LIBRARY}. Choose one of: fftw3, fftw2, mkl, acml, fftpack")
 610 endif(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 611
 612 # MKL has BLAS/LAPACK routines
 613 if(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 614   set(GMX_EXTERNAL_BLAS TRUE CACHE BOOL "Use external BLAS instead of built-in")
 615   set(GMX_EXTERNAL_LAPACK TRUE CACHE BOOL "Use external LAPACK instead of built-in")
 616 else(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 617   set(GMX_EXTERNAL_BLAS FALSE CACHE BOOL "Use external LAPACK instead of built-in")
 618   set(GMX_EXTERNAL_LAPACK FALSE CACHE BOOL "Use external LAPACK instead of built-in")
 619 endif(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 620
 621 # Math and thread libraries must often come after all others when linking...
 622 if(HAVE_LIBM)
 623     list(APPEND GMX_EXTRA_LIBRARIES m)
 624 endif(HAVE_LIBM)
 625
 626
 627
 628 if(GMX_FAHCORE)
 629   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 630       "Path to swindirect.h")
 631   include_directories(${COREWRAP_INCLUDE_DIR})
 632 endif(GMX_FAHCORE)
 633
 634 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 635 # these are set after everything else
 636 if (NOT DEFINED GROMACS_C_FLAGS_SET)
 637     set(GROMACS_C_FLAGS_SET true CACHE INTERNAL "Whether to reset the C flags"
 638         FORCE)
 639     set(CMAKE_C_FLAGS "${GROMACS_C_FLAGS} ${CMAKE_C_FLAGS}" CACHE STRING
 640         "Flags used by the compiler during all build types" FORCE)
 641     set(CMAKE_CXX_FLAGS "${GROMACS_CXX_FLAGS} ${CMAKE_CXX_FLAGS}" CACHE STRING
 642         "Flags used by the compiler during all build types" FORCE)
 643     set(CMAKE_EXE_LINKER_FLAGS
 644         "${GROMACS_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}"
 645         CACHE STRING "Linker flags" FORCE)
 646 endif (NOT DEFINED GROMACS_C_FLAGS_SET)
 647
 648 ########################################################################
 649 # Specify install locations and which subdirectories to process        #
 650 ########################################################################
 651 set(LIB_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/lib)
 652 set(BIN_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/bin)
 653 set(DATA_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/gromacs)
 654 set(MAN_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/share/man)
 655 set(INCL_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/include)
 656
 657 set(GMXLIBDIR        ${DATA_INSTALL_DIR}/top)
 658
 659 ##################################################################
 660 # Shared library settings - Darwin uses INSTALL_NAME_DIR instead!
 661 ##################################################################
 662 if(NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin")
 663     set(CMAKE_SKIP_BUILD_RPATH  FALSE)
 664     set(CMAKE_BUILD_WITH_INSTALL_RPATH TRUE)
 665     set(CMAKE_INSTALL_RPATH "${LIB_INSTALL_DIR}")
 666     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 667 endif()
 668
 669 add_subdirectory(share)
 670 add_subdirectory(include)
 671 add_subdirectory(man)
 672 add_subdirectory(src)
 673 add_subdirectory(scripts)
 674
 675 #######################
 676 ## uninstall target
 677 #######################
 678     CONFIGURE_FILE(
 679                    "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 680                    "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
 681                    IMMEDIATE @ONLY)
 682 ###########################
 683 ADD_CUSTOM_TARGET(uninstall
 684                   "${CMAKE_COMMAND}" -P
 685                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
 686 ###########################
 687
 688
 689 ########################################################################
 690 # Tests                                                                #
 691 ########################################################################
 692
 693 enable_testing()
 694 add_test(TestBuildAll make)
 695
 696 add_subdirectory(tests)