CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2012, by the GROMACS development team, led by
   5 # David van der Spoel, Berk Hess, Erik Lindahl, and including many
   6 # others, as listed in the AUTHORS file in the top-level source
   7 # directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34 #
  35 cmake_minimum_required(VERSION 2.8)
  36 # Keep CMake suitably quiet on Cygwin
  37 set(CMAKE_LEGACY_CYGWIN_WIN32 0) # Remove when CMake >= 2.8.4 is required
  38
  39 # Allows CPack to act differently for normal tools and mdrun (e.g. because of MPI)
  40 set(CPACK_COMPONENT_GROUP_TOOLS_DESCRIPTION "All GROMACS executable tools")
  41 set(CPACK_COMPONENT_GROUP_MDRUN_DESCRIPTION "GROMACS executable for running simulations")
  42
  43 # CMake modules/macros are in a subdirectory to keep this file cleaner
  44 # This needs to be set before project() in order to pick up toolchain files
  45 list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake ${CMAKE_CURRENT_SOURCE_DIR}/cmake/Platform)
  46
  47 project(Gromacs C)
  48 include(Dart)
  49 mark_as_advanced(DART_ROOT)
  50
  51 # PROJECT_VERSION should have the following structure:
  52 # VERSION-dev[-SUFFIX] where the VERSION should have the for: vMajor.vMinor.vPatch
  53 #
  54 # The "-dev" suffix is important to keep because it makes possible to distinguish
  55 # between a build from official release and a build from git release branch on a
  56 # machine with no git.
  57 #
  58 # NOTE: when releasing the "-dev" suffix needs to be stripped off!
  59 set(PROJECT_VERSION "4.6-beta3-dev")
  60 set(CUSTOM_VERSION_STRING ""
  61     CACHE STRING "Custom version string (if empty, use hard-coded default)")
  62 mark_as_advanced(CUSTOM_VERSION_STRING)
  63 if (CUSTOM_VERSION_STRING)
  64     set(PROJECT_VERSION ${CUSTOM_VERSION_STRING})
  65 endif (CUSTOM_VERSION_STRING)
  66 set(SOVERSION 6)
  67 # It is a bit irritating, but this has to be set separately for now!
  68 SET(CPACK_PACKAGE_VERSION_MAJOR "4")
  69 SET(CPACK_PACKAGE_VERSION_MINOR "6")
  70 #SET(CPACK_PACKAGE_VERSION_PATCH "0")
  71
  72 # The numerical gromacs version. It is 40600 for 4.6.0.
  73 # The #define GMX_VERSION in gmx_header_config_h is set to this value.
  74 math(EXPR NUM_VERSION
  75     "${CPACK_PACKAGE_VERSION_MAJOR}*10000 + ${CPACK_PACKAGE_VERSION_MINOR}*100")
  76 if(CPACK_PACKAGE_VERSION_PATCH)
  77     math(EXPR NUM_VERSION
  78          "${NUM_VERSION} + ${CPACK_PACKAGE_VERSION_PATCH}")
  79 endif()
  80
  81 # The API version tracks the numerical Gromacs version (for now).
  82 # It is potentially different from the Gromacs version in the future, if
  83 # the programs/libraries diverge from the presumably more stable API.
  84 # The #define GMX_API_VERSION in version.h is set to this value to
  85 # provide backward compatibility of software written against the Gromacs API.
  86 set(API_VERSION ${NUM_VERSION})
  87
  88 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT AND UNIX)
  89 set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
  90 endif()
  91
  92 include(gmxBuildTypeReference)
  93
  94 if(NOT CMAKE_BUILD_TYPE)
  95     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel Reference." FORCE)
  96 endif(NOT CMAKE_BUILD_TYPE)
  97
  98 enable_language(C)
  99
 100 set(GMX_USE_RELATIVE_INSTALL_PATH OFF CACHE STRING "Use relative paths not absolute paths for cmake install. Has only an effect on cpack.")
 101 mark_as_advanced(GMX_USE_RELATIVE_INSTALL_PATH)
 102
 103 set(CPACK_PACKAGE_VERSION ${PROJECT_VERSION})
 104 set(CPACK_PACKAGE_VENDOR "gromacs.org")
 105 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Gromacs - a toolkit for high-performance molecular simulation")
 106 if (NOT GMX_USE_RELATIVE_INSTALL_PATH)
 107     set(CPACK_SET_DESTDIR "ON")
 108 endif()
 109 set(CPACK_RESOURCE_FILE_WELCOME "${CMAKE_SOURCE_DIR}/admin/InstallWelcome.txt")
 110 # Its GPL/LGPL, so they do not have to agree to a license for mere usage, but some installers require this...
 111 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_SOURCE_DIR}/COPYING")
 112 set(CPACK_RESOURCE_FILE_README "${CMAKE_SOURCE_DIR}/admin/InstallInfo.txt")
 113 set(CPACK_SOURCE_IGNORE_FILES "\\\\.isreposource$;\\\\.git/;\\\\.gitignore$")
 114 set(CPACK_PROJECT_CONFIG_FILE "${CMAKE_SOURCE_DIR}/CPackInit.cmake")
 115 SET(CPACK_SOURCE_INSTALLED_DIRECTORIES "${CMAKE_SOURCE_DIR};/;${CMAKE_BINARY_DIR}/man;man")
 116 set(CPACK_PACKAGE_CONTACT "gmx-users@gromacs.org")
 117
 118 #must come after all cpack settings!
 119 include(CPack)
 120
 121 ########################################################################
 122 # Check and warn if cache generated on a different host is being reused
 123 ########################################################################
 124 if(CMAKE_HOST_UNIX)
 125     execute_process(COMMAND hostname
 126                     OUTPUT_VARIABLE TMP_HOSTNAME
 127                     OUTPUT_STRIP_TRAILING_WHITESPACE)
 128     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}")
 129         message(WARNING "
 130             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
 131             is being reused! This could lead to inconsitencies; therefore, it is
 132             recommended to regenerate the cache!")
 133     endif()
 134     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
 135             "Hostname of the machine where the cache was generated.")
 136 endif()
 137
 138 ########################################################################
 139 # User input options - enable C++ - before any CXX flags are changed   #
 140 ########################################################################
 141
 142 # decide on GPU settings based on user-settings and GPU/CUDA detection
 143 include(gmxManageGPU)
 144
 145 # TODO: move OpenMM to contrib
 146 option(GMX_OPENMM "Accelerated execution on GPUs through the OpenMM library (not fully supported)" OFF)
 147 mark_as_advanced(GMX_OPENMM)
 148
 149 option(GMX_FORCE_CXX "Enable C++ compilation even if not necessary" OFF)
 150 mark_as_advanced(GMX_FORCE_CXX)
 151
 152 option(GMX_COOL_QUOTES "Enable Gromacs cool quotes" ON)
 153 mark_as_advanced(GMX_COOL_QUOTES)
 154
 155 if(GMX_GPU OR GMX_OPENMM OR GMX_FORCE_CXX)
 156     enable_language(CXX)
 157 endif()
 158 set(CMAKE_PREFIX_PATH "" CACHE STRING "Extra locations to search for external libraries and tools (give directory without lib, bin, or include)")
 159
 160 ########################################################################
 161 # Fix stupid flags on Windows
 162 ########################################################################
 163 SET(SHARED_LIBS_DEFAULT ON)
 164 IF( WIN32 AND NOT CYGWIN)
 165   if (NOT BUILD_SHARED_LIBS)
 166     option(GMX_PREFER_STATIC_LIBS "When finding libraries prefer static system libraries (MT instead of MD)!" ON)
 167     mark_as_advanced(GMX_PREFER_STATIC_LIBS)
 168     SET(SHARED_LIBS_DEFAULT OFF)
 169   else()
 170     add_definitions(-DUSE_VISIBILITY -DTMPI_USE_VISIBILITY)
 171     set(PKG_CFLAGS "$PKG_CFLAGS -DUSE_VISIBILITY -DTMPI_USE_VISIBILITY")
 172   endif()
 173
 174   IF (GMX_PREFER_STATIC_LIBS)
 175     #Only setting Debug and Release flags. Others configurations current not used.
 176     STRING(REPLACE /MD /MT CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE})
 177     SET(CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE} CACHE STRING "" FORCE)
 178     STRING(REPLACE /MD /MT CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG})
 179     SET(CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG} CACHE STRING "" FORCE)
 180     if(CMAKE_CXX_COMPILER_LOADED)
 181         STRING(REPLACE /MD /MT CMAKE_CXX_FLAGS_RELEASE ${CMAKE_CXX_FLAGS_RELEASE})
 182         SET(CMAKE_CXX_FLAGS_RELEASE ${CMAKE_CXX_FLAGS_RELEASE} CACHE STRING "" FORCE)
 183         STRING(REPLACE /MD /MT CMAKE_CXX_FLAGS_DEBUG ${CMAKE_CXX_FLAGS_DEBUG})
 184         SET(CMAKE_CXX_FLAGS_DEBUG ${CMAKE_CXX_FLAGS_DEBUG} CACHE STRING "" FORCE)
 185     endif()
 186   ENDIF()
 187
 188   #Workaround for cmake bug 13174. Replace deprecated options.
 189   IF( CMAKE_C_COMPILER_ID MATCHES "Intel" )
 190     if(BUILD_SHARED_LIBS)
 191         STRING(REPLACE "/INCREMENTAL:YES" "" CMAKE_SHARED_LINKER_FLAGS ${CMAKE_SHARED_LINKER_FLAGS})
 192         SET(CMAKE_SHARED_LINKER_FLAGS ${CMAKE_SHARED_LINKER_FLAGS} CACHE STRING "" FORCE)
 193     endif()
 194     STRING(REPLACE /GZ /RTC1 CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG})
 195     SET(CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG} CACHE STRING "" FORCE)
 196   ENDIF()
 197   IF( CMAKE_CXX_COMPILER_ID MATCHES "Intel" AND CMAKE_CXX_COMPILER_LOADED)
 198     STRING(REPLACE /GZ /RTC1 CMAKE_CXX_FLAGS_DEBUG ${CMAKE_CXX_FLAGS_DEBUG})
 199     STRING(REPLACE /GX /EHsc CMAKE_CXX_FLAGS_DEBUG ${CMAKE_CXX_FLAGS_DEBUG})
 200     SET(CMAKE_CXX_FLAGS_DEBUG ${CMAKE_CXX_FLAGS_DEBUG} CACHE STRING "" FORCE)
 201
 202     STRING(REPLACE /GX /EHsc CMAKE_CXX_FLAGS_RELEASE ${CMAKE_CXX_FLAGS_RELEASE})
 203     SET(CMAKE_CXX_FLAGS_RELEASE ${CMAKE_CXX_FLAGS_RELEASE} CACHE STRING "" FORCE)
 204   ENDIF()
 205 ENDIF()
 206
 207
 208 ########################################################################
 209 # User input options                                                   #
 210 ########################################################################
 211 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" OFF)
 212 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 213 option(GMX_THREAD_MPI  "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" ON)
 214 option(GMX_SOFTWARE_INVSQRT "Use GROMACS software 1/sqrt" ON)
 215 mark_as_advanced(GMX_SOFTWARE_INVSQRT)
 216 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 217 mark_as_advanced(GMX_FAHCORE)
 218
 219 include(gmxDetectAcceleration)
 220 if(NOT DEFINED GMX_CPU_ACCELERATION)
 221     if(CMAKE_CROSSCOMPILING)
 222         set(GMX_SUGGESTED_CPU_ACCELERATION "None")
 223     else(CMAKE_CROSSCOMPILING)
 224         gmx_detect_acceleration(GMX_SUGGESTED_CPU_ACCELERATION)
 225     endif(CMAKE_CROSSCOMPILING)
 226 endif(NOT DEFINED GMX_CPU_ACCELERATION)
 227
 228 set(GMX_CPU_ACCELERATION "@GMX_SUGGESTED_CPU_ACCELERATION@"
 229     CACHE STRING "Accelerated CPU kernels. Pick one of: None, SSE2, SSE4.1, AVX_128_FMA, AVX_256, BlueGene")
 230
 231 set(GMX_FFT_LIBRARY "fftw3"
 232     CACHE STRING "FFT library choices: fftw3,mkl,fftpack[built-in]")
 233 option(GMX_BUILD_OWN_FFTW "Download and build FFTW 3 during the GROMACS build process, rather than fall back on the really slow fftpack." OFF)
 234 mark_as_advanced(GMX_BUILD_OWN_FFTW)
 235 option(GMX_DISABLE_FFTW_MEASURE
 236        "Do not optimize FFTW setups (not needed with SSE)" OFF)
 237 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 238 set(GMX_QMMM_PROGRAM "none"
 239     CACHE STRING "QM package choices: none,gaussian,mopac,gamess,orca")
 240 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 241 mark_as_advanced(GMX_BROKEN_CALLOC)
 242 option(GMX_MPI_IN_PLACE "Enable MPI_IN_PLACE for MPIs that have it defined" ON)
 243 mark_as_advanced(GMX_MPI_IN_PLACE)
 244 option(GMX_LOAD_PLUGINS "Compile with plugin support, needed to read VMD supported file formats" ON)
 245 mark_as_advanced(GMX_LOAD_PLUGINS)
 246
 247 option(GMX_OPENMP "Enable OpenMP-based multithreading" ON)
 248
 249 option(USE_VERSION_H "Generate development version string/information" ON)
 250 mark_as_advanced(USE_VERSION_H)
 251
 252 option(GMX_DEFAULT_SUFFIX "Use default suffixes for GROMACS binaries and libs (_d for double, _mpi for MPI; rerun cmake after changing to see relevant options)" ON)
 253
 254 if(UNIX)
 255     option(GMX_PREFER_STATIC_LIBS "When finding libraries prefer static archives (not available on non-*nix platforms and it will only work if static versions of external dependencies are available and found)!" OFF)
 256     mark_as_advanced(GMX_PREFER_STATIC_LIBS)
 257 endif()
 258
 259 option(GMX_CYCLE_SUBCOUNTERS "Enable cycle subcounters to get a more detailed cycle timings" OFF)
 260 mark_as_advanced(GMX_CYCLE_SUBCOUNTERS)
 261
 262 ######################################################################
 263 # Compiler tests
 264 # These need to be done early (before further tests).
 265 #####################################################################
 266
 267 # The cmake/Check{C,CXX}CompilerFlag.cmake files in the GROMACS distribution
 268 # are used with permission from CMake v2.8.9 so that GROMACS can detect
 269 # invalid options with the Intel Compilers.
 270 # These files should be removed from the source tree when a CMake version that
 271 # includes the features in question becomes required for building GROMACS.
 272 include(CheckCCompilerFlag)
 273 if(CMAKE_CXX_COMPILER_LOADED)
 274     include(CheckCXXCompilerFlag)
 275 endif()
 276
 277 # OpenMP check must come before other CFLAGS!
 278 if(GMX_OPENMP)
 279     find_package(OpenMP)
 280     if(OPENMP_FOUND)
 281         # CMake on Windows doesn't support linker flags passed to target_link_libraries
 282         # (i.e. it treats /openmp as \openmp library file). Also, no OpenMP linker flags are needed.
 283         if(NOT (WIN32 AND NOT CYGWIN))
 284             if(CMAKE_COMPILER_IS_GNUCC AND GMX_PREFER_STATIC_OPENMP)
 285                 set(OpenMP_LINKER_FLAGS "-Wl,-static -lgomp -lrt -Wl,-Bdynamic -lpthread")
 286                 set(OpenMP_SHARED_LINKER_FLAGS "")
 287             else()
 288                 # Only set a linker flag if the user didn't set them manually
 289                 if(NOT DEFINED OpenMP_LINKER_FLAGS)
 290                     set(OpenMP_LINKER_FLAGS "${OpenMP_C_FLAGS}")
 291                 endif()
 292                 if(NOT DEFINED OpenMP_SHARED_LINKER_FLAGS)
 293                     set(OpenMP_SHARED_LINKER_FLAGS "${OpenMP_C_FLAGS}")
 294                 endif()
 295             endif()
 296         endif()
 297     else(OPENMP_FOUND)
 298         message(WARNING
 299                 "The compiler you are using does not support OpenMP parallelism. This might hurt your performance a lot, in particular with GPUs. Try using a more recent version, or a different compiler. For now, we are proceeding by turning off OpenMP.")
 300         set(GMX_OPENMP OFF CACHE STRING "Whether GROMACS will use OpenMP parallelism." FORCE)
 301     endif(OPENMP_FOUND)
 302 endif()
 303
 304
 305 include(gmxCFlags)
 306 gmx_c_flags()
 307
 308 include(gmxGetCompilerInfo)
 309 get_compiler_version()
 310
 311 # gcc 4.4.x is buggy and crashes when compiling some files with O3 and OpenMP on.
 312 # Detect here whether applying a workaround is needed and will apply it later
 313 # on the affected files.
 314 include(gmxGCC44O3BugWorkaround)
 315 gmx_check_gcc44_bug_workaround_needed(GMX_USE_GCC44_BUG_WORKAROUND)
 316
 317 # clang 3.0 is buggy for some unknown reason detected during adding
 318 # the SSE2 group kernels for GROMACS 4.6. If we ever work out what
 319 # that is, we should replace these tests with a compiler feature test,
 320 # update GROMACS Redmine task #1039 and perhaps report a clang bug.
 321 #
 322 # In the meantime, until we require CMake 2.8.10 we cannot rely on it to detect
 323 # the compiler version for us. So we need a manual check for clang 3.0.
 324 include(gmxDetectClang30)
 325 gmx_detect_clang_3_0(COMPILER_IS_CLANG_3_0)
 326 if(COMPILER_IS_CLANG_3_0)
 327     message(FATAL_ERROR "Your compiler is clang version 3.0, which is known to be buggy for GROMACS. Use a different compiler.")
 328 endif()
 329
 330 if (CMAKE_C_COMPILER_ID STREQUAL "PGI")
 331     message(WARNING "All tested PGI compiler versions (up to 12.9.0) generate binaries which produce incorrect results, or even fail to compile Gromacs. Highly recommended to use a different compiler. If you choose to use PGI, make sure to run the regressiontests.")
 332 endif()
 333
 334 ########################################################################
 335 # Set up binary and library suffixing
 336 ########################################################################
 337 set(GMX_BINARY_SUFFIX "" CACHE STRING "Suffix for GROMACS binaries (default: _d for double, _mpi for MPI, _mpi_d for MPI and double).")
 338 set(GMX_LIBS_SUFFIX ""
 339   CACHE STRING "Suffix for GROMACS libs (default: _d for double, _mpi for MPI, _mpi_d for MPI and double).")
 340 if (GMX_DEFAULT_SUFFIX)
 341   set(GMX_BINARY_SUFFIX "")
 342   set(GMX_LIBS_SUFFIX "")
 343   if (GMX_MPI)
 344     set(GMX_BINARY_SUFFIX "_mpi")
 345     set(GMX_LIBS_SUFFIX "_mpi")
 346   endif(GMX_MPI)
 347   if (GMX_DOUBLE)
 348     set (GMX_BINARY_SUFFIX "${GMX_BINARY_SUFFIX}_d")
 349     set (GMX_LIBS_SUFFIX "${GMX_LIBS_SUFFIX}_d")
 350   endif(GMX_DOUBLE)
 351   if (GMX_OPENMM)
 352     set (GMX_BINARY_SUFFIX "-openmm")
 353     set (GMX_LIBS_SUFFIX "_openmm")
 354   endif(GMX_OPENMM)
 355   mark_as_advanced(FORCE GMX_BINARY_SUFFIX GMX_LIBS_SUFFIX)
 356   if (NOT SUFFIX_QUIETLY)
 357     message(STATUS "Using default binary suffix: \"${GMX_BINARY_SUFFIX}\"")
 358     message(STATUS "Using default library suffix: \"${GMX_LIBS_SUFFIX}\"")
 359   endif (NOT SUFFIX_QUIETLY)
 360 else(GMX_DEFAULT_SUFFIX)
 361   mark_as_advanced(CLEAR GMX_BINARY_SUFFIX GMX_LIBS_SUFFIX)
 362   if (NOT SUFFIX_QUIETLY)
 363     message(STATUS "Using manually set binary suffix: \"${GMX_BINARY_SUFFIX}\"")
 364     message(STATUS "Using manually set library suffix: \"${GMX_LIBS_SUFFIX}\"")
 365   endif (NOT SUFFIX_QUIETLY)
 366 endif(GMX_DEFAULT_SUFFIX)
 367 set(SUFFIX_QUIETLY TRUE CACHE INTERNAL "")
 368
 369 set(PKG_CFLAGS "")
 370 if(GMX_DOUBLE)
 371     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_DOUBLE")
 372 endif(GMX_DOUBLE)
 373 if(GMX_SOFTWARE_INVSQRT)
 374   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_SOFTWARE_INVSQRT")
 375 endif(GMX_SOFTWARE_INVSQRT)
 376
 377 ########################################################################
 378 #Process MPI settings
 379 ########################################################################
 380 include(gmxManageMPI)
 381
 382 #######################################################################
 383 # Check for options incompatible with OpenMM build                    #
 384 #######################################################################
 385 if(GMX_OPENMM)
 386     # we'll use the built-in fft to avoid unnecessary dependencies
 387     string(TOUPPER ${GMX_FFT_LIBRARY} GMX_FFT_LIBRARY)
 388     if(NOT ${GMX_FFT_LIBRARY} STREQUAL "FFTPACK")
 389         message(STATUS "No external FFT libraries needed for the OpenMM build, switching to fftpack!")
 390         set(GMX_FFT_LIBRARY "fftpack" CACHE STRING
 391                 "No external FFT libraries needed for the OpenMM build, switching to  fftpack!" FORCE)
 392     endif()
 393     if(GMX_MPI)
 394         message(FATAL_ERROR "The OpenMM build is not compatible with MPI!")
 395     endif(GMX_MPI)
 396     if(GMX_THREAD_MPI)
 397         message(STATUS "Thread-MPI not compatible with OpenMM, disabled!")
 398         set(GMX_THREAD_MPI OFF CACHE BOOL
 399                 "Thread-MPI not compatible with OpenMM build, disabled!" FORCE)
 400     endif(GMX_THREAD_MPI)
 401     if(GMX_OPENMP)
 402         message(STATUS "OpenMP multithreading not compatible with OpenMM, disabled")
 403         set(GMX_OPENMP OFF CACHE BOOL
 404             "OpenMP multithreading not compatible with OpenMM, disabled!" FORCE)
 405     endif()
 406     if(GMX_SOFTWARE_INVSQRT)
 407         set(GMX_SOFTWARE_INVSQRT OFF CACHE STRING
 408                 "The OpenMM build does not need GROMACS software 1/sqrt!" FORCE)
 409     endif(GMX_SOFTWARE_INVSQRT)
 410     string(TOUPPER ${GMX_CPU_ACCELERATION} GMX_CPU_ACCELERATION)
 411     if(NOT GMX_CPU_ACCELERATION STREQUAL "NONE")
 412         message(STATUS "Switching off CPU-based acceleration, the OpenMM build does not support/need any!")
 413         set(GMX_CPU_ACCELERATION "None" CACHE STRING
 414             "Switching off CPU-based acceleration, the OpenMM build does not support/need any!" FORCE)
 415     endif()
 416     if(GMX_FAHCORE)
 417         message(FATAL_ERROR "The OpenMM build does not support FAH build!")
 418     endif(GMX_FAHCORE)
 419     if(GMX_DOUBLE)
 420         message(FATAL_ERROR  "The OpenMM-build does not support double precision calculations!")
 421     endif()
 422     # mark as advanced the unused variables
 423     mark_as_advanced(FORCE GMX_CPU_ACCELERATION GMX_MPI GMX_FFT_LIBRARY
 424         GMX_QMMM_PROGRAM GMX_THREAD_MPI GMX_DOUBLE)
 425 else(GMX_OPENMM)
 426      mark_as_advanced(CLEAR GMX_CPU_ACCELERATION GMX_MPI GMX_FFT_LIBRARY
 427         GMX_QMMM_PROGRAM GMX_THREAD_MPI GMX_DOUBLE)
 428 endif(GMX_OPENMM)
 429
 430
 431 ########################################################################
 432 # Basic system tests (standard libraries, headers, functions, types)   #
 433 ########################################################################
 434 include(CheckIncludeFiles)
 435 check_include_files(string.h     HAVE_STRING_H)
 436 check_include_files(math.h       HAVE_MATH_H)
 437 check_include_files(limits.h     HAVE_LIMITS_H)
 438 check_include_files(memory.h     HAVE_MEMORY_H)
 439 check_include_files(unistd.h     HAVE_UNISTD_H)
 440 check_include_files(direct.h     HAVE_DIRECT_H)
 441 check_include_files(pwd.h        HAVE_PWD_H)
 442 check_include_files(stdint.h     HAVE_STDINT_H)
 443 check_include_files(stdlib.h     HAVE_STDLIB_H)
 444 check_include_files(pthread.h    HAVE_PTHREAD_H)
 445 check_include_files(dirent.h     HAVE_DIRENT_H)
 446 check_include_files(inttypes.h   HAVE_INTTYPES_H)
 447 check_include_files(regex.h      HAVE_REGEX_H)
 448 check_include_files(sys/types.h  HAVE_SYS_TYPES_H)
 449 check_include_files(sys/stat.h   HAVE_SYS_STAT_H)
 450 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 451 check_include_files(rpc/rpc.h    HAVE_RPC_RPC_H)
 452 check_include_files("rpc/rpc.h;rpc/xdr.h"    HAVE_RPC_XDR_H)
 453 check_include_files(io.h                 HAVE_IO_H)
 454 check_include_files(sched.h      HAVE_SCHED_H)
 455
 456 include(CheckFunctionExists)
 457 check_function_exists(strcasecmp        HAVE_STRCASECMP)
 458 check_function_exists(strdup            HAVE_STRDUP)
 459 check_function_exists(vprintf           HAVE_VPRINTF)
 460 check_function_exists(memcmp            HAVE_MEMCMP)
 461 check_function_exists(posix_memalign    HAVE_POSIX_MEMALIGN)
 462 check_function_exists(memalign          HAVE_MEMALIGN)
 463 check_function_exists(_aligned_malloc   HAVE__ALIGNED_MALLOC)
 464 check_function_exists(gettimeofday      HAVE_GETTIMEOFDAY)
 465 check_function_exists(isnan             HAVE_ISNAN)
 466 check_function_exists(_isnan            HAVE__ISNAN)
 467 check_function_exists(fsync             HAVE_FSYNC)
 468 check_function_exists(_fileno           HAVE__FILENO)
 469 check_function_exists(fileno            HAVE_FILENO)
 470 check_function_exists(_commit           HAVE__COMMIT)
 471 check_function_exists(sigaction         HAVE_SIGACTION)
 472 check_function_exists(sysconf           HAVE_SYSCONF)
 473 check_function_exists(sched_setaffinity HAVE_SCHED_SETAFFINITY)
 474 check_function_exists(sched_getaffinity HAVE_SCHED_GETAFFINITY)
 475 check_function_exists(rsqrt             HAVE_RSQRT)
 476 check_function_exists(rsqrtf            HAVE_RSQRTF)
 477 check_function_exists(sqrtf             HAVE_SQRTF)
 478
 479 include(CheckLibraryExists)
 480 check_library_exists(m sqrt "" HAVE_LIBM)
 481 check_library_exists(m cbrt "" HAVE_CBRT)
 482
 483
 484 include(CheckTypeSize)
 485
 486 check_type_size("bool"          SIZEOF_BOOL) # will also set HAVE_BOOL
 487 check_type_size("int"           SIZEOF_INT)
 488 check_type_size("long int"      SIZEOF_LONG_INT)
 489 check_type_size("long long int" SIZEOF_LONG_LONG_INT)
 490 check_type_size("off_t"         SIZEOF_OFF_T)
 491 check_type_size("void *"        SIZEOF_VOIDP)
 492
 493 if (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 494     set(GMX_64_BIT TRUE)
 495 else (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 496     set(GMX_64_BIT FALSE)
 497 endif (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 498
 499 # Check for some basic types that we *need*, so set these to int if they are not present
 500 check_type_size(uid_t uid_t)
 501 if(NOT uid_t)
 502   set(uid_t int)
 503 else(NOT uid_t)
 504   set(uid_t 0)
 505 endif(NOT uid_t)
 506
 507 check_type_size(gid_t gid_t)
 508 if(NOT gid_t)
 509   set(gid_t 1)
 510 else(NOT gid_t)
 511   set(gid_t 0)
 512 endif(NOT gid_t)
 513
 514 check_type_size(size_t size_t)
 515 if(NOT size_t)
 516   set(size_t int)
 517 else(NOT size_t)
 518   set(size_t 0)
 519 endif(NOT size_t)
 520
 521 check_type_size(off_t off_t)
 522 if(NOT off_t)
 523   set(off_t int)
 524 else(NOT off_t)
 525   set(off_t 0)
 526 endif(NOT off_t)
 527
 528 include(TestBigEndian)
 529 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 530
 531
 532
 533
 534 ########################################################################
 535 # Find external packages                                               #
 536 ########################################################################
 537 if(UNIX)
 538     if(GMX_PREFER_STATIC_LIBS)
 539         # On Linux .a is the static library suffix, on Mac OS X .lib can also
 540         # be used, so we'll add both to the preference list.
 541         SET(CMAKE_FIND_LIBRARY_SUFFIXES ".lib;.a" ${CMAKE_FIND_LIBRARY_SUFFIXES})
 542         if(SHARED_LIBS_DEFAULT)
 543             if(BUILD_SHARED_LIBS) #Warn the user about the combination. But don't overwrite the request.
 544                 message(WARNING "Static libraries requested, and shared Gromacs libraries requested.")
 545             elseif(NOT DEFINED BUILD_SHARED_LIBS) #Change default to OFF. Don't warn if it's already off.
 546                 message(WARNING "Static libraries requested, the GROMACS libraries will also be build static (BUILD_SHARED_LIBS=OFF)")
 547                 set(SHARED_LIBS_DEFAULT OFF)
 548             endif()
 549         endif()
 550     endif()
 551 endif()
 552 option(BUILD_SHARED_LIBS "Enable shared libraries (can be problematic with MPI, Windows)" ${SHARED_LIBS_DEFAULT})
 553
 554 option(GMX_GSL "Add support for gsl" OFF)
 555 if (GMX_GSL)
 556   find_package(gsl)
 557   set(PKG_GSL "")
 558   if(GSL_FOUND)
 559     include_directories(${GSL_INCLUDE_DIR})
 560     set(PKG_GSL gsl)
 561     set(HAVE_LIBGSL 1)
 562   endif(GSL_FOUND)
 563 endif (GMX_GSL)
 564
 565 option(GMX_X11 "Use X window system" OFF)
 566 if (GMX_X11)
 567         find_package(X11)
 568         # X11 includes/libraries are only set in the ngmx subdirectory!
 569         if(X11_FOUND)
 570         set(HAVE_X11 1)
 571         endif(X11_FOUND)
 572 endif(GMX_X11)
 573
 574 include(ThreadMPI)
 575 set(THREAD_MPI_LIB thread_mpi)
 576 if(GMX_THREAD_MPI)
 577     tmpi_get_source_list(THREAD_MPI_SRC)
 578     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_THREAD_MPI")
 579     set(GMX_MPI 1)
 580 else(GMX_THREAD_MPI)
 581     tmpi_get_source_list(THREAD_MPI_SRC NOMPI)
 582 endif(GMX_THREAD_MPI)
 583
 584 if(GMX_OPENMM)
 585     set(CUDA_BUILD_EMULATION OFF)
 586     find_package(CUDA 3.1 REQUIRED)
 587     add_definitions(-DGMX_OPENMM)
 588     if(CMAKE_BUILD_TYPE STREQUAL "DEBUG")
 589         set(CUDA_VERBOSE_BUILD ON)
 590     endif()
 591     find_package(OpenMM)
 592 endif(GMX_OPENMM)
 593
 594 if(GMX_GPU)
 595     # now that we have detected the dependencies, do the second configure pass
 596     gmx_gpu_setup()
 597 endif(GMX_GPU)
 598
 599 if(APPLE)
 600    find_library(ACCELERATE_FRAMEWORK Accelerate)
 601    list(APPEND GMX_EXTRA_LIBRARIES ${ACCELERATE_FRAMEWORK})
 602 endif(APPLE)
 603
 604 if(CYGWIN)
 605     set(GMX_CYGWIN 1)
 606 endif(CYGWIN)
 607
 608 if(WIN32 AND NOT CYGWIN)
 609     set(GMX_NATIVE_WINDOWS 1)
 610 endif()
 611
 612 # only bother with finding git and using version.h if the source is a git repo
 613 if(EXISTS "${CMAKE_SOURCE_DIR}/.git")
 614     if(USE_VERSION_H)
 615         # We need at least git v1.5.3 be able to parse git's date output. If not
 616         # found or the version is too small, we can't generate version information.
 617         find_package(Git)
 618
 619         # Find out the git version
 620         if(GIT_FOUND AND NOT GIT_VERSION)
 621           execute_process(COMMAND ${GIT_EXECUTABLE} "--version"
 622             OUTPUT_VARIABLE _exec_out
 623             OUTPUT_STRIP_TRAILING_WHITESPACE)
 624           string(REGEX REPLACE "git version (.*)" "\\1" GIT_VERSION ${_exec_out})
 625           set(GIT_VERSION ${GIT_VERSION} CACHE STRING "Git version")
 626           mark_as_advanced(GIT_VERSION)
 627         endif()
 628
 629         if(NOT GIT_FOUND OR GIT_VERSION VERSION_LESS "1.5.3")
 630           message("No compatible git version found, won't be able to generate proper development version information.")
 631           set(USE_VERSION_H OFF)
 632         endif()
 633     endif()
 634 else()
 635     set(USE_VERSION_H OFF)
 636 endif()
 637
 638 ########################################################################
 639 # Generate development version info for cache
 640 ########################################################################
 641 # set(GEN_VERSION_INFO_INTERNAL "ON")
 642 # include(gmxGenerateVersionString)
 643
 644 ########################################################################
 645 # Our own GROMACS tests
 646 ########################################################################
 647
 648 add_definitions( -DHAVE_CONFIG_H )
 649 include_directories(${CMAKE_BINARY_DIR}/src)
 650 include_directories(${CMAKE_BINARY_DIR}/include)
 651 include_directories(${CMAKE_SOURCE_DIR}/include)
 652
 653 include(gmxTestInlineASM)
 654 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 655
 656 include(gmxSetBuildInformation)
 657 gmx_set_build_information()
 658 if(BUILD_CPU_FEATURES MATCHES "rdtscp" AND NOT GMX_DISTRIBUTABLE_BUILD)
 659     # The timestep counter headers do not include config.h
 660     add_definitions(-DHAVE_RDTSCP)
 661 endif(BUILD_CPU_FEATURES MATCHES "rdtscp" AND NOT GMX_DISTRIBUTABLE_BUILD)
 662
 663 include(gmxTestFloatFormat)
 664 gmx_test_float_format(GMX_FLOAT_FORMAT_IEEE754
 665                       GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER
 666                       GMX_IEEE754_BIG_ENDIAN_WORD_ORDER)
 667
 668 include(gmxTestLargeFiles)
 669 gmx_test_large_files(GMX_LARGEFILES)
 670
 671 include(gmxTestSignal)
 672 gmx_test_sigusr1(HAVE_SIGUSR1)
 673
 674 include(gmxTestInline)
 675 gmx_test_inline(INLINE_KEYWORD)
 676
 677 include(gmxTestRestrict)
 678 gmx_test_restrict(RESTRICT_KEYWORD)
 679
 680 include(gmxTestPipes)
 681 gmx_test_pipes(HAVE_PIPES)
 682
 683 include(gmxTestIsfinite)
 684 gmx_test_isfinite(HAVE_ISFINITE)
 685 gmx_test__isfinite(HAVE__ISFINITE)
 686 gmx_test__finite(HAVE__FINITE)
 687
 688 include(gmxTestXDR)
 689 gmx_test_xdr(GMX_SYSTEM_XDR)
 690 if(NOT GMX_SYSTEM_XDR)
 691     set(GMX_INTERNAL_XDR 1)
 692     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_INTERNAL_XDR")
 693 endif(NOT GMX_SYSTEM_XDR)
 694
 695 # include avx test source, used if the AVX flags are set below
 696 include(gmxTestAVXMaskload)
 697
 698 # Process nonbonded accelerated kernels settings
 699 string(TOUPPER ${GMX_CPU_ACCELERATION} ${GMX_CPU_ACCELERATION})
 700 if(${GMX_CPU_ACCELERATION} STREQUAL "NONE")
 701     # nothing to do
 702 elseif(${GMX_CPU_ACCELERATION} STREQUAL "SSE2")
 703
 704     GMX_TEST_CFLAG(GNU_SSE2_CFLAG "-msse2" ACCELERATION_C_FLAGS)
 705     if(NOT GNU_SSE2_CFLAG AND GMX_NATIVE_WINDOWS)
 706         GMX_TEST_CFLAG(MSVC_SSE2_CFLAG "/arch:SSE2" ACCELERATION_C_FLAGS)
 707     endif(NOT GNU_SSE2_CFLAG AND GMX_NATIVE_WINDOWS)
 708
 709     if (CMAKE_CXX_COMPILER_LOADED)
 710         GMX_TEST_CXXFLAG(GNU_SSE2_CXXFLAG "-msse2" ACCELERATION_CXX_FLAGS)
 711         if(NOT GNU_SSE2_CXXFLAG AND GMX_NATIVE_WINDOWS)
 712             GMX_TEST_CXXFLAG(MSVC_SSE2_CXXFLAG "/arch:SSE2" ACCELERATION_CXX_FLAGS)
 713         endif(NOT GNU_SSE2_CXXFLAG AND GMX_NATIVE_WINDOWS)
 714     endif()
 715
 716     # We dont warn for lacking SSE2 flag support, since that is probably standard today.
 717
 718     # Only test the include after we have tried to add the correct flag for SSE2 support
 719     check_include_file(emmintrin.h  HAVE_EMMINTRIN_H ${ACCELERATION_C_FLAGS})
 720
 721     if(NOT HAVE_EMMINTRIN_H)
 722         message(FATAL_ERROR "Cannot find emmintrin.h, which is required for SSE2 intrinsics support.")
 723     endif(NOT HAVE_EMMINTRIN_H)
 724
 725     set(GMX_CPU_ACCELERATION_X86_SSE2 1)
 726     # The user should not be able to set this orthogonally to the acceleration
 727     set(GMX_X86_SSE2 1)
 728     if (NOT ACCELERATION_QUIETLY)
 729       message(STATUS "Enabling SSE2 Gromacs acceleration, and it will help compiler optimization.")
 730     endif()
 731
 732 elseif(${GMX_CPU_ACCELERATION} STREQUAL "SSE4.1")
 733
 734     GMX_TEST_CFLAG(GNU_SSE4_CFLAG "-msse4.1" ACCELERATION_C_FLAGS)
 735     if (NOT GNU_SSE4_CFLAG AND GMX_NATIVE_WINDOWS)
 736         GMX_TEST_CFLAG(MSVC_SSE4_CFLAG "/arch:SSE4.1" ACCELERATION_C_FLAGS)
 737     endif(NOT GNU_SSE4_CFLAG AND GMX_NATIVE_WINDOWS)
 738     if (NOT GNU_SSE4_CFLAG AND NOT MSVC_SSE4_CFLAG)
 739         message(WARNING "No C SSE4.1 flag found. Consider a newer compiler, or use SSE2 for slightly lower performance.")
 740         # Not surprising if we end up here! MSVC current does not support the SSE4.1 flag. However, it appears to accept SSE4.1
 741         # intrinsics when SSE2 support is enabled, so we try that instead.
 742         if (GMX_NATIVE_WINDOWS)
 743             GMX_TEST_CFLAG(MSVC_SSE2_CFLAG "/arch:SSE2" ACCELERATION_C_FLAGS)
 744         endif()
 745     endif(NOT GNU_SSE4_CFLAG AND NOT MSVC_SSE4_CFLAG)
 746
 747     if (CMAKE_CXX_COMPILER_LOADED)
 748         GMX_TEST_CXXFLAG(GNU_SSE4_CXXFLAG "-msse4.1" GROMACS_CXX_FLAG)
 749         if (NOT GNU_SSE4_CXXFLAG AND GMX_NATIVE_WINDOWS)
 750             GMX_TEST_CXXFLAG(MSVC_SSE4_CXXFLAG "/arch:SSE4.1" ACCELERATION_CXX_FLAGS)
 751         endif(NOT GNU_SSE4_CXXFLAG AND GMX_NATIVE_WINDOWS)
 752         if (NOT GNU_SSE4_CXXFLAG AND NOT MSVC_SSE4_CXXFLAG)
 753             message(WARNING "No C++ SSE4.1 flag found. Consider a newer compiler, or use SSE2 for slightly lower performance.")
 754             # Not surprising if we end up here! MSVC current does not support the SSE4.1 flag. However, it appears to accept SSE4.1
 755             # intrinsics when SSE2 support is enabled, so we try that instead.
 756             if (GMX_NATIVE_WINDOWS)
 757                 GMX_TEST_CXXFLAG(MSVC_SSE2_CXXFLAG "/arch:SSE2" ACCELERATION_CXX_FLAGS)
 758             endif()
 759         endif(NOT GNU_SSE4_CXXFLAG AND NOT MSVC_SSE4_CXXFLAG)
 760     endif()
 761
 762     # This must come after we have added the -msse4.1 flag on some platforms.
 763     check_include_file(smmintrin.h  HAVE_SMMINTRIN_H ${ACCELERATION_C_FLAGS})
 764
 765     if(NOT HAVE_SMMINTRIN_H)
 766         message(FATAL_ERROR "Cannot find smmintrin.h, which is required for SSE4.1 intrinsics support.")
 767     endif(NOT HAVE_SMMINTRIN_H)
 768
 769     set(GMX_CPU_ACCELERATION_X86_SSE4_1 1)
 770     # The user should not be able to set this orthogonally to the acceleration
 771     set(GMX_X86_SSE4_1 1)
 772     set(GMX_X86_SSE2   1)
 773     if (NOT ACCELERATION_QUIETLY)
 774       message(STATUS "Enabling SSE4.1 Gromacs acceleration, and it will help compiler optimization.")
 775     endif()
 776
 777 elseif(${GMX_CPU_ACCELERATION} STREQUAL "AVX_128_FMA" OR ${GMX_CPU_ACCELERATION} STREQUAL "AVX_256")
 778
 779     # Set the AVX compiler flag for both these choices!
 780
 781     GMX_TEST_CFLAG(GNU_AVX_CFLAG "-mavx" ACCELERATION_C_FLAGS)
 782     if (NOT GNU_AVX_CFLAG AND GMX_NATIVE_WINDOWS)
 783         GMX_TEST_CFLAG(MSVC_AVX_CFLAG "/arch:AVX" ACCELERATION_C_FLAGS)
 784     endif (NOT GNU_AVX_CFLAG AND GMX_NATIVE_WINDOWS)
 785     if (NOT GNU_AVX_CFLAG AND NOT MSVC_AVX_CFLAG)
 786         message(WARNING "No C AVX flag found. Consider a newer compiler, or try SSE4.1 (lower performance).")
 787     endif (NOT GNU_AVX_CFLAG AND NOT MSVC_AVX_CFLAG)
 788
 789     if (CMAKE_CXX_COMPILER_LOADED)
 790         GMX_TEST_CXXFLAG(GNU_AVX_CXXFLAG "-mavx" ACCELERATION_CXX_FLAGS)
 791         if (NOT GNU_AVX_CXXFLAG AND GMX_NATIVE_WINDOWS)
 792             GMX_TEST_CXXFLAG(MSVC_AVX_CXXFLAG "/arch:AVX" ACCELERATION_CXX_FLAGS)
 793         endif (NOT GNU_AVX_CXXFLAG AND GMX_NATIVE_WINDOWS)
 794         if (NOT GNU_AVX_CXXFLAG AND NOT MSVC_AVX_CXXFLAG)
 795             message(WARNING "No C++ AVX flag found. Consider a newer compiler, or try SSE4.1 (lower performance).")
 796         endif (NOT GNU_AVX_CXXFLAG AND NOT MSVC_AVX_CXXFLAG)
 797     endif()
 798
 799     # Set the FMA4 flags (MSVC doesn't require any)
 800     if(${GMX_CPU_ACCELERATION} STREQUAL "AVX_128_FMA" AND NOT MSVC)
 801         GMX_TEST_CFLAG(GNU_FMA_CFLAG "-mfma4" ACCELERATION_C_FLAGS)
 802         if (NOT GNU_FMA_CFLAG)
 803             message(WARNING "No C FMA4 flag found. Consider a newer compiler, or try SSE4.1 (lower performance).")
 804         endif(NOT GNU_FMA_CFLAG)
 805         GMX_TEST_CFLAG(GNU_XOP_CFLAG "-mxop" ACCELERATION_C_FLAGS)
 806         # No big deal if we do not have xop, so no point yelling warnings about it.
 807         if (CMAKE_CXX_COMPILER_LOADED)
 808             GMX_TEST_CXXFLAG(GNU_FMA_CXXFLAG "-mfma4" ACCELERATION_CXX_FLAGS)
 809             if (NOT GNU_FMA_CXXFLAG)
 810                 message(WARNING "No C++ FMA flag found. Consider a newer compiler, or try SSE4.1 (lower performance).")
 811             endif (NOT GNU_FMA_CXXFLAG)
 812             GMX_TEST_CXXFLAG(GNU_XOP_CXXFLAG "-mxop" ACCELERATION_CXX_FLAGS)
 813             # No big deal if we do not have xop, so no point yelling warnings about it.
 814         endif()
 815     endif()
 816
 817     # Only test the header after we have tried to add the flag for AVX support
 818     check_include_file(immintrin.h  HAVE_IMMINTRIN_H ${ACCELERATION_C_FLAGS})
 819
 820     if(NOT HAVE_IMMINTRIN_H)
 821         message(FATAL_ERROR "Cannot find immintrin.h, which is required for AVX intrinsics support. Consider switching compiler.")
 822     endif(NOT HAVE_IMMINTRIN_H)
 823
 824     if(${GMX_CPU_ACCELERATION} STREQUAL "AVX_256")
 825         try_compile(TEST_AVX ${CMAKE_BINARY_DIR}
 826             "${CMAKE_SOURCE_DIR}/cmake/TestAVX.c"
 827             COMPILE_DEFINITIONS "${ACCELERATION_C_FLAGS}")
 828         if(NOT TEST_AVX)
 829             message(FATAL_ERROR "Cannot compile AVX intrinsics. Consider switching compiler.")
 830         endif()
 831     endif()
 832
 833     # GCC requires x86intrin.h for FMA support. MSVC 2010 requires intrin.h for FMA support.
 834     check_include_file(x86intrin.h HAVE_X86INTRIN_H ${ACCELERATION_C_FLAGS})
 835     check_include_file(intrin.h HAVE_INTRIN_H ${ACCELERATION_C_FLAGS})
 836
 837     # The user should not be able to set this orthogonally to the acceleration
 838     set(GMX_X86_SSE4_1 1)
 839     set(GMX_X86_SSE2   1)
 840
 841     # But just enable one of the choices internally...
 842     if(${GMX_CPU_ACCELERATION} STREQUAL "AVX_128_FMA")
 843         set(GMX_CPU_ACCELERATION_X86_AVX_128_FMA 1)
 844         set(GMX_X86_AVX_128_FMA 1)
 845         if (NOT ACCELERATION_QUIETLY)
 846           message(STATUS "Enabling 128-bit AVX Gromacs acceleration (with fused-multiply add), and it will help compiler optimization.")
 847         endif()
 848     else()
 849         # If we are not doing AVX_128, it must be AVX_256...
 850         set(GMX_CPU_ACCELERATION_X86_AVX_256 1)
 851         set(GMX_X86_AVX_256 1)
 852         if (NOT ACCELERATION_QUIETLY)
 853           message(STATUS "Enabling 256-bit AVX Gromacs acceleration, and it will help compiler optimization.")
 854         endif()
 855     endif()
 856
 857     # Unfortunately gcc-4.5.2 and gcc-4.6.0 has a bug where they use the wrong datatype for the formal
 858     # parameter of the mask for maskload/maskstore arguments. Check if this is present, since we can work around it.
 859     gmx_test_avx_gcc_maskload_bug(${ACCELERATION_C_FLAGS} GMX_X86_AVX_GCC_MASKLOAD_BUG)
 860
 861 elseif(${GMX_CPU_ACCELERATION} STREQUAL "BLUEGENE")
 862 # GMX_CPU_ACCELERATION=BlueGene should be set in the Toolchain-BlueGene?-???.cmake file
 863     if (NOT ACCELERATION_QUIETLY)
 864       message(STATUS "Configuring for BlueGene")
 865     endif()
 866     set(GMX_BLUEGENE 1)
 867     if (${CMAKE_SYSTEM_NAME} STREQUAL "BlueGeneL")
 868         set(SHARED_LIBS_DEFAULT OFF CACHE BOOL "Shared libraries not compatible with BlueGene/L, disabled!" FORCE)
 869         set(BUILD_SHARED_LIBS OFF CACHE BOOL "Shared libraries not compatible with BlueGene/L, disabled!" FORCE)
 870     endif (${CMAKE_SYSTEM_NAME} STREQUAL "BlueGeneL")
 871     set(GMX_SOFTWARE_INVSQRT OFF CACHE BOOL "Do not use software reciprocal square root on BlueGene" FORCE)
 872     set(GMX_X11 OFF CACHE BOOL "X11 not compatible with BlueGene, disabled!" FORCE)
 873     set(GMX_THREAD_MPI OFF CACHE BOOL "Thread-MPI not compatible with BlueGene, disabled!" FORCE)
 874     set(GMX_MPI ON CACHE BOOL "Use MPI on BlueGene" FORCE)
 875 # Access to /etc/passwd is not available on the back end of BlueGene,
 876 # despite being detected by CMake. This can cause linker warnings
 877 # about harmless things in src/gmxlib/string2.h.
 878     set(HAVE_PWD_H OFF)
 879 # The automatic testing for endianness does not work for the BlueGene cross-compiler
 880     set(GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER 1 CACHE INTERNAL "BlueGene has big endian FP byte order (by default)" FORCE)
 881     set(GMX_IEEE754_BIG_ENDIAN_WORD_ORDER 1 CACHE INTERNAL "BlueGene has big endian FP word order (by default)" FORCE)
 882 else(${GMX_CPU_ACCELERATION} STREQUAL "NONE")
 883     MESSAGE(FATAL_ERROR "Unrecognized option for accelerated kernels: ${GMX_CPU_ACCELERATION}. Pick one of None, SSE2, SSE4.1, AVX_128_FMA, AVX_256, BlueGene")
 884 endif(${GMX_CPU_ACCELERATION} STREQUAL "NONE")
 885 set(ACCELERATION_QUIETLY TRUE CACHE INTERNAL "")
 886
 887 # Process QM/MM Settings
 888 string(TOUPPER ${GMX_QMMM_PROGRAM} ${GMX_QMMM_PROGRAM})
 889 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 890     set(GMX_QMMM_GAUSSIAN 1)
 891 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 892     set(GMX_QMMM_MOPAC 1)
 893 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 894     set(GMX_QMMM_GAMESS 1)
 895 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 896     set(GMX_QMMM_ORCA 1)
 897 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 898     # nothing to do
 899 else(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 900     MESSAGE(FATAL_ERROR "Invalid QM/MM program option: ${GMX_QMMM_PROGRAM}. Choose one of: Gaussian, Mopac, Gamess, Orca, None")
 901 endif(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 902
 903 # Process FFT library settings - if not OpenMM build
 904 string(TOUPPER ${GMX_FFT_LIBRARY} ${GMX_FFT_LIBRARY})
 905 set(PKG_FFT "")
 906 set(PKG_FFT_LIBS "")
 907 if(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 908     if(GMX_DOUBLE)
 909         set(FFTW fftw)
 910     else()
 911         set(FFTW fftwf)
 912     endif()
 913
 914     if(GMX_BUILD_OWN_FFTW)
 915       add_subdirectory(src/contrib/fftw)
 916     else()
 917       find_package(FFTW COMPONENTS ${FFTW})
 918     endif()
 919
 920     string(TOUPPER "${FFTW}" FFTW)
 921     set(PKG_FFT "${${FFTW}_PKG}")
 922     include_directories(${${FFTW}_INCLUDE_DIRS})
 923     set(FFT_LIBRARIES ${${FFTW}_LIBRARIES})
 924     if(NOT ${FFTW}_FOUND)
 925       MESSAGE(FATAL_ERROR "Cannot find FFTW 3 (with correct precision - libfftw3f for single-precision GROMACS or libfftw3 for double-precision GROMACS). Either choose the right precision, choose another FFT(W) library, enable the advanced option to let GROMACS build FFTW 3 for you, or use the really slow GROMACS built-in fftpack library.")
 926     endif()
 927
 928     set(GMX_FFT_FFTW3 1)
 929
 930     if (NOT ${GMX_CPU_ACCELERATION} STREQUAL "NONE" AND NOT ${FFTW}_HAVE_SIMD)
 931       message(WARNING "The fftw library found is compiled without SIMD support, which makes it slow. Consider recompiling it or contact your admin")
 932     endif()
 933
 934     if(NOT ${GMX_CPU_ACCELERATION} STREQUAL "NONE" AND ${FFTW}_HAVE_AVX)
 935         # If we're not doing CPU acceleration, we don't care about FFTW performance on x86 either
 936         message(WARNING "The FFTW library was compiled with --enable-avx to enable AVX SIMD instructions. That might sound like a good idea for your processor, but for FFTW versions up to 3.3.3, these are slower than the SSE/SSE2 SIMD instructions for the way GROMACS uses FFTs. Limitations in the way FFTW allows GROMACS to measure performance make it awkward for either GROMACS or FFTW to make the decision for you based on runtime performance. You should compile a different FFTW library with --enable-sse or --enable-sse2. If you have a more recent FFTW, you may like to compare the performance of GROMACS with FFTW libraries compiled with and without --enable-avx. However, the GROMACS developers do not really expect the FFTW AVX optimization to help, because the performance is limited by memory access, not computation.")
 937     endif()
 938
 939 elseif(${GMX_FFT_LIBRARY} STREQUAL "MKL")
 940 #    MESSAGE(STATUS "Using external FFT library - Intel MKL")
 941     find_package(MKL REQUIRED)
 942     include_directories(${MKL_INCLUDE_DIR})
 943     set(FFT_LIBRARIES ${MKL_LIBRARIES})
 944     set(PKG_FFT_LIBS ${MKL_LIBRARIES})
 945
 946     set(GMX_FFT_MKL 1)
 947     set(HAVE_MKL 1)
 948
 949 #elseif(${GMX_FFT_LIBRARY} STREQUAL "ACML")
 950 #    MESSAGE(STATUS "Using external FFT library - AMD core math library")
 951 #    set(GMX_FFT_ACML 1)
 952 elseif(${GMX_FFT_LIBRARY} STREQUAL "FFTPACK")
 953     MESSAGE(STATUS "Using internal FFT library - fftpack")
 954     set(GMX_FFT_FFTPACK 1)
 955 else(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 956     MESSAGE(FATAL_ERROR "Invalid FFT library setting: ${GMX_FFT_LIBRARY}. Choose one of: fftw3, mkl, fftpack")
 957 endif(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 958
 959 # enable threaded fftw3 if we've found it
 960 if(FFTW3_THREADS OR FFTW3F_THREADS)
 961     add_definitions(-DFFT5D_FFTW_THREADS)
 962 endif()
 963
 964 set(GMX_EXTERNAL_BLAS TRUE CACHE BOOL "Use external BLAS instead of built-in")
 965 set(GMX_EXTERNAL_LAPACK TRUE CACHE BOOL "Use external LAPACK instead of built-in")
 966 # MKL has BLAS/LAPACK routines
 967 if(NOT HAVE_MKL AND NOT ACCELERATE_FRAMEWORK)
 968   if(GMX_EXTERNAL_BLAS)
 969     if (GMX_BLAS_USER)
 970         list(APPEND GMX_EXTRA_LIBRARIES ${GMX_BLAS_USER})
 971     else(GMX_BLAS_USER)
 972         set(BLAS_FIND_QUIETLY ON)
 973         find_package(BLAS)
 974         if (BLAS_FOUND)
 975           list(APPEND GMX_EXTRA_LIBRARIES ${BLAS_LIBRARIES})
 976         else()
 977           MESSAGE(STATUS "Using internal BLAS library")
 978           set(GMX_EXTERNAL_BLAS FALSE CACHE BOOL "Use external BLAS instead of built-in" FORCE)
 979         endif()
 980     endif(GMX_BLAS_USER)
 981   endif(GMX_EXTERNAL_BLAS)
 982   if(GMX_EXTERNAL_LAPACK)
 983     if (GMX_LAPACK_USER)
 984         list(APPEND GMX_EXTRA_LIBRARIES ${GMX_LAPACK_USER})
 985     else(GMX_LAPACK_USER)
 986         set(LAPACK_FIND_QUIETLY ON)
 987         find_package(LAPACK)
 988         if (LAPACK_FOUND)
 989           list(APPEND GMX_EXTRA_LIBRARIES ${LAPACK_LIBRARIES})
 990         else()
 991           MESSAGE(STATUS "Using internal LAPACK library")
 992           set(GMX_EXTERNAL_LAPACK FALSE CACHE BOOL "Use external LAPACK instead of built-in" FORCE)
 993         endif()
 994     endif(GMX_LAPACK_USER)
 995   endif(GMX_EXTERNAL_LAPACK)
 996 endif()
 997 mark_as_advanced(GMX_EXTERNAL_LAPACK)
 998 mark_as_advanced(GMX_EXTERNAL_BLAS)
 999
1000 set(GMX_USE_PLUGINS OFF CACHE INTERNAL "Whether GROMACS will really try to compile support for VMD plugins")
1001
1002 if(GMX_LOAD_PLUGINS)
1003   if(CYGWIN OR NOT WIN32)
1004     # Native Windows does not have, nor need dlopen
1005     # Note that WIN32 is set with Cygwin, but Cygwin needs dlopen to use plug-ins
1006     include(gmxTestdlopen)
1007     gmx_test_dlopen(HAVE_DLOPEN)
1008   endif()
1009
1010   # so, should we use plug-ins?
1011   if((WIN32 AND NOT CYGWIN) OR (HAVE_DLOPEN AND BUILD_SHARED_LIBS))
1012     if(NOT VMD_QUIETLY)
1013       MESSAGE(STATUS
1014           "Found the ability to use plug-ins when building shared libaries, "
1015           "so will compile to use plug-ins (e.g. to read VMD-supported file "
1016           "formats).")
1017     endif()
1018     if(NOT GMX_VMD_PLUGIN_PATH)
1019       find_package(VMD)
1020     endif()
1021     set(GMX_USE_PLUGINS ON)
1022     list(APPEND GMX_EXTRA_LIBRARIES ${CMAKE_DL_LIBS}) # magic cross-platform pre-set variable for dlopen library
1023     set(PKG_DL_LIBS "-l${CMAKE_DL_LIBS}")
1024   else()
1025     set(PKG_DL_LIBS)
1026   endif()
1027 endif(GMX_LOAD_PLUGINS)
1028 set(VMD_QUIETLY TRUE CACHE INTERNAL "")
1029
1030 if(EXISTS "${CMAKE_SOURCE_DIR}/admin/.isreposource")
1031     if(NOT CMAKE_CROSSCOMPILING)
1032         option(GMX_BUILD_MANPAGES "Build man pages" ON)
1033     else()
1034         message(STATUS "Building the man pages is not available when "
1035             "cross-compiling the developer version from git")
1036     endif()
1037 else()
1038     #make sure source package contains all man pages
1039     if(NOT EXISTS "${CMAKE_SOURCE_DIR}/man/man1/ngmx.1")
1040         message(FATAL_ERROR "Man pages are missing from source package.")
1041     endif()
1042 endif()
1043 mark_as_advanced(GMX_BUILD_MANPAGES)
1044
1045 # Math and thread libraries must often come after all others when linking...
1046 if(HAVE_LIBM)
1047     list(APPEND GMX_EXTRA_LIBRARIES m)
1048 endif(HAVE_LIBM)
1049
1050 if(GMX_FAHCORE)
1051   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
1052       "Path to swindirect.h")
1053   include_directories(${COREWRAP_INCLUDE_DIR})
1054   set_property(CACHE GMX_COOL_QUOTES VALUE OFF)
1055 endif(GMX_FAHCORE)
1056
1057 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
1058 # these are set after everything else
1059 if (NOT DEFINED GROMACS_C_FLAGS_SET)
1060     set(GROMACS_C_FLAGS_SET true CACHE INTERNAL "Whether to reset the C flags"
1061         FORCE)
1062     set(CMAKE_C_FLAGS "${ACCELERATION_C_FLAGS} ${MPI_COMPILE_FLAGS} ${CMAKE_C_FLAGS}" CACHE STRING
1063         "Flags used by the compiler during all build types" FORCE)
1064     if (CMAKE_CXX_COMPILER_LOADED)
1065         set(CMAKE_CXX_FLAGS "${ACCELERATION_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${CMAKE_CXX_FLAGS}" CACHE STRING
1066             "Flags used by the compiler during all build types" FORCE)
1067     endif()
1068     set(CMAKE_EXE_LINKER_FLAGS
1069         "${MPI_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}"
1070         CACHE STRING "Linker flags for creating executables" FORCE)
1071     set(CMAKE_SHARED_LINKER_FLAGS
1072         "${MPI_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS}"
1073         CACHE STRING "Linker flags for creating shared libraries" FORCE)
1074 endif()
1075
1076 if(NOT GMX_OPENMP)
1077     #Unset all OpenMP flags in case OpenMP was disabled either by the user
1078     #or because it was only partially detected (e.g. only for C but not C++ compiler)
1079     unset(OpenMP_C_FLAGS CACHE)
1080     unset(OpenMP_CXX_FLAGS CACHE)
1081     unset(OpenMP_LINKER_FLAGS CACHE)
1082     unset(OpenMP_SHARED_LINKER_FLAGS)
1083 endif()
1084 set(PKG_CFLAGS "${PKG_CFLAGS} ${OpenMP_C_FLAGS}")
1085
1086 ######################################
1087 # Output compiler and CFLAGS used
1088 ######################################
1089 get_compiler_info(C BUILD_C_COMPILER BUILD_CFLAGS)
1090 if (CMAKE_CXX_COMPILER_LOADED)
1091     get_compiler_info(CXX BUILD_CXX_COMPILER BUILD_CXXFLAGS)
1092 endif ()
1093
1094 ########################################################################
1095 # Specify install locations and which subdirectories to process        #
1096 ########################################################################
1097 if (GMX_USE_RELATIVE_INSTALL_PATH)
1098     set(GMX_INSTALL_PREFIX "" CACHE STRING "Prefix gets appended to CMAKE_INSTALL_PREFIX. For cpack it sets the root folder of the archive.")
1099     mark_as_advanced(GMX_INSTALL_PREFIX)
1100 else()
1101     set(GMX_INSTALL_PREFIX "${CMAKE_INSTALL_PREFIX}/")
1102 endif()
1103
1104 if ( NOT DEFINED GMXLIB )
1105     set(GMXLIB lib)
1106 endif()
1107 set(LIB_INSTALL_DIR "${GMX_INSTALL_PREFIX}${GMXLIB}")
1108 set(BIN_INSTALL_DIR  ${GMX_INSTALL_PREFIX}bin)
1109 set(DATA_INSTALL_DIR ${GMX_INSTALL_PREFIX}share/gromacs)
1110 set(MAN_INSTALL_DIR  ${GMX_INSTALL_PREFIX}share/man)
1111 set(INCL_INSTALL_DIR ${GMX_INSTALL_PREFIX}include)
1112
1113 set(GMXLIBDIR        ${DATA_INSTALL_DIR}/top)
1114
1115 ##################################################################
1116 # Shared library settings - Darwin uses INSTALL_NAME_DIR instead!
1117 ##################################################################
1118 if(NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin")
1119     set(CMAKE_SKIP_BUILD_RPATH  FALSE)
1120     set(CMAKE_BUILD_WITH_INSTALL_RPATH FALSE)
1121     set(CMAKE_INSTALL_RPATH "\\\$ORIGIN/../${GMXLIB}")
1122     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
1123 endif()
1124
1125 #COPYING file: Only necessary for binary distributions.
1126 #Simpler to always install.
1127 install(FILES COPYING DESTINATION ${DATA_INSTALL_DIR} COMPONENT data)
1128
1129 add_subdirectory(share)
1130 add_subdirectory(include)
1131 add_subdirectory(src)
1132 add_subdirectory(scripts)
1133
1134 # Issue a warning if NVIDIA GPUs were detected, but CUDA was not found.
1135 # Don't bother the user after the first configure pass.
1136 if ((CUDA_NOTFOUND_AUTO AND GMX_DETECT_GPU_AVAILABLE) AND NOT GMX_GPU_DETECTION_DONE)
1137     message(WARNING "${CUDA_NOTFOUND_MESSAGE}")
1138     unset(CUDA_NOTFOUND_AUTO)
1139     unset(CUDA_NOTFOUND_MESSAGE)
1140 endif()
1141 set(GMX_GPU_DETECTION_DONE TRUE CACHE INTERNAL "Whether GPU detection has already been done")
1142
1143 #######################
1144 ## uninstall target
1145 #######################
1146     CONFIGURE_FILE(
1147                    "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
1148                    "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
1149                    IMMEDIATE @ONLY)
1150 ###########################
1151 ADD_CUSTOM_TARGET(uninstall
1152                   "${CMAKE_COMMAND}" -P
1153                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
1154 ###########################
1155
1156 ########################################################################
1157 # Tests                                                                #
1158 ########################################################################
1159
1160 include(CTest)
1161 mark_as_advanced(BUILD_TESTING)
1162 IF(BUILD_TESTING)
1163         enable_testing()
1164         add_subdirectory(tests)
1165 ENDIF()
1166