Merge "[tools] g_sans - add trajectory avereging"
[alexxy/gromacs.git] / CMakeLists.txt
1 cmake_minimum_required(VERSION 2.8)
2 # Keep CMake suitably quiet on Cygwin
3 set(CMAKE_LEGACY_CYGWIN_WIN32 0) # Remove when CMake >= 2.8.4 is required
4
5 # override bugs on OS X where Cmake picks gcc (GNU) for C instead of system default cc (Clang).
6 if(APPLE)
7     set(CMAKE_C_COMPILER_INIT "cc")
8 endif(APPLE)
9
10 project(Gromacs)
11 include(Dart)
12 mark_as_advanced(DART_ROOT)
13
14 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
15 set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
16 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
17
18 # PROJECT_VERSION should have the following structure: 
19 # VERSION-dev[-SUFFIX] where the VERSION should have the for: vMajor.vMinor.vPatch
20 #
21 # The "-dev" suffix is important to keep because it makes possible to distinguish 
22 # between a build from official release and a build from git release branch on a 
23 # machine with no git. 
24 #
25 # NOTE: when releasing the "-dev" suffix needs to be stripped off!
26 set(PROJECT_VERSION "5.0-dev")
27 set(CUSTOM_VERSION_STRING ""
28     CACHE STRING "Custom version string (if empty, use hard-coded default)")
29 mark_as_advanced(CUSTOM_VERSION_STRING)
30 if (CUSTOM_VERSION_STRING)
31     set(PROJECT_VERSION ${CUSTOM_VERSION_STRING})
32 endif (CUSTOM_VERSION_STRING)
33 set(SOVERSION 6)
34 # It is a bit irritating, but this has to be set separately for now!
35 SET(CPACK_PACKAGE_VERSION_MAJOR "5")
36 SET(CPACK_PACKAGE_VERSION_MINOR "0")
37 #SET(CPACK_PACKAGE_VERSION_PATCH "0")
38
39
40 # Cmake modules/macros are in a subdirectory to keep this file cleaner
41 set(CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake)
42
43 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT AND UNIX)
44 set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
45 endif()
46
47 if (GMX_USE_RELATIVE_INSTALL_PATH)
48     set(GMX_INSTALL_PREFIX "" CACHE STRING "Prefix gets appended to CMAKE_INSTALL_PREFIX. For cpack it sets the root folder of the archive.")
49     mark_as_advanced(GMX_INSTALL_PREFIX)
50 else()
51     set(GMX_INSTALL_PREFIX "${CMAKE_INSTALL_PREFIX}/")
52 endif()
53
54 if(NOT CMAKE_BUILD_TYPE)
55     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel." FORCE)
56 endif(NOT CMAKE_BUILD_TYPE)
57
58 enable_language(C)
59 enable_language(CXX)
60
61 set(GMX_USE_RELATIVE_INSTALL_PATH OFF CACHE STRING "Use relative paths not absolute paths for cmake install. Has only an effect on cpack.")
62 mark_as_advanced(GMX_USE_RELATIVE_INSTALL_PATH)
63
64 set(CPACK_PACKAGE_VERSION ${PROJECT_VERSION})
65 set(CPACK_PACKAGE_VENDOR "gromacs.org")
66 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Gromacs - a toolkit for high-performance molecular simulation")
67 if (NOT GMX_USE_RELATIVE_INSTALL_PATH)
68     set(CPACK_SET_DESTDIR "ON")
69 endif()
70 set(CPACK_RESOURCE_FILE_WELCOME "${CMAKE_SOURCE_DIR}/admin/InstallWelcome.txt")
71 # Its GPL/LGPL, so they do not have to agree to a license for mere usage, but some installers require this...
72 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_SOURCE_DIR}/admin/InstallLicense.txt")
73 set(CPACK_RESOURCE_FILE_README "${CMAKE_SOURCE_DIR}/admin/InstallInfo.txt")
74 set(CPACK_SOURCE_IGNORE_FILES ".isreposource;.git;.gitignore")
75 set(CPACK_PROJECT_CONFIG_FILE "${CMAKE_SOURCE_DIR}/CPackInit.cmake")
76 SET(CPACK_SOURCE_INSTALLED_DIRECTORIES "${CMAKE_SOURCE_DIR};/;${CMAKE_BINARY_DIR}/man;man")
77
78 #must come after all cpack settings!
79 include(CPack)
80
81 ########################################################################
82 # Check and warn if cache generated on a different host is being reused
83 ########################################################################
84 if(CMAKE_HOST_UNIX)
85     execute_process(COMMAND hostname
86                     OUTPUT_VARIABLE TMP_HOSTNAME
87                     OUTPUT_STRIP_TRAILING_WHITESPACE)
88     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}")
89         message(WARNING "
90             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
91             is being reused! This could lead to inconsitencies; therefore, it is
92             recommended to regenerate the cache!")
93     endif()
94     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
95             "Hostname of the machine where the cache was generated.")
96 endif()
97
98 ########################################################################
99 # Fix stupid flags on Windows
100 ########################################################################
101 SET(SHARED_LIBS_DEFAULT ON) 
102 IF( WIN32 AND NOT CYGWIN)
103   option(GMX_PREFER_STATIC_LIBS "When finding libraries prefer static system libraries (MT instead of MD)!" ON)
104   mark_as_advanced(GMX_PREFER_STATIC_LIBS)
105   SET(SHARED_LIBS_DEFAULT OFF)  #is currently not working on Windows
106   # This makes windows.h not declare min/max as macros that would break
107   # C++ code using std::min/std::max.
108   add_definitions(-DNOMINMAX)
109
110   IF (GMX_PREFER_STATIC_LIBS)
111     #Only setting Debug and Release flags. Others configurations current not used.
112     STRING(REPLACE /MD /MT CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE})
113     SET(CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE} CACHE STRING "" FORCE)
114     STRING(REPLACE /MD /MT CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG})
115     SET(CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG} CACHE STRING "" FORCE)
116     STRING(REPLACE /MD /MT CMAKE_CXX_FLAGS_RELEASE ${CMAKE_CXX_FLAGS_RELEASE})
117     SET(CMAKE_CXX_FLAGS_RELEASE ${CMAKE_CXX_FLAGS_RELEASE} CACHE STRING "" FORCE)
118     STRING(REPLACE /MD /MT CMAKE_CXX_FLAGS_DEBUG ${CMAKE_CXX_FLAGS_DEBUG})
119     SET(CMAKE_CXX_FLAGS_DEBUG ${CMAKE_CXX_FLAGS_DEBUG} CACHE STRING "" FORCE)
120   ENDIF()
121
122   #Workaround for cmake bug 13174. Replace deprecated options.
123   IF( CMAKE_C_COMPILER_ID MATCHES "Intel" )
124     STRING(REPLACE /GZ /RTC1 CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG})
125     SET(CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG} CACHE STRING "" FORCE)
126   ENDIF()
127   IF( CMAKE_CXX_COMPILER_ID MATCHES "Intel" )
128     STRING(REPLACE /GZ /RTC1 CMAKE_CXX_FLAGS_DEBUG ${CMAKE_CXX_FLAGS_DEBUG})
129     STRING(REPLACE /GX /EHsc CMAKE_CXX_FLAGS_DEBUG ${CMAKE_CXX_FLAGS_DEBUG})
130     SET(CMAKE_CXX_FLAGS_DEBUG ${CMAKE_CXX_FLAGS_DEBUG} CACHE STRING "" FORCE)
131
132     STRING(REPLACE /GX /EHsc CMAKE_CXX_FLAGS_RELEASE ${CMAKE_CXX_FLAGS_RELEASE})
133     SET(CMAKE_CXX_FLAGS_RELEASE ${CMAKE_CXX_FLAGS_RELEASE} CACHE STRING "" FORCE)
134   ENDIF()
135 ENDIF()
136
137 ########################################################################
138 # User input options                                                   #
139 ########################################################################
140 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" OFF)
141 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
142 option(GMX_THREAD_MPI  "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" ON)
143 option(GMX_SOFTWARE_INVSQRT "Use GROMACS software 1/sqrt" ON)
144 mark_as_advanced(GMX_SOFTWARE_INVSQRT)
145 option(GMX_POWERPC_INVSQRT "Use PowerPC hardware 1/sqrt" OFF)
146 mark_as_advanced(GMX_POWERPC_INVSQRT)
147 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
148 mark_as_advanced(GMX_FAHCORE)
149 option(GMX_OPENMM "Accelerated execution on GPUs through the OpenMM library (rerun cmake after changing to see relevant options)" OFF)
150
151 include(gmxDetectAcceleration)
152 if(NOT DEFINED GMX_ACCELERATION)
153     if(CMAKE_CROSSCOMPILING)
154         set(GMX_SUGGESTED_ACCELERATION "None")
155     else(CMAKE_CROSSCOMPILING)
156         gmx_detect_acceleration(GMX_SUGGESTED_ACCELERATION)
157     endif(CMAKE_CROSSCOMPILING)
158 endif(NOT DEFINED GMX_ACCELERATION)
159
160 set(GMX_ACCELERATION "@GMX_SUGGESTED_ACCELERATION@"
161     CACHE STRING "Accelerated kernels. Pick one of: None, SSE2, SSE4.1, AVX_128_FMA, AVX_256, BlueGene, Power6, Fortran")
162
163 set(GMX_FFT_LIBRARY "fftw3" 
164     CACHE STRING "FFT library choices: fftw3,mkl,fftpack[built-in]")
165 option(GMX_DISABLE_FFTW_MEASURE 
166        "Do not optimize FFTW setups (not needed with SSE)" OFF)
167 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
168 set(GMX_QMMM_PROGRAM "none" 
169     CACHE STRING "QM package choices: none,gaussian,mopac,gamess,orca")
170 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
171 mark_as_advanced(GMX_BROKEN_CALLOC)
172 option(GMX_MPI_IN_PLACE "Enable MPI_IN_PLACE for MPIs that have it defined" ON)
173 mark_as_advanced(GMX_MPI_IN_PLACE)
174 option(GMX_LOAD_PLUGINS "Compile with plugin support, needed to read VMD supported file formats" ON)
175 mark_as_advanced(GMX_LOAD_PLUGINS)
176
177 option(GMX_OPENMP "Enable OpenMP-based mutithreading. " ON)
178
179 option(USE_VERSION_H "Generate development version string/information" ON)
180 mark_as_advanced(USE_VERSION_H)
181
182 option(GMX_DEFAULT_SUFFIX "Use default suffixes for GROMACS binaries and libs (_d for double, _mpi for MPI; rerun cmake after changing to see relevant options)" ON)
183
184 if(UNIX AND NOT APPLE)
185     option(GMX_PREFER_STATIC_LIBS "When finding libraries prefer \".a\" static archives (NOTE: this is enabled only for UNIX (excluding APPLE) platforms but it might not always work!" OFF)
186     mark_as_advanced(GMX_PREFER_STATIC_LIBS)
187 endif()
188
189
190 ######################################################################
191 # compiler tests
192 # these need ot be done early (before further tests).
193 #####################################################################
194
195 # cmake/Check{C,CXX}CompilerFlag.cmake are lifted from CMake git next
196 # branch (proposed for v2.8.9) to be able to detect invalid options
197 # with the Intel Compilers.
198 # Remove these files from the source tree when a CMake version that
199 # includes the features in question becomes required.
200 include(CheckCCompilerFlag)
201 include(CheckCXXCompilerFlag)
202
203 # OpenMP check must come before other CFLAGS!
204 if(GMX_OPENMP)
205     find_package(OpenMP)
206     if(OPENMP_FOUND)
207         #- only set linker flag, if user didn't set them manual
208         #- cmake on windows doesn't support linker flags passed to target_link_libraries
209         #  (cmake treats /openmp as \openmp library file) and no openmp linker flags are needed
210         if(NOT (WIN32 AND NOT CYGWIN))
211             if(CMAKE_COMPILER_IS_GNUCC AND GMX_PREFER_STATIC_OPENMP)
212                 set(OpenMP_LINKER_FLAGS "-Wl,-static -lgomp -lrt -Wl,-Bdynamic -lpthread")
213                 set(OpenMP_SHARED_LINKER_FLAGS "")
214             else()
215                 if(NOT DEFINED OpenMP_LINKER_FLAGS)
216                     set(OpenMP_LINKER_FLAGS "${OpenMP_C_FLAGS}")
217                 endif()
218                 if(NOT DEFINED OpenMP_SHARED_LINKER_FLAGS)
219                     set(OpenMP_SHARED_LINKER_FLAGS "${OpenMP_C_FLAGS}")
220                 endif()
221             endif()
222         endif()
223     else(OPENMP_FOUND)
224         message(WARNING
225                 "Compiler not supporting OpenMP. This might hurt your performance a lot, "
226                 "in particular with GPUs. Try using a different compiler (Intel is good on x86) "
227                 "if you can - for now we are proceeding by turning off OpenMP.")
228         set(GMX_OPENMP OFF CACHE STRING "Compiler does not support OpenMP." FORCE)
229     endif(OPENMP_FOUND)
230 endif()
231
232
233 include(gmxCFlags)
234 gmx_c_flags()
235
236 ########################################################################
237 # Set up binary and library suffixing 
238 ########################################################################
239 set(GMX_BINARY_SUFFIX "" CACHE STRING "Suffix for GROMACS binaries (default: _d for double, _mpi for MPI, _mpi_d for MPI and double).")
240 set(GMX_LIBS_SUFFIX "" 
241   CACHE STRING "Suffix for GROMACS libs (default: _d for double, _mpi for MPI, _mpi_d for MPI and double).")
242 if (GMX_DEFAULT_SUFFIX)
243   set(GMX_BINARY_SUFFIX "")
244   set(GMX_LIBS_SUFFIX "")
245   if (GMX_MPI)
246     set(GMX_BINARY_SUFFIX "_mpi")
247     set(GMX_LIBS_SUFFIX "_mpi")
248   endif(GMX_MPI)
249   if (GMX_DOUBLE)
250     set (GMX_BINARY_SUFFIX "${GMX_BINARY_SUFFIX}_d")
251     set (GMX_LIBS_SUFFIX "${GMX_LIBS_SUFFIX}_d")
252   endif(GMX_DOUBLE)
253   if (GMX_OPENMM)
254     set (GMX_BINARY_SUFFIX "-openmm")
255     set (GMX_LIBS_SUFFIX "_openmm")
256   endif(GMX_OPENMM)
257   mark_as_advanced(FORCE GMX_BINARY_SUFFIX GMX_LIBS_SUFFIX)
258   if (NOT SUFFIX_QUIETLY)
259     message(STATUS "Using default binary suffix: \"${GMX_BINARY_SUFFIX}\"")
260     message(STATUS "Using default library suffix: \"${GMX_LIBS_SUFFIX}\"")
261   endif (NOT SUFFIX_QUIETLY)
262 else(GMX_DEFAULT_SUFFIX)
263   mark_as_advanced(CLEAR GMX_BINARY_SUFFIX GMX_LIBS_SUFFIX)
264   if (NOT SUFFIX_QUIETLY)
265     message(STATUS "Using manually set binary suffix: \"${GMX_BINARY_SUFFIX}\"")
266     message(STATUS "Using manually set library suffix: \"${GMX_LIBS_SUFFIX}\"")
267   endif (NOT SUFFIX_QUIETLY)
268 endif(GMX_DEFAULT_SUFFIX)
269 set(SUFFIX_QUIETLY TRUE CACHE INTERNAL "")
270
271 set(PKG_CFLAGS "")
272 if(GMX_DOUBLE)
273     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_DOUBLE")
274 endif(GMX_DOUBLE)
275 if(GMX_SOFTWARE_INVSQRT)
276   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_SOFTWARE_INVSQRT")
277 endif(GMX_SOFTWARE_INVSQRT)
278 if(GMX_POWERPC_INVSQRT)
279   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_POWERPC_INVSQRT")
280 endif(GMX_POWERPC_INVSQRT)
281
282 ########################################################################
283 #Process MPI settings
284 ########################################################################
285 include(gmxManageMPI)
286
287 #######################################################################
288 # Check for options incompatible with OpenMM build                    #
289 #######################################################################
290 if(GMX_OPENMM)
291     # we'll use the built-in fft to avoid unnecessary dependencies
292     string(TOUPPER ${GMX_FFT_LIBRARY} GMX_FFT_LIBRARY)
293     if(NOT ${GMX_FFT_LIBRARY} STREQUAL "FFTPACK")
294         message(STATUS "No external FFT libraries needed for the OpenMM build, switching to fftpack!")
295         set(GMX_FFT_LIBRARY "fftpack" CACHE STRING 
296                 "No external FFT libraries needed for the OpenMM build, switching to  fftpack!" FORCE)
297     endif()
298     if(GMX_MPI)
299         message(FATAL_ERROR "The OpenMM build is not compatible with MPI!")
300     endif(GMX_MPI)
301     if(GMX_THREAD_MPI)
302         message(STATUS "Thread-MPI not compatible with OpenMM, disabled!")
303         set(GMX_THREAD_MPI OFF CACHE BOOL
304                 "Thread-MPI not compatible with OpenMM build, disabled!" FORCE)
305     endif(GMX_THREAD_MPI)
306     if(GMX_OPENMP)
307         message(STATUS "OpenMP multithreading not compatible with OpenMM, disabled")
308         set(GMX_OPENMP OFF CACHE BOOL
309             "OpenMP multithreading not compatible with OpenMM, disabled!" FORCE)
310     endif()
311     if(GMX_SOFTWARE_INVSQRT)
312         set(GMX_SOFTWARE_INVSQRT OFF CACHE STRING 
313                 "The OpenMM build does not need GROMACS software 1/sqrt!" FORCE)
314     endif(GMX_SOFTWARE_INVSQRT)
315     string(TOUPPER ${GMX_ACCELERATION} GMX_ACCELERATION)
316     if(NOT GMX_ACCELERATION STREQUAL "NONE")
317         message(STATUS "Switching off CPU-based acceleration, the OpenMM build does not support/need any!")     
318         set(GMX_ACCELERATION "none" CACHE STRING 
319                 "Switching off CPU-based acceleration, the OpenMM build does not support/need any!" FORCE)
320     endif()
321     if(GMX_FAHCORE)
322         message(FATAL_ERROR "The OpenMM build does not support FAH build!")
323     endif(GMX_FAHCORE)
324     if(GMX_DOUBLE)
325         message(FATAL_ERROR  "The OpenMM-build does not support double precision calculations!")
326     endif()
327     # mark as advanced the unused variables
328     mark_as_advanced(FORCE GMX_ACCELERATION GMX_MPI GMX_FFT_LIBRARY 
329         GMX_QMMM_PROGRAM GMX_THREAD_MPI GMX_DOUBLE)
330 else(GMX_OPENMM)
331      mark_as_advanced(CLEAR GMX_ACCELERATION GMX_MPI GMX_FFT_LIBRARY 
332         GMX_QMMM_PROGRAM GMX_THREAD_MPI GMX_DOUBLE)
333 endif(GMX_OPENMM)
334
335
336
337
338 ########################################################################
339 # Basic system tests (standard libraries, headers, functions, types)   #
340 ########################################################################
341 include(CheckIncludeFiles)
342 include(CheckIncludeFileCXX)
343 check_include_files(unistd.h     HAVE_UNISTD_H)
344 check_include_files(pwd.h        HAVE_PWD_H)
345 check_include_files(pthread.h    HAVE_PTHREAD_H)
346 check_include_files(dirent.h     HAVE_DIRENT_H)
347 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
348 check_include_files(io.h                 HAVE_IO_H)
349
350 check_include_files(regex.h      HAVE_POSIX_REGEX)
351 check_include_file_cxx(regex     HAVE_CXX11_REGEX)
352 # TODO: It could be nice to inform the user if no regex support is found,
353 # as selections won't be fully functional.
354
355 include(CheckFunctionExists)
356 check_function_exists(strdup            HAVE_STRDUP)
357 check_function_exists(posix_memalign    HAVE_POSIX_MEMALIGN)
358 check_function_exists(memalign          HAVE_MEMALIGN)
359 check_function_exists(_aligned_malloc   HAVE__ALIGNED_MALLOC)
360 check_function_exists(gettimeofday      HAVE_GETTIMEOFDAY)
361 check_function_exists(fsync             HAVE_FSYNC)
362 check_function_exists(_fileno           HAVE__FILENO)
363 check_function_exists(fileno            HAVE_FILENO)
364 check_function_exists(_commit           HAVE__COMMIT)
365 check_function_exists(lstat             HAVE_LSTAT)
366 check_function_exists(sigaction         HAVE_SIGACTION)
367
368 include(CheckLibraryExists)
369 check_library_exists(m sqrt "" HAVE_LIBM)
370 check_library_exists(m cbrt "" HAVE_CBRT)
371
372
373 include(CheckTypeSize)
374
375 check_type_size("int"           SIZEOF_INT) 
376 check_type_size("long int"      SIZEOF_LONG_INT) 
377 check_type_size("long long int" SIZEOF_LONG_LONG_INT) 
378 check_type_size("off_t"         SIZEOF_OFF_T)
379 check_type_size("void *"        SIZEOF_VOIDP)
380
381 if (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
382     set(GMX_64_BIT TRUE)
383 else (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
384     set(GMX_64_BIT FALSE)
385 endif (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
386
387 include(TestBigEndian)
388 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
389
390
391
392
393 ########################################################################
394 # Find external packages                                               #
395 ########################################################################
396 if(UNIX AND NOT APPLE)
397     if(GMX_PREFER_STATIC_LIBS)
398         SET(CMAKE_FIND_LIBRARY_SUFFIXES .a ${CMAKE_FIND_LIBRARY_SUFFIXES})
399         if(SHARED_LIBS_DEFAULT)
400             if(BUILD_SHARED_LIBS) #Warn the user about the combination. But don't overwrite the request.
401                 message(WARNING "Static libraries requested, and shared Gromacs libraries requested.")
402             elseif(NOT DEFINED BUILD_SHARED_LIBS) #Change default to OFF. Don't warn if it's already off.
403                 message(WARNING "Static libraries requested, the GROMACS libraries will also be build static (BUILD_SHARED_LIBS=OFF)")
404                 set(SHARED_LIBS_DEFAULT OFF)
405             endif()
406         endif()
407     endif()
408 endif()
409 option(BUILD_SHARED_LIBS "Enable shared libraries (can be problematic with MPI, Windows)" ${SHARED_LIBS_DEFAULT})
410
411 option(GMX_XML "Use libxml2 to parse xml files" ON)
412 if (GMX_XML)
413   find_package(LibXml2)
414   set(PKG_XML "")
415   if(LIBXML2_FOUND)
416     include_directories(${LIBXML2_INCLUDE_DIR})
417     set(PKG_XML libxml-2.0)
418     set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
419   endif(LIBXML2_FOUND)
420 endif(GMX_XML)
421
422 option(GMX_GSL "Add support for gsl" OFF)
423 if (GMX_GSL)
424   find_package(gsl)
425   set(PKG_GSL "")
426   if(GSL_FOUND)
427     include_directories(${GSL_INCLUDE_DIR})
428     set(PKG_GSL gsl)
429     set(HAVE_LIBGSL 1)
430   endif(GSL_FOUND)
431 endif (GMX_GSL)
432
433 option(GMX_X11 "Use X window system" OFF)
434 if (GMX_X11)
435         find_package(X11)
436         # X11 includes/libraries are only set in the ngmx subdirectory!
437         if(X11_FOUND)
438         set(HAVE_X11 1)
439         endif(X11_FOUND)
440 endif(GMX_X11)
441
442 include(ThreadMPI)
443 set(THREAD_MPI_LIB thread_mpi)
444 if(GMX_THREAD_MPI)
445     tmpi_get_source_list(THREAD_MPI_SRC CXX)
446     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_THREAD_MPI")
447     set(GMX_MPI 1)
448 else(GMX_THREAD_MPI)
449     tmpi_get_source_list(THREAD_MPI_SRC CXX NOMPI)
450 endif(GMX_THREAD_MPI)
451
452 if(GMX_OPENMM)
453     set(CUDA_BUILD_EMULATION OFF)
454     find_package(CUDA 3.1 REQUIRED)
455     add_definitions(-DGMX_OPENMM)
456     if(CMAKE_BUILD_TYPE STREQUAL "DEBUG")    
457         set(CUDA_VERBOSE_BUILD ON)
458     endif()
459     find_package(OpenMM) 
460 endif(GMX_OPENMM)
461
462
463 if(APPLE)
464    find_library(ACCELERATE_FRAMEWORK Accelerate)
465    list(APPEND GMX_EXTRA_LIBRARIES ${ACCELERATE_FRAMEWORK})
466 endif(APPLE)
467
468 if(CYGWIN)
469     set(GMX_CYGWIN 1)
470 endif(CYGWIN)
471
472 if(WIN32 AND NOT CYGWIN)
473     set(GMX_NATIVE_WINDOWS 1)
474 endif()
475
476 # only bother with finding git and using version.h if the source is a git repo
477 if(EXISTS "${CMAKE_SOURCE_DIR}/.git")
478     if(USE_VERSION_H)
479         # We need at least git v1.5.3 be able to parse git's date output. If not
480         # found or the version is too small, we can't generate version information.
481         find_package(Git)
482
483         # Find out the git version
484         if(GIT_FOUND AND NOT GIT_VERSION)
485           execute_process(COMMAND ${GIT_EXECUTABLE} "--version"
486             OUTPUT_VARIABLE _exec_out
487             OUTPUT_STRIP_TRAILING_WHITESPACE)
488           string(REGEX REPLACE "git version (.*)" "\\1" GIT_VERSION ${_exec_out})
489           set(GIT_VERSION ${GIT_VERSION} CACHE STRING "Git version")
490           mark_as_advanced(GIT_VERSION)
491         endif()
492
493         if(NOT GIT_FOUND OR GIT_VERSION VERSION_LESS "1.5.3")
494           message("No compatible git version found, won't be able to generate proper development version information.")
495           set(USE_VERSION_H OFF)
496         endif()
497     endif()
498 else()
499     set(USE_VERSION_H OFF)
500 endif()
501
502 option(GMX_INTERNAL_BOOST "Use minimal internal version of boost" OFF)
503 if ( NOT GMX_INTERNAL_BOOST )
504   find_package( Boost 1.44.0 )
505 else ( NOT GMX_INTERNAL_BOOST )
506   set (Boost_FOUND FALSE)
507 endif( NOT GMX_INTERNAL_BOOST )
508
509 if(Boost_FOUND AND NOT Boost_VERSION VERSION_LESS "104400" )
510   include_directories(${Boost_INCLUDE_DIRS})
511 else()
512   if(NOT BOOST_QUIETLY)
513     message("Boost >= 1.44 not found. Using minimal internal version. Not recommended if GROMACS is used as library!")
514   endif()
515   include_directories(${CMAKE_SOURCE_DIR}/src/external/boost)
516   add_definitions( -DBOOST_NO_TYPEID )  #TYPEID not supported for minimal internal version (would add significant more code)
517   # TODO: Propagate the above settings to the installed CMakeFiles.txt template
518   # (from share/template/)
519   # TODO: Reorder stuff such that INCL_INSTALL_DIR could be used here
520   set(PKG_CFLAGS "${PKG_CFLAGS} -DBOOST_NO_TYPEID -I${GMX_INSTALL_PREFIX}include/gromacs/external/boost")
521   install(DIRECTORY ${CMAKE_SOURCE_DIR}/src/external/boost/boost
522           DESTINATION ${GMX_INSTALL_PREFIX}include/gromacs/external/boost
523           COMPONENT development)
524 endif()
525 set(BOOST_QUIETLY TRUE CACHE INTERNAL "")
526
527 if (LIBXML2_FOUND)
528     option(GMX_BUILD_UNITTESTS "Build unit tests with BUILD_TESTING (uses Google C++ Testing and Mocking Frameworks, requires libxml2)" ON)
529 else (LIBXML2_FOUND)
530     set(GMX_BUILD_UNITTESTS OFF)
531 endif (LIBXML2_FOUND)
532 mark_as_advanced(GMX_BUILD_UNITTESTS)
533 set(MEMORYCHECK_SUPPRESSIONS_FILE ${CMAKE_SOURCE_DIR}/cmake/legacy_and_external.supp)
534
535 ########################################################################
536 # Generate development version info for cache
537 ########################################################################
538 # set(GEN_VERSION_INFO_INTERNAL "ON")
539 # include(gmxGenerateVersionString)
540
541 ########################################################################
542 # Our own GROMACS tests
543 ########################################################################
544
545 add_definitions( -DHAVE_CONFIG_H )
546 include_directories(${CMAKE_SOURCE_DIR}/src)
547 # Required for config.h, maybe should only be set in src/CMakeLists.txt
548 include_directories(${CMAKE_BINARY_DIR}/src)
549 # Required for gmx_header_config_gen.h to be found before installation
550 include_directories(${CMAKE_BINARY_DIR}/src/gromacs/utility)
551 # Required for now to make old code compile
552 include_directories(${CMAKE_SOURCE_DIR}/src/gromacs/legacyheaders)
553
554 include(gmxTestInlineASM)
555 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
556
557 include(gmxSetBuildInformation)
558 gmx_set_build_information()
559 if(BUILD_CPU_FEATURES MATCHES "rdtscp")
560     # The timestep counter headers do not include config.h
561     add_definitions(-DHAVE_RDTSCP)
562 endif(BUILD_CPU_FEATURES MATCHES "rdtscp")
563
564 include(gmxTestFloatFormat)
565 gmx_test_float_format(GMX_FLOAT_FORMAT_IEEE754 
566                       GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER
567                       GMX_IEEE754_BIG_ENDIAN_WORD_ORDER)
568
569 include(gmxTestLargeFiles)
570 gmx_test_large_files(GMX_LARGEFILES)
571 check_function_exists(fseeko     HAVE_FSEEKO)
572
573 include(gmxTestSignal)
574 gmx_test_sigusr1(HAVE_SIGUSR1)
575
576 include(gmxTestInline)
577 gmx_test_inline(INLINE_KEYWORD)
578
579 include(gmxTestPipes)
580 gmx_test_pipes(HAVE_PIPES)
581
582 include(gmxTestIsfinite)
583 gmx_test_isfinite(HAVE_ISFINITE)
584 gmx_test__isfinite(HAVE__ISFINITE)
585 gmx_test__finite(HAVE__FINITE)
586
587 include(gmxTestCXX11)
588 gmx_test_cxx11(GMX_CXX11 CXX11_FLAG)
589 set(GROMACS_CXX_FLAGS "${CXX11_FLAG} ${GROMACS_CXX_FLAGS}")
590
591 include(gmxTestXDR)
592 gmx_test_xdr(GMX_SYSTEM_XDR)
593 if(NOT GMX_SYSTEM_XDR)
594     set(GMX_INTERNAL_XDR 1)
595     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_INTERNAL_XDR")
596 endif(NOT GMX_SYSTEM_XDR)
597
598 # Process nonbonded accelerated kernels settings
599 string(TOUPPER ${GMX_ACCELERATION} ${GMX_ACCELERATION})
600 if(${GMX_ACCELERATION} STREQUAL "NONE")
601     # nothing to do
602 elseif(${GMX_ACCELERATION} STREQUAL "SSE2")
603
604     GMX_TEST_CFLAG(GNU_SSE2_CFLAG "-msse2" GROMACS_C_FLAGS)
605     if(NOT GNU_SSE2_CFLAG)
606         GMX_TEST_CFLAG(MSVC_SSE2_CFLAG "/arch:SSE2" GROMACS_C_FLAGS)
607     endif(NOT GNU_SSE2_CFLAG)
608
609     GMX_TEST_CXXFLAG(GNU_SSE2_CXXFLAG "-msse2" GROMACS_CXX_FLAGS)
610     if(NOT GNU_SSE2_CXXFLAG)
611         GMX_TEST_CXXFLAG(MSVC_SSE2_CXXFLAG "/arch:SSE2" GROMACS_CXX_FLAGS)
612     endif(NOT GNU_SSE2_CXXFLAG)
613
614     # We dont warn for lacking SSE2 flag support, since that is probably standard today.
615
616     # Only test the include after we have tried to add the correct flag for SSE2 support
617     check_include_file(emmintrin.h  HAVE_EMMINTRIN_H ${GROMACS_C_FLAGS})
618
619     if(NOT HAVE_EMMINTRIN_H)
620         message(FATAL_ERROR "Cannot find emmintrin.h, which is required for SSE2 intrinsics support.")
621     endif(NOT HAVE_EMMINTRIN_H)
622
623     # The user should not be able to set this orthogonally to the acceleration
624     set(GMX_X86_SSE2 1)
625     if (NOT ACCELERATION_QUIETLY)
626       message(STATUS "Enabling SSE2 Gromacs acceleration, and it will help compiler optimization.")
627     endif()
628
629 elseif(${GMX_ACCELERATION} STREQUAL "SSE4.1")
630
631     GMX_TEST_CFLAG(GNU_SSE4_CFLAG "-msse4.1" GROMACS_C_FLAGS)
632     if (NOT GNU_SSE4_CFLAG)
633         GMX_TEST_CFLAG(MSVC_SSE4_CFLAG "/arch:SSE4.1" GROMACS_C_FLAGS)
634     endif(NOT GNU_SSE4_CFLAG)
635     if (NOT GNU_SSE4_CFLAG AND NOT MSVC_SSE4_CFLAG)
636         message(WARNING "No C SSE4.1 flag found. Consider a newer compiler, or disable SSE4.1 for slightly lower performance.")
637         # Not surprising if we end up here! MSVC current does not support the SSE4.1 flag. However, it appears to accept SSE4.1
638         # intrinsics when SSE2 support is enabled, so we try that instead.
639         GMX_TEST_CFLAG(MSVC_SSE2_CFLAG "/arch:SSE2" GROMACS_C_FLAGS)
640     endif(NOT GNU_SSE4_CFLAG AND NOT MSVC_SSE4_CFLAG)
641
642     GMX_TEST_CXXFLAG(GNU_SSE4_CXXFLAG "-msse4.1" GROMACS_CXX_FLAG)
643     if (NOT GNU_SSE4_CXXFLAG)
644        GMX_TEST_CXXFLAG(MSVC_SSE4_CXXFLAG "/arch:SSE4.1" GROMACS_CXX_FLAGS)
645     endif(NOT GNU_SSE4_CXXFLAG)
646     if (NOT GNU_SSE4_CXXFLAG AND NOT MSVC_SSE4_CXXFLAG)
647         message(WARNING "No C++ SSE4.1 flag found. Consider a newer compiler, or disable SSE4.1 for slightly lower performance.")
648         # Not surprising if we end up here! MSVC current does not support the SSE4.1 flag. However, it appears to accept SSE4.1
649         # intrinsics when SSE2 support is enabled, so we try that instead.
650         GMX_TEST_CXXFLAG(MSVC_SSE2_CXXFLAG "/arch:SSE2" GROMACS_CXX_FLAGS)
651     endif(NOT GNU_SSE4_CXXFLAG AND NOT MSVC_SSE4_CXXFLAG)
652
653     # This must come after we have added the -msse4.1 flag on some platforms.
654     check_include_file(smmintrin.h  HAVE_SMMINTRIN_H ${GROMACS_C_FLAGS})
655
656     if(NOT HAVE_SMMINTRIN_H)
657         message(FATAL_ERROR "Cannot find smmintrin.h, which is required for SSE4.1 intrinsics support.")
658     endif(NOT HAVE_SMMINTRIN_H)
659
660     # The user should not be able to set this orthogonally to the acceleration
661     set(GMX_X86_SSE4_1 1)
662     set(GMX_X86_SSE2   1)
663     if (NOT ACCELERATION_QUIETLY)
664       message(STATUS "Enabling SSE4.1 Gromacs acceleration, and it will help compiler optimization.")
665     endif()
666
667 elseif(${GMX_ACCELERATION} STREQUAL "AVX_128_FMA" OR ${GMX_ACCELERATION} STREQUAL "AVX_256")
668
669     # Set the AVX compiler flag for both these choices!
670
671     GMX_TEST_CFLAG(GNU_AVX_CFLAG "-mavx" GROMACS_C_FLAGS)
672     if (NOT GNU_AVX_CFLAG)
673         GMX_TEST_CFLAG(MSVC_AVX_CFLAG "/arch:AVX" GROMACS_C_FLAGS)
674     endif (NOT GNU_AVX_CFLAG)
675     if (NOT GNU_AVX_CFLAG AND NOT MSVC_AVX_CFLAG)
676         message(WARNING "No C AVX flag found. Consider a newer compiler, or disable AVX for much lower performance.")
677     endif (NOT GNU_AVX_CFLAG AND NOT MSVC_AVX_CFLAG)
678
679     GMX_TEST_CXXFLAG(GNU_AVX_CXXFLAG "-mavx" GROMACS_CXX_FLAGS)
680     if (NOT GNU_AVX_CXXFLAG)
681        GMX_TEST_CXXFLAG(MSVC_AVX_CXXFLAG "/arch:AVX" GROMACS_CXX_FLAGS)
682     endif (NOT GNU_AVX_CXXFLAG)
683     if (NOT GNU_AVX_CXXFLAG AND NOT MSVC_AVX_CXXFLAG)
684        message(WARNING "No C++ AVX flag found. Consider a newer compiler, or disable AVX for much lower performance.")
685     endif (NOT GNU_AVX_CXXFLAG AND NOT MSVC_AVX_CXXFLAG)
686
687     # Only test the header after we have tried to add the flag for AVX support
688     check_include_file(immintrin.h  HAVE_IMMINTRIN_H ${GROMACS_C_FLAGS})
689
690     if(NOT HAVE_IMMINTRIN_H)
691         message(FATAL_ERROR "Cannot find immintrin.h, which is required for AVX intrinsics support. Consider switching compiler.")
692     endif(NOT HAVE_IMMINTRIN_H)
693
694     # AMD says we should include x86intrin.h for FMA support, but MSVC seems to do fine without it, so don't require it.
695     check_include_file(x86intrin.h HAVE_X86INTRIN_H ${GROMACS_C_FLAGS})
696
697     # The user should not be able to set this orthogonally to the acceleration
698     set(GMX_X86_SSE4_1 1)
699     set(GMX_X86_SSE2   1)
700
701     # But just enable one of the choices internally...
702     if(${GMX_ACCELERATION} STREQUAL "AVX_128_FMA")
703         set(GMX_X86_AVX_128_FMA 1)
704         if (NOT ACCELERATION_QUIETLY)
705           message(STATUS "Enabling 128-bit AVX Gromacs acceleration (with fused-multiply add), and it will help compiler optimization.")
706         endif()
707     else()
708         # If we are not doing AVX_128, it must be AVX_256...
709         set(GMX_X86_AVX_256 1)
710         if (NOT ACCELERATION_QUIETLY)
711           message(STATUS "Enabling 256-bit AVX Gromacs acceleration, and it will help compiler optimization.")
712         endif()
713     endif()
714
715 elseif(${GMX_ACCELERATION} STREQUAL "FORTRAN")
716
717 #    Fortran is temporarily disabled while we push in nbNxN kernels.
718 #    We need to fake it a bit here to avoid jenkins build errors!
719 #    add_definitions(-DGMX_FORTRAN)
720
721 elseif(${GMX_ACCELERATION} STREQUAL "BLUEGENE")
722 # GMX_ACCELERATION=BlueGene should be set in the Toolchain-BlueGene?-???.cmake file
723     if (NOT ACCELERATION_QUIETLY)
724       message(STATUS "Configuring for BlueGene")
725     endif()
726     set(GMX_BLUEGENE 1)
727     if (${CMAKE_SYSTEM_NAME} STREQUAL "BlueGeneL")
728         set(SHARED_LIBS_DEFAULT OFF CACHE BOOL "Shared libraries not compatible with BlueGene/L, disabled!" FORCE)
729         set(BUILD_SHARED_LIBS OFF CACHE BOOL "Shared libraries not compatible with BlueGene/L, disabled!" FORCE)
730     endif (${CMAKE_SYSTEM_NAME} STREQUAL "BlueGeneL")
731     set(GMX_SOFTWARE_INVSQRT OFF CACHE BOOL "Do not use software reciprocal square root on BlueGene" FORCE)
732     set(GMX_POWERPC_INVSQRT ON CACHE BOOL "Use hardware reciprocal square root on BlueGene" FORCE)
733     set(GMX_X11 OFF CACHE BOOL "X11 not compatible with BlueGene, disabled!" FORCE)
734     set(GMX_THREAD_MPI OFF CACHE BOOL "Thread-MPI not compatible with BlueGene, disabled!" FORCE)
735     set(GMX_MPI ON CACHE BOOL "Use MPI on BlueGene" FORCE)
736 # Access to /etc/passwd is not available on the back end of BlueGene,
737 # despite being detected by CMake. This can cause linker warnings
738 # about harmless things in src/gmxlib/string2.h.
739     set(HAVE_PWD_H OFF)
740 # The automatic testing for endianness does not work for the BlueGene cross-compiler
741     set(GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER 1 CACHE INTERNAL "BlueGene has big endian FP byte order (by default)" FORCE)
742     set(GMX_IEEE754_BIG_ENDIAN_WORD_ORDER 1 CACHE INTERNAL "BlueGene has big endian FP word order (by default)" FORCE)
743 elseif(${GMX_ACCELERATION} STREQUAL "POWER6")
744     set(GMX_POWER6 1)
745     set(GMX_SOFTWARE_INVSQRT OFF CACHE BOOL "Do not use software reciprocal square root on Power6" FORCE)
746     set(GMX_POWERPC_INVSQRT ON CACHE BOOL "Use hardware reciprocal square root on Power6" FORCE)
747 else(${GMX_ACCELERATION} STREQUAL "NONE")
748     MESSAGE(FATAL_ERROR "Unrecognized option for accelerated kernels: ${GMX_ACCELERATION}. Pick one of None, SSE2, SSE4.1, AVX_128_FMA, AVX_256, Fortran, BlueGene, Power6")
749 endif(${GMX_ACCELERATION} STREQUAL "NONE")
750 set(ACCELERATION_QUIETLY TRUE CACHE INTERNAL "")
751
752 if(GMX_FORTRAN OR GMX_POWER6)
753     if (GMX_THREAD_MPI)
754         message(FATAL_ERROR "FORTRAN/POWER6 is incompatible with thread-MPI and only provides a speed-up on certain IBM compilers. Disable FORTRAN (or threads if you really want to use FORTRAN kernels).")
755     endif(GMX_THREAD_MPI)
756     enable_language(Fortran)
757     include(FortranCInterface)
758     discover_fortran_mangling(prefix isupper suffix extra_under_score found)
759     if(extra_under_score)
760         set(extrasuffix "_")
761     endif(extra_under_score)
762     if(prefix)
763       set(prefix "${prefix} ##")
764     endif(prefix)
765     if(suffix)
766       set(suffix "## ${suffix}")
767       if(extrasuffix)
768         set(extrasuffix "${suffix}${extrasuffix}")
769       endif(extrasuffix)
770     else(suffix)
771       if(extrasuffix)
772         # Don't know if this is needed, but it can't hurt
773         set(extrasuffix "## ${extrasuffix}")
774       endif(extrasuffix)
775     endif(suffix)
776
777     if(isupper)
778         set(F77_FUNCDEF   "${prefix} NAME ${suffix}")
779         # The underscored versions are not currently used.
780         #set(F77_FUNCDEF_  "${prefix} NAME ${extrasuffix}")
781     else(isupper)
782         set(F77_FUNCDEF   "${prefix} name ${suffix}")
783         #set(F77_FUNCDEF_  "${prefix} name ${extrasuffix}")
784     endif(isupper)
785 else(GMX_FORTRAN OR GMX_POWER6)
786         set(F77_FUNCDEF   "name ## _")
787         #set(F77_FUNCDEF_  "name ## _")
788 endif(GMX_FORTRAN OR GMX_POWER6)
789
790 # Process QM/MM Settings
791 string(TOUPPER ${GMX_QMMM_PROGRAM} ${GMX_QMMM_PROGRAM})
792 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
793     set(GMX_QMMM_GAUSSIAN 1)
794 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
795     set(GMX_QMMM_MOPAC 1)
796 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
797     set(GMX_QMMM_GAMESS 1)
798 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
799     set(GMX_QMMM_ORCA 1)
800 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
801     # nothing to do
802 else(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
803     MESSAGE(FATAL_ERROR "Invalid QM/MM program option: ${GMX_QMMM_PROGRAM}. Choose one of: Gaussian, Mopac, Gamess, Orca, None")
804 endif(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
805
806 # Process FFT library settings - if not OpenMM build 
807 string(TOUPPER ${GMX_FFT_LIBRARY} ${GMX_FFT_LIBRARY})
808 set(PKG_FFT "")
809 set(PKG_FFT_LIBS "")
810 if(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
811     if(GMX_DOUBLE)
812         find_package(FFTW 3 COMPONENTS fftw)
813     else(GMX_DOUBLE)
814         find_package(FFTW 3 COMPONENTS fftwf)
815     endif(GMX_DOUBLE)
816     if(NOT FFTW_FOUND)
817       MESSAGE(FATAL_ERROR "Cannot find FFTW3 (with correct precision - libfftw3f for single precision GROMACS or libfftw3 for double precision GROMACS). Fix it, choose another FFT library, or use the Gromacs built-in fftpack (slower)!")
818     endif(NOT FFTW_FOUND)
819     include_directories(${FFTW_INCLUDE_DIRS})
820     set(FFT_LIBRARIES ${FFTW_LIBRARIES})
821     set(PKG_FFT "${FFTW_PKG}")
822
823     set(GMX_FFT_FFTW3 1)
824
825     if (${GMX_ACCELERATION} STREQUAL "SSE" AND NOT FFTW_HAVE_SSE)
826       message(WARNING "The fftw library found is compiled without SSE support, which makes it slow. Consider recompiling it or contact your admin")
827     endif (${GMX_ACCELERATION} STREQUAL "SSE" AND NOT FFTW_HAVE_SSE)
828
829 elseif(${GMX_FFT_LIBRARY} STREQUAL "MKL")
830 #    MESSAGE(STATUS "Using external FFT library - Intel MKL")
831     find_package(MKL REQUIRED)
832     include_directories(${MKL_INCLUDE_DIR})
833     set(FFT_LIBRARIES ${MKL_LIBRARIES})
834     set(PKG_FFT_LIBS ${MKL_LIBRARIES})
835
836     set(GMX_FFT_MKL 1)
837     set(HAVE_MKL 1)
838
839 #elseif(${GMX_FFT_LIBRARY} STREQUAL "ACML")
840 #    MESSAGE(STATUS "Using external FFT library - AMD core math library")
841 #    set(GMX_FFT_ACML 1)
842 elseif(${GMX_FFT_LIBRARY} STREQUAL "FFTPACK")
843     MESSAGE(STATUS "Using internal FFT library - fftpack")
844     set(GMX_FFT_FFTPACK 1)
845 else(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
846     MESSAGE(FATAL_ERROR "Invalid FFT library setting: ${GMX_FFT_LIBRARY}. Choose one of: fftw3, mkl, fftpack")
847 endif(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
848
849 set(GMX_EXTERNAL_BLAS TRUE CACHE BOOL "Use external BLAS instead of built-in")
850 set(GMX_EXTERNAL_LAPACK TRUE CACHE BOOL "Use external LAPACK instead of built-in")
851 # MKL has BLAS/LAPACK routines
852 if(NOT HAVE_MKL AND NOT ACCELERATE_FRAMEWORK)
853   if(GMX_EXTERNAL_BLAS)
854     if (GMX_BLAS_USER)
855         list(APPEND GMX_EXTRA_LIBRARIES ${GMX_BLAS_USER})
856     else(GMX_BLAS_USER)
857         set(BLAS_FIND_QUIETLY ON)
858         find_package(BLAS)
859         if (BLAS_FOUND)
860           list(APPEND GMX_EXTRA_LIBRARIES ${BLAS_LIBRARIES})
861         else()
862           MESSAGE(STATUS "Using internal BLAS library")
863           set(GMX_EXTERNAL_BLAS FALSE CACHE BOOL "Use external BLAS instead of built-in" FORCE)
864         endif()
865     endif(GMX_BLAS_USER)
866   endif(GMX_EXTERNAL_BLAS)
867   if(GMX_EXTERNAL_LAPACK)
868     if (GMX_LAPACK_USER)
869         list(APPEND GMX_EXTRA_LIBRARIES ${GMX_LAPACK_USER})
870     else(GMX_LAPACK_USER)
871         set(LAPACK_FIND_QUIETLY ON)
872         find_package(LAPACK)
873         if (LAPACK_FOUND)
874           list(APPEND GMX_EXTRA_LIBRARIES ${LAPACK_LIBRARIES})
875         else()
876           MESSAGE(STATUS "Using internal LAPACK library")
877           set(GMX_EXTERNAL_LAPACK FALSE CACHE BOOL "Use external LAPACK instead of built-in" FORCE)
878         endif()
879     endif(GMX_LAPACK_USER)
880   endif(GMX_EXTERNAL_LAPACK)
881 endif()
882 mark_as_advanced(GMX_EXTERNAL_LAPACK)
883 mark_as_advanced(GMX_EXTERNAL_BLAS)
884
885 set(GMX_USE_PLUGINS OFF CACHE INTERNAL "Whether GROMACS will really try to compile support for VMD plugins")
886
887 if(GMX_LOAD_PLUGINS)
888   if(CYGWIN OR NOT WIN32)
889     # Native Windows does not have, nor need dlopen
890     # Note that WIN32 is set with Cygwin, but Cygwin needs dlopen to use plug-ins
891     include(gmxTestdlopen)
892     gmx_test_dlopen(HAVE_DLOPEN)
893   endif()
894
895   # so, should we use plug-ins?
896   if((WIN32 AND NOT CYGWIN) OR (HAVE_DLOPEN AND BUILD_SHARED_LIBS))
897     if(NOT VMD_QUIETLY)
898       MESSAGE(STATUS
899           "Found the ability to use plug-ins when building shared libaries, "
900           "so will compile to use plug-ins (e.g. to read VMD-supported file "
901           "formats).")
902     endif()
903     if(NOT GMX_VMD_PLUGIN_PATH)
904       find_package(VMD)
905     endif()
906     set(GMX_USE_PLUGINS ON)
907     list(APPEND GMX_EXTRA_LIBRARIES ${CMAKE_DL_LIBS}) # magic cross-platform pre-set variable for dlopen library
908     set(PKG_DL_LIBS "-l${CMAKE_DL_LIBS}")
909   else()
910     set(PKG_DL_LIBS)
911   endif()
912 endif(GMX_LOAD_PLUGINS)
913 set(VMD_QUIETLY TRUE CACHE INTERNAL "")
914
915 if(EXISTS "${CMAKE_SOURCE_DIR}/admin/.isreposource")
916     if(NOT CMAKE_CROSSCOMPILING)
917         option(GMX_BUILD_MANPAGES "Build man pages" ON)
918     else()
919         message(STATUS "Building the man pages is not available when "
920             "cross-compiling the developer version from git")
921     endif()
922 else()
923     #make sure source package contains all man pages
924     if(NOT EXISTS "${CMAKE_SOURCE_DIR}/man/man1/ngmx.1")
925         message(FATAL_ERROR "Man pages are missing from source package.")
926     endif()
927 endif()
928 mark_as_advanced(GMX_BUILD_MANPAGES)
929
930 # Math and thread libraries must often come after all others when linking...
931 if(HAVE_LIBM)
932     list(APPEND GMX_EXTRA_LIBRARIES m)
933 endif(HAVE_LIBM)
934
935 if(GMX_FAHCORE)
936   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING 
937       "Path to swindirect.h")
938   include_directories(${COREWRAP_INCLUDE_DIR})
939 endif(GMX_FAHCORE)
940
941 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
942 # these are set after everything else
943 if (NOT DEFINED GROMACS_C_FLAGS_SET)
944     set(GROMACS_C_FLAGS_SET true CACHE INTERNAL "Whether to reset the C flags" 
945         FORCE)
946     set(CMAKE_C_FLAGS "${GROMACS_C_FLAGS} ${CMAKE_C_FLAGS}" CACHE STRING 
947         "Flags used by the compiler during all build types" FORCE)
948     set(CMAKE_CXX_FLAGS "${GROMACS_CXX_FLAGS} ${CMAKE_CXX_FLAGS}" CACHE STRING 
949         "Flags used by the compiler during all build types" FORCE)
950     set(CMAKE_EXE_LINKER_FLAGS 
951         "${GROMACS_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}" 
952         CACHE STRING "Linker flags for creating executables" FORCE) 
953     set(CMAKE_SHARED_LINKER_FLAGS 
954         "${GROMACS_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS}" 
955         CACHE STRING "Linker flags for creating shared libraries" FORCE) 
956 endif (NOT DEFINED GROMACS_C_FLAGS_SET)
957
958 ######################################
959 # Output compiler and CFLAGS used
960 ######################################
961 execute_process(COMMAND ${CMAKE_C_COMPILER} --version RESULT_VARIABLE TMP_RESULT OUTPUT_VARIABLE CC_VERSION ERROR_VARIABLE CC_VERSION)
962 #try executing just the compiler command if that failed...
963 if(TMP_RESULT)
964     execute_process(COMMAND ${CMAKE_C_COMPILER} RESULT_VARIABLE TMP_RESULT OUTPUT_VARIABLE CC_VERSION ERROR_VARIABLE CC_VERSION)
965 endif()
966 string(LENGTH "${CC_VERSION}" len)
967 if(len)
968     string(REGEX MATCH "[^\n]*" CC_VERSION "${CC_VERSION}")
969 endif()
970
971 set(BUILD_COMPILER "@CMAKE_C_COMPILER@ @CMAKE_C_COMPILER_ID@ @CC_VERSION@")
972 set(BUILD_CFLAGS "@CMAKE_C_FLAGS@")
973 if(CMAKE_BUILD_TYPE STREQUAL "Debug")
974     set(BUILD_CFLAGS "@BUILD_CFLAGS@ @CMAKE_C_FLAGS_DEBUG@")
975 elseif(CMAKE_BUILD_TYPE STREQUAL "Release")
976     set(BUILD_CFLAGS "@BUILD_CFLAGS@ @CMAKE_C_FLAGS_RELEASE@")
977 elseif(CMAKE_BUILD_TYPE STREQUAL "MinSizeRel")
978     set(BUILD_CFLAGS "@BUILD_CFLAGS@ @CMAKE_C_FLAGS_MINSIZEREL@")
979 elseif(CMAKE_BUILD_TYPE STREQUAL "RelWithDebInfo")
980     set(BUILD_CFLAGS "@BUILD_CFLAGS@ @CMAKE_C_FLAGS_RELWITHDEBINFO@")
981 endif()
982
983
984 ########################################################################
985 # Specify install locations and which subdirectories to process        #
986 ########################################################################
987 if ( NOT DEFINED GMXLIB )
988     set(GMXLIB lib)
989 endif()
990 set(LIB_INSTALL_DIR "${GMX_INSTALL_PREFIX}${GMXLIB}")
991 set(BIN_INSTALL_DIR  ${GMX_INSTALL_PREFIX}bin)
992 set(DATA_INSTALL_DIR ${GMX_INSTALL_PREFIX}share/gromacs)
993 set(MAN_INSTALL_DIR  ${GMX_INSTALL_PREFIX}share/man)
994 set(INCL_INSTALL_DIR ${GMX_INSTALL_PREFIX}include)
995
996 set(GMXLIBDIR        ${DATA_INSTALL_DIR}/top)
997
998 ##################################################################
999 # Shared library settings - Darwin uses INSTALL_NAME_DIR instead!
1000 ##################################################################
1001 if(NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin")
1002     set(CMAKE_SKIP_BUILD_RPATH  FALSE)
1003     set(CMAKE_BUILD_WITH_INSTALL_RPATH FALSE)
1004     set(CMAKE_INSTALL_RPATH "\\\$ORIGIN/../${GMXLIB}")
1005     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
1006 endif()
1007
1008 add_subdirectory(doxygen)
1009 add_subdirectory(share)
1010 add_subdirectory(src)
1011 add_subdirectory(scripts)
1012
1013 #######################
1014 ## uninstall target
1015 #######################
1016     CONFIGURE_FILE(
1017                    "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
1018                    "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
1019                    IMMEDIATE @ONLY)
1020 ###########################
1021 ADD_CUSTOM_TARGET(uninstall
1022                   "${CMAKE_COMMAND}" -P 
1023                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
1024 ###########################
1025
1026
1027 ########################################################################
1028 # Tests                                                                #
1029 ########################################################################
1030
1031 include(CTest)
1032 mark_as_advanced(BUILD_TESTING)
1033 IF(BUILD_TESTING)
1034     enable_testing()
1035     add_subdirectory(tests)
1036 ENDIF()
1037