CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.6)
   2
   3 project(Gromacs)
   4 include(Dart)
   5 # PROJECT_VERSION should have the following structure:
   6 # VERSION[-dev-SUFFIX] where the VERSION can have any form and the suffix
   7 set(PROJECT_VERSION "4.5-beta4"
   8     CACHE STRING "Gromacs version string")
   9 set(SOVERSION 6)
  10 # It is a bit irritating, but this has to be set separately for now!
  11 SET(CPACK_PACKAGE_VERSION_MAJOR "4")
  12 SET(CPACK_PACKAGE_VERSION_MINOR "5")
  13 SET(CPACK_PACKAGE_VERSION_PATCH "0")
  14
  15
  16 # Cmake modules/macros are in a subdirectory to keep this file cleaner
  17 set(CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake)
  18
  19 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
  20 set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "" FORCE)
  21 endif()
  22
  23 if(NOT CMAKE_BUILD_TYPE)
  24     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel." FORCE)
  25 endif(NOT CMAKE_BUILD_TYPE)
  26
  27 enable_language(C)
  28
  29 set(CPACK_PACKAGE_VERSION ${PROJECT_VERSION})
  30 set(CPACK_PACKAGE_VENDOR "gromacs.org")
  31 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Gromacs - a toolkit for high-performance molecular simulation")
  32 set(CPACK_SET_DESTDIR "ON")
  33 set(CPACK_INCLUDE_TOPLEVEL_DIRECTORY 0)
  34 set(CPACK_RESOURCE_FILE_WELCOME "${CMAKE_SOURCE_DIR}/admin/InstallWelcome.txt")
  35 # Its GPL/LGPL, so they do not have to agree to a license for mere usage, but some installers require this...
  36 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_SOURCE_DIR}/admin/InstallLicense.txt")
  37 set(CPACK_RESOURCE_FILE_README "${CMAKE_SOURCE_DIR}/admin/InstallInfo.txt")
  38
  39 #must come after all cpack settings!
  40 include(CPack)
  41
  42 ########################################################################
  43 # Fix stupid flags on MSVC
  44 ########################################################################
  45 IF(CMAKE_GENERATOR MATCHES "Visual Studio")
  46     STRING(REPLACE /MD /MT CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE})
  47     SET(CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE} CACHE STRING "" FORCE)
  48     STRING(REPLACE /MD /MT CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG})
  49     SET(CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG} CACHE STRING "" FORCE)
  50 ENDIF(CMAKE_GENERATOR MATCHES "Visual Studio")
  51
  52 set(GMX_EXTRA_LIBRARIES)
  53
  54
  55
  56 ######################################################################
  57 # compiler tests
  58 # these need ot be done early (before further tests).
  59 #####################################################################
  60
  61 include(CheckCCompilerFlag)
  62 include(CheckCXXCompilerFlag)
  63
  64 include(gmxCFlags)
  65 gmx_c_flags()
  66
  67 ########################################################################
  68 # User input options                                                   #
  69 ########################################################################
  70 option(GMX_DOUBLE "Use double precision" OFF)
  71 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
  72 option(GMX_THREADS    "Build a parallel (thread-based) version of GROMACS)" ON)
  73 option(GMX_SOFTWARE_INVSQRT "Use GROMACS software 1/sqrt" ON)
  74 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
  75 option(GMX_OPENMM "Accelerated execution on GPUs through the OpenMM library" OFF)
  76 set(GMX_ACCELERATION "auto"
  77     CACHE STRING "Accelerated kernels. Pick one of: none, SSE, BlueGene, Power6, ia64, altivec")
  78
  79 set(GMX_FFT_LIBRARY "fftw3"
  80     CACHE STRING "FFT library choices: fftw3,fftw2,mkl,fftpack[built-in]")
  81 option(GMX_DISABLE_FFTW_MEASURE
  82        "Do not optimize FFTW setups (not needed with SSE)" OFF)
  83 set(GMX_QMMM_PROGRAM "none"
  84     CACHE STRING "QM package choices: none,gaussian,mopac,gamess,orca")
  85 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
  86 option(BUILD_SHARED_LIBS "Enable shared libraries (can be problematic with MPI)" ON)
  87 option(GMX_MPI_IN_PLACE "Enable MPI_IN_PLACE for MPIs that have it defined" ON)
  88 option(GMX_DLOPEN "Compile with dlopen, needed to read VMD supported file formats" ON)
  89 mark_as_advanced(GMX_MPI_IN_PLACE)
  90
  91
  92 option(GMX_IA32_ASM "Add SSE assembly files for IA32" OFF)
  93 option(GMX_X86_64_ASM "Add SSE assembly files for X86_64" OFF)
  94
  95 option(USE_VERSION_H "Generate development version string/information" ON)
  96
  97 option(GMX_DEFAULT_SUFFIX "Use default GROMACS suffixes" ON)
  98 set(GMX_BINARY_SUFFIX "" CACHE STRING "Suffix for GROMACS binaries (default: _d for doubule).")
  99 set(GMX_LIBS_SUFFIX ""
 100   CACHE STRING "Suffix for GROMACS libs (default: _d for double, _mpi for mpi, _mpi_d for mpi and double).")
 101 if (GMX_DEFAULT_SUFFIX)
 102   if (GMX_MPI)
 103     set(GMX_LIBS_SUFFIX "_mpi")
 104   endif(GMX_MPI)
 105   if (GMX_DOUBLE)
 106     set (GMX_BINARY_SUFFIX "_d")
 107     set (GMX_LIBS_SUFFIX "${GMX_LIBS_SUFFIX}_d")
 108   endif(GMX_DOUBLE)
 109 endif(GMX_DEFAULT_SUFFIX)
 110
 111 set(PKG_CFLAGS "")
 112 if(GMX_DOUBLE)
 113   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_DOUBLE")
 114 endif(GMX_DOUBLE)
 115 if(GMX_SOFTWARE_INVSQRT)
 116   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_SOFTWARE_INVSQRT")
 117 endif(GMX_SOFTWARE_INVSQRT)
 118
 119 ########################################################################
 120 #Process MPI settings
 121 ########################################################################
 122 if(GMX_MPI)
 123         MESSAGE(WARNING "
 124             There are known problems with some MPI implementations:
 125                      OpenMPI version < 1.4.1
 126                      MVAPICH2 version <= 1.4.1                               *")
 127     if(GMX_THREADS)
 128         #message(FATAL_ERROR "Thread-based parallelization conflicts with MPI.")
 129         set(GMX_THREADS OFF CACHE BOOL
 130             "Thread-based parallelization conflicts with MPI." FORCE)
 131     endif(GMX_THREADS)
 132     find_package(MPI)
 133     if(MPI_FOUND)
 134         set(GROMACS_C_FLAGS ${GROMACS_FLAGS} ${MPI_COMPILE_FLAGS})
 135         set(GROMACS_LINKER_FLAGS ${GROMACS_LINKER_FLAGS} ${MPI_LINK_FLAGS})
 136
 137         include_directories(${MPI_INCLUDE_PATH})
 138         list(APPEND GMX_EXTRA_LIBRARIES ${MPI_LIBRARIES})
 139         add_definitions( -DMPI ) #for FAHCORE
 140         include(gmxTestMPI_IN_PLACE)
 141         if (GMX_MPI_IN_PLACE)
 142             gmx_test_mpi_in_place(MPI_IN_PLACE_EXISTS)
 143         endif (GMX_MPI_IN_PLACE)
 144     else(MPI_FOUND)
 145         message(FATAL_ERROR "MPI support requested, but no MPI compiler found.")
 146     endif(MPI_FOUND)
 147     include(gmxTestCatamount)
 148     gmx_test_catamount(GMX_CRAY_XT3)
 149     if(GMX_CRAY_XT3)
 150         set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_CRAY_XT3")
 151         set(GMX_NO_SYSTEM 1)
 152         set(GMX_NO_NICE 1)
 153     endif(GMX_CRAY_XT3)
 154     set(GMX_LIB_MPI 1)
 155     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_LIB_MPI")
 156 endif(GMX_MPI)
 157
 158
 159 #######################################################################
 160 # Check for options incompatible with OpenMM build                    #
 161 #######################################################################
 162 if(GMX_OPENMM)
 163     cmake_minimum_required(VERSION 2.6.4)
 164     # we'll use the built-in fft to avoid unnecessary dependencies
 165     message(STATUS "No external FFT libraries needed for the OpenMM build, using fftpack!")
 166     set (GMX_FFT_LIBRARY "fftpack" CACHE STRING
 167                 "No external FFT libraries needed for the OpenMM build, using fftpack!" FORCE)
 168     if(GMX_MPI)
 169         message(FATAL_ERROR "The OpenMM build is not compatible with MPI!")
 170     endif(GMX_MPI)
 171     if(GMX_THREADS)
 172         message(STATUS "Threads not compatible with OpenMM build, disabled!")
 173         set(GMX_THREADS OFF CACHE BOOL
 174                 "Threads not compatible with OpenMM build, disabled!" FORCE)
 175     endif(GMX_THREADS)
 176     if(GMX_SOFTWARE_INVSQRT)
 177         set(GMX_SOFTWARE_INVSQRT OFF FORCE)
 178     endif(GMX_SOFTWARE_INVSQRT)
 179     if(NOT GMX_ACCELERATION MATCHES "^(none|None|NONE)")
 180         message(WARNING "CPU-based acceleration turned off, OpenMM does not support/need any!")
 181         unset(GMX_ACCELERATION CACHE)
 182         set(GMX_ACCELERATION "none" CACHE STRING
 183                 "CPU-based acceleration turned off, OpenMM does not support/need any!" FORCE)
 184     endif()
 185     if(GMX_FAHCORE)
 186         message(FATAL_ERROR "The OpenMM build does not support FAH build!")
 187     endif(GMX_FAHCORE)
 188 endif(GMX_OPENMM)
 189
 190
 191 ########################################################################
 192 # Basic system tests (standard libraries, headers, functions, types)   #
 193 ########################################################################
 194 include(CheckIncludeFiles)
 195 check_include_files(string.h     HAVE_STRING_H)
 196 check_include_files(math.h       HAVE_MATH_H)
 197 check_include_files(limits.h     HAVE_LIMITS_H)
 198 check_include_files(memory.h     HAVE_MEMORY_H)
 199 check_include_files(unistd.h     HAVE_UNISTD_H)
 200 check_include_files(pwd.h        HAVE_PWD_H)
 201 check_include_files(stdint.h     HAVE_STDINT_H)
 202 check_include_files(stdlib.h     HAVE_STDLIB_H)
 203 check_include_files(pthread.h    HAVE_PTHREAD_H)
 204 check_include_files(dirent.h     HAVE_DIRENT_H)
 205 check_include_files(inttypes.h   HAVE_INTTYPES_H)
 206 check_include_files(regex.h      HAVE_REGEX_H)
 207 check_include_files(sys/types.h  HAVE_SYS_TYPES_H)
 208 check_include_files(sys/stat.h   HAVE_SYS_STAT_H)
 209 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 210 check_include_files(rpc/rpc.h    HAVE_RPC_RPC_H)
 211 check_include_files("rpc/rpc.h;rpc/xdr.h"    HAVE_RPC_XDR_H)
 212 # SSE support
 213 check_include_files(xmmintrin.h  HAVE_XMMINTRIN_H)
 214 check_include_files(emmintrin.h  HAVE_EMMINTRIN_H)
 215 check_include_files(pmmintrin.h  HAVE_PMMINTRIN_H)
 216 check_include_files(smmintrin.h  HAVE_SMMINTRIN_H)
 217 check_include_files(io.h                 HAVE_IO_H)
 218
 219
 220 include(CheckFunctionExists)
 221 check_function_exists(strcasecmp        HAVE_STRCASECMP)
 222 check_function_exists(strdup            HAVE_STRDUP)
 223 check_function_exists(vprintf           HAVE_VPRINTF)
 224 check_function_exists(memcmp            HAVE_MEMCMP)
 225 check_function_exists(posix_memalign    HAVE_POSIX_MEMALIGN)
 226 check_function_exists(memalign          HAVE_MEMALIGN)
 227 check_function_exists(_aligned_malloc   HAVE__ALIGNED_MALLOC)
 228 check_function_exists(gettimeofday      HAVE_GETTIMEOFDAY)
 229 check_function_exists(isnan             HAVE_ISNAN)
 230 check_function_exists(_isnan            HAVE__ISNAN)
 231 check_function_exists(isfinite          HAVE_ISFINITE)
 232 check_function_exists(_isfinite         HAVE__ISFINITE)
 233 check_function_exists(fsync             HAVE_FSYNC)
 234 check_function_exists(_fileno           HAVE__FILENO)
 235 check_function_exists(fileno            HAVE_FILENO)
 236 check_function_exists(_commit           HAVE__COMMIT)
 237
 238 include(CheckLibraryExists)
 239 check_library_exists(m sqrt "" HAVE_LIBM)
 240 check_library_exists(m cbrt "" HAVE_CBRT)
 241
 242
 243 include(CheckTypeSize)
 244
 245 check_type_size("bool"          SIZEOF_BOOL) # will also set HAVE_BOOL
 246 check_type_size("int"           SIZEOF_INT)
 247 check_type_size("long int"      SIZEOF_LONG_INT)
 248 check_type_size("long long int" SIZEOF_LONG_LONG_INT)
 249 check_type_size("off_t"         SIZEOF_OFF_T)
 250 check_type_size("void *"        SIZEOF_VOIDP)
 251
 252 if (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 253     set(GMX_64_BIT TRUE)
 254 else (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 255     set(GMX_64_BIT FALSE)
 256 endif (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 257
 258 # Check for some basic types that we *need*, so set these to int if they are not present
 259 check_type_size(uid_t uid_t)
 260 if(NOT uid_t)
 261   set(uid_t int)
 262 else(NOT uid_t)
 263   set(uid_t 0)
 264 endif(NOT uid_t)
 265
 266 check_type_size(gid_t gid_t)
 267 if(NOT gid_t)
 268   set(gid_t 1)
 269 else(NOT gid_t)
 270   set(gid_t 0)
 271 endif(NOT gid_t)
 272
 273 check_type_size(size_t size_t)
 274 if(NOT size_t)
 275   set(size_t int)
 276 else(NOT size_t)
 277   set(size_t 0)
 278 endif(NOT size_t)
 279
 280 check_type_size(off_t off_t)
 281 if(NOT off_t)
 282   set(off_t int)
 283 else(NOT off_t)
 284   set(off_t 0)
 285 endif(NOT off_t)
 286
 287 include(TestBigEndian)
 288 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 289
 290
 291
 292
 293 ########################################################################
 294 # Find external packages                                               #
 295 ########################################################################
 296
 297 find_package(LibXml2)
 298 set(PKG_XML "")
 299 if(LIBXML2_FOUND)
 300     include_directories(${LIBXML2_INCLUDE_DIR})
 301     set(PKG_XML libxml-2.0)
 302     set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 303     set(HAVE_LIBXML2 1)
 304 endif(LIBXML2_FOUND)
 305
 306 find_package(X11)
 307 # X11 includes/libraries are only set in the ngmx subdirectory!
 308 if(X11_FOUND)
 309     set(HAVE_X11 1)
 310 endif(X11_FOUND)
 311
 312 if(GMX_THREADS)
 313     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_THREADS")
 314     include(ThreadMPI)
 315     set(THREAD_MPI_LIB thread_mpi)
 316     set(GMX_MPI 1)
 317     string(TOUPPER ${GMX_FFT_LIBRARY} ${GMX_FFT_LIBRARY})
 318     if(${GMX_FFT_LIBRARY} STREQUAL "FFTW2")
 319         message(FATAL_ERROR "FFTW2 can't be used with threads. Try fftw3 or mkl.")
 320     endif()
 321 endif(GMX_THREADS)
 322
 323 if(GMX_OPENMM)
 324     set(CUDA_BUILD_EMULATION OFF)
 325     find_package(CUDA 3.1 REQUIRED)
 326     add_definitions(-DGMX_OPENMM)
 327     if(CMAKE_BUILD_TYPE STREQUAL "DEBUG")
 328         set(CUDA_VERBOSE_BUILD ON)
 329     endif()
 330     find_package(OpenMM)
 331 endif(GMX_OPENMM)
 332
 333 if(APPLE)
 334    find_library(ACCELERATE_FRAMEWORK Accelerate)
 335    list(APPEND GMX_EXTRA_LIBRARIES ${ACCELERATE_FRAMEWORK})
 336 endif(APPLE)
 337
 338 # only bother with finding git and using version.h if the source is a git repo
 339 if(EXISTS "${CMAKE_SOURCE_DIR}/.git")
 340     if(USE_VERSION_H)
 341         # We need at least git v1.5.1 be able to parse git's date output. If not
 342         # fund or the version is too small, we can't generate version information.
 343         find_package(Git 1.5.1)
 344         # this should at some point become VERSION_LESS
 345         if(NOT Git_FOUND OR Git_VERSION STRLESS "1.5.1")
 346             message("No compatible git version found, won't be able to generate proper development version information.")
 347         endif()
 348     endif()
 349 else()
 350     set(USE_VERSION_H OFF)
 351 endif()
 352
 353 if (GMX_DLOPEN)
 354     list(APPEND GMX_EXTRA_LIBRARIES ${CMAKE_DL_LIBS})
 355 endif (GMX_DLOPEN)
 356
 357 ########################################################################
 358 # Generate development version info for cache
 359 ########################################################################
 360 # set(GEN_VERSION_INFO_INTERNAL "ON")
 361 # include(gmxGenerateVersionString)
 362
 363 ########################################################################
 364 # Our own GROMACS tests
 365 ########################################################################
 366
 367 add_definitions( -DHAVE_CONFIG_H )
 368 include_directories(${CMAKE_BINARY_DIR}/src)
 369 include_directories(${CMAKE_SOURCE_DIR}/include)
 370
 371 include(gmxCheckBuildUserTime)
 372 gmx_check_build_user_time(BUILD_TIME BUILD_USER BUILD_MACHINE)
 373
 374 include(gmxTestFloatFormat)
 375 gmx_test_float_format(GMX_FLOAT_FORMAT_IEEE754
 376                       GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER
 377                       GMX_IEEE754_BIG_ENDIAN_WORD_ORDER)
 378
 379 include(gmxTestLargeFiles)
 380 gmx_test_large_files(GMX_LARGEFILES)
 381 check_function_exists(fseeko     HAVE_FSEEKO)
 382
 383 include(gmxTestSignal)
 384 gmx_test_retsigtype(RETSIGTYPE)
 385 gmx_test_sigusr1(HAVE_SIGUSR1)
 386
 387 include(gmxTestInline)
 388 gmx_test_inline(INLINE_KEYWORD)
 389
 390 include(gmxTestRestrict)
 391 gmx_test_inline(RESTRICT_KEYWORD)
 392
 393 include(gmxTestPipes)
 394 gmx_test_pipes(HAVE_PIPES)
 395
 396 include(gmxTestInlineASM)
 397 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 398 gmx_test_inline_asm_msvc_x86(GMX_X86_MSVC_INLINE_ASM)
 399
 400 # turn on SSE if supported with reasonable defaults.
 401 if (${GMX_ACCELERATION} STREQUAL "auto" AND NOT GMX_OPENMM)
 402   if(CMAKE_SYSTEM_PROCESSOR MATCHES "^(i.86|x86|x64|x86_64|AMD64|amd64)")
 403
 404     set(GMX_ACCELERATION "SSE" CACHE STRING "Accelerated kernels. Pick one of: none, SSE, BlueGene, Power6, ia64, altivec" FORCE)
 405
 406     if (GMX_64_BIT)
 407       set(GMX_X86_64_ASM ON CACHE BOOL "Add SSE assembly files for x86_64" FORCE)
 408     else (GMX_64_BIT)
 409       set(GMX_IA32_ASM ON CACHE BOOL "Add SSE assembly files for i386" FORCE)
 410     endif (GMX_64_BIT)
 411
 412     # Determine the assembler/compiler to use
 413   else()
 414     set(GMX_ACCELERATION "none" CACHE STRING "Accelerated kernels. Pick one of: none, SSE, BlueGene, Power6, ia64, altivec" FORCE)
 415   endif()
 416 endif (${GMX_ACCELERATION} STREQUAL "auto" AND NOT GMX_OPENMM)
 417
 418
 419 include(gmxTestXDR)
 420 gmx_test_xdr(GMX_SYSTEM_XDR)
 421 if(NOT GMX_SYSTEM_XDR)
 422     set(GMX_INTERNAL_XDR 1)
 423     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_INTERNAL_XDR")
 424 endif(NOT GMX_SYSTEM_XDR)
 425
 426 if(GMX_FORTRAN OR GMX_POWER6)
 427     enable_language(Fortran)
 428     include(FortranCInterface)
 429     discover_fortran_mangling(prefix isupper suffix extra_under_score found)
 430     if(extra_under_score)
 431         set(extrasuffix "_")
 432     endif(extra_under_score)
 433
 434     if(isupper)
 435         set(F77_FUNCDEF   "${prefix} ## NAME ## ${suffix}")
 436         set(F77_FUNCDEF_  "${prefix} ## NAME ## ${suffix}${extrasuffix}")
 437     else(isupper)
 438         set(F77_FUNCDEF   "${prefix} ## name ## ${suffix}")
 439         set(F77_FUNCDEF_  "${prefix} ## name ## ${suffix}${extrasuffix}")
 440     endif(isupper)
 441 else(GMX_FORTRAN OR GMX_POWER6)
 442         set(F77_FUNCDEF   "name ## _")
 443         set(F77_FUNCDEF_  "name ## _")
 444 endif(GMX_FORTRAN OR GMX_POWER6)
 445
 446
 447 # Process nonbonded accelerated kernels settings
 448 string(TOUPPER ${GMX_ACCELERATION} ${GMX_ACCELERATION})
 449 if(${GMX_ACCELERATION} STREQUAL "NONE")
 450   # nothing to do
 451 elseif(${GMX_ACCELERATION} STREQUAL "SSE")
 452
 453     if(CMAKE_GENERATOR MATCHES "Visual Studio")
 454       option(GMX_ASM_USEASM-NASM "Use Nasm for assembly instead of compiler (necessary on windows)" ON)
 455     else(CMAKE_GENERATOR MATCHES "Visual Studio")
 456       option(GMX_ASM_USEASM-NASM "Use Nasm for assembly instead of compiler (necessary on windows)" OFF)
 457     endif(CMAKE_GENERATOR MATCHES "Visual Studio")
 458     if (NOT GMX_64_BIT)
 459         # for 32-bit compiles, we might need to turn on sse
 460         CHECK_C_COMPILER_FLAG("-msse2" XFLAGS_SSE)
 461         if (XFLAGS_SSE)
 462             set(GROMACS_C_FLAGS "-msse2 ${GROMACS_C_FLAGS}")
 463         endif (XFLAGS_SSE)
 464         CHECK_CXX_COMPILER_FLAG("-msse2" XXFLAGS_SSE)
 465         if (XXFLAGS_SSE)
 466             set(GROMACS_CXX_FLAGS "-msse2 ${GROMACS_CXX_FLAGS}")
 467         endif (XXFLAGS_SSE)
 468     endif (NOT GMX_64_BIT)
 469
 470     if(GMX_IA32_ASM)
 471       if(GMX_DOUBLE)
 472         set(GMX_IA32_SSE2 1)
 473       else()
 474         set(GMX_IA32_SSE 1)
 475       endif()
 476     elseif(GMX_X86_64_ASM)
 477       if(GMX_DOUBLE)
 478         set(GMX_X86_64_SSE2 1)
 479       else()
 480         set(GMX_X86_64_SSE 1)
 481       endif()
 482     endif()
 483
 484 #    if(HAVE_PMMINTRIN_H)
 485 #        set(GMX_SSE3 1)
 486 #    endif(HAVE_PMMINTRIN_H)
 487 #    if(HAVE_SMMINTRIN_H)
 488 #        set(GMX_SSE4_1 1)
 489 #    endif(HAVE_SMMINTRIN_H)
 490
 491 elseif(${GMX_ACCELERATION} STREQUAL "FORTRAN")
 492     set(GMX_FORTRAN 1)
 493 elseif(${GMX_ACCELERATION} STREQUAL "BLUEGENE")
 494     set(GMX_BLUEGENE 1)
 495 elseif(${GMX_ACCELERATION} STREQUAL "POWER6")
 496     set(GMX_POWER6 1)
 497 elseif(${GMX_ACCELERATION} STREQUAL "IA64")
 498     set(GMX_IA64_ASM 1)
 499     set(DISABLE_WATERWATER_NLIST 1)
 500     set(DISABLE_WATER_NLIST 1)
 501 elseif(${GMX_ACCELERATION} STREQUAL "ALTIVEC")
 502     check_include_files(altivec.h HAVE_ALTIVEC_H)
 503     if(HAVE_ALTIVEC_H)
 504         set(GMX_PPC_ALTIVEC 1)
 505     endif(HAVE_ALTIVEC_H)
 506 else(${GMX_ACCELERATION} STREQUAL "NONE")
 507     MESSAGE(FATAL_ERROR "Unrecognized option for accelerated kernels: ${GMX_ACCELERATION}. Pick one of none, SSE, Fortran, BlueGene, Power6, ia64, altivec")
 508 endif(${GMX_ACCELERATION} STREQUAL "NONE")
 509
 510
 511
 512
 513
 514
 515
 516 # Process QM/MM Settings
 517 string(TOUPPER ${GMX_QMMM_PROGRAM} ${GMX_QMMM_PROGRAM})
 518 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 519     set(GMX_QMMM_GAUSSIAN 1)
 520 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 521     set(GMX_QMMM_MOPAC 1)
 522 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 523     set(GMX_QMMM_GAMESS 1)
 524 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 525     set(GMX_QMMM_ORCA 1)
 526 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 527     # nothing to do
 528 else(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 529     MESSAGE(FATAL_ERROR "Invalid QM/MM program option: ${GMX_QMMM_PROGRAM}. Choose one of: Gaussian, Mopac, Gamess, Orca, None")
 530 endif(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 531
 532 # Process FFT library settings - if not OpenMM build
 533 string(TOUPPER ${GMX_FFT_LIBRARY} ${GMX_FFT_LIBRARY})
 534 set(PKG_FFT "")
 535 set(PKG_FFT_LIBS "")
 536 if(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 537 #    MESSAGE(STATUS "Using external FFT library - fftw3")
 538     if(GMX_DOUBLE)
 539         find_package(FFTW3 REQUIRED)
 540                 include_directories(${FFTW3_INCLUDE_DIR})
 541         set(FFT_LIBRARIES ${FFTW3_LIBRARIES})
 542         set(PKG_FFT "fftw3")
 543     else(GMX_DOUBLE)
 544         find_package(FFTW3F REQUIRED)
 545         include_directories(${FFTW3F_INCLUDE_DIR})
 546         set(FFT_LIBRARIES ${FFTW3F_LIBRARIES})
 547         set(PKG_FFT "fftw3f")
 548     endif(GMX_DOUBLE)
 549
 550     if(NOT FFTW3_FOUND AND NOT FFTW3F_FOUND)
 551         MESSAGE(FATAL_ERROR "Cannot find fftw3 (with correct precision). Fix it, choose another FFT library, or use the Gromacs built-in fftpack (slower)!")
 552     endif(NOT FFTW3_FOUND AND NOT FFTW3F_FOUND)
 553
 554     set(GMX_FFT_FFTW3 1)
 555
 556 elseif(${GMX_FFT_LIBRARY} STREQUAL "FFTW2")
 557 #    MESSAGE(STATUS "Using external FFT library - fftw2")
 558     if(GMX_DOUBLE)
 559         find_package(FFTW2 REQUIRED)
 560     else(GMX_DOUBLE)
 561         find_package(FFTW2F REQUIRED)
 562     endif(GMX_DOUBLE)
 563
 564     if(NOT FFTW2_FOUND)
 565            MESSAGE(FATAL_ERROR "Cannot find fftw2 (with correct precision). Fix it, choose another FFT library, or use the Gromacs built-in fftpack (slower)!")
 566     endif(NOT FFTW2_FOUND)
 567     include_directories(${FFTW2_INCLUDE_DIR})
 568     set(FFT_LIBRARIES ${FFTW2_LIBRARIES})
 569     set(PKG_FFT_LIBS ${FFTW2_LIBRARIES})
 570
 571     if("${FFTW2_LIBRARIES}" MATCHES "dfftw")
 572         set(FFTW2_NAME_DFFTW 1)
 573     elseif("${FFTW2_LIBRARIES}" MATCHES "sfftw")
 574         set(FFTW2_NAME_SFFTW 1)
 575     else("${FFTW2_LIBRARIES}" MATCHES "dfftw")
 576         set(FFTW2_NAME_FFTW 1)
 577     endif("${FFTW2_LIBRARIES}" MATCHES "dfftw")
 578
 579     set(GMX_FFT_FFTW2 1)
 580 elseif(${GMX_FFT_LIBRARY} STREQUAL "MKL")
 581 #    MESSAGE(STATUS "Using external FFT library - Intel MKL")
 582     find_package(MKL REQUIRED)
 583     include_directories(${MKL_INCLUDE_DIR})
 584     set(FFT_LIBRARIES ${MKL_LIBRARIES})
 585     set(PKG_FFT_LIBS ${MKL_LIBRARIES})
 586
 587     set(GMX_FFT_MKL 1)
 588     set(HAVE_MKL 1)
 589
 590 #elseif(${GMX_FFT_LIBRARY} STREQUAL "ACML")
 591 #    MESSAGE(STATUS "Using external FFT library - AMD core math library")
 592 #    set(GMX_FFT_ACML 1)
 593 elseif(${GMX_FFT_LIBRARY} STREQUAL "FFTPACK")
 594     MESSAGE(STATUS "Using internal FFT library - fftpack")
 595     set(GMX_FFT_FFTPACK 1)
 596 else(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 597     MESSAGE(FATAL_ERROR "Invalid FFT library setting: ${GMX_FFT_LIBRARY}. Choose one of: fftw3, fftw2, mkl, acml, fftpack")
 598 endif(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 599
 600 # MKL has BLAS/LAPACK routines
 601 if(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 602   set(GMX_EXTERNAL_BLAS TRUE CACHE BOOL "Use external BLAS instead of built-in")
 603   set(GMX_EXTERNAL_LAPACK TRUE CACHE BOOL "Use external LAPACK instead of built-in")
 604 else(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 605   set(GMX_EXTERNAL_BLAS FALSE CACHE BOOL "Use external LAPACK instead of built-in")
 606   set(GMX_EXTERNAL_LAPACK FALSE CACHE BOOL "Use external LAPACK instead of built-in")
 607 endif(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 608
 609 # Math and thread libraries must often come after all others when linking...
 610 if(HAVE_LIBM)
 611     list(APPEND GMX_EXTRA_LIBRARIES m)
 612 endif(HAVE_LIBM)
 613
 614
 615
 616 if(GMX_FAHCORE)
 617   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 618       "Path to swindirect.h")
 619   include_directories(${COREWRAP_INCLUDE_DIR})
 620 endif(GMX_FAHCORE)
 621
 622 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 623 # these are set after everything else
 624 if (NOT DEFINED GROMACS_C_FLAGS_SET)
 625     set(GROMACS_C_FLAGS_SET true CACHE INTERNAL "Whether to reset the C flags"
 626         FORCE)
 627     set(CMAKE_C_FLAGS "${GROMACS_C_FLAGS} ${CMAKE_C_FLAGS}" CACHE STRING
 628         "Flags used by the compiler during all build types" FORCE)
 629     set(CMAKE_CXX_FLAGS "${GROMACS_CXX_FLAGS} ${CMAKE_CXX_FLAGS}" CACHE STRING
 630         "Flags used by the compiler during all build types" FORCE)
 631     set(CMAKE_EXE_LINKER_FLAGS
 632         "${GROMACS_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}"
 633         CACHE STRING "Linker flags" FORCE)
 634 endif (NOT DEFINED GROMACS_C_FLAGS_SET)
 635
 636 ########################################################################
 637 # Specify install locations and which subdirectories to process        #
 638 ########################################################################
 639 set(LIB_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/lib)
 640 set(BIN_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/bin)
 641 set(DATA_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/gromacs)
 642 set(MAN_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/share/man)
 643 set(INCL_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/include)
 644
 645 set(GMXLIBDIR        ${DATA_INSTALL_DIR}/top)
 646
 647 ##################################################################
 648 # Shared library settings - Darwin uses INSTALL_NAME_DIR instead!
 649 ##################################################################
 650 if(NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin")
 651     set(CMAKE_SKIP_BUILD_RPATH  FALSE)
 652     set(CMAKE_BUILD_WITH_INSTALL_RPATH TRUE)
 653     set(CMAKE_INSTALL_RPATH "${LIB_INSTALL_DIR}")
 654     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 655 endif()
 656
 657 add_subdirectory(share)
 658 add_subdirectory(include)
 659 add_subdirectory(man)
 660 add_subdirectory(src)
 661 add_subdirectory(scripts)
 662
 663 #######################
 664 ## uninstall target
 665 #######################
 666     CONFIGURE_FILE(
 667                    "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 668                    "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
 669                    IMMEDIATE @ONLY)
 670 ###########################
 671 ADD_CUSTOM_TARGET(uninstall
 672                   "${CMAKE_COMMAND}" -P
 673                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
 674 ###########################
 675
 676
 677 ########################################################################
 678 # Tests                                                                #
 679 ########################################################################
 680
 681 enable_testing()
 682 add_test(TestBuildAll make)
 683
 684 add_subdirectory(tests)