CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.8)
   2 # Keep CMake suitably quiet on Cygwin
   3 set(CMAKE_LEGACY_CYGWIN_WIN32 0) # Remove when CMake >= 2.8.4 is required
   4
   5 # Allows CPack to act differently for normal tools and mdrun (e.g. because of MPI)
   6 set(CPACK_COMPONENT_GROUP_TOOLS_DESCRIPTION "All GROMACS executable tools")
   7 set(CPACK_COMPONENT_GROUP_MDRUN_DESCRIPTION "GROMACS executable for running simulations")
   8
   9 # override bugs on OS X where Cmake picks gcc (GNU) for C instead of system default cc (Clang).
  10 if(APPLE)
  11     set(CMAKE_C_COMPILER_INIT "cc")
  12 endif(APPLE)
  13
  14 project(Gromacs C)
  15 include(Dart)
  16 mark_as_advanced(DART_ROOT)
  17
  18 # PROJECT_VERSION should have the following structure:
  19 # VERSION-dev[-SUFFIX] where the VERSION should have the for: vMajor.vMinor.vPatch
  20 #
  21 # The "-dev" suffix is important to keep because it makes possible to distinguish
  22 # between a build from official release and a build from git release branch on a
  23 # machine with no git.
  24 #
  25 # NOTE: when releasing the "-dev" suffix needs to be stripped off!
  26 set(PROJECT_VERSION "4.6-dev")
  27 set(CUSTOM_VERSION_STRING ""
  28     CACHE STRING "Custom version string (if empty, use hard-coded default)")
  29 mark_as_advanced(CUSTOM_VERSION_STRING)
  30 if (CUSTOM_VERSION_STRING)
  31     set(PROJECT_VERSION ${CUSTOM_VERSION_STRING})
  32 endif (CUSTOM_VERSION_STRING)
  33 set(SOVERSION 6)
  34 # It is a bit irritating, but this has to be set separately for now!
  35 SET(CPACK_PACKAGE_VERSION_MAJOR "4")
  36 SET(CPACK_PACKAGE_VERSION_MINOR "6")
  37 #SET(CPACK_PACKAGE_VERSION_PATCH "0")
  38
  39 # The numerical gromacs version. It is 40600 for 4.6.0.
  40 # The #define GMX_VERSION in gmx_header_config_h is set to this value.
  41 math(EXPR NUM_VERSION
  42     "${CPACK_PACKAGE_VERSION_MAJOR}*10000 + ${CPACK_PACKAGE_VERSION_MINOR}*100")
  43 if(CPACK_PACKAGE_VERSION_PATCH)
  44     math(EXPR NUM_VERSION
  45          "${NUM_VERSION} + ${CPACK_PACKAGE_VERSION_PATCH}")
  46 endif()
  47
  48 # The API version tracks the numerical Gromacs version (for now).
  49 # It is potentially different from the Gromacs version in the future, if
  50 # the programs/libraries diverge from the presumably more stable API.
  51 # The #define GMX_API_VERSION in version.h is set to this value to
  52 # provide backward compatibility of software written against the Gromacs API.
  53 set(API_VERSION ${NUM_VERSION})
  54
  55 # Cmake modules/macros are in a subdirectory to keep this file cleaner
  56 set(CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake)
  57
  58 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT AND UNIX)
  59 set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
  60 endif()
  61
  62 if(NOT CMAKE_BUILD_TYPE)
  63     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel." FORCE)
  64 endif(NOT CMAKE_BUILD_TYPE)
  65
  66 enable_language(C)
  67
  68 set(GMX_USE_RELATIVE_INSTALL_PATH OFF CACHE STRING "Use relative paths not absolute paths for cmake install. Has only an effect on cpack.")
  69 mark_as_advanced(GMX_USE_RELATIVE_INSTALL_PATH)
  70
  71 set(CPACK_PACKAGE_VERSION ${PROJECT_VERSION})
  72 set(CPACK_PACKAGE_VENDOR "gromacs.org")
  73 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Gromacs - a toolkit for high-performance molecular simulation")
  74 if (NOT GMX_USE_RELATIVE_INSTALL_PATH)
  75     set(CPACK_SET_DESTDIR "ON")
  76 endif()
  77 set(CPACK_RESOURCE_FILE_WELCOME "${CMAKE_SOURCE_DIR}/admin/InstallWelcome.txt")
  78 # Its GPL/LGPL, so they do not have to agree to a license for mere usage, but some installers require this...
  79 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_SOURCE_DIR}/COPYING")
  80 set(CPACK_RESOURCE_FILE_README "${CMAKE_SOURCE_DIR}/admin/InstallInfo.txt")
  81 set(CPACK_SOURCE_IGNORE_FILES ".isreposource;.git;.gitignore")
  82 set(CPACK_PROJECT_CONFIG_FILE "${CMAKE_SOURCE_DIR}/CPackInit.cmake")
  83 SET(CPACK_SOURCE_INSTALLED_DIRECTORIES "${CMAKE_SOURCE_DIR};/;${CMAKE_BINARY_DIR}/man;man")
  84 set(CPACK_PACKAGE_CONTACT "gmx-users@gromacs.org")
  85
  86 #must come after all cpack settings!
  87 include(CPack)
  88
  89 ########################################################################
  90 # Check and warn if cache generated on a different host is being reused
  91 ########################################################################
  92 if(CMAKE_HOST_UNIX)
  93     execute_process(COMMAND hostname
  94                     OUTPUT_VARIABLE TMP_HOSTNAME
  95                     OUTPUT_STRIP_TRAILING_WHITESPACE)
  96     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}")
  97         message(WARNING "
  98             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
  99             is being reused! This could lead to inconsitencies; therefore, it is
 100             recommended to regenerate the cache!")
 101     endif()
 102     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
 103             "Hostname of the machine where the cache was generated.")
 104 endif()
 105
 106 ########################################################################
 107 # User input options - enable C++ - before any CXX flags are changed   #
 108 ########################################################################
 109 option(GMX_GPU  "Enable GPU acceleration" ON)
 110 option(GMX_OPENMM "Accelerated execution on GPUs through the OpenMM library (rerun cmake after changing to see relevant options)" OFF)
 111 option(GMX_FORCE_CXX "Enable C++ compilation even if not necessary" OFF)
 112 mark_as_advanced(GMX_FORCE_CXX)
 113 if(GMX_GPU OR GMX_OPENMM OR GMX_FORCE_CXX)
 114     enable_language(CXX)
 115 endif()
 116 set(CMAKE_PREFIX_PATH "" CACHE STRING "Extra locations to search for external libraries and tools (give directory without lib, bin, or include)")
 117
 118 ########################################################################
 119 # Fix stupid flags on Windows
 120 ########################################################################
 121 SET(SHARED_LIBS_DEFAULT ON)
 122 IF( WIN32 AND NOT CYGWIN)
 123   option(GMX_PREFER_STATIC_LIBS "When finding libraries prefer static system libraries (MT instead of MD)!" ON)
 124   mark_as_advanced(GMX_PREFER_STATIC_LIBS)
 125   SET(SHARED_LIBS_DEFAULT OFF)  #is currently not working on Windows
 126
 127   IF (GMX_PREFER_STATIC_LIBS)
 128     #Only setting Debug and Release flags. Others configurations current not used.
 129     STRING(REPLACE /MD /MT CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE})
 130     SET(CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE} CACHE STRING "" FORCE)
 131     STRING(REPLACE /MD /MT CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG})
 132     SET(CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG} CACHE STRING "" FORCE)
 133     if(CMAKE_CXX_COMPILER_LOADED)
 134         STRING(REPLACE /MD /MT CMAKE_CXX_FLAGS_RELEASE ${CMAKE_CXX_FLAGS_RELEASE})
 135         SET(CMAKE_CXX_FLAGS_RELEASE ${CMAKE_CXX_FLAGS_RELEASE} CACHE STRING "" FORCE)
 136         STRING(REPLACE /MD /MT CMAKE_CXX_FLAGS_DEBUG ${CMAKE_CXX_FLAGS_DEBUG})
 137         SET(CMAKE_CXX_FLAGS_DEBUG ${CMAKE_CXX_FLAGS_DEBUG} CACHE STRING "" FORCE)
 138     endif()
 139   ENDIF()
 140
 141   #Workaround for cmake bug 13174. Replace deprecated options.
 142   IF( CMAKE_C_COMPILER_ID MATCHES "Intel" )
 143     STRING(REPLACE /GZ /RTC1 CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG})
 144     SET(CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG} CACHE STRING "" FORCE)
 145   ENDIF()
 146   IF( CMAKE_CXX_COMPILER_ID MATCHES "Intel" AND CMAKE_CXX_COMPILER_LOADED)
 147     STRING(REPLACE /GZ /RTC1 CMAKE_CXX_FLAGS_DEBUG ${CMAKE_CXX_FLAGS_DEBUG})
 148     STRING(REPLACE /GX /EHsc CMAKE_CXX_FLAGS_DEBUG ${CMAKE_CXX_FLAGS_DEBUG})
 149     SET(CMAKE_CXX_FLAGS_DEBUG ${CMAKE_CXX_FLAGS_DEBUG} CACHE STRING "" FORCE)
 150
 151     STRING(REPLACE /GX /EHsc CMAKE_CXX_FLAGS_RELEASE ${CMAKE_CXX_FLAGS_RELEASE})
 152     SET(CMAKE_CXX_FLAGS_RELEASE ${CMAKE_CXX_FLAGS_RELEASE} CACHE STRING "" FORCE)
 153   ENDIF()
 154 ENDIF()
 155
 156
 157 ########################################################################
 158 # User input options                                                   #
 159 ########################################################################
 160 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" OFF)
 161 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 162 option(GMX_THREAD_MPI  "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" ON)
 163 option(GMX_SOFTWARE_INVSQRT "Use GROMACS software 1/sqrt" ON)
 164 mark_as_advanced(GMX_SOFTWARE_INVSQRT)
 165 option(GMX_POWERPC_INVSQRT "Use PowerPC hardware 1/sqrt" OFF)
 166 mark_as_advanced(GMX_POWERPC_INVSQRT)
 167 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 168 mark_as_advanced(GMX_FAHCORE)
 169
 170 include(gmxDetectAcceleration)
 171 if(NOT DEFINED GMX_CPU_ACCELERATION)
 172     if(CMAKE_CROSSCOMPILING)
 173         set(GMX_SUGGESTED_CPU_ACCELERATION "None")
 174     else(CMAKE_CROSSCOMPILING)
 175         gmx_detect_acceleration(GMX_SUGGESTED_CPU_ACCELERATION)
 176     endif(CMAKE_CROSSCOMPILING)
 177 endif(NOT DEFINED GMX_CPU_ACCELERATION)
 178
 179 set(GMX_CPU_ACCELERATION "@GMX_SUGGESTED_CPU_ACCELERATION@"
 180     CACHE STRING "Accelerated CPU kernels. Pick one of: None, SSE2, SSE4.1, AVX_128_FMA, AVX_256, BlueGene, Power6, Fortran")
 181
 182 set(GMX_FFT_LIBRARY "fftw3"
 183     CACHE STRING "FFT library choices: fftw3,mkl,fftpack[built-in]")
 184 option(GMX_DISABLE_FFTW_MEASURE
 185        "Do not optimize FFTW setups (not needed with SSE)" OFF)
 186 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 187 set(GMX_QMMM_PROGRAM "none"
 188     CACHE STRING "QM package choices: none,gaussian,mopac,gamess,orca")
 189 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 190 mark_as_advanced(GMX_BROKEN_CALLOC)
 191 option(GMX_MPI_IN_PLACE "Enable MPI_IN_PLACE for MPIs that have it defined" ON)
 192 mark_as_advanced(GMX_MPI_IN_PLACE)
 193 option(GMX_LOAD_PLUGINS "Compile with plugin support, needed to read VMD supported file formats" ON)
 194 mark_as_advanced(GMX_LOAD_PLUGINS)
 195
 196 option(GMX_OPENMP "Enable OpenMP-based multithreading" ON)
 197
 198 option(USE_VERSION_H "Generate development version string/information" ON)
 199 mark_as_advanced(USE_VERSION_H)
 200
 201 option(GMX_DEFAULT_SUFFIX "Use default suffixes for GROMACS binaries and libs (_d for double, _mpi for MPI; rerun cmake after changing to see relevant options)" ON)
 202
 203 if(UNIX)
 204     option(GMX_PREFER_STATIC_LIBS "When finding libraries prefer static archives (not available on non-*nix platforms and it will only work if static versions of external dependencies are available and found)!" OFF)
 205     mark_as_advanced(GMX_PREFER_STATIC_LIBS)
 206 endif()
 207
 208 option(GMX_CYCLE_SUBCOUNTERS "Enable cycle subcounters to get a more detailed cycle timings" OFF)
 209 mark_as_advanced(GMX_CYCLE_SUBCOUNTERS)
 210
 211 ######################################################################
 212 # Compiler tests
 213 # These need to be done early (before further tests).
 214 #####################################################################
 215
 216 # The cmake/Check{C,CXX}CompilerFlag.cmake files in the GROMACS distribution
 217 # are used with permission from CMake v2.8.9 so that GROMACS can detect
 218 # invalid options with the Intel Compilers.
 219 # These files should be removed from the source tree when a CMake version that
 220 # includes the features in question becomes required for building GROMACS.
 221 include(CheckCCompilerFlag)
 222 if(CMAKE_CXX_COMPILER_LOADED)
 223     include(CheckCXXCompilerFlag)
 224 endif()
 225
 226 # OpenMP check must come before other CFLAGS!
 227 if(GMX_OPENMP)
 228     find_package(OpenMP)
 229     if(OPENMP_FOUND)
 230         # CMake on Windows doesn't support linker flags passed to target_link_libraries
 231         # (i.e. it treats /openmp as \openmp library file). Also, no OpenMP linker flags are needed.
 232         if(NOT (WIN32 AND NOT CYGWIN))
 233             if(CMAKE_COMPILER_IS_GNUCC AND GMX_PREFER_STATIC_OPENMP)
 234                 set(OpenMP_LINKER_FLAGS "-Wl,-static -lgomp -lrt -Wl,-Bdynamic -lpthread")
 235                 set(OpenMP_SHARED_LINKER_FLAGS "")
 236             else()
 237                 # Only set a linker flag if the user didn't set them manually
 238                 if(NOT DEFINED OpenMP_LINKER_FLAGS)
 239                     set(OpenMP_LINKER_FLAGS "${OpenMP_C_FLAGS}")
 240                 endif()
 241                 if(NOT DEFINED OpenMP_SHARED_LINKER_FLAGS)
 242                     set(OpenMP_SHARED_LINKER_FLAGS "${OpenMP_C_FLAGS}")
 243                 endif()
 244             endif()
 245         endif()
 246     else(OPENMP_FOUND)
 247         message(WARNING
 248                 "The compiler you are using does not support OpenMP parallelism. This might hurt your performance a lot, in particular with GPUs. Try using a more recent version, or a different compiler. For now, we are proceeding by turning off OpenMP.")
 249         set(GMX_OPENMP OFF CACHE STRING "Whether GROMACS will use OpenMP parallelism." FORCE)
 250     endif(OPENMP_FOUND)
 251 endif()
 252
 253
 254 include(gmxCFlags)
 255 gmx_c_flags()
 256
 257 include(gmxGetCompilerVersion)
 258 get_compiler_version()
 259
 260 # gcc 4.4.x is buggy and crashes when compiling some files with O3 and OpenMP on.
 261 # Detect here whether applying a workaround is needed and will apply it later
 262 # on the affected files.
 263 include(gmxGCC44O3BugWorkaround)
 264 gmx_check_gcc44_bug_workaround_needed(GMX_USE_GCC44_BUG_WORKAROUND)
 265
 266 ########################################################################
 267 # Set up binary and library suffixing
 268 ########################################################################
 269 set(GMX_BINARY_SUFFIX "" CACHE STRING "Suffix for GROMACS binaries (default: _d for double, _mpi for MPI, _mpi_d for MPI and double).")
 270 set(GMX_LIBS_SUFFIX ""
 271   CACHE STRING "Suffix for GROMACS libs (default: _d for double, _mpi for MPI, _mpi_d for MPI and double).")
 272 if (GMX_DEFAULT_SUFFIX)
 273   set(GMX_BINARY_SUFFIX "")
 274   set(GMX_LIBS_SUFFIX "")
 275   if (GMX_MPI)
 276     set(GMX_BINARY_SUFFIX "_mpi")
 277     set(GMX_LIBS_SUFFIX "_mpi")
 278   endif(GMX_MPI)
 279   if (GMX_DOUBLE)
 280     set (GMX_BINARY_SUFFIX "${GMX_BINARY_SUFFIX}_d")
 281     set (GMX_LIBS_SUFFIX "${GMX_LIBS_SUFFIX}_d")
 282   endif(GMX_DOUBLE)
 283   if (GMX_OPENMM)
 284     set (GMX_BINARY_SUFFIX "-openmm")
 285     set (GMX_LIBS_SUFFIX "_openmm")
 286   endif(GMX_OPENMM)
 287   mark_as_advanced(FORCE GMX_BINARY_SUFFIX GMX_LIBS_SUFFIX)
 288   if (NOT SUFFIX_QUIETLY)
 289     message(STATUS "Using default binary suffix: \"${GMX_BINARY_SUFFIX}\"")
 290     message(STATUS "Using default library suffix: \"${GMX_LIBS_SUFFIX}\"")
 291   endif (NOT SUFFIX_QUIETLY)
 292 else(GMX_DEFAULT_SUFFIX)
 293   mark_as_advanced(CLEAR GMX_BINARY_SUFFIX GMX_LIBS_SUFFIX)
 294   if (NOT SUFFIX_QUIETLY)
 295     message(STATUS "Using manually set binary suffix: \"${GMX_BINARY_SUFFIX}\"")
 296     message(STATUS "Using manually set library suffix: \"${GMX_LIBS_SUFFIX}\"")
 297   endif (NOT SUFFIX_QUIETLY)
 298 endif(GMX_DEFAULT_SUFFIX)
 299 set(SUFFIX_QUIETLY TRUE CACHE INTERNAL "")
 300
 301 set(PKG_CFLAGS "")
 302 if(GMX_DOUBLE)
 303     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_DOUBLE")
 304 endif(GMX_DOUBLE)
 305 if(GMX_SOFTWARE_INVSQRT)
 306   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_SOFTWARE_INVSQRT")
 307 endif(GMX_SOFTWARE_INVSQRT)
 308 if(GMX_POWERPC_INVSQRT)
 309   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_POWERPC_INVSQRT")
 310 endif(GMX_POWERPC_INVSQRT)
 311
 312 ########################################################################
 313 #Process MPI settings
 314 ########################################################################
 315 include(gmxManageMPI)
 316
 317 #######################################################################
 318 # Check for options incompatible with OpenMM build                    #
 319 #######################################################################
 320 if(GMX_OPENMM)
 321     # we'll use the built-in fft to avoid unnecessary dependencies
 322     string(TOUPPER ${GMX_FFT_LIBRARY} GMX_FFT_LIBRARY)
 323     if(NOT ${GMX_FFT_LIBRARY} STREQUAL "FFTPACK")
 324         message(STATUS "No external FFT libraries needed for the OpenMM build, switching to fftpack!")
 325         set(GMX_FFT_LIBRARY "fftpack" CACHE STRING
 326                 "No external FFT libraries needed for the OpenMM build, switching to  fftpack!" FORCE)
 327     endif()
 328     if(GMX_MPI)
 329         message(FATAL_ERROR "The OpenMM build is not compatible with MPI!")
 330     endif(GMX_MPI)
 331     if(GMX_THREAD_MPI)
 332         message(STATUS "Thread-MPI not compatible with OpenMM, disabled!")
 333         set(GMX_THREAD_MPI OFF CACHE BOOL
 334                 "Thread-MPI not compatible with OpenMM build, disabled!" FORCE)
 335     endif(GMX_THREAD_MPI)
 336     if(GMX_OPENMP)
 337         message(STATUS "OpenMP multithreading not compatible with OpenMM, disabled")
 338         set(GMX_OPENMP OFF CACHE BOOL
 339             "OpenMP multithreading not compatible with OpenMM, disabled!" FORCE)
 340     endif()
 341     if(GMX_SOFTWARE_INVSQRT)
 342         set(GMX_SOFTWARE_INVSQRT OFF CACHE STRING
 343                 "The OpenMM build does not need GROMACS software 1/sqrt!" FORCE)
 344     endif(GMX_SOFTWARE_INVSQRT)
 345     string(TOUPPER ${GMX_CPU_ACCELERATION} GMX_CPU_ACCELERATION)
 346     if(NOT GMX_CPU_ACCELERATION STREQUAL "NONE")
 347         message(STATUS "Switching off CPU-based acceleration, the OpenMM build does not support/need any!")
 348         set(GMX_CPU_ACCELERATION "None" CACHE STRING
 349             "Switching off CPU-based acceleration, the OpenMM build does not support/need any!" FORCE)
 350     endif()
 351     if(GMX_FAHCORE)
 352         message(FATAL_ERROR "The OpenMM build does not support FAH build!")
 353     endif(GMX_FAHCORE)
 354     if(GMX_DOUBLE)
 355         message(FATAL_ERROR  "The OpenMM-build does not support double precision calculations!")
 356     endif()
 357     # mark as advanced the unused variables
 358     mark_as_advanced(FORCE GMX_CPU_ACCELERATION GMX_MPI GMX_FFT_LIBRARY
 359         GMX_QMMM_PROGRAM GMX_THREAD_MPI GMX_DOUBLE)
 360 else(GMX_OPENMM)
 361      mark_as_advanced(CLEAR GMX_CPU_ACCELERATION GMX_MPI GMX_FFT_LIBRARY
 362         GMX_QMMM_PROGRAM GMX_THREAD_MPI GMX_DOUBLE)
 363 endif(GMX_OPENMM)
 364
 365
 366 ########################################################################
 367 # Basic system tests (standard libraries, headers, functions, types)   #
 368 ########################################################################
 369 include(CheckIncludeFiles)
 370 check_include_files(string.h     HAVE_STRING_H)
 371 check_include_files(math.h       HAVE_MATH_H)
 372 check_include_files(limits.h     HAVE_LIMITS_H)
 373 check_include_files(memory.h     HAVE_MEMORY_H)
 374 check_include_files(unistd.h     HAVE_UNISTD_H)
 375 check_include_files(direct.h     HAVE_DIRECT_H)
 376 check_include_files(pwd.h        HAVE_PWD_H)
 377 check_include_files(stdint.h     HAVE_STDINT_H)
 378 check_include_files(stdlib.h     HAVE_STDLIB_H)
 379 check_include_files(pthread.h    HAVE_PTHREAD_H)
 380 check_include_files(dirent.h     HAVE_DIRENT_H)
 381 check_include_files(inttypes.h   HAVE_INTTYPES_H)
 382 check_include_files(regex.h      HAVE_REGEX_H)
 383 check_include_files(sys/types.h  HAVE_SYS_TYPES_H)
 384 check_include_files(sys/stat.h   HAVE_SYS_STAT_H)
 385 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 386 check_include_files(rpc/rpc.h    HAVE_RPC_RPC_H)
 387 check_include_files("rpc/rpc.h;rpc/xdr.h"    HAVE_RPC_XDR_H)
 388 check_include_files(io.h                 HAVE_IO_H)
 389 check_include_files(sched.h      HAVE_SCHED_H)
 390
 391 include(CheckFunctionExists)
 392 check_function_exists(strcasecmp        HAVE_STRCASECMP)
 393 check_function_exists(strdup            HAVE_STRDUP)
 394 check_function_exists(vprintf           HAVE_VPRINTF)
 395 check_function_exists(memcmp            HAVE_MEMCMP)
 396 check_function_exists(posix_memalign    HAVE_POSIX_MEMALIGN)
 397 check_function_exists(memalign          HAVE_MEMALIGN)
 398 check_function_exists(_aligned_malloc   HAVE__ALIGNED_MALLOC)
 399 check_function_exists(gettimeofday      HAVE_GETTIMEOFDAY)
 400 check_function_exists(isnan             HAVE_ISNAN)
 401 check_function_exists(_isnan            HAVE__ISNAN)
 402 check_function_exists(fsync             HAVE_FSYNC)
 403 check_function_exists(_fileno           HAVE__FILENO)
 404 check_function_exists(fileno            HAVE_FILENO)
 405 check_function_exists(_commit           HAVE__COMMIT)
 406 check_function_exists(lstat             HAVE_LSTAT)
 407 check_function_exists(sigaction         HAVE_SIGACTION)
 408 check_function_exists(sysconf           HAVE_SYSCONF)
 409 check_function_exists(sched_setaffinity HAVE_SCHED_SETAFFINITY)
 410 check_function_exists(sched_getaffinity HAVE_SCHED_GETAFFINITY)
 411 check_function_exists(rsqrt             HAVE_RSQRT)
 412 check_function_exists(rsqrtf            HAVE_RSQRTF)
 413 check_function_exists(sqrtf             HAVE_SQRTF)
 414
 415 include(CheckLibraryExists)
 416 check_library_exists(m sqrt "" HAVE_LIBM)
 417 check_library_exists(m cbrt "" HAVE_CBRT)
 418
 419
 420 include(CheckTypeSize)
 421
 422 check_type_size("bool"          SIZEOF_BOOL) # will also set HAVE_BOOL
 423 check_type_size("int"           SIZEOF_INT)
 424 check_type_size("long int"      SIZEOF_LONG_INT)
 425 check_type_size("long long int" SIZEOF_LONG_LONG_INT)
 426 check_type_size("off_t"         SIZEOF_OFF_T)
 427 check_type_size("void *"        SIZEOF_VOIDP)
 428
 429 if (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 430     set(GMX_64_BIT TRUE)
 431 else (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 432     set(GMX_64_BIT FALSE)
 433 endif (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 434
 435 # Check for some basic types that we *need*, so set these to int if they are not present
 436 check_type_size(uid_t uid_t)
 437 if(NOT uid_t)
 438   set(uid_t int)
 439 else(NOT uid_t)
 440   set(uid_t 0)
 441 endif(NOT uid_t)
 442
 443 check_type_size(gid_t gid_t)
 444 if(NOT gid_t)
 445   set(gid_t 1)
 446 else(NOT gid_t)
 447   set(gid_t 0)
 448 endif(NOT gid_t)
 449
 450 check_type_size(size_t size_t)
 451 if(NOT size_t)
 452   set(size_t int)
 453 else(NOT size_t)
 454   set(size_t 0)
 455 endif(NOT size_t)
 456
 457 check_type_size(off_t off_t)
 458 if(NOT off_t)
 459   set(off_t int)
 460 else(NOT off_t)
 461   set(off_t 0)
 462 endif(NOT off_t)
 463
 464 include(TestBigEndian)
 465 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 466
 467
 468
 469
 470 ########################################################################
 471 # Find external packages                                               #
 472 ########################################################################
 473 if(UNIX)
 474     if(GMX_PREFER_STATIC_LIBS)
 475         # On Linux .a is the static library suffix, on Mac OS X .lib can also
 476         # be used, so we'll add both to the preference list.
 477         SET(CMAKE_FIND_LIBRARY_SUFFIXES ".lib;.a" ${CMAKE_FIND_LIBRARY_SUFFIXES})
 478         if(SHARED_LIBS_DEFAULT)
 479             if(BUILD_SHARED_LIBS) #Warn the user about the combination. But don't overwrite the request.
 480                 message(WARNING "Static libraries requested, and shared Gromacs libraries requested.")
 481             elseif(NOT DEFINED BUILD_SHARED_LIBS) #Change default to OFF. Don't warn if it's already off.
 482                 message(WARNING "Static libraries requested, the GROMACS libraries will also be build static (BUILD_SHARED_LIBS=OFF)")
 483                 set(SHARED_LIBS_DEFAULT OFF)
 484             endif()
 485         endif()
 486     endif()
 487 endif()
 488 option(BUILD_SHARED_LIBS "Enable shared libraries (can be problematic with MPI, Windows)" ${SHARED_LIBS_DEFAULT})
 489
 490 option(GMX_GSL "Add support for gsl" OFF)
 491 if (GMX_GSL)
 492   find_package(gsl)
 493   set(PKG_GSL "")
 494   if(GSL_FOUND)
 495     include_directories(${GSL_INCLUDE_DIR})
 496     set(PKG_GSL gsl)
 497     set(HAVE_LIBGSL 1)
 498   endif(GSL_FOUND)
 499 endif (GMX_GSL)
 500
 501 option(GMX_X11 "Use X window system" OFF)
 502 if (GMX_X11)
 503         find_package(X11)
 504         # X11 includes/libraries are only set in the ngmx subdirectory!
 505         if(X11_FOUND)
 506         set(HAVE_X11 1)
 507         endif(X11_FOUND)
 508 endif(GMX_X11)
 509
 510 include(ThreadMPI)
 511 set(THREAD_MPI_LIB thread_mpi)
 512 if(GMX_THREAD_MPI)
 513     tmpi_get_source_list(THREAD_MPI_SRC)
 514     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_THREAD_MPI")
 515     set(GMX_MPI 1)
 516 else(GMX_THREAD_MPI)
 517     tmpi_get_source_list(THREAD_MPI_SRC NOMPI)
 518 endif(GMX_THREAD_MPI)
 519
 520 if(GMX_OPENMM)
 521     set(CUDA_BUILD_EMULATION OFF)
 522     find_package(CUDA 3.1 REQUIRED)
 523     add_definitions(-DGMX_OPENMM)
 524     if(CMAKE_BUILD_TYPE STREQUAL "DEBUG")
 525         set(CUDA_VERBOSE_BUILD ON)
 526     endif()
 527     find_package(OpenMM)
 528 endif(GMX_OPENMM)
 529
 530
 531 if(GMX_GPU)
 532     if(GMX_DOUBLE)
 533         message(WARNING "GPU acceleration is not available in double precision, disabled!")
 534         set(GMX_GPU OFF CACHE BOOL "Enable GPU acceleration" FORCE)
 535     endif()
 536 endif(GMX_GPU)
 537
 538 if(GMX_GPU)
 539
 540     # We support CUDA >=v3.2 on *nix, but <= v4.1 doesn't work with MSVC
 541     if(MSVC)
 542         find_package(CUDA 4.1)
 543     else()
 544         find_package(CUDA 3.2)
 545     endif()
 546
 547     if (NOT EXISTS ${CUDA_TOOLKIT_ROOT_DIR})
 548         message(FATAL_ERROR "
 549     mdrun supports native GPU acceleration on NVIDIA hardware with compute
 550     capability >=2.0. This requires the NVIDIA CUDA library, which was not
 551     found; the location can be hinted by setting CUDA_TOOLKIT_ROOT_DIR.
 552
 553     CPU or GPU acceleration can be selected at runtime, but if you are
 554     sure you can not make use of GPU acceleration, disable it by setting
 555     the CMake variable GMX_GPU=OFF.")
 556     endif()
 557
 558     if(NOT GMX_OPENMP)
 559         message(WARNING "
 560     In order to use GPU acceleration efficiently, mdrun requires OpenMP multithreding.
 561     Without OpenMP only a single CPU core per GPU can be used which is suboptimal.
 562     Note that with MPI multiple processes can be forced to use a single GPU, but this
 563     typically inefficient.")
 564     endif()
 565
 566     include(gmxManageNvccConfig)
 567
 568     # Check whether we can use atomic operations needed for polling wait for GPU
 569     # (to avoid the cudaStreamSynchronize + ECC bug).
 570     # With thread-MPI testing atomics has already been carried out, but without
 571     # thread-MPI we need to invoke the atomics test independently.
 572     if (NOT GMX_THREAD_MPI)
 573         set(TEST_TMPI_ATOMICS_ONLY ON CACHE INTERNAL
 574             "Test only the atomic operations of thread-MPI.")
 575         include(ThreadMPI)
 576     endif()
 577
 578 endif()
 579 # Annoyingly enough, FindCUDA leaves a few variables behind as non-advanced.
 580 # We need to mark these advanced outside the conditional, otherwise, if the user
 581 # tuns GMX_GPU=OFF after a failed cmake pass, these variables will be left behind.
 582 mark_as_advanced(CUDA_BUILD_CUBIN CUDA_BUILD_EMULATION CUDA_SDK_ROOT_DIR CUDA_VERBOSE_BUILD)
 583
 584 if(APPLE)
 585    find_library(ACCELERATE_FRAMEWORK Accelerate)
 586    list(APPEND GMX_EXTRA_LIBRARIES ${ACCELERATE_FRAMEWORK})
 587 endif(APPLE)
 588
 589 if(CYGWIN)
 590     set(GMX_CYGWIN 1)
 591 endif(CYGWIN)
 592
 593 if(WIN32 AND NOT CYGWIN)
 594     set(GMX_NATIVE_WINDOWS 1)
 595 endif()
 596
 597 # only bother with finding git and using version.h if the source is a git repo
 598 if(EXISTS "${CMAKE_SOURCE_DIR}/.git")
 599     if(USE_VERSION_H)
 600         # We need at least git v1.5.3 be able to parse git's date output. If not
 601         # found or the version is too small, we can't generate version information.
 602         find_package(Git)
 603
 604         # Find out the git version
 605         if(GIT_FOUND AND NOT GIT_VERSION)
 606           execute_process(COMMAND ${GIT_EXECUTABLE} "--version"
 607             OUTPUT_VARIABLE _exec_out
 608             OUTPUT_STRIP_TRAILING_WHITESPACE)
 609           string(REGEX REPLACE "git version (.*)" "\\1" GIT_VERSION ${_exec_out})
 610           set(GIT_VERSION ${GIT_VERSION} CACHE STRING "Git version")
 611           mark_as_advanced(GIT_VERSION)
 612         endif()
 613
 614         if(NOT GIT_FOUND OR GIT_VERSION VERSION_LESS "1.5.3")
 615           message("No compatible git version found, won't be able to generate proper development version information.")
 616           set(USE_VERSION_H OFF)
 617         endif()
 618     endif()
 619 else()
 620     set(USE_VERSION_H OFF)
 621 endif()
 622
 623 ########################################################################
 624 # Generate development version info for cache
 625 ########################################################################
 626 # set(GEN_VERSION_INFO_INTERNAL "ON")
 627 # include(gmxGenerateVersionString)
 628
 629 ########################################################################
 630 # Our own GROMACS tests
 631 ########################################################################
 632
 633 add_definitions( -DHAVE_CONFIG_H )
 634 include_directories(${CMAKE_BINARY_DIR}/src)
 635 include_directories(${CMAKE_BINARY_DIR}/include)
 636 include_directories(${CMAKE_SOURCE_DIR}/include)
 637
 638 include(gmxTestInlineASM)
 639 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 640
 641 include(gmxSetBuildInformation)
 642 gmx_set_build_information()
 643 if(BUILD_CPU_FEATURES MATCHES "rdtscp" AND NOT GMX_DISTRIBUTABLE_BUILD)
 644     # The timestep counter headers do not include config.h
 645     add_definitions(-DHAVE_RDTSCP)
 646 endif(BUILD_CPU_FEATURES MATCHES "rdtscp" AND NOT GMX_DISTRIBUTABLE_BUILD)
 647
 648 include(gmxTestFloatFormat)
 649 gmx_test_float_format(GMX_FLOAT_FORMAT_IEEE754
 650                       GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER
 651                       GMX_IEEE754_BIG_ENDIAN_WORD_ORDER)
 652
 653 include(gmxTestLargeFiles)
 654 gmx_test_large_files(GMX_LARGEFILES)
 655
 656 include(gmxTestSignal)
 657 gmx_test_sigusr1(HAVE_SIGUSR1)
 658
 659 include(gmxTestInline)
 660 gmx_test_inline(INLINE_KEYWORD)
 661
 662 include(gmxTestRestrict)
 663 gmx_test_restrict(RESTRICT_KEYWORD)
 664
 665 include(gmxTestPipes)
 666 gmx_test_pipes(HAVE_PIPES)
 667
 668 include(gmxTestIsfinite)
 669 gmx_test_isfinite(HAVE_ISFINITE)
 670 gmx_test__isfinite(HAVE__ISFINITE)
 671 gmx_test__finite(HAVE__FINITE)
 672
 673 include(gmxTestXDR)
 674 gmx_test_xdr(GMX_SYSTEM_XDR)
 675 if(NOT GMX_SYSTEM_XDR)
 676     set(GMX_INTERNAL_XDR 1)
 677     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_INTERNAL_XDR")
 678 endif(NOT GMX_SYSTEM_XDR)
 679
 680 # Process nonbonded accelerated kernels settings
 681 string(TOUPPER ${GMX_CPU_ACCELERATION} ${GMX_CPU_ACCELERATION})
 682 if(${GMX_CPU_ACCELERATION} STREQUAL "NONE")
 683     # nothing to do
 684 elseif(${GMX_CPU_ACCELERATION} STREQUAL "SSE2")
 685
 686     GMX_TEST_CFLAG(GNU_SSE2_CFLAG "-msse2" GROMACS_C_FLAGS)
 687     if(NOT GNU_SSE2_CFLAG)
 688         GMX_TEST_CFLAG(MSVC_SSE2_CFLAG "/arch:SSE2" GROMACS_C_FLAGS)
 689     endif(NOT GNU_SSE2_CFLAG)
 690
 691     if (CMAKE_CXX_COMPILER_LOADED)
 692         GMX_TEST_CXXFLAG(GNU_SSE2_CXXFLAG "-msse2" GROMACS_CXX_FLAGS)
 693         if(NOT GNU_SSE2_CXXFLAG)
 694             GMX_TEST_CXXFLAG(MSVC_SSE2_CXXFLAG "/arch:SSE2" GROMACS_CXX_FLAGS)
 695         endif(NOT GNU_SSE2_CXXFLAG)
 696     endif()
 697
 698     # We dont warn for lacking SSE2 flag support, since that is probably standard today.
 699
 700     # Only test the include after we have tried to add the correct flag for SSE2 support
 701     check_include_file(emmintrin.h  HAVE_EMMINTRIN_H ${GROMACS_C_FLAGS})
 702
 703     if(NOT HAVE_EMMINTRIN_H)
 704         message(FATAL_ERROR "Cannot find emmintrin.h, which is required for SSE2 intrinsics support.")
 705     endif(NOT HAVE_EMMINTRIN_H)
 706
 707     set(GMX_CPU_ACCELERATION_X86_SSE2 1)
 708     # The user should not be able to set this orthogonally to the acceleration
 709     set(GMX_X86_SSE2 1)
 710     if (NOT ACCELERATION_QUIETLY)
 711       message(STATUS "Enabling SSE2 Gromacs acceleration, and it will help compiler optimization.")
 712     endif()
 713
 714 elseif(${GMX_CPU_ACCELERATION} STREQUAL "SSE4.1")
 715
 716     GMX_TEST_CFLAG(GNU_SSE4_CFLAG "-msse4.1" GROMACS_C_FLAGS)
 717     if (NOT GNU_SSE4_CFLAG)
 718         GMX_TEST_CFLAG(MSVC_SSE4_CFLAG "/arch:SSE4.1" GROMACS_C_FLAGS)
 719     endif(NOT GNU_SSE4_CFLAG)
 720     if (NOT GNU_SSE4_CFLAG AND NOT MSVC_SSE4_CFLAG)
 721         message(WARNING "No C SSE4.1 flag found. Consider a newer compiler, or disable SSE4.1 for slightly lower performance.")
 722         # Not surprising if we end up here! MSVC current does not support the SSE4.1 flag. However, it appears to accept SSE4.1
 723         # intrinsics when SSE2 support is enabled, so we try that instead.
 724         GMX_TEST_CFLAG(MSVC_SSE2_CFLAG "/arch:SSE2" GROMACS_C_FLAGS)
 725     endif(NOT GNU_SSE4_CFLAG AND NOT MSVC_SSE4_CFLAG)
 726
 727     if (CMAKE_CXX_COMPILER_LOADED)
 728         GMX_TEST_CXXFLAG(GNU_SSE4_CXXFLAG "-msse4.1" GROMACS_CXX_FLAG)
 729         if (NOT GNU_SSE4_CXXFLAG)
 730             GMX_TEST_CXXFLAG(MSVC_SSE4_CXXFLAG "/arch:SSE4.1" GROMACS_CXX_FLAGS)
 731         endif(NOT GNU_SSE4_CXXFLAG)
 732         if (NOT GNU_SSE4_CXXFLAG AND NOT MSVC_SSE4_CXXFLAG)
 733             message(WARNING "No C++ SSE4.1 flag found. Consider a newer compiler, or disable SSE4.1 for slightly lower performance.")
 734             # Not surprising if we end up here! MSVC current does not support the SSE4.1 flag. However, it appears to accept SSE4.1
 735             # intrinsics when SSE2 support is enabled, so we try that instead.
 736             GMX_TEST_CXXFLAG(MSVC_SSE2_CXXFLAG "/arch:SSE2" GROMACS_CXX_FLAGS)
 737         endif(NOT GNU_SSE4_CXXFLAG AND NOT MSVC_SSE4_CXXFLAG)
 738     endif()
 739
 740     # This must come after we have added the -msse4.1 flag on some platforms.
 741     check_include_file(smmintrin.h  HAVE_SMMINTRIN_H ${GROMACS_C_FLAGS})
 742
 743     if(NOT HAVE_SMMINTRIN_H)
 744         message(FATAL_ERROR "Cannot find smmintrin.h, which is required for SSE4.1 intrinsics support.")
 745     endif(NOT HAVE_SMMINTRIN_H)
 746
 747     set(GMX_CPU_ACCELERATION_X86_SSE4_1 1)
 748     # The user should not be able to set this orthogonally to the acceleration
 749     set(GMX_X86_SSE4_1 1)
 750     set(GMX_X86_SSE2   1)
 751     if (NOT ACCELERATION_QUIETLY)
 752       message(STATUS "Enabling SSE4.1 Gromacs acceleration, and it will help compiler optimization.")
 753     endif()
 754
 755 elseif(${GMX_CPU_ACCELERATION} STREQUAL "AVX_128_FMA" OR ${GMX_CPU_ACCELERATION} STREQUAL "AVX_256")
 756
 757     # Set the AVX compiler flag for both these choices!
 758
 759     GMX_TEST_CFLAG(GNU_AVX_CFLAG "-mavx" GROMACS_C_FLAGS)
 760     if (NOT GNU_AVX_CFLAG)
 761         GMX_TEST_CFLAG(MSVC_AVX_CFLAG "/arch:AVX" GROMACS_C_FLAGS)
 762     endif (NOT GNU_AVX_CFLAG)
 763     if (NOT GNU_AVX_CFLAG AND NOT MSVC_AVX_CFLAG)
 764         message(WARNING "No C AVX flag found. Consider a newer compiler, or disable AVX for much lower performance.")
 765     endif (NOT GNU_AVX_CFLAG AND NOT MSVC_AVX_CFLAG)
 766
 767     if (CMAKE_CXX_COMPILER_LOADED)
 768         GMX_TEST_CXXFLAG(GNU_AVX_CXXFLAG "-mavx" GROMACS_CXX_FLAGS)
 769         if (NOT GNU_AVX_CXXFLAG)
 770             GMX_TEST_CXXFLAG(MSVC_AVX_CXXFLAG "/arch:AVX" GROMACS_CXX_FLAGS)
 771         endif (NOT GNU_AVX_CXXFLAG)
 772         if (NOT GNU_AVX_CXXFLAG AND NOT MSVC_AVX_CXXFLAG)
 773             message(WARNING "No C++ AVX flag found. Consider a newer compiler, or disable AVX for much lower performance.")
 774         endif (NOT GNU_AVX_CXXFLAG AND NOT MSVC_AVX_CXXFLAG)
 775     endif()
 776
 777     # Set the FMA4 flags (MSVC doesn't require any)
 778     if(${GMX_CPU_ACCELERATION} STREQUAL "AVX_128_FMA" AND NOT MSVC)
 779         GMX_TEST_CFLAG(GNU_FMA_CFLAG "-mfma4" GROMACS_C_FLAGS)
 780         if (NOT GNU_FMA_CFLAG)
 781             message(WARNING "No C FMA4 flag found. Consider a newer compiler, or disable AVX_128_FMA for much lower performance.")
 782         endif(NOT GNU_FMA_CFLAG)
 783         if (CMAKE_CXX_COMPILER_LOADED)
 784             GMX_TEST_CXXFLAG(GNU_FMA_CXXFLAG "-mfma4" GROMACS_CXX_FLAGS)
 785             if (NOT GNU_FMA_CXXFLAG)
 786                 message(WARNING "No C++ FMA flag found. Consider a newer compiler, or disable AVX_128_FMA for much lower performance.")
 787             endif (NOT GNU_FMA_CXXFLAG)
 788         endif()
 789     endif()
 790
 791     # Only test the header after we have tried to add the flag for AVX support
 792     check_include_file(immintrin.h  HAVE_IMMINTRIN_H ${GROMACS_C_FLAGS})
 793
 794     if(NOT HAVE_IMMINTRIN_H)
 795         message(FATAL_ERROR "Cannot find immintrin.h, which is required for AVX intrinsics support. Consider switching compiler.")
 796     endif(NOT HAVE_IMMINTRIN_H)
 797
 798     if(${GMX_CPU_ACCELERATION} STREQUAL "AVX_256")
 799         try_compile(TEST_AVX ${CMAKE_BINARY_DIR}
 800             "${CMAKE_SOURCE_DIR}/cmake/TestAVX.c"
 801             COMPILE_DEFINITIONS "${GROMACS_C_FLAGS}")
 802         if(NOT TEST_AVX)
 803             message(FATAL_ERROR "Cannot compile AVX intrinsics. Consider switching compiler.")
 804         endif()
 805     endif()
 806
 807     # GCC requires x86intrin.h for FMA support. MSVC 2010 requires intrin.h for FMA support.
 808     check_include_file(x86intrin.h HAVE_X86INTRIN_H ${GROMACS_C_FLAGS})
 809     check_include_file(intrin.h HAVE_INTRIN_H ${GROMACS_C_FLAGS})
 810
 811     # The user should not be able to set this orthogonally to the acceleration
 812     set(GMX_X86_SSE4_1 1)
 813     set(GMX_X86_SSE2   1)
 814
 815     # But just enable one of the choices internally...
 816     if(${GMX_CPU_ACCELERATION} STREQUAL "AVX_128_FMA")
 817         set(GMX_CPU_ACCELERATION_X86_AVX_128_FMA 1)
 818         set(GMX_X86_AVX_128_FMA 1)
 819         if (NOT ACCELERATION_QUIETLY)
 820           message(STATUS "Enabling 128-bit AVX Gromacs acceleration (with fused-multiply add), and it will help compiler optimization.")
 821         endif()
 822     else()
 823         # If we are not doing AVX_128, it must be AVX_256...
 824         set(GMX_CPU_ACCELERATION_X86_AVX_256 1)
 825         set(GMX_X86_AVX_256 1)
 826         if (NOT ACCELERATION_QUIETLY)
 827           message(STATUS "Enabling 256-bit AVX Gromacs acceleration, and it will help compiler optimization.")
 828         endif()
 829     endif()
 830
 831 elseif(${GMX_CPU_ACCELERATION} STREQUAL "FORTRAN")
 832
 833 #    Fortran is temporarily disabled while we push in nbNxN kernels.
 834 #    We need to fake it a bit here to avoid jenkins build errors!
 835 #    add_definitions(-DGMX_FORTRAN)
 836
 837 elseif(${GMX_CPU_ACCELERATION} STREQUAL "BLUEGENE")
 838 # GMX_CPU_ACCELERATION=BlueGene should be set in the Toolchain-BlueGene?-???.cmake file
 839     if (NOT ACCELERATION_QUIETLY)
 840       message(STATUS "Configuring for BlueGene")
 841     endif()
 842     set(GMX_BLUEGENE 1)
 843     if (${CMAKE_SYSTEM_NAME} STREQUAL "BlueGeneL")
 844         set(SHARED_LIBS_DEFAULT OFF CACHE BOOL "Shared libraries not compatible with BlueGene/L, disabled!" FORCE)
 845         set(BUILD_SHARED_LIBS OFF CACHE BOOL "Shared libraries not compatible with BlueGene/L, disabled!" FORCE)
 846     endif (${CMAKE_SYSTEM_NAME} STREQUAL "BlueGeneL")
 847     set(GMX_SOFTWARE_INVSQRT OFF CACHE BOOL "Do not use software reciprocal square root on BlueGene" FORCE)
 848     set(GMX_POWERPC_INVSQRT ON CACHE BOOL "Use hardware reciprocal square root on BlueGene" FORCE)
 849     set(GMX_X11 OFF CACHE BOOL "X11 not compatible with BlueGene, disabled!" FORCE)
 850     set(GMX_THREAD_MPI OFF CACHE BOOL "Thread-MPI not compatible with BlueGene, disabled!" FORCE)
 851     set(GMX_MPI ON CACHE BOOL "Use MPI on BlueGene" FORCE)
 852 # Access to /etc/passwd is not available on the back end of BlueGene,
 853 # despite being detected by CMake. This can cause linker warnings
 854 # about harmless things in src/gmxlib/string2.h.
 855     set(HAVE_PWD_H OFF)
 856 # The automatic testing for endianness does not work for the BlueGene cross-compiler
 857     set(GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER 1 CACHE INTERNAL "BlueGene has big endian FP byte order (by default)" FORCE)
 858     set(GMX_IEEE754_BIG_ENDIAN_WORD_ORDER 1 CACHE INTERNAL "BlueGene has big endian FP word order (by default)" FORCE)
 859 elseif(${GMX_CPU_ACCELERATION} STREQUAL "POWER6")
 860     set(GMX_POWER6 1)
 861     set(GMX_SOFTWARE_INVSQRT OFF CACHE BOOL "Do not use software reciprocal square root on Power6" FORCE)
 862     set(GMX_POWERPC_INVSQRT ON CACHE BOOL "Use hardware reciprocal square root on Power6" FORCE)
 863 else(${GMX_CPU_ACCELERATION} STREQUAL "NONE")
 864     MESSAGE(FATAL_ERROR "Unrecognized option for accelerated kernels: ${GMX_CPU_ACCELERATION}. Pick one of None, SSE2, SSE4.1, AVX_128_FMA, AVX_256, Fortran, BlueGene, Power6")
 865 endif(${GMX_CPU_ACCELERATION} STREQUAL "NONE")
 866 set(ACCELERATION_QUIETLY TRUE CACHE INTERNAL "")
 867
 868 if(GMX_FORTRAN OR GMX_POWER6)
 869     if (GMX_THREAD_MPI)
 870         message(FATAL_ERROR "FORTRAN/POWER6 is incompatible with thread-MPI and only provides a speed-up on certain IBM compilers. Disable FORTRAN (or threads if you really want to use FORTRAN kernels).")
 871     endif(GMX_THREAD_MPI)
 872     enable_language(Fortran)
 873     include(FortranCInterface)
 874     discover_fortran_mangling(prefix isupper suffix extra_under_score found)
 875     if(extra_under_score)
 876         set(extrasuffix "_")
 877     endif(extra_under_score)
 878     if(prefix)
 879       set(prefix "${prefix} ##")
 880     endif(prefix)
 881     if(suffix)
 882       set(suffix "## ${suffix}")
 883       if(extrasuffix)
 884         set(extrasuffix "${suffix}${extrasuffix}")
 885       endif(extrasuffix)
 886     else(suffix)
 887       if(extrasuffix)
 888         # Don't know if this is needed, but it can't hurt
 889         set(extrasuffix "## ${extrasuffix}")
 890       endif(extrasuffix)
 891     endif(suffix)
 892
 893     if(isupper)
 894         set(F77_FUNCDEF   "${prefix} NAME ${suffix}")
 895         set(F77_FUNCDEF_  "${prefix} NAME ${extrasuffix}")
 896     else(isupper)
 897         set(F77_FUNCDEF   "${prefix} name ${suffix}")
 898         set(F77_FUNCDEF_  "${prefix} name ${extrasuffix}")
 899     endif(isupper)
 900 else(GMX_FORTRAN OR GMX_POWER6)
 901         set(F77_FUNCDEF   "name ## _")
 902         set(F77_FUNCDEF_  "name ## _")
 903 endif(GMX_FORTRAN OR GMX_POWER6)
 904
 905 # Process QM/MM Settings
 906 string(TOUPPER ${GMX_QMMM_PROGRAM} ${GMX_QMMM_PROGRAM})
 907 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 908     set(GMX_QMMM_GAUSSIAN 1)
 909 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 910     set(GMX_QMMM_MOPAC 1)
 911 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 912     set(GMX_QMMM_GAMESS 1)
 913 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 914     set(GMX_QMMM_ORCA 1)
 915 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 916     # nothing to do
 917 else(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 918     MESSAGE(FATAL_ERROR "Invalid QM/MM program option: ${GMX_QMMM_PROGRAM}. Choose one of: Gaussian, Mopac, Gamess, Orca, None")
 919 endif(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 920
 921 # Process FFT library settings - if not OpenMM build
 922 string(TOUPPER ${GMX_FFT_LIBRARY} ${GMX_FFT_LIBRARY})
 923 set(PKG_FFT "")
 924 set(PKG_FFT_LIBS "")
 925 if(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 926     if(GMX_DOUBLE)
 927         set(FFTW fftw)
 928     else(GMX_DOUBLE)
 929         set(FFTW fftwf)
 930     endif(GMX_DOUBLE)
 931     find_package(FFTW COMPONENTS ${FFTW})
 932     string(TOUPPER "${FFTW}" FFTW)
 933     set(PKG_FFT "${${FFTW}_PKG}")
 934     include_directories(${${FFTW}_INCLUDE_DIRS})
 935     set(FFT_LIBRARIES ${${FFTW}_LIBRARIES})
 936     if(NOT ${FFTW}_FOUND)
 937       MESSAGE(FATAL_ERROR "Cannot find FFTW3 (with correct precision - libfftw3f for single precision GROMACS or libfftw3 for double precision GROMACS). Fix it, choose another FFT library, or use the Gromacs built-in fftpack (slower)!")
 938     endif(NOT ${FFTW}_FOUND)
 939
 940     set(GMX_FFT_FFTW3 1)
 941
 942     if (NOT ${GMX_CPU_ACCELERATION} STREQUAL "NONE" AND NOT ${FFTW}_HAVE_SIMD)
 943       message(WARNING "The fftw library found is compiled without SIMD support, which makes it slow. Consider recompiling it or contact your admin")
 944     endif (NOT ${GMX_CPU_ACCELERATION} STREQUAL "NONE" AND NOT ${FFTW}_HAVE_SIMD)
 945
 946 elseif(${GMX_FFT_LIBRARY} STREQUAL "MKL")
 947 #    MESSAGE(STATUS "Using external FFT library - Intel MKL")
 948     find_package(MKL REQUIRED)
 949     include_directories(${MKL_INCLUDE_DIR})
 950     set(FFT_LIBRARIES ${MKL_LIBRARIES})
 951     set(PKG_FFT_LIBS ${MKL_LIBRARIES})
 952
 953     set(GMX_FFT_MKL 1)
 954     set(HAVE_MKL 1)
 955
 956 #elseif(${GMX_FFT_LIBRARY} STREQUAL "ACML")
 957 #    MESSAGE(STATUS "Using external FFT library - AMD core math library")
 958 #    set(GMX_FFT_ACML 1)
 959 elseif(${GMX_FFT_LIBRARY} STREQUAL "FFTPACK")
 960     MESSAGE(STATUS "Using internal FFT library - fftpack")
 961     set(GMX_FFT_FFTPACK 1)
 962 else(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 963     MESSAGE(FATAL_ERROR "Invalid FFT library setting: ${GMX_FFT_LIBRARY}. Choose one of: fftw3, mkl, fftpack")
 964 endif(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 965
 966 # enable threaded fftw3 if we've found it
 967 if(FFTW3_THREADS OR FFTW3F_THREADS)
 968     add_definitions(-DFFT5D_FFTW_THREADS)
 969 endif()
 970
 971 set(GMX_EXTERNAL_BLAS TRUE CACHE BOOL "Use external BLAS instead of built-in")
 972 set(GMX_EXTERNAL_LAPACK TRUE CACHE BOOL "Use external LAPACK instead of built-in")
 973 # MKL has BLAS/LAPACK routines
 974 if(NOT HAVE_MKL AND NOT ACCELERATE_FRAMEWORK)
 975   if(GMX_EXTERNAL_BLAS)
 976     if (GMX_BLAS_USER)
 977         list(APPEND GMX_EXTRA_LIBRARIES ${GMX_BLAS_USER})
 978     else(GMX_BLAS_USER)
 979         set(BLAS_FIND_QUIETLY ON)
 980         find_package(BLAS)
 981         if (BLAS_FOUND)
 982           list(APPEND GMX_EXTRA_LIBRARIES ${BLAS_LIBRARIES})
 983         else()
 984           MESSAGE(STATUS "Using internal BLAS library")
 985           set(GMX_EXTERNAL_BLAS FALSE CACHE BOOL "Use external BLAS instead of built-in" FORCE)
 986         endif()
 987     endif(GMX_BLAS_USER)
 988   endif(GMX_EXTERNAL_BLAS)
 989   if(GMX_EXTERNAL_LAPACK)
 990     if (GMX_LAPACK_USER)
 991         list(APPEND GMX_EXTRA_LIBRARIES ${GMX_LAPACK_USER})
 992     else(GMX_LAPACK_USER)
 993         set(LAPACK_FIND_QUIETLY ON)
 994         find_package(LAPACK)
 995         if (LAPACK_FOUND)
 996           list(APPEND GMX_EXTRA_LIBRARIES ${LAPACK_LIBRARIES})
 997         else()
 998           MESSAGE(STATUS "Using internal LAPACK library")
 999           set(GMX_EXTERNAL_LAPACK FALSE CACHE BOOL "Use external LAPACK instead of built-in" FORCE)
1000         endif()
1001     endif(GMX_LAPACK_USER)
1002   endif(GMX_EXTERNAL_LAPACK)
1003 endif()
1004 mark_as_advanced(GMX_EXTERNAL_LAPACK)
1005 mark_as_advanced(GMX_EXTERNAL_BLAS)
1006
1007 set(GMX_USE_PLUGINS OFF CACHE INTERNAL "Whether GROMACS will really try to compile support for VMD plugins")
1008
1009 if(GMX_LOAD_PLUGINS)
1010   if(CYGWIN OR NOT WIN32)
1011     # Native Windows does not have, nor need dlopen
1012     # Note that WIN32 is set with Cygwin, but Cygwin needs dlopen to use plug-ins
1013     include(gmxTestdlopen)
1014     gmx_test_dlopen(HAVE_DLOPEN)
1015   endif()
1016
1017   # so, should we use plug-ins?
1018   if((WIN32 AND NOT CYGWIN) OR (HAVE_DLOPEN AND BUILD_SHARED_LIBS))
1019     if(NOT VMD_QUIETLY)
1020       MESSAGE(STATUS
1021           "Found the ability to use plug-ins when building shared libaries, "
1022           "so will compile to use plug-ins (e.g. to read VMD-supported file "
1023           "formats).")
1024     endif()
1025     if(NOT GMX_VMD_PLUGIN_PATH)
1026       find_package(VMD)
1027     endif()
1028     set(GMX_USE_PLUGINS ON)
1029     list(APPEND GMX_EXTRA_LIBRARIES ${CMAKE_DL_LIBS}) # magic cross-platform pre-set variable for dlopen library
1030     set(PKG_DL_LIBS "-l${CMAKE_DL_LIBS}")
1031   else()
1032     set(PKG_DL_LIBS)
1033   endif()
1034 endif(GMX_LOAD_PLUGINS)
1035 set(VMD_QUIETLY TRUE CACHE INTERNAL "")
1036
1037 if(EXISTS "${CMAKE_SOURCE_DIR}/admin/.isreposource")
1038     if(NOT CMAKE_CROSSCOMPILING)
1039         option(GMX_BUILD_MANPAGES "Build man pages" ON)
1040     else()
1041         message(STATUS "Building the man pages is not available when "
1042             "cross-compiling the developer version from git")
1043     endif()
1044 else()
1045     #make sure source package contains all man pages
1046     if(NOT EXISTS "${CMAKE_SOURCE_DIR}/man/man1/ngmx.1")
1047         message(FATAL_ERROR "Man pages are missing from source package.")
1048     endif()
1049 endif()
1050 mark_as_advanced(GMX_BUILD_MANPAGES)
1051
1052 # Math and thread libraries must often come after all others when linking...
1053 if(HAVE_LIBM)
1054     list(APPEND GMX_EXTRA_LIBRARIES m)
1055 endif(HAVE_LIBM)
1056
1057 if(GMX_FAHCORE)
1058   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
1059       "Path to swindirect.h")
1060   include_directories(${COREWRAP_INCLUDE_DIR})
1061 endif(GMX_FAHCORE)
1062
1063 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
1064 # these are set after everything else
1065 if (NOT DEFINED GROMACS_C_FLAGS_SET)
1066     set(GROMACS_C_FLAGS_SET true CACHE INTERNAL "Whether to reset the C flags"
1067         FORCE)
1068     set(CMAKE_C_FLAGS "${GROMACS_C_FLAGS} ${CMAKE_C_FLAGS}" CACHE STRING
1069         "Flags used by the compiler during all build types" FORCE)
1070     if (CMAKE_CXX_COMPILER_LOADED)
1071         set(CMAKE_CXX_FLAGS "${GROMACS_CXX_FLAGS} ${CMAKE_CXX_FLAGS}" CACHE STRING
1072             "Flags used by the compiler during all build types" FORCE)
1073     endif()
1074     set(CMAKE_EXE_LINKER_FLAGS
1075         "${GROMACS_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}"
1076         CACHE STRING "Linker flags for creating executables" FORCE)
1077     set(CMAKE_SHARED_LINKER_FLAGS
1078         "${GROMACS_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS}"
1079         CACHE STRING "Linker flags for creating shared libraries" FORCE)
1080 endif (NOT DEFINED GROMACS_C_FLAGS_SET)
1081
1082 if(NOT GMX_OPENMP)
1083     #Unset all OpenMP flags in case OpenMP was disabled either by the user
1084     #or because it was only partially detected (e.g. only for C but not C++ compiler)
1085     unset(OpenMP_C_FLAGS CACHE)
1086     unset(OpenMP_CXX_FLAGS CACHE)
1087     unset(OpenMP_LINKER_FLAGS CACHE)
1088     unset(OpenMP_SHARED_LINKER_FLAGS)
1089 endif()
1090 ######################################
1091 # Output compiler and CFLAGS used
1092 ######################################
1093 execute_process(COMMAND ${CMAKE_C_COMPILER} --version RESULT_VARIABLE TMP_RESULT OUTPUT_VARIABLE CC_VERSION ERROR_VARIABLE CC_VERSION)
1094 #try executing just the compiler command if that failed...
1095 if(TMP_RESULT)
1096     execute_process(COMMAND ${CMAKE_C_COMPILER} RESULT_VARIABLE TMP_RESULT OUTPUT_VARIABLE CC_VERSION ERROR_VARIABLE CC_VERSION)
1097 endif()
1098 string(LENGTH "${CC_VERSION}" len)
1099 if(len)
1100     string(REGEX MATCH "[^\n]+" CC_VERSION "${CC_VERSION}")
1101 endif()
1102
1103 set(BUILD_COMPILER "@CMAKE_C_COMPILER@ @CMAKE_C_COMPILER_ID@ @CC_VERSION@")
1104 set(BUILD_CFLAGS "@CMAKE_C_FLAGS@")
1105 if(CMAKE_BUILD_TYPE STREQUAL "Debug")
1106     set(BUILD_CFLAGS "@BUILD_CFLAGS@ @CMAKE_C_FLAGS_DEBUG@")
1107 elseif(CMAKE_BUILD_TYPE STREQUAL "Release")
1108     set(BUILD_CFLAGS "@BUILD_CFLAGS@ @CMAKE_C_FLAGS_RELEASE@")
1109 elseif(CMAKE_BUILD_TYPE STREQUAL "MinSizeRel")
1110     set(BUILD_CFLAGS "@BUILD_CFLAGS@ @CMAKE_C_FLAGS_MINSIZEREL@")
1111 elseif(CMAKE_BUILD_TYPE STREQUAL "RelWithDebInfo")
1112     set(BUILD_CFLAGS "@BUILD_CFLAGS@ @CMAKE_C_FLAGS_RELWITHDEBINFO@")
1113 endif()
1114
1115
1116 ########################################################################
1117 # Specify install locations and which subdirectories to process        #
1118 ########################################################################
1119 if (GMX_USE_RELATIVE_INSTALL_PATH)
1120     set(GMX_INSTALL_PREFIX "" CACHE STRING "Prefix gets appended to CMAKE_INSTALL_PREFIX. For cpack it sets the root folder of the archive.")
1121     mark_as_advanced(GMX_INSTALL_PREFIX)
1122 else()
1123     set(GMX_INSTALL_PREFIX "${CMAKE_INSTALL_PREFIX}/")
1124 endif()
1125
1126 if ( NOT DEFINED GMXLIB )
1127     set(GMXLIB lib)
1128 endif()
1129 set(LIB_INSTALL_DIR "${GMX_INSTALL_PREFIX}${GMXLIB}")
1130 set(BIN_INSTALL_DIR  ${GMX_INSTALL_PREFIX}bin)
1131 set(DATA_INSTALL_DIR ${GMX_INSTALL_PREFIX}share/gromacs)
1132 set(MAN_INSTALL_DIR  ${GMX_INSTALL_PREFIX}share/man)
1133 set(INCL_INSTALL_DIR ${GMX_INSTALL_PREFIX}include)
1134
1135 set(GMXLIBDIR        ${DATA_INSTALL_DIR}/top)
1136
1137 ##################################################################
1138 # Shared library settings - Darwin uses INSTALL_NAME_DIR instead!
1139 ##################################################################
1140 if(NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin")
1141     set(CMAKE_SKIP_BUILD_RPATH  FALSE)
1142     set(CMAKE_BUILD_WITH_INSTALL_RPATH FALSE)
1143     set(CMAKE_INSTALL_RPATH "\\\$ORIGIN/../${GMXLIB}")
1144     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
1145 endif()
1146
1147 #COPYING file: Only necessary for binary distributions.
1148 #Simpler to always install.
1149 install(FILES COPYING DESTINATION ${DATA_INSTALL_DIR} COMPONENT data)
1150
1151 add_subdirectory(share)
1152 add_subdirectory(include)
1153 add_subdirectory(src)
1154 add_subdirectory(scripts)
1155
1156 #######################
1157 ## uninstall target
1158 #######################
1159     CONFIGURE_FILE(
1160                    "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
1161                    "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
1162                    IMMEDIATE @ONLY)
1163 ###########################
1164 ADD_CUSTOM_TARGET(uninstall
1165                   "${CMAKE_COMMAND}" -P
1166                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
1167 ###########################
1168
1169
1170 ########################################################################
1171 # Tests                                                                #
1172 ########################################################################
1173
1174 include(CTest)
1175 mark_as_advanced(BUILD_TESTING)
1176 IF(BUILD_TESTING)
1177         enable_testing()
1178         add_subdirectory(tests)
1179 ENDIF()
1180