CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2009,2010,2011,2012,2013,2014, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 cmake_minimum_required(VERSION 2.8.8)
  36
  37 # CMake modules/macros are in a subdirectory to keep this file cleaner
  38 # This needs to be set before project() in order to pick up toolchain files
  39 list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake ${CMAKE_CURRENT_SOURCE_DIR}/cmake/Platform)
  40
  41 project(Gromacs)
  42
  43 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  44 set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  45 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
  46
  47 # PROJECT_VERSION should have the following structure:
  48 # VERSION-dev[-SUFFIX] where the VERSION should have the for: vMajor.vMinor.vPatch
  49 #
  50 # The "-dev" suffix is important to keep because it makes possible to distinguish
  51 # between a build from official release and a build from git release branch on a
  52 # machine with no git.
  53 #
  54 # NOTE: when releasing the "-dev" suffix needs to be stripped off!
  55 # REGRESSIONTEST_VERSION and REGRESSIONTEST_BRANCH should always be
  56 # defined.
  57 set(PROJECT_VERSION "5.1-dev")
  58 # If this is a released tarball, "-dev" will not be present in
  59 # PROJECT_VERSION, and REGRESSIONTEST_VERSION specifies the version
  60 # number of the regressiontest tarball against which the code tarball
  61 # can be tested. This will be the version of the last patch release.
  62 set(REGRESSIONTEST_VERSION "5.0-rc1")
  63 # If this is not a released tarball, "-dev" will be present in
  64 # PROJECT_VERSION, and REGRESSIONTEST_BRANCH specifies the name of the
  65 # gerrit.gromacs.org branch whose HEAD can test this code, *if* this
  66 # code contains all recent fixes from the corresponding code branch.
  67 set(REGRESSIONTEST_BRANCH "refs/heads/master")
  68
  69 set(CUSTOM_VERSION_STRING ""
  70     CACHE STRING "Custom version string (if empty, use hard-coded default)")
  71 mark_as_advanced(CUSTOM_VERSION_STRING)
  72 if (CUSTOM_VERSION_STRING)
  73     set(PROJECT_VERSION ${CUSTOM_VERSION_STRING})
  74 endif()
  75 set(LIBRARY_SOVERSION 0)
  76 set(LIBRARY_VERSION ${LIBRARY_SOVERSION}.0.0)
  77 # It is a bit irritating, but this has to be set separately for now!
  78 SET(CPACK_PACKAGE_VERSION_MAJOR "5")
  79 SET(CPACK_PACKAGE_VERSION_MINOR "1")
  80 #SET(CPACK_PACKAGE_VERSION_PATCH "0")
  81
  82 # The numerical gromacs version. It is 40600 for 4.6.0.
  83 # The #define GMX_VERSION in gromacs/version.h is set to this value.
  84 math(EXPR NUM_VERSION
  85     "${CPACK_PACKAGE_VERSION_MAJOR}*10000 + ${CPACK_PACKAGE_VERSION_MINOR}*100")
  86 if(CPACK_PACKAGE_VERSION_PATCH)
  87     math(EXPR NUM_VERSION
  88          "${NUM_VERSION} + ${CPACK_PACKAGE_VERSION_PATCH}")
  89 endif()
  90
  91 # The API version tracks the numerical Gromacs version (for now).
  92 # It is potentially different from the Gromacs version in the future, if
  93 # the programs/libraries diverge from the presumably more stable API.
  94 # The #define GMX_API_VERSION in version.h is set to this value to
  95 # provide backward compatibility of software written against the Gromacs API.
  96 set(API_VERSION ${NUM_VERSION})
  97
  98 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT AND UNIX)
  99     set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
 100 endif()
 101
 102 set(GMX_INSTALL_PREFIX "" CACHE STRING "Prefix gets appended to CMAKE_INSTALL_PREFIX. For cpack it sets the root folder of the archive.")
 103 mark_as_advanced(GMX_INSTALL_PREFIX)
 104
 105 include(gmxBuildTypeReference)
 106 include(gmxBuildTypeThreadSanitizer)
 107 include(gmxBuildTypeReleaseWithAssert)
 108
 109 if(NOT CMAKE_BUILD_TYPE)
 110     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel Reference RelWithAssert." FORCE)
 111     # There's no need to offer a user the choice of ThreadSanitizer
 112     # Set the possible values of build type for cmake-gui
 113     set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "Debug" "Release"
 114         "MinSizeRel" "RelWithDebInfo" "Reference" "RelWithAssert")
 115 endif()
 116 if(CMAKE_CONFIGURATION_TYPES)
 117     # Add appropriate GROMACS-specific build types for the Visual
 118     # Studio generator (Debug, Release, MinSizeRel and RelWithDebInfo
 119     # are already present by default).
 120     list(APPEND CMAKE_CONFIGURATION_TYPES "RelWithAssert" "Reference")
 121     list(REMOVE_DUPLICATES CMAKE_CONFIGURATION_TYPES)
 122     set(CMAKE_CONFIGURATION_TYPES "${CMAKE_CONFIGURATION_TYPES}" CACHE STRING
 123         "List of configuration types"
 124         FORCE)
 125 endif()
 126 set(build_types_with_explicit_flags RELEASE DEBUG RELWITHDEBUGINFO RELWITHASSERT MINSIZEREL)
 127
 128 enable_language(C)
 129 enable_language(CXX)
 130
 131 set(CPACK_PACKAGE_VERSION ${PROJECT_VERSION})
 132 set(CPACK_PACKAGE_VENDOR "gromacs.org")
 133 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Gromacs - a toolkit for high-performance molecular simulation")
 134 set(CPACK_RESOURCE_FILE_WELCOME "${CMAKE_SOURCE_DIR}/admin/InstallWelcome.txt")
 135 # Its GPL/LGPL, so they do not have to agree to a license for mere usage, but some installers require this...
 136 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_SOURCE_DIR}/COPYING")
 137 set(CPACK_RESOURCE_FILE_README "${CMAKE_SOURCE_DIR}/admin/InstallInfo.txt")
 138 set(CPACK_SOURCE_IGNORE_FILES "\\\\.isreposource$;\\\\.git/;\\\\.gitignore$")
 139 set(CPACK_PROJECT_CONFIG_FILE "${CMAKE_SOURCE_DIR}/CPackInit.cmake")
 140 set(CPACK_SOURCE_INSTALLED_DIRECTORIES "${CMAKE_SOURCE_DIR};/;${CMAKE_BINARY_DIR}/src/programs/completion;src/programs/completion;${CMAKE_BINARY_DIR}/share/man/man1;share/man/man1;${CMAKE_BINARY_DIR}/share/man/man7;share/man/man7;${CMAKE_BINARY_DIR}/share/html/final;share/html/final")
 141 set(CPACK_PACKAGE_CONTACT "gmx-users@gromacs.org")
 142
 143 #must come after all cpack settings!
 144 include(CPack)
 145
 146 # Set a default valgrind suppression file.
 147 # This unfortunately needs to duplicate information from CTest to work as
 148 # expected...
 149 set(MEMORYCHECK_SUPPRESSIONS_FILE
 150     "${CMAKE_SOURCE_DIR}/cmake/legacy_and_external.supp"
 151     CACHE FILEPATH
 152     "File that contains suppressions for the memory checker")
 153 include(CTest)
 154
 155 set(SOURCE_IS_GIT_REPOSITORY OFF)
 156 set(SOURCE_IS_SOURCE_DISTRIBUTION OFF)
 157 if(EXISTS "${CMAKE_SOURCE_DIR}/.git")
 158     set(SOURCE_IS_GIT_REPOSITORY ON)
 159 endif()
 160 if(NOT EXISTS "${CMAKE_SOURCE_DIR}/admin/.isreposource")
 161     set(SOURCE_IS_SOURCE_DISTRIBUTION ON)
 162 endif()
 163
 164 ########################################################################
 165 # Check and warn if cache generated on a different host is being reused
 166 ########################################################################
 167 if(CMAKE_HOST_UNIX)
 168     execute_process(COMMAND hostname
 169                     OUTPUT_VARIABLE TMP_HOSTNAME
 170                     OUTPUT_STRIP_TRAILING_WHITESPACE)
 171     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}")
 172         message(WARNING "
 173             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
 174             is being reused! This could lead to inconsitencies; therefore, it is
 175             recommended to regenerate the cache!")
 176     endif()
 177     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
 178             "Hostname of the machine where the cache was generated.")
 179 endif()
 180
 181 ########################################################################
 182 # User input options                                                   #
 183 ########################################################################
 184 include(gmxOptionUtilities)
 185
 186 set(CMAKE_PREFIX_PATH "" CACHE STRING "Extra locations to search for external libraries and tools (give directory without lib, bin, or include)")
 187
 188 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" OFF)
 189 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 190 option(GMX_THREAD_MPI  "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" ON)
 191 gmx_dependent_option(
 192     GMX_MPI_IN_PLACE
 193     "Enable MPI_IN_PLACE for MPIs that have it defined"
 194     ON
 195     GMX_MPI)
 196 mark_as_advanced(GMX_MPI_IN_PLACE)
 197 option(GMX_SOFTWARE_INVSQRT "Use GROMACS software 1/sqrt" ON)
 198 mark_as_advanced(GMX_SOFTWARE_INVSQRT)
 199 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 200 mark_as_advanced(GMX_FAHCORE)
 201
 202 option(GMX_COOL_QUOTES "Enable Gromacs cool quotes" ON)
 203 mark_as_advanced(GMX_COOL_QUOTES)
 204 gmx_add_cache_dependency(GMX_COOL_QUOTES BOOL "NOT GMX_FAHCORE" OFF)
 205
 206 # decide on GPU settings based on user-settings and GPU/CUDA detection
 207 include(gmxManageGPU)
 208
 209 # Detect the architecture the compiler is targetting, detect
 210 # SIMD instructions possibilities on that hardware, suggest SIMD instruction set
 211 # to use if none is specified, and populate the cache option for CPU
 212 # SIMD.
 213 include(gmxDetectTargetArchitecture)
 214 gmx_detect_target_architecture()
 215
 216 if(GMX_CPU_ACCELERATION)
 217     # Stay compatible with old Jenkins command line options for specific SIMD acceleration
 218     set(GMX_SIMD "${GMX_CPU_ACCELERATION}" CACHE STRING "SIMD instruction set level and compiler optimization" FORCE)
 219 endif()
 220
 221 if(NOT GMX_TARGET_MIC)
 222     include(gmxDetectSimd)
 223     gmx_detect_simd(GMX_SUGGESTED_SIMD)
 224 else()
 225     set(GMX_SUGGESTED_SIMD "None")
 226 endif()
 227
 228 gmx_option_multichoice(
 229     GMX_SIMD
 230     "SIMD instruction set for CPU kernels and compiler optimization"
 231     "${GMX_SUGGESTED_SIMD}"
 232     None SSE2 SSE4.1 AVX_128_FMA AVX_256 AVX2_256 IBM_QPX Sparc64_HPC_ACE Reference)
 233
 234 gmx_option_multichoice(
 235     GMX_FFT_LIBRARY
 236     "FFT library"
 237     "fftw3"
 238     fftw3 mkl "fftpack[built-in]")
 239 gmx_dependent_option(
 240     GMX_BUILD_OWN_FFTW
 241     "Download and build FFTW 3 during the GROMACS build process, rather than fall back on the really slow fftpack."
 242     OFF
 243     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 244 gmx_dependent_option(
 245     GMX_DISABLE_FFTW_MEASURE
 246     "Do not optimize FFTW setups (not needed with SSE)"
 247     OFF
 248     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 249 mark_as_advanced(GMX_BUILD_OWN_FFTW)
 250 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 251
 252 gmx_option_multichoice(
 253     GMX_QMMM_PROGRAM
 254     "QM package for QM/MM"
 255     None
 256     none gaussian mopac gamess orca)
 257
 258 gmx_dependent_cache_variable(GMX_SIMD_REF_FLOAT_WIDTH  "Reference SIMD single precision width" STRING "4" "GMX_SIMD STREQUAL REFERENCE")
 259 gmx_dependent_cache_variable(GMX_SIMD_REF_DOUBLE_WIDTH "Reference SIMD double precision width" STRING "2" "GMX_SIMD STREQUAL REFERENCE")
 260
 261 # This should be moved to a separate NBNXN cmake module when that code is cleaned up and modularized
 262
 263 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 264 mark_as_advanced(GMX_BROKEN_CALLOC)
 265 option(GMX_LOAD_PLUGINS "Compile with plugin support, needed to read VMD supported file formats" ON)
 266 mark_as_advanced(GMX_LOAD_PLUGINS)
 267
 268 option(GMX_GPU  "Enable GPU acceleration" ON)
 269 option(GMX_OPENMP "Enable OpenMP-based multithreading" ON)
 270
 271 option(GMX_USE_TNG "Use the TNG library for trajectory I/O" ON)
 272
 273 option(GMX_GIT_VERSION_INFO "Generate git version information" ${SOURCE_IS_GIT_REPOSITORY})
 274 mark_as_advanced(GMX_GIT_VERSION_INFO)
 275
 276 if(UNIX)
 277     option(GMX_SYMLINK_OLD_BINARY_NAMES "Create symbolic links for pre-5.0 binary names" ON)
 278 endif()
 279 option(GMX_BUILD_MDRUN_ONLY "Build and install only the mdrun binary" OFF)
 280
 281 option(GMX_CYCLE_SUBCOUNTERS "Enable cycle subcounters to get a more detailed cycle timings" OFF)
 282 mark_as_advanced(GMX_CYCLE_SUBCOUNTERS)
 283
 284 option(GMX_SKIP_DEFAULT_CFLAGS "Don't automatically add suggested/required Compiler flags." OFF)
 285 mark_as_advanced(GMX_SKIP_DEFAULT_CFLAGS)
 286
 287 option(GMX_BUILD_FOR_COVERAGE
 288        "Tune build for better code coverage metrics (e.g., disable asserts)"
 289        OFF)
 290 mark_as_advanced(GMX_BUILD_FOR_COVERAGE)
 291
 292
 293 ######################################################################
 294 # Detect OpenMP support
 295 ######################################################################
 296 # The OpenMP detection _must_ come before tests for other CFLAGS.
 297 include(gmxManageOpenMP)
 298
 299
 300
 301 ######################################################################
 302 # Compiler tests
 303 # These need to be done early (before further tests).
 304 #####################################################################
 305
 306 # The cmake/Check{C,CXX}CompilerFlag.cmake files in the GROMACS distribution
 307 # are used with permission from CMake v2.8.9 so that GROMACS can detect
 308 # invalid options with the Intel Compilers.
 309 # These files should be removed from the source tree when a CMake version that
 310 # includes the features in question becomes required for building GROMACS.
 311 include(CheckCCompilerFlag)
 312 include(CheckCXXCompilerFlag)
 313
 314
 315 include(gmxCFlags)
 316 gmx_c_flags()
 317
 318 # This variable should be used for additional compiler flags which are not
 319 # generated in gmxCFlags nor are SIMD or MPI related.
 320 set(EXTRA_C_FLAGS "")
 321 set(EXTRA_CXX_FLAGS "")
 322
 323 # Run through a number of tests for buggy compilers and other issues
 324 include(gmxTestCompilerProblems)
 325 gmx_test_compiler_problems()
 326
 327
 328 set(PKG_CFLAGS "")
 329 if(GMX_DOUBLE)
 330     add_definitions(-DGMX_DOUBLE)
 331     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_DOUBLE")
 332 endif()
 333 if(GMX_SOFTWARE_INVSQRT)
 334   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_SOFTWARE_INVSQRT")
 335 endif()
 336
 337 if(WIN32 AND NOT CYGWIN)
 338     set(GMX_WSOCKLIB_PATH CACHE PATH "Path to winsock (wsock32.lib) library.")
 339     mark_as_advanced(GMX_WSOCKLIB_PATH)
 340     find_library(WSOCK32_LIBRARY NAMES wsock32 PATHS ${GMX_WSOCKLIB_PATH})
 341     if(WSOCK32_LIBRARY)
 342         list(APPEND GMX_EXTRA_LIBRARIES ${WSOCK32_LIBRARY})
 343         add_definitions(-DGMX_HAVE_WINSOCK)
 344     else()
 345         message(STATUS "No winsock found. Cannot use interactive molecular dynamics (IMD).")
 346     endif(WSOCK32_LIBRARY)
 347 endif()
 348
 349
 350
 351 ########################################################################
 352 # Basic system tests (standard libraries, headers, functions, types)   #
 353 ########################################################################
 354 include(CheckIncludeFiles)
 355 include(CheckIncludeFileCXX)
 356 check_include_files(unistd.h     HAVE_UNISTD_H)
 357 check_include_files(pwd.h        HAVE_PWD_H)
 358 check_include_files(dirent.h     HAVE_DIRENT_H)
 359 check_include_files(time.h       HAVE_TIME_H)
 360 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 361 check_include_files(io.h         HAVE_IO_H)
 362 check_include_files(sched.h      HAVE_SCHED_H)
 363
 364 check_include_files(regex.h      HAVE_POSIX_REGEX)
 365 check_include_file_cxx(regex     HAVE_CXX11_REGEX)
 366 # TODO: It could be nice to inform the user if no regex support is found,
 367 # as selections won't be fully functional.
 368
 369 include(CheckFunctionExists)
 370 check_function_exists(posix_memalign    HAVE_POSIX_MEMALIGN)
 371 check_function_exists(memalign          HAVE_MEMALIGN)
 372 check_function_exists(_aligned_malloc   HAVE__ALIGNED_MALLOC)
 373 check_function_exists(gettimeofday      HAVE_GETTIMEOFDAY)
 374 check_function_exists(fsync             HAVE_FSYNC)
 375 check_function_exists(_fileno           HAVE__FILENO)
 376 check_function_exists(fileno            HAVE_FILENO)
 377 check_function_exists(_commit           HAVE__COMMIT)
 378 check_function_exists(sigaction         HAVE_SIGACTION)
 379 check_function_exists(sysconf           HAVE_SYSCONF)
 380 check_function_exists(sched_setaffinity HAVE_SCHED_SETAFFINITY)
 381 check_function_exists(sched_getaffinity HAVE_SCHED_GETAFFINITY)
 382 check_function_exists(rsqrt             HAVE_RSQRT)
 383 check_function_exists(rsqrtf            HAVE_RSQRTF)
 384 check_function_exists(sqrtf             HAVE_SQRTF)
 385
 386 include(CheckLibraryExists)
 387 check_library_exists(m sqrt "" HAVE_LIBM)
 388 check_library_exists(rt clock_gettime "" HAVE_CLOCK_GETTIME)
 389
 390 include(TestBigEndian)
 391 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 392
 393 # Management of GROMACS options for specific toolchains should go
 394 # here. Because the initial settings for some of the main options have
 395 # already happened, but things like library detection and MPI compiler
 396 # feature detection have not, the docstrings for any over-rides of
 397 # GROMACS defaults or user settings will make sense. Also, any
 398 # toolchain-related reasons for choosing whether to detect various
 399 # things can be sorted out now, before the detection takes place.
 400 if(${CMAKE_SYSTEM_NAME} MATCHES BlueGene)
 401     include(gmxManageBlueGene)
 402 endif()
 403
 404 ########################################################################
 405 #Process MPI settings
 406 ########################################################################
 407 include(gmxManageMPI)
 408
 409
 410 ########################################################################
 411 #Process shared/static library settings
 412 ########################################################################
 413 include(gmxManageSharedLibraries)
 414
 415
 416 ########################################################################
 417 # Find external packages                                               #
 418 ########################################################################
 419
 420 # Unconditionally find the package, as it is also required for unit
 421 # tests. This exports LIBXML2_FOUND, which we should not use because
 422 # it does not tell us that linking will succeed. Instead, we test that
 423 # next.
 424 find_package(LibXml2)
 425 include(gmxTestLibXml2)
 426 gmx_test_libxml2(HAVE_LIBXML2)
 427 option(GMX_XML "Use libxml2 to parse xml files (currently has no effect)" ${HAVE_LIBXML2})
 428 set(PKG_XML "")
 429 mark_as_advanced(GMX_XML)
 430 # Don't actually do anything, since libxml2 is currently not used by libgromacs
 431 #if(GMX_XML AND NOT HAVE_LIBXML2)
 432 #    message(FATAL_ERROR "libxml2 not found. Set GMX_XML=OFF to compile without XML support")
 433 #endif()
 434 #if(GMX_XML)
 435 #    include_directories(${LIBXML2_INCLUDE_DIR})
 436 #    set(PKG_XML libxml-2.0)
 437 #    set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 438 #endif()
 439
 440 option(GMX_EXTRAE "Add support for tracing using EXTRAE" OFF)
 441 mark_as_advanced(GMX_EXTRAE)
 442
 443 if (GMX_EXTRAE)
 444   find_package(EXTRAE)
 445   if(EXTRAE_FOUND)
 446     include_directories(${EXTRAE_INCLUDE_DIR})
 447     set(HAVE_EXTRAE 1)
 448   else()
 449     message(FATAL_ERROR "EXTRAE library was not found. Please add the correct path to CMAKE_PREFIX_PATH")
 450   endif()
 451 endif()
 452
 453 option(GMX_X11 "Use X window system" OFF)
 454 if (GMX_X11)
 455     find_package(X11)
 456     # X11 includes/libraries are only set in the ngmx subdirectory!
 457     if(NOT X11_FOUND)
 458         message(FATAL_ERROR
 459                 "X11 include files and/or libraries were not found. "
 460                 "Set GMX_X11=OFF to compile without X11 support. "
 461                 "gmx view will not be available.")
 462     endif()
 463     include_directories(${X11_INCLUDE_DIR})
 464 endif()
 465
 466 include(ThreadMPI)
 467 # Enable core threading facilities
 468 tmpi_enable_core("${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include")
 469 # Enable tMPI C++ support
 470 tmpi_enable_cxx()
 471 if(GMX_THREAD_MPI)
 472     # enable MPI functions
 473     tmpi_enable()
 474     set(GMX_MPI 1)
 475     set(MPI_IN_PLACE_EXISTS 1)
 476 endif()
 477 # If atomics are manually disabled a define is needed because atomics.h doesn't depend on config.h
 478 if (TMPI_ATOMICS_DISABLED)
 479    add_definitions(-DTMPI_ATOMICS_DISABLED)
 480 endif()
 481
 482 if(GMX_GPU)
 483     # now that we have detected the dependencies, do the second configure pass
 484     gmx_gpu_setup()
 485 endif()
 486
 487 if(CYGWIN)
 488     set(GMX_CYGWIN 1)
 489 endif()
 490
 491 if(WIN32 AND NOT CYGWIN)
 492     set(GMX_NATIVE_WINDOWS 1)
 493     # This makes windows.h not declare min/max as macros that would break
 494     # C++ code using std::min/std::max.
 495     add_definitions(-DNOMINMAX)
 496 endif()
 497
 498 # only bother with finding git and using version.h if the source is a git repo
 499 if(GMX_GIT_VERSION_INFO)
 500     if (NOT SOURCE_IS_GIT_REPOSITORY)
 501         message(FATAL_ERROR
 502             "Cannot generate git version information from source tree not under git. "
 503             "Set GMX_GIT_VERSION_INFO=OFF to proceed.")
 504     endif()
 505     # We need at least git v1.5.3 be able to parse git's date output. If not
 506     # found or the version is too small, we can't generate version information.
 507     find_package(Git)
 508
 509     if(NOT GIT_FOUND OR GIT_VERSION_STRING VERSION_LESS "1.5.3")
 510         message(FATAL_ERROR
 511             "No compatible git version found (>= 1.5.3 required). "
 512             "Won't be able to generate development version information. "
 513             "Set GMX_GIT_VERSION_INFO=OFF to proceed.")
 514     endif()
 515 endif()
 516
 517 # Detect boost unless GMX_EXTERNAL_BOOST is explicitly OFF
 518 # Used for default if GMX_EXTERNAL_BOOST is not defined (first CMake pass)
 519 if(NOT DEFINED GMX_EXTERNAL_BOOST OR GMX_EXTERNAL_BOOST)
 520     find_package(Boost 1.44.0)
 521     if(Boost_FOUND AND Boost_VERSION VERSION_LESS "104400")
 522         set(Boost_FOUND FALSE)
 523     endif()
 524     # Print the notification only on first run, when determining the default
 525     if(NOT DEFINED GMX_EXTERNAL_BOOST AND NOT Boost_FOUND)
 526         message("Boost >= 1.44 not found. Using minimal internal version. "
 527                 "This may cause trouble if you plan on compiling/linking other "
 528                 "software that uses Boost against Gromacs.")
 529     endif()
 530 endif()
 531 option(GMX_EXTERNAL_BOOST "Use external Boost instead of minimal built-in version"
 532        ${Boost_FOUND})
 533 if(GMX_EXTERNAL_BOOST AND NOT Boost_FOUND)
 534     message(FATAL_ERROR
 535         "Boost >= 1.44 not found. "
 536         "You can set GMX_EXTERNAL_BOOST=OFF to compile against minimal "
 537         "version of Boost included with Gromacs.")
 538 endif()
 539
 540 option(GMX_BUILD_UNITTESTS "Build unit tests with BUILD_TESTING (uses Google C++ Testing and Mocking Frameworks, requires libxml2)" ${HAVE_LIBXML2})
 541 mark_as_advanced(GMX_BUILD_UNITTESTS)
 542 gmx_add_cache_dependency(GMX_BUILD_UNITTESTS BOOL BUILD_TESTING OFF)
 543 if (GMX_BUILD_UNITTESTS AND NOT HAVE_LIBXML2)
 544     message(FATAL_ERROR
 545         "Cannot build unit tests without libxml2. "
 546         "Either set GMX_BUILD_UNITTESTS=OFF or tell CMake how to find a working version of libxml2.")
 547 endif()
 548
 549 ########################################################################
 550 # Generate development version info for cache
 551 ########################################################################
 552 # set(GEN_VERSION_INFO_INTERNAL "ON")
 553 # include(gmxGenerateVersionString)
 554
 555 ########################################################################
 556 # Our own GROMACS tests
 557 ########################################################################
 558
 559 add_definitions( -DHAVE_CONFIG_H )
 560 include_directories(${CMAKE_SOURCE_DIR}/src)
 561 include_directories(${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include)
 562 # Required for config.h, maybe should only be set in src/CMakeLists.txt
 563 include_directories(${CMAKE_BINARY_DIR}/src)
 564 # Required for gmx_header_config_gen.h to be found before installation
 565 include_directories(${CMAKE_BINARY_DIR}/src/gromacs/utility)
 566 # Required for now to make old code compile
 567 include_directories(${CMAKE_SOURCE_DIR}/src/gromacs/legacyheaders)
 568
 569 include(gmxTestInlineASM)
 570 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 571
 572 include(gmxSetBuildInformation)
 573 gmx_set_build_information()
 574 # Turn on RDTSCP if:
 575 # - the build system's CPU supports it
 576 # - the acceleration is set to AVX as all AVX-capable CPUs support AVX (which
 577 #   at this point means that the user set it).
 578 # Note: it's better to not use the later set value of GMX_SIMD because
 579 # it reflects the system's capability of both compiling and running AVX code.
 580 # TODO: After merge with 5.0 one could implement a cache variable dependency
 581 # such that GMX_USE_RDTSCP can change if GMX_CPU_ACCELERATION is changed to AVX
 582 # after the first cmake pass.
 583 if (BUILD_CPU_FEATURES MATCHES "rdtscp" OR GMX_SIMD MATCHES "AVX")
 584     set(GMX_USE_RDTSCP_DEFAULT_VALUE ON)
 585 else()
 586     set(GMX_USE_RDTSCP_DEFAULT_VALUE OFF)
 587 endif()
 588 option(GMX_USE_RDTSCP "Use RDTSCP for better CPU-based timers (available on recent x86 CPUs; might need to be off when compiling for heterogeneous environments)" ${GMX_USE_RDTSCP_DEFAULT_VALUE})
 589 mark_as_advanced(GMX_USE_RDTSCP)
 590 if(GMX_USE_RDTSCP)
 591     set(HAVE_RDTSCP 1)
 592 endif()
 593
 594 include(gmxTestFloatFormat)
 595 gmx_test_float_format(GMX_FLOAT_FORMAT_IEEE754
 596                       GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER
 597                       GMX_IEEE754_BIG_ENDIAN_WORD_ORDER)
 598
 599 include(gmxTestLargeFiles)
 600 gmx_test_large_files(GMX_LARGEFILES)
 601
 602 include(gmxTestSignal)
 603 gmx_test_sigusr1(HAVE_SIGUSR1)
 604
 605 include(gmxTestPipes)
 606 gmx_test_pipes(HAVE_PIPES)
 607
 608 include(gmxTestIsfinite)
 609 gmx_test_isfinite(HAVE_ISFINITE)
 610 gmx_test__isfinite(HAVE__ISFINITE)
 611 gmx_test__finite(HAVE__FINITE)
 612
 613 include(gmxTestCXX11)
 614 gmx_test_cxx11(GMX_CXX11_SUPPORTED GMX_CXX11_FLAGS)
 615 include(CMakeDependentOption)
 616 # nvcc does not support C++11 flags, so with GPUs we prefer to skip C++11 flags
 617 # entirely to keep the compilation environment uniform.
 618 cmake_dependent_option(GMX_CXX11
 619     "Use C++11 features"
 620     ON "GMX_CXX11_SUPPORTED AND NOT GMX_GPU" OFF)
 621 mark_as_advanced(GMX_CXX11)
 622 if(GMX_CXX11)
 623     set(EXTRA_CXX_FLAGS "${EXTRA_CXX_FLAGS} ${GMX_CXX11_FLAGS}")
 624 endif()
 625
 626
 627 include(gmxTestXDR)
 628 gmx_test_xdr(GMX_SYSTEM_XDR)
 629 if(NOT GMX_SYSTEM_XDR)
 630     set(GMX_INTERNAL_XDR 1)
 631 endif()
 632
 633
 634 ##################################################
 635 # Process SIMD instruction settings
 636 ##################################################
 637 # This checks what flags to add in order to
 638 # support the SIMD instructions we need, and sets
 639 # correct defines for the SIMD instructions supported.
 640 include(gmxTestSimd)
 641 gmx_test_simd()
 642
 643
 644 # Process QM/MM Settings
 645 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 646     set(GMX_QMMM_GAUSSIAN 1)
 647 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 648     set(GMX_QMMM_MOPAC 1)
 649 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 650     set(GMX_QMMM_GAMESS 1)
 651 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 652     set(GMX_QMMM_ORCA 1)
 653 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 654     # nothing to do
 655 else()
 656     gmx_invalid_option_value(GMX_QMMM_PROGRAM)
 657 endif()
 658
 659
 660 ##################################################
 661 # Process FFT library settings
 662 ##################################################
 663 include(gmxManageFFTLibraries)
 664
 665
 666 include(gmxManageLinearAlgebraLibraries)
 667
 668 # Whether GROMACS will really try to compile support for VMD plugins
 669 set(GMX_USE_PLUGINS OFF)
 670
 671 if(GMX_LOAD_PLUGINS)
 672   if(CYGWIN OR NOT WIN32)
 673     # Native Windows does not have, nor need dlopen
 674     # Note that WIN32 is set with Cygwin, but Cygwin needs dlopen to use plug-ins
 675     include(gmxTestdlopen)
 676     gmx_test_dlopen(HAVE_DLOPEN)
 677   endif()
 678
 679   # so, should we use plug-ins?
 680   if((WIN32 AND NOT CYGWIN) OR (HAVE_DLOPEN AND BUILD_SHARED_LIBS))
 681     if(NOT VMD_QUIETLY)
 682       MESSAGE(STATUS
 683           "Found the ability to use plug-ins when building shared libaries, "
 684           "so will compile to use plug-ins (e.g. to read VMD-supported file "
 685           "formats).")
 686     endif()
 687     if(NOT GMX_VMD_PLUGIN_PATH)
 688       find_package(VMD)
 689     endif()
 690     set(GMX_USE_PLUGINS ON)
 691     list(APPEND GMX_EXTRA_LIBRARIES ${CMAKE_DL_LIBS}) # magic cross-platform pre-set variable for dlopen library
 692     set(PKG_DL_LIBS "-l${CMAKE_DL_LIBS}")
 693   else()
 694     set(PKG_DL_LIBS)
 695   endif()
 696 endif()
 697 set(VMD_QUIETLY TRUE CACHE INTERNAL "")
 698
 699 # Link real-time library for POSIX timers. The check for clock_gettime
 700 # confirms the linkability of rt.
 701 if(HAVE_TIME_H AND HAVE_UNISTD_H AND HAVE_CLOCK_GETTIME)
 702     list(APPEND GMX_EXTRA_LIBRARIES rt)
 703 endif()
 704
 705 # Math and thread libraries must often come after all others when linking...
 706 if(HAVE_LIBM)
 707     list(APPEND GMX_EXTRA_LIBRARIES m)
 708 endif()
 709
 710 option(GMX_NACL "Configure for Native Client builds" OFF)
 711 if (GMX_NACL)
 712   list(APPEND GMX_EXTRA_LIBRARIES nosys)
 713   set(GMX_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -lnosys")
 714   set(GMX_NO_NICE 1)
 715   set(GMX_NO_RENAME 1)
 716 endif()
 717 mark_as_advanced(GMX_NACL)
 718
 719 if(GMX_FAHCORE)
 720   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 721       "Path to swindirect.h")
 722   include_directories(${COREWRAP_INCLUDE_DIR})
 723 endif()
 724
 725 option(GMX_BUILD_HELP "Build man pages, HTML help, and completions automatically (requires that compiled binaries can be executed on the build host)" OFF)
 726 mark_as_advanced(GMX_BUILD_HELP)
 727 if (GMX_BUILD_HELP AND SOURCE_IS_SOURCE_DISTRIBUTION AND
 728     "${CMAKE_CURRENT_SOURCE_DIR}" STREQUAL "${CMAKE_CURRENT_BINARY_DIR}")
 729
 730     message(FATAL_ERROR
 731         "Rebuilding HTML and man pages is not supported for in-source "
 732         "builds from a source distribution. "
 733         "Set GMX_BUILD_HELP=OFF or do an out-of-source build to proceed.")
 734 endif()
 735
 736 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 737 # these are set after everything else
 738 if (NOT GMX_SKIP_DEFAULT_CFLAGS)
 739     set(CMAKE_C_FLAGS "${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${CMAKE_C_FLAGS}")
 740     set(CMAKE_CXX_FLAGS "${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${CMAKE_CXX_FLAGS}")
 741     set(CMAKE_EXE_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}")
 742     set(CMAKE_SHARED_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS}")
 743 else()
 744     message("Recommended flags which are not added because GMX_SKIP_DEFAULT_CFLAGS=yes:")
 745     message("CMAKE_C_FLAGS: ${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${GMXC_CFLAGS}")
 746     message("CMAKE_C_FLAGS_RELEASE: ${GMXC_CFLAGS_RELEASE}")
 747     message("CMAKE_C_FLAGS_DEBUG: ${GMXC_CFLAGS_DEBUG}")
 748     message("CMAKE_CXX_FLAGS: ${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${GMXC_CXXFLAGS}")
 749     message("CMAKE_CXX_FLAGS_RELEASE: ${GMXC_CXXFLAGS_RELEASE}")
 750     message("CMAKE_CXX_FLAGS_DEBUG: ${GMXC_CXXFLAGS_DEBUG}")
 751     message("CMAKE_EXE_LINKER_FLAGS: ${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS}")
 752     message("CMAKE_SHARED_LINKER_FLAGS: ${MPI_LINKER_FLAGS}")
 753 endif()
 754
 755 if(NOT GMX_OPENMP)
 756     #Unset all OpenMP flags in case OpenMP was disabled either by the user
 757     #or because it was only partially detected (e.g. only for C but not C++ compiler)
 758     unset(OpenMP_C_FLAGS CACHE)
 759     unset(OpenMP_CXX_FLAGS CACHE)
 760 else()
 761     set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} ${OpenMP_LINKER_FLAGS})
 762     set(GMX_SHARED_LINKER_FLAGS ${GMX_SHARED_LINKER_FLAGS} ${OpenMP_SHARED_LINKER_FLAGS})
 763 endif()
 764 set(PKG_CFLAGS "${PKG_CFLAGS} ${OpenMP_C_FLAGS}")
 765
 766 ########################################################################
 767 # Specify install locations
 768 ########################################################################
 769 set(GMX_LIB_INSTALL_DIR lib CACHE STRING
 770     "Library installation directory (default: lib)")
 771 set(GMX_DATA_INSTALL_DIR gromacs CACHE STRING
 772     "Data installation directory under share/ (default: gromacs)")
 773 mark_as_advanced(GMX_LIB_INSTALL_DIR GMX_DATA_INSTALL_DIR)
 774
 775 set(LIB_INSTALL_DIR  ${GMX_INSTALL_PREFIX}${GMX_LIB_INSTALL_DIR})
 776 set(BIN_INSTALL_DIR  ${GMX_INSTALL_PREFIX}bin)
 777 set(DATA_INSTALL_DIR ${GMX_INSTALL_PREFIX}share/${GMX_DATA_INSTALL_DIR})
 778 set(MAN_INSTALL_DIR  ${GMX_INSTALL_PREFIX}share/man)
 779 set(INCL_INSTALL_DIR ${GMX_INSTALL_PREFIX}include)
 780
 781 set(GMXLIB_SEARCH_DIR share/${GMX_DATA_INSTALL_DIR}/top)
 782 set(GMXLIB_FALLBACK   ${CMAKE_INSTALL_PREFIX}/${DATA_INSTALL_DIR}/top)
 783
 784 # Binary and library suffix options
 785 include(gmxManageSuffixes)
 786
 787 ##################################################################
 788 # Shared library settings
 789 ##################################################################
 790 if(NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin")
 791     if(GMX_LIB_INSTALL_DIR STREQUAL "lib")
 792         set(CMAKE_BUILD_WITH_INSTALL_RPATH TRUE)
 793     endif()
 794     set(CMAKE_INSTALL_RPATH "\$ORIGIN/../${GMX_LIB_INSTALL_DIR}")
 795     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 796 else()
 797     if(CMAKE_SYSTEM_VERSION VERSION_GREATER 8.0) #rpath supported for >10.4
 798         set(CMAKE_INSTALL_NAME_DIR "@rpath")
 799         set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} "-Wl,-rpath,@executable_path/../${GMX_LIB_INSTALL_DIR}")
 800     else()
 801         set(CMAKE_INSTALL_NAME_DIR "${CMAKE_INSTALL_PREFIX}/${LIB_INSTALL_DIR}")
 802     endif()
 803 endif()
 804
 805 #COPYING file: Only necessary for binary distributions.
 806 #Simpler to always install.
 807 install(FILES COPYING DESTINATION ${DATA_INSTALL_DIR} COMPONENT data)
 808
 809 if(GMX_EXTERNAL_BOOST)
 810     include_directories(${Boost_INCLUDE_DIRS})
 811     set(PKG_CFLAGS "${PKG_CFLAGS} -I${Boost_INCLUDE_DIRS}")
 812 else()
 813     include_directories(${CMAKE_SOURCE_DIR}/src/external/boost)
 814     # typeid not supported for minimal internal version
 815     # (would add significant amount of code)
 816     add_definitions(-DBOOST_NO_TYPEID)
 817     # TODO: Propagate the above settings to the installed CMakeFiles.txt template
 818     # (from share/template/)
 819     set(PKG_CFLAGS "${PKG_CFLAGS} -DBOOST_NO_TYPEID -I${CMAKE_INSTALL_PREFIX}/${INCL_INSTALL_DIR}/gromacs/external/boost")
 820     if (NOT GMX_BUILD_MDRUN_ONLY)
 821         install(DIRECTORY ${CMAKE_SOURCE_DIR}/src/external/boost/boost
 822                 DESTINATION ${INCL_INSTALL_DIR}/gromacs/external/boost
 823                 COMPONENT development)
 824     endif()
 825 endif()
 826
 827 if(GMX_USE_TNG)
 828     find_package(ZLIB QUIET)
 829     include(gmxTestZLib)
 830     gmx_test_zlib(HAVE_ZLIB)
 831     set(TNG_BUILD_WITH_ZLIB ${HAVE_ZLIB} CACHE BOOL  "Build TNG with zlib compression")
 832     set(TNG_BUILD_FORTRAN OFF CACHE BOOL "Build Fortran compatible TNG library and examples for testing")
 833     set(TNG_BUILD_EXAMPLES OFF CACHE BOOL "Build examples showing usage of the TNG API")
 834     set(TNG_BUILD_COMPRESSION_TESTS OFF CACHE BOOL "Build tests of the TNG compression library")
 835     set(TNG_BUILD_DOCUMENTATION OFF CACHE BOOL "Use Doxygen to create the HTML based TNG API documentation")
 836     set(TNG_BUILD_TEST OFF CACHE BOOL "Build TNG testing binary.")
 837     add_subdirectory(${CMAKE_SOURCE_DIR}/src/external/tng_io)
 838     set(GMX_TNG_LIBRARIES tng_io)
 839 endif()
 840 mark_as_advanced(TNG_BUILD_FORTRAN)
 841 mark_as_advanced(TNG_BUILD_EXAMPLES)
 842 mark_as_advanced(TNG_BUILD_COMPRESSION_TESTS)
 843 mark_as_advanced(TNG_BUILD_DOCUMENTATION)
 844 mark_as_advanced(TNG_BUILD_TEST)
 845 mark_as_advanced(TNG_EXAMPLE_FILES_DIR)
 846
 847 if (GMX_BUILD_FOR_COVERAGE)
 848     # Code heavy with asserts makes conditional coverage close to useless metric,
 849     # as by design most of the false branches are impossible to trigger in
 850     # correctly functioning code.  And the benefit of testing those that could
 851     # be triggered by using an API against its specification isn't usually
 852     # worth the effort.
 853     add_definitions(-DNDEBUG -DBOOST_DISABLE_ASSERTS -DGMX_DISABLE_ASSERTS)
 854 endif()
 855
 856 if (BUILD_TESTING)
 857     # "tests" target builds all the separate test binaries.
 858     add_custom_target(tests)
 859     # "run-ctest" is an internal target that actually runs the tests.
 860     # This is necessary to be able to add separate targets that execute as part
 861     # of 'make check', but are ensured to be executed after the actual tests.
 862     add_custom_target(run-ctest
 863                       COMMAND ${CMAKE_CTEST_COMMAND} --output-on-failure
 864                       COMMENT "Running all tests"
 865                       VERBATIM)
 866     add_dependencies(run-ctest tests)
 867     # "check" target builds and runs all tests.
 868     add_custom_target(check DEPENDS run-ctest)
 869 endif()
 870
 871 if (NOT GMX_BUILD_MDRUN_ONLY)
 872     add_subdirectory(doxygen)
 873     add_subdirectory(share)
 874     add_subdirectory(scripts)
 875 endif()
 876 add_subdirectory(src)
 877
 878 if (BUILD_TESTING)
 879     add_subdirectory(tests)
 880 endif()
 881
 882 # Issue a warning if NVIDIA GPUs were detected, but CUDA was not found.
 883 # Don't bother the user after the first configure pass.
 884 if ((CUDA_NOTFOUND_AUTO AND GMX_DETECT_GPU_AVAILABLE) AND NOT GMX_GPU_DETECTION_DONE)
 885     message(WARNING "${CUDA_NOTFOUND_MESSAGE}")
 886 endif()
 887 set(GMX_GPU_DETECTION_DONE TRUE CACHE INTERNAL "Whether GPU detection has already been done")
 888
 889 #######################
 890 ## uninstall target
 891 #######################
 892     CONFIGURE_FILE(
 893                    "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 894                    "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
 895                    IMMEDIATE @ONLY)
 896 ###########################
 897 ADD_CUSTOM_TARGET(uninstall
 898                   "${CMAKE_COMMAND}" -P
 899                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
 900 ###########################
 901
 902 ########################################################################
 903 # Manual                                                               #
 904 ########################################################################
 905
 906 option(GMX_BUILD_MANUAL "Whether to try to configure to build the PDF manual" OFF)
 907 mark_as_advanced(GMX_BUILD_MANUAL)
 908 if(GMX_BUILD_MANUAL)
 909     # Make sure we only do detection of manual-building dependencies
 910     # when the user opted in for that.
 911     add_subdirectory(manual)
 912 endif()