2 # This file is part of the GROMACS molecular simulation package.
4 # Copyright (c) 2009,2010,2011,2012,2013 by the GROMACS development team.
5 # Copyright (c) 2014,2015,2016,2017,2018 by the GROMACS development team.
6 # Copyright (c) 2019,2020,2021, by the GROMACS development team, led by
7 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
8 # and including many others, as listed in the AUTHORS file in the
9 # top-level source directory and at http://www.gromacs.org.
11 # GROMACS is free software; you can redistribute it and/or
12 # modify it under the terms of the GNU Lesser General Public License
13 # as published by the Free Software Foundation; either version 2.1
14 # of the License, or (at your option) any later version.
16 # GROMACS is distributed in the hope that it will be useful,
17 # but WITHOUT ANY WARRANTY; without even the implied warranty of
18 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
19 # Lesser General Public License for more details.
21 # You should have received a copy of the GNU Lesser General Public
22 # License along with GROMACS; if not, see
23 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
24 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
26 # If you want to redistribute modifications to GROMACS, please
27 # consider that scientific software is very special. Version
28 # control is crucial - bugs must be traceable. We will be happy to
29 # consider code for inclusion in the official distribution, but
30 # derived work must not be called official GROMACS. Details are found
31 # in the README & COPYING files - if they are missing, get the
32 # official version at http://www.gromacs.org.
34 # To help us fund GROMACS development, we humbly ask that you cite
35 # the research papers on the package. Check out http://www.gromacs.org.
37 cmake_minimum_required(VERSION 3.16.3)
38 cmake_policy(SET CMP0074 NEW) # From CMake 3.12
39 cmake_policy(SET CMP0068 NEW) # From CMake-3.9
41 # CMake modules/macros are in a subdirectory to keep this file cleaner
42 # This needs to be set before project() in order to pick up toolchain files
43 list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake ${CMAKE_CURRENT_SOURCE_DIR}/cmake/Platform)
45 if(CMAKE_SYSTEM_NAME STREQUAL "Darwin")
46 # Providing a default value >=10.14 helps to find modern C++ compatibility,
47 # such as by defaulting to the Clang libc++ instead of libstdc++.
48 set(CMAKE_OSX_DEPLOYMENT_TARGET 10.14 CACHE STRING
49 "OS X deployment target affects default SDK version and compiler flags.")
50 # By default, limit the binary architecture to a single 64-bit build.
51 set(CMAKE_OSX_ARCHITECTURES x86_64 CACHE STRING
52 "OS X architecture affects the compatibility of the (potentially fat) binaries produced."
58 set(CMAKE_CXX_STANDARD 17)
59 set(CMAKE_CXX_STANDARD_REQUIRED ON)
60 set(CMAKE_CXX_EXTENSIONS OFF)
62 include(gmxManageCcache)
64 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
65 set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
66 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
68 find_package(LibStdCpp)
70 # Python is first referenced in gmxVersionInfo, so we perform the search early
71 # to find a suitable installation for all components.
72 include(gmxPythonDiscovery)
73 # Set up common version variables, as well as general information about
74 # the build tree (whether the build is from a source package or from a git
75 # repository). Also declares a few functions that will be used for generating
76 # version info files later.
77 include(gmxBuildTreeInfo)
78 include(gmxVersionInfo)
80 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT AND UNIX)
81 set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
83 if("${CMAKE_INSTALL_PREFIX}" STREQUAL "${CMAKE_BINARY_DIR}")
84 message(FATAL_ERROR "GROMACS cannot be installed into the build tree, choose a different location for CMAKE_INSTALL_PREFIX")
87 include(gmxBuildTypeReference)
88 include(gmxBuildTypeProfile)
89 include(gmxBuildTypeTSAN)
90 include(gmxBuildTypeASAN)
91 include(gmxBuildTypeMSAN)
92 include(gmxBuildTypeUBSAN)
93 include(gmxBuildTypeReleaseWithAssert)
95 if(NOT CMAKE_BUILD_TYPE)
96 set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel Reference RelWithAssert Profile TSAN ASAN MSAN UBSAN." FORCE)
97 # Set the possible values of build type for cmake-gui
98 set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "Debug" "Release"
99 "MinSizeRel" "RelWithDebInfo" "Reference" "RelWithAssert" "Profile" "TSAN" "ASAN" "MSAN" "UBSAN")
101 if(CMAKE_CONFIGURATION_TYPES)
102 # Add appropriate GROMACS-specific build types for the Visual
103 # Studio generator (Debug, Release, MinSizeRel and RelWithDebInfo
104 # are already present by default).
105 list(APPEND CMAKE_CONFIGURATION_TYPES "RelWithAssert" "Reference")
106 list(REMOVE_DUPLICATES CMAKE_CONFIGURATION_TYPES)
107 set(CMAKE_CONFIGURATION_TYPES "${CMAKE_CONFIGURATION_TYPES}" CACHE STRING
108 "List of configuration types"
111 set(build_types_with_explicit_flags RELEASE DEBUG RELWITHDEBINFO RELWITHASSERT MINSIZEREL PROFILE)
113 set_property(GLOBAL PROPERTY FIND_LIBRARY_USE_LIB64_PATHS ON)
115 include(gmxCTestUtilities)
118 include(gmxCPackUtilities)
121 # Variables that accumulate stuff influencing the installed headers
122 set(INSTALLED_HEADER_INCLUDE_DIRS "")
123 set(INSTALLED_HEADER_DEFINITIONS "")
125 ########################################################################
126 # Global non-cache variables for implementing the build system
127 ########################################################################
129 # These variables collect libraries that GROMACS requires for
130 # linking. They should be appended to with list(APPEND ${name}
131 # new-library) calls. They are:
132 # - Libraries that are required for libgromacs (only)
133 set(GMX_EXTRA_LIBRARIES "")
134 # - Libraries that are required for all code in the repository
135 set(GMX_COMMON_LIBRARIES "")
136 # - Libraries that all code linked against libgromacs needs
137 # (i.e., something that is exposed in installed headers).
138 set(GMX_PUBLIC_LIBRARIES "")
140 ########################################################################
141 # Check and warn if cache generated on a different host is being reused
142 ########################################################################
144 execute_process(COMMAND hostname
145 OUTPUT_VARIABLE TMP_HOSTNAME
146 OUTPUT_STRIP_TRAILING_WHITESPACE)
147 # Only check for host name if not running in a CI environment, as the cache might
148 # be reused there between different machines in different stages
149 if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}"
150 AND NOT DEFINED ENV{CI_JOB_ID})
152 The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
153 is being reused! This could lead to inconsistencies; therefore, it is
154 recommended to regenerate the cache!")
156 set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
157 "Hostname of the machine where the cache was generated.")
160 ########################################################################
161 # Detect architecture before setting options so we can alter defaults
162 ########################################################################
163 # Detect the architecture the compiler is targetting, detect
164 # SIMD instructions possibilities on that hardware, suggest SIMD instruction set
165 # to use if none is specified, and populate the cache option for CPU
167 include(gmxDetectTargetArchitecture)
168 gmx_detect_target_architecture()
170 ########################################################################
171 # User input options #
172 ########################################################################
173 include(gmxOptionUtilities)
175 set(CMAKE_PREFIX_PATH "" CACHE STRING "Extra locations to search for external libraries and tools (give directory without lib, bin, or include)")
177 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" OFF)
179 option(GMX_MPI "Build a parallel (message-passing) version of GROMACS" OFF)
180 option(GMX_THREAD_MPI "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" ON)
182 option(GMX_MIMIC "Enable MiMiC QM/MM interface (CPMD is required)" OFF)
184 option(GMX_CP2K "Enable CP2K QM/MM interface (CP2K 8.1 or later is required)" OFF)
186 # We need to enable Fortran, because CP2K will be linked
188 enable_language(Fortran)
191 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
192 mark_as_advanced(GMX_FAHCORE)
194 option(GMX_COOL_QUOTES "Enable GROMACS cool quotes" ON)
195 mark_as_advanced(GMX_COOL_QUOTES)
196 gmx_add_cache_dependency(GMX_COOL_QUOTES BOOL "NOT GMX_FAHCORE" OFF)
198 option(GMX_INSTALL_LEGACY_API "Install legacy headers" OFF)
200 gmx_option_multichoice(
202 "Framework for GPU acceleration"
204 OFF CUDA OpenCL SYCL)
206 gmx_option_multichoice(
208 "SIMD instruction set for CPU kernels and compiler optimization"
210 AUTO None SSE2 SSE4.1 AVX_128_FMA AVX_256 AVX2_256 AVX2_128 AVX_512 AVX_512_KNL ARM_NEON_ASIMD ARM_SVE IBM_VSX Reference)
212 set(GMX_FFT_LIBRARY_DEFAULT "fftw3")
214 gmx_option_multichoice(
217 "${GMX_FFT_LIBRARY_DEFAULT}"
218 fftw3 mkl "fftpack[built-in]")
219 gmx_dependent_option(
221 "Download and build FFTW 3 during the GROMACS build process, rather than fall back on the really slow fftpack."
223 "GMX_FFT_LIBRARY STREQUAL FFTW3")
224 gmx_dependent_option(
225 GMX_DISABLE_FFTW_MEASURE
226 "Do not optimize FFTW setups (not needed with SSE)"
228 "GMX_FFT_LIBRARY STREQUAL FFTW3")
229 mark_as_advanced(GMX_BUILD_OWN_FFTW)
230 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
232 gmx_dependent_cache_variable(GMX_SIMD_REF_FLOAT_WIDTH "Reference SIMD single precision width" STRING "4" "GMX_SIMD STREQUAL REFERENCE")
233 gmx_dependent_cache_variable(GMX_SIMD_REF_DOUBLE_WIDTH "Reference SIMD double precision width" STRING "2" "GMX_SIMD STREQUAL REFERENCE")
235 # This should be moved to a separate NBNXN cmake module when that code is cleaned up and modularized
237 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
238 mark_as_advanced(GMX_BROKEN_CALLOC)
240 option(GMX_OPENMP "Enable OpenMP-based multithreading" ON)
242 option(GMX_USE_TNG "Use the TNG library for trajectory I/O" ON)
244 option(GMX_CYCLE_SUBCOUNTERS "Enable cycle subcounters to get a more detailed cycle timings" OFF)
245 mark_as_advanced(GMX_CYCLE_SUBCOUNTERS)
247 option(GMX_SKIP_DEFAULT_CFLAGS "Don't automatically add suggested/required Compiler flags." OFF)
248 mark_as_advanced(GMX_SKIP_DEFAULT_CFLAGS)
250 option(GMX_BUILD_FOR_COVERAGE
251 "Tune build for better code coverage metrics (e.g., disable asserts)"
253 mark_as_advanced(GMX_BUILD_FOR_COVERAGE)
255 option(GMX_DEVELOPER_BUILD
256 "Enable Developer convenience features: always build unit-tests"
258 mark_as_advanced(GMX_DEVELOPER_BUILD)
260 gmx_set_boolean(GMX_COMPILER_WARNINGS_DEFAULT "NOT SOURCE_IS_SOURCE_DISTRIBUTION")
261 option(GMX_COMPILER_WARNINGS
262 "Enable a default set of compiler warnings"
263 ${GMX_COMPILER_WARNINGS_DEFAULT})
264 mark_as_advanced(GMX_COMPILER_WARNINGS)
265 # Always turn on compiler warnings with a developer build.
266 gmx_add_cache_dependency(GMX_COMPILER_WARNINGS BOOL "NOT GMX_DEVELOPER_BUILD" ON)
268 option(GMX_BUILD_SHARED_EXE
269 "Build exectuables as shared binaries. If not set, this disables rpath and dynamic linker flags in an attempt to build a static binary, but this may require setting up the toolchain properly and making appropriate libraries available."
271 mark_as_advanced(GMX_BUILD_SHARED_EXE)
273 option(GMX_PHYSICAL_VALIDATION
274 "Include physical validation tests in ctest environment. These can then be called using 'make check-phys' or
275 'make check-all'. Warning: Running the physical validation tests takes significantly more time than other tests!"
277 mark_as_advanced(GMX_PHYSICAL_VALIDATION)
279 ######################################################################
280 # Detect OpenMP support
281 ######################################################################
282 # The OpenMP detection _must_ come before tests for other CFLAGS.
283 include(gmxManageOpenMP)
287 ######################################################################
289 # These need to be done early (before further tests).
290 #####################################################################
292 include(gmxTestIntelLLVM)
296 # These variables should be used for CMake-style lists (ie. separated
297 # by semicolons) of additional compiler flags which are not generated
298 # in gmxCFlags nor are SIMD or MPI related.
300 # TODO These variables should be consolidated into
301 # EXTRA_COMPILER_FLAGS so that we we don't perpetrate bugs where
302 # things that work in C compilation (e.g. merging from old branches)
303 # might not also work for C++ compilation.
304 set(EXTRA_C_FLAGS "")
305 set(EXTRA_CXX_FLAGS "")
307 # Run through a number of tests for buggy compilers and other issues
308 include(gmxTestCompilerProblems)
309 gmx_test_compiler_problems()
311 # Implement double-precision option. This is complicated because we
312 # need installed headers to use the precision mode of the build that
313 # produced the library, but cannot use config.h in that case. We also
314 # want such variables to always have a definition, because #if is more
315 # robust than #ifdef. So, we put this value on the compiler command
318 set(GMX_DOUBLE_VALUE 1)
320 set(GMX_DOUBLE_VALUE 0)
322 add_definitions(-DGMX_DOUBLE=${GMX_DOUBLE_VALUE})
323 list(APPEND INSTALLED_HEADER_DEFINITIONS "-DGMX_DOUBLE=${GMX_DOUBLE_VALUE}")
325 option(GMX_IMD "Enable Interactive Molecular Dynamics (IMD) sessions, e.g. with VMD" ON)
326 if(GMX_IMD AND WIN32)
327 list(APPEND GMX_EXTRA_LIBRARIES "wsock32")
332 ########################################################################
333 # Basic system tests (standard libraries, headers, functions, types) #
334 ########################################################################
335 include(CheckIncludeFiles)
336 include(CheckIncludeFileCXX)
337 check_include_files(unistd.h HAVE_UNISTD_H)
338 check_include_files(pwd.h HAVE_PWD_H)
339 check_include_files(dirent.h HAVE_DIRENT_H)
340 check_include_files(time.h HAVE_TIME_H)
341 check_include_files(sys/time.h HAVE_SYS_TIME_H)
342 check_include_files(io.h HAVE_IO_H)
343 check_include_files(sched.h HAVE_SCHED_H)
344 check_include_files(xmmintrin.h HAVE_XMMINTRIN_H)
346 include(CheckCXXSymbolExists)
347 check_cxx_symbol_exists(gettimeofday sys/time.h HAVE_GETTIMEOFDAY)
348 check_cxx_symbol_exists(sysconf unistd.h HAVE_SYSCONF)
349 check_cxx_symbol_exists(nice unistd.h HAVE_NICE)
350 check_cxx_symbol_exists(fsync unistd.h HAVE_FSYNC)
351 check_cxx_symbol_exists(_fileno stdio.h HAVE__FILENO)
352 check_cxx_symbol_exists(fileno stdio.h HAVE_FILENO)
353 check_cxx_symbol_exists(_commit io.h HAVE__COMMIT)
354 check_cxx_symbol_exists(sigaction signal.h HAVE_SIGACTION)
356 # We cannot check for the __builtins as symbols, but check if code compiles
357 check_cxx_source_compiles("int main(){ return __builtin_clz(1);}" HAVE_BUILTIN_CLZ)
358 check_cxx_source_compiles("int main(){ return __builtin_clzll(1);}" HAVE_BUILTIN_CLZLL)
360 check_cxx_source_compiles("#include <intrin.h>\n int main(){unsigned long r;unsigned long i=1;_BitScanReverse(&r,i);return r;}" HAVE_BITSCANREVERSE)
361 check_cxx_source_compiles("#include <intrin.h>\n int main(){unsigned long r;unsigned __int64 i=1;_BitScanReverse64(&r,i);return r;}" HAVE_BITSCANREVERSE64)
362 elseif(CMAKE_CXX_COMPILER_ID MATCHES "XL")
363 check_cxx_source_compiles("int main(){ return __cntlz4(1);}" HAVE_CNTLZ4)
364 check_cxx_source_compiles("int main(){ return __cntlz8(1);}" HAVE_CNTLZ8)
367 include(CheckLibraryExists)
368 find_library(HAVE_LIBM m)
369 mark_as_advanced(HAVE_LIBM)
370 check_library_exists(rt clock_gettime "" HAVE_CLOCK_GETTIME)
371 check_library_exists(m feenableexcept "" HAVE_FEENABLEEXCEPT)
372 check_library_exists(m fedisableexcept "" HAVE_FEDISABLEEXCEPT)
374 include(TestSchedAffinity)
375 test_sched_affinity(HAVE_SCHED_AFFINITY)
377 # Aligned memory allocation. We need to check for both mm_malloc(),
378 # posix_memalign(), memalign(), and on windows also _aligned_malloc()
379 include(gmxTestMMMalloc)
380 gmx_test_mm_malloc(HAVE__MM_MALLOC)
381 check_cxx_symbol_exists(posix_memalign stdlib.h HAVE_POSIX_MEMALIGN)
382 check_cxx_symbol_exists(memalign stdlib.h HAVE_MEMALIGN)
384 # No need to waste time on this test on platforms where it will never be true
385 check_cxx_symbol_exists(_aligned_malloc stdlib.h HAVE__ALIGNED_MALLOC)
388 include(TestBigEndian)
389 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
391 gmx_set_boolean(GMX_USE_NICE "HAVE_UNISTD_H AND HAVE_NICE")
393 ########################################################################
394 #Process MPI settings
395 ########################################################################
396 include(gmxManageMPI)
398 ########################################################################
399 #Process MiMiC settings
400 ########################################################################
401 include(gmxManageMimic)
403 ########################################################################
404 #Process CP2K settings
405 ########################################################################
406 include(gmxManageCP2K)
408 ########################################################################
409 #Process shared/static library settings
410 ########################################################################
411 include(gmxManageSharedLibraries)
414 ########################################################################
415 # Specify install locations
416 ########################################################################
417 # Use GNUInstallDirs to set paths on multiarch systems.
418 include(GNUInstallDirs)
420 set(GMX_INSTALL_DATASUBDIR "gromacs" CACHE STRING "Subdirectory for GROMACS data under CMAKE_INSTALL_DATADIR")
421 mark_as_advanced(GMX_INSTALL_DATASUBDIR)
423 # Internal convenience so we do not have to join two path segments in the code
424 set(GMX_INSTALL_GMXDATADIR ${CMAKE_INSTALL_DATADIR}/${GMX_INSTALL_DATASUBDIR})
426 # If the nesting level wrt. the installation root is changed,
427 # gromacs-config.cmake.cmakein needs to be adapted.
428 set(GMX_INSTALL_CMAKEDIR ${CMAKE_INSTALL_DATAROOTDIR}/cmake)
430 # TODO: Make GMXRC adapt if this is changed
431 set(GMX_INSTALL_PKGCONFIGDIR ${CMAKE_INSTALL_LIBDIR}/pkgconfig)
433 list(APPEND INSTALLED_HEADER_INCLUDE_DIRS ${CMAKE_INSTALL_INCLUDEDIR})
435 # Binary and library suffix options
436 include(gmxManageSuffixes)
439 ########################################################################
440 # Find external packages #
441 ########################################################################
443 # Unconditionally find the package, as it is also required for unit
444 # tests. This exports LIBXML2_FOUND, which we should not use because
445 # it does not tell us that linking will succeed. Instead, we test that
447 #if(DEFINED LIBXML2_LIBRARIES)
448 # set(LibXml2_FIND_QUIETLY TRUE)
450 #find_package(LibXml2)
451 #include(gmxTestLibXml2)
452 #gmx_test_libxml2(HAVE_LIBXML2)
453 #option(GMX_XML "Use libxml2 to parse xml files (currently has no effect)" ${HAVE_LIBXML2})
455 #mark_as_advanced(GMX_XML)
456 # Don't actually do anything, since libxml2 is currently not used by libgromacs
457 #if(GMX_XML AND NOT HAVE_LIBXML2)
458 # message(FATAL_ERROR "libxml2 not found. Set GMX_XML=OFF to compile without XML support")
461 # include_directories(${LIBXML2_INCLUDE_DIR})
462 # set(PKG_XML libxml-2.0)
463 # set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
466 option(GMX_HWLOC "Use hwloc portable hardware locality library" OFF)
469 # Find quietly the second time.
470 if (HWLOC_FIND_QUIETLY_AFTER_FIRST_RUN)
471 set(HWLOC_FIND_QUIETLY TRUE)
473 find_package(HWLOC 1.5)
476 if (HWLOC_LIBRARIES MATCHES ".a$")
477 set(_STATIC_HWLOC TRUE)
480 gmx_check_if_changed(HWLOC_FOUND_CHANGED HWLOC_FOUND)
481 if (_STATIC_HWLOC AND HWLOC_FOUND_CHANGED AND NOT GMX_HWLOC_FORCE)
482 message(STATUS "Static hwloc library found, will not attempt using it as it could lead to link-time errors. To use the detected library, manually set GMX_HWLOC=ON and you will likely have to pass appropriate linker flags too to satisfy the link-time dependencies of your hwloc library. Try \"pkg-config --libs --static hwloc\" for suggestions on what you will need.")
483 set(GMX_USE_HWLOC OFF)
485 set(GMX_USE_HWLOC ON)
489 include_directories(SYSTEM ${HWLOC_INCLUDE_DIRS})
490 list(APPEND GMX_EXTRA_LIBRARIES ${HWLOC_LIBRARIES})
492 elseif(GMX_HWLOC_FORCE)
493 message(FATAL_ERROR "HWLOC package support required, but not found.")
496 if (HWLOC_FOUND AND HWLOC_VERSION VERSION_LESS "2")
497 message(STATUS "Support for hwloc versions 1.x is deprecated")
500 set(HWLOC_FIND_QUIETLY_AFTER_FIRST_RUN TRUE CACHE INTERNAL "Be quiet during future attempts to find HWLOC")
503 option(GMX_EXTERNAL_TINYXML2 "Use external TinyXML-2 instead of compiling the version bundled with GROMACS." OFF)
504 mark_as_advanced(GMX_EXTERNAL_TINYXML2)
505 if(GMX_EXTERNAL_TINYXML2)
506 # Find an external TinyXML-2 library.
507 find_package(TinyXML-2 3.0.0)
508 set(HAVE_TINYXML2 ${TinyXML2_FOUND})
509 if(NOT HAVE_TINYXML2)
510 message(FATAL_ERROR "External TinyXML-2 could not be found, please adjust your search paths")
514 option(GMX_EXTRAE "Add support for tracing using EXTRAE" OFF)
515 mark_as_advanced(GMX_EXTRAE)
520 include_directories(SYSTEM ${EXTRAE_INCLUDE_DIR})
523 message(FATAL_ERROR "EXTRAE library was not found. Please add the correct path to CMAKE_PREFIX_PATH")
527 option(GMX_X11 "Use X window system" OFF)
530 # X11 includes/libraries are only set in the ngmx subdirectory!
533 "X11 include files and/or libraries were not found. "
534 "Set GMX_X11=OFF to compile without X11 support. "
535 "gmx view will not be available.")
537 include_directories(SYSTEM ${X11_INCLUDE_DIR})
541 # Enable core threading facilities
542 tmpi_enable_core("${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include")
544 # enable MPI functions
547 # If atomics are manually disabled a define is needed because atomics.h doesn't depend on config.h
548 if (TMPI_ATOMICS_DISABLED)
549 add_definitions(-DTMPI_ATOMICS_DISABLED)
552 include(gmxManageTNG)
554 include(gmxManageLmfit)
556 include(gmxManageMuparser)
560 string(TOUPPER "${GMX_GPU}" _gmx_gpu_uppercase)
561 if(${_gmx_gpu_uppercase} STREQUAL "CUDA")
562 include(gmxManageCuda)
563 elseif(${_gmx_gpu_uppercase} STREQUAL "OPENCL")
564 message(STATUS "GPU support with OpenCL is deprecated. It is still fully supported (and "
565 "recommended for AMD and Intel GPUs). It may be replaced by different approaches in "
566 "future releases of GROMACS.")
567 include(gmxManageOpenCL)
568 elseif(${_gmx_gpu_uppercase} STREQUAL "SYCL")
569 include(gmxManageSYCL)
572 message(WARNING "To use GPU acceleration efficiently, mdrun requires OpenMP multi-threading, which is currently not enabled.")
575 if (GMX_OPENCL_NB_CLUSTER_SIZE)
576 message(WARNING "GMX_OPENCL_NB_CLUSTER_SIZE is deprecated, use GMX_GPU_NB_CLUSTER_SIZE instead")
578 if (GMX_OPENCL_NB_CLUSTER_SIZE AND GMX_GPU_NB_CLUSTER_SIZE)
579 if (NOT ${GMX_OPENCL_NB_CLUSTER_SIZE} EQUAL ${GMX_GPU_NB_CLUSTER_SIZE})
580 message(FATAL_ERROR "Mismatching values passed to GMX_OPENCL_NB_CLUSTER_SIZE and GMX_GPU_NB_CLUSTER_SIZE; the former is deprecated, use only the latter!")
583 # Only OpenCL and SYCL support changing the default cluster size
584 if (${_gmx_gpu_uppercase} STREQUAL "CUDA")
585 if (GMX_GPU_NB_CLUSTER_SIZE AND NOT "${GMX_GPU_NB_CLUSTER_SIZE}" EQUAL 8)
586 message(FATAL_ERROR "Setting GMX_GPU_NB_CLUSTER_SIZE is not supported in CUDA (the default GMX_GPU_NB_CLUSTER_SIZE=8 is used)")
589 # use the legacy GMX_OPENCL_NB_CLUSTER_SIZE variable if set, otherwise set the defaults
590 if (GMX_OPENCL_NB_CLUSTER_SIZE)
591 set(_gmx_gpu_nb_cluster_size_value ${GMX_OPENCL_NB_CLUSTER_SIZE})
593 # default cluster size is 8 with OpenCL and 4 with SYCL for now
594 if(${_gmx_gpu_uppercase} STREQUAL "OPENCL")
595 set(_gmx_gpu_nb_cluster_size_value 8)
597 if (GMX_SYCL_HIPSYCL AND NOT GMX_HIPSYCL_HAVE_LEVELZERO_TARGET)
598 set(_gmx_gpu_nb_cluster_size_value 8)
600 # Either DPCPP or hipSYCL targeting Intel Level0
601 set(_gmx_gpu_nb_cluster_size_value 4)
605 set(GMX_GPU_NB_CLUSTER_SIZE ${_gmx_gpu_nb_cluster_size_value} CACHE STRING "Cluster size used by the nonbonded kernel. Set to 4 for Intel GPUs.")
606 mark_as_advanced(GMX_GPU_NB_CLUSTER_SIZE)
611 # For build with CUDA and Lib-MPI, check if underlying MPI implementation is CUDA-aware
612 # CUDA-aware MPI allows direct GPU communication without staging data through host
613 if(GMX_GPU_CUDA AND GMX_LIB_MPI)
614 include(gmxManageCudaAwareMPI)
616 set(HAVE_CUDA_AWARE_MPI 0)
624 set(GMX_NATIVE_WINDOWS 1)
625 # This makes windows.h not declare min/max as macros that would break
626 # C++ code using std::min/std::max.
627 add_definitions(-DNOMINMAX)
630 option(GMX_BUILD_UNITTESTS "Build unit tests with BUILD_TESTING" ON)
631 mark_as_advanced(GMX_BUILD_UNITTESTS)
632 gmx_add_cache_dependency(GMX_BUILD_UNITTESTS BOOL BUILD_TESTING OFF)
634 ########################################################################
635 # Our own GROMACS tests
636 ########################################################################
638 include_directories(SYSTEM ${CMAKE_SOURCE_DIR}/src/external)
640 include(gmxTestInlineASM)
641 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
643 include(gmxSetBuildInformation)
644 gmx_set_build_information()
646 # Anything but truly ancient x86 hardware should support rdtscp, so we enable it by default.
647 # The inline assembly calling it is only ever compiled on x86, so defaulting to ON is OK.
648 option(GMX_USE_RDTSCP "Use low-latency RDTSCP instruction for x86 CPU-based timers for mdrun execution; might need to be off when compiling for heterogeneous environments" ON)
649 mark_as_advanced(GMX_USE_RDTSCP)
651 include(gmxTestLargeFiles)
652 gmx_test_large_files(GMX_LARGEFILES)
654 include(gmxTestSignal)
655 gmx_test_sigusr1(HAVE_SIGUSR1)
657 include(gmxTestPipes)
658 gmx_test_pipes(HAVE_PIPES)
661 gmx_test_xdr(GMX_SYSTEM_XDR)
662 # Darwin has system XDR, but it uses a three-argument flavour of
663 # xdrproc_t that it guarantees will still work if you pass the normal
664 # two-argument xdr filters, but gcc 8 warns about the cast necessary
665 # to do that, so it's simpler to just use our own XDR library.
667 # TODO It would be better to craft a cmake test which fails if such
668 # XDR operations cause warnings, and succeeds otherwise, because it is
669 # generally preferable to use system libraries where possible.
670 if(NOT GMX_SYSTEM_XDR OR CMAKE_SYSTEM_NAME STREQUAL "Darwin")
671 set(GMX_INTERNAL_XDR 1)
675 ##################################################
676 # Process SIMD instruction settings
677 ##################################################
678 # This checks what flags to add in order to
679 # support the SIMD instructions we need, it sets
680 # correct defines for the SIMD instructions supported,
681 # and adds advanced options to control accuracy
682 # for SIMD math operations.
683 include(gmxManageSimd)
686 ##################################################
687 # Process FFT library settings
688 ##################################################
689 include(gmxManageFFTLibraries)
692 include(gmxManageLinearAlgebraLibraries)
694 include(gmxManagePluginSupport)
695 gmx_manage_plugin_support()
698 if(NOT GMX_VMD_PLUGIN_PATH)
703 # People might want to customize the default location for the DSSP binary
704 set(GMX_DSSP_PROGRAM_PATH "/usr/local/bin/dssp"
706 "The default location to use for the DSSP binary")
707 mark_as_advanced(GMX_DSSP_PROGRAM_PATH)
709 # Link real-time library for POSIX timers. The check for clock_gettime
710 # confirms the linkability of rt.
711 if(HAVE_TIME_H AND HAVE_UNISTD_H AND HAVE_CLOCK_GETTIME)
712 list(APPEND GMX_EXTRA_LIBRARIES rt)
715 # Math and thread libraries must often come after all others when linking...
717 list(APPEND GMX_PUBLIC_LIBRARIES m)
720 option(GMX_NACL "Configure for Native Client builds" OFF)
722 list(APPEND GMX_EXTRA_LIBRARIES nosys)
723 set(GMX_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -lnosys")
724 # TODO: Is this still necessary with the check for its presence?
728 mark_as_advanced(GMX_NACL)
731 set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
732 "Path to swindirect.h")
733 include_directories(${COREWRAP_INCLUDE_DIR})
736 option(GMX_BUILD_HELP "Build completions (requires that compiled binaries can be executed on build host) and install man pages if built (requires building the 'man' target manually)" OFF)
737 mark_as_advanced(GMX_BUILD_HELP)
738 if (GMX_BUILD_HELP AND SOURCE_IS_SOURCE_DISTRIBUTION AND BUILD_IS_INSOURCE)
740 "Rebuilding shell completions or man pages is not supported for "
741 "in-source builds from a source distribution. "
742 "Set GMX_BUILD_HELP=OFF or do an out-of-source build to proceed.")
745 if (GMX_BUILD_FOR_COVERAGE)
746 # Set flags for coverage build here instead having to do so manually
747 set(CMAKE_C_FLAGS "-g --coverage")
748 set(CMAKE_CXX_FLAGS "-g --coverage")
751 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
752 # these are set after everything else
753 if (NOT GMX_SKIP_DEFAULT_CFLAGS)
754 #TODO(#3672): Use target_link_libraries(... MPI::MPI_CXX) instead of ${MPI_CXX_LINK_FLAGS}
755 set(CMAKE_EXE_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_CXX_LINK_FLAGS} ${CMAKE_EXE_LINKER_FLAGS} ${DISABLE_SYCL_CXX_FLAGS}")
756 set(CMAKE_SHARED_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_CXX_LINK_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS} ${DISABLE_SYCL_CXX_FLAGS}")
758 message("Recommended flags which are not added because GMX_SKIP_DEFAULT_CFLAGS=yes:")
759 message("CMAKE_C_FLAGS: ${SIMD_C_FLAGS};${MPI_COMPILE_FLAGS};${EXTRA_C_FLAGS};${GMXC_CFLAGS}")
760 foreach(build_type ${build_types_with_explicit_flags})
761 message("CMAKE_C_FLAGS_${build_type}: ${GMXC_CFLAGS_${build_type}}")
763 message("CMAKE_CXX_FLAGS: ${SIMD_CXX_FLAGS};${MPI_COMPILE_FLAGS};${EXTRA_CXX_FLAGS};${GMXC_CXXFLAGS}")
764 foreach(build_type ${build_types_with_explicit_flags})
765 message("CMAKE_CXX_FLAGS_${build_type}: ${GMXC_CXXFLAGS_${build_type}}")
767 message("CMAKE_EXE_LINKER_FLAGS: ${FFT_LINKER_FLAGS} ${MPI_CXX_LINK_FLAGS}")
768 message("CMAKE_SHARED_LINKER_FLAGS: ${FFT_LINKER_FLAGS} ${MPI_CXX_LINK_FLAGS}")
770 # Allow `admin` directory to be easily conveyed to nested CMake commands.
771 set(GMX_ADMIN_DIR ${CMAKE_SOURCE_DIR}/admin)
773 ################################################################
774 # Shared library load path settings
775 ################################################################
776 if(NOT GMX_BUILD_SHARED_EXE)
778 set(CMAKE_SKIP_RPATH TRUE)
779 set(CMAKE_EXE_LINK_DYNAMIC_C_FLAGS) # remove -Wl,-Bdynamic
780 set(CMAKE_EXE_LINK_DYNAMIC_CXX_FLAGS)
782 # The build folder always has bin/ and lib/; if we are also going to
783 # install to lib/, then the installation RPATH works also in the build
784 # tree. This makes installation slightly faster (no need to rewrite the
785 # RPATHs), and makes the binaries in the build tree relocatable.
786 if(CMAKE_INSTALL_LIBDIR STREQUAL "lib")
787 set(CMAKE_BUILD_WITH_INSTALL_RPATH TRUE)
788 set(CMAKE_BUILD_WITH_INSTALL_NAME_DIR TRUE)
790 # Set the RPATH as relative to the executable location to make the
791 # binaries relocatable.
792 if(CMAKE_SYSTEM_NAME STREQUAL "Darwin") #Assume OS X >=10.5
793 set(CMAKE_INSTALL_RPATH "@loader_path/../${CMAKE_INSTALL_LIBDIR}")
794 set(CMAKE_INSTALL_NAME_DIR ${CMAKE_INSTALL_RPATH})
796 set(CMAKE_INSTALL_RPATH "\$ORIGIN/../${CMAKE_INSTALL_LIBDIR}")
798 set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
799 set(CMAKE_MACOSX_RPATH 1)
802 #COPYING file: Only necessary for binary distributions.
803 #Simpler to always install.
804 install(FILES COPYING DESTINATION ${GMX_INSTALL_GMXDATADIR} COMPONENT data)
807 include(tests/CheckTarget.cmake)
810 # TODO: Determine control flow and defaults for package installation and testing use cases.
811 # Ref: https://gitlab.com/gromacs/gromacs/-/issues/2896
812 option(GMX_PYTHON_PACKAGE "Configure gmxapi Python package" OFF)
813 mark_as_advanced(GMX_PYTHON_PACKAGE)
815 find_package(ImageMagick QUIET COMPONENTS convert)
816 include(gmxTestImageMagick)
817 GMX_TEST_IMAGEMAGICK(IMAGE_CONVERT_POSSIBLE)
818 # TODO: Resolve circular dependency between docs, gromacs, and python_packaging
819 add_subdirectory(docs)
820 add_subdirectory(share)
821 add_subdirectory(scripts)
822 add_subdirectory(api)
823 add_subdirectory(src)
826 add_subdirectory(tests)
829 if(GMX_PYTHON_PACKAGE)
830 add_subdirectory(python_packaging)
833 gmx_cpack_write_config()
835 #######################
837 #######################
838 CONFIGURE_FILE( "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
839 "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
841 ###########################
842 ADD_CUSTOM_TARGET(uninstall
843 "${CMAKE_COMMAND}" -P
844 "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
845 ###########################
846 set_directory_properties(PROPERTIES
847 ADDITIONAL_MAKE_CLEAN_FILES "install_manifest.txt")