CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.6)
   2
   3 project(Gromacs)
   4 include(Dart)
   5 mark_as_advanced(DART_ROOT)
   6
   7 # PROJECT_VERSION should have the following structure:
   8 # VERSION-dev[-SUFFIX] where the VERSION should have the for: vMajor.vMinor.vPatch
   9 #
  10 # The "-dev" suffix is important to keep because it makes possible to distinguish
  11 # between a build from official release and a build from git release branch on a
  12 # machine with no git.
  13 #
  14 # NOTE: when releasing the "-dev" suffix needs to be stripped off!
  15 set(PROJECT_VERSION "4.5.3-dev")
  16 set(CUSTOM_VERSION_STRING ""
  17     CACHE STRING "Custom version string (if empty, use hard-coded default)")
  18 mark_as_advanced(CUSTOM_VERSION_STRING)
  19 if (CUSTOM_VERSION_STRING)
  20     set(PROJECT_VERSION ${CUSTOM_VERSION_STRING})
  21 endif (CUSTOM_VERSION_STRING)
  22 set(SOVERSION 6)
  23 # It is a bit irritating, but this has to be set separately for now!
  24 SET(CPACK_PACKAGE_VERSION_MAJOR "4")
  25 SET(CPACK_PACKAGE_VERSION_MINOR "5")
  26 SET(CPACK_PACKAGE_VERSION_PATCH "3")
  27
  28
  29 # Cmake modules/macros are in a subdirectory to keep this file cleaner
  30 set(CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake)
  31
  32 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
  33 set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
  34 endif()
  35
  36 if(NOT CMAKE_BUILD_TYPE)
  37     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel." FORCE)
  38 endif(NOT CMAKE_BUILD_TYPE)
  39
  40 enable_language(C)
  41
  42 set(CPACK_PACKAGE_VERSION ${PROJECT_VERSION})
  43 set(CPACK_PACKAGE_VENDOR "gromacs.org")
  44 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Gromacs - a toolkit for high-performance molecular simulation")
  45 set(CPACK_SET_DESTDIR "ON")
  46 set(CPACK_INCLUDE_TOPLEVEL_DIRECTORY 0)
  47 set(CPACK_RESOURCE_FILE_WELCOME "${CMAKE_SOURCE_DIR}/admin/InstallWelcome.txt")
  48 # Its GPL/LGPL, so they do not have to agree to a license for mere usage, but some installers require this...
  49 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_SOURCE_DIR}/admin/InstallLicense.txt")
  50 set(CPACK_RESOURCE_FILE_README "${CMAKE_SOURCE_DIR}/admin/InstallInfo.txt")
  51
  52 #must come after all cpack settings!
  53 include(CPack)
  54
  55 ########################################################################
  56 # Check and warn if cache generated on a different host is being reused
  57 ########################################################################
  58 if(CMAKE_HOST_UNIX)
  59     execute_process(COMMAND hostname
  60                     OUTPUT_VARIABLE TMP_HOSTNAME
  61                     OUTPUT_STRIP_TRAILING_WHITESPACE)
  62     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}")
  63         message(WARNING "
  64             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
  65             is being reused! This could lead to inconsitencies; therefore, it is
  66             recommended to regenerate the cache!")
  67     endif()
  68     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
  69             "Hostname of the machine where the cache was generated.")
  70 endif()
  71
  72 ########################################################################
  73 # Fix stupid flags on MSVC
  74 ########################################################################
  75 SET(SHARED_LIBS_DEFAULT ON)
  76 IF(CMAKE_GENERATOR MATCHES "Visual Studio")
  77     STRING(REPLACE /MD /MT CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE})
  78     SET(CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE} CACHE STRING "" FORCE)
  79     STRING(REPLACE /MD /MT CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG})
  80     SET(CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG} CACHE STRING "" FORCE)
  81     SET(SHARED_LIBS_DEFAULT OFF)
  82 ENDIF(CMAKE_GENERATOR MATCHES "Visual Studio")
  83
  84 set(GMX_EXTRA_LIBRARIES)
  85
  86
  87
  88 ######################################################################
  89 # compiler tests
  90 # these need ot be done early (before further tests).
  91 #####################################################################
  92
  93 include(CheckCCompilerFlag)
  94 include(CheckCXXCompilerFlag)
  95
  96 include(gmxCFlags)
  97 gmx_c_flags()
  98
  99 ########################################################################
 100 # User input options                                                   #
 101 ########################################################################
 102 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" OFF)
 103 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 104 option(GMX_THREADS    "Build a parallel (thread-based) version of GROMACS (cannot be combined with MPI yet)" ON)
 105 option(GMX_SOFTWARE_INVSQRT "Use GROMACS software 1/sqrt" ON)
 106 mark_as_advanced(GMX_SOFTWARE_INVSQRT)
 107 option(GMX_POWERPC_INVSQRT "Use PowerPC hardware 1/sqrt" OFF)
 108 mark_as_advanced(GMX_POWERPC_INVSQRT)
 109 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 110 mark_as_advanced(GMX_FAHCORE)
 111 option(GMX_OPENMM "Accelerated execution on GPUs through the OpenMM library (rerun cmake after changing to see relevant options)" OFF)
 112 set(GMX_ACCELERATION "auto"
 113     CACHE STRING "Accelerated kernels. Pick one of: auto, none, SSE, BlueGene, Power6, ia64, altivec, fortran")
 114
 115 set(GMX_FFT_LIBRARY "fftw3"
 116     CACHE STRING "FFT library choices: fftw3,fftw2,mkl,fftpack[built-in]")
 117 option(GMX_DISABLE_FFTW_MEASURE
 118        "Do not optimize FFTW setups (not needed with SSE)" OFF)
 119 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 120 set(GMX_QMMM_PROGRAM "none"
 121     CACHE STRING "QM package choices: none,gaussian,mopac,gamess,orca")
 122 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 123 mark_as_advanced(GMX_BROKEN_CALLOC)
 124 option(BUILD_SHARED_LIBS "Enable shared libraries (can be problematic with MPI, Windows)" ${SHARED_LIBS_DEFAULT})
 125 option(GMX_MPI_IN_PLACE "Enable MPI_IN_PLACE for MPIs that have it defined" ON)
 126 mark_as_advanced(GMX_MPI_IN_PLACE)
 127 option(GMX_DLOPEN "Compile with dlopen, needed to read VMD supported file formats" ON)
 128 mark_as_advanced(GMX_DLOPEN)
 129
 130
 131 option(GMX_IA32_ASM "Add SSE assembly files for IA32" OFF)
 132 mark_as_advanced(GMX_IA32_ASM)
 133 option(GMX_X86_64_ASM "Add SSE assembly files for X86_64" OFF)
 134 mark_as_advanced(GMX_X86_64_ASM)
 135
 136 option(USE_VERSION_H "Generate development version string/information" ON)
 137 mark_as_advanced(USE_VERSION_H)
 138
 139 option(GMX_DEFAULT_SUFFIX "Use default suffixes for GROMACS binaries and libs (_d for double, _mpi for MPI; rerun cmake after changing to see relevant options)" ON)
 140
 141 if(UNIX AND NOT APPLE)
 142     option(GMX_PREFER_STATIC_LIBS "When finding libraries prefer \".a\" static archives (NOTE: this is enabled only for UNIX (excluding APPLE) platforms but it might not always work!" OFF)
 143     mark_as_advanced(GMX_PREFER_STATIC_LIBS)
 144 endif()
 145
 146 ########################################################################
 147 # Set up binary and library suffixing
 148 ########################################################################
 149 set(GMX_BINARY_SUFFIX "" CACHE STRING "Suffix for GROMACS binaries (default: _d for double, _mpi for MPI, _mpi_d for MPI and double).")
 150 set(GMX_LIBS_SUFFIX ""
 151   CACHE STRING "Suffix for GROMACS libs (default: _d for double, _mpi for MPI, _mpi_d for MPI and double).")
 152 if (GMX_DEFAULT_SUFFIX)
 153   set(GMX_BINARY_SUFFIX "")
 154   set(GMX_LIBS_SUFFIX "")
 155   if (GMX_MPI)
 156     set(GMX_BINARY_SUFFIX "_mpi")
 157     set(GMX_LIBS_SUFFIX "_mpi")
 158   endif(GMX_MPI)
 159   if (GMX_DOUBLE)
 160     set (GMX_BINARY_SUFFIX "${GMX_BINARY_SUFFIX}_d")
 161     set (GMX_LIBS_SUFFIX "${GMX_LIBS_SUFFIX}_d")
 162   endif(GMX_DOUBLE)
 163   if (GMX_OPENMM)
 164     set (GMX_BINARY_SUFFIX "-gpu")
 165     set (GMX_LIBS_SUFFIX "_gpu")
 166   endif(GMX_OPENMM)
 167   mark_as_advanced(FORCE GMX_BINARY_SUFFIX GMX_LIBS_SUFFIX)
 168   message(STATUS "Using default binary suffix: \"${GMX_BINARY_SUFFIX}\"")
 169   message(STATUS "Using default library suffix: \"${GMX_LIBS_SUFFIX}\"")
 170 else(GMX_DEFAULT_SUFFIX)
 171   mark_as_advanced(CLEAR GMX_BINARY_SUFFIX GMX_LIBS_SUFFIX)
 172   message(STATUS "Using manually set binary suffix: \"${GMX_BINARY_SUFFIX}\"")
 173   message(STATUS "Using manually set library suffix: \"${GMX_LIBS_SUFFIX}\"")
 174 endif(GMX_DEFAULT_SUFFIX)
 175
 176 set(PKG_CFLAGS "")
 177 if(GMX_DOUBLE)
 178     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_DOUBLE")
 179 endif(GMX_DOUBLE)
 180 if(GMX_SOFTWARE_INVSQRT)
 181   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_SOFTWARE_INVSQRT")
 182 endif(GMX_SOFTWARE_INVSQRT)
 183 if(GMX_POWERPC_INVSQRT)
 184   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_POWERPC_INVSQRT")
 185 endif(GMX_POWERPC_INVSQRT)
 186
 187 ########################################################################
 188 #Process MPI settings
 189 ########################################################################
 190 include(CheckCSourceCompiles) # for gmxTestMPI_IN_PLACE
 191 if(GMX_MPI)
 192         MESSAGE(WARNING "
 193             There are known problems with some MPI implementations:
 194                      OpenMPI version < 1.4.1
 195                      MVAPICH2 version <= 1.4.1                               *")
 196     if(GMX_THREADS)
 197         #message(FATAL_ERROR "Thread-based parallelization conflicts with MPI.")
 198         set(GMX_THREADS OFF CACHE BOOL
 199             "Thread-based parallelization conflicts with MPI." FORCE)
 200     endif(GMX_THREADS)
 201     find_package(MPI)
 202     if(MPI_FOUND)
 203         set(GROMACS_C_FLAGS ${GROMACS_FLAGS} ${MPI_COMPILE_FLAGS})
 204         set(GROMACS_LINKER_FLAGS ${GROMACS_LINKER_FLAGS} ${MPI_LINK_FLAGS})
 205
 206         include_directories(${MPI_INCLUDE_PATH})
 207         list(APPEND GMX_EXTRA_LIBRARIES ${MPI_LIBRARIES})
 208         add_definitions( -DMPI ) #for FAHCORE
 209         include(gmxTestMPI_IN_PLACE)
 210         if (GMX_MPI_IN_PLACE)
 211             gmx_test_mpi_in_place(MPI_IN_PLACE_EXISTS)
 212         endif (GMX_MPI_IN_PLACE)
 213     else(MPI_FOUND)
 214         message(FATAL_ERROR "MPI support requested, but no MPI compiler found.")
 215     endif(MPI_FOUND)
 216     include(gmxTestCatamount)
 217     gmx_test_catamount(GMX_CRAY_XT3)
 218     if(GMX_CRAY_XT3)
 219         set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_CRAY_XT3")
 220         set(GMX_NO_SYSTEM 1)
 221         set(GMX_NO_NICE 1)
 222     endif(GMX_CRAY_XT3)
 223     set(GMX_LIB_MPI 1)
 224     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_LIB_MPI")
 225 endif(GMX_MPI)
 226
 227
 228 #######################################################################
 229 # Check for options incompatible with OpenMM build                    #
 230 #######################################################################
 231 if(GMX_OPENMM)
 232     cmake_minimum_required(VERSION 2.6.4)
 233     # we'll use the built-in fft to avoid unnecessary dependencies
 234     string(TOUPPER ${GMX_FFT_LIBRARY} GMX_FFT_LIBRARY)
 235     if(NOT ${GMX_FFT_LIBRARY} STREQUAL "FFTPACK")
 236         message(STATUS "No external FFT libraries needed for the OpenMM build, switching to fftpack!")
 237         set(GMX_FFT_LIBRARY "fftpack" CACHE STRING
 238                 "No external FFT libraries needed for the OpenMM build, switching to  fftpack!" FORCE)
 239     endif()
 240     if(GMX_MPI)
 241         message(FATAL_ERROR "The OpenMM build is not compatible with MPI!")
 242     endif(GMX_MPI)
 243     if(GMX_THREADS)
 244         message(STATUS "Threads are  not compatible with OpenMM build, disabled!")
 245         set(GMX_THREADS OFF CACHE BOOL
 246                 "Threads are not compatible with OpenMM build, disabled!" FORCE)
 247     endif(GMX_THREADS)
 248     if(GMX_SOFTWARE_INVSQRT)
 249         set(GMX_SOFTWARE_INVSQRT OFF CACHE STRING
 250                 "The OpenMM build does not need GROMACS software 1/sqrt!" FORCE)
 251     endif(GMX_SOFTWARE_INVSQRT)
 252     string(TOUPPER ${GMX_ACCELERATION} GMX_ACCELERATION)
 253     if(NOT GMX_ACCELERATION STREQUAL "NONE")
 254         message(STATUS "Switching off CPU-based acceleration, the OpenMM build does not support/need any!")
 255         set(GMX_ACCELERATION "none" CACHE STRING
 256                 "Switching off CPU-based acceleration, the OpenMM build does not support/need any!" FORCE)
 257     endif()
 258     if(GMX_FAHCORE)
 259         message(FATAL_ERROR "The OpenMM build does not support FAH build!")
 260     endif(GMX_FAHCORE)
 261     if(GMX_DOUBLE)
 262         message(FATAL_ERROR  "The OpenMM-build does not support double precision calculations!")
 263     endif()
 264     # mark as advanced the unused variables
 265     mark_as_advanced(FORCE GMX_ACCELERATION GMX_MPI GMX_FFT_LIBRARY
 266         GMX_QMMM_PROGRAM GMX_THREADS GMX_DOUBLE)
 267 else(GMX_OPENMM)
 268      mark_as_advanced(CLEAR GMX_ACCELERATION GMX_MPI GMX_FFT_LIBRARY
 269         GMX_QMMM_PROGRAM GMX_THREADS GMX_DOUBLE)
 270 endif(GMX_OPENMM)
 271
 272
 273 ########################################################################
 274 # Basic system tests (standard libraries, headers, functions, types)   #
 275 ########################################################################
 276 include(CheckIncludeFiles)
 277 check_include_files(string.h     HAVE_STRING_H)
 278 check_include_files(math.h       HAVE_MATH_H)
 279 check_include_files(limits.h     HAVE_LIMITS_H)
 280 check_include_files(memory.h     HAVE_MEMORY_H)
 281 check_include_files(unistd.h     HAVE_UNISTD_H)
 282 check_include_files(pwd.h        HAVE_PWD_H)
 283 check_include_files(stdint.h     HAVE_STDINT_H)
 284 check_include_files(stdlib.h     HAVE_STDLIB_H)
 285 check_include_files(pthread.h    HAVE_PTHREAD_H)
 286 check_include_files(dirent.h     HAVE_DIRENT_H)
 287 check_include_files(inttypes.h   HAVE_INTTYPES_H)
 288 check_include_files(regex.h      HAVE_REGEX_H)
 289 check_include_files(sys/types.h  HAVE_SYS_TYPES_H)
 290 check_include_files(sys/stat.h   HAVE_SYS_STAT_H)
 291 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 292 check_include_files(rpc/rpc.h    HAVE_RPC_RPC_H)
 293 check_include_files("rpc/rpc.h;rpc/xdr.h"    HAVE_RPC_XDR_H)
 294 # SSE support
 295 check_include_files(xmmintrin.h  HAVE_XMMINTRIN_H)
 296 check_include_files(emmintrin.h  HAVE_EMMINTRIN_H)
 297 check_include_files(pmmintrin.h  HAVE_PMMINTRIN_H)
 298 check_include_files(smmintrin.h  HAVE_SMMINTRIN_H)
 299 check_include_files(io.h                 HAVE_IO_H)
 300
 301
 302 include(CheckFunctionExists)
 303 check_function_exists(strcasecmp        HAVE_STRCASECMP)
 304 check_function_exists(strdup            HAVE_STRDUP)
 305 check_function_exists(vprintf           HAVE_VPRINTF)
 306 check_function_exists(memcmp            HAVE_MEMCMP)
 307 check_function_exists(posix_memalign    HAVE_POSIX_MEMALIGN)
 308 check_function_exists(memalign          HAVE_MEMALIGN)
 309 check_function_exists(_aligned_malloc   HAVE__ALIGNED_MALLOC)
 310 check_function_exists(gettimeofday      HAVE_GETTIMEOFDAY)
 311 check_function_exists(isnan             HAVE_ISNAN)
 312 check_function_exists(_isnan            HAVE__ISNAN)
 313 check_function_exists(isfinite          HAVE_ISFINITE)
 314 check_function_exists(_isfinite         HAVE__ISFINITE)
 315 check_function_exists(fsync             HAVE_FSYNC)
 316 check_function_exists(_fileno           HAVE__FILENO)
 317 check_function_exists(fileno            HAVE_FILENO)
 318 check_function_exists(_commit           HAVE__COMMIT)
 319
 320 include(CheckLibraryExists)
 321 check_library_exists(m sqrt "" HAVE_LIBM)
 322 check_library_exists(m cbrt "" HAVE_CBRT)
 323
 324
 325 include(CheckTypeSize)
 326
 327 check_type_size("bool"          SIZEOF_BOOL) # will also set HAVE_BOOL
 328 check_type_size("int"           SIZEOF_INT)
 329 check_type_size("long int"      SIZEOF_LONG_INT)
 330 check_type_size("long long int" SIZEOF_LONG_LONG_INT)
 331 check_type_size("off_t"         SIZEOF_OFF_T)
 332 check_type_size("void *"        SIZEOF_VOIDP)
 333
 334 if (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 335     set(GMX_64_BIT TRUE)
 336 else (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 337     set(GMX_64_BIT FALSE)
 338 endif (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 339
 340 # Check for some basic types that we *need*, so set these to int if they are not present
 341 check_type_size(uid_t uid_t)
 342 if(NOT uid_t)
 343   set(uid_t int)
 344 else(NOT uid_t)
 345   set(uid_t 0)
 346 endif(NOT uid_t)
 347
 348 check_type_size(gid_t gid_t)
 349 if(NOT gid_t)
 350   set(gid_t 1)
 351 else(NOT gid_t)
 352   set(gid_t 0)
 353 endif(NOT gid_t)
 354
 355 check_type_size(size_t size_t)
 356 if(NOT size_t)
 357   set(size_t int)
 358 else(NOT size_t)
 359   set(size_t 0)
 360 endif(NOT size_t)
 361
 362 check_type_size(off_t off_t)
 363 if(NOT off_t)
 364   set(off_t int)
 365 else(NOT off_t)
 366   set(off_t 0)
 367 endif(NOT off_t)
 368
 369 include(TestBigEndian)
 370 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 371
 372
 373
 374
 375 ########################################################################
 376 # Find external packages                                               #
 377 ########################################################################
 378 if(UNIX AND NOT APPLE)
 379     if(GMX_PREFER_STATIC_LIBS)
 380         SET(CMAKE_FIND_LIBRARY_SUFFIXES .a ${CMAKE_FIND_LIBRARY_SUFFIXES})
 381         if(BUILD_SHARED_LIBS)
 382             message(WARNING "Static libraries requested, the GROMACS libraries will also be build static (BUILD_SHARED_LIBS=OFF)")
 383             set(BUILD_SHARED_LIBS OFF CACHE BOOL "Enable shared libraries (can be problematic with MPI, Windows)" FORCE)
 384         endif()
 385     endif()
 386 endif()
 387
 388 option(GMX_XML "Use libxml2 to parse xml files" ON)
 389 if (GMX_XML)
 390   find_package(LibXml2)
 391   set(PKG_XML "")
 392   if(LIBXML2_FOUND)
 393     include_directories(${LIBXML2_INCLUDE_DIR})
 394     set(PKG_XML libxml-2.0)
 395     set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 396     set(HAVE_LIBXML2 1)
 397   endif(LIBXML2_FOUND)
 398 endif(GMX_XML)
 399
 400 option(GMX_GSL "Add support for gsl" OFF)
 401 if (GMX_GSL)
 402   find_package(gsl)
 403   set(PKG_GSL "")
 404   if(GSL_FOUND)
 405     include_directories(${GSL_INCLUDE_DIR})
 406     set(PKG_GSL gsl)
 407     set(HAVE_LIBGSL 1)
 408   endif(GSL_FOUND)
 409 endif (GMX_GSL)
 410
 411 option(GMX_X11 "Use X window system" OFF)
 412 if (GMX_X11)
 413         find_package(X11)
 414         # X11 includes/libraries are only set in the ngmx subdirectory!
 415         if(X11_FOUND)
 416         set(HAVE_X11 1)
 417         endif(X11_FOUND)
 418 endif(GMX_X11)
 419
 420 if(GMX_THREADS)
 421     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_THREADS")
 422     include(ThreadMPI)
 423     set(THREAD_MPI_LIB thread_mpi)
 424     set(GMX_MPI 1)
 425     string(TOUPPER ${GMX_FFT_LIBRARY} ${GMX_FFT_LIBRARY})
 426     if(${GMX_FFT_LIBRARY} STREQUAL "FFTW2")
 427         message(FATAL_ERROR "FFTW2 can't be used with threads. Try fftw3 or mkl.")
 428     endif()
 429 endif(GMX_THREADS)
 430
 431 if(GMX_OPENMM)
 432     set(CUDA_BUILD_EMULATION OFF)
 433     find_package(CUDA 3.1 REQUIRED)
 434     add_definitions(-DGMX_OPENMM)
 435     if(CMAKE_BUILD_TYPE STREQUAL "DEBUG")
 436         set(CUDA_VERBOSE_BUILD ON)
 437     endif()
 438     find_package(OpenMM)
 439 endif(GMX_OPENMM)
 440
 441 if(APPLE)
 442    find_library(ACCELERATE_FRAMEWORK Accelerate)
 443    list(APPEND GMX_EXTRA_LIBRARIES ${ACCELERATE_FRAMEWORK})
 444 endif(APPLE)
 445
 446 # only bother with finding git and using version.h if the source is a git repo
 447 if(EXISTS "${CMAKE_SOURCE_DIR}/.git")
 448     if(USE_VERSION_H)
 449         # We need at least git v1.5.1 be able to parse git's date output. If not
 450         # fund or the version is too small, we can't generate version information.
 451         find_package(Git 1.5.1)
 452         # this should at some point become VERSION_LESS
 453         if(NOT Git_FOUND OR Git_VERSION STRLESS "1.5.1")
 454             message("No compatible git version found, won't be able to generate proper development version information.")
 455             set(USE_VERSION_H OFF)
 456         endif()
 457     endif()
 458 else()
 459     set(USE_VERSION_H OFF)
 460 endif()
 461
 462 if (GMX_DLOPEN)
 463     list(APPEND GMX_EXTRA_LIBRARIES ${CMAKE_DL_LIBS})
 464 endif (GMX_DLOPEN)
 465
 466 ########################################################################
 467 # Generate development version info for cache
 468 ########################################################################
 469 # set(GEN_VERSION_INFO_INTERNAL "ON")
 470 # include(gmxGenerateVersionString)
 471
 472 ########################################################################
 473 # Our own GROMACS tests
 474 ########################################################################
 475
 476 add_definitions( -DHAVE_CONFIG_H )
 477 include_directories(${CMAKE_BINARY_DIR}/src)
 478 include_directories(${CMAKE_SOURCE_DIR}/include)
 479
 480 include(gmxCheckBuildUserTime)
 481 gmx_check_build_user_time(BUILD_TIME BUILD_USER BUILD_MACHINE)
 482
 483 include(gmxTestFloatFormat)
 484 gmx_test_float_format(GMX_FLOAT_FORMAT_IEEE754
 485                       GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER
 486                       GMX_IEEE754_BIG_ENDIAN_WORD_ORDER)
 487
 488 include(gmxTestLargeFiles)
 489 gmx_test_large_files(GMX_LARGEFILES)
 490 check_function_exists(fseeko     HAVE_FSEEKO)
 491
 492 include(gmxTestSignal)
 493 gmx_test_retsigtype(RETSIGTYPE)
 494 gmx_test_sigusr1(HAVE_SIGUSR1)
 495
 496 include(gmxTestInline)
 497 gmx_test_inline(INLINE_KEYWORD)
 498
 499 include(gmxTestRestrict)
 500 gmx_test_inline(RESTRICT_KEYWORD)
 501
 502 include(gmxTestPipes)
 503 gmx_test_pipes(HAVE_PIPES)
 504
 505 include(gmxTestInlineASM)
 506 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 507 gmx_test_inline_asm_msvc_x86(GMX_X86_MSVC_INLINE_ASM)
 508
 509 # turn on SSE if supported with reasonable defaults.
 510 if (${GMX_ACCELERATION} STREQUAL "auto" AND NOT GMX_OPENMM)
 511   if(CMAKE_SYSTEM_PROCESSOR MATCHES "^(i.86|x86|x64|x86_64|AMD64|amd64)")
 512
 513     set(GMX_ACCELERATION "SSE" CACHE STRING "Accelerated kernels. Pick one of: auto, none, SSE, BlueGene, Power6, ia64, altivec, fortran" FORCE)
 514
 515     if (GMX_64_BIT)
 516       set(GMX_X86_64_ASM ON CACHE BOOL "Add SSE assembly files for x86_64" FORCE)
 517     else (GMX_64_BIT)
 518       set(GMX_IA32_ASM ON CACHE BOOL "Add SSE assembly files for i386" FORCE)
 519     endif (GMX_64_BIT)
 520
 521     # Determine the assembler/compiler to use
 522   else()
 523     set(GMX_ACCELERATION "none" CACHE STRING "Accelerated kernels. Pick one of: auto, none, SSE, BlueGene, Power6, ia64, altivec, fortran" FORCE)
 524   endif()
 525 endif (${GMX_ACCELERATION} STREQUAL "auto" AND NOT GMX_OPENMM)
 526
 527 include(gmxTestXDR)
 528 gmx_test_xdr(GMX_SYSTEM_XDR)
 529 if(NOT GMX_SYSTEM_XDR)
 530     set(GMX_INTERNAL_XDR 1)
 531     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_INTERNAL_XDR")
 532 endif(NOT GMX_SYSTEM_XDR)
 533
 534 # Process nonbonded accelerated kernels settings
 535 string(TOUPPER ${GMX_ACCELERATION} ${GMX_ACCELERATION})
 536 if(${GMX_ACCELERATION} STREQUAL "NONE")
 537   # nothing to do
 538 elseif(${GMX_ACCELERATION} STREQUAL "SSE")
 539
 540     if(CMAKE_GENERATOR MATCHES "Visual Studio")
 541       option(GMX_ASM_USEASM-NASM "Use Nasm for assembly instead of compiler (necessary on windows)" ON)
 542     else()
 543       option(GMX_ASM_USEASM-NASM "Use Nasm for assembly instead of compiler (necessary on windows)" OFF)
 544     endif()
 545         mark_as_advanced(GMX_ASM_USEASM-NASM)
 546
 547     if (NOT GMX_64_BIT)
 548         # for 32-bit compiles, we might need to turn on sse
 549         CHECK_C_COMPILER_FLAG("-msse2" XFLAGS_SSE)
 550         if (XFLAGS_SSE)
 551             set(GROMACS_C_FLAGS "-msse2 ${GROMACS_C_FLAGS}")
 552         endif (XFLAGS_SSE)
 553         CHECK_CXX_COMPILER_FLAG("-msse2" XXFLAGS_SSE)
 554         if (XXFLAGS_SSE)
 555             set(GROMACS_CXX_FLAGS "-msse2 ${GROMACS_CXX_FLAGS}")
 556         endif (XXFLAGS_SSE)
 557     endif (NOT GMX_64_BIT)
 558
 559     if(GMX_IA32_ASM)
 560       if(GMX_DOUBLE)
 561         set(GMX_IA32_SSE2 1)
 562       else()
 563        set(GMX_IA32_SSE 1)
 564       endif()
 565     elseif(GMX_X86_64_ASM)
 566       if(GMX_DOUBLE)
 567        set(GMX_X86_64_SSE2 1)
 568       else()
 569         set(GMX_X86_64_SSE 1)
 570       endif()
 571     endif()
 572
 573 #    if(HAVE_PMMINTRIN_H)
 574 #        set(GMX_SSE3 1)
 575 #    endif(HAVE_PMMINTRIN_H)
 576 #    if(HAVE_SMMINTRIN_H)
 577 #        set(GMX_SSE4_1 1)
 578 #    endif(HAVE_SMMINTRIN_H)
 579
 580 elseif(${GMX_ACCELERATION} STREQUAL "FORTRAN")
 581     set(GMX_FORTRAN 1)
 582     #these are switch on by default sometimes
 583     set(GMX_IA32_ASM 0)
 584     set(GMX_GMX_X86_64_ASM 0)
 585 elseif(${GMX_ACCELERATION} STREQUAL "BLUEGENE")
 586 # GMX_ACCELERATION=BlueGene should be set in the Toolchain-BlueGene?-???.cmake file
 587     message(STATUS "Configuring for BlueGene")
 588     set(GMX_BLUEGENE 1)
 589     if (${CMAKE_SYSTEM_NAME} STREQUAL "BlueGeneL")
 590         set(SHARED_LIBS_DEFAULT OFF CACHE BOOL "Shared libraries not compatible with BlueGene/L, disabled!" FORCE)
 591         set(BUILD_SHARED_LIBS OFF CACHE BOOL "Shared libraries not compatible with BlueGene/L, disabled!" FORCE)
 592     endif (${CMAKE_SYSTEM_NAME} STREQUAL "BlueGeneL")
 593     set(GMX_SOFTWARE_INVSQRT OFF CACHE BOOL "Do not use software reciprocal square root on BlueGene" FORCE)
 594     set(GMX_POWERPC_INVSQRT ON CACHE BOOL "Use hardware reciprocal square root on BlueGene" FORCE)
 595     set(GMX_X11 OFF CACHE BOOL "X11 not compatible with BlueGene, disabled!" FORCE)
 596     set(GMX_THREADS OFF CACHE BOOL "Threads not compatible with BlueGene, disabled!" FORCE)
 597     set(GMX_MPI ON CACHE BOOL "Use MPI on BlueGene" FORCE)
 598     set(GMX_EXTERNAL_BLAS TRUE CACHE BOOL "Use MASSV for BLAS on BlueGene" FORCE)
 599     set(GMX_EXTERNAL_LAPACK TRUE CACHE BOOL "Use MASSV for LAPACK on BlueGene" FORCE)
 600     list(APPEND GMX_EXTRA_LIBRARIES massv)
 601 elseif(${GMX_ACCELERATION} STREQUAL "POWER6")
 602     set(GMX_POWER6 1)
 603     set(GMX_SOFTWARE_INVSQRT OFF CACHE BOOL "Do not use software reciprocal square root on Power6" FORCE)
 604     set(GMX_POWERPC_INVSQRT ON CACHE BOOL "Use hardware reciprocal square root on Power6" FORCE)
 605 elseif(${GMX_ACCELERATION} STREQUAL "IA64")
 606     set(GMX_IA64_ASM 1)
 607     set(DISABLE_WATERWATER_NLIST 1)
 608     set(DISABLE_WATER_NLIST 1)
 609 elseif(${GMX_ACCELERATION} STREQUAL "ALTIVEC")
 610     check_include_files(altivec.h HAVE_ALTIVEC_H)
 611     if(HAVE_ALTIVEC_H)
 612         set(GMX_PPC_ALTIVEC 1)
 613     endif(HAVE_ALTIVEC_H)
 614 else(${GMX_ACCELERATION} STREQUAL "NONE")
 615     MESSAGE(FATAL_ERROR "Unrecognized option for accelerated kernels: ${GMX_ACCELERATION}. Pick one of auto, none, SSE, Fortran, BlueGene, Power6, ia64, altivec")
 616 endif(${GMX_ACCELERATION} STREQUAL "NONE")
 617
 618 if(GMX_FORTRAN OR GMX_POWER6)
 619     if (GMX_THREADS)
 620         message(FATAL_ERROR "FORTRAN/POWER6 is incompatible with threads and only provides a speed-up on certain IBM compilers. Disable FORTRAN (or threads if you really want to use FORTRAN kernels).")
 621     endif(GMX_THREADS)
 622     enable_language(Fortran)
 623     include(FortranCInterface)
 624     discover_fortran_mangling(prefix isupper suffix extra_under_score found)
 625     if(extra_under_score)
 626         set(extrasuffix "_")
 627     endif(extra_under_score)
 628     if(prefix)
 629       set(prefix "${prefix} ##")
 630     endif(prefix)
 631
 632     if(isupper)
 633         set(F77_FUNCDEF   "${prefix} NAME ## ${suffix}")
 634         set(F77_FUNCDEF_  "${prefix} NAME ## ${suffix}${extrasuffix}")
 635     else(isupper)
 636         set(F77_FUNCDEF   "${prefix} name ## ${suffix}")
 637         set(F77_FUNCDEF_  "${prefix} name ## ${suffix}${extrasuffix}")
 638     endif(isupper)
 639 else(GMX_FORTRAN OR GMX_POWER6)
 640         set(F77_FUNCDEF   "name ## _")
 641         set(F77_FUNCDEF_  "name ## _")
 642 endif(GMX_FORTRAN OR GMX_POWER6)
 643
 644 # Process QM/MM Settings
 645 string(TOUPPER ${GMX_QMMM_PROGRAM} ${GMX_QMMM_PROGRAM})
 646 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 647     set(GMX_QMMM_GAUSSIAN 1)
 648 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 649     set(GMX_QMMM_MOPAC 1)
 650 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 651     set(GMX_QMMM_GAMESS 1)
 652 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 653     set(GMX_QMMM_ORCA 1)
 654 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 655     # nothing to do
 656 else(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 657     MESSAGE(FATAL_ERROR "Invalid QM/MM program option: ${GMX_QMMM_PROGRAM}. Choose one of: Gaussian, Mopac, Gamess, Orca, None")
 658 endif(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 659
 660 # Process FFT library settings - if not OpenMM build
 661 string(TOUPPER ${GMX_FFT_LIBRARY} ${GMX_FFT_LIBRARY})
 662 set(PKG_FFT "")
 663 set(PKG_FFT_LIBS "")
 664 if(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 665 #    MESSAGE(STATUS "Using external FFT library - fftw3")
 666     if(GMX_DOUBLE)
 667         find_package(FFTW3 REQUIRED)
 668                 include_directories(${FFTW3_INCLUDE_DIR})
 669         set(FFT_LIBRARIES ${FFTW3_LIBRARIES})
 670         set(PKG_FFT "fftw3")
 671     else(GMX_DOUBLE)
 672         find_package(FFTW3F REQUIRED)
 673         include_directories(${FFTW3F_INCLUDE_DIR})
 674         set(FFT_LIBRARIES ${FFTW3F_LIBRARIES})
 675         set(PKG_FFT "fftw3f")
 676     endif(GMX_DOUBLE)
 677
 678     if(NOT FFTW3_FOUND AND NOT FFTW3F_FOUND)
 679         MESSAGE(FATAL_ERROR "Cannot find fftw3 (with correct precision). Fix it, choose another FFT library, or use the Gromacs built-in fftpack (slower)!")
 680     endif(NOT FFTW3_FOUND AND NOT FFTW3F_FOUND)
 681
 682     set(GMX_FFT_FFTW3 1)
 683
 684 elseif(${GMX_FFT_LIBRARY} STREQUAL "FFTW2")
 685 #    MESSAGE(STATUS "Using external FFT library - fftw2")
 686     if(GMX_DOUBLE)
 687         find_package(FFTW2 REQUIRED)
 688     else(GMX_DOUBLE)
 689         find_package(FFTW2F REQUIRED)
 690     endif(GMX_DOUBLE)
 691
 692     if(NOT FFTW2_FOUND)
 693            MESSAGE(FATAL_ERROR "Cannot find fftw2 (with correct precision). Fix it, choose another FFT library, or use the Gromacs built-in fftpack (slower)!")
 694     endif(NOT FFTW2_FOUND)
 695     include_directories(${FFTW2_INCLUDE_DIR})
 696     set(FFT_LIBRARIES ${FFTW2_LIBRARIES})
 697     set(PKG_FFT_LIBS ${FFTW2_LIBRARIES})
 698
 699     if("${FFTW2_LIBRARIES}" MATCHES "dfftw")
 700         set(FFTW2_NAME_DFFTW 1)
 701     elseif("${FFTW2_LIBRARIES}" MATCHES "sfftw")
 702         set(FFTW2_NAME_SFFTW 1)
 703     else("${FFTW2_LIBRARIES}" MATCHES "dfftw")
 704         set(FFTW2_NAME_FFTW 1)
 705     endif("${FFTW2_LIBRARIES}" MATCHES "dfftw")
 706
 707     set(GMX_FFT_FFTW2 1)
 708 elseif(${GMX_FFT_LIBRARY} STREQUAL "MKL")
 709 #    MESSAGE(STATUS "Using external FFT library - Intel MKL")
 710     find_package(MKL REQUIRED)
 711     include_directories(${MKL_INCLUDE_DIR})
 712     set(FFT_LIBRARIES ${MKL_LIBRARIES})
 713     set(PKG_FFT_LIBS ${MKL_LIBRARIES})
 714
 715     set(GMX_FFT_MKL 1)
 716     set(HAVE_MKL 1)
 717
 718 #elseif(${GMX_FFT_LIBRARY} STREQUAL "ACML")
 719 #    MESSAGE(STATUS "Using external FFT library - AMD core math library")
 720 #    set(GMX_FFT_ACML 1)
 721 elseif(${GMX_FFT_LIBRARY} STREQUAL "FFTPACK")
 722     MESSAGE(STATUS "Using internal FFT library - fftpack")
 723     set(GMX_FFT_FFTPACK 1)
 724 else(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 725     MESSAGE(FATAL_ERROR "Invalid FFT library setting: ${GMX_FFT_LIBRARY}. Choose one of: fftw3, fftw2, mkl, acml, fftpack")
 726 endif(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 727
 728 # MKL has BLAS/LAPACK routines
 729 if(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 730   set(GMX_EXTERNAL_BLAS TRUE CACHE BOOL "Use external BLAS instead of built-in")
 731   set(GMX_EXTERNAL_LAPACK TRUE CACHE BOOL "Use external LAPACK instead of built-in")
 732 else(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 733   set(GMX_EXTERNAL_BLAS FALSE CACHE BOOL "Use external LAPACK instead of built-in")
 734   set(GMX_EXTERNAL_LAPACK FALSE CACHE BOOL "Use external LAPACK instead of built-in")
 735   if(GMX_EXTERNAL_BLAS)
 736     #FindBLAS needs Fortran
 737     enable_language(Fortran)
 738     find_package(BLAS REQUIRED)
 739     list(APPEND GMX_EXTRA_LIBRARIES ${BLAS_LIBRARIES})
 740   endif(GMX_EXTERNAL_BLAS)
 741   if(GMX_EXTERNAL_LAPACK)
 742     #FindLAPACK needs Fortran
 743     enable_language(Fortran)
 744     find_package(LAPACK REQUIRED)
 745     list(APPEND GMX_EXTRA_LIBRARIES ${LAPACK_LIBRARIES})
 746   endif(GMX_EXTERNAL_LAPACK)
 747 endif(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 748 mark_as_advanced(GMX_EXTERNAL_LAPACK)
 749 mark_as_advanced(GMX_EXTERNAL_BLAS)
 750
 751 # Math and thread libraries must often come after all others when linking...
 752 if(HAVE_LIBM)
 753     list(APPEND GMX_EXTRA_LIBRARIES m)
 754 endif(HAVE_LIBM)
 755
 756 if(GMX_FAHCORE)
 757   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 758       "Path to swindirect.h")
 759   include_directories(${COREWRAP_INCLUDE_DIR})
 760 endif(GMX_FAHCORE)
 761
 762 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 763 # these are set after everything else
 764 if (NOT DEFINED GROMACS_C_FLAGS_SET)
 765     set(GROMACS_C_FLAGS_SET true CACHE INTERNAL "Whether to reset the C flags"
 766         FORCE)
 767     set(CMAKE_C_FLAGS "${GROMACS_C_FLAGS} ${CMAKE_C_FLAGS}" CACHE STRING
 768         "Flags used by the compiler during all build types" FORCE)
 769     set(CMAKE_CXX_FLAGS "${GROMACS_CXX_FLAGS} ${CMAKE_CXX_FLAGS}" CACHE STRING
 770         "Flags used by the compiler during all build types" FORCE)
 771     set(CMAKE_EXE_LINKER_FLAGS
 772         "${GROMACS_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}"
 773         CACHE STRING "Linker flags" FORCE)
 774 endif (NOT DEFINED GROMACS_C_FLAGS_SET)
 775
 776 ########################################################################
 777 # Specify install locations and which subdirectories to process        #
 778 ########################################################################
 779 if ( DEFINED LIB )
 780     set(LIB_INSTALL_DIR "${CMAKE_INSTALL_PREFIX}/${LIB}")
 781 else()
 782     set(LIB_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/lib)
 783 endif()
 784 set(BIN_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/bin)
 785 set(DATA_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/gromacs)
 786 set(MAN_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/share/man)
 787 set(INCL_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/include)
 788
 789 set(GMXLIBDIR        ${DATA_INSTALL_DIR}/top)
 790
 791 ##################################################################
 792 # Shared library settings - Darwin uses INSTALL_NAME_DIR instead!
 793 ##################################################################
 794 if(NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin")
 795     set(CMAKE_SKIP_BUILD_RPATH  FALSE)
 796     set(CMAKE_BUILD_WITH_INSTALL_RPATH FALSE)
 797     set(CMAKE_INSTALL_RPATH "${LIB_INSTALL_DIR}")
 798     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 799 endif()
 800
 801 add_subdirectory(share)
 802 add_subdirectory(include)
 803 add_subdirectory(man)
 804 add_subdirectory(src)
 805 add_subdirectory(scripts)
 806
 807 #######################
 808 ## uninstall target
 809 #######################
 810     CONFIGURE_FILE(
 811                    "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 812                    "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
 813                    IMMEDIATE @ONLY)
 814 ###########################
 815 ADD_CUSTOM_TARGET(uninstall
 816                   "${CMAKE_COMMAND}" -P
 817                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
 818 ###########################
 819
 820
 821 ########################################################################
 822 # Tests                                                                #
 823 ########################################################################
 824
 825 include(CTest)
 826 mark_as_advanced(BUILD_TESTING)
 827 IF(BUILD_TESTING)
 828         enable_testing()
 829         add_test(TestBuildAll make)
 830         add_subdirectory(tests)
 831 ENDIF()
 832