CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.8)
   2 # Keep CMake suitably quiet on Cygwin
   3 set(CMAKE_LEGACY_CYGWIN_WIN32 0) # Remove when CMake >= 2.8.4 is required
   4
   5 # CMake modules/macros are in a subdirectory to keep this file cleaner
   6 # This needs to be set before project() in order to pick up toolchain files
   7 list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake ${CMAKE_CURRENT_SOURCE_DIR}/cmake/Platform)
   8
   9 project(Gromacs)
  10 include(Dart)
  11 mark_as_advanced(DART_ROOT)
  12
  13 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  14 set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  15 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
  16
  17 # PROJECT_VERSION should have the following structure:
  18 # VERSION-dev[-SUFFIX] where the VERSION should have the for: vMajor.vMinor.vPatch
  19 #
  20 # The "-dev" suffix is important to keep because it makes possible to distinguish
  21 # between a build from official release and a build from git release branch on a
  22 # machine with no git.
  23 #
  24 # NOTE: when releasing the "-dev" suffix needs to be stripped off!
  25 set(PROJECT_VERSION "5.0-dev")
  26 # The version number of the regressiontest tarball against which this
  27 # git branch can be tested. Normally, this will be the version of the
  28 # last patch release. Comment the next line out for branches leading
  29 # to a major/minor release.
  30 set(REGRESSIONTEST_VERSION "4.6.2")
  31 set(CUSTOM_VERSION_STRING ""
  32     CACHE STRING "Custom version string (if empty, use hard-coded default)")
  33 mark_as_advanced(CUSTOM_VERSION_STRING)
  34 if (CUSTOM_VERSION_STRING)
  35     set(PROJECT_VERSION ${CUSTOM_VERSION_STRING})
  36 endif (CUSTOM_VERSION_STRING)
  37 set(SOVERSION 8)
  38 # It is a bit irritating, but this has to be set separately for now!
  39 SET(CPACK_PACKAGE_VERSION_MAJOR "5")
  40 SET(CPACK_PACKAGE_VERSION_MINOR "0")
  41 #SET(CPACK_PACKAGE_VERSION_PATCH "0")
  42
  43 # The numerical gromacs version. It is 40600 for 4.6.0.
  44 # The #define GMX_VERSION in gmx_header_config_h is set to this value.
  45 math(EXPR NUM_VERSION
  46     "${CPACK_PACKAGE_VERSION_MAJOR}*10000 + ${CPACK_PACKAGE_VERSION_MINOR}*100")
  47 if(CPACK_PACKAGE_VERSION_PATCH)
  48     math(EXPR NUM_VERSION
  49          "${NUM_VERSION} + ${CPACK_PACKAGE_VERSION_PATCH}")
  50 endif()
  51
  52 # The API version tracks the numerical Gromacs version (for now).
  53 # It is potentially different from the Gromacs version in the future, if
  54 # the programs/libraries diverge from the presumably more stable API.
  55 # The #define GMX_API_VERSION in version.h is set to this value to
  56 # provide backward compatibility of software written against the Gromacs API.
  57 set(API_VERSION ${NUM_VERSION})
  58
  59 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT AND UNIX)
  60     set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
  61 endif()
  62
  63 set(GMX_INSTALL_PREFIX "" CACHE STRING "Prefix gets appended to CMAKE_INSTALL_PREFIX. For cpack it sets the root folder of the archive.")
  64 mark_as_advanced(GMX_INSTALL_PREFIX)
  65
  66 include(gmxBuildTypeReference)
  67
  68 if(NOT CMAKE_BUILD_TYPE)
  69     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel Reference." FORCE)
  70 endif(NOT CMAKE_BUILD_TYPE)
  71
  72 enable_language(C)
  73 enable_language(CXX)
  74
  75 set(CPACK_PACKAGE_VERSION ${PROJECT_VERSION})
  76 set(CPACK_PACKAGE_VENDOR "gromacs.org")
  77 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Gromacs - a toolkit for high-performance molecular simulation")
  78 set(CPACK_RESOURCE_FILE_WELCOME "${CMAKE_SOURCE_DIR}/admin/InstallWelcome.txt")
  79 # Its GPL/LGPL, so they do not have to agree to a license for mere usage, but some installers require this...
  80 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_SOURCE_DIR}/COPYING")
  81 set(CPACK_RESOURCE_FILE_README "${CMAKE_SOURCE_DIR}/admin/InstallInfo.txt")
  82 set(CPACK_SOURCE_IGNORE_FILES "\\\\.isreposource$;\\\\.git/;\\\\.gitignore$")
  83 set(CPACK_PROJECT_CONFIG_FILE "${CMAKE_SOURCE_DIR}/CPackInit.cmake")
  84 SET(CPACK_SOURCE_INSTALLED_DIRECTORIES "${CMAKE_SOURCE_DIR};/;${CMAKE_BINARY_DIR}/man;man")
  85 set(CPACK_PACKAGE_CONTACT "gmx-users@gromacs.org")
  86
  87 #must come after all cpack settings!
  88 include(CPack)
  89
  90 set(SOURCE_IS_GIT_REPOSITORY OFF)
  91 if(EXISTS "${CMAKE_SOURCE_DIR}/.git")
  92     set(SOURCE_IS_GIT_REPOSITORY ON)
  93 endif()
  94
  95 ########################################################################
  96 # Check and warn if cache generated on a different host is being reused
  97 ########################################################################
  98 if(CMAKE_HOST_UNIX)
  99     execute_process(COMMAND hostname
 100                     OUTPUT_VARIABLE TMP_HOSTNAME
 101                     OUTPUT_STRIP_TRAILING_WHITESPACE)
 102     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}")
 103         message(WARNING "
 104             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
 105             is being reused! This could lead to inconsitencies; therefore, it is
 106             recommended to regenerate the cache!")
 107     endif()
 108     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
 109             "Hostname of the machine where the cache was generated.")
 110 endif()
 111
 112 ########################################################################
 113 option(GMX_COOL_QUOTES "Enable Gromacs cool quotes" ON)
 114 mark_as_advanced(GMX_COOL_QUOTES)
 115
 116 set(CMAKE_PREFIX_PATH "" CACHE STRING "Extra locations to search for external libraries and tools (give directory without lib, bin, or include)")
 117 # User input options                                                   #
 118 ########################################################################
 119 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" OFF)
 120 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 121 option(GMX_THREAD_MPI  "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" ON)
 122 option(GMX_SOFTWARE_INVSQRT "Use GROMACS software 1/sqrt" ON)
 123 mark_as_advanced(GMX_SOFTWARE_INVSQRT)
 124 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 125 mark_as_advanced(GMX_FAHCORE)
 126
 127 # decide on GPU settings based on user-settings and GPU/CUDA detection
 128 include(gmxManageGPU)
 129
 130 include(gmxDetectAcceleration)
 131 if(NOT DEFINED GMX_CPU_ACCELERATION)
 132     if(CMAKE_CROSSCOMPILING)
 133         if("${CMAKE_SYSTEM_NAME}" MATCHES "BlueGeneQ")
 134             set(GMX_SUGGESTED_CPU_ACCELERATION "IBM_QPX")
 135         else()
 136             set(GMX_SUGGESTED_CPU_ACCELERATION "None")
 137         endif()
 138     else(CMAKE_CROSSCOMPILING)
 139         gmx_detect_acceleration(GMX_SUGGESTED_CPU_ACCELERATION)
 140     endif(CMAKE_CROSSCOMPILING)
 141 endif(NOT DEFINED GMX_CPU_ACCELERATION)
 142
 143 set(GMX_CPU_ACCELERATION "@GMX_SUGGESTED_CPU_ACCELERATION@"
 144     CACHE STRING "Accelerated CPU kernels. Pick one of: None, SSE2, SSE4.1, AVX_128_FMA, AVX_256, IBM_QPX, Sparc64_HPC_ACE")
 145
 146 set(GMX_FFT_LIBRARY "fftw3"
 147     CACHE STRING "FFT library choices: fftw3,mkl,fftpack[built-in]")
 148 option(GMX_BUILD_OWN_FFTW "Download and build FFTW 3 during the GROMACS build process, rather than fall back on the really slow fftpack." OFF)
 149 mark_as_advanced(GMX_BUILD_OWN_FFTW)
 150 option(GMX_DISABLE_FFTW_MEASURE
 151        "Do not optimize FFTW setups (not needed with SSE)" OFF)
 152 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 153 set(GMX_QMMM_PROGRAM "none"
 154     CACHE STRING "QM package choices: none,gaussian,mopac,gamess,orca")
 155 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 156 mark_as_advanced(GMX_BROKEN_CALLOC)
 157 option(GMX_MPI_IN_PLACE "Enable MPI_IN_PLACE for MPIs that have it defined" ON)
 158 mark_as_advanced(GMX_MPI_IN_PLACE)
 159 option(GMX_LOAD_PLUGINS "Compile with plugin support, needed to read VMD supported file formats" ON)
 160 mark_as_advanced(GMX_LOAD_PLUGINS)
 161
 162 option(GMX_GPU  "Enable GPU acceleration" ON)
 163 option(GMX_OPENMP "Enable OpenMP-based multithreading" ON)
 164
 165 option(GMX_GIT_VERSION_INFO "Generate git version information" ${SOURCE_IS_GIT_REPOSITORY})
 166 mark_as_advanced(GMX_GIT_VERSION_INFO)
 167
 168 option(GMX_DEFAULT_SUFFIX "Use default suffixes for GROMACS binaries and libs (_d for double, _mpi for MPI; rerun cmake after changing to see relevant options)" ON)
 169 if(UNIX)
 170     option(GMX_SYMLINK_OLD_BINARY_NAMES "Create symbolic links for pre-5.0 binary names" ON)
 171 endif()
 172 option(GMX_BUILD_MDRUN_ONLY "Build and install only the mdrun binary" OFF)
 173
 174 if(UNIX)
 175     option(GMX_PREFER_STATIC_LIBS "When finding libraries prefer static archives (not available on non-*nix platforms and it will only work if static versions of external dependencies are available and found)!" OFF)
 176     mark_as_advanced(GMX_PREFER_STATIC_LIBS)
 177 endif()
 178
 179 option(GMX_CYCLE_SUBCOUNTERS "Enable cycle subcounters to get a more detailed cycle timings" OFF)
 180 mark_as_advanced(GMX_CYCLE_SUBCOUNTERS)
 181
 182 option(GMX_SKIP_DEFAULT_CFLAGS "Don't automatically add suggested/required Compiler flags." OFF)
 183 mark_as_advanced(GMX_SKIP_DEFAULT_CFLAGS)
 184
 185 option(GMX_BUILD_FOR_COVERAGE
 186        "Tune build for better code coverage metrics (e.g., disable asserts)"
 187        OFF)
 188 mark_as_advanced(GMX_BUILD_FOR_COVERAGE)
 189
 190 ######################################################################
 191 # Compiler tests
 192 # These need to be done early (before further tests).
 193 #####################################################################
 194
 195 # The cmake/Check{C,CXX}CompilerFlag.cmake files in the GROMACS distribution
 196 # are used with permission from CMake v2.8.9 so that GROMACS can detect
 197 # invalid options with the Intel Compilers.
 198 # These files should be removed from the source tree when a CMake version that
 199 # includes the features in question becomes required for building GROMACS.
 200 include(CheckCCompilerFlag)
 201 include(CheckCXXCompilerFlag)
 202
 203 # Get compiler version information, needs to be done early as check that depend
 204 # on compiler verison follow below.
 205 include(gmxGetCompilerInfo)
 206 get_compiler_version()
 207
 208 # First exclude compilers known to not work with OpenMP although claim to support it:
 209 # gcc 4.2.1 and gcc-llvm 4.2.1 (also claims to be 4.2.1) on Mac OS X
 210 # This fixes redmine 900 and needs to run before OpenMP flags are set below.
 211 if (CMAKE_SYSTEM_NAME STREQUAL "Darwin" AND
 212     (CMAKE_COMPILER_IS_GNUCC AND C_COMPILER_VERSION AND C_COMPILER_VERSION VERSION_LESS 4.3))
 213     message(STATUS "OpenMP multithreading not supported with gcc/llvm-gcc 4.2 on Mac OS X, disabled")
 214     set(GMX_OPENMP OFF CACHE BOOL
 215         "OpenMP multithreading not not supported with gcc/llvm-gcc 4.2 on Mac OS X, disabled!" FORCE)
 216 endif()
 217
 218 # OpenMP check must come before other CFLAGS!
 219 if(GMX_OPENMP)
 220     find_package(OpenMP)
 221     if(OPENMP_FOUND)
 222         # CMake on Windows doesn't support linker flags passed to target_link_libraries
 223         # (i.e. it treats /openmp as \openmp library file). Also, no OpenMP linker flags are needed.
 224         if(NOT (WIN32 AND NOT CYGWIN))
 225             if(CMAKE_COMPILER_IS_GNUCC AND GMX_PREFER_STATIC_OPENMP AND NOT APPLE)
 226                 set(OpenMP_LINKER_FLAGS "-Wl,-static -lgomp -lrt -Wl,-Bdynamic -lpthread")
 227                 set(OpenMP_SHARED_LINKER_FLAGS "")
 228             else()
 229                 # Only set a linker flag if the user didn't set them manually
 230                 if(NOT DEFINED OpenMP_LINKER_FLAGS)
 231                     set(OpenMP_LINKER_FLAGS "${OpenMP_C_FLAGS}")
 232                 endif()
 233                 if(NOT DEFINED OpenMP_SHARED_LINKER_FLAGS)
 234                     set(OpenMP_SHARED_LINKER_FLAGS "${OpenMP_C_FLAGS}")
 235                 endif()
 236             endif()
 237         endif()
 238     else(OPENMP_FOUND)
 239         message(WARNING
 240                 "The compiler you are using does not support OpenMP parallelism. This might hurt your performance a lot, in particular with GPUs. Try using a more recent version, or a different compiler. For now, we are proceeding by turning off OpenMP.")
 241         set(GMX_OPENMP OFF CACHE STRING "Whether GROMACS will use OpenMP parallelism." FORCE)
 242     endif(OPENMP_FOUND)
 243 endif()
 244
 245
 246 include(gmxCFlags)
 247 gmx_c_flags()
 248
 249 # This variable should be used for additional compiler flags which are not
 250 # generated in gmxCFlags nor are acceleration or MPI related.
 251 set(EXTRA_C_FLAGS "")
 252 set(EXTRA_CXX_FLAGS "")
 253
 254 # gcc 4.4.x is buggy and crashes when compiling some files with O3 and OpenMP on.
 255 # Detect here whether applying a workaround is needed and will apply it later
 256 # on the affected files.
 257 include(gmxGCC44O3BugWorkaround)
 258 gmx_check_gcc44_bug_workaround_needed(GMX_USE_GCC44_BUG_WORKAROUND)
 259
 260 # clang 3.0 is buggy for some unknown reason detected during adding
 261 # the SSE2 group kernels for GROMACS 4.6. If we ever work out what
 262 # that is, we should replace these tests with a compiler feature test,
 263 # update GROMACS Redmine task #1039 and perhaps report a clang bug.
 264 #
 265 # In the meantime, until we require CMake 2.8.10 we cannot rely on it to detect
 266 # the compiler version for us. So we need a manual check for clang 3.0.
 267 include(gmxDetectClang30)
 268 gmx_detect_clang_3_0(COMPILER_IS_CLANG_3_0)
 269 if(COMPILER_IS_CLANG_3_0)
 270     message(FATAL_ERROR "Your compiler is clang version 3.0, which is known to be buggy for GROMACS. Use a different compiler.")
 271 endif()
 272
 273 # clang <=3.2 contains a bug that causes incorrect code to be generated for the
 274 # vfmaddps instruction and therefore the bug is triggered with AVX_128_FMA.
 275 # (see: http://llvm.org/bugs/show_bug.cgi?id=15040).
 276 # We can work around this by not using the integrated assembler (except on OS X
 277 # which has an outdated assembler that does not support AVX instructions).
 278 if (${CMAKE_C_COMPILER_ID} MATCHES "Clang" AND C_COMPILER_VERSION VERSION_LESS "3.3")
 279     set(GMX_USE_CLANG_C_FMA_BUG_WORKAROUND TRUE)
 280 endif()
 281 if (${CMAKE_CXX_COMPILER_ID} MATCHES "Clang" AND CXX_COMPILER_VERSION VERSION_LESS "3.3")
 282     set(GMX_USE_CLANG_CXX_FMA_BUG_WORKAROUND TRUE)
 283 endif()
 284
 285 if (CMAKE_C_COMPILER_ID STREQUAL "PGI")
 286     message(WARNING "All tested PGI compiler versions (up to 12.9.0) generate binaries which produce incorrect results, or even fail to compile Gromacs. Highly recommended to use a different compiler. If you choose to use PGI, make sure to run the regressiontests.")
 287 endif()
 288
 289 if(CMAKE_C_COMPILER_ID MATCHES "Intel" AND C_COMPILER_VERSION VERSION_LESS "12.0.0")
 290     message(WARNING "Intel compilers before 12.0.0 are not routinely tested, so there may be problems. Version 11.1 with SSE4.1 is known to produce incorrect results. It is highly recommended to use a more up-to-date compiler. If you choose to use this version, make sure you run the regressiontests.")
 291 endif()
 292
 293 set(PKG_CFLAGS "")
 294 if(GMX_DOUBLE)
 295     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_DOUBLE")
 296 endif(GMX_DOUBLE)
 297 if(GMX_SOFTWARE_INVSQRT)
 298   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_SOFTWARE_INVSQRT")
 299 endif(GMX_SOFTWARE_INVSQRT)
 300
 301
 302
 303 ########################################################################
 304 # Basic system tests (standard libraries, headers, functions, types)   #
 305 ########################################################################
 306 include(CheckIncludeFiles)
 307 include(CheckIncludeFileCXX)
 308 check_include_files(unistd.h     HAVE_UNISTD_H)
 309 check_include_files(pwd.h        HAVE_PWD_H)
 310 check_include_files(dirent.h     HAVE_DIRENT_H)
 311 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 312 check_include_files(io.h         HAVE_IO_H)
 313 check_include_files(sched.h      HAVE_SCHED_H)
 314
 315 check_include_files(regex.h      HAVE_POSIX_REGEX)
 316 check_include_file_cxx(regex     HAVE_CXX11_REGEX)
 317 # TODO: It could be nice to inform the user if no regex support is found,
 318 # as selections won't be fully functional.
 319
 320 include(CheckFunctionExists)
 321 check_function_exists(posix_memalign    HAVE_POSIX_MEMALIGN)
 322 check_function_exists(memalign          HAVE_MEMALIGN)
 323 check_function_exists(_aligned_malloc   HAVE__ALIGNED_MALLOC)
 324 check_function_exists(gettimeofday      HAVE_GETTIMEOFDAY)
 325 check_function_exists(fsync             HAVE_FSYNC)
 326 check_function_exists(_fileno           HAVE__FILENO)
 327 check_function_exists(fileno            HAVE_FILENO)
 328 check_function_exists(_commit           HAVE__COMMIT)
 329 check_function_exists(sigaction         HAVE_SIGACTION)
 330 check_function_exists(sysconf           HAVE_SYSCONF)
 331 check_function_exists(sched_setaffinity HAVE_SCHED_SETAFFINITY)
 332 check_function_exists(sched_getaffinity HAVE_SCHED_GETAFFINITY)
 333 check_function_exists(rsqrt             HAVE_RSQRT)
 334 check_function_exists(rsqrtf            HAVE_RSQRTF)
 335 check_function_exists(sqrtf             HAVE_SQRTF)
 336
 337 include(CheckLibraryExists)
 338 check_library_exists(m sqrt "" HAVE_LIBM)
 339
 340
 341 include(CheckTypeSize)
 342
 343 check_type_size("int"           SIZEOF_INT)
 344 check_type_size("long int"      SIZEOF_LONG_INT)
 345 check_type_size("long long int" SIZEOF_LONG_LONG_INT)
 346 check_type_size("off_t"         SIZEOF_OFF_T)
 347 check_type_size("void *"        SIZEOF_VOIDP)
 348
 349 include(TestBigEndian)
 350 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 351
 352
 353 if(APPLE OR CYGWIN OR ${CMAKE_SYSTEM_NAME} MATCHES "Linux|.*BSD")
 354     # Maybe Solaris should be here? Patch this if you know!
 355     SET(SHARED_LIBS_DEFAULT ON)
 356 elseif(WIN32 OR ${CMAKE_SYSTEM_NAME} MATCHES "BlueGene")
 357     # Support for shared libs on native Windows is a bit new. Its
 358     # default might change later if/when we sort things out. Also,
 359     # Cray should go here. What variable value can detect it?
 360     SET(SHARED_LIBS_DEFAULT OFF)
 361 else()
 362     message(STATUS "Defaulting to building static libraries")
 363     SET(SHARED_LIBS_DEFAULT OFF)
 364 endif()
 365
 366 # Management of GROMACS options for specific toolchains should go
 367 # here. Because the initial settings for some of the main options have
 368 # already happened, but things like library detection and MPI compiler
 369 # feature detection have not, the docstrings for any over-rides of
 370 # GROMACS defaults or user settings will make sense. Also, any
 371 # toolchain-related reasons for choosing whether to detect various
 372 # things can be sorted out now, before the detection takes place.
 373 if(${CMAKE_SYSTEM_NAME} MATCHES BlueGene)
 374     include(gmxManageBlueGene)
 375 endif()
 376
 377 if(UNIX AND GMX_PREFER_STATIC_LIBS AND SHARED_LIBS_DEFAULT)
 378     if(BUILD_SHARED_LIBS)
 379         # Warn the user about the combination. But don't overwrite the request.
 380         message(WARNING "Searching for static libraries requested, and building shared Gromacs libraries requested. This might cause problems linking later.")
 381     elseif(NOT DEFINED BUILD_SHARED_LIBS)
 382         # Change default to OFF. Don't warn if it's already off.
 383         message(WARNING "Searching for static libraries requested, so the GROMACS libraries will also be built statically (BUILD_SHARED_LIBS=OFF)")
 384         set(SHARED_LIBS_DEFAULT OFF)
 385     endif()
 386 endif()
 387
 388 # By now, all tool chains should have spoken up if they care about
 389 # the setting of SHARED_LIBS_DEFAULT.
 390 option(BUILD_SHARED_LIBS "Enable shared libraries (can be problematic e.g. with MPI, or on some HPC systems)" ${SHARED_LIBS_DEFAULT})
 391
 392 ########################################################################
 393 #Process MPI settings
 394 ########################################################################
 395 include(gmxManageMPI)
 396
 397 ########################################################################
 398 # Find external packages                                               #
 399 ########################################################################
 400 if(UNIX AND GMX_PREFER_STATIC_LIBS)
 401     # On Linux .a is the static library suffix, on Mac OS X .lib can also
 402     # be used, so we'll add both to the preference list.
 403     SET(CMAKE_FIND_LIBRARY_SUFFIXES ".lib;.a" ${CMAKE_FIND_LIBRARY_SUFFIXES})
 404 endif()
 405
 406 IF( WIN32 AND NOT CYGWIN)
 407   # This makes windows.h not declare min/max as macros that would break
 408   # C++ code using std::min/std::max.
 409   add_definitions(-DNOMINMAX)
 410
 411   if (NOT BUILD_SHARED_LIBS)
 412       option(GMX_PREFER_STATIC_LIBS "When finding libraries prefer static system libraries (MT instead of MD)!" ON)
 413       if(NOT GMX_PREFER_STATIC_LIBS)
 414           message(WARNING "Shared system libraries requested, and static Gromacs libraries requested.")
 415       endif()
 416   else()
 417       message(FATAL_ERROR "BUILD_SHARED_LIBS not yet working for Windows in the master branch")
 418       option(GMX_PREFER_STATIC_LIBS "When finding libraries prefer static system libraries (MT instead of MD)!" OFF)
 419       if(GMX_PREFER_STATIC_LIBS)
 420           #this combination segfaults (illigal passing of file handles)
 421           message(FATAL_ERROR "Static system libraries requested, and shared Gromacs libraries requested.")
 422       endif()
 423       add_definitions(-DUSE_VISIBILITY -DTMPI_USE_VISIBILITY)
 424       set(PKG_CFLAGS "$PKG_CFLAGS -DUSE_VISIBILITY -DTMPI_USE_VISIBILITY")
 425   endif()
 426   mark_as_advanced(GMX_PREFER_STATIC_LIBS)
 427
 428   IF (GMX_PREFER_STATIC_LIBS)
 429       #Only setting Debug and Release flags. Others configurations are current not used.
 430       STRING(REPLACE /MD /MT CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE})
 431       STRING(REPLACE /MD /MT CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG})
 432       STRING(REPLACE /MD /MT CMAKE_CXX_FLAGS_RELEASE ${CMAKE_CXX_FLAGS_RELEASE})
 433       STRING(REPLACE /MD /MT CMAKE_CXX_FLAGS_DEBUG ${CMAKE_CXX_FLAGS_DEBUG})
 434   ENDIF()
 435   IF( CMAKE_C_COMPILER_ID MATCHES "Intel" )
 436     if(BUILD_SHARED_LIBS) #not sure why incremental building with shared libs doesn't work
 437         STRING(REPLACE "/INCREMENTAL:YES" "" CMAKE_SHARED_LINKER_FLAGS ${CMAKE_SHARED_LINKER_FLAGS})
 438     endif()
 439   ENDIF()
 440 ENDIF()
 441
 442 # Unconditionally find the package, as it is also required for unit tests
 443 find_package(LibXml2)
 444 option(GMX_XML "Use libxml2 to parse xml files (currently has no effect)" ${LIBXML2_FOUND})
 445 set(PKG_XML "")
 446 mark_as_advanced(GMX_XML)
 447 # Don't actually do anything, since libxml2 is currently not used by libgromacs
 448 #if(GMX_XML AND NOT LIBXML2_FOUND)
 449 #    message(FATAL_ERROR "libxml2 not found. Set GMX_XML=OFF to compile without XML support")
 450 #endif()
 451 #if(GMX_XML)
 452 #    include_directories(${LIBXML2_INCLUDE_DIR})
 453 #    set(PKG_XML libxml-2.0)
 454 #    set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 455 #endif(GMX_XML)
 456
 457 option(GMX_GSL "Add support for gsl" OFF)
 458 if (GMX_GSL)
 459   find_package(GSL)
 460   set(PKG_GSL "")
 461   if(GSL_FOUND)
 462     include_directories(${GSL_INCLUDE_DIR})
 463     set(PKG_GSL gsl)
 464     set(HAVE_LIBGSL 1)
 465   endif(GSL_FOUND)
 466 endif (GMX_GSL)
 467
 468 option(GMX_X11 "Use X window system" OFF)
 469 if (GMX_X11)
 470     find_package(X11)
 471     # X11 includes/libraries are only set in the ngmx subdirectory!
 472     if(NOT X11_FOUND)
 473         message(WARNING "X11 include files and/or libraries were not found. Will not build the GROMACS X11-binaries, such as ngmx")
 474     endif()
 475 endif(GMX_X11)
 476
 477 include(ThreadMPI)
 478 set(THREAD_MPI_LIB thread_mpi)
 479 # Enable core threading facilities
 480 tmpi_enable_core("${CMAKE_SOURCE_DIR}/src/gromacs/legacyheaders")
 481 # Enable tMPI C++ support
 482 tmpi_enable_cxx()
 483 if(GMX_THREAD_MPI)
 484     # enable MPI functions
 485     tmpi_enable()
 486     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_THREAD_MPI")
 487     set(GMX_MPI 1)
 488 endif(GMX_THREAD_MPI)
 489 tmpi_get_source_list(THREAD_MPI_SRC)
 490
 491 if(GMX_GPU)
 492     # now that we have detected the dependencies, do the second configure pass
 493     gmx_gpu_setup()
 494 endif(GMX_GPU)
 495
 496 if(CYGWIN)
 497     set(GMX_CYGWIN 1)
 498 endif(CYGWIN)
 499
 500 if(WIN32 AND NOT CYGWIN)
 501     set(GMX_NATIVE_WINDOWS 1)
 502 endif()
 503
 504 # only bother with finding git and using version.h if the source is a git repo
 505 if(GMX_GIT_VERSION_INFO)
 506     if (NOT SOURCE_IS_GIT_REPOSITORY)
 507         message(FATAL_ERROR
 508             "Cannot generate git version information from source tree not under git. "
 509             "Set GMX_GIT_VERSION_INFO=OFF to proceed.")
 510     endif ()
 511     # We need at least git v1.5.3 be able to parse git's date output. If not
 512     # found or the version is too small, we can't generate version information.
 513     find_package(Git)
 514
 515     # Find out the git version
 516     if(GIT_FOUND AND NOT GIT_VERSION)
 517       execute_process(COMMAND ${GIT_EXECUTABLE} "--version"
 518         OUTPUT_VARIABLE _exec_out
 519         OUTPUT_STRIP_TRAILING_WHITESPACE)
 520       string(REGEX REPLACE "git version (.*)" "\\1" GIT_VERSION ${_exec_out})
 521       set(GIT_VERSION ${GIT_VERSION} CACHE STRING "Git version")
 522       mark_as_advanced(GIT_VERSION)
 523     endif()
 524
 525     if(NOT GIT_FOUND OR GIT_VERSION VERSION_LESS "1.5.3")
 526         message(FATAL_ERROR
 527             "No compatible git version found (>= 1.5.3 required). "
 528             "Won't be able to generate development version information. "
 529             "Set GMX_GIT_VERSION_INFO=OFF to proceed.")
 530     endif()
 531 endif()
 532
 533 # Detect boost unless GMX_EXTERNAL_BOOST is explicitly OFF
 534 # Used for default if GMX_EXTERNAL_BOOST is not defined (first CMake pass)
 535 if(NOT DEFINED GMX_EXTERNAL_BOOST OR GMX_EXTERNAL_BOOST)
 536     find_package(Boost 1.44.0)
 537     if(Boost_FOUND AND Boost_VERSION VERSION_LESS "104400")
 538         set(Boost_FOUND FALSE)
 539     endif()
 540     # Print the notification only on first run, when determining the default
 541     if(NOT DEFINED GMX_EXTERNAL_BOOST AND NOT Boost_FOUND)
 542         message("Boost >= 1.44 not found. Using minimal internal version. "
 543                 "This may cause trouble if you plan on compiling/linking other "
 544                 "software that uses Boost against Gromacs.")
 545     endif()
 546 endif()
 547 option(GMX_EXTERNAL_BOOST "Use external Boost instead of minimal built-in version"
 548        ${Boost_FOUND})
 549 if(GMX_EXTERNAL_BOOST AND NOT Boost_FOUND)
 550     message(FATAL_ERROR
 551         "Boost >= 1.44 not found. "
 552         "You can set GMX_EXTERNAL_BOOST=OFF to compile against minimal "
 553         "version of Boost included with Gromacs.")
 554 endif()
 555
 556 option(GMX_BUILD_UNITTESTS "Build unit tests with BUILD_TESTING (uses Google C++ Testing and Mocking Frameworks, requires libxml2)" ${LIBXML2_FOUND})
 557 mark_as_advanced(GMX_BUILD_UNITTESTS)
 558 if (GMX_BUILD_UNITTESTS AND NOT LIBXML2_FOUND)
 559     message(FATAL_ERROR
 560         "Cannot build unit tests without libxml2. "
 561         "Either set GMX_BUILD_UNITTESTS=OFF or tell CMake how to find libxml2.")
 562 endif()
 563 set(MEMORYCHECK_SUPPRESSIONS_FILE ${CMAKE_SOURCE_DIR}/cmake/legacy_and_external.supp)
 564
 565 ########################################################################
 566 # Generate development version info for cache
 567 ########################################################################
 568 # set(GEN_VERSION_INFO_INTERNAL "ON")
 569 # include(gmxGenerateVersionString)
 570
 571 ########################################################################
 572 # Our own GROMACS tests
 573 ########################################################################
 574
 575 add_definitions( -DHAVE_CONFIG_H )
 576 include_directories(${CMAKE_SOURCE_DIR}/src)
 577 # Required for config.h, maybe should only be set in src/CMakeLists.txt
 578 include_directories(${CMAKE_BINARY_DIR}/src)
 579 # Required for gmx_header_config_gen.h to be found before installation
 580 include_directories(${CMAKE_BINARY_DIR}/src/gromacs/utility)
 581 # Required for now to make old code compile
 582 include_directories(${CMAKE_SOURCE_DIR}/src/gromacs/legacyheaders)
 583
 584 include(gmxTestInlineASM)
 585 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 586
 587 include(gmxSetBuildInformation)
 588 gmx_set_build_information()
 589 if(BUILD_CPU_FEATURES MATCHES "rdtscp" AND NOT GMX_DISTRIBUTABLE_BUILD)
 590     # The timestep counter headers do not include config.h
 591     add_definitions(-DHAVE_RDTSCP)
 592 endif(BUILD_CPU_FEATURES MATCHES "rdtscp" AND NOT GMX_DISTRIBUTABLE_BUILD)
 593
 594 include(gmxTestFloatFormat)
 595 gmx_test_float_format(GMX_FLOAT_FORMAT_IEEE754
 596                       GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER
 597                       GMX_IEEE754_BIG_ENDIAN_WORD_ORDER)
 598
 599 include(gmxTestLargeFiles)
 600 gmx_test_large_files(GMX_LARGEFILES)
 601
 602 include(gmxTestSignal)
 603 gmx_test_sigusr1(HAVE_SIGUSR1)
 604
 605 include(gmxTestInline)
 606 gmx_test_inline(INLINE_KEYWORD)
 607
 608 include(gmxTestRestrict)
 609 gmx_test_restrict(RESTRICT_KEYWORD)
 610
 611 include(gmxTestPipes)
 612 gmx_test_pipes(HAVE_PIPES)
 613
 614 include(gmxTestIsfinite)
 615 gmx_test_isfinite(HAVE_ISFINITE)
 616 gmx_test__isfinite(HAVE__ISFINITE)
 617 gmx_test__finite(HAVE__FINITE)
 618
 619 include(gmxTestCXX11)
 620 gmx_test_cxx11(GMX_CXX11 GMX_CXX11_FLAGS)
 621 if(CXX11_FLAG AND GMX_GPU)
 622     #FIXME: add proper solution for progate all but cxx11 flag
 623     set(CUDA_PROPAGATE_HOST_FLAGS no)
 624     message(WARNING "Please manually add compiler flags to CUDA_NVCC_FLAGS. Automatic propogation temporary not working.")
 625 endif()
 626
 627 include(gmxTestXDR)
 628 gmx_test_xdr(GMX_SYSTEM_XDR)
 629 if(NOT GMX_SYSTEM_XDR)
 630     set(GMX_INTERNAL_XDR 1)
 631     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_INTERNAL_XDR")
 632 endif(NOT GMX_SYSTEM_XDR)
 633
 634 # include avx test source, used if the AVX flags are set below
 635 include(gmxTestAVXMaskload)
 636
 637 # Process nonbonded accelerated kernels settings
 638 #
 639 # Note that for the backward-compatible x86 SIMD architectures, the
 640 # GMX_CPU_ACCELERATION determines the maximum level of the instruction
 641 # set used (e.g. GMX_CPU_ACCLERATION=SSE4.1 implies
 642 # SSE2). Accordingly, there are a set of CMake variables
 643 # GMX_<arch>_<feature-set> that are exported to the C code to specify
 644 # CPU features that should be used. This means that the logic for
 645 # requiring such backward compatibility is all located here.
 646 string(TOUPPER ${GMX_CPU_ACCELERATION} GMX_CPU_ACCELERATION)
 647 if(${GMX_CPU_ACCELERATION} STREQUAL "NONE")
 648     # nothing to do
 649 elseif(${GMX_CPU_ACCELERATION} STREQUAL "SSE2")
 650
 651     GMX_TEST_CFLAG(GNU_SSE2_CFLAG "-msse2" ACCELERATION_C_FLAGS)
 652     if(NOT GNU_SSE2_CFLAG AND GMX_NATIVE_WINDOWS)
 653         GMX_TEST_CFLAG(MSVC_SSE2_CFLAG "/arch:SSE2" ACCELERATION_C_FLAGS)
 654     endif(NOT GNU_SSE2_CFLAG AND GMX_NATIVE_WINDOWS)
 655
 656     GMX_TEST_CXXFLAG(GNU_SSE2_CXXFLAG "-msse2" ACCELERATION_CXX_FLAGS)
 657     if(NOT GNU_SSE2_CXXFLAG AND GMX_NATIVE_WINDOWS)
 658         GMX_TEST_CXXFLAG(MSVC_SSE2_CXXFLAG "/arch:SSE2" ACCELERATION_CXX_FLAGS)
 659     endif(NOT GNU_SSE2_CXXFLAG AND GMX_NATIVE_WINDOWS)
 660
 661     # We dont warn for lacking SSE2 flag support, since that is probably standard today.
 662
 663     # Only test the include after we have tried to add the correct flag for SSE2 support
 664     check_include_file(emmintrin.h  HAVE_EMMINTRIN_H ${ACCELERATION_C_FLAGS})
 665
 666     if(NOT HAVE_EMMINTRIN_H)
 667         message(FATAL_ERROR "Cannot find emmintrin.h, which is required for SSE2 intrinsics support.")
 668     endif(NOT HAVE_EMMINTRIN_H)
 669
 670     set(GMX_CPU_ACCELERATION_X86_SSE2 1)
 671     # The user should not be able to set this orthogonally to the acceleration
 672     set(GMX_X86_SSE2 1)
 673     if (NOT ACCELERATION_QUIETLY)
 674       message(STATUS "Enabling SSE2 Gromacs acceleration, and it will help compiler optimization.")
 675     endif()
 676
 677 elseif(${GMX_CPU_ACCELERATION} STREQUAL "SSE4.1")
 678
 679     GMX_TEST_CFLAG(GNU_SSE4_CFLAG "-msse4.1" ACCELERATION_C_FLAGS)
 680     if (NOT GNU_SSE4_CFLAG AND GMX_NATIVE_WINDOWS)
 681         GMX_TEST_CFLAG(MSVC_SSE4_CFLAG "/arch:SSE4.1" ACCELERATION_C_FLAGS)
 682     endif(NOT GNU_SSE4_CFLAG AND GMX_NATIVE_WINDOWS)
 683     if (NOT GNU_SSE4_CFLAG AND NOT MSVC_SSE4_CFLAG)
 684         # Not surprising if we end up here! MSVC current does not support the SSE4.1 flag. However, it appears to accept SSE4.1
 685         # intrinsics when SSE2 support is enabled, so we try that instead first.
 686         if (GMX_NATIVE_WINDOWS)
 687             GMX_TEST_CFLAG(MSVC_SSE2_CFLAG "/arch:SSE2" ACCELERATION_C_FLAGS)
 688             message(WARNING "Neither SSE4.1 or SSE2 seems to be supported by your Windows compiler. Something is likely broken.")
 689         else()
 690             message(WARNING "No C SSE4.1 flag found. Consider a newer compiler, or use SSE2 for slightly lower performance")
 691         endif()
 692     endif(NOT GNU_SSE4_CFLAG AND NOT MSVC_SSE4_CFLAG)
 693
 694     GMX_TEST_CXXFLAG(GNU_SSE4_CXXFLAG "-msse4.1" ACCELERATION_CXX_FLAGS)
 695     if (NOT GNU_SSE4_CXXFLAG AND GMX_NATIVE_WINDOWS)
 696         GMX_TEST_CXXFLAG(MSVC_SSE4_CXXFLAG "/arch:SSE4.1" ACCELERATION_CXX_FLAGS)
 697     endif(NOT GNU_SSE4_CXXFLAG AND GMX_NATIVE_WINDOWS)
 698     if (NOT GNU_SSE4_CXXFLAG AND NOT MSVC_SSE4_CXXFLAG)
 699         message(WARNING "No C++ SSE4.1 flag found. Consider a newer compiler, or use SSE2 for slightly lower performance.")
 700         # Not surprising if we end up here! MSVC current does not support the SSE4.1 flag. However, it appears to accept SSE4.1
 701         # intrinsics when SSE2 support is enabled, so we try that instead.
 702         if (GMX_NATIVE_WINDOWS)
 703             GMX_TEST_CXXFLAG(MSVC_SSE2_CXXFLAG "/arch:SSE2" ACCELERATION_CXX_FLAGS)
 704         endif()
 705     endif(NOT GNU_SSE4_CXXFLAG AND NOT MSVC_SSE4_CXXFLAG)
 706
 707     # This must come after we have added the -msse4.1 flag on some platforms.
 708     check_include_file(smmintrin.h  HAVE_SMMINTRIN_H ${ACCELERATION_C_FLAGS})
 709
 710     if(NOT HAVE_SMMINTRIN_H)
 711         message(FATAL_ERROR "Cannot find smmintrin.h, which is required for SSE4.1 intrinsics support.")
 712     endif(NOT HAVE_SMMINTRIN_H)
 713
 714     set(GMX_CPU_ACCELERATION_X86_SSE4_1 1)
 715     # The user should not be able to set this orthogonally to the acceleration
 716     set(GMX_X86_SSE4_1 1)
 717     set(GMX_X86_SSE2   1)
 718     if (NOT ACCELERATION_QUIETLY)
 719       message(STATUS "Enabling SSE4.1 Gromacs acceleration, and it will help compiler optimization.")
 720     endif()
 721
 722     if(CMAKE_C_COMPILER_ID MATCHES "Intel" AND C_COMPILER_VERSION VERSION_EQUAL "11.1")
 723         message(FATAL_ERROR "You are using Intel compiler version 11.1, and that compiler is known to produce incorrect results with SSE4.1 acceleration. You need to use another compiler (e.g. icc 12 or newer) or different acceleration (probably slower simulations).")
 724     endif()
 725 elseif(${GMX_CPU_ACCELERATION} STREQUAL "AVX_128_FMA" OR ${GMX_CPU_ACCELERATION} STREQUAL "AVX_256")
 726
 727     # Set the AVX compiler flag for both these choices!
 728
 729     GMX_TEST_CFLAG(GNU_AVX_CFLAG "-mavx" ACCELERATION_C_FLAGS)
 730     if (NOT GNU_AVX_CFLAG AND GMX_NATIVE_WINDOWS)
 731         GMX_TEST_CFLAG(MSVC_AVX_CFLAG "/arch:AVX" ACCELERATION_C_FLAGS)
 732     endif (NOT GNU_AVX_CFLAG AND GMX_NATIVE_WINDOWS)
 733     if (NOT GNU_AVX_CFLAG AND NOT MSVC_AVX_CFLAG)
 734         message(WARNING "No C AVX flag found. Consider a newer compiler, or try SSE4.1 (lower performance) giving the -DGMX_CPU_ACCELERATION=SSE4.1 to cmake.")
 735     endif (NOT GNU_AVX_CFLAG AND NOT MSVC_AVX_CFLAG)
 736
 737     GMX_TEST_CXXFLAG(GNU_AVX_CXXFLAG "-mavx" ACCELERATION_CXX_FLAGS)
 738     if (NOT GNU_AVX_CXXFLAG AND GMX_NATIVE_WINDOWS)
 739         GMX_TEST_CXXFLAG(MSVC_AVX_CXXFLAG "/arch:AVX" ACCELERATION_CXX_FLAGS)
 740     endif (NOT GNU_AVX_CXXFLAG AND GMX_NATIVE_WINDOWS)
 741     if (NOT GNU_AVX_CXXFLAG AND NOT MSVC_AVX_CXXFLAG)
 742         message(WARNING "No C++ AVX flag found. Consider a newer compiler, or try SSE4.1 (lower performance) giving the -DGMX_CPU_ACCELERATION=SSE4.1 to cmake.")
 743     endif (NOT GNU_AVX_CXXFLAG AND NOT MSVC_AVX_CXXFLAG)
 744
 745     # Set the FMA4 flags (MSVC doesn't require any)
 746     if(${GMX_CPU_ACCELERATION} STREQUAL "AVX_128_FMA" AND NOT MSVC)
 747         GMX_TEST_CFLAG(GNU_FMA_CFLAG "-mfma4" ACCELERATION_C_FLAGS)
 748         if (NOT GNU_FMA_CFLAG)
 749             message(WARNING "No C FMA4 flag found. Consider a newer compiler, or try SSE4.1 (lower performance).")
 750         endif(NOT GNU_FMA_CFLAG)
 751         GMX_TEST_CFLAG(GNU_XOP_CFLAG "-mxop" ACCELERATION_C_FLAGS)
 752         # No big deal if we do not have xop, so no point yelling warnings about it.
 753         GMX_TEST_CXXFLAG(GNU_FMA_CXXFLAG "-mfma4" ACCELERATION_CXX_FLAGS)
 754         if (NOT GNU_FMA_CXXFLAG)
 755             message(WARNING "No C++ FMA flag found. Consider a newer compiler, or try SSE4.1 (lower performance).")
 756         endif (NOT GNU_FMA_CXXFLAG)
 757         GMX_TEST_CXXFLAG(GNU_XOP_CXXFLAG "-mxop" ACCELERATION_CXX_FLAGS)
 758         # No big deal if we do not have xop, so no point yelling warnings about it.
 759     endif()
 760
 761     # Only test the header after we have tried to add the flag for AVX support
 762     check_include_file(immintrin.h  HAVE_IMMINTRIN_H ${ACCELERATION_C_FLAGS})
 763
 764     if(NOT HAVE_IMMINTRIN_H)
 765         message(FATAL_ERROR "Cannot find immintrin.h, which is required for AVX intrinsics support. Consider switching compiler.")
 766     endif(NOT HAVE_IMMINTRIN_H)
 767
 768     if(${GMX_CPU_ACCELERATION} STREQUAL "AVX_256")
 769         try_compile(TEST_AVX ${CMAKE_BINARY_DIR}
 770             "${CMAKE_SOURCE_DIR}/cmake/TestAVX.c"
 771             COMPILE_DEFINITIONS "${ACCELERATION_C_FLAGS}")
 772         if(NOT TEST_AVX)
 773             message(FATAL_ERROR "Cannot compile AVX intrinsics. Consider switching compiler.")
 774         endif()
 775     endif()
 776
 777     # GCC requires x86intrin.h for FMA support. MSVC 2010 requires intrin.h for FMA support.
 778     check_include_file(x86intrin.h HAVE_X86INTRIN_H ${ACCELERATION_C_FLAGS})
 779     check_include_file(intrin.h HAVE_INTRIN_H ${ACCELERATION_C_FLAGS})
 780
 781     # The user should not be able to set this orthogonally to the acceleration
 782     set(GMX_X86_SSE4_1 1)
 783     set(GMX_X86_SSE2   1)
 784
 785     # But just enable one of the choices internally...
 786     if(${GMX_CPU_ACCELERATION} STREQUAL "AVX_128_FMA")
 787         set(GMX_CPU_ACCELERATION_X86_AVX_128_FMA 1)
 788         set(GMX_X86_AVX_128_FMA 1)
 789         if (NOT ACCELERATION_QUIETLY)
 790           message(STATUS "Enabling 128-bit AVX Gromacs acceleration (with fused-multiply add), and it will help compiler optimization.")
 791         endif()
 792
 793         # We don't have the full compiler version string yet (BUILD_C_COMPILER),
 794         # so we can't distinguish vanilla and Apple clang, but catering for AMD
 795         # hackintoshes is not worth the effort.
 796         if (APPLE AND (${CMAKE_C_COMPILER_ID} STREQUAL "Clang" OR
 797                     ${CMAKE_CXX_COMPILER_ID} STREQUAL "Clang"))
 798             message(WARNING "Due to a known compiler bug, Clang up to version 3.2 (and Apple Clang up to version 4.1) produces incorrect code with AVX_128_FMA acceleration. As we can not work around this bug on OS X, you will have to select a different compiler or CPU acceleration.")
 799         endif()
 800
 801         if (GMX_USE_CLANG_C_FMA_BUG_WORKAROUND)
 802             # we assume that we have an external assembler that supports AVX
 803             message(STATUS "Clang ${C_COMPILER_VERSION} detected, enabling FMA bug workaround")
 804             set(EXTRA_C_FLAGS "${EXTRA_C_FLAGS} -no-integrated-as")
 805         endif()
 806         if (GMX_USE_CLANG_CXX_FMA_BUG_WORKAROUND)
 807             # we assume that we have an external assembler that supports AVX
 808             message(STATUS "Clang ${CXX_COMPILER_VERSION} detected, enabling FMA bug workaround")
 809             set(EXTRA_CXX_FLAGS "${EXTRA_CXX_FLAGS} -no-integrated-as")
 810         endif()
 811
 812     else()
 813         # If we are not doing AVX_128, it must be AVX_256...
 814         set(GMX_CPU_ACCELERATION_X86_AVX_256 1)
 815         set(GMX_X86_AVX_256 1)
 816         if (NOT ACCELERATION_QUIETLY)
 817           message(STATUS "Enabling 256-bit AVX Gromacs acceleration, and it will help compiler optimization.")
 818         endif()
 819     endif()
 820
 821     # Unfortunately gcc-4.5.2 and gcc-4.6.0 has a bug where they use the wrong datatype for the formal
 822     # parameter of the mask for maskload/maskstore arguments. Check if this is present, since we can work around it.
 823     gmx_test_avx_gcc_maskload_bug(${ACCELERATION_C_FLAGS} GMX_X86_AVX_GCC_MASKLOAD_BUG)
 824
 825 elseif(${GMX_CPU_ACCELERATION} STREQUAL "IBM_QPX")
 826     # Used on BlueGene/Q
 827     if (CMAKE_C_COMPILER_ID MATCHES "XL")
 828         GMX_TEST_CFLAG(XLC_BLUEGENEQ_CFLAG "-qarch=qp -qtune=qp" ACCELERATION_C_FLAGS)
 829         try_compile(TEST_QPX ${CMAKE_BINARY_DIR}
 830             "${CMAKE_SOURCE_DIR}/cmake/TestQPX.c"
 831             COMPILE_DEFINITIONS "${ACCELERATION_C_FLAGS}")
 832         if(NOT TEST_QPX)
 833             message(FATAL_ERROR "Cannot compile the requested IBM QPX intrinsics.")
 834         endif()
 835     endif()
 836     if (CMAKE_CXX_COMPILER_ID MATCHES "XL")
 837         GMX_TEST_CXXFLAG(XLC_BLUEGENEQ_CXXFLAG "-qarch=qp -qtune=qp" ACCELERATION_CXX_FLAGS)
 838         try_compile(TEST_QPX ${CMAKE_BINARY_DIR}
 839             "${CMAKE_SOURCE_DIR}/cmake/TestQPX.c"
 840             COMPILE_DEFINITIONS "${ACCELERATION_CXX_FLAGS}")
 841         if(NOT TEST_QPX)
 842             message(FATAL_ERROR "Cannot compile the requested IBM QPX intrinsics.")
 843         endif()
 844     endif()
 845
 846     if (TEST_QPX)
 847         message(WARNING "IBM QPX acceleration was selected and could be compiled, but the accelerated kernels are not yet available.")
 848         set(GMX_CPU_ACCELERATION_IBM_QPX 1)
 849     else()
 850         message(FATAL_ERROR "Cannot compile IBM QPX intrinsics without the XL compiler. If you are compiling for BlueGene/Q, use 'cmake .. -DCMAKE_TOOLCHAIN_FILE=BlueGeneQ-static-XL-C' to set up the tool chain.")
 851     endif()
 852 elseif(${GMX_CPU_ACCELERATION} STREQUAL "SPARC64_HPC_ACE")
 853     set(GMX_CPU_ACCELERATION_SPARC64_HPC_ACE 1)
 854 else(${GMX_CPU_ACCELERATION} STREQUAL "NONE")
 855     MESSAGE(FATAL_ERROR "Unrecognized option for accelerated kernels: ${GMX_CPU_ACCELERATION}. Pick one of None, SSE2, SSE4.1, AVX_128_FMA, AVX_256, IBM_QPX, Sparc64_HPC_ACE")
 856 endif(${GMX_CPU_ACCELERATION} STREQUAL "NONE")
 857 set(ACCELERATION_QUIETLY TRUE CACHE INTERNAL "")
 858
 859 # Process QM/MM Settings
 860 string(TOUPPER ${GMX_QMMM_PROGRAM} GMX_QMMM_PROGRAM)
 861 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 862     set(GMX_QMMM_GAUSSIAN 1)
 863 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 864     set(GMX_QMMM_MOPAC 1)
 865 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 866     set(GMX_QMMM_GAMESS 1)
 867 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 868     set(GMX_QMMM_ORCA 1)
 869 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 870     # nothing to do
 871 else(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 872     MESSAGE(FATAL_ERROR "Invalid QM/MM program option: ${GMX_QMMM_PROGRAM}. Choose one of: Gaussian, Mopac, Gamess, Orca, None")
 873 endif(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 874
 875 # Process FFT library settings
 876 string(TOUPPER ${GMX_FFT_LIBRARY} GMX_FFT_LIBRARY)
 877 set(PKG_FFT "")
 878 set(PKG_FFT_LIBS "")
 879 set(MKL_LIBRARIES_FORMAT_DESCRIPTION "Use full paths to library files, in the right order, and separated by semicolons.")
 880 set(MKL_LIBRARIES "" CACHE STRING "List of libraries for linking to MKL. Only used with GMX_FFT_LIBRARY=mkl. ${MKL_LIBRARIES_FORMAT_DESCRIPTION}")
 881 set(MKL_INCLUDE_DIR "" CACHE PATH "Path to mkl.h (non-inclusive). Only used with GMX_FFT_LIBRARY=mkl.")
 882 mark_as_advanced(FORCE MKL_LIBRARIES)
 883 mark_as_advanced(FORCE MKL_INCLUDE_DIR)
 884 if(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 885     if(GMX_DOUBLE)
 886         set(FFTW fftw)
 887     else()
 888         set(FFTW fftwf)
 889     endif()
 890
 891     if(GMX_BUILD_OWN_FFTW)
 892       add_subdirectory(src/contrib/fftw)
 893     else()
 894       find_package(FFTW COMPONENTS ${FFTW})
 895     endif()
 896     if(NOT ${FFTW}_FOUND)
 897       MESSAGE(FATAL_ERROR "Cannot find FFTW 3 (with correct precision - libfftw3f for single-precision GROMACS or libfftw3 for double-precision GROMACS). Either choose the right precision, choose another FFT(W) library (-DGMX_FFT_LIBRARY), enable the advanced option to let GROMACS build FFTW 3 for you (-DGMX_BUILD_OWN_FFTW=ON) , or use the really slow GROMACS built-in fftpack library (-DGMX_FFT_LIBRARY=fftpack).")
 898     endif()
 899
 900     string(TOUPPER "${FFTW}" FFTW)
 901     set(PKG_FFT "${${FFTW}_PKG}")
 902     include_directories(${${FFTW}_INCLUDE_DIRS})
 903     set(FFT_LIBRARIES ${${FFTW}_LIBRARIES})
 904     set(GMX_FFT_FFTW3 1)
 905
 906     if ((${GMX_CPU_ACCELERATION} MATCHES "SSE" OR ${GMX_CPU_ACCELERATION} MATCHES "AVX") AND NOT ${FFTW}_HAVE_SIMD)
 907       message(WARNING "The fftw library found is compiled without SIMD support, which makes it slow. Consider recompiling it or contact your admin")
 908     endif()
 909
 910     if((${GMX_CPU_ACCELERATION} MATCHES "SSE" OR ${GMX_CPU_ACCELERATION} MATCHES "AVX") AND ${FFTW}_HAVE_AVX)
 911         # If we're not doing CPU acceleration, we don't care about FFTW performance on x86 either
 912         message(WARNING "The FFTW library was compiled with --enable-avx to enable AVX SIMD instructions. That might sound like a good idea for your processor, but for FFTW versions up to 3.3.3, these are slower than the SSE/SSE2 SIMD instructions for the way GROMACS uses FFTs. Limitations in the way FFTW allows GROMACS to measure performance make it awkward for either GROMACS or FFTW to make the decision for you based on runtime performance. You should compile a different FFTW library with --enable-sse or --enable-sse2. If you have a more recent FFTW, you may like to compare the performance of GROMACS with FFTW libraries compiled with and without --enable-avx. However, the GROMACS developers do not really expect the FFTW AVX optimization to help, because the performance is limited by memory access, not computation.")
 913     endif()
 914
 915     if(NOT "${GMX_FFT_LIBRARY}" STREQUAL "${GMX_FFT_LIBRARY_PREVIOUS_VALUE}")
 916         MESSAGE(STATUS "Using external FFT library - FFTW3")
 917     endif()
 918 elseif(${GMX_FFT_LIBRARY} STREQUAL "MKL")
 919     # Intel 11 and up makes life somewhat easy if you just want to use
 920     # all their stuff. It's not easy if you only want some of their
 921     # stuff...
 922     if (CMAKE_C_COMPILER_ID MATCHES "Intel" AND C_COMPILER_VERSION VERSION_GREATER "11")
 923         # The next line takes care of everything for MKL
 924         if (WIN32)
 925             set(FFT_LINKER_FLAGS "/Qmkl=sequential")
 926         else()
 927             set(FFT_LINKER_FLAGS "-mkl=sequential")
 928         endif()
 929         # Some versions of icc require this in order that mkl.h can be
 930         # found at compile time.
 931         set(EXTRA_C_FLAGS "${EXTRA_C_FLAGS} ${FFT_LINKER_FLAGS}")
 932
 933         set(MKL_ERROR_MESSAGE "Make sure you have configured your compiler so that ${FFT_LINKER_FLAGS} will work.")
 934     else()
 935         # The user will have to provide the set of magic libraries in
 936         # MKL_LIBRARIES, which we cache (non-advanced), so that they
 937         # don't have to keep specifying it, and can easily see that
 938         # CMake is still using that information.
 939         set(MKL_LIBRARIES "${MKL_LIBRARIES}" CACHE STRING "User-specified libraries for linking to MKL")
 940         mark_as_advanced(CLEAR MKL_LIBRARIES)
 941         include_directories(${MKL_INCLUDE_DIR})
 942         mark_as_advanced(CLEAR MKL_INCLUDE_DIR)
 943         set(FFT_LIBRARIES "${MKL_LIBRARIES}")
 944         set(MKL_ERROR_MESSAGE "The include path to mkl.h in MKL_INCLUDE_DIR, and the link libraries in MKL_LIBRARIES=${MKL_LIBRARIES} need to match what the MKL documentation says you need for your system. ${MKL_LIBRARIES_FORMAT_DESCRIPTION}")
 945         # Convert the semi-colon separated list to a list of
 946         # command-line linker arguments so that code using our
 947         # pkgconfig setup can use it.
 948         string(REGEX REPLACE ";" " " PKG_FFT_LIBS "${MKL_LIBRARIES}")
 949     endif()
 950
 951     # Check MKL works. If we were in a non-global scope, we wouldn't
 952     # have to play nicely.
 953     set(old_CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS}")
 954     set(CMAKE_REQUIRED_FLAGS "${FFT_LINKER_FLAGS}")
 955     set(old_CMAKE_REQUIRED_LIBRARIES "${CMAKE_REQUIRED_LIBRARIES}")
 956     set(CMAKE_REQUIRED_LIBRARIES "${FFT_LIBRARIES}")
 957
 958     check_function_exists(DftiCreateDescriptor TEST_MKL)
 959
 960     set(CMAKE_REQUIRED_FLAGS "${old_CMAKE_REQUIRED_FLAGS}")
 961     set(CMAKE_REQUIRED_LIBRARIES "${old_CMAKE_REQUIRED_LIBRARIES}")
 962
 963     if(NOT TEST_MKL)
 964         # Hack to help the user vary MKL settings until they work.
 965         # TODO Make this logic more useful.
 966         unset(TEST_MKL CACHE)
 967         message(FATAL_ERROR "Linking with MKL was requested, but was not successful. ${MKL_ERROR_MESSAGE}")
 968     endif()
 969
 970     # Set variables to signal that we have MKL available and should use it for FFTs.
 971     set(GMX_FFT_MKL 1)
 972     set(HAVE_LIBMKL 1)
 973
 974     if(NOT "${GMX_FFT_LIBRARY}" STREQUAL "${GMX_FFT_LIBRARY_PREVIOUS_VALUE}")
 975         MESSAGE(STATUS "Using external FFT library - Intel MKL")
 976     endif()
 977 elseif(${GMX_FFT_LIBRARY} STREQUAL "FFTPACK")
 978     set(GMX_FFT_FFTPACK 1)
 979     if(NOT "${GMX_FFT_LIBRARY}" STREQUAL "${GMX_FFT_LIBRARY_PREVIOUS_VALUE}")
 980         MESSAGE(STATUS "Using internal FFT library - fftpack")
 981     endif()
 982 else(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 983     MESSAGE(FATAL_ERROR "Invalid FFT library setting: ${GMX_FFT_LIBRARY}. Choose one of: fftw3, mkl, fftpack")
 984 endif(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 985 set(GMX_FFT_LIBRARY_PREVIOUS_VALUE ${GMX_FFT_LIBRARY} CACHE INTERNAL "Previous value for GMX_FFT_LIBRARY, so that we can detect when it changes.")
 986
 987 # enable threaded fftw3 if we've found it
 988 if(FFTW3_THREADS OR FFTW3F_THREADS)
 989     add_definitions(-DFFT5D_FFTW_THREADS)
 990 endif()
 991
 992 include(gmxManageLinearAlgebraLibraries)
 993
 994 # Whether GROMACS will really try to compile support for VMD plugins
 995 set(GMX_USE_PLUGINS OFF)
 996
 997 if(GMX_LOAD_PLUGINS)
 998   if(CYGWIN OR NOT WIN32)
 999     # Native Windows does not have, nor need dlopen
1000     # Note that WIN32 is set with Cygwin, but Cygwin needs dlopen to use plug-ins
1001     include(gmxTestdlopen)
1002     gmx_test_dlopen(HAVE_DLOPEN)
1003   endif()
1004
1005   # so, should we use plug-ins?
1006   if((WIN32 AND NOT CYGWIN) OR (HAVE_DLOPEN AND BUILD_SHARED_LIBS))
1007     if(NOT VMD_QUIETLY)
1008       MESSAGE(STATUS
1009           "Found the ability to use plug-ins when building shared libaries, "
1010           "so will compile to use plug-ins (e.g. to read VMD-supported file "
1011           "formats).")
1012     endif()
1013     if(NOT GMX_VMD_PLUGIN_PATH)
1014       find_package(VMD)
1015     endif()
1016     set(GMX_USE_PLUGINS ON)
1017     list(APPEND GMX_EXTRA_LIBRARIES ${CMAKE_DL_LIBS}) # magic cross-platform pre-set variable for dlopen library
1018     set(PKG_DL_LIBS "-l${CMAKE_DL_LIBS}")
1019   else()
1020     set(PKG_DL_LIBS)
1021   endif()
1022 endif(GMX_LOAD_PLUGINS)
1023 set(VMD_QUIETLY TRUE CACHE INTERNAL "")
1024
1025 if(EXISTS "${CMAKE_SOURCE_DIR}/admin/.isreposource")
1026     if(NOT CMAKE_CROSSCOMPILING)
1027         option(GMX_BUILD_MANPAGES "Build man pages" ON)
1028     else()
1029         message(STATUS "Building the man pages is not available when "
1030             "cross-compiling the developer version from git")
1031     endif()
1032 else()
1033     #make sure source package contains all man pages
1034     if(NOT EXISTS "${CMAKE_SOURCE_DIR}/man/man1/ngmx.1")
1035         message(FATAL_ERROR "Man pages are missing from source package.")
1036     endif()
1037 endif()
1038 mark_as_advanced(GMX_BUILD_MANPAGES)
1039
1040 # Math and thread libraries must often come after all others when linking...
1041 if(HAVE_LIBM)
1042     list(APPEND GMX_EXTRA_LIBRARIES m)
1043 endif(HAVE_LIBM)
1044
1045 if(GMX_FAHCORE)
1046   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
1047       "Path to swindirect.h")
1048   include_directories(${COREWRAP_INCLUDE_DIR})
1049   set_property(CACHE GMX_COOL_QUOTES PROPERTY VALUE OFF)
1050 endif(GMX_FAHCORE)
1051
1052 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
1053 # these are set after everything else
1054 if (NOT GMX_SKIP_DEFAULT_CFLAGS)
1055     set(CMAKE_C_FLAGS "${ACCELERATION_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${CMAKE_C_FLAGS}")
1056     set(CMAKE_CXX_FLAGS "${ACCELERATION_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${GMX_CXX11_FLAGS} ${EXTRA_CXX_FLAGS} ${CMAKE_CXX_FLAGS}")
1057     set(CMAKE_EXE_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}")
1058     set(CMAKE_SHARED_LINKER_FLAGS "${MPI_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS}")
1059 else()
1060     message("Recommended flags which are not added because GMX_SKIP_DEFAULT_CFLAGS=yes:")
1061     message("CMAKE_C_FLAGS: ${ACCELERATION_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${GMXC_CFLAGS}")
1062     message("CMAKE_C_FLAGS_RELEASE: ${GMXC_CFLAGS_RELEASE}")
1063     message("CMAKE_C_FLAGS_DEBUG: ${GMXC_CFLAGS_DEBUG}")
1064     message("CMAKE_CXX_FLAGS: ${ACCELERATION_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${GMX_CXX11_FLAGS} ${EXTRA_CXX_FLAGS} ${GMXC_CXXFLAGS}")
1065     message("CMAKE_CXX_FLAGS_RELEASE: ${GMXC_CXXFLAGS_RELEASE}")
1066     message("CMAKE_CXX_FLAGS_DEBUG: ${GMXC_CXXFLAGS_DEBUG}")
1067     message("CMAKE_EXE_LINKER_FLAGS: ${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS}")
1068     message("CMAKE_SHARED_LINKER_FLAGS: ${MPI_LINKER_FLAGS}")
1069 endif()
1070
1071 if(NOT GMX_OPENMP)
1072     #Unset all OpenMP flags in case OpenMP was disabled either by the user
1073     #or because it was only partially detected (e.g. only for C but not C++ compiler)
1074     unset(OpenMP_C_FLAGS CACHE)
1075     unset(OpenMP_CXX_FLAGS CACHE)
1076 else()
1077     set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} ${OpenMP_LINKER_FLAGS})
1078     set(GMX_SHARED_LINKER_FLAGS ${GMX_SHARED_LINKER_FLAGS} ${OpenMP_SHARED_LINKER_FLAGS})
1079 endif()
1080 set(PKG_CFLAGS "${PKG_CFLAGS} ${OpenMP_C_FLAGS}")
1081
1082 ######################################
1083 # Output compiler and CFLAGS used
1084 ######################################
1085 get_compiler_info(C BUILD_C_COMPILER BUILD_CFLAGS)
1086 get_compiler_info(CXX BUILD_CXX_COMPILER BUILD_CXXFLAGS)
1087 if(GMX_GPU)
1088     get_cuda_compiler_info(CUDA_NVCC_COMPILER_INFO CUDA_NVCC_COMPILER_FLAGS)
1089 endif(GMX_GPU)
1090
1091 ########################################################################
1092 # Specify install locations
1093 ########################################################################
1094 if ( NOT DEFINED GMXLIB )
1095     set(GMXLIB lib)
1096 endif()
1097 set(LIB_INSTALL_DIR "${GMX_INSTALL_PREFIX}${GMXLIB}")
1098 set(BIN_INSTALL_DIR  ${GMX_INSTALL_PREFIX}bin)
1099 set(DATA_INSTALL_DIR ${GMX_INSTALL_PREFIX}share/gromacs)
1100 set(MAN_INSTALL_DIR  ${GMX_INSTALL_PREFIX}share/man)
1101 set(INCL_INSTALL_DIR ${GMX_INSTALL_PREFIX}include)
1102
1103 set(GMXLIBDIR        ${DATA_INSTALL_DIR}/top)
1104
1105 ########################################################################
1106 # Set up binary and library suffixing
1107 ########################################################################
1108 set(GMX_BINARY_SUFFIX "" CACHE STRING "Suffix for GROMACS binaries (default: _d for double, _mpi for MPI, _mpi_d for MPI and double).")
1109 set(GMX_LIBS_SUFFIX ""
1110   CACHE STRING "Suffix for GROMACS libs (default: _d for double, _mpi for MPI, _mpi_d for MPI and double).")
1111 if (GMX_DEFAULT_SUFFIX)
1112   set(GMX_BINARY_SUFFIX "")
1113   set(GMX_LIBS_SUFFIX "")
1114   if (GMX_LIB_MPI)
1115     set(GMX_BINARY_SUFFIX "_mpi")
1116     set(GMX_LIBS_SUFFIX "_mpi")
1117   endif()
1118   if (GMX_DOUBLE)
1119     set (GMX_BINARY_SUFFIX "${GMX_BINARY_SUFFIX}_d")
1120     set (GMX_LIBS_SUFFIX "${GMX_LIBS_SUFFIX}_d")
1121   endif(GMX_DOUBLE)
1122   mark_as_advanced(FORCE GMX_BINARY_SUFFIX GMX_LIBS_SUFFIX)
1123   if (NOT SUFFIX_QUIETLY)
1124     message(STATUS "Using default binary suffix: \"${GMX_BINARY_SUFFIX}\"")
1125     message(STATUS "Using default library suffix: \"${GMX_LIBS_SUFFIX}\"")
1126   endif (NOT SUFFIX_QUIETLY)
1127 else(GMX_DEFAULT_SUFFIX)
1128   mark_as_advanced(CLEAR GMX_BINARY_SUFFIX GMX_LIBS_SUFFIX)
1129   if (NOT SUFFIX_QUIETLY)
1130     message(STATUS "Using manually set binary suffix: \"${GMX_BINARY_SUFFIX}\"")
1131     message(STATUS "Using manually set library suffix: \"${GMX_LIBS_SUFFIX}\"")
1132   endif (NOT SUFFIX_QUIETLY)
1133 endif(GMX_DEFAULT_SUFFIX)
1134 if (GMX_BUILD_MDRUN_ONLY)
1135     set(GMX_LIBS_SUFFIX "_mdrun${GMX_LIBS_SUFFIX}")
1136 endif ()
1137 set(SUFFIX_QUIETLY TRUE CACHE INTERNAL "")
1138
1139 ##################################################################
1140 # Shared library settings
1141 ##################################################################
1142 if(NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin")
1143     set(CMAKE_SKIP_BUILD_RPATH  FALSE)
1144     set(CMAKE_BUILD_WITH_INSTALL_RPATH FALSE)
1145     set(CMAKE_INSTALL_RPATH "\\\$ORIGIN/../${GMXLIB}")
1146     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
1147 else()
1148     if(CMAKE_SYSTEM_VERSION VERSION_GREATER 8.0) #rpath supported for >10.4
1149         set(CMAKE_INSTALL_NAME_DIR "@rpath")
1150         set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} "-Wl,-rpath,@executable_path/../lib")
1151     else()
1152         set(CMAKE_INSTALL_NAME_DIR "${CMAKE_INSTALL_PREFIX}/${LIB_INSTALL_DIR}")
1153     endif()
1154 endif()
1155
1156 #COPYING file: Only necessary for binary distributions.
1157 #Simpler to always install.
1158 install(FILES COPYING DESTINATION ${DATA_INSTALL_DIR} COMPONENT data)
1159
1160 if(GMX_EXTERNAL_BOOST)
1161     include_directories(${Boost_INCLUDE_DIRS})
1162 else()
1163     include_directories(${CMAKE_SOURCE_DIR}/src/external/boost)
1164     # typeid not supported for minimal internal version
1165     # (would add significant amount of code)
1166     add_definitions(-DBOOST_NO_TYPEID)
1167     # TODO: Propagate the above settings to the installed CMakeFiles.txt template
1168     # (from share/template/)
1169     set(PKG_CFLAGS "${PKG_CFLAGS} -DBOOST_NO_TYPEID -I${INCL_INSTALL_DIR}/gromacs/external/boost")
1170     if (NOT GMX_BUILD_MDRUN_ONLY)
1171         install(DIRECTORY ${CMAKE_SOURCE_DIR}/src/external/boost/boost
1172                 DESTINATION ${INCL_INSTALL_DIR}/gromacs/external/boost
1173                 COMPONENT development)
1174     endif ()
1175 endif()
1176
1177 if (GMX_BUILD_FOR_COVERAGE)
1178     # Code heavy with asserts makes conditional coverage close to useless metric,
1179     # as by design most of the false branches are impossible to trigger in
1180     # correctly functioning code.  And the benefit of testing those that could
1181     # be triggered by using an API against its specification isn't usually
1182     # worth the effort.
1183     add_definitions(-DNDEBUG -DBOOST_DISABLE_ASSERTS -DGMX_DISABLE_ASSERTS)
1184 endif ()
1185
1186 if (NOT GMX_BUILD_MDRUN_ONLY)
1187     add_subdirectory(doxygen)
1188     add_subdirectory(share)
1189     add_subdirectory(scripts)
1190 endif ()
1191 add_subdirectory(src)
1192
1193 # Issue a warning if NVIDIA GPUs were detected, but CUDA was not found.
1194 # Don't bother the user after the first configure pass.
1195 if ((CUDA_NOTFOUND_AUTO AND GMX_DETECT_GPU_AVAILABLE) AND NOT GMX_GPU_DETECTION_DONE)
1196     message(WARNING "${CUDA_NOTFOUND_MESSAGE}")
1197 endif()
1198 set(GMX_GPU_DETECTION_DONE TRUE CACHE INTERNAL "Whether GPU detection has already been done")
1199
1200 #######################
1201 ## uninstall target
1202 #######################
1203     CONFIGURE_FILE(
1204                    "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
1205                    "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
1206                    IMMEDIATE @ONLY)
1207 ###########################
1208 ADD_CUSTOM_TARGET(uninstall
1209                   "${CMAKE_COMMAND}" -P
1210                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
1211 ###########################
1212
1213 ########################################################################
1214 # Tests                                                                #
1215 ########################################################################
1216
1217 include(CTest)
1218 mark_as_advanced(BUILD_TESTING)
1219 IF(BUILD_TESTING)
1220     enable_testing()
1221     #"check" target builds and runs all tests
1222     add_custom_target(check COMMAND ${CMAKE_CTEST_COMMAND} --output-on-failure)
1223     add_dependencies(check tests)
1224     # TODO: This would be better within tests/CMakeLists.txt
1225     if (NOT GMX_BUILD_MDRUN_ONLY)
1226         #gmxtests target builds all binaries required for running gmxtest
1227         add_custom_target(gmxtests DEPENDS gmx links)
1228         add_dependencies(check gmxtests)
1229         add_subdirectory(tests)
1230     endif()
1231     #TODO: Add warning if NOT REGRESSIONTEST_PATH OR NOT GMX_XML that regression/unit tests are not run.
1232 ENDIF()
1233