CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2009,2010,2011,2012,2013,2014,2015,2016,2017,2018,2019, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 cmake_minimum_required(VERSION 3.9.6)
  36
  37 # CMake modules/macros are in a subdirectory to keep this file cleaner
  38 # This needs to be set before project() in order to pick up toolchain files
  39 list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake ${CMAKE_CURRENT_SOURCE_DIR}/cmake/Platform)
  40
  41 project(Gromacs)
  42
  43 set(CMAKE_CXX_STANDARD 14)
  44 set(CMAKE_CXX_STANDARD_REQUIRED ON)
  45 set(CMAKE_CXX_EXTENSIONS OFF)
  46
  47 include(gmxManageCcache)
  48
  49 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  50 set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  51 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
  52
  53 # Set up common version variables, as well as general information about
  54 # the build tree (whether the build is from a source package or from a git
  55 # repository).  Also declares a few functions that will be used for generating
  56 # version info files later.
  57 include(gmxBuildTreeInfo)
  58 include(gmxVersionInfo)
  59
  60 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT AND UNIX)
  61     set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
  62 endif()
  63 if("${CMAKE_INSTALL_PREFIX}" STREQUAL "${CMAKE_BINARY_DIR}")
  64     message(FATAL_ERROR "GROMACS cannot be installed into the build tree, choose a different location for CMAKE_INSTALL_PREFIX")
  65 endif()
  66
  67 include(gmxBuildTypeReference)
  68 include(gmxBuildTypeProfile)
  69 include(gmxBuildTypeTSAN)
  70 include(gmxBuildTypeASAN)
  71 include(gmxBuildTypeMSAN)
  72 include(gmxBuildTypeReleaseWithAssert)
  73
  74 if(NOT CMAKE_BUILD_TYPE)
  75     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel Reference RelWithAssert Profile TSAN ASAN MSAN." FORCE)
  76     # Set the possible values of build type for cmake-gui
  77     set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "Debug" "Release"
  78         "MinSizeRel" "RelWithDebInfo" "Reference" "RelWithAssert" "Profile" "TSAN" "ASAN" "MSAN")
  79 endif()
  80 if(CMAKE_CONFIGURATION_TYPES)
  81     # Add appropriate GROMACS-specific build types for the Visual
  82     # Studio generator (Debug, Release, MinSizeRel and RelWithDebInfo
  83     # are already present by default).
  84     list(APPEND CMAKE_CONFIGURATION_TYPES "RelWithAssert" "Reference")
  85     list(REMOVE_DUPLICATES CMAKE_CONFIGURATION_TYPES)
  86     set(CMAKE_CONFIGURATION_TYPES "${CMAKE_CONFIGURATION_TYPES}" CACHE STRING
  87         "List of configuration types"
  88         FORCE)
  89 endif()
  90 set(build_types_with_explicit_flags RELEASE DEBUG RELWITHDEBINFO RELWITHASSERT MINSIZEREL PROFILE)
  91
  92 set_property(GLOBAL PROPERTY FIND_LIBRARY_USE_LIB64_PATHS ON)
  93
  94 include(gmxCTestUtilities)
  95 gmx_ctest_init()
  96
  97 include(gmxCPackUtilities)
  98 gmx_cpack_init()
  99
 100 # Variables that accumulate stuff influencing the installed headers
 101 set(INSTALLED_HEADER_INCLUDE_DIRS "")
 102 set(INSTALLED_HEADER_DEFINITIONS "")
 103
 104 ########################################################################
 105 # Global non-cache variables for implementing the build system
 106 ########################################################################
 107
 108 # These variables collect libraries that GROMACS requires for
 109 # linking. They should be appended to with list(APPEND ${name}
 110 # new-library) calls. They are:
 111 #  - Libraries that are required for libgromacs (only)
 112 set(GMX_EXTRA_LIBRARIES "")
 113 #  - Libraries that are required for all code in the repository
 114 set(GMX_COMMON_LIBRARIES "")
 115 #  - Libraries that all code linked against libgromacs needs
 116 #    (i.e., something that is exposed in installed headers).
 117 set(GMX_PUBLIC_LIBRARIES "")
 118
 119 ########################################################################
 120 # Check and warn if cache generated on a different host is being reused
 121 ########################################################################
 122 if(CMAKE_HOST_UNIX)
 123     execute_process(COMMAND hostname
 124                     OUTPUT_VARIABLE TMP_HOSTNAME
 125                     OUTPUT_STRIP_TRAILING_WHITESPACE)
 126     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}")
 127         message(WARNING "
 128             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
 129             is being reused! This could lead to inconsistencies; therefore, it is
 130             recommended to regenerate the cache!")
 131     endif()
 132     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
 133             "Hostname of the machine where the cache was generated.")
 134 endif()
 135
 136 ########################################################################
 137 # Detect architecture before setting options so we can alter defaults
 138 ########################################################################
 139 # Detect the architecture the compiler is targetting, detect
 140 # SIMD instructions possibilities on that hardware, suggest SIMD instruction set
 141 # to use if none is specified, and populate the cache option for CPU
 142 # SIMD.
 143 include(gmxDetectTargetArchitecture)
 144 gmx_detect_target_architecture()
 145
 146 ########################################################################
 147 # User input options                                                   #
 148 ########################################################################
 149 include(gmxOptionUtilities)
 150
 151 set(CMAKE_PREFIX_PATH "" CACHE STRING "Extra locations to search for external libraries and tools (give directory without lib, bin, or include)")
 152
 153 # Fujitsu only has SIMD in double precision, so this will be faster
 154 gmx_set_boolean(GMX_DOUBLE_DEFAULT GMX_TARGET_FUJITSU_SPARC64)
 155 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" ${GMX_DOUBLE_DEFAULT})
 156 option(GMX_RELAXED_DOUBLE_PRECISION "Accept single precision 1/sqrt(x) when using Fujitsu HPC-ACE SIMD" OFF)
 157 mark_as_advanced(GMX_RELAXED_DOUBLE_PRECISION)
 158
 159 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 160 option(GMX_THREAD_MPI  "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" ON)
 161 gmx_dependent_option(
 162     GMX_MPI_IN_PLACE
 163     "Enable MPI_IN_PLACE for MPIs that have it defined"
 164     ON
 165     GMX_MPI)
 166 mark_as_advanced(GMX_MPI_IN_PLACE)
 167
 168 option(GMX_MIMIC "Enable MiMiC QM/MM interface (CPMD is required)" OFF)
 169
 170 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 171 mark_as_advanced(GMX_FAHCORE)
 172
 173 option(GMX_COOL_QUOTES "Enable GROMACS cool quotes" ON)
 174 mark_as_advanced(GMX_COOL_QUOTES)
 175 gmx_add_cache_dependency(GMX_COOL_QUOTES BOOL "NOT GMX_FAHCORE" OFF)
 176
 177 option(GMX_USE_OPENCL "Enable OpenCL acceleration" OFF)
 178
 179 # The earliest version of the CUDA toolkit that supports c++14 is 9.0
 180 set(REQUIRED_CUDA_VERSION 9.0)
 181 set(REQUIRED_CUDA_COMPUTE_CAPABILITY 3.0)
 182
 183 # OpenCL required version: 1.2 or newer
 184 set(REQUIRED_OPENCL_MIN_VERSION_MAJOR 1)
 185 set(REQUIRED_OPENCL_MIN_VERSION_MINOR 2)
 186 set(REQUIRED_OPENCL_MIN_VERSION ${REQUIRED_OPENCL_MIN_VERSION_MAJOR}.${REQUIRED_OPENCL_MIN_VERSION_MINOR})
 187
 188 if(NOT GMX_USE_OPENCL)
 189     # CUDA detection is done only if GMX_USE_OPENCL is OFF.
 190     include(gmxManageGPU)
 191     set(GMX_USE_CUDA ${GMX_GPU})
 192     if(GMX_GPU)
 193         set(GMX_GPU_ACCELERATION_FRAMEWORK "GMX_GPU_CUDA")
 194     else()
 195         set(GMX_GPU_ACCELERATION_FRAMEWORK "GMX_GPU_NONE")
 196     endif()
 197 else()
 198     #Now the OpenCL path (for both AMD and NVIDIA)
 199     if(GMX_GPU)
 200         include(gmxManageOpenCL)
 201         set(GMX_GPU_ACCELERATION_FRAMEWORK "GMX_GPU_OPENCL")
 202     else()
 203         message(FATAL_ERROR "OpenCL requested but GPU option is not enabled (try -DGMX_GPU=on) ")
 204     endif()
 205 endif()
 206
 207 gmx_option_multichoice(
 208     GMX_SIMD
 209     "SIMD instruction set for CPU kernels and compiler optimization"
 210     "AUTO"
 211     AUTO None SSE2 SSE4.1 AVX_128_FMA AVX_256 AVX2_256 AVX2_128 AVX_512 AVX_512_KNL MIC ARM_NEON ARM_NEON_ASIMD IBM_VMX IBM_VSX Sparc64_HPC_ACE Reference)
 212
 213 if(GMX_TARGET_MIC)
 214     set(GMX_FFT_LIBRARY_DEFAULT "mkl")
 215 else()
 216     set(GMX_FFT_LIBRARY_DEFAULT "fftw3")
 217 endif()
 218
 219 gmx_option_multichoice(
 220     GMX_FFT_LIBRARY
 221     "FFT library"
 222     "${GMX_FFT_LIBRARY_DEFAULT}"
 223     fftw3 mkl "fftpack[built-in]")
 224 gmx_dependent_option(
 225     GMX_BUILD_OWN_FFTW
 226     "Download and build FFTW 3 during the GROMACS build process, rather than fall back on the really slow fftpack."
 227     OFF
 228     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 229 gmx_dependent_option(
 230     GMX_DISABLE_FFTW_MEASURE
 231     "Do not optimize FFTW setups (not needed with SSE)"
 232     OFF
 233     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 234 mark_as_advanced(GMX_BUILD_OWN_FFTW)
 235 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 236
 237 gmx_option_multichoice(
 238     GMX_QMMM_PROGRAM
 239     "QM package for QM/MM"
 240     None
 241     none gaussian mopac gamess orca)
 242
 243 gmx_dependent_cache_variable(GMX_SIMD_REF_FLOAT_WIDTH  "Reference SIMD single precision width" STRING "4" "GMX_SIMD STREQUAL REFERENCE")
 244 gmx_dependent_cache_variable(GMX_SIMD_REF_DOUBLE_WIDTH "Reference SIMD double precision width" STRING "2" "GMX_SIMD STREQUAL REFERENCE")
 245
 246 # This should be moved to a separate NBNXN cmake module when that code is cleaned up and modularized
 247
 248 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 249 mark_as_advanced(GMX_BROKEN_CALLOC)
 250
 251 option(GMX_OPENMP "Enable OpenMP-based multithreading" ON)
 252
 253 option(GMX_USE_TNG "Use the TNG library for trajectory I/O" ON)
 254
 255 option(GMX_BUILD_MDRUN_ONLY "Build and install only the mdrun binary" OFF)
 256
 257 option(GMX_CYCLE_SUBCOUNTERS "Enable cycle subcounters to get a more detailed cycle timings" OFF)
 258 mark_as_advanced(GMX_CYCLE_SUBCOUNTERS)
 259
 260 option(GMX_SKIP_DEFAULT_CFLAGS "Don't automatically add suggested/required Compiler flags." OFF)
 261 mark_as_advanced(GMX_SKIP_DEFAULT_CFLAGS)
 262
 263 option(GMX_BUILD_FOR_COVERAGE
 264        "Tune build for better code coverage metrics (e.g., disable asserts)"
 265        OFF)
 266 mark_as_advanced(GMX_BUILD_FOR_COVERAGE)
 267
 268 option(GMX_DEVELOPER_BUILD
 269     "Enable Developer convenience features: always build unit-tests"
 270     OFF)
 271 mark_as_advanced(GMX_DEVELOPER_BUILD)
 272
 273 gmx_set_boolean(GMX_COMPILER_WARNINGS_DEFAULT "NOT SOURCE_IS_SOURCE_DISTRIBUTION")
 274 option(GMX_COMPILER_WARNINGS
 275     "Enable a default set of compiler warnings"
 276     ${GMX_COMPILER_WARNINGS_DEFAULT})
 277 mark_as_advanced(GMX_COMPILER_WARNINGS)
 278 # Always turn on compiler warnings with a developer build.
 279 gmx_add_cache_dependency(GMX_COMPILER_WARNINGS BOOL "NOT GMX_DEVELOPER_BUILD" ON)
 280
 281 option(GMX_BUILD_SHARED_EXE
 282     "Build exectuables as shared binaries. If not set, this disables rpath and dynamic linker flags in an attempt to build a static binary, but this may require setting up the toolchain properly and making appropriate libraries available."
 283     ON)
 284 mark_as_advanced(GMX_BUILD_SHARED_EXE)
 285
 286 option(GMX_PHYSICAL_VALIDATION
 287        "Include physical validation tests in ctest environment. These can then be called using 'make check-phys' or
 288        'make check-all'. Warning: Running the physical validation tests takes significantly more time than other tests!"
 289        OFF)
 290 mark_as_advanced(GMX_PHYSICAL_VALIDATION)
 291
 292 ######################################################################
 293 # Detect OpenMP support
 294 ######################################################################
 295 # The OpenMP detection _must_ come before tests for other CFLAGS.
 296 include(gmxManageOpenMP)
 297
 298
 299
 300 ######################################################################
 301 # Compiler tests
 302 # These need to be done early (before further tests).
 303 #####################################################################
 304
 305 include(gmxCFlags)
 306 gmx_c_flags()
 307
 308 # This variable should be used for additional compiler flags which are not
 309 # generated in gmxCFlags nor are SIMD or MPI related.
 310 #
 311 # TODO These variables should be consolidated into
 312 # EXTRA_COMPILER_FLAGS so that we we don't perpetrate bugs where
 313 # things that work in C compilation (e.g. merging from old branches)
 314 # also work for C++ compilation.
 315 set(EXTRA_C_FLAGS "")
 316 set(EXTRA_CXX_FLAGS "")
 317
 318 # Run through a number of tests for buggy compilers and other issues
 319 include(gmxTestCompilerProblems)
 320 gmx_test_compiler_problems()
 321
 322 # Implement double-precision option. This is complicated because we
 323 # need installed headers to use the precision mode of the build that
 324 # produced the library, but cannot use config.h in that case. We also
 325 # want such variables to always have a definition, because #if is more
 326 # robust than #ifdef. So, we put this value on the compiler command
 327 # line in all cases.
 328 #
 329 # GMX_RELAXED_DOUBLE_PRECISION does not need to be handled here,
 330 # because no installed header needs it
 331 if(GMX_DOUBLE)
 332     set(GMX_DOUBLE_VALUE 1)
 333 else()
 334     set(GMX_DOUBLE_VALUE 0)
 335 endif()
 336 add_definitions(-DGMX_DOUBLE=${GMX_DOUBLE_VALUE})
 337 list(APPEND INSTALLED_HEADER_DEFINITIONS "-DGMX_DOUBLE=${GMX_DOUBLE_VALUE}")
 338
 339 if(WIN32)
 340     list(APPEND GMX_EXTRA_LIBRARIES "wsock32")
 341     add_definitions(-DGMX_HAVE_WINSOCK)
 342 endif()
 343
 344
 345
 346 ########################################################################
 347 # Basic system tests (standard libraries, headers, functions, types)   #
 348 ########################################################################
 349 include(CheckIncludeFiles)
 350 include(CheckIncludeFileCXX)
 351 check_include_files(unistd.h     HAVE_UNISTD_H)
 352 check_include_files(pwd.h        HAVE_PWD_H)
 353 check_include_files(dirent.h     HAVE_DIRENT_H)
 354 check_include_files(time.h       HAVE_TIME_H)
 355 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 356 check_include_files(io.h         HAVE_IO_H)
 357 check_include_files(sched.h      HAVE_SCHED_H)
 358
 359 include(CheckCXXSymbolExists)
 360 check_cxx_symbol_exists(gettimeofday      sys/time.h   HAVE_GETTIMEOFDAY)
 361 check_cxx_symbol_exists(sysconf           unistd.h     HAVE_SYSCONF)
 362 check_cxx_symbol_exists(nice              unistd.h     HAVE_NICE)
 363 check_cxx_symbol_exists(fsync             unistd.h     HAVE_FSYNC)
 364 check_cxx_symbol_exists(_fileno           stdio.h      HAVE__FILENO)
 365 check_cxx_symbol_exists(fileno            stdio.h      HAVE_FILENO)
 366 check_cxx_symbol_exists(_commit           io.h         HAVE__COMMIT)
 367 check_cxx_symbol_exists(sigaction         signal.h     HAVE_SIGACTION)
 368
 369 # We cannot check for the __builtins as symbols, but check if code compiles
 370 check_cxx_source_compiles("int main(){ return __builtin_clz(1);}"   HAVE_BUILTIN_CLZ)
 371 check_cxx_source_compiles("int main(){ return __builtin_clzll(1);}" HAVE_BUILTIN_CLZLL)
 372 if(MSVC)
 373     check_cxx_source_compiles("#include <intrin.h>\n int main(){unsigned long r;unsigned long i=1;_BitScanReverse(&r,i);return r;}" HAVE_BITSCANREVERSE)
 374     check_cxx_source_compiles("#include <intrin.h>\n int main(){unsigned long r;unsigned __int64 i=1;_BitScanReverse(&r,i);return r;}" HAVE_BITSCANREVERSE64)
 375 elseif(CMAKE_CXX_COMPILER_ID MATCHES "XL")
 376     check_cxx_source_compiles("int main(){ return __cntlz4(1);}" HAVE_CNTLZ4)
 377     check_cxx_source_compiles("int main(){ return __cntlz8(1);}" HAVE_CNTLZ8)
 378 endif()
 379
 380 include(CheckLibraryExists)
 381 find_library(HAVE_LIBM m)
 382 mark_as_advanced(HAVE_LIBM)
 383 check_library_exists(rt clock_gettime "" HAVE_CLOCK_GETTIME)
 384 check_library_exists(m feenableexcept "" HAVE_FEENABLEEXCEPT)
 385 check_library_exists(m fedisableexcept "" HAVE_FEDISABLEEXCEPT)
 386
 387 include(TestSchedAffinity)
 388 test_sched_affinity(HAVE_SCHED_AFFINITY)
 389
 390 # Aligned memory allocation. We need to check for both mm_malloc(),
 391 # posix_memalign(), memalign(), and on windows also _aligned_malloc()
 392 include(gmxTestMMMalloc)
 393 gmx_test_mm_malloc(HAVE__MM_MALLOC)
 394 check_cxx_symbol_exists(posix_memalign    stdlib.h     HAVE_POSIX_MEMALIGN)
 395 check_cxx_symbol_exists(memalign          stdlib.h     HAVE_MEMALIGN)
 396 if(MSVC)
 397     # No need to waste time on this test on platforms where it will never be true
 398     check_cxx_symbol_exists(_aligned_malloc   stdlib.h     HAVE__ALIGNED_MALLOC)
 399 endif()
 400
 401 include(TestBigEndian)
 402 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 403
 404 gmx_set_boolean(GMX_USE_NICE "HAVE_UNISTD_H AND HAVE_NICE")
 405
 406 # Management of GROMACS options for specific toolchains should go
 407 # here. Because the initial settings for some of the main options have
 408 # already happened, but things like library detection and MPI compiler
 409 # feature detection have not, the docstrings for any over-rides of
 410 # GROMACS defaults or user settings will make sense. Also, any
 411 # toolchain-related reasons for choosing whether to detect various
 412 # things can be sorted out now, before the detection takes place.
 413 if(GMX_TARGET_FUJITSU_SPARC64)
 414     include(gmxManageFujitsuSparc64)
 415 endif()
 416
 417 ########################################################################
 418 #Process MPI settings
 419 ########################################################################
 420 include(gmxManageMPI)
 421
 422 ########################################################################
 423 #Process MiMiC settings
 424 ########################################################################
 425 include(gmxManageMimic)
 426
 427 ########################################################################
 428 #Process shared/static library settings
 429 ########################################################################
 430 include(gmxManageSharedLibraries)
 431
 432
 433 ########################################################################
 434 # Find external packages                                               #
 435 ########################################################################
 436
 437 # Unconditionally find the package, as it is also required for unit
 438 # tests. This exports LIBXML2_FOUND, which we should not use because
 439 # it does not tell us that linking will succeed. Instead, we test that
 440 # next.
 441 #if(DEFINED LIBXML2_LIBRARIES)
 442 #  set(LibXml2_FIND_QUIETLY TRUE)
 443 #endif()
 444 #find_package(LibXml2)
 445 #include(gmxTestLibXml2)
 446 #gmx_test_libxml2(HAVE_LIBXML2)
 447 #option(GMX_XML "Use libxml2 to parse xml files (currently has no effect)" ${HAVE_LIBXML2})
 448 #set(PKG_XML "")
 449 #mark_as_advanced(GMX_XML)
 450 # Don't actually do anything, since libxml2 is currently not used by libgromacs
 451 #if(GMX_XML AND NOT HAVE_LIBXML2)
 452 #    message(FATAL_ERROR "libxml2 not found. Set GMX_XML=OFF to compile without XML support")
 453 #endif()
 454 #if(GMX_XML)
 455 #    include_directories(${LIBXML2_INCLUDE_DIR})
 456 #    set(PKG_XML libxml-2.0)
 457 #    set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 458 #endif()
 459
 460 gmx_option_trivalue(
 461     GMX_HWLOC
 462     "Use hwloc portable hardware locality library"
 463     "AUTO")
 464
 465 if (GMX_HWLOC)
 466     # Find quietly the second time.
 467     if(DEFINED HWLOC_LIBRARIES)
 468         set(Hwloc_FIND_QUIETLY TRUE)
 469     endif()
 470     find_package(Hwloc 1.5)
 471
 472     if (HWLOC_FOUND)
 473         if (HWLOC_LIBRARIES MATCHES ".a$")
 474             set(_STATIC_HWLOC TRUE)
 475         endif()
 476
 477         gmx_check_if_changed(HWLOC_FOUND_CHANGED HWLOC_FOUND)
 478         if (_STATIC_HWLOC AND HWLOC_FOUND_CHANGED)
 479             message(STATUS "Static hwloc library found, will not attempt using it as it could lead to link-time errors. To use the detected library, manually set GMX_HWLOC=ON and you will likely have to pass appropriate linker flags too to satisfy the link-time dependencies of your hwloc library. Try \"pkg-config --libs --static hwloc\" for suggestions on what you will need.")
 480             set(GMX_USE_HWLOC OFF)
 481         else()
 482             set(GMX_USE_HWLOC ON)
 483         endif()
 484
 485         if (GMX_USE_HWLOC)
 486             include_directories(SYSTEM ${HWLOC_INCLUDE_DIRS})
 487             list(APPEND GMX_EXTRA_LIBRARIES ${HWLOC_LIBRARIES})
 488         endif()
 489     elseif(GMX_HWLOC_FORCE)
 490         message(FATAL_ERROR "Hwloc package support required, but not found.")
 491     endif()
 492 endif()
 493
 494 option(GMX_EXTERNAL_TINYXML2 "Use external TinyXML-2 instead of compiling the version bundled with GROMACS." OFF)
 495 mark_as_advanced(GMX_EXTERNAL_TINYXML2)
 496 if(GMX_EXTERNAL_TINYXML2)
 497     # Find an external TinyXML-2 library.
 498     find_package(TinyXML-2 3.0.0)
 499     set(HAVE_TINYXML2 ${TinyXML2_FOUND})
 500     if(NOT HAVE_TINYXML2)
 501         message(FATAL_ERROR "External TinyXML-2 could not be found, please adjust your search paths")
 502     endif()
 503 endif()
 504
 505 option(GMX_EXTRAE "Add support for tracing using EXTRAE" OFF)
 506 mark_as_advanced(GMX_EXTRAE)
 507
 508 if (GMX_EXTRAE)
 509   find_package(EXTRAE)
 510   if(EXTRAE_FOUND)
 511     include_directories(SYSTEM ${EXTRAE_INCLUDE_DIR})
 512     set(HAVE_EXTRAE 1)
 513   else()
 514     message(FATAL_ERROR "EXTRAE library was not found. Please add the correct path to CMAKE_PREFIX_PATH")
 515   endif()
 516 endif()
 517
 518 option(GMX_X11 "Use X window system" OFF)
 519 if (GMX_X11)
 520     find_package(X11)
 521     # X11 includes/libraries are only set in the ngmx subdirectory!
 522     if(NOT X11_FOUND)
 523         message(FATAL_ERROR
 524                 "X11 include files and/or libraries were not found. "
 525                 "Set GMX_X11=OFF to compile without X11 support. "
 526                 "gmx view will not be available.")
 527     endif()
 528     include_directories(SYSTEM ${X11_INCLUDE_DIR})
 529 endif()
 530
 531 include(ThreadMPI)
 532 # Enable core threading facilities
 533 tmpi_enable_core("${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include")
 534 if(GMX_THREAD_MPI)
 535     # enable MPI functions
 536     tmpi_enable()
 537     set(MPI_IN_PLACE_EXISTS 1)
 538 endif()
 539 # If atomics are manually disabled a define is needed because atomics.h doesn't depend on config.h
 540 if (TMPI_ATOMICS_DISABLED)
 541    add_definitions(-DTMPI_ATOMICS_DISABLED)
 542 endif()
 543
 544 include(gmxManageTNG)
 545
 546 include(gmxManageLmfit)
 547
 548 if(GMX_GPU)
 549     # now that we have detected the dependencies, do the second configure pass
 550     gmx_gpu_setup()
 551     if (GMX_CLANG_CUDA)
 552         list(APPEND GMX_EXTRA_LIBRARIES ${GMX_CUDA_CLANG_LINK_LIBS})
 553         link_directories("${GMX_CUDA_CLANG_LINK_DIRS}")
 554     endif()
 555 endif()
 556
 557 if(CYGWIN)
 558     set(GMX_CYGWIN 1)
 559 endif()
 560
 561 if(WIN32)
 562     set(GMX_NATIVE_WINDOWS 1)
 563     # This makes windows.h not declare min/max as macros that would break
 564     # C++ code using std::min/std::max.
 565     add_definitions(-DNOMINMAX)
 566 endif()
 567
 568 if(CMAKE_SYSTEM_NAME STREQUAL "Darwin") #Work-around for cmake bug #10837
 569     if (CMAKE_COMPILER_IS_GNUCC OR CMAKE_C_COMPILER_ID MATCHES "Intel" OR CMAKE_C_COMPILER_ID MATCHES "Clang")
 570         set(CMAKE_INCLUDE_SYSTEM_FLAG_C "-isystem ")
 571     endif()
 572     if (CMAKE_COMPILER_IS_GNUCXX OR CMAKE_CXX_COMPILER_ID MATCHES "Intel" OR CMAKE_CXX_COMPILER_ID MATCHES "Clang")
 573         set(CMAKE_INCLUDE_SYSTEM_FLAG_CXX "-isystem ")
 574     endif()
 575 endif()
 576
 577 option(GMX_BUILD_UNITTESTS "Build unit tests with BUILD_TESTING" ON)
 578 mark_as_advanced(GMX_BUILD_UNITTESTS)
 579 gmx_add_cache_dependency(GMX_BUILD_UNITTESTS BOOL BUILD_TESTING OFF)
 580
 581 ########################################################################
 582 # Our own GROMACS tests
 583 ########################################################################
 584
 585 add_definitions( -DHAVE_CONFIG_H )
 586 include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src)
 587 # TODO required at high level because both libgromacs and progs/mdrun
 588 # require it, both for thread-MPI and its atomics and mutexes.
 589 include_directories(BEFORE SYSTEM ${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include)
 590 # Required for config.h, maybe should only be set in src/CMakeLists.txt
 591 include_directories(BEFORE ${CMAKE_BINARY_DIR}/src)
 592
 593 include(gmxTestInlineASM)
 594 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 595
 596 include(gmxSetBuildInformation)
 597 gmx_set_build_information()
 598
 599 gmx_option_multichoice(
 600     GMX_USE_RDTSCP
 601     "Use low-latency RDTSCP instruction for CPU-based timers for mdrun execution; might need to be off when compiling for heterogeneous environments)"
 602     "AUTO"
 603     OFF ON AUTO DETECT)
 604 mark_as_advanced(GMX_USE_RDTSCP)
 605
 606 macro(gmx_check_rdtscp)
 607     if (CPU_DETECTION_FEATURES MATCHES "rdtscp")
 608         set(HAVE_RDTSCP 1)
 609         set(RDTSCP_DETECTION_MESSAGE " - detected on the build host")
 610     else()
 611         set(RDTSCP_DETECTION_MESSAGE " - not detected on the build host")
 612     endif()
 613 endmacro()
 614
 615 set(HAVE_RDTSCP 0)
 616 if (GMX_USE_RDTSCP STREQUAL "ON")
 617     set(HAVE_RDTSCP 1)
 618 elseif(GMX_USE_RDTSCP STREQUAL "DETECT")
 619     gmx_check_rdtscp()
 620 elseif(GMX_USE_RDTSCP STREQUAL "AUTO")
 621     # If the user specified automated SIMD selection, that the choice
 622     # is made based on detection on the build host. If so, then RDTSCP
 623     # should be chosen the same way.
 624     #
 625     # If the user specified an AVX SIMD level (e.g. when
 626     # cross-compiling GROMACS) then they will get our best guess, ie
 627     # that in practice AVX mostly correlates with rdtscp (and anyway
 628     # is only relevant in rather old x86 hardware).
 629     if (GMX_SIMD STREQUAL "AUTO")
 630         gmx_check_rdtscp()
 631     elseif (GMX_SIMD MATCHES "AVX")
 632         set(HAVE_RDTSCP 1)
 633     endif()
 634 endif()
 635 gmx_check_if_changed(HAVE_RDTSCP_CHANGED HAVE_RDTSCP)
 636 if (HAVE_RDTSCP_CHANGED)
 637     if (HAVE_RDTSCP)
 638         message(STATUS "Enabling RDTSCP support${RDTSCP_DETECTION_MESSAGE}")
 639     else()
 640         message(STATUS "Disabling RDTSCP support${RDTSCP_DETECTION_MESSAGE}")
 641     endif()
 642 endif()
 643
 644 include(gmxTestLargeFiles)
 645 gmx_test_large_files(GMX_LARGEFILES)
 646
 647 include(gmxTestSignal)
 648 gmx_test_sigusr1(HAVE_SIGUSR1)
 649
 650 include(gmxTestPipes)
 651 gmx_test_pipes(HAVE_PIPES)
 652
 653 include(gmxTestXDR)
 654 gmx_test_xdr(GMX_SYSTEM_XDR)
 655 # Darwin has system XDR, but it uses a three-argument flavour of
 656 # xdrproc_t that it guarantees will still work if you pass the normal
 657 # two-argument xdr filters, but gcc 8 warns about the cast necessary
 658 # to do that, so it's simpler to just use our own XDR library.
 659 #
 660 # TODO It would be better to craft a cmake test which fails if such
 661 # XDR operations cause warnings, and succeeds otherwise, because it is
 662 # generally preferable to use system libraries where possible.
 663 if(NOT GMX_SYSTEM_XDR OR CMAKE_SYSTEM_NAME STREQUAL "Darwin")
 664     set(GMX_INTERNAL_XDR 1)
 665 endif()
 666
 667
 668 ##################################################
 669 # Process SIMD instruction settings
 670 ##################################################
 671 # This checks what flags to add in order to
 672 # support the SIMD instructions we need, it sets
 673 # correct defines for the SIMD instructions supported,
 674 # and adds advanced options to control accuracy
 675 # for SIMD math operations.
 676 include(gmxManageSimd)
 677 gmx_manage_simd()
 678
 679 include(gmxManageCycleCounters)
 680 gmx_manage_cycle_counters()
 681
 682 # Process QM/MM Settings
 683 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 684     set(GMX_QMMM_GAUSSIAN 1)
 685 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 686     set(GMX_QMMM_MOPAC 1)
 687 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 688     set(GMX_QMMM_GAMESS 1)
 689 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 690     set(GMX_QMMM_ORCA 1)
 691 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 692     # nothing to do
 693 else()
 694     gmx_invalid_option_value(GMX_QMMM_PROGRAM)
 695 endif()
 696
 697
 698 ##################################################
 699 # Process FFT library settings
 700 ##################################################
 701 include(gmxManageFFTLibraries)
 702
 703
 704 include(gmxManageLinearAlgebraLibraries)
 705
 706 include(gmxManagePluginSupport)
 707
 708 if (GMX_USE_PLUGINS)
 709     if(NOT GMX_VMD_PLUGIN_PATH)
 710         find_package(VMD)
 711     endif()
 712 endif()
 713
 714 # Link real-time library for POSIX timers. The check for clock_gettime
 715 # confirms the linkability of rt.
 716 if(HAVE_TIME_H AND HAVE_UNISTD_H AND HAVE_CLOCK_GETTIME)
 717     list(APPEND GMX_EXTRA_LIBRARIES rt)
 718 endif()
 719
 720 # Math and thread libraries must often come after all others when linking...
 721 if (HAVE_LIBM)
 722     list(APPEND GMX_PUBLIC_LIBRARIES m)
 723 endif()
 724
 725 option(GMX_NACL "Configure for Native Client builds" OFF)
 726 if (GMX_NACL)
 727   list(APPEND GMX_EXTRA_LIBRARIES nosys)
 728   set(GMX_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -lnosys")
 729   # TODO: Is this still necessary with the check for its presence?
 730   set(GMX_USE_NICE 0)
 731   set(GMX_NO_RENAME 1)
 732 endif()
 733 mark_as_advanced(GMX_NACL)
 734
 735 if(GMX_FAHCORE)
 736   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 737       "Path to swindirect.h")
 738   include_directories(${COREWRAP_INCLUDE_DIR})
 739 endif()
 740
 741 # Value of GMX_BUILD_HELP=AUTO tries to generate things, but will only
 742 # produce warnings if that fails.
 743 set(build_help_default AUTO)
 744 if (SOURCE_IS_SOURCE_DISTRIBUTION OR CMAKE_CROSSCOMPILING)
 745     set(build_help_default OFF)
 746 endif()
 747 gmx_option_trivalue(GMX_BUILD_HELP "Build completions automatically (requires that compiled binaries can be executed on the build host) and install man pages if built (requires building the 'man' target manually)" ${build_help_default})
 748 mark_as_advanced(GMX_BUILD_HELP)
 749 if (GMX_BUILD_HELP AND SOURCE_IS_SOURCE_DISTRIBUTION AND BUILD_IS_INSOURCE)
 750     message(FATAL_ERROR
 751         "Rebuilding shell completions or man pages is not supported for "
 752         "in-source builds from a source distribution. "
 753         "Set GMX_BUILD_HELP=OFF or do an out-of-source build to proceed.")
 754 endif()
 755
 756 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 757 # these are set after everything else
 758 if (NOT GMX_SKIP_DEFAULT_CFLAGS)
 759     set(CMAKE_C_FLAGS "${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${CMAKE_C_FLAGS}")
 760     set(CMAKE_CXX_FLAGS "${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${CMAKE_CXX_FLAGS}")
 761     set(CMAKE_EXE_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}")
 762     set(CMAKE_SHARED_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS}")
 763 else()
 764     message("Recommended flags which are not added because GMX_SKIP_DEFAULT_CFLAGS=yes:")
 765     message("CMAKE_C_FLAGS: ${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${GMXC_CFLAGS}")
 766     message("CMAKE_C_FLAGS_RELEASE: ${GMXC_CFLAGS_RELEASE}")
 767     message("CMAKE_C_FLAGS_DEBUG: ${GMXC_CFLAGS_DEBUG}")
 768     message("CMAKE_CXX_FLAGS: ${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${GMXC_CXXFLAGS}")
 769     message("CMAKE_CXX_FLAGS_RELEASE: ${GMXC_CXXFLAGS_RELEASE}")
 770     message("CMAKE_CXX_FLAGS_DEBUG: ${GMXC_CXXFLAGS_DEBUG}")
 771     message("CMAKE_EXE_LINKER_FLAGS: ${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS}")
 772     message("CMAKE_SHARED_LINKER_FLAGS: ${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS}")
 773 endif()
 774
 775 ########################################################################
 776 # Specify install locations
 777 ########################################################################
 778 # Use GNUInstallDirs to set paths on multiarch systems.
 779 include(GNUInstallDirs)
 780
 781 set(GMX_INSTALL_DATASUBDIR "gromacs" CACHE STRING "Subdirectory for GROMACS data under CMAKE_INSTALL_DATADIR")
 782 mark_as_advanced(GMX_INSTALL_DATASUBDIR)
 783
 784 # Internal convenience so we do not have to join two path segments in the code
 785 set(GMX_INSTALL_GMXDATADIR ${CMAKE_INSTALL_DATADIR}/${GMX_INSTALL_DATASUBDIR})
 786
 787 # If the nesting level wrt. the installation root is changed,
 788 # gromacs-config.cmake.cmakein needs to be adapted.
 789 set(GMX_INSTALL_CMAKEDIR  ${CMAKE_INSTALL_DATAROOTDIR}/cmake)
 790
 791 # TODO: Make GMXRC adapt if this is changed
 792 set(GMX_INSTALL_PKGCONFIGDIR ${CMAKE_INSTALL_LIBDIR}/pkgconfig)
 793 set(GMX_INSTALL_OCLDIR       ${GMX_INSTALL_GMXDATADIR}/opencl)
 794
 795 list(APPEND INSTALLED_HEADER_INCLUDE_DIRS ${CMAKE_INSTALL_INCLUDEDIR})
 796
 797 # Binary and library suffix options
 798 include(gmxManageSuffixes)
 799
 800 ################################################################
 801 # Shared library load path settings
 802 ################################################################
 803 if(NOT GMX_BUILD_SHARED_EXE)
 804     # No rpath
 805     set(CMAKE_SKIP_RPATH TRUE)
 806     set(CMAKE_EXE_LINK_DYNAMIC_C_FLAGS) # remove -Wl,-Bdynamic
 807     set(CMAKE_EXE_LINK_DYNAMIC_CXX_FLAGS)
 808 else()
 809     # The build folder always has bin/ and lib/; if we are also going to
 810     # install to lib/, then the installation RPATH works also in the build
 811     # tree.  This makes installation slightly faster (no need to rewrite the
 812     # RPATHs), and makes the binaries in the build tree relocatable.
 813     if(CMAKE_INSTALL_LIBDIR STREQUAL "lib")
 814         set(CMAKE_BUILD_WITH_INSTALL_RPATH TRUE)
 815         if(POLICY CMP0068)
 816             cmake_policy(SET CMP0068 NEW) # From CMake-3.9
 817             set(CMAKE_BUILD_WITH_INSTALL_NAME_DIR TRUE)
 818         endif()
 819     endif()
 820     # Set the RPATH as relative to the executable location to make the
 821     # binaries relocatable.
 822     if(CMAKE_SYSTEM_NAME STREQUAL "Darwin") #Assume OS X >=10.5
 823         set(CMAKE_INSTALL_RPATH "@loader_path/../${CMAKE_INSTALL_LIBDIR}")
 824         set(CMAKE_INSTALL_NAME_DIR ${CMAKE_INSTALL_RPATH})
 825     else()
 826         set(CMAKE_INSTALL_RPATH "\$ORIGIN/../${CMAKE_INSTALL_LIBDIR}")
 827     endif()
 828     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 829     set(CMAKE_MACOSX_RPATH 1)
 830 endif()
 831
 832 #COPYING file: Only necessary for binary distributions.
 833 #Simpler to always install.
 834 install(FILES COPYING DESTINATION ${GMX_INSTALL_GMXDATADIR} COMPONENT data)
 835
 836 if (GMX_BUILD_FOR_COVERAGE)
 837     # Code heavy with asserts makes conditional coverage close to useless metric,
 838     # as by design most of the false branches are impossible to trigger in
 839     # correctly functioning code.  And the benefit of testing those that could
 840     # be triggered by using an API against its specification isn't usually
 841     # worth the effort.
 842     add_definitions(-DNDEBUG -DGMX_DISABLE_ASSERTS)
 843 endif()
 844
 845 if (BUILD_TESTING)
 846     include(tests/CheckTarget.cmake)
 847 endif()
 848
 849 if (NOT GMX_BUILD_MDRUN_ONLY)
 850     find_package(ImageMagick QUIET COMPONENTS convert)
 851     include(gmxTestImageMagick)
 852     GMX_TEST_IMAGEMAGICK(IMAGE_CONVERT_POSSIBLE)
 853     add_subdirectory(docs)
 854     add_subdirectory(share)
 855     add_subdirectory(scripts)
 856 endif()
 857 add_subdirectory(src)
 858
 859 if (BUILD_TESTING)
 860     add_subdirectory(tests)
 861 endif()
 862
 863 gmx_cpack_write_config()
 864
 865 # Issue a warning if NVIDIA GPUs were detected, but CUDA was not found.
 866 # Don't bother the user after the first configure pass.
 867 if ((CUDA_NOTFOUND_AUTO AND GMX_DETECT_GPU_AVAILABLE) AND NOT GMX_GPU_DETECTION_DONE)
 868     message(WARNING "${CUDA_NOTFOUND_MESSAGE}")
 869 endif()
 870 set(GMX_GPU_DETECTION_DONE TRUE CACHE INTERNAL "Whether GPU detection has already been done")
 871
 872 #######################
 873 ## uninstall target
 874 #######################
 875 CONFIGURE_FILE(   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 876                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
 877                   IMMEDIATE @ONLY)
 878 ###########################
 879 ADD_CUSTOM_TARGET(uninstall
 880                   "${CMAKE_COMMAND}" -P
 881                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
 882 ###########################
 883 set_directory_properties(PROPERTIES
 884             ADDITIONAL_MAKE_CLEAN_FILES "install_manifest.txt")