CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2009,2010,2011,2012,2013, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 cmake_minimum_required(VERSION 2.8.8)
  36
  37 # CMake modules/macros are in a subdirectory to keep this file cleaner
  38 # This needs to be set before project() in order to pick up toolchain files
  39 list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake ${CMAKE_CURRENT_SOURCE_DIR}/cmake/Platform)
  40
  41 project(Gromacs)
  42
  43 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  44 set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  45 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
  46
  47 # PROJECT_VERSION should have the following structure:
  48 # VERSION-dev[-SUFFIX] where the VERSION should have the for: vMajor.vMinor.vPatch
  49 #
  50 # The "-dev" suffix is important to keep because it makes possible to distinguish
  51 # between a build from official release and a build from git release branch on a
  52 # machine with no git.
  53 #
  54 # NOTE: when releasing the "-dev" suffix needs to be stripped off!
  55 set(PROJECT_VERSION "5.0-beta2-dev")
  56 # The version number of the regressiontest tarball against which this
  57 # git branch can be tested. Normally, this will be the version of the
  58 # last patch release. Comment the next line out for branches leading
  59 # to a major/minor release.
  60 set(REGRESSIONTEST_VERSION "5.0-beta1")
  61 set(CUSTOM_VERSION_STRING ""
  62     CACHE STRING "Custom version string (if empty, use hard-coded default)")
  63 mark_as_advanced(CUSTOM_VERSION_STRING)
  64 if (CUSTOM_VERSION_STRING)
  65     set(PROJECT_VERSION ${CUSTOM_VERSION_STRING})
  66 endif (CUSTOM_VERSION_STRING)
  67 set(SOVERSION 8)
  68 # It is a bit irritating, but this has to be set separately for now!
  69 SET(CPACK_PACKAGE_VERSION_MAJOR "5")
  70 SET(CPACK_PACKAGE_VERSION_MINOR "0")
  71 #SET(CPACK_PACKAGE_VERSION_PATCH "0")
  72
  73 # The numerical gromacs version. It is 40600 for 4.6.0.
  74 # The #define GMX_VERSION in gmx_header_config_h is set to this value.
  75 math(EXPR NUM_VERSION
  76     "${CPACK_PACKAGE_VERSION_MAJOR}*10000 + ${CPACK_PACKAGE_VERSION_MINOR}*100")
  77 if(CPACK_PACKAGE_VERSION_PATCH)
  78     math(EXPR NUM_VERSION
  79          "${NUM_VERSION} + ${CPACK_PACKAGE_VERSION_PATCH}")
  80 endif()
  81
  82 # The API version tracks the numerical Gromacs version (for now).
  83 # It is potentially different from the Gromacs version in the future, if
  84 # the programs/libraries diverge from the presumably more stable API.
  85 # The #define GMX_API_VERSION in version.h is set to this value to
  86 # provide backward compatibility of software written against the Gromacs API.
  87 set(API_VERSION ${NUM_VERSION})
  88
  89 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT AND UNIX)
  90     set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
  91 endif()
  92
  93 set(GMX_INSTALL_PREFIX "" CACHE STRING "Prefix gets appended to CMAKE_INSTALL_PREFIX. For cpack it sets the root folder of the archive.")
  94 mark_as_advanced(GMX_INSTALL_PREFIX)
  95
  96 include(gmxBuildTypeReference)
  97
  98 if(NOT CMAKE_BUILD_TYPE)
  99     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel Reference." FORCE)
 100     # Set the possible values of build type for cmake-gui
 101     set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "Debug" "Release"
 102         "MinSizeRel" "RelWithDebInfo")
 103 endif(NOT CMAKE_BUILD_TYPE)
 104
 105 enable_language(C)
 106 enable_language(CXX)
 107
 108 set(CPACK_PACKAGE_VERSION ${PROJECT_VERSION})
 109 set(CPACK_PACKAGE_VENDOR "gromacs.org")
 110 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Gromacs - a toolkit for high-performance molecular simulation")
 111 set(CPACK_RESOURCE_FILE_WELCOME "${CMAKE_SOURCE_DIR}/admin/InstallWelcome.txt")
 112 # Its GPL/LGPL, so they do not have to agree to a license for mere usage, but some installers require this...
 113 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_SOURCE_DIR}/COPYING")
 114 set(CPACK_RESOURCE_FILE_README "${CMAKE_SOURCE_DIR}/admin/InstallInfo.txt")
 115 set(CPACK_SOURCE_IGNORE_FILES "\\\\.isreposource$;\\\\.git/;\\\\.gitignore$")
 116 set(CPACK_PROJECT_CONFIG_FILE "${CMAKE_SOURCE_DIR}/CPackInit.cmake")
 117 set(CPACK_SOURCE_INSTALLED_DIRECTORIES "${CMAKE_SOURCE_DIR};/;${CMAKE_BINARY_DIR}/share/man/man1;share/man/man1;${CMAKE_BINARY_DIR}/share/man/man7;share/man/man7;${CMAKE_BINARY_DIR}/share/html/final;share/html")
 118 set(CPACK_PACKAGE_CONTACT "gmx-users@gromacs.org")
 119
 120 #must come after all cpack settings!
 121 include(CPack)
 122
 123 # Set a default valgrind suppression file.
 124 # This unfortunately needs to duplicate information from CTest to work as
 125 # expected...
 126 set(MEMORYCHECK_SUPPRESSIONS_FILE
 127     "${CMAKE_SOURCE_DIR}/cmake/legacy_and_external.supp"
 128     CACHE FILEPATH
 129     "File that contains suppressions for the memory checker")
 130 include(CTest)
 131
 132 set(SOURCE_IS_GIT_REPOSITORY OFF)
 133 set(SOURCE_IS_SOURCE_DISTRIBUTION OFF)
 134 if(EXISTS "${CMAKE_SOURCE_DIR}/.git")
 135     set(SOURCE_IS_GIT_REPOSITORY ON)
 136 endif()
 137 if(NOT EXISTS "${CMAKE_SOURCE_DIR}/admin/.isreposource")
 138     set(SOURCE_IS_SOURCE_DISTRIBUTION ON)
 139 endif()
 140
 141 ########################################################################
 142 # Check and warn if cache generated on a different host is being reused
 143 ########################################################################
 144 if(CMAKE_HOST_UNIX)
 145     execute_process(COMMAND hostname
 146                     OUTPUT_VARIABLE TMP_HOSTNAME
 147                     OUTPUT_STRIP_TRAILING_WHITESPACE)
 148     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}")
 149         message(WARNING "
 150             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
 151             is being reused! This could lead to inconsitencies; therefore, it is
 152             recommended to regenerate the cache!")
 153     endif()
 154     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
 155             "Hostname of the machine where the cache was generated.")
 156 endif()
 157
 158 ########################################################################
 159 # User input options                                                   #
 160 ########################################################################
 161 include(gmxOptionUtilities)
 162
 163 set(CMAKE_PREFIX_PATH "" CACHE STRING "Extra locations to search for external libraries and tools (give directory without lib, bin, or include)")
 164
 165 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" OFF)
 166 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 167 option(GMX_THREAD_MPI  "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" ON)
 168 gmx_dependent_option(
 169     GMX_MPI_IN_PLACE
 170     "Enable MPI_IN_PLACE for MPIs that have it defined"
 171     ON
 172     GMX_MPI)
 173 mark_as_advanced(GMX_MPI_IN_PLACE)
 174 option(GMX_SOFTWARE_INVSQRT "Use GROMACS software 1/sqrt" ON)
 175 mark_as_advanced(GMX_SOFTWARE_INVSQRT)
 176 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 177 mark_as_advanced(GMX_FAHCORE)
 178
 179 option(GMX_COOL_QUOTES "Enable Gromacs cool quotes" ON)
 180 mark_as_advanced(GMX_COOL_QUOTES)
 181 gmx_add_cache_dependency(GMX_COOL_QUOTES BOOL "NOT GMX_FAHCORE" OFF)
 182
 183 # decide on GPU settings based on user-settings and GPU/CUDA detection
 184 include(gmxManageGPU)
 185
 186 # Detect the architecture the compiler is targetting, detect
 187 # acceleration possibilities on that hardware, suggest an acceleration
 188 # to use if none is specified, and populate the cache option for CPU
 189 # accleration.
 190 include(gmxDetectTargetArchitecture)
 191 gmx_detect_target_architecture()
 192 include(gmxDetectAcceleration)
 193 gmx_detect_acceleration(GMX_SUGGESTED_CPU_ACCELERATION)
 194
 195 gmx_option_multichoice(
 196     GMX_CPU_ACCELERATION
 197     "Acceleration for CPU kernels and compiler optimization"
 198     "${GMX_SUGGESTED_CPU_ACCELERATION}"
 199     None SSE2 SSE4.1 AVX_128_FMA AVX_256 IBM_QPX Sparc64_HPC_ACE)
 200
 201 gmx_option_multichoice(
 202     GMX_FFT_LIBRARY
 203     "FFT library"
 204     "fftw3"
 205     fftw3 mkl "fftpack[built-in]")
 206 gmx_dependent_option(
 207     GMX_BUILD_OWN_FFTW
 208     "Download and build FFTW 3 during the GROMACS build process, rather than fall back on the really slow fftpack."
 209     OFF
 210     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 211 gmx_dependent_option(
 212     GMX_DISABLE_FFTW_MEASURE
 213     "Do not optimize FFTW setups (not needed with SSE)"
 214     OFF
 215     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 216 mark_as_advanced(GMX_BUILD_OWN_FFTW)
 217 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 218
 219 gmx_option_multichoice(
 220     GMX_QMMM_PROGRAM
 221     "QM package for QM/MM"
 222     None
 223     none gaussian mopac gamess orca)
 224
 225 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 226 mark_as_advanced(GMX_BROKEN_CALLOC)
 227 option(GMX_LOAD_PLUGINS "Compile with plugin support, needed to read VMD supported file formats" ON)
 228 mark_as_advanced(GMX_LOAD_PLUGINS)
 229
 230 option(GMX_GPU  "Enable GPU acceleration" ON)
 231 option(GMX_OPENMP "Enable OpenMP-based multithreading" ON)
 232
 233 option(GMX_GIT_VERSION_INFO "Generate git version information" ${SOURCE_IS_GIT_REPOSITORY})
 234 mark_as_advanced(GMX_GIT_VERSION_INFO)
 235
 236 if(UNIX)
 237     option(GMX_SYMLINK_OLD_BINARY_NAMES "Create symbolic links for pre-5.0 binary names" ON)
 238 endif()
 239 option(GMX_BUILD_MDRUN_ONLY "Build and install only the mdrun binary" OFF)
 240
 241 option(GMX_CYCLE_SUBCOUNTERS "Enable cycle subcounters to get a more detailed cycle timings" OFF)
 242 mark_as_advanced(GMX_CYCLE_SUBCOUNTERS)
 243
 244 option(GMX_SKIP_DEFAULT_CFLAGS "Don't automatically add suggested/required Compiler flags." OFF)
 245 mark_as_advanced(GMX_SKIP_DEFAULT_CFLAGS)
 246
 247 option(GMX_BUILD_FOR_COVERAGE
 248        "Tune build for better code coverage metrics (e.g., disable asserts)"
 249        OFF)
 250 mark_as_advanced(GMX_BUILD_FOR_COVERAGE)
 251
 252
 253 ######################################################################
 254 # Detect OpenMP support
 255 ######################################################################
 256 # The OpenMP detection _must_ come before tests for other CFLAGS.
 257 include(gmxManageOpenMP)
 258
 259
 260
 261 ######################################################################
 262 # Compiler tests
 263 # These need to be done early (before further tests).
 264 #####################################################################
 265
 266 # The cmake/Check{C,CXX}CompilerFlag.cmake files in the GROMACS distribution
 267 # are used with permission from CMake v2.8.9 so that GROMACS can detect
 268 # invalid options with the Intel Compilers.
 269 # These files should be removed from the source tree when a CMake version that
 270 # includes the features in question becomes required for building GROMACS.
 271 include(CheckCCompilerFlag)
 272 include(CheckCXXCompilerFlag)
 273
 274
 275 include(gmxCFlags)
 276 gmx_c_flags()
 277
 278 # This variable should be used for additional compiler flags which are not
 279 # generated in gmxCFlags nor are acceleration or MPI related.
 280 set(EXTRA_C_FLAGS "")
 281 set(EXTRA_CXX_FLAGS "")
 282
 283 # Run through a number of tests for buggy compilers and other issues
 284 include(gmxTestCompilerProblems)
 285 gmx_test_compiler_problems()
 286
 287
 288 set(PKG_CFLAGS "")
 289 if(GMX_DOUBLE)
 290     add_definitions(-DGMX_DOUBLE)
 291     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_DOUBLE")
 292 endif(GMX_DOUBLE)
 293 if(GMX_SOFTWARE_INVSQRT)
 294   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_SOFTWARE_INVSQRT")
 295 endif(GMX_SOFTWARE_INVSQRT)
 296
 297
 298
 299 ########################################################################
 300 # Basic system tests (standard libraries, headers, functions, types)   #
 301 ########################################################################
 302 include(CheckIncludeFiles)
 303 include(CheckIncludeFileCXX)
 304 check_include_files(unistd.h     HAVE_UNISTD_H)
 305 check_include_files(pwd.h        HAVE_PWD_H)
 306 check_include_files(dirent.h     HAVE_DIRENT_H)
 307 check_include_files(time.h       HAVE_TIME_H)
 308 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 309 check_include_files(io.h         HAVE_IO_H)
 310 check_include_files(sched.h      HAVE_SCHED_H)
 311
 312 check_include_files(regex.h      HAVE_POSIX_REGEX)
 313 check_include_file_cxx(regex     HAVE_CXX11_REGEX)
 314 # TODO: It could be nice to inform the user if no regex support is found,
 315 # as selections won't be fully functional.
 316
 317 include(CheckFunctionExists)
 318 check_function_exists(posix_memalign    HAVE_POSIX_MEMALIGN)
 319 check_function_exists(memalign          HAVE_MEMALIGN)
 320 check_function_exists(_aligned_malloc   HAVE__ALIGNED_MALLOC)
 321 check_function_exists(gettimeofday      HAVE_GETTIMEOFDAY)
 322 check_function_exists(fsync             HAVE_FSYNC)
 323 check_function_exists(_fileno           HAVE__FILENO)
 324 check_function_exists(fileno            HAVE_FILENO)
 325 check_function_exists(_commit           HAVE__COMMIT)
 326 check_function_exists(sigaction         HAVE_SIGACTION)
 327 check_function_exists(sysconf           HAVE_SYSCONF)
 328 check_function_exists(sched_setaffinity HAVE_SCHED_SETAFFINITY)
 329 check_function_exists(sched_getaffinity HAVE_SCHED_GETAFFINITY)
 330 check_function_exists(rsqrt             HAVE_RSQRT)
 331 check_function_exists(rsqrtf            HAVE_RSQRTF)
 332 check_function_exists(sqrtf             HAVE_SQRTF)
 333
 334 include(CheckLibraryExists)
 335 check_library_exists(m sqrt "" HAVE_LIBM)
 336 check_library_exists(rt clock_gettime "" HAVE_CLOCK_GETTIME)
 337
 338
 339 include(CheckTypeSize)
 340
 341 check_type_size("int"           SIZEOF_INT)
 342 check_type_size("long int"      SIZEOF_LONG_INT)
 343 check_type_size("long long int" SIZEOF_LONG_LONG_INT)
 344 check_type_size("off_t"         SIZEOF_OFF_T)
 345 check_type_size("void *"        SIZEOF_VOIDP)
 346
 347 include(TestBigEndian)
 348 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 349
 350 # Management of GROMACS options for specific toolchains should go
 351 # here. Because the initial settings for some of the main options have
 352 # already happened, but things like library detection and MPI compiler
 353 # feature detection have not, the docstrings for any over-rides of
 354 # GROMACS defaults or user settings will make sense. Also, any
 355 # toolchain-related reasons for choosing whether to detect various
 356 # things can be sorted out now, before the detection takes place.
 357 if(${CMAKE_SYSTEM_NAME} MATCHES BlueGene)
 358     include(gmxManageBlueGene)
 359 endif()
 360
 361 ########################################################################
 362 #Process MPI settings
 363 ########################################################################
 364 include(gmxManageMPI)
 365
 366 ########################################################################
 367 # Shared/static library settings
 368 ########################################################################
 369 # Determine the defaults (this block has no effect if the variables have
 370 # already been set)
 371 if(APPLE OR CYGWIN OR ${CMAKE_SYSTEM_NAME} MATCHES "Linux|.*BSD")
 372     # Maybe Solaris should be here? Patch this if you know!
 373     SET(SHARED_LIBS_DEFAULT ON)
 374 elseif(WIN32 OR ${CMAKE_SYSTEM_NAME} MATCHES "BlueGene")
 375     # Support for shared libs on native Windows is a bit new. Its
 376     # default might change later if/when we sort things out. Also,
 377     # Cray should go here. What variable value can detect it?
 378     SET(SHARED_LIBS_DEFAULT OFF)
 379 else()
 380     if (NOT DEFINED BUILD_SHARED_LIBS)
 381         message(STATUS "Defaulting to building static libraries")
 382     endif()
 383     SET(SHARED_LIBS_DEFAULT OFF)
 384 endif()
 385 if (GMX_PREFER_STATIC_LIBS)
 386     if (NOT DEFINED BUILD_SHARED_LIBS AND SHARED_LIBS_DEFAULT)
 387         message("Searching for static libraries requested, so the GROMACS libraries will also be built statically (BUILD_SHARED_LIBS=OFF)")
 388     endif()
 389     set(SHARED_LIBS_DEFAULT OFF)
 390 endif()
 391 set(GMX_PREFER_STATIC_LIBS_DEFAULT OFF)
 392 if (WIN32 AND NOT CYGWIN AND NOT BUILD_SHARED_LIBS)
 393     set(GMX_PREFER_STATIC_LIBS_DEFAULT ON)
 394 endif()
 395
 396 # Declare the user-visible options
 397 option(BUILD_SHARED_LIBS "Enable shared libraries (can be problematic e.g. with MPI, or on some HPC systems)" ${SHARED_LIBS_DEFAULT})
 398 if (UNIX)
 399     set(GMX_PREFER_STATIC_LIBS_DESCRIPTION
 400         "When finding libraries prefer static archives (it will only work if static versions of external dependencies are available and found)")
 401 elseif (WIN32 AND NOT CYGWIN)
 402     set(GMX_PREFER_STATIC_LIBS_DESCRIPTION
 403         "When finding libraries prefer static system libraries (MT instead of MD)")
 404 endif()
 405 option(GMX_PREFER_STATIC_LIBS "${GMX_PREFER_STATIC_LIBS_DESCRIPTION}"
 406        ${GMX_PREFER_STATIC_LIBS_DEFAULT})
 407 mark_as_advanced(GMX_PREFER_STATIC_LIBS)
 408
 409 # Act on the set values
 410 if (UNIX AND GMX_PREFER_STATIC_LIBS)
 411     if(BUILD_SHARED_LIBS)
 412         # Warn the user about the combination. But don't overwrite the request.
 413         message(WARNING "Searching for static libraries requested, and building shared Gromacs libraries requested. This might cause problems linking later.")
 414     endif()
 415     # On Linux .a is the static library suffix, on Mac OS X .lib can also
 416     # be used, so we'll add both to the preference list.
 417     SET(CMAKE_FIND_LIBRARY_SUFFIXES ".lib;.a" ${CMAKE_FIND_LIBRARY_SUFFIXES})
 418 endif()
 419 IF( WIN32 AND NOT CYGWIN)
 420   if (NOT BUILD_SHARED_LIBS)
 421       if(NOT GMX_PREFER_STATIC_LIBS)
 422           message(WARNING "Shared system libraries requested, and static Gromacs libraries requested.")
 423       endif()
 424   else()
 425       message(FATAL_ERROR "BUILD_SHARED_LIBS=ON not yet working for Windows in the master branch")
 426       if(GMX_PREFER_STATIC_LIBS)
 427           #this combination segfaults (illegal passing of file handles)
 428           message(FATAL_ERROR "Static system libraries requested, and shared Gromacs libraries requested.")
 429       endif()
 430       add_definitions(-DUSE_VISIBILITY -DTMPI_USE_VISIBILITY)
 431       set(PKG_CFLAGS "$PKG_CFLAGS -DUSE_VISIBILITY -DTMPI_USE_VISIBILITY")
 432   endif()
 433
 434   IF (GMX_PREFER_STATIC_LIBS)
 435       #Only setting Debug and Release flags. Others configurations are current not used.
 436       STRING(REPLACE /MD /MT CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE})
 437       STRING(REPLACE /MD /MT CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG})
 438       STRING(REPLACE /MD /MT CMAKE_CXX_FLAGS_RELEASE ${CMAKE_CXX_FLAGS_RELEASE})
 439       STRING(REPLACE /MD /MT CMAKE_CXX_FLAGS_DEBUG ${CMAKE_CXX_FLAGS_DEBUG})
 440   ENDIF()
 441   IF( CMAKE_C_COMPILER_ID MATCHES "Intel" )
 442     if(BUILD_SHARED_LIBS) #not sure why incremental building with shared libs doesn't work
 443         STRING(REPLACE "/INCREMENTAL:YES" "" CMAKE_SHARED_LINKER_FLAGS ${CMAKE_SHARED_LINKER_FLAGS})
 444     endif()
 445   ENDIF()
 446 ENDIF()
 447
 448 ########################################################################
 449 # Find external packages                                               #
 450 ########################################################################
 451
 452 # Unconditionally find the package, as it is also required for unit tests
 453 find_package(LibXml2)
 454 option(GMX_XML "Use libxml2 to parse xml files (currently has no effect)" ${LIBXML2_FOUND})
 455 set(PKG_XML "")
 456 mark_as_advanced(GMX_XML)
 457 # Don't actually do anything, since libxml2 is currently not used by libgromacs
 458 #if(GMX_XML AND NOT LIBXML2_FOUND)
 459 #    message(FATAL_ERROR "libxml2 not found. Set GMX_XML=OFF to compile without XML support")
 460 #endif()
 461 #if(GMX_XML)
 462 #    include_directories(${LIBXML2_INCLUDE_DIR})
 463 #    set(PKG_XML libxml-2.0)
 464 #    set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 465 #endif(GMX_XML)
 466
 467 option(GMX_GSL "Add support for gsl" OFF)
 468 if (GMX_GSL)
 469   find_package(GSL)
 470   set(PKG_GSL "")
 471   if(GSL_FOUND)
 472     include_directories(${GSL_INCLUDE_DIR})
 473     set(PKG_GSL gsl)
 474     set(HAVE_LIBGSL 1)
 475   endif(GSL_FOUND)
 476 endif (GMX_GSL)
 477
 478 option(GMX_X11 "Use X window system" OFF)
 479 if (GMX_X11)
 480     find_package(X11)
 481     # X11 includes/libraries are only set in the ngmx subdirectory!
 482     if(NOT X11_FOUND)
 483         message(FATAL_ERROR
 484                 "X11 include files and/or libraries were not found. "
 485                 "Set GMX_X11=OFF to compile without X11 support. "
 486                 "gmx view will not be available.")
 487     endif()
 488     include_directories(${X11_INCLUDE_DIR})
 489 endif(GMX_X11)
 490
 491 include(ThreadMPI)
 492 set(THREAD_MPI_LIB thread_mpi)
 493 # Enable core threading facilities
 494 tmpi_enable_core("${CMAKE_SOURCE_DIR}/src/gromacs/legacyheaders")
 495 # Enable tMPI C++ support
 496 tmpi_enable_cxx()
 497 if(GMX_THREAD_MPI)
 498     # enable MPI functions
 499     tmpi_enable()
 500     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_THREAD_MPI")
 501     set(GMX_MPI 1)
 502     set(MPI_IN_PLACE_EXISTS 1)
 503 endif(GMX_THREAD_MPI)
 504 tmpi_get_source_list(THREAD_MPI_SRC)
 505
 506 if(GMX_GPU)
 507     # now that we have detected the dependencies, do the second configure pass
 508     gmx_gpu_setup()
 509 endif(GMX_GPU)
 510
 511 if(CYGWIN)
 512     set(GMX_CYGWIN 1)
 513 endif(CYGWIN)
 514
 515 if(WIN32 AND NOT CYGWIN)
 516     set(GMX_NATIVE_WINDOWS 1)
 517     # This makes windows.h not declare min/max as macros that would break
 518     # C++ code using std::min/std::max.
 519     add_definitions(-DNOMINMAX)
 520 endif()
 521
 522 # only bother with finding git and using version.h if the source is a git repo
 523 if(GMX_GIT_VERSION_INFO)
 524     if (NOT SOURCE_IS_GIT_REPOSITORY)
 525         message(FATAL_ERROR
 526             "Cannot generate git version information from source tree not under git. "
 527             "Set GMX_GIT_VERSION_INFO=OFF to proceed.")
 528     endif ()
 529     # We need at least git v1.5.3 be able to parse git's date output. If not
 530     # found or the version is too small, we can't generate version information.
 531     find_package(Git)
 532
 533     if(NOT GIT_FOUND OR GIT_VERSION_STRING VERSION_LESS "1.5.3")
 534         message(FATAL_ERROR
 535             "No compatible git version found (>= 1.5.3 required). "
 536             "Won't be able to generate development version information. "
 537             "Set GMX_GIT_VERSION_INFO=OFF to proceed.")
 538     endif()
 539 endif()
 540
 541 # Detect boost unless GMX_EXTERNAL_BOOST is explicitly OFF
 542 # Used for default if GMX_EXTERNAL_BOOST is not defined (first CMake pass)
 543 if(NOT DEFINED GMX_EXTERNAL_BOOST OR GMX_EXTERNAL_BOOST)
 544     find_package(Boost 1.44.0)
 545     if(Boost_FOUND AND Boost_VERSION VERSION_LESS "104400")
 546         set(Boost_FOUND FALSE)
 547     endif()
 548     # Print the notification only on first run, when determining the default
 549     if(NOT DEFINED GMX_EXTERNAL_BOOST AND NOT Boost_FOUND)
 550         message("Boost >= 1.44 not found. Using minimal internal version. "
 551                 "This may cause trouble if you plan on compiling/linking other "
 552                 "software that uses Boost against Gromacs.")
 553     endif()
 554 endif()
 555 option(GMX_EXTERNAL_BOOST "Use external Boost instead of minimal built-in version"
 556        ${Boost_FOUND})
 557 if(GMX_EXTERNAL_BOOST AND NOT Boost_FOUND)
 558     message(FATAL_ERROR
 559         "Boost >= 1.44 not found. "
 560         "You can set GMX_EXTERNAL_BOOST=OFF to compile against minimal "
 561         "version of Boost included with Gromacs.")
 562 endif()
 563
 564 option(GMX_BUILD_UNITTESTS "Build unit tests with BUILD_TESTING (uses Google C++ Testing and Mocking Frameworks, requires libxml2)" ${LIBXML2_FOUND})
 565 mark_as_advanced(GMX_BUILD_UNITTESTS)
 566 gmx_add_cache_dependency(GMX_BUILD_UNITTESTS BOOL BUILD_TESTING OFF)
 567 if (GMX_BUILD_UNITTESTS AND NOT LIBXML2_FOUND)
 568     message(FATAL_ERROR
 569         "Cannot build unit tests without libxml2. "
 570         "Either set GMX_BUILD_UNITTESTS=OFF or tell CMake how to find libxml2.")
 571 endif()
 572
 573 ########################################################################
 574 # Generate development version info for cache
 575 ########################################################################
 576 # set(GEN_VERSION_INFO_INTERNAL "ON")
 577 # include(gmxGenerateVersionString)
 578
 579 ########################################################################
 580 # Our own GROMACS tests
 581 ########################################################################
 582
 583 add_definitions( -DHAVE_CONFIG_H )
 584 include_directories(${CMAKE_SOURCE_DIR}/src)
 585 # Required for config.h, maybe should only be set in src/CMakeLists.txt
 586 include_directories(${CMAKE_BINARY_DIR}/src)
 587 # Required for gmx_header_config_gen.h to be found before installation
 588 include_directories(${CMAKE_BINARY_DIR}/src/gromacs/utility)
 589 # Required for now to make old code compile
 590 include_directories(${CMAKE_SOURCE_DIR}/src/gromacs/legacyheaders)
 591
 592 include(gmxTestInlineASM)
 593 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 594
 595 include(gmxSetBuildInformation)
 596 gmx_set_build_information()
 597 if(BUILD_CPU_FEATURES MATCHES "rdtscp" AND NOT GMX_DISTRIBUTABLE_BUILD)
 598     set(HAVE_RDTSCP 1)
 599 endif(BUILD_CPU_FEATURES MATCHES "rdtscp" AND NOT GMX_DISTRIBUTABLE_BUILD)
 600
 601 include(gmxTestFloatFormat)
 602 gmx_test_float_format(GMX_FLOAT_FORMAT_IEEE754
 603                       GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER
 604                       GMX_IEEE754_BIG_ENDIAN_WORD_ORDER)
 605
 606 include(gmxTestLargeFiles)
 607 gmx_test_large_files(GMX_LARGEFILES)
 608
 609 include(gmxTestSignal)
 610 gmx_test_sigusr1(HAVE_SIGUSR1)
 611
 612 include(gmxTestInline)
 613 gmx_test_inline(INLINE_KEYWORD)
 614
 615 include(gmxTestRestrict)
 616 gmx_test_restrict(RESTRICT_KEYWORD)
 617
 618 include(gmxTestPipes)
 619 gmx_test_pipes(HAVE_PIPES)
 620
 621 include(gmxTestIsfinite)
 622 gmx_test_isfinite(HAVE_ISFINITE)
 623 gmx_test__isfinite(HAVE__ISFINITE)
 624 gmx_test__finite(HAVE__FINITE)
 625
 626 include(gmxTestCXX11)
 627 gmx_test_cxx11(GMX_CXX11 GMX_CXX11_FLAGS)
 628 if(CXX11_FLAG AND GMX_GPU)
 629     #FIXME: add proper solution for progate all but cxx11 flag
 630     set(CUDA_PROPAGATE_HOST_FLAGS no)
 631     message(WARNING "Please manually add compiler flags to CUDA_NVCC_FLAGS. Automatic propogation temporary not working.")
 632 endif()
 633
 634 include(gmxTestXDR)
 635 gmx_test_xdr(GMX_SYSTEM_XDR)
 636 if(NOT GMX_SYSTEM_XDR)
 637     set(GMX_INTERNAL_XDR 1)
 638 endif(NOT GMX_SYSTEM_XDR)
 639
 640 # include avx test source, used if the AVX flags are set below
 641 include(gmxTestAVXMaskload)
 642
 643 # Process nonbonded accelerated kernels settings
 644 #
 645 # Note that for the backward-compatible x86 SIMD architectures, the
 646 # GMX_CPU_ACCELERATION determines the maximum level of the instruction
 647 # set used (e.g. GMX_CPU_ACCLERATION=SSE4.1 implies
 648 # SSE2). Accordingly, there are a set of CMake variables
 649 # GMX_<arch>_<feature-set> that are exported to the C code to specify
 650 # CPU features that should be used. This means that the logic for
 651 # requiring such backward compatibility is all located here.
 652 if(${GMX_CPU_ACCELERATION} STREQUAL "NONE")
 653     # nothing to do
 654     set(ACCELERATION_STATUS_MESSAGE "CPU acceleration disabled")
 655
 656 elseif(${GMX_CPU_ACCELERATION} STREQUAL "SSE2")
 657
 658     GMX_TEST_CFLAG(GNU_SSE2_CFLAG "-msse2" ACCELERATION_C_FLAGS)
 659     if(NOT GNU_SSE2_CFLAG AND GMX_NATIVE_WINDOWS)
 660         GMX_TEST_CFLAG(MSVC_SSE2_CFLAG "/arch:SSE2" ACCELERATION_C_FLAGS)
 661     endif(NOT GNU_SSE2_CFLAG AND GMX_NATIVE_WINDOWS)
 662
 663     GMX_TEST_CXXFLAG(GNU_SSE2_CXXFLAG "-msse2" ACCELERATION_CXX_FLAGS)
 664     if(NOT GNU_SSE2_CXXFLAG AND GMX_NATIVE_WINDOWS)
 665         GMX_TEST_CXXFLAG(MSVC_SSE2_CXXFLAG "/arch:SSE2" ACCELERATION_CXX_FLAGS)
 666     endif(NOT GNU_SSE2_CXXFLAG AND GMX_NATIVE_WINDOWS)
 667
 668     # We dont warn for lacking SSE2 flag support, since that is probably standard today.
 669
 670     # Only test the include after we have tried to add the correct flag for SSE2 support
 671     check_include_file(emmintrin.h  HAVE_EMMINTRIN_H ${ACCELERATION_C_FLAGS})
 672
 673     if(NOT HAVE_EMMINTRIN_H)
 674         message(FATAL_ERROR "Cannot find emmintrin.h, which is required for SSE2 intrinsics support.")
 675     endif(NOT HAVE_EMMINTRIN_H)
 676
 677     set(GMX_CPU_ACCELERATION_X86_SSE2 1)
 678     # The user should not be able to set this orthogonally to the acceleration
 679     set(GMX_X86_SSE2 1)
 680     set(ACCELERATION_STATUS_MESSAGE
 681         "Enabling SSE2 Gromacs acceleration")
 682
 683 elseif(${GMX_CPU_ACCELERATION} STREQUAL "SSE4.1")
 684
 685     GMX_TEST_CFLAG(GNU_SSE4_CFLAG "-msse4.1" ACCELERATION_C_FLAGS)
 686     if (NOT GNU_SSE4_CFLAG AND GMX_NATIVE_WINDOWS)
 687         GMX_TEST_CFLAG(MSVC_SSE4_CFLAG "/arch:SSE4.1" ACCELERATION_C_FLAGS)
 688     endif(NOT GNU_SSE4_CFLAG AND GMX_NATIVE_WINDOWS)
 689     if (NOT GNU_SSE4_CFLAG AND NOT MSVC_SSE4_CFLAG)
 690         # Not surprising if we end up here! MSVC current does not support the SSE4.1 flag. However, it appears to accept SSE4.1
 691         # intrinsics when SSE2 support is enabled, so we try that instead first.
 692         if (GMX_NATIVE_WINDOWS)
 693             GMX_TEST_CFLAG(MSVC_SSE2_CFLAG "/arch:SSE2" ACCELERATION_C_FLAGS)
 694             message(WARNING "Neither SSE4.1 or SSE2 seems to be supported by your Windows compiler. Something is likely broken.")
 695         else()
 696             message(WARNING "No C SSE4.1 flag found. Consider a newer compiler, or use SSE2 for slightly lower performance")
 697         endif()
 698     endif(NOT GNU_SSE4_CFLAG AND NOT MSVC_SSE4_CFLAG)
 699
 700     GMX_TEST_CXXFLAG(GNU_SSE4_CXXFLAG "-msse4.1" ACCELERATION_CXX_FLAGS)
 701     if (NOT GNU_SSE4_CXXFLAG AND GMX_NATIVE_WINDOWS)
 702         GMX_TEST_CXXFLAG(MSVC_SSE4_CXXFLAG "/arch:SSE4.1" ACCELERATION_CXX_FLAGS)
 703     endif(NOT GNU_SSE4_CXXFLAG AND GMX_NATIVE_WINDOWS)
 704     if (NOT GNU_SSE4_CXXFLAG AND NOT MSVC_SSE4_CXXFLAG)
 705         message(WARNING "No C++ SSE4.1 flag found. Consider a newer compiler, or use SSE2 for slightly lower performance.")
 706         # Not surprising if we end up here! MSVC current does not support the SSE4.1 flag. However, it appears to accept SSE4.1
 707         # intrinsics when SSE2 support is enabled, so we try that instead.
 708         if (GMX_NATIVE_WINDOWS)
 709             GMX_TEST_CXXFLAG(MSVC_SSE2_CXXFLAG "/arch:SSE2" ACCELERATION_CXX_FLAGS)
 710         endif()
 711     endif(NOT GNU_SSE4_CXXFLAG AND NOT MSVC_SSE4_CXXFLAG)
 712
 713     # This must come after we have added the -msse4.1 flag on some platforms.
 714     check_include_file(smmintrin.h  HAVE_SMMINTRIN_H ${ACCELERATION_C_FLAGS})
 715
 716     if(NOT HAVE_SMMINTRIN_H)
 717         message(FATAL_ERROR "Cannot find smmintrin.h, which is required for SSE4.1 intrinsics support.")
 718     endif(NOT HAVE_SMMINTRIN_H)
 719
 720     if(CMAKE_C_COMPILER_ID MATCHES "Intel" AND CMAKE_C_COMPILER_VERSION VERSION_EQUAL "11.1")
 721         message(FATAL_ERROR "You are using Intel compiler version 11.1, and that compiler is known to produce incorrect results with SSE4.1 acceleration. You need to use another compiler (e.g. icc 12 or newer) or different acceleration (probably slower simulations).")
 722     endif()
 723
 724     set(GMX_CPU_ACCELERATION_X86_SSE4_1 1)
 725     # The user should not be able to set this orthogonally to the acceleration
 726     set(GMX_X86_SSE4_1 1)
 727     set(GMX_X86_SSE2   1)
 728     set(ACCELERATION_STATUS_MESSAGE
 729         "Enabling SSE4.1 Gromacs acceleration")
 730
 731 elseif(${GMX_CPU_ACCELERATION} STREQUAL "AVX_128_FMA" OR ${GMX_CPU_ACCELERATION} STREQUAL "AVX_256")
 732
 733     # Set the AVX compiler flag for both these choices!
 734
 735     GMX_TEST_CFLAG(GNU_AVX_CFLAG "-mavx" ACCELERATION_C_FLAGS)
 736     if (NOT GNU_AVX_CFLAG AND GMX_NATIVE_WINDOWS)
 737         GMX_TEST_CFLAG(MSVC_AVX_CFLAG "/arch:AVX" ACCELERATION_C_FLAGS)
 738     endif (NOT GNU_AVX_CFLAG AND GMX_NATIVE_WINDOWS)
 739     if (NOT GNU_AVX_CFLAG AND NOT MSVC_AVX_CFLAG)
 740         message(WARNING "No C AVX flag found. Consider a newer compiler, or try SSE4.1 (lower performance) giving the -DGMX_CPU_ACCELERATION=SSE4.1 to cmake.")
 741     endif (NOT GNU_AVX_CFLAG AND NOT MSVC_AVX_CFLAG)
 742
 743     GMX_TEST_CXXFLAG(GNU_AVX_CXXFLAG "-mavx" ACCELERATION_CXX_FLAGS)
 744     if (NOT GNU_AVX_CXXFLAG AND GMX_NATIVE_WINDOWS)
 745         GMX_TEST_CXXFLAG(MSVC_AVX_CXXFLAG "/arch:AVX" ACCELERATION_CXX_FLAGS)
 746     endif (NOT GNU_AVX_CXXFLAG AND GMX_NATIVE_WINDOWS)
 747     if (NOT GNU_AVX_CXXFLAG AND NOT MSVC_AVX_CXXFLAG)
 748         message(WARNING "No C++ AVX flag found. Consider a newer compiler, or try SSE4.1 (lower performance) giving the -DGMX_CPU_ACCELERATION=SSE4.1 to cmake.")
 749     endif (NOT GNU_AVX_CXXFLAG AND NOT MSVC_AVX_CXXFLAG)
 750
 751     # Set the FMA4 flags (MSVC doesn't require any)
 752     if(${GMX_CPU_ACCELERATION} STREQUAL "AVX_128_FMA" AND NOT MSVC)
 753         GMX_TEST_CFLAG(GNU_FMA_CFLAG "-mfma4" ACCELERATION_C_FLAGS)
 754         if (NOT GNU_FMA_CFLAG)
 755             message(WARNING "No C FMA4 flag found. Consider a newer compiler, or try SSE4.1 (lower performance).")
 756         endif(NOT GNU_FMA_CFLAG)
 757         GMX_TEST_CFLAG(GNU_XOP_CFLAG "-mxop" ACCELERATION_C_FLAGS)
 758         # No big deal if we do not have xop, so no point yelling warnings about it.
 759         GMX_TEST_CXXFLAG(GNU_FMA_CXXFLAG "-mfma4" ACCELERATION_CXX_FLAGS)
 760         if (NOT GNU_FMA_CXXFLAG)
 761             message(WARNING "No C++ FMA flag found. Consider a newer compiler, or try SSE4.1 (lower performance).")
 762         endif (NOT GNU_FMA_CXXFLAG)
 763         GMX_TEST_CXXFLAG(GNU_XOP_CXXFLAG "-mxop" ACCELERATION_CXX_FLAGS)
 764         # No big deal if we do not have xop, so no point yelling warnings about it.
 765     endif()
 766
 767     # Only test the header after we have tried to add the flag for AVX support
 768     check_include_file(immintrin.h  HAVE_IMMINTRIN_H ${ACCELERATION_C_FLAGS})
 769
 770     if(NOT HAVE_IMMINTRIN_H)
 771         message(FATAL_ERROR "Cannot find immintrin.h, which is required for AVX intrinsics support. Consider switching compiler.")
 772     endif(NOT HAVE_IMMINTRIN_H)
 773
 774     if(${GMX_CPU_ACCELERATION} STREQUAL "AVX_256")
 775         try_compile(TEST_AVX ${CMAKE_BINARY_DIR}
 776             "${CMAKE_SOURCE_DIR}/cmake/TestAVX.c"
 777             COMPILE_DEFINITIONS "${ACCELERATION_C_FLAGS}")
 778         if(NOT TEST_AVX)
 779             message(FATAL_ERROR "Cannot compile AVX intrinsics. Consider switching compiler.")
 780         endif()
 781     endif()
 782
 783     # GCC requires x86intrin.h for FMA support. MSVC 2010 requires intrin.h for FMA support.
 784     check_include_file(x86intrin.h HAVE_X86INTRIN_H ${ACCELERATION_C_FLAGS})
 785     check_include_file(intrin.h HAVE_INTRIN_H ${ACCELERATION_C_FLAGS})
 786
 787     # The user should not be able to set this orthogonally to the acceleration
 788     set(GMX_X86_SSE4_1 1)
 789     set(GMX_X86_SSE2   1)
 790
 791     # But just enable one of the choices internally...
 792     if(${GMX_CPU_ACCELERATION} STREQUAL "AVX_128_FMA")
 793         # We don't have the full compiler version string yet (BUILD_C_COMPILER),
 794         # so we can't distinguish vanilla and Apple clang, but catering for AMD
 795         # hackintoshes is not worth the effort.
 796         if (APPLE AND (${CMAKE_C_COMPILER_ID} STREQUAL "Clang" OR
 797                     ${CMAKE_CXX_COMPILER_ID} STREQUAL "Clang"))
 798             message(WARNING "Due to a known compiler bug, Clang up to version 3.2 (and Apple Clang up to version 4.1) produces incorrect code with AVX_128_FMA acceleration. As we can not work around this bug on OS X, you will have to select a different compiler or CPU acceleration.")
 799         endif()
 800
 801         if (GMX_USE_CLANG_C_FMA_BUG_WORKAROUND)
 802             # we assume that we have an external assembler that supports AVX
 803             message(STATUS "Clang ${CMAKE_C_COMPILER_VERSION} detected, enabling FMA bug workaround")
 804             set(EXTRA_C_FLAGS "${EXTRA_C_FLAGS} -no-integrated-as")
 805         endif()
 806         if (GMX_USE_CLANG_CXX_FMA_BUG_WORKAROUND)
 807             # we assume that we have an external assembler that supports AVX
 808             message(STATUS "Clang ${CMAKE_CXX_COMPILER_VERSION} detected, enabling FMA bug workaround")
 809             set(EXTRA_CXX_FLAGS "${EXTRA_CXX_FLAGS} -no-integrated-as")
 810         endif()
 811
 812         set(GMX_CPU_ACCELERATION_X86_AVX_128_FMA 1)
 813         set(GMX_X86_AVX_128_FMA 1)
 814         set(ACCELERATION_STATUS_MESSAGE
 815             "Enabling 128-bit AVX Gromacs acceleration (with fused-multiply add)")
 816
 817     else()
 818         # If we are not doing AVX_128, it must be AVX_256...
 819         set(GMX_CPU_ACCELERATION_X86_AVX_256 1)
 820         set(GMX_X86_AVX_256 1)
 821         set(ACCELERATION_STATUS_MESSAGE
 822             "Enabling 256-bit AVX Gromacs acceleration")
 823     endif()
 824
 825     # Unfortunately gcc-4.5.2 and gcc-4.6.0 has a bug where they use the wrong datatype for the formal
 826     # parameter of the mask for maskload/maskstore arguments. Check if this is present, since we can work around it.
 827     gmx_test_avx_gcc_maskload_bug(${ACCELERATION_C_FLAGS} GMX_X86_AVX_GCC_MASKLOAD_BUG)
 828
 829 elseif(${GMX_CPU_ACCELERATION} STREQUAL "IBM_QPX")
 830     try_compile(TEST_QPX ${CMAKE_BINARY_DIR}
 831         "${CMAKE_SOURCE_DIR}/cmake/TestQPX.c")
 832
 833     if (TEST_QPX)
 834         message(WARNING "IBM QPX acceleration was selected. This will work, but SIMD-accelerated kernels are only available for the Verlet cut-off scheme. The plain C kernels that are used for the group cut-off scheme kernels will be slow, so please consider using the Verlet cut-off scheme.")
 835         set(GMX_CPU_ACCELERATION_IBM_QPX 1)
 836     else()
 837         message(FATAL_ERROR "Cannot compile the requested IBM QPX intrinsics. If you are compiling for BlueGene/Q with the XL compilers, use 'cmake .. -DCMAKE_TOOLCHAIN_FILE=Platform/BlueGeneQ-static-XL-C' to set up the tool chain.")
 838     endif()
 839 elseif(${GMX_CPU_ACCELERATION} STREQUAL "SPARC64_HPC_ACE")
 840     set(GMX_CPU_ACCELERATION_SPARC64_HPC_ACE 1)
 841 else()
 842     gmx_invalid_option_value(GMX_CPU_ACCELERATION)
 843 endif()
 844 gmx_check_if_changed(ACCELERATION_CHANGED GMX_CPU_ACCELERATION)
 845 if (ACCELERATION_CHANGED AND DEFINED ACCELERATION_STATUS_MESSAGE)
 846     message(STATUS "${ACCELERATION_STATUS_MESSAGE}")
 847 endif()
 848
 849 # Process QM/MM Settings
 850 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 851     set(GMX_QMMM_GAUSSIAN 1)
 852 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 853     set(GMX_QMMM_MOPAC 1)
 854 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 855     set(GMX_QMMM_GAMESS 1)
 856 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 857     set(GMX_QMMM_ORCA 1)
 858 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 859     # nothing to do
 860 else()
 861     gmx_invalid_option_value(GMX_QMMM_PROGRAM)
 862 endif()
 863
 864
 865 ##################################################
 866 # Process FFT library settings
 867 ##################################################
 868 include(gmxManageFFTLibraries)
 869
 870
 871 include(gmxManageLinearAlgebraLibraries)
 872
 873 # Whether GROMACS will really try to compile support for VMD plugins
 874 set(GMX_USE_PLUGINS OFF)
 875
 876 if(GMX_LOAD_PLUGINS)
 877   if(CYGWIN OR NOT WIN32)
 878     # Native Windows does not have, nor need dlopen
 879     # Note that WIN32 is set with Cygwin, but Cygwin needs dlopen to use plug-ins
 880     include(gmxTestdlopen)
 881     gmx_test_dlopen(HAVE_DLOPEN)
 882   endif()
 883
 884   # so, should we use plug-ins?
 885   if((WIN32 AND NOT CYGWIN) OR (HAVE_DLOPEN AND BUILD_SHARED_LIBS))
 886     if(NOT VMD_QUIETLY)
 887       MESSAGE(STATUS
 888           "Found the ability to use plug-ins when building shared libaries, "
 889           "so will compile to use plug-ins (e.g. to read VMD-supported file "
 890           "formats).")
 891     endif()
 892     if(NOT GMX_VMD_PLUGIN_PATH)
 893       find_package(VMD)
 894     endif()
 895     set(GMX_USE_PLUGINS ON)
 896     list(APPEND GMX_EXTRA_LIBRARIES ${CMAKE_DL_LIBS}) # magic cross-platform pre-set variable for dlopen library
 897     set(PKG_DL_LIBS "-l${CMAKE_DL_LIBS}")
 898   else()
 899     set(PKG_DL_LIBS)
 900   endif()
 901 endif(GMX_LOAD_PLUGINS)
 902 set(VMD_QUIETLY TRUE CACHE INTERNAL "")
 903
 904 # Link real-time library for POSIX timers. The check for clock_gettime
 905 # confirms the linkability of rt.
 906 if(HAVE_TIME_H AND HAVE_UNISTD_H AND HAVE_CLOCK_GETTIME)
 907     list(APPEND GMX_EXTRA_LIBRARIES rt)
 908 endif()
 909
 910 # Math and thread libraries must often come after all others when linking...
 911 if(HAVE_LIBM)
 912     list(APPEND GMX_EXTRA_LIBRARIES m)
 913 endif(HAVE_LIBM)
 914 if (${CMAKE_SYSTEM_NAME} MATCHES "BlueGene")
 915     check_library_exists(mass_simd atan2f4 "" HAVE_MASS_SIMD)
 916     if(HAVE_MASS_SIMD)
 917         list(APPEND GMX_EXTRA_LIBRARIES mass_simd)
 918     else()
 919         message(FATAL_ERROR "Could not link to the SIMD version of the IBM MASS library. Please adjust your CMAKE_PREFIX_PATH to contain it")
 920     endif()
 921 endif()
 922
 923 if(GMX_FAHCORE)
 924   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 925       "Path to swindirect.h")
 926   include_directories(${COREWRAP_INCLUDE_DIR})
 927 endif(GMX_FAHCORE)
 928
 929 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 930 # these are set after everything else
 931 if (NOT GMX_SKIP_DEFAULT_CFLAGS)
 932     set(CMAKE_C_FLAGS "${ACCELERATION_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${CMAKE_C_FLAGS}")
 933     set(CMAKE_CXX_FLAGS "${ACCELERATION_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${GMX_CXX11_FLAGS} ${EXTRA_CXX_FLAGS} ${CMAKE_CXX_FLAGS}")
 934     set(CMAKE_EXE_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}")
 935     set(CMAKE_SHARED_LINKER_FLAGS "${MPI_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS}")
 936 else()
 937     message("Recommended flags which are not added because GMX_SKIP_DEFAULT_CFLAGS=yes:")
 938     message("CMAKE_C_FLAGS: ${ACCELERATION_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${GMXC_CFLAGS}")
 939     message("CMAKE_C_FLAGS_RELEASE: ${GMXC_CFLAGS_RELEASE}")
 940     message("CMAKE_C_FLAGS_DEBUG: ${GMXC_CFLAGS_DEBUG}")
 941     message("CMAKE_CXX_FLAGS: ${ACCELERATION_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${GMX_CXX11_FLAGS} ${EXTRA_CXX_FLAGS} ${GMXC_CXXFLAGS}")
 942     message("CMAKE_CXX_FLAGS_RELEASE: ${GMXC_CXXFLAGS_RELEASE}")
 943     message("CMAKE_CXX_FLAGS_DEBUG: ${GMXC_CXXFLAGS_DEBUG}")
 944     message("CMAKE_EXE_LINKER_FLAGS: ${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS}")
 945     message("CMAKE_SHARED_LINKER_FLAGS: ${MPI_LINKER_FLAGS}")
 946 endif()
 947
 948 if(NOT GMX_OPENMP)
 949     #Unset all OpenMP flags in case OpenMP was disabled either by the user
 950     #or because it was only partially detected (e.g. only for C but not C++ compiler)
 951     unset(OpenMP_C_FLAGS CACHE)
 952     unset(OpenMP_CXX_FLAGS CACHE)
 953 else()
 954     set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} ${OpenMP_LINKER_FLAGS})
 955     set(GMX_SHARED_LINKER_FLAGS ${GMX_SHARED_LINKER_FLAGS} ${OpenMP_SHARED_LINKER_FLAGS})
 956 endif()
 957 set(PKG_CFLAGS "${PKG_CFLAGS} ${OpenMP_C_FLAGS}")
 958
 959 ########################################################################
 960 # Specify install locations
 961 ########################################################################
 962 set(GMX_LIB_INSTALL_DIR lib CACHE STRING
 963     "Library installation directory (default: lib)")
 964 set(GMX_DATA_INSTALL_DIR gromacs CACHE STRING
 965     "Data installation directory under share/ (default: gromacs)")
 966 mark_as_advanced(GMX_LIB_INSTALL_DIR GMX_DATA_INSTALL_DIR)
 967
 968 set(LIB_INSTALL_DIR  ${GMX_INSTALL_PREFIX}${GMX_LIB_INSTALL_DIR})
 969 set(BIN_INSTALL_DIR  ${GMX_INSTALL_PREFIX}bin)
 970 set(DATA_INSTALL_DIR ${GMX_INSTALL_PREFIX}share/${GMX_DATA_INSTALL_DIR})
 971 set(MAN_INSTALL_DIR  ${GMX_INSTALL_PREFIX}share/man)
 972 set(INCL_INSTALL_DIR ${GMX_INSTALL_PREFIX}include)
 973
 974 set(GMXLIB_SEARCH_DIR share/${GMX_DATA_INSTALL_DIR}/top)
 975 set(GMXLIB_FALLBACK   ${CMAKE_INSTALL_PREFIX}/${DATA_INSTALL_DIR}/top)
 976
 977 ########################################################################
 978 # Set up binary and library suffixing
 979 ########################################################################
 980 option(
 981     GMX_DEFAULT_SUFFIX
 982     "Use default suffixes for GROMACS binaries and libs (_d for double, _mpi for MPI; rerun cmake after changing to see relevant options)"
 983     ON)
 984 gmx_dependent_cache_variable(
 985     GMX_BINARY_SUFFIX
 986     "Suffix for GROMACS binaries (default: _d for double, _mpi for MPI, _mpi_d for MPI and double)."
 987     STRING ""
 988     "NOT GMX_DEFAULT_SUFFIX")
 989 gmx_dependent_cache_variable(
 990     GMX_LIBS_SUFFIX
 991     "Suffix for GROMACS libraries (default: _d for double, _mpi for MPI, _mpi_d for MPI and double)."
 992     STRING ""
 993     "NOT GMX_DEFAULT_SUFFIX")
 994 if (GMX_DEFAULT_SUFFIX)
 995   gmx_check_if_changed(SUFFIXES_CHANGED GMX_DEFAULT_SUFFIX)
 996   set(GMX_BINARY_SUFFIX "")
 997   set(GMX_LIBS_SUFFIX "")
 998   if (GMX_LIB_MPI)
 999     set(GMX_BINARY_SUFFIX "_mpi")
1000     set(GMX_LIBS_SUFFIX "_mpi")
1001   endif()
1002   if (GMX_DOUBLE)
1003     set (GMX_BINARY_SUFFIX "${GMX_BINARY_SUFFIX}_d")
1004     set (GMX_LIBS_SUFFIX "${GMX_LIBS_SUFFIX}_d")
1005   endif(GMX_DOUBLE)
1006   if (SUFFIXES_CHANGED)
1007     message(STATUS "Using default binary suffix: \"${GMX_BINARY_SUFFIX}\"")
1008     message(STATUS "Using default library suffix: \"${GMX_LIBS_SUFFIX}\"")
1009   endif ()
1010 else(GMX_DEFAULT_SUFFIX)
1011   gmx_check_if_changed(SUFFIXES_CHANGED
1012                        GMX_DEFAULT_SUFFIX GMX_BINARY_SUFFIX GMX_LIBS_SUFFIX)
1013   if (SUFFIXES_CHANGED)
1014     message(STATUS "Using manually set binary suffix: \"${GMX_BINARY_SUFFIX}\"")
1015     message(STATUS "Using manually set library suffix: \"${GMX_LIBS_SUFFIX}\"")
1016   endif ()
1017 endif(GMX_DEFAULT_SUFFIX)
1018 if (GMX_BUILD_MDRUN_ONLY)
1019     set(GMX_LIBS_SUFFIX "_mdrun${GMX_LIBS_SUFFIX}")
1020 endif ()
1021
1022 ##################################################################
1023 # Shared library settings
1024 ##################################################################
1025 if(NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin")
1026     set(CMAKE_SKIP_BUILD_RPATH  FALSE)
1027     set(CMAKE_BUILD_WITH_INSTALL_RPATH FALSE)
1028     set(CMAKE_INSTALL_RPATH "\\\$ORIGIN/../${GMXLIB}")
1029     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
1030 else()
1031     if(CMAKE_SYSTEM_VERSION VERSION_GREATER 8.0) #rpath supported for >10.4
1032         set(CMAKE_INSTALL_NAME_DIR "@rpath")
1033         set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} "-Wl,-rpath,@executable_path/../lib")
1034     else()
1035         set(CMAKE_INSTALL_NAME_DIR "${CMAKE_INSTALL_PREFIX}/${LIB_INSTALL_DIR}")
1036     endif()
1037 endif()
1038
1039 #COPYING file: Only necessary for binary distributions.
1040 #Simpler to always install.
1041 install(FILES COPYING DESTINATION ${DATA_INSTALL_DIR} COMPONENT data)
1042
1043 if(GMX_EXTERNAL_BOOST)
1044     include_directories(${Boost_INCLUDE_DIRS})
1045 else()
1046     include_directories(${CMAKE_SOURCE_DIR}/src/external/boost)
1047     # typeid not supported for minimal internal version
1048     # (would add significant amount of code)
1049     add_definitions(-DBOOST_NO_TYPEID)
1050     # TODO: Propagate the above settings to the installed CMakeFiles.txt template
1051     # (from share/template/)
1052     set(PKG_CFLAGS "${PKG_CFLAGS} -DBOOST_NO_TYPEID -I${INCL_INSTALL_DIR}/gromacs/external/boost")
1053     if (NOT GMX_BUILD_MDRUN_ONLY)
1054         install(DIRECTORY ${CMAKE_SOURCE_DIR}/src/external/boost/boost
1055                 DESTINATION ${INCL_INSTALL_DIR}/gromacs/external/boost
1056                 COMPONENT development)
1057     endif ()
1058 endif()
1059
1060 if (GMX_BUILD_FOR_COVERAGE)
1061     # Code heavy with asserts makes conditional coverage close to useless metric,
1062     # as by design most of the false branches are impossible to trigger in
1063     # correctly functioning code.  And the benefit of testing those that could
1064     # be triggered by using an API against its specification isn't usually
1065     # worth the effort.
1066     add_definitions(-DNDEBUG -DBOOST_DISABLE_ASSERTS -DGMX_DISABLE_ASSERTS)
1067 endif ()
1068
1069 if (NOT GMX_BUILD_MDRUN_ONLY)
1070     add_subdirectory(doxygen)
1071     add_subdirectory(share)
1072     add_subdirectory(scripts)
1073 endif ()
1074 add_subdirectory(src)
1075
1076 # Issue a warning if NVIDIA GPUs were detected, but CUDA was not found.
1077 # Don't bother the user after the first configure pass.
1078 if ((CUDA_NOTFOUND_AUTO AND GMX_DETECT_GPU_AVAILABLE) AND NOT GMX_GPU_DETECTION_DONE)
1079     message(WARNING "${CUDA_NOTFOUND_MESSAGE}")
1080 endif()
1081 set(GMX_GPU_DETECTION_DONE TRUE CACHE INTERNAL "Whether GPU detection has already been done")
1082
1083 #######################
1084 ## uninstall target
1085 #######################
1086     CONFIGURE_FILE(
1087                    "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
1088                    "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
1089                    IMMEDIATE @ONLY)
1090 ###########################
1091 ADD_CUSTOM_TARGET(uninstall
1092                   "${CMAKE_COMMAND}" -P
1093                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
1094 ###########################
1095
1096 ########################################################################
1097 # Tests                                                                #
1098 ########################################################################
1099
1100 IF(BUILD_TESTING)
1101     enable_testing()
1102     #"check" target builds and runs all tests
1103     add_custom_target(check COMMAND ${CMAKE_CTEST_COMMAND} --output-on-failure)
1104     add_dependencies(check tests)
1105     # TODO: This would be better within tests/CMakeLists.txt
1106     if (NOT GMX_BUILD_MDRUN_ONLY)
1107         #gmxtests target builds all binaries required for running gmxtest
1108         add_custom_target(gmxtests DEPENDS gmx links)
1109         add_dependencies(check gmxtests)
1110         add_subdirectory(tests)
1111     endif()
1112     #TODO: Add warning if NOT REGRESSIONTEST_PATH OR NOT GMX_XML that regression/unit tests are not run.
1113 ENDIF()
1114
1115 ########################################################################
1116 # Manual                                                               #
1117 ########################################################################
1118
1119 option(GMX_BUILD_MANUAL "Whether to try to configure to build the PDF manual" OFF)
1120 mark_as_advanced(GMX_BUILD_MANUAL)
1121 if(GMX_BUILD_MANUAL)
1122     # Make sure we only do detection of manual-building dependencies
1123     # when the user opted in for that.
1124     add_subdirectory(manual)
1125 endif()