CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.8)
   2 # Keep CMake suitably quiet on Cygwin
   3 set(CMAKE_LEGACY_CYGWIN_WIN32 0) # Remove when CMake >= 2.8.4 is required
   4
   5 # CMake modules/macros are in a subdirectory to keep this file cleaner
   6 # This needs to be set before project() in order to pick up toolchain files
   7 list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake ${CMAKE_CURRENT_SOURCE_DIR}/cmake/Platform)
   8
   9 project(Gromacs)
  10 include(Dart)
  11 mark_as_advanced(DART_ROOT)
  12
  13 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  14 set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  15 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
  16
  17 # PROJECT_VERSION should have the following structure:
  18 # VERSION-dev[-SUFFIX] where the VERSION should have the for: vMajor.vMinor.vPatch
  19 #
  20 # The "-dev" suffix is important to keep because it makes possible to distinguish
  21 # between a build from official release and a build from git release branch on a
  22 # machine with no git.
  23 #
  24 # NOTE: when releasing the "-dev" suffix needs to be stripped off!
  25 set(PROJECT_VERSION "5.0-dev")
  26 set(CUSTOM_VERSION_STRING ""
  27     CACHE STRING "Custom version string (if empty, use hard-coded default)")
  28 mark_as_advanced(CUSTOM_VERSION_STRING)
  29 if (CUSTOM_VERSION_STRING)
  30     set(PROJECT_VERSION ${CUSTOM_VERSION_STRING})
  31 endif (CUSTOM_VERSION_STRING)
  32 set(SOVERSION 8)
  33 # It is a bit irritating, but this has to be set separately for now!
  34 SET(CPACK_PACKAGE_VERSION_MAJOR "5")
  35 SET(CPACK_PACKAGE_VERSION_MINOR "0")
  36 #SET(CPACK_PACKAGE_VERSION_PATCH "0")
  37
  38 # The numerical gromacs version. It is 40600 for 4.6.0.
  39 # The #define GMX_VERSION in gmx_header_config_h is set to this value.
  40 math(EXPR NUM_VERSION
  41     "${CPACK_PACKAGE_VERSION_MAJOR}*10000 + ${CPACK_PACKAGE_VERSION_MINOR}*100")
  42 if(CPACK_PACKAGE_VERSION_PATCH)
  43     math(EXPR NUM_VERSION
  44          "${NUM_VERSION} + ${CPACK_PACKAGE_VERSION_PATCH}")
  45 endif()
  46
  47 # The API version tracks the numerical Gromacs version (for now).
  48 # It is potentially different from the Gromacs version in the future, if
  49 # the programs/libraries diverge from the presumably more stable API.
  50 # The #define GMX_API_VERSION in version.h is set to this value to
  51 # provide backward compatibility of software written against the Gromacs API.
  52 set(API_VERSION ${NUM_VERSION})
  53
  54 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT AND UNIX)
  55     set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
  56 endif()
  57
  58 set(GMX_INSTALL_PREFIX "" CACHE STRING "Prefix gets appended to CMAKE_INSTALL_PREFIX. For cpack it sets the root folder of the archive.")
  59 mark_as_advanced(GMX_INSTALL_PREFIX)
  60
  61 include(gmxBuildTypeReference)
  62
  63 if(NOT CMAKE_BUILD_TYPE)
  64     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel Reference." FORCE)
  65 endif(NOT CMAKE_BUILD_TYPE)
  66
  67 enable_language(C)
  68 enable_language(CXX)
  69
  70 set(CPACK_PACKAGE_VERSION ${PROJECT_VERSION})
  71 set(CPACK_PACKAGE_VENDOR "gromacs.org")
  72 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Gromacs - a toolkit for high-performance molecular simulation")
  73 set(CPACK_RESOURCE_FILE_WELCOME "${CMAKE_SOURCE_DIR}/admin/InstallWelcome.txt")
  74 # Its GPL/LGPL, so they do not have to agree to a license for mere usage, but some installers require this...
  75 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_SOURCE_DIR}/COPYING")
  76 set(CPACK_RESOURCE_FILE_README "${CMAKE_SOURCE_DIR}/admin/InstallInfo.txt")
  77 set(CPACK_SOURCE_IGNORE_FILES "\\\\.isreposource$;\\\\.git/;\\\\.gitignore$")
  78 set(CPACK_PROJECT_CONFIG_FILE "${CMAKE_SOURCE_DIR}/CPackInit.cmake")
  79 SET(CPACK_SOURCE_INSTALLED_DIRECTORIES "${CMAKE_SOURCE_DIR};/;${CMAKE_BINARY_DIR}/man;man")
  80 set(CPACK_PACKAGE_CONTACT "gmx-users@gromacs.org")
  81
  82 #must come after all cpack settings!
  83 include(CPack)
  84
  85 set(SOURCE_IS_GIT_REPOSITORY OFF)
  86 if(EXISTS "${CMAKE_SOURCE_DIR}/.git")
  87     set(SOURCE_IS_GIT_REPOSITORY ON)
  88 endif()
  89
  90 ########################################################################
  91 # Check and warn if cache generated on a different host is being reused
  92 ########################################################################
  93 if(CMAKE_HOST_UNIX)
  94     execute_process(COMMAND hostname
  95                     OUTPUT_VARIABLE TMP_HOSTNAME
  96                     OUTPUT_STRIP_TRAILING_WHITESPACE)
  97     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}")
  98         message(WARNING "
  99             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
 100             is being reused! This could lead to inconsitencies; therefore, it is
 101             recommended to regenerate the cache!")
 102     endif()
 103     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
 104             "Hostname of the machine where the cache was generated.")
 105 endif()
 106
 107 ########################################################################
 108 option(GMX_COOL_QUOTES "Enable Gromacs cool quotes" ON)
 109 mark_as_advanced(GMX_COOL_QUOTES)
 110
 111 set(CMAKE_PREFIX_PATH "" CACHE STRING "Extra locations to search for external libraries and tools (give directory without lib, bin, or include)")
 112 # User input options                                                   #
 113 ########################################################################
 114 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" OFF)
 115 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 116 option(GMX_THREAD_MPI  "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" ON)
 117 option(GMX_SOFTWARE_INVSQRT "Use GROMACS software 1/sqrt" ON)
 118 mark_as_advanced(GMX_SOFTWARE_INVSQRT)
 119 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 120 mark_as_advanced(GMX_FAHCORE)
 121
 122 # decide on GPU settings based on user-settings and GPU/CUDA detection
 123 include(gmxManageGPU)
 124
 125 # TODO: move OpenMM to contrib
 126 option(GMX_OPENMM "Accelerated execution on GPUs through the OpenMM library (rerun cmake after changing to see relevant options)" OFF)
 127 mark_as_advanced(GMX_OPENMM)
 128
 129 include(gmxDetectAcceleration)
 130 if(NOT DEFINED GMX_CPU_ACCELERATION)
 131     if(CMAKE_CROSSCOMPILING)
 132         if("${CMAKE_SYSTEM_NAME}" MATCHES "BlueGeneQ")
 133             set(GMX_SUGGESTED_CPU_ACCELERATION "IBM_QPX")
 134         else()
 135             set(GMX_SUGGESTED_CPU_ACCELERATION "None")
 136         endif()
 137     else(CMAKE_CROSSCOMPILING)
 138         gmx_detect_acceleration(GMX_SUGGESTED_CPU_ACCELERATION)
 139     endif(CMAKE_CROSSCOMPILING)
 140 endif(NOT DEFINED GMX_CPU_ACCELERATION)
 141
 142 set(GMX_CPU_ACCELERATION "@GMX_SUGGESTED_CPU_ACCELERATION@"
 143     CACHE STRING "Accelerated CPU kernels. Pick one of: None, SSE2, SSE4.1, AVX_128_FMA, AVX_256, IBM_QPX")
 144
 145 set(GMX_FFT_LIBRARY "fftw3"
 146     CACHE STRING "FFT library choices: fftw3,mkl,fftpack[built-in]")
 147 option(GMX_BUILD_OWN_FFTW "Download and build FFTW 3 during the GROMACS build process, rather than fall back on the really slow fftpack." OFF)
 148 mark_as_advanced(GMX_BUILD_OWN_FFTW)
 149 option(GMX_DISABLE_FFTW_MEASURE
 150        "Do not optimize FFTW setups (not needed with SSE)" OFF)
 151 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 152 set(GMX_QMMM_PROGRAM "none"
 153     CACHE STRING "QM package choices: none,gaussian,mopac,gamess,orca")
 154 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 155 mark_as_advanced(GMX_BROKEN_CALLOC)
 156 option(GMX_MPI_IN_PLACE "Enable MPI_IN_PLACE for MPIs that have it defined" ON)
 157 mark_as_advanced(GMX_MPI_IN_PLACE)
 158 option(GMX_LOAD_PLUGINS "Compile with plugin support, needed to read VMD supported file formats" ON)
 159 mark_as_advanced(GMX_LOAD_PLUGINS)
 160
 161 option(GMX_GPU  "Enable GPU acceleration" ON)
 162 option(GMX_OPENMP "Enable OpenMP-based multithreading" ON)
 163
 164 option(GMX_GIT_VERSION_INFO "Generate git version information" ${SOURCE_IS_GIT_REPOSITORY})
 165 mark_as_advanced(GMX_GIT_VERSION_INFO)
 166
 167 option(GMX_DEFAULT_SUFFIX "Use default suffixes for GROMACS binaries and libs (_d for double, _mpi for MPI; rerun cmake after changing to see relevant options)" ON)
 168 if(UNIX)
 169     option(GMX_SYMLINK_OLD_BINARY_NAMES "Create symbolic links for pre-5.0 binary names" ON)
 170 endif()
 171
 172 if(UNIX)
 173     option(GMX_PREFER_STATIC_LIBS "When finding libraries prefer static archives (not available on non-*nix platforms and it will only work if static versions of external dependencies are available and found)!" OFF)
 174     mark_as_advanced(GMX_PREFER_STATIC_LIBS)
 175 endif()
 176
 177 option(GMX_CYCLE_SUBCOUNTERS "Enable cycle subcounters to get a more detailed cycle timings" OFF)
 178 mark_as_advanced(GMX_CYCLE_SUBCOUNTERS)
 179
 180 option(GMX_SKIP_DEFAULT_CFLAGS "Don't automatically add suggested/required Compiler flags." OFF)
 181 mark_as_advanced(GMX_SKIP_DEFAULT_CFLAGS)
 182
 183 ######################################################################
 184 # Compiler tests
 185 # These need to be done early (before further tests).
 186 #####################################################################
 187
 188 # The cmake/Check{C,CXX}CompilerFlag.cmake files in the GROMACS distribution
 189 # are used with permission from CMake v2.8.9 so that GROMACS can detect
 190 # invalid options with the Intel Compilers.
 191 # These files should be removed from the source tree when a CMake version that
 192 # includes the features in question becomes required for building GROMACS.
 193 include(CheckCCompilerFlag)
 194 include(CheckCXXCompilerFlag)
 195
 196 # Get compiler version information, needs to be done early as check that depend
 197 # on compiler verison follow below.
 198 include(gmxGetCompilerInfo)
 199 get_compiler_version()
 200
 201 # First exclude compilers known to not work with OpenMP although claim to support it:
 202 # gcc 4.2.1 and gcc-llvm 4.2.1 (also claims to be 4.2.1) on Mac OS X
 203 # This fixes redmine 900 and needs to run before OpenMP flags are set below.
 204 if (CMAKE_SYSTEM_NAME STREQUAL "Darwin" AND
 205     (CMAKE_COMPILER_IS_GNUCC AND C_COMPILER_VERSION AND C_COMPILER_VERSION VERSION_LESS 4.3))
 206     message(STATUS "OpenMP multithreading not supported with gcc/llvm-gcc 4.2 on Mac OS X, disabled")
 207     set(GMX_OPENMP OFF CACHE BOOL
 208         "OpenMP multithreading not not supported with gcc/llvm-gcc 4.2 on Mac OS X, disabled!" FORCE)
 209 endif()
 210
 211 # OpenMP check must come before other CFLAGS!
 212 if(GMX_OPENMP)
 213     find_package(OpenMP)
 214     if(OPENMP_FOUND)
 215         # CMake on Windows doesn't support linker flags passed to target_link_libraries
 216         # (i.e. it treats /openmp as \openmp library file). Also, no OpenMP linker flags are needed.
 217         if(NOT (WIN32 AND NOT CYGWIN))
 218             if(CMAKE_COMPILER_IS_GNUCC AND GMX_PREFER_STATIC_OPENMP AND NOT APPLE)
 219                 set(OpenMP_LINKER_FLAGS "-Wl,-static -lgomp -lrt -Wl,-Bdynamic -lpthread")
 220                 set(OpenMP_SHARED_LINKER_FLAGS "")
 221             else()
 222                 # Only set a linker flag if the user didn't set them manually
 223                 if(NOT DEFINED OpenMP_LINKER_FLAGS)
 224                     set(OpenMP_LINKER_FLAGS "${OpenMP_C_FLAGS}")
 225                 endif()
 226                 if(NOT DEFINED OpenMP_SHARED_LINKER_FLAGS)
 227                     set(OpenMP_SHARED_LINKER_FLAGS "${OpenMP_C_FLAGS}")
 228                 endif()
 229             endif()
 230         endif()
 231     else(OPENMP_FOUND)
 232         message(WARNING
 233                 "The compiler you are using does not support OpenMP parallelism. This might hurt your performance a lot, in particular with GPUs. Try using a more recent version, or a different compiler. For now, we are proceeding by turning off OpenMP.")
 234         set(GMX_OPENMP OFF CACHE STRING "Whether GROMACS will use OpenMP parallelism." FORCE)
 235     endif(OPENMP_FOUND)
 236 endif()
 237
 238
 239 include(gmxCFlags)
 240 gmx_c_flags()
 241
 242 # gcc 4.4.x is buggy and crashes when compiling some files with O3 and OpenMP on.
 243 # Detect here whether applying a workaround is needed and will apply it later
 244 # on the affected files.
 245 include(gmxGCC44O3BugWorkaround)
 246 gmx_check_gcc44_bug_workaround_needed(GMX_USE_GCC44_BUG_WORKAROUND)
 247
 248 # clang 3.0 is buggy for some unknown reason detected during adding
 249 # the SSE2 group kernels for GROMACS 4.6. If we ever work out what
 250 # that is, we should replace these tests with a compiler feature test,
 251 # update GROMACS Redmine task #1039 and perhaps report a clang bug.
 252 #
 253 # In the meantime, until we require CMake 2.8.10 we cannot rely on it to detect
 254 # the compiler version for us. So we need a manual check for clang 3.0.
 255 include(gmxDetectClang30)
 256 gmx_detect_clang_3_0(COMPILER_IS_CLANG_3_0)
 257 if(COMPILER_IS_CLANG_3_0)
 258     message(FATAL_ERROR "Your compiler is clang version 3.0, which is known to be buggy for GROMACS. Use a different compiler.")
 259 endif()
 260
 261 if (CMAKE_C_COMPILER_ID STREQUAL "PGI")
 262     message(WARNING "All tested PGI compiler versions (up to 12.9.0) generate binaries which produce incorrect results, or even fail to compile Gromacs. Highly recommended to use a different compiler. If you choose to use PGI, make sure to run the regressiontests.")
 263 endif()
 264
 265 if(CMAKE_C_COMPILER_ID MATCHES "Intel" AND C_COMPILER_VERSION VERSION_LESS "12.0.0")
 266     message(WARNING "Intel compilers before 12.0.0 are not routinely tested, so there may be problems. Version 11.1 with SSE4.1 is known to produce incorrect results. It is highly recommended to use a more up-to-date compiler. If you choose to use this version, make sure you run the regressiontests.")
 267 endif()
 268
 269 ########################################################################
 270 # Set up binary and library suffixing
 271 ########################################################################
 272 set(GMX_BINARY_SUFFIX "" CACHE STRING "Suffix for GROMACS binaries (default: _d for double, _mpi for MPI, _mpi_d for MPI and double).")
 273 set(GMX_LIBS_SUFFIX ""
 274   CACHE STRING "Suffix for GROMACS libs (default: _d for double, _mpi for MPI, _mpi_d for MPI and double).")
 275 if (GMX_DEFAULT_SUFFIX)
 276   set(GMX_BINARY_SUFFIX "")
 277   set(GMX_LIBS_SUFFIX "")
 278   if (GMX_MPI)
 279     set(GMX_BINARY_SUFFIX "_mpi")
 280     set(GMX_LIBS_SUFFIX "_mpi")
 281   endif(GMX_MPI)
 282   if (GMX_DOUBLE)
 283     set (GMX_BINARY_SUFFIX "${GMX_BINARY_SUFFIX}_d")
 284     set (GMX_LIBS_SUFFIX "${GMX_LIBS_SUFFIX}_d")
 285   endif(GMX_DOUBLE)
 286   mark_as_advanced(FORCE GMX_BINARY_SUFFIX GMX_LIBS_SUFFIX)
 287   if (NOT SUFFIX_QUIETLY)
 288     message(STATUS "Using default binary suffix: \"${GMX_BINARY_SUFFIX}\"")
 289     message(STATUS "Using default library suffix: \"${GMX_LIBS_SUFFIX}\"")
 290   endif (NOT SUFFIX_QUIETLY)
 291 else(GMX_DEFAULT_SUFFIX)
 292   mark_as_advanced(CLEAR GMX_BINARY_SUFFIX GMX_LIBS_SUFFIX)
 293   if (NOT SUFFIX_QUIETLY)
 294     message(STATUS "Using manually set binary suffix: \"${GMX_BINARY_SUFFIX}\"")
 295     message(STATUS "Using manually set library suffix: \"${GMX_LIBS_SUFFIX}\"")
 296   endif (NOT SUFFIX_QUIETLY)
 297 endif(GMX_DEFAULT_SUFFIX)
 298 set(SUFFIX_QUIETLY TRUE CACHE INTERNAL "")
 299
 300 set(PKG_CFLAGS "")
 301 if(GMX_DOUBLE)
 302     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_DOUBLE")
 303 endif(GMX_DOUBLE)
 304 if(GMX_SOFTWARE_INVSQRT)
 305   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_SOFTWARE_INVSQRT")
 306 endif(GMX_SOFTWARE_INVSQRT)
 307
 308
 309
 310 ########################################################################
 311 # Basic system tests (standard libraries, headers, functions, types)   #
 312 ########################################################################
 313 include(CheckIncludeFiles)
 314 include(CheckIncludeFileCXX)
 315 check_include_files(unistd.h     HAVE_UNISTD_H)
 316 check_include_files(pwd.h        HAVE_PWD_H)
 317 check_include_files(pthread.h    HAVE_PTHREAD_H)
 318 check_include_files(dirent.h     HAVE_DIRENT_H)
 319 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 320 check_include_files(io.h                 HAVE_IO_H)
 321 check_include_files(sched.h      HAVE_SCHED_H)
 322
 323 check_include_files(regex.h      HAVE_POSIX_REGEX)
 324 check_include_file_cxx(regex     HAVE_CXX11_REGEX)
 325 # TODO: It could be nice to inform the user if no regex support is found,
 326 # as selections won't be fully functional.
 327
 328 include(CheckFunctionExists)
 329 check_function_exists(strdup            HAVE_STRDUP)
 330 check_function_exists(posix_memalign    HAVE_POSIX_MEMALIGN)
 331 check_function_exists(memalign          HAVE_MEMALIGN)
 332 check_function_exists(_aligned_malloc   HAVE__ALIGNED_MALLOC)
 333 check_function_exists(gettimeofday      HAVE_GETTIMEOFDAY)
 334 check_function_exists(fsync             HAVE_FSYNC)
 335 check_function_exists(_fileno           HAVE__FILENO)
 336 check_function_exists(fileno            HAVE_FILENO)
 337 check_function_exists(_commit           HAVE__COMMIT)
 338 check_function_exists(sigaction         HAVE_SIGACTION)
 339 check_function_exists(sysconf           HAVE_SYSCONF)
 340 check_function_exists(sched_setaffinity HAVE_SCHED_SETAFFINITY)
 341 check_function_exists(sched_getaffinity HAVE_SCHED_GETAFFINITY)
 342 check_function_exists(rsqrt             HAVE_RSQRT)
 343 check_function_exists(rsqrtf            HAVE_RSQRTF)
 344 check_function_exists(sqrtf             HAVE_SQRTF)
 345
 346 include(CheckLibraryExists)
 347 check_library_exists(m sqrt "" HAVE_LIBM)
 348 check_library_exists(m cbrt "" HAVE_CBRT)
 349
 350
 351 include(CheckTypeSize)
 352
 353 check_type_size("int"           SIZEOF_INT)
 354 check_type_size("long int"      SIZEOF_LONG_INT)
 355 check_type_size("long long int" SIZEOF_LONG_LONG_INT)
 356 check_type_size("off_t"         SIZEOF_OFF_T)
 357 check_type_size("void *"        SIZEOF_VOIDP)
 358
 359 if (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 360     set(GMX_64_BIT TRUE)
 361 else (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 362     set(GMX_64_BIT FALSE)
 363 endif (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 364
 365 include(TestBigEndian)
 366 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 367
 368
 369 if(APPLE OR CYGWIN OR ${CMAKE_SYSTEM_NAME} MATCHES "Linux|.*BSD")
 370     # Maybe Solaris should be here? Patch this if you know!
 371     SET(SHARED_LIBS_DEFAULT ON)
 372 elseif(WIN32 OR ${CMAKE_SYSTEM_NAME} MATCHES "BlueGene")
 373     # Support for shared libs on native Windows is a bit new. Its
 374     # default might change later if/when we sort things out. Also,
 375     # Cray should go here. What variable value can detect it?
 376     SET(SHARED_LIBS_DEFAULT OFF)
 377 else()
 378     message(STATUS "Defaulting to building static libraries")
 379     SET(SHARED_LIBS_DEFAULT OFF)
 380 endif()
 381
 382 # Management of GROMACS options for specific toolchains should go
 383 # here. Because the initial settings for some of the main options have
 384 # already happened, but things like library detection and MPI compiler
 385 # feature detection have not, the docstrings for any over-rides of
 386 # GROMACS defaults or user settings will make sense. Also, any
 387 # toolchain-related reasons for choosing whether to detect various
 388 # things can be sorted out now, before the detection takes place.
 389 if(${CMAKE_SYSTEM_NAME} MATCHES BlueGene)
 390     include(gmxManageBlueGene)
 391 endif()
 392
 393 if(UNIX AND GMX_PREFER_STATIC_LIBS AND SHARED_LIBS_DEFAULT)
 394     if(BUILD_SHARED_LIBS)
 395         # Warn the user about the combination. But don't overwrite the request.
 396         message(WARNING "Searching for static libraries requested, and building shared Gromacs libraries requested. This might cause problems linking later.")
 397     elseif(NOT DEFINED BUILD_SHARED_LIBS)
 398         # Change default to OFF. Don't warn if it's already off.
 399         message(WARNING "Searching for static libraries requested, so the GROMACS libraries will also be built statically (BUILD_SHARED_LIBS=OFF)")
 400         set(SHARED_LIBS_DEFAULT OFF)
 401     endif()
 402 endif()
 403
 404 # By now, all tool chains should have spoken up if they care about
 405 # the setting of SHARED_LIBS_DEFAULT.
 406 option(BUILD_SHARED_LIBS "Enable shared libraries (can be problematic e.g. with MPI, or on some HPC systems)" ${SHARED_LIBS_DEFAULT})
 407
 408 ########################################################################
 409 #Process MPI settings
 410 ########################################################################
 411 include(gmxManageMPI)
 412
 413 ########################################################################
 414 # Find external packages                                               #
 415 ########################################################################
 416 if(UNIX AND GMX_PREFER_STATIC_LIBS)
 417     # On Linux .a is the static library suffix, on Mac OS X .lib can also
 418     # be used, so we'll add both to the preference list.
 419     SET(CMAKE_FIND_LIBRARY_SUFFIXES ".lib;.a" ${CMAKE_FIND_LIBRARY_SUFFIXES})
 420 endif()
 421
 422 IF( WIN32 AND NOT CYGWIN)
 423   # This makes windows.h not declare min/max as macros that would break
 424   # C++ code using std::min/std::max.
 425   add_definitions(-DNOMINMAX)
 426
 427   if (NOT BUILD_SHARED_LIBS)
 428       option(GMX_PREFER_STATIC_LIBS "When finding libraries prefer static system libraries (MT instead of MD)!" ON)
 429       if(NOT GMX_PREFER_STATIC_LIBS)
 430           message(WARNING "Shared system libraries requested, and static Gromacs libraries requested.")
 431       endif()
 432   else()
 433       message(FATAL_ERROR "BUILD_SHARED_LIBS not yet working for Windows in the master branch")
 434       option(GMX_PREFER_STATIC_LIBS "When finding libraries prefer static system libraries (MT instead of MD)!" OFF)
 435       if(GMX_PREFER_STATIC_LIBS)
 436           #this combination segfaults (illigal passing of file handles)
 437           message(FATAL_ERROR "Static system libraries requested, and shared Gromacs libraries requested.")
 438       endif()
 439       add_definitions(-DUSE_VISIBILITY -DTMPI_USE_VISIBILITY)
 440       set(PKG_CFLAGS "$PKG_CFLAGS -DUSE_VISIBILITY -DTMPI_USE_VISIBILITY")
 441   endif()
 442   mark_as_advanced(GMX_PREFER_STATIC_LIBS)
 443
 444   IF (GMX_PREFER_STATIC_LIBS)
 445       #Only setting Debug and Release flags. Others configurations are current not used.
 446       STRING(REPLACE /MD /MT CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE})
 447       STRING(REPLACE /MD /MT CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG})
 448       if(CMAKE_CXX_COMPILER_LOADED)
 449           STRING(REPLACE /MD /MT CMAKE_CXX_FLAGS_RELEASE ${CMAKE_CXX_FLAGS_RELEASE})
 450           STRING(REPLACE /MD /MT CMAKE_CXX_FLAGS_DEBUG ${CMAKE_CXX_FLAGS_DEBUG})
 451       endif()
 452   ENDIF()
 453   IF( CMAKE_C_COMPILER_ID MATCHES "Intel" )
 454     if(BUILD_SHARED_LIBS) #not sure why incremental building with shared libs doesn't work
 455         STRING(REPLACE "/INCREMENTAL:YES" "" CMAKE_SHARED_LINKER_FLAGS ${CMAKE_SHARED_LINKER_FLAGS})
 456     endif()
 457   ENDIF()
 458 ENDIF()
 459
 460 option(GMX_XML "Use libxml2 to parse xml files" ON)
 461 if (GMX_XML)
 462   find_package(LibXml2)
 463   set(PKG_XML "")
 464   if(LIBXML2_FOUND)
 465     include_directories(${LIBXML2_INCLUDE_DIR})
 466     set(PKG_XML libxml-2.0)
 467     set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 468   endif(LIBXML2_FOUND)
 469 endif(GMX_XML)
 470
 471 option(GMX_GSL "Add support for gsl" OFF)
 472 if (GMX_GSL)
 473   find_package(GSL)
 474   set(PKG_GSL "")
 475   if(GSL_FOUND)
 476     include_directories(${GSL_INCLUDE_DIR})
 477     set(PKG_GSL gsl)
 478     set(HAVE_LIBGSL 1)
 479   endif(GSL_FOUND)
 480 endif (GMX_GSL)
 481
 482 option(GMX_X11 "Use X window system" OFF)
 483 if (GMX_X11)
 484         find_package(X11)
 485         # X11 includes/libraries are only set in the ngmx subdirectory!
 486         if(X11_FOUND)
 487         set(HAVE_X11 1)
 488         endif(X11_FOUND)
 489 endif(GMX_X11)
 490
 491 include(ThreadMPI)
 492 set(THREAD_MPI_LIB thread_mpi)
 493 if(GMX_THREAD_MPI)
 494     tmpi_get_source_list(THREAD_MPI_SRC CXX)
 495     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_THREAD_MPI")
 496     set(GMX_MPI 1)
 497 else(GMX_THREAD_MPI)
 498     tmpi_get_source_list(THREAD_MPI_SRC CXX NOMPI)
 499 endif(GMX_THREAD_MPI)
 500
 501 if(GMX_GPU)
 502     # now that we have detected the dependencies, do the second configure pass
 503     gmx_gpu_setup()
 504 endif(GMX_GPU)
 505
 506 if(APPLE)
 507    find_library(ACCELERATE_FRAMEWORK Accelerate)
 508    list(APPEND GMX_EXTRA_LIBRARIES ${ACCELERATE_FRAMEWORK})
 509 endif(APPLE)
 510
 511 if(CYGWIN)
 512     set(GMX_CYGWIN 1)
 513 endif(CYGWIN)
 514
 515 if(WIN32 AND NOT CYGWIN)
 516     set(GMX_NATIVE_WINDOWS 1)
 517 endif()
 518
 519 # only bother with finding git and using version.h if the source is a git repo
 520 if(GMX_GIT_VERSION_INFO)
 521     if (NOT SOURCE_IS_GIT_REPOSITORY)
 522         message(FATAL_ERROR
 523             "Cannot generate git version information from source tree not under git. "
 524             "Set GMX_GIT_VERSION_INFO=OFF to proceed.")
 525     endif ()
 526     # We need at least git v1.5.3 be able to parse git's date output. If not
 527     # found or the version is too small, we can't generate version information.
 528     find_package(Git)
 529
 530     # Find out the git version
 531     if(GIT_FOUND AND NOT GIT_VERSION)
 532       execute_process(COMMAND ${GIT_EXECUTABLE} "--version"
 533         OUTPUT_VARIABLE _exec_out
 534         OUTPUT_STRIP_TRAILING_WHITESPACE)
 535       string(REGEX REPLACE "git version (.*)" "\\1" GIT_VERSION ${_exec_out})
 536       set(GIT_VERSION ${GIT_VERSION} CACHE STRING "Git version")
 537       mark_as_advanced(GIT_VERSION)
 538     endif()
 539
 540     if(NOT GIT_FOUND OR GIT_VERSION VERSION_LESS "1.5.3")
 541         message(FATAL_ERROR
 542             "No compatible git version found (>= 1.5.3 required). "
 543             "Won't be able to generate development version information. "
 544             "Set GMX_GIT_VERSION_INFO=OFF to proceed.")
 545     endif()
 546 endif()
 547
 548 option(GMX_INTERNAL_BOOST "Use minimal internal version of boost" OFF)
 549 if ( NOT GMX_INTERNAL_BOOST )
 550   find_package( Boost 1.44.0 )
 551 else ( NOT GMX_INTERNAL_BOOST )
 552   set (Boost_FOUND FALSE)
 553 endif( NOT GMX_INTERNAL_BOOST )
 554
 555 if(Boost_FOUND AND NOT Boost_VERSION VERSION_LESS "104400" )
 556   include_directories(${Boost_INCLUDE_DIRS})
 557 else()
 558   if(NOT BOOST_QUIETLY)
 559     message("Boost >= 1.44 not found. Using minimal internal version. Not recommended if GROMACS is used as library!")
 560   endif()
 561   include_directories(${CMAKE_SOURCE_DIR}/src/external/boost)
 562   add_definitions( -DBOOST_NO_TYPEID )  #TYPEID not supported for minimal internal version (would add significant more code)
 563   # TODO: Propagate the above settings to the installed CMakeFiles.txt template
 564   # (from share/template/)
 565   # TODO: Reorder stuff such that INCL_INSTALL_DIR could be used here
 566   set(PKG_CFLAGS "${PKG_CFLAGS} -DBOOST_NO_TYPEID -I${GMX_INSTALL_PREFIX}include/gromacs/external/boost")
 567   install(DIRECTORY ${CMAKE_SOURCE_DIR}/src/external/boost/boost
 568           DESTINATION ${GMX_INSTALL_PREFIX}include/gromacs/external/boost
 569           COMPONENT development)
 570 endif()
 571 set(BOOST_QUIETLY TRUE CACHE INTERNAL "")
 572
 573 if (LIBXML2_FOUND)
 574     option(GMX_BUILD_UNITTESTS "Build unit tests with BUILD_TESTING (uses Google C++ Testing and Mocking Frameworks, requires libxml2)" ON)
 575 else (LIBXML2_FOUND)
 576     set(GMX_BUILD_UNITTESTS OFF)
 577 endif (LIBXML2_FOUND)
 578 mark_as_advanced(GMX_BUILD_UNITTESTS)
 579 set(MEMORYCHECK_SUPPRESSIONS_FILE ${CMAKE_SOURCE_DIR}/cmake/legacy_and_external.supp)
 580
 581 ########################################################################
 582 # Generate development version info for cache
 583 ########################################################################
 584 # set(GEN_VERSION_INFO_INTERNAL "ON")
 585 # include(gmxGenerateVersionString)
 586
 587 ########################################################################
 588 # Our own GROMACS tests
 589 ########################################################################
 590
 591 add_definitions( -DHAVE_CONFIG_H )
 592 include_directories(${CMAKE_SOURCE_DIR}/src)
 593 # Required for config.h, maybe should only be set in src/CMakeLists.txt
 594 include_directories(${CMAKE_BINARY_DIR}/src)
 595 # Required for gmx_header_config_gen.h to be found before installation
 596 include_directories(${CMAKE_BINARY_DIR}/src/gromacs/utility)
 597 # Required for now to make old code compile
 598 include_directories(${CMAKE_SOURCE_DIR}/src/gromacs/legacyheaders)
 599
 600 include(gmxTestInlineASM)
 601 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 602
 603 include(gmxSetBuildInformation)
 604 gmx_set_build_information()
 605 if(BUILD_CPU_FEATURES MATCHES "rdtscp" AND NOT GMX_DISTRIBUTABLE_BUILD)
 606     # The timestep counter headers do not include config.h
 607     add_definitions(-DHAVE_RDTSCP)
 608 endif(BUILD_CPU_FEATURES MATCHES "rdtscp" AND NOT GMX_DISTRIBUTABLE_BUILD)
 609
 610 include(gmxTestFloatFormat)
 611 gmx_test_float_format(GMX_FLOAT_FORMAT_IEEE754
 612                       GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER
 613                       GMX_IEEE754_BIG_ENDIAN_WORD_ORDER)
 614
 615 include(gmxTestLargeFiles)
 616 gmx_test_large_files(GMX_LARGEFILES)
 617
 618 include(gmxTestSignal)
 619 gmx_test_sigusr1(HAVE_SIGUSR1)
 620
 621 include(gmxTestInline)
 622 gmx_test_inline(INLINE_KEYWORD)
 623
 624 include(gmxTestRestrict)
 625 gmx_test_restrict(RESTRICT_KEYWORD)
 626
 627 include(gmxTestPipes)
 628 gmx_test_pipes(HAVE_PIPES)
 629
 630 include(gmxTestIsfinite)
 631 gmx_test_isfinite(HAVE_ISFINITE)
 632 gmx_test__isfinite(HAVE__ISFINITE)
 633 gmx_test__finite(HAVE__FINITE)
 634
 635 include(gmxTestCXX11)
 636 gmx_test_cxx11(GMX_CXX11 GMX_CXX11_FLAGS)
 637 if(CXX11_FLAG AND GMX_GPU)
 638     #FIXME: add proper solution for progate all but cxx11 flag
 639     set(CUDA_PROPAGATE_HOST_FLAGS no)
 640     message(WARNING "Please manually add compiler flags to CUDA_NVCC_FLAGS. Automatic propogation temporary not working.")
 641 endif()
 642
 643 include(gmxTestXDR)
 644 gmx_test_xdr(GMX_SYSTEM_XDR)
 645 if(NOT GMX_SYSTEM_XDR)
 646     set(GMX_INTERNAL_XDR 1)
 647     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_INTERNAL_XDR")
 648 endif(NOT GMX_SYSTEM_XDR)
 649
 650 # include avx test source, used if the AVX flags are set below
 651 include(gmxTestAVXMaskload)
 652
 653 # Process nonbonded accelerated kernels settings
 654 #
 655 # Note that for the backward-compatible x86 SIMD architectures, the
 656 # GMX_CPU_ACCELERATION determines the maximum level of the instruction
 657 # set used (e.g. GMX_CPU_ACCLERATION=SSE4.1 implies
 658 # SSE2). Accordingly, there are a set of CMake variables
 659 # GMX_<arch>_<feature-set> that are exported to the C code to specify
 660 # CPU features that should be used. This means that the logic for
 661 # requiring such backward compatibility is all located here.
 662 string(TOUPPER ${GMX_CPU_ACCELERATION} GMX_CPU_ACCELERATION)
 663 if(${GMX_CPU_ACCELERATION} STREQUAL "NONE")
 664     # nothing to do
 665 elseif(${GMX_CPU_ACCELERATION} STREQUAL "SSE2")
 666
 667     GMX_TEST_CFLAG(GNU_SSE2_CFLAG "-msse2" ACCELERATION_C_FLAGS)
 668     if(NOT GNU_SSE2_CFLAG AND GMX_NATIVE_WINDOWS)
 669         GMX_TEST_CFLAG(MSVC_SSE2_CFLAG "/arch:SSE2" ACCELERATION_C_FLAGS)
 670     endif(NOT GNU_SSE2_CFLAG AND GMX_NATIVE_WINDOWS)
 671
 672     GMX_TEST_CXXFLAG(GNU_SSE2_CXXFLAG "-msse2" ACCELERATION_CXX_FLAGS)
 673     if(NOT GNU_SSE2_CXXFLAG AND GMX_NATIVE_WINDOWS)
 674         GMX_TEST_CXXFLAG(MSVC_SSE2_CXXFLAG "/arch:SSE2" ACCELERATION_CXX_FLAGS)
 675     endif(NOT GNU_SSE2_CXXFLAG AND GMX_NATIVE_WINDOWS)
 676
 677     # We dont warn for lacking SSE2 flag support, since that is probably standard today.
 678
 679     # Only test the include after we have tried to add the correct flag for SSE2 support
 680     check_include_file(emmintrin.h  HAVE_EMMINTRIN_H ${ACCELERATION_C_FLAGS})
 681
 682     if(NOT HAVE_EMMINTRIN_H)
 683         message(FATAL_ERROR "Cannot find emmintrin.h, which is required for SSE2 intrinsics support.")
 684     endif(NOT HAVE_EMMINTRIN_H)
 685
 686     set(GMX_CPU_ACCELERATION_X86_SSE2 1)
 687     # The user should not be able to set this orthogonally to the acceleration
 688     set(GMX_X86_SSE2 1)
 689     if (NOT ACCELERATION_QUIETLY)
 690       message(STATUS "Enabling SSE2 Gromacs acceleration, and it will help compiler optimization.")
 691     endif()
 692
 693 elseif(${GMX_CPU_ACCELERATION} STREQUAL "SSE4.1")
 694
 695     GMX_TEST_CFLAG(GNU_SSE4_CFLAG "-msse4.1" ACCELERATION_C_FLAGS)
 696     if (NOT GNU_SSE4_CFLAG AND GMX_NATIVE_WINDOWS)
 697         GMX_TEST_CFLAG(MSVC_SSE4_CFLAG "/arch:SSE4.1" ACCELERATION_C_FLAGS)
 698     endif(NOT GNU_SSE4_CFLAG AND GMX_NATIVE_WINDOWS)
 699     if (NOT GNU_SSE4_CFLAG AND NOT MSVC_SSE4_CFLAG)
 700         # Not surprising if we end up here! MSVC current does not support the SSE4.1 flag. However, it appears to accept SSE4.1
 701         # intrinsics when SSE2 support is enabled, so we try that instead first.
 702         if (GMX_NATIVE_WINDOWS)
 703             GMX_TEST_CFLAG(MSVC_SSE2_CFLAG "/arch:SSE2" ACCELERATION_C_FLAGS)
 704             message(WARNING "Neither SSE4.1 or SSE2 seems to be supported by your Windows compiler. Something is likely broken.")
 705         else()
 706             message(WARNING "No C SSE4.1 flag found. Consider a newer compiler, or use SSE2 for slightly lower performance")
 707         endif()
 708     endif(NOT GNU_SSE4_CFLAG AND NOT MSVC_SSE4_CFLAG)
 709
 710     GMX_TEST_CXXFLAG(GNU_SSE4_CXXFLAG "-msse4.1" ACCELERATION_CXX_FLAGS)
 711     if (NOT GNU_SSE4_CXXFLAG AND GMX_NATIVE_WINDOWS)
 712         GMX_TEST_CXXFLAG(MSVC_SSE4_CXXFLAG "/arch:SSE4.1" ACCELERATION_CXX_FLAGS)
 713     endif(NOT GNU_SSE4_CXXFLAG AND GMX_NATIVE_WINDOWS)
 714     if (NOT GNU_SSE4_CXXFLAG AND NOT MSVC_SSE4_CXXFLAG)
 715         message(WARNING "No C++ SSE4.1 flag found. Consider a newer compiler, or use SSE2 for slightly lower performance.")
 716         # Not surprising if we end up here! MSVC current does not support the SSE4.1 flag. However, it appears to accept SSE4.1
 717         # intrinsics when SSE2 support is enabled, so we try that instead.
 718         if (GMX_NATIVE_WINDOWS)
 719             GMX_TEST_CXXFLAG(MSVC_SSE2_CXXFLAG "/arch:SSE2" ACCELERATION_CXX_FLAGS)
 720         endif()
 721     endif(NOT GNU_SSE4_CXXFLAG AND NOT MSVC_SSE4_CXXFLAG)
 722
 723     # This must come after we have added the -msse4.1 flag on some platforms.
 724     check_include_file(smmintrin.h  HAVE_SMMINTRIN_H ${ACCELERATION_C_FLAGS})
 725
 726     if(NOT HAVE_SMMINTRIN_H)
 727         message(FATAL_ERROR "Cannot find smmintrin.h, which is required for SSE4.1 intrinsics support.")
 728     endif(NOT HAVE_SMMINTRIN_H)
 729
 730     set(GMX_CPU_ACCELERATION_X86_SSE4_1 1)
 731     # The user should not be able to set this orthogonally to the acceleration
 732     set(GMX_X86_SSE4_1 1)
 733     set(GMX_X86_SSE2   1)
 734     if (NOT ACCELERATION_QUIETLY)
 735       message(STATUS "Enabling SSE4.1 Gromacs acceleration, and it will help compiler optimization.")
 736     endif()
 737
 738     if(CMAKE_C_COMPILER_ID MATCHES "Intel" AND C_COMPILER_VERSION VERSION_EQUAL "11.1")
 739         message(FATAL_ERROR "You are using Intel compiler version 11.1, and that compiler is known to produce incorrect results with SSE4.1 acceleration. You need to use another compiler (e.g. icc 12 or newer) or different acceleration (probably slower simulations).")
 740     endif()
 741 elseif(${GMX_CPU_ACCELERATION} STREQUAL "AVX_128_FMA" OR ${GMX_CPU_ACCELERATION} STREQUAL "AVX_256")
 742
 743     # Set the AVX compiler flag for both these choices!
 744
 745     GMX_TEST_CFLAG(GNU_AVX_CFLAG "-mavx" ACCELERATION_C_FLAGS)
 746     if (NOT GNU_AVX_CFLAG AND GMX_NATIVE_WINDOWS)
 747         GMX_TEST_CFLAG(MSVC_AVX_CFLAG "/arch:AVX" ACCELERATION_C_FLAGS)
 748     endif (NOT GNU_AVX_CFLAG AND GMX_NATIVE_WINDOWS)
 749     if (NOT GNU_AVX_CFLAG AND NOT MSVC_AVX_CFLAG)
 750         message(WARNING "No C AVX flag found. Consider a newer compiler, or try SSE4.1 (lower performance).")
 751     endif (NOT GNU_AVX_CFLAG AND NOT MSVC_AVX_CFLAG)
 752
 753     GMX_TEST_CXXFLAG(GNU_AVX_CXXFLAG "-mavx" ACCELERATION_CXX_FLAGS)
 754     if (NOT GNU_AVX_CXXFLAG AND GMX_NATIVE_WINDOWS)
 755         GMX_TEST_CXXFLAG(MSVC_AVX_CXXFLAG "/arch:AVX" ACCELERATION_CXX_FLAGS)
 756     endif (NOT GNU_AVX_CXXFLAG AND GMX_NATIVE_WINDOWS)
 757     if (NOT GNU_AVX_CXXFLAG AND NOT MSVC_AVX_CXXFLAG)
 758        message(WARNING "No C++ AVX flag found. Consider a newer compiler, or try SSE4.1 (lower performance).")
 759     endif (NOT GNU_AVX_CXXFLAG AND NOT MSVC_AVX_CXXFLAG)
 760
 761     # Set the FMA4 flags (MSVC doesn't require any)
 762     if(${GMX_CPU_ACCELERATION} STREQUAL "AVX_128_FMA" AND NOT MSVC)
 763         if (${CMAKE_COMPILER_ID} MATCHES "Clang")
 764             message(FATAL_ERROR "Clang up to at least version 3.2 produces incorrect code for AVX_128_FMA. Sorry, but you will have to select a different compiler or acceleration.")
 765         endif()
 766         GMX_TEST_CFLAG(GNU_FMA_CFLAG "-mfma4" ACCELERATION_C_FLAGS)
 767         if (NOT GNU_FMA_CFLAG)
 768             message(WARNING "No C FMA4 flag found. Consider a newer compiler, or try SSE4.1 (lower performance).")
 769         endif(NOT GNU_FMA_CFLAG)
 770         GMX_TEST_CFLAG(GNU_XOP_CFLAG "-mxop" ACCELERATION_C_FLAGS)
 771         # No big deal if we do not have xop, so no point yelling warnings about it.
 772         if (CMAKE_CXX_COMPILER_LOADED)
 773             GMX_TEST_CXXFLAG(GNU_FMA_CXXFLAG "-mfma4" ACCELERATION_CXX_FLAGS)
 774             if (NOT GNU_FMA_CXXFLAG)
 775                 message(WARNING "No C++ FMA flag found. Consider a newer compiler, or try SSE4.1 (lower performance).")
 776             endif (NOT GNU_FMA_CXXFLAG)
 777             GMX_TEST_CXXFLAG(GNU_XOP_CXXFLAG "-mxop" ACCELERATION_CXX_FLAGS)
 778             # No big deal if we do not have xop, so no point yelling warnings about it.
 779         endif()
 780     endif()
 781
 782     # Only test the header after we have tried to add the flag for AVX support
 783     check_include_file(immintrin.h  HAVE_IMMINTRIN_H ${ACCELERATION_C_FLAGS})
 784
 785     if(NOT HAVE_IMMINTRIN_H)
 786         message(FATAL_ERROR "Cannot find immintrin.h, which is required for AVX intrinsics support. Consider switching compiler.")
 787     endif(NOT HAVE_IMMINTRIN_H)
 788
 789     if(${GMX_CPU_ACCELERATION} STREQUAL "AVX_256")
 790         try_compile(TEST_AVX ${CMAKE_BINARY_DIR}
 791             "${CMAKE_SOURCE_DIR}/cmake/TestAVX.c"
 792             COMPILE_DEFINITIONS "${ACCELERATION_C_FLAGS}")
 793         if(NOT TEST_AVX)
 794             message(FATAL_ERROR "Cannot compile AVX intrinsics. Consider switching compiler.")
 795         endif()
 796     endif()
 797
 798     # GCC requires x86intrin.h for FMA support. MSVC 2010 requires intrin.h for FMA support.
 799     check_include_file(x86intrin.h HAVE_X86INTRIN_H ${ACCELERATION_C_FLAGS})
 800     check_include_file(intrin.h HAVE_INTRIN_H ${ACCELERATION_C_FLAGS})
 801
 802     # The user should not be able to set this orthogonally to the acceleration
 803     set(GMX_X86_SSE4_1 1)
 804     set(GMX_X86_SSE2   1)
 805
 806     # But just enable one of the choices internally...
 807     if(${GMX_CPU_ACCELERATION} STREQUAL "AVX_128_FMA")
 808         set(GMX_CPU_ACCELERATION_X86_AVX_128_FMA 1)
 809         set(GMX_X86_AVX_128_FMA 1)
 810         if (NOT ACCELERATION_QUIETLY)
 811           message(STATUS "Enabling 128-bit AVX Gromacs acceleration (with fused-multiply add), and it will help compiler optimization.")
 812         endif()
 813     else()
 814         # If we are not doing AVX_128, it must be AVX_256...
 815         set(GMX_CPU_ACCELERATION_X86_AVX_256 1)
 816         set(GMX_X86_AVX_256 1)
 817         if (NOT ACCELERATION_QUIETLY)
 818           message(STATUS "Enabling 256-bit AVX Gromacs acceleration, and it will help compiler optimization.")
 819         endif()
 820     endif()
 821
 822     # Unfortunately gcc-4.5.2 and gcc-4.6.0 has a bug where they use the wrong datatype for the formal
 823     # parameter of the mask for maskload/maskstore arguments. Check if this is present, since we can work around it.
 824     gmx_test_avx_gcc_maskload_bug(${ACCELERATION_C_FLAGS} GMX_X86_AVX_GCC_MASKLOAD_BUG)
 825
 826 elseif(${GMX_CPU_ACCELERATION} STREQUAL "IBM_QPX")
 827     # Used on BlueGene/Q
 828     if (CMAKE_C_COMPILER_ID MATCHES "XL")
 829         GMX_TEST_CFLAG(XLC_BLUEGENEQ_CFLAG "-qarch=qp -qtune=qp" ACCELERATION_C_FLAGS)
 830         try_compile(TEST_QPX ${CMAKE_BINARY_DIR}
 831             "${CMAKE_SOURCE_DIR}/cmake/TestQPX.c"
 832             COMPILE_DEFINITIONS "${ACCELERATION_C_FLAGS}")
 833         if(NOT TEST_QPX)
 834             message(FATAL_ERROR "Cannot compile the requested IBM QPX intrinsics.")
 835         endif()
 836     endif()
 837     if (CMAKE_CXX_COMPILER_ID MATCHES "XL" AND CMAKE_CXX_COMPILER_LOADED)
 838         GMX_TEST_CXXFLAG(XLC_BLUEGENEQ_CXXFLAG "-qarch=qp -qtune=qp" ACCELERATION_CXX_FLAGS)
 839         try_compile(TEST_QPX ${CMAKE_BINARY_DIR}
 840             "cmake/TestQPX.c"
 841             COMPILE_DEFINITIONS "${ACCELERATION_CXX_FLAGS")
 842         if(NOT TEST_QPX)
 843             message(FATAL_ERROR "Cannot compile the requested IBM QPX intrinsics.")
 844         endif()
 845     endif()
 846
 847     if (TEST_QPX)
 848         message(WARNING "IBM QPX acceleration was selected and could be compiled, but the accelerated kernels are not yet available.")
 849         set(GMX_CPU_ACCELERATION_IBM_QPX 1)
 850     else()
 851         message(FATAL_ERROR "Cannot compile IBM QPX intrinsics without the XL compiler. If you are compiling for BlueGene/Q, use 'cmake .. -DCMAKE_TOOLCHAIN_FILE=BlueGeneQ-static-XL-C' to set up the tool chain.")
 852     endif()
 853
 854 else(${GMX_CPU_ACCELERATION} STREQUAL "NONE")
 855     MESSAGE(FATAL_ERROR "Unrecognized option for accelerated kernels: ${GMX_CPU_ACCELERATION}. Pick one of None, SSE2, SSE4.1, AVX_128_FMA, AVX_256, IBM_QPX")
 856 endif(${GMX_CPU_ACCELERATION} STREQUAL "NONE")
 857 set(ACCELERATION_QUIETLY TRUE CACHE INTERNAL "")
 858
 859 # Process QM/MM Settings
 860 string(TOUPPER ${GMX_QMMM_PROGRAM} GMX_QMMM_PROGRAM)
 861 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 862     set(GMX_QMMM_GAUSSIAN 1)
 863 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 864     set(GMX_QMMM_MOPAC 1)
 865 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 866     set(GMX_QMMM_GAMESS 1)
 867 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 868     set(GMX_QMMM_ORCA 1)
 869 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 870     # nothing to do
 871 else(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 872     MESSAGE(FATAL_ERROR "Invalid QM/MM program option: ${GMX_QMMM_PROGRAM}. Choose one of: Gaussian, Mopac, Gamess, Orca, None")
 873 endif(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 874
 875 # Process FFT library settings
 876 string(TOUPPER ${GMX_FFT_LIBRARY} GMX_FFT_LIBRARY)
 877 set(PKG_FFT "")
 878 set(PKG_FFT_LIBS "")
 879 if(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 880     if(GMX_DOUBLE)
 881         set(FFTW fftw)
 882     else()
 883         set(FFTW fftwf)
 884     endif()
 885
 886     if(GMX_BUILD_OWN_FFTW)
 887       add_subdirectory(src/contrib/fftw)
 888     else()
 889       find_package(FFTW COMPONENTS ${FFTW})
 890     endif()
 891
 892     string(TOUPPER "${FFTW}" FFTW)
 893     set(PKG_FFT "${${FFTW}_PKG}")
 894     include_directories(${${FFTW}_INCLUDE_DIRS})
 895     set(FFT_LIBRARIES ${${FFTW}_LIBRARIES})
 896     if(NOT ${FFTW}_FOUND)
 897       MESSAGE(FATAL_ERROR "Cannot find FFTW 3 (with correct precision - libfftw3f for single-precision GROMACS or libfftw3 for double-precision GROMACS). Either choose the right precision, choose another FFT(W) library, enable the advanced option to let GROMACS build FFTW 3 for you, or use the really slow GROMACS built-in fftpack library.")
 898     endif()
 899
 900     set(GMX_FFT_FFTW3 1)
 901
 902     if (NOT ${GMX_CPU_ACCELERATION} STREQUAL "NONE" AND NOT ${FFTW}_HAVE_SIMD)
 903       message(WARNING "The fftw library found is compiled without SIMD support, which makes it slow. Consider recompiling it or contact your admin")
 904     endif()
 905
 906     if(NOT ${GMX_CPU_ACCELERATION} STREQUAL "NONE" AND ${FFTW}_HAVE_AVX)
 907         # If we're not doing CPU acceleration, we don't care about FFTW performance on x86 either
 908         message(WARNING "The FFTW library was compiled with --enable-avx to enable AVX SIMD instructions. That might sound like a good idea for your processor, but for FFTW versions up to 3.3.3, these are slower than the SSE/SSE2 SIMD instructions for the way GROMACS uses FFTs. Limitations in the way FFTW allows GROMACS to measure performance make it awkward for either GROMACS or FFTW to make the decision for you based on runtime performance. You should compile a different FFTW library with --enable-sse or --enable-sse2. If you have a more recent FFTW, you may like to compare the performance of GROMACS with FFTW libraries compiled with and without --enable-avx. However, the GROMACS developers do not really expect the FFTW AVX optimization to help, because the performance is limited by memory access, not computation.")
 909     endif()
 910
 911 elseif(${GMX_FFT_LIBRARY} STREQUAL "MKL")
 912 #    MESSAGE(STATUS "Using external FFT library - Intel MKL")
 913     find_package(MKL REQUIRED)
 914     include_directories(${MKL_INCLUDE_DIR})
 915     set(FFT_LIBRARIES ${MKL_LIBRARIES})
 916     set(PKG_FFT_LIBS ${MKL_LIBRARIES})
 917
 918     set(GMX_FFT_MKL 1)
 919     set(HAVE_MKL 1)
 920
 921 #elseif(${GMX_FFT_LIBRARY} STREQUAL "ACML")
 922 #    MESSAGE(STATUS "Using external FFT library - AMD core math library")
 923 #    set(GMX_FFT_ACML 1)
 924 elseif(${GMX_FFT_LIBRARY} STREQUAL "FFTPACK")
 925     MESSAGE(STATUS "Using internal FFT library - fftpack")
 926     set(GMX_FFT_FFTPACK 1)
 927 else(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 928     MESSAGE(FATAL_ERROR "Invalid FFT library setting: ${GMX_FFT_LIBRARY}. Choose one of: fftw3, mkl, fftpack")
 929 endif(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 930
 931 # enable threaded fftw3 if we've found it
 932 if(FFTW3_THREADS OR FFTW3F_THREADS)
 933     add_definitions(-DFFT5D_FFTW_THREADS)
 934 endif()
 935
 936 set(GMX_EXTERNAL_BLAS TRUE CACHE BOOL "Use external BLAS instead of built-in")
 937 set(GMX_EXTERNAL_LAPACK TRUE CACHE BOOL "Use external LAPACK instead of built-in")
 938 # MKL has BLAS/LAPACK routines
 939 if(NOT HAVE_MKL AND NOT ACCELERATE_FRAMEWORK)
 940   if(GMX_EXTERNAL_BLAS)
 941     if (GMX_BLAS_USER)
 942         list(APPEND GMX_EXTRA_LIBRARIES ${GMX_BLAS_USER})
 943     else(GMX_BLAS_USER)
 944         set(BLAS_FIND_QUIETLY ON)
 945         find_package(BLAS)
 946         if (BLAS_FOUND)
 947           list(APPEND GMX_EXTRA_LIBRARIES ${BLAS_LIBRARIES})
 948         else()
 949           MESSAGE(STATUS "Using internal BLAS library")
 950           set(GMX_EXTERNAL_BLAS FALSE CACHE BOOL "Use external BLAS instead of built-in" FORCE)
 951         endif()
 952     endif(GMX_BLAS_USER)
 953   endif(GMX_EXTERNAL_BLAS)
 954   if(GMX_EXTERNAL_LAPACK)
 955     if (GMX_LAPACK_USER)
 956         list(APPEND GMX_EXTRA_LIBRARIES ${GMX_LAPACK_USER})
 957     else(GMX_LAPACK_USER)
 958         set(LAPACK_FIND_QUIETLY ON)
 959         find_package(LAPACK)
 960         if (LAPACK_FOUND)
 961           list(APPEND GMX_EXTRA_LIBRARIES ${LAPACK_LIBRARIES})
 962         else()
 963           MESSAGE(STATUS "Using internal LAPACK library")
 964           set(GMX_EXTERNAL_LAPACK FALSE CACHE BOOL "Use external LAPACK instead of built-in" FORCE)
 965         endif()
 966     endif(GMX_LAPACK_USER)
 967   endif(GMX_EXTERNAL_LAPACK)
 968 endif()
 969 mark_as_advanced(GMX_EXTERNAL_LAPACK)
 970 mark_as_advanced(GMX_EXTERNAL_BLAS)
 971
 972 set(GMX_USE_PLUGINS OFF CACHE INTERNAL "Whether GROMACS will really try to compile support for VMD plugins")
 973
 974 if(GMX_LOAD_PLUGINS)
 975   if(CYGWIN OR NOT WIN32)
 976     # Native Windows does not have, nor need dlopen
 977     # Note that WIN32 is set with Cygwin, but Cygwin needs dlopen to use plug-ins
 978     include(gmxTestdlopen)
 979     gmx_test_dlopen(HAVE_DLOPEN)
 980   endif()
 981
 982   # so, should we use plug-ins?
 983   if((WIN32 AND NOT CYGWIN) OR (HAVE_DLOPEN AND BUILD_SHARED_LIBS))
 984     if(NOT VMD_QUIETLY)
 985       MESSAGE(STATUS
 986           "Found the ability to use plug-ins when building shared libaries, "
 987           "so will compile to use plug-ins (e.g. to read VMD-supported file "
 988           "formats).")
 989     endif()
 990     if(NOT GMX_VMD_PLUGIN_PATH)
 991       find_package(VMD)
 992     endif()
 993     set(GMX_USE_PLUGINS ON)
 994     list(APPEND GMX_EXTRA_LIBRARIES ${CMAKE_DL_LIBS}) # magic cross-platform pre-set variable for dlopen library
 995     set(PKG_DL_LIBS "-l${CMAKE_DL_LIBS}")
 996   else()
 997     set(PKG_DL_LIBS)
 998   endif()
 999 endif(GMX_LOAD_PLUGINS)
1000 set(VMD_QUIETLY TRUE CACHE INTERNAL "")
1001
1002 if(EXISTS "${CMAKE_SOURCE_DIR}/admin/.isreposource")
1003     if(NOT CMAKE_CROSSCOMPILING)
1004         option(GMX_BUILD_MANPAGES "Build man pages" ON)
1005     else()
1006         message(STATUS "Building the man pages is not available when "
1007             "cross-compiling the developer version from git")
1008     endif()
1009 else()
1010     #make sure source package contains all man pages
1011     if(NOT EXISTS "${CMAKE_SOURCE_DIR}/man/man1/ngmx.1")
1012         message(FATAL_ERROR "Man pages are missing from source package.")
1013     endif()
1014 endif()
1015 mark_as_advanced(GMX_BUILD_MANPAGES)
1016
1017 # Math and thread libraries must often come after all others when linking...
1018 if(HAVE_LIBM)
1019     list(APPEND GMX_EXTRA_LIBRARIES m)
1020 endif(HAVE_LIBM)
1021
1022 if(GMX_FAHCORE)
1023   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
1024       "Path to swindirect.h")
1025   include_directories(${COREWRAP_INCLUDE_DIR})
1026   set_property(CACHE GMX_COOL_QUOTES VALUE OFF)
1027 endif(GMX_FAHCORE)
1028
1029 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
1030 # these are set after everything else
1031 if (NOT GMX_SKIP_DEFAULT_CFLAGS)
1032     set(CMAKE_C_FLAGS "${ACCELERATION_C_FLAGS} ${MPI_COMPILE_FLAGS} ${CMAKE_C_FLAGS}")
1033     set(CMAKE_CXX_FLAGS "${ACCELERATION_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${GMX_CXX11_FLAGS} ${CMAKE_CXX_FLAGS}")
1034     set(CMAKE_EXE_LINKER_FLAGS "${MPI_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}")
1035     set(CMAKE_SHARED_LINKER_FLAGS "${MPI_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS}")
1036 else()
1037     message("Recommended flags which are not added because GMX_SKIP_DEFAULT_CFLAGS=yes:")
1038     message("CMAKE_C_FLAGS: ${ACCELERATION_C_FLAGS} ${MPI_COMPILE_FLAGS} ${GMXC_CFLAGS}")
1039     message("CMAKE_C_FLAGS_RELEASE: ${GMXC_CFLAGS_RELEASE}")
1040     message("CMAKE_C_FLAGS_DEBUG: ${GMXC_CFLAGS_DEBUG}")
1041     message("CMAKE_CXX_FLAGS: ${ACCELERATION_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${GMX_CXX11_FLAGS} ${GMXC_CXXFLAGS}")
1042     message("CMAKE_CXX_FLAGS_RELEASE: ${GMXC_CXXFLAGS_RELEASE}")
1043     message("CMAKE_CXX_FLAGS_DEBUG: ${GMXC_CXXFLAGS_DEBUG}")
1044     message("CMAKE_EXE_LINKER_FLAGS: ${MPI_LINKER_FLAGS}")
1045     message("CMAKE_SHARED_LINKER_FLAGS: ${MPI_LINKER_FLAGS}")
1046 endif()
1047
1048 if(NOT GMX_OPENMP)
1049     #Unset all OpenMP flags in case OpenMP was disabled either by the user
1050     #or because it was only partially detected (e.g. only for C but not C++ compiler)
1051     unset(OpenMP_C_FLAGS CACHE)
1052     unset(OpenMP_CXX_FLAGS CACHE)
1053 else()
1054     set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} ${OpenMP_LINKER_FLAGS})
1055     set(GMX_SHARED_LINKER_FLAGS ${GMX_SHARED_LINKER_FLAGS} ${OpenMP_SHARED_LINKER_FLAGS})
1056 endif()
1057 set(PKG_CFLAGS "${PKG_CFLAGS} ${OpenMP_C_FLAGS}")
1058
1059 ######################################
1060 # Output compiler and CFLAGS used
1061 ######################################
1062 get_compiler_info(C BUILD_C_COMPILER BUILD_CFLAGS)
1063 if (CMAKE_CXX_COMPILER_LOADED)
1064     get_compiler_info(CXX BUILD_CXX_COMPILER BUILD_CXXFLAGS)
1065 endif ()
1066
1067 ########################################################################
1068 # Specify install locations and which subdirectories to process        #
1069 ########################################################################
1070 if ( NOT DEFINED GMXLIB )
1071     set(GMXLIB lib)
1072 endif()
1073 set(LIB_INSTALL_DIR "${GMX_INSTALL_PREFIX}${GMXLIB}")
1074 set(BIN_INSTALL_DIR  ${GMX_INSTALL_PREFIX}bin)
1075 set(DATA_INSTALL_DIR ${GMX_INSTALL_PREFIX}share/gromacs)
1076 set(MAN_INSTALL_DIR  ${GMX_INSTALL_PREFIX}share/man)
1077 set(INCL_INSTALL_DIR ${GMX_INSTALL_PREFIX}include)
1078
1079 set(GMXLIBDIR        ${DATA_INSTALL_DIR}/top)
1080
1081 ##################################################################
1082 # Shared library settings
1083 ##################################################################
1084 if(NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin")
1085     set(CMAKE_SKIP_BUILD_RPATH  FALSE)
1086     set(CMAKE_BUILD_WITH_INSTALL_RPATH FALSE)
1087     set(CMAKE_INSTALL_RPATH "\\\$ORIGIN/../${GMXLIB}")
1088     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
1089 else()
1090     if(CMAKE_SYSTEM_VERSION VERSION_GREATER 8.0) #rpath supported for >10.4
1091         set(CMAKE_INSTALL_NAME_DIR "@rpath")
1092         set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} "-Wl,-rpath,@executable_path/../lib")
1093     else()
1094         set(CMAKE_INSTALL_NAME_DIR "${CMAKE_INSTALL_PREFIX}/${LIB_INSTALL_DIR}")
1095     endif()
1096 endif()
1097
1098 #COPYING file: Only necessary for binary distributions.
1099 #Simpler to always install.
1100 install(FILES COPYING DESTINATION ${DATA_INSTALL_DIR} COMPONENT data)
1101
1102 add_subdirectory(doxygen)
1103 add_subdirectory(share)
1104 add_subdirectory(src)
1105 add_subdirectory(scripts)
1106
1107 # Issue a warning if NVIDIA GPUs were detected, but CUDA was not found.
1108 # Don't bother the user after the first configure pass.
1109 if ((CUDA_NOTFOUND_AUTO AND GMX_DETECT_GPU_AVAILABLE) AND NOT GMX_GPU_DETECTION_DONE)
1110     message(WARNING "${CUDA_NOTFOUND_MESSAGE}")
1111     unset(CUDA_NOTFOUND_AUTO)
1112     unset(CUDA_NOTFOUND_MESSAGE)
1113 endif()
1114 set(GMX_GPU_DETECTION_DONE TRUE CACHE INTERNAL "Whether GPU detection has already been done")
1115
1116 #######################
1117 ## uninstall target
1118 #######################
1119     CONFIGURE_FILE(
1120                    "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
1121                    "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
1122                    IMMEDIATE @ONLY)
1123 ###########################
1124 ADD_CUSTOM_TARGET(uninstall
1125                   "${CMAKE_COMMAND}" -P
1126                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
1127 ###########################
1128
1129 ########################################################################
1130 # Tests                                                                #
1131 ########################################################################
1132
1133 include(CTest)
1134 mark_as_advanced(BUILD_TESTING)
1135 #gmxtests target builds all binaries required for running gmxtest
1136 add_custom_target(gmxtests DEPENDS grompp mdrun pdb2gmx gmxcheck gmx links)
1137 IF(BUILD_TESTING)
1138     enable_testing()
1139     add_subdirectory(tests)
1140     #"check" target builds and runs all tests
1141     add_custom_target(check COMMAND ${CMAKE_CTEST_COMMAND} --output-on-failure)
1142     add_dependencies(check gmxtests tests)
1143     #TODO: Add warning if NOT REGRESSIONTEST_PATH OR NOT GMX_XML that regression/unit tests are not run.
1144 ENDIF()
1145