CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.8)
   2 # Keep CMake suitably quiet on Cygwin
   3 set(CMAKE_LEGACY_CYGWIN_WIN32 0) # Remove when CMake >= 2.8.4 is required
   4
   5 # CMake modules/macros are in a subdirectory to keep this file cleaner
   6 # This needs to be set before project() in order to pick up toolchain files
   7 list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake ${CMAKE_CURRENT_SOURCE_DIR}/cmake/Platform)
   8
   9 project(Gromacs)
  10 include(Dart)
  11 mark_as_advanced(DART_ROOT)
  12
  13 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  14 set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  15 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
  16
  17 # PROJECT_VERSION should have the following structure:
  18 # VERSION-dev[-SUFFIX] where the VERSION should have the for: vMajor.vMinor.vPatch
  19 #
  20 # The "-dev" suffix is important to keep because it makes possible to distinguish
  21 # between a build from official release and a build from git release branch on a
  22 # machine with no git.
  23 #
  24 # NOTE: when releasing the "-dev" suffix needs to be stripped off!
  25 set(PROJECT_VERSION "5.0-dev")
  26 # The version number of the regressiontest tarball against which this
  27 # git branch can be tested. Normally, this will be the version of the
  28 # last patch release. Comment the next line out for branches leading
  29 # to a major/minor release.
  30 set(REGRESSIONTEST_VERSION "4.6.2")
  31 set(CUSTOM_VERSION_STRING ""
  32     CACHE STRING "Custom version string (if empty, use hard-coded default)")
  33 mark_as_advanced(CUSTOM_VERSION_STRING)
  34 if (CUSTOM_VERSION_STRING)
  35     set(PROJECT_VERSION ${CUSTOM_VERSION_STRING})
  36 endif (CUSTOM_VERSION_STRING)
  37 set(SOVERSION 8)
  38 # It is a bit irritating, but this has to be set separately for now!
  39 SET(CPACK_PACKAGE_VERSION_MAJOR "5")
  40 SET(CPACK_PACKAGE_VERSION_MINOR "0")
  41 #SET(CPACK_PACKAGE_VERSION_PATCH "0")
  42
  43 # The numerical gromacs version. It is 40600 for 4.6.0.
  44 # The #define GMX_VERSION in gmx_header_config_h is set to this value.
  45 math(EXPR NUM_VERSION
  46     "${CPACK_PACKAGE_VERSION_MAJOR}*10000 + ${CPACK_PACKAGE_VERSION_MINOR}*100")
  47 if(CPACK_PACKAGE_VERSION_PATCH)
  48     math(EXPR NUM_VERSION
  49          "${NUM_VERSION} + ${CPACK_PACKAGE_VERSION_PATCH}")
  50 endif()
  51
  52 # The API version tracks the numerical Gromacs version (for now).
  53 # It is potentially different from the Gromacs version in the future, if
  54 # the programs/libraries diverge from the presumably more stable API.
  55 # The #define GMX_API_VERSION in version.h is set to this value to
  56 # provide backward compatibility of software written against the Gromacs API.
  57 set(API_VERSION ${NUM_VERSION})
  58
  59 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT AND UNIX)
  60     set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
  61 endif()
  62
  63 set(GMX_INSTALL_PREFIX "" CACHE STRING "Prefix gets appended to CMAKE_INSTALL_PREFIX. For cpack it sets the root folder of the archive.")
  64 mark_as_advanced(GMX_INSTALL_PREFIX)
  65
  66 include(gmxBuildTypeReference)
  67
  68 if(NOT CMAKE_BUILD_TYPE)
  69     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel Reference." FORCE)
  70 endif(NOT CMAKE_BUILD_TYPE)
  71
  72 enable_language(C)
  73 enable_language(CXX)
  74
  75 set(CPACK_PACKAGE_VERSION ${PROJECT_VERSION})
  76 set(CPACK_PACKAGE_VENDOR "gromacs.org")
  77 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Gromacs - a toolkit for high-performance molecular simulation")
  78 set(CPACK_RESOURCE_FILE_WELCOME "${CMAKE_SOURCE_DIR}/admin/InstallWelcome.txt")
  79 # Its GPL/LGPL, so they do not have to agree to a license for mere usage, but some installers require this...
  80 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_SOURCE_DIR}/COPYING")
  81 set(CPACK_RESOURCE_FILE_README "${CMAKE_SOURCE_DIR}/admin/InstallInfo.txt")
  82 set(CPACK_SOURCE_IGNORE_FILES "\\\\.isreposource$;\\\\.git/;\\\\.gitignore$")
  83 set(CPACK_PROJECT_CONFIG_FILE "${CMAKE_SOURCE_DIR}/CPackInit.cmake")
  84 SET(CPACK_SOURCE_INSTALLED_DIRECTORIES "${CMAKE_SOURCE_DIR};/;${CMAKE_BINARY_DIR}/man;man")
  85 set(CPACK_PACKAGE_CONTACT "gmx-users@gromacs.org")
  86
  87 #must come after all cpack settings!
  88 include(CPack)
  89
  90 set(SOURCE_IS_GIT_REPOSITORY OFF)
  91 if(EXISTS "${CMAKE_SOURCE_DIR}/.git")
  92     set(SOURCE_IS_GIT_REPOSITORY ON)
  93 endif()
  94
  95 ########################################################################
  96 # Check and warn if cache generated on a different host is being reused
  97 ########################################################################
  98 if(CMAKE_HOST_UNIX)
  99     execute_process(COMMAND hostname
 100                     OUTPUT_VARIABLE TMP_HOSTNAME
 101                     OUTPUT_STRIP_TRAILING_WHITESPACE)
 102     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}")
 103         message(WARNING "
 104             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
 105             is being reused! This could lead to inconsitencies; therefore, it is
 106             recommended to regenerate the cache!")
 107     endif()
 108     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
 109             "Hostname of the machine where the cache was generated.")
 110 endif()
 111
 112 ########################################################################
 113 option(GMX_COOL_QUOTES "Enable Gromacs cool quotes" ON)
 114 mark_as_advanced(GMX_COOL_QUOTES)
 115
 116 set(CMAKE_PREFIX_PATH "" CACHE STRING "Extra locations to search for external libraries and tools (give directory without lib, bin, or include)")
 117 # User input options                                                   #
 118 ########################################################################
 119 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" OFF)
 120 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 121 option(GMX_THREAD_MPI  "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" ON)
 122 option(GMX_SOFTWARE_INVSQRT "Use GROMACS software 1/sqrt" ON)
 123 mark_as_advanced(GMX_SOFTWARE_INVSQRT)
 124 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 125 mark_as_advanced(GMX_FAHCORE)
 126
 127 # decide on GPU settings based on user-settings and GPU/CUDA detection
 128 include(gmxManageGPU)
 129
 130 include(gmxDetectAcceleration)
 131 if(NOT DEFINED GMX_CPU_ACCELERATION)
 132     if(CMAKE_CROSSCOMPILING)
 133         if("${CMAKE_SYSTEM_NAME}" MATCHES "BlueGeneQ")
 134             set(GMX_SUGGESTED_CPU_ACCELERATION "IBM_QPX")
 135         else()
 136             set(GMX_SUGGESTED_CPU_ACCELERATION "None")
 137         endif()
 138     else(CMAKE_CROSSCOMPILING)
 139         gmx_detect_acceleration(GMX_SUGGESTED_CPU_ACCELERATION)
 140     endif(CMAKE_CROSSCOMPILING)
 141 endif(NOT DEFINED GMX_CPU_ACCELERATION)
 142
 143 set(GMX_CPU_ACCELERATION "@GMX_SUGGESTED_CPU_ACCELERATION@"
 144     CACHE STRING "Accelerated CPU kernels. Pick one of: None, SSE2, SSE4.1, AVX_128_FMA, AVX_256, IBM_QPX, Sparc64_HPC_ACE")
 145
 146 set(GMX_FFT_LIBRARY "fftw3"
 147     CACHE STRING "FFT library choices: fftw3,mkl,fftpack[built-in]")
 148 option(GMX_BUILD_OWN_FFTW "Download and build FFTW 3 during the GROMACS build process, rather than fall back on the really slow fftpack." OFF)
 149 mark_as_advanced(GMX_BUILD_OWN_FFTW)
 150 option(GMX_DISABLE_FFTW_MEASURE
 151        "Do not optimize FFTW setups (not needed with SSE)" OFF)
 152 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 153 set(GMX_QMMM_PROGRAM "none"
 154     CACHE STRING "QM package choices: none,gaussian,mopac,gamess,orca")
 155 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 156 mark_as_advanced(GMX_BROKEN_CALLOC)
 157 option(GMX_MPI_IN_PLACE "Enable MPI_IN_PLACE for MPIs that have it defined" ON)
 158 mark_as_advanced(GMX_MPI_IN_PLACE)
 159 option(GMX_LOAD_PLUGINS "Compile with plugin support, needed to read VMD supported file formats" ON)
 160 mark_as_advanced(GMX_LOAD_PLUGINS)
 161
 162 option(GMX_GPU  "Enable GPU acceleration" ON)
 163 option(GMX_OPENMP "Enable OpenMP-based multithreading" ON)
 164
 165 option(GMX_GIT_VERSION_INFO "Generate git version information" ${SOURCE_IS_GIT_REPOSITORY})
 166 mark_as_advanced(GMX_GIT_VERSION_INFO)
 167
 168 option(GMX_DEFAULT_SUFFIX "Use default suffixes for GROMACS binaries and libs (_d for double, _mpi for MPI; rerun cmake after changing to see relevant options)" ON)
 169 if(UNIX)
 170     option(GMX_SYMLINK_OLD_BINARY_NAMES "Create symbolic links for pre-5.0 binary names" ON)
 171 endif()
 172 option(GMX_BUILD_MDRUN_ONLY "Build and install only the mdrun binary" OFF)
 173
 174 if(UNIX)
 175     option(GMX_PREFER_STATIC_LIBS "When finding libraries prefer static archives (not available on non-*nix platforms and it will only work if static versions of external dependencies are available and found)!" OFF)
 176     mark_as_advanced(GMX_PREFER_STATIC_LIBS)
 177 endif()
 178
 179 option(GMX_CYCLE_SUBCOUNTERS "Enable cycle subcounters to get a more detailed cycle timings" OFF)
 180 mark_as_advanced(GMX_CYCLE_SUBCOUNTERS)
 181
 182 option(GMX_SKIP_DEFAULT_CFLAGS "Don't automatically add suggested/required Compiler flags." OFF)
 183 mark_as_advanced(GMX_SKIP_DEFAULT_CFLAGS)
 184
 185 option(GMX_BUILD_FOR_COVERAGE
 186        "Tune build for better code coverage metrics (e.g., disable asserts)"
 187        OFF)
 188 mark_as_advanced(GMX_BUILD_FOR_COVERAGE)
 189
 190 ######################################################################
 191 # Compiler tests
 192 # These need to be done early (before further tests).
 193 #####################################################################
 194
 195 # The cmake/Check{C,CXX}CompilerFlag.cmake files in the GROMACS distribution
 196 # are used with permission from CMake v2.8.9 so that GROMACS can detect
 197 # invalid options with the Intel Compilers.
 198 # These files should be removed from the source tree when a CMake version that
 199 # includes the features in question becomes required for building GROMACS.
 200 include(CheckCCompilerFlag)
 201 include(CheckCXXCompilerFlag)
 202
 203 # Get compiler version information, needs to be done early as check that depend
 204 # on compiler verison follow below.
 205 include(gmxGetCompilerInfo)
 206 get_compiler_version()
 207
 208 # First exclude compilers known to not work with OpenMP although claim to support it:
 209 # gcc 4.2.1 and gcc-llvm 4.2.1 (also claims to be 4.2.1) on Mac OS X
 210 # This fixes redmine 900 and needs to run before OpenMP flags are set below.
 211 if (CMAKE_SYSTEM_NAME STREQUAL "Darwin" AND
 212     (CMAKE_COMPILER_IS_GNUCC AND C_COMPILER_VERSION AND C_COMPILER_VERSION VERSION_LESS 4.3))
 213     message(STATUS "OpenMP multithreading not supported with gcc/llvm-gcc 4.2 on Mac OS X, disabled")
 214     set(GMX_OPENMP OFF CACHE BOOL
 215         "OpenMP multithreading not not supported with gcc/llvm-gcc 4.2 on Mac OS X, disabled!" FORCE)
 216 endif()
 217
 218 # OpenMP check must come before other CFLAGS!
 219 if(GMX_OPENMP)
 220     find_package(OpenMP)
 221     if(OPENMP_FOUND)
 222         # CMake on Windows doesn't support linker flags passed to target_link_libraries
 223         # (i.e. it treats /openmp as \openmp library file). Also, no OpenMP linker flags are needed.
 224         if(NOT (WIN32 AND NOT CYGWIN))
 225             if(CMAKE_COMPILER_IS_GNUCC AND GMX_PREFER_STATIC_OPENMP AND NOT APPLE)
 226                 set(OpenMP_LINKER_FLAGS "-Wl,-static -lgomp -lrt -Wl,-Bdynamic -lpthread")
 227                 set(OpenMP_SHARED_LINKER_FLAGS "")
 228             else()
 229                 # Only set a linker flag if the user didn't set them manually
 230                 if(NOT DEFINED OpenMP_LINKER_FLAGS)
 231                     set(OpenMP_LINKER_FLAGS "${OpenMP_C_FLAGS}")
 232                 endif()
 233                 if(NOT DEFINED OpenMP_SHARED_LINKER_FLAGS)
 234                     set(OpenMP_SHARED_LINKER_FLAGS "${OpenMP_C_FLAGS}")
 235                 endif()
 236             endif()
 237         endif()
 238     else(OPENMP_FOUND)
 239         message(WARNING
 240                 "The compiler you are using does not support OpenMP parallelism. This might hurt your performance a lot, in particular with GPUs. Try using a more recent version, or a different compiler. For now, we are proceeding by turning off OpenMP.")
 241         set(GMX_OPENMP OFF CACHE STRING "Whether GROMACS will use OpenMP parallelism." FORCE)
 242     endif(OPENMP_FOUND)
 243 endif()
 244
 245
 246 include(gmxCFlags)
 247 gmx_c_flags()
 248
 249 # This variable should be used for additional compiler flags which are not
 250 # generated in gmxCFlags nor are acceleration or MPI related.
 251 set(EXTRA_C_FLAGS "")
 252 set(EXTRA_CXX_FLAGS "")
 253
 254 # gcc 4.4.x is buggy and crashes when compiling some files with O3 and OpenMP on.
 255 # Detect here whether applying a workaround is needed and will apply it later
 256 # on the affected files.
 257 include(gmxGCC44O3BugWorkaround)
 258 gmx_check_gcc44_bug_workaround_needed(GMX_USE_GCC44_BUG_WORKAROUND)
 259
 260 # clang 3.0 is buggy for some unknown reason detected during adding
 261 # the SSE2 group kernels for GROMACS 4.6. If we ever work out what
 262 # that is, we should replace these tests with a compiler feature test,
 263 # update GROMACS Redmine task #1039 and perhaps report a clang bug.
 264 #
 265 # In the meantime, until we require CMake 2.8.10 we cannot rely on it to detect
 266 # the compiler version for us. So we need a manual check for clang 3.0.
 267 include(gmxDetectClang30)
 268 gmx_detect_clang_3_0(COMPILER_IS_CLANG_3_0)
 269 if(COMPILER_IS_CLANG_3_0)
 270     message(FATAL_ERROR "Your compiler is clang version 3.0, which is known to be buggy for GROMACS. Use a different compiler.")
 271 endif()
 272
 273 # clang <=3.2 contains a bug that causes incorrect code to be generated for the
 274 # vfmaddps instruction and therefore the bug is triggered with AVX_128_FMA.
 275 # (see: http://llvm.org/bugs/show_bug.cgi?id=15040).
 276 # We can work around this by not using the integrated assembler (except on OS X
 277 # which has an outdated assembler that does not support AVX instructions).
 278 if (${CMAKE_C_COMPILER_ID} MATCHES "Clang" AND C_COMPILER_VERSION VERSION_LESS "3.3")
 279     set(GMX_USE_CLANG_C_FMA_BUG_WORKAROUND TRUE)
 280 endif()
 281 if (${CMAKE_CXX_COMPILER_ID} MATCHES "Clang" AND CXX_COMPILER_VERSION VERSION_LESS "3.3")
 282     set(GMX_USE_CLANG_CXX_FMA_BUG_WORKAROUND TRUE)
 283 endif()
 284
 285 if (CMAKE_C_COMPILER_ID STREQUAL "PGI")
 286     message(WARNING "All tested PGI compiler versions (up to 12.9.0) generate binaries which produce incorrect results, or even fail to compile Gromacs. Highly recommended to use a different compiler. If you choose to use PGI, make sure to run the regressiontests.")
 287 endif()
 288
 289 if(CMAKE_C_COMPILER_ID MATCHES "Intel" AND C_COMPILER_VERSION VERSION_LESS "12.0.0")
 290     message(WARNING "Intel compilers before 12.0.0 are not routinely tested, so there may be problems. Version 11.1 with SSE4.1 is known to produce incorrect results. It is highly recommended to use a more up-to-date compiler. If you choose to use this version, make sure you run the regressiontests.")
 291 endif()
 292
 293 set(PKG_CFLAGS "")
 294 if(GMX_DOUBLE)
 295     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_DOUBLE")
 296 endif(GMX_DOUBLE)
 297 if(GMX_SOFTWARE_INVSQRT)
 298   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_SOFTWARE_INVSQRT")
 299 endif(GMX_SOFTWARE_INVSQRT)
 300
 301
 302
 303 ########################################################################
 304 # Basic system tests (standard libraries, headers, functions, types)   #
 305 ########################################################################
 306 include(CheckIncludeFiles)
 307 include(CheckIncludeFileCXX)
 308 check_include_files(unistd.h     HAVE_UNISTD_H)
 309 check_include_files(pwd.h        HAVE_PWD_H)
 310 check_include_files(dirent.h     HAVE_DIRENT_H)
 311 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 312 check_include_files(io.h         HAVE_IO_H)
 313 check_include_files(sched.h      HAVE_SCHED_H)
 314
 315 check_include_files(regex.h      HAVE_POSIX_REGEX)
 316 check_include_file_cxx(regex     HAVE_CXX11_REGEX)
 317 # TODO: It could be nice to inform the user if no regex support is found,
 318 # as selections won't be fully functional.
 319
 320 include(CheckFunctionExists)
 321 check_function_exists(posix_memalign    HAVE_POSIX_MEMALIGN)
 322 check_function_exists(memalign          HAVE_MEMALIGN)
 323 check_function_exists(_aligned_malloc   HAVE__ALIGNED_MALLOC)
 324 check_function_exists(gettimeofday      HAVE_GETTIMEOFDAY)
 325 check_function_exists(fsync             HAVE_FSYNC)
 326 check_function_exists(_fileno           HAVE__FILENO)
 327 check_function_exists(fileno            HAVE_FILENO)
 328 check_function_exists(_commit           HAVE__COMMIT)
 329 check_function_exists(sigaction         HAVE_SIGACTION)
 330 check_function_exists(sysconf           HAVE_SYSCONF)
 331 check_function_exists(sched_setaffinity HAVE_SCHED_SETAFFINITY)
 332 check_function_exists(sched_getaffinity HAVE_SCHED_GETAFFINITY)
 333 check_function_exists(rsqrt             HAVE_RSQRT)
 334 check_function_exists(rsqrtf            HAVE_RSQRTF)
 335 check_function_exists(sqrtf             HAVE_SQRTF)
 336
 337 include(CheckLibraryExists)
 338 check_library_exists(m sqrt "" HAVE_LIBM)
 339
 340
 341 include(CheckTypeSize)
 342
 343 check_type_size("int"           SIZEOF_INT)
 344 check_type_size("long int"      SIZEOF_LONG_INT)
 345 check_type_size("long long int" SIZEOF_LONG_LONG_INT)
 346 check_type_size("off_t"         SIZEOF_OFF_T)
 347 check_type_size("void *"        SIZEOF_VOIDP)
 348
 349 include(TestBigEndian)
 350 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 351
 352
 353 if(APPLE OR CYGWIN OR ${CMAKE_SYSTEM_NAME} MATCHES "Linux|.*BSD")
 354     # Maybe Solaris should be here? Patch this if you know!
 355     SET(SHARED_LIBS_DEFAULT ON)
 356 elseif(WIN32 OR ${CMAKE_SYSTEM_NAME} MATCHES "BlueGene")
 357     # Support for shared libs on native Windows is a bit new. Its
 358     # default might change later if/when we sort things out. Also,
 359     # Cray should go here. What variable value can detect it?
 360     SET(SHARED_LIBS_DEFAULT OFF)
 361 else()
 362     message(STATUS "Defaulting to building static libraries")
 363     SET(SHARED_LIBS_DEFAULT OFF)
 364 endif()
 365
 366 # Management of GROMACS options for specific toolchains should go
 367 # here. Because the initial settings for some of the main options have
 368 # already happened, but things like library detection and MPI compiler
 369 # feature detection have not, the docstrings for any over-rides of
 370 # GROMACS defaults or user settings will make sense. Also, any
 371 # toolchain-related reasons for choosing whether to detect various
 372 # things can be sorted out now, before the detection takes place.
 373 if(${CMAKE_SYSTEM_NAME} MATCHES BlueGene)
 374     include(gmxManageBlueGene)
 375 endif()
 376
 377 if(UNIX AND GMX_PREFER_STATIC_LIBS AND SHARED_LIBS_DEFAULT)
 378     if(BUILD_SHARED_LIBS)
 379         # Warn the user about the combination. But don't overwrite the request.
 380         message(WARNING "Searching for static libraries requested, and building shared Gromacs libraries requested. This might cause problems linking later.")
 381     elseif(NOT DEFINED BUILD_SHARED_LIBS)
 382         # Change default to OFF. Don't warn if it's already off.
 383         message(WARNING "Searching for static libraries requested, so the GROMACS libraries will also be built statically (BUILD_SHARED_LIBS=OFF)")
 384         set(SHARED_LIBS_DEFAULT OFF)
 385     endif()
 386 endif()
 387
 388 # By now, all tool chains should have spoken up if they care about
 389 # the setting of SHARED_LIBS_DEFAULT.
 390 option(BUILD_SHARED_LIBS "Enable shared libraries (can be problematic e.g. with MPI, or on some HPC systems)" ${SHARED_LIBS_DEFAULT})
 391
 392 ########################################################################
 393 #Process MPI settings
 394 ########################################################################
 395 include(gmxManageMPI)
 396
 397 ########################################################################
 398 # Find external packages                                               #
 399 ########################################################################
 400 if(UNIX AND GMX_PREFER_STATIC_LIBS)
 401     # On Linux .a is the static library suffix, on Mac OS X .lib can also
 402     # be used, so we'll add both to the preference list.
 403     SET(CMAKE_FIND_LIBRARY_SUFFIXES ".lib;.a" ${CMAKE_FIND_LIBRARY_SUFFIXES})
 404 endif()
 405
 406 IF( WIN32 AND NOT CYGWIN)
 407   # This makes windows.h not declare min/max as macros that would break
 408   # C++ code using std::min/std::max.
 409   add_definitions(-DNOMINMAX)
 410
 411   if (NOT BUILD_SHARED_LIBS)
 412       option(GMX_PREFER_STATIC_LIBS "When finding libraries prefer static system libraries (MT instead of MD)!" ON)
 413       if(NOT GMX_PREFER_STATIC_LIBS)
 414           message(WARNING "Shared system libraries requested, and static Gromacs libraries requested.")
 415       endif()
 416   else()
 417       message(FATAL_ERROR "BUILD_SHARED_LIBS not yet working for Windows in the master branch")
 418       option(GMX_PREFER_STATIC_LIBS "When finding libraries prefer static system libraries (MT instead of MD)!" OFF)
 419       if(GMX_PREFER_STATIC_LIBS)
 420           #this combination segfaults (illigal passing of file handles)
 421           message(FATAL_ERROR "Static system libraries requested, and shared Gromacs libraries requested.")
 422       endif()
 423       add_definitions(-DUSE_VISIBILITY -DTMPI_USE_VISIBILITY)
 424       set(PKG_CFLAGS "$PKG_CFLAGS -DUSE_VISIBILITY -DTMPI_USE_VISIBILITY")
 425   endif()
 426   mark_as_advanced(GMX_PREFER_STATIC_LIBS)
 427
 428   IF (GMX_PREFER_STATIC_LIBS)
 429       #Only setting Debug and Release flags. Others configurations are current not used.
 430       STRING(REPLACE /MD /MT CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE})
 431       STRING(REPLACE /MD /MT CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG})
 432       STRING(REPLACE /MD /MT CMAKE_CXX_FLAGS_RELEASE ${CMAKE_CXX_FLAGS_RELEASE})
 433       STRING(REPLACE /MD /MT CMAKE_CXX_FLAGS_DEBUG ${CMAKE_CXX_FLAGS_DEBUG})
 434   ENDIF()
 435   IF( CMAKE_C_COMPILER_ID MATCHES "Intel" )
 436     if(BUILD_SHARED_LIBS) #not sure why incremental building with shared libs doesn't work
 437         STRING(REPLACE "/INCREMENTAL:YES" "" CMAKE_SHARED_LINKER_FLAGS ${CMAKE_SHARED_LINKER_FLAGS})
 438     endif()
 439   ENDIF()
 440 ENDIF()
 441
 442 # Unconditionally find the package, as it is also required for unit tests
 443 find_package(LibXml2)
 444 option(GMX_XML "Use libxml2 to parse xml files (currently has no effect)" ${LIBXML2_FOUND})
 445 set(PKG_XML "")
 446 mark_as_advanced(GMX_XML)
 447 # Don't actually do anything, since libxml2 is currently not used by libgromacs
 448 #if(GMX_XML AND NOT LIBXML2_FOUND)
 449 #    message(FATAL_ERROR "libxml2 not found. Set GMX_XML=OFF to compile without XML support")
 450 #endif()
 451 #if(GMX_XML)
 452 #    include_directories(${LIBXML2_INCLUDE_DIR})
 453 #    set(PKG_XML libxml-2.0)
 454 #    set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 455 #endif(GMX_XML)
 456
 457 option(GMX_GSL "Add support for gsl" OFF)
 458 if (GMX_GSL)
 459   find_package(GSL)
 460   set(PKG_GSL "")
 461   if(GSL_FOUND)
 462     include_directories(${GSL_INCLUDE_DIR})
 463     set(PKG_GSL gsl)
 464     set(HAVE_LIBGSL 1)
 465   endif(GSL_FOUND)
 466 endif (GMX_GSL)
 467
 468 option(GMX_X11 "Use X window system" OFF)
 469 if (GMX_X11)
 470     find_package(X11)
 471     # X11 includes/libraries are only set in the ngmx subdirectory!
 472     if(NOT X11_FOUND)
 473         message(WARNING "X11 include files and/or libraries were not found. Will not build the GROMACS X11-binaries, such as ngmx")
 474     else()
 475         set(HAVE_X11 1)
 476         include_directories(${X11_INCLUDE_DIR})
 477     endif()
 478 endif(GMX_X11)
 479
 480 include(ThreadMPI)
 481 set(THREAD_MPI_LIB thread_mpi)
 482 # Enable core threading facilities
 483 tmpi_enable_core("${CMAKE_SOURCE_DIR}/src/gromacs/legacyheaders")
 484 # Enable tMPI C++ support
 485 tmpi_enable_cxx()
 486 if(GMX_THREAD_MPI)
 487     # enable MPI functions
 488     tmpi_enable()
 489     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_THREAD_MPI")
 490     set(GMX_MPI 1)
 491 endif(GMX_THREAD_MPI)
 492 tmpi_get_source_list(THREAD_MPI_SRC)
 493
 494 if(GMX_GPU)
 495     # now that we have detected the dependencies, do the second configure pass
 496     gmx_gpu_setup()
 497 endif(GMX_GPU)
 498
 499 if(CYGWIN)
 500     set(GMX_CYGWIN 1)
 501 endif(CYGWIN)
 502
 503 if(WIN32 AND NOT CYGWIN)
 504     set(GMX_NATIVE_WINDOWS 1)
 505 endif()
 506
 507 # only bother with finding git and using version.h if the source is a git repo
 508 if(GMX_GIT_VERSION_INFO)
 509     if (NOT SOURCE_IS_GIT_REPOSITORY)
 510         message(FATAL_ERROR
 511             "Cannot generate git version information from source tree not under git. "
 512             "Set GMX_GIT_VERSION_INFO=OFF to proceed.")
 513     endif ()
 514     # We need at least git v1.5.3 be able to parse git's date output. If not
 515     # found or the version is too small, we can't generate version information.
 516     find_package(Git)
 517
 518     # Find out the git version
 519     if(GIT_FOUND AND NOT GIT_VERSION)
 520       execute_process(COMMAND ${GIT_EXECUTABLE} "--version"
 521         OUTPUT_VARIABLE _exec_out
 522         OUTPUT_STRIP_TRAILING_WHITESPACE)
 523       string(REGEX REPLACE "git version (.*)" "\\1" GIT_VERSION ${_exec_out})
 524       set(GIT_VERSION ${GIT_VERSION} CACHE STRING "Git version")
 525       mark_as_advanced(GIT_VERSION)
 526     endif()
 527
 528     if(NOT GIT_FOUND OR GIT_VERSION VERSION_LESS "1.5.3")
 529         message(FATAL_ERROR
 530             "No compatible git version found (>= 1.5.3 required). "
 531             "Won't be able to generate development version information. "
 532             "Set GMX_GIT_VERSION_INFO=OFF to proceed.")
 533     endif()
 534 endif()
 535
 536 # Detect boost unless GMX_EXTERNAL_BOOST is explicitly OFF
 537 # Used for default if GMX_EXTERNAL_BOOST is not defined (first CMake pass)
 538 if(NOT DEFINED GMX_EXTERNAL_BOOST OR GMX_EXTERNAL_BOOST)
 539     find_package(Boost 1.44.0)
 540     if(Boost_FOUND AND Boost_VERSION VERSION_LESS "104400")
 541         set(Boost_FOUND FALSE)
 542     endif()
 543     # Print the notification only on first run, when determining the default
 544     if(NOT DEFINED GMX_EXTERNAL_BOOST AND NOT Boost_FOUND)
 545         message("Boost >= 1.44 not found. Using minimal internal version. "
 546                 "This may cause trouble if you plan on compiling/linking other "
 547                 "software that uses Boost against Gromacs.")
 548     endif()
 549 endif()
 550 option(GMX_EXTERNAL_BOOST "Use external Boost instead of minimal built-in version"
 551        ${Boost_FOUND})
 552 if(GMX_EXTERNAL_BOOST AND NOT Boost_FOUND)
 553     message(FATAL_ERROR
 554         "Boost >= 1.44 not found. "
 555         "You can set GMX_EXTERNAL_BOOST=OFF to compile against minimal "
 556         "version of Boost included with Gromacs.")
 557 endif()
 558
 559 option(GMX_BUILD_UNITTESTS "Build unit tests with BUILD_TESTING (uses Google C++ Testing and Mocking Frameworks, requires libxml2)" ${LIBXML2_FOUND})
 560 mark_as_advanced(GMX_BUILD_UNITTESTS)
 561 if (GMX_BUILD_UNITTESTS AND NOT LIBXML2_FOUND)
 562     message(FATAL_ERROR
 563         "Cannot build unit tests without libxml2. "
 564         "Either set GMX_BUILD_UNITTESTS=OFF or tell CMake how to find libxml2.")
 565 endif()
 566 set(MEMORYCHECK_SUPPRESSIONS_FILE ${CMAKE_SOURCE_DIR}/cmake/legacy_and_external.supp)
 567
 568 ########################################################################
 569 # Generate development version info for cache
 570 ########################################################################
 571 # set(GEN_VERSION_INFO_INTERNAL "ON")
 572 # include(gmxGenerateVersionString)
 573
 574 ########################################################################
 575 # Our own GROMACS tests
 576 ########################################################################
 577
 578 add_definitions( -DHAVE_CONFIG_H )
 579 include_directories(${CMAKE_SOURCE_DIR}/src)
 580 # Required for config.h, maybe should only be set in src/CMakeLists.txt
 581 include_directories(${CMAKE_BINARY_DIR}/src)
 582 # Required for gmx_header_config_gen.h to be found before installation
 583 include_directories(${CMAKE_BINARY_DIR}/src/gromacs/utility)
 584 # Required for now to make old code compile
 585 include_directories(${CMAKE_SOURCE_DIR}/src/gromacs/legacyheaders)
 586
 587 include(gmxTestInlineASM)
 588 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 589
 590 include(gmxSetBuildInformation)
 591 gmx_set_build_information()
 592 if(BUILD_CPU_FEATURES MATCHES "rdtscp" AND NOT GMX_DISTRIBUTABLE_BUILD)
 593     # The timestep counter headers do not include config.h
 594     add_definitions(-DHAVE_RDTSCP)
 595 endif(BUILD_CPU_FEATURES MATCHES "rdtscp" AND NOT GMX_DISTRIBUTABLE_BUILD)
 596
 597 include(gmxTestFloatFormat)
 598 gmx_test_float_format(GMX_FLOAT_FORMAT_IEEE754
 599                       GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER
 600                       GMX_IEEE754_BIG_ENDIAN_WORD_ORDER)
 601
 602 include(gmxTestLargeFiles)
 603 gmx_test_large_files(GMX_LARGEFILES)
 604
 605 include(gmxTestSignal)
 606 gmx_test_sigusr1(HAVE_SIGUSR1)
 607
 608 include(gmxTestInline)
 609 gmx_test_inline(INLINE_KEYWORD)
 610
 611 include(gmxTestRestrict)
 612 gmx_test_restrict(RESTRICT_KEYWORD)
 613
 614 include(gmxTestPipes)
 615 gmx_test_pipes(HAVE_PIPES)
 616
 617 include(gmxTestIsfinite)
 618 gmx_test_isfinite(HAVE_ISFINITE)
 619 gmx_test__isfinite(HAVE__ISFINITE)
 620 gmx_test__finite(HAVE__FINITE)
 621
 622 include(gmxTestCXX11)
 623 gmx_test_cxx11(GMX_CXX11 GMX_CXX11_FLAGS)
 624 if(CXX11_FLAG AND GMX_GPU)
 625     #FIXME: add proper solution for progate all but cxx11 flag
 626     set(CUDA_PROPAGATE_HOST_FLAGS no)
 627     message(WARNING "Please manually add compiler flags to CUDA_NVCC_FLAGS. Automatic propogation temporary not working.")
 628 endif()
 629
 630 include(gmxTestXDR)
 631 gmx_test_xdr(GMX_SYSTEM_XDR)
 632 if(NOT GMX_SYSTEM_XDR)
 633     set(GMX_INTERNAL_XDR 1)
 634     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_INTERNAL_XDR")
 635 endif(NOT GMX_SYSTEM_XDR)
 636
 637 # include avx test source, used if the AVX flags are set below
 638 include(gmxTestAVXMaskload)
 639
 640 # Process nonbonded accelerated kernels settings
 641 #
 642 # Note that for the backward-compatible x86 SIMD architectures, the
 643 # GMX_CPU_ACCELERATION determines the maximum level of the instruction
 644 # set used (e.g. GMX_CPU_ACCLERATION=SSE4.1 implies
 645 # SSE2). Accordingly, there are a set of CMake variables
 646 # GMX_<arch>_<feature-set> that are exported to the C code to specify
 647 # CPU features that should be used. This means that the logic for
 648 # requiring such backward compatibility is all located here.
 649 string(TOUPPER ${GMX_CPU_ACCELERATION} GMX_CPU_ACCELERATION)
 650 if(${GMX_CPU_ACCELERATION} STREQUAL "NONE")
 651     # nothing to do
 652 elseif(${GMX_CPU_ACCELERATION} STREQUAL "SSE2")
 653
 654     GMX_TEST_CFLAG(GNU_SSE2_CFLAG "-msse2" ACCELERATION_C_FLAGS)
 655     if(NOT GNU_SSE2_CFLAG AND GMX_NATIVE_WINDOWS)
 656         GMX_TEST_CFLAG(MSVC_SSE2_CFLAG "/arch:SSE2" ACCELERATION_C_FLAGS)
 657     endif(NOT GNU_SSE2_CFLAG AND GMX_NATIVE_WINDOWS)
 658
 659     GMX_TEST_CXXFLAG(GNU_SSE2_CXXFLAG "-msse2" ACCELERATION_CXX_FLAGS)
 660     if(NOT GNU_SSE2_CXXFLAG AND GMX_NATIVE_WINDOWS)
 661         GMX_TEST_CXXFLAG(MSVC_SSE2_CXXFLAG "/arch:SSE2" ACCELERATION_CXX_FLAGS)
 662     endif(NOT GNU_SSE2_CXXFLAG AND GMX_NATIVE_WINDOWS)
 663
 664     # We dont warn for lacking SSE2 flag support, since that is probably standard today.
 665
 666     # Only test the include after we have tried to add the correct flag for SSE2 support
 667     check_include_file(emmintrin.h  HAVE_EMMINTRIN_H ${ACCELERATION_C_FLAGS})
 668
 669     if(NOT HAVE_EMMINTRIN_H)
 670         message(FATAL_ERROR "Cannot find emmintrin.h, which is required for SSE2 intrinsics support.")
 671     endif(NOT HAVE_EMMINTRIN_H)
 672
 673     set(GMX_CPU_ACCELERATION_X86_SSE2 1)
 674     # The user should not be able to set this orthogonally to the acceleration
 675     set(GMX_X86_SSE2 1)
 676     if (NOT ACCELERATION_QUIETLY)
 677       message(STATUS "Enabling SSE2 Gromacs acceleration, and it will help compiler optimization.")
 678     endif()
 679
 680 elseif(${GMX_CPU_ACCELERATION} STREQUAL "SSE4.1")
 681
 682     GMX_TEST_CFLAG(GNU_SSE4_CFLAG "-msse4.1" ACCELERATION_C_FLAGS)
 683     if (NOT GNU_SSE4_CFLAG AND GMX_NATIVE_WINDOWS)
 684         GMX_TEST_CFLAG(MSVC_SSE4_CFLAG "/arch:SSE4.1" ACCELERATION_C_FLAGS)
 685     endif(NOT GNU_SSE4_CFLAG AND GMX_NATIVE_WINDOWS)
 686     if (NOT GNU_SSE4_CFLAG AND NOT MSVC_SSE4_CFLAG)
 687         # Not surprising if we end up here! MSVC current does not support the SSE4.1 flag. However, it appears to accept SSE4.1
 688         # intrinsics when SSE2 support is enabled, so we try that instead first.
 689         if (GMX_NATIVE_WINDOWS)
 690             GMX_TEST_CFLAG(MSVC_SSE2_CFLAG "/arch:SSE2" ACCELERATION_C_FLAGS)
 691             message(WARNING "Neither SSE4.1 or SSE2 seems to be supported by your Windows compiler. Something is likely broken.")
 692         else()
 693             message(WARNING "No C SSE4.1 flag found. Consider a newer compiler, or use SSE2 for slightly lower performance")
 694         endif()
 695     endif(NOT GNU_SSE4_CFLAG AND NOT MSVC_SSE4_CFLAG)
 696
 697     GMX_TEST_CXXFLAG(GNU_SSE4_CXXFLAG "-msse4.1" ACCELERATION_CXX_FLAGS)
 698     if (NOT GNU_SSE4_CXXFLAG AND GMX_NATIVE_WINDOWS)
 699         GMX_TEST_CXXFLAG(MSVC_SSE4_CXXFLAG "/arch:SSE4.1" ACCELERATION_CXX_FLAGS)
 700     endif(NOT GNU_SSE4_CXXFLAG AND GMX_NATIVE_WINDOWS)
 701     if (NOT GNU_SSE4_CXXFLAG AND NOT MSVC_SSE4_CXXFLAG)
 702         message(WARNING "No C++ SSE4.1 flag found. Consider a newer compiler, or use SSE2 for slightly lower performance.")
 703         # Not surprising if we end up here! MSVC current does not support the SSE4.1 flag. However, it appears to accept SSE4.1
 704         # intrinsics when SSE2 support is enabled, so we try that instead.
 705         if (GMX_NATIVE_WINDOWS)
 706             GMX_TEST_CXXFLAG(MSVC_SSE2_CXXFLAG "/arch:SSE2" ACCELERATION_CXX_FLAGS)
 707         endif()
 708     endif(NOT GNU_SSE4_CXXFLAG AND NOT MSVC_SSE4_CXXFLAG)
 709
 710     # This must come after we have added the -msse4.1 flag on some platforms.
 711     check_include_file(smmintrin.h  HAVE_SMMINTRIN_H ${ACCELERATION_C_FLAGS})
 712
 713     if(NOT HAVE_SMMINTRIN_H)
 714         message(FATAL_ERROR "Cannot find smmintrin.h, which is required for SSE4.1 intrinsics support.")
 715     endif(NOT HAVE_SMMINTRIN_H)
 716
 717     set(GMX_CPU_ACCELERATION_X86_SSE4_1 1)
 718     # The user should not be able to set this orthogonally to the acceleration
 719     set(GMX_X86_SSE4_1 1)
 720     set(GMX_X86_SSE2   1)
 721     if (NOT ACCELERATION_QUIETLY)
 722       message(STATUS "Enabling SSE4.1 Gromacs acceleration, and it will help compiler optimization.")
 723     endif()
 724
 725     if(CMAKE_C_COMPILER_ID MATCHES "Intel" AND C_COMPILER_VERSION VERSION_EQUAL "11.1")
 726         message(FATAL_ERROR "You are using Intel compiler version 11.1, and that compiler is known to produce incorrect results with SSE4.1 acceleration. You need to use another compiler (e.g. icc 12 or newer) or different acceleration (probably slower simulations).")
 727     endif()
 728 elseif(${GMX_CPU_ACCELERATION} STREQUAL "AVX_128_FMA" OR ${GMX_CPU_ACCELERATION} STREQUAL "AVX_256")
 729
 730     # Set the AVX compiler flag for both these choices!
 731
 732     GMX_TEST_CFLAG(GNU_AVX_CFLAG "-mavx" ACCELERATION_C_FLAGS)
 733     if (NOT GNU_AVX_CFLAG AND GMX_NATIVE_WINDOWS)
 734         GMX_TEST_CFLAG(MSVC_AVX_CFLAG "/arch:AVX" ACCELERATION_C_FLAGS)
 735     endif (NOT GNU_AVX_CFLAG AND GMX_NATIVE_WINDOWS)
 736     if (NOT GNU_AVX_CFLAG AND NOT MSVC_AVX_CFLAG)
 737         message(WARNING "No C AVX flag found. Consider a newer compiler, or try SSE4.1 (lower performance) giving the -DGMX_CPU_ACCELERATION=SSE4.1 to cmake.")
 738     endif (NOT GNU_AVX_CFLAG AND NOT MSVC_AVX_CFLAG)
 739
 740     GMX_TEST_CXXFLAG(GNU_AVX_CXXFLAG "-mavx" ACCELERATION_CXX_FLAGS)
 741     if (NOT GNU_AVX_CXXFLAG AND GMX_NATIVE_WINDOWS)
 742         GMX_TEST_CXXFLAG(MSVC_AVX_CXXFLAG "/arch:AVX" ACCELERATION_CXX_FLAGS)
 743     endif (NOT GNU_AVX_CXXFLAG AND GMX_NATIVE_WINDOWS)
 744     if (NOT GNU_AVX_CXXFLAG AND NOT MSVC_AVX_CXXFLAG)
 745         message(WARNING "No C++ AVX flag found. Consider a newer compiler, or try SSE4.1 (lower performance) giving the -DGMX_CPU_ACCELERATION=SSE4.1 to cmake.")
 746     endif (NOT GNU_AVX_CXXFLAG AND NOT MSVC_AVX_CXXFLAG)
 747
 748     # Set the FMA4 flags (MSVC doesn't require any)
 749     if(${GMX_CPU_ACCELERATION} STREQUAL "AVX_128_FMA" AND NOT MSVC)
 750         GMX_TEST_CFLAG(GNU_FMA_CFLAG "-mfma4" ACCELERATION_C_FLAGS)
 751         if (NOT GNU_FMA_CFLAG)
 752             message(WARNING "No C FMA4 flag found. Consider a newer compiler, or try SSE4.1 (lower performance).")
 753         endif(NOT GNU_FMA_CFLAG)
 754         GMX_TEST_CFLAG(GNU_XOP_CFLAG "-mxop" ACCELERATION_C_FLAGS)
 755         # No big deal if we do not have xop, so no point yelling warnings about it.
 756         GMX_TEST_CXXFLAG(GNU_FMA_CXXFLAG "-mfma4" ACCELERATION_CXX_FLAGS)
 757         if (NOT GNU_FMA_CXXFLAG)
 758             message(WARNING "No C++ FMA flag found. Consider a newer compiler, or try SSE4.1 (lower performance).")
 759         endif (NOT GNU_FMA_CXXFLAG)
 760         GMX_TEST_CXXFLAG(GNU_XOP_CXXFLAG "-mxop" ACCELERATION_CXX_FLAGS)
 761         # No big deal if we do not have xop, so no point yelling warnings about it.
 762     endif()
 763
 764     # Only test the header after we have tried to add the flag for AVX support
 765     check_include_file(immintrin.h  HAVE_IMMINTRIN_H ${ACCELERATION_C_FLAGS})
 766
 767     if(NOT HAVE_IMMINTRIN_H)
 768         message(FATAL_ERROR "Cannot find immintrin.h, which is required for AVX intrinsics support. Consider switching compiler.")
 769     endif(NOT HAVE_IMMINTRIN_H)
 770
 771     if(${GMX_CPU_ACCELERATION} STREQUAL "AVX_256")
 772         try_compile(TEST_AVX ${CMAKE_BINARY_DIR}
 773             "${CMAKE_SOURCE_DIR}/cmake/TestAVX.c"
 774             COMPILE_DEFINITIONS "${ACCELERATION_C_FLAGS}")
 775         if(NOT TEST_AVX)
 776             message(FATAL_ERROR "Cannot compile AVX intrinsics. Consider switching compiler.")
 777         endif()
 778     endif()
 779
 780     # GCC requires x86intrin.h for FMA support. MSVC 2010 requires intrin.h for FMA support.
 781     check_include_file(x86intrin.h HAVE_X86INTRIN_H ${ACCELERATION_C_FLAGS})
 782     check_include_file(intrin.h HAVE_INTRIN_H ${ACCELERATION_C_FLAGS})
 783
 784     # The user should not be able to set this orthogonally to the acceleration
 785     set(GMX_X86_SSE4_1 1)
 786     set(GMX_X86_SSE2   1)
 787
 788     # But just enable one of the choices internally...
 789     if(${GMX_CPU_ACCELERATION} STREQUAL "AVX_128_FMA")
 790         set(GMX_CPU_ACCELERATION_X86_AVX_128_FMA 1)
 791         set(GMX_X86_AVX_128_FMA 1)
 792         if (NOT ACCELERATION_QUIETLY)
 793           message(STATUS "Enabling 128-bit AVX Gromacs acceleration (with fused-multiply add), and it will help compiler optimization.")
 794         endif()
 795
 796         # We don't have the full compiler version string yet (BUILD_C_COMPILER),
 797         # so we can't distinguish vanilla and Apple clang, but catering for AMD
 798         # hackintoshes is not worth the effort.
 799         if (APPLE AND (${CMAKE_C_COMPILER_ID} STREQUAL "Clang" OR
 800                     ${CMAKE_CXX_COMPILER_ID} STREQUAL "Clang"))
 801             message(WARNING "Due to a known compiler bug, Clang up to version 3.2 (and Apple Clang up to version 4.1) produces incorrect code with AVX_128_FMA acceleration. As we can not work around this bug on OS X, you will have to select a different compiler or CPU acceleration.")
 802         endif()
 803
 804         if (GMX_USE_CLANG_C_FMA_BUG_WORKAROUND)
 805             # we assume that we have an external assembler that supports AVX
 806             message(STATUS "Clang ${C_COMPILER_VERSION} detected, enabling FMA bug workaround")
 807             set(EXTRA_C_FLAGS "${EXTRA_C_FLAGS} -no-integrated-as")
 808         endif()
 809         if (GMX_USE_CLANG_CXX_FMA_BUG_WORKAROUND)
 810             # we assume that we have an external assembler that supports AVX
 811             message(STATUS "Clang ${CXX_COMPILER_VERSION} detected, enabling FMA bug workaround")
 812             set(EXTRA_CXX_FLAGS "${EXTRA_CXX_FLAGS} -no-integrated-as")
 813         endif()
 814
 815     else()
 816         # If we are not doing AVX_128, it must be AVX_256...
 817         set(GMX_CPU_ACCELERATION_X86_AVX_256 1)
 818         set(GMX_X86_AVX_256 1)
 819         if (NOT ACCELERATION_QUIETLY)
 820           message(STATUS "Enabling 256-bit AVX Gromacs acceleration, and it will help compiler optimization.")
 821         endif()
 822     endif()
 823
 824     # Unfortunately gcc-4.5.2 and gcc-4.6.0 has a bug where they use the wrong datatype for the formal
 825     # parameter of the mask for maskload/maskstore arguments. Check if this is present, since we can work around it.
 826     gmx_test_avx_gcc_maskload_bug(${ACCELERATION_C_FLAGS} GMX_X86_AVX_GCC_MASKLOAD_BUG)
 827
 828 elseif(${GMX_CPU_ACCELERATION} STREQUAL "IBM_QPX")
 829     # Used on BlueGene/Q
 830     if (CMAKE_C_COMPILER_ID MATCHES "XL")
 831         GMX_TEST_CFLAG(XLC_BLUEGENEQ_CFLAG "-qarch=qp -qtune=qp" ACCELERATION_C_FLAGS)
 832         try_compile(TEST_QPX ${CMAKE_BINARY_DIR}
 833             "${CMAKE_SOURCE_DIR}/cmake/TestQPX.c"
 834             COMPILE_DEFINITIONS "${ACCELERATION_C_FLAGS}")
 835         if(NOT TEST_QPX)
 836             message(FATAL_ERROR "Cannot compile the requested IBM QPX intrinsics.")
 837         endif()
 838     endif()
 839     if (CMAKE_CXX_COMPILER_ID MATCHES "XL")
 840         GMX_TEST_CXXFLAG(XLC_BLUEGENEQ_CXXFLAG "-qarch=qp -qtune=qp" ACCELERATION_CXX_FLAGS)
 841         try_compile(TEST_QPX ${CMAKE_BINARY_DIR}
 842             "${CMAKE_SOURCE_DIR}/cmake/TestQPX.c"
 843             COMPILE_DEFINITIONS "${ACCELERATION_CXX_FLAGS}")
 844         if(NOT TEST_QPX)
 845             message(FATAL_ERROR "Cannot compile the requested IBM QPX intrinsics.")
 846         endif()
 847     endif()
 848
 849     if (TEST_QPX)
 850         message(WARNING "IBM QPX acceleration was selected and could be compiled, but the accelerated kernels are not yet available.")
 851         set(GMX_CPU_ACCELERATION_IBM_QPX 1)
 852     else()
 853         message(FATAL_ERROR "Cannot compile IBM QPX intrinsics without the XL compiler. If you are compiling for BlueGene/Q, use 'cmake .. -DCMAKE_TOOLCHAIN_FILE=BlueGeneQ-static-XL-C' to set up the tool chain.")
 854     endif()
 855 elseif(${GMX_CPU_ACCELERATION} STREQUAL "SPARC64_HPC_ACE")
 856     set(GMX_CPU_ACCELERATION_SPARC64_HPC_ACE 1)
 857 else(${GMX_CPU_ACCELERATION} STREQUAL "NONE")
 858     MESSAGE(FATAL_ERROR "Unrecognized option for accelerated kernels: ${GMX_CPU_ACCELERATION}. Pick one of None, SSE2, SSE4.1, AVX_128_FMA, AVX_256, IBM_QPX, Sparc64_HPC_ACE")
 859 endif(${GMX_CPU_ACCELERATION} STREQUAL "NONE")
 860 set(ACCELERATION_QUIETLY TRUE CACHE INTERNAL "")
 861
 862 # Process QM/MM Settings
 863 string(TOUPPER ${GMX_QMMM_PROGRAM} GMX_QMMM_PROGRAM)
 864 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 865     set(GMX_QMMM_GAUSSIAN 1)
 866 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 867     set(GMX_QMMM_MOPAC 1)
 868 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 869     set(GMX_QMMM_GAMESS 1)
 870 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 871     set(GMX_QMMM_ORCA 1)
 872 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 873     # nothing to do
 874 else(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 875     MESSAGE(FATAL_ERROR "Invalid QM/MM program option: ${GMX_QMMM_PROGRAM}. Choose one of: Gaussian, Mopac, Gamess, Orca, None")
 876 endif(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 877
 878 # Process FFT library settings
 879 string(TOUPPER ${GMX_FFT_LIBRARY} GMX_FFT_LIBRARY)
 880 set(PKG_FFT "")
 881 set(PKG_FFT_LIBS "")
 882 set(MKL_LIBRARIES_FORMAT_DESCRIPTION "Use full paths to library files, in the right order, and separated by semicolons.")
 883 set(MKL_LIBRARIES "" CACHE STRING "List of libraries for linking to MKL. Only used with GMX_FFT_LIBRARY=mkl. ${MKL_LIBRARIES_FORMAT_DESCRIPTION}")
 884 set(MKL_INCLUDE_DIR "" CACHE PATH "Path to mkl.h (non-inclusive). Only used with GMX_FFT_LIBRARY=mkl.")
 885 mark_as_advanced(FORCE MKL_LIBRARIES)
 886 mark_as_advanced(FORCE MKL_INCLUDE_DIR)
 887 if(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 888     if(GMX_DOUBLE)
 889         set(FFTW fftw)
 890     else()
 891         set(FFTW fftwf)
 892     endif()
 893
 894     if(GMX_BUILD_OWN_FFTW)
 895       add_subdirectory(src/contrib/fftw)
 896     else()
 897       find_package(FFTW COMPONENTS ${FFTW})
 898     endif()
 899     if(NOT ${FFTW}_FOUND)
 900       MESSAGE(FATAL_ERROR "Cannot find FFTW 3 (with correct precision - libfftw3f for single-precision GROMACS or libfftw3 for double-precision GROMACS). Either choose the right precision, choose another FFT(W) library (-DGMX_FFT_LIBRARY), enable the advanced option to let GROMACS build FFTW 3 for you (-DGMX_BUILD_OWN_FFTW=ON) , or use the really slow GROMACS built-in fftpack library (-DGMX_FFT_LIBRARY=fftpack).")
 901     endif()
 902
 903     string(TOUPPER "${FFTW}" FFTW)
 904     set(PKG_FFT "${${FFTW}_PKG}")
 905     include_directories(${${FFTW}_INCLUDE_DIRS})
 906     set(FFT_LIBRARIES ${${FFTW}_LIBRARIES})
 907     set(GMX_FFT_FFTW3 1)
 908
 909     if ((${GMX_CPU_ACCELERATION} MATCHES "SSE" OR ${GMX_CPU_ACCELERATION} MATCHES "AVX") AND NOT ${FFTW}_HAVE_SIMD)
 910       message(WARNING "The fftw library found is compiled without SIMD support, which makes it slow. Consider recompiling it or contact your admin")
 911     endif()
 912
 913     if((${GMX_CPU_ACCELERATION} MATCHES "SSE" OR ${GMX_CPU_ACCELERATION} MATCHES "AVX") AND ${FFTW}_HAVE_AVX)
 914         # If we're not doing CPU acceleration, we don't care about FFTW performance on x86 either
 915         message(WARNING "The FFTW library was compiled with --enable-avx to enable AVX SIMD instructions. That might sound like a good idea for your processor, but for FFTW versions up to 3.3.3, these are slower than the SSE/SSE2 SIMD instructions for the way GROMACS uses FFTs. Limitations in the way FFTW allows GROMACS to measure performance make it awkward for either GROMACS or FFTW to make the decision for you based on runtime performance. You should compile a different FFTW library with --enable-sse or --enable-sse2. If you have a more recent FFTW, you may like to compare the performance of GROMACS with FFTW libraries compiled with and without --enable-avx. However, the GROMACS developers do not really expect the FFTW AVX optimization to help, because the performance is limited by memory access, not computation.")
 916     endif()
 917
 918     if(NOT "${GMX_FFT_LIBRARY}" STREQUAL "${GMX_FFT_LIBRARY_PREVIOUS_VALUE}")
 919         MESSAGE(STATUS "Using external FFT library - FFTW3")
 920     endif()
 921 elseif(${GMX_FFT_LIBRARY} STREQUAL "MKL")
 922     # Intel 11 and up makes life somewhat easy if you just want to use
 923     # all their stuff. It's not easy if you only want some of their
 924     # stuff...
 925     if (CMAKE_C_COMPILER_ID MATCHES "Intel" AND C_COMPILER_VERSION VERSION_GREATER "11")
 926         # The next line takes care of everything for MKL
 927         if (WIN32)
 928             set(FFT_LINKER_FLAGS "/Qmkl=sequential")
 929         else()
 930             set(FFT_LINKER_FLAGS "-mkl=sequential")
 931         endif()
 932         # Some versions of icc require this in order that mkl.h can be
 933         # found at compile time.
 934         set(EXTRA_C_FLAGS "${EXTRA_C_FLAGS} ${FFT_LINKER_FLAGS}")
 935
 936         set(MKL_ERROR_MESSAGE "Make sure you have configured your compiler so that ${FFT_LINKER_FLAGS} will work.")
 937     else()
 938         # The user will have to provide the set of magic libraries in
 939         # MKL_LIBRARIES, which we cache (non-advanced), so that they
 940         # don't have to keep specifying it, and can easily see that
 941         # CMake is still using that information.
 942         set(MKL_LIBRARIES "${MKL_LIBRARIES}" CACHE STRING "User-specified libraries for linking to MKL")
 943         mark_as_advanced(CLEAR MKL_LIBRARIES)
 944         include_directories(${MKL_INCLUDE_DIR})
 945         mark_as_advanced(CLEAR MKL_INCLUDE_DIR)
 946         set(FFT_LIBRARIES "${MKL_LIBRARIES}")
 947         set(MKL_ERROR_MESSAGE "The include path to mkl.h in MKL_INCLUDE_DIR, and the link libraries in MKL_LIBRARIES=${MKL_LIBRARIES} need to match what the MKL documentation says you need for your system. ${MKL_LIBRARIES_FORMAT_DESCRIPTION}")
 948         # Convert the semi-colon separated list to a list of
 949         # command-line linker arguments so that code using our
 950         # pkgconfig setup can use it.
 951         string(REGEX REPLACE ";" " " PKG_FFT_LIBS "${MKL_LIBRARIES}")
 952     endif()
 953
 954     # Check MKL works. If we were in a non-global scope, we wouldn't
 955     # have to play nicely.
 956     set(old_CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS}")
 957     set(CMAKE_REQUIRED_FLAGS "${FFT_LINKER_FLAGS}")
 958     set(old_CMAKE_REQUIRED_LIBRARIES "${CMAKE_REQUIRED_LIBRARIES}")
 959     set(CMAKE_REQUIRED_LIBRARIES "${FFT_LIBRARIES}")
 960
 961     check_function_exists(DftiCreateDescriptor TEST_MKL)
 962
 963     set(CMAKE_REQUIRED_FLAGS "${old_CMAKE_REQUIRED_FLAGS}")
 964     set(CMAKE_REQUIRED_LIBRARIES "${old_CMAKE_REQUIRED_LIBRARIES}")
 965
 966     if(NOT TEST_MKL)
 967         # Hack to help the user vary MKL settings until they work.
 968         # TODO Make this logic more useful.
 969         unset(TEST_MKL CACHE)
 970         message(FATAL_ERROR "Linking with MKL was requested, but was not successful. ${MKL_ERROR_MESSAGE}")
 971     endif()
 972
 973     # Set variables to signal that we have MKL available and should use it for FFTs.
 974     set(GMX_FFT_MKL 1)
 975     set(HAVE_LIBMKL 1)
 976
 977     if(NOT "${GMX_FFT_LIBRARY}" STREQUAL "${GMX_FFT_LIBRARY_PREVIOUS_VALUE}")
 978         MESSAGE(STATUS "Using external FFT library - Intel MKL")
 979     endif()
 980 elseif(${GMX_FFT_LIBRARY} STREQUAL "FFTPACK")
 981     set(GMX_FFT_FFTPACK 1)
 982     if(NOT "${GMX_FFT_LIBRARY}" STREQUAL "${GMX_FFT_LIBRARY_PREVIOUS_VALUE}")
 983         MESSAGE(STATUS "Using internal FFT library - fftpack")
 984     endif()
 985 else(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 986     MESSAGE(FATAL_ERROR "Invalid FFT library setting: ${GMX_FFT_LIBRARY}. Choose one of: fftw3, mkl, fftpack")
 987 endif(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 988 set(GMX_FFT_LIBRARY_PREVIOUS_VALUE ${GMX_FFT_LIBRARY} CACHE INTERNAL "Previous value for GMX_FFT_LIBRARY, so that we can detect when it changes.")
 989
 990 # enable threaded fftw3 if we've found it
 991 if(FFTW3_THREADS OR FFTW3F_THREADS)
 992     add_definitions(-DFFT5D_FFTW_THREADS)
 993 endif()
 994
 995 include(gmxManageLinearAlgebraLibraries)
 996
 997 # Whether GROMACS will really try to compile support for VMD plugins
 998 set(GMX_USE_PLUGINS OFF)
 999
1000 if(GMX_LOAD_PLUGINS)
1001   if(CYGWIN OR NOT WIN32)
1002     # Native Windows does not have, nor need dlopen
1003     # Note that WIN32 is set with Cygwin, but Cygwin needs dlopen to use plug-ins
1004     include(gmxTestdlopen)
1005     gmx_test_dlopen(HAVE_DLOPEN)
1006   endif()
1007
1008   # so, should we use plug-ins?
1009   if((WIN32 AND NOT CYGWIN) OR (HAVE_DLOPEN AND BUILD_SHARED_LIBS))
1010     if(NOT VMD_QUIETLY)
1011       MESSAGE(STATUS
1012           "Found the ability to use plug-ins when building shared libaries, "
1013           "so will compile to use plug-ins (e.g. to read VMD-supported file "
1014           "formats).")
1015     endif()
1016     if(NOT GMX_VMD_PLUGIN_PATH)
1017       find_package(VMD)
1018     endif()
1019     set(GMX_USE_PLUGINS ON)
1020     list(APPEND GMX_EXTRA_LIBRARIES ${CMAKE_DL_LIBS}) # magic cross-platform pre-set variable for dlopen library
1021     set(PKG_DL_LIBS "-l${CMAKE_DL_LIBS}")
1022   else()
1023     set(PKG_DL_LIBS)
1024   endif()
1025 endif(GMX_LOAD_PLUGINS)
1026 set(VMD_QUIETLY TRUE CACHE INTERNAL "")
1027
1028 if(EXISTS "${CMAKE_SOURCE_DIR}/admin/.isreposource")
1029     if(NOT CMAKE_CROSSCOMPILING)
1030         option(GMX_BUILD_MANPAGES "Build man pages" ON)
1031     else()
1032         message(STATUS "Building the man pages is not available when "
1033             "cross-compiling the developer version from git")
1034     endif()
1035 else()
1036     #make sure source package contains all man pages
1037     if(NOT EXISTS "${CMAKE_SOURCE_DIR}/man/man1/ngmx.1")
1038         message(FATAL_ERROR "Man pages are missing from source package.")
1039     endif()
1040 endif()
1041 mark_as_advanced(GMX_BUILD_MANPAGES)
1042
1043 # Math and thread libraries must often come after all others when linking...
1044 if(HAVE_LIBM)
1045     list(APPEND GMX_EXTRA_LIBRARIES m)
1046 endif(HAVE_LIBM)
1047
1048 if(GMX_FAHCORE)
1049   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
1050       "Path to swindirect.h")
1051   include_directories(${COREWRAP_INCLUDE_DIR})
1052   set_property(CACHE GMX_COOL_QUOTES PROPERTY VALUE OFF)
1053 endif(GMX_FAHCORE)
1054
1055 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
1056 # these are set after everything else
1057 if (NOT GMX_SKIP_DEFAULT_CFLAGS)
1058     set(CMAKE_C_FLAGS "${ACCELERATION_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${CMAKE_C_FLAGS}")
1059     set(CMAKE_CXX_FLAGS "${ACCELERATION_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${GMX_CXX11_FLAGS} ${EXTRA_CXX_FLAGS} ${CMAKE_CXX_FLAGS}")
1060     set(CMAKE_EXE_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}")
1061     set(CMAKE_SHARED_LINKER_FLAGS "${MPI_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS}")
1062 else()
1063     message("Recommended flags which are not added because GMX_SKIP_DEFAULT_CFLAGS=yes:")
1064     message("CMAKE_C_FLAGS: ${ACCELERATION_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${GMXC_CFLAGS}")
1065     message("CMAKE_C_FLAGS_RELEASE: ${GMXC_CFLAGS_RELEASE}")
1066     message("CMAKE_C_FLAGS_DEBUG: ${GMXC_CFLAGS_DEBUG}")
1067     message("CMAKE_CXX_FLAGS: ${ACCELERATION_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${GMX_CXX11_FLAGS} ${EXTRA_CXX_FLAGS} ${GMXC_CXXFLAGS}")
1068     message("CMAKE_CXX_FLAGS_RELEASE: ${GMXC_CXXFLAGS_RELEASE}")
1069     message("CMAKE_CXX_FLAGS_DEBUG: ${GMXC_CXXFLAGS_DEBUG}")
1070     message("CMAKE_EXE_LINKER_FLAGS: ${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS}")
1071     message("CMAKE_SHARED_LINKER_FLAGS: ${MPI_LINKER_FLAGS}")
1072 endif()
1073
1074 if(NOT GMX_OPENMP)
1075     #Unset all OpenMP flags in case OpenMP was disabled either by the user
1076     #or because it was only partially detected (e.g. only for C but not C++ compiler)
1077     unset(OpenMP_C_FLAGS CACHE)
1078     unset(OpenMP_CXX_FLAGS CACHE)
1079 else()
1080     set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} ${OpenMP_LINKER_FLAGS})
1081     set(GMX_SHARED_LINKER_FLAGS ${GMX_SHARED_LINKER_FLAGS} ${OpenMP_SHARED_LINKER_FLAGS})
1082 endif()
1083 set(PKG_CFLAGS "${PKG_CFLAGS} ${OpenMP_C_FLAGS}")
1084
1085 ######################################
1086 # Output compiler and CFLAGS used
1087 ######################################
1088 get_compiler_info(C BUILD_C_COMPILER BUILD_CFLAGS)
1089 get_compiler_info(CXX BUILD_CXX_COMPILER BUILD_CXXFLAGS)
1090 if(GMX_GPU)
1091     get_cuda_compiler_info(CUDA_NVCC_COMPILER_INFO CUDA_NVCC_COMPILER_FLAGS)
1092 endif(GMX_GPU)
1093
1094 ########################################################################
1095 # Specify install locations
1096 ########################################################################
1097 if ( NOT DEFINED GMXLIB )
1098     set(GMXLIB lib)
1099 endif()
1100 set(LIB_INSTALL_DIR "${GMX_INSTALL_PREFIX}${GMXLIB}")
1101 set(BIN_INSTALL_DIR  ${GMX_INSTALL_PREFIX}bin)
1102 set(DATA_INSTALL_DIR ${GMX_INSTALL_PREFIX}share/gromacs)
1103 set(MAN_INSTALL_DIR  ${GMX_INSTALL_PREFIX}share/man)
1104 set(INCL_INSTALL_DIR ${GMX_INSTALL_PREFIX}include)
1105
1106 set(GMXLIBDIR        ${DATA_INSTALL_DIR}/top)
1107
1108 ########################################################################
1109 # Set up binary and library suffixing
1110 ########################################################################
1111 set(GMX_BINARY_SUFFIX "" CACHE STRING "Suffix for GROMACS binaries (default: _d for double, _mpi for MPI, _mpi_d for MPI and double).")
1112 set(GMX_LIBS_SUFFIX ""
1113   CACHE STRING "Suffix for GROMACS libs (default: _d for double, _mpi for MPI, _mpi_d for MPI and double).")
1114 if (GMX_DEFAULT_SUFFIX)
1115   set(GMX_BINARY_SUFFIX "")
1116   set(GMX_LIBS_SUFFIX "")
1117   if (GMX_LIB_MPI)
1118     set(GMX_BINARY_SUFFIX "_mpi")
1119     set(GMX_LIBS_SUFFIX "_mpi")
1120   endif()
1121   if (GMX_DOUBLE)
1122     set (GMX_BINARY_SUFFIX "${GMX_BINARY_SUFFIX}_d")
1123     set (GMX_LIBS_SUFFIX "${GMX_LIBS_SUFFIX}_d")
1124   endif(GMX_DOUBLE)
1125   mark_as_advanced(FORCE GMX_BINARY_SUFFIX GMX_LIBS_SUFFIX)
1126   if (NOT SUFFIX_QUIETLY)
1127     message(STATUS "Using default binary suffix: \"${GMX_BINARY_SUFFIX}\"")
1128     message(STATUS "Using default library suffix: \"${GMX_LIBS_SUFFIX}\"")
1129   endif (NOT SUFFIX_QUIETLY)
1130 else(GMX_DEFAULT_SUFFIX)
1131   mark_as_advanced(CLEAR GMX_BINARY_SUFFIX GMX_LIBS_SUFFIX)
1132   if (NOT SUFFIX_QUIETLY)
1133     message(STATUS "Using manually set binary suffix: \"${GMX_BINARY_SUFFIX}\"")
1134     message(STATUS "Using manually set library suffix: \"${GMX_LIBS_SUFFIX}\"")
1135   endif (NOT SUFFIX_QUIETLY)
1136 endif(GMX_DEFAULT_SUFFIX)
1137 if (GMX_BUILD_MDRUN_ONLY)
1138     set(GMX_LIBS_SUFFIX "_mdrun${GMX_LIBS_SUFFIX}")
1139 endif ()
1140 set(SUFFIX_QUIETLY TRUE CACHE INTERNAL "")
1141
1142 ##################################################################
1143 # Shared library settings
1144 ##################################################################
1145 if(NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin")
1146     set(CMAKE_SKIP_BUILD_RPATH  FALSE)
1147     set(CMAKE_BUILD_WITH_INSTALL_RPATH FALSE)
1148     set(CMAKE_INSTALL_RPATH "\\\$ORIGIN/../${GMXLIB}")
1149     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
1150 else()
1151     if(CMAKE_SYSTEM_VERSION VERSION_GREATER 8.0) #rpath supported for >10.4
1152         set(CMAKE_INSTALL_NAME_DIR "@rpath")
1153         set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} "-Wl,-rpath,@executable_path/../lib")
1154     else()
1155         set(CMAKE_INSTALL_NAME_DIR "${CMAKE_INSTALL_PREFIX}/${LIB_INSTALL_DIR}")
1156     endif()
1157 endif()
1158
1159 #COPYING file: Only necessary for binary distributions.
1160 #Simpler to always install.
1161 install(FILES COPYING DESTINATION ${DATA_INSTALL_DIR} COMPONENT data)
1162
1163 if(GMX_EXTERNAL_BOOST)
1164     include_directories(${Boost_INCLUDE_DIRS})
1165 else()
1166     include_directories(${CMAKE_SOURCE_DIR}/src/external/boost)
1167     # typeid not supported for minimal internal version
1168     # (would add significant amount of code)
1169     add_definitions(-DBOOST_NO_TYPEID)
1170     # TODO: Propagate the above settings to the installed CMakeFiles.txt template
1171     # (from share/template/)
1172     set(PKG_CFLAGS "${PKG_CFLAGS} -DBOOST_NO_TYPEID -I${INCL_INSTALL_DIR}/gromacs/external/boost")
1173     if (NOT GMX_BUILD_MDRUN_ONLY)
1174         install(DIRECTORY ${CMAKE_SOURCE_DIR}/src/external/boost/boost
1175                 DESTINATION ${INCL_INSTALL_DIR}/gromacs/external/boost
1176                 COMPONENT development)
1177     endif ()
1178 endif()
1179
1180 if (GMX_BUILD_FOR_COVERAGE)
1181     # Code heavy with asserts makes conditional coverage close to useless metric,
1182     # as by design most of the false branches are impossible to trigger in
1183     # correctly functioning code.  And the benefit of testing those that could
1184     # be triggered by using an API against its specification isn't usually
1185     # worth the effort.
1186     add_definitions(-DNDEBUG -DBOOST_DISABLE_ASSERTS -DGMX_DISABLE_ASSERTS)
1187 endif ()
1188
1189 if (NOT GMX_BUILD_MDRUN_ONLY)
1190     add_subdirectory(doxygen)
1191     add_subdirectory(share)
1192     add_subdirectory(scripts)
1193 endif ()
1194 add_subdirectory(src)
1195
1196 # Issue a warning if NVIDIA GPUs were detected, but CUDA was not found.
1197 # Don't bother the user after the first configure pass.
1198 if ((CUDA_NOTFOUND_AUTO AND GMX_DETECT_GPU_AVAILABLE) AND NOT GMX_GPU_DETECTION_DONE)
1199     message(WARNING "${CUDA_NOTFOUND_MESSAGE}")
1200 endif()
1201 set(GMX_GPU_DETECTION_DONE TRUE CACHE INTERNAL "Whether GPU detection has already been done")
1202
1203 #######################
1204 ## uninstall target
1205 #######################
1206     CONFIGURE_FILE(
1207                    "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
1208                    "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
1209                    IMMEDIATE @ONLY)
1210 ###########################
1211 ADD_CUSTOM_TARGET(uninstall
1212                   "${CMAKE_COMMAND}" -P
1213                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
1214 ###########################
1215
1216 ########################################################################
1217 # Tests                                                                #
1218 ########################################################################
1219
1220 include(CTest)
1221 mark_as_advanced(BUILD_TESTING)
1222 IF(BUILD_TESTING)
1223     enable_testing()
1224     #"check" target builds and runs all tests
1225     add_custom_target(check COMMAND ${CMAKE_CTEST_COMMAND} --output-on-failure)
1226     add_dependencies(check tests)
1227     # TODO: This would be better within tests/CMakeLists.txt
1228     if (NOT GMX_BUILD_MDRUN_ONLY)
1229         #gmxtests target builds all binaries required for running gmxtest
1230         add_custom_target(gmxtests DEPENDS gmx links)
1231         add_dependencies(check gmxtests)
1232         add_subdirectory(tests)
1233     endif()
1234     #TODO: Add warning if NOT REGRESSIONTEST_PATH OR NOT GMX_XML that regression/unit tests are not run.
1235 ENDIF()
1236