CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2009,2010,2011,2012,2013,2014, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 cmake_minimum_required(VERSION 2.8.8)
  36 # When we require cmake >= 2.8.12, it will provide
  37 # CMAKE_MINIMUM_REQUIRED_VERSION automatically, but in the meantime we
  38 # need to set a variable, and it must have a different name.
  39 set(GMX_CMAKE_MINIMUM_REQUIRED_VERSION "2.8.8")
  40
  41 # CMake modules/macros are in a subdirectory to keep this file cleaner
  42 # This needs to be set before project() in order to pick up toolchain files
  43 list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake ${CMAKE_CURRENT_SOURCE_DIR}/cmake/Platform)
  44
  45 project(Gromacs)
  46
  47 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  48 set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  49 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
  50
  51 # Set up common version variables, as well as general information about
  52 # the build tree (whether the build is from a source package or from a git
  53 # repository).  Also declares a few functions that will be used for generating
  54 # version info files later.
  55 include(gmxVersionInfo)
  56
  57 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT AND UNIX)
  58     set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
  59 endif()
  60
  61 include(gmxBuildTypeReference)
  62 include(gmxBuildTypeProfile)
  63 include(gmxBuildTypeTSAN)
  64 include(gmxBuildTypeASAN)
  65 include(gmxBuildTypeReleaseWithAssert)
  66
  67 if(NOT CMAKE_BUILD_TYPE)
  68     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel Reference RelWithAssert Profile." FORCE)
  69     # There's no need to offer a user the choice of ThreadSanitizer
  70     # Set the possible values of build type for cmake-gui
  71     set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "Debug" "Release"
  72         "MinSizeRel" "RelWithDebInfo" "Reference" "RelWithAssert" "Profile")
  73 endif()
  74 if(CMAKE_CONFIGURATION_TYPES)
  75     # Add appropriate GROMACS-specific build types for the Visual
  76     # Studio generator (Debug, Release, MinSizeRel and RelWithDebInfo
  77     # are already present by default).
  78     list(APPEND CMAKE_CONFIGURATION_TYPES "RelWithAssert" "Reference")
  79     list(REMOVE_DUPLICATES CMAKE_CONFIGURATION_TYPES)
  80     set(CMAKE_CONFIGURATION_TYPES "${CMAKE_CONFIGURATION_TYPES}" CACHE STRING
  81         "List of configuration types"
  82         FORCE)
  83 endif()
  84 set(build_types_with_explicit_flags RELEASE DEBUG RELWITHDEBINFO RELWITHASSERT MINSIZEREL PROFILE)
  85
  86 set_property(GLOBAL PROPERTY FIND_LIBRARY_USE_LIB64_PATHS ON)
  87
  88 # Set a default valgrind suppression file.
  89 # This unfortunately needs to duplicate information from CTest to work as
  90 # expected...
  91 set(MEMORYCHECK_SUPPRESSIONS_FILE
  92     "${CMAKE_SOURCE_DIR}/cmake/legacy_and_external.supp"
  93     CACHE FILEPATH
  94     "File that contains suppressions for the memory checker")
  95 include(CTest)
  96
  97 include(gmxCPackUtilities)
  98 gmx_cpack_init()
  99
 100 # Variables that accumulate stuff influencing the installed headers
 101 set(INSTALLED_HEADER_INCLUDE_DIRS "")
 102 set(INSTALLED_HEADER_DEFINITIONS "")
 103
 104 ########################################################################
 105 # Check and warn if cache generated on a different host is being reused
 106 ########################################################################
 107 if(CMAKE_HOST_UNIX)
 108     execute_process(COMMAND hostname
 109                     OUTPUT_VARIABLE TMP_HOSTNAME
 110                     OUTPUT_STRIP_TRAILING_WHITESPACE)
 111     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}")
 112         message(WARNING "
 113             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
 114             is being reused! This could lead to inconsistencies; therefore, it is
 115             recommended to regenerate the cache!")
 116     endif()
 117     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
 118             "Hostname of the machine where the cache was generated.")
 119 endif()
 120
 121 ########################################################################
 122 # Detect architecture before setting options so we can alter defaults
 123 ########################################################################
 124 # Detect the architecture the compiler is targetting, detect
 125 # SIMD instructions possibilities on that hardware, suggest SIMD instruction set
 126 # to use if none is specified, and populate the cache option for CPU
 127 # SIMD.
 128 include(gmxDetectTargetArchitecture)
 129 gmx_detect_target_architecture()
 130
 131 ########################################################################
 132 # User input options                                                   #
 133 ########################################################################
 134 include(gmxOptionUtilities)
 135
 136 set(CMAKE_PREFIX_PATH "" CACHE STRING "Extra locations to search for external libraries and tools (give directory without lib, bin, or include)")
 137
 138 if(GMX_TARGET_FUJITSU_SPARC64)
 139     # Fujitsu only has SIMD in double precision, so this will be faster
 140     set(GMX_DOUBLE_DEFAULT ON)
 141 else()
 142     set(GMX_DOUBLE_DEFAULT OFF)
 143 endif()
 144 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" ${GMX_DOUBLE_DEFAULT})
 145 option(GMX_RELAXED_DOUBLE_PRECISION "Accept single precision 1/sqrt(x) when using Fujitsu HPC-ACE SIMD" OFF)
 146 mark_as_advanced(GMX_RELAXED_DOUBLE_PRECISION)
 147
 148 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 149 option(GMX_THREAD_MPI  "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" ON)
 150 gmx_dependent_option(
 151     GMX_MPI_IN_PLACE
 152     "Enable MPI_IN_PLACE for MPIs that have it defined"
 153     ON
 154     GMX_MPI)
 155 mark_as_advanced(GMX_MPI_IN_PLACE)
 156 option(GMX_SOFTWARE_INVSQRT "Use GROMACS software 1/sqrt" ON)
 157 mark_as_advanced(GMX_SOFTWARE_INVSQRT)
 158 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 159 mark_as_advanced(GMX_FAHCORE)
 160
 161 option(GMX_COOL_QUOTES "Enable Gromacs cool quotes" ON)
 162 mark_as_advanced(GMX_COOL_QUOTES)
 163 gmx_add_cache_dependency(GMX_COOL_QUOTES BOOL "NOT GMX_FAHCORE" OFF)
 164
 165 # Decide on GPU settings based on user-settings and GPU/CUDA detection.
 166 # We support CUDA >=v4.0 on *nix, but <= v4.1 doesn't work with MSVC
 167 if(MSVC)
 168     set(REQUIRED_CUDA_VERSION 4.1)
 169 else()
 170     set(REQUIRED_CUDA_VERSION 4.0)
 171 endif()
 172 set(REQUIRED_CUDA_COMPUTE_CAPABILITY 2.0)
 173 include(gmxManageGPU)
 174
 175 include(gmxDetectSimd)
 176 gmx_detect_simd(GMX_SUGGESTED_SIMD)
 177
 178 gmx_option_multichoice(
 179     GMX_SIMD
 180     "SIMD instruction set for CPU kernels and compiler optimization"
 181     "${GMX_SUGGESTED_SIMD}"
 182     None SSE2 SSE4.1 AVX_128_FMA AVX_256 AVX2_256 MIC ARM_NEON ARM_NEON_ASIMD IBM_QPX IBM_VMX IBM_VSX Sparc64_HPC_ACE Reference)
 183
 184 gmx_option_multichoice(
 185     GMX_FFT_LIBRARY
 186     "FFT library"
 187     "fftw3"
 188     fftw3 mkl "fftpack[built-in]")
 189 gmx_dependent_option(
 190     GMX_BUILD_OWN_FFTW
 191     "Download and build FFTW 3 during the GROMACS build process, rather than fall back on the really slow fftpack."
 192     OFF
 193     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 194 gmx_dependent_option(
 195     GMX_DISABLE_FFTW_MEASURE
 196     "Do not optimize FFTW setups (not needed with SSE)"
 197     OFF
 198     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 199 mark_as_advanced(GMX_BUILD_OWN_FFTW)
 200 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 201
 202 gmx_option_multichoice(
 203     GMX_QMMM_PROGRAM
 204     "QM package for QM/MM"
 205     None
 206     none gaussian mopac gamess orca)
 207
 208 gmx_dependent_cache_variable(GMX_SIMD_REF_FLOAT_WIDTH  "Reference SIMD single precision width" STRING "4" "GMX_SIMD STREQUAL REFERENCE")
 209 gmx_dependent_cache_variable(GMX_SIMD_REF_DOUBLE_WIDTH "Reference SIMD double precision width" STRING "2" "GMX_SIMD STREQUAL REFERENCE")
 210
 211 # This should be moved to a separate NBNXN cmake module when that code is cleaned up and modularized
 212
 213 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 214 mark_as_advanced(GMX_BROKEN_CALLOC)
 215 option(GMX_LOAD_PLUGINS "Compile with plugin support, needed to read VMD supported file formats" ON)
 216 mark_as_advanced(GMX_LOAD_PLUGINS)
 217
 218 option(GMX_GPU  "Enable GPU acceleration" ON)
 219 option(GMX_OPENMP "Enable OpenMP-based multithreading" ON)
 220
 221 option(GMX_USE_TNG "Use the TNG library for trajectory I/O" ON)
 222
 223 if(UNIX)
 224     option(GMX_SYMLINK_OLD_BINARY_NAMES "Create symbolic links for pre-5.0 binary names" ON)
 225 endif()
 226 option(GMX_BUILD_MDRUN_ONLY "Build and install only the mdrun binary" OFF)
 227
 228 option(GMX_CYCLE_SUBCOUNTERS "Enable cycle subcounters to get a more detailed cycle timings" OFF)
 229 mark_as_advanced(GMX_CYCLE_SUBCOUNTERS)
 230
 231 option(GMX_SKIP_DEFAULT_CFLAGS "Don't automatically add suggested/required Compiler flags." OFF)
 232 mark_as_advanced(GMX_SKIP_DEFAULT_CFLAGS)
 233
 234 option(GMX_BUILD_FOR_COVERAGE
 235        "Tune build for better code coverage metrics (e.g., disable asserts)"
 236        OFF)
 237 mark_as_advanced(GMX_BUILD_FOR_COVERAGE)
 238
 239 option(GMX_DEVELOPER_BUILD
 240     "Enable Developer convenience features: always build unit-tests"
 241     OFF)
 242 mark_as_advanced(GMX_DEVELOPER_BUILD)
 243
 244 ######################################################################
 245 # Detect OpenMP support
 246 ######################################################################
 247 # The OpenMP detection _must_ come before tests for other CFLAGS.
 248 include(gmxManageOpenMP)
 249
 250
 251
 252 ######################################################################
 253 # Compiler tests
 254 # These need to be done early (before further tests).
 255 #####################################################################
 256
 257 # The cmake/Check{C,CXX}CompilerFlag.cmake files in the GROMACS distribution
 258 # are used with permission from CMake v3.0.0 so that GROMACS can detect
 259 # invalid options with the Intel Compilers, and we have added a line
 260 # to detect warnings with the Fujitsu compilers on K computer and ICC.
 261 # CMake-3.0 also has a bug where the FAIL_REGEX pattern for AIX contains
 262 # a semicolon. Since this is also used as a separator in lists inside CMake,
 263 # that string ends up being split into two separate patterns, and the last
 264 # part is just a single word that also matches other messages. We solved this
 265 # by replacing the semicolon with a period that matches any character.
 266 #
 267 # These files should be removed from the source tree when a CMake version that
 268 # includes the features in question becomes required for building GROMACS.
 269 include(CheckCCompilerFlag)
 270 include(CheckCXXCompilerFlag)
 271
 272 include(gmxCFlags)
 273 gmx_c_flags()
 274
 275 # This variable should be used for additional compiler flags which are not
 276 # generated in gmxCFlags nor are SIMD or MPI related.
 277 set(EXTRA_C_FLAGS "")
 278 set(EXTRA_CXX_FLAGS "")
 279
 280 # Run through a number of tests for buggy compilers and other issues
 281 include(gmxTestCompilerProblems)
 282 gmx_test_compiler_problems()
 283 # GMX_SIMD will not be set automatically until the second
 284 # pass (which is not strictly guaranteed to occur), so putting this
 285 # check here among logically-related tests is inefficient, but the
 286 # potential loss is likely zero.
 287 if(GMX_SIMD STREQUAL "AVX_256"
 288         AND CMAKE_COMPILER_IS_GNUCC
 289         AND (C_COMPILER_VERSION VERSION_EQUAL "4.6.1"
 290             OR CXX_COMPILER_VERSION VERSION_EQUAL "4.6.1"))
 291     message(FATAL_ERROR "gcc 4.6.1 has buggy support for AVX, and GROMACS mdrun will not work. If you want simulation performance, use a more recent compiler. Otherwise, use GMX_SIMD=SSE4.1")
 292     # See http://gcc.gnu.org/bugzilla/show_bug.cgi?id=49002
 293 endif()
 294
 295
 296 if(GMX_DOUBLE)
 297     add_definitions(-DGMX_DOUBLE)
 298     list(APPEND INSTALLED_HEADER_DEFINITIONS "-DGMX_DOUBLE")
 299     if(GMX_RELAXED_DOUBLE_PRECISION)
 300         add_definitions(-DGMX_RELAXED_DOUBLE_PRECISION)
 301     endif()
 302 endif()
 303 if(GMX_SOFTWARE_INVSQRT)
 304     list(APPEND INSTALLED_HEADER_DEFINITIONS "-DGMX_SOFTWARE_INVSQRT")
 305 endif()
 306
 307 if(WIN32)
 308     list(APPEND GMX_EXTRA_LIBRARIES "wsock32")
 309     add_definitions(-DGMX_HAVE_WINSOCK)
 310 endif()
 311
 312
 313
 314 ########################################################################
 315 # Basic system tests (standard libraries, headers, functions, types)   #
 316 ########################################################################
 317 include(CheckIncludeFiles)
 318 include(CheckIncludeFileCXX)
 319 check_include_files(unistd.h     HAVE_UNISTD_H)
 320 check_include_files(pwd.h        HAVE_PWD_H)
 321 check_include_files(dirent.h     HAVE_DIRENT_H)
 322 check_include_files(time.h       HAVE_TIME_H)
 323 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 324 check_include_files(io.h         HAVE_IO_H)
 325 check_include_files(sched.h      HAVE_SCHED_H)
 326
 327 check_include_files(regex.h      HAVE_POSIX_REGEX)
 328 check_include_file_cxx(regex     HAVE_CXX11_REGEX)
 329 # TODO: It could be nice to inform the user if no regex support is found,
 330 # as selections won't be fully functional.
 331
 332 include(CheckFunctionExists)
 333 check_function_exists(posix_memalign    HAVE_POSIX_MEMALIGN)
 334 check_function_exists(memalign          HAVE_MEMALIGN)
 335 check_function_exists(_aligned_malloc   HAVE__ALIGNED_MALLOC)
 336 check_function_exists(gettimeofday      HAVE_GETTIMEOFDAY)
 337 check_function_exists(fsync             HAVE_FSYNC)
 338 check_function_exists(_fileno           HAVE__FILENO)
 339 check_function_exists(fileno            HAVE_FILENO)
 340 check_function_exists(_commit           HAVE__COMMIT)
 341 check_function_exists(sigaction         HAVE_SIGACTION)
 342 check_function_exists(sysconf           HAVE_SYSCONF)
 343 check_function_exists(rsqrt             HAVE_RSQRT)
 344 check_function_exists(rsqrtf            HAVE_RSQRTF)
 345 check_function_exists(sqrtf             HAVE_SQRTF)
 346 check_function_exists(nice              HAVE_NICE)
 347
 348 include(CheckLibraryExists)
 349 check_library_exists(m sqrt "" HAVE_LIBM)
 350 check_library_exists(rt clock_gettime "" HAVE_CLOCK_GETTIME)
 351 check_library_exists(m feenableexcept "" HAVE_FEENABLEEXCEPT)
 352
 353 include(TestSchedAffinity)
 354 test_sched_affinity(HAVE_SCHED_AFFINITY)
 355
 356 include(TestBigEndian)
 357 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 358
 359 set(GMX_USE_NICE 0)
 360 if (HAVE_UNISTD_H AND HAVE_NICE)
 361     set(GMX_USE_NICE 1)
 362 endif()
 363
 364 # Management of GROMACS options for specific toolchains should go
 365 # here. Because the initial settings for some of the main options have
 366 # already happened, but things like library detection and MPI compiler
 367 # feature detection have not, the docstrings for any over-rides of
 368 # GROMACS defaults or user settings will make sense. Also, any
 369 # toolchain-related reasons for choosing whether to detect various
 370 # things can be sorted out now, before the detection takes place.
 371 if(${CMAKE_SYSTEM_NAME} MATCHES BlueGene)
 372     include(gmxManageBlueGene)
 373 endif()
 374
 375 if(GMX_TARGET_FUJITSU_SPARC64)
 376     include(gmxManageFujitsuSparc64)
 377 endif()
 378
 379 ########################################################################
 380 #Process MPI settings
 381 ########################################################################
 382 include(gmxManageMPI)
 383
 384
 385 ########################################################################
 386 #Process shared/static library settings
 387 ########################################################################
 388 include(gmxManageSharedLibraries)
 389
 390
 391 ########################################################################
 392 # Find external packages                                               #
 393 ########################################################################
 394
 395 # Unconditionally find the package, as it is also required for unit
 396 # tests. This exports LIBXML2_FOUND, which we should not use because
 397 # it does not tell us that linking will succeed. Instead, we test that
 398 # next.
 399 if(DEFINED LIBXML2_LIBRARIES)
 400   set(LibXml2_FIND_QUIETLY TRUE)
 401 endif()
 402 find_package(LibXml2)
 403 include(gmxTestLibXml2)
 404 gmx_test_libxml2(HAVE_LIBXML2)
 405 option(GMX_XML "Use libxml2 to parse xml files (currently has no effect)" ${HAVE_LIBXML2})
 406 set(PKG_XML "")
 407 mark_as_advanced(GMX_XML)
 408 # Don't actually do anything, since libxml2 is currently not used by libgromacs
 409 #if(GMX_XML AND NOT HAVE_LIBXML2)
 410 #    message(FATAL_ERROR "libxml2 not found. Set GMX_XML=OFF to compile without XML support")
 411 #endif()
 412 #if(GMX_XML)
 413 #    include_directories(${LIBXML2_INCLUDE_DIR})
 414 #    set(PKG_XML libxml-2.0)
 415 #    set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 416 #endif()
 417
 418 option(GMX_EXTRAE "Add support for tracing using EXTRAE" OFF)
 419 mark_as_advanced(GMX_EXTRAE)
 420
 421 if (GMX_EXTRAE)
 422   find_package(EXTRAE)
 423   if(EXTRAE_FOUND)
 424     include_directories(${EXTRAE_INCLUDE_DIR})
 425     set(HAVE_EXTRAE 1)
 426   else()
 427     message(FATAL_ERROR "EXTRAE library was not found. Please add the correct path to CMAKE_PREFIX_PATH")
 428   endif()
 429 endif()
 430
 431 option(GMX_X11 "Use X window system" OFF)
 432 if (GMX_X11)
 433     find_package(X11)
 434     # X11 includes/libraries are only set in the ngmx subdirectory!
 435     if(NOT X11_FOUND)
 436         message(FATAL_ERROR
 437                 "X11 include files and/or libraries were not found. "
 438                 "Set GMX_X11=OFF to compile without X11 support. "
 439                 "gmx view will not be available.")
 440     endif()
 441     include_directories(${X11_INCLUDE_DIR})
 442 endif()
 443
 444 include(ThreadMPI)
 445 # Enable core threading facilities
 446 tmpi_enable_core("${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include")
 447 # Enable tMPI C++ support
 448 tmpi_enable_cxx()
 449 if(GMX_THREAD_MPI)
 450     # enable MPI functions
 451     tmpi_enable()
 452     set(GMX_MPI 1)
 453     set(MPI_IN_PLACE_EXISTS 1)
 454 endif()
 455 # If atomics are manually disabled a define is needed because atomics.h doesn't depend on config.h
 456 if (TMPI_ATOMICS_DISABLED)
 457    add_definitions(-DTMPI_ATOMICS_DISABLED)
 458 endif()
 459
 460 if(GMX_GPU)
 461     # now that we have detected the dependencies, do the second configure pass
 462     gmx_gpu_setup()
 463 endif()
 464
 465 if(CYGWIN)
 466     set(GMX_CYGWIN 1)
 467 endif()
 468
 469 if(WIN32)
 470     set(GMX_NATIVE_WINDOWS 1)
 471     # This makes windows.h not declare min/max as macros that would break
 472     # C++ code using std::min/std::max.
 473     add_definitions(-DNOMINMAX)
 474 endif()
 475
 476 # Detect boost unless GMX_EXTERNAL_BOOST is explicitly OFF
 477 # Used for default if GMX_EXTERNAL_BOOST is not defined (first CMake pass)
 478 if(NOT DEFINED GMX_EXTERNAL_BOOST OR GMX_EXTERNAL_BOOST)
 479     find_package(Boost 1.44.0)
 480     if(Boost_FOUND AND Boost_VERSION VERSION_LESS "104400")
 481         set(Boost_FOUND FALSE)
 482     endif()
 483     # Print the notification only on first run, when determining the default
 484     if(NOT DEFINED GMX_EXTERNAL_BOOST AND NOT Boost_FOUND)
 485         message("Boost >= 1.44 not found. Using minimal internal version. "
 486                 "This may cause trouble if you plan on compiling/linking other "
 487                 "software that uses Boost against Gromacs.")
 488     endif()
 489 endif()
 490 option(GMX_EXTERNAL_BOOST "Use external Boost instead of minimal built-in version"
 491        ${Boost_FOUND})
 492 if(GMX_EXTERNAL_BOOST AND NOT Boost_FOUND)
 493     message(FATAL_ERROR
 494         "Boost >= 1.44 not found. "
 495         "You can set GMX_EXTERNAL_BOOST=OFF to compile against minimal "
 496         "version of Boost included with Gromacs.")
 497 endif()
 498
 499 if(NOT DEFINED GMX_BUILD_UNITTESTS AND NOT HAVE_LIBXML2)
 500     message(WARNING "libxml2 not found. Will build GROMACS without unit-tests. This is not recommended, because the unit-tests help to verify that GROMACS functions correctly. Most likely you are missing the libxml2-dev(el) package. After you installed it, set GMX_BUILD_UNITTESTS=ON.")
 501 endif()
 502 option(GMX_BUILD_UNITTESTS "Build unit tests with BUILD_TESTING (uses Google C++ Testing and Mocking Frameworks, requires libxml2)" ${HAVE_LIBXML2})
 503 mark_as_advanced(GMX_BUILD_UNITTESTS)
 504 gmx_add_cache_dependency(GMX_BUILD_UNITTESTS BOOL BUILD_TESTING OFF)
 505 if (GMX_BUILD_UNITTESTS AND NOT HAVE_LIBXML2)
 506     message(FATAL_ERROR
 507         "Cannot build unit tests without libxml2. "
 508         "Either set GMX_BUILD_UNITTESTS=OFF or tell CMake how to find a working version of libxml2.")
 509 endif()
 510
 511 if(GMX_USE_TNG AND NOT GMX_EXTERNAL_TNG)
 512     # TNG wants zlib if it is available
 513     find_package(ZLIB QUIET)
 514     include(gmxTestZLib)
 515     gmx_test_zlib(HAVE_ZLIB)
 516 endif()
 517
 518 ########################################################################
 519 # Our own GROMACS tests
 520 ########################################################################
 521
 522 add_definitions( -DHAVE_CONFIG_H )
 523 include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src)
 524 include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include)
 525 # Required for config.h, maybe should only be set in src/CMakeLists.txt
 526 include_directories(BEFORE ${CMAKE_BINARY_DIR}/src)
 527
 528 include(gmxTestInlineASM)
 529 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 530
 531 include(gmxSetBuildInformation)
 532 gmx_set_build_information()
 533 # Turn on RDTSCP if:
 534 # - the build system's CPU supports it
 535 # - the acceleration is set to AVX as all AVX-capable CPUs support AVX (which
 536 #   at this point means that the user set it).
 537 # Note: it's better to not use the later set value of GMX_SIMD because
 538 # it reflects the system's capability of both compiling and running AVX code.
 539 # TODO: After merge with 5.0 one could implement a cache variable dependency
 540 # such that GMX_USE_RDTSCP can change if GMX_SIMD is changed to AVX
 541 # after the first cmake pass.
 542 if (BUILD_CPU_FEATURES MATCHES "rdtscp" OR GMX_SIMD MATCHES "AVX")
 543     set(GMX_USE_RDTSCP_DEFAULT_VALUE ON)
 544 else()
 545     set(GMX_USE_RDTSCP_DEFAULT_VALUE OFF)
 546 endif()
 547 option(GMX_USE_RDTSCP "Use RDTSCP for better CPU-based timers (available on recent x86 CPUs; might need to be off when compiling for heterogeneous environments)" ${GMX_USE_RDTSCP_DEFAULT_VALUE})
 548 mark_as_advanced(GMX_USE_RDTSCP)
 549 if(GMX_USE_RDTSCP)
 550     set(HAVE_RDTSCP 1)
 551 endif()
 552
 553 include(gmxTestFloatFormat)
 554 gmx_test_float_format(GMX_FLOAT_FORMAT_IEEE754
 555                       GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER
 556                       GMX_IEEE754_BIG_ENDIAN_WORD_ORDER)
 557
 558 include(gmxTestLargeFiles)
 559 gmx_test_large_files(GMX_LARGEFILES)
 560
 561 include(gmxTestSignal)
 562 gmx_test_sigusr1(HAVE_SIGUSR1)
 563
 564 include(gmxTestPipes)
 565 gmx_test_pipes(HAVE_PIPES)
 566
 567 include(gmxTestIsfinite)
 568 gmx_test_isfinite(HAVE_ISFINITE)
 569 gmx_test__isfinite(HAVE__ISFINITE)
 570 gmx_test__finite(HAVE__FINITE)
 571
 572 include(gmxTestCXX11)
 573 gmx_test_cxx11(GMX_CXX11_SUPPORTED GMX_CXX11_FLAGS)
 574 include(CMakeDependentOption)
 575 # clang with some older versions of boost fail to work with C++11
 576 if(CMAKE_CXX_COMPILER_ID MATCHES Clang AND
 577     (Boost_VERSION VERSION_EQUAL 104601 OR Boost_VERSION VERSION_EQUAL 104700))
 578     set(CLANG_AND_OLD_EXTERNAL_BOOST TRUE)
 579 endif()
 580 # nvcc does not support C++11 flags, so with GPUs we prefer to skip C++11 flags
 581 # entirely to keep the compilation environment uniform.
 582 cmake_dependent_option(GMX_CXX11
 583     "Use C++11 features"
 584     ON "GMX_CXX11_SUPPORTED AND NOT GMX_GPU AND NOT CLANG_AND_OLD_EXTERNAL_BOOST" OFF)
 585 mark_as_advanced(GMX_CXX11)
 586 if(GMX_CXX11)
 587     set(EXTRA_CXX_FLAGS "${EXTRA_CXX_FLAGS} ${GMX_CXX11_FLAGS}")
 588 endif()
 589
 590
 591 include(gmxTestXDR)
 592 gmx_test_xdr(GMX_SYSTEM_XDR)
 593 if(NOT GMX_SYSTEM_XDR)
 594     set(GMX_INTERNAL_XDR 1)
 595 endif()
 596
 597
 598 ##################################################
 599 # Process SIMD instruction settings
 600 ##################################################
 601 # This checks what flags to add in order to
 602 # support the SIMD instructions we need, and sets
 603 # correct defines for the SIMD instructions supported.
 604 include(gmxTestSimd)
 605 gmx_test_simd()
 606
 607
 608 # Process QM/MM Settings
 609 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 610     set(GMX_QMMM_GAUSSIAN 1)
 611 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 612     set(GMX_QMMM_MOPAC 1)
 613 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 614     set(GMX_QMMM_GAMESS 1)
 615 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 616     set(GMX_QMMM_ORCA 1)
 617 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 618     # nothing to do
 619 else()
 620     gmx_invalid_option_value(GMX_QMMM_PROGRAM)
 621 endif()
 622
 623
 624 ##################################################
 625 # Process FFT library settings
 626 ##################################################
 627 include(gmxManageFFTLibraries)
 628
 629
 630 include(gmxManageLinearAlgebraLibraries)
 631
 632 # Whether GROMACS will really try to compile support for VMD plugins
 633 set(GMX_USE_PLUGINS OFF)
 634
 635 if(GMX_LOAD_PLUGINS)
 636   if(NOT WIN32)
 637     # Native Windows does not have, nor need dlopen
 638     include(gmxTestdlopen)
 639     gmx_test_dlopen(HAVE_DLOPEN)
 640   endif()
 641
 642   # so, should we use plug-ins?
 643   if(WIN32 OR (HAVE_DLOPEN AND BUILD_SHARED_LIBS))
 644     if(NOT VMD_QUIETLY)
 645       MESSAGE(STATUS "Using dynamic plugins (e.g VMD-supported file formats)")
 646     endif()
 647     if(NOT GMX_VMD_PLUGIN_PATH)
 648       find_package(VMD)
 649     endif()
 650     set(GMX_USE_PLUGINS ON)
 651     list(APPEND GMX_EXTRA_LIBRARIES ${CMAKE_DL_LIBS}) # magic cross-platform pre-set variable for dlopen library
 652     set(PKG_DL_LIBS "-l${CMAKE_DL_LIBS}")
 653   else()
 654     set(PKG_DL_LIBS)
 655   endif()
 656 endif()
 657 set(VMD_QUIETLY TRUE CACHE INTERNAL "")
 658
 659 # Link real-time library for POSIX timers. The check for clock_gettime
 660 # confirms the linkability of rt.
 661 if(HAVE_TIME_H AND HAVE_UNISTD_H AND HAVE_CLOCK_GETTIME)
 662     list(APPEND GMX_EXTRA_LIBRARIES rt)
 663 endif()
 664
 665 # Math and thread libraries must often come after all others when linking...
 666 if(HAVE_LIBM)
 667     list(APPEND GMX_EXTRA_LIBRARIES m)
 668 endif()
 669
 670 option(GMX_NACL "Configure for Native Client builds" OFF)
 671 if (GMX_NACL)
 672   list(APPEND GMX_EXTRA_LIBRARIES nosys)
 673   set(GMX_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -lnosys")
 674   # TODO: Is this still necessary with the check for its presence?
 675   set(GMX_USE_NICE 0)
 676   set(GMX_NO_RENAME 1)
 677 endif()
 678 mark_as_advanced(GMX_NACL)
 679
 680 if(GMX_FAHCORE)
 681   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 682       "Path to swindirect.h")
 683   include_directories(${COREWRAP_INCLUDE_DIR})
 684 endif()
 685
 686 # Value of AUTO tries to generate things, but will only produce warnings if
 687 # that fails.
 688 set(build_help_default AUTO)
 689 if (SOURCE_IS_SOURCE_DISTRIBUTION)
 690     set(build_help_default OFF)
 691 endif()
 692 gmx_option_trivalue(GMX_BUILD_HELP "Build man pages, HTML help, and completions automatically (requires that compiled binaries can be executed on the build host)" ${build_help_default})
 693 mark_as_advanced(GMX_BUILD_HELP)
 694 if (GMX_BUILD_HELP AND SOURCE_IS_SOURCE_DISTRIBUTION AND BUILD_IS_INSOURCE)
 695     message(FATAL_ERROR
 696         "Rebuilding HTML and man pages or shell completions is not supported "
 697         "for in-source builds from a source distribution. "
 698         "Set GMX_BUILD_HELP=OFF or do an out-of-source build to proceed.")
 699 endif()
 700
 701 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 702 # these are set after everything else
 703 if (NOT GMX_SKIP_DEFAULT_CFLAGS)
 704     set(CMAKE_C_FLAGS "${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${CMAKE_C_FLAGS}")
 705     set(CMAKE_CXX_FLAGS "${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${CMAKE_CXX_FLAGS}")
 706     set(CMAKE_EXE_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}")
 707     set(CMAKE_SHARED_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS}")
 708 else()
 709     message("Recommended flags which are not added because GMX_SKIP_DEFAULT_CFLAGS=yes:")
 710     message("CMAKE_C_FLAGS: ${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${GMXC_CFLAGS}")
 711     message("CMAKE_C_FLAGS_RELEASE: ${GMXC_CFLAGS_RELEASE}")
 712     message("CMAKE_C_FLAGS_DEBUG: ${GMXC_CFLAGS_DEBUG}")
 713     message("CMAKE_CXX_FLAGS: ${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${GMXC_CXXFLAGS}")
 714     message("CMAKE_CXX_FLAGS_RELEASE: ${GMXC_CXXFLAGS_RELEASE}")
 715     message("CMAKE_CXX_FLAGS_DEBUG: ${GMXC_CXXFLAGS_DEBUG}")
 716     message("CMAKE_EXE_LINKER_FLAGS: ${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS}")
 717     message("CMAKE_SHARED_LINKER_FLAGS: ${MPI_LINKER_FLAGS}")
 718 endif()
 719
 720 if(NOT GMX_OPENMP)
 721     #Unset all OpenMP flags in case OpenMP was disabled either by the user
 722     #or because it was only partially detected (e.g. only for C but not C++ compiler)
 723     unset(OpenMP_C_FLAGS CACHE)
 724     unset(OpenMP_CXX_FLAGS CACHE)
 725 else()
 726     set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} ${OpenMP_LINKER_FLAGS})
 727     set(GMX_SHARED_LINKER_FLAGS ${GMX_SHARED_LINKER_FLAGS} ${OpenMP_SHARED_LINKER_FLAGS})
 728 endif()
 729
 730 ########################################################################
 731 # Specify install locations
 732 ########################################################################
 733 # Use GNUInstallDirs to set paths on multiarch systems.
 734 include(GNUInstallDirs)
 735
 736 # Customization for the installation tree paths.
 737 set(GMX_LIB_INSTALL_DIR ${CMAKE_INSTALL_LIBDIR} CACHE STRING
 738     "Library installation directory (default: ${CMAKE_INSTALL_LIBDIR})")
 739 set(GMX_DATA_INSTALL_DIR gromacs CACHE STRING
 740     "Data installation directory under share/ (default: gromacs)")
 741 mark_as_advanced(GMX_LIB_INSTALL_DIR GMX_DATA_INSTALL_DIR)
 742
 743 # These variables are used internally to provide a central location for
 744 # customizing the install locations.
 745 set(LIB_INSTALL_DIR       ${GMX_LIB_INSTALL_DIR})
 746 set(BIN_INSTALL_DIR       bin)
 747 set(DATA_INSTALL_DIR      share/${GMX_DATA_INSTALL_DIR})
 748 set(MAN_INSTALL_DIR       share/man)
 749 # If the nesting level wrt. the installation root is changed,
 750 # gromacs-config.cmake.cmakein needs to be adapted.
 751 set(CMAKE_INSTALL_DIR     share/cmake)
 752 # TODO: Make GMXRC adapt if this is changed
 753 set(PKGCONFIG_INSTALL_DIR ${LIB_INSTALL_DIR}/pkgconfig)
 754 set(INCL_INSTALL_DIR      include)
 755
 756 # These variables get written into config.h for use in finding the data
 757 # directories.
 758 set(GMXLIB_SEARCH_DIR share/${GMX_DATA_INSTALL_DIR}/top)
 759 set(GMXLIB_FALLBACK   ${CMAKE_INSTALL_PREFIX}/${DATA_INSTALL_DIR}/top)
 760
 761 list(APPEND INSTALLED_HEADER_INCLUDE_DIRS ${INCL_INSTALL_DIR})
 762
 763 # Binary and library suffix options
 764 include(gmxManageSuffixes)
 765
 766 ################################################################
 767 # Shared library load path settings
 768 ################################################################
 769 # CMake supports RPATH on OS X only from 2.8.12 upwards.
 770 # CMAKE_SYSTEM_VERSION > 8.0 matches OS X 10.5 and above, where RPATH support
 771 # was added.
 772 if((NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin") OR
 773    ((CMAKE_SYSTEM_VERSION VERSION_GREATER 8.0) AND (NOT CMAKE_VERSION VERSION_LESS 2.8.12)))
 774     # The build folder always has bin/ and lib/; if we are also going to
 775     # install to lib/, then the installation RPATH works also in the build
 776     # tree.  This makes installation slightly faster (no need to rewrite the
 777     # RPATHs), and makes the binaries in the build tree relocatable.
 778     if(GMX_LIB_INSTALL_DIR STREQUAL "lib")
 779         set(CMAKE_BUILD_WITH_INSTALL_RPATH TRUE)
 780     endif()
 781     # Set the RPATH as relative to the executable location to make the
 782     # binaries relocatable.
 783     if(NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin")
 784         set(CMAKE_INSTALL_RPATH "\$ORIGIN/../${GMX_LIB_INSTALL_DIR}")
 785     else()
 786         set(CMAKE_INSTALL_RPATH "@executable_path/../${GMX_LIB_INSTALL_DIR}")
 787     endif()
 788     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 789     set(CMAKE_MACOSX_RPATH 1)
 790 else()
 791     # We are on Darwin/OSX, and CMake cannot handle RPATHs automatically.
 792     if(CMAKE_SYSTEM_VERSION VERSION_GREATER 8.0)
 793         # Set the RPATH options manually.
 794         set(CMAKE_INSTALL_NAME_DIR "@rpath")
 795         set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} "-Wl,-rpath,@executable_path/../${GMX_LIB_INSTALL_DIR}")
 796     else()
 797         # Use the old INSTALL_NAME_DIR mechanism if RPATH is not supported.
 798         set(CMAKE_INSTALL_NAME_DIR "${CMAKE_INSTALL_PREFIX}/${LIB_INSTALL_DIR}")
 799     endif()
 800 endif()
 801
 802 #COPYING file: Only necessary for binary distributions.
 803 #Simpler to always install.
 804 install(FILES COPYING DESTINATION ${DATA_INSTALL_DIR} COMPONENT data)
 805
 806 if(GMX_EXTERNAL_BOOST)
 807     include_directories(${Boost_INCLUDE_DIRS})
 808     list(APPEND INSTALLED_HEADER_INCLUDE_DIRS ${Boost_INCLUDE_DIRS})
 809 else()
 810     include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src/external/boost)
 811     list(APPEND INSTALLED_HEADER_INCLUDE_DIRS ${INCL_INSTALL_DIR}/gromacs/external/boost)
 812     list(APPEND INSTALLED_HEADED_DEFINITIONS "-DBOOST_NO_TYPEID")
 813     # typeid not supported for minimal internal version
 814     # (would add significant amount of code)
 815     add_definitions(-DBOOST_NO_TYPEID)
 816     if (NOT GMX_BUILD_MDRUN_ONLY)
 817         install(DIRECTORY ${CMAKE_SOURCE_DIR}/src/external/boost/boost
 818                 DESTINATION ${INCL_INSTALL_DIR}/gromacs/external/boost
 819                 COMPONENT development)
 820     endif()
 821 endif()
 822
 823 if (GMX_BUILD_FOR_COVERAGE)
 824     # Code heavy with asserts makes conditional coverage close to useless metric,
 825     # as by design most of the false branches are impossible to trigger in
 826     # correctly functioning code.  And the benefit of testing those that could
 827     # be triggered by using an API against its specification isn't usually
 828     # worth the effort.
 829     add_definitions(-DNDEBUG -DBOOST_DISABLE_ASSERTS -DGMX_DISABLE_ASSERTS)
 830 endif()
 831
 832 if (BUILD_TESTING)
 833     # "tests" target builds all the separate test binaries.
 834     add_custom_target(tests)
 835     # "run-ctest" is an internal target that actually runs the tests.
 836     # This is necessary to be able to add separate targets that execute as part
 837     # of 'make check', but are ensured to be executed after the actual tests.
 838     add_custom_target(run-ctest
 839                       COMMAND ${CMAKE_CTEST_COMMAND} --output-on-failure
 840                       COMMENT "Running all tests"
 841                       VERBATIM)
 842     add_dependencies(run-ctest tests)
 843     # "check" target builds and runs all tests.
 844     add_custom_target(check DEPENDS run-ctest)
 845 endif()
 846
 847 if (NOT GMX_BUILD_MDRUN_ONLY)
 848     add_subdirectory(docs)
 849     add_subdirectory(share)
 850     add_subdirectory(scripts)
 851 endif()
 852 add_subdirectory(src)
 853
 854 if (BUILD_TESTING)
 855     add_subdirectory(tests)
 856 endif()
 857
 858 gmx_cpack_write_config()
 859
 860 # Issue a warning if NVIDIA GPUs were detected, but CUDA was not found.
 861 # Don't bother the user after the first configure pass.
 862 if ((CUDA_NOTFOUND_AUTO AND GMX_DETECT_GPU_AVAILABLE) AND NOT GMX_GPU_DETECTION_DONE)
 863     message(WARNING "${CUDA_NOTFOUND_MESSAGE}")
 864 endif()
 865 set(GMX_GPU_DETECTION_DONE TRUE CACHE INTERNAL "Whether GPU detection has already been done")
 866
 867 #######################
 868 ## uninstall target
 869 #######################
 870 CONFIGURE_FILE(   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 871                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
 872                   IMMEDIATE @ONLY)
 873 ###########################
 874 ADD_CUSTOM_TARGET(uninstall
 875                   "${CMAKE_COMMAND}" -P
 876                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
 877 ###########################
 878 set_directory_properties(PROPERTIES
 879             ADDITIONAL_MAKE_CLEAN_FILES "install_manifest.txt")