CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.8)
   2 # Keep CMake suitably quiet on Cygwin
   3 set(CMAKE_LEGACY_CYGWIN_WIN32 0) # Remove when CMake >= 2.8.4 is required
   4
   5 # Allows CPack to act differently for normal tools and mdrun (e.g. because of MPI)
   6 set(CPACK_COMPONENT_GROUP_TOOLS_DESCRIPTION "All GROMACS executable tools")
   7 set(CPACK_COMPONENT_GROUP_MDRUN_DESCRIPTION "GROMACS executable for running simulations")
   8
   9 # override bugs on OS X where Cmake picks gcc (GNU) for C instead of system default cc (Clang).
  10 if(APPLE)
  11     set(CMAKE_C_COMPILER_INIT "cc")
  12 endif(APPLE)
  13
  14 project(Gromacs C)
  15 include(Dart)
  16 mark_as_advanced(DART_ROOT)
  17
  18 # PROJECT_VERSION should have the following structure:
  19 # VERSION-dev[-SUFFIX] where the VERSION should have the for: vMajor.vMinor.vPatch
  20 #
  21 # The "-dev" suffix is important to keep because it makes possible to distinguish
  22 # between a build from official release and a build from git release branch on a
  23 # machine with no git.
  24 #
  25 # NOTE: when releasing the "-dev" suffix needs to be stripped off!
  26 set(PROJECT_VERSION "4.6-dev")
  27 set(CUSTOM_VERSION_STRING ""
  28     CACHE STRING "Custom version string (if empty, use hard-coded default)")
  29 mark_as_advanced(CUSTOM_VERSION_STRING)
  30 if (CUSTOM_VERSION_STRING)
  31     set(PROJECT_VERSION ${CUSTOM_VERSION_STRING})
  32 endif (CUSTOM_VERSION_STRING)
  33 set(SOVERSION 6)
  34 # It is a bit irritating, but this has to be set separately for now!
  35 SET(CPACK_PACKAGE_VERSION_MAJOR "4")
  36 SET(CPACK_PACKAGE_VERSION_MINOR "6")
  37 #SET(CPACK_PACKAGE_VERSION_PATCH "0")
  38
  39 # The numerical gromacs version. It is 40600 for 4.6.0.
  40 # The #define GMX_VERSION in gmx_header_config_h is set to this value.
  41 math(EXPR NUM_VERSION
  42     "${CPACK_PACKAGE_VERSION_MAJOR}*10000 + ${CPACK_PACKAGE_VERSION_MINOR}*100")
  43 if(CPACK_PACKAGE_VERSION_PATCH)
  44     math(EXPR NUM_VERSION
  45          "${NUM_VERSION} + ${CPACK_PACKAGE_VERSION_PATCH}")
  46 endif()
  47
  48 # The API version tracks the numerical Gromacs version (for now).
  49 # It is potentially different from the Gromacs version in the future, if
  50 # the programs/libraries diverge from the presumably more stable API.
  51 # The #define GMX_API_VERSION in version.h is set to this value to
  52 # provide backward compatibility of software written against the Gromacs API.
  53 set(API_VERSION ${NUM_VERSION})
  54
  55 # Cmake modules/macros are in a subdirectory to keep this file cleaner
  56 set(CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake)
  57
  58 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT AND UNIX)
  59 set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
  60 endif()
  61
  62 if(NOT CMAKE_BUILD_TYPE)
  63     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel." FORCE)
  64 endif(NOT CMAKE_BUILD_TYPE)
  65
  66 enable_language(C)
  67
  68 set(GMX_USE_RELATIVE_INSTALL_PATH OFF CACHE STRING "Use relative paths not absolute paths for cmake install. Has only an effect on cpack.")
  69 mark_as_advanced(GMX_USE_RELATIVE_INSTALL_PATH)
  70
  71 set(CPACK_PACKAGE_VERSION ${PROJECT_VERSION})
  72 set(CPACK_PACKAGE_VENDOR "gromacs.org")
  73 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Gromacs - a toolkit for high-performance molecular simulation")
  74 if (NOT GMX_USE_RELATIVE_INSTALL_PATH)
  75     set(CPACK_SET_DESTDIR "ON")
  76 endif()
  77 set(CPACK_RESOURCE_FILE_WELCOME "${CMAKE_SOURCE_DIR}/admin/InstallWelcome.txt")
  78 # Its GPL/LGPL, so they do not have to agree to a license for mere usage, but some installers require this...
  79 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_SOURCE_DIR}/COPYING")
  80 set(CPACK_RESOURCE_FILE_README "${CMAKE_SOURCE_DIR}/admin/InstallInfo.txt")
  81 set(CPACK_SOURCE_IGNORE_FILES ".isreposource;.git;.gitignore")
  82 set(CPACK_PROJECT_CONFIG_FILE "${CMAKE_SOURCE_DIR}/CPackInit.cmake")
  83 SET(CPACK_SOURCE_INSTALLED_DIRECTORIES "${CMAKE_SOURCE_DIR};/;${CMAKE_BINARY_DIR}/man;man")
  84 set(CPACK_PACKAGE_CONTACT "gmx-users@gromacs.org")
  85
  86 #must come after all cpack settings!
  87 include(CPack)
  88
  89 ########################################################################
  90 # Check and warn if cache generated on a different host is being reused
  91 ########################################################################
  92 if(CMAKE_HOST_UNIX)
  93     execute_process(COMMAND hostname
  94                     OUTPUT_VARIABLE TMP_HOSTNAME
  95                     OUTPUT_STRIP_TRAILING_WHITESPACE)
  96     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}")
  97         message(WARNING "
  98             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
  99             is being reused! This could lead to inconsitencies; therefore, it is
 100             recommended to regenerate the cache!")
 101     endif()
 102     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
 103             "Hostname of the machine where the cache was generated.")
 104 endif()
 105
 106 ########################################################################
 107 # User input options - enable C++ - before any CXX flags are changed   #
 108 ########################################################################
 109 option(GMX_GPU  "Enable GPU acceleration" ON)
 110 option(GMX_OPENMM "Accelerated execution on GPUs through the OpenMM library (rerun cmake after changing to see relevant options)" OFF)
 111 option(GMX_FORCE_CXX "Enable C++ compilation even if not necessary" OFF)
 112 mark_as_advanced(GMX_FORCE_CXX)
 113 if(GMX_GPU OR GMX_OPENMM OR GMX_FORCE_CXX)
 114     enable_language(CXX)
 115 endif()
 116 set(CMAKE_PREFIX_PATH "" CACHE STRING "Extra locations to search for external libraries and tools (give directory without lib, bin, or include)")
 117
 118 ########################################################################
 119 # Fix stupid flags on Windows
 120 ########################################################################
 121 SET(SHARED_LIBS_DEFAULT ON)
 122 IF( WIN32 AND NOT CYGWIN)
 123   option(GMX_PREFER_STATIC_LIBS "When finding libraries prefer static system libraries (MT instead of MD)!" ON)
 124   mark_as_advanced(GMX_PREFER_STATIC_LIBS)
 125   SET(SHARED_LIBS_DEFAULT OFF)  #is currently not working on Windows
 126
 127   IF (GMX_PREFER_STATIC_LIBS)
 128     #Only setting Debug and Release flags. Others configurations current not used.
 129     STRING(REPLACE /MD /MT CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE})
 130     SET(CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE} CACHE STRING "" FORCE)
 131     STRING(REPLACE /MD /MT CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG})
 132     SET(CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG} CACHE STRING "" FORCE)
 133     if(CMAKE_CXX_COMPILER_LOADED)
 134         STRING(REPLACE /MD /MT CMAKE_CXX_FLAGS_RELEASE ${CMAKE_CXX_FLAGS_RELEASE})
 135         SET(CMAKE_CXX_FLAGS_RELEASE ${CMAKE_CXX_FLAGS_RELEASE} CACHE STRING "" FORCE)
 136         STRING(REPLACE /MD /MT CMAKE_CXX_FLAGS_DEBUG ${CMAKE_CXX_FLAGS_DEBUG})
 137         SET(CMAKE_CXX_FLAGS_DEBUG ${CMAKE_CXX_FLAGS_DEBUG} CACHE STRING "" FORCE)
 138     endif()
 139   ENDIF()
 140
 141   #Workaround for cmake bug 13174. Replace deprecated options.
 142   IF( CMAKE_C_COMPILER_ID MATCHES "Intel" )
 143     STRING(REPLACE /GZ /RTC1 CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG})
 144     SET(CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG} CACHE STRING "" FORCE)
 145   ENDIF()
 146   IF( CMAKE_CXX_COMPILER_ID MATCHES "Intel" AND CMAKE_CXX_COMPILER_LOADED)
 147     STRING(REPLACE /GZ /RTC1 CMAKE_CXX_FLAGS_DEBUG ${CMAKE_CXX_FLAGS_DEBUG})
 148     STRING(REPLACE /GX /EHsc CMAKE_CXX_FLAGS_DEBUG ${CMAKE_CXX_FLAGS_DEBUG})
 149     SET(CMAKE_CXX_FLAGS_DEBUG ${CMAKE_CXX_FLAGS_DEBUG} CACHE STRING "" FORCE)
 150
 151     STRING(REPLACE /GX /EHsc CMAKE_CXX_FLAGS_RELEASE ${CMAKE_CXX_FLAGS_RELEASE})
 152     SET(CMAKE_CXX_FLAGS_RELEASE ${CMAKE_CXX_FLAGS_RELEASE} CACHE STRING "" FORCE)
 153   ENDIF()
 154 ENDIF()
 155
 156
 157 ########################################################################
 158 # User input options                                                   #
 159 ########################################################################
 160 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" OFF)
 161 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 162 option(GMX_THREAD_MPI  "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" ON)
 163 option(GMX_SOFTWARE_INVSQRT "Use GROMACS software 1/sqrt" ON)
 164 mark_as_advanced(GMX_SOFTWARE_INVSQRT)
 165 option(GMX_POWERPC_INVSQRT "Use PowerPC hardware 1/sqrt" OFF)
 166 mark_as_advanced(GMX_POWERPC_INVSQRT)
 167 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 168 mark_as_advanced(GMX_FAHCORE)
 169
 170 include(gmxDetectAcceleration)
 171 if(NOT DEFINED GMX_CPU_ACCELERATION)
 172     if(CMAKE_CROSSCOMPILING)
 173         set(GMX_SUGGESTED_CPU_ACCELERATION "None")
 174     else(CMAKE_CROSSCOMPILING)
 175         gmx_detect_acceleration(GMX_SUGGESTED_CPU_ACCELERATION)
 176     endif(CMAKE_CROSSCOMPILING)
 177 endif(NOT DEFINED GMX_CPU_ACCELERATION)
 178
 179 set(GMX_CPU_ACCELERATION "@GMX_SUGGESTED_CPU_ACCELERATION@"
 180     CACHE STRING "Accelerated CPU kernels. Pick one of: None, SSE2, SSE4.1, AVX_128_FMA, AVX_256, BlueGene, Power6, Fortran")
 181
 182 set(GMX_FFT_LIBRARY "fftw3"
 183     CACHE STRING "FFT library choices: fftw3,mkl,fftpack[built-in]")
 184 option(GMX_DISABLE_FFTW_MEASURE
 185        "Do not optimize FFTW setups (not needed with SSE)" OFF)
 186 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 187 set(GMX_QMMM_PROGRAM "none"
 188     CACHE STRING "QM package choices: none,gaussian,mopac,gamess,orca")
 189 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 190 mark_as_advanced(GMX_BROKEN_CALLOC)
 191 option(GMX_MPI_IN_PLACE "Enable MPI_IN_PLACE for MPIs that have it defined" ON)
 192 mark_as_advanced(GMX_MPI_IN_PLACE)
 193 option(GMX_LOAD_PLUGINS "Compile with plugin support, needed to read VMD supported file formats" ON)
 194 mark_as_advanced(GMX_LOAD_PLUGINS)
 195
 196 option(GMX_OPENMP "Enable OpenMP-based multithreading" ON)
 197
 198 option(USE_VERSION_H "Generate development version string/information" ON)
 199 mark_as_advanced(USE_VERSION_H)
 200
 201 option(GMX_DEFAULT_SUFFIX "Use default suffixes for GROMACS binaries and libs (_d for double, _mpi for MPI; rerun cmake after changing to see relevant options)" ON)
 202
 203 if(UNIX)
 204     option(GMX_PREFER_STATIC_LIBS "When finding libraries prefer static archives (not available on non-*nix platforms and it will only work if static versions of external dependencies are available and found)!" OFF)
 205     mark_as_advanced(GMX_PREFER_STATIC_LIBS)
 206 endif()
 207
 208 option(GMX_CYCLE_SUBCOUNTERS "Enable cycle subcounters to get a more detailed cycle timings" OFF)
 209 mark_as_advanced(GMX_CYCLE_SUBCOUNTERS)
 210
 211 ######################################################################
 212 # Compiler tests
 213 # These need to be done early (before further tests).
 214 #####################################################################
 215
 216 # The cmake/Check{C,CXX}CompilerFlag.cmake files in the GROMACS distribution
 217 # are used with permission from CMake v2.8.9 so that GROMACS can detect
 218 # invalid options with the Intel Compilers.
 219 # These files should be removed from the source tree when a CMake version that
 220 # includes the features in question becomes required for building GROMACS.
 221 include(CheckCCompilerFlag)
 222 if(CMAKE_CXX_COMPILER_LOADED)
 223     include(CheckCXXCompilerFlag)
 224 endif()
 225
 226 # OpenMP check must come before other CFLAGS!
 227 if(GMX_OPENMP)
 228     find_package(OpenMP)
 229     if(OPENMP_FOUND)
 230         # CMake on Windows doesn't support linker flags passed to target_link_libraries
 231         # (i.e. it treats /openmp as \openmp library file). Also, no OpenMP linker flags are needed.
 232         if(NOT (WIN32 AND NOT CYGWIN))
 233             if(CMAKE_COMPILER_IS_GNUCC AND GMX_PREFER_STATIC_OPENMP)
 234                 set(OpenMP_LINKER_FLAGS "-Wl,-static -lgomp -lrt -Wl,-Bdynamic -lpthread")
 235                 set(OpenMP_SHARED_LINKER_FLAGS "")
 236             else()
 237                 # Only set a linker flag if the user didn't set them manually
 238                 if(NOT DEFINED OpenMP_LINKER_FLAGS)
 239                     set(OpenMP_LINKER_FLAGS "${OpenMP_C_FLAGS}")
 240                 endif()
 241                 if(NOT DEFINED OpenMP_SHARED_LINKER_FLAGS)
 242                     set(OpenMP_SHARED_LINKER_FLAGS "${OpenMP_C_FLAGS}")
 243                 endif()
 244             endif()
 245         endif()
 246     else(OPENMP_FOUND)
 247         message(WARNING
 248                 "The compiler you are using does not support OpenMP parallelism. This might hurt your performance a lot, in particular with GPUs. Try using a more recent version, or a different compiler. For now, we are proceeding by turning off OpenMP.")
 249         set(GMX_OPENMP OFF CACHE STRING "Whether GROMACS will use OpenMP parallelism." FORCE)
 250     endif(OPENMP_FOUND)
 251 endif()
 252
 253
 254 include(gmxCFlags)
 255 gmx_c_flags()
 256
 257 include(gmxGetCompilerVersion)
 258 get_compiler_version()
 259
 260 # gcc 4.4.x is buggy and crashes when compiling some files with O3 and OpenMP on.
 261 # Detect here whether applying a workaround is needed and will apply it later
 262 # on the affected files.
 263 include(gmxGCC44O3BugWorkaround)
 264 gmx_check_gcc44_bug_workaround_needed(GMX_USE_GCC44_BUG_WORKAROUND)
 265
 266 ########################################################################
 267 # Set up binary and library suffixing
 268 ########################################################################
 269 set(GMX_BINARY_SUFFIX "" CACHE STRING "Suffix for GROMACS binaries (default: _d for double, _mpi for MPI, _mpi_d for MPI and double).")
 270 set(GMX_LIBS_SUFFIX ""
 271   CACHE STRING "Suffix for GROMACS libs (default: _d for double, _mpi for MPI, _mpi_d for MPI and double).")
 272 if (GMX_DEFAULT_SUFFIX)
 273   set(GMX_BINARY_SUFFIX "")
 274   set(GMX_LIBS_SUFFIX "")
 275   if (GMX_MPI)
 276     set(GMX_BINARY_SUFFIX "_mpi")
 277     set(GMX_LIBS_SUFFIX "_mpi")
 278   endif(GMX_MPI)
 279   if (GMX_DOUBLE)
 280     set (GMX_BINARY_SUFFIX "${GMX_BINARY_SUFFIX}_d")
 281     set (GMX_LIBS_SUFFIX "${GMX_LIBS_SUFFIX}_d")
 282   endif(GMX_DOUBLE)
 283   if (GMX_OPENMM)
 284     set (GMX_BINARY_SUFFIX "-openmm")
 285     set (GMX_LIBS_SUFFIX "_openmm")
 286   endif(GMX_OPENMM)
 287   mark_as_advanced(FORCE GMX_BINARY_SUFFIX GMX_LIBS_SUFFIX)
 288   if (NOT SUFFIX_QUIETLY)
 289     message(STATUS "Using default binary suffix: \"${GMX_BINARY_SUFFIX}\"")
 290     message(STATUS "Using default library suffix: \"${GMX_LIBS_SUFFIX}\"")
 291   endif (NOT SUFFIX_QUIETLY)
 292 else(GMX_DEFAULT_SUFFIX)
 293   mark_as_advanced(CLEAR GMX_BINARY_SUFFIX GMX_LIBS_SUFFIX)
 294   if (NOT SUFFIX_QUIETLY)
 295     message(STATUS "Using manually set binary suffix: \"${GMX_BINARY_SUFFIX}\"")
 296     message(STATUS "Using manually set library suffix: \"${GMX_LIBS_SUFFIX}\"")
 297   endif (NOT SUFFIX_QUIETLY)
 298 endif(GMX_DEFAULT_SUFFIX)
 299 set(SUFFIX_QUIETLY TRUE CACHE INTERNAL "")
 300
 301 set(PKG_CFLAGS "")
 302 if(GMX_DOUBLE)
 303     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_DOUBLE")
 304 endif(GMX_DOUBLE)
 305 if(GMX_SOFTWARE_INVSQRT)
 306   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_SOFTWARE_INVSQRT")
 307 endif(GMX_SOFTWARE_INVSQRT)
 308 if(GMX_POWERPC_INVSQRT)
 309   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_POWERPC_INVSQRT")
 310 endif(GMX_POWERPC_INVSQRT)
 311
 312 ########################################################################
 313 #Process MPI settings
 314 ########################################################################
 315 include(gmxManageMPI)
 316
 317 #######################################################################
 318 # Check for options incompatible with OpenMM build                    #
 319 #######################################################################
 320 if(GMX_OPENMM)
 321     # we'll use the built-in fft to avoid unnecessary dependencies
 322     string(TOUPPER ${GMX_FFT_LIBRARY} GMX_FFT_LIBRARY)
 323     if(NOT ${GMX_FFT_LIBRARY} STREQUAL "FFTPACK")
 324         message(STATUS "No external FFT libraries needed for the OpenMM build, switching to fftpack!")
 325         set(GMX_FFT_LIBRARY "fftpack" CACHE STRING
 326                 "No external FFT libraries needed for the OpenMM build, switching to  fftpack!" FORCE)
 327     endif()
 328     if(GMX_MPI)
 329         message(FATAL_ERROR "The OpenMM build is not compatible with MPI!")
 330     endif(GMX_MPI)
 331     if(GMX_THREAD_MPI)
 332         message(STATUS "Thread-MPI not compatible with OpenMM, disabled!")
 333         set(GMX_THREAD_MPI OFF CACHE BOOL
 334                 "Thread-MPI not compatible with OpenMM build, disabled!" FORCE)
 335     endif(GMX_THREAD_MPI)
 336     if(GMX_OPENMP)
 337         message(STATUS "OpenMP multithreading not compatible with OpenMM, disabled")
 338         set(GMX_OPENMP OFF CACHE BOOL
 339             "OpenMP multithreading not compatible with OpenMM, disabled!" FORCE)
 340     endif()
 341     if(GMX_SOFTWARE_INVSQRT)
 342         set(GMX_SOFTWARE_INVSQRT OFF CACHE STRING
 343                 "The OpenMM build does not need GROMACS software 1/sqrt!" FORCE)
 344     endif(GMX_SOFTWARE_INVSQRT)
 345     string(TOUPPER ${GMX_CPU_ACCELERATION} GMX_CPU_ACCELERATION)
 346     if(NOT GMX_CPU_ACCELERATION STREQUAL "NONE")
 347         message(STATUS "Switching off CPU-based acceleration, the OpenMM build does not support/need any!")
 348         set(GMX_CPU_ACCELERATION "None" CACHE STRING
 349             "Switching off CPU-based acceleration, the OpenMM build does not support/need any!" FORCE)
 350     endif()
 351     if(GMX_FAHCORE)
 352         message(FATAL_ERROR "The OpenMM build does not support FAH build!")
 353     endif(GMX_FAHCORE)
 354     if(GMX_DOUBLE)
 355         message(FATAL_ERROR  "The OpenMM-build does not support double precision calculations!")
 356     endif()
 357     # mark as advanced the unused variables
 358     mark_as_advanced(FORCE GMX_CPU_ACCELERATION GMX_MPI GMX_FFT_LIBRARY
 359         GMX_QMMM_PROGRAM GMX_THREAD_MPI GMX_DOUBLE)
 360 else(GMX_OPENMM)
 361      mark_as_advanced(CLEAR GMX_CPU_ACCELERATION GMX_MPI GMX_FFT_LIBRARY
 362         GMX_QMMM_PROGRAM GMX_THREAD_MPI GMX_DOUBLE)
 363 endif(GMX_OPENMM)
 364
 365
 366 ########################################################################
 367 # Basic system tests (standard libraries, headers, functions, types)   #
 368 ########################################################################
 369 include(CheckIncludeFiles)
 370 check_include_files(string.h     HAVE_STRING_H)
 371 check_include_files(math.h       HAVE_MATH_H)
 372 check_include_files(limits.h     HAVE_LIMITS_H)
 373 check_include_files(memory.h     HAVE_MEMORY_H)
 374 check_include_files(unistd.h     HAVE_UNISTD_H)
 375 check_include_files(direct.h     HAVE_DIRECT_H)
 376 check_include_files(pwd.h        HAVE_PWD_H)
 377 check_include_files(stdint.h     HAVE_STDINT_H)
 378 check_include_files(stdlib.h     HAVE_STDLIB_H)
 379 check_include_files(pthread.h    HAVE_PTHREAD_H)
 380 check_include_files(dirent.h     HAVE_DIRENT_H)
 381 check_include_files(inttypes.h   HAVE_INTTYPES_H)
 382 check_include_files(regex.h      HAVE_REGEX_H)
 383 check_include_files(sys/types.h  HAVE_SYS_TYPES_H)
 384 check_include_files(sys/stat.h   HAVE_SYS_STAT_H)
 385 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 386 check_include_files(rpc/rpc.h    HAVE_RPC_RPC_H)
 387 check_include_files("rpc/rpc.h;rpc/xdr.h"    HAVE_RPC_XDR_H)
 388 check_include_files(io.h                 HAVE_IO_H)
 389 check_include_files(sched.h      HAVE_SCHED_H)
 390
 391 include(CheckFunctionExists)
 392 check_function_exists(strcasecmp        HAVE_STRCASECMP)
 393 check_function_exists(strdup            HAVE_STRDUP)
 394 check_function_exists(vprintf           HAVE_VPRINTF)
 395 check_function_exists(memcmp            HAVE_MEMCMP)
 396 check_function_exists(posix_memalign    HAVE_POSIX_MEMALIGN)
 397 check_function_exists(memalign          HAVE_MEMALIGN)
 398 check_function_exists(_aligned_malloc   HAVE__ALIGNED_MALLOC)
 399 check_function_exists(gettimeofday      HAVE_GETTIMEOFDAY)
 400 check_function_exists(isnan             HAVE_ISNAN)
 401 check_function_exists(_isnan            HAVE__ISNAN)
 402 check_function_exists(fsync             HAVE_FSYNC)
 403 check_function_exists(_fileno           HAVE__FILENO)
 404 check_function_exists(fileno            HAVE_FILENO)
 405 check_function_exists(_commit           HAVE__COMMIT)
 406 check_function_exists(lstat             HAVE_LSTAT)
 407 check_function_exists(sigaction         HAVE_SIGACTION)
 408 check_function_exists(sysconf           HAVE_SYSCONF)
 409 check_function_exists(sched_setaffinity HAVE_SCHED_SETAFFINITY)
 410 check_function_exists(sched_getaffinity HAVE_SCHED_GETAFFINITY)
 411 check_function_exists(rsqrt             HAVE_RSQRT)
 412 check_function_exists(rsqrtf            HAVE_RSQRTF)
 413 check_function_exists(sqrtf             HAVE_SQRTF)
 414
 415 include(CheckLibraryExists)
 416 check_library_exists(m sqrt "" HAVE_LIBM)
 417 check_library_exists(m cbrt "" HAVE_CBRT)
 418
 419
 420 include(CheckTypeSize)
 421
 422 check_type_size("bool"          SIZEOF_BOOL) # will also set HAVE_BOOL
 423 check_type_size("int"           SIZEOF_INT)
 424 check_type_size("long int"      SIZEOF_LONG_INT)
 425 check_type_size("long long int" SIZEOF_LONG_LONG_INT)
 426 check_type_size("off_t"         SIZEOF_OFF_T)
 427 check_type_size("void *"        SIZEOF_VOIDP)
 428
 429 if (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 430     set(GMX_64_BIT TRUE)
 431 else (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 432     set(GMX_64_BIT FALSE)
 433 endif (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 434
 435 # Check for some basic types that we *need*, so set these to int if they are not present
 436 check_type_size(uid_t uid_t)
 437 if(NOT uid_t)
 438   set(uid_t int)
 439 else(NOT uid_t)
 440   set(uid_t 0)
 441 endif(NOT uid_t)
 442
 443 check_type_size(gid_t gid_t)
 444 if(NOT gid_t)
 445   set(gid_t 1)
 446 else(NOT gid_t)
 447   set(gid_t 0)
 448 endif(NOT gid_t)
 449
 450 check_type_size(size_t size_t)
 451 if(NOT size_t)
 452   set(size_t int)
 453 else(NOT size_t)
 454   set(size_t 0)
 455 endif(NOT size_t)
 456
 457 check_type_size(off_t off_t)
 458 if(NOT off_t)
 459   set(off_t int)
 460 else(NOT off_t)
 461   set(off_t 0)
 462 endif(NOT off_t)
 463
 464 include(TestBigEndian)
 465 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 466
 467
 468
 469
 470 ########################################################################
 471 # Find external packages                                               #
 472 ########################################################################
 473 if(UNIX)
 474     if(GMX_PREFER_STATIC_LIBS)
 475         # On Linux .a is the static library suffix, on Mac OS X .lib can also
 476         # be used, so we'll add both to the preference list.
 477         SET(CMAKE_FIND_LIBRARY_SUFFIXES ".lib;.a" ${CMAKE_FIND_LIBRARY_SUFFIXES})
 478         if(SHARED_LIBS_DEFAULT)
 479             if(BUILD_SHARED_LIBS) #Warn the user about the combination. But don't overwrite the request.
 480                 message(WARNING "Static libraries requested, and shared Gromacs libraries requested.")
 481             elseif(NOT DEFINED BUILD_SHARED_LIBS) #Change default to OFF. Don't warn if it's already off.
 482                 message(WARNING "Static libraries requested, the GROMACS libraries will also be build static (BUILD_SHARED_LIBS=OFF)")
 483                 set(SHARED_LIBS_DEFAULT OFF)
 484             endif()
 485         endif()
 486     endif()
 487 endif()
 488 option(BUILD_SHARED_LIBS "Enable shared libraries (can be problematic with MPI, Windows)" ${SHARED_LIBS_DEFAULT})
 489
 490 option(GMX_GSL "Add support for gsl" OFF)
 491 if (GMX_GSL)
 492   find_package(gsl)
 493   set(PKG_GSL "")
 494   if(GSL_FOUND)
 495     include_directories(${GSL_INCLUDE_DIR})
 496     set(PKG_GSL gsl)
 497     set(HAVE_LIBGSL 1)
 498   endif(GSL_FOUND)
 499 endif (GMX_GSL)
 500
 501 option(GMX_X11 "Use X window system" OFF)
 502 if (GMX_X11)
 503         find_package(X11)
 504         # X11 includes/libraries are only set in the ngmx subdirectory!
 505         if(X11_FOUND)
 506         set(HAVE_X11 1)
 507         endif(X11_FOUND)
 508 endif(GMX_X11)
 509
 510 include(ThreadMPI)
 511 set(THREAD_MPI_LIB thread_mpi)
 512 if(GMX_THREAD_MPI)
 513     tmpi_get_source_list(THREAD_MPI_SRC)
 514     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_THREAD_MPI")
 515     set(GMX_MPI 1)
 516 else(GMX_THREAD_MPI)
 517     tmpi_get_source_list(THREAD_MPI_SRC NOMPI)
 518 endif(GMX_THREAD_MPI)
 519
 520 if(GMX_OPENMM)
 521     set(CUDA_BUILD_EMULATION OFF)
 522     find_package(CUDA 3.1 REQUIRED)
 523     add_definitions(-DGMX_OPENMM)
 524     if(CMAKE_BUILD_TYPE STREQUAL "DEBUG")
 525         set(CUDA_VERBOSE_BUILD ON)
 526     endif()
 527     find_package(OpenMM)
 528 endif(GMX_OPENMM)
 529
 530
 531 if(GMX_GPU)
 532     if(GMX_DOUBLE)
 533         message(WARNING "GPU acceleration is not available in double precision, disabled!")
 534         set(GMX_GPU OFF CACHE BOOL "Enable GPU acceleration" FORCE)
 535     endif()
 536 endif(GMX_GPU)
 537
 538 if(GMX_GPU)
 539
 540     # We support CUDA >=v3.2 on *nix, but <= v4.1 doesn't work with MSVC
 541     if(MSVC)
 542         find_package(CUDA 4.1)
 543     else()
 544         find_package(CUDA 3.2)
 545     endif()
 546
 547     if (NOT EXISTS ${CUDA_TOOLKIT_ROOT_DIR})
 548         message(FATAL_ERROR "
 549     mdrun supports native GPU acceleration on NVIDIA hardware with compute
 550     capability >=2.0. This requires the NVIDIA CUDA library, which was not
 551     found; the location can be hinted by setting CUDA_TOOLKIT_ROOT_DIR.
 552
 553     CPU or GPU acceleration can be selected at runtime, but if you are
 554     sure you can not make use of GPU acceleration, disable it by setting
 555     the CMake variable GMX_GPU=OFF.")
 556     endif()
 557
 558     if(NOT GMX_OPENMP)
 559         message(WARNING "
 560     In order to use GPU acceleration efficiently, mdrun requires OpenMP multithreding.
 561     Without OpenMP only a single CPU core per GPU can be used which is suboptimal.
 562     Note that with MPI multiple processes can be forced to use a single GPU, but this
 563     typically inefficient.")
 564     endif()
 565
 566     include(gmxManageNvccConfig)
 567
 568     # Check whether we can use atomic operations needed for polling wait for GPU
 569     # (to avoid the cudaStreamSynchronize + ECC bug).
 570     # With thread-MPI testing atomics has already been carried out, but without
 571     # thread-MPI we need to invoke the atomics test independently.
 572     if (NOT GMX_THREAD_MPI)
 573         set(TEST_TMPI_ATOMICS_ONLY ON CACHE INTERNAL
 574             "Test only the atomic operations of thread-MPI.")
 575         include(ThreadMPI)
 576     endif()
 577
 578     # we need this linker flag in case if we have ld >= 2.22 (typically with gcc 4.5+),
 579     # but it's too cumbersome to check the ld version and the flag should not hurt
 580     if(CMAKE_COMPILER_IS_GNUCC)
 581         set(GROMACS_LINKER_FLAGS "-Wl,--add-needed ${GROMACS_LINKER_FLAGS}")
 582     endif()
 583 endif()
 584 # Annoyingly enough, FindCUDA leaves a few variables behind as non-advanced.
 585 # We need to mark these advanced outside the conditional, otherwise, if the user
 586 # tuns GMX_GPU=OFF after a failed cmake pass, these variables will be left behind.
 587 mark_as_advanced(CUDA_BUILD_CUBIN CUDA_BUILD_EMULATION CUDA_SDK_ROOT_DIR CUDA_VERBOSE_BUILD)
 588
 589 if(APPLE)
 590    find_library(ACCELERATE_FRAMEWORK Accelerate)
 591    list(APPEND GMX_EXTRA_LIBRARIES ${ACCELERATE_FRAMEWORK})
 592 endif(APPLE)
 593
 594 if(CYGWIN)
 595     set(GMX_CYGWIN 1)
 596 endif(CYGWIN)
 597
 598 if(WIN32 AND NOT CYGWIN)
 599     set(GMX_NATIVE_WINDOWS 1)
 600 endif()
 601
 602 # only bother with finding git and using version.h if the source is a git repo
 603 if(EXISTS "${CMAKE_SOURCE_DIR}/.git")
 604     if(USE_VERSION_H)
 605         # We need at least git v1.5.3 be able to parse git's date output. If not
 606         # found or the version is too small, we can't generate version information.
 607         find_package(Git)
 608
 609         # Find out the git version
 610         if(GIT_FOUND AND NOT GIT_VERSION)
 611           execute_process(COMMAND ${GIT_EXECUTABLE} "--version"
 612             OUTPUT_VARIABLE _exec_out
 613             OUTPUT_STRIP_TRAILING_WHITESPACE)
 614           string(REGEX REPLACE "git version (.*)" "\\1" GIT_VERSION ${_exec_out})
 615           set(GIT_VERSION ${GIT_VERSION} CACHE STRING "Git version")
 616           mark_as_advanced(GIT_VERSION)
 617         endif()
 618
 619         if(NOT GIT_FOUND OR GIT_VERSION VERSION_LESS "1.5.3")
 620           message("No compatible git version found, won't be able to generate proper development version information.")
 621           set(USE_VERSION_H OFF)
 622         endif()
 623     endif()
 624 else()
 625     set(USE_VERSION_H OFF)
 626 endif()
 627
 628 ########################################################################
 629 # Generate development version info for cache
 630 ########################################################################
 631 # set(GEN_VERSION_INFO_INTERNAL "ON")
 632 # include(gmxGenerateVersionString)
 633
 634 ########################################################################
 635 # Our own GROMACS tests
 636 ########################################################################
 637
 638 add_definitions( -DHAVE_CONFIG_H )
 639 include_directories(${CMAKE_BINARY_DIR}/src)
 640 include_directories(${CMAKE_BINARY_DIR}/include)
 641 include_directories(${CMAKE_SOURCE_DIR}/include)
 642
 643 include(gmxTestInlineASM)
 644 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 645
 646 include(gmxSetBuildInformation)
 647 gmx_set_build_information()
 648 if(BUILD_CPU_FEATURES MATCHES "rdtscp" AND NOT GMX_DISTRIBUTABLE_BUILD)
 649     # The timestep counter headers do not include config.h
 650     add_definitions(-DHAVE_RDTSCP)
 651 endif(BUILD_CPU_FEATURES MATCHES "rdtscp" AND NOT GMX_DISTRIBUTABLE_BUILD)
 652
 653 include(gmxTestFloatFormat)
 654 gmx_test_float_format(GMX_FLOAT_FORMAT_IEEE754
 655                       GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER
 656                       GMX_IEEE754_BIG_ENDIAN_WORD_ORDER)
 657
 658 include(gmxTestLargeFiles)
 659 gmx_test_large_files(GMX_LARGEFILES)
 660
 661 include(gmxTestSignal)
 662 gmx_test_sigusr1(HAVE_SIGUSR1)
 663
 664 include(gmxTestInline)
 665 gmx_test_inline(INLINE_KEYWORD)
 666
 667 include(gmxTestRestrict)
 668 gmx_test_restrict(RESTRICT_KEYWORD)
 669
 670 include(gmxTestPipes)
 671 gmx_test_pipes(HAVE_PIPES)
 672
 673 include(gmxTestIsfinite)
 674 gmx_test_isfinite(HAVE_ISFINITE)
 675 gmx_test__isfinite(HAVE__ISFINITE)
 676 gmx_test__finite(HAVE__FINITE)
 677
 678 include(gmxTestXDR)
 679 gmx_test_xdr(GMX_SYSTEM_XDR)
 680 if(NOT GMX_SYSTEM_XDR)
 681     set(GMX_INTERNAL_XDR 1)
 682     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_INTERNAL_XDR")
 683 endif(NOT GMX_SYSTEM_XDR)
 684
 685 # Process nonbonded accelerated kernels settings
 686 string(TOUPPER ${GMX_CPU_ACCELERATION} ${GMX_CPU_ACCELERATION})
 687 if(${GMX_CPU_ACCELERATION} STREQUAL "NONE")
 688     # nothing to do
 689 elseif(${GMX_CPU_ACCELERATION} STREQUAL "SSE2")
 690
 691     GMX_TEST_CFLAG(GNU_SSE2_CFLAG "-msse2" GROMACS_C_FLAGS)
 692     if(NOT GNU_SSE2_CFLAG)
 693         GMX_TEST_CFLAG(MSVC_SSE2_CFLAG "/arch:SSE2" GROMACS_C_FLAGS)
 694     endif(NOT GNU_SSE2_CFLAG)
 695
 696     if (CMAKE_CXX_COMPILER_LOADED)
 697         GMX_TEST_CXXFLAG(GNU_SSE2_CXXFLAG "-msse2" GROMACS_CXX_FLAGS)
 698         if(NOT GNU_SSE2_CXXFLAG)
 699             GMX_TEST_CXXFLAG(MSVC_SSE2_CXXFLAG "/arch:SSE2" GROMACS_CXX_FLAGS)
 700         endif(NOT GNU_SSE2_CXXFLAG)
 701     endif()
 702
 703     # We dont warn for lacking SSE2 flag support, since that is probably standard today.
 704
 705     # Only test the include after we have tried to add the correct flag for SSE2 support
 706     check_include_file(emmintrin.h  HAVE_EMMINTRIN_H ${GROMACS_C_FLAGS})
 707
 708     if(NOT HAVE_EMMINTRIN_H)
 709         message(FATAL_ERROR "Cannot find emmintrin.h, which is required for SSE2 intrinsics support.")
 710     endif(NOT HAVE_EMMINTRIN_H)
 711
 712     set(GMX_CPU_ACCELERATION_X86_SSE2 1)
 713     # The user should not be able to set this orthogonally to the acceleration
 714     set(GMX_X86_SSE2 1)
 715     if (NOT ACCELERATION_QUIETLY)
 716       message(STATUS "Enabling SSE2 Gromacs acceleration, and it will help compiler optimization.")
 717     endif()
 718
 719 elseif(${GMX_CPU_ACCELERATION} STREQUAL "SSE4.1")
 720
 721     GMX_TEST_CFLAG(GNU_SSE4_CFLAG "-msse4.1" GROMACS_C_FLAGS)
 722     if (NOT GNU_SSE4_CFLAG)
 723         GMX_TEST_CFLAG(MSVC_SSE4_CFLAG "/arch:SSE4.1" GROMACS_C_FLAGS)
 724     endif(NOT GNU_SSE4_CFLAG)
 725     if (NOT GNU_SSE4_CFLAG AND NOT MSVC_SSE4_CFLAG)
 726         message(WARNING "No C SSE4.1 flag found. Consider a newer compiler, or disable SSE4.1 for slightly lower performance.")
 727         # Not surprising if we end up here! MSVC current does not support the SSE4.1 flag. However, it appears to accept SSE4.1
 728         # intrinsics when SSE2 support is enabled, so we try that instead.
 729         GMX_TEST_CFLAG(MSVC_SSE2_CFLAG "/arch:SSE2" GROMACS_C_FLAGS)
 730     endif(NOT GNU_SSE4_CFLAG AND NOT MSVC_SSE4_CFLAG)
 731
 732     if (CMAKE_CXX_COMPILER_LOADED)
 733         GMX_TEST_CXXFLAG(GNU_SSE4_CXXFLAG "-msse4.1" GROMACS_CXX_FLAG)
 734         if (NOT GNU_SSE4_CXXFLAG)
 735             GMX_TEST_CXXFLAG(MSVC_SSE4_CXXFLAG "/arch:SSE4.1" GROMACS_CXX_FLAGS)
 736         endif(NOT GNU_SSE4_CXXFLAG)
 737         if (NOT GNU_SSE4_CXXFLAG AND NOT MSVC_SSE4_CXXFLAG)
 738             message(WARNING "No C++ SSE4.1 flag found. Consider a newer compiler, or disable SSE4.1 for slightly lower performance.")
 739             # Not surprising if we end up here! MSVC current does not support the SSE4.1 flag. However, it appears to accept SSE4.1
 740             # intrinsics when SSE2 support is enabled, so we try that instead.
 741             GMX_TEST_CXXFLAG(MSVC_SSE2_CXXFLAG "/arch:SSE2" GROMACS_CXX_FLAGS)
 742         endif(NOT GNU_SSE4_CXXFLAG AND NOT MSVC_SSE4_CXXFLAG)
 743     endif()
 744
 745     # This must come after we have added the -msse4.1 flag on some platforms.
 746     check_include_file(smmintrin.h  HAVE_SMMINTRIN_H ${GROMACS_C_FLAGS})
 747
 748     if(NOT HAVE_SMMINTRIN_H)
 749         message(FATAL_ERROR "Cannot find smmintrin.h, which is required for SSE4.1 intrinsics support.")
 750     endif(NOT HAVE_SMMINTRIN_H)
 751
 752     set(GMX_CPU_ACCELERATION_X86_SSE4_1 1)
 753     # The user should not be able to set this orthogonally to the acceleration
 754     set(GMX_X86_SSE4_1 1)
 755     set(GMX_X86_SSE2   1)
 756     if (NOT ACCELERATION_QUIETLY)
 757       message(STATUS "Enabling SSE4.1 Gromacs acceleration, and it will help compiler optimization.")
 758     endif()
 759
 760 elseif(${GMX_CPU_ACCELERATION} STREQUAL "AVX_128_FMA" OR ${GMX_CPU_ACCELERATION} STREQUAL "AVX_256")
 761
 762     # Set the AVX compiler flag for both these choices!
 763
 764     GMX_TEST_CFLAG(GNU_AVX_CFLAG "-mavx" GROMACS_C_FLAGS)
 765     if (NOT GNU_AVX_CFLAG)
 766         GMX_TEST_CFLAG(MSVC_AVX_CFLAG "/arch:AVX" GROMACS_C_FLAGS)
 767     endif (NOT GNU_AVX_CFLAG)
 768     if (NOT GNU_AVX_CFLAG AND NOT MSVC_AVX_CFLAG)
 769         message(WARNING "No C AVX flag found. Consider a newer compiler, or disable AVX for much lower performance.")
 770     endif (NOT GNU_AVX_CFLAG AND NOT MSVC_AVX_CFLAG)
 771
 772     if (CMAKE_CXX_COMPILER_LOADED)
 773         GMX_TEST_CXXFLAG(GNU_AVX_CXXFLAG "-mavx" GROMACS_CXX_FLAGS)
 774         if (NOT GNU_AVX_CXXFLAG)
 775             GMX_TEST_CXXFLAG(MSVC_AVX_CXXFLAG "/arch:AVX" GROMACS_CXX_FLAGS)
 776         endif (NOT GNU_AVX_CXXFLAG)
 777         if (NOT GNU_AVX_CXXFLAG AND NOT MSVC_AVX_CXXFLAG)
 778             message(WARNING "No C++ AVX flag found. Consider a newer compiler, or disable AVX for much lower performance.")
 779         endif (NOT GNU_AVX_CXXFLAG AND NOT MSVC_AVX_CXXFLAG)
 780     endif()
 781
 782     # Set the FMA4 flags (MSVC doesn't require any)
 783     if(${GMX_CPU_ACCELERATION} STREQUAL "AVX_128_FMA" AND NOT MSVC)
 784         GMX_TEST_CFLAG(GNU_FMA_CFLAG "-mfma4" GROMACS_C_FLAGS)
 785         if (NOT GNU_FMA_CFLAG)
 786             message(WARNING "No C FMA4 flag found. Consider a newer compiler, or disable AVX_128_FMA for much lower performance.")
 787         endif(NOT GNU_FMA_CFLAG)
 788         if (CMAKE_CXX_COMPILER_LOADED)
 789             GMX_TEST_CXXFLAG(GNU_FMA_CXXFLAG "-mfma4" GROMACS_CXX_FLAGS)
 790             if (NOT GNU_FMA_CXXFLAG)
 791                 message(WARNING "No C++ FMA flag found. Consider a newer compiler, or disable AVX_128_FMA for much lower performance.")
 792             endif (NOT GNU_FMA_CXXFLAG)
 793         endif()
 794     endif()
 795
 796     # Only test the header after we have tried to add the flag for AVX support
 797     check_include_file(immintrin.h  HAVE_IMMINTRIN_H ${GROMACS_C_FLAGS})
 798
 799     if(NOT HAVE_IMMINTRIN_H)
 800         message(FATAL_ERROR "Cannot find immintrin.h, which is required for AVX intrinsics support. Consider switching compiler.")
 801     endif(NOT HAVE_IMMINTRIN_H)
 802
 803     if(${GMX_CPU_ACCELERATION} STREQUAL "AVX_256")
 804         try_compile(TEST_AVX ${CMAKE_BINARY_DIR}
 805             "${CMAKE_SOURCE_DIR}/cmake/TestAVX.c"
 806             COMPILE_DEFINITIONS "${GROMACS_C_FLAGS}")
 807         if(NOT TEST_AVX)
 808             message(FATAL_ERROR "Cannot compile AVX intrinsics. Consider switching compiler.")
 809         endif()
 810     endif()
 811
 812     # GCC requires x86intrin.h for FMA support. MSVC 2010 requires intrin.h for FMA support.
 813     check_include_file(x86intrin.h HAVE_X86INTRIN_H ${GROMACS_C_FLAGS})
 814     check_include_file(intrin.h HAVE_INTRIN_H ${GROMACS_C_FLAGS})
 815
 816     # The user should not be able to set this orthogonally to the acceleration
 817     set(GMX_X86_SSE4_1 1)
 818     set(GMX_X86_SSE2   1)
 819
 820     # But just enable one of the choices internally...
 821     if(${GMX_CPU_ACCELERATION} STREQUAL "AVX_128_FMA")
 822         set(GMX_CPU_ACCELERATION_X86_AVX_128_FMA 1)
 823         set(GMX_X86_AVX_128_FMA 1)
 824         if (NOT ACCELERATION_QUIETLY)
 825           message(STATUS "Enabling 128-bit AVX Gromacs acceleration (with fused-multiply add), and it will help compiler optimization.")
 826         endif()
 827     else()
 828         # If we are not doing AVX_128, it must be AVX_256...
 829         set(GMX_CPU_ACCELERATION_X86_AVX_256 1)
 830         set(GMX_X86_AVX_256 1)
 831         if (NOT ACCELERATION_QUIETLY)
 832           message(STATUS "Enabling 256-bit AVX Gromacs acceleration, and it will help compiler optimization.")
 833         endif()
 834     endif()
 835
 836 elseif(${GMX_CPU_ACCELERATION} STREQUAL "FORTRAN")
 837
 838 #    Fortran is temporarily disabled while we push in nbNxN kernels.
 839 #    We need to fake it a bit here to avoid jenkins build errors!
 840 #    add_definitions(-DGMX_FORTRAN)
 841
 842 elseif(${GMX_CPU_ACCELERATION} STREQUAL "BLUEGENE")
 843 # GMX_CPU_ACCELERATION=BlueGene should be set in the Toolchain-BlueGene?-???.cmake file
 844     if (NOT ACCELERATION_QUIETLY)
 845       message(STATUS "Configuring for BlueGene")
 846     endif()
 847     set(GMX_BLUEGENE 1)
 848     if (${CMAKE_SYSTEM_NAME} STREQUAL "BlueGeneL")
 849         set(SHARED_LIBS_DEFAULT OFF CACHE BOOL "Shared libraries not compatible with BlueGene/L, disabled!" FORCE)
 850         set(BUILD_SHARED_LIBS OFF CACHE BOOL "Shared libraries not compatible with BlueGene/L, disabled!" FORCE)
 851     endif (${CMAKE_SYSTEM_NAME} STREQUAL "BlueGeneL")
 852     set(GMX_SOFTWARE_INVSQRT OFF CACHE BOOL "Do not use software reciprocal square root on BlueGene" FORCE)
 853     set(GMX_POWERPC_INVSQRT ON CACHE BOOL "Use hardware reciprocal square root on BlueGene" FORCE)
 854     set(GMX_X11 OFF CACHE BOOL "X11 not compatible with BlueGene, disabled!" FORCE)
 855     set(GMX_THREAD_MPI OFF CACHE BOOL "Thread-MPI not compatible with BlueGene, disabled!" FORCE)
 856     set(GMX_MPI ON CACHE BOOL "Use MPI on BlueGene" FORCE)
 857 # Access to /etc/passwd is not available on the back end of BlueGene,
 858 # despite being detected by CMake. This can cause linker warnings
 859 # about harmless things in src/gmxlib/string2.h.
 860     set(HAVE_PWD_H OFF)
 861 # The automatic testing for endianness does not work for the BlueGene cross-compiler
 862     set(GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER 1 CACHE INTERNAL "BlueGene has big endian FP byte order (by default)" FORCE)
 863     set(GMX_IEEE754_BIG_ENDIAN_WORD_ORDER 1 CACHE INTERNAL "BlueGene has big endian FP word order (by default)" FORCE)
 864 elseif(${GMX_CPU_ACCELERATION} STREQUAL "POWER6")
 865     set(GMX_POWER6 1)
 866     set(GMX_SOFTWARE_INVSQRT OFF CACHE BOOL "Do not use software reciprocal square root on Power6" FORCE)
 867     set(GMX_POWERPC_INVSQRT ON CACHE BOOL "Use hardware reciprocal square root on Power6" FORCE)
 868 else(${GMX_CPU_ACCELERATION} STREQUAL "NONE")
 869     MESSAGE(FATAL_ERROR "Unrecognized option for accelerated kernels: ${GMX_CPU_ACCELERATION}. Pick one of None, SSE2, SSE4.1, AVX_128_FMA, AVX_256, Fortran, BlueGene, Power6")
 870 endif(${GMX_CPU_ACCELERATION} STREQUAL "NONE")
 871 set(ACCELERATION_QUIETLY TRUE CACHE INTERNAL "")
 872
 873 if(GMX_FORTRAN OR GMX_POWER6)
 874     if (GMX_THREAD_MPI)
 875         message(FATAL_ERROR "FORTRAN/POWER6 is incompatible with thread-MPI and only provides a speed-up on certain IBM compilers. Disable FORTRAN (or threads if you really want to use FORTRAN kernels).")
 876     endif(GMX_THREAD_MPI)
 877     enable_language(Fortran)
 878     include(FortranCInterface)
 879     discover_fortran_mangling(prefix isupper suffix extra_under_score found)
 880     if(extra_under_score)
 881         set(extrasuffix "_")
 882     endif(extra_under_score)
 883     if(prefix)
 884       set(prefix "${prefix} ##")
 885     endif(prefix)
 886     if(suffix)
 887       set(suffix "## ${suffix}")
 888       if(extrasuffix)
 889         set(extrasuffix "${suffix}${extrasuffix}")
 890       endif(extrasuffix)
 891     else(suffix)
 892       if(extrasuffix)
 893         # Don't know if this is needed, but it can't hurt
 894         set(extrasuffix "## ${extrasuffix}")
 895       endif(extrasuffix)
 896     endif(suffix)
 897
 898     if(isupper)
 899         set(F77_FUNCDEF   "${prefix} NAME ${suffix}")
 900         set(F77_FUNCDEF_  "${prefix} NAME ${extrasuffix}")
 901     else(isupper)
 902         set(F77_FUNCDEF   "${prefix} name ${suffix}")
 903         set(F77_FUNCDEF_  "${prefix} name ${extrasuffix}")
 904     endif(isupper)
 905 else(GMX_FORTRAN OR GMX_POWER6)
 906         set(F77_FUNCDEF   "name ## _")
 907         set(F77_FUNCDEF_  "name ## _")
 908 endif(GMX_FORTRAN OR GMX_POWER6)
 909
 910 # Process QM/MM Settings
 911 string(TOUPPER ${GMX_QMMM_PROGRAM} ${GMX_QMMM_PROGRAM})
 912 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 913     set(GMX_QMMM_GAUSSIAN 1)
 914 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 915     set(GMX_QMMM_MOPAC 1)
 916 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 917     set(GMX_QMMM_GAMESS 1)
 918 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 919     set(GMX_QMMM_ORCA 1)
 920 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 921     # nothing to do
 922 else(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 923     MESSAGE(FATAL_ERROR "Invalid QM/MM program option: ${GMX_QMMM_PROGRAM}. Choose one of: Gaussian, Mopac, Gamess, Orca, None")
 924 endif(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 925
 926 # Process FFT library settings - if not OpenMM build
 927 string(TOUPPER ${GMX_FFT_LIBRARY} ${GMX_FFT_LIBRARY})
 928 set(PKG_FFT "")
 929 set(PKG_FFT_LIBS "")
 930 if(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 931     if(GMX_DOUBLE)
 932         set(FFTW fftw)
 933     else(GMX_DOUBLE)
 934         set(FFTW fftwf)
 935     endif(GMX_DOUBLE)
 936     find_package(FFTW COMPONENTS ${FFTW})
 937     string(TOUPPER "${FFTW}" FFTW)
 938     set(PKG_FFT "${${FFTW}_PKG}")
 939     include_directories(${${FFTW}_INCLUDE_DIRS})
 940     set(FFT_LIBRARIES ${${FFTW}_LIBRARIES})
 941     if(NOT ${FFTW}_FOUND)
 942       MESSAGE(FATAL_ERROR "Cannot find FFTW3 (with correct precision - libfftw3f for single precision GROMACS or libfftw3 for double precision GROMACS). Fix it, choose another FFT library, or use the Gromacs built-in fftpack (slower)!")
 943     endif(NOT ${FFTW}_FOUND)
 944
 945     set(GMX_FFT_FFTW3 1)
 946
 947     if (NOT ${GMX_CPU_ACCELERATION} STREQUAL "NONE" AND NOT ${FFTW}_HAVE_SIMD)
 948       message(WARNING "The fftw library found is compiled without SIMD support, which makes it slow. Consider recompiling it or contact your admin")
 949     endif (NOT ${GMX_CPU_ACCELERATION} STREQUAL "NONE" AND NOT ${FFTW}_HAVE_SIMD)
 950
 951 elseif(${GMX_FFT_LIBRARY} STREQUAL "MKL")
 952 #    MESSAGE(STATUS "Using external FFT library - Intel MKL")
 953     find_package(MKL REQUIRED)
 954     include_directories(${MKL_INCLUDE_DIR})
 955     set(FFT_LIBRARIES ${MKL_LIBRARIES})
 956     set(PKG_FFT_LIBS ${MKL_LIBRARIES})
 957
 958     set(GMX_FFT_MKL 1)
 959     set(HAVE_MKL 1)
 960
 961 #elseif(${GMX_FFT_LIBRARY} STREQUAL "ACML")
 962 #    MESSAGE(STATUS "Using external FFT library - AMD core math library")
 963 #    set(GMX_FFT_ACML 1)
 964 elseif(${GMX_FFT_LIBRARY} STREQUAL "FFTPACK")
 965     MESSAGE(STATUS "Using internal FFT library - fftpack")
 966     set(GMX_FFT_FFTPACK 1)
 967 else(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 968     MESSAGE(FATAL_ERROR "Invalid FFT library setting: ${GMX_FFT_LIBRARY}. Choose one of: fftw3, mkl, fftpack")
 969 endif(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 970
 971 # enable threaded fftw3 if we've found it
 972 if(FFTW3_THREADS OR FFTW3F_THREADS)
 973     add_definitions(-DFFT5D_FFTW_THREADS)
 974 endif()
 975
 976 set(GMX_EXTERNAL_BLAS TRUE CACHE BOOL "Use external BLAS instead of built-in")
 977 set(GMX_EXTERNAL_LAPACK TRUE CACHE BOOL "Use external LAPACK instead of built-in")
 978 # MKL has BLAS/LAPACK routines
 979 if(NOT HAVE_MKL AND NOT ACCELERATE_FRAMEWORK)
 980   if(GMX_EXTERNAL_BLAS)
 981     if (GMX_BLAS_USER)
 982         list(APPEND GMX_EXTRA_LIBRARIES ${GMX_BLAS_USER})
 983     else(GMX_BLAS_USER)
 984         set(BLAS_FIND_QUIETLY ON)
 985         find_package(BLAS)
 986         if (BLAS_FOUND)
 987           list(APPEND GMX_EXTRA_LIBRARIES ${BLAS_LIBRARIES})
 988         else()
 989           MESSAGE(STATUS "Using internal BLAS library")
 990           set(GMX_EXTERNAL_BLAS FALSE CACHE BOOL "Use external BLAS instead of built-in" FORCE)
 991         endif()
 992     endif(GMX_BLAS_USER)
 993   endif(GMX_EXTERNAL_BLAS)
 994   if(GMX_EXTERNAL_LAPACK)
 995     if (GMX_LAPACK_USER)
 996         list(APPEND GMX_EXTRA_LIBRARIES ${GMX_LAPACK_USER})
 997     else(GMX_LAPACK_USER)
 998         set(LAPACK_FIND_QUIETLY ON)
 999         find_package(LAPACK)
1000         if (LAPACK_FOUND)
1001           list(APPEND GMX_EXTRA_LIBRARIES ${LAPACK_LIBRARIES})
1002         else()
1003           MESSAGE(STATUS "Using internal LAPACK library")
1004           set(GMX_EXTERNAL_LAPACK FALSE CACHE BOOL "Use external LAPACK instead of built-in" FORCE)
1005         endif()
1006     endif(GMX_LAPACK_USER)
1007   endif(GMX_EXTERNAL_LAPACK)
1008 endif()
1009 mark_as_advanced(GMX_EXTERNAL_LAPACK)
1010 mark_as_advanced(GMX_EXTERNAL_BLAS)
1011
1012 set(GMX_USE_PLUGINS OFF CACHE INTERNAL "Whether GROMACS will really try to compile support for VMD plugins")
1013
1014 if(GMX_LOAD_PLUGINS)
1015   if(CYGWIN OR NOT WIN32)
1016     # Native Windows does not have, nor need dlopen
1017     # Note that WIN32 is set with Cygwin, but Cygwin needs dlopen to use plug-ins
1018     include(gmxTestdlopen)
1019     gmx_test_dlopen(HAVE_DLOPEN)
1020   endif()
1021
1022   # so, should we use plug-ins?
1023   if((WIN32 AND NOT CYGWIN) OR (HAVE_DLOPEN AND BUILD_SHARED_LIBS))
1024     if(NOT VMD_QUIETLY)
1025       MESSAGE(STATUS
1026           "Found the ability to use plug-ins when building shared libaries, "
1027           "so will compile to use plug-ins (e.g. to read VMD-supported file "
1028           "formats).")
1029     endif()
1030     if(NOT GMX_VMD_PLUGIN_PATH)
1031       find_package(VMD)
1032     endif()
1033     set(GMX_USE_PLUGINS ON)
1034     list(APPEND GMX_EXTRA_LIBRARIES ${CMAKE_DL_LIBS}) # magic cross-platform pre-set variable for dlopen library
1035     set(PKG_DL_LIBS "-l${CMAKE_DL_LIBS}")
1036   else()
1037     set(PKG_DL_LIBS)
1038   endif()
1039 endif(GMX_LOAD_PLUGINS)
1040 set(VMD_QUIETLY TRUE CACHE INTERNAL "")
1041
1042 if(EXISTS "${CMAKE_SOURCE_DIR}/admin/.isreposource")
1043     if(NOT CMAKE_CROSSCOMPILING)
1044         option(GMX_BUILD_MANPAGES "Build man pages" ON)
1045     else()
1046         message(STATUS "Building the man pages is not available when "
1047             "cross-compiling the developer version from git")
1048     endif()
1049 else()
1050     #make sure source package contains all man pages
1051     if(NOT EXISTS "${CMAKE_SOURCE_DIR}/man/man1/ngmx.1")
1052         message(FATAL_ERROR "Man pages are missing from source package.")
1053     endif()
1054 endif()
1055 mark_as_advanced(GMX_BUILD_MANPAGES)
1056
1057 # Math and thread libraries must often come after all others when linking...
1058 if(HAVE_LIBM)
1059     list(APPEND GMX_EXTRA_LIBRARIES m)
1060 endif(HAVE_LIBM)
1061
1062 if(GMX_FAHCORE)
1063   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
1064       "Path to swindirect.h")
1065   include_directories(${COREWRAP_INCLUDE_DIR})
1066 endif(GMX_FAHCORE)
1067
1068 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
1069 # these are set after everything else
1070 if (NOT DEFINED GROMACS_C_FLAGS_SET)
1071     set(GROMACS_C_FLAGS_SET true CACHE INTERNAL "Whether to reset the C flags"
1072         FORCE)
1073     set(CMAKE_C_FLAGS "${GROMACS_C_FLAGS} ${CMAKE_C_FLAGS}" CACHE STRING
1074         "Flags used by the compiler during all build types" FORCE)
1075     if (CMAKE_CXX_COMPILER_LOADED)
1076         set(CMAKE_CXX_FLAGS "${GROMACS_CXX_FLAGS} ${CMAKE_CXX_FLAGS}" CACHE STRING
1077             "Flags used by the compiler during all build types" FORCE)
1078     endif()
1079     set(CMAKE_EXE_LINKER_FLAGS
1080         "${GROMACS_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}"
1081         CACHE STRING "Linker flags for creating executables" FORCE)
1082     set(CMAKE_SHARED_LINKER_FLAGS
1083         "${GROMACS_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS}"
1084         CACHE STRING "Linker flags for creating shared libraries" FORCE)
1085 endif (NOT DEFINED GROMACS_C_FLAGS_SET)
1086
1087 if(NOT GMX_OPENMP)
1088     #Unset all OpenMP flags in case OpenMP was disabled either by the user
1089     #or because it was only partially detected (e.g. only for C but not C++ compiler)
1090     unset(OpenMP_C_FLAGS CACHE)
1091     unset(OpenMP_CXX_FLAGS CACHE)
1092     unset(OpenMP_LINKER_FLAGS CACHE)
1093     unset(OpenMP_SHARED_LINKER_FLAGS)
1094 endif()
1095 ######################################
1096 # Output compiler and CFLAGS used
1097 ######################################
1098 execute_process(COMMAND ${CMAKE_C_COMPILER} --version RESULT_VARIABLE TMP_RESULT OUTPUT_VARIABLE CC_VERSION ERROR_VARIABLE CC_VERSION)
1099 #try executing just the compiler command if that failed...
1100 if(TMP_RESULT)
1101     execute_process(COMMAND ${CMAKE_C_COMPILER} RESULT_VARIABLE TMP_RESULT OUTPUT_VARIABLE CC_VERSION ERROR_VARIABLE CC_VERSION)
1102 endif()
1103 string(LENGTH "${CC_VERSION}" len)
1104 if(len)
1105     string(REGEX MATCH "[^\n]+" CC_VERSION "${CC_VERSION}")
1106 endif()
1107
1108 set(BUILD_COMPILER "@CMAKE_C_COMPILER@ @CMAKE_C_COMPILER_ID@ @CC_VERSION@")
1109 set(BUILD_CFLAGS "@CMAKE_C_FLAGS@")
1110 if(CMAKE_BUILD_TYPE STREQUAL "Debug")
1111     set(BUILD_CFLAGS "@BUILD_CFLAGS@ @CMAKE_C_FLAGS_DEBUG@")
1112 elseif(CMAKE_BUILD_TYPE STREQUAL "Release")
1113     set(BUILD_CFLAGS "@BUILD_CFLAGS@ @CMAKE_C_FLAGS_RELEASE@")
1114 elseif(CMAKE_BUILD_TYPE STREQUAL "MinSizeRel")
1115     set(BUILD_CFLAGS "@BUILD_CFLAGS@ @CMAKE_C_FLAGS_MINSIZEREL@")
1116 elseif(CMAKE_BUILD_TYPE STREQUAL "RelWithDebInfo")
1117     set(BUILD_CFLAGS "@BUILD_CFLAGS@ @CMAKE_C_FLAGS_RELWITHDEBINFO@")
1118 endif()
1119
1120
1121 ########################################################################
1122 # Specify install locations and which subdirectories to process        #
1123 ########################################################################
1124 if (GMX_USE_RELATIVE_INSTALL_PATH)
1125     set(GMX_INSTALL_PREFIX "" CACHE STRING "Prefix gets appended to CMAKE_INSTALL_PREFIX. For cpack it sets the root folder of the archive.")
1126     mark_as_advanced(GMX_INSTALL_PREFIX)
1127 else()
1128     set(GMX_INSTALL_PREFIX "${CMAKE_INSTALL_PREFIX}/")
1129 endif()
1130
1131 if ( NOT DEFINED GMXLIB )
1132     set(GMXLIB lib)
1133 endif()
1134 set(LIB_INSTALL_DIR "${GMX_INSTALL_PREFIX}${GMXLIB}")
1135 set(BIN_INSTALL_DIR  ${GMX_INSTALL_PREFIX}bin)
1136 set(DATA_INSTALL_DIR ${GMX_INSTALL_PREFIX}share/gromacs)
1137 set(MAN_INSTALL_DIR  ${GMX_INSTALL_PREFIX}share/man)
1138 set(INCL_INSTALL_DIR ${GMX_INSTALL_PREFIX}include)
1139
1140 set(GMXLIBDIR        ${DATA_INSTALL_DIR}/top)
1141
1142 ##################################################################
1143 # Shared library settings - Darwin uses INSTALL_NAME_DIR instead!
1144 ##################################################################
1145 if(NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin")
1146     set(CMAKE_SKIP_BUILD_RPATH  FALSE)
1147     set(CMAKE_BUILD_WITH_INSTALL_RPATH FALSE)
1148     set(CMAKE_INSTALL_RPATH "\\\$ORIGIN/../${GMXLIB}")
1149     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
1150 endif()
1151
1152 #COPYING file: Only necessary for binary distributions.
1153 #Simpler to always install.
1154 install(FILES COPYING DESTINATION ${DATA_INSTALL_DIR} COMPONENT data)
1155
1156 add_subdirectory(share)
1157 add_subdirectory(include)
1158 add_subdirectory(src)
1159 add_subdirectory(scripts)
1160
1161 #######################
1162 ## uninstall target
1163 #######################
1164     CONFIGURE_FILE(
1165                    "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
1166                    "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
1167                    IMMEDIATE @ONLY)
1168 ###########################
1169 ADD_CUSTOM_TARGET(uninstall
1170                   "${CMAKE_COMMAND}" -P
1171                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
1172 ###########################
1173
1174
1175 ########################################################################
1176 # Tests                                                                #
1177 ########################################################################
1178
1179 include(CTest)
1180 mark_as_advanced(BUILD_TESTING)
1181 IF(BUILD_TESTING)
1182         enable_testing()
1183         add_subdirectory(tests)
1184 ENDIF()
1185