CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.6)
   2
   3 project(Gromacs)
   4 include(Dart)
   5 mark_as_advanced(DART_ROOT)
   6
   7 # PROJECT_VERSION should have the following structure:
   8 # VERSION-dev[-SUFFIX] where the VERSION should have the for: vMajor.vMinor.vPatch
   9 #
  10 # The "-dev" suffix is important to keep because it makes possible to distinguish
  11 # between a build from official release and a build from git release branch on a
  12 # machine with no git.
  13 #
  14 # NOTE: when releasing the "-dev" suffix needs to be stripped off!
  15 set(PROJECT_VERSION "4.5.5-dev")
  16 set(CUSTOM_VERSION_STRING ""
  17     CACHE STRING "Custom version string (if empty, use hard-coded default)")
  18 mark_as_advanced(CUSTOM_VERSION_STRING)
  19 if (CUSTOM_VERSION_STRING)
  20     set(PROJECT_VERSION ${CUSTOM_VERSION_STRING})
  21 endif (CUSTOM_VERSION_STRING)
  22 set(SOVERSION 6)
  23 # It is a bit irritating, but this has to be set separately for now!
  24 SET(CPACK_PACKAGE_VERSION_MAJOR "4")
  25 SET(CPACK_PACKAGE_VERSION_MINOR "5")
  26 SET(CPACK_PACKAGE_VERSION_PATCH "5")
  27
  28
  29 # Cmake modules/macros are in a subdirectory to keep this file cleaner
  30 set(CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake)
  31
  32 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
  33 set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
  34 endif()
  35
  36 if(NOT CMAKE_BUILD_TYPE)
  37     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel." FORCE)
  38 endif(NOT CMAKE_BUILD_TYPE)
  39
  40 enable_language(C)
  41
  42 set(CPACK_PACKAGE_VERSION ${PROJECT_VERSION})
  43 set(CPACK_PACKAGE_VENDOR "gromacs.org")
  44 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Gromacs - a toolkit for high-performance molecular simulation")
  45 set(CPACK_SET_DESTDIR "ON")
  46 set(CPACK_INCLUDE_TOPLEVEL_DIRECTORY 0)
  47 set(CPACK_RESOURCE_FILE_WELCOME "${CMAKE_SOURCE_DIR}/admin/InstallWelcome.txt")
  48 # Its GPL/LGPL, so they do not have to agree to a license for mere usage, but some installers require this...
  49 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_SOURCE_DIR}/admin/InstallLicense.txt")
  50 set(CPACK_RESOURCE_FILE_README "${CMAKE_SOURCE_DIR}/admin/InstallInfo.txt")
  51
  52 #must come after all cpack settings!
  53 include(CPack)
  54
  55 ########################################################################
  56 # Check and warn if cache generated on a different host is being reused
  57 ########################################################################
  58 if(CMAKE_HOST_UNIX)
  59     execute_process(COMMAND hostname
  60                     OUTPUT_VARIABLE TMP_HOSTNAME
  61                     OUTPUT_STRIP_TRAILING_WHITESPACE)
  62     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}")
  63         message(WARNING "
  64             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
  65             is being reused! This could lead to inconsitencies; therefore, it is
  66             recommended to regenerate the cache!")
  67     endif()
  68     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
  69             "Hostname of the machine where the cache was generated.")
  70 endif()
  71
  72 ########################################################################
  73 # Fix stupid flags on Windows
  74 ########################################################################
  75 SET(SHARED_LIBS_DEFAULT ON)
  76 IF( (CMAKE_GENERATOR MATCHES "Visual Studio" OR CMAKE_GENERATOR MATCHES "NMake") AND MSVC )
  77     STRING(REPLACE /MD /MT CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE})
  78     SET(CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE} CACHE STRING "" FORCE)
  79     STRING(REPLACE /MD /MT CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG})
  80     SET(CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG} CACHE STRING "" FORCE)
  81     SET(SHARED_LIBS_DEFAULT OFF)
  82 ENDIF()
  83
  84 IF(CMAKE_GENERATOR MATCHES "NMake" AND CMAKE_C_COMPILER_ID MATCHES "Intel")
  85     STRING(REPLACE /GZ /RTC1 CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE})
  86     SET(CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE} CACHE STRING "" FORCE)
  87     STRING(REPLACE /GZ /RTC1 CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG})
  88     SET(CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG} CACHE STRING "" FORCE)
  89     SET(SHARED_LIBS_DEFAULT OFF)
  90 ENDIF()
  91
  92 set(GMX_EXTRA_LIBRARIES)
  93
  94
  95
  96 ######################################################################
  97 # compiler tests
  98 # these need ot be done early (before further tests).
  99 #####################################################################
 100
 101 include(CheckCCompilerFlag)
 102 include(CheckCXXCompilerFlag)
 103
 104 include(gmxCFlags)
 105 gmx_c_flags()
 106
 107 ########################################################################
 108 # User input options                                                   #
 109 ########################################################################
 110 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" OFF)
 111 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 112 option(GMX_THREADS    "Build a parallel (thread-based) version of GROMACS (cannot be combined with MPI yet)" ON)
 113 option(GMX_SOFTWARE_INVSQRT "Use GROMACS software 1/sqrt" ON)
 114 mark_as_advanced(GMX_SOFTWARE_INVSQRT)
 115 option(GMX_POWERPC_INVSQRT "Use PowerPC hardware 1/sqrt" OFF)
 116 mark_as_advanced(GMX_POWERPC_INVSQRT)
 117 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 118 mark_as_advanced(GMX_FAHCORE)
 119 option(GMX_OPENMM "Accelerated execution on GPUs through the OpenMM library (rerun cmake after changing to see relevant options)" OFF)
 120 set(GMX_ACCELERATION "auto"
 121     CACHE STRING "Accelerated kernels. Pick one of: auto, none, SSE, BlueGene, Power6, ia64, altivec, fortran")
 122
 123 set(GMX_FFT_LIBRARY "fftw3"
 124     CACHE STRING "FFT library choices: fftw3,fftw2,mkl,fftpack[built-in]")
 125 option(GMX_DISABLE_FFTW_MEASURE
 126        "Do not optimize FFTW setups (not needed with SSE)" OFF)
 127 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 128 set(GMX_QMMM_PROGRAM "none"
 129     CACHE STRING "QM package choices: none,gaussian,mopac,gamess,orca")
 130 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 131 mark_as_advanced(GMX_BROKEN_CALLOC)
 132 option(BUILD_SHARED_LIBS "Enable shared libraries (can be problematic with MPI, Windows)" ${SHARED_LIBS_DEFAULT})
 133 option(GMX_MPI_IN_PLACE "Enable MPI_IN_PLACE for MPIs that have it defined" ON)
 134 mark_as_advanced(GMX_MPI_IN_PLACE)
 135 option(GMX_DLOPEN "Compile with dlopen, needed to read VMD supported file formats" ON)
 136 mark_as_advanced(GMX_DLOPEN)
 137
 138
 139 option(GMX_IA32_ASM "Add SSE assembly files for IA32" OFF)
 140 mark_as_advanced(GMX_IA32_ASM)
 141 option(GMX_X86_64_ASM "Add SSE assembly files for X86_64" OFF)
 142 mark_as_advanced(GMX_X86_64_ASM)
 143
 144 option(USE_VERSION_H "Generate development version string/information" ON)
 145 mark_as_advanced(USE_VERSION_H)
 146
 147 option(GMX_DEFAULT_SUFFIX "Use default suffixes for GROMACS binaries and libs (_d for double, _mpi for MPI; rerun cmake after changing to see relevant options)" ON)
 148
 149 if(UNIX AND NOT APPLE)
 150     option(GMX_PREFER_STATIC_LIBS "When finding libraries prefer \".a\" static archives (NOTE: this is enabled only for UNIX (excluding APPLE) platforms but it might not always work!" OFF)
 151     mark_as_advanced(GMX_PREFER_STATIC_LIBS)
 152 endif()
 153
 154 ########################################################################
 155 # Set up binary and library suffixing
 156 ########################################################################
 157 set(GMX_BINARY_SUFFIX "" CACHE STRING "Suffix for GROMACS binaries (default: _d for double, _mpi for MPI, _mpi_d for MPI and double).")
 158 set(GMX_LIBS_SUFFIX ""
 159   CACHE STRING "Suffix for GROMACS libs (default: _d for double, _mpi for MPI, _mpi_d for MPI and double).")
 160 if (GMX_DEFAULT_SUFFIX)
 161   set(GMX_BINARY_SUFFIX "")
 162   set(GMX_LIBS_SUFFIX "")
 163   if (GMX_MPI)
 164     set(GMX_BINARY_SUFFIX "_mpi")
 165     set(GMX_LIBS_SUFFIX "_mpi")
 166   endif(GMX_MPI)
 167   if (GMX_DOUBLE)
 168     set (GMX_BINARY_SUFFIX "${GMX_BINARY_SUFFIX}_d")
 169     set (GMX_LIBS_SUFFIX "${GMX_LIBS_SUFFIX}_d")
 170   endif(GMX_DOUBLE)
 171   if (GMX_OPENMM)
 172     set (GMX_BINARY_SUFFIX "-gpu")
 173     set (GMX_LIBS_SUFFIX "_gpu")
 174   endif(GMX_OPENMM)
 175   mark_as_advanced(FORCE GMX_BINARY_SUFFIX GMX_LIBS_SUFFIX)
 176   message(STATUS "Using default binary suffix: \"${GMX_BINARY_SUFFIX}\"")
 177   message(STATUS "Using default library suffix: \"${GMX_LIBS_SUFFIX}\"")
 178 else(GMX_DEFAULT_SUFFIX)
 179   mark_as_advanced(CLEAR GMX_BINARY_SUFFIX GMX_LIBS_SUFFIX)
 180   message(STATUS "Using manually set binary suffix: \"${GMX_BINARY_SUFFIX}\"")
 181   message(STATUS "Using manually set library suffix: \"${GMX_LIBS_SUFFIX}\"")
 182 endif(GMX_DEFAULT_SUFFIX)
 183
 184 set(PKG_CFLAGS "")
 185 if(GMX_DOUBLE)
 186     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_DOUBLE")
 187 endif(GMX_DOUBLE)
 188 if(GMX_SOFTWARE_INVSQRT)
 189   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_SOFTWARE_INVSQRT")
 190 endif(GMX_SOFTWARE_INVSQRT)
 191 if(GMX_POWERPC_INVSQRT)
 192   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_POWERPC_INVSQRT")
 193 endif(GMX_POWERPC_INVSQRT)
 194
 195 ########################################################################
 196 #Process MPI settings
 197 ########################################################################
 198 include(CheckCSourceCompiles) # for gmxTestMPI_IN_PLACE
 199 if(GMX_MPI)
 200     if(GMX_THREADS)
 201         #message(FATAL_ERROR "Thread-based parallelization conflicts with MPI.")
 202         set(GMX_THREADS OFF CACHE BOOL
 203             "Thread-based parallelization conflicts with MPI." FORCE)
 204     endif(GMX_THREADS)
 205     find_package(MPI)
 206     if(MPI_FOUND)
 207         set(GROMACS_C_FLAGS ${GROMACS_FLAGS} ${MPI_COMPILE_FLAGS})
 208         set(GROMACS_LINKER_FLAGS ${GROMACS_LINKER_FLAGS} ${MPI_LINK_FLAGS})
 209
 210         include_directories(${MPI_INCLUDE_PATH})
 211         list(APPEND GMX_EXTRA_LIBRARIES ${MPI_LIBRARIES})
 212         if(GMX_FAHCORE)
 213             add_definitions( -DMPI ) #for FAHCORE
 214         endif(GMX_FAHCORE)
 215         include(gmxTestMPI_IN_PLACE)
 216         if (GMX_MPI_IN_PLACE)
 217             gmx_test_mpi_in_place(MPI_IN_PLACE_EXISTS)
 218         endif (GMX_MPI_IN_PLACE)
 219
 220         # test for unsuitable versions of OpenMPI
 221         exec_program(${MPIEXEC}
 222           ARGS --version
 223           OUTPUT_VARIABLE MPI_TYPE
 224           RETURN_VALUE MPI_EXEC_RETURN)
 225         if(MPI_EXEC_RETURN EQUAL 0)
 226           if(MPI_TYPE MATCHES "Open MPI|OpenRTE")
 227             string(REGEX MATCH "[0-9]+\\.[0-9]*\\.?[0-9]*" MPI_VERSION ${MPI_TYPE})
 228             if(MPI_VERSION VERSION_LESS "1.4.1")
 229               MESSAGE(WARNING "
 230             There are known problems with OpenMPI version < 1.4.1.
 231             Please consider updating your OpenMPI.")
 232             endif(MPI_VERSION VERSION_LESS "1.4.1")
 233             unset(MPI_VERSION)
 234           else(MPI_TYPE MATCHES "Open MPI|OpenRTE")
 235             # This is not OpenMPI, so give the old generic warning message
 236             MESSAGE(WARNING "
 237             There are known problems with some MPI implementations:
 238                      MVAPICH2 version <= 1.4.1
 239             Please consider updating your MPI if applicable.")
 240           endif(MPI_TYPE MATCHES "Open MPI|OpenRTE")
 241           unset(MPI_TYPE)
 242         endif(MPI_EXEC_RETURN EQUAL 0)
 243     else(MPI_FOUND)
 244         message(FATAL_ERROR "MPI support requested, but no MPI compiler found.")
 245     endif(MPI_FOUND)
 246     include(gmxTestCatamount)
 247     gmx_test_catamount(GMX_CRAY_XT3)
 248     if(GMX_CRAY_XT3)
 249         set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_CRAY_XT3")
 250         set(GMX_NO_SYSTEM 1)
 251         set(GMX_NO_NICE 1)
 252     endif(GMX_CRAY_XT3)
 253     set(GMX_LIB_MPI 1)
 254     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_LIB_MPI")
 255 endif(GMX_MPI)
 256
 257
 258 #######################################################################
 259 # Check for options incompatible with OpenMM build                    #
 260 #######################################################################
 261 if(GMX_OPENMM)
 262     cmake_minimum_required(VERSION 2.6.4)
 263     # we'll use the built-in fft to avoid unnecessary dependencies
 264     string(TOUPPER ${GMX_FFT_LIBRARY} GMX_FFT_LIBRARY)
 265     if(NOT ${GMX_FFT_LIBRARY} STREQUAL "FFTPACK")
 266         message(STATUS "No external FFT libraries needed for the OpenMM build, switching to fftpack!")
 267         set(GMX_FFT_LIBRARY "fftpack" CACHE STRING
 268                 "No external FFT libraries needed for the OpenMM build, switching to  fftpack!" FORCE)
 269     endif()
 270     if(GMX_MPI)
 271         message(FATAL_ERROR "The OpenMM build is not compatible with MPI!")
 272     endif(GMX_MPI)
 273     if(GMX_THREADS)
 274         message(STATUS "Threads are  not compatible with OpenMM build, disabled!")
 275         set(GMX_THREADS OFF CACHE BOOL
 276                 "Threads are not compatible with OpenMM build, disabled!" FORCE)
 277     endif(GMX_THREADS)
 278     if(GMX_SOFTWARE_INVSQRT)
 279         set(GMX_SOFTWARE_INVSQRT OFF CACHE STRING
 280                 "The OpenMM build does not need GROMACS software 1/sqrt!" FORCE)
 281     endif(GMX_SOFTWARE_INVSQRT)
 282     string(TOUPPER ${GMX_ACCELERATION} GMX_ACCELERATION)
 283     if(NOT GMX_ACCELERATION STREQUAL "NONE")
 284         message(STATUS "Switching off CPU-based acceleration, the OpenMM build does not support/need any!")
 285         set(GMX_ACCELERATION "none" CACHE STRING
 286                 "Switching off CPU-based acceleration, the OpenMM build does not support/need any!" FORCE)
 287     endif()
 288     if(GMX_FAHCORE)
 289         message(FATAL_ERROR "The OpenMM build does not support FAH build!")
 290     endif(GMX_FAHCORE)
 291     if(GMX_DOUBLE)
 292         message(FATAL_ERROR  "The OpenMM-build does not support double precision calculations!")
 293     endif()
 294     # mark as advanced the unused variables
 295     mark_as_advanced(FORCE GMX_ACCELERATION GMX_MPI GMX_FFT_LIBRARY
 296         GMX_QMMM_PROGRAM GMX_THREADS GMX_DOUBLE)
 297 else(GMX_OPENMM)
 298      mark_as_advanced(CLEAR GMX_ACCELERATION GMX_MPI GMX_FFT_LIBRARY
 299         GMX_QMMM_PROGRAM GMX_THREADS GMX_DOUBLE)
 300 endif(GMX_OPENMM)
 301
 302
 303 ########################################################################
 304 # Basic system tests (standard libraries, headers, functions, types)   #
 305 ########################################################################
 306 include(CheckIncludeFiles)
 307 check_include_files(string.h     HAVE_STRING_H)
 308 check_include_files(math.h       HAVE_MATH_H)
 309 check_include_files(limits.h     HAVE_LIMITS_H)
 310 check_include_files(memory.h     HAVE_MEMORY_H)
 311 check_include_files(unistd.h     HAVE_UNISTD_H)
 312 check_include_files(direct.h     HAVE_DIRECT_H)
 313 check_include_files(pwd.h        HAVE_PWD_H)
 314 check_include_files(stdint.h     HAVE_STDINT_H)
 315 check_include_files(stdlib.h     HAVE_STDLIB_H)
 316 check_include_files(pthread.h    HAVE_PTHREAD_H)
 317 check_include_files(dirent.h     HAVE_DIRENT_H)
 318 check_include_files(inttypes.h   HAVE_INTTYPES_H)
 319 check_include_files(regex.h      HAVE_REGEX_H)
 320 check_include_files(sys/types.h  HAVE_SYS_TYPES_H)
 321 check_include_files(sys/stat.h   HAVE_SYS_STAT_H)
 322 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 323 check_include_files(rpc/rpc.h    HAVE_RPC_RPC_H)
 324 check_include_files("rpc/rpc.h;rpc/xdr.h"    HAVE_RPC_XDR_H)
 325 # SSE support
 326 check_include_files(xmmintrin.h  HAVE_XMMINTRIN_H)
 327 check_include_files(emmintrin.h  HAVE_EMMINTRIN_H)
 328 check_include_files(pmmintrin.h  HAVE_PMMINTRIN_H)
 329 check_include_files(smmintrin.h  HAVE_SMMINTRIN_H)
 330 check_include_files(io.h                 HAVE_IO_H)
 331
 332
 333 include(CheckFunctionExists)
 334 check_function_exists(strcasecmp        HAVE_STRCASECMP)
 335 check_function_exists(strdup            HAVE_STRDUP)
 336 check_function_exists(vprintf           HAVE_VPRINTF)
 337 check_function_exists(memcmp            HAVE_MEMCMP)
 338 check_function_exists(posix_memalign    HAVE_POSIX_MEMALIGN)
 339 check_function_exists(memalign          HAVE_MEMALIGN)
 340 check_function_exists(_aligned_malloc   HAVE__ALIGNED_MALLOC)
 341 check_function_exists(gettimeofday      HAVE_GETTIMEOFDAY)
 342 check_function_exists(isnan             HAVE_ISNAN)
 343 check_function_exists(_isnan            HAVE__ISNAN)
 344 check_function_exists(fsync             HAVE_FSYNC)
 345 check_function_exists(_fileno           HAVE__FILENO)
 346 check_function_exists(fileno            HAVE_FILENO)
 347 check_function_exists(_commit           HAVE__COMMIT)
 348
 349 include(CheckLibraryExists)
 350 check_library_exists(m sqrt "" HAVE_LIBM)
 351 check_library_exists(m cbrt "" HAVE_CBRT)
 352
 353
 354 include(CheckTypeSize)
 355
 356 check_type_size("bool"          SIZEOF_BOOL) # will also set HAVE_BOOL
 357 check_type_size("int"           SIZEOF_INT)
 358 check_type_size("long int"      SIZEOF_LONG_INT)
 359 check_type_size("long long int" SIZEOF_LONG_LONG_INT)
 360 check_type_size("off_t"         SIZEOF_OFF_T)
 361 check_type_size("void *"        SIZEOF_VOIDP)
 362
 363 if (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 364     set(GMX_64_BIT TRUE)
 365 else (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 366     set(GMX_64_BIT FALSE)
 367 endif (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 368
 369 # Check for some basic types that we *need*, so set these to int if they are not present
 370 check_type_size(uid_t uid_t)
 371 if(NOT uid_t)
 372   set(uid_t int)
 373 else(NOT uid_t)
 374   set(uid_t 0)
 375 endif(NOT uid_t)
 376
 377 check_type_size(gid_t gid_t)
 378 if(NOT gid_t)
 379   set(gid_t 1)
 380 else(NOT gid_t)
 381   set(gid_t 0)
 382 endif(NOT gid_t)
 383
 384 check_type_size(size_t size_t)
 385 if(NOT size_t)
 386   set(size_t int)
 387 else(NOT size_t)
 388   set(size_t 0)
 389 endif(NOT size_t)
 390
 391 check_type_size(off_t off_t)
 392 if(NOT off_t)
 393   set(off_t int)
 394 else(NOT off_t)
 395   set(off_t 0)
 396 endif(NOT off_t)
 397
 398 include(TestBigEndian)
 399 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 400
 401
 402
 403
 404 ########################################################################
 405 # Find external packages                                               #
 406 ########################################################################
 407 if(UNIX AND NOT APPLE)
 408     if(GMX_PREFER_STATIC_LIBS)
 409         SET(CMAKE_FIND_LIBRARY_SUFFIXES .a ${CMAKE_FIND_LIBRARY_SUFFIXES})
 410         if(BUILD_SHARED_LIBS)
 411             message(WARNING "Static libraries requested, the GROMACS libraries will also be build static (BUILD_SHARED_LIBS=OFF)")
 412             set(BUILD_SHARED_LIBS OFF CACHE BOOL "Enable shared libraries (can be problematic with MPI, Windows)" FORCE)
 413         endif()
 414     endif()
 415 endif()
 416
 417 option(GMX_XML "Use libxml2 to parse xml files" ON)
 418 if (GMX_XML)
 419   find_package(LibXml2)
 420   set(PKG_XML "")
 421   if(LIBXML2_FOUND)
 422     include_directories(${LIBXML2_INCLUDE_DIR})
 423     set(PKG_XML libxml-2.0)
 424     set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 425     set(HAVE_LIBXML2 1)
 426   endif(LIBXML2_FOUND)
 427 endif(GMX_XML)
 428
 429 option(GMX_GSL "Add support for gsl" OFF)
 430 if (GMX_GSL)
 431   find_package(gsl)
 432   set(PKG_GSL "")
 433   if(GSL_FOUND)
 434     include_directories(${GSL_INCLUDE_DIR})
 435     set(PKG_GSL gsl)
 436     set(HAVE_LIBGSL 1)
 437   endif(GSL_FOUND)
 438 endif (GMX_GSL)
 439
 440 option(GMX_X11 "Use X window system" OFF)
 441 if (GMX_X11)
 442         find_package(X11)
 443         # X11 includes/libraries are only set in the ngmx subdirectory!
 444         if(X11_FOUND)
 445         set(HAVE_X11 1)
 446         endif(X11_FOUND)
 447 endif(GMX_X11)
 448
 449 if(GMX_THREADS)
 450     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_THREADS")
 451     include(ThreadMPI)
 452     set(THREAD_MPI_LIB thread_mpi)
 453     set(GMX_MPI 1)
 454     string(TOUPPER ${GMX_FFT_LIBRARY} ${GMX_FFT_LIBRARY})
 455     if(${GMX_FFT_LIBRARY} STREQUAL "FFTW2")
 456         message(FATAL_ERROR "FFTW2 can't be used with threads. Try fftw3 or mkl.")
 457     endif()
 458 endif(GMX_THREADS)
 459
 460 if(GMX_OPENMM)
 461     set(CUDA_BUILD_EMULATION OFF)
 462     find_package(CUDA 3.1 REQUIRED)
 463     add_definitions(-DGMX_OPENMM)
 464     if(CMAKE_BUILD_TYPE STREQUAL "DEBUG")
 465         set(CUDA_VERBOSE_BUILD ON)
 466     endif()
 467     find_package(OpenMM)
 468 endif(GMX_OPENMM)
 469
 470 if(APPLE)
 471    find_library(ACCELERATE_FRAMEWORK Accelerate)
 472    list(APPEND GMX_EXTRA_LIBRARIES ${ACCELERATE_FRAMEWORK})
 473 endif(APPLE)
 474
 475 if(CYGWIN)
 476     set(GMX_CYGWIN 1)
 477 endif(CYGWIN)
 478
 479 # only bother with finding git and using version.h if the source is a git repo
 480 if(EXISTS "${CMAKE_SOURCE_DIR}/.git")
 481     if(USE_VERSION_H)
 482         # We need at least git v1.5.1 be able to parse git's date output. If not
 483         # fund or the version is too small, we can't generate version information.
 484         find_package(Git 1.5.1)
 485         # this should at some point become VERSION_LESS
 486         if(NOT Git_FOUND OR Git_VERSION STRLESS "1.5.1")
 487             message("No compatible git version found, won't be able to generate proper development version information.")
 488             set(USE_VERSION_H OFF)
 489         endif()
 490     endif()
 491 else()
 492     set(USE_VERSION_H OFF)
 493 endif()
 494
 495 if (GMX_DLOPEN)
 496     list(APPEND GMX_EXTRA_LIBRARIES ${CMAKE_DL_LIBS})
 497     set(PKG_DL_LIBS "-l${CMAKE_DL_LIBS}")
 498 else(GMX_DLOPEN)
 499     set(PKG_DL_LIBS)
 500 endif (GMX_DLOPEN)
 501
 502 ########################################################################
 503 # Generate development version info for cache
 504 ########################################################################
 505 # set(GEN_VERSION_INFO_INTERNAL "ON")
 506 # include(gmxGenerateVersionString)
 507
 508 ########################################################################
 509 # Our own GROMACS tests
 510 ########################################################################
 511
 512 add_definitions( -DHAVE_CONFIG_H )
 513 include_directories(${CMAKE_BINARY_DIR}/src)
 514 include_directories(${CMAKE_SOURCE_DIR}/include)
 515
 516 include(gmxCheckBuildUserTime)
 517 gmx_check_build_user_time(BUILD_TIME BUILD_USER BUILD_MACHINE)
 518
 519 include(gmxTestFloatFormat)
 520 gmx_test_float_format(GMX_FLOAT_FORMAT_IEEE754
 521                       GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER
 522                       GMX_IEEE754_BIG_ENDIAN_WORD_ORDER)
 523
 524 include(gmxTestLargeFiles)
 525 gmx_test_large_files(GMX_LARGEFILES)
 526 check_function_exists(fseeko     HAVE_FSEEKO)
 527
 528 include(gmxTestSignal)
 529 gmx_test_retsigtype(RETSIGTYPE)
 530 gmx_test_sigusr1(HAVE_SIGUSR1)
 531
 532 include(gmxTestInline)
 533 gmx_test_inline(INLINE_KEYWORD)
 534
 535 include(gmxTestRestrict)
 536 gmx_test_inline(RESTRICT_KEYWORD)
 537
 538 include(gmxTestPipes)
 539 gmx_test_pipes(HAVE_PIPES)
 540
 541 include(gmxTestIsfinite)
 542 gmx_test_isfinite(HAVE_ISFINITE)
 543 gmx_test__isfinite(HAVE__ISFINITE)
 544 gmx_test__finite(HAVE__FINITE)
 545
 546 include(gmxTestInlineASM)
 547 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 548 gmx_test_inline_asm_msvc_x86(GMX_X86_MSVC_INLINE_ASM)
 549
 550 # turn on SSE if supported with reasonable defaults.
 551 if (${GMX_ACCELERATION} STREQUAL "auto" AND NOT GMX_OPENMM)
 552   if(CMAKE_SYSTEM_PROCESSOR MATCHES "^(i.86|x86|x64|x86_64|AMD64|amd64)" OR CYGWIN)
 553
 554     set(GMX_ACCELERATION "SSE" CACHE STRING "Accelerated kernels. Pick one of: auto, none, SSE, BlueGene, Power6, ia64, altivec, fortran" FORCE)
 555
 556     # Determine the assembler/compiler to use
 557   else()
 558     set(GMX_ACCELERATION "none" CACHE STRING "Accelerated kernels. Pick one of: auto, none, SSE, BlueGene, Power6, ia64, altivec, fortran" FORCE)
 559   endif()
 560 endif (${GMX_ACCELERATION} STREQUAL "auto" AND NOT GMX_OPENMM)
 561
 562 include(gmxTestXDR)
 563 gmx_test_xdr(GMX_SYSTEM_XDR)
 564 if(NOT GMX_SYSTEM_XDR)
 565     set(GMX_INTERNAL_XDR 1)
 566     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_INTERNAL_XDR")
 567 endif(NOT GMX_SYSTEM_XDR)
 568
 569 # Process nonbonded accelerated kernels settings
 570 string(TOUPPER ${GMX_ACCELERATION} ${GMX_ACCELERATION})
 571 if(${GMX_ACCELERATION} STREQUAL "NONE")
 572   # nothing to do
 573 elseif(${GMX_ACCELERATION} STREQUAL "SSE")
 574
 575     if (GMX_64_BIT)
 576       set(GMX_X86_64_ASM ON CACHE BOOL "Add SSE assembly files for x86_64" FORCE)
 577     else (GMX_64_BIT)
 578       set(GMX_IA32_ASM ON CACHE BOOL "Add SSE assembly files for i386" FORCE)
 579     endif (GMX_64_BIT)
 580
 581     if(CMAKE_GENERATOR MATCHES "Visual Studio" OR CMAKE_GENERATOR MATCHES NMake )
 582       option(GMX_ASM_USEASM_NASM "Use Nasm for assembly instead of compiler (necessary on windows)" ON)
 583     else()
 584       option(GMX_ASM_USEASM_NASM "Use Nasm for assembly instead of compiler (necessary on windows)" OFF)
 585     endif()
 586         mark_as_advanced(GMX_ASM_USEASM_NASM)
 587
 588     if (NOT GMX_64_BIT)
 589         # for 32-bit compiles, we might need to turn on sse
 590         CHECK_C_COMPILER_FLAG("-msse2" XFLAGS_SSE)
 591         if (XFLAGS_SSE)
 592             set(GROMACS_C_FLAGS "-msse2 ${GROMACS_C_FLAGS}")
 593         endif (XFLAGS_SSE)
 594         CHECK_CXX_COMPILER_FLAG("-msse2" XXFLAGS_SSE)
 595         if (XXFLAGS_SSE)
 596             set(GROMACS_CXX_FLAGS "-msse2 ${GROMACS_CXX_FLAGS}")
 597         endif (XXFLAGS_SSE)
 598     endif (NOT GMX_64_BIT)
 599
 600     if(GMX_IA32_ASM)
 601       if(GMX_DOUBLE)
 602         set(GMX_IA32_SSE2 1)
 603       else()
 604        set(GMX_IA32_SSE 1)
 605       endif()
 606     elseif(GMX_X86_64_ASM)
 607       if(GMX_DOUBLE)
 608        set(GMX_X86_64_SSE2 1)
 609       else()
 610         set(GMX_X86_64_SSE 1)
 611       endif()
 612     endif()
 613
 614 #    if(HAVE_PMMINTRIN_H)
 615 #        set(GMX_SSE3 1)
 616 #    endif(HAVE_PMMINTRIN_H)
 617 #    if(HAVE_SMMINTRIN_H)
 618 #        set(GMX_SSE4_1 1)
 619 #    endif(HAVE_SMMINTRIN_H)
 620
 621 elseif(${GMX_ACCELERATION} STREQUAL "FORTRAN")
 622     set(GMX_FORTRAN 1)
 623     #these are switch on by default sometimes
 624     set(GMX_IA32_ASM 0)
 625     set(GMX_GMX_X86_64_ASM 0)
 626 elseif(${GMX_ACCELERATION} STREQUAL "BLUEGENE")
 627 # GMX_ACCELERATION=BlueGene should be set in the Toolchain-BlueGene?-???.cmake file
 628     message(STATUS "Configuring for BlueGene")
 629     set(GMX_BLUEGENE 1)
 630     if (${CMAKE_SYSTEM_NAME} STREQUAL "BlueGeneL")
 631         set(SHARED_LIBS_DEFAULT OFF CACHE BOOL "Shared libraries not compatible with BlueGene/L, disabled!" FORCE)
 632         set(BUILD_SHARED_LIBS OFF CACHE BOOL "Shared libraries not compatible with BlueGene/L, disabled!" FORCE)
 633     endif (${CMAKE_SYSTEM_NAME} STREQUAL "BlueGeneL")
 634     set(GMX_SOFTWARE_INVSQRT OFF CACHE BOOL "Do not use software reciprocal square root on BlueGene" FORCE)
 635     set(GMX_POWERPC_INVSQRT ON CACHE BOOL "Use hardware reciprocal square root on BlueGene" FORCE)
 636     set(GMX_X11 OFF CACHE BOOL "X11 not compatible with BlueGene, disabled!" FORCE)
 637     set(GMX_THREADS OFF CACHE BOOL "Threads not compatible with BlueGene, disabled!" FORCE)
 638     set(GMX_MPI ON CACHE BOOL "Use MPI on BlueGene" FORCE)
 639 elseif(${GMX_ACCELERATION} STREQUAL "POWER6")
 640     set(GMX_POWER6 1)
 641     set(GMX_SOFTWARE_INVSQRT OFF CACHE BOOL "Do not use software reciprocal square root on Power6" FORCE)
 642     set(GMX_POWERPC_INVSQRT ON CACHE BOOL "Use hardware reciprocal square root on Power6" FORCE)
 643 elseif(${GMX_ACCELERATION} STREQUAL "IA64")
 644     set(GMX_IA64_ASM 1)
 645     set(DISABLE_WATERWATER_NLIST 1)
 646     set(DISABLE_WATER_NLIST 1)
 647 elseif(${GMX_ACCELERATION} STREQUAL "ALTIVEC")
 648     check_include_files(altivec.h HAVE_ALTIVEC_H)
 649     if(HAVE_ALTIVEC_H)
 650         set(GMX_PPC_ALTIVEC 1)
 651     endif(HAVE_ALTIVEC_H)
 652 else(${GMX_ACCELERATION} STREQUAL "NONE")
 653     MESSAGE(FATAL_ERROR "Unrecognized option for accelerated kernels: ${GMX_ACCELERATION}. Pick one of auto, none, SSE, Fortran, BlueGene, Power6, ia64, altivec")
 654 endif(${GMX_ACCELERATION} STREQUAL "NONE")
 655
 656 if(GMX_FORTRAN OR GMX_POWER6)
 657     if (GMX_THREADS)
 658         message(FATAL_ERROR "FORTRAN/POWER6 is incompatible with threads and only provides a speed-up on certain IBM compilers. Disable FORTRAN (or threads if you really want to use FORTRAN kernels).")
 659     endif(GMX_THREADS)
 660     enable_language(Fortran)
 661     include(FortranCInterface)
 662     discover_fortran_mangling(prefix isupper suffix extra_under_score found)
 663     if(extra_under_score)
 664         set(extrasuffix "_")
 665     endif(extra_under_score)
 666     if(prefix)
 667       set(prefix "${prefix} ##")
 668     endif(prefix)
 669     if(suffix)
 670       set(suffix "## ${suffix}")
 671       if(extrasuffix)
 672         set(extrasuffix "${suffix}${extrasuffix}")
 673       endif(extrasuffix)
 674     else(suffix)
 675       if(extrasuffix)
 676         # Don't know if this is needed, but it can't hurt
 677         set(extrasuffix "## ${extrasuffix}")
 678       endif(extrasuffix)
 679     endif(suffix)
 680
 681     if(isupper)
 682         set(F77_FUNCDEF   "${prefix} NAME ${suffix}")
 683         set(F77_FUNCDEF_  "${prefix} NAME ${extrasuffix}")
 684     else(isupper)
 685         set(F77_FUNCDEF   "${prefix} name ${suffix}")
 686         set(F77_FUNCDEF_  "${prefix} name ${extrasuffix}")
 687     endif(isupper)
 688 else(GMX_FORTRAN OR GMX_POWER6)
 689         set(F77_FUNCDEF   "name ## _")
 690         set(F77_FUNCDEF_  "name ## _")
 691 endif(GMX_FORTRAN OR GMX_POWER6)
 692
 693 # Process QM/MM Settings
 694 string(TOUPPER ${GMX_QMMM_PROGRAM} ${GMX_QMMM_PROGRAM})
 695 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 696     set(GMX_QMMM_GAUSSIAN 1)
 697 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 698     set(GMX_QMMM_MOPAC 1)
 699 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 700     set(GMX_QMMM_GAMESS 1)
 701 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 702     set(GMX_QMMM_ORCA 1)
 703 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 704     # nothing to do
 705 else(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 706     MESSAGE(FATAL_ERROR "Invalid QM/MM program option: ${GMX_QMMM_PROGRAM}. Choose one of: Gaussian, Mopac, Gamess, Orca, None")
 707 endif(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 708
 709 # Process FFT library settings - if not OpenMM build
 710 string(TOUPPER ${GMX_FFT_LIBRARY} ${GMX_FFT_LIBRARY})
 711 set(PKG_FFT "")
 712 set(PKG_FFT_LIBS "")
 713 if(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 714 #    MESSAGE(STATUS "Using external FFT library - fftw3")
 715     if(GMX_DOUBLE)
 716         find_package(FFTW3 REQUIRED)
 717                 include_directories(${FFTW3_INCLUDE_DIR})
 718         set(FFT_LIBRARIES ${FFTW3_LIBRARIES})
 719         set(PKG_FFT "fftw3")
 720     else(GMX_DOUBLE)
 721         find_package(FFTW3F REQUIRED)
 722         include_directories(${FFTW3F_INCLUDE_DIR})
 723         set(FFT_LIBRARIES ${FFTW3F_LIBRARIES})
 724         set(PKG_FFT "fftw3f")
 725     endif(GMX_DOUBLE)
 726
 727     if(NOT FFTW3_FOUND AND NOT FFTW3F_FOUND)
 728         MESSAGE(FATAL_ERROR "Cannot find fftw3 (with correct precision). Fix it, choose another FFT library, or use the Gromacs built-in fftpack (slower)!")
 729     endif(NOT FFTW3_FOUND AND NOT FFTW3F_FOUND)
 730
 731     set(GMX_FFT_FFTW3 1)
 732
 733 elseif(${GMX_FFT_LIBRARY} STREQUAL "FFTW2")
 734 #    MESSAGE(STATUS "Using external FFT library - fftw2")
 735     if(GMX_DOUBLE)
 736         find_package(FFTW2 REQUIRED)
 737     else(GMX_DOUBLE)
 738         find_package(FFTW2F REQUIRED)
 739     endif(GMX_DOUBLE)
 740
 741     if(NOT FFTW2_FOUND)
 742            MESSAGE(FATAL_ERROR "Cannot find fftw2 (with correct precision). Fix it, choose another FFT library, or use the Gromacs built-in fftpack (slower)!")
 743     endif(NOT FFTW2_FOUND)
 744     include_directories(${FFTW2_INCLUDE_DIR})
 745     set(FFT_LIBRARIES ${FFTW2_LIBRARIES})
 746     set(PKG_FFT_LIBS ${FFTW2_LIBRARIES})
 747
 748     if("${FFTW2_LIBRARIES}" MATCHES "dfftw")
 749         set(FFTW2_NAME_DFFTW 1)
 750     elseif("${FFTW2_LIBRARIES}" MATCHES "sfftw")
 751         set(FFTW2_NAME_SFFTW 1)
 752     else("${FFTW2_LIBRARIES}" MATCHES "dfftw")
 753         set(FFTW2_NAME_FFTW 1)
 754     endif("${FFTW2_LIBRARIES}" MATCHES "dfftw")
 755
 756     set(GMX_FFT_FFTW2 1)
 757 elseif(${GMX_FFT_LIBRARY} STREQUAL "MKL")
 758 #    MESSAGE(STATUS "Using external FFT library - Intel MKL")
 759     find_package(MKL REQUIRED)
 760     include_directories(${MKL_INCLUDE_DIR})
 761     set(FFT_LIBRARIES ${MKL_LIBRARIES})
 762     set(PKG_FFT_LIBS ${MKL_LIBRARIES})
 763
 764     set(GMX_FFT_MKL 1)
 765     set(HAVE_MKL 1)
 766
 767 #elseif(${GMX_FFT_LIBRARY} STREQUAL "ACML")
 768 #    MESSAGE(STATUS "Using external FFT library - AMD core math library")
 769 #    set(GMX_FFT_ACML 1)
 770 elseif(${GMX_FFT_LIBRARY} STREQUAL "FFTPACK")
 771     MESSAGE(STATUS "Using internal FFT library - fftpack")
 772     set(GMX_FFT_FFTPACK 1)
 773 else(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 774     MESSAGE(FATAL_ERROR "Invalid FFT library setting: ${GMX_FFT_LIBRARY}. Choose one of: fftw3, fftw2, mkl, acml, fftpack")
 775 endif(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 776
 777 # MKL has BLAS/LAPACK routines
 778 if(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 779   set(GMX_EXTERNAL_BLAS TRUE CACHE BOOL "Use external BLAS instead of built-in")
 780   set(GMX_EXTERNAL_LAPACK TRUE CACHE BOOL "Use external LAPACK instead of built-in")
 781 else(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 782   set(GMX_EXTERNAL_BLAS FALSE CACHE BOOL "Use external BLAS instead of built-in")
 783   set(GMX_EXTERNAL_LAPACK FALSE CACHE BOOL "Use external LAPACK instead of built-in")
 784   if(GMX_EXTERNAL_BLAS)
 785     #FindBLAS needs Fortran
 786     enable_language(Fortran)
 787     if (GMX_BLAS_USER)
 788         list(APPEND GMX_EXTRA_LIBRARIES ${GMX_BLAS_USER})
 789     else(GMX_BLAS_USER)
 790         find_package(BLAS REQUIRED)
 791         list(APPEND GMX_EXTRA_LIBRARIES ${BLAS_LIBRARIES})
 792     endif(GMX_BLAS_USER)
 793   endif(GMX_EXTERNAL_BLAS)
 794   if(GMX_EXTERNAL_LAPACK)
 795     #FindLAPACK needs Fortran
 796     enable_language(Fortran)
 797         if (GMX_LAPACK_USER)
 798         list(APPEND GMX_EXTRA_LIBRARIES ${GMX_LAPACK_USER})
 799         else(GMX_LAPACK_USER)
 800         find_package(LAPACK REQUIRED)
 801         list(APPEND GMX_EXTRA_LIBRARIES ${LAPACK_LIBRARIES})
 802     endif(GMX_LAPACK_USER)
 803   endif(GMX_EXTERNAL_LAPACK)
 804 endif(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 805 mark_as_advanced(GMX_EXTERNAL_LAPACK)
 806 mark_as_advanced(GMX_EXTERNAL_BLAS)
 807
 808 # Math and thread libraries must often come after all others when linking...
 809 if(HAVE_LIBM)
 810     list(APPEND GMX_EXTRA_LIBRARIES m)
 811 endif(HAVE_LIBM)
 812
 813 if(GMX_FAHCORE)
 814   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 815       "Path to swindirect.h")
 816   include_directories(${COREWRAP_INCLUDE_DIR})
 817 endif(GMX_FAHCORE)
 818
 819 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 820 # these are set after everything else
 821 if (NOT DEFINED GROMACS_C_FLAGS_SET)
 822     set(GROMACS_C_FLAGS_SET true CACHE INTERNAL "Whether to reset the C flags"
 823         FORCE)
 824     set(CMAKE_C_FLAGS "${GROMACS_C_FLAGS} ${CMAKE_C_FLAGS}" CACHE STRING
 825         "Flags used by the compiler during all build types" FORCE)
 826     set(CMAKE_CXX_FLAGS "${GROMACS_CXX_FLAGS} ${CMAKE_CXX_FLAGS}" CACHE STRING
 827         "Flags used by the compiler during all build types" FORCE)
 828     set(CMAKE_EXE_LINKER_FLAGS
 829         "${GROMACS_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}"
 830         CACHE STRING "Linker flags" FORCE)
 831 endif (NOT DEFINED GROMACS_C_FLAGS_SET)
 832
 833 ########################################################################
 834 # Specify install locations and which subdirectories to process        #
 835 ########################################################################
 836 if ( DEFINED GMXLIB )
 837     set(LIB_INSTALL_DIR "${CMAKE_INSTALL_PREFIX}/${GMXLIB}")
 838 else()
 839     set(LIB_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/lib)
 840 endif()
 841 set(BIN_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/bin)
 842 set(DATA_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/gromacs)
 843 set(MAN_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/share/man)
 844 set(INCL_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/include)
 845
 846 set(GMXLIBDIR        ${DATA_INSTALL_DIR}/top)
 847
 848 ##################################################################
 849 # Shared library settings - Darwin uses INSTALL_NAME_DIR instead!
 850 ##################################################################
 851 if(NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin")
 852     set(CMAKE_SKIP_BUILD_RPATH  FALSE)
 853     set(CMAKE_BUILD_WITH_INSTALL_RPATH FALSE)
 854     set(CMAKE_INSTALL_RPATH "${LIB_INSTALL_DIR}")
 855     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 856 endif()
 857
 858 add_subdirectory(share)
 859 add_subdirectory(include)
 860 add_subdirectory(man)
 861 add_subdirectory(src)
 862 add_subdirectory(scripts)
 863
 864 #######################
 865 ## uninstall target
 866 #######################
 867     CONFIGURE_FILE(
 868                    "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 869                    "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
 870                    IMMEDIATE @ONLY)
 871 ###########################
 872 ADD_CUSTOM_TARGET(uninstall
 873                   "${CMAKE_COMMAND}" -P
 874                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
 875 ###########################
 876
 877
 878 ########################################################################
 879 # Tests                                                                #
 880 ########################################################################
 881
 882 include(CTest)
 883 mark_as_advanced(BUILD_TESTING)
 884 IF(BUILD_TESTING)
 885         enable_testing()
 886         add_subdirectory(tests)
 887 ENDIF()
 888