CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2009,2010,2011,2012,2013,2014,2015, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 cmake_minimum_required(VERSION 2.8.8)
  36 # When we require cmake >= 2.8.12, it will provide
  37 # CMAKE_MINIMUM_REQUIRED_VERSION automatically, but in the meantime we
  38 # need to set a variable, and it must have a different name.
  39 set(GMX_CMAKE_MINIMUM_REQUIRED_VERSION "2.8.8")
  40
  41 # CMake modules/macros are in a subdirectory to keep this file cleaner
  42 # This needs to be set before project() in order to pick up toolchain files
  43 list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake ${CMAKE_CURRENT_SOURCE_DIR}/cmake/Platform)
  44
  45 project(Gromacs)
  46
  47 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  48 set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  49 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
  50
  51 # Set up common version variables, as well as general information about
  52 # the build tree (whether the build is from a source package or from a git
  53 # repository).  Also declares a few functions that will be used for generating
  54 # version info files later.
  55 include(gmxVersionInfo)
  56
  57 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT AND UNIX)
  58     set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
  59 endif()
  60 if("${CMAKE_INSTALL_PREFIX}" STREQUAL "${CMAKE_BINARY_DIR}")
  61     message(FATAL_ERROR "GROMACS cannot be installed into the build tree, choose a different location for CMAKE_INSTALL_PREFIX")
  62 endif()
  63
  64 include(gmxBuildTypeReference)
  65 include(gmxBuildTypeProfile)
  66 include(gmxBuildTypeTSAN)
  67 include(gmxBuildTypeASAN)
  68 include(gmxBuildTypeMSAN)
  69 include(gmxBuildTypeReleaseWithAssert)
  70
  71 if(NOT CMAKE_BUILD_TYPE)
  72     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel Reference RelWithAssert Profile." FORCE)
  73     # There's no need to offer a user the choice of ThreadSanitizer
  74     # Set the possible values of build type for cmake-gui
  75     set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "Debug" "Release"
  76         "MinSizeRel" "RelWithDebInfo" "Reference" "RelWithAssert" "Profile")
  77 endif()
  78 if(CMAKE_CONFIGURATION_TYPES)
  79     # Add appropriate GROMACS-specific build types for the Visual
  80     # Studio generator (Debug, Release, MinSizeRel and RelWithDebInfo
  81     # are already present by default).
  82     list(APPEND CMAKE_CONFIGURATION_TYPES "RelWithAssert" "Reference")
  83     list(REMOVE_DUPLICATES CMAKE_CONFIGURATION_TYPES)
  84     set(CMAKE_CONFIGURATION_TYPES "${CMAKE_CONFIGURATION_TYPES}" CACHE STRING
  85         "List of configuration types"
  86         FORCE)
  87 endif()
  88 set(build_types_with_explicit_flags RELEASE DEBUG RELWITHDEBINFO RELWITHASSERT MINSIZEREL PROFILE)
  89
  90 set_property(GLOBAL PROPERTY FIND_LIBRARY_USE_LIB64_PATHS ON)
  91
  92 # Set a default valgrind suppression file.
  93 # This unfortunately needs to duplicate information from CTest to work as
  94 # expected...
  95 set(MEMORYCHECK_SUPPRESSIONS_FILE
  96     "${CMAKE_SOURCE_DIR}/cmake/legacy_and_external.supp"
  97     CACHE FILEPATH
  98     "File that contains suppressions for the memory checker")
  99 include(CTest)
 100
 101 include(gmxCPackUtilities)
 102 gmx_cpack_init()
 103
 104 # Variables that accumulate stuff influencing the installed headers
 105 set(INSTALLED_HEADER_INCLUDE_DIRS "")
 106 set(INSTALLED_HEADER_DEFINITIONS "")
 107
 108 ########################################################################
 109 # Check and warn if cache generated on a different host is being reused
 110 ########################################################################
 111 if(CMAKE_HOST_UNIX)
 112     execute_process(COMMAND hostname
 113                     OUTPUT_VARIABLE TMP_HOSTNAME
 114                     OUTPUT_STRIP_TRAILING_WHITESPACE)
 115     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}")
 116         message(WARNING "
 117             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
 118             is being reused! This could lead to inconsistencies; therefore, it is
 119             recommended to regenerate the cache!")
 120     endif()
 121     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
 122             "Hostname of the machine where the cache was generated.")
 123 endif()
 124
 125 ########################################################################
 126 # Detect architecture before setting options so we can alter defaults
 127 ########################################################################
 128 # Detect the architecture the compiler is targetting, detect
 129 # SIMD instructions possibilities on that hardware, suggest SIMD instruction set
 130 # to use if none is specified, and populate the cache option for CPU
 131 # SIMD.
 132 include(gmxDetectTargetArchitecture)
 133 gmx_detect_target_architecture()
 134
 135 ########################################################################
 136 # User input options                                                   #
 137 ########################################################################
 138 include(gmxOptionUtilities)
 139
 140 set(CMAKE_PREFIX_PATH "" CACHE STRING "Extra locations to search for external libraries and tools (give directory without lib, bin, or include)")
 141
 142 if(GMX_TARGET_FUJITSU_SPARC64)
 143     # Fujitsu only has SIMD in double precision, so this will be faster
 144     set(GMX_DOUBLE_DEFAULT ON)
 145 else()
 146     set(GMX_DOUBLE_DEFAULT OFF)
 147 endif()
 148 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" ${GMX_DOUBLE_DEFAULT})
 149 option(GMX_RELAXED_DOUBLE_PRECISION "Accept single precision 1/sqrt(x) when using Fujitsu HPC-ACE SIMD" OFF)
 150 mark_as_advanced(GMX_RELAXED_DOUBLE_PRECISION)
 151
 152 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 153 option(GMX_THREAD_MPI  "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" ON)
 154 gmx_dependent_option(
 155     GMX_MPI_IN_PLACE
 156     "Enable MPI_IN_PLACE for MPIs that have it defined"
 157     ON
 158     GMX_MPI)
 159 mark_as_advanced(GMX_MPI_IN_PLACE)
 160 option(GMX_SOFTWARE_INVSQRT "Use GROMACS software 1/sqrt" ON)
 161 mark_as_advanced(GMX_SOFTWARE_INVSQRT)
 162 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 163 mark_as_advanced(GMX_FAHCORE)
 164
 165 option(GMX_COOL_QUOTES "Enable GROMACS cool quotes" ON)
 166 mark_as_advanced(GMX_COOL_QUOTES)
 167 gmx_add_cache_dependency(GMX_COOL_QUOTES BOOL "NOT GMX_FAHCORE" OFF)
 168
 169 # Decide on GPU settings based on user-settings and GPU/CUDA detection.
 170 # We support CUDA >=v4.0 on *nix, but <= v4.1 doesn't work with MSVC
 171 if(MSVC)
 172     set(REQUIRED_CUDA_VERSION 4.1)
 173 else()
 174     set(REQUIRED_CUDA_VERSION 4.0)
 175 endif()
 176 set(REQUIRED_CUDA_COMPUTE_CAPABILITY 2.0)
 177 include(gmxManageGPU)
 178
 179 include(gmxDetectSimd)
 180 gmx_detect_simd(GMX_SUGGESTED_SIMD)
 181
 182 gmx_option_multichoice(
 183     GMX_SIMD
 184     "SIMD instruction set for CPU kernels and compiler optimization"
 185     "${GMX_SUGGESTED_SIMD}"
 186     None SSE2 SSE4.1 AVX_128_FMA AVX_256 AVX2_256 AVX_512F AVX_512ER MIC ARM_NEON ARM_NEON_ASIMD IBM_QPX IBM_VMX IBM_VSX Sparc64_HPC_ACE Reference)
 187
 188 if(GMX_TARGET_MIC)
 189     set(GMX_FFT_LIBRARY_DEFAULT "mkl")
 190 else()
 191     set(GMX_FFT_LIBRARY_DEFAULT "fftw3")
 192 endif()
 193
 194 gmx_option_multichoice(
 195     GMX_FFT_LIBRARY
 196     "FFT library"
 197     "${GMX_FFT_LIBRARY_DEFAULT}"
 198     fftw3 mkl "fftpack[built-in]")
 199 gmx_dependent_option(
 200     GMX_BUILD_OWN_FFTW
 201     "Download and build FFTW 3 during the GROMACS build process, rather than fall back on the really slow fftpack."
 202     OFF
 203     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 204 gmx_dependent_option(
 205     GMX_DISABLE_FFTW_MEASURE
 206     "Do not optimize FFTW setups (not needed with SSE)"
 207     OFF
 208     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 209 mark_as_advanced(GMX_BUILD_OWN_FFTW)
 210 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 211
 212 gmx_option_multichoice(
 213     GMX_QMMM_PROGRAM
 214     "QM package for QM/MM"
 215     None
 216     none gaussian mopac gamess orca)
 217
 218 gmx_dependent_cache_variable(GMX_SIMD_REF_FLOAT_WIDTH  "Reference SIMD single precision width" STRING "4" "GMX_SIMD STREQUAL REFERENCE")
 219 gmx_dependent_cache_variable(GMX_SIMD_REF_DOUBLE_WIDTH "Reference SIMD double precision width" STRING "2" "GMX_SIMD STREQUAL REFERENCE")
 220
 221 # This should be moved to a separate NBNXN cmake module when that code is cleaned up and modularized
 222
 223 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 224 mark_as_advanced(GMX_BROKEN_CALLOC)
 225 option(GMX_LOAD_PLUGINS "Compile with plugin support, needed to read VMD supported file formats" ON)
 226 mark_as_advanced(GMX_LOAD_PLUGINS)
 227
 228 option(GMX_GPU  "Enable GPU acceleration" ON)
 229 option(GMX_OPENMP "Enable OpenMP-based multithreading" ON)
 230
 231 option(GMX_USE_TNG "Use the TNG library for trajectory I/O" ON)
 232
 233 option(GMX_BUILD_MDRUN_ONLY "Build and install only the mdrun binary" OFF)
 234
 235 option(GMX_CYCLE_SUBCOUNTERS "Enable cycle subcounters to get a more detailed cycle timings" OFF)
 236 mark_as_advanced(GMX_CYCLE_SUBCOUNTERS)
 237
 238 option(GMX_SKIP_DEFAULT_CFLAGS "Don't automatically add suggested/required Compiler flags." OFF)
 239 mark_as_advanced(GMX_SKIP_DEFAULT_CFLAGS)
 240
 241 option(GMX_BUILD_FOR_COVERAGE
 242        "Tune build for better code coverage metrics (e.g., disable asserts)"
 243        OFF)
 244 mark_as_advanced(GMX_BUILD_FOR_COVERAGE)
 245
 246 option(GMX_DEVELOPER_BUILD
 247     "Enable Developer convenience features: always build unit-tests"
 248     OFF)
 249 mark_as_advanced(GMX_DEVELOPER_BUILD)
 250
 251 option(GMX_BUILD_SHARED_EXE
 252     "Build exectuables as shared binaries. If not set, this disables rpath and dynamic linker flags in an attempt to build a static binary, but this may require setting up the toolchain properly and making appropriate libraries available."
 253     ON)
 254 mark_as_advanced(GMX_BUILD_SHARED_EXE)
 255
 256 ######################################################################
 257 # Detect OpenMP support
 258 ######################################################################
 259 # The OpenMP detection _must_ come before tests for other CFLAGS.
 260 include(gmxManageOpenMP)
 261
 262
 263
 264 ######################################################################
 265 # Compiler tests
 266 # These need to be done early (before further tests).
 267 #####################################################################
 268
 269 # The cmake/Check{C,CXX}CompilerFlag.cmake files in the GROMACS distribution
 270 # are used with permission from CMake v3.0.0 so that GROMACS can detect
 271 # invalid options with the Intel Compilers, and we have added a line
 272 # to detect warnings with the Fujitsu compilers on K computer and ICC.
 273 # CMake-3.0 also has a bug where the FAIL_REGEX pattern for AIX contains
 274 # a semicolon. Since this is also used as a separator in lists inside CMake,
 275 # that string ends up being split into two separate patterns, and the last
 276 # part is just a single word that also matches other messages. We solved this
 277 # by replacing the semicolon with a period that matches any character.
 278 #
 279 # These files should be removed from the source tree when a CMake version that
 280 # includes the features in question becomes required for building GROMACS.
 281 include(CheckCCompilerFlag)
 282 include(CheckCXXCompilerFlag)
 283
 284 include(gmxCFlags)
 285 gmx_c_flags()
 286
 287 # This variable should be used for additional compiler flags which are not
 288 # generated in gmxCFlags nor are SIMD or MPI related.
 289 set(EXTRA_C_FLAGS "")
 290 set(EXTRA_CXX_FLAGS "")
 291
 292 # Run through a number of tests for buggy compilers and other issues
 293 include(gmxTestCompilerProblems)
 294 gmx_test_compiler_problems()
 295 # GMX_SIMD will not be set automatically until the second
 296 # pass (which is not strictly guaranteed to occur), so putting this
 297 # check here among logically-related tests is inefficient, but the
 298 # potential loss is likely zero.
 299 if(GMX_SIMD STREQUAL "AVX_256"
 300         AND CMAKE_COMPILER_IS_GNUCC
 301         AND (C_COMPILER_VERSION VERSION_EQUAL "4.6.1"
 302             OR CXX_COMPILER_VERSION VERSION_EQUAL "4.6.1"))
 303     message(FATAL_ERROR "gcc 4.6.1 has buggy support for AVX, and GROMACS mdrun will not work. If you want simulation performance, use a more recent compiler. Otherwise, use GMX_SIMD=SSE4.1")
 304     # See http://gcc.gnu.org/bugzilla/show_bug.cgi?id=49002
 305 endif()
 306
 307
 308 if(GMX_DOUBLE)
 309     add_definitions(-DGMX_DOUBLE)
 310     list(APPEND INSTALLED_HEADER_DEFINITIONS "-DGMX_DOUBLE")
 311     if(GMX_RELAXED_DOUBLE_PRECISION)
 312         add_definitions(-DGMX_RELAXED_DOUBLE_PRECISION)
 313     endif()
 314 endif()
 315 if(GMX_SOFTWARE_INVSQRT)
 316     list(APPEND INSTALLED_HEADER_DEFINITIONS "-DGMX_SOFTWARE_INVSQRT")
 317 endif()
 318
 319 if(WIN32)
 320     list(APPEND GMX_EXTRA_LIBRARIES "wsock32")
 321     add_definitions(-DGMX_HAVE_WINSOCK)
 322 endif()
 323
 324
 325
 326 ########################################################################
 327 # Basic system tests (standard libraries, headers, functions, types)   #
 328 ########################################################################
 329 include(CheckIncludeFiles)
 330 include(CheckIncludeFileCXX)
 331 check_include_files(unistd.h     HAVE_UNISTD_H)
 332 check_include_files(pwd.h        HAVE_PWD_H)
 333 check_include_files(dirent.h     HAVE_DIRENT_H)
 334 check_include_files(time.h       HAVE_TIME_H)
 335 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 336 check_include_files(io.h         HAVE_IO_H)
 337 check_include_files(sched.h      HAVE_SCHED_H)
 338
 339 check_include_files(regex.h      HAVE_POSIX_REGEX)
 340 # TODO: It could be nice to inform the user if no regex support is found,
 341 # as selections won't be fully functional.
 342
 343 include(CheckCXXSymbolExists)
 344 check_cxx_symbol_exists(posix_memalign    stdlib.h     HAVE_POSIX_MEMALIGN)
 345 check_cxx_symbol_exists(memalign          stdlib.h     HAVE_MEMALIGN)
 346 check_cxx_symbol_exists(_aligned_malloc   stdlib.h     HAVE__ALIGNED_MALLOC)
 347 check_cxx_symbol_exists(gettimeofday      sys/time.h   HAVE_GETTIMEOFDAY)
 348 check_cxx_symbol_exists(sysconf           unistd.h     HAVE_SYSCONF)
 349 check_cxx_symbol_exists(nice              unistd.h     HAVE_NICE)
 350 check_cxx_symbol_exists(fsync             unistd.h     HAVE_FSYNC)
 351 check_cxx_symbol_exists(_fileno           stdio.h      HAVE__FILENO)
 352 check_cxx_symbol_exists(fileno            stdio.h      HAVE_FILENO)
 353 check_cxx_symbol_exists(_commit           io.h         HAVE__COMMIT)
 354 check_cxx_symbol_exists(sigaction         signal.h     HAVE_SIGACTION)
 355 check_cxx_symbol_exists(rsqrt             math.h       HAVE_RSQRT)
 356 check_cxx_symbol_exists(rsqrtf            math.h       HAVE_RSQRTF)
 357 check_cxx_symbol_exists(sqrtf             math.h       HAVE_SQRTF)
 358
 359 include(CheckLibraryExists)
 360 find_library(HAVE_LIBM m)
 361 check_library_exists(rt clock_gettime "" HAVE_CLOCK_GETTIME)
 362 check_library_exists(m feenableexcept "" HAVE_FEENABLEEXCEPT)
 363
 364 include(TestSchedAffinity)
 365 test_sched_affinity(HAVE_SCHED_AFFINITY)
 366
 367 include(TestBigEndian)
 368 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 369
 370 set(GMX_USE_NICE 0)
 371 if (HAVE_UNISTD_H AND HAVE_NICE)
 372     set(GMX_USE_NICE 1)
 373 endif()
 374
 375 # Management of GROMACS options for specific toolchains should go
 376 # here. Because the initial settings for some of the main options have
 377 # already happened, but things like library detection and MPI compiler
 378 # feature detection have not, the docstrings for any over-rides of
 379 # GROMACS defaults or user settings will make sense. Also, any
 380 # toolchain-related reasons for choosing whether to detect various
 381 # things can be sorted out now, before the detection takes place.
 382 if(${CMAKE_SYSTEM_NAME} MATCHES BlueGene)
 383     include(gmxManageBlueGene)
 384 endif()
 385
 386 if(GMX_TARGET_FUJITSU_SPARC64)
 387     include(gmxManageFujitsuSparc64)
 388 endif()
 389
 390 ########################################################################
 391 #Process MPI settings
 392 ########################################################################
 393 include(gmxManageMPI)
 394
 395
 396 ########################################################################
 397 #Process shared/static library settings
 398 ########################################################################
 399 include(gmxManageSharedLibraries)
 400
 401
 402 ########################################################################
 403 # Find external packages                                               #
 404 ########################################################################
 405
 406 # TNG wants zlib if it is available. And static libxml2 might have a dependency
 407 find_package(ZLIB QUIET)
 408 include(gmxTestZLib)
 409 gmx_test_zlib(HAVE_ZLIB)
 410
 411 # Unconditionally find the package, as it is also required for unit
 412 # tests. This exports LIBXML2_FOUND, which we should not use because
 413 # it does not tell us that linking will succeed. Instead, we test that
 414 # next.
 415 if(DEFINED LIBXML2_LIBRARIES)
 416   set(LibXml2_FIND_QUIETLY TRUE)
 417 endif()
 418 find_package(LibXml2)
 419 include(gmxTestLibXml2)
 420 gmx_test_libxml2(HAVE_LIBXML2)
 421 option(GMX_XML "Use libxml2 to parse xml files (currently has no effect)" ${HAVE_LIBXML2})
 422 set(PKG_XML "")
 423 mark_as_advanced(GMX_XML)
 424 # Don't actually do anything, since libxml2 is currently not used by libgromacs
 425 #if(GMX_XML AND NOT HAVE_LIBXML2)
 426 #    message(FATAL_ERROR "libxml2 not found. Set GMX_XML=OFF to compile without XML support")
 427 #endif()
 428 #if(GMX_XML)
 429 #    include_directories(${LIBXML2_INCLUDE_DIR})
 430 #    set(PKG_XML libxml-2.0)
 431 #    set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 432 #endif()
 433
 434 option(GMX_EXTRAE "Add support for tracing using EXTRAE" OFF)
 435 mark_as_advanced(GMX_EXTRAE)
 436
 437 if (GMX_EXTRAE)
 438   find_package(EXTRAE)
 439   if(EXTRAE_FOUND)
 440     include_directories(${EXTRAE_INCLUDE_DIR})
 441     set(HAVE_EXTRAE 1)
 442   else()
 443     message(FATAL_ERROR "EXTRAE library was not found. Please add the correct path to CMAKE_PREFIX_PATH")
 444   endif()
 445 endif()
 446
 447 option(GMX_X11 "Use X window system" OFF)
 448 if (GMX_X11)
 449     find_package(X11)
 450     # X11 includes/libraries are only set in the ngmx subdirectory!
 451     if(NOT X11_FOUND)
 452         message(FATAL_ERROR
 453                 "X11 include files and/or libraries were not found. "
 454                 "Set GMX_X11=OFF to compile without X11 support. "
 455                 "gmx view will not be available.")
 456     endif()
 457     include_directories(${X11_INCLUDE_DIR})
 458 endif()
 459
 460 include(ThreadMPI)
 461 # Enable core threading facilities
 462 tmpi_enable_core("${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include")
 463 # Enable tMPI C++ support
 464 tmpi_enable_cxx()
 465 if(GMX_THREAD_MPI)
 466     # enable MPI functions
 467     tmpi_enable()
 468     set(MPI_IN_PLACE_EXISTS 1)
 469 endif()
 470 # If atomics are manually disabled a define is needed because atomics.h doesn't depend on config.h
 471 if (TMPI_ATOMICS_DISABLED)
 472    add_definitions(-DTMPI_ATOMICS_DISABLED)
 473 endif()
 474
 475 if(GMX_GPU)
 476     # now that we have detected the dependencies, do the second configure pass
 477     gmx_gpu_setup()
 478 endif()
 479
 480 if(CYGWIN)
 481     set(GMX_CYGWIN 1)
 482 endif()
 483
 484 if(WIN32)
 485     set(GMX_NATIVE_WINDOWS 1)
 486     # This makes windows.h not declare min/max as macros that would break
 487     # C++ code using std::min/std::max.
 488     add_definitions(-DNOMINMAX)
 489 endif()
 490
 491 if(CMAKE_SYSTEM_NAME STREQUAL "Darwin") #Work-around for cmake bug #10837
 492     if (CMAKE_COMPILER_IS_GNUCC OR CMAKE_C_COMPILER_ID MATCHES "Intel" OR CMAKE_C_COMPILER_ID MATCHES "Clang")
 493         set(CMAKE_INCLUDE_SYSTEM_FLAG_C "-isystem ")
 494     endif()
 495     if (CMAKE_COMPILER_IS_GNUCXX OR CMAKE_CXX_COMPILER_ID MATCHES "Intel" OR CMAKE_CXX_COMPILER_ID MATCHES "Clang")
 496         set(CMAKE_INCLUDE_SYSTEM_FLAG_CXX "-isystem ")
 497     endif()
 498 endif()
 499
 500 # Detect boost unless GMX_EXTERNAL_BOOST is explicitly OFF
 501 # Used for default if GMX_EXTERNAL_BOOST is not defined (first CMake pass)
 502 if(NOT DEFINED GMX_EXTERNAL_BOOST OR GMX_EXTERNAL_BOOST)
 503     if(DEFINED Boost_INCLUDE_DIR)
 504         set(Boost_FIND_QUIETLY TRUE)
 505     endif()
 506     find_package(Boost 1.44.0)
 507     if(Boost_FOUND AND Boost_VERSION VERSION_LESS "104400")
 508         set(Boost_FOUND FALSE)
 509     endif()
 510     # Print the notification only on first run, when determining the default
 511     if(NOT DEFINED GMX_EXTERNAL_BOOST AND NOT Boost_FOUND)
 512         message("Boost >= 1.44 not found. Using minimal internal version. "
 513                 "This may cause trouble if you plan on compiling/linking other "
 514                 "software that uses Boost against GROMACS.")
 515     endif()
 516 endif()
 517 option(GMX_EXTERNAL_BOOST "Use external Boost instead of minimal built-in version"
 518        ${Boost_FOUND})
 519 if(GMX_EXTERNAL_BOOST AND NOT Boost_FOUND)
 520     message(FATAL_ERROR
 521         "Boost >= 1.44 not found. "
 522         "You can set GMX_EXTERNAL_BOOST=OFF to compile against minimal "
 523         "version of Boost included with GROMACS.")
 524 endif()
 525
 526 if(NOT DEFINED GMX_BUILD_UNITTESTS AND NOT HAVE_LIBXML2)
 527     message(WARNING "libxml2 not found. Will build GROMACS without unit-tests. This is not recommended, because the unit-tests help to verify that GROMACS functions correctly. Most likely you are missing the libxml2-dev(el) package. After you installed it, set GMX_BUILD_UNITTESTS=ON.")
 528 endif()
 529 option(GMX_BUILD_UNITTESTS "Build unit tests with BUILD_TESTING (uses Google C++ Testing and Mocking Frameworks, requires libxml2)" ${HAVE_LIBXML2})
 530 mark_as_advanced(GMX_BUILD_UNITTESTS)
 531 gmx_add_cache_dependency(GMX_BUILD_UNITTESTS BOOL BUILD_TESTING OFF)
 532 if (GMX_BUILD_UNITTESTS AND NOT HAVE_LIBXML2)
 533     message(FATAL_ERROR
 534         "Cannot build unit tests without libxml2. "
 535         "Either set GMX_BUILD_UNITTESTS=OFF or tell CMake how to find a working version of libxml2.")
 536 endif()
 537
 538 ########################################################################
 539 # Our own GROMACS tests
 540 ########################################################################
 541
 542 add_definitions( -DHAVE_CONFIG_H )
 543 include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src)
 544 include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include)
 545 # Required for config.h, maybe should only be set in src/CMakeLists.txt
 546 include_directories(BEFORE ${CMAKE_BINARY_DIR}/src)
 547
 548 include(gmxTestInlineASM)
 549 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 550
 551 include(gmxSetBuildInformation)
 552 gmx_set_build_information()
 553 # Turn on RDTSCP if:
 554 # - the build system's CPU supports it
 555 # - the acceleration is set to AVX as all AVX-capable CPUs support AVX (which
 556 #   at this point means that the user set it).
 557 # Note: it's better to not use the later set value of GMX_SIMD because
 558 # it reflects the system's capability of both compiling and running AVX code.
 559 # TODO: After merge with 5.0 one could implement a cache variable dependency
 560 # such that GMX_USE_RDTSCP can change if GMX_SIMD is changed to AVX
 561 # after the first cmake pass.
 562 if (BUILD_CPU_FEATURES MATCHES "rdtscp" OR GMX_SIMD MATCHES "AVX")
 563     set(GMX_USE_RDTSCP_DEFAULT_VALUE ON)
 564 else()
 565     set(GMX_USE_RDTSCP_DEFAULT_VALUE OFF)
 566 endif()
 567 option(GMX_USE_RDTSCP "Use RDTSCP for better CPU-based timers (available on recent x86 CPUs; might need to be off when compiling for heterogeneous environments)" ${GMX_USE_RDTSCP_DEFAULT_VALUE})
 568 mark_as_advanced(GMX_USE_RDTSCP)
 569 if(GMX_USE_RDTSCP)
 570     set(HAVE_RDTSCP 1)
 571 endif()
 572
 573 include(gmxTestFloatFormat)
 574 gmx_test_float_format(GMX_FLOAT_FORMAT_IEEE754
 575                       GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER
 576                       GMX_IEEE754_BIG_ENDIAN_WORD_ORDER)
 577
 578 include(gmxTestLargeFiles)
 579 gmx_test_large_files(GMX_LARGEFILES)
 580
 581 include(gmxTestSignal)
 582 gmx_test_sigusr1(HAVE_SIGUSR1)
 583
 584 include(gmxTestPipes)
 585 gmx_test_pipes(HAVE_PIPES)
 586
 587 include(gmxTestIsfinite)
 588 gmx_test_isfinite(HAVE_ISFINITE)
 589 gmx_test__isfinite(HAVE__ISFINITE)
 590 gmx_test__finite(HAVE__FINITE)
 591
 592 include(gmxTestCXX11)
 593 gmx_test_cxx11(GMX_CXX11_SUPPORTED GMX_CXX11_FLAGS)
 594 include(CMakeDependentOption)
 595 # clang with some older versions of boost fail to work with C++11
 596 if(CMAKE_CXX_COMPILER_ID MATCHES Clang AND
 597     (Boost_VERSION VERSION_EQUAL 104601 OR Boost_VERSION VERSION_EQUAL 104700))
 598     set(CLANG_AND_OLD_EXTERNAL_BOOST TRUE)
 599 endif()
 600 # nvcc does not support C++11 flags, so with GPUs we prefer to skip C++11 flags
 601 # entirely to keep the compilation environment uniform.
 602 cmake_dependent_option(GMX_CXX11
 603     "Use C++11 features"
 604     ON "GMX_CXX11_SUPPORTED AND NOT GMX_GPU AND NOT CLANG_AND_OLD_EXTERNAL_BOOST" OFF)
 605 mark_as_advanced(GMX_CXX11)
 606 if(GMX_CXX11)
 607     set(EXTRA_CXX_FLAGS "${EXTRA_CXX_FLAGS} ${GMX_CXX11_FLAGS}")
 608 endif()
 609
 610 # Now we can test for CXX11_REGEX include file
 611 check_include_file_cxx(regex     HAVE_CXX11_REGEX)
 612
 613 include(gmxTestXDR)
 614 gmx_test_xdr(GMX_SYSTEM_XDR)
 615 if(NOT GMX_SYSTEM_XDR)
 616     set(GMX_INTERNAL_XDR 1)
 617 endif()
 618
 619
 620 ##################################################
 621 # Process SIMD instruction settings
 622 ##################################################
 623 # This checks what flags to add in order to
 624 # support the SIMD instructions we need, it sets
 625 # correct defines for the SIMD instructions supported,
 626 # and adds advanced options to control accuracy
 627 # for SIMD math operations.
 628 include(gmxManageSimd)
 629 gmx_manage_simd()
 630
 631 # Process QM/MM Settings
 632 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 633     set(GMX_QMMM_GAUSSIAN 1)
 634 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 635     set(GMX_QMMM_MOPAC 1)
 636 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 637     set(GMX_QMMM_GAMESS 1)
 638 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 639     set(GMX_QMMM_ORCA 1)
 640 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 641     # nothing to do
 642 else()
 643     gmx_invalid_option_value(GMX_QMMM_PROGRAM)
 644 endif()
 645
 646
 647 ##################################################
 648 # Process FFT library settings
 649 ##################################################
 650 include(gmxManageFFTLibraries)
 651
 652
 653 include(gmxManageLinearAlgebraLibraries)
 654
 655 # Whether GROMACS will really try to compile support for VMD plugins
 656 set(GMX_USE_PLUGINS OFF)
 657
 658 if(GMX_LOAD_PLUGINS)
 659   if(NOT WIN32)
 660     # Native Windows does not have, nor need dlopen
 661     include(gmxTestdlopen)
 662     gmx_test_dlopen(HAVE_DLOPEN)
 663   endif()
 664
 665   # so, should we use plug-ins?
 666   if(WIN32 OR (HAVE_DLOPEN AND BUILD_SHARED_LIBS))
 667     if(NOT VMD_QUIETLY)
 668       MESSAGE(STATUS "Using dynamic plugins (e.g VMD-supported file formats)")
 669     endif()
 670     if(NOT GMX_VMD_PLUGIN_PATH)
 671       find_package(VMD)
 672     endif()
 673     set(GMX_USE_PLUGINS ON)
 674     list(APPEND GMX_EXTRA_LIBRARIES ${CMAKE_DL_LIBS}) # magic cross-platform pre-set variable for dlopen library
 675     set(PKG_DL_LIBS "-l${CMAKE_DL_LIBS}")
 676   else()
 677     set(PKG_DL_LIBS)
 678   endif()
 679 endif()
 680 set(VMD_QUIETLY TRUE CACHE INTERNAL "")
 681
 682 # Link real-time library for POSIX timers. The check for clock_gettime
 683 # confirms the linkability of rt.
 684 if(HAVE_TIME_H AND HAVE_UNISTD_H AND HAVE_CLOCK_GETTIME)
 685     list(APPEND GMX_EXTRA_LIBRARIES rt)
 686 endif()
 687
 688 # Math and thread libraries must often come after all others when linking...
 689 if(HAVE_LIBM)
 690     list(APPEND GMX_EXTRA_LIBRARIES m)
 691 endif()
 692
 693 option(GMX_NACL "Configure for Native Client builds" OFF)
 694 if (GMX_NACL)
 695   list(APPEND GMX_EXTRA_LIBRARIES nosys)
 696   set(GMX_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -lnosys")
 697   # TODO: Is this still necessary with the check for its presence?
 698   set(GMX_USE_NICE 0)
 699   set(GMX_NO_RENAME 1)
 700 endif()
 701 mark_as_advanced(GMX_NACL)
 702
 703 if(GMX_FAHCORE)
 704   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 705       "Path to swindirect.h")
 706   include_directories(${COREWRAP_INCLUDE_DIR})
 707 endif()
 708
 709 # Value of GMX_BUILD_HELP=AUTO tries to generate things, but will only
 710 # produce warnings if that fails.
 711 set(build_help_default AUTO)
 712 if (SOURCE_IS_SOURCE_DISTRIBUTION OR CMAKE_CROSSCOMPILING)
 713     set(build_help_default OFF)
 714 endif()
 715 gmx_option_trivalue(GMX_BUILD_HELP "Build completions automatically (requires that compiled binaries can be executed on the build host) and install man pages if built (requires building the 'man' target manually)" ${build_help_default})
 716 mark_as_advanced(GMX_BUILD_HELP)
 717 if (GMX_BUILD_HELP AND SOURCE_IS_SOURCE_DISTRIBUTION AND BUILD_IS_INSOURCE)
 718     message(FATAL_ERROR
 719         "Rebuilding shell completions or man pages is not supported for "
 720         "in-source builds from a source distribution. "
 721         "Set GMX_BUILD_HELP=OFF or do an out-of-source build to proceed.")
 722 endif()
 723
 724 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 725 # these are set after everything else
 726 if (NOT GMX_SKIP_DEFAULT_CFLAGS)
 727     set(CMAKE_C_FLAGS "${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${CMAKE_C_FLAGS}")
 728     set(CMAKE_CXX_FLAGS "${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${CMAKE_CXX_FLAGS}")
 729     set(CMAKE_EXE_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}")
 730     set(CMAKE_SHARED_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS}")
 731 else()
 732     message("Recommended flags which are not added because GMX_SKIP_DEFAULT_CFLAGS=yes:")
 733     message("CMAKE_C_FLAGS: ${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${GMXC_CFLAGS}")
 734     message("CMAKE_C_FLAGS_RELEASE: ${GMXC_CFLAGS_RELEASE}")
 735     message("CMAKE_C_FLAGS_DEBUG: ${GMXC_CFLAGS_DEBUG}")
 736     message("CMAKE_CXX_FLAGS: ${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${GMXC_CXXFLAGS}")
 737     message("CMAKE_CXX_FLAGS_RELEASE: ${GMXC_CXXFLAGS_RELEASE}")
 738     message("CMAKE_CXX_FLAGS_DEBUG: ${GMXC_CXXFLAGS_DEBUG}")
 739     message("CMAKE_EXE_LINKER_FLAGS: ${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS}")
 740     message("CMAKE_SHARED_LINKER_FLAGS: ${MPI_LINKER_FLAGS}")
 741 endif()
 742
 743 if(NOT GMX_OPENMP)
 744     #Unset all OpenMP flags in case OpenMP was disabled either by the user
 745     #or because it was only partially detected (e.g. only for C but not C++ compiler)
 746     unset(OpenMP_C_FLAGS CACHE)
 747     unset(OpenMP_CXX_FLAGS CACHE)
 748 else()
 749     set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} ${OpenMP_LINKER_FLAGS})
 750     set(GMX_SHARED_LINKER_FLAGS ${GMX_SHARED_LINKER_FLAGS} ${OpenMP_SHARED_LINKER_FLAGS})
 751 endif()
 752
 753 ########################################################################
 754 # Specify install locations
 755 ########################################################################
 756 # Use GNUInstallDirs to set paths on multiarch systems.
 757 include(GNUInstallDirs)
 758
 759 # Customization for the installation tree paths.
 760 set(GMX_LIB_INSTALL_DIR ${CMAKE_INSTALL_LIBDIR} CACHE STRING
 761     "Library installation directory (default: ${CMAKE_INSTALL_LIBDIR})")
 762 set(GMX_DATA_INSTALL_DIR gromacs CACHE STRING
 763     "Data installation directory under share/ (default: gromacs)")
 764 mark_as_advanced(GMX_LIB_INSTALL_DIR GMX_DATA_INSTALL_DIR)
 765
 766 # These variables are used internally to provide a central location for
 767 # customizing the install locations.
 768 set(LIB_INSTALL_DIR       ${GMX_LIB_INSTALL_DIR})
 769 set(BIN_INSTALL_DIR       bin)
 770 # This variable also gets written into config.h for use in finding the data
 771 # directories.
 772 set(DATA_INSTALL_DIR      share/${GMX_DATA_INSTALL_DIR})
 773 set(MAN_INSTALL_DIR       share/man)
 774 # If the nesting level wrt. the installation root is changed,
 775 # gromacs-config.cmake.cmakein needs to be adapted.
 776 set(CMAKE_INSTALL_DIR     share/cmake)
 777 # TODO: Make GMXRC adapt if this is changed
 778 set(PKGCONFIG_INSTALL_DIR ${LIB_INSTALL_DIR}/pkgconfig)
 779 set(INCL_INSTALL_DIR      include)
 780
 781 list(APPEND INSTALLED_HEADER_INCLUDE_DIRS ${INCL_INSTALL_DIR})
 782
 783 # Binary and library suffix options
 784 include(gmxManageSuffixes)
 785
 786 ################################################################
 787 # Shared library load path settings
 788 ################################################################
 789 # CMake supports RPATH on OS X only from 2.8.12 upwards.
 790 # CMAKE_SYSTEM_VERSION > 8.0 matches OS X 10.5 and above, where RPATH support
 791 # was added.
 792
 793 if(NOT GMX_BUILD_SHARED_EXE)
 794     # No rpath
 795     set(CMAKE_SKIP_RPATH TRUE)
 796     set(CMAKE_EXE_LINK_DYNAMIC_C_FLAGS) # remove -Wl,-Bdynamic
 797     set(CMAKE_EXE_LINK_DYNAMIC_CXX_FLAGS)
 798 elseif((NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin") OR
 799    ((CMAKE_SYSTEM_VERSION VERSION_GREATER 8.0) AND (NOT CMAKE_VERSION VERSION_LESS 2.8.12)))
 800     # The build folder always has bin/ and lib/; if we are also going to
 801     # install to lib/, then the installation RPATH works also in the build
 802     # tree.  This makes installation slightly faster (no need to rewrite the
 803     # RPATHs), and makes the binaries in the build tree relocatable.
 804     if(GMX_LIB_INSTALL_DIR STREQUAL "lib")
 805         set(CMAKE_BUILD_WITH_INSTALL_RPATH TRUE)
 806     endif()
 807     # Set the RPATH as relative to the executable location to make the
 808     # binaries relocatable.
 809     if(NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin")
 810         set(CMAKE_INSTALL_RPATH "\$ORIGIN/../${GMX_LIB_INSTALL_DIR}")
 811     else()
 812         set(CMAKE_INSTALL_RPATH "@executable_path/../${GMX_LIB_INSTALL_DIR}")
 813     endif()
 814     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 815     set(CMAKE_MACOSX_RPATH 1)
 816 else()
 817     # We are on Darwin/OSX, and CMake cannot handle RPATHs automatically.
 818     if(CMAKE_SYSTEM_VERSION VERSION_GREATER 8.0)
 819         # Set the RPATH options manually.
 820         set(CMAKE_INSTALL_NAME_DIR "@rpath")
 821         set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} "-Wl,-rpath,@executable_path/../${GMX_LIB_INSTALL_DIR}")
 822     else()
 823         # Use the old INSTALL_NAME_DIR mechanism if RPATH is not supported.
 824         set(CMAKE_INSTALL_NAME_DIR "${CMAKE_INSTALL_PREFIX}/${LIB_INSTALL_DIR}")
 825     endif()
 826 endif()
 827
 828 #COPYING file: Only necessary for binary distributions.
 829 #Simpler to always install.
 830 install(FILES COPYING DESTINATION ${DATA_INSTALL_DIR} COMPONENT data)
 831
 832 if(GMX_EXTERNAL_BOOST)
 833     include_directories(SYSTEM ${Boost_INCLUDE_DIRS})
 834     list(APPEND INSTALLED_HEADER_INCLUDE_DIRS ${Boost_INCLUDE_DIRS})
 835 else()
 836     include_directories(BEFORE SYSTEM ${CMAKE_SOURCE_DIR}/src/external/boost)
 837     list(APPEND INSTALLED_HEADER_INCLUDE_DIRS ${INCL_INSTALL_DIR}/gromacs/external/boost)
 838     list(APPEND INSTALLED_HEADED_DEFINITIONS "-DBOOST_NO_TYPEID")
 839     # typeid not supported for minimal internal version
 840     # (would add significant amount of code)
 841     add_definitions(-DBOOST_NO_TYPEID)
 842     if (NOT GMX_BUILD_MDRUN_ONLY)
 843         install(DIRECTORY ${CMAKE_SOURCE_DIR}/src/external/boost/boost
 844                 DESTINATION ${INCL_INSTALL_DIR}/gromacs/external/boost
 845                 COMPONENT development)
 846     endif()
 847 endif()
 848
 849 if (GMX_BUILD_FOR_COVERAGE)
 850     # Code heavy with asserts makes conditional coverage close to useless metric,
 851     # as by design most of the false branches are impossible to trigger in
 852     # correctly functioning code.  And the benefit of testing those that could
 853     # be triggered by using an API against its specification isn't usually
 854     # worth the effort.
 855     add_definitions(-DNDEBUG -DBOOST_DISABLE_ASSERTS -DGMX_DISABLE_ASSERTS)
 856 endif()
 857
 858 if (BUILD_TESTING)
 859     # "tests" target builds all the separate test binaries.
 860     add_custom_target(tests)
 861     # "run-ctest" is an internal target that actually runs the tests.
 862     # This is necessary to be able to add separate targets that execute as part
 863     # of 'make check', but are ensured to be executed after the actual tests.
 864     add_custom_target(run-ctest
 865                       COMMAND ${CMAKE_CTEST_COMMAND} --output-on-failure
 866                       COMMENT "Running all tests"
 867                       VERBATIM)
 868     add_dependencies(run-ctest tests)
 869     # "check" target builds and runs all tests.
 870     add_custom_target(check DEPENDS run-ctest)
 871 endif()
 872
 873 if (NOT GMX_BUILD_MDRUN_ONLY)
 874     add_subdirectory(docs)
 875     add_subdirectory(share)
 876     add_subdirectory(scripts)
 877 endif()
 878 add_subdirectory(src)
 879
 880 if (BUILD_TESTING)
 881     add_subdirectory(tests)
 882 endif()
 883
 884 gmx_cpack_write_config()
 885
 886 # Issue a warning if NVIDIA GPUs were detected, but CUDA was not found.
 887 # Don't bother the user after the first configure pass.
 888 if ((CUDA_NOTFOUND_AUTO AND GMX_DETECT_GPU_AVAILABLE) AND NOT GMX_GPU_DETECTION_DONE)
 889     message(WARNING "${CUDA_NOTFOUND_MESSAGE}")
 890 endif()
 891 set(GMX_GPU_DETECTION_DONE TRUE CACHE INTERNAL "Whether GPU detection has already been done")
 892
 893 #######################
 894 ## uninstall target
 895 #######################
 896 CONFIGURE_FILE(   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 897                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
 898                   IMMEDIATE @ONLY)
 899 ###########################
 900 ADD_CUSTOM_TARGET(uninstall
 901                   "${CMAKE_COMMAND}" -P
 902                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
 903 ###########################
 904 set_directory_properties(PROPERTIES
 905             ADDITIONAL_MAKE_CLEAN_FILES "install_manifest.txt")