CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2009,2010,2011,2012,2013,2014, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 cmake_minimum_required(VERSION 2.8.8)
  36 # When we require cmake >= 2.8.12, it will provide
  37 # CMAKE_MINIMUM_REQUIRED_VERSION automatically, but in the meantime we
  38 # need to set a variable, and it must have a different name.
  39 set(GMX_CMAKE_MINIMUM_REQUIRED_VERSION "2.8.8")
  40
  41 # CMake modules/macros are in a subdirectory to keep this file cleaner
  42 # This needs to be set before project() in order to pick up toolchain files
  43 list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake ${CMAKE_CURRENT_SOURCE_DIR}/cmake/Platform)
  44
  45 project(Gromacs)
  46
  47 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  48 set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  49 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
  50
  51 # PROJECT_VERSION should have the following structure:
  52 # VERSION-dev[-SUFFIX] where the VERSION should have the for: vMajor.vMinor.vPatch
  53 #
  54 # The "-dev" suffix is important to keep because it makes possible to distinguish
  55 # between a build from official release and a build from git release branch on a
  56 # machine with no git.
  57 #
  58 # NOTE: when releasing the "-dev" suffix needs to be stripped off!
  59 # REGRESSIONTEST_VERSION and REGRESSIONTEST_BRANCH should always be
  60 # defined.
  61 set(PROJECT_VERSION "5.1-dev")
  62 # If this is a released tarball, "-dev" will not be present in
  63 # PROJECT_VERSION, and REGRESSIONTEST_VERSION specifies the version
  64 # number of the regressiontest tarball against which the code tarball
  65 # can be tested. This will be the version of the last patch release.
  66 set(REGRESSIONTEST_VERSION "5.0.1-dev")
  67 # If this is not a released tarball, "-dev" will be present in
  68 # PROJECT_VERSION, and REGRESSIONTEST_BRANCH specifies the name of the
  69 # gerrit.gromacs.org branch whose HEAD can test this code, *if* this
  70 # code contains all recent fixes from the corresponding code branch.
  71 set(REGRESSIONTEST_BRANCH "refs/heads/master")
  72
  73 set(CUSTOM_VERSION_STRING ""
  74     CACHE STRING "Custom version string (if empty, use hard-coded default)")
  75 mark_as_advanced(CUSTOM_VERSION_STRING)
  76 if (CUSTOM_VERSION_STRING)
  77     set(PROJECT_VERSION ${CUSTOM_VERSION_STRING})
  78 endif()
  79 set(LIBRARY_SOVERSION 0)
  80 set(LIBRARY_VERSION ${LIBRARY_SOVERSION}.0.0)
  81 # It is a bit irritating, but this has to be set separately for now!
  82 SET(CPACK_PACKAGE_VERSION_MAJOR "5")
  83 SET(CPACK_PACKAGE_VERSION_MINOR "1")
  84 #SET(CPACK_PACKAGE_VERSION_PATCH "0")
  85
  86 # The numerical gromacs version. It is 40600 for 4.6.0.
  87 # The #define GMX_VERSION in gromacs/version.h is set to this value.
  88 math(EXPR NUM_VERSION
  89     "${CPACK_PACKAGE_VERSION_MAJOR}*10000 + ${CPACK_PACKAGE_VERSION_MINOR}*100")
  90 if(CPACK_PACKAGE_VERSION_PATCH)
  91     math(EXPR NUM_VERSION
  92          "${NUM_VERSION} + ${CPACK_PACKAGE_VERSION_PATCH}")
  93 endif()
  94
  95 # The API version tracks the numerical Gromacs version (for now).
  96 # It is potentially different from the Gromacs version in the future, if
  97 # the programs/libraries diverge from the presumably more stable API.
  98 # The #define GMX_API_VERSION in version.h is set to this value to
  99 # provide backward compatibility of software written against the Gromacs API.
 100 set(API_VERSION ${NUM_VERSION})
 101
 102 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT AND UNIX)
 103     set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
 104 endif()
 105
 106 include(gmxBuildTypeReference)
 107 include(gmxBuildTypeProfile)
 108 include(gmxBuildTypeTSAN)
 109 include(gmxBuildTypeASAN)
 110 include(gmxBuildTypeReleaseWithAssert)
 111
 112 if(NOT CMAKE_BUILD_TYPE)
 113     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel Reference RelWithAssert Profile." FORCE)
 114     # There's no need to offer a user the choice of ThreadSanitizer
 115     # Set the possible values of build type for cmake-gui
 116     set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "Debug" "Release"
 117         "MinSizeRel" "RelWithDebInfo" "Reference" "RelWithAssert" "Profile")
 118 endif()
 119 if(CMAKE_CONFIGURATION_TYPES)
 120     # Add appropriate GROMACS-specific build types for the Visual
 121     # Studio generator (Debug, Release, MinSizeRel and RelWithDebInfo
 122     # are already present by default).
 123     list(APPEND CMAKE_CONFIGURATION_TYPES "RelWithAssert" "Reference")
 124     list(REMOVE_DUPLICATES CMAKE_CONFIGURATION_TYPES)
 125     set(CMAKE_CONFIGURATION_TYPES "${CMAKE_CONFIGURATION_TYPES}" CACHE STRING
 126         "List of configuration types"
 127         FORCE)
 128 endif()
 129 set(build_types_with_explicit_flags RELEASE DEBUG RELWITHDEBUGINFO RELWITHASSERT MINSIZEREL PROFILE)
 130
 131 enable_language(C)
 132 enable_language(CXX)
 133
 134 set(CPACK_PACKAGE_VERSION ${PROJECT_VERSION})
 135 set(CPACK_PACKAGE_VENDOR "gromacs.org")
 136 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Gromacs - a toolkit for high-performance molecular simulation")
 137 set(CPACK_RESOURCE_FILE_WELCOME "${CMAKE_SOURCE_DIR}/admin/InstallWelcome.txt")
 138 # Its GPL/LGPL, so they do not have to agree to a license for mere usage, but some installers require this...
 139 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_SOURCE_DIR}/COPYING")
 140 set(CPACK_RESOURCE_FILE_README "${CMAKE_SOURCE_DIR}/admin/InstallInfo.txt")
 141 set(CPACK_SOURCE_IGNORE_FILES "\\\\.isreposource$;\\\\.git/;\\\\.gitignore$")
 142 set(CPACK_PROJECT_CONFIG_FILE "${CMAKE_SOURCE_DIR}/CPackInit.cmake")
 143 set(CPACK_SOURCE_INSTALLED_DIRECTORIES "${CMAKE_SOURCE_DIR};/;${CMAKE_BINARY_DIR}/src/programs/completion;src/programs/completion;${CMAKE_BINARY_DIR}/share/man/man1;share/man/man1;${CMAKE_BINARY_DIR}/share/man/man7;share/man/man7;${CMAKE_BINARY_DIR}/share/html/final;share/html/final")
 144 set(CPACK_PACKAGE_CONTACT "gmx-users@gromacs.org")
 145
 146 #must come after all cpack settings!
 147 include(CPack)
 148
 149 # Set a default valgrind suppression file.
 150 # This unfortunately needs to duplicate information from CTest to work as
 151 # expected...
 152 set(MEMORYCHECK_SUPPRESSIONS_FILE
 153     "${CMAKE_SOURCE_DIR}/cmake/legacy_and_external.supp"
 154     CACHE FILEPATH
 155     "File that contains suppressions for the memory checker")
 156 include(CTest)
 157
 158 set(SOURCE_IS_GIT_REPOSITORY OFF)
 159 set(SOURCE_IS_SOURCE_DISTRIBUTION OFF)
 160 if(EXISTS "${CMAKE_SOURCE_DIR}/.git")
 161     set(SOURCE_IS_GIT_REPOSITORY ON)
 162 endif()
 163 if(NOT EXISTS "${CMAKE_SOURCE_DIR}/admin/.isreposource")
 164     set(SOURCE_IS_SOURCE_DISTRIBUTION ON)
 165 endif()
 166
 167 ########################################################################
 168 # Check and warn if cache generated on a different host is being reused
 169 ########################################################################
 170 if(CMAKE_HOST_UNIX)
 171     execute_process(COMMAND hostname
 172                     OUTPUT_VARIABLE TMP_HOSTNAME
 173                     OUTPUT_STRIP_TRAILING_WHITESPACE)
 174     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}")
 175         message(WARNING "
 176             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
 177             is being reused! This could lead to inconsitencies; therefore, it is
 178             recommended to regenerate the cache!")
 179     endif()
 180     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
 181             "Hostname of the machine where the cache was generated.")
 182 endif()
 183
 184 ########################################################################
 185 # User input options                                                   #
 186 ########################################################################
 187 include(gmxOptionUtilities)
 188
 189 set(CMAKE_PREFIX_PATH "" CACHE STRING "Extra locations to search for external libraries and tools (give directory without lib, bin, or include)")
 190
 191 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" OFF)
 192 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 193 option(GMX_THREAD_MPI  "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" ON)
 194 gmx_dependent_option(
 195     GMX_MPI_IN_PLACE
 196     "Enable MPI_IN_PLACE for MPIs that have it defined"
 197     ON
 198     GMX_MPI)
 199 mark_as_advanced(GMX_MPI_IN_PLACE)
 200 option(GMX_SOFTWARE_INVSQRT "Use GROMACS software 1/sqrt" ON)
 201 mark_as_advanced(GMX_SOFTWARE_INVSQRT)
 202 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 203 mark_as_advanced(GMX_FAHCORE)
 204
 205 option(GMX_COOL_QUOTES "Enable Gromacs cool quotes" ON)
 206 mark_as_advanced(GMX_COOL_QUOTES)
 207 gmx_add_cache_dependency(GMX_COOL_QUOTES BOOL "NOT GMX_FAHCORE" OFF)
 208
 209 # Decide on GPU settings based on user-settings and GPU/CUDA detection.
 210 # We support CUDA >=v4.0 on *nix, but <= v4.1 doesn't work with MSVC
 211 if(MSVC)
 212     set(REQUIRED_CUDA_VERSION 4.1)
 213 else()
 214     set(REQUIRED_CUDA_VERSION 4.0)
 215 endif()
 216 set(REQUIRED_CUDA_COMPUTE_CAPABILITY 2.0)
 217 include(gmxManageGPU)
 218
 219 # Detect the architecture the compiler is targetting, detect
 220 # SIMD instructions possibilities on that hardware, suggest SIMD instruction set
 221 # to use if none is specified, and populate the cache option for CPU
 222 # SIMD.
 223 include(gmxDetectTargetArchitecture)
 224 gmx_detect_target_architecture()
 225
 226 if(GMX_CPU_ACCELERATION)
 227     # Stay compatible with old Jenkins command line options for specific SIMD acceleration
 228     set(GMX_SIMD "${GMX_CPU_ACCELERATION}" CACHE STRING "SIMD instruction set level and compiler optimization" FORCE)
 229     message("You set GMX_CPU_ACCELERATION, which is deprecated, and will be removed in a later version of GROMACS. It is replaced by GMX_SIMD. For now, copying the value from GMX_CPU_ACCELERATION to GMX_SIMD.")
 230     # TODO remove all references to GMX_CPU_ACCELERATION in master branch
 231 endif()
 232
 233 if(NOT GMX_TARGET_MIC)
 234     include(gmxDetectSimd)
 235     gmx_detect_simd(GMX_SUGGESTED_SIMD)
 236 else()
 237     set(GMX_SUGGESTED_SIMD "None")
 238 endif()
 239
 240 gmx_option_multichoice(
 241     GMX_SIMD
 242     "SIMD instruction set for CPU kernels and compiler optimization"
 243     "${GMX_SUGGESTED_SIMD}"
 244     None SSE2 SSE4.1 AVX_128_FMA AVX_256 AVX2_256 IBM_QPX Sparc64_HPC_ACE Reference)
 245
 246 gmx_option_multichoice(
 247     GMX_FFT_LIBRARY
 248     "FFT library"
 249     "fftw3"
 250     fftw3 mkl "fftpack[built-in]")
 251 gmx_dependent_option(
 252     GMX_BUILD_OWN_FFTW
 253     "Download and build FFTW 3 during the GROMACS build process, rather than fall back on the really slow fftpack."
 254     OFF
 255     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 256 gmx_dependent_option(
 257     GMX_DISABLE_FFTW_MEASURE
 258     "Do not optimize FFTW setups (not needed with SSE)"
 259     OFF
 260     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 261 mark_as_advanced(GMX_BUILD_OWN_FFTW)
 262 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 263
 264 gmx_option_multichoice(
 265     GMX_QMMM_PROGRAM
 266     "QM package for QM/MM"
 267     None
 268     none gaussian mopac gamess orca)
 269
 270 gmx_dependent_cache_variable(GMX_SIMD_REF_FLOAT_WIDTH  "Reference SIMD single precision width" STRING "4" "GMX_SIMD STREQUAL REFERENCE")
 271 gmx_dependent_cache_variable(GMX_SIMD_REF_DOUBLE_WIDTH "Reference SIMD double precision width" STRING "2" "GMX_SIMD STREQUAL REFERENCE")
 272
 273 # This should be moved to a separate NBNXN cmake module when that code is cleaned up and modularized
 274
 275 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 276 mark_as_advanced(GMX_BROKEN_CALLOC)
 277 option(GMX_LOAD_PLUGINS "Compile with plugin support, needed to read VMD supported file formats" ON)
 278 mark_as_advanced(GMX_LOAD_PLUGINS)
 279
 280 option(GMX_GPU  "Enable GPU acceleration" ON)
 281 option(GMX_OPENMP "Enable OpenMP-based multithreading" ON)
 282
 283 option(GMX_USE_TNG "Use the TNG library for trajectory I/O" ON)
 284
 285 option(GMX_GIT_VERSION_INFO "Generate git version information" ${SOURCE_IS_GIT_REPOSITORY})
 286 mark_as_advanced(GMX_GIT_VERSION_INFO)
 287
 288 if(UNIX)
 289     option(GMX_SYMLINK_OLD_BINARY_NAMES "Create symbolic links for pre-5.0 binary names" ON)
 290 endif()
 291 option(GMX_BUILD_MDRUN_ONLY "Build and install only the mdrun binary" OFF)
 292
 293 option(GMX_CYCLE_SUBCOUNTERS "Enable cycle subcounters to get a more detailed cycle timings" OFF)
 294 mark_as_advanced(GMX_CYCLE_SUBCOUNTERS)
 295
 296 option(GMX_SKIP_DEFAULT_CFLAGS "Don't automatically add suggested/required Compiler flags." OFF)
 297 mark_as_advanced(GMX_SKIP_DEFAULT_CFLAGS)
 298
 299 option(GMX_BUILD_FOR_COVERAGE
 300        "Tune build for better code coverage metrics (e.g., disable asserts)"
 301        OFF)
 302 mark_as_advanced(GMX_BUILD_FOR_COVERAGE)
 303
 304
 305 ######################################################################
 306 # Detect OpenMP support
 307 ######################################################################
 308 # The OpenMP detection _must_ come before tests for other CFLAGS.
 309 include(gmxManageOpenMP)
 310
 311
 312
 313 ######################################################################
 314 # Compiler tests
 315 # These need to be done early (before further tests).
 316 #####################################################################
 317
 318 # The cmake/Check{C,CXX}CompilerFlag.cmake files in the GROMACS distribution
 319 # are used with permission from CMake v2.8.9 so that GROMACS can detect
 320 # invalid options with the Intel Compilers.
 321 # These files should be removed from the source tree when a CMake version that
 322 # includes the features in question becomes required for building GROMACS.
 323 include(CheckCCompilerFlag)
 324 include(CheckCXXCompilerFlag)
 325
 326
 327 include(gmxCFlags)
 328 gmx_c_flags()
 329
 330 # This variable should be used for additional compiler flags which are not
 331 # generated in gmxCFlags nor are SIMD or MPI related.
 332 set(EXTRA_C_FLAGS "")
 333 set(EXTRA_CXX_FLAGS "")
 334
 335 # Run through a number of tests for buggy compilers and other issues
 336 include(gmxTestCompilerProblems)
 337 gmx_test_compiler_problems()
 338 # GMX_SIMD will not be set automatically until the second
 339 # pass (which is not strictly guaranteed to occur), so putting this
 340 # check here among logically-related tests is inefficient, but the
 341 # potential loss is likely zero.
 342 if(GMX_SIMD STREQUAL "AVX_256"
 343         AND CMAKE_COMPILER_IS_GNUCC
 344         AND (C_COMPILER_VERSION VERSION_EQUAL "4.6.1"
 345             OR CXX_COMPILER_VERSION VERSION_EQUAL "4.6.1"))
 346     message(FATAL_ERROR "gcc 4.6.1 has buggy support for AVX, and GROMACS mdrun will not work. If you want simulation performance, use a more recent compiler. Otherwise, use GMX_SIMD=SSE4.1")
 347     # See http://gcc.gnu.org/bugzilla/show_bug.cgi?id=49002
 348 endif()
 349
 350
 351
 352 set(PKG_CFLAGS "")
 353 if(GMX_DOUBLE)
 354     add_definitions(-DGMX_DOUBLE)
 355     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_DOUBLE")
 356 endif()
 357 if(GMX_SOFTWARE_INVSQRT)
 358   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_SOFTWARE_INVSQRT")
 359 endif()
 360
 361 if(WIN32 AND NOT CYGWIN)
 362     set(GMX_WSOCKLIB_PATH CACHE PATH "Path to winsock (wsock32.lib) library.")
 363     mark_as_advanced(GMX_WSOCKLIB_PATH)
 364     find_library(WSOCK32_LIBRARY NAMES wsock32 PATHS ${GMX_WSOCKLIB_PATH})
 365     if(WSOCK32_LIBRARY)
 366         list(APPEND GMX_EXTRA_LIBRARIES ${WSOCK32_LIBRARY})
 367         add_definitions(-DGMX_HAVE_WINSOCK)
 368     else()
 369         message(STATUS "No winsock found. Cannot use interactive molecular dynamics (IMD).")
 370     endif(WSOCK32_LIBRARY)
 371 endif()
 372
 373
 374
 375 ########################################################################
 376 # Basic system tests (standard libraries, headers, functions, types)   #
 377 ########################################################################
 378 include(CheckIncludeFiles)
 379 include(CheckIncludeFileCXX)
 380 check_include_files(unistd.h     HAVE_UNISTD_H)
 381 check_include_files(pwd.h        HAVE_PWD_H)
 382 check_include_files(dirent.h     HAVE_DIRENT_H)
 383 check_include_files(time.h       HAVE_TIME_H)
 384 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 385 check_include_files(io.h         HAVE_IO_H)
 386 check_include_files(sched.h      HAVE_SCHED_H)
 387
 388 check_include_files(regex.h      HAVE_POSIX_REGEX)
 389 check_include_file_cxx(regex     HAVE_CXX11_REGEX)
 390 # TODO: It could be nice to inform the user if no regex support is found,
 391 # as selections won't be fully functional.
 392
 393 include(CheckFunctionExists)
 394 check_function_exists(posix_memalign    HAVE_POSIX_MEMALIGN)
 395 check_function_exists(memalign          HAVE_MEMALIGN)
 396 check_function_exists(_aligned_malloc   HAVE__ALIGNED_MALLOC)
 397 check_function_exists(gettimeofday      HAVE_GETTIMEOFDAY)
 398 check_function_exists(fsync             HAVE_FSYNC)
 399 check_function_exists(_fileno           HAVE__FILENO)
 400 check_function_exists(fileno            HAVE_FILENO)
 401 check_function_exists(_commit           HAVE__COMMIT)
 402 check_function_exists(sigaction         HAVE_SIGACTION)
 403 check_function_exists(sysconf           HAVE_SYSCONF)
 404 check_function_exists(sched_setaffinity HAVE_SCHED_SETAFFINITY)
 405 check_function_exists(sched_getaffinity HAVE_SCHED_GETAFFINITY)
 406 check_function_exists(rsqrt             HAVE_RSQRT)
 407 check_function_exists(rsqrtf            HAVE_RSQRTF)
 408 check_function_exists(sqrtf             HAVE_SQRTF)
 409
 410 include(CheckLibraryExists)
 411 check_library_exists(m sqrt "" HAVE_LIBM)
 412 check_library_exists(rt clock_gettime "" HAVE_CLOCK_GETTIME)
 413
 414 include(TestBigEndian)
 415 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 416
 417 # Management of GROMACS options for specific toolchains should go
 418 # here. Because the initial settings for some of the main options have
 419 # already happened, but things like library detection and MPI compiler
 420 # feature detection have not, the docstrings for any over-rides of
 421 # GROMACS defaults or user settings will make sense. Also, any
 422 # toolchain-related reasons for choosing whether to detect various
 423 # things can be sorted out now, before the detection takes place.
 424 if(${CMAKE_SYSTEM_NAME} MATCHES BlueGene)
 425     include(gmxManageBlueGene)
 426 endif()
 427
 428 ########################################################################
 429 #Process MPI settings
 430 ########################################################################
 431 include(gmxManageMPI)
 432
 433
 434 ########################################################################
 435 #Process shared/static library settings
 436 ########################################################################
 437 include(gmxManageSharedLibraries)
 438
 439
 440 ########################################################################
 441 # Find external packages                                               #
 442 ########################################################################
 443
 444 # Unconditionally find the package, as it is also required for unit
 445 # tests. This exports LIBXML2_FOUND, which we should not use because
 446 # it does not tell us that linking will succeed. Instead, we test that
 447 # next.
 448 find_package(LibXml2)
 449 include(gmxTestLibXml2)
 450 gmx_test_libxml2(HAVE_LIBXML2)
 451 option(GMX_XML "Use libxml2 to parse xml files (currently has no effect)" ${HAVE_LIBXML2})
 452 set(PKG_XML "")
 453 mark_as_advanced(GMX_XML)
 454 # Don't actually do anything, since libxml2 is currently not used by libgromacs
 455 #if(GMX_XML AND NOT HAVE_LIBXML2)
 456 #    message(FATAL_ERROR "libxml2 not found. Set GMX_XML=OFF to compile without XML support")
 457 #endif()
 458 #if(GMX_XML)
 459 #    include_directories(${LIBXML2_INCLUDE_DIR})
 460 #    set(PKG_XML libxml-2.0)
 461 #    set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 462 #endif()
 463
 464 option(GMX_EXTRAE "Add support for tracing using EXTRAE" OFF)
 465 mark_as_advanced(GMX_EXTRAE)
 466
 467 if (GMX_EXTRAE)
 468   find_package(EXTRAE)
 469   if(EXTRAE_FOUND)
 470     include_directories(${EXTRAE_INCLUDE_DIR})
 471     set(HAVE_EXTRAE 1)
 472   else()
 473     message(FATAL_ERROR "EXTRAE library was not found. Please add the correct path to CMAKE_PREFIX_PATH")
 474   endif()
 475 endif()
 476
 477 option(GMX_X11 "Use X window system" OFF)
 478 if (GMX_X11)
 479     find_package(X11)
 480     # X11 includes/libraries are only set in the ngmx subdirectory!
 481     if(NOT X11_FOUND)
 482         message(FATAL_ERROR
 483                 "X11 include files and/or libraries were not found. "
 484                 "Set GMX_X11=OFF to compile without X11 support. "
 485                 "gmx view will not be available.")
 486     endif()
 487     include_directories(${X11_INCLUDE_DIR})
 488 endif()
 489
 490 include(ThreadMPI)
 491 # Enable core threading facilities
 492 tmpi_enable_core("${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include")
 493 # Enable tMPI C++ support
 494 tmpi_enable_cxx()
 495 if(GMX_THREAD_MPI)
 496     # enable MPI functions
 497     tmpi_enable()
 498     set(GMX_MPI 1)
 499     set(MPI_IN_PLACE_EXISTS 1)
 500 endif()
 501 # If atomics are manually disabled a define is needed because atomics.h doesn't depend on config.h
 502 if (TMPI_ATOMICS_DISABLED)
 503    add_definitions(-DTMPI_ATOMICS_DISABLED)
 504 endif()
 505
 506 if(GMX_GPU)
 507     # now that we have detected the dependencies, do the second configure pass
 508     gmx_gpu_setup()
 509 endif()
 510
 511 if(CYGWIN)
 512     set(GMX_CYGWIN 1)
 513 endif()
 514
 515 if(WIN32 AND NOT CYGWIN)
 516     set(GMX_NATIVE_WINDOWS 1)
 517     # This makes windows.h not declare min/max as macros that would break
 518     # C++ code using std::min/std::max.
 519     add_definitions(-DNOMINMAX)
 520 endif()
 521
 522 # only bother with finding git and using version.h if the source is a git repo
 523 if(GMX_GIT_VERSION_INFO)
 524     if (NOT SOURCE_IS_GIT_REPOSITORY)
 525         message(FATAL_ERROR
 526             "Cannot generate git version information from source tree not under git. "
 527             "Set GMX_GIT_VERSION_INFO=OFF to proceed.")
 528     endif()
 529     # We need at least git v1.5.3 be able to parse git's date output. If not
 530     # found or the version is too small, we can't generate version information.
 531     find_package(Git)
 532
 533     if(NOT GIT_FOUND OR GIT_VERSION_STRING VERSION_LESS "1.5.3")
 534         message(FATAL_ERROR
 535             "No compatible git version found (>= 1.5.3 required). "
 536             "Won't be able to generate development version information. "
 537             "Set GMX_GIT_VERSION_INFO=OFF to proceed.")
 538     endif()
 539 endif()
 540
 541 # Detect boost unless GMX_EXTERNAL_BOOST is explicitly OFF
 542 # Used for default if GMX_EXTERNAL_BOOST is not defined (first CMake pass)
 543 if(NOT DEFINED GMX_EXTERNAL_BOOST OR GMX_EXTERNAL_BOOST)
 544     find_package(Boost 1.44.0)
 545     if(Boost_FOUND AND Boost_VERSION VERSION_LESS "104400")
 546         set(Boost_FOUND FALSE)
 547     endif()
 548     # Print the notification only on first run, when determining the default
 549     if(NOT DEFINED GMX_EXTERNAL_BOOST AND NOT Boost_FOUND)
 550         message("Boost >= 1.44 not found. Using minimal internal version. "
 551                 "This may cause trouble if you plan on compiling/linking other "
 552                 "software that uses Boost against Gromacs.")
 553     endif()
 554 endif()
 555 option(GMX_EXTERNAL_BOOST "Use external Boost instead of minimal built-in version"
 556        ${Boost_FOUND})
 557 if(GMX_EXTERNAL_BOOST AND NOT Boost_FOUND)
 558     message(FATAL_ERROR
 559         "Boost >= 1.44 not found. "
 560         "You can set GMX_EXTERNAL_BOOST=OFF to compile against minimal "
 561         "version of Boost included with Gromacs.")
 562 endif()
 563
 564 if(NOT DEFINED GMX_BUILD_UNITTESTS AND NOT HAVE_LIBXML2)
 565     message(WARNING "libxml2 not found. Will build GROMACS without unit-tests. This is not recommended, because the unit-tests help to verify that GROMACS functions correctly. Most likely you are missing the libxml2-dev(el) package. After you installed it, set GMX_BUILD_UNITTESTS=ON.")
 566 endif()
 567 option(GMX_BUILD_UNITTESTS "Build unit tests with BUILD_TESTING (uses Google C++ Testing and Mocking Frameworks, requires libxml2)" ${HAVE_LIBXML2})
 568 mark_as_advanced(GMX_BUILD_UNITTESTS)
 569 gmx_add_cache_dependency(GMX_BUILD_UNITTESTS BOOL BUILD_TESTING OFF)
 570 if (GMX_BUILD_UNITTESTS AND NOT HAVE_LIBXML2)
 571     message(FATAL_ERROR
 572         "Cannot build unit tests without libxml2. "
 573         "Either set GMX_BUILD_UNITTESTS=OFF or tell CMake how to find a working version of libxml2.")
 574 endif()
 575
 576 ########################################################################
 577 # Generate development version info for cache
 578 ########################################################################
 579 # set(GEN_VERSION_INFO_INTERNAL "ON")
 580 # include(gmxGenerateVersionString)
 581
 582 ########################################################################
 583 # Our own GROMACS tests
 584 ########################################################################
 585
 586 add_definitions( -DHAVE_CONFIG_H )
 587 include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src)
 588 include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include)
 589 # Required for config.h, maybe should only be set in src/CMakeLists.txt
 590 include_directories(BEFORE ${CMAKE_BINARY_DIR}/src)
 591 # Required for gmx_header_config_gen.h to be found before installation
 592 include_directories(BEFORE ${CMAKE_BINARY_DIR}/src/gromacs/utility)
 593 # Required for now to make old code compile
 594 include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src/gromacs/legacyheaders)
 595
 596 include(gmxTestInlineASM)
 597 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 598
 599 include(gmxSetBuildInformation)
 600 gmx_set_build_information()
 601 # Turn on RDTSCP if:
 602 # - the build system's CPU supports it
 603 # - the acceleration is set to AVX as all AVX-capable CPUs support AVX (which
 604 #   at this point means that the user set it).
 605 # Note: it's better to not use the later set value of GMX_SIMD because
 606 # it reflects the system's capability of both compiling and running AVX code.
 607 # TODO: After merge with 5.0 one could implement a cache variable dependency
 608 # such that GMX_USE_RDTSCP can change if GMX_SIMD is changed to AVX
 609 # after the first cmake pass.
 610 if (BUILD_CPU_FEATURES MATCHES "rdtscp" OR GMX_SIMD MATCHES "AVX")
 611     set(GMX_USE_RDTSCP_DEFAULT_VALUE ON)
 612 else()
 613     set(GMX_USE_RDTSCP_DEFAULT_VALUE OFF)
 614 endif()
 615 option(GMX_USE_RDTSCP "Use RDTSCP for better CPU-based timers (available on recent x86 CPUs; might need to be off when compiling for heterogeneous environments)" ${GMX_USE_RDTSCP_DEFAULT_VALUE})
 616 mark_as_advanced(GMX_USE_RDTSCP)
 617 if(GMX_USE_RDTSCP)
 618     set(HAVE_RDTSCP 1)
 619 endif()
 620
 621 include(gmxTestFloatFormat)
 622 gmx_test_float_format(GMX_FLOAT_FORMAT_IEEE754
 623                       GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER
 624                       GMX_IEEE754_BIG_ENDIAN_WORD_ORDER)
 625
 626 include(gmxTestLargeFiles)
 627 gmx_test_large_files(GMX_LARGEFILES)
 628
 629 include(gmxTestSignal)
 630 gmx_test_sigusr1(HAVE_SIGUSR1)
 631
 632 include(gmxTestPipes)
 633 gmx_test_pipes(HAVE_PIPES)
 634
 635 include(gmxTestIsfinite)
 636 gmx_test_isfinite(HAVE_ISFINITE)
 637 gmx_test__isfinite(HAVE__ISFINITE)
 638 gmx_test__finite(HAVE__FINITE)
 639
 640 include(gmxTestCXX11)
 641 gmx_test_cxx11(GMX_CXX11_SUPPORTED GMX_CXX11_FLAGS)
 642 include(CMakeDependentOption)
 643 # nvcc does not support C++11 flags, so with GPUs we prefer to skip C++11 flags
 644 # entirely to keep the compilation environment uniform.
 645 cmake_dependent_option(GMX_CXX11
 646     "Use C++11 features"
 647     ON "GMX_CXX11_SUPPORTED AND NOT GMX_GPU" OFF)
 648 mark_as_advanced(GMX_CXX11)
 649 if(GMX_CXX11)
 650     set(EXTRA_CXX_FLAGS "${EXTRA_CXX_FLAGS} ${GMX_CXX11_FLAGS}")
 651 endif()
 652
 653
 654 include(gmxTestXDR)
 655 gmx_test_xdr(GMX_SYSTEM_XDR)
 656 if(NOT GMX_SYSTEM_XDR)
 657     set(GMX_INTERNAL_XDR 1)
 658 endif()
 659
 660
 661 ##################################################
 662 # Process SIMD instruction settings
 663 ##################################################
 664 # This checks what flags to add in order to
 665 # support the SIMD instructions we need, and sets
 666 # correct defines for the SIMD instructions supported.
 667 include(gmxTestSimd)
 668 gmx_test_simd()
 669
 670
 671 # Process QM/MM Settings
 672 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 673     set(GMX_QMMM_GAUSSIAN 1)
 674 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 675     set(GMX_QMMM_MOPAC 1)
 676 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 677     set(GMX_QMMM_GAMESS 1)
 678 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 679     set(GMX_QMMM_ORCA 1)
 680 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 681     # nothing to do
 682 else()
 683     gmx_invalid_option_value(GMX_QMMM_PROGRAM)
 684 endif()
 685
 686
 687 ##################################################
 688 # Process FFT library settings
 689 ##################################################
 690 include(gmxManageFFTLibraries)
 691
 692
 693 include(gmxManageLinearAlgebraLibraries)
 694
 695 # Whether GROMACS will really try to compile support for VMD plugins
 696 set(GMX_USE_PLUGINS OFF)
 697
 698 if(GMX_LOAD_PLUGINS)
 699   if(CYGWIN OR NOT WIN32)
 700     # Native Windows does not have, nor need dlopen
 701     # Note that WIN32 is set with Cygwin, but Cygwin needs dlopen to use plug-ins
 702     include(gmxTestdlopen)
 703     gmx_test_dlopen(HAVE_DLOPEN)
 704   endif()
 705
 706   # so, should we use plug-ins?
 707   if((WIN32 AND NOT CYGWIN) OR (HAVE_DLOPEN AND BUILD_SHARED_LIBS))
 708     if(NOT VMD_QUIETLY)
 709       MESSAGE(STATUS
 710           "Found the ability to use plug-ins when building shared libaries, "
 711           "so will compile to use plug-ins (e.g. to read VMD-supported file "
 712           "formats).")
 713     endif()
 714     if(NOT GMX_VMD_PLUGIN_PATH)
 715       find_package(VMD)
 716     endif()
 717     set(GMX_USE_PLUGINS ON)
 718     list(APPEND GMX_EXTRA_LIBRARIES ${CMAKE_DL_LIBS}) # magic cross-platform pre-set variable for dlopen library
 719     set(PKG_DL_LIBS "-l${CMAKE_DL_LIBS}")
 720   else()
 721     set(PKG_DL_LIBS)
 722   endif()
 723 endif()
 724 set(VMD_QUIETLY TRUE CACHE INTERNAL "")
 725
 726 # Link real-time library for POSIX timers. The check for clock_gettime
 727 # confirms the linkability of rt.
 728 if(HAVE_TIME_H AND HAVE_UNISTD_H AND HAVE_CLOCK_GETTIME)
 729     list(APPEND GMX_EXTRA_LIBRARIES rt)
 730 endif()
 731
 732 # Math and thread libraries must often come after all others when linking...
 733 if(HAVE_LIBM)
 734     list(APPEND GMX_EXTRA_LIBRARIES m)
 735 endif()
 736
 737 option(GMX_NACL "Configure for Native Client builds" OFF)
 738 if (GMX_NACL)
 739   list(APPEND GMX_EXTRA_LIBRARIES nosys)
 740   set(GMX_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -lnosys")
 741   set(GMX_NO_NICE 1)
 742   set(GMX_NO_RENAME 1)
 743 endif()
 744 mark_as_advanced(GMX_NACL)
 745
 746 if(GMX_FAHCORE)
 747   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 748       "Path to swindirect.h")
 749   include_directories(${COREWRAP_INCLUDE_DIR})
 750 endif()
 751
 752 option(GMX_BUILD_HELP "Build man pages, HTML help, and completions automatically (requires that compiled binaries can be executed on the build host)" OFF)
 753 mark_as_advanced(GMX_BUILD_HELP)
 754 if (GMX_BUILD_HELP AND SOURCE_IS_SOURCE_DISTRIBUTION AND
 755     "${CMAKE_CURRENT_SOURCE_DIR}" STREQUAL "${CMAKE_CURRENT_BINARY_DIR}")
 756
 757     message(FATAL_ERROR
 758         "Rebuilding HTML and man pages is not supported for in-source "
 759         "builds from a source distribution. "
 760         "Set GMX_BUILD_HELP=OFF or do an out-of-source build to proceed.")
 761 endif()
 762
 763 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 764 # these are set after everything else
 765 if (NOT GMX_SKIP_DEFAULT_CFLAGS)
 766     set(CMAKE_C_FLAGS "${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${CMAKE_C_FLAGS}")
 767     set(CMAKE_CXX_FLAGS "${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${CMAKE_CXX_FLAGS}")
 768     set(CMAKE_EXE_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}")
 769     set(CMAKE_SHARED_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS}")
 770 else()
 771     message("Recommended flags which are not added because GMX_SKIP_DEFAULT_CFLAGS=yes:")
 772     message("CMAKE_C_FLAGS: ${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${GMXC_CFLAGS}")
 773     message("CMAKE_C_FLAGS_RELEASE: ${GMXC_CFLAGS_RELEASE}")
 774     message("CMAKE_C_FLAGS_DEBUG: ${GMXC_CFLAGS_DEBUG}")
 775     message("CMAKE_CXX_FLAGS: ${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${GMXC_CXXFLAGS}")
 776     message("CMAKE_CXX_FLAGS_RELEASE: ${GMXC_CXXFLAGS_RELEASE}")
 777     message("CMAKE_CXX_FLAGS_DEBUG: ${GMXC_CXXFLAGS_DEBUG}")
 778     message("CMAKE_EXE_LINKER_FLAGS: ${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS}")
 779     message("CMAKE_SHARED_LINKER_FLAGS: ${MPI_LINKER_FLAGS}")
 780 endif()
 781
 782 if(NOT GMX_OPENMP)
 783     #Unset all OpenMP flags in case OpenMP was disabled either by the user
 784     #or because it was only partially detected (e.g. only for C but not C++ compiler)
 785     unset(OpenMP_C_FLAGS CACHE)
 786     unset(OpenMP_CXX_FLAGS CACHE)
 787 else()
 788     set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} ${OpenMP_LINKER_FLAGS})
 789     set(GMX_SHARED_LINKER_FLAGS ${GMX_SHARED_LINKER_FLAGS} ${OpenMP_SHARED_LINKER_FLAGS})
 790 endif()
 791 set(PKG_CFLAGS "${PKG_CFLAGS} ${OpenMP_C_FLAGS}")
 792
 793 ########################################################################
 794 # Specify install locations
 795 ########################################################################
 796 # Use GNUInstallDirs to set paths on multiarch systems.
 797 include(GNUInstallDirs)
 798
 799 # Customization for the installation tree paths.
 800 set(GMX_LIB_INSTALL_DIR ${CMAKE_INSTALL_LIBDIR} CACHE STRING
 801     "Library installation directory (default: ${CMAKE_INSTALL_LIBDIR})")
 802 set(GMX_DATA_INSTALL_DIR gromacs CACHE STRING
 803     "Data installation directory under share/ (default: gromacs)")
 804 mark_as_advanced(GMX_LIB_INSTALL_DIR GMX_DATA_INSTALL_DIR)
 805
 806 # These variables are used internally to provide a central location for
 807 # customizing the install locations.
 808 set(LIB_INSTALL_DIR  ${GMX_LIB_INSTALL_DIR})
 809 set(BIN_INSTALL_DIR  bin)
 810 set(DATA_INSTALL_DIR share/${GMX_DATA_INSTALL_DIR})
 811 set(MAN_INSTALL_DIR  share/man)
 812 set(INCL_INSTALL_DIR include)
 813
 814 # These variables get written into config.h for use in finding the data
 815 # directories.
 816 set(GMXLIB_SEARCH_DIR share/${GMX_DATA_INSTALL_DIR}/top)
 817 set(GMXLIB_FALLBACK   ${CMAKE_INSTALL_PREFIX}/${DATA_INSTALL_DIR}/top)
 818
 819 # Binary and library suffix options
 820 include(gmxManageSuffixes)
 821
 822 ################################################################
 823 # Shared library load path settings
 824 ################################################################
 825 # CMake supports RPATH on OS X only from 2.8.12 upwards.
 826 # CMAKE_SYSTEM_VERSION > 8.0 matches OS X 10.5 and above, where RPATH support
 827 # was added.
 828 if((NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin") OR
 829    ((CMAKE_SYSTEM_VERSION VERSION_GREATER 8.0) AND (NOT CMAKE_VERSION VERSION_LESS 2.8.12)))
 830     # The build folder always has bin/ and lib/; if we are also going to
 831     # install to lib/, then the installation RPATH works also in the build
 832     # tree.  This makes installation slightly faster (no need to rewrite the
 833     # RPATHs), and makes the binaries in the build tree relocatable.
 834     if(GMX_LIB_INSTALL_DIR STREQUAL "lib")
 835         set(CMAKE_BUILD_WITH_INSTALL_RPATH TRUE)
 836     endif()
 837     # Set the RPATH as relative to the executable location to make the
 838     # binaries relocatable.
 839     if(NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin")
 840         set(CMAKE_INSTALL_RPATH "\$ORIGIN/../${GMX_LIB_INSTALL_DIR}")
 841     else()
 842         set(CMAKE_INSTALL_RPATH "@executable_path/../${GMX_LIB_INSTALL_DIR}")
 843     endif()
 844     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 845     set(CMAKE_MACOSX_RPATH 1)
 846 else()
 847     # We are on Darwin/OSX, and CMake cannot handle RPATHs automatically.
 848     if(CMAKE_SYSTEM_VERSION VERSION_GREATER 8.0)
 849         # Set the RPATH options manually.
 850         set(CMAKE_INSTALL_NAME_DIR "@rpath")
 851         set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} "-Wl,-rpath,@executable_path/../${GMX_LIB_INSTALL_DIR}")
 852     else()
 853         # Use the old INSTALL_NAME_DIR mechanism if RPATH is not supported.
 854         set(CMAKE_INSTALL_NAME_DIR "${CMAKE_INSTALL_PREFIX}/${LIB_INSTALL_DIR}")
 855     endif()
 856 endif()
 857
 858 #COPYING file: Only necessary for binary distributions.
 859 #Simpler to always install.
 860 install(FILES COPYING DESTINATION ${DATA_INSTALL_DIR} COMPONENT data)
 861
 862 if(GMX_EXTERNAL_BOOST)
 863     include_directories(${Boost_INCLUDE_DIRS})
 864     set(PKG_CFLAGS "${PKG_CFLAGS} -I${Boost_INCLUDE_DIRS}")
 865 else()
 866     include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src/external/boost)
 867     # typeid not supported for minimal internal version
 868     # (would add significant amount of code)
 869     add_definitions(-DBOOST_NO_TYPEID)
 870     # TODO: Propagate the above settings to the installed CMakeFiles.txt template
 871     # (from share/template/)
 872     set(PKG_CFLAGS "${PKG_CFLAGS} -DBOOST_NO_TYPEID -I${CMAKE_INSTALL_PREFIX}/${INCL_INSTALL_DIR}/gromacs/external/boost")
 873     if (NOT GMX_BUILD_MDRUN_ONLY)
 874         install(DIRECTORY ${CMAKE_SOURCE_DIR}/src/external/boost/boost
 875                 DESTINATION ${INCL_INSTALL_DIR}/gromacs/external/boost
 876                 COMPONENT development)
 877     endif()
 878 endif()
 879
 880 if (GMX_BUILD_FOR_COVERAGE)
 881     # Code heavy with asserts makes conditional coverage close to useless metric,
 882     # as by design most of the false branches are impossible to trigger in
 883     # correctly functioning code.  And the benefit of testing those that could
 884     # be triggered by using an API against its specification isn't usually
 885     # worth the effort.
 886     add_definitions(-DNDEBUG -DBOOST_DISABLE_ASSERTS -DGMX_DISABLE_ASSERTS)
 887 endif()
 888
 889 if (BUILD_TESTING)
 890     # "tests" target builds all the separate test binaries.
 891     add_custom_target(tests)
 892     # "run-ctest" is an internal target that actually runs the tests.
 893     # This is necessary to be able to add separate targets that execute as part
 894     # of 'make check', but are ensured to be executed after the actual tests.
 895     add_custom_target(run-ctest
 896                       COMMAND ${CMAKE_CTEST_COMMAND} --output-on-failure
 897                       COMMENT "Running all tests"
 898                       VERBATIM)
 899     add_dependencies(run-ctest tests)
 900     # "check" target builds and runs all tests.
 901     add_custom_target(check DEPENDS run-ctest)
 902 endif()
 903
 904 if (NOT GMX_BUILD_MDRUN_ONLY)
 905     add_subdirectory(doxygen)
 906     add_subdirectory(install-guide)
 907     add_subdirectory(share)
 908     add_subdirectory(scripts)
 909 endif()
 910 add_subdirectory(src)
 911
 912 if (BUILD_TESTING)
 913     add_subdirectory(tests)
 914 endif()
 915
 916 # Issue a warning if NVIDIA GPUs were detected, but CUDA was not found.
 917 # Don't bother the user after the first configure pass.
 918 if ((CUDA_NOTFOUND_AUTO AND GMX_DETECT_GPU_AVAILABLE) AND NOT GMX_GPU_DETECTION_DONE)
 919     message(WARNING "${CUDA_NOTFOUND_MESSAGE}")
 920 endif()
 921 set(GMX_GPU_DETECTION_DONE TRUE CACHE INTERNAL "Whether GPU detection has already been done")
 922
 923 #######################
 924 ## uninstall target
 925 #######################
 926 CONFIGURE_FILE(   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 927                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
 928                   IMMEDIATE @ONLY)
 929 ###########################
 930 ADD_CUSTOM_TARGET(uninstall
 931                   "${CMAKE_COMMAND}" -P
 932                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
 933 ###########################
 934 set_directory_properties(PROPERTIES
 935             ADDITIONAL_MAKE_CLEAN_FILES "install_manifest.txt")
 936
 937 ########################################################################
 938 # Manual                                                               #
 939 ########################################################################
 940
 941 option(GMX_BUILD_MANUAL "Whether to try to configure to build the PDF manual" OFF)
 942 mark_as_advanced(GMX_BUILD_MANUAL)
 943 if(GMX_BUILD_MANUAL)
 944     # Make sure we only do detection of manual-building dependencies
 945     # when the user opted in for that.
 946     add_subdirectory(manual)
 947 endif()