CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.8)
   2 # Keep CMake suitably quiet on Cygwin
   3 set(CMAKE_LEGACY_CYGWIN_WIN32 0) # Remove when CMake >= 2.8.4 is required
   4
   5 # Allows CPack to act differently for normal tools and mdrun (e.g. because of MPI)
   6 set(CPACK_COMPONENT_GROUP_TOOLS_DESCRIPTION "All GROMACS executable tools")
   7 set(CPACK_COMPONENT_GROUP_MDRUN_DESCRIPTION "GROMACS executable for running simulations")
   8
   9 # override bugs on OS X where Cmake picks gcc (GNU) for C instead of system default cc (Clang).
  10 if(APPLE)
  11     set(CMAKE_C_COMPILER_INIT "cc")
  12 endif(APPLE)
  13
  14 project(Gromacs C)
  15 include(Dart)
  16 mark_as_advanced(DART_ROOT)
  17
  18 # PROJECT_VERSION should have the following structure:
  19 # VERSION-dev[-SUFFIX] where the VERSION should have the for: vMajor.vMinor.vPatch
  20 #
  21 # The "-dev" suffix is important to keep because it makes possible to distinguish
  22 # between a build from official release and a build from git release branch on a
  23 # machine with no git.
  24 #
  25 # NOTE: when releasing the "-dev" suffix needs to be stripped off!
  26 set(PROJECT_VERSION "4.6-dev")
  27 set(CUSTOM_VERSION_STRING ""
  28     CACHE STRING "Custom version string (if empty, use hard-coded default)")
  29 mark_as_advanced(CUSTOM_VERSION_STRING)
  30 if (CUSTOM_VERSION_STRING)
  31     set(PROJECT_VERSION ${CUSTOM_VERSION_STRING})
  32 endif (CUSTOM_VERSION_STRING)
  33 set(SOVERSION 6)
  34 # It is a bit irritating, but this has to be set separately for now!
  35 SET(CPACK_PACKAGE_VERSION_MAJOR "4")
  36 SET(CPACK_PACKAGE_VERSION_MINOR "6")
  37 #SET(CPACK_PACKAGE_VERSION_PATCH "0")
  38
  39 # The numerical gromacs version. It is 40600 for 4.6.0.
  40 # The #define GMX_VERSION in gmx_header_config_h is set to this value.
  41 math(EXPR NUM_VERSION
  42     "${CPACK_PACKAGE_VERSION_MAJOR}*10000 + ${CPACK_PACKAGE_VERSION_MINOR}*100")
  43 if(CPACK_PACKAGE_VERSION_PATCH)
  44     math(EXPR NUM_VERSION
  45          "${NUM_VERSION} + ${CPACK_PACKAGE_VERSION_PATCH}")
  46 endif()
  47
  48 # The API version tracks the numerical Gromacs version (for now).
  49 # It is potentially different from the Gromacs version in the future, if
  50 # the programs/libraries diverge from the presumably more stable API.
  51 # The #define GMX_API_VERSION in version.h is set to this value to
  52 # provide backward compatibility of software written against the Gromacs API.
  53 set(API_VERSION ${NUM_VERSION})
  54
  55 # Cmake modules/macros are in a subdirectory to keep this file cleaner
  56 set(CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake)
  57
  58 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT AND UNIX)
  59 set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
  60 endif()
  61
  62 if(NOT CMAKE_BUILD_TYPE)
  63     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel." FORCE)
  64 endif(NOT CMAKE_BUILD_TYPE)
  65
  66 enable_language(C)
  67
  68 set(GMX_USE_RELATIVE_INSTALL_PATH OFF CACHE STRING "Use relative paths not absolute paths for cmake install. Has only an effect on cpack.")
  69 mark_as_advanced(GMX_USE_RELATIVE_INSTALL_PATH)
  70
  71 set(CPACK_PACKAGE_VERSION ${PROJECT_VERSION})
  72 set(CPACK_PACKAGE_VENDOR "gromacs.org")
  73 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Gromacs - a toolkit for high-performance molecular simulation")
  74 if (NOT GMX_USE_RELATIVE_INSTALL_PATH)
  75     set(CPACK_SET_DESTDIR "ON")
  76 endif()
  77 set(CPACK_RESOURCE_FILE_WELCOME "${CMAKE_SOURCE_DIR}/admin/InstallWelcome.txt")
  78 # Its GPL/LGPL, so they do not have to agree to a license for mere usage, but some installers require this...
  79 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_SOURCE_DIR}/COPYING")
  80 set(CPACK_RESOURCE_FILE_README "${CMAKE_SOURCE_DIR}/admin/InstallInfo.txt")
  81 set(CPACK_SOURCE_IGNORE_FILES ".isreposource;.git;.gitignore")
  82 set(CPACK_PROJECT_CONFIG_FILE "${CMAKE_SOURCE_DIR}/CPackInit.cmake")
  83 SET(CPACK_SOURCE_INSTALLED_DIRECTORIES "${CMAKE_SOURCE_DIR};/;${CMAKE_BINARY_DIR}/man;man")
  84 set(CPACK_PACKAGE_CONTACT "gmx-users@gromacs.org")
  85
  86 #must come after all cpack settings!
  87 include(CPack)
  88
  89 ########################################################################
  90 # Check and warn if cache generated on a different host is being reused
  91 ########################################################################
  92 if(CMAKE_HOST_UNIX)
  93     execute_process(COMMAND hostname
  94                     OUTPUT_VARIABLE TMP_HOSTNAME
  95                     OUTPUT_STRIP_TRAILING_WHITESPACE)
  96     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}")
  97         message(WARNING "
  98             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
  99             is being reused! This could lead to inconsitencies; therefore, it is
 100             recommended to regenerate the cache!")
 101     endif()
 102     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
 103             "Hostname of the machine where the cache was generated.")
 104 endif()
 105
 106 ########################################################################
 107 # User input options - enable C++ - before any CXX flags are changed   #
 108 ########################################################################
 109 option(GMX_GPU  "Enable GPU acceleration" ON)
 110 option(GMX_OPENMM "Accelerated execution on GPUs through the OpenMM library (rerun cmake after changing to see relevant options)" OFF)
 111 option(GMX_FORCE_CXX "Enable C++ compilation even if not necessary" OFF)
 112 mark_as_advanced(GMX_FORCE_CXX)
 113 if(GMX_GPU OR GMX_OPENMM OR GMX_FORCE_CXX)
 114     enable_language(CXX)
 115 endif()
 116
 117 ########################################################################
 118 # Fix stupid flags on Windows
 119 ########################################################################
 120 SET(SHARED_LIBS_DEFAULT ON)
 121 IF( WIN32 AND NOT CYGWIN)
 122   option(GMX_PREFER_STATIC_LIBS "When finding libraries prefer static system libraries (MT instead of MD)!" ON)
 123   mark_as_advanced(GMX_PREFER_STATIC_LIBS)
 124   SET(SHARED_LIBS_DEFAULT OFF)  #is currently not working on Windows
 125
 126   IF (GMX_PREFER_STATIC_LIBS)
 127     #Only setting Debug and Release flags. Others configurations current not used.
 128     STRING(REPLACE /MD /MT CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE})
 129     SET(CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE} CACHE STRING "" FORCE)
 130     STRING(REPLACE /MD /MT CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG})
 131     SET(CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG} CACHE STRING "" FORCE)
 132     if(CMAKE_CXX_COMPILER_LOADED)
 133         STRING(REPLACE /MD /MT CMAKE_CXX_FLAGS_RELEASE ${CMAKE_CXX_FLAGS_RELEASE})
 134         SET(CMAKE_CXX_FLAGS_RELEASE ${CMAKE_CXX_FLAGS_RELEASE} CACHE STRING "" FORCE)
 135         STRING(REPLACE /MD /MT CMAKE_CXX_FLAGS_DEBUG ${CMAKE_CXX_FLAGS_DEBUG})
 136         SET(CMAKE_CXX_FLAGS_DEBUG ${CMAKE_CXX_FLAGS_DEBUG} CACHE STRING "" FORCE)
 137     endif()
 138   ENDIF()
 139
 140   #Workaround for cmake bug 13174. Replace deprecated options.
 141   IF( CMAKE_C_COMPILER_ID MATCHES "Intel" )
 142     STRING(REPLACE /GZ /RTC1 CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG})
 143     SET(CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG} CACHE STRING "" FORCE)
 144   ENDIF()
 145   IF( CMAKE_CXX_COMPILER_ID MATCHES "Intel" AND CMAKE_CXX_COMPILER_LOADED)
 146     STRING(REPLACE /GZ /RTC1 CMAKE_CXX_FLAGS_DEBUG ${CMAKE_CXX_FLAGS_DEBUG})
 147     STRING(REPLACE /GX /EHsc CMAKE_CXX_FLAGS_DEBUG ${CMAKE_CXX_FLAGS_DEBUG})
 148     SET(CMAKE_CXX_FLAGS_DEBUG ${CMAKE_CXX_FLAGS_DEBUG} CACHE STRING "" FORCE)
 149
 150     STRING(REPLACE /GX /EHsc CMAKE_CXX_FLAGS_RELEASE ${CMAKE_CXX_FLAGS_RELEASE})
 151     SET(CMAKE_CXX_FLAGS_RELEASE ${CMAKE_CXX_FLAGS_RELEASE} CACHE STRING "" FORCE)
 152   ENDIF()
 153 ENDIF()
 154
 155
 156 ########################################################################
 157 # User input options                                                   #
 158 ########################################################################
 159 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" OFF)
 160 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 161 option(GMX_THREAD_MPI  "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" ON)
 162 option(GMX_SOFTWARE_INVSQRT "Use GROMACS software 1/sqrt" ON)
 163 mark_as_advanced(GMX_SOFTWARE_INVSQRT)
 164 option(GMX_POWERPC_INVSQRT "Use PowerPC hardware 1/sqrt" OFF)
 165 mark_as_advanced(GMX_POWERPC_INVSQRT)
 166 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 167 mark_as_advanced(GMX_FAHCORE)
 168
 169 include(gmxDetectAcceleration)
 170 if(NOT DEFINED GMX_ACCELERATION)
 171     if(CMAKE_CROSSCOMPILING)
 172         set(GMX_SUGGESTED_ACCELERATION "None")
 173     else(CMAKE_CROSSCOMPILING)
 174         gmx_detect_acceleration(GMX_SUGGESTED_ACCELERATION)
 175     endif(CMAKE_CROSSCOMPILING)
 176 endif(NOT DEFINED GMX_ACCELERATION)
 177
 178 set(GMX_ACCELERATION "@GMX_SUGGESTED_ACCELERATION@"
 179     CACHE STRING "Accelerated kernels. Pick one of: None, SSE2, SSE4.1, AVX_128_FMA, AVX_256, BlueGene, Power6, Fortran")
 180
 181 set(GMX_FFT_LIBRARY "fftw3"
 182     CACHE STRING "FFT library choices: fftw3,mkl,fftpack[built-in]")
 183 option(GMX_DISABLE_FFTW_MEASURE
 184        "Do not optimize FFTW setups (not needed with SSE)" OFF)
 185 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 186 set(GMX_QMMM_PROGRAM "none"
 187     CACHE STRING "QM package choices: none,gaussian,mopac,gamess,orca")
 188 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 189 mark_as_advanced(GMX_BROKEN_CALLOC)
 190 option(GMX_MPI_IN_PLACE "Enable MPI_IN_PLACE for MPIs that have it defined" ON)
 191 mark_as_advanced(GMX_MPI_IN_PLACE)
 192 option(GMX_LOAD_PLUGINS "Compile with plugin support, needed to read VMD supported file formats" ON)
 193 mark_as_advanced(GMX_LOAD_PLUGINS)
 194
 195 option(GMX_OPENMP "Enable OpenMP-based multithreading" ON)
 196
 197 option(USE_VERSION_H "Generate development version string/information" ON)
 198 mark_as_advanced(USE_VERSION_H)
 199
 200 option(GMX_DEFAULT_SUFFIX "Use default suffixes for GROMACS binaries and libs (_d for double, _mpi for MPI; rerun cmake after changing to see relevant options)" ON)
 201
 202 if(UNIX)
 203     option(GMX_PREFER_STATIC_LIBS "When finding libraries prefer \".a\" static archives (NOTE: this is enabled only for UNIX platforms but it might not always work!" OFF)
 204     mark_as_advanced(GMX_PREFER_STATIC_LIBS)
 205 endif()
 206
 207 option(GMX_CYCLE_SUBCOUNTERS "Enable cycle subcounters to get a more detailed cycle timings" OFF)
 208 mark_as_advanced(GMX_CYCLE_SUBCOUNTERS)
 209
 210 ######################################################################
 211 # compiler tests
 212 # these need ot be done early (before further tests).
 213 #####################################################################
 214
 215 # cmake/Check{C,CXX}CompilerFlag.cmake are lifted from CMake git next
 216 # branch (proposed for v2.8.9) to be able to detect invalid options
 217 # with the Intel Compilers.
 218 # Remove these files from the source tree when a CMake version that
 219 # includes the features in question becomes required.
 220 include(CheckCCompilerFlag)
 221 if(CMAKE_CXX_COMPILER_LOADED)
 222     include(CheckCXXCompilerFlag)
 223 endif()
 224
 225 # OpenMP check must come before other CFLAGS!
 226 if(GMX_OPENMP)
 227     find_package(OpenMP)
 228     if(OPENMP_FOUND)
 229         #- only set linker flag, if user didn't set them manual
 230         #- cmake on windows doesn't support linker flags passed to target_link_libraries
 231         #  (cmake treats /openmp as \openmp library file) and no openmp linker flags are needed
 232         if(NOT (WIN32 AND NOT CYGWIN))
 233             if(CMAKE_COMPILER_IS_GNUCC AND GMX_PREFER_STATIC_OPENMP)
 234                 set(OpenMP_LINKER_FLAGS "-Wl,-static -lgomp -lrt -Wl,-Bdynamic -lpthread")
 235                 set(OpenMP_SHARED_LINKER_FLAGS "")
 236             else()
 237                 if(NOT DEFINED OpenMP_LINKER_FLAGS)
 238                     set(OpenMP_LINKER_FLAGS "${OpenMP_C_FLAGS}")
 239                 endif()
 240                 if(NOT DEFINED OpenMP_SHARED_LINKER_FLAGS)
 241                     set(OpenMP_SHARED_LINKER_FLAGS "${OpenMP_C_FLAGS}")
 242                 endif()
 243             endif()
 244         endif()
 245     else(OPENMP_FOUND)
 246         message(WARNING
 247                 "Compiler not supporting OpenMP. This might hurt your performance a lot, "
 248                 "in particular with GPUs. Try using a different compiler (Intel is good on x86) "
 249                 "if you can - for now we are proceeding by turning off OpenMP.")
 250         set(GMX_OPENMP OFF CACHE STRING "Compiler does not support OpenMP." FORCE)
 251     endif(OPENMP_FOUND)
 252 endif()
 253
 254
 255 include(gmxCFlags)
 256 gmx_c_flags()
 257
 258 include(gmxGetCompilerVersion)
 259 get_compiler_version()
 260
 261 # gcc 4.4.x is buggy and crashes when compiling some files with O3 and OpenMP on.
 262 # Detect here whether applying a workaround is needed and will apply it later
 263 # on the affected files.
 264 include(gmxGCC44O3BugWorkaround)
 265 gmx_check_gcc44_bug_workaround_needed(GMX_USE_GCC44_BUG_WORKAROUND)
 266
 267 ########################################################################
 268 # Set up binary and library suffixing
 269 ########################################################################
 270 set(GMX_BINARY_SUFFIX "" CACHE STRING "Suffix for GROMACS binaries (default: _d for double, _mpi for MPI, _mpi_d for MPI and double).")
 271 set(GMX_LIBS_SUFFIX ""
 272   CACHE STRING "Suffix for GROMACS libs (default: _d for double, _mpi for MPI, _mpi_d for MPI and double).")
 273 if (GMX_DEFAULT_SUFFIX)
 274   set(GMX_BINARY_SUFFIX "")
 275   set(GMX_LIBS_SUFFIX "")
 276   if (GMX_MPI)
 277     set(GMX_BINARY_SUFFIX "_mpi")
 278     set(GMX_LIBS_SUFFIX "_mpi")
 279   endif(GMX_MPI)
 280   if (GMX_DOUBLE)
 281     set (GMX_BINARY_SUFFIX "${GMX_BINARY_SUFFIX}_d")
 282     set (GMX_LIBS_SUFFIX "${GMX_LIBS_SUFFIX}_d")
 283   endif(GMX_DOUBLE)
 284   if (GMX_OPENMM)
 285     set (GMX_BINARY_SUFFIX "-openmm")
 286     set (GMX_LIBS_SUFFIX "_openmm")
 287   endif(GMX_OPENMM)
 288   mark_as_advanced(FORCE GMX_BINARY_SUFFIX GMX_LIBS_SUFFIX)
 289   if (NOT SUFFIX_QUIETLY)
 290     message(STATUS "Using default binary suffix: \"${GMX_BINARY_SUFFIX}\"")
 291     message(STATUS "Using default library suffix: \"${GMX_LIBS_SUFFIX}\"")
 292   endif (NOT SUFFIX_QUIETLY)
 293 else(GMX_DEFAULT_SUFFIX)
 294   mark_as_advanced(CLEAR GMX_BINARY_SUFFIX GMX_LIBS_SUFFIX)
 295   if (NOT SUFFIX_QUIETLY)
 296     message(STATUS "Using manually set binary suffix: \"${GMX_BINARY_SUFFIX}\"")
 297     message(STATUS "Using manually set library suffix: \"${GMX_LIBS_SUFFIX}\"")
 298   endif (NOT SUFFIX_QUIETLY)
 299 endif(GMX_DEFAULT_SUFFIX)
 300 set(SUFFIX_QUIETLY TRUE CACHE INTERNAL "")
 301
 302 set(PKG_CFLAGS "")
 303 if(GMX_DOUBLE)
 304     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_DOUBLE")
 305 endif(GMX_DOUBLE)
 306 if(GMX_SOFTWARE_INVSQRT)
 307   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_SOFTWARE_INVSQRT")
 308 endif(GMX_SOFTWARE_INVSQRT)
 309 if(GMX_POWERPC_INVSQRT)
 310   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_POWERPC_INVSQRT")
 311 endif(GMX_POWERPC_INVSQRT)
 312
 313 ########################################################################
 314 #Process MPI settings
 315 ########################################################################
 316 include(gmxManageMPI)
 317
 318 #######################################################################
 319 # Check for options incompatible with OpenMM build                    #
 320 #######################################################################
 321 if(GMX_OPENMM)
 322     # we'll use the built-in fft to avoid unnecessary dependencies
 323     string(TOUPPER ${GMX_FFT_LIBRARY} GMX_FFT_LIBRARY)
 324     if(NOT ${GMX_FFT_LIBRARY} STREQUAL "FFTPACK")
 325         message(STATUS "No external FFT libraries needed for the OpenMM build, switching to fftpack!")
 326         set(GMX_FFT_LIBRARY "fftpack" CACHE STRING
 327                 "No external FFT libraries needed for the OpenMM build, switching to  fftpack!" FORCE)
 328     endif()
 329     if(GMX_MPI)
 330         message(FATAL_ERROR "The OpenMM build is not compatible with MPI!")
 331     endif(GMX_MPI)
 332     if(GMX_THREAD_MPI)
 333         message(STATUS "Thread-MPI not compatible with OpenMM, disabled!")
 334         set(GMX_THREAD_MPI OFF CACHE BOOL
 335                 "Thread-MPI not compatible with OpenMM build, disabled!" FORCE)
 336     endif(GMX_THREAD_MPI)
 337     if(GMX_OPENMP)
 338         message(STATUS "OpenMP multithreading not compatible with OpenMM, disabled")
 339         set(GMX_OPENMP OFF CACHE BOOL
 340             "OpenMP multithreading not compatible with OpenMM, disabled!" FORCE)
 341     endif()
 342     if(GMX_SOFTWARE_INVSQRT)
 343         set(GMX_SOFTWARE_INVSQRT OFF CACHE STRING
 344                 "The OpenMM build does not need GROMACS software 1/sqrt!" FORCE)
 345     endif(GMX_SOFTWARE_INVSQRT)
 346     string(TOUPPER ${GMX_ACCELERATION} GMX_ACCELERATION)
 347     if(NOT GMX_ACCELERATION STREQUAL "NONE")
 348         message(STATUS "Switching off CPU-based acceleration, the OpenMM build does not support/need any!")
 349         set(GMX_ACCELERATION "none" CACHE STRING
 350                 "Switching off CPU-based acceleration, the OpenMM build does not support/need any!" FORCE)
 351     endif()
 352     if(GMX_FAHCORE)
 353         message(FATAL_ERROR "The OpenMM build does not support FAH build!")
 354     endif(GMX_FAHCORE)
 355     if(GMX_DOUBLE)
 356         message(FATAL_ERROR  "The OpenMM-build does not support double precision calculations!")
 357     endif()
 358     # mark as advanced the unused variables
 359     mark_as_advanced(FORCE GMX_ACCELERATION GMX_MPI GMX_FFT_LIBRARY
 360         GMX_QMMM_PROGRAM GMX_THREAD_MPI GMX_DOUBLE)
 361 else(GMX_OPENMM)
 362      mark_as_advanced(CLEAR GMX_ACCELERATION GMX_MPI GMX_FFT_LIBRARY
 363         GMX_QMMM_PROGRAM GMX_THREAD_MPI GMX_DOUBLE)
 364 endif(GMX_OPENMM)
 365
 366
 367 ########################################################################
 368 # Basic system tests (standard libraries, headers, functions, types)   #
 369 ########################################################################
 370 include(CheckIncludeFiles)
 371 check_include_files(string.h     HAVE_STRING_H)
 372 check_include_files(math.h       HAVE_MATH_H)
 373 check_include_files(limits.h     HAVE_LIMITS_H)
 374 check_include_files(memory.h     HAVE_MEMORY_H)
 375 check_include_files(unistd.h     HAVE_UNISTD_H)
 376 check_include_files(direct.h     HAVE_DIRECT_H)
 377 check_include_files(pwd.h        HAVE_PWD_H)
 378 check_include_files(stdint.h     HAVE_STDINT_H)
 379 check_include_files(stdlib.h     HAVE_STDLIB_H)
 380 check_include_files(pthread.h    HAVE_PTHREAD_H)
 381 check_include_files(dirent.h     HAVE_DIRENT_H)
 382 check_include_files(inttypes.h   HAVE_INTTYPES_H)
 383 check_include_files(regex.h      HAVE_REGEX_H)
 384 check_include_files(sys/types.h  HAVE_SYS_TYPES_H)
 385 check_include_files(sys/stat.h   HAVE_SYS_STAT_H)
 386 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 387 check_include_files(rpc/rpc.h    HAVE_RPC_RPC_H)
 388 check_include_files("rpc/rpc.h;rpc/xdr.h"    HAVE_RPC_XDR_H)
 389 check_include_files(io.h                 HAVE_IO_H)
 390 check_include_files(sched.h      HAVE_SCHED_H)
 391
 392 include(CheckFunctionExists)
 393 check_function_exists(strcasecmp        HAVE_STRCASECMP)
 394 check_function_exists(strdup            HAVE_STRDUP)
 395 check_function_exists(vprintf           HAVE_VPRINTF)
 396 check_function_exists(memcmp            HAVE_MEMCMP)
 397 check_function_exists(posix_memalign    HAVE_POSIX_MEMALIGN)
 398 check_function_exists(memalign          HAVE_MEMALIGN)
 399 check_function_exists(_aligned_malloc   HAVE__ALIGNED_MALLOC)
 400 check_function_exists(gettimeofday      HAVE_GETTIMEOFDAY)
 401 check_function_exists(isnan             HAVE_ISNAN)
 402 check_function_exists(_isnan            HAVE__ISNAN)
 403 check_function_exists(fsync             HAVE_FSYNC)
 404 check_function_exists(_fileno           HAVE__FILENO)
 405 check_function_exists(fileno            HAVE_FILENO)
 406 check_function_exists(_commit           HAVE__COMMIT)
 407 check_function_exists(lstat             HAVE_LSTAT)
 408 check_function_exists(sigaction         HAVE_SIGACTION)
 409 check_function_exists(sysconf           HAVE_SYSCONF)
 410 check_function_exists(sched_setaffinity HAVE_SCHED_SETAFFINITY)
 411 check_function_exists(sched_getaffinity HAVE_SCHED_GETAFFINITY)
 412 check_function_exists(rsqrt             HAVE_RSQRT)
 413 check_function_exists(rsqrtf            HAVE_RSQRTF)
 414 check_function_exists(sqrtf             HAVE_SQRTF)
 415
 416 include(CheckLibraryExists)
 417 check_library_exists(m sqrt "" HAVE_LIBM)
 418 check_library_exists(m cbrt "" HAVE_CBRT)
 419
 420
 421 include(CheckTypeSize)
 422
 423 check_type_size("bool"          SIZEOF_BOOL) # will also set HAVE_BOOL
 424 check_type_size("int"           SIZEOF_INT)
 425 check_type_size("long int"      SIZEOF_LONG_INT)
 426 check_type_size("long long int" SIZEOF_LONG_LONG_INT)
 427 check_type_size("off_t"         SIZEOF_OFF_T)
 428 check_type_size("void *"        SIZEOF_VOIDP)
 429
 430 if (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 431     set(GMX_64_BIT TRUE)
 432 else (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 433     set(GMX_64_BIT FALSE)
 434 endif (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 435
 436 # Check for some basic types that we *need*, so set these to int if they are not present
 437 check_type_size(uid_t uid_t)
 438 if(NOT uid_t)
 439   set(uid_t int)
 440 else(NOT uid_t)
 441   set(uid_t 0)
 442 endif(NOT uid_t)
 443
 444 check_type_size(gid_t gid_t)
 445 if(NOT gid_t)
 446   set(gid_t 1)
 447 else(NOT gid_t)
 448   set(gid_t 0)
 449 endif(NOT gid_t)
 450
 451 check_type_size(size_t size_t)
 452 if(NOT size_t)
 453   set(size_t int)
 454 else(NOT size_t)
 455   set(size_t 0)
 456 endif(NOT size_t)
 457
 458 check_type_size(off_t off_t)
 459 if(NOT off_t)
 460   set(off_t int)
 461 else(NOT off_t)
 462   set(off_t 0)
 463 endif(NOT off_t)
 464
 465 include(TestBigEndian)
 466 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 467
 468
 469
 470
 471 ########################################################################
 472 # Find external packages                                               #
 473 ########################################################################
 474 if(UNIX)
 475     if(GMX_PREFER_STATIC_LIBS)
 476         SET(CMAKE_FIND_LIBRARY_SUFFIXES .a ${CMAKE_FIND_LIBRARY_SUFFIXES})
 477         if(SHARED_LIBS_DEFAULT)
 478             if(BUILD_SHARED_LIBS) #Warn the user about the combination. But don't overwrite the request.
 479                 message(WARNING "Static libraries requested, and shared Gromacs libraries requested.")
 480             elseif(NOT DEFINED BUILD_SHARED_LIBS) #Change default to OFF. Don't warn if it's already off.
 481                 message(WARNING "Static libraries requested, the GROMACS libraries will also be build static (BUILD_SHARED_LIBS=OFF)")
 482                 set(SHARED_LIBS_DEFAULT OFF)
 483             endif()
 484         endif()
 485     endif()
 486 endif()
 487 option(BUILD_SHARED_LIBS "Enable shared libraries (can be problematic with MPI, Windows)" ${SHARED_LIBS_DEFAULT})
 488
 489 option(GMX_XML "Use libxml2 to parse xml files" ON)
 490 if (GMX_XML)
 491   find_package(LibXml2)
 492   set(PKG_XML "")
 493   if(LIBXML2_FOUND)
 494     include_directories(${LIBXML2_INCLUDE_DIR})
 495     set(PKG_XML libxml-2.0)
 496     set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 497     set(HAVE_LIBXML2 1)
 498   endif(LIBXML2_FOUND)
 499 endif(GMX_XML)
 500
 501 option(GMX_GSL "Add support for gsl" OFF)
 502 if (GMX_GSL)
 503   find_package(gsl)
 504   set(PKG_GSL "")
 505   if(GSL_FOUND)
 506     include_directories(${GSL_INCLUDE_DIR})
 507     set(PKG_GSL gsl)
 508     set(HAVE_LIBGSL 1)
 509   endif(GSL_FOUND)
 510 endif (GMX_GSL)
 511
 512 option(GMX_X11 "Use X window system" OFF)
 513 if (GMX_X11)
 514         find_package(X11)
 515         # X11 includes/libraries are only set in the ngmx subdirectory!
 516         if(X11_FOUND)
 517         set(HAVE_X11 1)
 518         endif(X11_FOUND)
 519 endif(GMX_X11)
 520
 521 if(GMX_THREAD_MPI)
 522     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_THREAD_MPI")
 523     include(ThreadMPI)
 524     set(THREAD_MPI_LIB thread_mpi)
 525     set(GMX_MPI 1)
 526     string(TOUPPER ${GMX_FFT_LIBRARY} ${GMX_FFT_LIBRARY})
 527 endif(GMX_THREAD_MPI)
 528
 529 if(GMX_OPENMM)
 530     set(CUDA_BUILD_EMULATION OFF)
 531     find_package(CUDA 3.1 REQUIRED)
 532     add_definitions(-DGMX_OPENMM)
 533     if(CMAKE_BUILD_TYPE STREQUAL "DEBUG")
 534         set(CUDA_VERBOSE_BUILD ON)
 535     endif()
 536     find_package(OpenMM)
 537 endif(GMX_OPENMM)
 538
 539
 540 if(GMX_GPU)
 541     if(GMX_DOUBLE)
 542         message(WARNING "GPU acceleration is not available in double precision, disabled!")
 543         set(GMX_GPU OFF CACHE BOOL "Enable GPU acceleration" FORCE)
 544     endif()
 545 endif(GMX_GPU)
 546
 547 if(GMX_GPU)
 548
 549     # We support CUDA >=v3.2 on *nix, but <= v4.1 doesn't work with MSVC
 550     if(MSVC)
 551         find_package(CUDA 4.1)
 552     else()
 553         find_package(CUDA 3.2)
 554     endif()
 555
 556     if (NOT EXISTS ${CUDA_TOOLKIT_ROOT_DIR})
 557         message(FATAL_ERROR "
 558     mdrun supports native GPU acceleration on NVIDIA hardware with compute
 559     capability >=2.0. This requires the NVIDIA CUDA library, which was not
 560     found; the location can be hinted by setting CUDA_TOOLKIT_ROOT_DIR.
 561
 562     CPU or GPU acceleration can be selected at runtime, but if you are
 563     sure you can not make use of GPU acceleration, disable it by setting
 564     the CMake variable GMX_GPU=OFF.")
 565     endif()
 566
 567     if(NOT GMX_OPENMP)
 568         message(WARNING "
 569     In order to use GPU acceleration efficiently, mdrun requires OpenMP multithreding.
 570     Without OpenMP only a single CPU core per GPU can be used which is suboptimal.
 571     Note that with MPI multiple processes can be forced to use a single GPU, but this
 572     typically inefficient.")
 573     endif()
 574
 575     include(gmxManageNvccConfig)
 576
 577     # Check whether we can use atomic operations needed for polling wait for GPU
 578     # (to avoid the cudaStreamSynchronize + ECC bug).
 579     # With thread-MPI testing atomics has already been carried out, but without
 580     # thread-MPI we need to invoke the atomics test independently.
 581     if (NOT GMX_THREAD_MPI)
 582         set(TEST_TMPI_ATOMICS_ONLY ON CACHE INTERNAL
 583             "Test only the atomic operations of thread-MPI.")
 584         include(ThreadMPI)
 585     endif()
 586
 587     # we need this linker flag in case if we have ld >= 2.22 (typically with gcc 4.5+),
 588     # but it's too cumbersome to check the ld version and the flag should not hurt
 589     if(CMAKE_COMPILER_IS_GNUCC)
 590         set(GROMACS_LINKER_FLAGS "-Wl,--add-needed ${GROMACS_LINKER_FLAGS}")
 591     endif()
 592
 593     # annoyingly enough, FindCUDA leaves a few variables behind as non-advanced
 594     mark_as_advanced(CUDA_BUILD_CUBIN CUDA_BUILD_EMULATION CUDA_SDK_ROOT_DIR CUDA_VERBOSE_BUILD)
 595 endif()
 596
 597 if(APPLE)
 598    find_library(ACCELERATE_FRAMEWORK Accelerate)
 599    list(APPEND GMX_EXTRA_LIBRARIES ${ACCELERATE_FRAMEWORK})
 600 endif(APPLE)
 601
 602 if(CYGWIN)
 603     set(GMX_CYGWIN 1)
 604 endif(CYGWIN)
 605
 606 if(WIN32 AND NOT CYGWIN)
 607     set(GMX_NATIVE_WINDOWS 1)
 608 endif()
 609
 610 # only bother with finding git and using version.h if the source is a git repo
 611 if(EXISTS "${CMAKE_SOURCE_DIR}/.git")
 612     if(USE_VERSION_H)
 613         # We need at least git v1.5.3 be able to parse git's date output. If not
 614         # found or the version is too small, we can't generate version information.
 615         find_package(Git)
 616
 617         # Find out the git version
 618         if(GIT_FOUND AND NOT GIT_VERSION)
 619           execute_process(COMMAND ${GIT_EXECUTABLE} "--version"
 620             OUTPUT_VARIABLE _exec_out
 621             OUTPUT_STRIP_TRAILING_WHITESPACE)
 622           string(REGEX REPLACE "git version (.*)" "\\1" GIT_VERSION ${_exec_out})
 623           set(GIT_VERSION ${GIT_VERSION} CACHE STRING "Git version")
 624           mark_as_advanced(GIT_VERSION)
 625         endif()
 626
 627         if(NOT GIT_FOUND OR GIT_VERSION VERSION_LESS "1.5.3")
 628           message("No compatible git version found, won't be able to generate proper development version information.")
 629           set(USE_VERSION_H OFF)
 630         endif()
 631     endif()
 632 else()
 633     set(USE_VERSION_H OFF)
 634 endif()
 635
 636 ########################################################################
 637 # Generate development version info for cache
 638 ########################################################################
 639 # set(GEN_VERSION_INFO_INTERNAL "ON")
 640 # include(gmxGenerateVersionString)
 641
 642 ########################################################################
 643 # Our own GROMACS tests
 644 ########################################################################
 645
 646 add_definitions( -DHAVE_CONFIG_H )
 647 include_directories(${CMAKE_BINARY_DIR}/src)
 648 include_directories(${CMAKE_BINARY_DIR}/include)
 649 include_directories(${CMAKE_SOURCE_DIR}/include)
 650
 651 include(gmxTestInlineASM)
 652 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 653
 654 include(gmxSetBuildInformation)
 655 gmx_set_build_information()
 656 if(BUILD_CPU_FEATURES MATCHES "rdtscp")
 657     # The timestep counter headers do not include config.h
 658     add_definitions(-DHAVE_RDTSCP)
 659 endif(BUILD_CPU_FEATURES MATCHES "rdtscp")
 660
 661 include(gmxTestFloatFormat)
 662 gmx_test_float_format(GMX_FLOAT_FORMAT_IEEE754
 663                       GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER
 664                       GMX_IEEE754_BIG_ENDIAN_WORD_ORDER)
 665
 666 include(gmxTestLargeFiles)
 667 gmx_test_large_files(GMX_LARGEFILES)
 668
 669 include(gmxTestSignal)
 670 gmx_test_sigusr1(HAVE_SIGUSR1)
 671
 672 include(gmxTestInline)
 673 gmx_test_inline(INLINE_KEYWORD)
 674
 675 include(gmxTestRestrict)
 676 gmx_test_restrict(RESTRICT_KEYWORD)
 677
 678 include(gmxTestPipes)
 679 gmx_test_pipes(HAVE_PIPES)
 680
 681 include(gmxTestIsfinite)
 682 gmx_test_isfinite(HAVE_ISFINITE)
 683 gmx_test__isfinite(HAVE__ISFINITE)
 684 gmx_test__finite(HAVE__FINITE)
 685
 686 include(gmxTestXDR)
 687 gmx_test_xdr(GMX_SYSTEM_XDR)
 688 if(NOT GMX_SYSTEM_XDR)
 689     set(GMX_INTERNAL_XDR 1)
 690     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_INTERNAL_XDR")
 691 endif(NOT GMX_SYSTEM_XDR)
 692
 693 # Process nonbonded accelerated kernels settings
 694 string(TOUPPER ${GMX_ACCELERATION} ${GMX_ACCELERATION})
 695 if(${GMX_ACCELERATION} STREQUAL "NONE")
 696     # nothing to do
 697 elseif(${GMX_ACCELERATION} STREQUAL "SSE2")
 698
 699     GMX_TEST_CFLAG(GNU_SSE2_CFLAG "-msse2" GROMACS_C_FLAGS)
 700     if(NOT GNU_SSE2_CFLAG)
 701         GMX_TEST_CFLAG(MSVC_SSE2_CFLAG "/arch:SSE2" GROMACS_C_FLAGS)
 702     endif(NOT GNU_SSE2_CFLAG)
 703
 704     if (CMAKE_CXX_COMPILER_LOADED)
 705         GMX_TEST_CXXFLAG(GNU_SSE2_CXXFLAG "-msse2" GROMACS_CXX_FLAGS)
 706         if(NOT GNU_SSE2_CXXFLAG)
 707             GMX_TEST_CXXFLAG(MSVC_SSE2_CXXFLAG "/arch:SSE2" GROMACS_CXX_FLAGS)
 708         endif(NOT GNU_SSE2_CXXFLAG)
 709     endif()
 710
 711     # We dont warn for lacking SSE2 flag support, since that is probably standard today.
 712
 713     # Only test the include after we have tried to add the correct flag for SSE2 support
 714     check_include_file(emmintrin.h  HAVE_EMMINTRIN_H ${GROMACS_C_FLAGS})
 715
 716     if(NOT HAVE_EMMINTRIN_H)
 717         message(FATAL_ERROR "Cannot find emmintrin.h, which is required for SSE2 intrinsics support.")
 718     endif(NOT HAVE_EMMINTRIN_H)
 719
 720     # The user should not be able to set this orthogonally to the acceleration
 721     set(GMX_X86_SSE2 1)
 722     if (NOT ACCELERATION_QUIETLY)
 723       message(STATUS "Enabling SSE2 Gromacs acceleration, and it will help compiler optimization.")
 724     endif()
 725
 726 elseif(${GMX_ACCELERATION} STREQUAL "SSE4.1")
 727
 728     GMX_TEST_CFLAG(GNU_SSE4_CFLAG "-msse4.1" GROMACS_C_FLAGS)
 729     if (NOT GNU_SSE4_CFLAG)
 730         GMX_TEST_CFLAG(MSVC_SSE4_CFLAG "/arch:SSE4.1" GROMACS_C_FLAGS)
 731     endif(NOT GNU_SSE4_CFLAG)
 732     if (NOT GNU_SSE4_CFLAG AND NOT MSVC_SSE4_CFLAG)
 733         message(WARNING "No C SSE4.1 flag found. Consider a newer compiler, or disable SSE4.1 for slightly lower performance.")
 734         # Not surprising if we end up here! MSVC current does not support the SSE4.1 flag. However, it appears to accept SSE4.1
 735         # intrinsics when SSE2 support is enabled, so we try that instead.
 736         GMX_TEST_CFLAG(MSVC_SSE2_CFLAG "/arch:SSE2" GROMACS_C_FLAGS)
 737     endif(NOT GNU_SSE4_CFLAG AND NOT MSVC_SSE4_CFLAG)
 738
 739     if (CMAKE_CXX_COMPILER_LOADED)
 740         GMX_TEST_CXXFLAG(GNU_SSE4_CXXFLAG "-msse4.1" GROMACS_CXX_FLAG)
 741         if (NOT GNU_SSE4_CXXFLAG)
 742             GMX_TEST_CXXFLAG(MSVC_SSE4_CXXFLAG "/arch:SSE4.1" GROMACS_CXX_FLAGS)
 743         endif(NOT GNU_SSE4_CXXFLAG)
 744         if (NOT GNU_SSE4_CXXFLAG AND NOT MSVC_SSE4_CXXFLAG)
 745             message(WARNING "No C++ SSE4.1 flag found. Consider a newer compiler, or disable SSE4.1 for slightly lower performance.")
 746             # Not surprising if we end up here! MSVC current does not support the SSE4.1 flag. However, it appears to accept SSE4.1
 747             # intrinsics when SSE2 support is enabled, so we try that instead.
 748             GMX_TEST_CXXFLAG(MSVC_SSE2_CXXFLAG "/arch:SSE2" GROMACS_CXX_FLAGS)
 749         endif(NOT GNU_SSE4_CXXFLAG AND NOT MSVC_SSE4_CXXFLAG)
 750     endif()
 751
 752     # This must come after we have added the -msse4.1 flag on some platforms.
 753     check_include_file(smmintrin.h  HAVE_SMMINTRIN_H ${GROMACS_C_FLAGS})
 754
 755     if(NOT HAVE_SMMINTRIN_H)
 756         message(FATAL_ERROR "Cannot find smmintrin.h, which is required for SSE4.1 intrinsics support.")
 757     endif(NOT HAVE_SMMINTRIN_H)
 758
 759     # The user should not be able to set this orthogonally to the acceleration
 760     set(GMX_X86_SSE4_1 1)
 761     set(GMX_X86_SSE2   1)
 762     if (NOT ACCELERATION_QUIETLY)
 763       message(STATUS "Enabling SSE4.1 Gromacs acceleration, and it will help compiler optimization.")
 764     endif()
 765
 766 elseif(${GMX_ACCELERATION} STREQUAL "AVX_128_FMA" OR ${GMX_ACCELERATION} STREQUAL "AVX_256")
 767
 768     # Set the AVX compiler flag for both these choices!
 769
 770     GMX_TEST_CFLAG(GNU_AVX_CFLAG "-mavx" GROMACS_C_FLAGS)
 771     if (NOT GNU_AVX_CFLAG)
 772         GMX_TEST_CFLAG(MSVC_AVX_CFLAG "/arch:AVX" GROMACS_C_FLAGS)
 773     endif (NOT GNU_AVX_CFLAG)
 774     if (NOT GNU_AVX_CFLAG AND NOT MSVC_AVX_CFLAG)
 775         message(WARNING "No C AVX flag found. Consider a newer compiler, or disable AVX for much lower performance.")
 776     endif (NOT GNU_AVX_CFLAG AND NOT MSVC_AVX_CFLAG)
 777
 778     if (CMAKE_CXX_COMPILER_LOADED)
 779         GMX_TEST_CXXFLAG(GNU_AVX_CXXFLAG "-mavx" GROMACS_CXX_FLAGS)
 780         if (NOT GNU_AVX_CXXFLAG)
 781             GMX_TEST_CXXFLAG(MSVC_AVX_CXXFLAG "/arch:AVX" GROMACS_CXX_FLAGS)
 782         endif (NOT GNU_AVX_CXXFLAG)
 783         if (NOT GNU_AVX_CXXFLAG AND NOT MSVC_AVX_CXXFLAG)
 784             message(WARNING "No C++ AVX flag found. Consider a newer compiler, or disable AVX for much lower performance.")
 785         endif (NOT GNU_AVX_CXXFLAG AND NOT MSVC_AVX_CXXFLAG)
 786     endif()
 787
 788     # Only test the header after we have tried to add the flag for AVX support
 789     check_include_file(immintrin.h  HAVE_IMMINTRIN_H ${GROMACS_C_FLAGS})
 790
 791     if(NOT HAVE_IMMINTRIN_H)
 792         message(FATAL_ERROR "Cannot find immintrin.h, which is required for AVX intrinsics support. Consider switching compiler.")
 793     endif(NOT HAVE_IMMINTRIN_H)
 794
 795     # AMD says we should include x86intrin.h for FMA support, but MSVC seems to do fine without it, so don't require it.
 796     check_include_file(x86intrin.h HAVE_X86INTRIN_H ${GROMACS_C_FLAGS})
 797
 798     # The user should not be able to set this orthogonally to the acceleration
 799     set(GMX_X86_SSE4_1 1)
 800     set(GMX_X86_SSE2   1)
 801
 802     # But just enable one of the choices internally...
 803     if(${GMX_ACCELERATION} STREQUAL "AVX_128_FMA")
 804         set(GMX_X86_AVX_128_FMA 1)
 805         if (NOT ACCELERATION_QUIETLY)
 806           message(STATUS "Enabling 128-bit AVX Gromacs acceleration (with fused-multiply add), and it will help compiler optimization.")
 807         endif()
 808     else()
 809         # If we are not doing AVX_128, it must be AVX_256...
 810         set(GMX_X86_AVX_256 1)
 811         if (NOT ACCELERATION_QUIETLY)
 812           message(STATUS "Enabling 256-bit AVX Gromacs acceleration, and it will help compiler optimization.")
 813         endif()
 814     endif()
 815
 816 elseif(${GMX_ACCELERATION} STREQUAL "FORTRAN")
 817
 818 #    Fortran is temporarily disabled while we push in nbNxN kernels.
 819 #    We need to fake it a bit here to avoid jenkins build errors!
 820 #    add_definitions(-DGMX_FORTRAN)
 821
 822 elseif(${GMX_ACCELERATION} STREQUAL "BLUEGENE")
 823 # GMX_ACCELERATION=BlueGene should be set in the Toolchain-BlueGene?-???.cmake file
 824     if (NOT ACCELERATION_QUIETLY)
 825       message(STATUS "Configuring for BlueGene")
 826     endif()
 827     set(GMX_BLUEGENE 1)
 828     if (${CMAKE_SYSTEM_NAME} STREQUAL "BlueGeneL")
 829         set(SHARED_LIBS_DEFAULT OFF CACHE BOOL "Shared libraries not compatible with BlueGene/L, disabled!" FORCE)
 830         set(BUILD_SHARED_LIBS OFF CACHE BOOL "Shared libraries not compatible with BlueGene/L, disabled!" FORCE)
 831     endif (${CMAKE_SYSTEM_NAME} STREQUAL "BlueGeneL")
 832     set(GMX_SOFTWARE_INVSQRT OFF CACHE BOOL "Do not use software reciprocal square root on BlueGene" FORCE)
 833     set(GMX_POWERPC_INVSQRT ON CACHE BOOL "Use hardware reciprocal square root on BlueGene" FORCE)
 834     set(GMX_X11 OFF CACHE BOOL "X11 not compatible with BlueGene, disabled!" FORCE)
 835     set(GMX_THREAD_MPI OFF CACHE BOOL "Thread-MPI not compatible with BlueGene, disabled!" FORCE)
 836     set(GMX_MPI ON CACHE BOOL "Use MPI on BlueGene" FORCE)
 837 # Access to /etc/passwd is not available on the back end of BlueGene,
 838 # despite being detected by CMake. This can cause linker warnings
 839 # about harmless things in src/gmxlib/string2.h.
 840     set(HAVE_PWD_H OFF)
 841 # The automatic testing for endianness does not work for the BlueGene cross-compiler
 842     set(GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER 1 CACHE INTERNAL "BlueGene has big endian FP byte order (by default)" FORCE)
 843     set(GMX_IEEE754_BIG_ENDIAN_WORD_ORDER 1 CACHE INTERNAL "BlueGene has big endian FP word order (by default)" FORCE)
 844 elseif(${GMX_ACCELERATION} STREQUAL "POWER6")
 845     set(GMX_POWER6 1)
 846     set(GMX_SOFTWARE_INVSQRT OFF CACHE BOOL "Do not use software reciprocal square root on Power6" FORCE)
 847     set(GMX_POWERPC_INVSQRT ON CACHE BOOL "Use hardware reciprocal square root on Power6" FORCE)
 848 else(${GMX_ACCELERATION} STREQUAL "NONE")
 849     MESSAGE(FATAL_ERROR "Unrecognized option for accelerated kernels: ${GMX_ACCELERATION}. Pick one of None, SSE2, SSE4.1, AVX_128_FMA, AVX_256, Fortran, BlueGene, Power6")
 850 endif(${GMX_ACCELERATION} STREQUAL "NONE")
 851 set(ACCELERATION_QUIETLY TRUE CACHE INTERNAL "")
 852
 853 if(GMX_FORTRAN OR GMX_POWER6)
 854     if (GMX_THREAD_MPI)
 855         message(FATAL_ERROR "FORTRAN/POWER6 is incompatible with thread-MPI and only provides a speed-up on certain IBM compilers. Disable FORTRAN (or threads if you really want to use FORTRAN kernels).")
 856     endif(GMX_THREAD_MPI)
 857     enable_language(Fortran)
 858     include(FortranCInterface)
 859     discover_fortran_mangling(prefix isupper suffix extra_under_score found)
 860     if(extra_under_score)
 861         set(extrasuffix "_")
 862     endif(extra_under_score)
 863     if(prefix)
 864       set(prefix "${prefix} ##")
 865     endif(prefix)
 866     if(suffix)
 867       set(suffix "## ${suffix}")
 868       if(extrasuffix)
 869         set(extrasuffix "${suffix}${extrasuffix}")
 870       endif(extrasuffix)
 871     else(suffix)
 872       if(extrasuffix)
 873         # Don't know if this is needed, but it can't hurt
 874         set(extrasuffix "## ${extrasuffix}")
 875       endif(extrasuffix)
 876     endif(suffix)
 877
 878     if(isupper)
 879         set(F77_FUNCDEF   "${prefix} NAME ${suffix}")
 880         set(F77_FUNCDEF_  "${prefix} NAME ${extrasuffix}")
 881     else(isupper)
 882         set(F77_FUNCDEF   "${prefix} name ${suffix}")
 883         set(F77_FUNCDEF_  "${prefix} name ${extrasuffix}")
 884     endif(isupper)
 885 else(GMX_FORTRAN OR GMX_POWER6)
 886         set(F77_FUNCDEF   "name ## _")
 887         set(F77_FUNCDEF_  "name ## _")
 888 endif(GMX_FORTRAN OR GMX_POWER6)
 889
 890 # Process QM/MM Settings
 891 string(TOUPPER ${GMX_QMMM_PROGRAM} ${GMX_QMMM_PROGRAM})
 892 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 893     set(GMX_QMMM_GAUSSIAN 1)
 894 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 895     set(GMX_QMMM_MOPAC 1)
 896 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 897     set(GMX_QMMM_GAMESS 1)
 898 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 899     set(GMX_QMMM_ORCA 1)
 900 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 901     # nothing to do
 902 else(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 903     MESSAGE(FATAL_ERROR "Invalid QM/MM program option: ${GMX_QMMM_PROGRAM}. Choose one of: Gaussian, Mopac, Gamess, Orca, None")
 904 endif(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 905
 906 # Process FFT library settings - if not OpenMM build
 907 string(TOUPPER ${GMX_FFT_LIBRARY} ${GMX_FFT_LIBRARY})
 908 set(PKG_FFT "")
 909 set(PKG_FFT_LIBS "")
 910 if(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 911     if(GMX_DOUBLE)
 912         set(FFTW fftw)
 913     else(GMX_DOUBLE)
 914         set(FFTW fftwf)
 915     endif(GMX_DOUBLE)
 916     find_package(FFTW COMPONENTS ${FFTW})
 917     string(TOUPPER "${FFTW}" FFTW)
 918     set(PKG_FFT "${${FFTW}_PKG}")
 919     include_directories(${${FFTW}_INCLUDE_DIRS})
 920     set(FFT_LIBRARIES ${${FFTW}_LIBRARIES})
 921     if(NOT ${FFTW}_FOUND)
 922       MESSAGE(FATAL_ERROR "Cannot find FFTW3 (with correct precision - libfftw3f for single precision GROMACS or libfftw3 for double precision GROMACS). Fix it, choose another FFT library, or use the Gromacs built-in fftpack (slower)!")
 923     endif(NOT ${FFTW}_FOUND)
 924
 925     set(GMX_FFT_FFTW3 1)
 926
 927     if (NOT ${GMX_ACCELERATION} STREQUAL "NONE" AND NOT ${FFTW}_HAVE_SIMD)
 928       message(WARNING "The fftw library found is compiled without SIMD support, which makes it slow. Consider recompiling it or contact your admin")
 929     endif (NOT ${GMX_ACCELERATION} STREQUAL "NONE" AND NOT ${FFTW}_HAVE_SIMD)
 930
 931 elseif(${GMX_FFT_LIBRARY} STREQUAL "MKL")
 932 #    MESSAGE(STATUS "Using external FFT library - Intel MKL")
 933     find_package(MKL REQUIRED)
 934     include_directories(${MKL_INCLUDE_DIR})
 935     set(FFT_LIBRARIES ${MKL_LIBRARIES})
 936     set(PKG_FFT_LIBS ${MKL_LIBRARIES})
 937
 938     set(GMX_FFT_MKL 1)
 939     set(HAVE_MKL 1)
 940
 941 #elseif(${GMX_FFT_LIBRARY} STREQUAL "ACML")
 942 #    MESSAGE(STATUS "Using external FFT library - AMD core math library")
 943 #    set(GMX_FFT_ACML 1)
 944 elseif(${GMX_FFT_LIBRARY} STREQUAL "FFTPACK")
 945     MESSAGE(STATUS "Using internal FFT library - fftpack")
 946     set(GMX_FFT_FFTPACK 1)
 947 else(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 948     MESSAGE(FATAL_ERROR "Invalid FFT library setting: ${GMX_FFT_LIBRARY}. Choose one of: fftw3, mkl, fftpack")
 949 endif(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 950
 951 # enable threaded fftw3 if we've found it
 952 if(FFTW3_THREADS OR FFTW3F_THREADS)
 953     add_definitions(-DFFT5D_FFTW_THREADS)
 954 endif()
 955
 956 set(GMX_EXTERNAL_BLAS TRUE CACHE BOOL "Use external BLAS instead of built-in")
 957 set(GMX_EXTERNAL_LAPACK TRUE CACHE BOOL "Use external LAPACK instead of built-in")
 958 # MKL has BLAS/LAPACK routines
 959 if(NOT HAVE_MKL AND NOT ACCELERATE_FRAMEWORK)
 960   if(GMX_EXTERNAL_BLAS)
 961     if (GMX_BLAS_USER)
 962         list(APPEND GMX_EXTRA_LIBRARIES ${GMX_BLAS_USER})
 963     else(GMX_BLAS_USER)
 964         set(BLAS_FIND_QUIETLY ON)
 965         find_package(BLAS)
 966         if (BLAS_FOUND)
 967           list(APPEND GMX_EXTRA_LIBRARIES ${BLAS_LIBRARIES})
 968         else()
 969           MESSAGE(STATUS "Using internal BLAS library")
 970           set(GMX_EXTERNAL_BLAS FALSE CACHE BOOL "Use external BLAS instead of built-in" FORCE)
 971         endif()
 972     endif(GMX_BLAS_USER)
 973   endif(GMX_EXTERNAL_BLAS)
 974   if(GMX_EXTERNAL_LAPACK)
 975     if (GMX_LAPACK_USER)
 976         list(APPEND GMX_EXTRA_LIBRARIES ${GMX_LAPACK_USER})
 977     else(GMX_LAPACK_USER)
 978         set(LAPACK_FIND_QUIETLY ON)
 979         find_package(LAPACK)
 980         if (LAPACK_FOUND)
 981           list(APPEND GMX_EXTRA_LIBRARIES ${LAPACK_LIBRARIES})
 982         else()
 983           MESSAGE(STATUS "Using internal LAPACK library")
 984           set(GMX_EXTERNAL_LAPACK FALSE CACHE BOOL "Use external LAPACK instead of built-in" FORCE)
 985         endif()
 986     endif(GMX_LAPACK_USER)
 987   endif(GMX_EXTERNAL_LAPACK)
 988 endif()
 989 mark_as_advanced(GMX_EXTERNAL_LAPACK)
 990 mark_as_advanced(GMX_EXTERNAL_BLAS)
 991
 992 set(GMX_USE_PLUGINS OFF CACHE INTERNAL "Whether GROMACS will really try to compile support for VMD plugins")
 993
 994 if(GMX_LOAD_PLUGINS)
 995   if(CYGWIN OR NOT WIN32)
 996     # Native Windows does not have, nor need dlopen
 997     # Note that WIN32 is set with Cygwin, but Cygwin needs dlopen to use plug-ins
 998     include(gmxTestdlopen)
 999     gmx_test_dlopen(HAVE_DLOPEN)
1000   endif()
1001
1002   # so, should we use plug-ins?
1003   if((WIN32 AND NOT CYGWIN) OR (HAVE_DLOPEN AND BUILD_SHARED_LIBS))
1004     if(NOT VMD_QUIETLY)
1005       MESSAGE(STATUS
1006           "Found the ability to use plug-ins when building shared libaries, "
1007           "so will compile to use plug-ins (e.g. to read VMD-supported file "
1008           "formats).")
1009     endif()
1010     if(NOT GMX_VMD_PLUGIN_PATH)
1011       find_package(VMD)
1012     endif()
1013     set(GMX_USE_PLUGINS ON)
1014     list(APPEND GMX_EXTRA_LIBRARIES ${CMAKE_DL_LIBS}) # magic cross-platform pre-set variable for dlopen library
1015     set(PKG_DL_LIBS "-l${CMAKE_DL_LIBS}")
1016   else()
1017     set(PKG_DL_LIBS)
1018   endif()
1019 endif(GMX_LOAD_PLUGINS)
1020 set(VMD_QUIETLY TRUE CACHE INTERNAL "")
1021
1022 if(EXISTS "${CMAKE_SOURCE_DIR}/admin/.isreposource")
1023     if(NOT CMAKE_CROSSCOMPILING)
1024         option(GMX_BUILD_MANPAGES "Build man pages" ON)
1025     else()
1026         message(STATUS "Building the man pages is not available when "
1027             "cross-compiling the developer version from git")
1028     endif()
1029 else()
1030     #make sure source package contains all man pages
1031     if(NOT EXISTS "${CMAKE_SOURCE_DIR}/man/man1/ngmx.1")
1032         message(FATAL_ERROR "Man pages are missing from source package.")
1033     endif()
1034 endif()
1035 mark_as_advanced(GMX_BUILD_MANPAGES)
1036
1037 # Math and thread libraries must often come after all others when linking...
1038 if(HAVE_LIBM)
1039     list(APPEND GMX_EXTRA_LIBRARIES m)
1040 endif(HAVE_LIBM)
1041
1042 if(GMX_FAHCORE)
1043   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
1044       "Path to swindirect.h")
1045   include_directories(${COREWRAP_INCLUDE_DIR})
1046 endif(GMX_FAHCORE)
1047
1048 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
1049 # these are set after everything else
1050 if (NOT DEFINED GROMACS_C_FLAGS_SET)
1051     set(GROMACS_C_FLAGS_SET true CACHE INTERNAL "Whether to reset the C flags"
1052         FORCE)
1053     set(CMAKE_C_FLAGS "${GROMACS_C_FLAGS} ${CMAKE_C_FLAGS}" CACHE STRING
1054         "Flags used by the compiler during all build types" FORCE)
1055     if (CMAKE_CXX_COMPILER_LOADED)
1056         set(CMAKE_CXX_FLAGS "${GROMACS_CXX_FLAGS} ${CMAKE_CXX_FLAGS}" CACHE STRING
1057             "Flags used by the compiler during all build types" FORCE)
1058     endif()
1059     set(CMAKE_EXE_LINKER_FLAGS
1060         "${GROMACS_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}"
1061         CACHE STRING "Linker flags for creating executables" FORCE)
1062     set(CMAKE_SHARED_LINKER_FLAGS
1063         "${GROMACS_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS}"
1064         CACHE STRING "Linker flags for creating shared libraries" FORCE)
1065 endif (NOT DEFINED GROMACS_C_FLAGS_SET)
1066
1067 if(NOT GMX_OPENMP)
1068     #Unset all OpenMP flags in case OpenMP was disabled either by the user
1069     #or because it was only partially detected (e.g. only for C but not C++ compiler)
1070     unset(OpenMP_C_FLAGS CACHE)
1071     unset(OpenMP_CXX_FLAGS CACHE)
1072     unset(OpenMP_LINKER_FLAGS CACHE)
1073     unset(OpenMP_SHARED_LINKER_FLAGS)
1074 endif()
1075 ######################################
1076 # Output compiler and CFLAGS used
1077 ######################################
1078 execute_process(COMMAND ${CMAKE_C_COMPILER} --version RESULT_VARIABLE TMP_RESULT OUTPUT_VARIABLE CC_VERSION ERROR_VARIABLE CC_VERSION)
1079 #try executing just the compiler command if that failed...
1080 if(TMP_RESULT)
1081     execute_process(COMMAND ${CMAKE_C_COMPILER} RESULT_VARIABLE TMP_RESULT OUTPUT_VARIABLE CC_VERSION ERROR_VARIABLE CC_VERSION)
1082 endif()
1083 string(LENGTH "${CC_VERSION}" len)
1084 if(len)
1085     string(REGEX MATCH "[^\n]+" CC_VERSION "${CC_VERSION}")
1086 endif()
1087
1088 set(BUILD_COMPILER "@CMAKE_C_COMPILER@ @CMAKE_C_COMPILER_ID@ @CC_VERSION@")
1089 set(BUILD_CFLAGS "@CMAKE_C_FLAGS@")
1090 if(CMAKE_BUILD_TYPE STREQUAL "Debug")
1091     set(BUILD_CFLAGS "@BUILD_CFLAGS@ @CMAKE_C_FLAGS_DEBUG@")
1092 elseif(CMAKE_BUILD_TYPE STREQUAL "Release")
1093     set(BUILD_CFLAGS "@BUILD_CFLAGS@ @CMAKE_C_FLAGS_RELEASE@")
1094 elseif(CMAKE_BUILD_TYPE STREQUAL "MinSizeRel")
1095     set(BUILD_CFLAGS "@BUILD_CFLAGS@ @CMAKE_C_FLAGS_MINSIZEREL@")
1096 elseif(CMAKE_BUILD_TYPE STREQUAL "RelWithDebInfo")
1097     set(BUILD_CFLAGS "@BUILD_CFLAGS@ @CMAKE_C_FLAGS_RELWITHDEBINFO@")
1098 endif()
1099
1100
1101 ########################################################################
1102 # Specify install locations and which subdirectories to process        #
1103 ########################################################################
1104 if (GMX_USE_RELATIVE_INSTALL_PATH)
1105     set(GMX_INSTALL_PREFIX "" CACHE STRING "Prefix gets appended to CMAKE_INSTALL_PREFIX. For cpack it sets the root folder of the archive.")
1106     mark_as_advanced(GMX_INSTALL_PREFIX)
1107 else()
1108     set(GMX_INSTALL_PREFIX "${CMAKE_INSTALL_PREFIX}/")
1109 endif()
1110
1111 if ( NOT DEFINED GMXLIB )
1112     set(GMXLIB lib)
1113 endif()
1114 set(LIB_INSTALL_DIR "${GMX_INSTALL_PREFIX}${GMXLIB}")
1115 set(BIN_INSTALL_DIR  ${GMX_INSTALL_PREFIX}bin)
1116 set(DATA_INSTALL_DIR ${GMX_INSTALL_PREFIX}share/gromacs)
1117 set(MAN_INSTALL_DIR  ${GMX_INSTALL_PREFIX}share/man)
1118 set(INCL_INSTALL_DIR ${GMX_INSTALL_PREFIX}include)
1119
1120 set(GMXLIBDIR        ${DATA_INSTALL_DIR}/top)
1121
1122 ##################################################################
1123 # Shared library settings - Darwin uses INSTALL_NAME_DIR instead!
1124 ##################################################################
1125 if(NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin")
1126     set(CMAKE_SKIP_BUILD_RPATH  FALSE)
1127     set(CMAKE_BUILD_WITH_INSTALL_RPATH FALSE)
1128     set(CMAKE_INSTALL_RPATH "\\\$ORIGIN/../${GMXLIB}")
1129     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
1130 endif()
1131
1132 #COPYING file: Only necessary for binary distributions.
1133 #Simpler to always install.
1134 install(FILES COPYING DESTINATION ${DATA_INSTALL_DIR} COMPONENT data)
1135
1136 add_subdirectory(share)
1137 add_subdirectory(include)
1138 add_subdirectory(src)
1139 add_subdirectory(scripts)
1140
1141 #######################
1142 ## uninstall target
1143 #######################
1144     CONFIGURE_FILE(
1145                    "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
1146                    "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
1147                    IMMEDIATE @ONLY)
1148 ###########################
1149 ADD_CUSTOM_TARGET(uninstall
1150                   "${CMAKE_COMMAND}" -P
1151                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
1152 ###########################
1153
1154
1155 ########################################################################
1156 # Tests                                                                #
1157 ########################################################################
1158
1159 include(CTest)
1160 mark_as_advanced(BUILD_TESTING)
1161 IF(BUILD_TESTING)
1162         enable_testing()
1163         add_subdirectory(tests)
1164 ENDIF()
1165