CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.8)
   2 # Keep CMake suitably quiet on Cygwin
   3 set(CMAKE_LEGACY_CYGWIN_WIN32 0) # Remove when CMake >= 2.8.4 is required
   4
   5 project(Gromacs)
   6 include(Dart)
   7 mark_as_advanced(DART_ROOT)
   8
   9 # PROJECT_VERSION should have the following structure:
  10 # VERSION-dev[-SUFFIX] where the VERSION should have the for: vMajor.vMinor.vPatch
  11 #
  12 # The "-dev" suffix is important to keep because it makes possible to distinguish
  13 # between a build from official release and a build from git release branch on a
  14 # machine with no git.
  15 #
  16 # NOTE: when releasing the "-dev" suffix needs to be stripped off!
  17 set(PROJECT_VERSION "5.0-dev")
  18 set(CUSTOM_VERSION_STRING ""
  19     CACHE STRING "Custom version string (if empty, use hard-coded default)")
  20 mark_as_advanced(CUSTOM_VERSION_STRING)
  21 if (CUSTOM_VERSION_STRING)
  22     set(PROJECT_VERSION ${CUSTOM_VERSION_STRING})
  23 endif (CUSTOM_VERSION_STRING)
  24 set(SOVERSION 6)
  25 # It is a bit irritating, but this has to be set separately for now!
  26 SET(CPACK_PACKAGE_VERSION_MAJOR "4")
  27 SET(CPACK_PACKAGE_VERSION_MINOR "6")
  28 #SET(CPACK_PACKAGE_VERSION_PATCH "0")
  29
  30
  31 # Cmake modules/macros are in a subdirectory to keep this file cleaner
  32 set(CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake)
  33
  34 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
  35 set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
  36 endif()
  37
  38 if(NOT CMAKE_BUILD_TYPE)
  39     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel." FORCE)
  40 endif(NOT CMAKE_BUILD_TYPE)
  41
  42 enable_language(C)
  43 enable_language(CXX)
  44
  45 set(CPACK_PACKAGE_VERSION ${PROJECT_VERSION})
  46 set(CPACK_PACKAGE_VENDOR "gromacs.org")
  47 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Gromacs - a toolkit for high-performance molecular simulation")
  48 set(CPACK_SET_DESTDIR "ON")
  49 set(CPACK_INCLUDE_TOPLEVEL_DIRECTORY 0)
  50 set(CPACK_RESOURCE_FILE_WELCOME "${CMAKE_SOURCE_DIR}/admin/InstallWelcome.txt")
  51 # Its GPL/LGPL, so they do not have to agree to a license for mere usage, but some installers require this...
  52 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_SOURCE_DIR}/admin/InstallLicense.txt")
  53 set(CPACK_RESOURCE_FILE_README "${CMAKE_SOURCE_DIR}/admin/InstallInfo.txt")
  54
  55 #must come after all cpack settings!
  56 include(CPack)
  57
  58 ########################################################################
  59 # Check and warn if cache generated on a different host is being reused
  60 ########################################################################
  61 if(CMAKE_HOST_UNIX)
  62     execute_process(COMMAND hostname
  63                     OUTPUT_VARIABLE TMP_HOSTNAME
  64                     OUTPUT_STRIP_TRAILING_WHITESPACE)
  65     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}")
  66         message(WARNING "
  67             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
  68             is being reused! This could lead to inconsitencies; therefore, it is
  69             recommended to regenerate the cache!")
  70     endif()
  71     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
  72             "Hostname of the machine where the cache was generated.")
  73 endif()
  74
  75 ########################################################################
  76 # Fix stupid flags on Windows
  77 ########################################################################
  78 SET(SHARED_LIBS_DEFAULT ON)
  79 IF( WIN32 AND NOT CYGWIN)
  80   option(GMX_PREFER_STATIC_LIBS "When finding libraries prefer static system libraries (MT instead of MD)!" ON)
  81   mark_as_advanced(GMX_PREFER_STATIC_LIBS)
  82   SET(SHARED_LIBS_DEFAULT OFF)  #is currently not working on Windows
  83   # This makes windows.h not declare min/max as macros that would break
  84   # C++ code using std::min/std::max.
  85   add_definitions(-DNOMINMAX)
  86
  87   IF (GMX_PREFER_STATIC_LIBS)
  88     #Only setting Debug and Release flags. Others configurations current not used.
  89     STRING(REPLACE /MD /MT CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE})
  90     SET(CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE} CACHE STRING "" FORCE)
  91     STRING(REPLACE /MD /MT CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG})
  92     SET(CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG} CACHE STRING "" FORCE)
  93     STRING(REPLACE /MD /MT CMAKE_CXX_FLAGS_RELEASE ${CMAKE_CXX_FLAGS_RELEASE})
  94     SET(CMAKE_CXX_FLAGS_RELEASE ${CMAKE_CXX_FLAGS_RELEASE} CACHE STRING "" FORCE)
  95     STRING(REPLACE /MD /MT CMAKE_CXX_FLAGS_DEBUG ${CMAKE_CXX_FLAGS_DEBUG})
  96     SET(CMAKE_CXX_FLAGS_DEBUG ${CMAKE_CXX_FLAGS_DEBUG} CACHE STRING "" FORCE)
  97   ENDIF()
  98
  99   #Workaround for cmake bug 13174. Replace deprecated options.
 100   IF( CMAKE_C_COMPILER_ID MATCHES "Intel" )
 101     STRING(REPLACE /GZ /RTC1 CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG})
 102     SET(CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG} CACHE STRING "" FORCE)
 103   ENDIF()
 104   IF( CMAKE_CXX_COMPILER_ID MATCHES "Intel" )
 105     STRING(REPLACE /GZ /RTC1 CMAKE_CXX_FLAGS_DEBUG ${CMAKE_CXX_FLAGS_DEBUG})
 106     STRING(REPLACE /GX /EHsc CMAKE_CXX_FLAGS_DEBUG ${CMAKE_CXX_FLAGS_DEBUG})
 107     SET(CMAKE_CXX_FLAGS_DEBUG ${CMAKE_CXX_FLAGS_DEBUG} CACHE STRING "" FORCE)
 108
 109     STRING(REPLACE /GX /EHsc CMAKE_CXX_FLAGS_RELEASE ${CMAKE_CXX_FLAGS_RELEASE})
 110     SET(CMAKE_CXX_FLAGS_RELEASE ${CMAKE_CXX_FLAGS_RELEASE} CACHE STRING "" FORCE)
 111   ENDIF()
 112 ENDIF()
 113
 114 ########################################################################
 115 # User input options                                                   #
 116 ########################################################################
 117 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" OFF)
 118 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 119 option(GMX_THREAD_MPI  "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" ON)
 120 option(GMX_SOFTWARE_INVSQRT "Use GROMACS software 1/sqrt" ON)
 121 mark_as_advanced(GMX_SOFTWARE_INVSQRT)
 122 option(GMX_POWERPC_INVSQRT "Use PowerPC hardware 1/sqrt" OFF)
 123 mark_as_advanced(GMX_POWERPC_INVSQRT)
 124 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 125 mark_as_advanced(GMX_FAHCORE)
 126 option(GMX_OPENMM "Accelerated execution on GPUs through the OpenMM library (rerun cmake after changing to see relevant options)" OFF)
 127 set(GMX_ACCELERATION "auto"
 128     CACHE STRING "Accelerated kernels. Pick one of: auto, none, SSE, BlueGene, Power6, ia64, altivec, fortran")
 129
 130 set(GMX_FFT_LIBRARY "fftw3"
 131     CACHE STRING "FFT library choices: fftw3,mkl,fftpack[built-in]")
 132 option(GMX_DISABLE_FFTW_MEASURE
 133        "Do not optimize FFTW setups (not needed with SSE)" OFF)
 134 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 135 set(GMX_QMMM_PROGRAM "none"
 136     CACHE STRING "QM package choices: none,gaussian,mopac,gamess,orca")
 137 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 138 mark_as_advanced(GMX_BROKEN_CALLOC)
 139 option(BUILD_SHARED_LIBS "Enable shared libraries (can be problematic with MPI, Windows)" ${SHARED_LIBS_DEFAULT})
 140 option(GMX_MPI_IN_PLACE "Enable MPI_IN_PLACE for MPIs that have it defined" ON)
 141 mark_as_advanced(GMX_MPI_IN_PLACE)
 142 option(GMX_LOAD_PLUGINS "Compile with plugin support, needed to read VMD supported file formats" ON)
 143 mark_as_advanced(GMX_LOAD_PLUGINS)
 144
 145
 146 option(GMX_IA32_ASM "Add SSE assembly files for IA32" OFF)
 147 mark_as_advanced(GMX_IA32_ASM)
 148 option(GMX_X86_64_ASM "Add SSE assembly files for X86_64" OFF)
 149 mark_as_advanced(GMX_X86_64_ASM)
 150
 151 option(GMX_OPENMP "Enable OpenMP-based mutithreading. " ON)
 152
 153 option(USE_VERSION_H "Generate development version string/information" ON)
 154 mark_as_advanced(USE_VERSION_H)
 155
 156 option(GMX_DEFAULT_SUFFIX "Use default suffixes for GROMACS binaries and libs (_d for double, _mpi for MPI; rerun cmake after changing to see relevant options)" ON)
 157
 158 if(UNIX AND NOT APPLE)
 159     option(GMX_PREFER_STATIC_LIBS "When finding libraries prefer \".a\" static archives (NOTE: this is enabled only for UNIX (excluding APPLE) platforms but it might not always work!" OFF)
 160     mark_as_advanced(GMX_PREFER_STATIC_LIBS)
 161 endif()
 162
 163
 164 ######################################################################
 165 # compiler tests
 166 # these need ot be done early (before further tests).
 167 #####################################################################
 168
 169 # cmake/Check{C,CXX}CompilerFlag.cmake are lifted from CMake git next
 170 # branch (proposed for v2.8.9) to be able to detect invalid options
 171 # with the Intel Compilers.
 172 # Remove these files from the source tree when a CMake version that
 173 # includes the features in question becomes required.
 174 include(CheckCCompilerFlag)
 175 include(CheckCXXCompilerFlag)
 176
 177 include(gmxCFlags)
 178 gmx_c_flags()
 179
 180
 181 ########################################################################
 182 # Set up binary and library suffixing
 183 ########################################################################
 184 set(GMX_BINARY_SUFFIX "" CACHE STRING "Suffix for GROMACS binaries (default: _d for double, _mpi for MPI, _mpi_d for MPI and double).")
 185 set(GMX_LIBS_SUFFIX ""
 186   CACHE STRING "Suffix for GROMACS libs (default: _d for double, _mpi for MPI, _mpi_d for MPI and double).")
 187 if (GMX_DEFAULT_SUFFIX)
 188   set(GMX_BINARY_SUFFIX "")
 189   set(GMX_LIBS_SUFFIX "")
 190   if (GMX_MPI)
 191     set(GMX_BINARY_SUFFIX "_mpi")
 192     set(GMX_LIBS_SUFFIX "_mpi")
 193   endif(GMX_MPI)
 194   if (GMX_DOUBLE)
 195     set (GMX_BINARY_SUFFIX "${GMX_BINARY_SUFFIX}_d")
 196     set (GMX_LIBS_SUFFIX "${GMX_LIBS_SUFFIX}_d")
 197   endif(GMX_DOUBLE)
 198   if (GMX_OPENMM)
 199     set (GMX_BINARY_SUFFIX "-gpu")
 200     set (GMX_LIBS_SUFFIX "_gpu")
 201   endif(GMX_OPENMM)
 202   mark_as_advanced(FORCE GMX_BINARY_SUFFIX GMX_LIBS_SUFFIX)
 203   if (NOT SUFFIX_QUIETLY)
 204     message(STATUS "Using default binary suffix: \"${GMX_BINARY_SUFFIX}\"")
 205     message(STATUS "Using default library suffix: \"${GMX_LIBS_SUFFIX}\"")
 206   endif (NOT SUFFIX_QUIETLY)
 207 else(GMX_DEFAULT_SUFFIX)
 208   mark_as_advanced(CLEAR GMX_BINARY_SUFFIX GMX_LIBS_SUFFIX)
 209   if (NOT SUFFIX_QUIETLY)
 210     message(STATUS "Using manually set binary suffix: \"${GMX_BINARY_SUFFIX}\"")
 211     message(STATUS "Using manually set library suffix: \"${GMX_LIBS_SUFFIX}\"")
 212   endif (NOT SUFFIX_QUIETLY)
 213 endif(GMX_DEFAULT_SUFFIX)
 214 set(SUFFIX_QUIETLY TRUE CACHE INTERNAL "")
 215
 216 set(PKG_CFLAGS "")
 217 if(GMX_DOUBLE)
 218     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_DOUBLE")
 219 endif(GMX_DOUBLE)
 220 if(GMX_SOFTWARE_INVSQRT)
 221   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_SOFTWARE_INVSQRT")
 222 endif(GMX_SOFTWARE_INVSQRT)
 223 if(GMX_POWERPC_INVSQRT)
 224   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_POWERPC_INVSQRT")
 225 endif(GMX_POWERPC_INVSQRT)
 226
 227 ########################################################################
 228 #Process MPI settings
 229 ########################################################################
 230 include(gmxManageMPI)
 231
 232 #######################################################################
 233 # Check for options incompatible with OpenMM build                    #
 234 #######################################################################
 235 if(GMX_OPENMM)
 236     # we'll use the built-in fft to avoid unnecessary dependencies
 237     string(TOUPPER ${GMX_FFT_LIBRARY} GMX_FFT_LIBRARY)
 238     if(NOT ${GMX_FFT_LIBRARY} STREQUAL "FFTPACK")
 239         message(STATUS "No external FFT libraries needed for the OpenMM build, switching to fftpack!")
 240         set(GMX_FFT_LIBRARY "fftpack" CACHE STRING
 241                 "No external FFT libraries needed for the OpenMM build, switching to  fftpack!" FORCE)
 242     endif()
 243     if(GMX_MPI)
 244         message(FATAL_ERROR "The OpenMM build is not compatible with MPI!")
 245     endif(GMX_MPI)
 246     if(GMX_THREAD_MPI)
 247         message(STATUS "Thread-MPI not compatible with OpenMM, disabled!")
 248         set(GMX_THREAD_MPI OFF CACHE BOOL
 249                 "Thread-MPI not compatible with OpenMM build, disabled!" FORCE)
 250     endif(GMX_THREAD_MPI)
 251     if(GMX_OPENMP)
 252         message(STATUS "OpenMP multithreading not compatible with OpenMM, disabled")
 253         set(GMX_OPENMP OFF CACHE BOOL
 254             "OpenMP multithreading not compatible with OpenMM, disabled!" FORCE)
 255     endif()
 256     if(GMX_SOFTWARE_INVSQRT)
 257         set(GMX_SOFTWARE_INVSQRT OFF CACHE STRING
 258                 "The OpenMM build does not need GROMACS software 1/sqrt!" FORCE)
 259     endif(GMX_SOFTWARE_INVSQRT)
 260     string(TOUPPER ${GMX_ACCELERATION} GMX_ACCELERATION)
 261     if(NOT GMX_ACCELERATION STREQUAL "NONE")
 262         message(STATUS "Switching off CPU-based acceleration, the OpenMM build does not support/need any!")
 263         set(GMX_ACCELERATION "none" CACHE STRING
 264                 "Switching off CPU-based acceleration, the OpenMM build does not support/need any!" FORCE)
 265     endif()
 266     if(GMX_FAHCORE)
 267         message(FATAL_ERROR "The OpenMM build does not support FAH build!")
 268     endif(GMX_FAHCORE)
 269     if(GMX_DOUBLE)
 270         message(FATAL_ERROR  "The OpenMM-build does not support double precision calculations!")
 271     endif()
 272     # mark as advanced the unused variables
 273     mark_as_advanced(FORCE GMX_ACCELERATION GMX_MPI GMX_FFT_LIBRARY
 274         GMX_QMMM_PROGRAM GMX_THREAD_MPI GMX_DOUBLE)
 275 else(GMX_OPENMM)
 276      mark_as_advanced(CLEAR GMX_ACCELERATION GMX_MPI GMX_FFT_LIBRARY
 277         GMX_QMMM_PROGRAM GMX_THREAD_MPI GMX_DOUBLE)
 278 endif(GMX_OPENMM)
 279
 280
 281 ########################################################################
 282 # Basic system tests (standard libraries, headers, functions, types)   #
 283 ########################################################################
 284 include(CheckIncludeFiles)
 285 check_include_files(unistd.h     HAVE_UNISTD_H)
 286 check_include_files(pwd.h        HAVE_PWD_H)
 287 check_include_files(pthread.h    HAVE_PTHREAD_H)
 288 check_include_files(dirent.h     HAVE_DIRENT_H)
 289 check_include_files(regex.h      HAVE_REGEX_H)
 290 check_include_files(sys/types.h  HAVE_SYS_TYPES_H)
 291 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 292 check_include_files(io.h                 HAVE_IO_H)
 293
 294
 295 include(CheckFunctionExists)
 296 check_function_exists(strdup            HAVE_STRDUP)
 297 check_function_exists(posix_memalign    HAVE_POSIX_MEMALIGN)
 298 check_function_exists(memalign          HAVE_MEMALIGN)
 299 check_function_exists(_aligned_malloc   HAVE__ALIGNED_MALLOC)
 300 check_function_exists(gettimeofday      HAVE_GETTIMEOFDAY)
 301 check_function_exists(fsync             HAVE_FSYNC)
 302 check_function_exists(_fileno           HAVE__FILENO)
 303 check_function_exists(fileno            HAVE_FILENO)
 304 check_function_exists(_commit           HAVE__COMMIT)
 305 check_function_exists(lstat             HAVE_LSTAT)
 306 check_function_exists(sigaction         HAVE_SIGACTION)
 307
 308 include(CheckLibraryExists)
 309 check_library_exists(m sqrt "" HAVE_LIBM)
 310 check_library_exists(m cbrt "" HAVE_CBRT)
 311
 312
 313 include(CheckTypeSize)
 314
 315 check_type_size("int"           SIZEOF_INT)
 316 check_type_size("long int"      SIZEOF_LONG_INT)
 317 check_type_size("long long int" SIZEOF_LONG_LONG_INT)
 318 check_type_size("off_t"         SIZEOF_OFF_T)
 319 check_type_size("void *"        SIZEOF_VOIDP)
 320
 321 if (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 322     set(GMX_64_BIT TRUE)
 323 else (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 324     set(GMX_64_BIT FALSE)
 325 endif (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 326
 327 include(TestBigEndian)
 328 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 329
 330
 331
 332
 333 ########################################################################
 334 # Find external packages                                               #
 335 ########################################################################
 336 if(UNIX AND NOT APPLE)
 337     if(GMX_PREFER_STATIC_LIBS)
 338         SET(CMAKE_FIND_LIBRARY_SUFFIXES .a ${CMAKE_FIND_LIBRARY_SUFFIXES})
 339         if(BUILD_SHARED_LIBS)
 340             message(WARNING "Static libraries requested, the GROMACS libraries will also be build static (BUILD_SHARED_LIBS=OFF)")
 341             set(BUILD_SHARED_LIBS OFF CACHE BOOL "Enable shared libraries (can be problematic with MPI, Windows)" FORCE)
 342         endif()
 343     endif()
 344 endif()
 345
 346 option(GMX_XML "Use libxml2 to parse xml files" ON)
 347 if (GMX_XML)
 348   find_package(LibXml2)
 349   set(PKG_XML "")
 350   if(LIBXML2_FOUND)
 351     include_directories(${LIBXML2_INCLUDE_DIR})
 352     set(PKG_XML libxml-2.0)
 353     set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 354   endif(LIBXML2_FOUND)
 355 endif(GMX_XML)
 356
 357 option(GMX_GSL "Add support for gsl" OFF)
 358 if (GMX_GSL)
 359   find_package(gsl)
 360   set(PKG_GSL "")
 361   if(GSL_FOUND)
 362     include_directories(${GSL_INCLUDE_DIR})
 363     set(PKG_GSL gsl)
 364     set(HAVE_LIBGSL 1)
 365   endif(GSL_FOUND)
 366 endif (GMX_GSL)
 367
 368 option(GMX_X11 "Use X window system" OFF)
 369 if (GMX_X11)
 370         find_package(X11)
 371         # X11 includes/libraries are only set in the ngmx subdirectory!
 372         if(X11_FOUND)
 373         set(HAVE_X11 1)
 374         endif(X11_FOUND)
 375 endif(GMX_X11)
 376
 377 if(GMX_THREAD_MPI)
 378     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_THREAD_MPI")
 379     include(ThreadMPI)
 380     tmpi_make_cxx_lib()
 381     set(THREAD_MPI_LIB thread_mpi)
 382     set(GMX_MPI 1)
 383     string(TOUPPER ${GMX_FFT_LIBRARY} ${GMX_FFT_LIBRARY})
 384 endif(GMX_THREAD_MPI)
 385
 386 if(GMX_OPENMM)
 387     set(CUDA_BUILD_EMULATION OFF)
 388     find_package(CUDA 3.1 REQUIRED)
 389     add_definitions(-DGMX_OPENMM)
 390     if(CMAKE_BUILD_TYPE STREQUAL "DEBUG")
 391         set(CUDA_VERBOSE_BUILD ON)
 392     endif()
 393     find_package(OpenMM)
 394 endif(GMX_OPENMM)
 395
 396 if(GMX_OPENMP)
 397     find_package(OpenMP REQUIRED)
 398     set(GROMACS_C_FLAGS "${OpenMP_C_FLAGS} ${GROMACS_C_FLAGS}")
 399     set(GROMACS_CXX_FLAGS "${OpenMP_CXX_FLAGS} ${GROMACS_CXX_FLAGS}")
 400     add_definitions(-DGMX_OPENMP)
 401 endif()
 402
 403 if(APPLE)
 404    find_library(ACCELERATE_FRAMEWORK Accelerate)
 405    list(APPEND GMX_EXTRA_LIBRARIES ${ACCELERATE_FRAMEWORK})
 406 endif(APPLE)
 407
 408 if(CYGWIN)
 409     set(GMX_CYGWIN 1)
 410 endif(CYGWIN)
 411
 412 if(WIN32 AND NOT CYGWIN)
 413     set(GMX_NATIVE_WINDOWS 1)
 414 endif()
 415
 416 # only bother with finding git and using version.h if the source is a git repo
 417 if(EXISTS "${CMAKE_SOURCE_DIR}/.git")
 418     if(USE_VERSION_H)
 419         # We need at least git v1.5.3 be able to parse git's date output. If not
 420         # found or the version is too small, we can't generate version information.
 421         find_package(Git)
 422
 423         # Find out the git version
 424         if(GIT_FOUND AND NOT GIT_VERSION)
 425           execute_process(COMMAND ${GIT_EXECUTABLE} "--version"
 426             OUTPUT_VARIABLE _exec_out
 427             OUTPUT_STRIP_TRAILING_WHITESPACE)
 428           string(REGEX REPLACE "git version (.*)" "\\1" GIT_VERSION ${_exec_out})
 429           set(GIT_VERSION ${GIT_VERSION} CACHE STRING "Git version")
 430           mark_as_advanced(GIT_VERSION)
 431         endif()
 432
 433         if(NOT GIT_FOUND OR GIT_VERSION VERSION_LESS "1.5.3")
 434           message("No compatible git version found, won't be able to generate proper development version information.")
 435           set(USE_VERSION_H OFF)
 436         endif()
 437     endif()
 438 else()
 439     set(USE_VERSION_H OFF)
 440 endif()
 441
 442 option(GMX_INTERNAL_BOOST "Use minimal internal version of boost" OFF)
 443 if ( NOT GMX_INTERNAL_BOOST )
 444   find_package( Boost 1.36.0 )
 445 else ( NOT GMX_INTERNAL_BOOST )
 446   set (Boost_FOUND FALSE)
 447 endif( NOT GMX_INTERNAL_BOOST )
 448
 449 if(Boost_FOUND)
 450   include_directories(${Boost_INCLUDE_DIRS})
 451 else()
 452   message("Boost >= 1.36 not found. Using minimal internal version. Not recommended if GROMACS is used as library!")
 453   include_directories(${CMAKE_SOURCE_DIR}/src/external/boost)
 454   add_definitions( -DBOOST_NO_TYPEID )  #TYPEID not supported for minimal internal version (would add significant more code)
 455   # TODO: Propagate the above settings to the installed CMakeFiles.txt template
 456   # (from share/template/)
 457   # TODO: Reorder stuff such that INCL_INSTALL_DIR could be used here
 458   set(PKG_CFLAGS "${PKG_CFLAGS} -DBOOST_NO_TYPEID -I${CMAKE_INSTALL_PREFIX}/include/gromacs/external/boost")
 459   install(DIRECTORY ${CMAKE_SOURCE_DIR}/src/external/boost/boost
 460           DESTINATION ${CMAKE_INSTALL_PREFIX}/include/gromacs/external/boost
 461           COMPONENT development)
 462 endif()
 463
 464 if (LIBXML2_FOUND)
 465     option(GMX_BUILD_UNITTESTS "Build unit tests with BUILD_TESTING (uses Google C++ Testing and Mocking Frameworks, requires libxml2)" ON)
 466 else (LIBXML2_FOUND)
 467     set(GMX_BUILD_UNITTESTS OFF)
 468 endif (LIBXML2_FOUND)
 469 mark_as_advanced(GMX_BUILD_UNITTESTS)
 470 set(MEMORYCHECK_SUPPRESSIONS_FILE ${CMAKE_SOURCE_DIR}/cmake/legacy_and_external.supp)
 471
 472 find_package(Doxygen)
 473
 474 ########################################################################
 475 # Generate development version info for cache
 476 ########################################################################
 477 # set(GEN_VERSION_INFO_INTERNAL "ON")
 478 # include(gmxGenerateVersionString)
 479
 480 ########################################################################
 481 # Our own GROMACS tests
 482 ########################################################################
 483
 484 add_definitions( -DHAVE_CONFIG_H )
 485 include_directories(${CMAKE_SOURCE_DIR}/src)
 486 # Required for config.h, maybe should only be set in src/CMakeLists.txt
 487 include_directories(${CMAKE_BINARY_DIR}/src)
 488 # Required for now to make old code compile
 489 include_directories(${CMAKE_SOURCE_DIR}/src/gromacs/legacyheaders)
 490
 491 include(gmxCheckBuildUserTime)
 492 gmx_check_build_user_time(BUILD_TIME BUILD_USER BUILD_MACHINE)
 493
 494 include(gmxTestFloatFormat)
 495 gmx_test_float_format(GMX_FLOAT_FORMAT_IEEE754
 496                       GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER
 497                       GMX_IEEE754_BIG_ENDIAN_WORD_ORDER)
 498
 499 include(gmxTestLargeFiles)
 500 gmx_test_large_files(GMX_LARGEFILES)
 501 check_function_exists(fseeko     HAVE_FSEEKO)
 502
 503 include(gmxTestSignal)
 504 gmx_test_sigusr1(HAVE_SIGUSR1)
 505
 506 include(gmxTestInline)
 507 gmx_test_inline(INLINE_KEYWORD)
 508
 509 include(gmxTestPipes)
 510 gmx_test_pipes(HAVE_PIPES)
 511
 512 include(gmxTestIsfinite)
 513 gmx_test_isfinite(HAVE_ISFINITE)
 514 gmx_test__isfinite(HAVE__ISFINITE)
 515 gmx_test__finite(HAVE__FINITE)
 516
 517 include(gmxTestCXX11)
 518 gmx_test_cxx11(GMX_CXX11 CXX11_FLAG)
 519 set(GROMACS_CXX_FLAGS "${CXX11_FLAG} ${GROMACS_CXX_FLAGS}")
 520
 521 # turn on SSE if supported with reasonable defaults.
 522 if (${GMX_ACCELERATION} STREQUAL "auto" AND NOT GMX_OPENMM)
 523   if(CMAKE_SYSTEM_PROCESSOR MATCHES "^(i.86|x86|x64|x86_64|AMD64|amd64)" OR CYGWIN)
 524
 525     set(GMX_ACCELERATION "SSE" CACHE STRING "Accelerated kernels. Pick one of: auto, none, SSE, BlueGene, Power6, ia64, altivec, fortran" FORCE)
 526
 527     # Determine the assembler/compiler to use
 528   else()
 529     set(GMX_ACCELERATION "none" CACHE STRING "Accelerated kernels. Pick one of: auto, none, SSE, BlueGene, Power6, ia64, altivec, fortran" FORCE)
 530   endif()
 531 endif (${GMX_ACCELERATION} STREQUAL "auto" AND NOT GMX_OPENMM)
 532
 533 include(gmxTestXDR)
 534 gmx_test_xdr(GMX_SYSTEM_XDR)
 535 if(NOT GMX_SYSTEM_XDR)
 536     set(GMX_INTERNAL_XDR 1)
 537     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_INTERNAL_XDR")
 538 endif(NOT GMX_SYSTEM_XDR)
 539
 540 # Process nonbonded accelerated kernels settings
 541 string(TOUPPER ${GMX_ACCELERATION} ${GMX_ACCELERATION})
 542 if(${GMX_ACCELERATION} STREQUAL "NONE")
 543   # nothing to do
 544 elseif(${GMX_ACCELERATION} STREQUAL "SSE")
 545
 546     if (GMX_64_BIT)
 547       set(GMX_X86_64_ASM ON CACHE BOOL "Add SSE assembly files for x86_64" FORCE)
 548     else (GMX_64_BIT)
 549       set(GMX_IA32_ASM ON CACHE BOOL "Add SSE assembly files for i386" FORCE)
 550     endif (GMX_64_BIT)
 551
 552     if( WIN32 AND NOT CYGWIN )
 553       option(GMX_ASM_USEASM_NASM "Use Nasm for assembly instead of compiler (necessary on windows)" ON)
 554     else()
 555       option(GMX_ASM_USEASM_NASM "Use Nasm for assembly instead of compiler (necessary on windows)" OFF)
 556     endif()
 557         mark_as_advanced(GMX_ASM_USEASM_NASM)
 558
 559     if (NOT GMX_64_BIT)
 560         # for 32-bit compiles, we might need to turn on sse
 561         CHECK_C_COMPILER_FLAG("-msse2" XFLAGS_SSE)
 562         if (XFLAGS_SSE)
 563             set(GROMACS_C_FLAGS "-msse2 ${GROMACS_C_FLAGS}")
 564         endif (XFLAGS_SSE)
 565         CHECK_CXX_COMPILER_FLAG("-msse2" XXFLAGS_SSE)
 566         if (XXFLAGS_SSE)
 567             set(GROMACS_CXX_FLAGS "-msse2 ${GROMACS_CXX_FLAGS}")
 568         endif (XXFLAGS_SSE)
 569     endif (NOT GMX_64_BIT)
 570
 571     if(GMX_IA32_ASM)
 572       if(GMX_DOUBLE)
 573         set(GMX_IA32_SSE2 1)
 574       else()
 575        set(GMX_IA32_SSE 1)
 576       endif()
 577     elseif(GMX_X86_64_ASM)
 578       if(GMX_DOUBLE)
 579        set(GMX_X86_64_SSE2 1)
 580       else()
 581         set(GMX_X86_64_SSE 1)
 582       endif()
 583     endif()
 584
 585 elseif(${GMX_ACCELERATION} STREQUAL "FORTRAN")
 586     set(GMX_FORTRAN 1)
 587     #these are switch on by default sometimes
 588     set(GMX_IA32_ASM 0)
 589     set(GMX_GMX_X86_64_ASM 0)
 590 elseif(${GMX_ACCELERATION} STREQUAL "BLUEGENE")
 591 # GMX_ACCELERATION=BlueGene should be set in the Toolchain-BlueGene?-???.cmake file
 592     message(STATUS "Configuring for BlueGene")
 593     set(GMX_BLUEGENE 1)
 594     if (${CMAKE_SYSTEM_NAME} STREQUAL "BlueGeneL")
 595         set(SHARED_LIBS_DEFAULT OFF CACHE BOOL "Shared libraries not compatible with BlueGene/L, disabled!" FORCE)
 596         set(BUILD_SHARED_LIBS OFF CACHE BOOL "Shared libraries not compatible with BlueGene/L, disabled!" FORCE)
 597     endif (${CMAKE_SYSTEM_NAME} STREQUAL "BlueGeneL")
 598     set(GMX_SOFTWARE_INVSQRT OFF CACHE BOOL "Do not use software reciprocal square root on BlueGene" FORCE)
 599     set(GMX_POWERPC_INVSQRT ON CACHE BOOL "Use hardware reciprocal square root on BlueGene" FORCE)
 600     set(GMX_X11 OFF CACHE BOOL "X11 not compatible with BlueGene, disabled!" FORCE)
 601     set(GMX_THREAD_MPI OFF CACHE BOOL "Thread-MPI not compatible with BlueGene, disabled!" FORCE)
 602     set(GMX_MPI ON CACHE BOOL "Use MPI on BlueGene" FORCE)
 603 elseif(${GMX_ACCELERATION} STREQUAL "POWER6")
 604     set(GMX_POWER6 1)
 605     set(GMX_SOFTWARE_INVSQRT OFF CACHE BOOL "Do not use software reciprocal square root on Power6" FORCE)
 606     set(GMX_POWERPC_INVSQRT ON CACHE BOOL "Use hardware reciprocal square root on Power6" FORCE)
 607 elseif(${GMX_ACCELERATION} STREQUAL "IA64")
 608     set(GMX_IA64_ASM 1)
 609     set(DISABLE_WATERWATER_NLIST 1)
 610     set(DISABLE_WATER_NLIST 1)
 611 elseif(${GMX_ACCELERATION} STREQUAL "ALTIVEC")
 612     check_include_files(altivec.h HAVE_ALTIVEC_H)
 613     if(HAVE_ALTIVEC_H)
 614         set(GMX_PPC_ALTIVEC 1)
 615     endif(HAVE_ALTIVEC_H)
 616 else(${GMX_ACCELERATION} STREQUAL "NONE")
 617     MESSAGE(FATAL_ERROR "Unrecognized option for accelerated kernels: ${GMX_ACCELERATION}. Pick one of auto, none, SSE, Fortran, BlueGene, Power6, ia64, altivec")
 618 endif(${GMX_ACCELERATION} STREQUAL "NONE")
 619
 620 if(GMX_FORTRAN OR GMX_POWER6)
 621     if (GMX_THREAD_MPI)
 622         message(FATAL_ERROR "FORTRAN/POWER6 is incompatible with thread-MPI and only provides a speed-up on certain IBM compilers. Disable FORTRAN (or threads if you really want to use FORTRAN kernels).")
 623     endif(GMX_THREAD_MPI)
 624     enable_language(Fortran)
 625     include(FortranCInterface)
 626     discover_fortran_mangling(prefix isupper suffix extra_under_score found)
 627     if(extra_under_score)
 628         set(extrasuffix "_")
 629     endif(extra_under_score)
 630     if(prefix)
 631       set(prefix "${prefix} ##")
 632     endif(prefix)
 633     if(suffix)
 634       set(suffix "## ${suffix}")
 635       if(extrasuffix)
 636         set(extrasuffix "${suffix}${extrasuffix}")
 637       endif(extrasuffix)
 638     else(suffix)
 639       if(extrasuffix)
 640         # Don't know if this is needed, but it can't hurt
 641         set(extrasuffix "## ${extrasuffix}")
 642       endif(extrasuffix)
 643     endif(suffix)
 644
 645     if(isupper)
 646         set(F77_FUNCDEF   "${prefix} NAME ${suffix}")
 647         # The underscored versions are not currently used.
 648         #set(F77_FUNCDEF_  "${prefix} NAME ${extrasuffix}")
 649     else(isupper)
 650         set(F77_FUNCDEF   "${prefix} name ${suffix}")
 651         #set(F77_FUNCDEF_  "${prefix} name ${extrasuffix}")
 652     endif(isupper)
 653 else(GMX_FORTRAN OR GMX_POWER6)
 654         set(F77_FUNCDEF   "name ## _")
 655         #set(F77_FUNCDEF_  "name ## _")
 656 endif(GMX_FORTRAN OR GMX_POWER6)
 657
 658 # Process QM/MM Settings
 659 string(TOUPPER ${GMX_QMMM_PROGRAM} ${GMX_QMMM_PROGRAM})
 660 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 661     set(GMX_QMMM_GAUSSIAN 1)
 662 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 663     set(GMX_QMMM_MOPAC 1)
 664 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 665     set(GMX_QMMM_GAMESS 1)
 666 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 667     set(GMX_QMMM_ORCA 1)
 668 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 669     # nothing to do
 670 else(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 671     MESSAGE(FATAL_ERROR "Invalid QM/MM program option: ${GMX_QMMM_PROGRAM}. Choose one of: Gaussian, Mopac, Gamess, Orca, None")
 672 endif(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 673
 674 # Process FFT library settings - if not OpenMM build
 675 string(TOUPPER ${GMX_FFT_LIBRARY} ${GMX_FFT_LIBRARY})
 676 set(PKG_FFT "")
 677 set(PKG_FFT_LIBS "")
 678 if(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 679     if(GMX_DOUBLE)
 680         find_package(FFTW 3 COMPONENTS fftw)
 681     else(GMX_DOUBLE)
 682         find_package(FFTW 3 COMPONENTS fftwf)
 683     endif(GMX_DOUBLE)
 684     if(NOT FFTW_FOUND)
 685       MESSAGE(FATAL_ERROR "Cannot find FFTW3 (with correct precision - libfftw3f for single precision GROMACS or libfftw3 for double precision GROMACS). Fix it, choose another FFT library, or use the Gromacs built-in fftpack (slower)!")
 686     endif(NOT FFTW_FOUND)
 687     include_directories(${FFTW_INCLUDE_DIRS})
 688     set(FFT_LIBRARIES ${FFTW_LIBRARIES})
 689     set(PKG_FFT "${FFTW_PKG}")
 690
 691     set(GMX_FFT_FFTW3 1)
 692
 693     if (${GMX_ACCELERATION} STREQUAL "SSE" AND NOT FFTW_HAVE_SSE)
 694       message(WARNING "The fftw library found is compiled without SSE support, which makes it slow. Consider recompiling it or contact your admin")
 695     endif (${GMX_ACCELERATION} STREQUAL "SSE" AND NOT FFTW_HAVE_SSE)
 696
 697 elseif(${GMX_FFT_LIBRARY} STREQUAL "MKL")
 698 #    MESSAGE(STATUS "Using external FFT library - Intel MKL")
 699     find_package(MKL REQUIRED)
 700     include_directories(${MKL_INCLUDE_DIR})
 701     set(FFT_LIBRARIES ${MKL_LIBRARIES})
 702     set(PKG_FFT_LIBS ${MKL_LIBRARIES})
 703
 704     set(GMX_FFT_MKL 1)
 705     set(HAVE_MKL 1)
 706
 707 #elseif(${GMX_FFT_LIBRARY} STREQUAL "ACML")
 708 #    MESSAGE(STATUS "Using external FFT library - AMD core math library")
 709 #    set(GMX_FFT_ACML 1)
 710 elseif(${GMX_FFT_LIBRARY} STREQUAL "FFTPACK")
 711     MESSAGE(STATUS "Using internal FFT library - fftpack")
 712     set(GMX_FFT_FFTPACK 1)
 713 else(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 714     MESSAGE(FATAL_ERROR "Invalid FFT library setting: ${GMX_FFT_LIBRARY}. Choose one of: fftw3, mkl, fftpack")
 715 endif(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 716
 717 set(GMX_EXTERNAL_BLAS TRUE CACHE BOOL "Use external BLAS instead of built-in")
 718 set(GMX_EXTERNAL_LAPACK TRUE CACHE BOOL "Use external LAPACK instead of built-in")
 719 # MKL has BLAS/LAPACK routines
 720 if(NOT HAVE_MKL AND NOT ACCELERATE_FRAMEWORK)
 721   if(GMX_EXTERNAL_BLAS)
 722     if (GMX_BLAS_USER)
 723         list(APPEND GMX_EXTRA_LIBRARIES ${GMX_BLAS_USER})
 724     else(GMX_BLAS_USER)
 725         set(BLAS_FIND_QUIETLY ON)
 726         find_package(BLAS)
 727         if (BLAS_FOUND)
 728           list(APPEND GMX_EXTRA_LIBRARIES ${BLAS_LIBRARIES})
 729         else()
 730           MESSAGE(STATUS "Using internal BLAS library")
 731           set(GMX_EXTERNAL_BLAS FALSE CACHE BOOL "Use external BLAS instead of built-in" FORCE)
 732         endif()
 733     endif(GMX_BLAS_USER)
 734   endif(GMX_EXTERNAL_BLAS)
 735   if(GMX_EXTERNAL_LAPACK)
 736     if (GMX_LAPACK_USER)
 737         list(APPEND GMX_EXTRA_LIBRARIES ${GMX_LAPACK_USER})
 738     else(GMX_LAPACK_USER)
 739         set(LAPACK_FIND_QUIETLY ON)
 740         find_package(LAPACK)
 741         if (LAPACK_FOUND)
 742           list(APPEND GMX_EXTRA_LIBRARIES ${LAPACK_LIBRARIES})
 743         else()
 744           MESSAGE(STATUS "Using internal LAPACK library")
 745           set(GMX_EXTERNAL_LAPACK FALSE CACHE BOOL "Use external LAPACK instead of built-in" FORCE)
 746         endif()
 747     endif(GMX_LAPACK_USER)
 748   endif(GMX_EXTERNAL_LAPACK)
 749 endif()
 750 mark_as_advanced(GMX_EXTERNAL_LAPACK)
 751 mark_as_advanced(GMX_EXTERNAL_BLAS)
 752
 753 set(GMX_USE_PLUGINS OFF CACHE INTERNAL "Whether GROMACS will really try to compile support for VMD plugins")
 754 set(GMX_VMD_PLUGIN_PATH)
 755 mark_as_advanced(GMX_VMD_PLUGIN_PATH)
 756
 757 if(GMX_LOAD_PLUGINS)
 758   if(CYGWIN OR NOT WIN32)
 759     # Native Windows does not have, nor need dlopen
 760     # Note that WIN32 is set with Cygwin, but Cygwin needs dlopen to use plug-ins
 761     include(gmxTestdlopen)
 762     gmx_test_dlopen(HAVE_DLOPEN)
 763   endif()
 764
 765   find_package(VMD)
 766
 767   # Test for unsuitable versions of VMD
 768
 769   if(VMD_FOUND AND NOT GMX_VMD_PLUGIN_PATH)
 770     message(STATUS "Checking for suitable VMD version")
 771     exec_program(${VMD_EXECUTABLE}
 772       ARGS --help
 773       OUTPUT_VARIABLE VMD_HELP
 774       RETURN_VALUE VMD_EXEC_RETURN)
 775
 776     if(VMD_EXEC_RETURN EQUAL 0)
 777       # This is the accepted idiom for subexpression matching, unfortunately
 778       string(REGEX REPLACE ".*VMD for .*, version ([0-9]+\\.[0-9]*\\.?[0-9]*).*" "\\1" VMD_VERSION ${VMD_HELP})
 779       string(REGEX REPLACE ".*VMD for (.*), version .*" "\\1" VMD_ARCH ${VMD_HELP})
 780
 781       if(VMD_VERSION VERSION_LESS "1.8")
 782         MESSAGE(WARNING "Found VMD version ${VMD_VERSION}, but GROMACS needs at least 1.8")
 783         unset(VMD_EXECUTABLE)
 784         set(VMD_FOUND FALSE)
 785       else()
 786         message(STATUS "VMD version ${VMD_VERSION} is suitable")
 787         if(DEFINED ENV{VMDDIR})
 788           # This permits GROMACS to avoid hard-coding a fall-back
 789           # path that it can tell right now would be useless.
 790           set(GMX_VMD_PLUGIN_PATH "$ENV{VMDDIR}/plugins/${VMD_ARCH}/molfile" CACHE PATH "Path to VMD plugins for molfile I/O")
 791         else()
 792           set(GMX_VMD_PLUGIN_PATH "/usr/local/lib/vmd/plugins/*/molfile" CACHE PATH "Path to VMD plugins for molfile I/O")
 793         endif()
 794       endif()
 795
 796       # clean up
 797       unset(VMD_HELP)
 798       unset(VMD_VERSION)
 799       unset(VMD_ARCH)
 800     endif()
 801   endif()
 802
 803   # so, should we use plug-ins?
 804   if((WIN32 AND NOT CYGWIN) OR (HAVE_DLOPEN AND BUILD_SHARED_LIBS))
 805     if (NOT VMD_QUIETLY)
 806       MESSAGE(STATUS "Found the ability to use plug-ins when building shared libaries, so will compile to use plug-ins (e.g. to read VMD-supported file formats).")
 807     endif(NOT VMD_QUIETLY)
 808     set(GMX_USE_PLUGINS ON)
 809     list(APPEND GMX_EXTRA_LIBRARIES ${CMAKE_DL_LIBS}) # magic cross-platform pre-set variable for dlopen library
 810     set(PKG_DL_LIBS "-l${CMAKE_DL_LIBS}")
 811   else()
 812     set(PKG_DL_LIBS)
 813   endif()
 814 endif(GMX_LOAD_PLUGINS)
 815 set(VMD_QUIETLY TRUE CACHE INTERNAL "")
 816
 817 # Math and thread libraries must often come after all others when linking...
 818 if(HAVE_LIBM)
 819     list(APPEND GMX_EXTRA_LIBRARIES m)
 820 endif(HAVE_LIBM)
 821
 822 if(GMX_FAHCORE)
 823   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 824       "Path to swindirect.h")
 825   include_directories(${COREWRAP_INCLUDE_DIR})
 826 endif(GMX_FAHCORE)
 827
 828 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 829 # these are set after everything else
 830 if (NOT DEFINED GROMACS_C_FLAGS_SET)
 831     set(GROMACS_C_FLAGS_SET true CACHE INTERNAL "Whether to reset the C flags"
 832         FORCE)
 833     set(CMAKE_C_FLAGS "${GROMACS_C_FLAGS} ${CMAKE_C_FLAGS}" CACHE STRING
 834         "Flags used by the compiler during all build types" FORCE)
 835     set(CMAKE_CXX_FLAGS "${GROMACS_CXX_FLAGS} ${CMAKE_CXX_FLAGS}" CACHE STRING
 836         "Flags used by the compiler during all build types" FORCE)
 837     set(CMAKE_EXE_LINKER_FLAGS
 838         "${GROMACS_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}"
 839         CACHE STRING "Linker flags" FORCE)
 840 endif (NOT DEFINED GROMACS_C_FLAGS_SET)
 841
 842 ########################################################################
 843 # Specify install locations and which subdirectories to process        #
 844 ########################################################################
 845 if ( DEFINED GMXLIB )
 846     set(LIB_INSTALL_DIR "${CMAKE_INSTALL_PREFIX}/${GMXLIB}")
 847 else()
 848     set(LIB_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/lib)
 849 endif()
 850 set(BIN_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/bin)
 851 set(DATA_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/gromacs)
 852 set(MAN_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/share/man)
 853 set(INCL_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/include)
 854
 855 set(GMXLIBDIR        ${DATA_INSTALL_DIR}/top)
 856
 857 ##################################################################
 858 # Shared library settings - Darwin uses INSTALL_NAME_DIR instead!
 859 ##################################################################
 860 if(NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin")
 861     set(CMAKE_SKIP_BUILD_RPATH  FALSE)
 862     set(CMAKE_BUILD_WITH_INSTALL_RPATH FALSE)
 863     set(CMAKE_INSTALL_RPATH "${LIB_INSTALL_DIR}")
 864     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 865 endif()
 866
 867 add_subdirectory(share)
 868 add_subdirectory(man)
 869 add_subdirectory(src)
 870 add_subdirectory(scripts)
 871
 872 #######################
 873 ## uninstall target
 874 #######################
 875     CONFIGURE_FILE(
 876                    "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 877                    "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
 878                    IMMEDIATE @ONLY)
 879 ###########################
 880 ADD_CUSTOM_TARGET(uninstall
 881                   "${CMAKE_COMMAND}" -P
 882                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
 883 ###########################
 884
 885 ########################################################################
 886 # Doxygen configuration
 887 ########################################################################
 888 if (DOXYGEN_FOUND)
 889     FILE(GLOB NB_KERNEL_DIRS src/gromacs/gmxlib/nonbonded/nb_kernel_*/)
 890     LIST(REMOVE_ITEM NB_KERNEL_DIRS
 891          ${CMAKE_SOURCE_DIR}/src/gromacs/gmxlib/nonbonded/nb_kernel_c)
 892     FOREACH(NB_KERNEL_DIR ${NB_KERNEL_DIRS})
 893         SET(NB_KERNEL_DIRS_TO_IGNORE_IN_DOXYGEN
 894             "${NB_KERNEL_DIRS_TO_IGNORE_IN_DOXYGEN} \\\n                         ${NB_KERNEL_DIR}")
 895     ENDFOREACH(NB_KERNEL_DIR)
 896     CONFIGURE_FILE(${CMAKE_SOURCE_DIR}/Doxyfile.cmakein
 897                    ${CMAKE_BINARY_DIR}/Doxyfile)
 898     CONFIGURE_FILE(${CMAKE_SOURCE_DIR}/Doxyfile-lib.cmakein
 899                    ${CMAKE_BINARY_DIR}/Doxyfile-lib)
 900     CONFIGURE_FILE(${CMAKE_SOURCE_DIR}/Doxyfile-user.cmakein
 901                    ${CMAKE_BINARY_DIR}/Doxyfile-user)
 902     add_custom_target(doc
 903       ${DOXYGEN_EXECUTABLE} ${CMAKE_CURRENT_BINARY_DIR}/Doxyfile
 904       WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}
 905       COMMENT "Generating full documentation with Doxygen" VERBATIM)
 906     add_custom_target(doc-user
 907       ${DOXYGEN_EXECUTABLE} ${CMAKE_CURRENT_BINARY_DIR}/Doxyfile-user
 908       WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}
 909       COMMENT "Generating user documentation with Doxygen" VERBATIM)
 910     add_custom_target(doc-lib
 911       ${DOXYGEN_EXECUTABLE} ${CMAKE_CURRENT_BINARY_DIR}/Doxyfile-lib
 912       WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}
 913       COMMENT "Generating libary documentation with Doxygen" VERBATIM)
 914 endif (DOXYGEN_FOUND)
 915
 916
 917 ########################################################################
 918 # Tests                                                                #
 919 ########################################################################
 920
 921 include(CTest)
 922 mark_as_advanced(BUILD_TESTING)
 923 IF(BUILD_TESTING)
 924     enable_testing()
 925     add_subdirectory(tests)
 926 ENDIF()
 927