CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.6)
   2
   3 project(Gromacs)
   4 include(Dart)
   5 mark_as_advanced(DART_ROOT)
   6 # PROJECT_VERSION should have the following structure:
   7 # VERSION[-dev-SUFFIX] where the VERSION can have any form and the suffix
   8 set(PROJECT_VERSION "4.5.1")
   9 set(CUSTOM_VERSION_STRING ""
  10     CACHE STRING "Custom version string (if empty, use hard-coded default)")
  11 mark_as_advanced(CUSTOM_VERSION_STRING)
  12 if (CUSTOM_VERSION_STRING)
  13     set(PROJECT_VERSION ${CUSTOM_VERSION_STRING})
  14 endif (CUSTOM_VERSION_STRING)
  15 set(SOVERSION 6)
  16 # It is a bit irritating, but this has to be set separately for now!
  17 SET(CPACK_PACKAGE_VERSION_MAJOR "4")
  18 SET(CPACK_PACKAGE_VERSION_MINOR "5")
  19 SET(CPACK_PACKAGE_VERSION_PATCH "1")
  20
  21
  22 # Cmake modules/macros are in a subdirectory to keep this file cleaner
  23 set(CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake)
  24
  25 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
  26 set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
  27 endif()
  28
  29 if(NOT CMAKE_BUILD_TYPE)
  30     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel." FORCE)
  31 endif(NOT CMAKE_BUILD_TYPE)
  32
  33 enable_language(C)
  34
  35 set(CPACK_PACKAGE_VERSION ${PROJECT_VERSION})
  36 set(CPACK_PACKAGE_VENDOR "gromacs.org")
  37 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Gromacs - a toolkit for high-performance molecular simulation")
  38 set(CPACK_SET_DESTDIR "ON")
  39 set(CPACK_INCLUDE_TOPLEVEL_DIRECTORY 0)
  40 set(CPACK_RESOURCE_FILE_WELCOME "${CMAKE_SOURCE_DIR}/admin/InstallWelcome.txt")
  41 # Its GPL/LGPL, so they do not have to agree to a license for mere usage, but some installers require this...
  42 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_SOURCE_DIR}/admin/InstallLicense.txt")
  43 set(CPACK_RESOURCE_FILE_README "${CMAKE_SOURCE_DIR}/admin/InstallInfo.txt")
  44
  45 #must come after all cpack settings!
  46 include(CPack)
  47
  48
  49 ########################################################################
  50 # Fix stupid flags on MSVC
  51 ########################################################################
  52 SET(SHARED_LIBS_DEFAULT ON)
  53 IF(CMAKE_GENERATOR MATCHES "Visual Studio")
  54     STRING(REPLACE /MD /MT CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE})
  55     SET(CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE} CACHE STRING "" FORCE)
  56     STRING(REPLACE /MD /MT CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG})
  57     SET(CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG} CACHE STRING "" FORCE)
  58     SET(SHARED_LIBS_DEFAULT OFF)
  59 ENDIF(CMAKE_GENERATOR MATCHES "Visual Studio")
  60
  61 set(GMX_EXTRA_LIBRARIES)
  62
  63
  64
  65 ######################################################################
  66 # compiler tests
  67 # these need ot be done early (before further tests).
  68 #####################################################################
  69
  70 include(CheckCCompilerFlag)
  71 include(CheckCXXCompilerFlag)
  72
  73 include(gmxCFlags)
  74 gmx_c_flags()
  75
  76 ########################################################################
  77 # User input options                                                   #
  78 ########################################################################
  79 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" OFF)
  80 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
  81 option(GMX_THREADS    "Build a parallel (thread-based) version of GROMACS (cannot be combined with MPI yet)" ON)
  82 option(GMX_SOFTWARE_INVSQRT "Use GROMACS software 1/sqrt" ON)
  83 mark_as_advanced(GMX_SOFTWARE_INVSQRT)
  84 option(GMX_POWERPC_INVSQRT "Use PowerPC hardware 1/sqrt" ON)
  85 mark_as_advanced(GMX_POWERPC_INVSQRT)
  86 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
  87 mark_as_advanced(GMX_FAHCORE)
  88 option(GMX_OPENMM "Accelerated execution on GPUs through the OpenMM library (rerun cmake after changing to see relevant options)" OFF)
  89 set(GMX_ACCELERATION "auto"
  90     CACHE STRING "Accelerated kernels. Pick one of: auto, none, SSE, BlueGene, Power6, ia64, altivec, fortran")
  91
  92 set(GMX_FFT_LIBRARY "fftw3"
  93     CACHE STRING "FFT library choices: fftw3,fftw2,mkl,fftpack[built-in]")
  94 option(GMX_DISABLE_FFTW_MEASURE
  95        "Do not optimize FFTW setups (not needed with SSE)" OFF)
  96 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
  97 set(GMX_QMMM_PROGRAM "none"
  98     CACHE STRING "QM package choices: none,gaussian,mopac,gamess,orca")
  99 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 100 mark_as_advanced(GMX_BROKEN_CALLOC)
 101 option(BUILD_SHARED_LIBS "Enable shared libraries (can be problematic with MPI, Windows)" ${SHARED_LIBS_DEFAULT})
 102 option(GMX_MPI_IN_PLACE "Enable MPI_IN_PLACE for MPIs that have it defined" ON)
 103 mark_as_advanced(GMX_MPI_IN_PLACE)
 104 option(GMX_DLOPEN "Compile with dlopen, needed to read VMD supported file formats" ON)
 105 mark_as_advanced(GMX_DLOPEN)
 106
 107
 108 option(GMX_IA32_ASM "Add SSE assembly files for IA32" OFF)
 109 mark_as_advanced(GMX_IA32_ASM)
 110 option(GMX_X86_64_ASM "Add SSE assembly files for X86_64" OFF)
 111 mark_as_advanced(GMX_X86_64_ASM)
 112
 113 option(USE_VERSION_H "Generate development version string/information" ON)
 114 mark_as_advanced(USE_VERSION_H)
 115
 116 option(GMX_DEFAULT_SUFFIX "Use default suffixes for GROMACS binaries and libs (_d for double, _mpi for MPI; rerun cmake after changing to see relevant options)" ON)
 117
 118 ########################################################################
 119 # Set up binary and library suffixing
 120 ########################################################################
 121 set(GMX_BINARY_SUFFIX "" CACHE STRING "Suffix for GROMACS binaries (default: _d for double, _mpi for MPI, _mpi_d for MPI and double).")
 122 set(GMX_LIBS_SUFFIX ""
 123   CACHE STRING "Suffix for GROMACS libs (default: _d for double, _mpi for MPI, _mpi_d for MPI and double).")
 124 if (GMX_DEFAULT_SUFFIX)
 125   set(GMX_BINARY_SUFFIX "")
 126   set(GMX_LIBS_SUFFIX "")
 127   if (GMX_MPI)
 128     set(GMX_BINARY_SUFFIX "_mpi")
 129     set(GMX_LIBS_SUFFIX "_mpi")
 130   endif(GMX_MPI)
 131   if (GMX_DOUBLE)
 132     set (GMX_BINARY_SUFFIX "${GMX_BINARY_SUFFIX}_d")
 133     set (GMX_LIBS_SUFFIX "${GMX_LIBS_SUFFIX}_d")
 134   endif(GMX_DOUBLE)
 135   if (GMX_OPENMM)
 136     set (GMX_BINARY_SUFFIX "-gpu")
 137     set (GMX_LIBS_SUFFIX "_gpu")
 138   endif(GMX_OPENMM)
 139   mark_as_advanced(FORCE GMX_BINARY_SUFFIX GMX_LIBS_SUFFIX)
 140   message(STATUS "Using default binary suffix: \"${GMX_BINARY_SUFFIX}\"")
 141   message(STATUS "Using default library suffix: \"${GMX_LIBS_SUFFIX}\"")
 142 else(GMX_DEFAULT_SUFFIX)
 143   mark_as_advanced(CLEAR GMX_BINARY_SUFFIX GMX_LIBS_SUFFIX)
 144   message(STATUS "Using manually set binary suffix: \"${GMX_BINARY_SUFFIX}\"")
 145   message(STATUS "Using manually set library suffix: \"${GMX_LIBS_SUFFIX}\"")
 146 endif(GMX_DEFAULT_SUFFIX)
 147
 148 set(PKG_CFLAGS "")
 149 if(GMX_DOUBLE)
 150     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_DOUBLE")
 151 endif(GMX_DOUBLE)
 152 if(GMX_SOFTWARE_INVSQRT)
 153   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_SOFTWARE_INVSQRT")
 154 endif(GMX_SOFTWARE_INVSQRT)
 155 if(GMX_POWERPC_INVSQRT)
 156   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_POWERPC_INVSQRT")
 157 endif(GMX_POWERPC_INVSQRT)
 158
 159 ########################################################################
 160 #Process MPI settings
 161 ########################################################################
 162 if(GMX_MPI)
 163         MESSAGE(WARNING "
 164             There are known problems with some MPI implementations:
 165                      OpenMPI version < 1.4.1
 166                      MVAPICH2 version <= 1.4.1                               *")
 167     if(GMX_THREADS)
 168         #message(FATAL_ERROR "Thread-based parallelization conflicts with MPI.")
 169         set(GMX_THREADS OFF CACHE BOOL
 170             "Thread-based parallelization conflicts with MPI." FORCE)
 171     endif(GMX_THREADS)
 172     find_package(MPI)
 173     if(MPI_FOUND)
 174         set(GROMACS_C_FLAGS ${GROMACS_FLAGS} ${MPI_COMPILE_FLAGS})
 175         set(GROMACS_LINKER_FLAGS ${GROMACS_LINKER_FLAGS} ${MPI_LINK_FLAGS})
 176
 177         include_directories(${MPI_INCLUDE_PATH})
 178         list(APPEND GMX_EXTRA_LIBRARIES ${MPI_LIBRARIES})
 179         add_definitions( -DMPI ) #for FAHCORE
 180         include(gmxTestMPI_IN_PLACE)
 181         if (GMX_MPI_IN_PLACE)
 182             gmx_test_mpi_in_place(MPI_IN_PLACE_EXISTS)
 183         endif (GMX_MPI_IN_PLACE)
 184     else(MPI_FOUND)
 185         message(FATAL_ERROR "MPI support requested, but no MPI compiler found.")
 186     endif(MPI_FOUND)
 187     include(gmxTestCatamount)
 188     gmx_test_catamount(GMX_CRAY_XT3)
 189     if(GMX_CRAY_XT3)
 190         set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_CRAY_XT3")
 191         set(GMX_NO_SYSTEM 1)
 192         set(GMX_NO_NICE 1)
 193     endif(GMX_CRAY_XT3)
 194     set(GMX_LIB_MPI 1)
 195     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_LIB_MPI")
 196 endif(GMX_MPI)
 197
 198
 199 #######################################################################
 200 # Check for options incompatible with OpenMM build                    #
 201 #######################################################################
 202 if(GMX_OPENMM)
 203     cmake_minimum_required(VERSION 2.6.4)
 204     # we'll use the built-in fft to avoid unnecessary dependencies
 205     string(TOUPPER ${GMX_FFT_LIBRARY} GMX_FFT_LIBRARY)
 206     if(NOT ${GMX_FFT_LIBRARY} STREQUAL "FFTPACK")
 207         message(STATUS "No external FFT libraries needed for the OpenMM build, switching to fftpack!")
 208         set(GMX_FFT_LIBRARY "fftpack" CACHE STRING
 209                 "No external FFT libraries needed for the OpenMM build, switching to  fftpack!" FORCE)
 210     endif()
 211     if(GMX_MPI)
 212         message(FATAL_ERROR "The OpenMM build is not compatible with MPI!")
 213     endif(GMX_MPI)
 214     if(GMX_THREADS)
 215         message(STATUS "Threads are  not compatible with OpenMM build, disabled!")
 216         set(GMX_THREADS OFF CACHE BOOL
 217                 "Threads are not compatible with OpenMM build, disabled!" FORCE)
 218     endif(GMX_THREADS)
 219     if(GMX_SOFTWARE_INVSQRT)
 220         set(GMX_SOFTWARE_INVSQRT OFF CACHE STRING
 221                 "The OpenMM build does not need GROMACS software 1/sqrt!" FORCE)
 222     endif(GMX_SOFTWARE_INVSQRT)
 223     string(TOUPPER ${GMX_ACCELERATION} GMX_ACCELERATION)
 224     if(NOT GMX_ACCELERATION STREQUAL "NONE")
 225         message(STATUS "Switching off CPU-based acceleration, the OpenMM build does not support/need any!")
 226         set(GMX_ACCELERATION "none" CACHE STRING
 227                 "Switching off CPU-based acceleration, the OpenMM build does not support/need any!" FORCE)
 228     endif()
 229     if(GMX_FAHCORE)
 230         message(FATAL_ERROR "The OpenMM build does not support FAH build!")
 231     endif(GMX_FAHCORE)
 232     if(GMX_DOUBLE)
 233         message(FATAL_ERROR  "The OpenMM-build does not support double precision calculations!")
 234     endif()
 235     # mark as advanced the unused variables
 236     mark_as_advanced(FORCE GMX_ACCELERATION GMX_MPI GMX_FFT_LIBRARY
 237         GMX_QMMM_PROGRAM GMX_THREADS GMX_DOUBLE)
 238 else(GMX_OPENMM)
 239      mark_as_advanced(CLEAR GMX_ACCELERATION GMX_MPI GMX_FFT_LIBRARY
 240         GMX_QMMM_PROGRAM GMX_THREADS GMX_DOUBLE)
 241 endif(GMX_OPENMM)
 242
 243
 244 ########################################################################
 245 # Basic system tests (standard libraries, headers, functions, types)   #
 246 ########################################################################
 247 include(CheckIncludeFiles)
 248 check_include_files(string.h     HAVE_STRING_H)
 249 check_include_files(math.h       HAVE_MATH_H)
 250 check_include_files(limits.h     HAVE_LIMITS_H)
 251 check_include_files(memory.h     HAVE_MEMORY_H)
 252 check_include_files(unistd.h     HAVE_UNISTD_H)
 253 check_include_files(pwd.h        HAVE_PWD_H)
 254 check_include_files(stdint.h     HAVE_STDINT_H)
 255 check_include_files(stdlib.h     HAVE_STDLIB_H)
 256 check_include_files(pthread.h    HAVE_PTHREAD_H)
 257 check_include_files(dirent.h     HAVE_DIRENT_H)
 258 check_include_files(inttypes.h   HAVE_INTTYPES_H)
 259 check_include_files(regex.h      HAVE_REGEX_H)
 260 check_include_files(sys/types.h  HAVE_SYS_TYPES_H)
 261 check_include_files(sys/stat.h   HAVE_SYS_STAT_H)
 262 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 263 check_include_files(rpc/rpc.h    HAVE_RPC_RPC_H)
 264 check_include_files("rpc/rpc.h;rpc/xdr.h"    HAVE_RPC_XDR_H)
 265 # SSE support
 266 check_include_files(xmmintrin.h  HAVE_XMMINTRIN_H)
 267 check_include_files(emmintrin.h  HAVE_EMMINTRIN_H)
 268 check_include_files(pmmintrin.h  HAVE_PMMINTRIN_H)
 269 check_include_files(smmintrin.h  HAVE_SMMINTRIN_H)
 270 check_include_files(io.h                 HAVE_IO_H)
 271
 272
 273 include(CheckFunctionExists)
 274 check_function_exists(strcasecmp        HAVE_STRCASECMP)
 275 check_function_exists(strdup            HAVE_STRDUP)
 276 check_function_exists(vprintf           HAVE_VPRINTF)
 277 check_function_exists(memcmp            HAVE_MEMCMP)
 278 check_function_exists(posix_memalign    HAVE_POSIX_MEMALIGN)
 279 check_function_exists(memalign          HAVE_MEMALIGN)
 280 check_function_exists(_aligned_malloc   HAVE__ALIGNED_MALLOC)
 281 check_function_exists(gettimeofday      HAVE_GETTIMEOFDAY)
 282 check_function_exists(isnan             HAVE_ISNAN)
 283 check_function_exists(_isnan            HAVE__ISNAN)
 284 check_function_exists(isfinite          HAVE_ISFINITE)
 285 check_function_exists(_isfinite         HAVE__ISFINITE)
 286 check_function_exists(fsync             HAVE_FSYNC)
 287 check_function_exists(_fileno           HAVE__FILENO)
 288 check_function_exists(fileno            HAVE_FILENO)
 289 check_function_exists(_commit           HAVE__COMMIT)
 290
 291 include(CheckLibraryExists)
 292 check_library_exists(m sqrt "" HAVE_LIBM)
 293 check_library_exists(m cbrt "" HAVE_CBRT)
 294
 295
 296 include(CheckTypeSize)
 297
 298 check_type_size("bool"          SIZEOF_BOOL) # will also set HAVE_BOOL
 299 check_type_size("int"           SIZEOF_INT)
 300 check_type_size("long int"      SIZEOF_LONG_INT)
 301 check_type_size("long long int" SIZEOF_LONG_LONG_INT)
 302 check_type_size("off_t"         SIZEOF_OFF_T)
 303 check_type_size("void *"        SIZEOF_VOIDP)
 304
 305 if (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 306     set(GMX_64_BIT TRUE)
 307 else (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 308     set(GMX_64_BIT FALSE)
 309 endif (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 310
 311 # Check for some basic types that we *need*, so set these to int if they are not present
 312 check_type_size(uid_t uid_t)
 313 if(NOT uid_t)
 314   set(uid_t int)
 315 else(NOT uid_t)
 316   set(uid_t 0)
 317 endif(NOT uid_t)
 318
 319 check_type_size(gid_t gid_t)
 320 if(NOT gid_t)
 321   set(gid_t 1)
 322 else(NOT gid_t)
 323   set(gid_t 0)
 324 endif(NOT gid_t)
 325
 326 check_type_size(size_t size_t)
 327 if(NOT size_t)
 328   set(size_t int)
 329 else(NOT size_t)
 330   set(size_t 0)
 331 endif(NOT size_t)
 332
 333 check_type_size(off_t off_t)
 334 if(NOT off_t)
 335   set(off_t int)
 336 else(NOT off_t)
 337   set(off_t 0)
 338 endif(NOT off_t)
 339
 340 include(TestBigEndian)
 341 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 342
 343
 344
 345
 346 ########################################################################
 347 # Find external packages                                               #
 348 ########################################################################
 349
 350 find_package(LibXml2)
 351 set(PKG_XML "")
 352 if(LIBXML2_FOUND)
 353     include_directories(${LIBXML2_INCLUDE_DIR})
 354     set(PKG_XML libxml-2.0)
 355     set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 356     set(HAVE_LIBXML2 1)
 357 endif(LIBXML2_FOUND)
 358
 359 option(GMX_X11 "Use X window system" OFF)
 360 if (GMX_X11)
 361         find_package(X11)
 362         # X11 includes/libraries are only set in the ngmx subdirectory!
 363         if(X11_FOUND)
 364         set(HAVE_X11 1)
 365         endif(X11_FOUND)
 366 endif(GMX_X11)
 367
 368 if(GMX_THREADS)
 369     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_THREADS")
 370     include(ThreadMPI)
 371     set(THREAD_MPI_LIB thread_mpi)
 372     set(GMX_MPI 1)
 373     string(TOUPPER ${GMX_FFT_LIBRARY} ${GMX_FFT_LIBRARY})
 374     if(${GMX_FFT_LIBRARY} STREQUAL "FFTW2")
 375         message(FATAL_ERROR "FFTW2 can't be used with threads. Try fftw3 or mkl.")
 376     endif()
 377 endif(GMX_THREADS)
 378
 379 if(GMX_OPENMM)
 380     set(CUDA_BUILD_EMULATION OFF)
 381     find_package(CUDA 3.1 REQUIRED)
 382     add_definitions(-DGMX_OPENMM)
 383     if(CMAKE_BUILD_TYPE STREQUAL "DEBUG")
 384         set(CUDA_VERBOSE_BUILD ON)
 385     endif()
 386     find_package(OpenMM)
 387 endif(GMX_OPENMM)
 388
 389 if(APPLE)
 390    find_library(ACCELERATE_FRAMEWORK Accelerate)
 391    list(APPEND GMX_EXTRA_LIBRARIES ${ACCELERATE_FRAMEWORK})
 392 endif(APPLE)
 393
 394 # only bother with finding git and using version.h if the source is a git repo
 395 if(EXISTS "${CMAKE_SOURCE_DIR}/.git")
 396     if(USE_VERSION_H)
 397         # We need at least git v1.5.1 be able to parse git's date output. If not
 398         # fund or the version is too small, we can't generate version information.
 399         find_package(Git 1.5.1)
 400         # this should at some point become VERSION_LESS
 401         if(NOT Git_FOUND OR Git_VERSION STRLESS "1.5.1")
 402             message("No compatible git version found, won't be able to generate proper development version information.")
 403             set(USE_VERSION_H OFF)
 404         endif()
 405     endif()
 406 else()
 407     set(USE_VERSION_H OFF)
 408 endif()
 409
 410 if (GMX_DLOPEN)
 411     list(APPEND GMX_EXTRA_LIBRARIES ${CMAKE_DL_LIBS})
 412 endif (GMX_DLOPEN)
 413
 414 ########################################################################
 415 # Generate development version info for cache
 416 ########################################################################
 417 # set(GEN_VERSION_INFO_INTERNAL "ON")
 418 # include(gmxGenerateVersionString)
 419
 420 ########################################################################
 421 # Our own GROMACS tests
 422 ########################################################################
 423
 424 add_definitions( -DHAVE_CONFIG_H )
 425 include_directories(${CMAKE_BINARY_DIR}/src)
 426 include_directories(${CMAKE_SOURCE_DIR}/include)
 427
 428 include(gmxCheckBuildUserTime)
 429 gmx_check_build_user_time(BUILD_TIME BUILD_USER BUILD_MACHINE)
 430
 431 include(gmxTestFloatFormat)
 432 gmx_test_float_format(GMX_FLOAT_FORMAT_IEEE754
 433                       GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER
 434                       GMX_IEEE754_BIG_ENDIAN_WORD_ORDER)
 435
 436 include(gmxTestLargeFiles)
 437 gmx_test_large_files(GMX_LARGEFILES)
 438 check_function_exists(fseeko     HAVE_FSEEKO)
 439
 440 include(gmxTestSignal)
 441 gmx_test_retsigtype(RETSIGTYPE)
 442 gmx_test_sigusr1(HAVE_SIGUSR1)
 443
 444 include(gmxTestInline)
 445 gmx_test_inline(INLINE_KEYWORD)
 446
 447 include(gmxTestRestrict)
 448 gmx_test_inline(RESTRICT_KEYWORD)
 449
 450 include(gmxTestPipes)
 451 gmx_test_pipes(HAVE_PIPES)
 452
 453 include(gmxTestInlineASM)
 454 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 455 gmx_test_inline_asm_msvc_x86(GMX_X86_MSVC_INLINE_ASM)
 456
 457 # turn on SSE if supported with reasonable defaults.
 458 if (${GMX_ACCELERATION} STREQUAL "auto" AND NOT GMX_OPENMM)
 459   if(CMAKE_SYSTEM_PROCESSOR MATCHES "^(i.86|x86|x64|x86_64|AMD64|amd64)")
 460
 461     set(GMX_ACCELERATION "SSE" CACHE STRING "Accelerated kernels. Pick one of: auto, none, SSE, BlueGene, Power6, ia64, altivec, fortran" FORCE)
 462
 463     if (GMX_64_BIT)
 464       set(GMX_X86_64_ASM ON CACHE BOOL "Add SSE assembly files for x86_64" FORCE)
 465     else (GMX_64_BIT)
 466       set(GMX_IA32_ASM ON CACHE BOOL "Add SSE assembly files for i386" FORCE)
 467     endif (GMX_64_BIT)
 468
 469     # Determine the assembler/compiler to use
 470   else()
 471     set(GMX_ACCELERATION "none" CACHE STRING "Accelerated kernels. Pick one of: auto, none, SSE, BlueGene, Power6, ia64, altivec, fortran" FORCE)
 472   endif()
 473 endif (${GMX_ACCELERATION} STREQUAL "auto" AND NOT GMX_OPENMM)
 474
 475 include(gmxTestXDR)
 476 gmx_test_xdr(GMX_SYSTEM_XDR)
 477 if(NOT GMX_SYSTEM_XDR)
 478     set(GMX_INTERNAL_XDR 1)
 479     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_INTERNAL_XDR")
 480 endif(NOT GMX_SYSTEM_XDR)
 481
 482 # Process nonbonded accelerated kernels settings
 483 string(TOUPPER ${GMX_ACCELERATION} ${GMX_ACCELERATION})
 484 if(${GMX_ACCELERATION} STREQUAL "NONE")
 485   # nothing to do
 486 elseif(${GMX_ACCELERATION} STREQUAL "SSE")
 487
 488     if(CMAKE_GENERATOR MATCHES "Visual Studio")
 489       option(GMX_ASM_USEASM-NASM "Use Nasm for assembly instead of compiler (necessary on windows)" ON)
 490     else()
 491       option(GMX_ASM_USEASM-NASM "Use Nasm for assembly instead of compiler (necessary on windows)" OFF)
 492     endif()
 493         mark_as_advanced(GMX_ASM_USEASM-NASM)
 494
 495     if (NOT GMX_64_BIT)
 496         # for 32-bit compiles, we might need to turn on sse
 497         CHECK_C_COMPILER_FLAG("-msse2" XFLAGS_SSE)
 498         if (XFLAGS_SSE)
 499             set(GROMACS_C_FLAGS "-msse2 ${GROMACS_C_FLAGS}")
 500         endif (XFLAGS_SSE)
 501         CHECK_CXX_COMPILER_FLAG("-msse2" XXFLAGS_SSE)
 502         if (XXFLAGS_SSE)
 503             set(GROMACS_CXX_FLAGS "-msse2 ${GROMACS_CXX_FLAGS}")
 504         endif (XXFLAGS_SSE)
 505     endif (NOT GMX_64_BIT)
 506
 507     if(GMX_IA32_ASM)
 508       if(GMX_DOUBLE)
 509         set(GMX_IA32_SSE2 1)
 510       else()
 511        set(GMX_IA32_SSE 1)
 512       endif()
 513     elseif(GMX_X86_64_ASM)
 514       if(GMX_DOUBLE)
 515        set(GMX_X86_64_SSE2 1)
 516       else()
 517         set(GMX_X86_64_SSE 1)
 518       endif()
 519     endif()
 520
 521 #    if(HAVE_PMMINTRIN_H)
 522 #        set(GMX_SSE3 1)
 523 #    endif(HAVE_PMMINTRIN_H)
 524 #    if(HAVE_SMMINTRIN_H)
 525 #        set(GMX_SSE4_1 1)
 526 #    endif(HAVE_SMMINTRIN_H)
 527
 528 elseif(${GMX_ACCELERATION} STREQUAL "FORTRAN")
 529     set(GMX_FORTRAN 1)
 530     #these are switch on by default sometimes
 531     set(GMX_IA32_ASM 0)
 532     set(GMX_GMX_X86_64_ASM 0)
 533 elseif(${GMX_ACCELERATION} STREQUAL "BLUEGENE")
 534 # GMX_ACCELERATION=BlueGene should be set in the Toolchain-BlueGene?-???.cmake file
 535     message(STATUS "Configuring for BlueGene")
 536     set(GMX_BLUEGENE 1)
 537     if (${CMAKE_SYSTEM_NAME} STREQUAL "BlueGeneL")
 538         set(SHARED_LIBS_DEFAULT OFF CACHE BOOL "Shared libraries not compatible with BlueGene/L, disabled!" FORCE)
 539         set(BUILD_SHARED_LIBS OFF CACHE BOOL "Shared libraries not compatible with BlueGene/L, disabled!" FORCE)
 540     endif (${CMAKE_SYSTEM_NAME} STREQUAL "BlueGeneL")
 541     set(GMX_SOFTWARE_INVSQRT OFF CACHE BOOL "Do not use software reciprocal square root on BlueGene" FORCE)
 542     set(GMX_POWERPC_INVSQRT ON CACHE BOOL "Use hardware reciprocal square root on BlueGene" FORCE)
 543     set(GMX_X11 OFF CACHE BOOL "X11 not compatible with BlueGene, disabled!" FORCE)
 544     set(GMX_THREADS OFF CACHE BOOL "Threads not compatible with BlueGene, disabled!" FORCE)
 545     set(GMX_MPI ON CACHE BOOL "Use MPI on BlueGene" FORCE)
 546     set(GMX_EXTERNAL_BLAS TRUE CACHE BOOL "Use MASSV for BLAS on BlueGene" FORCE)
 547     set(GMX_EXTERNAL_LAPACK TRUE CACHE BOOL "Use MASSV for LAPACK on BlueGene" FORCE)
 548     list(APPEND GMX_EXTRA_LIBRARIES massv)
 549 elseif(${GMX_ACCELERATION} STREQUAL "POWER6")
 550     set(GMX_POWER6 1)
 551     set(GMX_SOFTWARE_INVSQRT OFF CACHE BOOL "Do not use software reciprocal square root on Power6" FORCE)
 552     set(GMX_POWERPC_INVSQRT ON CACHE BOOL "Use hardware reciprocal square root on Power6" FORCE)
 553 elseif(${GMX_ACCELERATION} STREQUAL "IA64")
 554     set(GMX_IA64_ASM 1)
 555     set(DISABLE_WATERWATER_NLIST 1)
 556     set(DISABLE_WATER_NLIST 1)
 557 elseif(${GMX_ACCELERATION} STREQUAL "ALTIVEC")
 558     check_include_files(altivec.h HAVE_ALTIVEC_H)
 559     if(HAVE_ALTIVEC_H)
 560         set(GMX_PPC_ALTIVEC 1)
 561     endif(HAVE_ALTIVEC_H)
 562 else(${GMX_ACCELERATION} STREQUAL "NONE")
 563     MESSAGE(FATAL_ERROR "Unrecognized option for accelerated kernels: ${GMX_ACCELERATION}. Pick one of auto, none, SSE, Fortran, BlueGene, Power6, ia64, altivec")
 564 endif(${GMX_ACCELERATION} STREQUAL "NONE")
 565
 566 if(GMX_FORTRAN OR GMX_POWER6)
 567     if (GMX_THREADS)
 568         message(FATAL_ERROR "FORTRAN/POWER6 is incompatible with threads and only provides a speed-up on certain IBM compilers. Disable FORTRAN (or threads if you really want to use FORTRAN kernels).")
 569     endif(GMX_THREADS)
 570     enable_language(Fortran)
 571     include(FortranCInterface)
 572     discover_fortran_mangling(prefix isupper suffix extra_under_score found)
 573     if(extra_under_score)
 574         set(extrasuffix "_")
 575     endif(extra_under_score)
 576     if(prefix)
 577       set(prefix "${prefix} ##")
 578     endif(prefix)
 579
 580     if(isupper)
 581         set(F77_FUNCDEF   "${prefix} NAME ## ${suffix}")
 582         set(F77_FUNCDEF_  "${prefix} NAME ## ${suffix}${extrasuffix}")
 583     else(isupper)
 584         set(F77_FUNCDEF   "${prefix} name ## ${suffix}")
 585         set(F77_FUNCDEF_  "${prefix} name ## ${suffix}${extrasuffix}")
 586     endif(isupper)
 587 else(GMX_FORTRAN OR GMX_POWER6)
 588         set(F77_FUNCDEF   "name ## _")
 589         set(F77_FUNCDEF_  "name ## _")
 590 endif(GMX_FORTRAN OR GMX_POWER6)
 591
 592 # Process QM/MM Settings
 593 string(TOUPPER ${GMX_QMMM_PROGRAM} ${GMX_QMMM_PROGRAM})
 594 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 595     set(GMX_QMMM_GAUSSIAN 1)
 596 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 597     set(GMX_QMMM_MOPAC 1)
 598 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 599     set(GMX_QMMM_GAMESS 1)
 600 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 601     set(GMX_QMMM_ORCA 1)
 602 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 603     # nothing to do
 604 else(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 605     MESSAGE(FATAL_ERROR "Invalid QM/MM program option: ${GMX_QMMM_PROGRAM}. Choose one of: Gaussian, Mopac, Gamess, Orca, None")
 606 endif(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 607
 608 # Process FFT library settings - if not OpenMM build
 609 string(TOUPPER ${GMX_FFT_LIBRARY} ${GMX_FFT_LIBRARY})
 610 set(PKG_FFT "")
 611 set(PKG_FFT_LIBS "")
 612 if(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 613 #    MESSAGE(STATUS "Using external FFT library - fftw3")
 614     if(GMX_DOUBLE)
 615         find_package(FFTW3 REQUIRED)
 616                 include_directories(${FFTW3_INCLUDE_DIR})
 617         set(FFT_LIBRARIES ${FFTW3_LIBRARIES})
 618         set(PKG_FFT "fftw3")
 619     else(GMX_DOUBLE)
 620         find_package(FFTW3F REQUIRED)
 621         include_directories(${FFTW3F_INCLUDE_DIR})
 622         set(FFT_LIBRARIES ${FFTW3F_LIBRARIES})
 623         set(PKG_FFT "fftw3f")
 624     endif(GMX_DOUBLE)
 625
 626     if(NOT FFTW3_FOUND AND NOT FFTW3F_FOUND)
 627         MESSAGE(FATAL_ERROR "Cannot find fftw3 (with correct precision). Fix it, choose another FFT library, or use the Gromacs built-in fftpack (slower)!")
 628     endif(NOT FFTW3_FOUND AND NOT FFTW3F_FOUND)
 629
 630     set(GMX_FFT_FFTW3 1)
 631
 632 elseif(${GMX_FFT_LIBRARY} STREQUAL "FFTW2")
 633 #    MESSAGE(STATUS "Using external FFT library - fftw2")
 634     if(GMX_DOUBLE)
 635         find_package(FFTW2 REQUIRED)
 636     else(GMX_DOUBLE)
 637         find_package(FFTW2F REQUIRED)
 638     endif(GMX_DOUBLE)
 639
 640     if(NOT FFTW2_FOUND)
 641            MESSAGE(FATAL_ERROR "Cannot find fftw2 (with correct precision). Fix it, choose another FFT library, or use the Gromacs built-in fftpack (slower)!")
 642     endif(NOT FFTW2_FOUND)
 643     include_directories(${FFTW2_INCLUDE_DIR})
 644     set(FFT_LIBRARIES ${FFTW2_LIBRARIES})
 645     set(PKG_FFT_LIBS ${FFTW2_LIBRARIES})
 646
 647     if("${FFTW2_LIBRARIES}" MATCHES "dfftw")
 648         set(FFTW2_NAME_DFFTW 1)
 649     elseif("${FFTW2_LIBRARIES}" MATCHES "sfftw")
 650         set(FFTW2_NAME_SFFTW 1)
 651     else("${FFTW2_LIBRARIES}" MATCHES "dfftw")
 652         set(FFTW2_NAME_FFTW 1)
 653     endif("${FFTW2_LIBRARIES}" MATCHES "dfftw")
 654
 655     set(GMX_FFT_FFTW2 1)
 656 elseif(${GMX_FFT_LIBRARY} STREQUAL "MKL")
 657 #    MESSAGE(STATUS "Using external FFT library - Intel MKL")
 658     find_package(MKL REQUIRED)
 659     include_directories(${MKL_INCLUDE_DIR})
 660     set(FFT_LIBRARIES ${MKL_LIBRARIES})
 661     set(PKG_FFT_LIBS ${MKL_LIBRARIES})
 662
 663     set(GMX_FFT_MKL 1)
 664     set(HAVE_MKL 1)
 665
 666 #elseif(${GMX_FFT_LIBRARY} STREQUAL "ACML")
 667 #    MESSAGE(STATUS "Using external FFT library - AMD core math library")
 668 #    set(GMX_FFT_ACML 1)
 669 elseif(${GMX_FFT_LIBRARY} STREQUAL "FFTPACK")
 670     MESSAGE(STATUS "Using internal FFT library - fftpack")
 671     set(GMX_FFT_FFTPACK 1)
 672 else(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 673     MESSAGE(FATAL_ERROR "Invalid FFT library setting: ${GMX_FFT_LIBRARY}. Choose one of: fftw3, fftw2, mkl, acml, fftpack")
 674 endif(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 675
 676 # MKL has BLAS/LAPACK routines
 677 if(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 678   set(GMX_EXTERNAL_BLAS TRUE CACHE BOOL "Use external BLAS instead of built-in")
 679   set(GMX_EXTERNAL_LAPACK TRUE CACHE BOOL "Use external LAPACK instead of built-in")
 680 else(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 681   set(GMX_EXTERNAL_BLAS FALSE CACHE BOOL "Use external LAPACK instead of built-in")
 682   set(GMX_EXTERNAL_LAPACK FALSE CACHE BOOL "Use external LAPACK instead of built-in")
 683 endif(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 684 mark_as_advanced(GMX_EXTERNAL_LAPACK)
 685 mark_as_advanced(GMX_EXTERNAL_BLAS)
 686
 687 # Math and thread libraries must often come after all others when linking...
 688 if(HAVE_LIBM)
 689     list(APPEND GMX_EXTRA_LIBRARIES m)
 690 endif(HAVE_LIBM)
 691
 692
 693
 694 if(GMX_FAHCORE)
 695   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 696       "Path to swindirect.h")
 697   include_directories(${COREWRAP_INCLUDE_DIR})
 698 endif(GMX_FAHCORE)
 699
 700 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 701 # these are set after everything else
 702 if (NOT DEFINED GROMACS_C_FLAGS_SET)
 703     set(GROMACS_C_FLAGS_SET true CACHE INTERNAL "Whether to reset the C flags"
 704         FORCE)
 705     set(CMAKE_C_FLAGS "${GROMACS_C_FLAGS} ${CMAKE_C_FLAGS}" CACHE STRING
 706         "Flags used by the compiler during all build types" FORCE)
 707     set(CMAKE_CXX_FLAGS "${GROMACS_CXX_FLAGS} ${CMAKE_CXX_FLAGS}" CACHE STRING
 708         "Flags used by the compiler during all build types" FORCE)
 709     set(CMAKE_EXE_LINKER_FLAGS
 710         "${GROMACS_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}"
 711         CACHE STRING "Linker flags" FORCE)
 712 endif (NOT DEFINED GROMACS_C_FLAGS_SET)
 713
 714 ########################################################################
 715 # Specify install locations and which subdirectories to process        #
 716 ########################################################################
 717 if ( DEFINED LIB )
 718     set(LIB_INSTALL_DIR "${CMAKE_INSTALL_PREFIX}/${LIB}")
 719 else()
 720     set(LIB_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/lib)
 721 endif()
 722 set(BIN_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/bin)
 723 set(DATA_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/gromacs)
 724 set(MAN_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/share/man)
 725 set(INCL_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/include)
 726
 727 set(GMXLIBDIR        ${DATA_INSTALL_DIR}/top)
 728
 729 ##################################################################
 730 # Shared library settings - Darwin uses INSTALL_NAME_DIR instead!
 731 ##################################################################
 732 if(NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin")
 733     set(CMAKE_SKIP_BUILD_RPATH  FALSE)
 734     set(CMAKE_BUILD_WITH_INSTALL_RPATH TRUE)
 735     set(CMAKE_INSTALL_RPATH "${LIB_INSTALL_DIR}")
 736     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 737 endif()
 738
 739 add_subdirectory(share)
 740 add_subdirectory(include)
 741 add_subdirectory(man)
 742 add_subdirectory(src)
 743 add_subdirectory(scripts)
 744
 745 #######################
 746 ## uninstall target
 747 #######################
 748     CONFIGURE_FILE(
 749                    "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 750                    "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
 751                    IMMEDIATE @ONLY)
 752 ###########################
 753 ADD_CUSTOM_TARGET(uninstall
 754                   "${CMAKE_COMMAND}" -P
 755                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
 756 ###########################
 757
 758
 759 ########################################################################
 760 # Tests                                                                #
 761 ########################################################################
 762
 763 include(CTest)
 764 mark_as_advanced(BUILD_TESTING)
 765 IF(BUILD_TESTING)
 766         enable_testing()
 767         add_test(TestBuildAll make)
 768         add_subdirectory(tests)
 769 ENDIF()
 770