CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.8)
   2 # Keep CMake suitably quiet on Cygwin
   3 set(CMAKE_LEGACY_CYGWIN_WIN32 0) # Remove when CMake >= 2.8.4 is required
   4
   5 # override bugs on OS X where Cmake picks gcc (GNU) for C instead of system default cc (Clang).
   6 if(APPLE)
   7     set(CMAKE_C_COMPILER_INIT "cc")
   8 endif(APPLE)
   9
  10 project(Gromacs)
  11 include(Dart)
  12 mark_as_advanced(DART_ROOT)
  13
  14 # PROJECT_VERSION should have the following structure:
  15 # VERSION-dev[-SUFFIX] where the VERSION should have the for: vMajor.vMinor.vPatch
  16 #
  17 # The "-dev" suffix is important to keep because it makes possible to distinguish
  18 # between a build from official release and a build from git release branch on a
  19 # machine with no git.
  20 #
  21 # NOTE: when releasing the "-dev" suffix needs to be stripped off!
  22 set(PROJECT_VERSION "5.0-dev")
  23 set(CUSTOM_VERSION_STRING ""
  24     CACHE STRING "Custom version string (if empty, use hard-coded default)")
  25 mark_as_advanced(CUSTOM_VERSION_STRING)
  26 if (CUSTOM_VERSION_STRING)
  27     set(PROJECT_VERSION ${CUSTOM_VERSION_STRING})
  28 endif (CUSTOM_VERSION_STRING)
  29 set(SOVERSION 6)
  30 # It is a bit irritating, but this has to be set separately for now!
  31 SET(CPACK_PACKAGE_VERSION_MAJOR "4")
  32 SET(CPACK_PACKAGE_VERSION_MINOR "6")
  33 #SET(CPACK_PACKAGE_VERSION_PATCH "0")
  34
  35
  36 # Cmake modules/macros are in a subdirectory to keep this file cleaner
  37 set(CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake)
  38
  39 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
  40 set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
  41 endif()
  42
  43 if(NOT CMAKE_BUILD_TYPE)
  44     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel." FORCE)
  45 endif(NOT CMAKE_BUILD_TYPE)
  46
  47 enable_language(C)
  48 enable_language(CXX)
  49
  50 set(CPACK_PACKAGE_VERSION ${PROJECT_VERSION})
  51 set(CPACK_PACKAGE_VENDOR "gromacs.org")
  52 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Gromacs - a toolkit for high-performance molecular simulation")
  53 set(CPACK_SET_DESTDIR "ON")
  54 set(CPACK_INCLUDE_TOPLEVEL_DIRECTORY 0)
  55 set(CPACK_RESOURCE_FILE_WELCOME "${CMAKE_SOURCE_DIR}/admin/InstallWelcome.txt")
  56 # Its GPL/LGPL, so they do not have to agree to a license for mere usage, but some installers require this...
  57 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_SOURCE_DIR}/admin/InstallLicense.txt")
  58 set(CPACK_RESOURCE_FILE_README "${CMAKE_SOURCE_DIR}/admin/InstallInfo.txt")
  59
  60 #must come after all cpack settings!
  61 include(CPack)
  62
  63 ########################################################################
  64 # Check and warn if cache generated on a different host is being reused
  65 ########################################################################
  66 if(CMAKE_HOST_UNIX)
  67     execute_process(COMMAND hostname
  68                     OUTPUT_VARIABLE TMP_HOSTNAME
  69                     OUTPUT_STRIP_TRAILING_WHITESPACE)
  70     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}")
  71         message(WARNING "
  72             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
  73             is being reused! This could lead to inconsitencies; therefore, it is
  74             recommended to regenerate the cache!")
  75     endif()
  76     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
  77             "Hostname of the machine where the cache was generated.")
  78 endif()
  79
  80 ########################################################################
  81 # Fix stupid flags on Windows
  82 ########################################################################
  83 SET(SHARED_LIBS_DEFAULT ON)
  84 IF( WIN32 AND NOT CYGWIN)
  85   option(GMX_PREFER_STATIC_LIBS "When finding libraries prefer static system libraries (MT instead of MD)!" ON)
  86   mark_as_advanced(GMX_PREFER_STATIC_LIBS)
  87   SET(SHARED_LIBS_DEFAULT OFF)  #is currently not working on Windows
  88   # This makes windows.h not declare min/max as macros that would break
  89   # C++ code using std::min/std::max.
  90   add_definitions(-DNOMINMAX)
  91
  92   IF (GMX_PREFER_STATIC_LIBS)
  93     #Only setting Debug and Release flags. Others configurations current not used.
  94     STRING(REPLACE /MD /MT CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE})
  95     SET(CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE} CACHE STRING "" FORCE)
  96     STRING(REPLACE /MD /MT CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG})
  97     SET(CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG} CACHE STRING "" FORCE)
  98     STRING(REPLACE /MD /MT CMAKE_CXX_FLAGS_RELEASE ${CMAKE_CXX_FLAGS_RELEASE})
  99     SET(CMAKE_CXX_FLAGS_RELEASE ${CMAKE_CXX_FLAGS_RELEASE} CACHE STRING "" FORCE)
 100     STRING(REPLACE /MD /MT CMAKE_CXX_FLAGS_DEBUG ${CMAKE_CXX_FLAGS_DEBUG})
 101     SET(CMAKE_CXX_FLAGS_DEBUG ${CMAKE_CXX_FLAGS_DEBUG} CACHE STRING "" FORCE)
 102   ENDIF()
 103
 104   #Workaround for cmake bug 13174. Replace deprecated options.
 105   IF( CMAKE_C_COMPILER_ID MATCHES "Intel" )
 106     STRING(REPLACE /GZ /RTC1 CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG})
 107     SET(CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG} CACHE STRING "" FORCE)
 108   ENDIF()
 109   IF( CMAKE_CXX_COMPILER_ID MATCHES "Intel" )
 110     STRING(REPLACE /GZ /RTC1 CMAKE_CXX_FLAGS_DEBUG ${CMAKE_CXX_FLAGS_DEBUG})
 111     STRING(REPLACE /GX /EHsc CMAKE_CXX_FLAGS_DEBUG ${CMAKE_CXX_FLAGS_DEBUG})
 112     SET(CMAKE_CXX_FLAGS_DEBUG ${CMAKE_CXX_FLAGS_DEBUG} CACHE STRING "" FORCE)
 113
 114     STRING(REPLACE /GX /EHsc CMAKE_CXX_FLAGS_RELEASE ${CMAKE_CXX_FLAGS_RELEASE})
 115     SET(CMAKE_CXX_FLAGS_RELEASE ${CMAKE_CXX_FLAGS_RELEASE} CACHE STRING "" FORCE)
 116   ENDIF()
 117 ENDIF()
 118
 119 ########################################################################
 120 # User input options                                                   #
 121 ########################################################################
 122 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" OFF)
 123 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 124 option(GMX_THREAD_MPI  "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" ON)
 125 option(GMX_SOFTWARE_INVSQRT "Use GROMACS software 1/sqrt" ON)
 126 mark_as_advanced(GMX_SOFTWARE_INVSQRT)
 127 option(GMX_POWERPC_INVSQRT "Use PowerPC hardware 1/sqrt" OFF)
 128 mark_as_advanced(GMX_POWERPC_INVSQRT)
 129 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 130 mark_as_advanced(GMX_FAHCORE)
 131 option(GMX_OPENMM "Accelerated execution on GPUs through the OpenMM library (rerun cmake after changing to see relevant options)" OFF)
 132
 133 include(gmxDetectAcceleration)
 134 if(NOT DEFINED GMX_ACCELERATION)
 135     if(CMAKE_CROSSCOMPILING)
 136         set(GMX_SUGGESTED_ACCELERATION "None")
 137     else(CMAKE_CROSSCOMPILING)
 138         gmx_detect_acceleration(GMX_SUGGESTED_ACCELERATION)
 139     endif(CMAKE_CROSSCOMPILING)
 140 endif(NOT DEFINED GMX_ACCELERATION)
 141
 142 set(GMX_ACCELERATION "@GMX_SUGGESTED_ACCELERATION@"
 143     CACHE STRING "Accelerated kernels. Pick one of: None, SSE2, SSE4.1, AVX_128_FMA, AVX_256, BlueGene, Power6, Fortran")
 144
 145 set(GMX_FFT_LIBRARY "fftw3"
 146     CACHE STRING "FFT library choices: fftw3,mkl,fftpack[built-in]")
 147 option(GMX_DISABLE_FFTW_MEASURE
 148        "Do not optimize FFTW setups (not needed with SSE)" OFF)
 149 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 150 set(GMX_QMMM_PROGRAM "none"
 151     CACHE STRING "QM package choices: none,gaussian,mopac,gamess,orca")
 152 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 153 mark_as_advanced(GMX_BROKEN_CALLOC)
 154 option(BUILD_SHARED_LIBS "Enable shared libraries (can be problematic with MPI, Windows)" ${SHARED_LIBS_DEFAULT})
 155 option(GMX_MPI_IN_PLACE "Enable MPI_IN_PLACE for MPIs that have it defined" ON)
 156 mark_as_advanced(GMX_MPI_IN_PLACE)
 157 option(GMX_LOAD_PLUGINS "Compile with plugin support, needed to read VMD supported file formats" ON)
 158 mark_as_advanced(GMX_LOAD_PLUGINS)
 159
 160 option(GMX_OPENMP "Enable OpenMP-based mutithreading. " ON)
 161
 162 option(USE_VERSION_H "Generate development version string/information" ON)
 163 mark_as_advanced(USE_VERSION_H)
 164
 165 option(GMX_DEFAULT_SUFFIX "Use default suffixes for GROMACS binaries and libs (_d for double, _mpi for MPI; rerun cmake after changing to see relevant options)" ON)
 166
 167 if(UNIX AND NOT APPLE)
 168     option(GMX_PREFER_STATIC_LIBS "When finding libraries prefer \".a\" static archives (NOTE: this is enabled only for UNIX (excluding APPLE) platforms but it might not always work!" OFF)
 169     mark_as_advanced(GMX_PREFER_STATIC_LIBS)
 170 endif()
 171
 172
 173 ######################################################################
 174 # compiler tests
 175 # these need ot be done early (before further tests).
 176 #####################################################################
 177
 178 # cmake/Check{C,CXX}CompilerFlag.cmake are lifted from CMake git next
 179 # branch (proposed for v2.8.9) to be able to detect invalid options
 180 # with the Intel Compilers.
 181 # Remove these files from the source tree when a CMake version that
 182 # includes the features in question becomes required.
 183 include(CheckCCompilerFlag)
 184 include(CheckCXXCompilerFlag)
 185
 186 # OpenMP check must come before other CFLAGS!
 187 if(GMX_OPENMP)
 188     find_package(OpenMP)
 189     if(OPENMP_FOUND)
 190         set(GROMACS_C_FLAGS "${OpenMP_C_FLAGS} ${GROMACS_C_FLAGS}")
 191         set(GROMACS_CXX_FLAGS "${OpenMP_CXX_FLAGS} ${GROMACS_CXX_FLAGS}")
 192         add_definitions(-DGMX_OPENMP)
 193     else(OPENMP_FOUND)
 194         message(WARNING
 195                 "Compiler not supporting OpenMP. This might hurt your performance a lot, "
 196                 "in particular with GPUs. Try using a different compiler (Intel is good on x86) "
 197                 "if you can - for now we are proceeding by turning off OpenMP.")
 198         set(GMX_OPENMP OFF CACHE STRING "Compiler does not support OpenMP." FORCE)
 199     endif(OPENMP_FOUND)
 200 endif()
 201
 202
 203 include(gmxCFlags)
 204 gmx_c_flags()
 205
 206 ########################################################################
 207 # Set up binary and library suffixing
 208 ########################################################################
 209 set(GMX_BINARY_SUFFIX "" CACHE STRING "Suffix for GROMACS binaries (default: _d for double, _mpi for MPI, _mpi_d for MPI and double).")
 210 set(GMX_LIBS_SUFFIX ""
 211   CACHE STRING "Suffix for GROMACS libs (default: _d for double, _mpi for MPI, _mpi_d for MPI and double).")
 212 if (GMX_DEFAULT_SUFFIX)
 213   set(GMX_BINARY_SUFFIX "")
 214   set(GMX_LIBS_SUFFIX "")
 215   if (GMX_MPI)
 216     set(GMX_BINARY_SUFFIX "_mpi")
 217     set(GMX_LIBS_SUFFIX "_mpi")
 218   endif(GMX_MPI)
 219   if (GMX_DOUBLE)
 220     set (GMX_BINARY_SUFFIX "${GMX_BINARY_SUFFIX}_d")
 221     set (GMX_LIBS_SUFFIX "${GMX_LIBS_SUFFIX}_d")
 222   endif(GMX_DOUBLE)
 223   if (GMX_OPENMM)
 224     set (GMX_BINARY_SUFFIX "-openmm")
 225     set (GMX_LIBS_SUFFIX "_openmm")
 226   endif(GMX_OPENMM)
 227   mark_as_advanced(FORCE GMX_BINARY_SUFFIX GMX_LIBS_SUFFIX)
 228   if (NOT SUFFIX_QUIETLY)
 229     message(STATUS "Using default binary suffix: \"${GMX_BINARY_SUFFIX}\"")
 230     message(STATUS "Using default library suffix: \"${GMX_LIBS_SUFFIX}\"")
 231   endif (NOT SUFFIX_QUIETLY)
 232 else(GMX_DEFAULT_SUFFIX)
 233   mark_as_advanced(CLEAR GMX_BINARY_SUFFIX GMX_LIBS_SUFFIX)
 234   if (NOT SUFFIX_QUIETLY)
 235     message(STATUS "Using manually set binary suffix: \"${GMX_BINARY_SUFFIX}\"")
 236     message(STATUS "Using manually set library suffix: \"${GMX_LIBS_SUFFIX}\"")
 237   endif (NOT SUFFIX_QUIETLY)
 238 endif(GMX_DEFAULT_SUFFIX)
 239 set(SUFFIX_QUIETLY TRUE CACHE INTERNAL "")
 240
 241 set(PKG_CFLAGS "")
 242 if(GMX_DOUBLE)
 243     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_DOUBLE")
 244 endif(GMX_DOUBLE)
 245 if(GMX_SOFTWARE_INVSQRT)
 246   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_SOFTWARE_INVSQRT")
 247 endif(GMX_SOFTWARE_INVSQRT)
 248 if(GMX_POWERPC_INVSQRT)
 249   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_POWERPC_INVSQRT")
 250 endif(GMX_POWERPC_INVSQRT)
 251
 252 ########################################################################
 253 #Process MPI settings
 254 ########################################################################
 255 include(gmxManageMPI)
 256
 257 #######################################################################
 258 # Check for options incompatible with OpenMM build                    #
 259 #######################################################################
 260 if(GMX_OPENMM)
 261     # we'll use the built-in fft to avoid unnecessary dependencies
 262     string(TOUPPER ${GMX_FFT_LIBRARY} GMX_FFT_LIBRARY)
 263     if(NOT ${GMX_FFT_LIBRARY} STREQUAL "FFTPACK")
 264         message(STATUS "No external FFT libraries needed for the OpenMM build, switching to fftpack!")
 265         set(GMX_FFT_LIBRARY "fftpack" CACHE STRING
 266                 "No external FFT libraries needed for the OpenMM build, switching to  fftpack!" FORCE)
 267     endif()
 268     if(GMX_MPI)
 269         message(FATAL_ERROR "The OpenMM build is not compatible with MPI!")
 270     endif(GMX_MPI)
 271     if(GMX_THREAD_MPI)
 272         message(STATUS "Thread-MPI not compatible with OpenMM, disabled!")
 273         set(GMX_THREAD_MPI OFF CACHE BOOL
 274                 "Thread-MPI not compatible with OpenMM build, disabled!" FORCE)
 275     endif(GMX_THREAD_MPI)
 276     if(GMX_OPENMP)
 277         message(STATUS "OpenMP multithreading not compatible with OpenMM, disabled")
 278         set(GMX_OPENMP OFF CACHE BOOL
 279             "OpenMP multithreading not compatible with OpenMM, disabled!" FORCE)
 280     endif()
 281     if(GMX_SOFTWARE_INVSQRT)
 282         set(GMX_SOFTWARE_INVSQRT OFF CACHE STRING
 283                 "The OpenMM build does not need GROMACS software 1/sqrt!" FORCE)
 284     endif(GMX_SOFTWARE_INVSQRT)
 285     string(TOUPPER ${GMX_ACCELERATION} GMX_ACCELERATION)
 286     if(NOT GMX_ACCELERATION STREQUAL "NONE")
 287         message(STATUS "Switching off CPU-based acceleration, the OpenMM build does not support/need any!")
 288         set(GMX_ACCELERATION "none" CACHE STRING
 289                 "Switching off CPU-based acceleration, the OpenMM build does not support/need any!" FORCE)
 290     endif()
 291     if(GMX_FAHCORE)
 292         message(FATAL_ERROR "The OpenMM build does not support FAH build!")
 293     endif(GMX_FAHCORE)
 294     if(GMX_DOUBLE)
 295         message(FATAL_ERROR  "The OpenMM-build does not support double precision calculations!")
 296     endif()
 297     # mark as advanced the unused variables
 298     mark_as_advanced(FORCE GMX_ACCELERATION GMX_MPI GMX_FFT_LIBRARY
 299         GMX_QMMM_PROGRAM GMX_THREAD_MPI GMX_DOUBLE)
 300 else(GMX_OPENMM)
 301      mark_as_advanced(CLEAR GMX_ACCELERATION GMX_MPI GMX_FFT_LIBRARY
 302         GMX_QMMM_PROGRAM GMX_THREAD_MPI GMX_DOUBLE)
 303 endif(GMX_OPENMM)
 304
 305
 306
 307
 308 ########################################################################
 309 # Basic system tests (standard libraries, headers, functions, types)   #
 310 ########################################################################
 311 include(CheckIncludeFiles)
 312 check_include_files(unistd.h     HAVE_UNISTD_H)
 313 check_include_files(pwd.h        HAVE_PWD_H)
 314 check_include_files(pthread.h    HAVE_PTHREAD_H)
 315 check_include_files(dirent.h     HAVE_DIRENT_H)
 316 check_include_files(regex.h      HAVE_REGEX_H)
 317 check_include_files(sys/types.h  HAVE_SYS_TYPES_H)
 318 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 319 check_include_files(io.h                 HAVE_IO_H)
 320
 321
 322 include(CheckFunctionExists)
 323 check_function_exists(strdup            HAVE_STRDUP)
 324 check_function_exists(posix_memalign    HAVE_POSIX_MEMALIGN)
 325 check_function_exists(memalign          HAVE_MEMALIGN)
 326 check_function_exists(_aligned_malloc   HAVE__ALIGNED_MALLOC)
 327 check_function_exists(gettimeofday      HAVE_GETTIMEOFDAY)
 328 check_function_exists(fsync             HAVE_FSYNC)
 329 check_function_exists(_fileno           HAVE__FILENO)
 330 check_function_exists(fileno            HAVE_FILENO)
 331 check_function_exists(_commit           HAVE__COMMIT)
 332 check_function_exists(lstat             HAVE_LSTAT)
 333 check_function_exists(sigaction         HAVE_SIGACTION)
 334
 335 include(CheckLibraryExists)
 336 check_library_exists(m sqrt "" HAVE_LIBM)
 337 check_library_exists(m cbrt "" HAVE_CBRT)
 338
 339
 340 include(CheckTypeSize)
 341
 342 check_type_size("int"           SIZEOF_INT)
 343 check_type_size("long int"      SIZEOF_LONG_INT)
 344 check_type_size("long long int" SIZEOF_LONG_LONG_INT)
 345 check_type_size("off_t"         SIZEOF_OFF_T)
 346 check_type_size("void *"        SIZEOF_VOIDP)
 347
 348 if (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 349     set(GMX_64_BIT TRUE)
 350 else (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 351     set(GMX_64_BIT FALSE)
 352 endif (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 353
 354 include(TestBigEndian)
 355 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 356
 357
 358
 359
 360 ########################################################################
 361 # Find external packages                                               #
 362 ########################################################################
 363 if(UNIX AND NOT APPLE)
 364     if(GMX_PREFER_STATIC_LIBS)
 365         SET(CMAKE_FIND_LIBRARY_SUFFIXES .a ${CMAKE_FIND_LIBRARY_SUFFIXES})
 366         if(BUILD_SHARED_LIBS)
 367             message(WARNING "Static libraries requested, the GROMACS libraries will also be build static (BUILD_SHARED_LIBS=OFF)")
 368             set(BUILD_SHARED_LIBS OFF CACHE BOOL "Enable shared libraries (can be problematic with MPI, Windows)" FORCE)
 369         endif()
 370     endif()
 371 endif()
 372
 373 option(GMX_XML "Use libxml2 to parse xml files" ON)
 374 if (GMX_XML)
 375   find_package(LibXml2)
 376   set(PKG_XML "")
 377   if(LIBXML2_FOUND)
 378     include_directories(${LIBXML2_INCLUDE_DIR})
 379     set(PKG_XML libxml-2.0)
 380     set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 381   endif(LIBXML2_FOUND)
 382 endif(GMX_XML)
 383
 384 option(GMX_GSL "Add support for gsl" OFF)
 385 if (GMX_GSL)
 386   find_package(gsl)
 387   set(PKG_GSL "")
 388   if(GSL_FOUND)
 389     include_directories(${GSL_INCLUDE_DIR})
 390     set(PKG_GSL gsl)
 391     set(HAVE_LIBGSL 1)
 392   endif(GSL_FOUND)
 393 endif (GMX_GSL)
 394
 395 option(GMX_X11 "Use X window system" OFF)
 396 if (GMX_X11)
 397         find_package(X11)
 398         # X11 includes/libraries are only set in the ngmx subdirectory!
 399         if(X11_FOUND)
 400         set(HAVE_X11 1)
 401         endif(X11_FOUND)
 402 endif(GMX_X11)
 403
 404 if(GMX_THREAD_MPI)
 405     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_THREAD_MPI")
 406     include(ThreadMPI)
 407     tmpi_make_cxx_lib()
 408     set(THREAD_MPI_LIB thread_mpi)
 409     set(GMX_MPI 1)
 410     string(TOUPPER ${GMX_FFT_LIBRARY} ${GMX_FFT_LIBRARY})
 411 endif(GMX_THREAD_MPI)
 412
 413 if(GMX_OPENMM)
 414     set(CUDA_BUILD_EMULATION OFF)
 415     find_package(CUDA 3.1 REQUIRED)
 416     add_definitions(-DGMX_OPENMM)
 417     if(CMAKE_BUILD_TYPE STREQUAL "DEBUG")
 418         set(CUDA_VERBOSE_BUILD ON)
 419     endif()
 420     find_package(OpenMM)
 421 endif(GMX_OPENMM)
 422
 423
 424 if(APPLE)
 425    find_library(ACCELERATE_FRAMEWORK Accelerate)
 426    list(APPEND GMX_EXTRA_LIBRARIES ${ACCELERATE_FRAMEWORK})
 427 endif(APPLE)
 428
 429 if(CYGWIN)
 430     set(GMX_CYGWIN 1)
 431 endif(CYGWIN)
 432
 433 if(WIN32 AND NOT CYGWIN)
 434     set(GMX_NATIVE_WINDOWS 1)
 435 endif()
 436
 437 # only bother with finding git and using version.h if the source is a git repo
 438 if(EXISTS "${CMAKE_SOURCE_DIR}/.git")
 439     if(USE_VERSION_H)
 440         # We need at least git v1.5.3 be able to parse git's date output. If not
 441         # found or the version is too small, we can't generate version information.
 442         find_package(Git)
 443
 444         # Find out the git version
 445         if(GIT_FOUND AND NOT GIT_VERSION)
 446           execute_process(COMMAND ${GIT_EXECUTABLE} "--version"
 447             OUTPUT_VARIABLE _exec_out
 448             OUTPUT_STRIP_TRAILING_WHITESPACE)
 449           string(REGEX REPLACE "git version (.*)" "\\1" GIT_VERSION ${_exec_out})
 450           set(GIT_VERSION ${GIT_VERSION} CACHE STRING "Git version")
 451           mark_as_advanced(GIT_VERSION)
 452         endif()
 453
 454         if(NOT GIT_FOUND OR GIT_VERSION VERSION_LESS "1.5.3")
 455           message("No compatible git version found, won't be able to generate proper development version information.")
 456           set(USE_VERSION_H OFF)
 457         endif()
 458     endif()
 459 else()
 460     set(USE_VERSION_H OFF)
 461 endif()
 462
 463 option(GMX_INTERNAL_BOOST "Use minimal internal version of boost" OFF)
 464 if ( NOT GMX_INTERNAL_BOOST )
 465   find_package( Boost 1.36.0 )
 466 else ( NOT GMX_INTERNAL_BOOST )
 467   set (Boost_FOUND FALSE)
 468 endif( NOT GMX_INTERNAL_BOOST )
 469
 470 if(Boost_FOUND)
 471   include_directories(${Boost_INCLUDE_DIRS})
 472 else()
 473   message("Boost >= 1.36 not found. Using minimal internal version. Not recommended if GROMACS is used as library!")
 474   include_directories(${CMAKE_SOURCE_DIR}/src/external/boost)
 475   add_definitions( -DBOOST_NO_TYPEID )  #TYPEID not supported for minimal internal version (would add significant more code)
 476   # TODO: Propagate the above settings to the installed CMakeFiles.txt template
 477   # (from share/template/)
 478   # TODO: Reorder stuff such that INCL_INSTALL_DIR could be used here
 479   set(PKG_CFLAGS "${PKG_CFLAGS} -DBOOST_NO_TYPEID -I${CMAKE_INSTALL_PREFIX}/include/gromacs/external/boost")
 480   install(DIRECTORY ${CMAKE_SOURCE_DIR}/src/external/boost/boost
 481           DESTINATION ${CMAKE_INSTALL_PREFIX}/include/gromacs/external/boost
 482           COMPONENT development)
 483 endif()
 484
 485 if (LIBXML2_FOUND)
 486     option(GMX_BUILD_UNITTESTS "Build unit tests with BUILD_TESTING (uses Google C++ Testing and Mocking Frameworks, requires libxml2)" ON)
 487 else (LIBXML2_FOUND)
 488     set(GMX_BUILD_UNITTESTS OFF)
 489 endif (LIBXML2_FOUND)
 490 mark_as_advanced(GMX_BUILD_UNITTESTS)
 491 set(MEMORYCHECK_SUPPRESSIONS_FILE ${CMAKE_SOURCE_DIR}/cmake/legacy_and_external.supp)
 492
 493 find_package(Doxygen)
 494
 495 ########################################################################
 496 # Generate development version info for cache
 497 ########################################################################
 498 # set(GEN_VERSION_INFO_INTERNAL "ON")
 499 # include(gmxGenerateVersionString)
 500
 501 ########################################################################
 502 # Our own GROMACS tests
 503 ########################################################################
 504
 505 add_definitions( -DHAVE_CONFIG_H )
 506 include_directories(${CMAKE_SOURCE_DIR}/src)
 507 # Required for config.h, maybe should only be set in src/CMakeLists.txt
 508 include_directories(${CMAKE_BINARY_DIR}/src)
 509 # Required for now to make old code compile
 510 include_directories(${CMAKE_SOURCE_DIR}/src/gromacs/legacyheaders)
 511
 512 include(gmxTestInlineASM)
 513 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 514
 515 include(gmxSetBuildInformation)
 516 gmx_set_build_information()
 517 if(BUILD_CPU_FEATURES MATCHES "rdtscp")
 518     # The timestep counter headers do not include config.h
 519     add_definitions(-DHAVE_RDTSCP)
 520 endif(BUILD_CPU_FEATURES MATCHES "rdtscp")
 521
 522 include(gmxTestFloatFormat)
 523 gmx_test_float_format(GMX_FLOAT_FORMAT_IEEE754
 524                       GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER
 525                       GMX_IEEE754_BIG_ENDIAN_WORD_ORDER)
 526
 527 include(gmxTestLargeFiles)
 528 gmx_test_large_files(GMX_LARGEFILES)
 529 check_function_exists(fseeko     HAVE_FSEEKO)
 530
 531 include(gmxTestSignal)
 532 gmx_test_sigusr1(HAVE_SIGUSR1)
 533
 534 include(gmxTestInline)
 535 gmx_test_inline(INLINE_KEYWORD)
 536
 537 include(gmxTestPipes)
 538 gmx_test_pipes(HAVE_PIPES)
 539
 540 include(gmxTestIsfinite)
 541 gmx_test_isfinite(HAVE_ISFINITE)
 542 gmx_test__isfinite(HAVE__ISFINITE)
 543 gmx_test__finite(HAVE__FINITE)
 544
 545 include(gmxTestCXX11)
 546 gmx_test_cxx11(GMX_CXX11 CXX11_FLAG)
 547 set(GROMACS_CXX_FLAGS "${CXX11_FLAG} ${GROMACS_CXX_FLAGS}")
 548
 549 include(gmxTestXDR)
 550 gmx_test_xdr(GMX_SYSTEM_XDR)
 551 if(NOT GMX_SYSTEM_XDR)
 552     set(GMX_INTERNAL_XDR 1)
 553     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_INTERNAL_XDR")
 554 endif(NOT GMX_SYSTEM_XDR)
 555
 556 # Process nonbonded accelerated kernels settings
 557 string(TOUPPER ${GMX_ACCELERATION} ${GMX_ACCELERATION})
 558 if(${GMX_ACCELERATION} STREQUAL "NONE")
 559     # nothing to do
 560 elseif(${GMX_ACCELERATION} STREQUAL "SSE2")
 561
 562     GMX_TEST_CFLAG(GNU_SSE2_CFLAG "-msse2" GROMACS_C_FLAGS)
 563     if(NOT GNU_SSE2_CFLAG)
 564         GMX_TEST_CFLAG(MSVC_SSE2_CFLAG "/arch:SSE2" GROMACS_C_FLAGS)
 565     endif(NOT GNU_SSE2_CFLAG)
 566
 567     GMX_TEST_CXXFLAG(GNU_SSE2_CXXFLAG "-msse2" GROMACS_CXX_FLAGS)
 568     if(NOT GNU_SSE2_CXXFLAG)
 569         GMX_TEST_CXXFLAG(MSVC_SSE2_CXXFLAG "/arch:SSE2" GROMACS_CXX_FLAGS)
 570     endif(NOT GNU_SSE2_CXXFLAG)
 571
 572     # We dont warn for lacking SSE2 flag support, since that is probably standard today.
 573
 574     # Only test the include after we have tried to add the correct flag for SSE2 support
 575     check_include_file(emmintrin.h  HAVE_EMMINTRIN_H ${GROMACS_C_FLAGS})
 576
 577     if(NOT HAVE_EMMINTRIN_H)
 578         message(FATAL_ERROR "Cannot find emmintrin.h, which is required for SSE2 intrinsics support.")
 579     endif(NOT HAVE_EMMINTRIN_H)
 580
 581     # The user should not be able to set this orthogonally to the acceleration
 582     set(GMX_X86_SSE2 1)
 583
 584     message(STATUS "Enabling SSE2 Gromacs acceleration, and it will help compiler optimization.")
 585
 586 elseif(${GMX_ACCELERATION} STREQUAL "SSE4.1")
 587
 588     GMX_TEST_CFLAG(GNU_SSE4_CFLAG "-msse4.1" GROMACS_C_FLAGS)
 589     if (NOT GNU_SSE4_CFLAG)
 590         GMX_TEST_CFLAG(MSVC_SSE4_CFLAG "/arch:SSE4.1" GROMACS_C_FLAGS)
 591     endif(NOT GNU_SSE4_CFLAG)
 592     if (NOT GNU_SSE4_CFLAG AND NOT MSVC_SSE4_CFLAG)
 593         message(WARNING "No C SSE4.1 flag found. Consider a newer compiler, or disable SSE4.1 for slightly lower performance.")
 594         # Not surprising if we end up here! MSVC current does not support the SSE4.1 flag. However, it appears to accept SSE4.1
 595         # intrinsics when SSE2 support is enabled, so we try that instead.
 596         GMX_TEST_CFLAG(MSVC_SSE2_CFLAG "/arch:SSE2" GROMACS_C_FLAGS)
 597     endif(NOT GNU_SSE4_CFLAG AND NOT MSVC_SSE4_CFLAG)
 598
 599     GMX_TEST_CXXFLAG(GNU_SSE4_CXXFLAG "-msse4.1" GROMACS_CXX_FLAG)
 600     if (NOT GNU_SSE4_CXXFLAG)
 601        GMX_TEST_CXXFLAG(MSVC_SSE4_CXXFLAG "/arch:SSE4.1" GROMACS_CXX_FLAGS)
 602     endif(NOT GNU_SSE4_CXXFLAG)
 603     if (NOT GNU_SSE4_CXXFLAG AND NOT MSVC_SSE4_CXXFLAG)
 604         message(WARNING "No C++ SSE4.1 flag found. Consider a newer compiler, or disable SSE4.1 for slightly lower performance.")
 605         # Not surprising if we end up here! MSVC current does not support the SSE4.1 flag. However, it appears to accept SSE4.1
 606         # intrinsics when SSE2 support is enabled, so we try that instead.
 607         GMX_TEST_CXXFLAG(MSVC_SSE2_CXXFLAG "/arch:SSE2" GROMACS_CXX_FLAGS)
 608     endif(NOT GNU_SSE4_CXXFLAG AND NOT MSVC_SSE4_CXXFLAG)
 609
 610     # This must come after we have added the -msse4.1 flag on some platforms.
 611     check_include_file(smmintrin.h  HAVE_SMMINTRIN_H ${GROMACS_C_FLAGS})
 612
 613     if(NOT HAVE_SMMINTRIN_H)
 614         message(FATAL_ERROR "Cannot find smmintrin.h, which is required for SSE4.1 intrinsics support.")
 615     endif(NOT HAVE_SMMINTRIN_H)
 616
 617     # The user should not be able to set this orthogonally to the acceleration
 618     set(GMX_X86_SSE4_1 1)
 619     set(GMX_X86_SSE2   1)
 620
 621     message(STATUS "Enabling SSE4.1 Gromacs acceleration, and it will help compiler optimization.")
 622
 623 elseif(${GMX_ACCELERATION} STREQUAL "AVX_128_FMA" OR ${GMX_ACCELERATION} STREQUAL "AVX_256")
 624
 625     # Set the AVX compiler flag for both these choices!
 626
 627     GMX_TEST_CFLAG(GNU_AVX_CFLAG "-mavx" GROMACS_C_FLAGS)
 628     if (NOT GNU_AVX_CFLAG)
 629         GMX_TEST_CFLAG(MSVC_AVX_CFLAG "/arch:AVX" GROMACS_C_FLAGS)
 630     endif (NOT GNU_AVX_CFLAG)
 631     if (NOT GNU_AVX_CFLAG AND NOT MSVC_AVX_CFLAG)
 632         message(WARNING "No C AVX flag found. Consider a newer compiler, or disable AVX for much lower performance.")
 633     endif (NOT GNU_AVX_CFLAG AND NOT MSVC_AVX_CFLAG)
 634
 635     GMX_TEST_CXXFLAG(GNU_AVX_CXXFLAG "-mavx" GROMACS_CXX_FLAGS)
 636     if (NOT GNU_AVX_CXXFLAG)
 637        GMX_TEST_CXXFLAG(MSVC_AVX_CXXFLAG "/arch:AVX" GROMACS_CXX_FLAGS)
 638     endif (NOT GNU_AVX_CXXFLAG)
 639     if (NOT GNU_AVX_CXXFLAG AND NOT MSVC_AVX_CXXFLAG)
 640        message(WARNING "No C++ AVX flag found. Consider a newer compiler, or disable AVX for much lower performance.")
 641     endif (NOT GNU_AVX_CXXFLAG AND NOT MSVC_AVX_CXXFLAG)
 642
 643     # Only test the header after we have tried to add the flag for AVX support
 644     check_include_file(immintrin.h  HAVE_IMMINTRIN_H ${GROMACS_C_FLAGS})
 645
 646     if(NOT HAVE_IMMINTRIN_H)
 647         message(FATAL_ERROR "Cannot find immintrin.h, which is required for AVX intrinsics support. Consider switching compiler.")
 648     endif(NOT HAVE_IMMINTRIN_H)
 649
 650     # AMD says we should include x86intrin.h for FMA support, but MSVC seems to do fine without it, so don't require it.
 651     check_include_file(x86intrin.h HAVE_X86INTRIN_H ${GROMACS_C_FLAGS})
 652
 653     # The user should not be able to set this orthogonally to the acceleration
 654     set(GMX_X86_SSE4_1 1)
 655     set(GMX_X86_SSE2   1)
 656
 657     # But just enable one of the choices internally...
 658     if(${GMX_ACCELERATION} STREQUAL "AVX_128_FMA")
 659         set(GMX_X86_AVX_128_FMA 1)
 660         message(STATUS "Enabling 128-bit AVX Gromacs acceleration (with fused-multiply add), and it will help compiler optimization.")
 661     else()
 662         # If we are not doing AVX_128, it must be AVX_256...
 663         set(GMX_X86_AVX_256 1)
 664         message(STATUS "Enabling 256-bit AVX Gromacs acceleration, and it will help compiler optimization.")
 665     endif()
 666
 667 elseif(${GMX_ACCELERATION} STREQUAL "FORTRAN")
 668
 669 #    Fortran is temporarily disabled while we push in nbNxN kernels.
 670 #    We need to fake it a bit here to avoid jenkins build errors!
 671 #    add_definitions(-DGMX_FORTRAN)
 672
 673 elseif(${GMX_ACCELERATION} STREQUAL "BLUEGENE")
 674 # GMX_ACCELERATION=BlueGene should be set in the Toolchain-BlueGene?-???.cmake file
 675     message(STATUS "Configuring for BlueGene")
 676     set(GMX_BLUEGENE 1)
 677     if (${CMAKE_SYSTEM_NAME} STREQUAL "BlueGeneL")
 678         set(SHARED_LIBS_DEFAULT OFF CACHE BOOL "Shared libraries not compatible with BlueGene/L, disabled!" FORCE)
 679         set(BUILD_SHARED_LIBS OFF CACHE BOOL "Shared libraries not compatible with BlueGene/L, disabled!" FORCE)
 680     endif (${CMAKE_SYSTEM_NAME} STREQUAL "BlueGeneL")
 681     set(GMX_SOFTWARE_INVSQRT OFF CACHE BOOL "Do not use software reciprocal square root on BlueGene" FORCE)
 682     set(GMX_POWERPC_INVSQRT ON CACHE BOOL "Use hardware reciprocal square root on BlueGene" FORCE)
 683     set(GMX_X11 OFF CACHE BOOL "X11 not compatible with BlueGene, disabled!" FORCE)
 684     set(GMX_THREAD_MPI OFF CACHE BOOL "Thread-MPI not compatible with BlueGene, disabled!" FORCE)
 685     set(GMX_MPI ON CACHE BOOL "Use MPI on BlueGene" FORCE)
 686 elseif(${GMX_ACCELERATION} STREQUAL "POWER6")
 687     set(GMX_POWER6 1)
 688     set(GMX_SOFTWARE_INVSQRT OFF CACHE BOOL "Do not use software reciprocal square root on Power6" FORCE)
 689     set(GMX_POWERPC_INVSQRT ON CACHE BOOL "Use hardware reciprocal square root on Power6" FORCE)
 690 else(${GMX_ACCELERATION} STREQUAL "NONE")
 691     MESSAGE(FATAL_ERROR "Unrecognized option for accelerated kernels: ${GMX_ACCELERATION}. Pick one of None, SSE2, SSE4.1, AVX_128_FMA, AVX_256, Fortran, BlueGene, Power6")
 692 endif(${GMX_ACCELERATION} STREQUAL "NONE")
 693
 694 if(GMX_FORTRAN OR GMX_POWER6)
 695     if (GMX_THREAD_MPI)
 696         message(FATAL_ERROR "FORTRAN/POWER6 is incompatible with thread-MPI and only provides a speed-up on certain IBM compilers. Disable FORTRAN (or threads if you really want to use FORTRAN kernels).")
 697     endif(GMX_THREAD_MPI)
 698     enable_language(Fortran)
 699     include(FortranCInterface)
 700     discover_fortran_mangling(prefix isupper suffix extra_under_score found)
 701     if(extra_under_score)
 702         set(extrasuffix "_")
 703     endif(extra_under_score)
 704     if(prefix)
 705       set(prefix "${prefix} ##")
 706     endif(prefix)
 707     if(suffix)
 708       set(suffix "## ${suffix}")
 709       if(extrasuffix)
 710         set(extrasuffix "${suffix}${extrasuffix}")
 711       endif(extrasuffix)
 712     else(suffix)
 713       if(extrasuffix)
 714         # Don't know if this is needed, but it can't hurt
 715         set(extrasuffix "## ${extrasuffix}")
 716       endif(extrasuffix)
 717     endif(suffix)
 718
 719     if(isupper)
 720         set(F77_FUNCDEF   "${prefix} NAME ${suffix}")
 721         # The underscored versions are not currently used.
 722         #set(F77_FUNCDEF_  "${prefix} NAME ${extrasuffix}")
 723     else(isupper)
 724         set(F77_FUNCDEF   "${prefix} name ${suffix}")
 725         #set(F77_FUNCDEF_  "${prefix} name ${extrasuffix}")
 726     endif(isupper)
 727 else(GMX_FORTRAN OR GMX_POWER6)
 728         set(F77_FUNCDEF   "name ## _")
 729         #set(F77_FUNCDEF_  "name ## _")
 730 endif(GMX_FORTRAN OR GMX_POWER6)
 731
 732 # Process QM/MM Settings
 733 string(TOUPPER ${GMX_QMMM_PROGRAM} ${GMX_QMMM_PROGRAM})
 734 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 735     set(GMX_QMMM_GAUSSIAN 1)
 736 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 737     set(GMX_QMMM_MOPAC 1)
 738 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 739     set(GMX_QMMM_GAMESS 1)
 740 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 741     set(GMX_QMMM_ORCA 1)
 742 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 743     # nothing to do
 744 else(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 745     MESSAGE(FATAL_ERROR "Invalid QM/MM program option: ${GMX_QMMM_PROGRAM}. Choose one of: Gaussian, Mopac, Gamess, Orca, None")
 746 endif(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 747
 748 # Process FFT library settings - if not OpenMM build
 749 string(TOUPPER ${GMX_FFT_LIBRARY} ${GMX_FFT_LIBRARY})
 750 set(PKG_FFT "")
 751 set(PKG_FFT_LIBS "")
 752 if(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 753     if(GMX_DOUBLE)
 754         find_package(FFTW 3 COMPONENTS fftw)
 755     else(GMX_DOUBLE)
 756         find_package(FFTW 3 COMPONENTS fftwf)
 757     endif(GMX_DOUBLE)
 758     if(NOT FFTW_FOUND)
 759       MESSAGE(FATAL_ERROR "Cannot find FFTW3 (with correct precision - libfftw3f for single precision GROMACS or libfftw3 for double precision GROMACS). Fix it, choose another FFT library, or use the Gromacs built-in fftpack (slower)!")
 760     endif(NOT FFTW_FOUND)
 761     include_directories(${FFTW_INCLUDE_DIRS})
 762     set(FFT_LIBRARIES ${FFTW_LIBRARIES})
 763     set(PKG_FFT "${FFTW_PKG}")
 764
 765     set(GMX_FFT_FFTW3 1)
 766
 767     if (${GMX_ACCELERATION} STREQUAL "SSE" AND NOT FFTW_HAVE_SSE)
 768       message(WARNING "The fftw library found is compiled without SSE support, which makes it slow. Consider recompiling it or contact your admin")
 769     endif (${GMX_ACCELERATION} STREQUAL "SSE" AND NOT FFTW_HAVE_SSE)
 770
 771 elseif(${GMX_FFT_LIBRARY} STREQUAL "MKL")
 772 #    MESSAGE(STATUS "Using external FFT library - Intel MKL")
 773     find_package(MKL REQUIRED)
 774     include_directories(${MKL_INCLUDE_DIR})
 775     set(FFT_LIBRARIES ${MKL_LIBRARIES})
 776     set(PKG_FFT_LIBS ${MKL_LIBRARIES})
 777
 778     set(GMX_FFT_MKL 1)
 779     set(HAVE_MKL 1)
 780
 781 #elseif(${GMX_FFT_LIBRARY} STREQUAL "ACML")
 782 #    MESSAGE(STATUS "Using external FFT library - AMD core math library")
 783 #    set(GMX_FFT_ACML 1)
 784 elseif(${GMX_FFT_LIBRARY} STREQUAL "FFTPACK")
 785     MESSAGE(STATUS "Using internal FFT library - fftpack")
 786     set(GMX_FFT_FFTPACK 1)
 787 else(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 788     MESSAGE(FATAL_ERROR "Invalid FFT library setting: ${GMX_FFT_LIBRARY}. Choose one of: fftw3, mkl, fftpack")
 789 endif(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 790
 791 set(GMX_EXTERNAL_BLAS TRUE CACHE BOOL "Use external BLAS instead of built-in")
 792 set(GMX_EXTERNAL_LAPACK TRUE CACHE BOOL "Use external LAPACK instead of built-in")
 793 # MKL has BLAS/LAPACK routines
 794 if(NOT HAVE_MKL AND NOT ACCELERATE_FRAMEWORK)
 795   if(GMX_EXTERNAL_BLAS)
 796     if (GMX_BLAS_USER)
 797         list(APPEND GMX_EXTRA_LIBRARIES ${GMX_BLAS_USER})
 798     else(GMX_BLAS_USER)
 799         set(BLAS_FIND_QUIETLY ON)
 800         find_package(BLAS)
 801         if (BLAS_FOUND)
 802           list(APPEND GMX_EXTRA_LIBRARIES ${BLAS_LIBRARIES})
 803         else()
 804           MESSAGE(STATUS "Using internal BLAS library")
 805           set(GMX_EXTERNAL_BLAS FALSE CACHE BOOL "Use external BLAS instead of built-in" FORCE)
 806         endif()
 807     endif(GMX_BLAS_USER)
 808   endif(GMX_EXTERNAL_BLAS)
 809   if(GMX_EXTERNAL_LAPACK)
 810     if (GMX_LAPACK_USER)
 811         list(APPEND GMX_EXTRA_LIBRARIES ${GMX_LAPACK_USER})
 812     else(GMX_LAPACK_USER)
 813         set(LAPACK_FIND_QUIETLY ON)
 814         find_package(LAPACK)
 815         if (LAPACK_FOUND)
 816           list(APPEND GMX_EXTRA_LIBRARIES ${LAPACK_LIBRARIES})
 817         else()
 818           MESSAGE(STATUS "Using internal LAPACK library")
 819           set(GMX_EXTERNAL_LAPACK FALSE CACHE BOOL "Use external LAPACK instead of built-in" FORCE)
 820         endif()
 821     endif(GMX_LAPACK_USER)
 822   endif(GMX_EXTERNAL_LAPACK)
 823 endif()
 824 mark_as_advanced(GMX_EXTERNAL_LAPACK)
 825 mark_as_advanced(GMX_EXTERNAL_BLAS)
 826
 827 set(GMX_USE_PLUGINS OFF CACHE INTERNAL "Whether GROMACS will really try to compile support for VMD plugins")
 828 set(GMX_VMD_PLUGIN_PATH)
 829 mark_as_advanced(GMX_VMD_PLUGIN_PATH)
 830
 831 if(GMX_LOAD_PLUGINS)
 832   if(CYGWIN OR NOT WIN32)
 833     # Native Windows does not have, nor need dlopen
 834     # Note that WIN32 is set with Cygwin, but Cygwin needs dlopen to use plug-ins
 835     include(gmxTestdlopen)
 836     gmx_test_dlopen(HAVE_DLOPEN)
 837   endif()
 838
 839   find_package(VMD)
 840
 841   # Test for unsuitable versions of VMD
 842
 843   if(VMD_FOUND AND NOT GMX_VMD_PLUGIN_PATH)
 844     message(STATUS "Checking for suitable VMD version")
 845     exec_program(${VMD_EXECUTABLE}
 846       ARGS --help
 847       OUTPUT_VARIABLE VMD_HELP
 848       RETURN_VALUE VMD_EXEC_RETURN)
 849
 850     if(VMD_EXEC_RETURN EQUAL 0)
 851       # This is the accepted idiom for subexpression matching, unfortunately
 852       string(REGEX REPLACE ".*VMD for .*, version ([0-9]+\\.[0-9]*\\.?[0-9]*).*" "\\1" VMD_VERSION ${VMD_HELP})
 853       string(REGEX REPLACE ".*VMD for (.*), version .*" "\\1" VMD_ARCH ${VMD_HELP})
 854
 855       if(VMD_VERSION VERSION_LESS "1.8")
 856         MESSAGE(WARNING "Found VMD version ${VMD_VERSION}, but GROMACS needs at least 1.8")
 857         unset(VMD_EXECUTABLE)
 858         set(VMD_FOUND FALSE)
 859       else()
 860         message(STATUS "VMD version ${VMD_VERSION} is suitable")
 861         if(DEFINED ENV{VMDDIR})
 862           # This permits GROMACS to avoid hard-coding a fall-back
 863           # path that it can tell right now would be useless.
 864           set(GMX_VMD_PLUGIN_PATH "$ENV{VMDDIR}/plugins/${VMD_ARCH}/molfile" CACHE PATH "Path to VMD plugins for molfile I/O")
 865         else()
 866           set(GMX_VMD_PLUGIN_PATH "/usr/local/lib/vmd/plugins/*/molfile" CACHE PATH "Path to VMD plugins for molfile I/O")
 867         endif()
 868       endif()
 869
 870       # clean up
 871       unset(VMD_HELP)
 872       unset(VMD_VERSION)
 873       unset(VMD_ARCH)
 874     endif()
 875   endif()
 876
 877   # so, should we use plug-ins?
 878   if((WIN32 AND NOT CYGWIN) OR (HAVE_DLOPEN AND BUILD_SHARED_LIBS))
 879     if (NOT VMD_QUIETLY)
 880       MESSAGE(STATUS "Found the ability to use plug-ins when building shared libaries, so will compile to use plug-ins (e.g. to read VMD-supported file formats).")
 881     endif(NOT VMD_QUIETLY)
 882     set(GMX_USE_PLUGINS ON)
 883     list(APPEND GMX_EXTRA_LIBRARIES ${CMAKE_DL_LIBS}) # magic cross-platform pre-set variable for dlopen library
 884     set(PKG_DL_LIBS "-l${CMAKE_DL_LIBS}")
 885   else()
 886     set(PKG_DL_LIBS)
 887   endif()
 888 endif(GMX_LOAD_PLUGINS)
 889 set(VMD_QUIETLY TRUE CACHE INTERNAL "")
 890
 891 # Math and thread libraries must often come after all others when linking...
 892 if(HAVE_LIBM)
 893     list(APPEND GMX_EXTRA_LIBRARIES m)
 894 endif(HAVE_LIBM)
 895
 896 if(GMX_FAHCORE)
 897   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 898       "Path to swindirect.h")
 899   include_directories(${COREWRAP_INCLUDE_DIR})
 900 endif(GMX_FAHCORE)
 901
 902 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 903 # these are set after everything else
 904 if (NOT DEFINED GROMACS_C_FLAGS_SET)
 905     set(GROMACS_C_FLAGS_SET true CACHE INTERNAL "Whether to reset the C flags"
 906         FORCE)
 907     set(CMAKE_C_FLAGS "${GROMACS_C_FLAGS} ${CMAKE_C_FLAGS}" CACHE STRING
 908         "Flags used by the compiler during all build types" FORCE)
 909     set(CMAKE_CXX_FLAGS "${GROMACS_CXX_FLAGS} ${CMAKE_CXX_FLAGS}" CACHE STRING
 910         "Flags used by the compiler during all build types" FORCE)
 911     set(CMAKE_EXE_LINKER_FLAGS
 912         "${GROMACS_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}"
 913         CACHE STRING "Linker flags" FORCE)
 914 endif (NOT DEFINED GROMACS_C_FLAGS_SET)
 915
 916 ######################################
 917 # Output compiler and CFLAGS used
 918 ######################################
 919 execute_process(COMMAND ${CMAKE_C_COMPILER} --version RESULT_VARIABLE TMP_RESULT OUTPUT_VARIABLE CC_VERSION ERROR_VARIABLE CC_VERSION)
 920 #try executing just the compiler command if that failed...
 921 if(TMP_RESULT)
 922     execute_process(COMMAND ${CMAKE_C_COMPILER} RESULT_VARIABLE TMP_RESULT OUTPUT_VARIABLE CC_VERSION ERROR_VARIABLE CC_VERSION)
 923 endif()
 924 string(LENGTH "${CC_VERSION}" len)
 925 if(len)
 926     string(REGEX MATCH "[^\n]*" CC_VERSION "${CC_VERSION}")
 927 endif()
 928
 929 set(BUILD_COMPILER "@CMAKE_C_COMPILER@ @CMAKE_C_COMPILER_ID@ @CC_VERSION@")
 930 set(BUILD_CFLAGS "@CMAKE_C_FLAGS@")
 931 if(CMAKE_BUILD_TYPE STREQUAL "Debug")
 932     set(BUILD_CFLAGS "@BUILD_CFLAGS@ @CMAKE_C_FLAGS_DEBUG@")
 933 elseif(CMAKE_BUILD_TYPE STREQUAL "Release")
 934     set(BUILD_CFLAGS "@BUILD_CFLAGS@ @CMAKE_C_FLAGS_RELEASE@")
 935 elseif(CMAKE_BUILD_TYPE STREQUAL "MinSizeRel")
 936     set(BUILD_CFLAGS "@BUILD_CFLAGS@ @CMAKE_C_FLAGS_MINSIZEREL@")
 937 elseif(CMAKE_BUILD_TYPE STREQUAL "RelWithDebInfo")
 938     set(BUILD_CFLAGS "@BUILD_CFLAGS@ @CMAKE_C_FLAGS_RELWITHDEBINFO@")
 939 endif()
 940
 941
 942 ########################################################################
 943 # Specify install locations and which subdirectories to process        #
 944 ########################################################################
 945 if ( DEFINED GMXLIB )
 946     set(LIB_INSTALL_DIR "${CMAKE_INSTALL_PREFIX}/${GMXLIB}")
 947 else()
 948     set(LIB_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/lib)
 949 endif()
 950 set(BIN_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/bin)
 951 set(DATA_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/gromacs)
 952 set(MAN_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/share/man)
 953 set(INCL_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/include)
 954
 955 set(GMXLIBDIR        ${DATA_INSTALL_DIR}/top)
 956
 957 ##################################################################
 958 # Shared library settings - Darwin uses INSTALL_NAME_DIR instead!
 959 ##################################################################
 960 if(NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin")
 961     set(CMAKE_SKIP_BUILD_RPATH  FALSE)
 962     set(CMAKE_BUILD_WITH_INSTALL_RPATH FALSE)
 963     set(CMAKE_INSTALL_RPATH "${LIB_INSTALL_DIR}")
 964     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 965 endif()
 966
 967 add_subdirectory(share)
 968 add_subdirectory(man)
 969 add_subdirectory(src)
 970 add_subdirectory(scripts)
 971
 972 #######################
 973 ## uninstall target
 974 #######################
 975     CONFIGURE_FILE(
 976                    "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 977                    "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
 978                    IMMEDIATE @ONLY)
 979 ###########################
 980 ADD_CUSTOM_TARGET(uninstall
 981                   "${CMAKE_COMMAND}" -P
 982                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
 983 ###########################
 984
 985 ########################################################################
 986 # Doxygen configuration
 987 ########################################################################
 988 if (DOXYGEN_FOUND)
 989     FILE(GLOB NB_KERNEL_DIRS src/gromacs/gmxlib/nonbonded/nb_kernel_*/)
 990     LIST(REMOVE_ITEM NB_KERNEL_DIRS
 991          ${CMAKE_SOURCE_DIR}/src/gromacs/gmxlib/nonbonded/nb_kernel_c)
 992     FOREACH(NB_KERNEL_DIR ${NB_KERNEL_DIRS})
 993         SET(NB_KERNEL_DIRS_TO_IGNORE_IN_DOXYGEN
 994             "${NB_KERNEL_DIRS_TO_IGNORE_IN_DOXYGEN} \\\n                         ${NB_KERNEL_DIR}")
 995     ENDFOREACH(NB_KERNEL_DIR)
 996     CONFIGURE_FILE(${CMAKE_SOURCE_DIR}/Doxyfile.cmakein
 997                    ${CMAKE_BINARY_DIR}/Doxyfile)
 998     CONFIGURE_FILE(${CMAKE_SOURCE_DIR}/Doxyfile-lib.cmakein
 999                    ${CMAKE_BINARY_DIR}/Doxyfile-lib)
1000     CONFIGURE_FILE(${CMAKE_SOURCE_DIR}/Doxyfile-user.cmakein
1001                    ${CMAKE_BINARY_DIR}/Doxyfile-user)
1002     add_custom_target(doc
1003       ${DOXYGEN_EXECUTABLE} ${CMAKE_CURRENT_BINARY_DIR}/Doxyfile
1004       WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}
1005       COMMENT "Generating full documentation with Doxygen" VERBATIM)
1006     add_custom_target(doc-user
1007       ${DOXYGEN_EXECUTABLE} ${CMAKE_CURRENT_BINARY_DIR}/Doxyfile-user
1008       WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}
1009       COMMENT "Generating user documentation with Doxygen" VERBATIM)
1010     add_custom_target(doc-lib
1011       ${DOXYGEN_EXECUTABLE} ${CMAKE_CURRENT_BINARY_DIR}/Doxyfile-lib
1012       WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}
1013       COMMENT "Generating libary documentation with Doxygen" VERBATIM)
1014 endif (DOXYGEN_FOUND)
1015
1016
1017 ########################################################################
1018 # Tests                                                                #
1019 ########################################################################
1020
1021 include(CTest)
1022 mark_as_advanced(BUILD_TESTING)
1023 IF(BUILD_TESTING)
1024     enable_testing()
1025     add_subdirectory(tests)
1026 ENDIF()
1027