CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.6)
   2
   3 project(Gromacs)
   4 include(Dart)
   5 mark_as_advanced(DART_ROOT)
   6 # PROJECT_VERSION should have the following structure:
   7 # VERSION[-dev-SUFFIX] where the VERSION can have any form and the suffix
   8 set(PROJECT_VERSION "4.5.1")
   9 set(CUSTOM_VERSION_STRING ""
  10     CACHE STRING "Custom version string (if empty, use hard-coded default)")
  11 mark_as_advanced(CUSTOM_VERSION_STRING)
  12 if (CUSTOM_VERSION_STRING)
  13     set(PROJECT_VERSION ${CUSTOM_VERSION_STRING})
  14 endif (CUSTOM_VERSION_STRING)
  15 set(SOVERSION 6)
  16 # It is a bit irritating, but this has to be set separately for now!
  17 SET(CPACK_PACKAGE_VERSION_MAJOR "4")
  18 SET(CPACK_PACKAGE_VERSION_MINOR "5")
  19 SET(CPACK_PACKAGE_VERSION_PATCH "1")
  20
  21
  22 # Cmake modules/macros are in a subdirectory to keep this file cleaner
  23 set(CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake)
  24
  25 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
  26 set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
  27 endif()
  28
  29 if(NOT CMAKE_BUILD_TYPE)
  30     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel." FORCE)
  31 endif(NOT CMAKE_BUILD_TYPE)
  32
  33 enable_language(C)
  34
  35 set(CPACK_PACKAGE_VERSION ${PROJECT_VERSION})
  36 set(CPACK_PACKAGE_VENDOR "gromacs.org")
  37 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Gromacs - a toolkit for high-performance molecular simulation")
  38 set(CPACK_SET_DESTDIR "ON")
  39 set(CPACK_INCLUDE_TOPLEVEL_DIRECTORY 0)
  40 set(CPACK_RESOURCE_FILE_WELCOME "${CMAKE_SOURCE_DIR}/admin/InstallWelcome.txt")
  41 # Its GPL/LGPL, so they do not have to agree to a license for mere usage, but some installers require this...
  42 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_SOURCE_DIR}/admin/InstallLicense.txt")
  43 set(CPACK_RESOURCE_FILE_README "${CMAKE_SOURCE_DIR}/admin/InstallInfo.txt")
  44
  45 #must come after all cpack settings!
  46 include(CPack)
  47
  48
  49 ########################################################################
  50 # Fix stupid flags on MSVC
  51 ########################################################################
  52 SET(SHARED_LIBS_DEFAULT ON)
  53 IF(CMAKE_GENERATOR MATCHES "Visual Studio")
  54     STRING(REPLACE /MD /MT CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE})
  55     SET(CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE} CACHE STRING "" FORCE)
  56     STRING(REPLACE /MD /MT CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG})
  57     SET(CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG} CACHE STRING "" FORCE)
  58     SET(SHARED_LIBS_DEFAULT OFF)
  59 ENDIF(CMAKE_GENERATOR MATCHES "Visual Studio")
  60
  61 set(GMX_EXTRA_LIBRARIES)
  62
  63
  64
  65 ######################################################################
  66 # compiler tests
  67 # these need ot be done early (before further tests).
  68 #####################################################################
  69
  70 include(CheckCCompilerFlag)
  71 include(CheckCXXCompilerFlag)
  72
  73 include(gmxCFlags)
  74 gmx_c_flags()
  75
  76 ########################################################################
  77 # User input options                                                   #
  78 ########################################################################
  79 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" OFF)
  80 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
  81 option(GMX_THREADS    "Build a parallel (thread-based) version of GROMACS (cannot be combined with MPI yet)" ON)
  82 option(GMX_SOFTWARE_INVSQRT "Use GROMACS software 1/sqrt" ON)
  83 mark_as_advanced(GMX_SOFTWARE_INVSQRT)
  84 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
  85 mark_as_advanced(GMX_FAHCORE)
  86 option(GMX_OPENMM "Accelerated execution on GPUs through the OpenMM library (rerun cmake after changing to see relevant options)" OFF)
  87 set(GMX_ACCELERATION "auto"
  88     CACHE STRING "Accelerated kernels. Pick one of: auto, none, SSE, BlueGene, Power6, ia64, altivec")
  89
  90 set(GMX_FFT_LIBRARY "fftw3"
  91     CACHE STRING "FFT library choices: fftw3,fftw2,mkl,fftpack[built-in]")
  92 option(GMX_DISABLE_FFTW_MEASURE
  93        "Do not optimize FFTW setups (not needed with SSE)" OFF)
  94 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
  95 set(GMX_QMMM_PROGRAM "none"
  96     CACHE STRING "QM package choices: none,gaussian,mopac,gamess,orca")
  97 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
  98 mark_as_advanced(GMX_BROKEN_CALLOC)
  99 option(BUILD_SHARED_LIBS "Enable shared libraries (can be problematic with MPI, Windows)" ${SHARED_LIBS_DEFAULT})
 100 option(GMX_MPI_IN_PLACE "Enable MPI_IN_PLACE for MPIs that have it defined" ON)
 101 mark_as_advanced(GMX_MPI_IN_PLACE)
 102 option(GMX_DLOPEN "Compile with dlopen, needed to read VMD supported file formats" ON)
 103 mark_as_advanced(GMX_DLOPEN)
 104
 105
 106 option(GMX_IA32_ASM "Add SSE assembly files for IA32" OFF)
 107 mark_as_advanced(GMX_IA32_ASM)
 108 option(GMX_X86_64_ASM "Add SSE assembly files for X86_64" OFF)
 109 mark_as_advanced(GMX_X86_64_ASM)
 110
 111 option(USE_VERSION_H "Generate development version string/information" ON)
 112 mark_as_advanced(USE_VERSION_H)
 113
 114 option(GMX_DEFAULT_SUFFIX "Use default suffixes for GROMACS binaries and libs (_d for double, _mpi for MPI; rerun cmake after changing to see relevant options)" ON)
 115
 116 ########################################################################
 117 # Set up binary and library suffixing
 118 ########################################################################
 119 set(GMX_BINARY_SUFFIX "" CACHE STRING "Suffix for GROMACS binaries (default: _d for double, _mpi for MPI, _mpi_d for MPI and double).")
 120 set(GMX_LIBS_SUFFIX ""
 121   CACHE STRING "Suffix for GROMACS libs (default: _d for double, _mpi for MPI, _mpi_d for MPI and double).")
 122 if (GMX_DEFAULT_SUFFIX)
 123   set(GMX_BINARY_SUFFIX "")
 124   set(GMX_LIBS_SUFFIX "")
 125   if (GMX_MPI)
 126     set(GMX_BINARY_SUFFIX "_mpi")
 127     set(GMX_LIBS_SUFFIX "_mpi")
 128   endif(GMX_MPI)
 129   if (GMX_DOUBLE)
 130     set (GMX_BINARY_SUFFIX "${GMX_BINARY_SUFFIX}_d")
 131     set (GMX_LIBS_SUFFIX "${GMX_LIBS_SUFFIX}_d")
 132   endif(GMX_DOUBLE)
 133   mark_as_advanced(FORCE GMX_BINARY_SUFFIX GMX_LIBS_SUFFIX)
 134   message(STATUS "Using default binary suffix: \"${GMX_BINARY_SUFFIX}\"")
 135   message(STATUS "Using default library suffix: \"${GMX_LIBS_SUFFIX}\"")
 136 else(GMX_DEFAULT_SUFFIX)
 137   mark_as_advanced(CLEAR GMX_BINARY_SUFFIX GMX_LIBS_SUFFIX)
 138   message(STATUS "Using manually set binary suffix: \"${GMX_BINARY_SUFFIX}\"")
 139   message(STATUS "Using manually set library suffix: \"${GMX_LIBS_SUFFIX}\"")
 140 endif(GMX_DEFAULT_SUFFIX)
 141
 142 set(PKG_CFLAGS "")
 143 if(GMX_DOUBLE)
 144     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_DOUBLE")
 145 endif(GMX_DOUBLE)
 146 if(GMX_SOFTWARE_INVSQRT)
 147   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_SOFTWARE_INVSQRT")
 148 endif(GMX_SOFTWARE_INVSQRT)
 149
 150 ########################################################################
 151 #Process MPI settings
 152 ########################################################################
 153 if(GMX_MPI)
 154         MESSAGE(WARNING "
 155             There are known problems with some MPI implementations:
 156                      OpenMPI version < 1.4.1
 157                      MVAPICH2 version <= 1.4.1                               *")
 158     if(GMX_THREADS)
 159         #message(FATAL_ERROR "Thread-based parallelization conflicts with MPI.")
 160         set(GMX_THREADS OFF CACHE BOOL
 161             "Thread-based parallelization conflicts with MPI." FORCE)
 162     endif(GMX_THREADS)
 163     find_package(MPI)
 164     if(MPI_FOUND)
 165         set(GROMACS_C_FLAGS ${GROMACS_FLAGS} ${MPI_COMPILE_FLAGS})
 166         set(GROMACS_LINKER_FLAGS ${GROMACS_LINKER_FLAGS} ${MPI_LINK_FLAGS})
 167
 168         include_directories(${MPI_INCLUDE_PATH})
 169         list(APPEND GMX_EXTRA_LIBRARIES ${MPI_LIBRARIES})
 170         add_definitions( -DMPI ) #for FAHCORE
 171         include(gmxTestMPI_IN_PLACE)
 172         if (GMX_MPI_IN_PLACE)
 173             gmx_test_mpi_in_place(MPI_IN_PLACE_EXISTS)
 174         endif (GMX_MPI_IN_PLACE)
 175     else(MPI_FOUND)
 176         message(FATAL_ERROR "MPI support requested, but no MPI compiler found.")
 177     endif(MPI_FOUND)
 178     include(gmxTestCatamount)
 179     gmx_test_catamount(GMX_CRAY_XT3)
 180     if(GMX_CRAY_XT3)
 181         set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_CRAY_XT3")
 182         set(GMX_NO_SYSTEM 1)
 183         set(GMX_NO_NICE 1)
 184     endif(GMX_CRAY_XT3)
 185     set(GMX_LIB_MPI 1)
 186     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_LIB_MPI")
 187 endif(GMX_MPI)
 188
 189
 190 #######################################################################
 191 # Check for options incompatible with OpenMM build                    #
 192 #######################################################################
 193 if(GMX_OPENMM)
 194     cmake_minimum_required(VERSION 2.6.4)
 195     # we'll use the built-in fft to avoid unnecessary dependencies
 196     string(TOUPPER ${GMX_FFT_LIBRARY} GMX_FFT_LIBRARY)
 197     if(NOT ${GMX_FFT_LIBRARY} STREQUAL "FFTPACK")
 198         message(STATUS "No external FFT libraries needed for the OpenMM build, switching to fftpack!")
 199         set(GMX_FFT_LIBRARY "fftpack" CACHE STRING
 200                 "No external FFT libraries needed for the OpenMM build, switching to  fftpack!" FORCE)
 201     endif()
 202     if(GMX_MPI)
 203         message(FATAL_ERROR "The OpenMM build is not compatible with MPI!")
 204     endif(GMX_MPI)
 205     if(GMX_THREADS)
 206         message(STATUS "Threads are  not compatible with OpenMM build, disabled!")
 207         set(GMX_THREADS OFF CACHE BOOL
 208                 "Threads are not compatible with OpenMM build, disabled!" FORCE)
 209     endif(GMX_THREADS)
 210     if(GMX_SOFTWARE_INVSQRT)
 211         set(GMX_SOFTWARE_INVSQRT OFF CACHE STRING
 212                 "The OpenMM build does not need GROMACS software 1/sqrt!" FORCE)
 213     endif(GMX_SOFTWARE_INVSQRT)
 214     string(TOUPPER ${GMX_ACCELERATION} GMX_ACCELERATION)
 215     if(NOT GMX_ACCELERATION STREQUAL "NONE")
 216         message(STATUS "Switching off CPU-based acceleration, the OpenMM build does not support/need any!")
 217         set(GMX_ACCELERATION "none" CACHE STRING
 218                 "Switching off CPU-based acceleration, the OpenMM build does not support/need any!" FORCE)
 219     endif()
 220     if(GMX_FAHCORE)
 221         message(FATAL_ERROR "The OpenMM build does not support FAH build!")
 222     endif(GMX_FAHCORE)
 223     if(GMX_DOUBLE)
 224         message(FATAL_ERROR  "The OpenMM-build does not support double precision calculations!")
 225     endif()
 226     # mark as advanced the unused variables
 227     mark_as_advanced(FORCE GMX_ACCELERATION GMX_MPI GMX_FFT_LIBRARY
 228         GMX_QMMM_PROGRAM GMX_THREADS GMX_DOUBLE)
 229 else(GMX_OPENMM)
 230      mark_as_advanced(CLEAR GMX_ACCELERATION GMX_MPI GMX_FFT_LIBRARY
 231         GMX_QMMM_PROGRAM GMX_THREADS GMX_DOUBLE)
 232 endif(GMX_OPENMM)
 233
 234
 235 ########################################################################
 236 # Basic system tests (standard libraries, headers, functions, types)   #
 237 ########################################################################
 238 include(CheckIncludeFiles)
 239 check_include_files(string.h     HAVE_STRING_H)
 240 check_include_files(math.h       HAVE_MATH_H)
 241 check_include_files(limits.h     HAVE_LIMITS_H)
 242 check_include_files(memory.h     HAVE_MEMORY_H)
 243 check_include_files(unistd.h     HAVE_UNISTD_H)
 244 check_include_files(pwd.h        HAVE_PWD_H)
 245 check_include_files(stdint.h     HAVE_STDINT_H)
 246 check_include_files(stdlib.h     HAVE_STDLIB_H)
 247 check_include_files(pthread.h    HAVE_PTHREAD_H)
 248 check_include_files(dirent.h     HAVE_DIRENT_H)
 249 check_include_files(inttypes.h   HAVE_INTTYPES_H)
 250 check_include_files(regex.h      HAVE_REGEX_H)
 251 check_include_files(sys/types.h  HAVE_SYS_TYPES_H)
 252 check_include_files(sys/stat.h   HAVE_SYS_STAT_H)
 253 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 254 check_include_files(rpc/rpc.h    HAVE_RPC_RPC_H)
 255 check_include_files("rpc/rpc.h;rpc/xdr.h"    HAVE_RPC_XDR_H)
 256 # SSE support
 257 check_include_files(xmmintrin.h  HAVE_XMMINTRIN_H)
 258 check_include_files(emmintrin.h  HAVE_EMMINTRIN_H)
 259 check_include_files(pmmintrin.h  HAVE_PMMINTRIN_H)
 260 check_include_files(smmintrin.h  HAVE_SMMINTRIN_H)
 261 check_include_files(io.h                 HAVE_IO_H)
 262
 263
 264 include(CheckFunctionExists)
 265 check_function_exists(strcasecmp        HAVE_STRCASECMP)
 266 check_function_exists(strdup            HAVE_STRDUP)
 267 check_function_exists(vprintf           HAVE_VPRINTF)
 268 check_function_exists(memcmp            HAVE_MEMCMP)
 269 check_function_exists(posix_memalign    HAVE_POSIX_MEMALIGN)
 270 check_function_exists(memalign          HAVE_MEMALIGN)
 271 check_function_exists(_aligned_malloc   HAVE__ALIGNED_MALLOC)
 272 check_function_exists(gettimeofday      HAVE_GETTIMEOFDAY)
 273 check_function_exists(isnan             HAVE_ISNAN)
 274 check_function_exists(_isnan            HAVE__ISNAN)
 275 check_function_exists(isfinite          HAVE_ISFINITE)
 276 check_function_exists(_isfinite         HAVE__ISFINITE)
 277 check_function_exists(fsync             HAVE_FSYNC)
 278 check_function_exists(_fileno           HAVE__FILENO)
 279 check_function_exists(fileno            HAVE_FILENO)
 280 check_function_exists(_commit           HAVE__COMMIT)
 281
 282 include(CheckLibraryExists)
 283 check_library_exists(m sqrt "" HAVE_LIBM)
 284 check_library_exists(m cbrt "" HAVE_CBRT)
 285
 286
 287 include(CheckTypeSize)
 288
 289 check_type_size("bool"          SIZEOF_BOOL) # will also set HAVE_BOOL
 290 check_type_size("int"           SIZEOF_INT)
 291 check_type_size("long int"      SIZEOF_LONG_INT)
 292 check_type_size("long long int" SIZEOF_LONG_LONG_INT)
 293 check_type_size("off_t"         SIZEOF_OFF_T)
 294 check_type_size("void *"        SIZEOF_VOIDP)
 295
 296 if (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 297     set(GMX_64_BIT TRUE)
 298 else (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 299     set(GMX_64_BIT FALSE)
 300 endif (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 301
 302 # Check for some basic types that we *need*, so set these to int if they are not present
 303 check_type_size(uid_t uid_t)
 304 if(NOT uid_t)
 305   set(uid_t int)
 306 else(NOT uid_t)
 307   set(uid_t 0)
 308 endif(NOT uid_t)
 309
 310 check_type_size(gid_t gid_t)
 311 if(NOT gid_t)
 312   set(gid_t 1)
 313 else(NOT gid_t)
 314   set(gid_t 0)
 315 endif(NOT gid_t)
 316
 317 check_type_size(size_t size_t)
 318 if(NOT size_t)
 319   set(size_t int)
 320 else(NOT size_t)
 321   set(size_t 0)
 322 endif(NOT size_t)
 323
 324 check_type_size(off_t off_t)
 325 if(NOT off_t)
 326   set(off_t int)
 327 else(NOT off_t)
 328   set(off_t 0)
 329 endif(NOT off_t)
 330
 331 include(TestBigEndian)
 332 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 333
 334
 335
 336
 337 ########################################################################
 338 # Find external packages                                               #
 339 ########################################################################
 340
 341 find_package(LibXml2)
 342 set(PKG_XML "")
 343 if(LIBXML2_FOUND)
 344     include_directories(${LIBXML2_INCLUDE_DIR})
 345     set(PKG_XML libxml-2.0)
 346     set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 347     set(HAVE_LIBXML2 1)
 348 endif(LIBXML2_FOUND)
 349
 350 option(GMX_X11 "Use X window system" OFF)
 351 if (GMX_X11)
 352         find_package(X11)
 353         # X11 includes/libraries are only set in the ngmx subdirectory!
 354         if(X11_FOUND)
 355         set(HAVE_X11 1)
 356         endif(X11_FOUND)
 357 endif(GMX_X11)
 358
 359 if(GMX_THREADS)
 360     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_THREADS")
 361     include(ThreadMPI)
 362     set(THREAD_MPI_LIB thread_mpi)
 363     set(GMX_MPI 1)
 364     string(TOUPPER ${GMX_FFT_LIBRARY} ${GMX_FFT_LIBRARY})
 365     if(${GMX_FFT_LIBRARY} STREQUAL "FFTW2")
 366         message(FATAL_ERROR "FFTW2 can't be used with threads. Try fftw3 or mkl.")
 367     endif()
 368 endif(GMX_THREADS)
 369
 370 if(GMX_OPENMM)
 371     set(CUDA_BUILD_EMULATION OFF)
 372     find_package(CUDA 3.1 REQUIRED)
 373     add_definitions(-DGMX_OPENMM)
 374     if(CMAKE_BUILD_TYPE STREQUAL "DEBUG")
 375         set(CUDA_VERBOSE_BUILD ON)
 376     endif()
 377     find_package(OpenMM)
 378 endif(GMX_OPENMM)
 379
 380 if(APPLE)
 381    find_library(ACCELERATE_FRAMEWORK Accelerate)
 382    list(APPEND GMX_EXTRA_LIBRARIES ${ACCELERATE_FRAMEWORK})
 383 endif(APPLE)
 384
 385 # only bother with finding git and using version.h if the source is a git repo
 386 if(EXISTS "${CMAKE_SOURCE_DIR}/.git")
 387     if(USE_VERSION_H)
 388         # We need at least git v1.5.1 be able to parse git's date output. If not
 389         # fund or the version is too small, we can't generate version information.
 390         find_package(Git 1.5.1)
 391         # this should at some point become VERSION_LESS
 392         if(NOT Git_FOUND OR Git_VERSION STRLESS "1.5.1")
 393             message("No compatible git version found, won't be able to generate proper development version information.")
 394             set(USE_VERSION_H OFF)
 395         endif()
 396     endif()
 397 else()
 398     set(USE_VERSION_H OFF)
 399 endif()
 400
 401 if (GMX_DLOPEN)
 402     list(APPEND GMX_EXTRA_LIBRARIES ${CMAKE_DL_LIBS})
 403 endif (GMX_DLOPEN)
 404
 405 ########################################################################
 406 # Generate development version info for cache
 407 ########################################################################
 408 # set(GEN_VERSION_INFO_INTERNAL "ON")
 409 # include(gmxGenerateVersionString)
 410
 411 ########################################################################
 412 # Our own GROMACS tests
 413 ########################################################################
 414
 415 add_definitions( -DHAVE_CONFIG_H )
 416 include_directories(${CMAKE_BINARY_DIR}/src)
 417 include_directories(${CMAKE_SOURCE_DIR}/include)
 418
 419 include(gmxCheckBuildUserTime)
 420 gmx_check_build_user_time(BUILD_TIME BUILD_USER BUILD_MACHINE)
 421
 422 include(gmxTestFloatFormat)
 423 gmx_test_float_format(GMX_FLOAT_FORMAT_IEEE754
 424                       GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER
 425                       GMX_IEEE754_BIG_ENDIAN_WORD_ORDER)
 426
 427 include(gmxTestLargeFiles)
 428 gmx_test_large_files(GMX_LARGEFILES)
 429 check_function_exists(fseeko     HAVE_FSEEKO)
 430
 431 include(gmxTestSignal)
 432 gmx_test_retsigtype(RETSIGTYPE)
 433 gmx_test_sigusr1(HAVE_SIGUSR1)
 434
 435 include(gmxTestInline)
 436 gmx_test_inline(INLINE_KEYWORD)
 437
 438 include(gmxTestRestrict)
 439 gmx_test_inline(RESTRICT_KEYWORD)
 440
 441 include(gmxTestPipes)
 442 gmx_test_pipes(HAVE_PIPES)
 443
 444 include(gmxTestInlineASM)
 445 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 446 gmx_test_inline_asm_msvc_x86(GMX_X86_MSVC_INLINE_ASM)
 447
 448 # turn on SSE if supported with reasonable defaults.
 449 if (${GMX_ACCELERATION} STREQUAL "auto" AND NOT GMX_OPENMM)
 450   if(CMAKE_SYSTEM_PROCESSOR MATCHES "^(i.86|x86|x64|x86_64|AMD64|amd64)")
 451
 452     set(GMX_ACCELERATION "SSE" CACHE STRING "Accelerated kernels. Pick one of: auto, none, SSE, BlueGene, Power6, ia64, altivec" FORCE)
 453
 454     if (GMX_64_BIT)
 455       set(GMX_X86_64_ASM ON CACHE BOOL "Add SSE assembly files for x86_64" FORCE)
 456     else (GMX_64_BIT)
 457       set(GMX_IA32_ASM ON CACHE BOOL "Add SSE assembly files for i386" FORCE)
 458     endif (GMX_64_BIT)
 459
 460     # Determine the assembler/compiler to use
 461   else()
 462     set(GMX_ACCELERATION "none" CACHE STRING "Accelerated kernels. Pick one of: auto, none, SSE, BlueGene, Power6, ia64, altivec" FORCE)
 463   endif()
 464 endif (${GMX_ACCELERATION} STREQUAL "auto" AND NOT GMX_OPENMM)
 465
 466
 467 include(gmxTestXDR)
 468 gmx_test_xdr(GMX_SYSTEM_XDR)
 469 if(NOT GMX_SYSTEM_XDR)
 470     set(GMX_INTERNAL_XDR 1)
 471     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_INTERNAL_XDR")
 472 endif(NOT GMX_SYSTEM_XDR)
 473
 474 if(GMX_FORTRAN OR GMX_POWER6)
 475     enable_language(Fortran)
 476     include(FortranCInterface)
 477     discover_fortran_mangling(prefix isupper suffix extra_under_score found)
 478     if(extra_under_score)
 479         set(extrasuffix "_")
 480     endif(extra_under_score)
 481
 482     if(isupper)
 483         set(F77_FUNCDEF   "${prefix} ## NAME ## ${suffix}")
 484         set(F77_FUNCDEF_  "${prefix} ## NAME ## ${suffix}${extrasuffix}")
 485     else(isupper)
 486         set(F77_FUNCDEF   "${prefix} ## name ## ${suffix}")
 487         set(F77_FUNCDEF_  "${prefix} ## name ## ${suffix}${extrasuffix}")
 488     endif(isupper)
 489 else(GMX_FORTRAN OR GMX_POWER6)
 490         set(F77_FUNCDEF   "name ## _")
 491         set(F77_FUNCDEF_  "name ## _")
 492 endif(GMX_FORTRAN OR GMX_POWER6)
 493
 494
 495 # Process nonbonded accelerated kernels settings
 496 string(TOUPPER ${GMX_ACCELERATION} ${GMX_ACCELERATION})
 497 if(${GMX_ACCELERATION} STREQUAL "NONE")
 498   # nothing to do
 499 elseif(${GMX_ACCELERATION} STREQUAL "SSE")
 500
 501     if(CMAKE_GENERATOR MATCHES "Visual Studio")
 502       option(GMX_ASM_USEASM-NASM "Use Nasm for assembly instead of compiler (necessary on windows)" ON)
 503     else()
 504       option(GMX_ASM_USEASM-NASM "Use Nasm for assembly instead of compiler (necessary on windows)" OFF)
 505     endif()
 506         mark_as_advanced(GMX_ASM_USEASM-NASM)
 507
 508     if (NOT GMX_64_BIT)
 509         # for 32-bit compiles, we might need to turn on sse
 510         CHECK_C_COMPILER_FLAG("-msse2" XFLAGS_SSE)
 511         if (XFLAGS_SSE)
 512             set(GROMACS_C_FLAGS "-msse2 ${GROMACS_C_FLAGS}")
 513         endif (XFLAGS_SSE)
 514         CHECK_CXX_COMPILER_FLAG("-msse2" XXFLAGS_SSE)
 515         if (XXFLAGS_SSE)
 516             set(GROMACS_CXX_FLAGS "-msse2 ${GROMACS_CXX_FLAGS}")
 517         endif (XXFLAGS_SSE)
 518     endif (NOT GMX_64_BIT)
 519
 520     if(GMX_IA32_ASM)
 521       if(GMX_DOUBLE)
 522         set(GMX_IA32_SSE2 1)
 523       else()
 524         set(GMX_IA32_SSE 1)
 525       endif()
 526     elseif(GMX_X86_64_ASM)
 527       if(GMX_DOUBLE)
 528         set(GMX_X86_64_SSE2 1)
 529       else()
 530         set(GMX_X86_64_SSE 1)
 531       endif()
 532     endif()
 533
 534 #    if(HAVE_PMMINTRIN_H)
 535 #        set(GMX_SSE3 1)
 536 #    endif(HAVE_PMMINTRIN_H)
 537 #    if(HAVE_SMMINTRIN_H)
 538 #        set(GMX_SSE4_1 1)
 539 #    endif(HAVE_SMMINTRIN_H)
 540
 541 elseif(${GMX_ACCELERATION} STREQUAL "FORTRAN")
 542     set(GMX_FORTRAN 1)
 543 elseif(${GMX_ACCELERATION} STREQUAL "BLUEGENE")
 544     set(GMX_BLUEGENE 1)
 545 elseif(${GMX_ACCELERATION} STREQUAL "POWER6")
 546     set(GMX_POWER6 1)
 547 elseif(${GMX_ACCELERATION} STREQUAL "IA64")
 548     set(GMX_IA64_ASM 1)
 549     set(DISABLE_WATERWATER_NLIST 1)
 550     set(DISABLE_WATER_NLIST 1)
 551 elseif(${GMX_ACCELERATION} STREQUAL "ALTIVEC")
 552     check_include_files(altivec.h HAVE_ALTIVEC_H)
 553     if(HAVE_ALTIVEC_H)
 554         set(GMX_PPC_ALTIVEC 1)
 555     endif(HAVE_ALTIVEC_H)
 556 else(${GMX_ACCELERATION} STREQUAL "NONE")
 557     MESSAGE(FATAL_ERROR "Unrecognized option for accelerated kernels: ${GMX_ACCELERATION}. Pick one of auto, none, SSE, Fortran, BlueGene, Power6, ia64, altivec")
 558 endif(${GMX_ACCELERATION} STREQUAL "NONE")
 559
 560
 561 if(GMX_FORTRAN)
 562     if (GMX_THREADS)
 563         message(WARNING "FORTRAN is incompatible with threads. Disable threads or FORTRAN kernels")
 564     endif()
 565 endif()
 566
 567
 568
 569
 570
 571 # Process QM/MM Settings
 572 string(TOUPPER ${GMX_QMMM_PROGRAM} ${GMX_QMMM_PROGRAM})
 573 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 574     set(GMX_QMMM_GAUSSIAN 1)
 575 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 576     set(GMX_QMMM_MOPAC 1)
 577 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 578     set(GMX_QMMM_GAMESS 1)
 579 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 580     set(GMX_QMMM_ORCA 1)
 581 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 582     # nothing to do
 583 else(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 584     MESSAGE(FATAL_ERROR "Invalid QM/MM program option: ${GMX_QMMM_PROGRAM}. Choose one of: Gaussian, Mopac, Gamess, Orca, None")
 585 endif(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 586
 587 # Process FFT library settings - if not OpenMM build
 588 string(TOUPPER ${GMX_FFT_LIBRARY} ${GMX_FFT_LIBRARY})
 589 set(PKG_FFT "")
 590 set(PKG_FFT_LIBS "")
 591 if(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 592 #    MESSAGE(STATUS "Using external FFT library - fftw3")
 593     if(GMX_DOUBLE)
 594         find_package(FFTW3 REQUIRED)
 595                 include_directories(${FFTW3_INCLUDE_DIR})
 596         set(FFT_LIBRARIES ${FFTW3_LIBRARIES})
 597         set(PKG_FFT "fftw3")
 598     else(GMX_DOUBLE)
 599         find_package(FFTW3F REQUIRED)
 600         include_directories(${FFTW3F_INCLUDE_DIR})
 601         set(FFT_LIBRARIES ${FFTW3F_LIBRARIES})
 602         set(PKG_FFT "fftw3f")
 603     endif(GMX_DOUBLE)
 604
 605     if(NOT FFTW3_FOUND AND NOT FFTW3F_FOUND)
 606         MESSAGE(FATAL_ERROR "Cannot find fftw3 (with correct precision). Fix it, choose another FFT library, or use the Gromacs built-in fftpack (slower)!")
 607     endif(NOT FFTW3_FOUND AND NOT FFTW3F_FOUND)
 608
 609     set(GMX_FFT_FFTW3 1)
 610
 611 elseif(${GMX_FFT_LIBRARY} STREQUAL "FFTW2")
 612 #    MESSAGE(STATUS "Using external FFT library - fftw2")
 613     if(GMX_DOUBLE)
 614         find_package(FFTW2 REQUIRED)
 615     else(GMX_DOUBLE)
 616         find_package(FFTW2F REQUIRED)
 617     endif(GMX_DOUBLE)
 618
 619     if(NOT FFTW2_FOUND)
 620            MESSAGE(FATAL_ERROR "Cannot find fftw2 (with correct precision). Fix it, choose another FFT library, or use the Gromacs built-in fftpack (slower)!")
 621     endif(NOT FFTW2_FOUND)
 622     include_directories(${FFTW2_INCLUDE_DIR})
 623     set(FFT_LIBRARIES ${FFTW2_LIBRARIES})
 624     set(PKG_FFT_LIBS ${FFTW2_LIBRARIES})
 625
 626     if("${FFTW2_LIBRARIES}" MATCHES "dfftw")
 627         set(FFTW2_NAME_DFFTW 1)
 628     elseif("${FFTW2_LIBRARIES}" MATCHES "sfftw")
 629         set(FFTW2_NAME_SFFTW 1)
 630     else("${FFTW2_LIBRARIES}" MATCHES "dfftw")
 631         set(FFTW2_NAME_FFTW 1)
 632     endif("${FFTW2_LIBRARIES}" MATCHES "dfftw")
 633
 634     set(GMX_FFT_FFTW2 1)
 635 elseif(${GMX_FFT_LIBRARY} STREQUAL "MKL")
 636 #    MESSAGE(STATUS "Using external FFT library - Intel MKL")
 637     find_package(MKL REQUIRED)
 638     include_directories(${MKL_INCLUDE_DIR})
 639     set(FFT_LIBRARIES ${MKL_LIBRARIES})
 640     set(PKG_FFT_LIBS ${MKL_LIBRARIES})
 641
 642     set(GMX_FFT_MKL 1)
 643     set(HAVE_MKL 1)
 644
 645 #elseif(${GMX_FFT_LIBRARY} STREQUAL "ACML")
 646 #    MESSAGE(STATUS "Using external FFT library - AMD core math library")
 647 #    set(GMX_FFT_ACML 1)
 648 elseif(${GMX_FFT_LIBRARY} STREQUAL "FFTPACK")
 649     MESSAGE(STATUS "Using internal FFT library - fftpack")
 650     set(GMX_FFT_FFTPACK 1)
 651 else(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 652     MESSAGE(FATAL_ERROR "Invalid FFT library setting: ${GMX_FFT_LIBRARY}. Choose one of: fftw3, fftw2, mkl, acml, fftpack")
 653 endif(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 654
 655 # MKL has BLAS/LAPACK routines
 656 if(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 657   set(GMX_EXTERNAL_BLAS TRUE CACHE BOOL "Use external BLAS instead of built-in")
 658   set(GMX_EXTERNAL_LAPACK TRUE CACHE BOOL "Use external LAPACK instead of built-in")
 659 else(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 660   set(GMX_EXTERNAL_BLAS FALSE CACHE BOOL "Use external LAPACK instead of built-in")
 661   set(GMX_EXTERNAL_LAPACK FALSE CACHE BOOL "Use external LAPACK instead of built-in")
 662 endif(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 663 mark_as_advanced(GMX_EXTERNAL_LAPACK)
 664 mark_as_advanced(GMX_EXTERNAL_BLAS)
 665
 666 # Math and thread libraries must often come after all others when linking...
 667 if(HAVE_LIBM)
 668     list(APPEND GMX_EXTRA_LIBRARIES m)
 669 endif(HAVE_LIBM)
 670
 671
 672
 673 if(GMX_FAHCORE)
 674   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 675       "Path to swindirect.h")
 676   include_directories(${COREWRAP_INCLUDE_DIR})
 677 endif(GMX_FAHCORE)
 678
 679 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 680 # these are set after everything else
 681 if (NOT DEFINED GROMACS_C_FLAGS_SET)
 682     set(GROMACS_C_FLAGS_SET true CACHE INTERNAL "Whether to reset the C flags"
 683         FORCE)
 684     set(CMAKE_C_FLAGS "${GROMACS_C_FLAGS} ${CMAKE_C_FLAGS}" CACHE STRING
 685         "Flags used by the compiler during all build types" FORCE)
 686     set(CMAKE_CXX_FLAGS "${GROMACS_CXX_FLAGS} ${CMAKE_CXX_FLAGS}" CACHE STRING
 687         "Flags used by the compiler during all build types" FORCE)
 688     set(CMAKE_EXE_LINKER_FLAGS
 689         "${GROMACS_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}"
 690         CACHE STRING "Linker flags" FORCE)
 691 endif (NOT DEFINED GROMACS_C_FLAGS_SET)
 692
 693 ########################################################################
 694 # Specify install locations and which subdirectories to process        #
 695 ########################################################################
 696 set(LIB_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/lib)
 697 set(BIN_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/bin)
 698 set(DATA_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/gromacs)
 699 set(MAN_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/share/man)
 700 set(INCL_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/include)
 701
 702 set(GMXLIBDIR        ${DATA_INSTALL_DIR}/top)
 703
 704 ##################################################################
 705 # Shared library settings - Darwin uses INSTALL_NAME_DIR instead!
 706 ##################################################################
 707 if(NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin")
 708     set(CMAKE_SKIP_BUILD_RPATH  FALSE)
 709     set(CMAKE_BUILD_WITH_INSTALL_RPATH TRUE)
 710     set(CMAKE_INSTALL_RPATH "${LIB_INSTALL_DIR}")
 711     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 712 endif()
 713
 714 add_subdirectory(share)
 715 add_subdirectory(include)
 716 add_subdirectory(man)
 717 add_subdirectory(src)
 718 add_subdirectory(scripts)
 719
 720 #######################
 721 ## uninstall target
 722 #######################
 723     CONFIGURE_FILE(
 724                    "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 725                    "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
 726                    IMMEDIATE @ONLY)
 727 ###########################
 728 ADD_CUSTOM_TARGET(uninstall
 729                   "${CMAKE_COMMAND}" -P
 730                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
 731 ###########################
 732
 733
 734 ########################################################################
 735 # Tests                                                                #
 736 ########################################################################
 737
 738 include(CTest)
 739 mark_as_advanced(BUILD_TESTING)
 740 IF(BUILD_TESTING)
 741         enable_testing()
 742         add_test(TestBuildAll make)
 743         add_subdirectory(tests)
 744 ENDIF()
 745