CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.6)
   2
   3 project(Gromacs)
   4 include(Dart)
   5 mark_as_advanced(DART_ROOT)
   6
   7 # PROJECT_VERSION should have the following structure:
   8 # VERSION-dev[-SUFFIX] where the VERSION should have the for: vMajor.vMinor.vPatch
   9 #
  10 # The "-dev" suffix is important to keep because it makes possible to distinguish
  11 # between a build from official release and a build from git release branch on a
  12 # machine with no git.
  13 #
  14 # NOTE: when releasing the "-dev" suffix needs to be stripped off!
  15 set(PROJECT_VERSION "4.5.3-dev")
  16 set(CUSTOM_VERSION_STRING ""
  17     CACHE STRING "Custom version string (if empty, use hard-coded default)")
  18 mark_as_advanced(CUSTOM_VERSION_STRING)
  19 if (CUSTOM_VERSION_STRING)
  20     set(PROJECT_VERSION ${CUSTOM_VERSION_STRING})
  21 endif (CUSTOM_VERSION_STRING)
  22 set(SOVERSION 6)
  23 # It is a bit irritating, but this has to be set separately for now!
  24 SET(CPACK_PACKAGE_VERSION_MAJOR "4")
  25 SET(CPACK_PACKAGE_VERSION_MINOR "5")
  26 SET(CPACK_PACKAGE_VERSION_PATCH "3")
  27
  28
  29 # Cmake modules/macros are in a subdirectory to keep this file cleaner
  30 set(CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake)
  31
  32 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
  33 set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
  34 endif()
  35
  36 if(NOT CMAKE_BUILD_TYPE)
  37     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel." FORCE)
  38 endif(NOT CMAKE_BUILD_TYPE)
  39
  40 enable_language(C)
  41 enable_language(CXX)
  42
  43 set(CPACK_PACKAGE_VERSION ${PROJECT_VERSION})
  44 set(CPACK_PACKAGE_VENDOR "gromacs.org")
  45 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Gromacs - a toolkit for high-performance molecular simulation")
  46 set(CPACK_SET_DESTDIR "ON")
  47 set(CPACK_INCLUDE_TOPLEVEL_DIRECTORY 0)
  48 set(CPACK_RESOURCE_FILE_WELCOME "${CMAKE_SOURCE_DIR}/admin/InstallWelcome.txt")
  49 # Its GPL/LGPL, so they do not have to agree to a license for mere usage, but some installers require this...
  50 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_SOURCE_DIR}/admin/InstallLicense.txt")
  51 set(CPACK_RESOURCE_FILE_README "${CMAKE_SOURCE_DIR}/admin/InstallInfo.txt")
  52
  53 #must come after all cpack settings!
  54 include(CPack)
  55
  56
  57 ########################################################################
  58 # Fix stupid flags on MSVC
  59 ########################################################################
  60 SET(SHARED_LIBS_DEFAULT ON)
  61 IF(CMAKE_GENERATOR MATCHES "Visual Studio")
  62     STRING(REPLACE /MD /MT CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE})
  63     SET(CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE} CACHE STRING "" FORCE)
  64     STRING(REPLACE /MD /MT CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG})
  65     SET(CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG} CACHE STRING "" FORCE)
  66     SET(SHARED_LIBS_DEFAULT OFF)
  67 ENDIF(CMAKE_GENERATOR MATCHES "Visual Studio")
  68
  69 set(GMX_EXTRA_LIBRARIES)
  70
  71
  72
  73 ######################################################################
  74 # compiler tests
  75 # these need ot be done early (before further tests).
  76 #####################################################################
  77
  78 include(CheckCCompilerFlag)
  79 include(CheckCXXCompilerFlag)
  80
  81 include(gmxCFlags)
  82 gmx_c_flags()
  83
  84 ########################################################################
  85 # User input options                                                   #
  86 ########################################################################
  87 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" OFF)
  88 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
  89 option(GMX_THREADS    "Build a parallel (thread-based) version of GROMACS (cannot be combined with MPI yet)" ON)
  90 option(GMX_SOFTWARE_INVSQRT "Use GROMACS software 1/sqrt" ON)
  91 mark_as_advanced(GMX_SOFTWARE_INVSQRT)
  92 option(GMX_POWERPC_INVSQRT "Use PowerPC hardware 1/sqrt" OFF)
  93 mark_as_advanced(GMX_POWERPC_INVSQRT)
  94 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
  95 mark_as_advanced(GMX_FAHCORE)
  96 option(GMX_OPENMM "Accelerated execution on GPUs through the OpenMM library (rerun cmake after changing to see relevant options)" OFF)
  97 set(GMX_ACCELERATION "auto"
  98     CACHE STRING "Accelerated kernels. Pick one of: auto, none, SSE, BlueGene, Power6, ia64, altivec, fortran")
  99
 100 set(GMX_FFT_LIBRARY "fftw3"
 101     CACHE STRING "FFT library choices: fftw3,fftw2,mkl,fftpack[built-in]")
 102 option(GMX_DISABLE_FFTW_MEASURE
 103        "Do not optimize FFTW setups (not needed with SSE)" OFF)
 104 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 105 set(GMX_QMMM_PROGRAM "none"
 106     CACHE STRING "QM package choices: none,gaussian,mopac,gamess,orca")
 107 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 108 mark_as_advanced(GMX_BROKEN_CALLOC)
 109 option(BUILD_SHARED_LIBS "Enable shared libraries (can be problematic with MPI, Windows)" ${SHARED_LIBS_DEFAULT})
 110 option(GMX_MPI_IN_PLACE "Enable MPI_IN_PLACE for MPIs that have it defined" ON)
 111 mark_as_advanced(GMX_MPI_IN_PLACE)
 112 option(GMX_DLOPEN "Compile with dlopen, needed to read VMD supported file formats" ON)
 113 mark_as_advanced(GMX_DLOPEN)
 114
 115
 116 option(GMX_IA32_ASM "Add SSE assembly files for IA32" OFF)
 117 mark_as_advanced(GMX_IA32_ASM)
 118 option(GMX_X86_64_ASM "Add SSE assembly files for X86_64" OFF)
 119 mark_as_advanced(GMX_X86_64_ASM)
 120
 121 option(USE_VERSION_H "Generate development version string/information" ON)
 122 mark_as_advanced(USE_VERSION_H)
 123
 124 option(GMX_DEFAULT_SUFFIX "Use default suffixes for GROMACS binaries and libs (_d for double, _mpi for MPI; rerun cmake after changing to see relevant options)" ON)
 125
 126 if(UNIX AND NOT APPLE)
 127     option(GMX_PREFER_STATIC_LIBS "When finding libraries prefer \".a\" static archives (NOTE: this is enabled only for UNIX (excluding APPLE) platforms but it might not always work!" OFF)
 128     mark_as_advanced(GMX_PREFER_STATIC_LIBS)
 129 endif()
 130
 131 ########################################################################
 132 # Set up binary and library suffixing
 133 ########################################################################
 134 set(GMX_BINARY_SUFFIX "" CACHE STRING "Suffix for GROMACS binaries (default: _d for double, _mpi for MPI, _mpi_d for MPI and double).")
 135 set(GMX_LIBS_SUFFIX ""
 136   CACHE STRING "Suffix for GROMACS libs (default: _d for double, _mpi for MPI, _mpi_d for MPI and double).")
 137 if (GMX_DEFAULT_SUFFIX)
 138   set(GMX_BINARY_SUFFIX "")
 139   set(GMX_LIBS_SUFFIX "")
 140   if (GMX_MPI)
 141     set(GMX_BINARY_SUFFIX "_mpi")
 142     set(GMX_LIBS_SUFFIX "_mpi")
 143   endif(GMX_MPI)
 144   if (GMX_DOUBLE)
 145     set (GMX_BINARY_SUFFIX "${GMX_BINARY_SUFFIX}_d")
 146     set (GMX_LIBS_SUFFIX "${GMX_LIBS_SUFFIX}_d")
 147   endif(GMX_DOUBLE)
 148   if (GMX_OPENMM)
 149     set (GMX_BINARY_SUFFIX "-gpu")
 150     set (GMX_LIBS_SUFFIX "_gpu")
 151   endif(GMX_OPENMM)
 152   mark_as_advanced(FORCE GMX_BINARY_SUFFIX GMX_LIBS_SUFFIX)
 153   message(STATUS "Using default binary suffix: \"${GMX_BINARY_SUFFIX}\"")
 154   message(STATUS "Using default library suffix: \"${GMX_LIBS_SUFFIX}\"")
 155 else(GMX_DEFAULT_SUFFIX)
 156   mark_as_advanced(CLEAR GMX_BINARY_SUFFIX GMX_LIBS_SUFFIX)
 157   message(STATUS "Using manually set binary suffix: \"${GMX_BINARY_SUFFIX}\"")
 158   message(STATUS "Using manually set library suffix: \"${GMX_LIBS_SUFFIX}\"")
 159 endif(GMX_DEFAULT_SUFFIX)
 160
 161 set(PKG_CFLAGS "")
 162 if(GMX_DOUBLE)
 163     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_DOUBLE")
 164 endif(GMX_DOUBLE)
 165 if(GMX_SOFTWARE_INVSQRT)
 166   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_SOFTWARE_INVSQRT")
 167 endif(GMX_SOFTWARE_INVSQRT)
 168 if(GMX_POWERPC_INVSQRT)
 169   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_POWERPC_INVSQRT")
 170 endif(GMX_POWERPC_INVSQRT)
 171
 172 ########################################################################
 173 #Process MPI settings
 174 ########################################################################
 175 include(CheckCSourceCompiles) # for gmxTestMPI_IN_PLACE
 176 if(GMX_MPI)
 177         MESSAGE(WARNING "
 178             There are known problems with some MPI implementations:
 179                      OpenMPI version < 1.4.1
 180                      MVAPICH2 version <= 1.4.1                               *")
 181     if(GMX_THREADS)
 182         #message(FATAL_ERROR "Thread-based parallelization conflicts with MPI.")
 183         set(GMX_THREADS OFF CACHE BOOL
 184             "Thread-based parallelization conflicts with MPI." FORCE)
 185     endif(GMX_THREADS)
 186     find_package(MPI)
 187     if(MPI_FOUND)
 188         set(GROMACS_C_FLAGS ${GROMACS_FLAGS} ${MPI_COMPILE_FLAGS})
 189         set(GROMACS_LINKER_FLAGS ${GROMACS_LINKER_FLAGS} ${MPI_LINK_FLAGS})
 190
 191         include_directories(${MPI_INCLUDE_PATH})
 192         list(APPEND GMX_EXTRA_LIBRARIES ${MPI_LIBRARIES})
 193         add_definitions( -DMPI ) #for FAHCORE
 194         include(gmxTestMPI_IN_PLACE)
 195         if (GMX_MPI_IN_PLACE)
 196             gmx_test_mpi_in_place(MPI_IN_PLACE_EXISTS)
 197         endif (GMX_MPI_IN_PLACE)
 198     else(MPI_FOUND)
 199         message(FATAL_ERROR "MPI support requested, but no MPI compiler found.")
 200     endif(MPI_FOUND)
 201     include(gmxTestCatamount)
 202     gmx_test_catamount(GMX_CRAY_XT3)
 203     if(GMX_CRAY_XT3)
 204         set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_CRAY_XT3")
 205         set(GMX_NO_SYSTEM 1)
 206         set(GMX_NO_NICE 1)
 207     endif(GMX_CRAY_XT3)
 208     set(GMX_LIB_MPI 1)
 209     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_LIB_MPI")
 210 endif(GMX_MPI)
 211
 212
 213 #######################################################################
 214 # Check for options incompatible with OpenMM build                    #
 215 #######################################################################
 216 if(GMX_OPENMM)
 217     cmake_minimum_required(VERSION 2.6.4)
 218     # we'll use the built-in fft to avoid unnecessary dependencies
 219     string(TOUPPER ${GMX_FFT_LIBRARY} GMX_FFT_LIBRARY)
 220     if(NOT ${GMX_FFT_LIBRARY} STREQUAL "FFTPACK")
 221         message(STATUS "No external FFT libraries needed for the OpenMM build, switching to fftpack!")
 222         set(GMX_FFT_LIBRARY "fftpack" CACHE STRING
 223                 "No external FFT libraries needed for the OpenMM build, switching to  fftpack!" FORCE)
 224     endif()
 225     if(GMX_MPI)
 226         message(FATAL_ERROR "The OpenMM build is not compatible with MPI!")
 227     endif(GMX_MPI)
 228     if(GMX_THREADS)
 229         message(STATUS "Threads are  not compatible with OpenMM build, disabled!")
 230         set(GMX_THREADS OFF CACHE BOOL
 231                 "Threads are not compatible with OpenMM build, disabled!" FORCE)
 232     endif(GMX_THREADS)
 233     if(GMX_SOFTWARE_INVSQRT)
 234         set(GMX_SOFTWARE_INVSQRT OFF CACHE STRING
 235                 "The OpenMM build does not need GROMACS software 1/sqrt!" FORCE)
 236     endif(GMX_SOFTWARE_INVSQRT)
 237     string(TOUPPER ${GMX_ACCELERATION} GMX_ACCELERATION)
 238     if(NOT GMX_ACCELERATION STREQUAL "NONE")
 239         message(STATUS "Switching off CPU-based acceleration, the OpenMM build does not support/need any!")
 240         set(GMX_ACCELERATION "none" CACHE STRING
 241                 "Switching off CPU-based acceleration, the OpenMM build does not support/need any!" FORCE)
 242     endif()
 243     if(GMX_FAHCORE)
 244         message(FATAL_ERROR "The OpenMM build does not support FAH build!")
 245     endif(GMX_FAHCORE)
 246     if(GMX_DOUBLE)
 247         message(FATAL_ERROR  "The OpenMM-build does not support double precision calculations!")
 248     endif()
 249     # mark as advanced the unused variables
 250     mark_as_advanced(FORCE GMX_ACCELERATION GMX_MPI GMX_FFT_LIBRARY
 251         GMX_QMMM_PROGRAM GMX_THREADS GMX_DOUBLE)
 252 else(GMX_OPENMM)
 253      mark_as_advanced(CLEAR GMX_ACCELERATION GMX_MPI GMX_FFT_LIBRARY
 254         GMX_QMMM_PROGRAM GMX_THREADS GMX_DOUBLE)
 255 endif(GMX_OPENMM)
 256
 257
 258 ########################################################################
 259 # Basic system tests (standard libraries, headers, functions, types)   #
 260 ########################################################################
 261 include(CheckIncludeFiles)
 262 check_include_files(string.h     HAVE_STRING_H)
 263 check_include_files(math.h       HAVE_MATH_H)
 264 check_include_files(limits.h     HAVE_LIMITS_H)
 265 check_include_files(memory.h     HAVE_MEMORY_H)
 266 check_include_files(unistd.h     HAVE_UNISTD_H)
 267 check_include_files(pwd.h        HAVE_PWD_H)
 268 check_include_files(stdint.h     HAVE_STDINT_H)
 269 check_include_files(stdlib.h     HAVE_STDLIB_H)
 270 check_include_files(pthread.h    HAVE_PTHREAD_H)
 271 check_include_files(dirent.h     HAVE_DIRENT_H)
 272 check_include_files(inttypes.h   HAVE_INTTYPES_H)
 273 check_include_files(regex.h      HAVE_REGEX_H)
 274 check_include_files(sys/types.h  HAVE_SYS_TYPES_H)
 275 check_include_files(sys/stat.h   HAVE_SYS_STAT_H)
 276 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 277 check_include_files(rpc/rpc.h    HAVE_RPC_RPC_H)
 278 check_include_files("rpc/rpc.h;rpc/xdr.h"    HAVE_RPC_XDR_H)
 279 # SSE support
 280 check_include_files(xmmintrin.h  HAVE_XMMINTRIN_H)
 281 check_include_files(emmintrin.h  HAVE_EMMINTRIN_H)
 282 check_include_files(pmmintrin.h  HAVE_PMMINTRIN_H)
 283 check_include_files(smmintrin.h  HAVE_SMMINTRIN_H)
 284 check_include_files(io.h                 HAVE_IO_H)
 285
 286
 287 include(CheckFunctionExists)
 288 check_function_exists(strcasecmp        HAVE_STRCASECMP)
 289 check_function_exists(strdup            HAVE_STRDUP)
 290 check_function_exists(vprintf           HAVE_VPRINTF)
 291 check_function_exists(memcmp            HAVE_MEMCMP)
 292 check_function_exists(posix_memalign    HAVE_POSIX_MEMALIGN)
 293 check_function_exists(memalign          HAVE_MEMALIGN)
 294 check_function_exists(_aligned_malloc   HAVE__ALIGNED_MALLOC)
 295 check_function_exists(gettimeofday      HAVE_GETTIMEOFDAY)
 296 check_function_exists(isnan             HAVE_ISNAN)
 297 check_function_exists(_isnan            HAVE__ISNAN)
 298 check_function_exists(isfinite          HAVE_ISFINITE)
 299 check_function_exists(_isfinite         HAVE__ISFINITE)
 300 check_function_exists(fsync             HAVE_FSYNC)
 301 check_function_exists(_fileno           HAVE__FILENO)
 302 check_function_exists(fileno            HAVE_FILENO)
 303 check_function_exists(_commit           HAVE__COMMIT)
 304
 305 include(CheckLibraryExists)
 306 check_library_exists(m sqrt "" HAVE_LIBM)
 307 check_library_exists(m cbrt "" HAVE_CBRT)
 308
 309
 310 include(CheckTypeSize)
 311
 312 check_type_size("bool"          SIZEOF_BOOL) # will also set HAVE_BOOL
 313 check_type_size("int"           SIZEOF_INT)
 314 check_type_size("long int"      SIZEOF_LONG_INT)
 315 check_type_size("long long int" SIZEOF_LONG_LONG_INT)
 316 check_type_size("off_t"         SIZEOF_OFF_T)
 317 check_type_size("void *"        SIZEOF_VOIDP)
 318
 319 if (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 320     set(GMX_64_BIT TRUE)
 321 else (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 322     set(GMX_64_BIT FALSE)
 323 endif (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 324
 325 # Check for some basic types that we *need*, so set these to int if they are not present
 326 check_type_size(uid_t uid_t)
 327 if(NOT uid_t)
 328   set(uid_t int)
 329 else(NOT uid_t)
 330   set(uid_t 0)
 331 endif(NOT uid_t)
 332
 333 check_type_size(gid_t gid_t)
 334 if(NOT gid_t)
 335   set(gid_t 1)
 336 else(NOT gid_t)
 337   set(gid_t 0)
 338 endif(NOT gid_t)
 339
 340 check_type_size(size_t size_t)
 341 if(NOT size_t)
 342   set(size_t int)
 343 else(NOT size_t)
 344   set(size_t 0)
 345 endif(NOT size_t)
 346
 347 check_type_size(off_t off_t)
 348 if(NOT off_t)
 349   set(off_t int)
 350 else(NOT off_t)
 351   set(off_t 0)
 352 endif(NOT off_t)
 353
 354 include(TestBigEndian)
 355 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 356
 357
 358
 359
 360 ########################################################################
 361 # Find external packages                                               #
 362 ########################################################################
 363 if(UNIX AND NOT APPLE)
 364     if(GMX_PREFER_STATIC_LIBS)
 365         SET(CMAKE_FIND_LIBRARY_SUFFIXES .a ${CMAKE_FIND_LIBRARY_SUFFIXES})
 366         if(BUILD_SHARED_LIBS)
 367             message(WARNING "Static libraries requested, the GROMACS libraries will also be build static (BUILD_SHARED_LIBS=OFF)")
 368             set(BUILD_SHARED_LIBS OFF CACHE BOOL "Enable shared libraries (can be problematic with MPI, Windows)" FORCE)
 369         endif()
 370     endif()
 371 endif()
 372
 373 option(GMX_XML "Use libxml2 to parse xml files" ON)
 374 if (GMX_XML)
 375   find_package(LibXml2)
 376   set(PKG_XML "")
 377   if(LIBXML2_FOUND)
 378     include_directories(${LIBXML2_INCLUDE_DIR})
 379     set(PKG_XML libxml-2.0)
 380     set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 381     set(HAVE_LIBXML2 1)
 382   endif(LIBXML2_FOUND)
 383 endif(GMX_XML)
 384
 385 option(GMX_GSL "Add support for gsl" OFF)
 386 if (GMX_GSL)
 387   find_package(gsl)
 388   set(PKG_GSL "")
 389   if(GSL_FOUND)
 390     include_directories(${GSL_INCLUDE_DIR})
 391     set(PKG_GSL gsl)
 392     set(HAVE_LIBGSL 1)
 393   endif(GSL_FOUND)
 394 endif (GMX_GSL)
 395
 396 option(GMX_X11 "Use X window system" OFF)
 397 if (GMX_X11)
 398         find_package(X11)
 399         # X11 includes/libraries are only set in the ngmx subdirectory!
 400         if(X11_FOUND)
 401         set(HAVE_X11 1)
 402         endif(X11_FOUND)
 403 endif(GMX_X11)
 404
 405 if(GMX_THREADS)
 406     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_THREADS")
 407     include(ThreadMPI)
 408     set(THREAD_MPI_LIB thread_mpi)
 409     set(GMX_MPI 1)
 410     string(TOUPPER ${GMX_FFT_LIBRARY} ${GMX_FFT_LIBRARY})
 411     if(${GMX_FFT_LIBRARY} STREQUAL "FFTW2")
 412         message(FATAL_ERROR "FFTW2 can't be used with threads. Try fftw3 or mkl.")
 413     endif()
 414 endif(GMX_THREADS)
 415
 416 if(GMX_OPENMM)
 417     set(CUDA_BUILD_EMULATION OFF)
 418     find_package(CUDA 3.1 REQUIRED)
 419     add_definitions(-DGMX_OPENMM)
 420     if(CMAKE_BUILD_TYPE STREQUAL "DEBUG")
 421         set(CUDA_VERBOSE_BUILD ON)
 422     endif()
 423     find_package(OpenMM)
 424 endif(GMX_OPENMM)
 425
 426 if(APPLE)
 427    find_library(ACCELERATE_FRAMEWORK Accelerate)
 428    list(APPEND GMX_EXTRA_LIBRARIES ${ACCELERATE_FRAMEWORK})
 429 endif(APPLE)
 430
 431 # only bother with finding git and using version.h if the source is a git repo
 432 if(EXISTS "${CMAKE_SOURCE_DIR}/.git")
 433     if(USE_VERSION_H)
 434         # We need at least git v1.5.1 be able to parse git's date output. If not
 435         # fund or the version is too small, we can't generate version information.
 436         find_package(Git 1.5.1)
 437         # this should at some point become VERSION_LESS
 438         if(NOT Git_FOUND OR Git_VERSION STRLESS "1.5.1")
 439             message("No compatible git version found, won't be able to generate proper development version information.")
 440             set(USE_VERSION_H OFF)
 441         endif()
 442     endif()
 443 else()
 444     set(USE_VERSION_H OFF)
 445 endif()
 446
 447 if (GMX_DLOPEN)
 448     list(APPEND GMX_EXTRA_LIBRARIES ${CMAKE_DL_LIBS})
 449 endif (GMX_DLOPEN)
 450
 451 find_package(GTest)
 452 find_package(GMock)
 453 find_package(Doxygen)
 454
 455 ########################################################################
 456 # Generate development version info for cache
 457 ########################################################################
 458 # set(GEN_VERSION_INFO_INTERNAL "ON")
 459 # include(gmxGenerateVersionString)
 460
 461 ########################################################################
 462 # Our own GROMACS tests
 463 ########################################################################
 464
 465 add_definitions( -DHAVE_CONFIG_H )
 466 include_directories(${CMAKE_SOURCE_DIR}/src)
 467 # Required for config.h, maybe should only be set in src/CMakeLists.txt
 468 include_directories(${CMAKE_BINARY_DIR}/src)
 469 # Required for now to make old code compile
 470 include_directories(${CMAKE_SOURCE_DIR}/src/gromacs/legacyheaders)
 471
 472 include(gmxCheckBuildUserTime)
 473 gmx_check_build_user_time(BUILD_TIME BUILD_USER BUILD_MACHINE)
 474
 475 include(gmxTestFloatFormat)
 476 gmx_test_float_format(GMX_FLOAT_FORMAT_IEEE754
 477                       GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER
 478                       GMX_IEEE754_BIG_ENDIAN_WORD_ORDER)
 479
 480 include(gmxTestLargeFiles)
 481 gmx_test_large_files(GMX_LARGEFILES)
 482 check_function_exists(fseeko     HAVE_FSEEKO)
 483
 484 include(gmxTestSignal)
 485 gmx_test_retsigtype(RETSIGTYPE)
 486 gmx_test_sigusr1(HAVE_SIGUSR1)
 487
 488 include(gmxTestInline)
 489 gmx_test_inline(INLINE_KEYWORD)
 490
 491 include(gmxTestRestrict)
 492 gmx_test_inline(RESTRICT_KEYWORD)
 493
 494 include(gmxTestPipes)
 495 gmx_test_pipes(HAVE_PIPES)
 496
 497 include(gmxTestInlineASM)
 498 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 499 gmx_test_inline_asm_msvc_x86(GMX_X86_MSVC_INLINE_ASM)
 500
 501 # turn on SSE if supported with reasonable defaults.
 502 if (${GMX_ACCELERATION} STREQUAL "auto" AND NOT GMX_OPENMM)
 503   if(CMAKE_SYSTEM_PROCESSOR MATCHES "^(i.86|x86|x64|x86_64|AMD64|amd64)")
 504
 505     set(GMX_ACCELERATION "SSE" CACHE STRING "Accelerated kernels. Pick one of: auto, none, SSE, BlueGene, Power6, ia64, altivec, fortran" FORCE)
 506
 507     if (GMX_64_BIT)
 508       set(GMX_X86_64_ASM ON CACHE BOOL "Add SSE assembly files for x86_64" FORCE)
 509     else (GMX_64_BIT)
 510       set(GMX_IA32_ASM ON CACHE BOOL "Add SSE assembly files for i386" FORCE)
 511     endif (GMX_64_BIT)
 512
 513     # Determine the assembler/compiler to use
 514   else()
 515     set(GMX_ACCELERATION "none" CACHE STRING "Accelerated kernels. Pick one of: auto, none, SSE, BlueGene, Power6, ia64, altivec, fortran" FORCE)
 516   endif()
 517 endif (${GMX_ACCELERATION} STREQUAL "auto" AND NOT GMX_OPENMM)
 518
 519 include(gmxTestXDR)
 520 gmx_test_xdr(GMX_SYSTEM_XDR)
 521 if(NOT GMX_SYSTEM_XDR)
 522     set(GMX_INTERNAL_XDR 1)
 523     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_INTERNAL_XDR")
 524 endif(NOT GMX_SYSTEM_XDR)
 525
 526 # Process nonbonded accelerated kernels settings
 527 string(TOUPPER ${GMX_ACCELERATION} ${GMX_ACCELERATION})
 528 if(${GMX_ACCELERATION} STREQUAL "NONE")
 529   # nothing to do
 530 elseif(${GMX_ACCELERATION} STREQUAL "SSE")
 531
 532     if(CMAKE_GENERATOR MATCHES "Visual Studio")
 533       option(GMX_ASM_USEASM-NASM "Use Nasm for assembly instead of compiler (necessary on windows)" ON)
 534     else()
 535       option(GMX_ASM_USEASM-NASM "Use Nasm for assembly instead of compiler (necessary on windows)" OFF)
 536     endif()
 537         mark_as_advanced(GMX_ASM_USEASM-NASM)
 538
 539     if (NOT GMX_64_BIT)
 540         # for 32-bit compiles, we might need to turn on sse
 541         CHECK_C_COMPILER_FLAG("-msse2" XFLAGS_SSE)
 542         if (XFLAGS_SSE)
 543             set(GROMACS_C_FLAGS "-msse2 ${GROMACS_C_FLAGS}")
 544         endif (XFLAGS_SSE)
 545         CHECK_CXX_COMPILER_FLAG("-msse2" XXFLAGS_SSE)
 546         if (XXFLAGS_SSE)
 547             set(GROMACS_CXX_FLAGS "-msse2 ${GROMACS_CXX_FLAGS}")
 548         endif (XXFLAGS_SSE)
 549     endif (NOT GMX_64_BIT)
 550
 551     if(GMX_IA32_ASM)
 552       if(GMX_DOUBLE)
 553         set(GMX_IA32_SSE2 1)
 554       else()
 555        set(GMX_IA32_SSE 1)
 556       endif()
 557     elseif(GMX_X86_64_ASM)
 558       if(GMX_DOUBLE)
 559        set(GMX_X86_64_SSE2 1)
 560       else()
 561         set(GMX_X86_64_SSE 1)
 562       endif()
 563     endif()
 564
 565 #    if(HAVE_PMMINTRIN_H)
 566 #        set(GMX_SSE3 1)
 567 #    endif(HAVE_PMMINTRIN_H)
 568 #    if(HAVE_SMMINTRIN_H)
 569 #        set(GMX_SSE4_1 1)
 570 #    endif(HAVE_SMMINTRIN_H)
 571
 572 elseif(${GMX_ACCELERATION} STREQUAL "FORTRAN")
 573     set(GMX_FORTRAN 1)
 574     #these are switch on by default sometimes
 575     set(GMX_IA32_ASM 0)
 576     set(GMX_GMX_X86_64_ASM 0)
 577 elseif(${GMX_ACCELERATION} STREQUAL "BLUEGENE")
 578 # GMX_ACCELERATION=BlueGene should be set in the Toolchain-BlueGene?-???.cmake file
 579     message(STATUS "Configuring for BlueGene")
 580     set(GMX_BLUEGENE 1)
 581     if (${CMAKE_SYSTEM_NAME} STREQUAL "BlueGeneL")
 582         set(SHARED_LIBS_DEFAULT OFF CACHE BOOL "Shared libraries not compatible with BlueGene/L, disabled!" FORCE)
 583         set(BUILD_SHARED_LIBS OFF CACHE BOOL "Shared libraries not compatible with BlueGene/L, disabled!" FORCE)
 584     endif (${CMAKE_SYSTEM_NAME} STREQUAL "BlueGeneL")
 585     set(GMX_SOFTWARE_INVSQRT OFF CACHE BOOL "Do not use software reciprocal square root on BlueGene" FORCE)
 586     set(GMX_POWERPC_INVSQRT ON CACHE BOOL "Use hardware reciprocal square root on BlueGene" FORCE)
 587     set(GMX_X11 OFF CACHE BOOL "X11 not compatible with BlueGene, disabled!" FORCE)
 588     set(GMX_THREADS OFF CACHE BOOL "Threads not compatible with BlueGene, disabled!" FORCE)
 589     set(GMX_MPI ON CACHE BOOL "Use MPI on BlueGene" FORCE)
 590     set(GMX_EXTERNAL_BLAS TRUE CACHE BOOL "Use MASSV for BLAS on BlueGene" FORCE)
 591     set(GMX_EXTERNAL_LAPACK TRUE CACHE BOOL "Use MASSV for LAPACK on BlueGene" FORCE)
 592     list(APPEND GMX_EXTRA_LIBRARIES massv)
 593 elseif(${GMX_ACCELERATION} STREQUAL "POWER6")
 594     set(GMX_POWER6 1)
 595     set(GMX_SOFTWARE_INVSQRT OFF CACHE BOOL "Do not use software reciprocal square root on Power6" FORCE)
 596     set(GMX_POWERPC_INVSQRT ON CACHE BOOL "Use hardware reciprocal square root on Power6" FORCE)
 597 elseif(${GMX_ACCELERATION} STREQUAL "IA64")
 598     set(GMX_IA64_ASM 1)
 599     set(DISABLE_WATERWATER_NLIST 1)
 600     set(DISABLE_WATER_NLIST 1)
 601 elseif(${GMX_ACCELERATION} STREQUAL "ALTIVEC")
 602     check_include_files(altivec.h HAVE_ALTIVEC_H)
 603     if(HAVE_ALTIVEC_H)
 604         set(GMX_PPC_ALTIVEC 1)
 605     endif(HAVE_ALTIVEC_H)
 606 else(${GMX_ACCELERATION} STREQUAL "NONE")
 607     MESSAGE(FATAL_ERROR "Unrecognized option for accelerated kernels: ${GMX_ACCELERATION}. Pick one of auto, none, SSE, Fortran, BlueGene, Power6, ia64, altivec")
 608 endif(${GMX_ACCELERATION} STREQUAL "NONE")
 609
 610 if(GMX_FORTRAN OR GMX_POWER6)
 611     if (GMX_THREADS)
 612         message(FATAL_ERROR "FORTRAN/POWER6 is incompatible with threads and only provides a speed-up on certain IBM compilers. Disable FORTRAN (or threads if you really want to use FORTRAN kernels).")
 613     endif(GMX_THREADS)
 614     enable_language(Fortran)
 615     include(FortranCInterface)
 616     discover_fortran_mangling(prefix isupper suffix extra_under_score found)
 617     if(extra_under_score)
 618         set(extrasuffix "_")
 619     endif(extra_under_score)
 620     if(prefix)
 621       set(prefix "${prefix} ##")
 622     endif(prefix)
 623
 624     if(isupper)
 625         set(F77_FUNCDEF   "${prefix} NAME ## ${suffix}")
 626         set(F77_FUNCDEF_  "${prefix} NAME ## ${suffix}${extrasuffix}")
 627     else(isupper)
 628         set(F77_FUNCDEF   "${prefix} name ## ${suffix}")
 629         set(F77_FUNCDEF_  "${prefix} name ## ${suffix}${extrasuffix}")
 630     endif(isupper)
 631 else(GMX_FORTRAN OR GMX_POWER6)
 632         set(F77_FUNCDEF   "name ## _")
 633         set(F77_FUNCDEF_  "name ## _")
 634 endif(GMX_FORTRAN OR GMX_POWER6)
 635
 636 # Process QM/MM Settings
 637 string(TOUPPER ${GMX_QMMM_PROGRAM} ${GMX_QMMM_PROGRAM})
 638 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 639     set(GMX_QMMM_GAUSSIAN 1)
 640 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 641     set(GMX_QMMM_MOPAC 1)
 642 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 643     set(GMX_QMMM_GAMESS 1)
 644 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 645     set(GMX_QMMM_ORCA 1)
 646 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 647     # nothing to do
 648 else(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 649     MESSAGE(FATAL_ERROR "Invalid QM/MM program option: ${GMX_QMMM_PROGRAM}. Choose one of: Gaussian, Mopac, Gamess, Orca, None")
 650 endif(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 651
 652 # Process FFT library settings - if not OpenMM build
 653 string(TOUPPER ${GMX_FFT_LIBRARY} ${GMX_FFT_LIBRARY})
 654 set(PKG_FFT "")
 655 set(PKG_FFT_LIBS "")
 656 if(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 657 #    MESSAGE(STATUS "Using external FFT library - fftw3")
 658     if(GMX_DOUBLE)
 659         find_package(FFTW3 REQUIRED)
 660                 include_directories(${FFTW3_INCLUDE_DIR})
 661         set(FFT_LIBRARIES ${FFTW3_LIBRARIES})
 662         set(PKG_FFT "fftw3")
 663     else(GMX_DOUBLE)
 664         find_package(FFTW3F REQUIRED)
 665         include_directories(${FFTW3F_INCLUDE_DIR})
 666         set(FFT_LIBRARIES ${FFTW3F_LIBRARIES})
 667         set(PKG_FFT "fftw3f")
 668     endif(GMX_DOUBLE)
 669
 670     if(NOT FFTW3_FOUND AND NOT FFTW3F_FOUND)
 671         MESSAGE(FATAL_ERROR "Cannot find fftw3 (with correct precision). Fix it, choose another FFT library, or use the Gromacs built-in fftpack (slower)!")
 672     endif(NOT FFTW3_FOUND AND NOT FFTW3F_FOUND)
 673
 674     set(GMX_FFT_FFTW3 1)
 675
 676 elseif(${GMX_FFT_LIBRARY} STREQUAL "FFTW2")
 677 #    MESSAGE(STATUS "Using external FFT library - fftw2")
 678     if(GMX_DOUBLE)
 679         find_package(FFTW2 REQUIRED)
 680     else(GMX_DOUBLE)
 681         find_package(FFTW2F REQUIRED)
 682     endif(GMX_DOUBLE)
 683
 684     if(NOT FFTW2_FOUND)
 685            MESSAGE(FATAL_ERROR "Cannot find fftw2 (with correct precision). Fix it, choose another FFT library, or use the Gromacs built-in fftpack (slower)!")
 686     endif(NOT FFTW2_FOUND)
 687     include_directories(${FFTW2_INCLUDE_DIR})
 688     set(FFT_LIBRARIES ${FFTW2_LIBRARIES})
 689     set(PKG_FFT_LIBS ${FFTW2_LIBRARIES})
 690
 691     if("${FFTW2_LIBRARIES}" MATCHES "dfftw")
 692         set(FFTW2_NAME_DFFTW 1)
 693     elseif("${FFTW2_LIBRARIES}" MATCHES "sfftw")
 694         set(FFTW2_NAME_SFFTW 1)
 695     else("${FFTW2_LIBRARIES}" MATCHES "dfftw")
 696         set(FFTW2_NAME_FFTW 1)
 697     endif("${FFTW2_LIBRARIES}" MATCHES "dfftw")
 698
 699     set(GMX_FFT_FFTW2 1)
 700 elseif(${GMX_FFT_LIBRARY} STREQUAL "MKL")
 701 #    MESSAGE(STATUS "Using external FFT library - Intel MKL")
 702     find_package(MKL REQUIRED)
 703     include_directories(${MKL_INCLUDE_DIR})
 704     set(FFT_LIBRARIES ${MKL_LIBRARIES})
 705     set(PKG_FFT_LIBS ${MKL_LIBRARIES})
 706
 707     set(GMX_FFT_MKL 1)
 708     set(HAVE_MKL 1)
 709
 710 #elseif(${GMX_FFT_LIBRARY} STREQUAL "ACML")
 711 #    MESSAGE(STATUS "Using external FFT library - AMD core math library")
 712 #    set(GMX_FFT_ACML 1)
 713 elseif(${GMX_FFT_LIBRARY} STREQUAL "FFTPACK")
 714     MESSAGE(STATUS "Using internal FFT library - fftpack")
 715     set(GMX_FFT_FFTPACK 1)
 716 else(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 717     MESSAGE(FATAL_ERROR "Invalid FFT library setting: ${GMX_FFT_LIBRARY}. Choose one of: fftw3, fftw2, mkl, acml, fftpack")
 718 endif(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 719
 720 # MKL has BLAS/LAPACK routines
 721 if(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 722   set(GMX_EXTERNAL_BLAS TRUE CACHE BOOL "Use external BLAS instead of built-in")
 723   set(GMX_EXTERNAL_LAPACK TRUE CACHE BOOL "Use external LAPACK instead of built-in")
 724 else(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 725   set(GMX_EXTERNAL_BLAS FALSE CACHE BOOL "Use external LAPACK instead of built-in")
 726   set(GMX_EXTERNAL_LAPACK FALSE CACHE BOOL "Use external LAPACK instead of built-in")
 727   if(GMX_EXTERNAL_BLAS)
 728     #FindBLAS needs Fortran
 729     enable_language(Fortran)
 730     find_package(BLAS REQUIRED)
 731     list(APPEND GMX_EXTRA_LIBRARIES ${BLAS_LIBRARIES})
 732   endif(GMX_EXTERNAL_BLAS)
 733   if(GMX_EXTERNAL_LAPACK)
 734     #FindLAPACK needs Fortran
 735     enable_language(Fortran)
 736     find_package(LAPACK REQUIRED)
 737     list(APPEND GMX_EXTRA_LIBRARIES ${LAPACK_LIBRARIES})
 738   endif(GMX_EXTERNAL_LAPACK)
 739 endif(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 740 mark_as_advanced(GMX_EXTERNAL_LAPACK)
 741 mark_as_advanced(GMX_EXTERNAL_BLAS)
 742
 743 # Math and thread libraries must often come after all others when linking...
 744 if(HAVE_LIBM)
 745     list(APPEND GMX_EXTRA_LIBRARIES m)
 746 endif(HAVE_LIBM)
 747
 748 if(GMX_FAHCORE)
 749   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 750       "Path to swindirect.h")
 751   include_directories(${COREWRAP_INCLUDE_DIR})
 752 endif(GMX_FAHCORE)
 753
 754 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 755 # these are set after everything else
 756 if (NOT DEFINED GROMACS_C_FLAGS_SET)
 757     set(GROMACS_C_FLAGS_SET true CACHE INTERNAL "Whether to reset the C flags"
 758         FORCE)
 759     set(CMAKE_C_FLAGS "${GROMACS_C_FLAGS} ${CMAKE_C_FLAGS}" CACHE STRING
 760         "Flags used by the compiler during all build types" FORCE)
 761     set(CMAKE_CXX_FLAGS "${GROMACS_CXX_FLAGS} ${CMAKE_CXX_FLAGS}" CACHE STRING
 762         "Flags used by the compiler during all build types" FORCE)
 763     set(CMAKE_EXE_LINKER_FLAGS
 764         "${GROMACS_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}"
 765         CACHE STRING "Linker flags" FORCE)
 766 endif (NOT DEFINED GROMACS_C_FLAGS_SET)
 767
 768 ########################################################################
 769 # Specify install locations and which subdirectories to process        #
 770 ########################################################################
 771 if ( DEFINED LIB )
 772     set(LIB_INSTALL_DIR "${CMAKE_INSTALL_PREFIX}/${LIB}")
 773 else()
 774     set(LIB_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/lib)
 775 endif()
 776 set(BIN_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/bin)
 777 set(DATA_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/gromacs)
 778 set(MAN_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/share/man)
 779 set(INCL_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/include)
 780
 781 set(GMXLIBDIR        ${DATA_INSTALL_DIR}/top)
 782
 783 ##################################################################
 784 # Shared library settings - Darwin uses INSTALL_NAME_DIR instead!
 785 ##################################################################
 786 if(NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin")
 787     set(CMAKE_SKIP_BUILD_RPATH  FALSE)
 788     set(CMAKE_BUILD_WITH_INSTALL_RPATH FALSE)
 789     set(CMAKE_INSTALL_RPATH "${LIB_INSTALL_DIR}")
 790     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 791 endif()
 792
 793 add_subdirectory(share)
 794 add_subdirectory(man)
 795 add_subdirectory(src)
 796 add_subdirectory(scripts)
 797
 798 #######################
 799 ## uninstall target
 800 #######################
 801     CONFIGURE_FILE(
 802                    "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 803                    "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
 804                    IMMEDIATE @ONLY)
 805 ###########################
 806 ADD_CUSTOM_TARGET(uninstall
 807                   "${CMAKE_COMMAND}" -P
 808                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
 809 ###########################
 810
 811 ########################################################################
 812 # Doxygen configuration
 813 ########################################################################
 814 if (DOXYGEN_FOUND)
 815     FILE(GLOB NB_KERNEL_DIRS src/gromacs/gmxlib/nonbonded/nb_kernel_*/)
 816     LIST(REMOVE_ITEM NB_KERNEL_DIRS
 817          ${CMAKE_SOURCE_DIR}/src/gromacs/gmxlib/nonbonded/nb_kernel_c)
 818     FOREACH(NB_KERNEL_DIR ${NB_KERNEL_DIRS})
 819         SET(NB_KERNEL_DIRS_TO_IGNORE_IN_DOXYGEN
 820             "${NB_KERNEL_DIRS_TO_IGNORE_IN_DOXYGEN} \\\n                         ${NB_KERNEL_DIR}")
 821     ENDFOREACH(NB_KERNEL_DIR)
 822     CONFIGURE_FILE(${CMAKE_SOURCE_DIR}/Doxyfile.cmakein
 823                    ${CMAKE_BINARY_DIR}/Doxyfile)
 824     CONFIGURE_FILE(${CMAKE_SOURCE_DIR}/Doxyfile-lib.cmakein
 825                    ${CMAKE_BINARY_DIR}/Doxyfile-lib)
 826     CONFIGURE_FILE(${CMAKE_SOURCE_DIR}/Doxyfile-user.cmakein
 827                    ${CMAKE_BINARY_DIR}/Doxyfile-user)
 828 endif (DOXYGEN_FOUND)
 829
 830
 831 ########################################################################
 832 # Tests                                                                #
 833 ########################################################################
 834
 835 include(CTest)
 836 mark_as_advanced(BUILD_TESTING)
 837 IF(BUILD_TESTING)
 838         enable_testing()
 839         add_subdirectory(tests)
 840 ENDIF()
 841