CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.6)
   2
   3 project(Gromacs)
   4 include(Dart)
   5 mark_as_advanced(DART_ROOT)
   6 # PROJECT_VERSION should have the following structure:
   7 # VERSION[-dev-SUFFIX] where the VERSION can have any form and the suffix
   8 set(PROJECT_VERSION "4.5.1")
   9 set(CUSTOM_VERSION_STRING ""
  10     CACHE STRING "Custom version string (if empty, use hard-coded default)")
  11 mark_as_advanced(CUSTOM_VERSION_STRING)
  12 if (CUSTOM_VERSION_STRING)
  13     set(PROJECT_VERSION ${CUSTOM_VERSION_STRING})
  14 endif (CUSTOM_VERSION_STRING)
  15 set(SOVERSION 6)
  16 # It is a bit irritating, but this has to be set separately for now!
  17 SET(CPACK_PACKAGE_VERSION_MAJOR "4")
  18 SET(CPACK_PACKAGE_VERSION_MINOR "5")
  19 SET(CPACK_PACKAGE_VERSION_PATCH "1")
  20
  21
  22 # Cmake modules/macros are in a subdirectory to keep this file cleaner
  23 set(CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake)
  24
  25 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
  26 set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "" FORCE)
  27 endif()
  28
  29 if(NOT CMAKE_BUILD_TYPE)
  30     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel." FORCE)
  31 endif(NOT CMAKE_BUILD_TYPE)
  32
  33 enable_language(C)
  34
  35 set(CPACK_PACKAGE_VERSION ${PROJECT_VERSION})
  36 set(CPACK_PACKAGE_VENDOR "gromacs.org")
  37 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Gromacs - a toolkit for high-performance molecular simulation")
  38 set(CPACK_SET_DESTDIR "ON")
  39 set(CPACK_INCLUDE_TOPLEVEL_DIRECTORY 0)
  40 set(CPACK_RESOURCE_FILE_WELCOME "${CMAKE_SOURCE_DIR}/admin/InstallWelcome.txt")
  41 # Its GPL/LGPL, so they do not have to agree to a license for mere usage, but some installers require this...
  42 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_SOURCE_DIR}/admin/InstallLicense.txt")
  43 set(CPACK_RESOURCE_FILE_README "${CMAKE_SOURCE_DIR}/admin/InstallInfo.txt")
  44
  45 #must come after all cpack settings!
  46 include(CPack)
  47
  48
  49 ########################################################################
  50 # Fix stupid flags on MSVC
  51 ########################################################################
  52 SET(SHARED_LIBS_DEFAULT ON)
  53 IF(CMAKE_GENERATOR MATCHES "Visual Studio")
  54     STRING(REPLACE /MD /MT CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE})
  55     SET(CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE} CACHE STRING "" FORCE)
  56     STRING(REPLACE /MD /MT CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG})
  57     SET(CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG} CACHE STRING "" FORCE)
  58     SET(SHARED_LIBS_DEFAULT OFF)
  59 ENDIF(CMAKE_GENERATOR MATCHES "Visual Studio")
  60
  61 set(GMX_EXTRA_LIBRARIES)
  62
  63
  64
  65 ######################################################################
  66 # compiler tests
  67 # these need ot be done early (before further tests).
  68 #####################################################################
  69
  70 include(CheckCCompilerFlag)
  71 include(CheckCXXCompilerFlag)
  72
  73 include(gmxCFlags)
  74 gmx_c_flags()
  75
  76 ########################################################################
  77 # User input options                                                   #
  78 ########################################################################
  79 option(GMX_DOUBLE "Use double precision. Much slower, use only if needed!)" OFF)
  80 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
  81 option(GMX_THREADS    "Build a parallel (thread-based) version of GROMACS)" ON)
  82 option(GMX_SOFTWARE_INVSQRT "Use GROMACS software 1/sqrt" ON)
  83 mark_as_advanced(GMX_SOFTWARE_INVSQRT)
  84 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
  85 mark_as_advanced(GMX_FAHCORE)
  86 option(GMX_OPENMM "Accelerated execution on GPUs through the OpenMM library" OFF)
  87 set(GMX_ACCELERATION "auto"
  88     CACHE STRING "Accelerated kernels. Pick one of: auto, none, SSE, BlueGene, Power6, ia64, altivec")
  89
  90 set(GMX_FFT_LIBRARY "fftw3"
  91     CACHE STRING "FFT library choices: fftw3,fftw2,mkl,fftpack[built-in]")
  92 option(GMX_DISABLE_FFTW_MEASURE
  93        "Do not optimize FFTW setups (not needed with SSE)" OFF)
  94 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
  95 set(GMX_QMMM_PROGRAM "none"
  96     CACHE STRING "QM package choices: none,gaussian,mopac,gamess,orca")
  97 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
  98 mark_as_advanced(GMX_BROKEN_CALLOC)
  99 option(BUILD_SHARED_LIBS "Enable shared libraries (can be problematic with MPI, Windows)" ${SHARED_LIBS_DEFAULT})
 100 option(GMX_MPI_IN_PLACE "Enable MPI_IN_PLACE for MPIs that have it defined" ON)
 101 mark_as_advanced(GMX_MPI_IN_PLACE)
 102 option(GMX_DLOPEN "Compile with dlopen, needed to read VMD supported file formats" ON)
 103 mark_as_advanced(GMX_DLOPEN)
 104
 105
 106 option(GMX_IA32_ASM "Add SSE assembly files for IA32" OFF)
 107 mark_as_advanced(GMX_IA32_ASM)
 108 option(GMX_X86_64_ASM "Add SSE assembly files for X86_64" OFF)
 109 mark_as_advanced(GMX_X86_64_ASM)
 110
 111 option(USE_VERSION_H "Generate development version string/information" ON)
 112 mark_as_advanced(USE_VERSION_H)
 113
 114 option(GMX_DEFAULT_SUFFIX "Use default GROMACS suffixes" ON)
 115 set(GMX_BINARY_SUFFIX "" CACHE STRING "Suffix for GROMACS binaries (default: _d for double).")
 116 set(GMX_LIBS_SUFFIX ""
 117   CACHE STRING "Suffix for GROMACS libs (default: _d for double, _mpi for mpi, _mpi_d for mpi and double).")
 118 if (GMX_DEFAULT_SUFFIX)
 119   if (GMX_MPI)
 120     set(GMX_LIBS_SUFFIX "_mpi")
 121   endif(GMX_MPI)
 122   if (GMX_DOUBLE)
 123     set (GMX_BINARY_SUFFIX "_d")
 124     set (GMX_LIBS_SUFFIX "${GMX_LIBS_SUFFIX}_d")
 125   endif(GMX_DOUBLE)
 126   mark_as_advanced(FORCE GMX_BINARY_SUFFIX GMX_LIBS_SUFFIX)
 127 else(GMX_DEFAULT_SUFFIX)
 128    mark_as_advanced(CLEAR GMX_BINARY_SUFFIX GMX_LIBS_SUFFIX)
 129 endif(GMX_DEFAULT_SUFFIX)
 130
 131 set(PKG_CFLAGS "")
 132 if(GMX_DOUBLE)
 133   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_DOUBLE")
 134 endif(GMX_DOUBLE)
 135 if(GMX_SOFTWARE_INVSQRT)
 136   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_SOFTWARE_INVSQRT")
 137 endif(GMX_SOFTWARE_INVSQRT)
 138
 139 ########################################################################
 140 #Process MPI settings
 141 ########################################################################
 142 if(GMX_MPI)
 143         MESSAGE(WARNING "
 144             There are known problems with some MPI implementations:
 145                      OpenMPI version < 1.4.1
 146                      MVAPICH2 version <= 1.4.1                               *")
 147     if(GMX_THREADS)
 148         #message(FATAL_ERROR "Thread-based parallelization conflicts with MPI.")
 149         set(GMX_THREADS OFF CACHE BOOL
 150             "Thread-based parallelization conflicts with MPI." FORCE)
 151     endif(GMX_THREADS)
 152     find_package(MPI)
 153     if(MPI_FOUND)
 154         set(GROMACS_C_FLAGS ${GROMACS_FLAGS} ${MPI_COMPILE_FLAGS})
 155         set(GROMACS_LINKER_FLAGS ${GROMACS_LINKER_FLAGS} ${MPI_LINK_FLAGS})
 156
 157         include_directories(${MPI_INCLUDE_PATH})
 158         list(APPEND GMX_EXTRA_LIBRARIES ${MPI_LIBRARIES})
 159         add_definitions( -DMPI ) #for FAHCORE
 160         include(gmxTestMPI_IN_PLACE)
 161         if (GMX_MPI_IN_PLACE)
 162             gmx_test_mpi_in_place(MPI_IN_PLACE_EXISTS)
 163         endif (GMX_MPI_IN_PLACE)
 164     else(MPI_FOUND)
 165         message(FATAL_ERROR "MPI support requested, but no MPI compiler found.")
 166     endif(MPI_FOUND)
 167     include(gmxTestCatamount)
 168     gmx_test_catamount(GMX_CRAY_XT3)
 169     if(GMX_CRAY_XT3)
 170         set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_CRAY_XT3")
 171         set(GMX_NO_SYSTEM 1)
 172         set(GMX_NO_NICE 1)
 173     endif(GMX_CRAY_XT3)
 174     set(GMX_LIB_MPI 1)
 175     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_LIB_MPI")
 176 endif(GMX_MPI)
 177
 178
 179 #######################################################################
 180 # Check for options incompatible with OpenMM build                    #
 181 #######################################################################
 182 if(GMX_OPENMM)
 183     cmake_minimum_required(VERSION 2.6.4)
 184     # we'll use the built-in fft to avoid unnecessary dependencies
 185     message(STATUS "No external FFT libraries needed for the OpenMM build, using fftpack!")
 186     set (GMX_FFT_LIBRARY "fftpack" CACHE STRING
 187                 "No external FFT libraries needed for the OpenMM build, using fftpack!" FORCE)
 188     if(GMX_MPI)
 189         message(FATAL_ERROR "The OpenMM build is not compatible with MPI!")
 190     endif(GMX_MPI)
 191     if(GMX_THREADS)
 192         message(STATUS "Threads not compatible with OpenMM build, disabled!")
 193         set(GMX_THREADS OFF CACHE BOOL
 194                 "Threads not compatible with OpenMM build, disabled!" FORCE)
 195     endif(GMX_THREADS)
 196     if(GMX_SOFTWARE_INVSQRT)
 197         set(GMX_SOFTWARE_INVSQRT OFF FORCE)
 198     endif(GMX_SOFTWARE_INVSQRT)
 199     if(NOT GMX_ACCELERATION MATCHES "^(none|None|NONE)")
 200         message(WARNING "CPU-based acceleration turned off, OpenMM does not support/need any!")
 201         unset(GMX_ACCELERATION CACHE)
 202         set(GMX_ACCELERATION "none" CACHE STRING
 203                 "CPU-based acceleration turned off, OpenMM does not support/need any!" FORCE)
 204     endif()
 205     if(GMX_FAHCORE)
 206         message(FATAL_ERROR "The OpenMM build does not support FAH build!")
 207     endif(GMX_FAHCORE)
 208     set(GMX_DOUBLE OFF FORCE )
 209     # mark as advanced the unused variables
 210     mark_as_advanced(FORCE GMX_ACCELERATION GMX_MPI GMX_FFT_LIBRARY
 211         GMX_QMMM_PROGRAM GMX_THREADS GMX_DOUBLE)
 212 else(GMX_OPENMM)
 213      mark_as_advanced(CLEAR GMX_ACCELERATION GMX_MPI GMX_FFT_LIBRARY
 214         GMX_QMMM_PROGRAM GMX_THREADS GMX_DOUBLE)
 215 endif(GMX_OPENMM)
 216
 217
 218 ########################################################################
 219 # Basic system tests (standard libraries, headers, functions, types)   #
 220 ########################################################################
 221 include(CheckIncludeFiles)
 222 check_include_files(string.h     HAVE_STRING_H)
 223 check_include_files(math.h       HAVE_MATH_H)
 224 check_include_files(limits.h     HAVE_LIMITS_H)
 225 check_include_files(memory.h     HAVE_MEMORY_H)
 226 check_include_files(unistd.h     HAVE_UNISTD_H)
 227 check_include_files(pwd.h        HAVE_PWD_H)
 228 check_include_files(stdint.h     HAVE_STDINT_H)
 229 check_include_files(stdlib.h     HAVE_STDLIB_H)
 230 check_include_files(pthread.h    HAVE_PTHREAD_H)
 231 check_include_files(dirent.h     HAVE_DIRENT_H)
 232 check_include_files(inttypes.h   HAVE_INTTYPES_H)
 233 check_include_files(regex.h      HAVE_REGEX_H)
 234 check_include_files(sys/types.h  HAVE_SYS_TYPES_H)
 235 check_include_files(sys/stat.h   HAVE_SYS_STAT_H)
 236 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 237 check_include_files(rpc/rpc.h    HAVE_RPC_RPC_H)
 238 check_include_files("rpc/rpc.h;rpc/xdr.h"    HAVE_RPC_XDR_H)
 239 # SSE support
 240 check_include_files(xmmintrin.h  HAVE_XMMINTRIN_H)
 241 check_include_files(emmintrin.h  HAVE_EMMINTRIN_H)
 242 check_include_files(pmmintrin.h  HAVE_PMMINTRIN_H)
 243 check_include_files(smmintrin.h  HAVE_SMMINTRIN_H)
 244 check_include_files(io.h                 HAVE_IO_H)
 245
 246
 247 include(CheckFunctionExists)
 248 check_function_exists(strcasecmp        HAVE_STRCASECMP)
 249 check_function_exists(strdup            HAVE_STRDUP)
 250 check_function_exists(vprintf           HAVE_VPRINTF)
 251 check_function_exists(memcmp            HAVE_MEMCMP)
 252 check_function_exists(posix_memalign    HAVE_POSIX_MEMALIGN)
 253 check_function_exists(memalign          HAVE_MEMALIGN)
 254 check_function_exists(_aligned_malloc   HAVE__ALIGNED_MALLOC)
 255 check_function_exists(gettimeofday      HAVE_GETTIMEOFDAY)
 256 check_function_exists(isnan             HAVE_ISNAN)
 257 check_function_exists(_isnan            HAVE__ISNAN)
 258 check_function_exists(isfinite          HAVE_ISFINITE)
 259 check_function_exists(_isfinite         HAVE__ISFINITE)
 260 check_function_exists(fsync             HAVE_FSYNC)
 261 check_function_exists(_fileno           HAVE__FILENO)
 262 check_function_exists(fileno            HAVE_FILENO)
 263 check_function_exists(_commit           HAVE__COMMIT)
 264
 265 include(CheckLibraryExists)
 266 check_library_exists(m sqrt "" HAVE_LIBM)
 267 check_library_exists(m cbrt "" HAVE_CBRT)
 268
 269
 270 include(CheckTypeSize)
 271
 272 check_type_size("bool"          SIZEOF_BOOL) # will also set HAVE_BOOL
 273 check_type_size("int"           SIZEOF_INT)
 274 check_type_size("long int"      SIZEOF_LONG_INT)
 275 check_type_size("long long int" SIZEOF_LONG_LONG_INT)
 276 check_type_size("off_t"         SIZEOF_OFF_T)
 277 check_type_size("void *"        SIZEOF_VOIDP)
 278
 279 if (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 280     set(GMX_64_BIT TRUE)
 281 else (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 282     set(GMX_64_BIT FALSE)
 283 endif (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 284
 285 # Check for some basic types that we *need*, so set these to int if they are not present
 286 check_type_size(uid_t uid_t)
 287 if(NOT uid_t)
 288   set(uid_t int)
 289 else(NOT uid_t)
 290   set(uid_t 0)
 291 endif(NOT uid_t)
 292
 293 check_type_size(gid_t gid_t)
 294 if(NOT gid_t)
 295   set(gid_t 1)
 296 else(NOT gid_t)
 297   set(gid_t 0)
 298 endif(NOT gid_t)
 299
 300 check_type_size(size_t size_t)
 301 if(NOT size_t)
 302   set(size_t int)
 303 else(NOT size_t)
 304   set(size_t 0)
 305 endif(NOT size_t)
 306
 307 check_type_size(off_t off_t)
 308 if(NOT off_t)
 309   set(off_t int)
 310 else(NOT off_t)
 311   set(off_t 0)
 312 endif(NOT off_t)
 313
 314 include(TestBigEndian)
 315 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 316
 317
 318
 319
 320 ########################################################################
 321 # Find external packages                                               #
 322 ########################################################################
 323
 324 find_package(LibXml2)
 325 set(PKG_XML "")
 326 if(LIBXML2_FOUND)
 327     include_directories(${LIBXML2_INCLUDE_DIR})
 328     set(PKG_XML libxml-2.0)
 329     set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 330     set(HAVE_LIBXML2 1)
 331 endif(LIBXML2_FOUND)
 332
 333 option(GMX_X11 "Use X window system" OFF)
 334 if (GMX_X11)
 335         find_package(X11)
 336         # X11 includes/libraries are only set in the ngmx subdirectory!
 337         if(X11_FOUND)
 338         set(HAVE_X11 1)
 339         endif(X11_FOUND)
 340 endif(GMX_X11)
 341
 342 if(GMX_THREADS)
 343     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_THREADS")
 344     include(ThreadMPI)
 345     set(THREAD_MPI_LIB thread_mpi)
 346     set(GMX_MPI 1)
 347     string(TOUPPER ${GMX_FFT_LIBRARY} ${GMX_FFT_LIBRARY})
 348     if(${GMX_FFT_LIBRARY} STREQUAL "FFTW2")
 349         message(FATAL_ERROR "FFTW2 can't be used with threads. Try fftw3 or mkl.")
 350     endif()
 351 endif(GMX_THREADS)
 352
 353 if(GMX_OPENMM)
 354     set(CUDA_BUILD_EMULATION OFF)
 355     find_package(CUDA 3.1 REQUIRED)
 356     add_definitions(-DGMX_OPENMM)
 357     if(CMAKE_BUILD_TYPE STREQUAL "DEBUG")
 358         set(CUDA_VERBOSE_BUILD ON)
 359     endif()
 360     find_package(OpenMM)
 361 endif(GMX_OPENMM)
 362
 363 if(APPLE)
 364    find_library(ACCELERATE_FRAMEWORK Accelerate)
 365    list(APPEND GMX_EXTRA_LIBRARIES ${ACCELERATE_FRAMEWORK})
 366 endif(APPLE)
 367
 368 # only bother with finding git and using version.h if the source is a git repo
 369 if(EXISTS "${CMAKE_SOURCE_DIR}/.git")
 370     if(USE_VERSION_H)
 371         # We need at least git v1.5.1 be able to parse git's date output. If not
 372         # fund or the version is too small, we can't generate version information.
 373         find_package(Git 1.5.1)
 374         # this should at some point become VERSION_LESS
 375         if(NOT Git_FOUND OR Git_VERSION STRLESS "1.5.1")
 376             message("No compatible git version found, won't be able to generate proper development version information.")
 377         endif()
 378     endif()
 379 else()
 380     set(USE_VERSION_H OFF)
 381 endif()
 382
 383 if (GMX_DLOPEN)
 384     list(APPEND GMX_EXTRA_LIBRARIES ${CMAKE_DL_LIBS})
 385 endif (GMX_DLOPEN)
 386
 387 ########################################################################
 388 # Generate development version info for cache
 389 ########################################################################
 390 # set(GEN_VERSION_INFO_INTERNAL "ON")
 391 # include(gmxGenerateVersionString)
 392
 393 ########################################################################
 394 # Our own GROMACS tests
 395 ########################################################################
 396
 397 add_definitions( -DHAVE_CONFIG_H )
 398 include_directories(${CMAKE_BINARY_DIR}/src)
 399 include_directories(${CMAKE_SOURCE_DIR}/include)
 400
 401 include(gmxCheckBuildUserTime)
 402 gmx_check_build_user_time(BUILD_TIME BUILD_USER BUILD_MACHINE)
 403
 404 include(gmxTestFloatFormat)
 405 gmx_test_float_format(GMX_FLOAT_FORMAT_IEEE754
 406                       GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER
 407                       GMX_IEEE754_BIG_ENDIAN_WORD_ORDER)
 408
 409 include(gmxTestLargeFiles)
 410 gmx_test_large_files(GMX_LARGEFILES)
 411 check_function_exists(fseeko     HAVE_FSEEKO)
 412
 413 include(gmxTestSignal)
 414 gmx_test_retsigtype(RETSIGTYPE)
 415 gmx_test_sigusr1(HAVE_SIGUSR1)
 416
 417 include(gmxTestInline)
 418 gmx_test_inline(INLINE_KEYWORD)
 419
 420 include(gmxTestRestrict)
 421 gmx_test_inline(RESTRICT_KEYWORD)
 422
 423 include(gmxTestPipes)
 424 gmx_test_pipes(HAVE_PIPES)
 425
 426 include(gmxTestInlineASM)
 427 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 428 gmx_test_inline_asm_msvc_x86(GMX_X86_MSVC_INLINE_ASM)
 429
 430 # turn on SSE if supported with reasonable defaults.
 431 if (${GMX_ACCELERATION} STREQUAL "auto" AND NOT GMX_OPENMM)
 432   if(CMAKE_SYSTEM_PROCESSOR MATCHES "^(i.86|x86|x64|x86_64|AMD64|amd64)")
 433
 434     set(GMX_ACCELERATION "SSE" CACHE STRING "Accelerated kernels. Pick one of: auto, none, SSE, BlueGene, Power6, ia64, altivec" FORCE)
 435
 436     if (GMX_64_BIT)
 437       set(GMX_X86_64_ASM ON CACHE BOOL "Add SSE assembly files for x86_64" FORCE)
 438     else (GMX_64_BIT)
 439       set(GMX_IA32_ASM ON CACHE BOOL "Add SSE assembly files for i386" FORCE)
 440     endif (GMX_64_BIT)
 441
 442     # Determine the assembler/compiler to use
 443   else()
 444     set(GMX_ACCELERATION "none" CACHE STRING "Accelerated kernels. Pick one of: auto, none, SSE, BlueGene, Power6, ia64, altivec" FORCE)
 445   endif()
 446 endif (${GMX_ACCELERATION} STREQUAL "auto" AND NOT GMX_OPENMM)
 447
 448
 449 include(gmxTestXDR)
 450 gmx_test_xdr(GMX_SYSTEM_XDR)
 451 if(NOT GMX_SYSTEM_XDR)
 452     set(GMX_INTERNAL_XDR 1)
 453     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_INTERNAL_XDR")
 454 endif(NOT GMX_SYSTEM_XDR)
 455
 456 if(GMX_FORTRAN OR GMX_POWER6)
 457     enable_language(Fortran)
 458     include(FortranCInterface)
 459     discover_fortran_mangling(prefix isupper suffix extra_under_score found)
 460     if(extra_under_score)
 461         set(extrasuffix "_")
 462     endif(extra_under_score)
 463
 464     if(isupper)
 465         set(F77_FUNCDEF   "${prefix} ## NAME ## ${suffix}")
 466         set(F77_FUNCDEF_  "${prefix} ## NAME ## ${suffix}${extrasuffix}")
 467     else(isupper)
 468         set(F77_FUNCDEF   "${prefix} ## name ## ${suffix}")
 469         set(F77_FUNCDEF_  "${prefix} ## name ## ${suffix}${extrasuffix}")
 470     endif(isupper)
 471 else(GMX_FORTRAN OR GMX_POWER6)
 472         set(F77_FUNCDEF   "name ## _")
 473         set(F77_FUNCDEF_  "name ## _")
 474 endif(GMX_FORTRAN OR GMX_POWER6)
 475
 476
 477 # Process nonbonded accelerated kernels settings
 478 string(TOUPPER ${GMX_ACCELERATION} ${GMX_ACCELERATION})
 479 if(${GMX_ACCELERATION} STREQUAL "NONE")
 480   # nothing to do
 481 elseif(${GMX_ACCELERATION} STREQUAL "SSE")
 482
 483     if(CMAKE_GENERATOR MATCHES "Visual Studio")
 484       option(GMX_ASM_USEASM-NASM "Use Nasm for assembly instead of compiler (necessary on windows)" ON)
 485     else()
 486       option(GMX_ASM_USEASM-NASM "Use Nasm for assembly instead of compiler (necessary on windows)" OFF)
 487     endif()
 488         mark_as_advanced(GMX_ASM_USEASM-NASM)
 489
 490     if (NOT GMX_64_BIT)
 491         # for 32-bit compiles, we might need to turn on sse
 492         CHECK_C_COMPILER_FLAG("-msse2" XFLAGS_SSE)
 493         if (XFLAGS_SSE)
 494             set(GROMACS_C_FLAGS "-msse2 ${GROMACS_C_FLAGS}")
 495         endif (XFLAGS_SSE)
 496         CHECK_CXX_COMPILER_FLAG("-msse2" XXFLAGS_SSE)
 497         if (XXFLAGS_SSE)
 498             set(GROMACS_CXX_FLAGS "-msse2 ${GROMACS_CXX_FLAGS}")
 499         endif (XXFLAGS_SSE)
 500     endif (NOT GMX_64_BIT)
 501
 502     if(GMX_IA32_ASM)
 503       if(GMX_DOUBLE)
 504         set(GMX_IA32_SSE2 1)
 505       else()
 506         set(GMX_IA32_SSE 1)
 507       endif()
 508     elseif(GMX_X86_64_ASM)
 509       if(GMX_DOUBLE)
 510         set(GMX_X86_64_SSE2 1)
 511       else()
 512         set(GMX_X86_64_SSE 1)
 513       endif()
 514     endif()
 515
 516 #    if(HAVE_PMMINTRIN_H)
 517 #        set(GMX_SSE3 1)
 518 #    endif(HAVE_PMMINTRIN_H)
 519 #    if(HAVE_SMMINTRIN_H)
 520 #        set(GMX_SSE4_1 1)
 521 #    endif(HAVE_SMMINTRIN_H)
 522
 523 elseif(${GMX_ACCELERATION} STREQUAL "FORTRAN")
 524     set(GMX_FORTRAN 1)
 525 elseif(${GMX_ACCELERATION} STREQUAL "BLUEGENE")
 526     set(GMX_BLUEGENE 1)
 527 elseif(${GMX_ACCELERATION} STREQUAL "POWER6")
 528     set(GMX_POWER6 1)
 529 elseif(${GMX_ACCELERATION} STREQUAL "IA64")
 530     set(GMX_IA64_ASM 1)
 531     set(DISABLE_WATERWATER_NLIST 1)
 532     set(DISABLE_WATER_NLIST 1)
 533 elseif(${GMX_ACCELERATION} STREQUAL "ALTIVEC")
 534     check_include_files(altivec.h HAVE_ALTIVEC_H)
 535     if(HAVE_ALTIVEC_H)
 536         set(GMX_PPC_ALTIVEC 1)
 537     endif(HAVE_ALTIVEC_H)
 538 else(${GMX_ACCELERATION} STREQUAL "NONE")
 539     MESSAGE(FATAL_ERROR "Unrecognized option for accelerated kernels: ${GMX_ACCELERATION}. Pick one of auto, none, SSE, Fortran, BlueGene, Power6, ia64, altivec")
 540 endif(${GMX_ACCELERATION} STREQUAL "NONE")
 541
 542
 543
 544
 545
 546
 547
 548 # Process QM/MM Settings
 549 string(TOUPPER ${GMX_QMMM_PROGRAM} ${GMX_QMMM_PROGRAM})
 550 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 551     set(GMX_QMMM_GAUSSIAN 1)
 552 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 553     set(GMX_QMMM_MOPAC 1)
 554 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 555     set(GMX_QMMM_GAMESS 1)
 556 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 557     set(GMX_QMMM_ORCA 1)
 558 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 559     # nothing to do
 560 else(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 561     MESSAGE(FATAL_ERROR "Invalid QM/MM program option: ${GMX_QMMM_PROGRAM}. Choose one of: Gaussian, Mopac, Gamess, Orca, None")
 562 endif(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 563
 564 # Process FFT library settings - if not OpenMM build
 565 string(TOUPPER ${GMX_FFT_LIBRARY} ${GMX_FFT_LIBRARY})
 566 set(PKG_FFT "")
 567 set(PKG_FFT_LIBS "")
 568 if(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 569 #    MESSAGE(STATUS "Using external FFT library - fftw3")
 570     if(GMX_DOUBLE)
 571         find_package(FFTW3 REQUIRED)
 572                 include_directories(${FFTW3_INCLUDE_DIR})
 573         set(FFT_LIBRARIES ${FFTW3_LIBRARIES})
 574         set(PKG_FFT "fftw3")
 575     else(GMX_DOUBLE)
 576         find_package(FFTW3F REQUIRED)
 577         include_directories(${FFTW3F_INCLUDE_DIR})
 578         set(FFT_LIBRARIES ${FFTW3F_LIBRARIES})
 579         set(PKG_FFT "fftw3f")
 580     endif(GMX_DOUBLE)
 581
 582     if(NOT FFTW3_FOUND AND NOT FFTW3F_FOUND)
 583         MESSAGE(FATAL_ERROR "Cannot find fftw3 (with correct precision). Fix it, choose another FFT library, or use the Gromacs built-in fftpack (slower)!")
 584     endif(NOT FFTW3_FOUND AND NOT FFTW3F_FOUND)
 585
 586     set(GMX_FFT_FFTW3 1)
 587
 588 elseif(${GMX_FFT_LIBRARY} STREQUAL "FFTW2")
 589 #    MESSAGE(STATUS "Using external FFT library - fftw2")
 590     if(GMX_DOUBLE)
 591         find_package(FFTW2 REQUIRED)
 592     else(GMX_DOUBLE)
 593         find_package(FFTW2F REQUIRED)
 594     endif(GMX_DOUBLE)
 595
 596     if(NOT FFTW2_FOUND)
 597            MESSAGE(FATAL_ERROR "Cannot find fftw2 (with correct precision). Fix it, choose another FFT library, or use the Gromacs built-in fftpack (slower)!")
 598     endif(NOT FFTW2_FOUND)
 599     include_directories(${FFTW2_INCLUDE_DIR})
 600     set(FFT_LIBRARIES ${FFTW2_LIBRARIES})
 601     set(PKG_FFT_LIBS ${FFTW2_LIBRARIES})
 602
 603     if("${FFTW2_LIBRARIES}" MATCHES "dfftw")
 604         set(FFTW2_NAME_DFFTW 1)
 605     elseif("${FFTW2_LIBRARIES}" MATCHES "sfftw")
 606         set(FFTW2_NAME_SFFTW 1)
 607     else("${FFTW2_LIBRARIES}" MATCHES "dfftw")
 608         set(FFTW2_NAME_FFTW 1)
 609     endif("${FFTW2_LIBRARIES}" MATCHES "dfftw")
 610
 611     set(GMX_FFT_FFTW2 1)
 612 elseif(${GMX_FFT_LIBRARY} STREQUAL "MKL")
 613 #    MESSAGE(STATUS "Using external FFT library - Intel MKL")
 614     find_package(MKL REQUIRED)
 615     include_directories(${MKL_INCLUDE_DIR})
 616     set(FFT_LIBRARIES ${MKL_LIBRARIES})
 617     set(PKG_FFT_LIBS ${MKL_LIBRARIES})
 618
 619     set(GMX_FFT_MKL 1)
 620     set(HAVE_MKL 1)
 621
 622 #elseif(${GMX_FFT_LIBRARY} STREQUAL "ACML")
 623 #    MESSAGE(STATUS "Using external FFT library - AMD core math library")
 624 #    set(GMX_FFT_ACML 1)
 625 elseif(${GMX_FFT_LIBRARY} STREQUAL "FFTPACK")
 626     MESSAGE(STATUS "Using internal FFT library - fftpack")
 627     set(GMX_FFT_FFTPACK 1)
 628 else(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 629     MESSAGE(FATAL_ERROR "Invalid FFT library setting: ${GMX_FFT_LIBRARY}. Choose one of: fftw3, fftw2, mkl, acml, fftpack")
 630 endif(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 631
 632 # MKL has BLAS/LAPACK routines
 633 if(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 634   set(GMX_EXTERNAL_BLAS TRUE CACHE BOOL "Use external BLAS instead of built-in")
 635   set(GMX_EXTERNAL_LAPACK TRUE CACHE BOOL "Use external LAPACK instead of built-in")
 636 else(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 637   set(GMX_EXTERNAL_BLAS FALSE CACHE BOOL "Use external LAPACK instead of built-in")
 638   set(GMX_EXTERNAL_LAPACK FALSE CACHE BOOL "Use external LAPACK instead of built-in")
 639 endif(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 640 mark_as_advanced(GMX_EXTERNAL_LAPACK)
 641 mark_as_advanced(GMX_EXTERNAL_BLAS)
 642
 643 # Math and thread libraries must often come after all others when linking...
 644 if(HAVE_LIBM)
 645     list(APPEND GMX_EXTRA_LIBRARIES m)
 646 endif(HAVE_LIBM)
 647
 648
 649
 650 if(GMX_FAHCORE)
 651   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 652       "Path to swindirect.h")
 653   include_directories(${COREWRAP_INCLUDE_DIR})
 654 endif(GMX_FAHCORE)
 655
 656 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 657 # these are set after everything else
 658 if (NOT DEFINED GROMACS_C_FLAGS_SET)
 659     set(GROMACS_C_FLAGS_SET true CACHE INTERNAL "Whether to reset the C flags"
 660         FORCE)
 661     set(CMAKE_C_FLAGS "${GROMACS_C_FLAGS} ${CMAKE_C_FLAGS}" CACHE STRING
 662         "Flags used by the compiler during all build types" FORCE)
 663     set(CMAKE_CXX_FLAGS "${GROMACS_CXX_FLAGS} ${CMAKE_CXX_FLAGS}" CACHE STRING
 664         "Flags used by the compiler during all build types" FORCE)
 665     set(CMAKE_EXE_LINKER_FLAGS
 666         "${GROMACS_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}"
 667         CACHE STRING "Linker flags" FORCE)
 668 endif (NOT DEFINED GROMACS_C_FLAGS_SET)
 669
 670 ########################################################################
 671 # Specify install locations and which subdirectories to process        #
 672 ########################################################################
 673 set(LIB_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/lib)
 674 set(BIN_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/bin)
 675 set(DATA_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/gromacs)
 676 set(MAN_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/share/man)
 677 set(INCL_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/include)
 678
 679 set(GMXLIBDIR        ${DATA_INSTALL_DIR}/top)
 680
 681 ##################################################################
 682 # Shared library settings - Darwin uses INSTALL_NAME_DIR instead!
 683 ##################################################################
 684 if(NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin")
 685     set(CMAKE_SKIP_BUILD_RPATH  FALSE)
 686     set(CMAKE_BUILD_WITH_INSTALL_RPATH TRUE)
 687     set(CMAKE_INSTALL_RPATH "${LIB_INSTALL_DIR}")
 688     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 689 endif()
 690
 691 add_subdirectory(share)
 692 add_subdirectory(include)
 693 add_subdirectory(man)
 694 add_subdirectory(src)
 695 add_subdirectory(scripts)
 696
 697 #######################
 698 ## uninstall target
 699 #######################
 700     CONFIGURE_FILE(
 701                    "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 702                    "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
 703                    IMMEDIATE @ONLY)
 704 ###########################
 705 ADD_CUSTOM_TARGET(uninstall
 706                   "${CMAKE_COMMAND}" -P
 707                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
 708 ###########################
 709
 710
 711 ########################################################################
 712 # Tests                                                                #
 713 ########################################################################
 714
 715 include(CTest)
 716 mark_as_advanced(BUILD_TESTING)
 717 IF(BUILD_TESTING)
 718         enable_testing()
 719         add_test(TestBuildAll make)
 720         add_subdirectory(tests)
 721 ENDIF()
 722