CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2009,2010,2011,2012,2013 by the GROMACS development team.
   5 # Copyright (c) 2014,2015,2016,2017,2018 by the GROMACS development team.
   6 # Copyright (c) 2019,2020,2021, by the GROMACS development team, led by
   7 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   8 # and including many others, as listed in the AUTHORS file in the
   9 # top-level source directory and at http://www.gromacs.org.
  10 #
  11 # GROMACS is free software; you can redistribute it and/or
  12 # modify it under the terms of the GNU Lesser General Public License
  13 # as published by the Free Software Foundation; either version 2.1
  14 # of the License, or (at your option) any later version.
  15 #
  16 # GROMACS is distributed in the hope that it will be useful,
  17 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  19 # Lesser General Public License for more details.
  20 #
  21 # You should have received a copy of the GNU Lesser General Public
  22 # License along with GROMACS; if not, see
  23 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  24 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  25 #
  26 # If you want to redistribute modifications to GROMACS, please
  27 # consider that scientific software is very special. Version
  28 # control is crucial - bugs must be traceable. We will be happy to
  29 # consider code for inclusion in the official distribution, but
  30 # derived work must not be called official GROMACS. Details are found
  31 # in the README & COPYING files - if they are missing, get the
  32 # official version at http://www.gromacs.org.
  33 #
  34 # To help us fund GROMACS development, we humbly ask that you cite
  35 # the research papers on the package. Check out http://www.gromacs.org.
  36
  37 cmake_minimum_required(VERSION 3.13)
  38 cmake_policy(SET CMP0074 NEW) # From CMake 3.12
  39 cmake_policy(SET CMP0068 NEW) # From CMake-3.9
  40
  41 # CMake modules/macros are in a subdirectory to keep this file cleaner
  42 # This needs to be set before project() in order to pick up toolchain files
  43 list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake ${CMAKE_CURRENT_SOURCE_DIR}/cmake/Platform)
  44
  45 if(CMAKE_SYSTEM_NAME STREQUAL "Darwin")
  46     # Providing a default value >=10.14 helps to find modern C++ compatibility,
  47     # such as by defaulting to the Clang libc++ instead of libstdc++.
  48     set(CMAKE_OSX_DEPLOYMENT_TARGET 10.14 CACHE STRING
  49         "OS X deployment target affects default SDK version and compiler flags.")
  50     # By default, limit the binary architecture to a single 64-bit build.
  51     set(CMAKE_OSX_ARCHITECTURES x86_64 CACHE STRING
  52         "OS X architecture affects the compatibility of the (potentially fat) binaries produced."
  53         FORCE)
  54 endif()
  55
  56 project(Gromacs)
  57
  58 set(CMAKE_CXX_STANDARD 17)
  59 set(CMAKE_CXX_STANDARD_REQUIRED ON)
  60 set(CMAKE_CXX_EXTENSIONS OFF)
  61
  62 include(gmxManageCcache)
  63
  64 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  65 set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  66 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
  67
  68 find_package(LibStdCpp)
  69
  70 # Python is first referenced in gmxVersionInfo, so we perform the search early
  71 # to find a suitable installation for all components.
  72 include(gmxPythonDiscovery)
  73 # Set up common version variables, as well as general information about
  74 # the build tree (whether the build is from a source package or from a git
  75 # repository).  Also declares a few functions that will be used for generating
  76 # version info files later.
  77 include(gmxBuildTreeInfo)
  78 include(gmxVersionInfo)
  79
  80 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT AND UNIX)
  81     set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
  82 endif()
  83 if("${CMAKE_INSTALL_PREFIX}" STREQUAL "${CMAKE_BINARY_DIR}")
  84     message(FATAL_ERROR "GROMACS cannot be installed into the build tree, choose a different location for CMAKE_INSTALL_PREFIX")
  85 endif()
  86
  87 include(gmxBuildTypeReference)
  88 include(gmxBuildTypeProfile)
  89 include(gmxBuildTypeTSAN)
  90 include(gmxBuildTypeASAN)
  91 include(gmxBuildTypeMSAN)
  92 include(gmxBuildTypeUBSAN)
  93 include(gmxBuildTypeReleaseWithAssert)
  94
  95 if(NOT CMAKE_BUILD_TYPE)
  96     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel Reference RelWithAssert Profile TSAN ASAN MSAN UBSAN." FORCE)
  97     # Set the possible values of build type for cmake-gui
  98     set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "Debug" "Release"
  99         "MinSizeRel" "RelWithDebInfo" "Reference" "RelWithAssert" "Profile" "TSAN" "ASAN" "MSAN" "UBSAN")
 100 endif()
 101 if(CMAKE_CONFIGURATION_TYPES)
 102     # Add appropriate GROMACS-specific build types for the Visual
 103     # Studio generator (Debug, Release, MinSizeRel and RelWithDebInfo
 104     # are already present by default).
 105     list(APPEND CMAKE_CONFIGURATION_TYPES "RelWithAssert" "Reference")
 106     list(REMOVE_DUPLICATES CMAKE_CONFIGURATION_TYPES)
 107     set(CMAKE_CONFIGURATION_TYPES "${CMAKE_CONFIGURATION_TYPES}" CACHE STRING
 108         "List of configuration types"
 109         FORCE)
 110 endif()
 111 set(build_types_with_explicit_flags RELEASE DEBUG RELWITHDEBINFO RELWITHASSERT MINSIZEREL PROFILE)
 112
 113 set_property(GLOBAL PROPERTY FIND_LIBRARY_USE_LIB64_PATHS ON)
 114
 115 include(gmxCTestUtilities)
 116 gmx_ctest_init()
 117
 118 include(gmxCPackUtilities)
 119 gmx_cpack_init()
 120
 121 # Variables that accumulate stuff influencing the installed headers
 122 set(INSTALLED_HEADER_INCLUDE_DIRS "")
 123 set(INSTALLED_HEADER_DEFINITIONS "")
 124
 125 ########################################################################
 126 # Global non-cache variables for implementing the build system
 127 ########################################################################
 128
 129 # These variables collect libraries that GROMACS requires for
 130 # linking. They should be appended to with list(APPEND ${name}
 131 # new-library) calls. They are:
 132 #  - Libraries that are required for libgromacs (only)
 133 set(GMX_EXTRA_LIBRARIES "")
 134 #  - Libraries that are required for all code in the repository
 135 set(GMX_COMMON_LIBRARIES "")
 136 #  - Libraries that all code linked against libgromacs needs
 137 #    (i.e., something that is exposed in installed headers).
 138 set(GMX_PUBLIC_LIBRARIES "")
 139
 140 ########################################################################
 141 # Check and warn if cache generated on a different host is being reused
 142 ########################################################################
 143 if(CMAKE_HOST_UNIX)
 144     execute_process(COMMAND hostname
 145                     OUTPUT_VARIABLE TMP_HOSTNAME
 146                     OUTPUT_STRIP_TRAILING_WHITESPACE)
 147     # Only check for host name if not running in a CI environment, as the cache might
 148     # be reused there between different machines in different stages
 149     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}"
 150             AND NOT DEFINED ENV{CI_JOB_ID})
 151         message(WARNING "
 152             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
 153             is being reused! This could lead to inconsistencies; therefore, it is
 154             recommended to regenerate the cache!")
 155     endif()
 156     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
 157             "Hostname of the machine where the cache was generated.")
 158 endif()
 159
 160 ########################################################################
 161 # Detect architecture before setting options so we can alter defaults
 162 ########################################################################
 163 # Detect the architecture the compiler is targetting, detect
 164 # SIMD instructions possibilities on that hardware, suggest SIMD instruction set
 165 # to use if none is specified, and populate the cache option for CPU
 166 # SIMD.
 167 include(gmxDetectTargetArchitecture)
 168 gmx_detect_target_architecture()
 169
 170 ########################################################################
 171 # User input options                                                   #
 172 ########################################################################
 173 include(gmxOptionUtilities)
 174
 175 set(CMAKE_PREFIX_PATH "" CACHE STRING "Extra locations to search for external libraries and tools (give directory without lib, bin, or include)")
 176
 177 # Fujitsu only has SIMD in double precision, so this will be faster
 178 gmx_set_boolean(GMX_DOUBLE_DEFAULT GMX_TARGET_FUJITSU_SPARC64)
 179 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" ${GMX_DOUBLE_DEFAULT})
 180 option(GMX_RELAXED_DOUBLE_PRECISION "Accept single precision 1/sqrt(x) when using Fujitsu HPC-ACE SIMD" OFF)
 181 mark_as_advanced(GMX_RELAXED_DOUBLE_PRECISION)
 182
 183 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 184 option(GMX_THREAD_MPI  "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" ON)
 185 gmx_dependent_option(
 186     GMX_MPI_IN_PLACE
 187     "Enable MPI_IN_PLACE for MPIs that have it defined"
 188     ON
 189     GMX_MPI)
 190 mark_as_advanced(GMX_MPI_IN_PLACE)
 191
 192 option(GMX_MIMIC "Enable MiMiC QM/MM interface (CPMD is required)" OFF)
 193
 194 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 195 mark_as_advanced(GMX_FAHCORE)
 196
 197 option(GMX_COOL_QUOTES "Enable GROMACS cool quotes" ON)
 198 mark_as_advanced(GMX_COOL_QUOTES)
 199 gmx_add_cache_dependency(GMX_COOL_QUOTES BOOL "NOT GMX_FAHCORE" OFF)
 200
 201 option(GMX_INSTALL_LEGACY_API "Install legacy headers" OFF)
 202
 203 gmx_option_multichoice(
 204     GMX_GPU
 205     "Framework for GPU acceleration"
 206     OFF
 207     OFF CUDA OpenCL SYCL)
 208
 209 gmx_option_multichoice(
 210     GMX_SIMD
 211     "SIMD instruction set for CPU kernels and compiler optimization"
 212     "AUTO"
 213     AUTO None SSE2 SSE4.1 AVX_128_FMA AVX_256 AVX2_256 AVX2_128 AVX_512 AVX_512_KNL MIC ARM_NEON ARM_NEON_ASIMD ARM_SVE IBM_VMX IBM_VSX Sparc64_HPC_ACE Reference)
 214
 215 if(GMX_TARGET_MIC)
 216     set(GMX_FFT_LIBRARY_DEFAULT "mkl")
 217 else()
 218     set(GMX_FFT_LIBRARY_DEFAULT "fftw3")
 219 endif()
 220
 221 gmx_option_multichoice(
 222     GMX_FFT_LIBRARY
 223     "FFT library"
 224     "${GMX_FFT_LIBRARY_DEFAULT}"
 225     fftw3 mkl "fftpack[built-in]")
 226 gmx_dependent_option(
 227     GMX_BUILD_OWN_FFTW
 228     "Download and build FFTW 3 during the GROMACS build process, rather than fall back on the really slow fftpack."
 229     OFF
 230     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 231 gmx_dependent_option(
 232     GMX_DISABLE_FFTW_MEASURE
 233     "Do not optimize FFTW setups (not needed with SSE)"
 234     OFF
 235     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 236 mark_as_advanced(GMX_BUILD_OWN_FFTW)
 237 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 238
 239 gmx_dependent_cache_variable(GMX_SIMD_REF_FLOAT_WIDTH  "Reference SIMD single precision width" STRING "4" "GMX_SIMD STREQUAL REFERENCE")
 240 gmx_dependent_cache_variable(GMX_SIMD_REF_DOUBLE_WIDTH "Reference SIMD double precision width" STRING "2" "GMX_SIMD STREQUAL REFERENCE")
 241
 242 # This should be moved to a separate NBNXN cmake module when that code is cleaned up and modularized
 243
 244 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 245 mark_as_advanced(GMX_BROKEN_CALLOC)
 246
 247 option(GMX_OPENMP "Enable OpenMP-based multithreading" ON)
 248
 249 option(GMX_USE_TNG "Use the TNG library for trajectory I/O" ON)
 250
 251 option(GMX_CYCLE_SUBCOUNTERS "Enable cycle subcounters to get a more detailed cycle timings" OFF)
 252 mark_as_advanced(GMX_CYCLE_SUBCOUNTERS)
 253
 254 option(GMX_SKIP_DEFAULT_CFLAGS "Don't automatically add suggested/required Compiler flags." OFF)
 255 mark_as_advanced(GMX_SKIP_DEFAULT_CFLAGS)
 256
 257 option(GMX_BUILD_FOR_COVERAGE
 258        "Tune build for better code coverage metrics (e.g., disable asserts)"
 259        OFF)
 260 mark_as_advanced(GMX_BUILD_FOR_COVERAGE)
 261
 262 option(GMX_DEVELOPER_BUILD
 263     "Enable Developer convenience features: always build unit-tests"
 264     OFF)
 265 mark_as_advanced(GMX_DEVELOPER_BUILD)
 266
 267 gmx_set_boolean(GMX_COMPILER_WARNINGS_DEFAULT "NOT SOURCE_IS_SOURCE_DISTRIBUTION")
 268 option(GMX_COMPILER_WARNINGS
 269     "Enable a default set of compiler warnings"
 270     ${GMX_COMPILER_WARNINGS_DEFAULT})
 271 mark_as_advanced(GMX_COMPILER_WARNINGS)
 272 # Always turn on compiler warnings with a developer build.
 273 gmx_add_cache_dependency(GMX_COMPILER_WARNINGS BOOL "NOT GMX_DEVELOPER_BUILD" ON)
 274
 275 option(GMX_BUILD_SHARED_EXE
 276     "Build exectuables as shared binaries. If not set, this disables rpath and dynamic linker flags in an attempt to build a static binary, but this may require setting up the toolchain properly and making appropriate libraries available."
 277     ON)
 278 mark_as_advanced(GMX_BUILD_SHARED_EXE)
 279
 280 option(GMX_PHYSICAL_VALIDATION
 281        "Include physical validation tests in ctest environment. These can then be called using 'make check-phys' or
 282        'make check-all'. Warning: Running the physical validation tests takes significantly more time than other tests!"
 283        OFF)
 284 mark_as_advanced(GMX_PHYSICAL_VALIDATION)
 285
 286 ######################################################################
 287 # Detect OpenMP support
 288 ######################################################################
 289 # The OpenMP detection _must_ come before tests for other CFLAGS.
 290 include(gmxManageOpenMP)
 291
 292
 293
 294 ######################################################################
 295 # Compiler tests
 296 # These need to be done early (before further tests).
 297 #####################################################################
 298
 299 include(gmxCFlags)
 300 gmx_c_flags()
 301
 302 # These variables should be used for CMake-style lists (ie. separated
 303 # by semicolons) of additional compiler flags which are not generated
 304 # in gmxCFlags nor are SIMD or MPI related.
 305 #
 306 # TODO These variables should be consolidated into
 307 # EXTRA_COMPILER_FLAGS so that we we don't perpetrate bugs where
 308 # things that work in C compilation (e.g. merging from old branches)
 309 # might not also work for C++ compilation.
 310 set(EXTRA_C_FLAGS "")
 311 set(EXTRA_CXX_FLAGS "")
 312
 313 # Run through a number of tests for buggy compilers and other issues
 314 include(gmxTestCompilerProblems)
 315 gmx_test_compiler_problems()
 316
 317 # Implement double-precision option. This is complicated because we
 318 # need installed headers to use the precision mode of the build that
 319 # produced the library, but cannot use config.h in that case. We also
 320 # want such variables to always have a definition, because #if is more
 321 # robust than #ifdef. So, we put this value on the compiler command
 322 # line in all cases.
 323 #
 324 # GMX_RELAXED_DOUBLE_PRECISION does not need to be handled here,
 325 # because no installed header needs it
 326 if(GMX_DOUBLE)
 327     set(GMX_DOUBLE_VALUE 1)
 328 else()
 329     set(GMX_DOUBLE_VALUE 0)
 330 endif()
 331 add_definitions(-DGMX_DOUBLE=${GMX_DOUBLE_VALUE})
 332 list(APPEND INSTALLED_HEADER_DEFINITIONS "-DGMX_DOUBLE=${GMX_DOUBLE_VALUE}")
 333
 334 option(GMX_IMD "Enable Interactive Molecular Dynamics (IMD) sessions, e.g. with VMD" ON)
 335 if(GMX_IMD AND WIN32)
 336     list(APPEND GMX_EXTRA_LIBRARIES "wsock32")
 337 endif()
 338
 339
 340
 341 ########################################################################
 342 # Basic system tests (standard libraries, headers, functions, types)   #
 343 ########################################################################
 344 include(CheckIncludeFiles)
 345 include(CheckIncludeFileCXX)
 346 check_include_files(unistd.h     HAVE_UNISTD_H)
 347 check_include_files(pwd.h        HAVE_PWD_H)
 348 check_include_files(dirent.h     HAVE_DIRENT_H)
 349 check_include_files(time.h       HAVE_TIME_H)
 350 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 351 check_include_files(io.h         HAVE_IO_H)
 352 check_include_files(sched.h      HAVE_SCHED_H)
 353 check_include_files(xmmintrin.h  HAVE_XMMINTRIN_H)
 354
 355 include(CheckCXXSymbolExists)
 356 check_cxx_symbol_exists(gettimeofday      sys/time.h   HAVE_GETTIMEOFDAY)
 357 check_cxx_symbol_exists(sysconf           unistd.h     HAVE_SYSCONF)
 358 check_cxx_symbol_exists(nice              unistd.h     HAVE_NICE)
 359 check_cxx_symbol_exists(fsync             unistd.h     HAVE_FSYNC)
 360 check_cxx_symbol_exists(_fileno           stdio.h      HAVE__FILENO)
 361 check_cxx_symbol_exists(fileno            stdio.h      HAVE_FILENO)
 362 check_cxx_symbol_exists(_commit           io.h         HAVE__COMMIT)
 363 check_cxx_symbol_exists(sigaction         signal.h     HAVE_SIGACTION)
 364
 365 # We cannot check for the __builtins as symbols, but check if code compiles
 366 check_cxx_source_compiles("int main(){ return __builtin_clz(1);}"   HAVE_BUILTIN_CLZ)
 367 check_cxx_source_compiles("int main(){ return __builtin_clzll(1);}" HAVE_BUILTIN_CLZLL)
 368 if(MSVC)
 369     check_cxx_source_compiles("#include <intrin.h>\n int main(){unsigned long r;unsigned long i=1;_BitScanReverse(&r,i);return r;}" HAVE_BITSCANREVERSE)
 370     check_cxx_source_compiles("#include <intrin.h>\n int main(){unsigned long r;unsigned __int64 i=1;_BitScanReverse64(&r,i);return r;}" HAVE_BITSCANREVERSE64)
 371 elseif(CMAKE_CXX_COMPILER_ID MATCHES "XL")
 372     check_cxx_source_compiles("int main(){ return __cntlz4(1);}" HAVE_CNTLZ4)
 373     check_cxx_source_compiles("int main(){ return __cntlz8(1);}" HAVE_CNTLZ8)
 374 endif()
 375
 376 include(CheckLibraryExists)
 377 find_library(HAVE_LIBM m)
 378 mark_as_advanced(HAVE_LIBM)
 379 check_library_exists(rt clock_gettime "" HAVE_CLOCK_GETTIME)
 380 check_library_exists(m feenableexcept "" HAVE_FEENABLEEXCEPT)
 381 check_library_exists(m fedisableexcept "" HAVE_FEDISABLEEXCEPT)
 382
 383 include(TestSchedAffinity)
 384 test_sched_affinity(HAVE_SCHED_AFFINITY)
 385
 386 # Aligned memory allocation. We need to check for both mm_malloc(),
 387 # posix_memalign(), memalign(), and on windows also _aligned_malloc()
 388 include(gmxTestMMMalloc)
 389 gmx_test_mm_malloc(HAVE__MM_MALLOC)
 390 check_cxx_symbol_exists(posix_memalign    stdlib.h     HAVE_POSIX_MEMALIGN)
 391 check_cxx_symbol_exists(memalign          stdlib.h     HAVE_MEMALIGN)
 392 if(MSVC)
 393     # No need to waste time on this test on platforms where it will never be true
 394     check_cxx_symbol_exists(_aligned_malloc   stdlib.h     HAVE__ALIGNED_MALLOC)
 395 endif()
 396
 397 include(TestBigEndian)
 398 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 399
 400 gmx_set_boolean(GMX_USE_NICE "HAVE_UNISTD_H AND HAVE_NICE")
 401
 402 # Management of GROMACS options for specific toolchains should go
 403 # here. Because the initial settings for some of the main options have
 404 # already happened, but things like library detection and MPI compiler
 405 # feature detection have not, the docstrings for any over-rides of
 406 # GROMACS defaults or user settings will make sense. Also, any
 407 # toolchain-related reasons for choosing whether to detect various
 408 # things can be sorted out now, before the detection takes place.
 409 if(GMX_TARGET_FUJITSU_SPARC64)
 410     include(gmxManageFujitsuSparc64)
 411 endif()
 412
 413 ########################################################################
 414 #Process MPI settings
 415 ########################################################################
 416 include(gmxManageMPI)
 417
 418 ########################################################################
 419 #Process MiMiC settings
 420 ########################################################################
 421 include(gmxManageMimic)
 422
 423 ########################################################################
 424 #Process shared/static library settings
 425 ########################################################################
 426 include(gmxManageSharedLibraries)
 427
 428
 429 ########################################################################
 430 # Specify install locations
 431 ########################################################################
 432 # Use GNUInstallDirs to set paths on multiarch systems.
 433 include(GNUInstallDirs)
 434
 435 set(GMX_INSTALL_DATASUBDIR "gromacs" CACHE STRING "Subdirectory for GROMACS data under CMAKE_INSTALL_DATADIR")
 436 mark_as_advanced(GMX_INSTALL_DATASUBDIR)
 437
 438 # Internal convenience so we do not have to join two path segments in the code
 439 set(GMX_INSTALL_GMXDATADIR ${CMAKE_INSTALL_DATADIR}/${GMX_INSTALL_DATASUBDIR})
 440
 441 # If the nesting level wrt. the installation root is changed,
 442 # gromacs-config.cmake.cmakein needs to be adapted.
 443 set(GMX_INSTALL_CMAKEDIR  ${CMAKE_INSTALL_DATAROOTDIR}/cmake)
 444
 445 # TODO: Make GMXRC adapt if this is changed
 446 set(GMX_INSTALL_PKGCONFIGDIR ${CMAKE_INSTALL_LIBDIR}/pkgconfig)
 447
 448 list(APPEND INSTALLED_HEADER_INCLUDE_DIRS ${CMAKE_INSTALL_INCLUDEDIR})
 449
 450 # Binary and library suffix options
 451 include(gmxManageSuffixes)
 452
 453
 454 ########################################################################
 455 # Find external packages                                               #
 456 ########################################################################
 457
 458 # Unconditionally find the package, as it is also required for unit
 459 # tests. This exports LIBXML2_FOUND, which we should not use because
 460 # it does not tell us that linking will succeed. Instead, we test that
 461 # next.
 462 #if(DEFINED LIBXML2_LIBRARIES)
 463 #  set(LibXml2_FIND_QUIETLY TRUE)
 464 #endif()
 465 #find_package(LibXml2)
 466 #include(gmxTestLibXml2)
 467 #gmx_test_libxml2(HAVE_LIBXML2)
 468 #option(GMX_XML "Use libxml2 to parse xml files (currently has no effect)" ${HAVE_LIBXML2})
 469 #set(PKG_XML "")
 470 #mark_as_advanced(GMX_XML)
 471 # Don't actually do anything, since libxml2 is currently not used by libgromacs
 472 #if(GMX_XML AND NOT HAVE_LIBXML2)
 473 #    message(FATAL_ERROR "libxml2 not found. Set GMX_XML=OFF to compile without XML support")
 474 #endif()
 475 #if(GMX_XML)
 476 #    include_directories(${LIBXML2_INCLUDE_DIR})
 477 #    set(PKG_XML libxml-2.0)
 478 #    set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 479 #endif()
 480
 481 option(GMX_HWLOC "Use hwloc portable hardware locality library" OFF)
 482
 483 if (GMX_HWLOC)
 484     # Find quietly the second time.
 485     if (HWLOC_FIND_QUIETLY_AFTER_FIRST_RUN)
 486         set(HWLOC_FIND_QUIETLY TRUE)
 487     endif()
 488     find_package(HWLOC 1.5)
 489
 490     if (HWLOC_FOUND)
 491         if (HWLOC_LIBRARIES MATCHES ".a$")
 492             set(_STATIC_HWLOC TRUE)
 493         endif()
 494
 495         gmx_check_if_changed(HWLOC_FOUND_CHANGED HWLOC_FOUND)
 496         if (_STATIC_HWLOC AND HWLOC_FOUND_CHANGED AND NOT GMX_HWLOC_FORCE)
 497             message(STATUS "Static hwloc library found, will not attempt using it as it could lead to link-time errors. To use the detected library, manually set GMX_HWLOC=ON and you will likely have to pass appropriate linker flags too to satisfy the link-time dependencies of your hwloc library. Try \"pkg-config --libs --static hwloc\" for suggestions on what you will need.")
 498             set(GMX_USE_HWLOC OFF)
 499         else()
 500             set(GMX_USE_HWLOC ON)
 501         endif()
 502
 503         if (GMX_USE_HWLOC)
 504             include_directories(SYSTEM ${HWLOC_INCLUDE_DIRS})
 505             list(APPEND GMX_EXTRA_LIBRARIES ${HWLOC_LIBRARIES})
 506         endif()
 507     elseif(GMX_HWLOC_FORCE)
 508         message(FATAL_ERROR "HWLOC package support required, but not found.")
 509     endif()
 510
 511     if (HWLOC_FOUND AND HWLOC_VERSION VERSION_LESS "2")
 512         message(STATUS "Support for hwloc versions 1.x is deprecated")
 513     endif()
 514
 515     set(HWLOC_FIND_QUIETLY_AFTER_FIRST_RUN TRUE CACHE INTERNAL "Be quiet during future attempts to find HWLOC")
 516 endif()
 517
 518 option(GMX_EXTERNAL_TINYXML2 "Use external TinyXML-2 instead of compiling the version bundled with GROMACS." OFF)
 519 mark_as_advanced(GMX_EXTERNAL_TINYXML2)
 520 if(GMX_EXTERNAL_TINYXML2)
 521     # Find an external TinyXML-2 library.
 522     find_package(TinyXML-2 3.0.0)
 523     set(HAVE_TINYXML2 ${TinyXML2_FOUND})
 524     if(NOT HAVE_TINYXML2)
 525         message(FATAL_ERROR "External TinyXML-2 could not be found, please adjust your search paths")
 526     endif()
 527 endif()
 528
 529 option(GMX_EXTRAE "Add support for tracing using EXTRAE" OFF)
 530 mark_as_advanced(GMX_EXTRAE)
 531
 532 if (GMX_EXTRAE)
 533   find_package(EXTRAE)
 534   if(EXTRAE_FOUND)
 535     include_directories(SYSTEM ${EXTRAE_INCLUDE_DIR})
 536     set(HAVE_EXTRAE 1)
 537   else()
 538     message(FATAL_ERROR "EXTRAE library was not found. Please add the correct path to CMAKE_PREFIX_PATH")
 539   endif()
 540 endif()
 541
 542 option(GMX_X11 "Use X window system" OFF)
 543 if (GMX_X11)
 544     find_package(X11)
 545     # X11 includes/libraries are only set in the ngmx subdirectory!
 546     if(NOT X11_FOUND)
 547         message(FATAL_ERROR
 548                 "X11 include files and/or libraries were not found. "
 549                 "Set GMX_X11=OFF to compile without X11 support. "
 550                 "gmx view will not be available.")
 551     endif()
 552     include_directories(SYSTEM ${X11_INCLUDE_DIR})
 553 endif()
 554
 555 include(ThreadMPI)
 556 # Enable core threading facilities
 557 tmpi_enable_core("${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include")
 558 if(GMX_THREAD_MPI)
 559     # enable MPI functions
 560     tmpi_enable()
 561     set(MPI_IN_PLACE_EXISTS 1)
 562 endif()
 563 # If atomics are manually disabled a define is needed because atomics.h doesn't depend on config.h
 564 if (TMPI_ATOMICS_DISABLED)
 565    add_definitions(-DTMPI_ATOMICS_DISABLED)
 566 endif()
 567
 568 include(gmxManageTNG)
 569
 570 include(gmxManageLmfit)
 571
 572 if(GMX_GPU)
 573
 574     string(TOUPPER "${GMX_GPU}" _gmx_gpu_uppercase)
 575     if(${_gmx_gpu_uppercase} STREQUAL "CUDA")
 576         include(gmxManageCuda)
 577     elseif(${_gmx_gpu_uppercase} STREQUAL "OPENCL")
 578         message(STATUS "GPU support with OpenCL is deprecated. It is still fully supported (and "
 579             "recommended for AMD and Intel GPUs). It may be replaced by different approaches in "
 580             "future releases of GROMACS.")
 581         include(gmxManageOpenCL)
 582     elseif(${_gmx_gpu_uppercase} STREQUAL "SYCL")
 583         include(gmxManageSYCL)
 584     endif()
 585     if(NOT GMX_OPENMP)
 586         message(WARNING "To use GPU acceleration efficiently, mdrun requires OpenMP multi-threading, which is currently not enabled.")
 587     endif()
 588
 589 endif()
 590
 591 if(CYGWIN)
 592     set(GMX_CYGWIN 1)
 593 endif()
 594
 595 if(WIN32)
 596     set(GMX_NATIVE_WINDOWS 1)
 597     # This makes windows.h not declare min/max as macros that would break
 598     # C++ code using std::min/std::max.
 599     add_definitions(-DNOMINMAX)
 600 endif()
 601
 602 option(GMX_BUILD_UNITTESTS "Build unit tests with BUILD_TESTING" ON)
 603 mark_as_advanced(GMX_BUILD_UNITTESTS)
 604 gmx_add_cache_dependency(GMX_BUILD_UNITTESTS BOOL BUILD_TESTING OFF)
 605
 606 ########################################################################
 607 # Our own GROMACS tests
 608 ########################################################################
 609
 610 include_directories(SYSTEM ${CMAKE_SOURCE_DIR}/src/external)
 611
 612 include(gmxTestInlineASM)
 613 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 614
 615 include(gmxSetBuildInformation)
 616 gmx_set_build_information()
 617
 618 # Anything but truly ancient x86 hardware should support rdtscp, so we enable it by default.
 619 # The inline assembly calling it is only ever compiled on x86, so defaulting to ON is OK.
 620 option(GMX_USE_RDTSCP "Use low-latency RDTSCP instruction for x86 CPU-based timers for mdrun execution; might need to be off when compiling for heterogeneous environments" ON)
 621 mark_as_advanced(GMX_USE_RDTSCP)
 622
 623 include(gmxTestLargeFiles)
 624 gmx_test_large_files(GMX_LARGEFILES)
 625
 626 include(gmxTestSignal)
 627 gmx_test_sigusr1(HAVE_SIGUSR1)
 628
 629 include(gmxTestPipes)
 630 gmx_test_pipes(HAVE_PIPES)
 631
 632 include(gmxTestXDR)
 633 gmx_test_xdr(GMX_SYSTEM_XDR)
 634 # Darwin has system XDR, but it uses a three-argument flavour of
 635 # xdrproc_t that it guarantees will still work if you pass the normal
 636 # two-argument xdr filters, but gcc 8 warns about the cast necessary
 637 # to do that, so it's simpler to just use our own XDR library.
 638 #
 639 # TODO It would be better to craft a cmake test which fails if such
 640 # XDR operations cause warnings, and succeeds otherwise, because it is
 641 # generally preferable to use system libraries where possible.
 642 if(NOT GMX_SYSTEM_XDR OR CMAKE_SYSTEM_NAME STREQUAL "Darwin")
 643     set(GMX_INTERNAL_XDR 1)
 644 endif()
 645
 646
 647 ##################################################
 648 # Process SIMD instruction settings
 649 ##################################################
 650 # This checks what flags to add in order to
 651 # support the SIMD instructions we need, it sets
 652 # correct defines for the SIMD instructions supported,
 653 # and adds advanced options to control accuracy
 654 # for SIMD math operations.
 655 include(gmxManageSimd)
 656 gmx_manage_simd()
 657
 658 ##################################################
 659 # Process FFT library settings
 660 ##################################################
 661 include(gmxManageFFTLibraries)
 662
 663
 664 include(gmxManageLinearAlgebraLibraries)
 665
 666 include(gmxManagePluginSupport)
 667 gmx_manage_plugin_support()
 668
 669 if(GMX_USE_PLUGINS)
 670     if(NOT GMX_VMD_PLUGIN_PATH)
 671         find_package(VMD)
 672     endif()
 673 endif()
 674
 675 # People might want to customize the default location for the DSSP binary
 676 set(GMX_DSSP_PROGRAM_PATH "/usr/local/bin/dssp"
 677     CACHE PATH
 678     "The default location to use for the DSSP binary")
 679 mark_as_advanced(GMX_DSSP_PROGRAM_PATH)
 680
 681 # Link real-time library for POSIX timers. The check for clock_gettime
 682 # confirms the linkability of rt.
 683 if(HAVE_TIME_H AND HAVE_UNISTD_H AND HAVE_CLOCK_GETTIME)
 684     list(APPEND GMX_EXTRA_LIBRARIES rt)
 685 endif()
 686
 687 # Math and thread libraries must often come after all others when linking...
 688 if (HAVE_LIBM)
 689     list(APPEND GMX_PUBLIC_LIBRARIES m)
 690 endif()
 691
 692 option(GMX_NACL "Configure for Native Client builds" OFF)
 693 if (GMX_NACL)
 694   list(APPEND GMX_EXTRA_LIBRARIES nosys)
 695   set(GMX_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -lnosys")
 696   # TODO: Is this still necessary with the check for its presence?
 697   set(GMX_USE_NICE 0)
 698   set(GMX_NO_RENAME 1)
 699 endif()
 700 mark_as_advanced(GMX_NACL)
 701
 702 if(GMX_FAHCORE)
 703   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 704       "Path to swindirect.h")
 705   include_directories(${COREWRAP_INCLUDE_DIR})
 706 endif()
 707
 708 option(GMX_BUILD_HELP "Build completions (requires that compiled binaries can be executed on build host) and install man pages if built (requires building the 'man' target manually)" OFF)
 709 mark_as_advanced(GMX_BUILD_HELP)
 710 if (GMX_BUILD_HELP AND SOURCE_IS_SOURCE_DISTRIBUTION AND BUILD_IS_INSOURCE)
 711     message(FATAL_ERROR
 712         "Rebuilding shell completions or man pages is not supported for "
 713         "in-source builds from a source distribution. "
 714         "Set GMX_BUILD_HELP=OFF or do an out-of-source build to proceed.")
 715 endif()
 716
 717 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 718 # these are set after everything else
 719 if (NOT GMX_SKIP_DEFAULT_CFLAGS)
 720     set(CMAKE_EXE_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS} ${DISABLE_SYCL_CXX_FLAGS}")
 721     set(CMAKE_SHARED_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS} ${DISABLE_SYCL_CXX_FLAGS}")
 722 else()
 723     message("Recommended flags which are not added because GMX_SKIP_DEFAULT_CFLAGS=yes:")
 724     message("CMAKE_C_FLAGS: ${SIMD_C_FLAGS};${MPI_COMPILE_FLAGS};${EXTRA_C_FLAGS};${GMXC_CFLAGS}")
 725     foreach(build_type ${build_types_with_explicit_flags})
 726         message("CMAKE_C_FLAGS_${build_type}: ${GMXC_CFLAGS_${build_type}}")
 727     endforeach()
 728     message("CMAKE_CXX_FLAGS: ${SIMD_CXX_FLAGS};${MPI_COMPILE_FLAGS};${EXTRA_CXX_FLAGS};${GMXC_CXXFLAGS}")
 729     foreach(build_type ${build_types_with_explicit_flags})
 730         message("CMAKE_CXX_FLAGS_${build_type}: ${GMXC_CXXFLAGS_${build_type}}")
 731     endforeach()
 732     message("CMAKE_EXE_LINKER_FLAGS: ${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS}")
 733     message("CMAKE_SHARED_LINKER_FLAGS: ${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS}")
 734 endif()
 735 # Allow `admin` directory to be easily conveyed to nested CMake commands.
 736 set(GMX_ADMIN_DIR ${CMAKE_SOURCE_DIR}/admin)
 737
 738 ################################################################
 739 # Shared library load path settings
 740 ################################################################
 741 if(NOT GMX_BUILD_SHARED_EXE)
 742     # No rpath
 743     set(CMAKE_SKIP_RPATH TRUE)
 744     set(CMAKE_EXE_LINK_DYNAMIC_C_FLAGS) # remove -Wl,-Bdynamic
 745     set(CMAKE_EXE_LINK_DYNAMIC_CXX_FLAGS)
 746 else()
 747     # The build folder always has bin/ and lib/; if we are also going to
 748     # install to lib/, then the installation RPATH works also in the build
 749     # tree.  This makes installation slightly faster (no need to rewrite the
 750     # RPATHs), and makes the binaries in the build tree relocatable.
 751     if(CMAKE_INSTALL_LIBDIR STREQUAL "lib")
 752         set(CMAKE_BUILD_WITH_INSTALL_RPATH TRUE)
 753         set(CMAKE_BUILD_WITH_INSTALL_NAME_DIR TRUE)
 754     endif()
 755     # Set the RPATH as relative to the executable location to make the
 756     # binaries relocatable.
 757     if(CMAKE_SYSTEM_NAME STREQUAL "Darwin") #Assume OS X >=10.5
 758         set(CMAKE_INSTALL_RPATH "@loader_path/../${CMAKE_INSTALL_LIBDIR}")
 759         set(CMAKE_INSTALL_NAME_DIR ${CMAKE_INSTALL_RPATH})
 760     else()
 761         set(CMAKE_INSTALL_RPATH "\$ORIGIN/../${CMAKE_INSTALL_LIBDIR}")
 762     endif()
 763     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 764     set(CMAKE_MACOSX_RPATH 1)
 765 endif()
 766
 767 #COPYING file: Only necessary for binary distributions.
 768 #Simpler to always install.
 769 install(FILES COPYING DESTINATION ${GMX_INSTALL_GMXDATADIR} COMPONENT data)
 770
 771 if (GMX_BUILD_FOR_COVERAGE)
 772     # Code heavy with asserts makes conditional coverage close to useless metric,
 773     # as by design most of the false branches are impossible to trigger in
 774     # correctly functioning code.  And the benefit of testing those that could
 775     # be triggered by using an API against its specification isn't usually
 776     # worth the effort.
 777     add_definitions(-DNDEBUG -DGMX_DISABLE_ASSERTS)
 778 endif()
 779
 780 if (BUILD_TESTING)
 781     include(tests/CheckTarget.cmake)
 782 endif()
 783
 784 # TODO: Determine control flow and defaults for package installation and testing use cases.
 785 # Ref: https://gitlab.com/gromacs/gromacs/-/issues/2896
 786 option(GMX_PYTHON_PACKAGE "Configure gmxapi Python package" OFF)
 787 mark_as_advanced(GMX_PYTHON_PACKAGE)
 788
 789 find_package(ImageMagick QUIET COMPONENTS convert)
 790 include(gmxTestImageMagick)
 791 GMX_TEST_IMAGEMAGICK(IMAGE_CONVERT_POSSIBLE)
 792 # TODO: Resolve circular dependency between docs, gromacs, and python_packaging
 793 add_subdirectory(docs)
 794 add_subdirectory(share)
 795 add_subdirectory(scripts)
 796 add_subdirectory(api)
 797 add_subdirectory(src)
 798
 799 if (BUILD_TESTING)
 800     add_subdirectory(tests)
 801 endif()
 802
 803 if(GMX_PYTHON_PACKAGE)
 804     add_subdirectory(python_packaging)
 805 endif()
 806
 807 gmx_cpack_write_config()
 808
 809 #######################
 810 ## uninstall target
 811 #######################
 812 CONFIGURE_FILE(   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 813                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
 814                   IMMEDIATE @ONLY)
 815 ###########################
 816 ADD_CUSTOM_TARGET(uninstall
 817                   "${CMAKE_COMMAND}" -P
 818                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
 819 ###########################
 820 set_directory_properties(PROPERTIES
 821             ADDITIONAL_MAKE_CLEAN_FILES "install_manifest.txt")