CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.8)
   2 # Keep CMake suitably quiet on Cygwin
   3 set(CMAKE_LEGACY_CYGWIN_WIN32 0) # Remove when CMake >= 2.8.4 is required
   4
   5 project(Gromacs)
   6 include(Dart)
   7 mark_as_advanced(DART_ROOT)
   8
   9 # PROJECT_VERSION should have the following structure:
  10 # VERSION-dev[-SUFFIX] where the VERSION should have the for: vMajor.vMinor.vPatch
  11 #
  12 # The "-dev" suffix is important to keep because it makes possible to distinguish
  13 # between a build from official release and a build from git release branch on a
  14 # machine with no git.
  15 #
  16 # NOTE: when releasing the "-dev" suffix needs to be stripped off!
  17 set(PROJECT_VERSION "4.6-dev")
  18 set(CUSTOM_VERSION_STRING ""
  19     CACHE STRING "Custom version string (if empty, use hard-coded default)")
  20 mark_as_advanced(CUSTOM_VERSION_STRING)
  21 if (CUSTOM_VERSION_STRING)
  22     set(PROJECT_VERSION ${CUSTOM_VERSION_STRING})
  23 endif (CUSTOM_VERSION_STRING)
  24 set(SOVERSION 6)
  25 # It is a bit irritating, but this has to be set separately for now!
  26 SET(CPACK_PACKAGE_VERSION_MAJOR "4")
  27 SET(CPACK_PACKAGE_VERSION_MINOR "6")
  28 #SET(CPACK_PACKAGE_VERSION_PATCH "0")
  29
  30
  31 # Cmake modules/macros are in a subdirectory to keep this file cleaner
  32 set(CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake)
  33
  34 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
  35 set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
  36 endif()
  37
  38 if(NOT CMAKE_BUILD_TYPE)
  39     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel." FORCE)
  40 endif(NOT CMAKE_BUILD_TYPE)
  41
  42 enable_language(C)
  43
  44 set(CPACK_PACKAGE_VERSION ${PROJECT_VERSION})
  45 set(CPACK_PACKAGE_VENDOR "gromacs.org")
  46 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Gromacs - a toolkit for high-performance molecular simulation")
  47 set(CPACK_SET_DESTDIR "ON")
  48 set(CPACK_INCLUDE_TOPLEVEL_DIRECTORY 0)
  49 set(CPACK_RESOURCE_FILE_WELCOME "${CMAKE_SOURCE_DIR}/admin/InstallWelcome.txt")
  50 # Its GPL/LGPL, so they do not have to agree to a license for mere usage, but some installers require this...
  51 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_SOURCE_DIR}/admin/InstallLicense.txt")
  52 set(CPACK_RESOURCE_FILE_README "${CMAKE_SOURCE_DIR}/admin/InstallInfo.txt")
  53
  54 #must come after all cpack settings!
  55 include(CPack)
  56
  57 ########################################################################
  58 # Check and warn if cache generated on a different host is being reused
  59 ########################################################################
  60 if(CMAKE_HOST_UNIX)
  61     execute_process(COMMAND hostname
  62                     OUTPUT_VARIABLE TMP_HOSTNAME
  63                     OUTPUT_STRIP_TRAILING_WHITESPACE)
  64     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}")
  65         message(WARNING "
  66             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
  67             is being reused! This could lead to inconsitencies; therefore, it is
  68             recommended to regenerate the cache!")
  69     endif()
  70     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
  71             "Hostname of the machine where the cache was generated.")
  72 endif()
  73
  74 ########################################################################
  75 # Fix stupid flags on Windows
  76 ########################################################################
  77 SET(SHARED_LIBS_DEFAULT ON)
  78 IF( (CMAKE_GENERATOR MATCHES "Visual Studio" OR CMAKE_GENERATOR MATCHES "NMake") AND MSVC )
  79     STRING(REPLACE /MD /MT CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE})
  80     SET(CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE} CACHE STRING "" FORCE)
  81     STRING(REPLACE /MD /MT CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG})
  82     SET(CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG} CACHE STRING "" FORCE)
  83     SET(SHARED_LIBS_DEFAULT OFF)
  84 ENDIF()
  85
  86 IF(CMAKE_GENERATOR MATCHES "NMake" AND CMAKE_C_COMPILER_ID MATCHES "Intel")
  87     STRING(REPLACE /GZ /RTC1 CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE})
  88     SET(CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE} CACHE STRING "" FORCE)
  89     STRING(REPLACE /GZ /RTC1 CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG})
  90     SET(CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG} CACHE STRING "" FORCE)
  91     SET(SHARED_LIBS_DEFAULT OFF)
  92 ENDIF()
  93
  94 set(GMX_EXTRA_LIBRARIES)
  95
  96
  97
  98 ######################################################################
  99 # compiler tests
 100 # these need ot be done early (before further tests).
 101 #####################################################################
 102
 103 include(CheckCCompilerFlag)
 104 include(CheckCXXCompilerFlag)
 105
 106 include(gmxCFlags)
 107 gmx_c_flags()
 108
 109 ########################################################################
 110 # User input options                                                   #
 111 ########################################################################
 112 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" OFF)
 113 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 114 option(GMX_THREAD_MPI  "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" ON)
 115 option(GMX_SOFTWARE_INVSQRT "Use GROMACS software 1/sqrt" ON)
 116 mark_as_advanced(GMX_SOFTWARE_INVSQRT)
 117 option(GMX_POWERPC_INVSQRT "Use PowerPC hardware 1/sqrt" OFF)
 118 mark_as_advanced(GMX_POWERPC_INVSQRT)
 119 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 120 mark_as_advanced(GMX_FAHCORE)
 121 option(GMX_OPENMM "Accelerated execution on GPUs through the OpenMM library (rerun cmake after changing to see relevant options)" OFF)
 122 set(GMX_ACCELERATION "auto"
 123     CACHE STRING "Accelerated kernels. Pick one of: auto, none, SSE, BlueGene, Power6, ia64, altivec, fortran")
 124
 125 set(GMX_FFT_LIBRARY "fftw3"
 126     CACHE STRING "FFT library choices: fftw3,mkl,fftpack[built-in]")
 127 option(GMX_DISABLE_FFTW_MEASURE
 128        "Do not optimize FFTW setups (not needed with SSE)" OFF)
 129 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 130 set(GMX_QMMM_PROGRAM "none"
 131     CACHE STRING "QM package choices: none,gaussian,mopac,gamess,orca")
 132 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 133 mark_as_advanced(GMX_BROKEN_CALLOC)
 134 option(BUILD_SHARED_LIBS "Enable shared libraries (can be problematic with MPI, Windows)" ${SHARED_LIBS_DEFAULT})
 135 option(GMX_MPI_IN_PLACE "Enable MPI_IN_PLACE for MPIs that have it defined" ON)
 136 mark_as_advanced(GMX_MPI_IN_PLACE)
 137 option(GMX_LOAD_PLUGINS "Compile with plugin support, needed to read VMD supported file formats" ON)
 138 mark_as_advanced(GMX_LOAD_PLUGINS)
 139
 140
 141 option(GMX_IA32_ASM "Add SSE assembly files for IA32" OFF)
 142 mark_as_advanced(GMX_IA32_ASM)
 143 option(GMX_X86_64_ASM "Add SSE assembly files for X86_64" OFF)
 144 mark_as_advanced(GMX_X86_64_ASM)
 145
 146 option(GMX_OPENMP "Enable OpenMP-based mutithreading. " ON)
 147
 148 option(USE_VERSION_H "Generate development version string/information" ON)
 149 mark_as_advanced(USE_VERSION_H)
 150
 151 option(GMX_DEFAULT_SUFFIX "Use default suffixes for GROMACS binaries and libs (_d for double, _mpi for MPI; rerun cmake after changing to see relevant options)" ON)
 152
 153 if(UNIX AND NOT APPLE)
 154     option(GMX_PREFER_STATIC_LIBS "When finding libraries prefer \".a\" static archives (NOTE: this is enabled only for UNIX (excluding APPLE) platforms but it might not always work!" OFF)
 155     mark_as_advanced(GMX_PREFER_STATIC_LIBS)
 156 endif()
 157
 158 ########################################################################
 159 # Set up binary and library suffixing
 160 ########################################################################
 161 set(GMX_BINARY_SUFFIX "" CACHE STRING "Suffix for GROMACS binaries (default: _d for double, _mpi for MPI, _mpi_d for MPI and double).")
 162 set(GMX_LIBS_SUFFIX ""
 163   CACHE STRING "Suffix for GROMACS libs (default: _d for double, _mpi for MPI, _mpi_d for MPI and double).")
 164 if (GMX_DEFAULT_SUFFIX)
 165   set(GMX_BINARY_SUFFIX "")
 166   set(GMX_LIBS_SUFFIX "")
 167   if (GMX_MPI)
 168     set(GMX_BINARY_SUFFIX "_mpi")
 169     set(GMX_LIBS_SUFFIX "_mpi")
 170   endif(GMX_MPI)
 171   if (GMX_DOUBLE)
 172     set (GMX_BINARY_SUFFIX "${GMX_BINARY_SUFFIX}_d")
 173     set (GMX_LIBS_SUFFIX "${GMX_LIBS_SUFFIX}_d")
 174   endif(GMX_DOUBLE)
 175   if (GMX_OPENMM)
 176     set (GMX_BINARY_SUFFIX "-gpu")
 177     set (GMX_LIBS_SUFFIX "_gpu")
 178   endif(GMX_OPENMM)
 179   mark_as_advanced(FORCE GMX_BINARY_SUFFIX GMX_LIBS_SUFFIX)
 180   if (NOT SUFFIX_QUIETLY)
 181     message(STATUS "Using default binary suffix: \"${GMX_BINARY_SUFFIX}\"")
 182     message(STATUS "Using default library suffix: \"${GMX_LIBS_SUFFIX}\"")
 183   endif (NOT SUFFIX_QUIETLY)
 184 else(GMX_DEFAULT_SUFFIX)
 185   mark_as_advanced(CLEAR GMX_BINARY_SUFFIX GMX_LIBS_SUFFIX)
 186   if (NOT SUFFIX_QUIETLY)
 187     message(STATUS "Using manually set binary suffix: \"${GMX_BINARY_SUFFIX}\"")
 188     message(STATUS "Using manually set library suffix: \"${GMX_LIBS_SUFFIX}\"")
 189   endif (NOT SUFFIX_QUIETLY)
 190 endif(GMX_DEFAULT_SUFFIX)
 191 set(SUFFIX_QUIETLY TRUE CACHE INTERNAL "")
 192
 193 set(PKG_CFLAGS "")
 194 if(GMX_DOUBLE)
 195     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_DOUBLE")
 196 endif(GMX_DOUBLE)
 197 if(GMX_SOFTWARE_INVSQRT)
 198   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_SOFTWARE_INVSQRT")
 199 endif(GMX_SOFTWARE_INVSQRT)
 200 if(GMX_POWERPC_INVSQRT)
 201   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_POWERPC_INVSQRT")
 202 endif(GMX_POWERPC_INVSQRT)
 203
 204 ########################################################################
 205 #Process MPI settings
 206 ########################################################################
 207 include(gmxManageMPI)
 208
 209 #######################################################################
 210 # Check for options incompatible with OpenMM build                    #
 211 #######################################################################
 212 if(GMX_OPENMM)
 213     cmake_minimum_required(VERSION 2.6.4)
 214     # we'll use the built-in fft to avoid unnecessary dependencies
 215     string(TOUPPER ${GMX_FFT_LIBRARY} GMX_FFT_LIBRARY)
 216     if(NOT ${GMX_FFT_LIBRARY} STREQUAL "FFTPACK")
 217         message(STATUS "No external FFT libraries needed for the OpenMM build, switching to fftpack!")
 218         set(GMX_FFT_LIBRARY "fftpack" CACHE STRING
 219                 "No external FFT libraries needed for the OpenMM build, switching to  fftpack!" FORCE)
 220     endif()
 221     if(GMX_MPI)
 222         message(FATAL_ERROR "The OpenMM build is not compatible with MPI!")
 223     endif(GMX_MPI)
 224     if(GMX_THREAD_MPI)
 225         message(STATUS "Thread-MPI not compatible with OpenMM, disabled!")
 226         set(GMX_THREAD_MPI OFF CACHE BOOL
 227                 "Thread-MPI not compatible with OpenMM build, disabled!" FORCE)
 228     endif(GMX_THREAD_MPI)
 229     if(GMX_OPENMP)
 230         message(STATUS "OpenMP multithreading not compatible with OpenMM, disabled")
 231         set(GMX_OPENMP OFF CACHE BOOL
 232             "OpenMP multithreading not compatible with OpenMM, disabled!" FORCE)
 233     endif()
 234     if(GMX_SOFTWARE_INVSQRT)
 235         set(GMX_SOFTWARE_INVSQRT OFF CACHE STRING
 236                 "The OpenMM build does not need GROMACS software 1/sqrt!" FORCE)
 237     endif(GMX_SOFTWARE_INVSQRT)
 238     string(TOUPPER ${GMX_ACCELERATION} GMX_ACCELERATION)
 239     if(NOT GMX_ACCELERATION STREQUAL "NONE")
 240         message(STATUS "Switching off CPU-based acceleration, the OpenMM build does not support/need any!")
 241         set(GMX_ACCELERATION "none" CACHE STRING
 242                 "Switching off CPU-based acceleration, the OpenMM build does not support/need any!" FORCE)
 243     endif()
 244     if(GMX_FAHCORE)
 245         message(FATAL_ERROR "The OpenMM build does not support FAH build!")
 246     endif(GMX_FAHCORE)
 247     if(GMX_DOUBLE)
 248         message(FATAL_ERROR  "The OpenMM-build does not support double precision calculations!")
 249     endif()
 250     # mark as advanced the unused variables
 251     mark_as_advanced(FORCE GMX_ACCELERATION GMX_MPI GMX_FFT_LIBRARY
 252         GMX_QMMM_PROGRAM GMX_THREAD_MPI GMX_DOUBLE)
 253 else(GMX_OPENMM)
 254      mark_as_advanced(CLEAR GMX_ACCELERATION GMX_MPI GMX_FFT_LIBRARY
 255         GMX_QMMM_PROGRAM GMX_THREAD_MPI GMX_DOUBLE)
 256 endif(GMX_OPENMM)
 257
 258
 259 ########################################################################
 260 # Basic system tests (standard libraries, headers, functions, types)   #
 261 ########################################################################
 262 include(CheckIncludeFiles)
 263 check_include_files(string.h     HAVE_STRING_H)
 264 check_include_files(math.h       HAVE_MATH_H)
 265 check_include_files(limits.h     HAVE_LIMITS_H)
 266 check_include_files(memory.h     HAVE_MEMORY_H)
 267 check_include_files(unistd.h     HAVE_UNISTD_H)
 268 check_include_files(direct.h     HAVE_DIRECT_H)
 269 check_include_files(pwd.h        HAVE_PWD_H)
 270 check_include_files(stdint.h     HAVE_STDINT_H)
 271 check_include_files(stdlib.h     HAVE_STDLIB_H)
 272 check_include_files(pthread.h    HAVE_PTHREAD_H)
 273 check_include_files(dirent.h     HAVE_DIRENT_H)
 274 check_include_files(inttypes.h   HAVE_INTTYPES_H)
 275 check_include_files(regex.h      HAVE_REGEX_H)
 276 check_include_files(sys/types.h  HAVE_SYS_TYPES_H)
 277 check_include_files(sys/stat.h   HAVE_SYS_STAT_H)
 278 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 279 check_include_files(rpc/rpc.h    HAVE_RPC_RPC_H)
 280 check_include_files("rpc/rpc.h;rpc/xdr.h"    HAVE_RPC_XDR_H)
 281 # SSE support
 282 check_include_files(xmmintrin.h  HAVE_XMMINTRIN_H)
 283 check_include_files(emmintrin.h  HAVE_EMMINTRIN_H)
 284 check_include_files(pmmintrin.h  HAVE_PMMINTRIN_H)
 285 check_include_files(smmintrin.h  HAVE_SMMINTRIN_H)
 286 check_include_files(io.h                 HAVE_IO_H)
 287
 288
 289 include(CheckFunctionExists)
 290 check_function_exists(strcasecmp        HAVE_STRCASECMP)
 291 check_function_exists(strdup            HAVE_STRDUP)
 292 check_function_exists(vprintf           HAVE_VPRINTF)
 293 check_function_exists(memcmp            HAVE_MEMCMP)
 294 check_function_exists(posix_memalign    HAVE_POSIX_MEMALIGN)
 295 check_function_exists(memalign          HAVE_MEMALIGN)
 296 check_function_exists(_aligned_malloc   HAVE__ALIGNED_MALLOC)
 297 check_function_exists(gettimeofday      HAVE_GETTIMEOFDAY)
 298 check_function_exists(isnan             HAVE_ISNAN)
 299 check_function_exists(_isnan            HAVE__ISNAN)
 300 check_function_exists(fsync             HAVE_FSYNC)
 301 check_function_exists(_fileno           HAVE__FILENO)
 302 check_function_exists(fileno            HAVE_FILENO)
 303 check_function_exists(_commit           HAVE__COMMIT)
 304
 305 include(CheckLibraryExists)
 306 check_library_exists(m sqrt "" HAVE_LIBM)
 307 check_library_exists(m cbrt "" HAVE_CBRT)
 308
 309
 310 include(CheckTypeSize)
 311
 312 check_type_size("bool"          SIZEOF_BOOL) # will also set HAVE_BOOL
 313 check_type_size("int"           SIZEOF_INT)
 314 check_type_size("long int"      SIZEOF_LONG_INT)
 315 check_type_size("long long int" SIZEOF_LONG_LONG_INT)
 316 check_type_size("off_t"         SIZEOF_OFF_T)
 317 check_type_size("void *"        SIZEOF_VOIDP)
 318
 319 if (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 320     set(GMX_64_BIT TRUE)
 321 else (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 322     set(GMX_64_BIT FALSE)
 323 endif (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 324
 325 # Check for some basic types that we *need*, so set these to int if they are not present
 326 check_type_size(uid_t uid_t)
 327 if(NOT uid_t)
 328   set(uid_t int)
 329 else(NOT uid_t)
 330   set(uid_t 0)
 331 endif(NOT uid_t)
 332
 333 check_type_size(gid_t gid_t)
 334 if(NOT gid_t)
 335   set(gid_t 1)
 336 else(NOT gid_t)
 337   set(gid_t 0)
 338 endif(NOT gid_t)
 339
 340 check_type_size(size_t size_t)
 341 if(NOT size_t)
 342   set(size_t int)
 343 else(NOT size_t)
 344   set(size_t 0)
 345 endif(NOT size_t)
 346
 347 check_type_size(off_t off_t)
 348 if(NOT off_t)
 349   set(off_t int)
 350 else(NOT off_t)
 351   set(off_t 0)
 352 endif(NOT off_t)
 353
 354 include(TestBigEndian)
 355 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 356
 357
 358
 359
 360 ########################################################################
 361 # Find external packages                                               #
 362 ########################################################################
 363 if(UNIX AND NOT APPLE)
 364     if(GMX_PREFER_STATIC_LIBS)
 365         SET(CMAKE_FIND_LIBRARY_SUFFIXES .a ${CMAKE_FIND_LIBRARY_SUFFIXES})
 366         if(BUILD_SHARED_LIBS)
 367             message(WARNING "Static libraries requested, the GROMACS libraries will also be build static (BUILD_SHARED_LIBS=OFF)")
 368             set(BUILD_SHARED_LIBS OFF CACHE BOOL "Enable shared libraries (can be problematic with MPI, Windows)" FORCE)
 369         endif()
 370     endif()
 371 endif()
 372
 373 option(GMX_XML "Use libxml2 to parse xml files" ON)
 374 if (GMX_XML)
 375   find_package(LibXml2)
 376   set(PKG_XML "")
 377   if(LIBXML2_FOUND)
 378     include_directories(${LIBXML2_INCLUDE_DIR})
 379     set(PKG_XML libxml-2.0)
 380     set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 381     set(HAVE_LIBXML2 1)
 382   endif(LIBXML2_FOUND)
 383 endif(GMX_XML)
 384
 385 option(GMX_GSL "Add support for gsl" OFF)
 386 if (GMX_GSL)
 387   find_package(gsl)
 388   set(PKG_GSL "")
 389   if(GSL_FOUND)
 390     include_directories(${GSL_INCLUDE_DIR})
 391     set(PKG_GSL gsl)
 392     set(HAVE_LIBGSL 1)
 393   endif(GSL_FOUND)
 394 endif (GMX_GSL)
 395
 396 option(GMX_X11 "Use X window system" OFF)
 397 if (GMX_X11)
 398         find_package(X11)
 399         # X11 includes/libraries are only set in the ngmx subdirectory!
 400         if(X11_FOUND)
 401         set(HAVE_X11 1)
 402         endif(X11_FOUND)
 403 endif(GMX_X11)
 404
 405 if(GMX_THREAD_MPI)
 406     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_THREAD_MPI")
 407     include(ThreadMPI)
 408     set(THREAD_MPI_LIB thread_mpi)
 409     set(GMX_MPI 1)
 410     string(TOUPPER ${GMX_FFT_LIBRARY} ${GMX_FFT_LIBRARY})
 411 endif(GMX_THREAD_MPI)
 412
 413 if(GMX_OPENMM)
 414     set(CUDA_BUILD_EMULATION OFF)
 415     find_package(CUDA 3.1 REQUIRED)
 416     add_definitions(-DGMX_OPENMM)
 417     if(CMAKE_BUILD_TYPE STREQUAL "DEBUG")
 418         set(CUDA_VERBOSE_BUILD ON)
 419     endif()
 420     find_package(OpenMM)
 421 endif(GMX_OPENMM)
 422
 423 if(GMX_OPENMP)
 424     find_package(OpenMP REQUIRED)
 425     set(GROMACS_C_FLAGS "${OpenMP_C_FLAGS} ${GROMACS_C_FLAGS}")
 426     set(GROMACS_CXX_FLAGS "${OpenMP_CXX_FLAGS} ${GROMACS_CXX_FLAGS}")
 427     add_definitions(-DGMX_OPENMP)
 428 endif()
 429
 430 if(APPLE)
 431    find_library(ACCELERATE_FRAMEWORK Accelerate)
 432    list(APPEND GMX_EXTRA_LIBRARIES ${ACCELERATE_FRAMEWORK})
 433 endif(APPLE)
 434
 435 if(CYGWIN)
 436     set(GMX_CYGWIN 1)
 437 endif(CYGWIN)
 438
 439 if(WIN32 AND NOT CYGWIN)
 440     set(GMX_NATIVE_WINDOWS 1)
 441 endif()
 442
 443 # only bother with finding git and using version.h if the source is a git repo
 444 if(EXISTS "${CMAKE_SOURCE_DIR}/.git")
 445     if(USE_VERSION_H)
 446         # We need at least git v1.5.1 be able to parse git's date output. If not
 447         # found or the version is too small, we can't generate version information.
 448         find_package(Git)
 449
 450         # Find out the git version
 451         if(GIT_FOUND AND NOT GIT_VERSION)
 452           execute_process(COMMAND ${GIT_EXECUTABLE} "--version"
 453             OUTPUT_VARIABLE _exec_out
 454             OUTPUT_STRIP_TRAILING_WHITESPACE)
 455           string(REGEX REPLACE "git version (.*)" "\\1" GIT_VERSION ${_exec_out})
 456           set(GIT_VERSION ${GIT_VERSION} CACHE STRING "Git version")
 457           mark_as_advanced(GIT_VERSION)
 458         endif()
 459
 460         if(NOT GIT_FOUND OR GIT_VERSION VERSION_LESS "1.5.1")
 461           message("No compatible git version found, won't be able to generate proper development version information.")
 462           set(USE_VERSION_H OFF)
 463         endif()
 464     endif()
 465 else()
 466     set(USE_VERSION_H OFF)
 467 endif()
 468
 469 ########################################################################
 470 # Generate development version info for cache
 471 ########################################################################
 472 # set(GEN_VERSION_INFO_INTERNAL "ON")
 473 # include(gmxGenerateVersionString)
 474
 475 ########################################################################
 476 # Our own GROMACS tests
 477 ########################################################################
 478
 479 add_definitions( -DHAVE_CONFIG_H )
 480 include_directories(${CMAKE_BINARY_DIR}/src)
 481 include_directories(${CMAKE_BINARY_DIR}/include)
 482 include_directories(${CMAKE_SOURCE_DIR}/include)
 483
 484 include(gmxCheckBuildUserTime)
 485 gmx_check_build_user_time(BUILD_TIME BUILD_USER BUILD_MACHINE)
 486
 487 include(gmxTestFloatFormat)
 488 gmx_test_float_format(GMX_FLOAT_FORMAT_IEEE754
 489                       GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER
 490                       GMX_IEEE754_BIG_ENDIAN_WORD_ORDER)
 491
 492 include(gmxTestLargeFiles)
 493 gmx_test_large_files(GMX_LARGEFILES)
 494 check_function_exists(fseeko     HAVE_FSEEKO)
 495
 496 include(gmxTestSignal)
 497 gmx_test_sigusr1(HAVE_SIGUSR1)
 498
 499 include(gmxTestInline)
 500 gmx_test_inline(INLINE_KEYWORD)
 501
 502 include(gmxTestRestrict)
 503 gmx_test_inline(RESTRICT_KEYWORD)
 504
 505 include(gmxTestPipes)
 506 gmx_test_pipes(HAVE_PIPES)
 507
 508 include(gmxTestIsfinite)
 509 gmx_test_isfinite(HAVE_ISFINITE)
 510 gmx_test__isfinite(HAVE__ISFINITE)
 511 gmx_test__finite(HAVE__FINITE)
 512
 513 include(gmxTestInlineASM)
 514 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 515 gmx_test_inline_asm_msvc_x86(GMX_X86_MSVC_INLINE_ASM)
 516
 517 # turn on SSE if supported with reasonable defaults.
 518 if (${GMX_ACCELERATION} STREQUAL "auto" AND NOT GMX_OPENMM)
 519   if(CMAKE_SYSTEM_PROCESSOR MATCHES "^(i.86|x86|x64|x86_64|AMD64|amd64)" OR CYGWIN)
 520
 521     set(GMX_ACCELERATION "SSE" CACHE STRING "Accelerated kernels. Pick one of: auto, none, SSE, BlueGene, Power6, ia64, altivec, fortran" FORCE)
 522
 523     # Determine the assembler/compiler to use
 524   else()
 525     set(GMX_ACCELERATION "none" CACHE STRING "Accelerated kernels. Pick one of: auto, none, SSE, BlueGene, Power6, ia64, altivec, fortran" FORCE)
 526   endif()
 527 endif (${GMX_ACCELERATION} STREQUAL "auto" AND NOT GMX_OPENMM)
 528
 529 include(gmxTestXDR)
 530 gmx_test_xdr(GMX_SYSTEM_XDR)
 531 if(NOT GMX_SYSTEM_XDR)
 532     set(GMX_INTERNAL_XDR 1)
 533     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_INTERNAL_XDR")
 534 endif(NOT GMX_SYSTEM_XDR)
 535
 536 # Process nonbonded accelerated kernels settings
 537 string(TOUPPER ${GMX_ACCELERATION} ${GMX_ACCELERATION})
 538 if(${GMX_ACCELERATION} STREQUAL "NONE")
 539   # nothing to do
 540 elseif(${GMX_ACCELERATION} STREQUAL "SSE")
 541
 542     if (GMX_64_BIT)
 543       set(GMX_X86_64_ASM ON CACHE BOOL "Add SSE assembly files for x86_64" FORCE)
 544     else (GMX_64_BIT)
 545       set(GMX_IA32_ASM ON CACHE BOOL "Add SSE assembly files for i386" FORCE)
 546     endif (GMX_64_BIT)
 547
 548     if(CMAKE_GENERATOR MATCHES "Visual Studio" OR CMAKE_GENERATOR MATCHES NMake )
 549       option(GMX_ASM_USEASM_NASM "Use Nasm for assembly instead of compiler (necessary on windows)" ON)
 550     else()
 551       option(GMX_ASM_USEASM_NASM "Use Nasm for assembly instead of compiler (necessary on windows)" OFF)
 552     endif()
 553         mark_as_advanced(GMX_ASM_USEASM_NASM)
 554
 555     if (NOT GMX_64_BIT)
 556         # for 32-bit compiles, we might need to turn on sse
 557         CHECK_C_COMPILER_FLAG("-msse2" XFLAGS_SSE)
 558         if (XFLAGS_SSE)
 559             set(GROMACS_C_FLAGS "-msse2 ${GROMACS_C_FLAGS}")
 560         endif (XFLAGS_SSE)
 561         CHECK_CXX_COMPILER_FLAG("-msse2" XXFLAGS_SSE)
 562         if (XXFLAGS_SSE)
 563             set(GROMACS_CXX_FLAGS "-msse2 ${GROMACS_CXX_FLAGS}")
 564         endif (XXFLAGS_SSE)
 565     endif (NOT GMX_64_BIT)
 566
 567     if(GMX_IA32_ASM)
 568       if(GMX_DOUBLE)
 569         set(GMX_IA32_SSE2 1)
 570       else()
 571        set(GMX_IA32_SSE 1)
 572       endif()
 573     elseif(GMX_X86_64_ASM)
 574       if(GMX_DOUBLE)
 575        set(GMX_X86_64_SSE2 1)
 576       else()
 577         set(GMX_X86_64_SSE 1)
 578       endif()
 579     endif()
 580
 581 #    if(HAVE_PMMINTRIN_H)
 582 #        set(GMX_SSE3 1)
 583 #    endif(HAVE_PMMINTRIN_H)
 584 #    if(HAVE_SMMINTRIN_H)
 585 #        set(GMX_SSE4_1 1)
 586 #    endif(HAVE_SMMINTRIN_H)
 587
 588 elseif(${GMX_ACCELERATION} STREQUAL "FORTRAN")
 589     set(GMX_FORTRAN 1)
 590     #these are switch on by default sometimes
 591     set(GMX_IA32_ASM 0)
 592     set(GMX_GMX_X86_64_ASM 0)
 593 elseif(${GMX_ACCELERATION} STREQUAL "BLUEGENE")
 594 # GMX_ACCELERATION=BlueGene should be set in the Toolchain-BlueGene?-???.cmake file
 595     message(STATUS "Configuring for BlueGene")
 596     set(GMX_BLUEGENE 1)
 597     if (${CMAKE_SYSTEM_NAME} STREQUAL "BlueGeneL")
 598         set(SHARED_LIBS_DEFAULT OFF CACHE BOOL "Shared libraries not compatible with BlueGene/L, disabled!" FORCE)
 599         set(BUILD_SHARED_LIBS OFF CACHE BOOL "Shared libraries not compatible with BlueGene/L, disabled!" FORCE)
 600     endif (${CMAKE_SYSTEM_NAME} STREQUAL "BlueGeneL")
 601     set(GMX_SOFTWARE_INVSQRT OFF CACHE BOOL "Do not use software reciprocal square root on BlueGene" FORCE)
 602     set(GMX_POWERPC_INVSQRT ON CACHE BOOL "Use hardware reciprocal square root on BlueGene" FORCE)
 603     set(GMX_X11 OFF CACHE BOOL "X11 not compatible with BlueGene, disabled!" FORCE)
 604     set(GMX_THREAD_MPI OFF CACHE BOOL "Thread-MPI not compatible with BlueGene, disabled!" FORCE)
 605     set(GMX_MPI ON CACHE BOOL "Use MPI on BlueGene" FORCE)
 606 elseif(${GMX_ACCELERATION} STREQUAL "POWER6")
 607     set(GMX_POWER6 1)
 608     set(GMX_SOFTWARE_INVSQRT OFF CACHE BOOL "Do not use software reciprocal square root on Power6" FORCE)
 609     set(GMX_POWERPC_INVSQRT ON CACHE BOOL "Use hardware reciprocal square root on Power6" FORCE)
 610 elseif(${GMX_ACCELERATION} STREQUAL "IA64")
 611     set(GMX_IA64_ASM 1)
 612     set(DISABLE_WATERWATER_NLIST 1)
 613     set(DISABLE_WATER_NLIST 1)
 614 elseif(${GMX_ACCELERATION} STREQUAL "ALTIVEC")
 615     check_include_files(altivec.h HAVE_ALTIVEC_H)
 616     if(HAVE_ALTIVEC_H)
 617         set(GMX_PPC_ALTIVEC 1)
 618     endif(HAVE_ALTIVEC_H)
 619 else(${GMX_ACCELERATION} STREQUAL "NONE")
 620     MESSAGE(FATAL_ERROR "Unrecognized option for accelerated kernels: ${GMX_ACCELERATION}. Pick one of auto, none, SSE, Fortran, BlueGene, Power6, ia64, altivec")
 621 endif(${GMX_ACCELERATION} STREQUAL "NONE")
 622
 623 if(GMX_FORTRAN OR GMX_POWER6)
 624     if (GMX_THREAD_MPI)
 625         message(FATAL_ERROR "FORTRAN/POWER6 is incompatible with thread-MPI and only provides a speed-up on certain IBM compilers. Disable FORTRAN (or threads if you really want to use FORTRAN kernels).")
 626     endif(GMX_THREAD_MPI)
 627     enable_language(Fortran)
 628     include(FortranCInterface)
 629     discover_fortran_mangling(prefix isupper suffix extra_under_score found)
 630     if(extra_under_score)
 631         set(extrasuffix "_")
 632     endif(extra_under_score)
 633     if(prefix)
 634       set(prefix "${prefix} ##")
 635     endif(prefix)
 636     if(suffix)
 637       set(suffix "## ${suffix}")
 638       if(extrasuffix)
 639         set(extrasuffix "${suffix}${extrasuffix}")
 640       endif(extrasuffix)
 641     else(suffix)
 642       if(extrasuffix)
 643         # Don't know if this is needed, but it can't hurt
 644         set(extrasuffix "## ${extrasuffix}")
 645       endif(extrasuffix)
 646     endif(suffix)
 647
 648     if(isupper)
 649         set(F77_FUNCDEF   "${prefix} NAME ${suffix}")
 650         set(F77_FUNCDEF_  "${prefix} NAME ${extrasuffix}")
 651     else(isupper)
 652         set(F77_FUNCDEF   "${prefix} name ${suffix}")
 653         set(F77_FUNCDEF_  "${prefix} name ${extrasuffix}")
 654     endif(isupper)
 655 else(GMX_FORTRAN OR GMX_POWER6)
 656         set(F77_FUNCDEF   "name ## _")
 657         set(F77_FUNCDEF_  "name ## _")
 658 endif(GMX_FORTRAN OR GMX_POWER6)
 659
 660 # Process QM/MM Settings
 661 string(TOUPPER ${GMX_QMMM_PROGRAM} ${GMX_QMMM_PROGRAM})
 662 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 663     set(GMX_QMMM_GAUSSIAN 1)
 664 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 665     set(GMX_QMMM_MOPAC 1)
 666 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 667     set(GMX_QMMM_GAMESS 1)
 668 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 669     set(GMX_QMMM_ORCA 1)
 670 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 671     # nothing to do
 672 else(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 673     MESSAGE(FATAL_ERROR "Invalid QM/MM program option: ${GMX_QMMM_PROGRAM}. Choose one of: Gaussian, Mopac, Gamess, Orca, None")
 674 endif(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 675
 676 # Process FFT library settings - if not OpenMM build
 677 string(TOUPPER ${GMX_FFT_LIBRARY} ${GMX_FFT_LIBRARY})
 678 set(PKG_FFT "")
 679 set(PKG_FFT_LIBS "")
 680 if(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 681     if(GMX_DOUBLE)
 682         find_package(FFTW 3 COMPONENTS fftw)
 683     else(GMX_DOUBLE)
 684         find_package(FFTW 3 COMPONENTS fftwf)
 685     endif(GMX_DOUBLE)
 686     if(NOT FFTW_FOUND)
 687       MESSAGE(FATAL_ERROR "Cannot find FFTW3 (with correct precision - libfftw3f for single precision GROMACS or libfftw3 for double precision GROMACS). Fix it, choose another FFT library, or use the Gromacs built-in fftpack (slower)!")
 688     endif(NOT FFTW_FOUND)
 689     include_directories(${FFTW_INCLUDE_DIRS})
 690     set(FFT_LIBRARIES ${FFTW_LIBRARIES})
 691     set(PKG_FFT "${FFTW_PKG}")
 692
 693     set(GMX_FFT_FFTW3 1)
 694
 695     if (${GMX_ACCELERATION} STREQUAL "SSE" AND NOT FFTW_HAVE_SSE)
 696       message(WARNING "The fftw library found is compiled without SSE support, which makes it slow. Consider recompiling it or contact your admin")
 697     endif (${GMX_ACCELERATION} STREQUAL "SSE" AND NOT FFTW_HAVE_SSE)
 698
 699 elseif(${GMX_FFT_LIBRARY} STREQUAL "MKL")
 700 #    MESSAGE(STATUS "Using external FFT library - Intel MKL")
 701     find_package(MKL REQUIRED)
 702     include_directories(${MKL_INCLUDE_DIR})
 703     set(FFT_LIBRARIES ${MKL_LIBRARIES})
 704     set(PKG_FFT_LIBS ${MKL_LIBRARIES})
 705
 706     set(GMX_FFT_MKL 1)
 707     set(HAVE_MKL 1)
 708
 709 #elseif(${GMX_FFT_LIBRARY} STREQUAL "ACML")
 710 #    MESSAGE(STATUS "Using external FFT library - AMD core math library")
 711 #    set(GMX_FFT_ACML 1)
 712 elseif(${GMX_FFT_LIBRARY} STREQUAL "FFTPACK")
 713     MESSAGE(STATUS "Using internal FFT library - fftpack")
 714     set(GMX_FFT_FFTPACK 1)
 715 else(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 716     MESSAGE(FATAL_ERROR "Invalid FFT library setting: ${GMX_FFT_LIBRARY}. Choose one of: fftw3, mkl, fftpack")
 717 endif(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 718
 719 # MKL has BLAS/LAPACK routines
 720 if(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 721   set(GMX_EXTERNAL_BLAS TRUE CACHE BOOL "Use external BLAS instead of built-in")
 722   set(GMX_EXTERNAL_LAPACK TRUE CACHE BOOL "Use external LAPACK instead of built-in")
 723 else(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 724   set(GMX_EXTERNAL_BLAS FALSE CACHE BOOL "Use external BLAS instead of built-in")
 725   set(GMX_EXTERNAL_LAPACK FALSE CACHE BOOL "Use external LAPACK instead of built-in")
 726   if(GMX_EXTERNAL_BLAS)
 727     #FindBLAS needs Fortran
 728     enable_language(Fortran)
 729     if (GMX_BLAS_USER)
 730         list(APPEND GMX_EXTRA_LIBRARIES ${GMX_BLAS_USER})
 731     else(GMX_BLAS_USER)
 732         find_package(BLAS REQUIRED)
 733         list(APPEND GMX_EXTRA_LIBRARIES ${BLAS_LIBRARIES})
 734     endif(GMX_BLAS_USER)
 735   endif(GMX_EXTERNAL_BLAS)
 736   if(GMX_EXTERNAL_LAPACK)
 737     #FindLAPACK needs Fortran
 738     enable_language(Fortran)
 739         if (GMX_LAPACK_USER)
 740         list(APPEND GMX_EXTRA_LIBRARIES ${GMX_LAPACK_USER})
 741         else(GMX_LAPACK_USER)
 742         find_package(LAPACK REQUIRED)
 743         list(APPEND GMX_EXTRA_LIBRARIES ${LAPACK_LIBRARIES})
 744     endif(GMX_LAPACK_USER)
 745   endif(GMX_EXTERNAL_LAPACK)
 746 endif(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 747 mark_as_advanced(GMX_EXTERNAL_LAPACK)
 748 mark_as_advanced(GMX_EXTERNAL_BLAS)
 749
 750 set(GMX_USE_PLUGINS OFF CACHE INTERNAL "Whether GROMACS will really try to compile support for VMD plugins")
 751 set(GMX_VMD_PLUGIN_PATH)
 752 mark_as_advanced(GMX_VMD_PLUGIN_PATH)
 753
 754 if(GMX_LOAD_PLUGINS)
 755   if(CYGWIN OR NOT WIN32)
 756     # Native Windows does not have, nor need dlopen
 757     # Note that WIN32 is set with Cygwin, but Cygwin needs dlopen to use plug-ins
 758     include(gmxTestdlopen)
 759     gmx_test_dlopen(HAVE_DLOPEN)
 760   endif()
 761
 762   find_package(VMD)
 763
 764   # Test for unsuitable versions of VMD
 765
 766   if(VMD_FOUND AND NOT GMX_VMD_PLUGIN_PATH)
 767     message(STATUS "Checking for suitable VMD version")
 768     exec_program(${VMD_EXECUTABLE}
 769       ARGS --help
 770       OUTPUT_VARIABLE VMD_HELP
 771       RETURN_VALUE VMD_EXEC_RETURN)
 772
 773     if(VMD_EXEC_RETURN EQUAL 0)
 774       # This is the accepted idiom for subexpression matching, unfortunately
 775       string(REGEX REPLACE ".*VMD for .*, version ([0-9]+\\.[0-9]*\\.?[0-9]*).*" "\\1" VMD_VERSION ${VMD_HELP})
 776       string(REGEX REPLACE ".*VMD for (.*), version .*" "\\1" VMD_ARCH ${VMD_HELP})
 777
 778       if(VMD_VERSION VERSION_LESS "1.8")
 779         MESSAGE(WARNING "Found VMD version ${VMD_VERSION}, but GROMACS needs at least 1.8")
 780         unset(VMD_EXECUTABLE)
 781         set(VMD_FOUND FALSE)
 782       else()
 783         message(STATUS "VMD version ${VMD_VERSION} is suitable")
 784         if(DEFINED ENV{VMDDIR})
 785           # This permits GROMACS to avoid hard-coding a fall-back
 786           # path that it can tell right now would be useless.
 787           set(GMX_VMD_PLUGIN_PATH "$ENV{VMDDIR}/plugins/${VMD_ARCH}/molfile" CACHE PATH "Path to VMD plugins for molfile I/O")
 788         else()
 789           set(GMX_VMD_PLUGIN_PATH "/usr/local/lib/vmd/plugins/*/molfile" CACHE PATH "Path to VMD plugins for molfile I/O")
 790         endif()
 791       endif()
 792
 793       # clean up
 794       unset(VMD_HELP)
 795       unset(VMD_VERSION)
 796       unset(VMD_ARCH)
 797     endif()
 798   endif()
 799
 800   # so, should we use plug-ins?
 801   if((WIN32 AND NOT CYGWIN) OR (HAVE_DLOPEN AND BUILD_SHARED_LIBS))
 802     if (NOT VMD_QUIETLY)
 803       MESSAGE(STATUS "Found the ability to use plug-ins when building shared libaries, so will compile to use plug-ins (e.g. to read VMD-supported file formats).")
 804     endif(NOT VMD_QUIETLY)
 805     set(GMX_USE_PLUGINS ON)
 806     list(APPEND GMX_EXTRA_LIBRARIES ${CMAKE_DL_LIBS}) # magic cross-platform pre-set variable for dlopen library
 807     set(PKG_DL_LIBS "-l${CMAKE_DL_LIBS}")
 808   else()
 809     set(PKG_DL_LIBS)
 810   endif()
 811 endif(GMX_LOAD_PLUGINS)
 812 set(VMD_QUIETLY TRUE CACHE INTERNAL "")
 813
 814 # Math and thread libraries must often come after all others when linking...
 815 if(HAVE_LIBM)
 816     list(APPEND GMX_EXTRA_LIBRARIES m)
 817 endif(HAVE_LIBM)
 818
 819 if(GMX_FAHCORE)
 820   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 821       "Path to swindirect.h")
 822   include_directories(${COREWRAP_INCLUDE_DIR})
 823 endif(GMX_FAHCORE)
 824
 825 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 826 # these are set after everything else
 827 if (NOT DEFINED GROMACS_C_FLAGS_SET)
 828     set(GROMACS_C_FLAGS_SET true CACHE INTERNAL "Whether to reset the C flags"
 829         FORCE)
 830     set(CMAKE_C_FLAGS "${GROMACS_C_FLAGS} ${CMAKE_C_FLAGS}" CACHE STRING
 831         "Flags used by the compiler during all build types" FORCE)
 832     set(CMAKE_CXX_FLAGS "${GROMACS_CXX_FLAGS} ${CMAKE_CXX_FLAGS}" CACHE STRING
 833         "Flags used by the compiler during all build types" FORCE)
 834     set(CMAKE_EXE_LINKER_FLAGS
 835         "${GROMACS_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}"
 836         CACHE STRING "Linker flags" FORCE)
 837 endif (NOT DEFINED GROMACS_C_FLAGS_SET)
 838
 839 ########################################################################
 840 # Specify install locations and which subdirectories to process        #
 841 ########################################################################
 842 if ( DEFINED GMXLIB )
 843     set(LIB_INSTALL_DIR "${CMAKE_INSTALL_PREFIX}/${GMXLIB}")
 844 else()
 845     set(LIB_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/lib)
 846 endif()
 847 set(BIN_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/bin)
 848 set(DATA_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/gromacs)
 849 set(MAN_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/share/man)
 850 set(INCL_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/include)
 851
 852 set(GMXLIBDIR        ${DATA_INSTALL_DIR}/top)
 853
 854 ##################################################################
 855 # Shared library settings - Darwin uses INSTALL_NAME_DIR instead!
 856 ##################################################################
 857 if(NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin")
 858     set(CMAKE_SKIP_BUILD_RPATH  FALSE)
 859     set(CMAKE_BUILD_WITH_INSTALL_RPATH FALSE)
 860     set(CMAKE_INSTALL_RPATH "${LIB_INSTALL_DIR}")
 861     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 862 endif()
 863
 864 add_subdirectory(share)
 865 add_subdirectory(include)
 866 add_subdirectory(man)
 867 add_subdirectory(src)
 868 add_subdirectory(scripts)
 869
 870 #######################
 871 ## uninstall target
 872 #######################
 873     CONFIGURE_FILE(
 874                    "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 875                    "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
 876                    IMMEDIATE @ONLY)
 877 ###########################
 878 ADD_CUSTOM_TARGET(uninstall
 879                   "${CMAKE_COMMAND}" -P
 880                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
 881 ###########################
 882
 883
 884 ########################################################################
 885 # Tests                                                                #
 886 ########################################################################
 887
 888 include(CTest)
 889 mark_as_advanced(BUILD_TESTING)
 890 IF(BUILD_TESTING)
 891         enable_testing()
 892         add_subdirectory(tests)
 893 ENDIF()
 894