CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.8)
   2
   3 project(Gromacs)
   4 include(Dart)
   5 mark_as_advanced(DART_ROOT)
   6
   7 # PROJECT_VERSION should have the following structure:
   8 # VERSION-dev[-SUFFIX] where the VERSION should have the for: vMajor.vMinor.vPatch
   9 #
  10 # The "-dev" suffix is important to keep because it makes possible to distinguish
  11 # between a build from official release and a build from git release branch on a
  12 # machine with no git.
  13 #
  14 # NOTE: when releasing the "-dev" suffix needs to be stripped off!
  15 set(PROJECT_VERSION "4.6-dev")
  16 set(CUSTOM_VERSION_STRING ""
  17     CACHE STRING "Custom version string (if empty, use hard-coded default)")
  18 mark_as_advanced(CUSTOM_VERSION_STRING)
  19 if (CUSTOM_VERSION_STRING)
  20     set(PROJECT_VERSION ${CUSTOM_VERSION_STRING})
  21 endif (CUSTOM_VERSION_STRING)
  22 set(SOVERSION 6)
  23 # It is a bit irritating, but this has to be set separately for now!
  24 SET(CPACK_PACKAGE_VERSION_MAJOR "4")
  25 SET(CPACK_PACKAGE_VERSION_MINOR "6")
  26 #SET(CPACK_PACKAGE_VERSION_PATCH "0")
  27
  28
  29 # Cmake modules/macros are in a subdirectory to keep this file cleaner
  30 set(CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake)
  31
  32 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
  33 set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
  34 endif()
  35
  36 if(NOT CMAKE_BUILD_TYPE)
  37     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel." FORCE)
  38 endif(NOT CMAKE_BUILD_TYPE)
  39
  40 enable_language(C)
  41
  42 set(CPACK_PACKAGE_VERSION ${PROJECT_VERSION})
  43 set(CPACK_PACKAGE_VENDOR "gromacs.org")
  44 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Gromacs - a toolkit for high-performance molecular simulation")
  45 set(CPACK_SET_DESTDIR "ON")
  46 set(CPACK_INCLUDE_TOPLEVEL_DIRECTORY 0)
  47 set(CPACK_RESOURCE_FILE_WELCOME "${CMAKE_SOURCE_DIR}/admin/InstallWelcome.txt")
  48 # Its GPL/LGPL, so they do not have to agree to a license for mere usage, but some installers require this...
  49 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_SOURCE_DIR}/admin/InstallLicense.txt")
  50 set(CPACK_RESOURCE_FILE_README "${CMAKE_SOURCE_DIR}/admin/InstallInfo.txt")
  51
  52 #must come after all cpack settings!
  53 include(CPack)
  54
  55 ########################################################################
  56 # Check and warn if cache generated on a different host is being reused
  57 ########################################################################
  58 if(CMAKE_HOST_UNIX)
  59     execute_process(COMMAND hostname
  60                     OUTPUT_VARIABLE TMP_HOSTNAME
  61                     OUTPUT_STRIP_TRAILING_WHITESPACE)
  62     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}")
  63         message(WARNING "
  64             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
  65             is being reused! This could lead to inconsitencies; therefore, it is
  66             recommended to regenerate the cache!")
  67     endif()
  68     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
  69             "Hostname of the machine where the cache was generated.")
  70 endif()
  71
  72 ########################################################################
  73 # Fix stupid flags on MSVC
  74 ########################################################################
  75 SET(SHARED_LIBS_DEFAULT ON)
  76 IF(CMAKE_GENERATOR MATCHES "Visual Studio")
  77     STRING(REPLACE /MD /MT CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE})
  78     SET(CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE} CACHE STRING "" FORCE)
  79     STRING(REPLACE /MD /MT CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG})
  80     SET(CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG} CACHE STRING "" FORCE)
  81     SET(SHARED_LIBS_DEFAULT OFF)
  82 ENDIF(CMAKE_GENERATOR MATCHES "Visual Studio")
  83
  84 set(GMX_EXTRA_LIBRARIES)
  85
  86
  87
  88 ######################################################################
  89 # compiler tests
  90 # these need ot be done early (before further tests).
  91 #####################################################################
  92
  93 include(CheckCCompilerFlag)
  94 include(CheckCXXCompilerFlag)
  95
  96 include(gmxCFlags)
  97 gmx_c_flags()
  98
  99 ########################################################################
 100 # User input options                                                   #
 101 ########################################################################
 102 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" OFF)
 103 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 104 option(GMX_THREADS    "Build a parallel (thread-based) version of GROMACS (cannot be combined with MPI yet)" ON)
 105 option(GMX_SOFTWARE_INVSQRT "Use GROMACS software 1/sqrt" ON)
 106 mark_as_advanced(GMX_SOFTWARE_INVSQRT)
 107 option(GMX_POWERPC_INVSQRT "Use PowerPC hardware 1/sqrt" OFF)
 108 mark_as_advanced(GMX_POWERPC_INVSQRT)
 109 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 110 mark_as_advanced(GMX_FAHCORE)
 111 option(GMX_OPENMM "Accelerated execution on GPUs through the OpenMM library (rerun cmake after changing to see relevant options)" OFF)
 112 set(GMX_ACCELERATION "auto"
 113     CACHE STRING "Accelerated kernels. Pick one of: auto, none, SSE, BlueGene, Power6, ia64, altivec, fortran")
 114
 115 set(GMX_FFT_LIBRARY "fftw3"
 116     CACHE STRING "FFT library choices: fftw3,fftw2,mkl,fftpack[built-in]")
 117 option(GMX_DISABLE_FFTW_MEASURE
 118        "Do not optimize FFTW setups (not needed with SSE)" OFF)
 119 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 120 set(GMX_QMMM_PROGRAM "none"
 121     CACHE STRING "QM package choices: none,gaussian,mopac,gamess,orca")
 122 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 123 mark_as_advanced(GMX_BROKEN_CALLOC)
 124 option(BUILD_SHARED_LIBS "Enable shared libraries (can be problematic with MPI, Windows)" ${SHARED_LIBS_DEFAULT})
 125 option(GMX_MPI_IN_PLACE "Enable MPI_IN_PLACE for MPIs that have it defined" ON)
 126 mark_as_advanced(GMX_MPI_IN_PLACE)
 127 option(GMX_LOAD_PLUGINS "Compile with plugin support, needed to read VMD supported file formats" ON)
 128 mark_as_advanced(GMX_LOAD_PLUGINS)
 129
 130
 131 option(GMX_IA32_ASM "Add SSE assembly files for IA32" OFF)
 132 mark_as_advanced(GMX_IA32_ASM)
 133 option(GMX_X86_64_ASM "Add SSE assembly files for X86_64" OFF)
 134 mark_as_advanced(GMX_X86_64_ASM)
 135
 136 option(USE_VERSION_H "Generate development version string/information" ON)
 137 mark_as_advanced(USE_VERSION_H)
 138
 139 option(GMX_DEFAULT_SUFFIX "Use default suffixes for GROMACS binaries and libs (_d for double, _mpi for MPI; rerun cmake after changing to see relevant options)" ON)
 140
 141 if(UNIX AND NOT APPLE)
 142     option(GMX_PREFER_STATIC_LIBS "When finding libraries prefer \".a\" static archives (NOTE: this is enabled only for UNIX (excluding APPLE) platforms but it might not always work!" OFF)
 143     mark_as_advanced(GMX_PREFER_STATIC_LIBS)
 144 endif()
 145
 146 ########################################################################
 147 # Set up binary and library suffixing
 148 ########################################################################
 149 set(GMX_BINARY_SUFFIX "" CACHE STRING "Suffix for GROMACS binaries (default: _d for double, _mpi for MPI, _mpi_d for MPI and double).")
 150 set(GMX_LIBS_SUFFIX ""
 151   CACHE STRING "Suffix for GROMACS libs (default: _d for double, _mpi for MPI, _mpi_d for MPI and double).")
 152 if (GMX_DEFAULT_SUFFIX)
 153   set(GMX_BINARY_SUFFIX "")
 154   set(GMX_LIBS_SUFFIX "")
 155   if (GMX_MPI)
 156     set(GMX_BINARY_SUFFIX "_mpi")
 157     set(GMX_LIBS_SUFFIX "_mpi")
 158   endif(GMX_MPI)
 159   if (GMX_DOUBLE)
 160     set (GMX_BINARY_SUFFIX "${GMX_BINARY_SUFFIX}_d")
 161     set (GMX_LIBS_SUFFIX "${GMX_LIBS_SUFFIX}_d")
 162   endif(GMX_DOUBLE)
 163   if (GMX_OPENMM)
 164     set (GMX_BINARY_SUFFIX "-gpu")
 165     set (GMX_LIBS_SUFFIX "_gpu")
 166   endif(GMX_OPENMM)
 167   mark_as_advanced(FORCE GMX_BINARY_SUFFIX GMX_LIBS_SUFFIX)
 168   if (NOT SUFFIX_QUIETLY)
 169     message(STATUS "Using default binary suffix: \"${GMX_BINARY_SUFFIX}\"")
 170     message(STATUS "Using default library suffix: \"${GMX_LIBS_SUFFIX}\"")
 171   endif (NOT SUFFIX_QUIETLY)
 172 else(GMX_DEFAULT_SUFFIX)
 173   mark_as_advanced(CLEAR GMX_BINARY_SUFFIX GMX_LIBS_SUFFIX)
 174   if (NOT SUFFIX_QUIETLY)
 175     message(STATUS "Using manually set binary suffix: \"${GMX_BINARY_SUFFIX}\"")
 176     message(STATUS "Using manually set library suffix: \"${GMX_LIBS_SUFFIX}\"")
 177   endif (NOT SUFFIX_QUIETLY)
 178 endif(GMX_DEFAULT_SUFFIX)
 179 set(SUFFIX_QUIETLY TRUE CACHE INTERNAL "")
 180
 181 set(PKG_CFLAGS "")
 182 if(GMX_DOUBLE)
 183     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_DOUBLE")
 184 endif(GMX_DOUBLE)
 185 if(GMX_SOFTWARE_INVSQRT)
 186   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_SOFTWARE_INVSQRT")
 187 endif(GMX_SOFTWARE_INVSQRT)
 188 if(GMX_POWERPC_INVSQRT)
 189   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_POWERPC_INVSQRT")
 190 endif(GMX_POWERPC_INVSQRT)
 191
 192 ########################################################################
 193 #Process MPI settings
 194 ########################################################################
 195 include(gmxManageMPI)
 196
 197 #######################################################################
 198 # Check for options incompatible with OpenMM build                    #
 199 #######################################################################
 200 if(GMX_OPENMM)
 201     cmake_minimum_required(VERSION 2.6.4)
 202     # we'll use the built-in fft to avoid unnecessary dependencies
 203     string(TOUPPER ${GMX_FFT_LIBRARY} GMX_FFT_LIBRARY)
 204     if(NOT ${GMX_FFT_LIBRARY} STREQUAL "FFTPACK")
 205         message(STATUS "No external FFT libraries needed for the OpenMM build, switching to fftpack!")
 206         set(GMX_FFT_LIBRARY "fftpack" CACHE STRING
 207                 "No external FFT libraries needed for the OpenMM build, switching to  fftpack!" FORCE)
 208     endif()
 209     if(GMX_MPI)
 210         message(FATAL_ERROR "The OpenMM build is not compatible with MPI!")
 211     endif(GMX_MPI)
 212     if(GMX_THREADS)
 213         message(STATUS "Threads are  not compatible with OpenMM build, disabled!")
 214         set(GMX_THREADS OFF CACHE BOOL
 215                 "Threads are not compatible with OpenMM build, disabled!" FORCE)
 216     endif(GMX_THREADS)
 217     if(GMX_SOFTWARE_INVSQRT)
 218         set(GMX_SOFTWARE_INVSQRT OFF CACHE STRING
 219                 "The OpenMM build does not need GROMACS software 1/sqrt!" FORCE)
 220     endif(GMX_SOFTWARE_INVSQRT)
 221     string(TOUPPER ${GMX_ACCELERATION} GMX_ACCELERATION)
 222     if(NOT GMX_ACCELERATION STREQUAL "NONE")
 223         message(STATUS "Switching off CPU-based acceleration, the OpenMM build does not support/need any!")
 224         set(GMX_ACCELERATION "none" CACHE STRING
 225                 "Switching off CPU-based acceleration, the OpenMM build does not support/need any!" FORCE)
 226     endif()
 227     if(GMX_FAHCORE)
 228         message(FATAL_ERROR "The OpenMM build does not support FAH build!")
 229     endif(GMX_FAHCORE)
 230     if(GMX_DOUBLE)
 231         message(FATAL_ERROR  "The OpenMM-build does not support double precision calculations!")
 232     endif()
 233     # mark as advanced the unused variables
 234     mark_as_advanced(FORCE GMX_ACCELERATION GMX_MPI GMX_FFT_LIBRARY
 235         GMX_QMMM_PROGRAM GMX_THREADS GMX_DOUBLE)
 236 else(GMX_OPENMM)
 237      mark_as_advanced(CLEAR GMX_ACCELERATION GMX_MPI GMX_FFT_LIBRARY
 238         GMX_QMMM_PROGRAM GMX_THREADS GMX_DOUBLE)
 239 endif(GMX_OPENMM)
 240
 241
 242 ########################################################################
 243 # Basic system tests (standard libraries, headers, functions, types)   #
 244 ########################################################################
 245 include(CheckIncludeFiles)
 246 check_include_files(string.h     HAVE_STRING_H)
 247 check_include_files(math.h       HAVE_MATH_H)
 248 check_include_files(limits.h     HAVE_LIMITS_H)
 249 check_include_files(memory.h     HAVE_MEMORY_H)
 250 check_include_files(unistd.h     HAVE_UNISTD_H)
 251 check_include_files(direct.h     HAVE_DIRECT_H)
 252 check_include_files(pwd.h        HAVE_PWD_H)
 253 check_include_files(stdint.h     HAVE_STDINT_H)
 254 check_include_files(stdlib.h     HAVE_STDLIB_H)
 255 check_include_files(pthread.h    HAVE_PTHREAD_H)
 256 check_include_files(dirent.h     HAVE_DIRENT_H)
 257 check_include_files(inttypes.h   HAVE_INTTYPES_H)
 258 check_include_files(regex.h      HAVE_REGEX_H)
 259 check_include_files(sys/types.h  HAVE_SYS_TYPES_H)
 260 check_include_files(sys/stat.h   HAVE_SYS_STAT_H)
 261 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 262 check_include_files(rpc/rpc.h    HAVE_RPC_RPC_H)
 263 check_include_files("rpc/rpc.h;rpc/xdr.h"    HAVE_RPC_XDR_H)
 264 # SSE support
 265 check_include_files(xmmintrin.h  HAVE_XMMINTRIN_H)
 266 check_include_files(emmintrin.h  HAVE_EMMINTRIN_H)
 267 check_include_files(pmmintrin.h  HAVE_PMMINTRIN_H)
 268 check_include_files(smmintrin.h  HAVE_SMMINTRIN_H)
 269 check_include_files(io.h                 HAVE_IO_H)
 270
 271
 272 include(CheckFunctionExists)
 273 check_function_exists(strcasecmp        HAVE_STRCASECMP)
 274 check_function_exists(strdup            HAVE_STRDUP)
 275 check_function_exists(vprintf           HAVE_VPRINTF)
 276 check_function_exists(memcmp            HAVE_MEMCMP)
 277 check_function_exists(posix_memalign    HAVE_POSIX_MEMALIGN)
 278 check_function_exists(memalign          HAVE_MEMALIGN)
 279 check_function_exists(_aligned_malloc   HAVE__ALIGNED_MALLOC)
 280 check_function_exists(gettimeofday      HAVE_GETTIMEOFDAY)
 281 check_function_exists(isnan             HAVE_ISNAN)
 282 check_function_exists(_isnan            HAVE__ISNAN)
 283 check_function_exists(fsync             HAVE_FSYNC)
 284 check_function_exists(_fileno           HAVE__FILENO)
 285 check_function_exists(fileno            HAVE_FILENO)
 286 check_function_exists(_commit           HAVE__COMMIT)
 287
 288 include(CheckLibraryExists)
 289 check_library_exists(m sqrt "" HAVE_LIBM)
 290 check_library_exists(m cbrt "" HAVE_CBRT)
 291
 292
 293 include(CheckTypeSize)
 294
 295 check_type_size("bool"          SIZEOF_BOOL) # will also set HAVE_BOOL
 296 check_type_size("int"           SIZEOF_INT)
 297 check_type_size("long int"      SIZEOF_LONG_INT)
 298 check_type_size("long long int" SIZEOF_LONG_LONG_INT)
 299 check_type_size("off_t"         SIZEOF_OFF_T)
 300 check_type_size("void *"        SIZEOF_VOIDP)
 301
 302 if (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 303     set(GMX_64_BIT TRUE)
 304 else (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 305     set(GMX_64_BIT FALSE)
 306 endif (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 307
 308 # Check for some basic types that we *need*, so set these to int if they are not present
 309 check_type_size(uid_t uid_t)
 310 if(NOT uid_t)
 311   set(uid_t int)
 312 else(NOT uid_t)
 313   set(uid_t 0)
 314 endif(NOT uid_t)
 315
 316 check_type_size(gid_t gid_t)
 317 if(NOT gid_t)
 318   set(gid_t 1)
 319 else(NOT gid_t)
 320   set(gid_t 0)
 321 endif(NOT gid_t)
 322
 323 check_type_size(size_t size_t)
 324 if(NOT size_t)
 325   set(size_t int)
 326 else(NOT size_t)
 327   set(size_t 0)
 328 endif(NOT size_t)
 329
 330 check_type_size(off_t off_t)
 331 if(NOT off_t)
 332   set(off_t int)
 333 else(NOT off_t)
 334   set(off_t 0)
 335 endif(NOT off_t)
 336
 337 include(TestBigEndian)
 338 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 339
 340
 341
 342
 343 ########################################################################
 344 # Find external packages                                               #
 345 ########################################################################
 346 if(UNIX AND NOT APPLE)
 347     if(GMX_PREFER_STATIC_LIBS)
 348         SET(CMAKE_FIND_LIBRARY_SUFFIXES .a ${CMAKE_FIND_LIBRARY_SUFFIXES})
 349         if(BUILD_SHARED_LIBS)
 350             message(WARNING "Static libraries requested, the GROMACS libraries will also be build static (BUILD_SHARED_LIBS=OFF)")
 351             set(BUILD_SHARED_LIBS OFF CACHE BOOL "Enable shared libraries (can be problematic with MPI, Windows)" FORCE)
 352         endif()
 353     endif()
 354 endif()
 355
 356 option(GMX_XML "Use libxml2 to parse xml files" ON)
 357 if (GMX_XML)
 358   find_package(LibXml2)
 359   set(PKG_XML "")
 360   if(LIBXML2_FOUND)
 361     include_directories(${LIBXML2_INCLUDE_DIR})
 362     set(PKG_XML libxml-2.0)
 363     set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 364     set(HAVE_LIBXML2 1)
 365   endif(LIBXML2_FOUND)
 366 endif(GMX_XML)
 367
 368 option(GMX_GSL "Add support for gsl" OFF)
 369 if (GMX_GSL)
 370   find_package(gsl)
 371   set(PKG_GSL "")
 372   if(GSL_FOUND)
 373     include_directories(${GSL_INCLUDE_DIR})
 374     set(PKG_GSL gsl)
 375     set(HAVE_LIBGSL 1)
 376   endif(GSL_FOUND)
 377 endif (GMX_GSL)
 378
 379 option(GMX_X11 "Use X window system" OFF)
 380 if (GMX_X11)
 381         find_package(X11)
 382         # X11 includes/libraries are only set in the ngmx subdirectory!
 383         if(X11_FOUND)
 384         set(HAVE_X11 1)
 385         endif(X11_FOUND)
 386 endif(GMX_X11)
 387
 388 if(GMX_THREADS)
 389     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_THREADS")
 390     include(ThreadMPI)
 391     set(THREAD_MPI_LIB thread_mpi)
 392     set(GMX_MPI 1)
 393     string(TOUPPER ${GMX_FFT_LIBRARY} ${GMX_FFT_LIBRARY})
 394     if(${GMX_FFT_LIBRARY} STREQUAL "FFTW2")
 395         message(FATAL_ERROR "FFTW2 can't be used with threads. Try fftw3 or mkl.")
 396     endif()
 397 endif(GMX_THREADS)
 398
 399 if(GMX_OPENMM)
 400     set(CUDA_BUILD_EMULATION OFF)
 401     find_package(CUDA 3.1 REQUIRED)
 402     add_definitions(-DGMX_OPENMM)
 403     if(CMAKE_BUILD_TYPE STREQUAL "DEBUG")
 404         set(CUDA_VERBOSE_BUILD ON)
 405     endif()
 406     find_package(OpenMM)
 407 endif(GMX_OPENMM)
 408
 409 if(APPLE)
 410    find_library(ACCELERATE_FRAMEWORK Accelerate)
 411    list(APPEND GMX_EXTRA_LIBRARIES ${ACCELERATE_FRAMEWORK})
 412 endif(APPLE)
 413
 414 if(CYGWIN)
 415     set(GMX_CYGWIN 1)
 416 endif(CYGWIN)
 417
 418 # only bother with finding git and using version.h if the source is a git repo
 419 if(EXISTS "${CMAKE_SOURCE_DIR}/.git")
 420     if(USE_VERSION_H)
 421         # We need at least git v1.5.1 be able to parse git's date output. If not
 422         # found or the version is too small, we can't generate version information.
 423         find_package(Git)
 424
 425         # Find out the git version
 426         if(GIT_FOUND AND NOT GIT_VERSION)
 427           execute_process(COMMAND ${GIT_EXECUTABLE} "--version"
 428             OUTPUT_VARIABLE _exec_out
 429             OUTPUT_STRIP_TRAILING_WHITESPACE)
 430           string(REGEX REPLACE "git version (.*)" "\\1" GIT_VERSION ${_exec_out})
 431           set(GIT_VERSION ${GIT_VERSION} CACHE STRING "Git version")
 432           mark_as_advanced(GIT_VERSION)
 433         endif()
 434
 435         if(NOT GIT_FOUND OR GIT_VERSION VERSION_LESS "1.5.1")
 436           message("No compatible git version found, won't be able to generate proper development version information.")
 437           set(USE_VERSION_H OFF)
 438         endif()
 439     endif()
 440 else()
 441     set(USE_VERSION_H OFF)
 442 endif()
 443
 444 ########################################################################
 445 # Generate development version info for cache
 446 ########################################################################
 447 # set(GEN_VERSION_INFO_INTERNAL "ON")
 448 # include(gmxGenerateVersionString)
 449
 450 ########################################################################
 451 # Our own GROMACS tests
 452 ########################################################################
 453
 454 add_definitions( -DHAVE_CONFIG_H )
 455 include_directories(${CMAKE_BINARY_DIR}/src)
 456 include_directories(${CMAKE_SOURCE_DIR}/include)
 457
 458 include(gmxCheckBuildUserTime)
 459 gmx_check_build_user_time(BUILD_TIME BUILD_USER BUILD_MACHINE)
 460
 461 include(gmxTestFloatFormat)
 462 gmx_test_float_format(GMX_FLOAT_FORMAT_IEEE754
 463                       GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER
 464                       GMX_IEEE754_BIG_ENDIAN_WORD_ORDER)
 465
 466 include(gmxTestLargeFiles)
 467 gmx_test_large_files(GMX_LARGEFILES)
 468 check_function_exists(fseeko     HAVE_FSEEKO)
 469
 470 include(gmxTestSignal)
 471 gmx_test_sigusr1(HAVE_SIGUSR1)
 472
 473 include(gmxTestInline)
 474 gmx_test_inline(INLINE_KEYWORD)
 475
 476 include(gmxTestRestrict)
 477 gmx_test_inline(RESTRICT_KEYWORD)
 478
 479 include(gmxTestPipes)
 480 gmx_test_pipes(HAVE_PIPES)
 481
 482 include(gmxTestIsfinite)
 483 gmx_test_isfinite(HAVE_ISFINITE)
 484 gmx_test__isfinite(HAVE__ISFINITE)
 485 gmx_test__finite(HAVE__FINITE)
 486
 487 include(gmxTestInlineASM)
 488 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 489 gmx_test_inline_asm_msvc_x86(GMX_X86_MSVC_INLINE_ASM)
 490
 491 # turn on SSE if supported with reasonable defaults.
 492 if (${GMX_ACCELERATION} STREQUAL "auto" AND NOT GMX_OPENMM)
 493   if(CMAKE_SYSTEM_PROCESSOR MATCHES "^(i.86|x86|x64|x86_64|AMD64|amd64)" OR CYGWIN)
 494
 495     set(GMX_ACCELERATION "SSE" CACHE STRING "Accelerated kernels. Pick one of: auto, none, SSE, BlueGene, Power6, ia64, altivec, fortran" FORCE)
 496
 497     # Determine the assembler/compiler to use
 498   else()
 499     set(GMX_ACCELERATION "none" CACHE STRING "Accelerated kernels. Pick one of: auto, none, SSE, BlueGene, Power6, ia64, altivec, fortran" FORCE)
 500   endif()
 501 endif (${GMX_ACCELERATION} STREQUAL "auto" AND NOT GMX_OPENMM)
 502
 503 include(gmxTestXDR)
 504 gmx_test_xdr(GMX_SYSTEM_XDR)
 505 if(NOT GMX_SYSTEM_XDR)
 506     set(GMX_INTERNAL_XDR 1)
 507     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_INTERNAL_XDR")
 508 endif(NOT GMX_SYSTEM_XDR)
 509
 510 # Process nonbonded accelerated kernels settings
 511 string(TOUPPER ${GMX_ACCELERATION} ${GMX_ACCELERATION})
 512 if(${GMX_ACCELERATION} STREQUAL "NONE")
 513   # nothing to do
 514 elseif(${GMX_ACCELERATION} STREQUAL "SSE")
 515
 516     if (GMX_64_BIT)
 517       set(GMX_X86_64_ASM ON CACHE BOOL "Add SSE assembly files for x86_64" FORCE)
 518     else (GMX_64_BIT)
 519       set(GMX_IA32_ASM ON CACHE BOOL "Add SSE assembly files for i386" FORCE)
 520     endif (GMX_64_BIT)
 521
 522     if(CMAKE_GENERATOR MATCHES "Visual Studio")
 523       option(GMX_ASM_USEASM-NASM "Use Nasm for assembly instead of compiler (necessary on windows)" ON)
 524     else()
 525       option(GMX_ASM_USEASM-NASM "Use Nasm for assembly instead of compiler (necessary on windows)" OFF)
 526     endif()
 527         mark_as_advanced(GMX_ASM_USEASM-NASM)
 528
 529     if (NOT GMX_64_BIT)
 530         # for 32-bit compiles, we might need to turn on sse
 531         CHECK_C_COMPILER_FLAG("-msse2" XFLAGS_SSE)
 532         if (XFLAGS_SSE)
 533             set(GROMACS_C_FLAGS "-msse2 ${GROMACS_C_FLAGS}")
 534         endif (XFLAGS_SSE)
 535         CHECK_CXX_COMPILER_FLAG("-msse2" XXFLAGS_SSE)
 536         if (XXFLAGS_SSE)
 537             set(GROMACS_CXX_FLAGS "-msse2 ${GROMACS_CXX_FLAGS}")
 538         endif (XXFLAGS_SSE)
 539     endif (NOT GMX_64_BIT)
 540
 541     if(GMX_IA32_ASM)
 542       if(GMX_DOUBLE)
 543         set(GMX_IA32_SSE2 1)
 544       else()
 545        set(GMX_IA32_SSE 1)
 546       endif()
 547     elseif(GMX_X86_64_ASM)
 548       if(GMX_DOUBLE)
 549        set(GMX_X86_64_SSE2 1)
 550       else()
 551         set(GMX_X86_64_SSE 1)
 552       endif()
 553     endif()
 554
 555 #    if(HAVE_PMMINTRIN_H)
 556 #        set(GMX_SSE3 1)
 557 #    endif(HAVE_PMMINTRIN_H)
 558 #    if(HAVE_SMMINTRIN_H)
 559 #        set(GMX_SSE4_1 1)
 560 #    endif(HAVE_SMMINTRIN_H)
 561
 562 elseif(${GMX_ACCELERATION} STREQUAL "FORTRAN")
 563     set(GMX_FORTRAN 1)
 564     #these are switch on by default sometimes
 565     set(GMX_IA32_ASM 0)
 566     set(GMX_GMX_X86_64_ASM 0)
 567 elseif(${GMX_ACCELERATION} STREQUAL "BLUEGENE")
 568 # GMX_ACCELERATION=BlueGene should be set in the Toolchain-BlueGene?-???.cmake file
 569     message(STATUS "Configuring for BlueGene")
 570     set(GMX_BLUEGENE 1)
 571     if (${CMAKE_SYSTEM_NAME} STREQUAL "BlueGeneL")
 572         set(SHARED_LIBS_DEFAULT OFF CACHE BOOL "Shared libraries not compatible with BlueGene/L, disabled!" FORCE)
 573         set(BUILD_SHARED_LIBS OFF CACHE BOOL "Shared libraries not compatible with BlueGene/L, disabled!" FORCE)
 574     endif (${CMAKE_SYSTEM_NAME} STREQUAL "BlueGeneL")
 575     set(GMX_SOFTWARE_INVSQRT OFF CACHE BOOL "Do not use software reciprocal square root on BlueGene" FORCE)
 576     set(GMX_POWERPC_INVSQRT ON CACHE BOOL "Use hardware reciprocal square root on BlueGene" FORCE)
 577     set(GMX_X11 OFF CACHE BOOL "X11 not compatible with BlueGene, disabled!" FORCE)
 578     set(GMX_THREADS OFF CACHE BOOL "Threads not compatible with BlueGene, disabled!" FORCE)
 579     set(GMX_MPI ON CACHE BOOL "Use MPI on BlueGene" FORCE)
 580 elseif(${GMX_ACCELERATION} STREQUAL "POWER6")
 581     set(GMX_POWER6 1)
 582     set(GMX_SOFTWARE_INVSQRT OFF CACHE BOOL "Do not use software reciprocal square root on Power6" FORCE)
 583     set(GMX_POWERPC_INVSQRT ON CACHE BOOL "Use hardware reciprocal square root on Power6" FORCE)
 584 elseif(${GMX_ACCELERATION} STREQUAL "IA64")
 585     set(GMX_IA64_ASM 1)
 586     set(DISABLE_WATERWATER_NLIST 1)
 587     set(DISABLE_WATER_NLIST 1)
 588 elseif(${GMX_ACCELERATION} STREQUAL "ALTIVEC")
 589     check_include_files(altivec.h HAVE_ALTIVEC_H)
 590     if(HAVE_ALTIVEC_H)
 591         set(GMX_PPC_ALTIVEC 1)
 592     endif(HAVE_ALTIVEC_H)
 593 else(${GMX_ACCELERATION} STREQUAL "NONE")
 594     MESSAGE(FATAL_ERROR "Unrecognized option for accelerated kernels: ${GMX_ACCELERATION}. Pick one of auto, none, SSE, Fortran, BlueGene, Power6, ia64, altivec")
 595 endif(${GMX_ACCELERATION} STREQUAL "NONE")
 596
 597 if(GMX_FORTRAN OR GMX_POWER6)
 598     if (GMX_THREADS)
 599         message(FATAL_ERROR "FORTRAN/POWER6 is incompatible with threads and only provides a speed-up on certain IBM compilers. Disable FORTRAN (or threads if you really want to use FORTRAN kernels).")
 600     endif(GMX_THREADS)
 601     enable_language(Fortran)
 602     include(FortranCInterface)
 603     discover_fortran_mangling(prefix isupper suffix extra_under_score found)
 604     if(extra_under_score)
 605         set(extrasuffix "_")
 606     endif(extra_under_score)
 607     if(prefix)
 608       set(prefix "${prefix} ##")
 609     endif(prefix)
 610     if(suffix)
 611       set(suffix "## ${suffix}")
 612       if(extrasuffix)
 613         set(extrasuffix "${suffix}${extrasuffix}")
 614       endif(extrasuffix)
 615     else(suffix)
 616       if(extrasuffix)
 617         # Don't know if this is needed, but it can't hurt
 618         set(extrasuffix "## ${extrasuffix}")
 619       endif(extrasuffix)
 620     endif(suffix)
 621
 622     if(isupper)
 623         set(F77_FUNCDEF   "${prefix} NAME ${suffix}")
 624         set(F77_FUNCDEF_  "${prefix} NAME ${extrasuffix}")
 625     else(isupper)
 626         set(F77_FUNCDEF   "${prefix} name ${suffix}")
 627         set(F77_FUNCDEF_  "${prefix} name ${extrasuffix}")
 628     endif(isupper)
 629 else(GMX_FORTRAN OR GMX_POWER6)
 630         set(F77_FUNCDEF   "name ## _")
 631         set(F77_FUNCDEF_  "name ## _")
 632 endif(GMX_FORTRAN OR GMX_POWER6)
 633
 634 # Process QM/MM Settings
 635 string(TOUPPER ${GMX_QMMM_PROGRAM} ${GMX_QMMM_PROGRAM})
 636 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 637     set(GMX_QMMM_GAUSSIAN 1)
 638 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 639     set(GMX_QMMM_MOPAC 1)
 640 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 641     set(GMX_QMMM_GAMESS 1)
 642 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 643     set(GMX_QMMM_ORCA 1)
 644 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 645     # nothing to do
 646 else(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 647     MESSAGE(FATAL_ERROR "Invalid QM/MM program option: ${GMX_QMMM_PROGRAM}. Choose one of: Gaussian, Mopac, Gamess, Orca, None")
 648 endif(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 649
 650 # Process FFT library settings - if not OpenMM build
 651 string(TOUPPER ${GMX_FFT_LIBRARY} ${GMX_FFT_LIBRARY})
 652 set(PKG_FFT "")
 653 set(PKG_FFT_LIBS "")
 654 if(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 655 #    MESSAGE(STATUS "Using external FFT library - fftw3")
 656     if(GMX_DOUBLE)
 657         find_package(FFTW3 REQUIRED)
 658                 include_directories(${FFTW3_INCLUDE_DIR})
 659         set(FFT_LIBRARIES ${FFTW3_LIBRARIES})
 660         set(PKG_FFT "fftw3")
 661     else(GMX_DOUBLE)
 662         find_package(FFTW3F REQUIRED)
 663         include_directories(${FFTW3F_INCLUDE_DIR})
 664         set(FFT_LIBRARIES ${FFTW3F_LIBRARIES})
 665         set(PKG_FFT "fftw3f")
 666     endif(GMX_DOUBLE)
 667
 668     if(NOT FFTW3_FOUND AND NOT FFTW3F_FOUND)
 669         MESSAGE(FATAL_ERROR "Cannot find fftw3 (with correct precision). Fix it, choose another FFT library, or use the Gromacs built-in fftpack (slower)!")
 670     endif(NOT FFTW3_FOUND AND NOT FFTW3F_FOUND)
 671
 672     set(GMX_FFT_FFTW3 1)
 673
 674 elseif(${GMX_FFT_LIBRARY} STREQUAL "FFTW2")
 675 #    MESSAGE(STATUS "Using external FFT library - fftw2")
 676     if(GMX_DOUBLE)
 677         find_package(FFTW2 REQUIRED)
 678     else(GMX_DOUBLE)
 679         find_package(FFTW2F REQUIRED)
 680     endif(GMX_DOUBLE)
 681
 682     if(NOT FFTW2_FOUND)
 683            MESSAGE(FATAL_ERROR "Cannot find fftw2 (with correct precision). Fix it, choose another FFT library, or use the Gromacs built-in fftpack (slower)!")
 684     endif(NOT FFTW2_FOUND)
 685     include_directories(${FFTW2_INCLUDE_DIR})
 686     set(FFT_LIBRARIES ${FFTW2_LIBRARIES})
 687     set(PKG_FFT_LIBS ${FFTW2_LIBRARIES})
 688
 689     if("${FFTW2_LIBRARIES}" MATCHES "dfftw")
 690         set(FFTW2_NAME_DFFTW 1)
 691     elseif("${FFTW2_LIBRARIES}" MATCHES "sfftw")
 692         set(FFTW2_NAME_SFFTW 1)
 693     else("${FFTW2_LIBRARIES}" MATCHES "dfftw")
 694         set(FFTW2_NAME_FFTW 1)
 695     endif("${FFTW2_LIBRARIES}" MATCHES "dfftw")
 696
 697     set(GMX_FFT_FFTW2 1)
 698 elseif(${GMX_FFT_LIBRARY} STREQUAL "MKL")
 699 #    MESSAGE(STATUS "Using external FFT library - Intel MKL")
 700     find_package(MKL REQUIRED)
 701     include_directories(${MKL_INCLUDE_DIR})
 702     set(FFT_LIBRARIES ${MKL_LIBRARIES})
 703     set(PKG_FFT_LIBS ${MKL_LIBRARIES})
 704
 705     set(GMX_FFT_MKL 1)
 706     set(HAVE_MKL 1)
 707
 708 #elseif(${GMX_FFT_LIBRARY} STREQUAL "ACML")
 709 #    MESSAGE(STATUS "Using external FFT library - AMD core math library")
 710 #    set(GMX_FFT_ACML 1)
 711 elseif(${GMX_FFT_LIBRARY} STREQUAL "FFTPACK")
 712     MESSAGE(STATUS "Using internal FFT library - fftpack")
 713     set(GMX_FFT_FFTPACK 1)
 714 else(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 715     MESSAGE(FATAL_ERROR "Invalid FFT library setting: ${GMX_FFT_LIBRARY}. Choose one of: fftw3, fftw2, mkl, acml, fftpack")
 716 endif(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 717
 718 # MKL has BLAS/LAPACK routines
 719 if(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 720   set(GMX_EXTERNAL_BLAS TRUE CACHE BOOL "Use external BLAS instead of built-in")
 721   set(GMX_EXTERNAL_LAPACK TRUE CACHE BOOL "Use external LAPACK instead of built-in")
 722 else(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 723   set(GMX_EXTERNAL_BLAS FALSE CACHE BOOL "Use external BLAS instead of built-in")
 724   set(GMX_EXTERNAL_LAPACK FALSE CACHE BOOL "Use external LAPACK instead of built-in")
 725   if(GMX_EXTERNAL_BLAS)
 726     #FindBLAS needs Fortran
 727     enable_language(Fortran)
 728     if (GMX_BLAS_USER)
 729         list(APPEND GMX_EXTRA_LIBRARIES ${GMX_BLAS_USER})
 730     else(GMX_BLAS_USER)
 731         find_package(BLAS REQUIRED)
 732         list(APPEND GMX_EXTRA_LIBRARIES ${BLAS_LIBRARIES})
 733     endif(GMX_BLAS_USER)
 734   endif(GMX_EXTERNAL_BLAS)
 735   if(GMX_EXTERNAL_LAPACK)
 736     #FindLAPACK needs Fortran
 737     enable_language(Fortran)
 738         if (GMX_LAPACK_USER)
 739         list(APPEND GMX_EXTRA_LIBRARIES ${GMX_LAPACK_USER})
 740         else(GMX_LAPACK_USER)
 741         find_package(LAPACK REQUIRED)
 742         list(APPEND GMX_EXTRA_LIBRARIES ${LAPACK_LIBRARIES})
 743     endif(GMX_LAPACK_USER)
 744   endif(GMX_EXTERNAL_LAPACK)
 745 endif(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 746 mark_as_advanced(GMX_EXTERNAL_LAPACK)
 747 mark_as_advanced(GMX_EXTERNAL_BLAS)
 748
 749 set(GMX_USE_PLUGINS OFF CACHE INTERNAL "Whether GROMACS will really try to compile support for VMD plugins")
 750 set(GMX_VMD_PLUGIN_PATH)
 751 mark_as_advanced(GMX_VMD_PLUGIN_PATH)
 752
 753 if(GMX_LOAD_PLUGINS)
 754   if(CYGWIN OR NOT WIN32)
 755     # Native Windows does not have, nor need dlopen
 756     # Note that WIN32 is set with Cygwin, but Cygwin needs dlopen to use plug-ins
 757     include(gmxTestdlopen)
 758     gmx_test_dlopen(HAVE_DLOPEN)
 759   endif()
 760
 761   find_package(VMD)
 762
 763   # Test for unsuitable versions of VMD
 764
 765   if(VMD_FOUND AND NOT GMX_VMD_PLUGIN_PATH)
 766     message(STATUS "Checking for suitable VMD version")
 767     exec_program(${VMD_EXECUTABLE}
 768       ARGS --help
 769       OUTPUT_VARIABLE VMD_HELP
 770       RETURN_VALUE VMD_EXEC_RETURN)
 771
 772     if(VMD_EXEC_RETURN EQUAL 0)
 773       # This is the accepted idiom for subexpression matching, unfortunately
 774       string(REGEX REPLACE ".*VMD for .*, version ([0-9]+\\.[0-9]*\\.?[0-9]*).*" "\\1" VMD_VERSION ${VMD_HELP})
 775       string(REGEX REPLACE ".*VMD for (.*), version .*" "\\1" VMD_ARCH ${VMD_HELP})
 776
 777       if(VMD_VERSION VERSION_LESS "1.8")
 778         MESSAGE(WARNING "Found VMD version ${VMD_VERSION}, but GROMACS needs at least 1.8")
 779         unset(VMD_EXECUTABLE)
 780         set(VMD_FOUND FALSE)
 781       else()
 782         message(STATUS "VMD version ${VMD_VERSION} is suitable")
 783         if(DEFINED ENV{VMDDIR})
 784           # This permits GROMACS to avoid hard-coding a fall-back
 785           # path that it can tell right now would be useless.
 786           set(GMX_VMD_PLUGIN_PATH "$ENV{VMDDIR}/plugins/${VMD_ARCH}/molfile" CACHE PATH "Path to VMD plugins for molfile I/O")
 787         else()
 788           set(GMX_VMD_PLUGIN_PATH "/usr/local/lib/vmd/plugins/*/molfile" CACHE PATH "Path to VMD plugins for molfile I/O")
 789         endif()
 790       endif()
 791
 792       # clean up
 793       unset(VMD_HELP)
 794       unset(VMD_VERSION)
 795       unset(VMD_ARCH)
 796     endif()
 797   endif()
 798
 799   # so, should we use plug-ins?
 800   if((WIN32 AND NOT CYGWIN) OR (HAVE_DLOPEN AND BUILD_SHARED_LIBS))
 801     if (NOT VMD_QUIETLY)
 802       MESSAGE(STATUS "Found the ability to use plug-ins when building shared libaries, so will compile to use plug-ins (e.g. to read VMD-supported file formats).")
 803     endif(NOT VMD_QUIETLY)
 804     set(GMX_USE_PLUGINS ON)
 805     list(APPEND GMX_EXTRA_LIBRARIES ${CMAKE_DL_LIBS}) # magic cross-platform pre-set variable for dlopen library
 806     set(PKG_DL_LIBS "-l${CMAKE_DL_LIBS}")
 807   else()
 808     set(PKG_DL_LIBS)
 809   endif()
 810 endif(GMX_LOAD_PLUGINS)
 811 set(VMD_QUIETLY TRUE CACHE INTERNAL "")
 812
 813 # Math and thread libraries must often come after all others when linking...
 814 if(HAVE_LIBM)
 815     list(APPEND GMX_EXTRA_LIBRARIES m)
 816 endif(HAVE_LIBM)
 817
 818 if(GMX_FAHCORE)
 819   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 820       "Path to swindirect.h")
 821   include_directories(${COREWRAP_INCLUDE_DIR})
 822 endif(GMX_FAHCORE)
 823
 824 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 825 # these are set after everything else
 826 if (NOT DEFINED GROMACS_C_FLAGS_SET)
 827     set(GROMACS_C_FLAGS_SET true CACHE INTERNAL "Whether to reset the C flags"
 828         FORCE)
 829     set(CMAKE_C_FLAGS "${GROMACS_C_FLAGS} ${CMAKE_C_FLAGS}" CACHE STRING
 830         "Flags used by the compiler during all build types" FORCE)
 831     set(CMAKE_CXX_FLAGS "${GROMACS_CXX_FLAGS} ${CMAKE_CXX_FLAGS}" CACHE STRING
 832         "Flags used by the compiler during all build types" FORCE)
 833     set(CMAKE_EXE_LINKER_FLAGS
 834         "${GROMACS_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}"
 835         CACHE STRING "Linker flags" FORCE)
 836 endif (NOT DEFINED GROMACS_C_FLAGS_SET)
 837
 838 ########################################################################
 839 # Specify install locations and which subdirectories to process        #
 840 ########################################################################
 841 if ( DEFINED GMXLIB )
 842     set(LIB_INSTALL_DIR "${CMAKE_INSTALL_PREFIX}/${GMXLIB}")
 843 else()
 844     set(LIB_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/lib)
 845 endif()
 846 set(BIN_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/bin)
 847 set(DATA_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/gromacs)
 848 set(MAN_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/share/man)
 849 set(INCL_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/include)
 850
 851 set(GMXLIBDIR        ${DATA_INSTALL_DIR}/top)
 852
 853 ##################################################################
 854 # Shared library settings - Darwin uses INSTALL_NAME_DIR instead!
 855 ##################################################################
 856 if(NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin")
 857     set(CMAKE_SKIP_BUILD_RPATH  FALSE)
 858     set(CMAKE_BUILD_WITH_INSTALL_RPATH FALSE)
 859     set(CMAKE_INSTALL_RPATH "${LIB_INSTALL_DIR}")
 860     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 861 endif()
 862
 863 add_subdirectory(share)
 864 add_subdirectory(include)
 865 add_subdirectory(man)
 866 add_subdirectory(src)
 867 add_subdirectory(scripts)
 868
 869 #######################
 870 ## uninstall target
 871 #######################
 872     CONFIGURE_FILE(
 873                    "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 874                    "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
 875                    IMMEDIATE @ONLY)
 876 ###########################
 877 ADD_CUSTOM_TARGET(uninstall
 878                   "${CMAKE_COMMAND}" -P
 879                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
 880 ###########################
 881
 882
 883 ########################################################################
 884 # Tests                                                                #
 885 ########################################################################
 886
 887 include(CTest)
 888 mark_as_advanced(BUILD_TESTING)
 889 IF(BUILD_TESTING)
 890         enable_testing()
 891         add_subdirectory(tests)
 892 ENDIF()
 893