CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2009,2010,2011,2012,2013,2014, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 cmake_minimum_required(VERSION 2.8.8)
  36 # When we require cmake >= 2.8.12, it will provide
  37 # CMAKE_MINIMUM_REQUIRED_VERSION automatically, but in the meantime we
  38 # need to set a variable, and it must have a different name.
  39 set(GMX_CMAKE_MINIMUM_REQUIRED_VERSION "2.8.8")
  40
  41 # CMake modules/macros are in a subdirectory to keep this file cleaner
  42 # This needs to be set before project() in order to pick up toolchain files
  43 list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake ${CMAKE_CURRENT_SOURCE_DIR}/cmake/Platform)
  44
  45 project(Gromacs)
  46
  47 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  48 set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  49 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
  50
  51 # PROJECT_VERSION should have the following structure:
  52 # VERSION-dev[-SUFFIX] where the VERSION should have the for: vMajor.vMinor.vPatch
  53 #
  54 # The "-dev" suffix is important to keep because it makes possible to distinguish
  55 # between a build from official release and a build from git release branch on a
  56 # machine with no git.
  57 #
  58 # NOTE: when releasing the "-dev" suffix needs to be stripped off!
  59 # REGRESSIONTEST_VERSION and REGRESSIONTEST_BRANCH should always be
  60 # defined.
  61 set(PROJECT_VERSION "5.0.1-dev")
  62 # If this is a released tarball, "-dev" will not be present in
  63 # PROJECT_VERSION, and REGRESSIONTEST_VERSION specifies the version
  64 # number of the regressiontest tarball against which the code tarball
  65 # can be tested. This will be the version of the last patch release.
  66 set(REGRESSIONTEST_VERSION "5.0.1-dev")
  67 # The MD5 checksum of the regressiontest tarball. Only used if "-dev"
  68 # is not present in the PROJECT_VERSION
  69 set(REGRESSIONTEST_MD5SUM "a07524afebca5013540d4f2f72df2dce")
  70 # If this is not a released tarball, "-dev" will be present in
  71 # PROJECT_VERSION, and REGRESSIONTEST_BRANCH specifies the name of the
  72 # gerrit.gromacs.org branch whose HEAD can test this code, *if* this
  73 # code contains all recent fixes from the corresponding code branch.
  74 set(REGRESSIONTEST_BRANCH "refs/heads/release-5-0")
  75
  76 set(CUSTOM_VERSION_STRING ""
  77     CACHE STRING "Custom version string (if empty, use hard-coded default)")
  78 mark_as_advanced(CUSTOM_VERSION_STRING)
  79 if (CUSTOM_VERSION_STRING)
  80     set(PROJECT_VERSION ${CUSTOM_VERSION_STRING})
  81 endif()
  82 set(LIBRARY_SOVERSION 0)
  83 set(LIBRARY_VERSION ${LIBRARY_SOVERSION}.0.0)
  84 # It is a bit irritating, but this has to be set separately for now!
  85 SET(CPACK_PACKAGE_VERSION_MAJOR "5")
  86 SET(CPACK_PACKAGE_VERSION_MINOR "0")
  87 #SET(CPACK_PACKAGE_VERSION_PATCH "0")
  88
  89 # The numerical gromacs version. It is 40600 for 4.6.0.
  90 # The #define GMX_VERSION in gromacs/version.h is set to this value.
  91 math(EXPR NUM_VERSION
  92     "${CPACK_PACKAGE_VERSION_MAJOR}*10000 + ${CPACK_PACKAGE_VERSION_MINOR}*100")
  93 if(CPACK_PACKAGE_VERSION_PATCH)
  94     math(EXPR NUM_VERSION
  95          "${NUM_VERSION} + ${CPACK_PACKAGE_VERSION_PATCH}")
  96 endif()
  97
  98 # The API version tracks the numerical Gromacs version (for now).
  99 # It is potentially different from the Gromacs version in the future, if
 100 # the programs/libraries diverge from the presumably more stable API.
 101 # The #define GMX_API_VERSION in version.h is set to this value to
 102 # provide backward compatibility of software written against the Gromacs API.
 103 set(API_VERSION ${NUM_VERSION})
 104
 105 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT AND UNIX)
 106     set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
 107 endif()
 108
 109 include(gmxBuildTypeReference)
 110 include(gmxBuildTypeTSAN)
 111 include(gmxBuildTypeASAN)
 112 include(gmxBuildTypeReleaseWithAssert)
 113
 114 if(NOT CMAKE_BUILD_TYPE)
 115     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel Reference RelWithAssert." FORCE)
 116     # There's no need to offer a user the choice of ThreadSanitizer
 117     # Set the possible values of build type for cmake-gui
 118     set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "Debug" "Release"
 119         "MinSizeRel" "RelWithDebInfo" "Reference" "RelWithAssert")
 120 endif()
 121 if(CMAKE_CONFIGURATION_TYPES)
 122     # Add appropriate GROMACS-specific build types for the Visual
 123     # Studio generator (Debug, Release, MinSizeRel and RelWithDebInfo
 124     # are already present by default).
 125     list(APPEND CMAKE_CONFIGURATION_TYPES "RelWithAssert" "Reference")
 126     list(REMOVE_DUPLICATES CMAKE_CONFIGURATION_TYPES)
 127     set(CMAKE_CONFIGURATION_TYPES "${CMAKE_CONFIGURATION_TYPES}" CACHE STRING
 128         "List of configuration types"
 129         FORCE)
 130 endif()
 131 set(build_types_with_explicit_flags RELEASE DEBUG RELWITHDEBUGINFO RELWITHASSERT MINSIZEREL)
 132
 133 enable_language(C)
 134 enable_language(CXX)
 135
 136 set(CPACK_PACKAGE_NAME "gromacs")
 137 set(CPACK_PACKAGE_VERSION ${PROJECT_VERSION})
 138 set(CPACK_SOURCE_PACKAGE_FILE_NAME "${CPACK_PACKAGE_NAME}-${CPACK_PACKAGE_VERSION}")
 139 set(CPACK_PACKAGE_VENDOR "gromacs.org")
 140 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Gromacs - a toolkit for high-performance molecular simulation")
 141 set(CPACK_RESOURCE_FILE_WELCOME "${CMAKE_SOURCE_DIR}/admin/InstallWelcome.txt")
 142 # Its GPL/LGPL, so they do not have to agree to a license for mere usage, but some installers require this...
 143 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_SOURCE_DIR}/COPYING")
 144 set(CPACK_RESOURCE_FILE_README "${CMAKE_SOURCE_DIR}/admin/InstallInfo.txt")
 145 set(CPACK_SOURCE_IGNORE_FILES "\\\\.isreposource$;\\\\.git/;\\\\.gitignore$;\\\\.gitattributes;")
 146 set(CPACK_PROJECT_CONFIG_FILE "${CMAKE_SOURCE_DIR}/CPackInit.cmake")
 147 # CPack source archives include only the directories we list here.
 148 # This variable is a list of pairs of names of source and destination
 149 # directories. Most of these are used for content GROMACS generates as
 150 # part of the configuration or build.
 151 set(CPACK_SOURCE_INSTALLED_DIRECTORIES "${CMAKE_SOURCE_DIR};/;${CMAKE_BINARY_DIR}/src/programs/completion;src/programs/completion;${CMAKE_BINARY_DIR}/share/man/man1;share/man/man1;${CMAKE_BINARY_DIR}/share/man/man7;share/man/man7;${CMAKE_BINARY_DIR}/share/html/final;share/html/final;${CMAKE_BINARY_DIR}/install-guide/final;/")
 152 set(CPACK_PACKAGE_CONTACT "gmx-users@gromacs.org")
 153 set(CPACK_GMX_BUILD_HELP "${GMX_BUILD_HELP}") #Works even though GMX_BUILD_HELP is defined later because it is off by default.
 154
 155 #must come after all cpack settings!
 156 include(CPack)
 157
 158 # Set a default valgrind suppression file.
 159 # This unfortunately needs to duplicate information from CTest to work as
 160 # expected...
 161 set(MEMORYCHECK_SUPPRESSIONS_FILE
 162     "${CMAKE_SOURCE_DIR}/cmake/legacy_and_external.supp"
 163     CACHE FILEPATH
 164     "File that contains suppressions for the memory checker")
 165 include(CTest)
 166
 167 set(SOURCE_IS_GIT_REPOSITORY OFF)
 168 set(SOURCE_IS_SOURCE_DISTRIBUTION OFF)
 169 if(EXISTS "${CMAKE_SOURCE_DIR}/.git")
 170     set(SOURCE_IS_GIT_REPOSITORY ON)
 171 endif()
 172 if(NOT EXISTS "${CMAKE_SOURCE_DIR}/admin/.isreposource")
 173     set(SOURCE_IS_SOURCE_DISTRIBUTION ON)
 174 endif()
 175
 176 ########################################################################
 177 # Check and warn if cache generated on a different host is being reused
 178 ########################################################################
 179 if(CMAKE_HOST_UNIX)
 180     execute_process(COMMAND hostname
 181                     OUTPUT_VARIABLE TMP_HOSTNAME
 182                     OUTPUT_STRIP_TRAILING_WHITESPACE)
 183     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}")
 184         message(WARNING "
 185             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
 186             is being reused! This could lead to inconsitencies; therefore, it is
 187             recommended to regenerate the cache!")
 188     endif()
 189     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
 190             "Hostname of the machine where the cache was generated.")
 191 endif()
 192
 193 ########################################################################
 194 # User input options                                                   #
 195 ########################################################################
 196 include(gmxOptionUtilities)
 197
 198 set(CMAKE_PREFIX_PATH "" CACHE STRING "Extra locations to search for external libraries and tools (give directory without lib, bin, or include)")
 199
 200 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" OFF)
 201 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 202 option(GMX_THREAD_MPI  "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" ON)
 203 gmx_dependent_option(
 204     GMX_MPI_IN_PLACE
 205     "Enable MPI_IN_PLACE for MPIs that have it defined"
 206     ON
 207     GMX_MPI)
 208 mark_as_advanced(GMX_MPI_IN_PLACE)
 209 option(GMX_SOFTWARE_INVSQRT "Use GROMACS software 1/sqrt" ON)
 210 mark_as_advanced(GMX_SOFTWARE_INVSQRT)
 211 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 212 mark_as_advanced(GMX_FAHCORE)
 213
 214 option(GMX_COOL_QUOTES "Enable Gromacs cool quotes" ON)
 215 mark_as_advanced(GMX_COOL_QUOTES)
 216 gmx_add_cache_dependency(GMX_COOL_QUOTES BOOL "NOT GMX_FAHCORE" OFF)
 217
 218 # Decide on GPU settings based on user-settings and GPU/CUDA detection.
 219 # We support CUDA >=v4.0 on *nix, but <= v4.1 doesn't work with MSVC
 220 if(MSVC)
 221     set(REQUIRED_CUDA_VERSION 4.1)
 222 else()
 223     set(REQUIRED_CUDA_VERSION 4.0)
 224 endif()
 225 set(REQUIRED_CUDA_COMPUTE_CAPABILITY 2.0)
 226 include(gmxManageGPU)
 227
 228 # Detect the architecture the compiler is targetting, detect
 229 # SIMD instructions possibilities on that hardware, suggest SIMD instruction set
 230 # to use if none is specified, and populate the cache option for CPU
 231 # SIMD.
 232 include(gmxDetectTargetArchitecture)
 233 gmx_detect_target_architecture()
 234
 235 if(GMX_CPU_ACCELERATION)
 236     # Stay compatible with old Jenkins command line options for specific SIMD acceleration
 237     set(GMX_SIMD "${GMX_CPU_ACCELERATION}" CACHE STRING "SIMD instruction set level and compiler optimization" FORCE)
 238     message("You set GMX_CPU_ACCELERATION, which is deprecated, and will be removed in a later version of GROMACS. It is replaced by GMX_SIMD. For now, copying the value from GMX_CPU_ACCELERATION to GMX_SIMD.")
 239     # TODO remove all references to GMX_CPU_ACCELERATION in master branch
 240 endif()
 241
 242 if(NOT GMX_TARGET_MIC)
 243     include(gmxDetectSimd)
 244     gmx_detect_simd(GMX_SUGGESTED_SIMD)
 245 else()
 246     set(GMX_SUGGESTED_SIMD "None")
 247 endif()
 248
 249 gmx_option_multichoice(
 250     GMX_SIMD
 251     "SIMD instruction set for CPU kernels and compiler optimization"
 252     "${GMX_SUGGESTED_SIMD}"
 253     None SSE2 SSE4.1 AVX_128_FMA AVX_256 AVX2_256 IBM_QPX Sparc64_HPC_ACE Reference)
 254
 255 gmx_option_multichoice(
 256     GMX_FFT_LIBRARY
 257     "FFT library"
 258     "fftw3"
 259     fftw3 mkl "fftpack[built-in]")
 260 gmx_dependent_option(
 261     GMX_BUILD_OWN_FFTW
 262     "Download and build FFTW 3 during the GROMACS build process, rather than fall back on the really slow fftpack."
 263     OFF
 264     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 265 gmx_dependent_option(
 266     GMX_DISABLE_FFTW_MEASURE
 267     "Do not optimize FFTW setups (not needed with SSE)"
 268     OFF
 269     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 270 mark_as_advanced(GMX_BUILD_OWN_FFTW)
 271 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 272
 273 gmx_option_multichoice(
 274     GMX_QMMM_PROGRAM
 275     "QM package for QM/MM"
 276     None
 277     none gaussian mopac gamess orca)
 278
 279 gmx_dependent_cache_variable(GMX_SIMD_REF_FLOAT_WIDTH  "Reference SIMD single precision width" STRING "4" "GMX_SIMD STREQUAL REFERENCE")
 280 gmx_dependent_cache_variable(GMX_SIMD_REF_DOUBLE_WIDTH "Reference SIMD double precision width" STRING "2" "GMX_SIMD STREQUAL REFERENCE")
 281
 282 # This should be moved to a separate NBNXN cmake module when that code is cleaned up and modularized
 283
 284 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 285 mark_as_advanced(GMX_BROKEN_CALLOC)
 286 option(GMX_LOAD_PLUGINS "Compile with plugin support, needed to read VMD supported file formats" ON)
 287 mark_as_advanced(GMX_LOAD_PLUGINS)
 288
 289 option(GMX_GPU  "Enable GPU acceleration" ON)
 290 option(GMX_OPENMP "Enable OpenMP-based multithreading" ON)
 291
 292 option(GMX_USE_TNG "Use the TNG library for trajectory I/O" ON)
 293
 294 option(GMX_GIT_VERSION_INFO "Generate git version information" ${SOURCE_IS_GIT_REPOSITORY})
 295 mark_as_advanced(GMX_GIT_VERSION_INFO)
 296
 297 if(UNIX)
 298     option(GMX_SYMLINK_OLD_BINARY_NAMES "Create symbolic links for pre-5.0 binary names" ON)
 299 endif()
 300 option(GMX_BUILD_MDRUN_ONLY "Build and install only the mdrun binary" OFF)
 301
 302 option(GMX_CYCLE_SUBCOUNTERS "Enable cycle subcounters to get a more detailed cycle timings" OFF)
 303 mark_as_advanced(GMX_CYCLE_SUBCOUNTERS)
 304
 305 option(GMX_SKIP_DEFAULT_CFLAGS "Don't automatically add suggested/required Compiler flags." OFF)
 306 mark_as_advanced(GMX_SKIP_DEFAULT_CFLAGS)
 307
 308 option(GMX_BUILD_FOR_COVERAGE
 309        "Tune build for better code coverage metrics (e.g., disable asserts)"
 310        OFF)
 311 mark_as_advanced(GMX_BUILD_FOR_COVERAGE)
 312
 313 option(GMX_DEVELOPER_BUILD
 314     "Enable Developer convenience features: always build unit-tests"
 315     OFF)
 316 mark_as_advanced(GMX_DEVELOPER_BUILD)
 317
 318 ######################################################################
 319 # Detect OpenMP support
 320 ######################################################################
 321 # The OpenMP detection _must_ come before tests for other CFLAGS.
 322 include(gmxManageOpenMP)
 323
 324
 325
 326 ######################################################################
 327 # Compiler tests
 328 # These need to be done early (before further tests).
 329 #####################################################################
 330
 331 # The cmake/Check{C,CXX}CompilerFlag.cmake files in the GROMACS distribution
 332 # are used with permission from CMake v3.0.0 so that GROMACS can detect
 333 # invalid options with the Intel Compilers, and we have added a line
 334 # to detect warnings with the Fujitsu compilers on K computer and ICC.
 335 # CMake-3.0 also has a bug where the FAIL_REGEX pattern for AIX contains
 336 # a semicolon. Since this is also used as a separator in lists inside CMake,
 337 # that string ends up being split into two separate patterns, and the last
 338 # part is just a single word that also matches other messages. We solved this
 339 # by replacing the semicolon with a period that matches any character.
 340 #
 341 # These files should be removed from the source tree when a CMake version that
 342 # includes the features in question becomes required for building GROMACS.
 343 include(CheckCCompilerFlag)
 344 include(CheckCXXCompilerFlag)
 345
 346 include(gmxCFlags)
 347 gmx_c_flags()
 348
 349 # This variable should be used for additional compiler flags which are not
 350 # generated in gmxCFlags nor are SIMD or MPI related.
 351 set(EXTRA_C_FLAGS "")
 352 set(EXTRA_CXX_FLAGS "")
 353
 354 # Run through a number of tests for buggy compilers and other issues
 355 include(gmxTestCompilerProblems)
 356 gmx_test_compiler_problems()
 357 # GMX_SIMD will not be set automatically until the second
 358 # pass (which is not strictly guaranteed to occur), so putting this
 359 # check here among logically-related tests is inefficient, but the
 360 # potential loss is likely zero.
 361 if(GMX_SIMD STREQUAL "AVX_256"
 362         AND CMAKE_COMPILER_IS_GNUCC
 363         AND (C_COMPILER_VERSION VERSION_EQUAL "4.6.1"
 364             OR CXX_COMPILER_VERSION VERSION_EQUAL "4.6.1"))
 365     message(FATAL_ERROR "gcc 4.6.1 has buggy support for AVX, and GROMACS mdrun will not work. If you want simulation performance, use a more recent compiler. Otherwise, use GMX_SIMD=SSE4.1")
 366     # See http://gcc.gnu.org/bugzilla/show_bug.cgi?id=49002
 367 endif()
 368
 369
 370
 371 set(PKG_CFLAGS "")
 372 if(GMX_DOUBLE)
 373     add_definitions(-DGMX_DOUBLE)
 374     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_DOUBLE")
 375 endif()
 376 if(GMX_SOFTWARE_INVSQRT)
 377   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_SOFTWARE_INVSQRT")
 378 endif()
 379
 380 if(WIN32 AND NOT CYGWIN)
 381     set(GMX_WSOCKLIB_PATH CACHE PATH "Path to winsock (wsock32.lib) library.")
 382     mark_as_advanced(GMX_WSOCKLIB_PATH)
 383     find_library(WSOCK32_LIBRARY NAMES wsock32 PATHS ${GMX_WSOCKLIB_PATH})
 384     if(WSOCK32_LIBRARY)
 385         list(APPEND GMX_EXTRA_LIBRARIES ${WSOCK32_LIBRARY})
 386         add_definitions(-DGMX_HAVE_WINSOCK)
 387     else()
 388         message(STATUS "No winsock found. Cannot use interactive molecular dynamics (IMD).")
 389     endif(WSOCK32_LIBRARY)
 390 endif()
 391
 392
 393
 394 ########################################################################
 395 # Basic system tests (standard libraries, headers, functions, types)   #
 396 ########################################################################
 397 include(CheckIncludeFiles)
 398 include(CheckIncludeFileCXX)
 399 check_include_files(unistd.h     HAVE_UNISTD_H)
 400 check_include_files(pwd.h        HAVE_PWD_H)
 401 check_include_files(dirent.h     HAVE_DIRENT_H)
 402 check_include_files(time.h       HAVE_TIME_H)
 403 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 404 check_include_files(io.h         HAVE_IO_H)
 405 check_include_files(sched.h      HAVE_SCHED_H)
 406
 407 check_include_files(regex.h      HAVE_POSIX_REGEX)
 408 check_include_file_cxx(regex     HAVE_CXX11_REGEX)
 409 # TODO: It could be nice to inform the user if no regex support is found,
 410 # as selections won't be fully functional.
 411
 412 include(CheckFunctionExists)
 413 check_function_exists(posix_memalign    HAVE_POSIX_MEMALIGN)
 414 check_function_exists(memalign          HAVE_MEMALIGN)
 415 check_function_exists(_aligned_malloc   HAVE__ALIGNED_MALLOC)
 416 check_function_exists(gettimeofday      HAVE_GETTIMEOFDAY)
 417 check_function_exists(fsync             HAVE_FSYNC)
 418 check_function_exists(_fileno           HAVE__FILENO)
 419 check_function_exists(fileno            HAVE_FILENO)
 420 check_function_exists(_commit           HAVE__COMMIT)
 421 check_function_exists(sigaction         HAVE_SIGACTION)
 422 check_function_exists(sysconf           HAVE_SYSCONF)
 423 check_function_exists(rsqrt             HAVE_RSQRT)
 424 check_function_exists(rsqrtf            HAVE_RSQRTF)
 425 check_function_exists(sqrtf             HAVE_SQRTF)
 426
 427 include(CheckLibraryExists)
 428 check_library_exists(m sqrt "" HAVE_LIBM)
 429 check_library_exists(rt clock_gettime "" HAVE_CLOCK_GETTIME)
 430
 431 include(TestSchedAffinity)
 432 test_sched_affinity(HAVE_SCHED_AFFINITY)
 433
 434 include(TestBigEndian)
 435 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 436
 437 # Management of GROMACS options for specific toolchains should go
 438 # here. Because the initial settings for some of the main options have
 439 # already happened, but things like library detection and MPI compiler
 440 # feature detection have not, the docstrings for any over-rides of
 441 # GROMACS defaults or user settings will make sense. Also, any
 442 # toolchain-related reasons for choosing whether to detect various
 443 # things can be sorted out now, before the detection takes place.
 444 if(${CMAKE_SYSTEM_NAME} MATCHES BlueGene)
 445     include(gmxManageBlueGene)
 446 endif()
 447
 448 ########################################################################
 449 #Process MPI settings
 450 ########################################################################
 451 include(gmxManageMPI)
 452
 453
 454 ########################################################################
 455 #Process shared/static library settings
 456 ########################################################################
 457 include(gmxManageSharedLibraries)
 458
 459
 460 ########################################################################
 461 # Find external packages                                               #
 462 ########################################################################
 463
 464 # Unconditionally find the package, as it is also required for unit
 465 # tests. This exports LIBXML2_FOUND, which we should not use because
 466 # it does not tell us that linking will succeed. Instead, we test that
 467 # next.
 468 if(DEFINED LIBXML2_LIBRARIES)
 469   set(LibXml2_FIND_QUIETLY TRUE)
 470 endif()
 471 find_package(LibXml2)
 472 include(gmxTestLibXml2)
 473 gmx_test_libxml2(HAVE_LIBXML2)
 474 option(GMX_XML "Use libxml2 to parse xml files (currently has no effect)" ${HAVE_LIBXML2})
 475 set(PKG_XML "")
 476 mark_as_advanced(GMX_XML)
 477 # Don't actually do anything, since libxml2 is currently not used by libgromacs
 478 #if(GMX_XML AND NOT HAVE_LIBXML2)
 479 #    message(FATAL_ERROR "libxml2 not found. Set GMX_XML=OFF to compile without XML support")
 480 #endif()
 481 #if(GMX_XML)
 482 #    include_directories(${LIBXML2_INCLUDE_DIR})
 483 #    set(PKG_XML libxml-2.0)
 484 #    set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 485 #endif()
 486
 487 option(GMX_EXTRAE "Add support for tracing using EXTRAE" OFF)
 488 mark_as_advanced(GMX_EXTRAE)
 489
 490 if (GMX_EXTRAE)
 491   find_package(EXTRAE)
 492   if(EXTRAE_FOUND)
 493     include_directories(${EXTRAE_INCLUDE_DIR})
 494     set(HAVE_EXTRAE 1)
 495   else()
 496     message(FATAL_ERROR "EXTRAE library was not found. Please add the correct path to CMAKE_PREFIX_PATH")
 497   endif()
 498 endif()
 499
 500 option(GMX_X11 "Use X window system" OFF)
 501 if (GMX_X11)
 502     find_package(X11)
 503     # X11 includes/libraries are only set in the ngmx subdirectory!
 504     if(NOT X11_FOUND)
 505         message(FATAL_ERROR
 506                 "X11 include files and/or libraries were not found. "
 507                 "Set GMX_X11=OFF to compile without X11 support. "
 508                 "gmx view will not be available.")
 509     endif()
 510     include_directories(${X11_INCLUDE_DIR})
 511 endif()
 512
 513 include(ThreadMPI)
 514 # Enable core threading facilities
 515 tmpi_enable_core("${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include")
 516 # Enable tMPI C++ support
 517 tmpi_enable_cxx()
 518 if(GMX_THREAD_MPI)
 519     # enable MPI functions
 520     tmpi_enable()
 521     set(GMX_MPI 1)
 522     set(MPI_IN_PLACE_EXISTS 1)
 523 endif()
 524 # If atomics are manually disabled a define is needed because atomics.h doesn't depend on config.h
 525 if (TMPI_ATOMICS_DISABLED)
 526    add_definitions(-DTMPI_ATOMICS_DISABLED)
 527 endif()
 528
 529 if(GMX_GPU)
 530     # now that we have detected the dependencies, do the second configure pass
 531     gmx_gpu_setup()
 532 endif()
 533
 534 if(CYGWIN)
 535     set(GMX_CYGWIN 1)
 536 endif()
 537
 538 if(WIN32 AND NOT CYGWIN)
 539     set(GMX_NATIVE_WINDOWS 1)
 540     # This makes windows.h not declare min/max as macros that would break
 541     # C++ code using std::min/std::max.
 542     add_definitions(-DNOMINMAX)
 543 endif()
 544
 545 # only bother with finding git and using version.h if the source is a git repo
 546 if(GMX_GIT_VERSION_INFO)
 547     if (NOT SOURCE_IS_GIT_REPOSITORY)
 548         message(FATAL_ERROR
 549             "Cannot generate git version information from source tree not under git. "
 550             "Set GMX_GIT_VERSION_INFO=OFF to proceed.")
 551     endif()
 552     # We need at least git v1.5.3 be able to parse git's date output. If not
 553     # found or the version is too small, we can't generate version information.
 554     find_package(Git)
 555
 556     if(NOT GIT_FOUND OR GIT_VERSION_STRING VERSION_LESS "1.5.3")
 557         message(FATAL_ERROR
 558             "No compatible git version found (>= 1.5.3 required). "
 559             "Won't be able to generate development version information. "
 560             "Set GMX_GIT_VERSION_INFO=OFF to proceed.")
 561     endif()
 562 endif()
 563
 564 # Detect boost unless GMX_EXTERNAL_BOOST is explicitly OFF
 565 # Used for default if GMX_EXTERNAL_BOOST is not defined (first CMake pass)
 566 if(NOT DEFINED GMX_EXTERNAL_BOOST OR GMX_EXTERNAL_BOOST)
 567     find_package(Boost 1.44.0)
 568     if(Boost_FOUND AND Boost_VERSION VERSION_LESS "104400")
 569         set(Boost_FOUND FALSE)
 570     endif()
 571     # Print the notification only on first run, when determining the default
 572     if(NOT DEFINED GMX_EXTERNAL_BOOST AND NOT Boost_FOUND)
 573         message("Boost >= 1.44 not found. Using minimal internal version. "
 574                 "This may cause trouble if you plan on compiling/linking other "
 575                 "software that uses Boost against Gromacs.")
 576     endif()
 577 endif()
 578 option(GMX_EXTERNAL_BOOST "Use external Boost instead of minimal built-in version"
 579        ${Boost_FOUND})
 580 if(GMX_EXTERNAL_BOOST AND NOT Boost_FOUND)
 581     message(FATAL_ERROR
 582         "Boost >= 1.44 not found. "
 583         "You can set GMX_EXTERNAL_BOOST=OFF to compile against minimal "
 584         "version of Boost included with Gromacs.")
 585 endif()
 586
 587 if(NOT DEFINED GMX_BUILD_UNITTESTS AND NOT HAVE_LIBXML2)
 588     message(WARNING "libxml2 not found. Will build GROMACS without unit-tests. This is not recommended, because the unit-tests help to verify that GROMACS functions correctly. Most likely you are missing the libxml2-dev(el) package. After you installed it, set GMX_BUILD_UNITTESTS=ON.")
 589 endif()
 590 option(GMX_BUILD_UNITTESTS "Build unit tests with BUILD_TESTING (uses Google C++ Testing and Mocking Frameworks, requires libxml2)" ${HAVE_LIBXML2})
 591 mark_as_advanced(GMX_BUILD_UNITTESTS)
 592 gmx_add_cache_dependency(GMX_BUILD_UNITTESTS BOOL BUILD_TESTING OFF)
 593 if (GMX_BUILD_UNITTESTS AND NOT HAVE_LIBXML2)
 594     message(FATAL_ERROR
 595         "Cannot build unit tests without libxml2. "
 596         "Either set GMX_BUILD_UNITTESTS=OFF or tell CMake how to find a working version of libxml2.")
 597 endif()
 598
 599 ########################################################################
 600 # Generate development version info for cache
 601 ########################################################################
 602 # set(GEN_VERSION_INFO_INTERNAL "ON")
 603 # include(gmxGenerateVersionString)
 604
 605 ########################################################################
 606 # Our own GROMACS tests
 607 ########################################################################
 608
 609 add_definitions( -DHAVE_CONFIG_H )
 610 include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src)
 611 include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include)
 612 # Required for config.h, maybe should only be set in src/CMakeLists.txt
 613 include_directories(BEFORE ${CMAKE_BINARY_DIR}/src)
 614 # Required for gmx_header_config_gen.h to be found before installation
 615 include_directories(BEFORE ${CMAKE_BINARY_DIR}/src/gromacs/utility)
 616 # Required for now to make old code compile
 617 include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src/gromacs/legacyheaders)
 618
 619 include(gmxTestInlineASM)
 620 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 621
 622 include(gmxSetBuildInformation)
 623 gmx_set_build_information()
 624 # Turn on RDTSCP if:
 625 # - the build system's CPU supports it
 626 # - the acceleration is set to AVX as all AVX-capable CPUs support AVX (which
 627 #   at this point means that the user set it).
 628 # Note: it's better to not use the later set value of GMX_SIMD because
 629 # it reflects the system's capability of both compiling and running AVX code.
 630 # TODO: After merge with 5.0 one could implement a cache variable dependency
 631 # such that GMX_USE_RDTSCP can change if GMX_SIMD is changed to AVX
 632 # after the first cmake pass.
 633 if (BUILD_CPU_FEATURES MATCHES "rdtscp" OR GMX_SIMD MATCHES "AVX")
 634     set(GMX_USE_RDTSCP_DEFAULT_VALUE ON)
 635 else()
 636     set(GMX_USE_RDTSCP_DEFAULT_VALUE OFF)
 637 endif()
 638 option(GMX_USE_RDTSCP "Use RDTSCP for better CPU-based timers (available on recent x86 CPUs; might need to be off when compiling for heterogeneous environments)" ${GMX_USE_RDTSCP_DEFAULT_VALUE})
 639 mark_as_advanced(GMX_USE_RDTSCP)
 640 if(GMX_USE_RDTSCP)
 641     set(HAVE_RDTSCP 1)
 642 endif()
 643
 644 include(gmxTestFloatFormat)
 645 gmx_test_float_format(GMX_FLOAT_FORMAT_IEEE754
 646                       GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER
 647                       GMX_IEEE754_BIG_ENDIAN_WORD_ORDER)
 648
 649 include(gmxTestLargeFiles)
 650 gmx_test_large_files(GMX_LARGEFILES)
 651
 652 include(gmxTestSignal)
 653 gmx_test_sigusr1(HAVE_SIGUSR1)
 654
 655 include(gmxTestPipes)
 656 gmx_test_pipes(HAVE_PIPES)
 657
 658 include(gmxTestIsfinite)
 659 gmx_test_isfinite(HAVE_ISFINITE)
 660 gmx_test__isfinite(HAVE__ISFINITE)
 661 gmx_test__finite(HAVE__FINITE)
 662
 663 include(gmxTestCXX11)
 664 gmx_test_cxx11(GMX_CXX11_SUPPORTED GMX_CXX11_FLAGS)
 665 include(CMakeDependentOption)
 666 # nvcc does not support C++11 flags, so with GPUs we prefer to skip C++11 flags
 667 # entirely to keep the compilation environment uniform.
 668 cmake_dependent_option(GMX_CXX11
 669     "Use C++11 features"
 670     ON "GMX_CXX11_SUPPORTED AND NOT GMX_GPU" OFF)
 671 mark_as_advanced(GMX_CXX11)
 672 if(GMX_CXX11)
 673     set(EXTRA_CXX_FLAGS "${EXTRA_CXX_FLAGS} ${GMX_CXX11_FLAGS}")
 674 endif()
 675
 676
 677 include(gmxTestXDR)
 678 gmx_test_xdr(GMX_SYSTEM_XDR)
 679 if(NOT GMX_SYSTEM_XDR)
 680     set(GMX_INTERNAL_XDR 1)
 681 endif()
 682
 683
 684 ##################################################
 685 # Process SIMD instruction settings
 686 ##################################################
 687 # This checks what flags to add in order to
 688 # support the SIMD instructions we need, and sets
 689 # correct defines for the SIMD instructions supported.
 690 include(gmxTestSimd)
 691 gmx_test_simd()
 692
 693
 694 # Process QM/MM Settings
 695 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 696     set(GMX_QMMM_GAUSSIAN 1)
 697 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 698     set(GMX_QMMM_MOPAC 1)
 699 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 700     set(GMX_QMMM_GAMESS 1)
 701 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 702     set(GMX_QMMM_ORCA 1)
 703 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 704     # nothing to do
 705 else()
 706     gmx_invalid_option_value(GMX_QMMM_PROGRAM)
 707 endif()
 708
 709
 710 ##################################################
 711 # Process FFT library settings
 712 ##################################################
 713 include(gmxManageFFTLibraries)
 714
 715
 716 include(gmxManageLinearAlgebraLibraries)
 717
 718 # Whether GROMACS will really try to compile support for VMD plugins
 719 set(GMX_USE_PLUGINS OFF)
 720
 721 if(GMX_LOAD_PLUGINS)
 722   if(CYGWIN OR NOT WIN32)
 723     # Native Windows does not have, nor need dlopen
 724     # Note that WIN32 is set with Cygwin, but Cygwin needs dlopen to use plug-ins
 725     include(gmxTestdlopen)
 726     gmx_test_dlopen(HAVE_DLOPEN)
 727   endif()
 728
 729   # so, should we use plug-ins?
 730   if((WIN32 AND NOT CYGWIN) OR (HAVE_DLOPEN AND BUILD_SHARED_LIBS))
 731     if(NOT VMD_QUIETLY)
 732       MESSAGE(STATUS "Using dynamic plugins (e.g VMD-supported file formats)")
 733     endif()
 734     if(NOT GMX_VMD_PLUGIN_PATH)
 735       find_package(VMD)
 736     endif()
 737     set(GMX_USE_PLUGINS ON)
 738     list(APPEND GMX_EXTRA_LIBRARIES ${CMAKE_DL_LIBS}) # magic cross-platform pre-set variable for dlopen library
 739     set(PKG_DL_LIBS "-l${CMAKE_DL_LIBS}")
 740   else()
 741     set(PKG_DL_LIBS)
 742   endif()
 743 endif()
 744 set(VMD_QUIETLY TRUE CACHE INTERNAL "")
 745
 746 # Link real-time library for POSIX timers. The check for clock_gettime
 747 # confirms the linkability of rt.
 748 if(HAVE_TIME_H AND HAVE_UNISTD_H AND HAVE_CLOCK_GETTIME)
 749     list(APPEND GMX_EXTRA_LIBRARIES rt)
 750 endif()
 751
 752 # Math and thread libraries must often come after all others when linking...
 753 if(HAVE_LIBM)
 754     list(APPEND GMX_EXTRA_LIBRARIES m)
 755 endif()
 756
 757 option(GMX_NACL "Configure for Native Client builds" OFF)
 758 if (GMX_NACL)
 759   list(APPEND GMX_EXTRA_LIBRARIES nosys)
 760   set(GMX_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -lnosys")
 761   set(GMX_NO_NICE 1)
 762   set(GMX_NO_RENAME 1)
 763 endif()
 764 mark_as_advanced(GMX_NACL)
 765
 766 if(GMX_FAHCORE)
 767   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 768       "Path to swindirect.h")
 769   include_directories(${COREWRAP_INCLUDE_DIR})
 770 endif()
 771
 772 option(GMX_BUILD_HELP "Build man pages, HTML help, and completions automatically (requires that compiled binaries can be executed on the build host)" OFF)
 773 mark_as_advanced(GMX_BUILD_HELP)
 774 if (GMX_BUILD_HELP AND SOURCE_IS_SOURCE_DISTRIBUTION AND
 775     "${CMAKE_CURRENT_SOURCE_DIR}" STREQUAL "${CMAKE_CURRENT_BINARY_DIR}")
 776
 777     message(FATAL_ERROR
 778         "Rebuilding HTML and man pages is not supported for in-source "
 779         "builds from a source distribution. "
 780         "Set GMX_BUILD_HELP=OFF or do an out-of-source build to proceed.")
 781 endif()
 782
 783 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 784 # these are set after everything else
 785 if (NOT GMX_SKIP_DEFAULT_CFLAGS)
 786     set(CMAKE_C_FLAGS "${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${CMAKE_C_FLAGS}")
 787     set(CMAKE_CXX_FLAGS "${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${CMAKE_CXX_FLAGS}")
 788     set(CMAKE_EXE_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}")
 789     set(CMAKE_SHARED_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS}")
 790 else()
 791     message("Recommended flags which are not added because GMX_SKIP_DEFAULT_CFLAGS=yes:")
 792     message("CMAKE_C_FLAGS: ${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${GMXC_CFLAGS}")
 793     message("CMAKE_C_FLAGS_RELEASE: ${GMXC_CFLAGS_RELEASE}")
 794     message("CMAKE_C_FLAGS_DEBUG: ${GMXC_CFLAGS_DEBUG}")
 795     message("CMAKE_CXX_FLAGS: ${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${GMXC_CXXFLAGS}")
 796     message("CMAKE_CXX_FLAGS_RELEASE: ${GMXC_CXXFLAGS_RELEASE}")
 797     message("CMAKE_CXX_FLAGS_DEBUG: ${GMXC_CXXFLAGS_DEBUG}")
 798     message("CMAKE_EXE_LINKER_FLAGS: ${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS}")
 799     message("CMAKE_SHARED_LINKER_FLAGS: ${MPI_LINKER_FLAGS}")
 800 endif()
 801
 802 if(NOT GMX_OPENMP)
 803     #Unset all OpenMP flags in case OpenMP was disabled either by the user
 804     #or because it was only partially detected (e.g. only for C but not C++ compiler)
 805     unset(OpenMP_C_FLAGS CACHE)
 806     unset(OpenMP_CXX_FLAGS CACHE)
 807 else()
 808     set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} ${OpenMP_LINKER_FLAGS})
 809     set(GMX_SHARED_LINKER_FLAGS ${GMX_SHARED_LINKER_FLAGS} ${OpenMP_SHARED_LINKER_FLAGS})
 810 endif()
 811 set(PKG_CFLAGS "${PKG_CFLAGS} ${OpenMP_C_FLAGS}")
 812
 813 ########################################################################
 814 # Specify install locations
 815 ########################################################################
 816 # Use GNUInstallDirs to set paths on multiarch systems.
 817 include(GNUInstallDirs)
 818
 819 # Customization for the installation tree paths.
 820 set(GMX_LIB_INSTALL_DIR ${CMAKE_INSTALL_LIBDIR} CACHE STRING
 821     "Library installation directory (default: ${CMAKE_INSTALL_LIBDIR})")
 822 set(GMX_DATA_INSTALL_DIR gromacs CACHE STRING
 823     "Data installation directory under share/ (default: gromacs)")
 824 mark_as_advanced(GMX_LIB_INSTALL_DIR GMX_DATA_INSTALL_DIR)
 825
 826 # These variables are used internally to provide a central location for
 827 # customizing the install locations.
 828 set(LIB_INSTALL_DIR  ${GMX_LIB_INSTALL_DIR})
 829 set(BIN_INSTALL_DIR  bin)
 830 set(DATA_INSTALL_DIR share/${GMX_DATA_INSTALL_DIR})
 831 set(MAN_INSTALL_DIR  share/man)
 832 set(INCL_INSTALL_DIR include)
 833
 834 # These variables get written into config.h for use in finding the data
 835 # directories.
 836 set(GMXLIB_SEARCH_DIR share/${GMX_DATA_INSTALL_DIR}/top)
 837 set(GMXLIB_FALLBACK   ${CMAKE_INSTALL_PREFIX}/${DATA_INSTALL_DIR}/top)
 838
 839 # Binary and library suffix options
 840 include(gmxManageSuffixes)
 841
 842 ################################################################
 843 # Shared library load path settings
 844 ################################################################
 845 # CMake supports RPATH on OS X only from 2.8.12 upwards.
 846 # CMAKE_SYSTEM_VERSION > 8.0 matches OS X 10.5 and above, where RPATH support
 847 # was added.
 848 if((NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin") OR
 849    ((CMAKE_SYSTEM_VERSION VERSION_GREATER 8.0) AND (NOT CMAKE_VERSION VERSION_LESS 2.8.12)))
 850     # The build folder always has bin/ and lib/; if we are also going to
 851     # install to lib/, then the installation RPATH works also in the build
 852     # tree.  This makes installation slightly faster (no need to rewrite the
 853     # RPATHs), and makes the binaries in the build tree relocatable.
 854     if(GMX_LIB_INSTALL_DIR STREQUAL "lib")
 855         set(CMAKE_BUILD_WITH_INSTALL_RPATH TRUE)
 856     endif()
 857     # Set the RPATH as relative to the executable location to make the
 858     # binaries relocatable.
 859     if(NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin")
 860         set(CMAKE_INSTALL_RPATH "\$ORIGIN/../${GMX_LIB_INSTALL_DIR}")
 861     else()
 862         set(CMAKE_INSTALL_RPATH "@executable_path/../${GMX_LIB_INSTALL_DIR}")
 863     endif()
 864     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 865     set(CMAKE_MACOSX_RPATH 1)
 866 else()
 867     # We are on Darwin/OSX, and CMake cannot handle RPATHs automatically.
 868     if(CMAKE_SYSTEM_VERSION VERSION_GREATER 8.0)
 869         # Set the RPATH options manually.
 870         set(CMAKE_INSTALL_NAME_DIR "@rpath")
 871         set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} "-Wl,-rpath,@executable_path/../${GMX_LIB_INSTALL_DIR}")
 872     else()
 873         # Use the old INSTALL_NAME_DIR mechanism if RPATH is not supported.
 874         set(CMAKE_INSTALL_NAME_DIR "${CMAKE_INSTALL_PREFIX}/${LIB_INSTALL_DIR}")
 875     endif()
 876 endif()
 877
 878 #COPYING file: Only necessary for binary distributions.
 879 #Simpler to always install.
 880 install(FILES COPYING DESTINATION ${DATA_INSTALL_DIR} COMPONENT data)
 881
 882 if(GMX_EXTERNAL_BOOST)
 883     include_directories(${Boost_INCLUDE_DIRS})
 884     set(PKG_CFLAGS "${PKG_CFLAGS} -I${Boost_INCLUDE_DIRS}")
 885 else()
 886     include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src/external/boost)
 887     # typeid not supported for minimal internal version
 888     # (would add significant amount of code)
 889     add_definitions(-DBOOST_NO_TYPEID)
 890     # TODO: Propagate the above settings to the installed CMakeFiles.txt template
 891     # (from share/template/)
 892     set(PKG_CFLAGS "${PKG_CFLAGS} -DBOOST_NO_TYPEID -I${CMAKE_INSTALL_PREFIX}/${INCL_INSTALL_DIR}/gromacs/external/boost")
 893     if (NOT GMX_BUILD_MDRUN_ONLY)
 894         install(DIRECTORY ${CMAKE_SOURCE_DIR}/src/external/boost/boost
 895                 DESTINATION ${INCL_INSTALL_DIR}/gromacs/external/boost
 896                 COMPONENT development)
 897     endif()
 898 endif()
 899
 900 if (GMX_BUILD_FOR_COVERAGE)
 901     # Code heavy with asserts makes conditional coverage close to useless metric,
 902     # as by design most of the false branches are impossible to trigger in
 903     # correctly functioning code.  And the benefit of testing those that could
 904     # be triggered by using an API against its specification isn't usually
 905     # worth the effort.
 906     add_definitions(-DNDEBUG -DBOOST_DISABLE_ASSERTS -DGMX_DISABLE_ASSERTS)
 907 endif()
 908
 909 if (BUILD_TESTING)
 910     # "tests" target builds all the separate test binaries.
 911     add_custom_target(tests)
 912     # "run-ctest" is an internal target that actually runs the tests.
 913     # This is necessary to be able to add separate targets that execute as part
 914     # of 'make check', but are ensured to be executed after the actual tests.
 915     add_custom_target(run-ctest
 916                       COMMAND ${CMAKE_CTEST_COMMAND} --output-on-failure
 917                       COMMENT "Running all tests"
 918                       VERBATIM)
 919     add_dependencies(run-ctest tests)
 920     # "check" target builds and runs all tests.
 921     add_custom_target(check DEPENDS run-ctest)
 922 endif()
 923
 924 if (NOT GMX_BUILD_MDRUN_ONLY)
 925     add_subdirectory(doxygen)
 926     add_subdirectory(install-guide)
 927     add_subdirectory(share)
 928     add_subdirectory(scripts)
 929 endif()
 930 add_subdirectory(src)
 931
 932 if (BUILD_TESTING)
 933     add_subdirectory(tests)
 934 endif()
 935
 936 # Issue a warning if NVIDIA GPUs were detected, but CUDA was not found.
 937 # Don't bother the user after the first configure pass.
 938 if ((CUDA_NOTFOUND_AUTO AND GMX_DETECT_GPU_AVAILABLE) AND NOT GMX_GPU_DETECTION_DONE)
 939     message(WARNING "${CUDA_NOTFOUND_MESSAGE}")
 940 endif()
 941 set(GMX_GPU_DETECTION_DONE TRUE CACHE INTERNAL "Whether GPU detection has already been done")
 942
 943 #######################
 944 ## uninstall target
 945 #######################
 946 CONFIGURE_FILE(   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 947                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
 948                   IMMEDIATE @ONLY)
 949 ###########################
 950 ADD_CUSTOM_TARGET(uninstall
 951                   "${CMAKE_COMMAND}" -P
 952                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
 953 ###########################
 954 set_directory_properties(PROPERTIES
 955             ADDITIONAL_MAKE_CLEAN_FILES "install_manifest.txt")
 956
 957 ########################################################################
 958 # Manual                                                               #
 959 ########################################################################
 960
 961 option(GMX_BUILD_MANUAL "Whether to try to configure to build the PDF manual" OFF)
 962 mark_as_advanced(GMX_BUILD_MANUAL)
 963 if(GMX_BUILD_MANUAL)
 964     # Make sure we only do detection of manual-building dependencies
 965     # when the user opted in for that.
 966     add_subdirectory(manual)
 967 endif()