CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.8)
   2 # Keep CMake suitably quiet on Cygwin
   3 set(CMAKE_LEGACY_CYGWIN_WIN32 0) # Remove when CMake >= 2.8.4 is required
   4
   5 project(Gromacs)
   6 include(Dart)
   7 mark_as_advanced(DART_ROOT)
   8
   9 # PROJECT_VERSION should have the following structure:
  10 # VERSION-dev[-SUFFIX] where the VERSION should have the for: vMajor.vMinor.vPatch
  11 #
  12 # The "-dev" suffix is important to keep because it makes possible to distinguish
  13 # between a build from official release and a build from git release branch on a
  14 # machine with no git.
  15 #
  16 # NOTE: when releasing the "-dev" suffix needs to be stripped off!
  17 set(PROJECT_VERSION "5.0-dev")
  18 set(CUSTOM_VERSION_STRING ""
  19     CACHE STRING "Custom version string (if empty, use hard-coded default)")
  20 mark_as_advanced(CUSTOM_VERSION_STRING)
  21 if (CUSTOM_VERSION_STRING)
  22     set(PROJECT_VERSION ${CUSTOM_VERSION_STRING})
  23 endif (CUSTOM_VERSION_STRING)
  24 set(SOVERSION 6)
  25 # It is a bit irritating, but this has to be set separately for now!
  26 SET(CPACK_PACKAGE_VERSION_MAJOR "4")
  27 SET(CPACK_PACKAGE_VERSION_MINOR "6")
  28 #SET(CPACK_PACKAGE_VERSION_PATCH "0")
  29
  30
  31 # Cmake modules/macros are in a subdirectory to keep this file cleaner
  32 set(CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake)
  33
  34 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
  35 set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
  36 endif()
  37
  38 if(NOT CMAKE_BUILD_TYPE)
  39     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel." FORCE)
  40 endif(NOT CMAKE_BUILD_TYPE)
  41
  42 enable_language(C)
  43 enable_language(CXX)
  44
  45 set(CPACK_PACKAGE_VERSION ${PROJECT_VERSION})
  46 set(CPACK_PACKAGE_VENDOR "gromacs.org")
  47 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Gromacs - a toolkit for high-performance molecular simulation")
  48 set(CPACK_SET_DESTDIR "ON")
  49 set(CPACK_INCLUDE_TOPLEVEL_DIRECTORY 0)
  50 set(CPACK_RESOURCE_FILE_WELCOME "${CMAKE_SOURCE_DIR}/admin/InstallWelcome.txt")
  51 # Its GPL/LGPL, so they do not have to agree to a license for mere usage, but some installers require this...
  52 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_SOURCE_DIR}/admin/InstallLicense.txt")
  53 set(CPACK_RESOURCE_FILE_README "${CMAKE_SOURCE_DIR}/admin/InstallInfo.txt")
  54
  55 #must come after all cpack settings!
  56 include(CPack)
  57
  58 ########################################################################
  59 # Check and warn if cache generated on a different host is being reused
  60 ########################################################################
  61 if(CMAKE_HOST_UNIX)
  62     execute_process(COMMAND hostname
  63                     OUTPUT_VARIABLE TMP_HOSTNAME
  64                     OUTPUT_STRIP_TRAILING_WHITESPACE)
  65     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}")
  66         message(WARNING "
  67             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
  68             is being reused! This could lead to inconsitencies; therefore, it is
  69             recommended to regenerate the cache!")
  70     endif()
  71     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
  72             "Hostname of the machine where the cache was generated.")
  73 endif()
  74
  75 ########################################################################
  76 # Fix stupid flags on Windows
  77 ########################################################################
  78 SET(SHARED_LIBS_DEFAULT ON)
  79 IF( WIN32 AND NOT CYGWIN)
  80   option(GMX_PREFER_STATIC_LIBS "When finding libraries prefer static system libraries (MT instead of MD)!" ON)
  81   mark_as_advanced(GMX_PREFER_STATIC_LIBS)
  82   SET(SHARED_LIBS_DEFAULT OFF)  #is currently not working on Windows
  83
  84   IF (GMX_PREFER_STATIC_LIBS)
  85     #Only setting Debug and Release flags. Others configurations current not used.
  86     STRING(REPLACE /MD /MT CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE})
  87     SET(CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE} CACHE STRING "" FORCE)
  88     STRING(REPLACE /MD /MT CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG})
  89     SET(CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG} CACHE STRING "" FORCE)
  90     STRING(REPLACE /MD /MT CMAKE_CXX_FLAGS_RELEASE ${CMAKE_CXX_FLAGS_RELEASE})
  91     SET(CMAKE_CXX_FLAGS_RELEASE ${CMAKE_CXX_FLAGS_RELEASE} CACHE STRING "" FORCE)
  92     STRING(REPLACE /MD /MT CMAKE_CXX_FLAGS_DEBUG ${CMAKE_CXX_FLAGS_DEBUG})
  93     SET(CMAKE_CXX_FLAGS_DEBUG ${CMAKE_CXX_FLAGS_DEBUG} CACHE STRING "" FORCE)
  94   ENDIF()
  95
  96   #Workaround for cmake bug 13174. Replace deprecated options.
  97   IF( CMAKE_C_COMPILER_ID MATCHES "Intel" )
  98     STRING(REPLACE /GZ /RTC1 CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG})
  99     SET(CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG} CACHE STRING "" FORCE)
 100   ENDIF()
 101   IF( CMAKE_CXX_COMPILER_ID MATCHES "Intel" )
 102     STRING(REPLACE /GZ /RTC1 CMAKE_CXX_FLAGS_DEBUG ${CMAKE_CXX_FLAGS_DEBUG})
 103     STRING(REPLACE /GX /EHsc CMAKE_CXX_FLAGS_DEBUG ${CMAKE_CXX_FLAGS_DEBUG})
 104     SET(CMAKE_CXX_FLAGS_DEBUG ${CMAKE_CXX_FLAGS_DEBUG} CACHE STRING "" FORCE)
 105
 106     STRING(REPLACE /GX /EHsc CMAKE_CXX_FLAGS_RELEASE ${CMAKE_CXX_FLAGS_RELEASE})
 107     SET(CMAKE_CXX_FLAGS_RELEASE ${CMAKE_CXX_FLAGS_RELEASE} CACHE STRING "" FORCE)
 108   ENDIF()
 109 ENDIF()
 110
 111 ########################################################################
 112 # User input options                                                   #
 113 ########################################################################
 114 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" OFF)
 115 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 116 option(GMX_THREAD_MPI  "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" ON)
 117 option(GMX_SOFTWARE_INVSQRT "Use GROMACS software 1/sqrt" ON)
 118 mark_as_advanced(GMX_SOFTWARE_INVSQRT)
 119 option(GMX_POWERPC_INVSQRT "Use PowerPC hardware 1/sqrt" OFF)
 120 mark_as_advanced(GMX_POWERPC_INVSQRT)
 121 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 122 mark_as_advanced(GMX_FAHCORE)
 123 option(GMX_OPENMM "Accelerated execution on GPUs through the OpenMM library (rerun cmake after changing to see relevant options)" OFF)
 124 set(GMX_ACCELERATION "auto"
 125     CACHE STRING "Accelerated kernels. Pick one of: auto, none, SSE, BlueGene, Power6, ia64, altivec, fortran")
 126
 127 set(GMX_FFT_LIBRARY "fftw3"
 128     CACHE STRING "FFT library choices: fftw3,mkl,fftpack[built-in]")
 129 option(GMX_DISABLE_FFTW_MEASURE
 130        "Do not optimize FFTW setups (not needed with SSE)" OFF)
 131 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 132 set(GMX_QMMM_PROGRAM "none"
 133     CACHE STRING "QM package choices: none,gaussian,mopac,gamess,orca")
 134 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 135 mark_as_advanced(GMX_BROKEN_CALLOC)
 136 option(BUILD_SHARED_LIBS "Enable shared libraries (can be problematic with MPI, Windows)" ${SHARED_LIBS_DEFAULT})
 137 option(GMX_MPI_IN_PLACE "Enable MPI_IN_PLACE for MPIs that have it defined" ON)
 138 mark_as_advanced(GMX_MPI_IN_PLACE)
 139 option(GMX_LOAD_PLUGINS "Compile with plugin support, needed to read VMD supported file formats" ON)
 140 mark_as_advanced(GMX_LOAD_PLUGINS)
 141
 142
 143 option(GMX_IA32_ASM "Add SSE assembly files for IA32" OFF)
 144 mark_as_advanced(GMX_IA32_ASM)
 145 option(GMX_X86_64_ASM "Add SSE assembly files for X86_64" OFF)
 146 mark_as_advanced(GMX_X86_64_ASM)
 147
 148 option(GMX_OPENMP "Enable OpenMP-based mutithreading. " ON)
 149
 150 option(USE_VERSION_H "Generate development version string/information" ON)
 151 mark_as_advanced(USE_VERSION_H)
 152
 153 option(GMX_DEFAULT_SUFFIX "Use default suffixes for GROMACS binaries and libs (_d for double, _mpi for MPI; rerun cmake after changing to see relevant options)" ON)
 154
 155 if(UNIX AND NOT APPLE)
 156     option(GMX_PREFER_STATIC_LIBS "When finding libraries prefer \".a\" static archives (NOTE: this is enabled only for UNIX (excluding APPLE) platforms but it might not always work!" OFF)
 157     mark_as_advanced(GMX_PREFER_STATIC_LIBS)
 158 endif()
 159
 160
 161 ######################################################################
 162 # compiler tests
 163 # these need ot be done early (before further tests).
 164 #####################################################################
 165
 166 # cmake/Check{C,CXX}CompilerFlag.cmake are lifted from CMake git next
 167 # branch (proposed for v2.8.9) to be able to detect invalid options
 168 # with the Intel Compilers.
 169 # Remove these files from the source tree when a CMake version that
 170 # includes the features in question becomes required.
 171 include(CheckCCompilerFlag)
 172 include(CheckCXXCompilerFlag)
 173
 174 include(gmxCFlags)
 175 gmx_c_flags()
 176
 177
 178 ########################################################################
 179 # Set up binary and library suffixing
 180 ########################################################################
 181 set(GMX_BINARY_SUFFIX "" CACHE STRING "Suffix for GROMACS binaries (default: _d for double, _mpi for MPI, _mpi_d for MPI and double).")
 182 set(GMX_LIBS_SUFFIX ""
 183   CACHE STRING "Suffix for GROMACS libs (default: _d for double, _mpi for MPI, _mpi_d for MPI and double).")
 184 if (GMX_DEFAULT_SUFFIX)
 185   set(GMX_BINARY_SUFFIX "")
 186   set(GMX_LIBS_SUFFIX "")
 187   if (GMX_MPI)
 188     set(GMX_BINARY_SUFFIX "_mpi")
 189     set(GMX_LIBS_SUFFIX "_mpi")
 190   endif(GMX_MPI)
 191   if (GMX_DOUBLE)
 192     set (GMX_BINARY_SUFFIX "${GMX_BINARY_SUFFIX}_d")
 193     set (GMX_LIBS_SUFFIX "${GMX_LIBS_SUFFIX}_d")
 194   endif(GMX_DOUBLE)
 195   if (GMX_OPENMM)
 196     set (GMX_BINARY_SUFFIX "-gpu")
 197     set (GMX_LIBS_SUFFIX "_gpu")
 198   endif(GMX_OPENMM)
 199   mark_as_advanced(FORCE GMX_BINARY_SUFFIX GMX_LIBS_SUFFIX)
 200   if (NOT SUFFIX_QUIETLY)
 201     message(STATUS "Using default binary suffix: \"${GMX_BINARY_SUFFIX}\"")
 202     message(STATUS "Using default library suffix: \"${GMX_LIBS_SUFFIX}\"")
 203   endif (NOT SUFFIX_QUIETLY)
 204 else(GMX_DEFAULT_SUFFIX)
 205   mark_as_advanced(CLEAR GMX_BINARY_SUFFIX GMX_LIBS_SUFFIX)
 206   if (NOT SUFFIX_QUIETLY)
 207     message(STATUS "Using manually set binary suffix: \"${GMX_BINARY_SUFFIX}\"")
 208     message(STATUS "Using manually set library suffix: \"${GMX_LIBS_SUFFIX}\"")
 209   endif (NOT SUFFIX_QUIETLY)
 210 endif(GMX_DEFAULT_SUFFIX)
 211 set(SUFFIX_QUIETLY TRUE CACHE INTERNAL "")
 212
 213 set(PKG_CFLAGS "")
 214 if(GMX_DOUBLE)
 215     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_DOUBLE")
 216 endif(GMX_DOUBLE)
 217 if(GMX_SOFTWARE_INVSQRT)
 218   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_SOFTWARE_INVSQRT")
 219 endif(GMX_SOFTWARE_INVSQRT)
 220 if(GMX_POWERPC_INVSQRT)
 221   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_POWERPC_INVSQRT")
 222 endif(GMX_POWERPC_INVSQRT)
 223
 224 ########################################################################
 225 #Process MPI settings
 226 ########################################################################
 227 include(gmxManageMPI)
 228
 229 #######################################################################
 230 # Check for options incompatible with OpenMM build                    #
 231 #######################################################################
 232 if(GMX_OPENMM)
 233     # we'll use the built-in fft to avoid unnecessary dependencies
 234     string(TOUPPER ${GMX_FFT_LIBRARY} GMX_FFT_LIBRARY)
 235     if(NOT ${GMX_FFT_LIBRARY} STREQUAL "FFTPACK")
 236         message(STATUS "No external FFT libraries needed for the OpenMM build, switching to fftpack!")
 237         set(GMX_FFT_LIBRARY "fftpack" CACHE STRING
 238                 "No external FFT libraries needed for the OpenMM build, switching to  fftpack!" FORCE)
 239     endif()
 240     if(GMX_MPI)
 241         message(FATAL_ERROR "The OpenMM build is not compatible with MPI!")
 242     endif(GMX_MPI)
 243     if(GMX_THREAD_MPI)
 244         message(STATUS "Thread-MPI not compatible with OpenMM, disabled!")
 245         set(GMX_THREAD_MPI OFF CACHE BOOL
 246                 "Thread-MPI not compatible with OpenMM build, disabled!" FORCE)
 247     endif(GMX_THREAD_MPI)
 248     if(GMX_OPENMP)
 249         message(STATUS "OpenMP multithreading not compatible with OpenMM, disabled")
 250         set(GMX_OPENMP OFF CACHE BOOL
 251             "OpenMP multithreading not compatible with OpenMM, disabled!" FORCE)
 252     endif()
 253     if(GMX_SOFTWARE_INVSQRT)
 254         set(GMX_SOFTWARE_INVSQRT OFF CACHE STRING
 255                 "The OpenMM build does not need GROMACS software 1/sqrt!" FORCE)
 256     endif(GMX_SOFTWARE_INVSQRT)
 257     string(TOUPPER ${GMX_ACCELERATION} GMX_ACCELERATION)
 258     if(NOT GMX_ACCELERATION STREQUAL "NONE")
 259         message(STATUS "Switching off CPU-based acceleration, the OpenMM build does not support/need any!")
 260         set(GMX_ACCELERATION "none" CACHE STRING
 261                 "Switching off CPU-based acceleration, the OpenMM build does not support/need any!" FORCE)
 262     endif()
 263     if(GMX_FAHCORE)
 264         message(FATAL_ERROR "The OpenMM build does not support FAH build!")
 265     endif(GMX_FAHCORE)
 266     if(GMX_DOUBLE)
 267         message(FATAL_ERROR  "The OpenMM-build does not support double precision calculations!")
 268     endif()
 269     # mark as advanced the unused variables
 270     mark_as_advanced(FORCE GMX_ACCELERATION GMX_MPI GMX_FFT_LIBRARY
 271         GMX_QMMM_PROGRAM GMX_THREAD_MPI GMX_DOUBLE)
 272 else(GMX_OPENMM)
 273      mark_as_advanced(CLEAR GMX_ACCELERATION GMX_MPI GMX_FFT_LIBRARY
 274         GMX_QMMM_PROGRAM GMX_THREAD_MPI GMX_DOUBLE)
 275 endif(GMX_OPENMM)
 276
 277
 278 ########################################################################
 279 # Basic system tests (standard libraries, headers, functions, types)   #
 280 ########################################################################
 281 include(CheckIncludeFiles)
 282 check_include_files(unistd.h     HAVE_UNISTD_H)
 283 check_include_files(pwd.h        HAVE_PWD_H)
 284 check_include_files(pthread.h    HAVE_PTHREAD_H)
 285 check_include_files(dirent.h     HAVE_DIRENT_H)
 286 check_include_files(regex.h      HAVE_REGEX_H)
 287 check_include_files(sys/types.h  HAVE_SYS_TYPES_H)
 288 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 289 check_include_files(io.h                 HAVE_IO_H)
 290
 291
 292 include(CheckFunctionExists)
 293 check_function_exists(strdup            HAVE_STRDUP)
 294 check_function_exists(posix_memalign    HAVE_POSIX_MEMALIGN)
 295 check_function_exists(memalign          HAVE_MEMALIGN)
 296 check_function_exists(_aligned_malloc   HAVE__ALIGNED_MALLOC)
 297 check_function_exists(gettimeofday      HAVE_GETTIMEOFDAY)
 298 check_function_exists(fsync             HAVE_FSYNC)
 299 check_function_exists(_fileno           HAVE__FILENO)
 300 check_function_exists(fileno            HAVE_FILENO)
 301 check_function_exists(_commit           HAVE__COMMIT)
 302 check_function_exists(lstat             HAVE_LSTAT)
 303 check_function_exists(sigaction         HAVE_SIGACTION)
 304
 305 include(CheckLibraryExists)
 306 check_library_exists(m sqrt "" HAVE_LIBM)
 307 check_library_exists(m cbrt "" HAVE_CBRT)
 308
 309
 310 include(CheckTypeSize)
 311
 312 check_type_size("int"           SIZEOF_INT)
 313 check_type_size("long int"      SIZEOF_LONG_INT)
 314 check_type_size("long long int" SIZEOF_LONG_LONG_INT)
 315 check_type_size("off_t"         SIZEOF_OFF_T)
 316 check_type_size("void *"        SIZEOF_VOIDP)
 317
 318 if (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 319     set(GMX_64_BIT TRUE)
 320 else (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 321     set(GMX_64_BIT FALSE)
 322 endif (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 323
 324 # Check for some basic types that we *need*, so set these to int if they are not present
 325 check_type_size(uid_t uid_t)
 326 if(NOT uid_t)
 327   set(uid_t int)
 328 else(NOT uid_t)
 329   set(uid_t 0)
 330 endif(NOT uid_t)
 331
 332 check_type_size(gid_t gid_t)
 333 if(NOT gid_t)
 334   set(gid_t 1)
 335 else(NOT gid_t)
 336   set(gid_t 0)
 337 endif(NOT gid_t)
 338
 339 check_type_size(size_t size_t)
 340 if(NOT size_t)
 341   set(size_t int)
 342 else(NOT size_t)
 343   set(size_t 0)
 344 endif(NOT size_t)
 345
 346 check_type_size(off_t off_t)
 347 if(NOT off_t)
 348   set(off_t int)
 349 else(NOT off_t)
 350   set(off_t 0)
 351 endif(NOT off_t)
 352
 353 include(TestBigEndian)
 354 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 355
 356
 357
 358
 359 ########################################################################
 360 # Find external packages                                               #
 361 ########################################################################
 362 if(UNIX AND NOT APPLE)
 363     if(GMX_PREFER_STATIC_LIBS)
 364         SET(CMAKE_FIND_LIBRARY_SUFFIXES .a ${CMAKE_FIND_LIBRARY_SUFFIXES})
 365         if(BUILD_SHARED_LIBS)
 366             message(WARNING "Static libraries requested, the GROMACS libraries will also be build static (BUILD_SHARED_LIBS=OFF)")
 367             set(BUILD_SHARED_LIBS OFF CACHE BOOL "Enable shared libraries (can be problematic with MPI, Windows)" FORCE)
 368         endif()
 369     endif()
 370 endif()
 371
 372 option(GMX_XML "Use libxml2 to parse xml files" ON)
 373 if (GMX_XML)
 374   find_package(LibXml2)
 375   set(PKG_XML "")
 376   if(LIBXML2_FOUND)
 377     include_directories(${LIBXML2_INCLUDE_DIR})
 378     set(PKG_XML libxml-2.0)
 379     set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 380   endif(LIBXML2_FOUND)
 381 endif(GMX_XML)
 382
 383 option(GMX_GSL "Add support for gsl" OFF)
 384 if (GMX_GSL)
 385   find_package(gsl)
 386   set(PKG_GSL "")
 387   if(GSL_FOUND)
 388     include_directories(${GSL_INCLUDE_DIR})
 389     set(PKG_GSL gsl)
 390     set(HAVE_LIBGSL 1)
 391   endif(GSL_FOUND)
 392 endif (GMX_GSL)
 393
 394 option(GMX_X11 "Use X window system" OFF)
 395 if (GMX_X11)
 396         find_package(X11)
 397         # X11 includes/libraries are only set in the ngmx subdirectory!
 398         if(X11_FOUND)
 399         set(HAVE_X11 1)
 400         endif(X11_FOUND)
 401 endif(GMX_X11)
 402
 403 if(GMX_THREAD_MPI)
 404     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_THREAD_MPI")
 405     include(ThreadMPI)
 406     set(THREAD_MPI_LIB thread_mpi)
 407     set(GMX_MPI 1)
 408     string(TOUPPER ${GMX_FFT_LIBRARY} ${GMX_FFT_LIBRARY})
 409 endif(GMX_THREAD_MPI)
 410
 411 if(GMX_OPENMM)
 412     set(CUDA_BUILD_EMULATION OFF)
 413     find_package(CUDA 3.1 REQUIRED)
 414     add_definitions(-DGMX_OPENMM)
 415     if(CMAKE_BUILD_TYPE STREQUAL "DEBUG")
 416         set(CUDA_VERBOSE_BUILD ON)
 417     endif()
 418     find_package(OpenMM)
 419 endif(GMX_OPENMM)
 420
 421 if(GMX_OPENMP)
 422     find_package(OpenMP REQUIRED)
 423     set(GROMACS_C_FLAGS "${OpenMP_C_FLAGS} ${GROMACS_C_FLAGS}")
 424     set(GROMACS_CXX_FLAGS "${OpenMP_CXX_FLAGS} ${GROMACS_CXX_FLAGS}")
 425     add_definitions(-DGMX_OPENMP)
 426 endif()
 427
 428 if(APPLE)
 429    find_library(ACCELERATE_FRAMEWORK Accelerate)
 430    list(APPEND GMX_EXTRA_LIBRARIES ${ACCELERATE_FRAMEWORK})
 431 endif(APPLE)
 432
 433 if(CYGWIN)
 434     set(GMX_CYGWIN 1)
 435 endif(CYGWIN)
 436
 437 if(WIN32 AND NOT CYGWIN)
 438     set(GMX_NATIVE_WINDOWS 1)
 439 endif()
 440
 441 # only bother with finding git and using version.h if the source is a git repo
 442 if(EXISTS "${CMAKE_SOURCE_DIR}/.git")
 443     if(USE_VERSION_H)
 444         # We need at least git v1.5.3 be able to parse git's date output. If not
 445         # found or the version is too small, we can't generate version information.
 446         find_package(Git)
 447
 448         # Find out the git version
 449         if(GIT_FOUND AND NOT GIT_VERSION)
 450           execute_process(COMMAND ${GIT_EXECUTABLE} "--version"
 451             OUTPUT_VARIABLE _exec_out
 452             OUTPUT_STRIP_TRAILING_WHITESPACE)
 453           string(REGEX REPLACE "git version (.*)" "\\1" GIT_VERSION ${_exec_out})
 454           set(GIT_VERSION ${GIT_VERSION} CACHE STRING "Git version")
 455           mark_as_advanced(GIT_VERSION)
 456         endif()
 457
 458         if(NOT GIT_FOUND OR GIT_VERSION VERSION_LESS "1.5.3")
 459           message("No compatible git version found, won't be able to generate proper development version information.")
 460           set(USE_VERSION_H OFF)
 461         endif()
 462     endif()
 463 else()
 464     set(USE_VERSION_H OFF)
 465 endif()
 466
 467 option(GMX_INTERNAL_BOOST "Use minimal internal version of boost" OFF)
 468 if ( NOT GMX_INTERNAL_BOOST )
 469   find_package( Boost 1.36.0 )
 470 else ( NOT GMX_INTERNAL_BOOST )
 471   set (Boost_FOUND FALSE)
 472 endif( NOT GMX_INTERNAL_BOOST )
 473
 474 if(Boost_FOUND)
 475   include_directories(${Boost_INCLUDE_DIRS})
 476 else()
 477   message("Boost >= 1.36 not found. Using minimal internal version. Not recommended if GROMACS is used as library!")
 478   include_directories(${CMAKE_SOURCE_DIR}/src/external/boost)
 479   add_definitions( -DBOOST_NO_TYPEID )  #TYPEID not supported for minimal internal version (would add significant more code)
 480   # TODO: Propagate the above settings to the installed CMakeFiles.txt template
 481   # (from share/template/)
 482   # TODO: Reorder stuff such that INCL_INSTALL_DIR could be used here
 483   set(PKG_CFLAGS "${PKG_CFLAGS} -DBOOST_NO_TYPEID -I${CMAKE_INSTALL_PREFIX}/include/gromacs/external/boost")
 484   install(DIRECTORY ${CMAKE_SOURCE_DIR}/src/external/boost/boost
 485           DESTINATION ${CMAKE_INSTALL_PREFIX}/include/gromacs/external/boost
 486           COMPONENT development)
 487 endif()
 488
 489 if (LIBXML2_FOUND)
 490     option(GMX_BUILD_UNITTESTS "Build unit tests with BUILD_TESTING (uses Google C++ Testing and Mocking Frameworks, requires libxml2)" ON)
 491 else (LIBXML2_FOUND)
 492     set(GMX_BUILD_UNITTESTS OFF)
 493 endif (LIBXML2_FOUND)
 494 mark_as_advanced(GMX_BUILD_UNITTESTS)
 495 set(MEMORYCHECK_SUPPRESSIONS_FILE ${CMAKE_SOURCE_DIR}/cmake/legacy_and_external.supp)
 496
 497 find_package(Doxygen)
 498
 499 ########################################################################
 500 # Generate development version info for cache
 501 ########################################################################
 502 # set(GEN_VERSION_INFO_INTERNAL "ON")
 503 # include(gmxGenerateVersionString)
 504
 505 ########################################################################
 506 # Our own GROMACS tests
 507 ########################################################################
 508
 509 add_definitions( -DHAVE_CONFIG_H )
 510 include_directories(${CMAKE_SOURCE_DIR}/src)
 511 # Required for config.h, maybe should only be set in src/CMakeLists.txt
 512 include_directories(${CMAKE_BINARY_DIR}/src)
 513 # Required for now to make old code compile
 514 include_directories(${CMAKE_SOURCE_DIR}/src/gromacs/legacyheaders)
 515
 516 include(gmxCheckBuildUserTime)
 517 gmx_check_build_user_time(BUILD_TIME BUILD_USER BUILD_MACHINE)
 518
 519 include(gmxTestFloatFormat)
 520 gmx_test_float_format(GMX_FLOAT_FORMAT_IEEE754
 521                       GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER
 522                       GMX_IEEE754_BIG_ENDIAN_WORD_ORDER)
 523
 524 include(gmxTestLargeFiles)
 525 gmx_test_large_files(GMX_LARGEFILES)
 526 check_function_exists(fseeko     HAVE_FSEEKO)
 527
 528 include(gmxTestSignal)
 529 gmx_test_sigusr1(HAVE_SIGUSR1)
 530
 531 include(gmxTestInline)
 532 gmx_test_inline(INLINE_KEYWORD)
 533
 534 include(gmxTestPipes)
 535 gmx_test_pipes(HAVE_PIPES)
 536
 537 include(gmxTestIsfinite)
 538 gmx_test_isfinite(HAVE_ISFINITE)
 539 gmx_test__isfinite(HAVE__ISFINITE)
 540 gmx_test__finite(HAVE__FINITE)
 541
 542 include(gmxTestCXX11)
 543 gmx_test_cxx11(GMX_CXX11 CXX11_FLAG)
 544 set(GROMACS_CXX_FLAGS "${CXX11_FLAG} ${GROMACS_CXX_FLAGS}")
 545
 546 # turn on SSE if supported with reasonable defaults.
 547 if (${GMX_ACCELERATION} STREQUAL "auto" AND NOT GMX_OPENMM)
 548   if(CMAKE_SYSTEM_PROCESSOR MATCHES "^(i.86|x86|x64|x86_64|AMD64|amd64)" OR CYGWIN)
 549
 550     set(GMX_ACCELERATION "SSE" CACHE STRING "Accelerated kernels. Pick one of: auto, none, SSE, BlueGene, Power6, ia64, altivec, fortran" FORCE)
 551
 552     # Determine the assembler/compiler to use
 553   else()
 554     set(GMX_ACCELERATION "none" CACHE STRING "Accelerated kernels. Pick one of: auto, none, SSE, BlueGene, Power6, ia64, altivec, fortran" FORCE)
 555   endif()
 556 endif (${GMX_ACCELERATION} STREQUAL "auto" AND NOT GMX_OPENMM)
 557
 558 include(gmxTestXDR)
 559 gmx_test_xdr(GMX_SYSTEM_XDR)
 560 if(NOT GMX_SYSTEM_XDR)
 561     set(GMX_INTERNAL_XDR 1)
 562     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_INTERNAL_XDR")
 563 endif(NOT GMX_SYSTEM_XDR)
 564
 565 # Process nonbonded accelerated kernels settings
 566 string(TOUPPER ${GMX_ACCELERATION} ${GMX_ACCELERATION})
 567 if(${GMX_ACCELERATION} STREQUAL "NONE")
 568   # nothing to do
 569 elseif(${GMX_ACCELERATION} STREQUAL "SSE")
 570
 571     if (GMX_64_BIT)
 572       set(GMX_X86_64_ASM ON CACHE BOOL "Add SSE assembly files for x86_64" FORCE)
 573     else (GMX_64_BIT)
 574       set(GMX_IA32_ASM ON CACHE BOOL "Add SSE assembly files for i386" FORCE)
 575     endif (GMX_64_BIT)
 576
 577     if( WIN32 AND NOT CYGWIN )
 578       option(GMX_ASM_USEASM_NASM "Use Nasm for assembly instead of compiler (necessary on windows)" ON)
 579     else()
 580       option(GMX_ASM_USEASM_NASM "Use Nasm for assembly instead of compiler (necessary on windows)" OFF)
 581     endif()
 582         mark_as_advanced(GMX_ASM_USEASM_NASM)
 583
 584     if (NOT GMX_64_BIT)
 585         # for 32-bit compiles, we might need to turn on sse
 586         CHECK_C_COMPILER_FLAG("-msse2" XFLAGS_SSE)
 587         if (XFLAGS_SSE)
 588             set(GROMACS_C_FLAGS "-msse2 ${GROMACS_C_FLAGS}")
 589         endif (XFLAGS_SSE)
 590         CHECK_CXX_COMPILER_FLAG("-msse2" XXFLAGS_SSE)
 591         if (XXFLAGS_SSE)
 592             set(GROMACS_CXX_FLAGS "-msse2 ${GROMACS_CXX_FLAGS}")
 593         endif (XXFLAGS_SSE)
 594     endif (NOT GMX_64_BIT)
 595
 596     if(GMX_IA32_ASM)
 597       if(GMX_DOUBLE)
 598         set(GMX_IA32_SSE2 1)
 599       else()
 600        set(GMX_IA32_SSE 1)
 601       endif()
 602     elseif(GMX_X86_64_ASM)
 603       if(GMX_DOUBLE)
 604        set(GMX_X86_64_SSE2 1)
 605       else()
 606         set(GMX_X86_64_SSE 1)
 607       endif()
 608     endif()
 609
 610 elseif(${GMX_ACCELERATION} STREQUAL "FORTRAN")
 611     set(GMX_FORTRAN 1)
 612     #these are switch on by default sometimes
 613     set(GMX_IA32_ASM 0)
 614     set(GMX_GMX_X86_64_ASM 0)
 615 elseif(${GMX_ACCELERATION} STREQUAL "BLUEGENE")
 616 # GMX_ACCELERATION=BlueGene should be set in the Toolchain-BlueGene?-???.cmake file
 617     message(STATUS "Configuring for BlueGene")
 618     set(GMX_BLUEGENE 1)
 619     if (${CMAKE_SYSTEM_NAME} STREQUAL "BlueGeneL")
 620         set(SHARED_LIBS_DEFAULT OFF CACHE BOOL "Shared libraries not compatible with BlueGene/L, disabled!" FORCE)
 621         set(BUILD_SHARED_LIBS OFF CACHE BOOL "Shared libraries not compatible with BlueGene/L, disabled!" FORCE)
 622     endif (${CMAKE_SYSTEM_NAME} STREQUAL "BlueGeneL")
 623     set(GMX_SOFTWARE_INVSQRT OFF CACHE BOOL "Do not use software reciprocal square root on BlueGene" FORCE)
 624     set(GMX_POWERPC_INVSQRT ON CACHE BOOL "Use hardware reciprocal square root on BlueGene" FORCE)
 625     set(GMX_X11 OFF CACHE BOOL "X11 not compatible with BlueGene, disabled!" FORCE)
 626     set(GMX_THREAD_MPI OFF CACHE BOOL "Thread-MPI not compatible with BlueGene, disabled!" FORCE)
 627     set(GMX_MPI ON CACHE BOOL "Use MPI on BlueGene" FORCE)
 628 elseif(${GMX_ACCELERATION} STREQUAL "POWER6")
 629     set(GMX_POWER6 1)
 630     set(GMX_SOFTWARE_INVSQRT OFF CACHE BOOL "Do not use software reciprocal square root on Power6" FORCE)
 631     set(GMX_POWERPC_INVSQRT ON CACHE BOOL "Use hardware reciprocal square root on Power6" FORCE)
 632 elseif(${GMX_ACCELERATION} STREQUAL "IA64")
 633     set(GMX_IA64_ASM 1)
 634     set(DISABLE_WATERWATER_NLIST 1)
 635     set(DISABLE_WATER_NLIST 1)
 636 elseif(${GMX_ACCELERATION} STREQUAL "ALTIVEC")
 637     check_include_files(altivec.h HAVE_ALTIVEC_H)
 638     if(HAVE_ALTIVEC_H)
 639         set(GMX_PPC_ALTIVEC 1)
 640     endif(HAVE_ALTIVEC_H)
 641 else(${GMX_ACCELERATION} STREQUAL "NONE")
 642     MESSAGE(FATAL_ERROR "Unrecognized option for accelerated kernels: ${GMX_ACCELERATION}. Pick one of auto, none, SSE, Fortran, BlueGene, Power6, ia64, altivec")
 643 endif(${GMX_ACCELERATION} STREQUAL "NONE")
 644
 645 if(GMX_FORTRAN OR GMX_POWER6)
 646     if (GMX_THREAD_MPI)
 647         message(FATAL_ERROR "FORTRAN/POWER6 is incompatible with thread-MPI and only provides a speed-up on certain IBM compilers. Disable FORTRAN (or threads if you really want to use FORTRAN kernels).")
 648     endif(GMX_THREAD_MPI)
 649     enable_language(Fortran)
 650     include(FortranCInterface)
 651     discover_fortran_mangling(prefix isupper suffix extra_under_score found)
 652     if(extra_under_score)
 653         set(extrasuffix "_")
 654     endif(extra_under_score)
 655     if(prefix)
 656       set(prefix "${prefix} ##")
 657     endif(prefix)
 658     if(suffix)
 659       set(suffix "## ${suffix}")
 660       if(extrasuffix)
 661         set(extrasuffix "${suffix}${extrasuffix}")
 662       endif(extrasuffix)
 663     else(suffix)
 664       if(extrasuffix)
 665         # Don't know if this is needed, but it can't hurt
 666         set(extrasuffix "## ${extrasuffix}")
 667       endif(extrasuffix)
 668     endif(suffix)
 669
 670     if(isupper)
 671         set(F77_FUNCDEF   "${prefix} NAME ${suffix}")
 672         # The underscored versions are not currently used.
 673         #set(F77_FUNCDEF_  "${prefix} NAME ${extrasuffix}")
 674     else(isupper)
 675         set(F77_FUNCDEF   "${prefix} name ${suffix}")
 676         #set(F77_FUNCDEF_  "${prefix} name ${extrasuffix}")
 677     endif(isupper)
 678 else(GMX_FORTRAN OR GMX_POWER6)
 679         set(F77_FUNCDEF   "name ## _")
 680         #set(F77_FUNCDEF_  "name ## _")
 681 endif(GMX_FORTRAN OR GMX_POWER6)
 682
 683 # Process QM/MM Settings
 684 string(TOUPPER ${GMX_QMMM_PROGRAM} ${GMX_QMMM_PROGRAM})
 685 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 686     set(GMX_QMMM_GAUSSIAN 1)
 687 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 688     set(GMX_QMMM_MOPAC 1)
 689 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 690     set(GMX_QMMM_GAMESS 1)
 691 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 692     set(GMX_QMMM_ORCA 1)
 693 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 694     # nothing to do
 695 else(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 696     MESSAGE(FATAL_ERROR "Invalid QM/MM program option: ${GMX_QMMM_PROGRAM}. Choose one of: Gaussian, Mopac, Gamess, Orca, None")
 697 endif(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 698
 699 # Process FFT library settings - if not OpenMM build
 700 string(TOUPPER ${GMX_FFT_LIBRARY} ${GMX_FFT_LIBRARY})
 701 set(PKG_FFT "")
 702 set(PKG_FFT_LIBS "")
 703 if(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 704     if(GMX_DOUBLE)
 705         find_package(FFTW 3 COMPONENTS fftw)
 706     else(GMX_DOUBLE)
 707         find_package(FFTW 3 COMPONENTS fftwf)
 708     endif(GMX_DOUBLE)
 709     if(NOT FFTW_FOUND)
 710       MESSAGE(FATAL_ERROR "Cannot find FFTW3 (with correct precision - libfftw3f for single precision GROMACS or libfftw3 for double precision GROMACS). Fix it, choose another FFT library, or use the Gromacs built-in fftpack (slower)!")
 711     endif(NOT FFTW_FOUND)
 712     include_directories(${FFTW_INCLUDE_DIRS})
 713     set(FFT_LIBRARIES ${FFTW_LIBRARIES})
 714     set(PKG_FFT "${FFTW_PKG}")
 715
 716     set(GMX_FFT_FFTW3 1)
 717
 718     if (${GMX_ACCELERATION} STREQUAL "SSE" AND NOT FFTW_HAVE_SSE)
 719       message(WARNING "The fftw library found is compiled without SSE support, which makes it slow. Consider recompiling it or contact your admin")
 720     endif (${GMX_ACCELERATION} STREQUAL "SSE" AND NOT FFTW_HAVE_SSE)
 721
 722 elseif(${GMX_FFT_LIBRARY} STREQUAL "MKL")
 723 #    MESSAGE(STATUS "Using external FFT library - Intel MKL")
 724     find_package(MKL REQUIRED)
 725     include_directories(${MKL_INCLUDE_DIR})
 726     set(FFT_LIBRARIES ${MKL_LIBRARIES})
 727     set(PKG_FFT_LIBS ${MKL_LIBRARIES})
 728
 729     set(GMX_FFT_MKL 1)
 730     set(HAVE_MKL 1)
 731
 732 #elseif(${GMX_FFT_LIBRARY} STREQUAL "ACML")
 733 #    MESSAGE(STATUS "Using external FFT library - AMD core math library")
 734 #    set(GMX_FFT_ACML 1)
 735 elseif(${GMX_FFT_LIBRARY} STREQUAL "FFTPACK")
 736     MESSAGE(STATUS "Using internal FFT library - fftpack")
 737     set(GMX_FFT_FFTPACK 1)
 738 else(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 739     MESSAGE(FATAL_ERROR "Invalid FFT library setting: ${GMX_FFT_LIBRARY}. Choose one of: fftw3, mkl, fftpack")
 740 endif(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 741
 742 # MKL has BLAS/LAPACK routines
 743 if(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 744   set(GMX_EXTERNAL_BLAS TRUE CACHE BOOL "Use external BLAS instead of built-in")
 745   set(GMX_EXTERNAL_LAPACK TRUE CACHE BOOL "Use external LAPACK instead of built-in")
 746 else(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 747   set(GMX_EXTERNAL_BLAS FALSE CACHE BOOL "Use external BLAS instead of built-in")
 748   set(GMX_EXTERNAL_LAPACK FALSE CACHE BOOL "Use external LAPACK instead of built-in")
 749   if(GMX_EXTERNAL_BLAS)
 750     #FindBLAS needs Fortran
 751     enable_language(Fortran)
 752     if (GMX_BLAS_USER)
 753         list(APPEND GMX_EXTRA_LIBRARIES ${GMX_BLAS_USER})
 754     else(GMX_BLAS_USER)
 755         find_package(BLAS REQUIRED)
 756         list(APPEND GMX_EXTRA_LIBRARIES ${BLAS_LIBRARIES})
 757     endif(GMX_BLAS_USER)
 758   endif(GMX_EXTERNAL_BLAS)
 759   if(GMX_EXTERNAL_LAPACK)
 760     #FindLAPACK needs Fortran
 761     enable_language(Fortran)
 762         if (GMX_LAPACK_USER)
 763         list(APPEND GMX_EXTRA_LIBRARIES ${GMX_LAPACK_USER})
 764         else(GMX_LAPACK_USER)
 765         find_package(LAPACK REQUIRED)
 766         list(APPEND GMX_EXTRA_LIBRARIES ${LAPACK_LIBRARIES})
 767     endif(GMX_LAPACK_USER)
 768   endif(GMX_EXTERNAL_LAPACK)
 769 endif(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 770 mark_as_advanced(GMX_EXTERNAL_LAPACK)
 771 mark_as_advanced(GMX_EXTERNAL_BLAS)
 772
 773 set(GMX_USE_PLUGINS OFF CACHE INTERNAL "Whether GROMACS will really try to compile support for VMD plugins")
 774 set(GMX_VMD_PLUGIN_PATH)
 775 mark_as_advanced(GMX_VMD_PLUGIN_PATH)
 776
 777 if(GMX_LOAD_PLUGINS)
 778   if(CYGWIN OR NOT WIN32)
 779     # Native Windows does not have, nor need dlopen
 780     # Note that WIN32 is set with Cygwin, but Cygwin needs dlopen to use plug-ins
 781     include(gmxTestdlopen)
 782     gmx_test_dlopen(HAVE_DLOPEN)
 783   endif()
 784
 785   find_package(VMD)
 786
 787   # Test for unsuitable versions of VMD
 788
 789   if(VMD_FOUND AND NOT GMX_VMD_PLUGIN_PATH)
 790     message(STATUS "Checking for suitable VMD version")
 791     exec_program(${VMD_EXECUTABLE}
 792       ARGS --help
 793       OUTPUT_VARIABLE VMD_HELP
 794       RETURN_VALUE VMD_EXEC_RETURN)
 795
 796     if(VMD_EXEC_RETURN EQUAL 0)
 797       # This is the accepted idiom for subexpression matching, unfortunately
 798       string(REGEX REPLACE ".*VMD for .*, version ([0-9]+\\.[0-9]*\\.?[0-9]*).*" "\\1" VMD_VERSION ${VMD_HELP})
 799       string(REGEX REPLACE ".*VMD for (.*), version .*" "\\1" VMD_ARCH ${VMD_HELP})
 800
 801       if(VMD_VERSION VERSION_LESS "1.8")
 802         MESSAGE(WARNING "Found VMD version ${VMD_VERSION}, but GROMACS needs at least 1.8")
 803         unset(VMD_EXECUTABLE)
 804         set(VMD_FOUND FALSE)
 805       else()
 806         message(STATUS "VMD version ${VMD_VERSION} is suitable")
 807         if(DEFINED ENV{VMDDIR})
 808           # This permits GROMACS to avoid hard-coding a fall-back
 809           # path that it can tell right now would be useless.
 810           set(GMX_VMD_PLUGIN_PATH "$ENV{VMDDIR}/plugins/${VMD_ARCH}/molfile" CACHE PATH "Path to VMD plugins for molfile I/O")
 811         else()
 812           set(GMX_VMD_PLUGIN_PATH "/usr/local/lib/vmd/plugins/*/molfile" CACHE PATH "Path to VMD plugins for molfile I/O")
 813         endif()
 814       endif()
 815
 816       # clean up
 817       unset(VMD_HELP)
 818       unset(VMD_VERSION)
 819       unset(VMD_ARCH)
 820     endif()
 821   endif()
 822
 823   # so, should we use plug-ins?
 824   if((WIN32 AND NOT CYGWIN) OR (HAVE_DLOPEN AND BUILD_SHARED_LIBS))
 825     if (NOT VMD_QUIETLY)
 826       MESSAGE(STATUS "Found the ability to use plug-ins when building shared libaries, so will compile to use plug-ins (e.g. to read VMD-supported file formats).")
 827     endif(NOT VMD_QUIETLY)
 828     set(GMX_USE_PLUGINS ON)
 829     list(APPEND GMX_EXTRA_LIBRARIES ${CMAKE_DL_LIBS}) # magic cross-platform pre-set variable for dlopen library
 830     set(PKG_DL_LIBS "-l${CMAKE_DL_LIBS}")
 831   else()
 832     set(PKG_DL_LIBS)
 833   endif()
 834 endif(GMX_LOAD_PLUGINS)
 835 set(VMD_QUIETLY TRUE CACHE INTERNAL "")
 836
 837 # Math and thread libraries must often come after all others when linking...
 838 if(HAVE_LIBM)
 839     list(APPEND GMX_EXTRA_LIBRARIES m)
 840 endif(HAVE_LIBM)
 841
 842 if(GMX_FAHCORE)
 843   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 844       "Path to swindirect.h")
 845   include_directories(${COREWRAP_INCLUDE_DIR})
 846 endif(GMX_FAHCORE)
 847
 848 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 849 # these are set after everything else
 850 if (NOT DEFINED GROMACS_C_FLAGS_SET)
 851     set(GROMACS_C_FLAGS_SET true CACHE INTERNAL "Whether to reset the C flags"
 852         FORCE)
 853     set(CMAKE_C_FLAGS "${GROMACS_C_FLAGS} ${CMAKE_C_FLAGS}" CACHE STRING
 854         "Flags used by the compiler during all build types" FORCE)
 855     set(CMAKE_CXX_FLAGS "${GROMACS_CXX_FLAGS} ${CMAKE_CXX_FLAGS}" CACHE STRING
 856         "Flags used by the compiler during all build types" FORCE)
 857     set(CMAKE_EXE_LINKER_FLAGS
 858         "${GROMACS_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}"
 859         CACHE STRING "Linker flags" FORCE)
 860 endif (NOT DEFINED GROMACS_C_FLAGS_SET)
 861
 862 ########################################################################
 863 # Specify install locations and which subdirectories to process        #
 864 ########################################################################
 865 if ( DEFINED GMXLIB )
 866     set(LIB_INSTALL_DIR "${CMAKE_INSTALL_PREFIX}/${GMXLIB}")
 867 else()
 868     set(LIB_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/lib)
 869 endif()
 870 set(BIN_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/bin)
 871 set(DATA_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/gromacs)
 872 set(MAN_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/share/man)
 873 set(INCL_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/include)
 874
 875 set(GMXLIBDIR        ${DATA_INSTALL_DIR}/top)
 876
 877 ##################################################################
 878 # Shared library settings - Darwin uses INSTALL_NAME_DIR instead!
 879 ##################################################################
 880 if(NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin")
 881     set(CMAKE_SKIP_BUILD_RPATH  FALSE)
 882     set(CMAKE_BUILD_WITH_INSTALL_RPATH FALSE)
 883     set(CMAKE_INSTALL_RPATH "${LIB_INSTALL_DIR}")
 884     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 885 endif()
 886
 887 add_subdirectory(share)
 888 add_subdirectory(man)
 889 add_subdirectory(src)
 890 add_subdirectory(scripts)
 891
 892 #######################
 893 ## uninstall target
 894 #######################
 895     CONFIGURE_FILE(
 896                    "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 897                    "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
 898                    IMMEDIATE @ONLY)
 899 ###########################
 900 ADD_CUSTOM_TARGET(uninstall
 901                   "${CMAKE_COMMAND}" -P
 902                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
 903 ###########################
 904
 905 ########################################################################
 906 # Doxygen configuration
 907 ########################################################################
 908 if (DOXYGEN_FOUND)
 909     FILE(GLOB NB_KERNEL_DIRS src/gromacs/gmxlib/nonbonded/nb_kernel_*/)
 910     LIST(REMOVE_ITEM NB_KERNEL_DIRS
 911          ${CMAKE_SOURCE_DIR}/src/gromacs/gmxlib/nonbonded/nb_kernel_c)
 912     FOREACH(NB_KERNEL_DIR ${NB_KERNEL_DIRS})
 913         SET(NB_KERNEL_DIRS_TO_IGNORE_IN_DOXYGEN
 914             "${NB_KERNEL_DIRS_TO_IGNORE_IN_DOXYGEN} \\\n                         ${NB_KERNEL_DIR}")
 915     ENDFOREACH(NB_KERNEL_DIR)
 916     CONFIGURE_FILE(${CMAKE_SOURCE_DIR}/Doxyfile.cmakein
 917                    ${CMAKE_BINARY_DIR}/Doxyfile)
 918     CONFIGURE_FILE(${CMAKE_SOURCE_DIR}/Doxyfile-lib.cmakein
 919                    ${CMAKE_BINARY_DIR}/Doxyfile-lib)
 920     CONFIGURE_FILE(${CMAKE_SOURCE_DIR}/Doxyfile-user.cmakein
 921                    ${CMAKE_BINARY_DIR}/Doxyfile-user)
 922     add_custom_target(doc
 923       ${DOXYGEN_EXECUTABLE} ${CMAKE_CURRENT_BINARY_DIR}/Doxyfile
 924       WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}
 925       COMMENT "Generating full documentation with Doxygen" VERBATIM)
 926     add_custom_target(doc-user
 927       ${DOXYGEN_EXECUTABLE} ${CMAKE_CURRENT_BINARY_DIR}/Doxyfile-user
 928       WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}
 929       COMMENT "Generating user documentation with Doxygen" VERBATIM)
 930     add_custom_target(doc-lib
 931       ${DOXYGEN_EXECUTABLE} ${CMAKE_CURRENT_BINARY_DIR}/Doxyfile-lib
 932       WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}
 933       COMMENT "Generating libary documentation with Doxygen" VERBATIM)
 934 endif (DOXYGEN_FOUND)
 935
 936
 937 ########################################################################
 938 # Tests                                                                #
 939 ########################################################################
 940
 941 include(CTest)
 942 mark_as_advanced(BUILD_TESTING)
 943 IF(BUILD_TESTING)
 944     enable_testing()
 945     add_subdirectory(tests)
 946 ENDIF()
 947