CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.8)
   2
   3 project(Gromacs)
   4 include(Dart)
   5 mark_as_advanced(DART_ROOT)
   6
   7 # PROJECT_VERSION should have the following structure:
   8 # VERSION-dev[-SUFFIX] where the VERSION should have the for: vMajor.vMinor.vPatch
   9 #
  10 # The "-dev" suffix is important to keep because it makes possible to distinguish
  11 # between a build from official release and a build from git release branch on a
  12 # machine with no git.
  13 #
  14 # NOTE: when releasing the "-dev" suffix needs to be stripped off!
  15 set(PROJECT_VERSION "4.6-dev")
  16 set(CUSTOM_VERSION_STRING ""
  17     CACHE STRING "Custom version string (if empty, use hard-coded default)")
  18 mark_as_advanced(CUSTOM_VERSION_STRING)
  19 if (CUSTOM_VERSION_STRING)
  20     set(PROJECT_VERSION ${CUSTOM_VERSION_STRING})
  21 endif (CUSTOM_VERSION_STRING)
  22 set(SOVERSION 6)
  23 # It is a bit irritating, but this has to be set separately for now!
  24 SET(CPACK_PACKAGE_VERSION_MAJOR "4")
  25 SET(CPACK_PACKAGE_VERSION_MINOR "6")
  26 #SET(CPACK_PACKAGE_VERSION_PATCH "0")
  27
  28
  29 # Cmake modules/macros are in a subdirectory to keep this file cleaner
  30 set(CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake)
  31
  32 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
  33 set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
  34 endif()
  35
  36 if(NOT CMAKE_BUILD_TYPE)
  37     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel." FORCE)
  38 endif(NOT CMAKE_BUILD_TYPE)
  39
  40 enable_language(C)
  41
  42 set(CPACK_PACKAGE_VERSION ${PROJECT_VERSION})
  43 set(CPACK_PACKAGE_VENDOR "gromacs.org")
  44 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Gromacs - a toolkit for high-performance molecular simulation")
  45 set(CPACK_SET_DESTDIR "ON")
  46 set(CPACK_INCLUDE_TOPLEVEL_DIRECTORY 0)
  47 set(CPACK_RESOURCE_FILE_WELCOME "${CMAKE_SOURCE_DIR}/admin/InstallWelcome.txt")
  48 # Its GPL/LGPL, so they do not have to agree to a license for mere usage, but some installers require this...
  49 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_SOURCE_DIR}/admin/InstallLicense.txt")
  50 set(CPACK_RESOURCE_FILE_README "${CMAKE_SOURCE_DIR}/admin/InstallInfo.txt")
  51
  52 #must come after all cpack settings!
  53 include(CPack)
  54
  55 ########################################################################
  56 # Check and warn if cache generated on a different host is being reused
  57 ########################################################################
  58 if(CMAKE_HOST_UNIX)
  59     execute_process(COMMAND hostname
  60                     OUTPUT_VARIABLE TMP_HOSTNAME
  61                     OUTPUT_STRIP_TRAILING_WHITESPACE)
  62     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}")
  63         message(WARNING "
  64             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
  65             is being reused! This could lead to inconsitencies; therefore, it is
  66             recommended to regenerate the cache!")
  67     endif()
  68     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
  69             "Hostname of the machine where the cache was generated.")
  70 endif()
  71
  72 ########################################################################
  73 # Fix stupid flags on MSVC
  74 ########################################################################
  75 SET(SHARED_LIBS_DEFAULT ON)
  76 IF(CMAKE_GENERATOR MATCHES "Visual Studio")
  77     STRING(REPLACE /MD /MT CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE})
  78     SET(CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE} CACHE STRING "" FORCE)
  79     STRING(REPLACE /MD /MT CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG})
  80     SET(CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG} CACHE STRING "" FORCE)
  81     SET(SHARED_LIBS_DEFAULT OFF)
  82 ENDIF(CMAKE_GENERATOR MATCHES "Visual Studio")
  83
  84 set(GMX_EXTRA_LIBRARIES)
  85
  86
  87
  88 ######################################################################
  89 # compiler tests
  90 # these need ot be done early (before further tests).
  91 #####################################################################
  92
  93 include(CheckCCompilerFlag)
  94 include(CheckCXXCompilerFlag)
  95
  96 include(gmxCFlags)
  97 gmx_c_flags()
  98
  99 ########################################################################
 100 # User input options                                                   #
 101 ########################################################################
 102 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" OFF)
 103 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 104 option(GMX_THREADS    "Build a parallel (thread-based) version of GROMACS (cannot be combined with MPI yet)" ON)
 105 option(GMX_SOFTWARE_INVSQRT "Use GROMACS software 1/sqrt" ON)
 106 mark_as_advanced(GMX_SOFTWARE_INVSQRT)
 107 option(GMX_POWERPC_INVSQRT "Use PowerPC hardware 1/sqrt" OFF)
 108 mark_as_advanced(GMX_POWERPC_INVSQRT)
 109 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 110 mark_as_advanced(GMX_FAHCORE)
 111 option(GMX_OPENMM "Accelerated execution on GPUs through the OpenMM library (rerun cmake after changing to see relevant options)" OFF)
 112 set(GMX_ACCELERATION "auto"
 113     CACHE STRING "Accelerated kernels. Pick one of: auto, none, SSE, BlueGene, Power6, ia64, altivec, fortran")
 114
 115 set(GMX_FFT_LIBRARY "fftw3"
 116     CACHE STRING "FFT library choices: fftw3,fftw2,mkl,fftpack[built-in]")
 117 option(GMX_DISABLE_FFTW_MEASURE
 118        "Do not optimize FFTW setups (not needed with SSE)" OFF)
 119 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 120 set(GMX_QMMM_PROGRAM "none"
 121     CACHE STRING "QM package choices: none,gaussian,mopac,gamess,orca")
 122 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 123 mark_as_advanced(GMX_BROKEN_CALLOC)
 124 option(BUILD_SHARED_LIBS "Enable shared libraries (can be problematic with MPI, Windows)" ${SHARED_LIBS_DEFAULT})
 125 option(GMX_MPI_IN_PLACE "Enable MPI_IN_PLACE for MPIs that have it defined" ON)
 126 mark_as_advanced(GMX_MPI_IN_PLACE)
 127 option(GMX_DLOPEN "Compile with dlopen, needed to read VMD supported file formats" ON)
 128 mark_as_advanced(GMX_DLOPEN)
 129
 130
 131 option(GMX_IA32_ASM "Add SSE assembly files for IA32" OFF)
 132 mark_as_advanced(GMX_IA32_ASM)
 133 option(GMX_X86_64_ASM "Add SSE assembly files for X86_64" OFF)
 134 mark_as_advanced(GMX_X86_64_ASM)
 135
 136 option(USE_VERSION_H "Generate development version string/information" ON)
 137 mark_as_advanced(USE_VERSION_H)
 138
 139 option(GMX_DEFAULT_SUFFIX "Use default suffixes for GROMACS binaries and libs (_d for double, _mpi for MPI; rerun cmake after changing to see relevant options)" ON)
 140
 141 if(UNIX AND NOT APPLE)
 142     option(GMX_PREFER_STATIC_LIBS "When finding libraries prefer \".a\" static archives (NOTE: this is enabled only for UNIX (excluding APPLE) platforms but it might not always work!" OFF)
 143     mark_as_advanced(GMX_PREFER_STATIC_LIBS)
 144 endif()
 145
 146 ########################################################################
 147 # Set up binary and library suffixing
 148 ########################################################################
 149 set(GMX_BINARY_SUFFIX "" CACHE STRING "Suffix for GROMACS binaries (default: _d for double, _mpi for MPI, _mpi_d for MPI and double).")
 150 set(GMX_LIBS_SUFFIX ""
 151   CACHE STRING "Suffix for GROMACS libs (default: _d for double, _mpi for MPI, _mpi_d for MPI and double).")
 152 if (GMX_DEFAULT_SUFFIX)
 153   set(GMX_BINARY_SUFFIX "")
 154   set(GMX_LIBS_SUFFIX "")
 155   if (GMX_MPI)
 156     set(GMX_BINARY_SUFFIX "_mpi")
 157     set(GMX_LIBS_SUFFIX "_mpi")
 158   endif(GMX_MPI)
 159   if (GMX_DOUBLE)
 160     set (GMX_BINARY_SUFFIX "${GMX_BINARY_SUFFIX}_d")
 161     set (GMX_LIBS_SUFFIX "${GMX_LIBS_SUFFIX}_d")
 162   endif(GMX_DOUBLE)
 163   if (GMX_OPENMM)
 164     set (GMX_BINARY_SUFFIX "-gpu")
 165     set (GMX_LIBS_SUFFIX "_gpu")
 166   endif(GMX_OPENMM)
 167   mark_as_advanced(FORCE GMX_BINARY_SUFFIX GMX_LIBS_SUFFIX)
 168   message(STATUS "Using default binary suffix: \"${GMX_BINARY_SUFFIX}\"")
 169   message(STATUS "Using default library suffix: \"${GMX_LIBS_SUFFIX}\"")
 170 else(GMX_DEFAULT_SUFFIX)
 171   mark_as_advanced(CLEAR GMX_BINARY_SUFFIX GMX_LIBS_SUFFIX)
 172   message(STATUS "Using manually set binary suffix: \"${GMX_BINARY_SUFFIX}\"")
 173   message(STATUS "Using manually set library suffix: \"${GMX_LIBS_SUFFIX}\"")
 174 endif(GMX_DEFAULT_SUFFIX)
 175
 176 set(PKG_CFLAGS "")
 177 if(GMX_DOUBLE)
 178     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_DOUBLE")
 179 endif(GMX_DOUBLE)
 180 if(GMX_SOFTWARE_INVSQRT)
 181   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_SOFTWARE_INVSQRT")
 182 endif(GMX_SOFTWARE_INVSQRT)
 183 if(GMX_POWERPC_INVSQRT)
 184   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_POWERPC_INVSQRT")
 185 endif(GMX_POWERPC_INVSQRT)
 186
 187 ########################################################################
 188 #Process MPI settings
 189 ########################################################################
 190 include(CheckCSourceCompiles) # for gmxTestMPI_IN_PLACE
 191 if(GMX_MPI)
 192     if(GMX_THREADS)
 193         #message(FATAL_ERROR "Thread-based parallelization conflicts with MPI.")
 194         set(GMX_THREADS OFF CACHE BOOL
 195             "Thread-based parallelization conflicts with MPI." FORCE)
 196     endif(GMX_THREADS)
 197
 198     # Work-around for Cray MPI
 199     TRY_COMPILE(MPI_FOUND ${CMAKE_BINARY_DIR}
 200       "${CMAKE_SOURCE_DIR}/cmake/TestMPI.c"
 201       COMPILE_DEFINITIONS )
 202     if(NOT MPI_FOUND)
 203       # search for normal MPI installations
 204       find_package(MPI)
 205     endif(NOT MPI_FOUND)
 206
 207     if(MPI_FOUND)
 208         set(GROMACS_C_FLAGS ${GROMACS_FLAGS} ${MPI_COMPILE_FLAGS})
 209         set(GROMACS_LINKER_FLAGS ${GROMACS_LINKER_FLAGS} ${MPI_LINK_FLAGS})
 210
 211         include_directories(${MPI_INCLUDE_PATH})
 212         list(APPEND GMX_EXTRA_LIBRARIES ${MPI_LIBRARIES})
 213         if(GMX_FAHCORE)
 214             add_definitions( -DMPI ) #for FAHCORE
 215         endif(GMX_FAHCORE)
 216         include(gmxTestMPI_IN_PLACE)
 217         if (GMX_MPI_IN_PLACE)
 218             gmx_test_mpi_in_place(MPI_IN_PLACE_EXISTS)
 219         endif (GMX_MPI_IN_PLACE)
 220
 221         # test for unsuitable versions of OpenMPI
 222         exec_program(${MPIEXEC}
 223           ARGS --version
 224           OUTPUT_VARIABLE MPI_TYPE
 225           RETURN_VALUE MPI_EXEC_RETURN)
 226         if(MPI_EXEC_RETURN EQUAL 0)
 227           if(MPI_TYPE MATCHES "Open MPI|OpenRTE")
 228             string(REGEX MATCH "[0-9]+\\.[0-9]*\\.?[0-9]*" MPI_VERSION ${MPI_TYPE})
 229             if(MPI_VERSION VERSION_LESS "1.4.1")
 230               MESSAGE(WARNING "
 231             There are known problems with OpenMPI version < 1.4.1.
 232             Please consider updating your OpenMPI.")
 233             endif(MPI_VERSION VERSION_LESS "1.4.1")
 234             unset(MPI_VERSION)
 235           else(MPI_TYPE MATCHES "Open MPI|OpenRTE")
 236             # This is not OpenMPI, so give the old generic warning message
 237             MESSAGE(WARNING "
 238             There are known problems with some MPI implementations:
 239                      MVAPICH2 version <= 1.4.1
 240             Please consider updating your MPI if applicable.")
 241           endif(MPI_TYPE MATCHES "Open MPI|OpenRTE")
 242           unset(MPI_TYPE)
 243         endif(MPI_EXEC_RETURN EQUAL 0)
 244     else(MPI_FOUND)
 245         message(FATAL_ERROR "MPI support requested, but no MPI compiler found.")
 246     endif(MPI_FOUND)
 247     include(gmxTestCatamount)
 248     gmx_test_catamount(GMX_CRAY_XT3)
 249     if(GMX_CRAY_XT3)
 250         set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_CRAY_XT3")
 251         set(GMX_NO_SYSTEM 1)
 252         set(GMX_NO_NICE 1)
 253     endif(GMX_CRAY_XT3)
 254     set(GMX_LIB_MPI 1)
 255     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_LIB_MPI")
 256 endif(GMX_MPI)
 257
 258
 259 #######################################################################
 260 # Check for options incompatible with OpenMM build                    #
 261 #######################################################################
 262 if(GMX_OPENMM)
 263     cmake_minimum_required(VERSION 2.6.4)
 264     # we'll use the built-in fft to avoid unnecessary dependencies
 265     string(TOUPPER ${GMX_FFT_LIBRARY} GMX_FFT_LIBRARY)
 266     if(NOT ${GMX_FFT_LIBRARY} STREQUAL "FFTPACK")
 267         message(STATUS "No external FFT libraries needed for the OpenMM build, switching to fftpack!")
 268         set(GMX_FFT_LIBRARY "fftpack" CACHE STRING
 269                 "No external FFT libraries needed for the OpenMM build, switching to  fftpack!" FORCE)
 270     endif()
 271     if(GMX_MPI)
 272         message(FATAL_ERROR "The OpenMM build is not compatible with MPI!")
 273     endif(GMX_MPI)
 274     if(GMX_THREADS)
 275         message(STATUS "Threads are  not compatible with OpenMM build, disabled!")
 276         set(GMX_THREADS OFF CACHE BOOL
 277                 "Threads are not compatible with OpenMM build, disabled!" FORCE)
 278     endif(GMX_THREADS)
 279     if(GMX_SOFTWARE_INVSQRT)
 280         set(GMX_SOFTWARE_INVSQRT OFF CACHE STRING
 281                 "The OpenMM build does not need GROMACS software 1/sqrt!" FORCE)
 282     endif(GMX_SOFTWARE_INVSQRT)
 283     string(TOUPPER ${GMX_ACCELERATION} GMX_ACCELERATION)
 284     if(NOT GMX_ACCELERATION STREQUAL "NONE")
 285         message(STATUS "Switching off CPU-based acceleration, the OpenMM build does not support/need any!")
 286         set(GMX_ACCELERATION "none" CACHE STRING
 287                 "Switching off CPU-based acceleration, the OpenMM build does not support/need any!" FORCE)
 288     endif()
 289     if(GMX_FAHCORE)
 290         message(FATAL_ERROR "The OpenMM build does not support FAH build!")
 291     endif(GMX_FAHCORE)
 292     if(GMX_DOUBLE)
 293         message(FATAL_ERROR  "The OpenMM-build does not support double precision calculations!")
 294     endif()
 295     # mark as advanced the unused variables
 296     mark_as_advanced(FORCE GMX_ACCELERATION GMX_MPI GMX_FFT_LIBRARY
 297         GMX_QMMM_PROGRAM GMX_THREADS GMX_DOUBLE)
 298 else(GMX_OPENMM)
 299      mark_as_advanced(CLEAR GMX_ACCELERATION GMX_MPI GMX_FFT_LIBRARY
 300         GMX_QMMM_PROGRAM GMX_THREADS GMX_DOUBLE)
 301 endif(GMX_OPENMM)
 302
 303
 304 ########################################################################
 305 # Basic system tests (standard libraries, headers, functions, types)   #
 306 ########################################################################
 307 include(CheckIncludeFiles)
 308 check_include_files(string.h     HAVE_STRING_H)
 309 check_include_files(math.h       HAVE_MATH_H)
 310 check_include_files(limits.h     HAVE_LIMITS_H)
 311 check_include_files(memory.h     HAVE_MEMORY_H)
 312 check_include_files(unistd.h     HAVE_UNISTD_H)
 313 check_include_files(direct.h     HAVE_DIRECT_H)
 314 check_include_files(pwd.h        HAVE_PWD_H)
 315 check_include_files(stdint.h     HAVE_STDINT_H)
 316 check_include_files(stdlib.h     HAVE_STDLIB_H)
 317 check_include_files(pthread.h    HAVE_PTHREAD_H)
 318 check_include_files(dirent.h     HAVE_DIRENT_H)
 319 check_include_files(inttypes.h   HAVE_INTTYPES_H)
 320 check_include_files(regex.h      HAVE_REGEX_H)
 321 check_include_files(sys/types.h  HAVE_SYS_TYPES_H)
 322 check_include_files(sys/stat.h   HAVE_SYS_STAT_H)
 323 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 324 check_include_files(rpc/rpc.h    HAVE_RPC_RPC_H)
 325 check_include_files("rpc/rpc.h;rpc/xdr.h"    HAVE_RPC_XDR_H)
 326 # SSE support
 327 check_include_files(xmmintrin.h  HAVE_XMMINTRIN_H)
 328 check_include_files(emmintrin.h  HAVE_EMMINTRIN_H)
 329 check_include_files(pmmintrin.h  HAVE_PMMINTRIN_H)
 330 check_include_files(smmintrin.h  HAVE_SMMINTRIN_H)
 331 check_include_files(io.h                 HAVE_IO_H)
 332
 333
 334 include(CheckFunctionExists)
 335 check_function_exists(strcasecmp        HAVE_STRCASECMP)
 336 check_function_exists(strdup            HAVE_STRDUP)
 337 check_function_exists(vprintf           HAVE_VPRINTF)
 338 check_function_exists(memcmp            HAVE_MEMCMP)
 339 check_function_exists(posix_memalign    HAVE_POSIX_MEMALIGN)
 340 check_function_exists(memalign          HAVE_MEMALIGN)
 341 check_function_exists(_aligned_malloc   HAVE__ALIGNED_MALLOC)
 342 check_function_exists(gettimeofday      HAVE_GETTIMEOFDAY)
 343 check_function_exists(isnan             HAVE_ISNAN)
 344 check_function_exists(_isnan            HAVE__ISNAN)
 345 check_function_exists(isfinite          HAVE_ISFINITE)
 346 check_function_exists(_isfinite         HAVE__ISFINITE)
 347 check_function_exists(fsync             HAVE_FSYNC)
 348 check_function_exists(_fileno           HAVE__FILENO)
 349 check_function_exists(fileno            HAVE_FILENO)
 350 check_function_exists(_commit           HAVE__COMMIT)
 351
 352 include(CheckLibraryExists)
 353 check_library_exists(m sqrt "" HAVE_LIBM)
 354 check_library_exists(m cbrt "" HAVE_CBRT)
 355
 356
 357 include(CheckTypeSize)
 358
 359 check_type_size("bool"          SIZEOF_BOOL) # will also set HAVE_BOOL
 360 check_type_size("int"           SIZEOF_INT)
 361 check_type_size("long int"      SIZEOF_LONG_INT)
 362 check_type_size("long long int" SIZEOF_LONG_LONG_INT)
 363 check_type_size("off_t"         SIZEOF_OFF_T)
 364 check_type_size("void *"        SIZEOF_VOIDP)
 365
 366 if (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 367     set(GMX_64_BIT TRUE)
 368 else (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 369     set(GMX_64_BIT FALSE)
 370 endif (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 371
 372 # Check for some basic types that we *need*, so set these to int if they are not present
 373 check_type_size(uid_t uid_t)
 374 if(NOT uid_t)
 375   set(uid_t int)
 376 else(NOT uid_t)
 377   set(uid_t 0)
 378 endif(NOT uid_t)
 379
 380 check_type_size(gid_t gid_t)
 381 if(NOT gid_t)
 382   set(gid_t 1)
 383 else(NOT gid_t)
 384   set(gid_t 0)
 385 endif(NOT gid_t)
 386
 387 check_type_size(size_t size_t)
 388 if(NOT size_t)
 389   set(size_t int)
 390 else(NOT size_t)
 391   set(size_t 0)
 392 endif(NOT size_t)
 393
 394 check_type_size(off_t off_t)
 395 if(NOT off_t)
 396   set(off_t int)
 397 else(NOT off_t)
 398   set(off_t 0)
 399 endif(NOT off_t)
 400
 401 include(TestBigEndian)
 402 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 403
 404
 405
 406
 407 ########################################################################
 408 # Find external packages                                               #
 409 ########################################################################
 410 if(UNIX AND NOT APPLE)
 411     if(GMX_PREFER_STATIC_LIBS)
 412         SET(CMAKE_FIND_LIBRARY_SUFFIXES .a ${CMAKE_FIND_LIBRARY_SUFFIXES})
 413         if(BUILD_SHARED_LIBS)
 414             message(WARNING "Static libraries requested, the GROMACS libraries will also be build static (BUILD_SHARED_LIBS=OFF)")
 415             set(BUILD_SHARED_LIBS OFF CACHE BOOL "Enable shared libraries (can be problematic with MPI, Windows)" FORCE)
 416         endif()
 417     endif()
 418 endif()
 419
 420 option(GMX_XML "Use libxml2 to parse xml files" ON)
 421 if (GMX_XML)
 422   find_package(LibXml2)
 423   set(PKG_XML "")
 424   if(LIBXML2_FOUND)
 425     include_directories(${LIBXML2_INCLUDE_DIR})
 426     set(PKG_XML libxml-2.0)
 427     set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 428     set(HAVE_LIBXML2 1)
 429   endif(LIBXML2_FOUND)
 430 endif(GMX_XML)
 431
 432 option(GMX_GSL "Add support for gsl" OFF)
 433 if (GMX_GSL)
 434   find_package(gsl)
 435   set(PKG_GSL "")
 436   if(GSL_FOUND)
 437     include_directories(${GSL_INCLUDE_DIR})
 438     set(PKG_GSL gsl)
 439     set(HAVE_LIBGSL 1)
 440   endif(GSL_FOUND)
 441 endif (GMX_GSL)
 442
 443 option(GMX_X11 "Use X window system" OFF)
 444 if (GMX_X11)
 445         find_package(X11)
 446         # X11 includes/libraries are only set in the ngmx subdirectory!
 447         if(X11_FOUND)
 448         set(HAVE_X11 1)
 449         endif(X11_FOUND)
 450 endif(GMX_X11)
 451
 452 if(GMX_THREADS)
 453     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_THREADS")
 454     include(ThreadMPI)
 455     set(THREAD_MPI_LIB thread_mpi)
 456     set(GMX_MPI 1)
 457     string(TOUPPER ${GMX_FFT_LIBRARY} ${GMX_FFT_LIBRARY})
 458     if(${GMX_FFT_LIBRARY} STREQUAL "FFTW2")
 459         message(FATAL_ERROR "FFTW2 can't be used with threads. Try fftw3 or mkl.")
 460     endif()
 461 endif(GMX_THREADS)
 462
 463 if(GMX_OPENMM)
 464     set(CUDA_BUILD_EMULATION OFF)
 465     find_package(CUDA 3.1 REQUIRED)
 466     add_definitions(-DGMX_OPENMM)
 467     if(CMAKE_BUILD_TYPE STREQUAL "DEBUG")
 468         set(CUDA_VERBOSE_BUILD ON)
 469     endif()
 470     find_package(OpenMM)
 471 endif(GMX_OPENMM)
 472
 473 if(APPLE)
 474    find_library(ACCELERATE_FRAMEWORK Accelerate)
 475    list(APPEND GMX_EXTRA_LIBRARIES ${ACCELERATE_FRAMEWORK})
 476 endif(APPLE)
 477
 478 if(CYGWIN)
 479     set(GMX_CYGWIN 1)
 480 endif(CYGWIN)
 481
 482 # only bother with finding git and using version.h if the source is a git repo
 483 if(EXISTS "${CMAKE_SOURCE_DIR}/.git")
 484     if(USE_VERSION_H)
 485         # We need at least git v1.5.1 be able to parse git's date output. If not
 486         # found or the version is too small, we can't generate version information.
 487         find_package(Git)
 488
 489         # Find out the git version
 490         if(GIT_FOUND AND NOT GIT_VERSION)
 491           execute_process(COMMAND ${GIT_EXECUTABLE} "--version"
 492             OUTPUT_VARIABLE _exec_out
 493             OUTPUT_STRIP_TRAILING_WHITESPACE)
 494           string(REGEX REPLACE "git version (.*)" "\\1" GIT_VERSION ${_exec_out})
 495           set(GIT_VERSION ${GIT_VERSION} CACHE STRING "Git version")
 496           mark_as_advanced(GIT_VERSION)
 497         endif()
 498
 499         if(NOT GIT_FOUND OR GIT_VERSION VERSION_LESS "1.5.1")
 500           message("No compatible git version found, won't be able to generate proper development version information.")
 501           set(USE_VERSION_H OFF)
 502         endif()
 503     endif()
 504 else()
 505     set(USE_VERSION_H OFF)
 506 endif()
 507
 508 if (GMX_DLOPEN)
 509     list(APPEND GMX_EXTRA_LIBRARIES ${CMAKE_DL_LIBS})
 510     set(PKG_DL_LIBS "-l${CMAKE_DL_LIBS}")
 511 else(GMX_DLOPEN)
 512     set(PKG_DL_LIBS)
 513 endif (GMX_DLOPEN)
 514
 515 ########################################################################
 516 # Generate development version info for cache
 517 ########################################################################
 518 # set(GEN_VERSION_INFO_INTERNAL "ON")
 519 # include(gmxGenerateVersionString)
 520
 521 ########################################################################
 522 # Our own GROMACS tests
 523 ########################################################################
 524
 525 add_definitions( -DHAVE_CONFIG_H )
 526 include_directories(${CMAKE_BINARY_DIR}/src)
 527 include_directories(${CMAKE_SOURCE_DIR}/include)
 528
 529 include(gmxCheckBuildUserTime)
 530 gmx_check_build_user_time(BUILD_TIME BUILD_USER BUILD_MACHINE)
 531
 532 include(gmxTestFloatFormat)
 533 gmx_test_float_format(GMX_FLOAT_FORMAT_IEEE754
 534                       GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER
 535                       GMX_IEEE754_BIG_ENDIAN_WORD_ORDER)
 536
 537 include(gmxTestLargeFiles)
 538 gmx_test_large_files(GMX_LARGEFILES)
 539 check_function_exists(fseeko     HAVE_FSEEKO)
 540
 541 include(gmxTestSignal)
 542 gmx_test_sigusr1(HAVE_SIGUSR1)
 543
 544 include(gmxTestInline)
 545 gmx_test_inline(INLINE_KEYWORD)
 546
 547 include(gmxTestRestrict)
 548 gmx_test_inline(RESTRICT_KEYWORD)
 549
 550 include(gmxTestPipes)
 551 gmx_test_pipes(HAVE_PIPES)
 552
 553 include(gmxTestInlineASM)
 554 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 555 gmx_test_inline_asm_msvc_x86(GMX_X86_MSVC_INLINE_ASM)
 556
 557 # turn on SSE if supported with reasonable defaults.
 558 if (${GMX_ACCELERATION} STREQUAL "auto" AND NOT GMX_OPENMM)
 559   if(CMAKE_SYSTEM_PROCESSOR MATCHES "^(i.86|x86|x64|x86_64|AMD64|amd64)" OR CYGWIN)
 560
 561     set(GMX_ACCELERATION "SSE" CACHE STRING "Accelerated kernels. Pick one of: auto, none, SSE, BlueGene, Power6, ia64, altivec, fortran" FORCE)
 562
 563     if (GMX_64_BIT)
 564       set(GMX_X86_64_ASM ON CACHE BOOL "Add SSE assembly files for x86_64" FORCE)
 565     else (GMX_64_BIT)
 566       set(GMX_IA32_ASM ON CACHE BOOL "Add SSE assembly files for i386" FORCE)
 567     endif (GMX_64_BIT)
 568
 569     # Determine the assembler/compiler to use
 570   else()
 571     set(GMX_ACCELERATION "none" CACHE STRING "Accelerated kernels. Pick one of: auto, none, SSE, BlueGene, Power6, ia64, altivec, fortran" FORCE)
 572   endif()
 573 endif (${GMX_ACCELERATION} STREQUAL "auto" AND NOT GMX_OPENMM)
 574
 575 include(gmxTestXDR)
 576 gmx_test_xdr(GMX_SYSTEM_XDR)
 577 if(NOT GMX_SYSTEM_XDR)
 578     set(GMX_INTERNAL_XDR 1)
 579     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_INTERNAL_XDR")
 580 endif(NOT GMX_SYSTEM_XDR)
 581
 582 # Process nonbonded accelerated kernels settings
 583 string(TOUPPER ${GMX_ACCELERATION} ${GMX_ACCELERATION})
 584 if(${GMX_ACCELERATION} STREQUAL "NONE")
 585   # nothing to do
 586 elseif(${GMX_ACCELERATION} STREQUAL "SSE")
 587
 588     if(CMAKE_GENERATOR MATCHES "Visual Studio")
 589       option(GMX_ASM_USEASM-NASM "Use Nasm for assembly instead of compiler (necessary on windows)" ON)
 590     else()
 591       option(GMX_ASM_USEASM-NASM "Use Nasm for assembly instead of compiler (necessary on windows)" OFF)
 592     endif()
 593         mark_as_advanced(GMX_ASM_USEASM-NASM)
 594
 595     if (NOT GMX_64_BIT)
 596         # for 32-bit compiles, we might need to turn on sse
 597         CHECK_C_COMPILER_FLAG("-msse2" XFLAGS_SSE)
 598         if (XFLAGS_SSE)
 599             set(GROMACS_C_FLAGS "-msse2 ${GROMACS_C_FLAGS}")
 600         endif (XFLAGS_SSE)
 601         CHECK_CXX_COMPILER_FLAG("-msse2" XXFLAGS_SSE)
 602         if (XXFLAGS_SSE)
 603             set(GROMACS_CXX_FLAGS "-msse2 ${GROMACS_CXX_FLAGS}")
 604         endif (XXFLAGS_SSE)
 605     endif (NOT GMX_64_BIT)
 606
 607     if(GMX_IA32_ASM)
 608       if(GMX_DOUBLE)
 609         set(GMX_IA32_SSE2 1)
 610       else()
 611        set(GMX_IA32_SSE 1)
 612       endif()
 613     elseif(GMX_X86_64_ASM)
 614       if(GMX_DOUBLE)
 615        set(GMX_X86_64_SSE2 1)
 616       else()
 617         set(GMX_X86_64_SSE 1)
 618       endif()
 619     endif()
 620
 621 #    if(HAVE_PMMINTRIN_H)
 622 #        set(GMX_SSE3 1)
 623 #    endif(HAVE_PMMINTRIN_H)
 624 #    if(HAVE_SMMINTRIN_H)
 625 #        set(GMX_SSE4_1 1)
 626 #    endif(HAVE_SMMINTRIN_H)
 627
 628 elseif(${GMX_ACCELERATION} STREQUAL "FORTRAN")
 629     set(GMX_FORTRAN 1)
 630     #these are switch on by default sometimes
 631     set(GMX_IA32_ASM 0)
 632     set(GMX_GMX_X86_64_ASM 0)
 633 elseif(${GMX_ACCELERATION} STREQUAL "BLUEGENE")
 634 # GMX_ACCELERATION=BlueGene should be set in the Toolchain-BlueGene?-???.cmake file
 635     message(STATUS "Configuring for BlueGene")
 636     set(GMX_BLUEGENE 1)
 637     if (${CMAKE_SYSTEM_NAME} STREQUAL "BlueGeneL")
 638         set(SHARED_LIBS_DEFAULT OFF CACHE BOOL "Shared libraries not compatible with BlueGene/L, disabled!" FORCE)
 639         set(BUILD_SHARED_LIBS OFF CACHE BOOL "Shared libraries not compatible with BlueGene/L, disabled!" FORCE)
 640     endif (${CMAKE_SYSTEM_NAME} STREQUAL "BlueGeneL")
 641     set(GMX_SOFTWARE_INVSQRT OFF CACHE BOOL "Do not use software reciprocal square root on BlueGene" FORCE)
 642     set(GMX_POWERPC_INVSQRT ON CACHE BOOL "Use hardware reciprocal square root on BlueGene" FORCE)
 643     set(GMX_X11 OFF CACHE BOOL "X11 not compatible with BlueGene, disabled!" FORCE)
 644     set(GMX_THREADS OFF CACHE BOOL "Threads not compatible with BlueGene, disabled!" FORCE)
 645     set(GMX_MPI ON CACHE BOOL "Use MPI on BlueGene" FORCE)
 646 elseif(${GMX_ACCELERATION} STREQUAL "POWER6")
 647     set(GMX_POWER6 1)
 648     set(GMX_SOFTWARE_INVSQRT OFF CACHE BOOL "Do not use software reciprocal square root on Power6" FORCE)
 649     set(GMX_POWERPC_INVSQRT ON CACHE BOOL "Use hardware reciprocal square root on Power6" FORCE)
 650 elseif(${GMX_ACCELERATION} STREQUAL "IA64")
 651     set(GMX_IA64_ASM 1)
 652     set(DISABLE_WATERWATER_NLIST 1)
 653     set(DISABLE_WATER_NLIST 1)
 654 elseif(${GMX_ACCELERATION} STREQUAL "ALTIVEC")
 655     check_include_files(altivec.h HAVE_ALTIVEC_H)
 656     if(HAVE_ALTIVEC_H)
 657         set(GMX_PPC_ALTIVEC 1)
 658     endif(HAVE_ALTIVEC_H)
 659 else(${GMX_ACCELERATION} STREQUAL "NONE")
 660     MESSAGE(FATAL_ERROR "Unrecognized option for accelerated kernels: ${GMX_ACCELERATION}. Pick one of auto, none, SSE, Fortran, BlueGene, Power6, ia64, altivec")
 661 endif(${GMX_ACCELERATION} STREQUAL "NONE")
 662
 663 if(GMX_FORTRAN OR GMX_POWER6)
 664     if (GMX_THREADS)
 665         message(FATAL_ERROR "FORTRAN/POWER6 is incompatible with threads and only provides a speed-up on certain IBM compilers. Disable FORTRAN (or threads if you really want to use FORTRAN kernels).")
 666     endif(GMX_THREADS)
 667     enable_language(Fortran)
 668     include(FortranCInterface)
 669     discover_fortran_mangling(prefix isupper suffix extra_under_score found)
 670     if(extra_under_score)
 671         set(extrasuffix "_")
 672     endif(extra_under_score)
 673     if(prefix)
 674       set(prefix "${prefix} ##")
 675     endif(prefix)
 676     if(suffix)
 677       set(suffix "## ${suffix}")
 678       if(extrasuffix)
 679         set(extrasuffix "${suffix}${extrasuffix}")
 680       endif(extrasuffix)
 681     else(suffix)
 682       if(extrasuffix)
 683         # Don't know if this is needed, but it can't hurt
 684         set(extrasuffix "## ${extrasuffix}")
 685       endif(extrasuffix)
 686     endif(suffix)
 687
 688     if(isupper)
 689         set(F77_FUNCDEF   "${prefix} NAME ${suffix}")
 690         set(F77_FUNCDEF_  "${prefix} NAME ${extrasuffix}")
 691     else(isupper)
 692         set(F77_FUNCDEF   "${prefix} name ${suffix}")
 693         set(F77_FUNCDEF_  "${prefix} name ${extrasuffix}")
 694     endif(isupper)
 695 else(GMX_FORTRAN OR GMX_POWER6)
 696         set(F77_FUNCDEF   "name ## _")
 697         set(F77_FUNCDEF_  "name ## _")
 698 endif(GMX_FORTRAN OR GMX_POWER6)
 699
 700 # Process QM/MM Settings
 701 string(TOUPPER ${GMX_QMMM_PROGRAM} ${GMX_QMMM_PROGRAM})
 702 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 703     set(GMX_QMMM_GAUSSIAN 1)
 704 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 705     set(GMX_QMMM_MOPAC 1)
 706 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 707     set(GMX_QMMM_GAMESS 1)
 708 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 709     set(GMX_QMMM_ORCA 1)
 710 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 711     # nothing to do
 712 else(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 713     MESSAGE(FATAL_ERROR "Invalid QM/MM program option: ${GMX_QMMM_PROGRAM}. Choose one of: Gaussian, Mopac, Gamess, Orca, None")
 714 endif(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 715
 716 # Process FFT library settings - if not OpenMM build
 717 string(TOUPPER ${GMX_FFT_LIBRARY} ${GMX_FFT_LIBRARY})
 718 set(PKG_FFT "")
 719 set(PKG_FFT_LIBS "")
 720 if(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 721 #    MESSAGE(STATUS "Using external FFT library - fftw3")
 722     if(GMX_DOUBLE)
 723         find_package(FFTW3 REQUIRED)
 724                 include_directories(${FFTW3_INCLUDE_DIR})
 725         set(FFT_LIBRARIES ${FFTW3_LIBRARIES})
 726         set(PKG_FFT "fftw3")
 727     else(GMX_DOUBLE)
 728         find_package(FFTW3F REQUIRED)
 729         include_directories(${FFTW3F_INCLUDE_DIR})
 730         set(FFT_LIBRARIES ${FFTW3F_LIBRARIES})
 731         set(PKG_FFT "fftw3f")
 732     endif(GMX_DOUBLE)
 733
 734     if(NOT FFTW3_FOUND AND NOT FFTW3F_FOUND)
 735         MESSAGE(FATAL_ERROR "Cannot find fftw3 (with correct precision). Fix it, choose another FFT library, or use the Gromacs built-in fftpack (slower)!")
 736     endif(NOT FFTW3_FOUND AND NOT FFTW3F_FOUND)
 737
 738     set(GMX_FFT_FFTW3 1)
 739
 740 elseif(${GMX_FFT_LIBRARY} STREQUAL "FFTW2")
 741 #    MESSAGE(STATUS "Using external FFT library - fftw2")
 742     if(GMX_DOUBLE)
 743         find_package(FFTW2 REQUIRED)
 744     else(GMX_DOUBLE)
 745         find_package(FFTW2F REQUIRED)
 746     endif(GMX_DOUBLE)
 747
 748     if(NOT FFTW2_FOUND)
 749            MESSAGE(FATAL_ERROR "Cannot find fftw2 (with correct precision). Fix it, choose another FFT library, or use the Gromacs built-in fftpack (slower)!")
 750     endif(NOT FFTW2_FOUND)
 751     include_directories(${FFTW2_INCLUDE_DIR})
 752     set(FFT_LIBRARIES ${FFTW2_LIBRARIES})
 753     set(PKG_FFT_LIBS ${FFTW2_LIBRARIES})
 754
 755     if("${FFTW2_LIBRARIES}" MATCHES "dfftw")
 756         set(FFTW2_NAME_DFFTW 1)
 757     elseif("${FFTW2_LIBRARIES}" MATCHES "sfftw")
 758         set(FFTW2_NAME_SFFTW 1)
 759     else("${FFTW2_LIBRARIES}" MATCHES "dfftw")
 760         set(FFTW2_NAME_FFTW 1)
 761     endif("${FFTW2_LIBRARIES}" MATCHES "dfftw")
 762
 763     set(GMX_FFT_FFTW2 1)
 764 elseif(${GMX_FFT_LIBRARY} STREQUAL "MKL")
 765 #    MESSAGE(STATUS "Using external FFT library - Intel MKL")
 766     find_package(MKL REQUIRED)
 767     include_directories(${MKL_INCLUDE_DIR})
 768     set(FFT_LIBRARIES ${MKL_LIBRARIES})
 769     set(PKG_FFT_LIBS ${MKL_LIBRARIES})
 770
 771     set(GMX_FFT_MKL 1)
 772     set(HAVE_MKL 1)
 773
 774 #elseif(${GMX_FFT_LIBRARY} STREQUAL "ACML")
 775 #    MESSAGE(STATUS "Using external FFT library - AMD core math library")
 776 #    set(GMX_FFT_ACML 1)
 777 elseif(${GMX_FFT_LIBRARY} STREQUAL "FFTPACK")
 778     MESSAGE(STATUS "Using internal FFT library - fftpack")
 779     set(GMX_FFT_FFTPACK 1)
 780 else(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 781     MESSAGE(FATAL_ERROR "Invalid FFT library setting: ${GMX_FFT_LIBRARY}. Choose one of: fftw3, fftw2, mkl, acml, fftpack")
 782 endif(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 783
 784 # MKL has BLAS/LAPACK routines
 785 if(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 786   set(GMX_EXTERNAL_BLAS TRUE CACHE BOOL "Use external BLAS instead of built-in")
 787   set(GMX_EXTERNAL_LAPACK TRUE CACHE BOOL "Use external LAPACK instead of built-in")
 788 else(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 789   set(GMX_EXTERNAL_BLAS FALSE CACHE BOOL "Use external BLAS instead of built-in")
 790   set(GMX_EXTERNAL_LAPACK FALSE CACHE BOOL "Use external LAPACK instead of built-in")
 791   if(GMX_EXTERNAL_BLAS)
 792     #FindBLAS needs Fortran
 793     enable_language(Fortran)
 794     if (GMX_BLAS_USER)
 795         list(APPEND GMX_EXTRA_LIBRARIES ${GMX_BLAS_USER})
 796     else(GMX_BLAS_USER)
 797         find_package(BLAS REQUIRED)
 798         list(APPEND GMX_EXTRA_LIBRARIES ${BLAS_LIBRARIES})
 799     endif(GMX_BLAS_USER)
 800   endif(GMX_EXTERNAL_BLAS)
 801   if(GMX_EXTERNAL_LAPACK)
 802     #FindLAPACK needs Fortran
 803     enable_language(Fortran)
 804         if (GMX_LAPACK_USER)
 805         list(APPEND GMX_EXTRA_LIBRARIES ${GMX_LAPACK_USER})
 806         else(GMX_LAPACK_USER)
 807         find_package(LAPACK REQUIRED)
 808         list(APPEND GMX_EXTRA_LIBRARIES ${LAPACK_LIBRARIES})
 809     endif(GMX_LAPACK_USER)
 810   endif(GMX_EXTERNAL_LAPACK)
 811 endif(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 812 mark_as_advanced(GMX_EXTERNAL_LAPACK)
 813 mark_as_advanced(GMX_EXTERNAL_BLAS)
 814
 815 # Math and thread libraries must often come after all others when linking...
 816 if(HAVE_LIBM)
 817     list(APPEND GMX_EXTRA_LIBRARIES m)
 818 endif(HAVE_LIBM)
 819
 820 if(GMX_FAHCORE)
 821   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 822       "Path to swindirect.h")
 823   include_directories(${COREWRAP_INCLUDE_DIR})
 824 endif(GMX_FAHCORE)
 825
 826 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 827 # these are set after everything else
 828 if (NOT DEFINED GROMACS_C_FLAGS_SET)
 829     set(GROMACS_C_FLAGS_SET true CACHE INTERNAL "Whether to reset the C flags"
 830         FORCE)
 831     set(CMAKE_C_FLAGS "${GROMACS_C_FLAGS} ${CMAKE_C_FLAGS}" CACHE STRING
 832         "Flags used by the compiler during all build types" FORCE)
 833     set(CMAKE_CXX_FLAGS "${GROMACS_CXX_FLAGS} ${CMAKE_CXX_FLAGS}" CACHE STRING
 834         "Flags used by the compiler during all build types" FORCE)
 835     set(CMAKE_EXE_LINKER_FLAGS
 836         "${GROMACS_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}"
 837         CACHE STRING "Linker flags" FORCE)
 838 endif (NOT DEFINED GROMACS_C_FLAGS_SET)
 839
 840 ########################################################################
 841 # Specify install locations and which subdirectories to process        #
 842 ########################################################################
 843 if ( DEFINED GMXLIB )
 844     set(LIB_INSTALL_DIR "${CMAKE_INSTALL_PREFIX}/${GMXLIB}")
 845 else()
 846     set(LIB_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/lib)
 847 endif()
 848 set(BIN_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/bin)
 849 set(DATA_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/gromacs)
 850 set(MAN_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/share/man)
 851 set(INCL_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/include)
 852
 853 set(GMXLIBDIR        ${DATA_INSTALL_DIR}/top)
 854
 855 ##################################################################
 856 # Shared library settings - Darwin uses INSTALL_NAME_DIR instead!
 857 ##################################################################
 858 if(NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin")
 859     set(CMAKE_SKIP_BUILD_RPATH  FALSE)
 860     set(CMAKE_BUILD_WITH_INSTALL_RPATH FALSE)
 861     set(CMAKE_INSTALL_RPATH "${LIB_INSTALL_DIR}")
 862     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 863 endif()
 864
 865 add_subdirectory(share)
 866 add_subdirectory(include)
 867 add_subdirectory(man)
 868 add_subdirectory(src)
 869 add_subdirectory(scripts)
 870
 871 #######################
 872 ## uninstall target
 873 #######################
 874     CONFIGURE_FILE(
 875                    "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 876                    "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
 877                    IMMEDIATE @ONLY)
 878 ###########################
 879 ADD_CUSTOM_TARGET(uninstall
 880                   "${CMAKE_COMMAND}" -P
 881                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
 882 ###########################
 883
 884
 885 ########################################################################
 886 # Tests                                                                #
 887 ########################################################################
 888
 889 include(CTest)
 890 mark_as_advanced(BUILD_TESTING)
 891 IF(BUILD_TESTING)
 892         enable_testing()
 893         add_subdirectory(tests)
 894 ENDIF()
 895