CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.6)
   2
   3 project(Gromacs)
   4 include(Dart)
   5 mark_as_advanced(DART_ROOT)
   6 # PROJECT_VERSION should have the following structure:
   7 # VERSION[-dev-SUFFIX] where the VERSION can have any form and the suffix
   8 set(PROJECT_VERSION "4.5.1")
   9 set(CUSTOM_VERSION_STRING ""
  10     CACHE STRING "Custom version string (if empty, use hard-coded default)")
  11 mark_as_advanced(CUSTOM_VERSION_STRING)
  12 if (CUSTOM_VERSION_STRING)
  13     set(PROJECT_VERSION ${CUSTOM_VERSION_STRING})
  14 endif (CUSTOM_VERSION_STRING)
  15 set(SOVERSION 6)
  16 # It is a bit irritating, but this has to be set separately for now!
  17 SET(CPACK_PACKAGE_VERSION_MAJOR "4")
  18 SET(CPACK_PACKAGE_VERSION_MINOR "5")
  19 SET(CPACK_PACKAGE_VERSION_PATCH "1")
  20
  21
  22 # Cmake modules/macros are in a subdirectory to keep this file cleaner
  23 set(CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake)
  24
  25 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
  26 set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "" FORCE)
  27 endif()
  28
  29 if(NOT CMAKE_BUILD_TYPE)
  30     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel." FORCE)
  31 endif(NOT CMAKE_BUILD_TYPE)
  32
  33 enable_language(C)
  34
  35 set(CPACK_PACKAGE_VERSION ${PROJECT_VERSION})
  36 set(CPACK_PACKAGE_VENDOR "gromacs.org")
  37 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Gromacs - a toolkit for high-performance molecular simulation")
  38 set(CPACK_SET_DESTDIR "ON")
  39 set(CPACK_INCLUDE_TOPLEVEL_DIRECTORY 0)
  40 set(CPACK_RESOURCE_FILE_WELCOME "${CMAKE_SOURCE_DIR}/admin/InstallWelcome.txt")
  41 # Its GPL/LGPL, so they do not have to agree to a license for mere usage, but some installers require this...
  42 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_SOURCE_DIR}/admin/InstallLicense.txt")
  43 set(CPACK_RESOURCE_FILE_README "${CMAKE_SOURCE_DIR}/admin/InstallInfo.txt")
  44
  45 #must come after all cpack settings!
  46 include(CPack)
  47
  48
  49 ########################################################################
  50 # Fix stupid flags on MSVC
  51 ########################################################################
  52 SET(SHARED_LIBS_DEFAULT ON)
  53 IF(CMAKE_GENERATOR MATCHES "Visual Studio")
  54     STRING(REPLACE /MD /MT CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE})
  55     SET(CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE} CACHE STRING "" FORCE)
  56     STRING(REPLACE /MD /MT CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG})
  57     SET(CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG} CACHE STRING "" FORCE)
  58     SET(SHARED_LIBS_DEFAULT OFF)
  59 ENDIF(CMAKE_GENERATOR MATCHES "Visual Studio")
  60
  61 set(GMX_EXTRA_LIBRARIES)
  62
  63
  64
  65 ######################################################################
  66 # compiler tests
  67 # these need ot be done early (before further tests).
  68 #####################################################################
  69
  70 include(CheckCCompilerFlag)
  71 include(CheckCXXCompilerFlag)
  72
  73 include(gmxCFlags)
  74 gmx_c_flags()
  75
  76 ########################################################################
  77 # User input options                                                   #
  78 ########################################################################
  79 option(GMX_DOUBLE "Use double precision. Much slower, use only if needed!)" OFF)
  80 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
  81 option(GMX_THREADS    "Build a parallel (thread-based) version of GROMACS)" ON)
  82 option(GMX_SOFTWARE_INVSQRT "Use GROMACS software 1/sqrt" ON)
  83 mark_as_advanced(GMX_SOFTWARE_INVSQRT)
  84 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
  85 mark_as_advanced(GMX_FAHCORE)
  86 option(GMX_OPENMM "Accelerated execution on GPUs through the OpenMM library" OFF)
  87 set(GMX_ACCELERATION "auto"
  88     CACHE STRING "Accelerated kernels. Pick one of: auto, none, SSE, BlueGene, Power6, ia64, altivec")
  89
  90 set(GMX_FFT_LIBRARY "fftw3"
  91     CACHE STRING "FFT library choices: fftw3,fftw2,mkl,fftpack[built-in]")
  92 option(GMX_DISABLE_FFTW_MEASURE
  93        "Do not optimize FFTW setups (not needed with SSE)" OFF)
  94 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
  95 set(GMX_QMMM_PROGRAM "none"
  96     CACHE STRING "QM package choices: none,gaussian,mopac,gamess,orca")
  97 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
  98 mark_as_advanced(GMX_BROKEN_CALLOC)
  99 option(BUILD_SHARED_LIBS "Enable shared libraries (can be problematic with MPI, Windows)" ${SHARED_LIBS_DEFAULT})
 100 option(GMX_MPI_IN_PLACE "Enable MPI_IN_PLACE for MPIs that have it defined" ON)
 101 mark_as_advanced(GMX_MPI_IN_PLACE)
 102 option(GMX_DLOPEN "Compile with dlopen, needed to read VMD supported file formats" ON)
 103 mark_as_advanced(GMX_DLOPEN)
 104
 105
 106 option(GMX_IA32_ASM "Add SSE assembly files for IA32" OFF)
 107 mark_as_advanced(GMX_IA32_ASM)
 108 option(GMX_X86_64_ASM "Add SSE assembly files for X86_64" OFF)
 109 mark_as_advanced(GMX_X86_64_ASM)
 110
 111 option(USE_VERSION_H "Generate development version string/information" ON)
 112 mark_as_advanced(USE_VERSION_H)
 113
 114 option(GMX_DEFAULT_SUFFIX "Use default GROMACS suffixes" ON)
 115 set(GMX_BINARY_SUFFIX "" CACHE STRING "Suffix for GROMACS binaries (default: _d for double, _mpi for mpi, _mpi_d for mpi and double).")
 116 set(GMX_LIBS_SUFFIX ""
 117   CACHE STRING "Suffix for GROMACS libs (default: _d for double, _mpi for mpi, _mpi_d for mpi and double).")
 118 if (GMX_DEFAULT_SUFFIX)
 119   set(GMX_BINARY_SUFFIX "")
 120   set(GMX_LIBS_SUFFIX "")
 121   if (GMX_MPI)
 122     set(GMX_BINARY_SUFFIX "_mpi")
 123     set(GMX_LIBS_SUFFIX "_mpi")
 124   endif(GMX_MPI)
 125   if (GMX_DOUBLE)
 126     set (GMX_BINARY_SUFFIX "${GMX_BINARY_SUFFIX}_d")
 127     set (GMX_LIBS_SUFFIX "${GMX_LIBS_SUFFIX}_d")
 128   endif(GMX_DOUBLE)
 129   mark_as_advanced(FORCE GMX_BINARY_SUFFIX GMX_LIBS_SUFFIX)
 130   message(STATUS "Using default binary suffix: \"${GMX_BINARY_SUFFIX}\"")
 131   message(STATUS "Using default library suffix: \"${GMX_LIBS_SUFFIX}\"")
 132 else(GMX_DEFAULT_SUFFIX)
 133   mark_as_advanced(CLEAR GMX_BINARY_SUFFIX GMX_LIBS_SUFFIX)
 134   message(STATUS "Using manually set binary suffix: \"${GMX_BINARY_SUFFIX}\"")
 135   message(STATUS "Using manually set library suffix: \"${GMX_LIBS_SUFFIX}\"")
 136 endif(GMX_DEFAULT_SUFFIX)
 137
 138 set(PKG_CFLAGS "")
 139 if(GMX_DOUBLE)
 140   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_DOUBLE")
 141 endif(GMX_DOUBLE)
 142 if(GMX_SOFTWARE_INVSQRT)
 143   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_SOFTWARE_INVSQRT")
 144 endif(GMX_SOFTWARE_INVSQRT)
 145
 146 ########################################################################
 147 #Process MPI settings
 148 ########################################################################
 149 if(GMX_MPI)
 150         MESSAGE(WARNING "
 151             There are known problems with some MPI implementations:
 152                      OpenMPI version < 1.4.1
 153                      MVAPICH2 version <= 1.4.1                               *")
 154     if(GMX_THREADS)
 155         #message(FATAL_ERROR "Thread-based parallelization conflicts with MPI.")
 156         set(GMX_THREADS OFF CACHE BOOL
 157             "Thread-based parallelization conflicts with MPI." FORCE)
 158     endif(GMX_THREADS)
 159     find_package(MPI)
 160     if(MPI_FOUND)
 161         set(GROMACS_C_FLAGS ${GROMACS_FLAGS} ${MPI_COMPILE_FLAGS})
 162         set(GROMACS_LINKER_FLAGS ${GROMACS_LINKER_FLAGS} ${MPI_LINK_FLAGS})
 163
 164         include_directories(${MPI_INCLUDE_PATH})
 165         list(APPEND GMX_EXTRA_LIBRARIES ${MPI_LIBRARIES})
 166         add_definitions( -DMPI ) #for FAHCORE
 167         include(gmxTestMPI_IN_PLACE)
 168         if (GMX_MPI_IN_PLACE)
 169             gmx_test_mpi_in_place(MPI_IN_PLACE_EXISTS)
 170         endif (GMX_MPI_IN_PLACE)
 171     else(MPI_FOUND)
 172         message(FATAL_ERROR "MPI support requested, but no MPI compiler found.")
 173     endif(MPI_FOUND)
 174     include(gmxTestCatamount)
 175     gmx_test_catamount(GMX_CRAY_XT3)
 176     if(GMX_CRAY_XT3)
 177         set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_CRAY_XT3")
 178         set(GMX_NO_SYSTEM 1)
 179         set(GMX_NO_NICE 1)
 180     endif(GMX_CRAY_XT3)
 181     set(GMX_LIB_MPI 1)
 182     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_LIB_MPI")
 183 endif(GMX_MPI)
 184
 185
 186 #######################################################################
 187 # Check for options incompatible with OpenMM build                    #
 188 #######################################################################
 189 if(GMX_OPENMM)
 190     cmake_minimum_required(VERSION 2.6.4)
 191     # we'll use the built-in fft to avoid unnecessary dependencies
 192     message(STATUS "No external FFT libraries needed for the OpenMM build, using fftpack!")
 193     set (GMX_FFT_LIBRARY "fftpack" CACHE STRING
 194                 "No external FFT libraries needed for the OpenMM build, using fftpack!" FORCE)
 195     if(GMX_MPI)
 196         message(FATAL_ERROR "The OpenMM build is not compatible with MPI!")
 197     endif(GMX_MPI)
 198     if(GMX_THREADS)
 199         message(STATUS "Threads not compatible with OpenMM build, disabled!")
 200         set(GMX_THREADS OFF CACHE BOOL
 201                 "Threads not compatible with OpenMM build, disabled!" FORCE)
 202     endif(GMX_THREADS)
 203     if(GMX_SOFTWARE_INVSQRT)
 204         set(GMX_SOFTWARE_INVSQRT OFF FORCE)
 205     endif(GMX_SOFTWARE_INVSQRT)
 206     if(NOT GMX_ACCELERATION MATCHES "^(none|None|NONE)")
 207         message(WARNING "CPU-based acceleration turned off, OpenMM does not support/need any!")
 208         unset(GMX_ACCELERATION CACHE)
 209         set(GMX_ACCELERATION "none" CACHE STRING
 210                 "CPU-based acceleration turned off, OpenMM does not support/need any!" FORCE)
 211     endif()
 212     if(GMX_FAHCORE)
 213         message(FATAL_ERROR "The OpenMM build does not support FAH build!")
 214     endif(GMX_FAHCORE)
 215     set(GMX_DOUBLE OFF FORCE )
 216     # mark as advanced the unused variables
 217     mark_as_advanced(FORCE GMX_ACCELERATION GMX_MPI GMX_FFT_LIBRARY
 218         GMX_QMMM_PROGRAM GMX_THREADS GMX_DOUBLE)
 219 else(GMX_OPENMM)
 220      mark_as_advanced(CLEAR GMX_ACCELERATION GMX_MPI GMX_FFT_LIBRARY
 221         GMX_QMMM_PROGRAM GMX_THREADS GMX_DOUBLE)
 222 endif(GMX_OPENMM)
 223
 224
 225 ########################################################################
 226 # Basic system tests (standard libraries, headers, functions, types)   #
 227 ########################################################################
 228 include(CheckIncludeFiles)
 229 check_include_files(string.h     HAVE_STRING_H)
 230 check_include_files(math.h       HAVE_MATH_H)
 231 check_include_files(limits.h     HAVE_LIMITS_H)
 232 check_include_files(memory.h     HAVE_MEMORY_H)
 233 check_include_files(unistd.h     HAVE_UNISTD_H)
 234 check_include_files(pwd.h        HAVE_PWD_H)
 235 check_include_files(stdint.h     HAVE_STDINT_H)
 236 check_include_files(stdlib.h     HAVE_STDLIB_H)
 237 check_include_files(pthread.h    HAVE_PTHREAD_H)
 238 check_include_files(dirent.h     HAVE_DIRENT_H)
 239 check_include_files(inttypes.h   HAVE_INTTYPES_H)
 240 check_include_files(regex.h      HAVE_REGEX_H)
 241 check_include_files(sys/types.h  HAVE_SYS_TYPES_H)
 242 check_include_files(sys/stat.h   HAVE_SYS_STAT_H)
 243 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 244 check_include_files(rpc/rpc.h    HAVE_RPC_RPC_H)
 245 check_include_files("rpc/rpc.h;rpc/xdr.h"    HAVE_RPC_XDR_H)
 246 # SSE support
 247 check_include_files(xmmintrin.h  HAVE_XMMINTRIN_H)
 248 check_include_files(emmintrin.h  HAVE_EMMINTRIN_H)
 249 check_include_files(pmmintrin.h  HAVE_PMMINTRIN_H)
 250 check_include_files(smmintrin.h  HAVE_SMMINTRIN_H)
 251 check_include_files(io.h                 HAVE_IO_H)
 252
 253
 254 include(CheckFunctionExists)
 255 check_function_exists(strcasecmp        HAVE_STRCASECMP)
 256 check_function_exists(strdup            HAVE_STRDUP)
 257 check_function_exists(vprintf           HAVE_VPRINTF)
 258 check_function_exists(memcmp            HAVE_MEMCMP)
 259 check_function_exists(posix_memalign    HAVE_POSIX_MEMALIGN)
 260 check_function_exists(memalign          HAVE_MEMALIGN)
 261 check_function_exists(_aligned_malloc   HAVE__ALIGNED_MALLOC)
 262 check_function_exists(gettimeofday      HAVE_GETTIMEOFDAY)
 263 check_function_exists(isnan             HAVE_ISNAN)
 264 check_function_exists(_isnan            HAVE__ISNAN)
 265 check_function_exists(isfinite          HAVE_ISFINITE)
 266 check_function_exists(_isfinite         HAVE__ISFINITE)
 267 check_function_exists(fsync             HAVE_FSYNC)
 268 check_function_exists(_fileno           HAVE__FILENO)
 269 check_function_exists(fileno            HAVE_FILENO)
 270 check_function_exists(_commit           HAVE__COMMIT)
 271
 272 include(CheckLibraryExists)
 273 check_library_exists(m sqrt "" HAVE_LIBM)
 274 check_library_exists(m cbrt "" HAVE_CBRT)
 275
 276
 277 include(CheckTypeSize)
 278
 279 check_type_size("bool"          SIZEOF_BOOL) # will also set HAVE_BOOL
 280 check_type_size("int"           SIZEOF_INT)
 281 check_type_size("long int"      SIZEOF_LONG_INT)
 282 check_type_size("long long int" SIZEOF_LONG_LONG_INT)
 283 check_type_size("off_t"         SIZEOF_OFF_T)
 284 check_type_size("void *"        SIZEOF_VOIDP)
 285
 286 if (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 287     set(GMX_64_BIT TRUE)
 288 else (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 289     set(GMX_64_BIT FALSE)
 290 endif (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 291
 292 # Check for some basic types that we *need*, so set these to int if they are not present
 293 check_type_size(uid_t uid_t)
 294 if(NOT uid_t)
 295   set(uid_t int)
 296 else(NOT uid_t)
 297   set(uid_t 0)
 298 endif(NOT uid_t)
 299
 300 check_type_size(gid_t gid_t)
 301 if(NOT gid_t)
 302   set(gid_t 1)
 303 else(NOT gid_t)
 304   set(gid_t 0)
 305 endif(NOT gid_t)
 306
 307 check_type_size(size_t size_t)
 308 if(NOT size_t)
 309   set(size_t int)
 310 else(NOT size_t)
 311   set(size_t 0)
 312 endif(NOT size_t)
 313
 314 check_type_size(off_t off_t)
 315 if(NOT off_t)
 316   set(off_t int)
 317 else(NOT off_t)
 318   set(off_t 0)
 319 endif(NOT off_t)
 320
 321 include(TestBigEndian)
 322 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 323
 324
 325
 326
 327 ########################################################################
 328 # Find external packages                                               #
 329 ########################################################################
 330
 331 find_package(LibXml2)
 332 set(PKG_XML "")
 333 if(LIBXML2_FOUND)
 334     include_directories(${LIBXML2_INCLUDE_DIR})
 335     set(PKG_XML libxml-2.0)
 336     set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 337     set(HAVE_LIBXML2 1)
 338 endif(LIBXML2_FOUND)
 339
 340 option(GMX_X11 "Use X window system" OFF)
 341 if (GMX_X11)
 342         find_package(X11)
 343         # X11 includes/libraries are only set in the ngmx subdirectory!
 344         if(X11_FOUND)
 345         set(HAVE_X11 1)
 346         endif(X11_FOUND)
 347 endif(GMX_X11)
 348
 349 if(GMX_THREADS)
 350     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_THREADS")
 351     include(ThreadMPI)
 352     set(THREAD_MPI_LIB thread_mpi)
 353     set(GMX_MPI 1)
 354     string(TOUPPER ${GMX_FFT_LIBRARY} ${GMX_FFT_LIBRARY})
 355     if(${GMX_FFT_LIBRARY} STREQUAL "FFTW2")
 356         message(FATAL_ERROR "FFTW2 can't be used with threads. Try fftw3 or mkl.")
 357     endif()
 358 endif(GMX_THREADS)
 359
 360 if(GMX_OPENMM)
 361     set(CUDA_BUILD_EMULATION OFF)
 362     find_package(CUDA 3.1 REQUIRED)
 363     add_definitions(-DGMX_OPENMM)
 364     if(CMAKE_BUILD_TYPE STREQUAL "DEBUG")
 365         set(CUDA_VERBOSE_BUILD ON)
 366     endif()
 367     find_package(OpenMM)
 368 endif(GMX_OPENMM)
 369
 370 if(APPLE)
 371    find_library(ACCELERATE_FRAMEWORK Accelerate)
 372    list(APPEND GMX_EXTRA_LIBRARIES ${ACCELERATE_FRAMEWORK})
 373 endif(APPLE)
 374
 375 # only bother with finding git and using version.h if the source is a git repo
 376 if(EXISTS "${CMAKE_SOURCE_DIR}/.git")
 377     if(USE_VERSION_H)
 378         # We need at least git v1.5.1 be able to parse git's date output. If not
 379         # fund or the version is too small, we can't generate version information.
 380         find_package(Git 1.5.1)
 381         # this should at some point become VERSION_LESS
 382         if(NOT Git_FOUND OR Git_VERSION STRLESS "1.5.1")
 383             message("No compatible git version found, won't be able to generate proper development version information.")
 384         endif()
 385     endif()
 386 else()
 387     set(USE_VERSION_H OFF)
 388 endif()
 389
 390 if (GMX_DLOPEN)
 391     list(APPEND GMX_EXTRA_LIBRARIES ${CMAKE_DL_LIBS})
 392 endif (GMX_DLOPEN)
 393
 394 ########################################################################
 395 # Generate development version info for cache
 396 ########################################################################
 397 # set(GEN_VERSION_INFO_INTERNAL "ON")
 398 # include(gmxGenerateVersionString)
 399
 400 ########################################################################
 401 # Our own GROMACS tests
 402 ########################################################################
 403
 404 add_definitions( -DHAVE_CONFIG_H )
 405 include_directories(${CMAKE_BINARY_DIR}/src)
 406 include_directories(${CMAKE_SOURCE_DIR}/include)
 407
 408 include(gmxCheckBuildUserTime)
 409 gmx_check_build_user_time(BUILD_TIME BUILD_USER BUILD_MACHINE)
 410
 411 include(gmxTestFloatFormat)
 412 gmx_test_float_format(GMX_FLOAT_FORMAT_IEEE754
 413                       GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER
 414                       GMX_IEEE754_BIG_ENDIAN_WORD_ORDER)
 415
 416 include(gmxTestLargeFiles)
 417 gmx_test_large_files(GMX_LARGEFILES)
 418 check_function_exists(fseeko     HAVE_FSEEKO)
 419
 420 include(gmxTestSignal)
 421 gmx_test_retsigtype(RETSIGTYPE)
 422 gmx_test_sigusr1(HAVE_SIGUSR1)
 423
 424 include(gmxTestInline)
 425 gmx_test_inline(INLINE_KEYWORD)
 426
 427 include(gmxTestRestrict)
 428 gmx_test_inline(RESTRICT_KEYWORD)
 429
 430 include(gmxTestPipes)
 431 gmx_test_pipes(HAVE_PIPES)
 432
 433 include(gmxTestInlineASM)
 434 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 435 gmx_test_inline_asm_msvc_x86(GMX_X86_MSVC_INLINE_ASM)
 436
 437 # turn on SSE if supported with reasonable defaults.
 438 if (${GMX_ACCELERATION} STREQUAL "auto" AND NOT GMX_OPENMM)
 439   if(CMAKE_SYSTEM_PROCESSOR MATCHES "^(i.86|x86|x64|x86_64|AMD64|amd64)")
 440
 441     set(GMX_ACCELERATION "SSE" CACHE STRING "Accelerated kernels. Pick one of: auto, none, SSE, BlueGene, Power6, ia64, altivec" FORCE)
 442
 443     if (GMX_64_BIT)
 444       set(GMX_X86_64_ASM ON CACHE BOOL "Add SSE assembly files for x86_64" FORCE)
 445     else (GMX_64_BIT)
 446       set(GMX_IA32_ASM ON CACHE BOOL "Add SSE assembly files for i386" FORCE)
 447     endif (GMX_64_BIT)
 448
 449     # Determine the assembler/compiler to use
 450   else()
 451     set(GMX_ACCELERATION "none" CACHE STRING "Accelerated kernels. Pick one of: auto, none, SSE, BlueGene, Power6, ia64, altivec" FORCE)
 452   endif()
 453 endif (${GMX_ACCELERATION} STREQUAL "auto" AND NOT GMX_OPENMM)
 454
 455
 456 include(gmxTestXDR)
 457 gmx_test_xdr(GMX_SYSTEM_XDR)
 458 if(NOT GMX_SYSTEM_XDR)
 459     set(GMX_INTERNAL_XDR 1)
 460     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_INTERNAL_XDR")
 461 endif(NOT GMX_SYSTEM_XDR)
 462
 463 if(GMX_FORTRAN OR GMX_POWER6)
 464     enable_language(Fortran)
 465     include(FortranCInterface)
 466     discover_fortran_mangling(prefix isupper suffix extra_under_score found)
 467     if(extra_under_score)
 468         set(extrasuffix "_")
 469     endif(extra_under_score)
 470
 471     if(isupper)
 472         set(F77_FUNCDEF   "${prefix} ## NAME ## ${suffix}")
 473         set(F77_FUNCDEF_  "${prefix} ## NAME ## ${suffix}${extrasuffix}")
 474     else(isupper)
 475         set(F77_FUNCDEF   "${prefix} ## name ## ${suffix}")
 476         set(F77_FUNCDEF_  "${prefix} ## name ## ${suffix}${extrasuffix}")
 477     endif(isupper)
 478 else(GMX_FORTRAN OR GMX_POWER6)
 479         set(F77_FUNCDEF   "name ## _")
 480         set(F77_FUNCDEF_  "name ## _")
 481 endif(GMX_FORTRAN OR GMX_POWER6)
 482
 483
 484 # Process nonbonded accelerated kernels settings
 485 string(TOUPPER ${GMX_ACCELERATION} ${GMX_ACCELERATION})
 486 if(${GMX_ACCELERATION} STREQUAL "NONE")
 487   # nothing to do
 488 elseif(${GMX_ACCELERATION} STREQUAL "SSE")
 489
 490     if(CMAKE_GENERATOR MATCHES "Visual Studio")
 491       option(GMX_ASM_USEASM-NASM "Use Nasm for assembly instead of compiler (necessary on windows)" ON)
 492     else()
 493       option(GMX_ASM_USEASM-NASM "Use Nasm for assembly instead of compiler (necessary on windows)" OFF)
 494     endif()
 495         mark_as_advanced(GMX_ASM_USEASM-NASM)
 496
 497     if (NOT GMX_64_BIT)
 498         # for 32-bit compiles, we might need to turn on sse
 499         CHECK_C_COMPILER_FLAG("-msse2" XFLAGS_SSE)
 500         if (XFLAGS_SSE)
 501             set(GROMACS_C_FLAGS "-msse2 ${GROMACS_C_FLAGS}")
 502         endif (XFLAGS_SSE)
 503         CHECK_CXX_COMPILER_FLAG("-msse2" XXFLAGS_SSE)
 504         if (XXFLAGS_SSE)
 505             set(GROMACS_CXX_FLAGS "-msse2 ${GROMACS_CXX_FLAGS}")
 506         endif (XXFLAGS_SSE)
 507     endif (NOT GMX_64_BIT)
 508
 509     if(GMX_IA32_ASM)
 510       if(GMX_DOUBLE)
 511         set(GMX_IA32_SSE2 1)
 512       else()
 513         set(GMX_IA32_SSE 1)
 514       endif()
 515     elseif(GMX_X86_64_ASM)
 516       if(GMX_DOUBLE)
 517         set(GMX_X86_64_SSE2 1)
 518       else()
 519         set(GMX_X86_64_SSE 1)
 520       endif()
 521     endif()
 522
 523 #    if(HAVE_PMMINTRIN_H)
 524 #        set(GMX_SSE3 1)
 525 #    endif(HAVE_PMMINTRIN_H)
 526 #    if(HAVE_SMMINTRIN_H)
 527 #        set(GMX_SSE4_1 1)
 528 #    endif(HAVE_SMMINTRIN_H)
 529
 530 elseif(${GMX_ACCELERATION} STREQUAL "FORTRAN")
 531     set(GMX_FORTRAN 1)
 532 elseif(${GMX_ACCELERATION} STREQUAL "BLUEGENE")
 533     set(GMX_BLUEGENE 1)
 534 elseif(${GMX_ACCELERATION} STREQUAL "POWER6")
 535     set(GMX_POWER6 1)
 536 elseif(${GMX_ACCELERATION} STREQUAL "IA64")
 537     set(GMX_IA64_ASM 1)
 538     set(DISABLE_WATERWATER_NLIST 1)
 539     set(DISABLE_WATER_NLIST 1)
 540 elseif(${GMX_ACCELERATION} STREQUAL "ALTIVEC")
 541     check_include_files(altivec.h HAVE_ALTIVEC_H)
 542     if(HAVE_ALTIVEC_H)
 543         set(GMX_PPC_ALTIVEC 1)
 544     endif(HAVE_ALTIVEC_H)
 545 else(${GMX_ACCELERATION} STREQUAL "NONE")
 546     MESSAGE(FATAL_ERROR "Unrecognized option for accelerated kernels: ${GMX_ACCELERATION}. Pick one of auto, none, SSE, Fortran, BlueGene, Power6, ia64, altivec")
 547 endif(${GMX_ACCELERATION} STREQUAL "NONE")
 548
 549
 550
 551
 552
 553
 554
 555 # Process QM/MM Settings
 556 string(TOUPPER ${GMX_QMMM_PROGRAM} ${GMX_QMMM_PROGRAM})
 557 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 558     set(GMX_QMMM_GAUSSIAN 1)
 559 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 560     set(GMX_QMMM_MOPAC 1)
 561 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 562     set(GMX_QMMM_GAMESS 1)
 563 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 564     set(GMX_QMMM_ORCA 1)
 565 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 566     # nothing to do
 567 else(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 568     MESSAGE(FATAL_ERROR "Invalid QM/MM program option: ${GMX_QMMM_PROGRAM}. Choose one of: Gaussian, Mopac, Gamess, Orca, None")
 569 endif(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 570
 571 # Process FFT library settings - if not OpenMM build
 572 string(TOUPPER ${GMX_FFT_LIBRARY} ${GMX_FFT_LIBRARY})
 573 set(PKG_FFT "")
 574 set(PKG_FFT_LIBS "")
 575 if(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 576 #    MESSAGE(STATUS "Using external FFT library - fftw3")
 577     if(GMX_DOUBLE)
 578         find_package(FFTW3 REQUIRED)
 579                 include_directories(${FFTW3_INCLUDE_DIR})
 580         set(FFT_LIBRARIES ${FFTW3_LIBRARIES})
 581         set(PKG_FFT "fftw3")
 582     else(GMX_DOUBLE)
 583         find_package(FFTW3F REQUIRED)
 584         include_directories(${FFTW3F_INCLUDE_DIR})
 585         set(FFT_LIBRARIES ${FFTW3F_LIBRARIES})
 586         set(PKG_FFT "fftw3f")
 587     endif(GMX_DOUBLE)
 588
 589     if(NOT FFTW3_FOUND AND NOT FFTW3F_FOUND)
 590         MESSAGE(FATAL_ERROR "Cannot find fftw3 (with correct precision). Fix it, choose another FFT library, or use the Gromacs built-in fftpack (slower)!")
 591     endif(NOT FFTW3_FOUND AND NOT FFTW3F_FOUND)
 592
 593     set(GMX_FFT_FFTW3 1)
 594
 595 elseif(${GMX_FFT_LIBRARY} STREQUAL "FFTW2")
 596 #    MESSAGE(STATUS "Using external FFT library - fftw2")
 597     if(GMX_DOUBLE)
 598         find_package(FFTW2 REQUIRED)
 599     else(GMX_DOUBLE)
 600         find_package(FFTW2F REQUIRED)
 601     endif(GMX_DOUBLE)
 602
 603     if(NOT FFTW2_FOUND)
 604            MESSAGE(FATAL_ERROR "Cannot find fftw2 (with correct precision). Fix it, choose another FFT library, or use the Gromacs built-in fftpack (slower)!")
 605     endif(NOT FFTW2_FOUND)
 606     include_directories(${FFTW2_INCLUDE_DIR})
 607     set(FFT_LIBRARIES ${FFTW2_LIBRARIES})
 608     set(PKG_FFT_LIBS ${FFTW2_LIBRARIES})
 609
 610     if("${FFTW2_LIBRARIES}" MATCHES "dfftw")
 611         set(FFTW2_NAME_DFFTW 1)
 612     elseif("${FFTW2_LIBRARIES}" MATCHES "sfftw")
 613         set(FFTW2_NAME_SFFTW 1)
 614     else("${FFTW2_LIBRARIES}" MATCHES "dfftw")
 615         set(FFTW2_NAME_FFTW 1)
 616     endif("${FFTW2_LIBRARIES}" MATCHES "dfftw")
 617
 618     set(GMX_FFT_FFTW2 1)
 619 elseif(${GMX_FFT_LIBRARY} STREQUAL "MKL")
 620 #    MESSAGE(STATUS "Using external FFT library - Intel MKL")
 621     find_package(MKL REQUIRED)
 622     include_directories(${MKL_INCLUDE_DIR})
 623     set(FFT_LIBRARIES ${MKL_LIBRARIES})
 624     set(PKG_FFT_LIBS ${MKL_LIBRARIES})
 625
 626     set(GMX_FFT_MKL 1)
 627     set(HAVE_MKL 1)
 628
 629 #elseif(${GMX_FFT_LIBRARY} STREQUAL "ACML")
 630 #    MESSAGE(STATUS "Using external FFT library - AMD core math library")
 631 #    set(GMX_FFT_ACML 1)
 632 elseif(${GMX_FFT_LIBRARY} STREQUAL "FFTPACK")
 633     MESSAGE(STATUS "Using internal FFT library - fftpack")
 634     set(GMX_FFT_FFTPACK 1)
 635 else(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 636     MESSAGE(FATAL_ERROR "Invalid FFT library setting: ${GMX_FFT_LIBRARY}. Choose one of: fftw3, fftw2, mkl, acml, fftpack")
 637 endif(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 638
 639 # MKL has BLAS/LAPACK routines
 640 if(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 641   set(GMX_EXTERNAL_BLAS TRUE CACHE BOOL "Use external BLAS instead of built-in")
 642   set(GMX_EXTERNAL_LAPACK TRUE CACHE BOOL "Use external LAPACK instead of built-in")
 643 else(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 644   set(GMX_EXTERNAL_BLAS FALSE CACHE BOOL "Use external LAPACK instead of built-in")
 645   set(GMX_EXTERNAL_LAPACK FALSE CACHE BOOL "Use external LAPACK instead of built-in")
 646 endif(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 647 mark_as_advanced(GMX_EXTERNAL_LAPACK)
 648 mark_as_advanced(GMX_EXTERNAL_BLAS)
 649
 650 # Math and thread libraries must often come after all others when linking...
 651 if(HAVE_LIBM)
 652     list(APPEND GMX_EXTRA_LIBRARIES m)
 653 endif(HAVE_LIBM)
 654
 655
 656
 657 if(GMX_FAHCORE)
 658   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 659       "Path to swindirect.h")
 660   include_directories(${COREWRAP_INCLUDE_DIR})
 661 endif(GMX_FAHCORE)
 662
 663 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 664 # these are set after everything else
 665 if (NOT DEFINED GROMACS_C_FLAGS_SET)
 666     set(GROMACS_C_FLAGS_SET true CACHE INTERNAL "Whether to reset the C flags"
 667         FORCE)
 668     set(CMAKE_C_FLAGS "${GROMACS_C_FLAGS} ${CMAKE_C_FLAGS}" CACHE STRING
 669         "Flags used by the compiler during all build types" FORCE)
 670     set(CMAKE_CXX_FLAGS "${GROMACS_CXX_FLAGS} ${CMAKE_CXX_FLAGS}" CACHE STRING
 671         "Flags used by the compiler during all build types" FORCE)
 672     set(CMAKE_EXE_LINKER_FLAGS
 673         "${GROMACS_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}"
 674         CACHE STRING "Linker flags" FORCE)
 675 endif (NOT DEFINED GROMACS_C_FLAGS_SET)
 676
 677 ########################################################################
 678 # Specify install locations and which subdirectories to process        #
 679 ########################################################################
 680 set(LIB_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/lib)
 681 set(BIN_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/bin)
 682 set(DATA_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/gromacs)
 683 set(MAN_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/share/man)
 684 set(INCL_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/include)
 685
 686 set(GMXLIBDIR        ${DATA_INSTALL_DIR}/top)
 687
 688 ##################################################################
 689 # Shared library settings - Darwin uses INSTALL_NAME_DIR instead!
 690 ##################################################################
 691 if(NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin")
 692     set(CMAKE_SKIP_BUILD_RPATH  FALSE)
 693     set(CMAKE_BUILD_WITH_INSTALL_RPATH TRUE)
 694     set(CMAKE_INSTALL_RPATH "${LIB_INSTALL_DIR}")
 695     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 696 endif()
 697
 698 add_subdirectory(share)
 699 add_subdirectory(include)
 700 add_subdirectory(man)
 701 add_subdirectory(src)
 702 add_subdirectory(scripts)
 703
 704 #######################
 705 ## uninstall target
 706 #######################
 707     CONFIGURE_FILE(
 708                    "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 709                    "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
 710                    IMMEDIATE @ONLY)
 711 ###########################
 712 ADD_CUSTOM_TARGET(uninstall
 713                   "${CMAKE_COMMAND}" -P
 714                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
 715 ###########################
 716
 717
 718 ########################################################################
 719 # Tests                                                                #
 720 ########################################################################
 721
 722 include(CTest)
 723 mark_as_advanced(BUILD_TESTING)
 724 IF(BUILD_TESTING)
 725         enable_testing()
 726         add_test(TestBuildAll make)
 727         add_subdirectory(tests)
 728 ENDIF()
 729