CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.8)
   2 # Keep CMake suitably quiet on Cygwin
   3 set(CMAKE_LEGACY_CYGWIN_WIN32 0) # Remove when CMake >= 2.8.4 is required
   4
   5 # Allows CPack to act differently for normal tools and mdrun (e.g. because of MPI)
   6 set(CPACK_COMPONENT_GROUP_TOOLS_DESCRIPTION "All GROMACS executable tools")
   7 set(CPACK_COMPONENT_GROUP_MDRUN_DESCRIPTION "GROMACS executable for running simulations")
   8
   9 # override bugs on OS X where Cmake picks gcc (GNU) for C instead of system default cc (Clang).
  10 if(APPLE)
  11     set(CMAKE_C_COMPILER_INIT "cc")
  12 endif(APPLE)
  13
  14 project(Gromacs C)
  15 include(Dart)
  16 mark_as_advanced(DART_ROOT)
  17
  18 # PROJECT_VERSION should have the following structure:
  19 # VERSION-dev[-SUFFIX] where the VERSION should have the for: vMajor.vMinor.vPatch
  20 #
  21 # The "-dev" suffix is important to keep because it makes possible to distinguish
  22 # between a build from official release and a build from git release branch on a
  23 # machine with no git.
  24 #
  25 # NOTE: when releasing the "-dev" suffix needs to be stripped off!
  26 set(PROJECT_VERSION "4.6-dev")
  27 set(CUSTOM_VERSION_STRING ""
  28     CACHE STRING "Custom version string (if empty, use hard-coded default)")
  29 mark_as_advanced(CUSTOM_VERSION_STRING)
  30 if (CUSTOM_VERSION_STRING)
  31     set(PROJECT_VERSION ${CUSTOM_VERSION_STRING})
  32 endif (CUSTOM_VERSION_STRING)
  33 set(SOVERSION 6)
  34 # It is a bit irritating, but this has to be set separately for now!
  35 SET(CPACK_PACKAGE_VERSION_MAJOR "4")
  36 SET(CPACK_PACKAGE_VERSION_MINOR "6")
  37 #SET(CPACK_PACKAGE_VERSION_PATCH "0")
  38
  39 # The numerical gromacs version. It is 40600 for 4.6.0.
  40 # The #define GMX_VERSION in gmx_header_config_h is set to this value.
  41 math(EXPR NUM_VERSION
  42     "${CPACK_PACKAGE_VERSION_MAJOR}*10000 + ${CPACK_PACKAGE_VERSION_MINOR}*100")
  43 if(CPACK_PACKAGE_VERSION_PATCH)
  44     math(EXPR NUM_VERSION
  45          "${NUM_VERSION} + ${CPACK_PACKAGE_VERSION_PATCH}")
  46 endif()
  47
  48 # The API version tracks the numerical Gromacs version (for now).
  49 # It is potentially different from the Gromacs version in the future, if
  50 # the programs/libraries diverge from the presumably more stable API.
  51 # The #define GMX_API_VERSION in version.h is set to this value to
  52 # provide backward compatibility of software written against the Gromacs API.
  53 set(API_VERSION ${NUM_VERSION})
  54
  55 # Cmake modules/macros are in a subdirectory to keep this file cleaner
  56 set(CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake)
  57
  58 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT AND UNIX)
  59 set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
  60 endif()
  61
  62 if(NOT CMAKE_BUILD_TYPE)
  63     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel." FORCE)
  64 endif(NOT CMAKE_BUILD_TYPE)
  65
  66 enable_language(C)
  67
  68 set(GMX_USE_RELATIVE_INSTALL_PATH OFF CACHE STRING "Use relative paths not absolute paths for cmake install. Has only an effect on cpack.")
  69 mark_as_advanced(GMX_USE_RELATIVE_INSTALL_PATH)
  70
  71 set(CPACK_PACKAGE_VERSION ${PROJECT_VERSION})
  72 set(CPACK_PACKAGE_VENDOR "gromacs.org")
  73 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Gromacs - a toolkit for high-performance molecular simulation")
  74 if (NOT GMX_USE_RELATIVE_INSTALL_PATH)
  75     set(CPACK_SET_DESTDIR "ON")
  76 endif()
  77 set(CPACK_RESOURCE_FILE_WELCOME "${CMAKE_SOURCE_DIR}/admin/InstallWelcome.txt")
  78 # Its GPL/LGPL, so they do not have to agree to a license for mere usage, but some installers require this...
  79 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_SOURCE_DIR}/COPYING")
  80 set(CPACK_RESOURCE_FILE_README "${CMAKE_SOURCE_DIR}/admin/InstallInfo.txt")
  81 set(CPACK_SOURCE_IGNORE_FILES ".isreposource;.git;.gitignore")
  82 set(CPACK_PROJECT_CONFIG_FILE "${CMAKE_SOURCE_DIR}/CPackInit.cmake")
  83 SET(CPACK_SOURCE_INSTALLED_DIRECTORIES "${CMAKE_SOURCE_DIR};/;${CMAKE_BINARY_DIR}/man;man")
  84 set(CPACK_PACKAGE_CONTACT "gmx-users@gromacs.org")
  85
  86 #must come after all cpack settings!
  87 include(CPack)
  88
  89 ########################################################################
  90 # Check and warn if cache generated on a different host is being reused
  91 ########################################################################
  92 if(CMAKE_HOST_UNIX)
  93     execute_process(COMMAND hostname
  94                     OUTPUT_VARIABLE TMP_HOSTNAME
  95                     OUTPUT_STRIP_TRAILING_WHITESPACE)
  96     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}")
  97         message(WARNING "
  98             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
  99             is being reused! This could lead to inconsitencies; therefore, it is
 100             recommended to regenerate the cache!")
 101     endif()
 102     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
 103             "Hostname of the machine where the cache was generated.")
 104 endif()
 105
 106 ########################################################################
 107 # User input options - enable C++ - before any CXX flags are changed   #
 108 ########################################################################
 109 option(GMX_GPU  "Enable GPU acceleration" ON)
 110 option(GMX_OPENMM "Accelerated execution on GPUs through the OpenMM library (rerun cmake after changing to see relevant options)" OFF)
 111 option(GMX_FORCE_CXX "Enable C++ compilation even if not necessary" OFF)
 112 mark_as_advanced(GMX_FORCE_CXX)
 113 if(GMX_GPU OR GMX_OPENMM OR GMX_FORCE_CXX)
 114     enable_language(CXX)
 115 endif()
 116
 117 ########################################################################
 118 # Fix stupid flags on Windows
 119 ########################################################################
 120 SET(SHARED_LIBS_DEFAULT ON)
 121 IF( WIN32 AND NOT CYGWIN)
 122   option(GMX_PREFER_STATIC_LIBS "When finding libraries prefer static system libraries (MT instead of MD)!" ON)
 123   mark_as_advanced(GMX_PREFER_STATIC_LIBS)
 124   SET(SHARED_LIBS_DEFAULT OFF)  #is currently not working on Windows
 125
 126   IF (GMX_PREFER_STATIC_LIBS)
 127     #Only setting Debug and Release flags. Others configurations current not used.
 128     STRING(REPLACE /MD /MT CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE})
 129     SET(CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE} CACHE STRING "" FORCE)
 130     STRING(REPLACE /MD /MT CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG})
 131     SET(CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG} CACHE STRING "" FORCE)
 132     if(CMAKE_CXX_COMPILER_LOADED)
 133         STRING(REPLACE /MD /MT CMAKE_CXX_FLAGS_RELEASE ${CMAKE_CXX_FLAGS_RELEASE})
 134         SET(CMAKE_CXX_FLAGS_RELEASE ${CMAKE_CXX_FLAGS_RELEASE} CACHE STRING "" FORCE)
 135         STRING(REPLACE /MD /MT CMAKE_CXX_FLAGS_DEBUG ${CMAKE_CXX_FLAGS_DEBUG})
 136         SET(CMAKE_CXX_FLAGS_DEBUG ${CMAKE_CXX_FLAGS_DEBUG} CACHE STRING "" FORCE)
 137     endif()
 138   ENDIF()
 139
 140   #Workaround for cmake bug 13174. Replace deprecated options.
 141   IF( CMAKE_C_COMPILER_ID MATCHES "Intel" )
 142     STRING(REPLACE /GZ /RTC1 CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG})
 143     SET(CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG} CACHE STRING "" FORCE)
 144   ENDIF()
 145   IF( CMAKE_CXX_COMPILER_ID MATCHES "Intel" AND CMAKE_CXX_COMPILER_LOADED)
 146     STRING(REPLACE /GZ /RTC1 CMAKE_CXX_FLAGS_DEBUG ${CMAKE_CXX_FLAGS_DEBUG})
 147     STRING(REPLACE /GX /EHsc CMAKE_CXX_FLAGS_DEBUG ${CMAKE_CXX_FLAGS_DEBUG})
 148     SET(CMAKE_CXX_FLAGS_DEBUG ${CMAKE_CXX_FLAGS_DEBUG} CACHE STRING "" FORCE)
 149
 150     STRING(REPLACE /GX /EHsc CMAKE_CXX_FLAGS_RELEASE ${CMAKE_CXX_FLAGS_RELEASE})
 151     SET(CMAKE_CXX_FLAGS_RELEASE ${CMAKE_CXX_FLAGS_RELEASE} CACHE STRING "" FORCE)
 152   ENDIF()
 153 ENDIF()
 154
 155
 156 ########################################################################
 157 # User input options                                                   #
 158 ########################################################################
 159 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" OFF)
 160 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 161 option(GMX_THREAD_MPI  "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" ON)
 162 option(GMX_SOFTWARE_INVSQRT "Use GROMACS software 1/sqrt" ON)
 163 mark_as_advanced(GMX_SOFTWARE_INVSQRT)
 164 option(GMX_POWERPC_INVSQRT "Use PowerPC hardware 1/sqrt" OFF)
 165 mark_as_advanced(GMX_POWERPC_INVSQRT)
 166 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 167 mark_as_advanced(GMX_FAHCORE)
 168
 169 include(gmxDetectAcceleration)
 170 if(NOT DEFINED GMX_ACCELERATION)
 171     if(CMAKE_CROSSCOMPILING)
 172         set(GMX_SUGGESTED_ACCELERATION "None")
 173     else(CMAKE_CROSSCOMPILING)
 174         gmx_detect_acceleration(GMX_SUGGESTED_ACCELERATION)
 175     endif(CMAKE_CROSSCOMPILING)
 176 endif(NOT DEFINED GMX_ACCELERATION)
 177
 178 set(GMX_ACCELERATION "@GMX_SUGGESTED_ACCELERATION@"
 179     CACHE STRING "Accelerated kernels. Pick one of: None, SSE2, SSE4.1, AVX_128_FMA, AVX_256, BlueGene, Power6, Fortran")
 180
 181 set(GMX_FFT_LIBRARY "fftw3"
 182     CACHE STRING "FFT library choices: fftw3,mkl,fftpack[built-in]")
 183 option(GMX_DISABLE_FFTW_MEASURE
 184        "Do not optimize FFTW setups (not needed with SSE)" OFF)
 185 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 186 set(GMX_QMMM_PROGRAM "none"
 187     CACHE STRING "QM package choices: none,gaussian,mopac,gamess,orca")
 188 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 189 mark_as_advanced(GMX_BROKEN_CALLOC)
 190 option(GMX_MPI_IN_PLACE "Enable MPI_IN_PLACE for MPIs that have it defined" ON)
 191 mark_as_advanced(GMX_MPI_IN_PLACE)
 192 option(GMX_LOAD_PLUGINS "Compile with plugin support, needed to read VMD supported file formats" ON)
 193 mark_as_advanced(GMX_LOAD_PLUGINS)
 194
 195 option(GMX_OPENMP "Enable OpenMP-based multithreading" ON)
 196
 197 option(USE_VERSION_H "Generate development version string/information" ON)
 198 mark_as_advanced(USE_VERSION_H)
 199
 200 option(GMX_DEFAULT_SUFFIX "Use default suffixes for GROMACS binaries and libs (_d for double, _mpi for MPI; rerun cmake after changing to see relevant options)" ON)
 201
 202 if(UNIX)
 203     option(GMX_PREFER_STATIC_LIBS "When finding libraries prefer static archives (not available on non-*nix platforms and it will only work if static versions of external dependencies are available and found)!" OFF)
 204     mark_as_advanced(GMX_PREFER_STATIC_LIBS)
 205 endif()
 206
 207 option(GMX_CYCLE_SUBCOUNTERS "Enable cycle subcounters to get a more detailed cycle timings" OFF)
 208 mark_as_advanced(GMX_CYCLE_SUBCOUNTERS)
 209
 210 ######################################################################
 211 # compiler tests
 212 # these need ot be done early (before further tests).
 213 #####################################################################
 214
 215 # cmake/Check{C,CXX}CompilerFlag.cmake are lifted from CMake git next
 216 # branch (proposed for v2.8.9) to be able to detect invalid options
 217 # with the Intel Compilers.
 218 # Remove these files from the source tree when a CMake version that
 219 # includes the features in question becomes required.
 220 include(CheckCCompilerFlag)
 221 if(CMAKE_CXX_COMPILER_LOADED)
 222     include(CheckCXXCompilerFlag)
 223 endif()
 224
 225 # OpenMP check must come before other CFLAGS!
 226 if(GMX_OPENMP)
 227     find_package(OpenMP)
 228     if(OPENMP_FOUND)
 229         #- only set linker flag, if user didn't set them manual
 230         #- cmake on windows doesn't support linker flags passed to target_link_libraries
 231         #  (cmake treats /openmp as \openmp library file) and no openmp linker flags are needed
 232         if(NOT (WIN32 AND NOT CYGWIN))
 233             if(CMAKE_COMPILER_IS_GNUCC AND GMX_PREFER_STATIC_OPENMP)
 234                 set(OpenMP_LINKER_FLAGS "-Wl,-static -lgomp -lrt -Wl,-Bdynamic -lpthread")
 235                 set(OpenMP_SHARED_LINKER_FLAGS "")
 236             else()
 237                 if(NOT DEFINED OpenMP_LINKER_FLAGS)
 238                     set(OpenMP_LINKER_FLAGS "${OpenMP_C_FLAGS}")
 239                 endif()
 240                 if(NOT DEFINED OpenMP_SHARED_LINKER_FLAGS)
 241                     set(OpenMP_SHARED_LINKER_FLAGS "${OpenMP_C_FLAGS}")
 242                 endif()
 243             endif()
 244         endif()
 245     else(OPENMP_FOUND)
 246         message(WARNING
 247                 "Compiler not supporting OpenMP. This might hurt your performance a lot, "
 248                 "in particular with GPUs. Try using a different compiler (Intel is good on x86) "
 249                 "if you can - for now we are proceeding by turning off OpenMP.")
 250         set(GMX_OPENMP OFF CACHE STRING "Compiler does not support OpenMP." FORCE)
 251     endif(OPENMP_FOUND)
 252 endif()
 253
 254
 255 include(gmxCFlags)
 256 gmx_c_flags()
 257
 258 include(gmxGetCompilerVersion)
 259 get_compiler_version()
 260
 261 # gcc 4.4.x is buggy and crashes when compiling some files with O3 and OpenMP on.
 262 # Detect here whether applying a workaround is needed and will apply it later
 263 # on the affected files.
 264 include(gmxGCC44O3BugWorkaround)
 265 gmx_check_gcc44_bug_workaround_needed(GMX_USE_GCC44_BUG_WORKAROUND)
 266
 267 ########################################################################
 268 # Set up binary and library suffixing
 269 ########################################################################
 270 set(GMX_BINARY_SUFFIX "" CACHE STRING "Suffix for GROMACS binaries (default: _d for double, _mpi for MPI, _mpi_d for MPI and double).")
 271 set(GMX_LIBS_SUFFIX ""
 272   CACHE STRING "Suffix for GROMACS libs (default: _d for double, _mpi for MPI, _mpi_d for MPI and double).")
 273 if (GMX_DEFAULT_SUFFIX)
 274   set(GMX_BINARY_SUFFIX "")
 275   set(GMX_LIBS_SUFFIX "")
 276   if (GMX_MPI)
 277     set(GMX_BINARY_SUFFIX "_mpi")
 278     set(GMX_LIBS_SUFFIX "_mpi")
 279   endif(GMX_MPI)
 280   if (GMX_DOUBLE)
 281     set (GMX_BINARY_SUFFIX "${GMX_BINARY_SUFFIX}_d")
 282     set (GMX_LIBS_SUFFIX "${GMX_LIBS_SUFFIX}_d")
 283   endif(GMX_DOUBLE)
 284   if (GMX_OPENMM)
 285     set (GMX_BINARY_SUFFIX "-openmm")
 286     set (GMX_LIBS_SUFFIX "_openmm")
 287   endif(GMX_OPENMM)
 288   mark_as_advanced(FORCE GMX_BINARY_SUFFIX GMX_LIBS_SUFFIX)
 289   if (NOT SUFFIX_QUIETLY)
 290     message(STATUS "Using default binary suffix: \"${GMX_BINARY_SUFFIX}\"")
 291     message(STATUS "Using default library suffix: \"${GMX_LIBS_SUFFIX}\"")
 292   endif (NOT SUFFIX_QUIETLY)
 293 else(GMX_DEFAULT_SUFFIX)
 294   mark_as_advanced(CLEAR GMX_BINARY_SUFFIX GMX_LIBS_SUFFIX)
 295   if (NOT SUFFIX_QUIETLY)
 296     message(STATUS "Using manually set binary suffix: \"${GMX_BINARY_SUFFIX}\"")
 297     message(STATUS "Using manually set library suffix: \"${GMX_LIBS_SUFFIX}\"")
 298   endif (NOT SUFFIX_QUIETLY)
 299 endif(GMX_DEFAULT_SUFFIX)
 300 set(SUFFIX_QUIETLY TRUE CACHE INTERNAL "")
 301
 302 set(PKG_CFLAGS "")
 303 if(GMX_DOUBLE)
 304     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_DOUBLE")
 305 endif(GMX_DOUBLE)
 306 if(GMX_SOFTWARE_INVSQRT)
 307   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_SOFTWARE_INVSQRT")
 308 endif(GMX_SOFTWARE_INVSQRT)
 309 if(GMX_POWERPC_INVSQRT)
 310   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_POWERPC_INVSQRT")
 311 endif(GMX_POWERPC_INVSQRT)
 312
 313 ########################################################################
 314 #Process MPI settings
 315 ########################################################################
 316 include(gmxManageMPI)
 317
 318 #######################################################################
 319 # Check for options incompatible with OpenMM build                    #
 320 #######################################################################
 321 if(GMX_OPENMM)
 322     # we'll use the built-in fft to avoid unnecessary dependencies
 323     string(TOUPPER ${GMX_FFT_LIBRARY} GMX_FFT_LIBRARY)
 324     if(NOT ${GMX_FFT_LIBRARY} STREQUAL "FFTPACK")
 325         message(STATUS "No external FFT libraries needed for the OpenMM build, switching to fftpack!")
 326         set(GMX_FFT_LIBRARY "fftpack" CACHE STRING
 327                 "No external FFT libraries needed for the OpenMM build, switching to  fftpack!" FORCE)
 328     endif()
 329     if(GMX_MPI)
 330         message(FATAL_ERROR "The OpenMM build is not compatible with MPI!")
 331     endif(GMX_MPI)
 332     if(GMX_THREAD_MPI)
 333         message(STATUS "Thread-MPI not compatible with OpenMM, disabled!")
 334         set(GMX_THREAD_MPI OFF CACHE BOOL
 335                 "Thread-MPI not compatible with OpenMM build, disabled!" FORCE)
 336     endif(GMX_THREAD_MPI)
 337     if(GMX_OPENMP)
 338         message(STATUS "OpenMP multithreading not compatible with OpenMM, disabled")
 339         set(GMX_OPENMP OFF CACHE BOOL
 340             "OpenMP multithreading not compatible with OpenMM, disabled!" FORCE)
 341     endif()
 342     if(GMX_SOFTWARE_INVSQRT)
 343         set(GMX_SOFTWARE_INVSQRT OFF CACHE STRING
 344                 "The OpenMM build does not need GROMACS software 1/sqrt!" FORCE)
 345     endif(GMX_SOFTWARE_INVSQRT)
 346     string(TOUPPER ${GMX_ACCELERATION} GMX_ACCELERATION)
 347     if(NOT GMX_ACCELERATION STREQUAL "NONE")
 348         message(STATUS "Switching off CPU-based acceleration, the OpenMM build does not support/need any!")
 349         set(GMX_ACCELERATION "none" CACHE STRING
 350                 "Switching off CPU-based acceleration, the OpenMM build does not support/need any!" FORCE)
 351     endif()
 352     if(GMX_FAHCORE)
 353         message(FATAL_ERROR "The OpenMM build does not support FAH build!")
 354     endif(GMX_FAHCORE)
 355     if(GMX_DOUBLE)
 356         message(FATAL_ERROR  "The OpenMM-build does not support double precision calculations!")
 357     endif()
 358     # mark as advanced the unused variables
 359     mark_as_advanced(FORCE GMX_ACCELERATION GMX_MPI GMX_FFT_LIBRARY
 360         GMX_QMMM_PROGRAM GMX_THREAD_MPI GMX_DOUBLE)
 361 else(GMX_OPENMM)
 362      mark_as_advanced(CLEAR GMX_ACCELERATION GMX_MPI GMX_FFT_LIBRARY
 363         GMX_QMMM_PROGRAM GMX_THREAD_MPI GMX_DOUBLE)
 364 endif(GMX_OPENMM)
 365
 366
 367 ########################################################################
 368 # Basic system tests (standard libraries, headers, functions, types)   #
 369 ########################################################################
 370 include(CheckIncludeFiles)
 371 check_include_files(string.h     HAVE_STRING_H)
 372 check_include_files(math.h       HAVE_MATH_H)
 373 check_include_files(limits.h     HAVE_LIMITS_H)
 374 check_include_files(memory.h     HAVE_MEMORY_H)
 375 check_include_files(unistd.h     HAVE_UNISTD_H)
 376 check_include_files(direct.h     HAVE_DIRECT_H)
 377 check_include_files(pwd.h        HAVE_PWD_H)
 378 check_include_files(stdint.h     HAVE_STDINT_H)
 379 check_include_files(stdlib.h     HAVE_STDLIB_H)
 380 check_include_files(pthread.h    HAVE_PTHREAD_H)
 381 check_include_files(dirent.h     HAVE_DIRENT_H)
 382 check_include_files(inttypes.h   HAVE_INTTYPES_H)
 383 check_include_files(regex.h      HAVE_REGEX_H)
 384 check_include_files(sys/types.h  HAVE_SYS_TYPES_H)
 385 check_include_files(sys/stat.h   HAVE_SYS_STAT_H)
 386 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 387 check_include_files(rpc/rpc.h    HAVE_RPC_RPC_H)
 388 check_include_files("rpc/rpc.h;rpc/xdr.h"    HAVE_RPC_XDR_H)
 389 check_include_files(io.h                 HAVE_IO_H)
 390 check_include_files(sched.h      HAVE_SCHED_H)
 391
 392 include(CheckFunctionExists)
 393 check_function_exists(strcasecmp        HAVE_STRCASECMP)
 394 check_function_exists(strdup            HAVE_STRDUP)
 395 check_function_exists(vprintf           HAVE_VPRINTF)
 396 check_function_exists(memcmp            HAVE_MEMCMP)
 397 check_function_exists(posix_memalign    HAVE_POSIX_MEMALIGN)
 398 check_function_exists(memalign          HAVE_MEMALIGN)
 399 check_function_exists(_aligned_malloc   HAVE__ALIGNED_MALLOC)
 400 check_function_exists(gettimeofday      HAVE_GETTIMEOFDAY)
 401 check_function_exists(isnan             HAVE_ISNAN)
 402 check_function_exists(_isnan            HAVE__ISNAN)
 403 check_function_exists(fsync             HAVE_FSYNC)
 404 check_function_exists(_fileno           HAVE__FILENO)
 405 check_function_exists(fileno            HAVE_FILENO)
 406 check_function_exists(_commit           HAVE__COMMIT)
 407 check_function_exists(lstat             HAVE_LSTAT)
 408 check_function_exists(sigaction         HAVE_SIGACTION)
 409 check_function_exists(sysconf           HAVE_SYSCONF)
 410 check_function_exists(sched_setaffinity HAVE_SCHED_SETAFFINITY)
 411 check_function_exists(sched_getaffinity HAVE_SCHED_GETAFFINITY)
 412 check_function_exists(rsqrt             HAVE_RSQRT)
 413 check_function_exists(rsqrtf            HAVE_RSQRTF)
 414 check_function_exists(sqrtf             HAVE_SQRTF)
 415
 416 include(CheckLibraryExists)
 417 check_library_exists(m sqrt "" HAVE_LIBM)
 418 check_library_exists(m cbrt "" HAVE_CBRT)
 419
 420
 421 include(CheckTypeSize)
 422
 423 check_type_size("bool"          SIZEOF_BOOL) # will also set HAVE_BOOL
 424 check_type_size("int"           SIZEOF_INT)
 425 check_type_size("long int"      SIZEOF_LONG_INT)
 426 check_type_size("long long int" SIZEOF_LONG_LONG_INT)
 427 check_type_size("off_t"         SIZEOF_OFF_T)
 428 check_type_size("void *"        SIZEOF_VOIDP)
 429
 430 if (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 431     set(GMX_64_BIT TRUE)
 432 else (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 433     set(GMX_64_BIT FALSE)
 434 endif (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 435
 436 # Check for some basic types that we *need*, so set these to int if they are not present
 437 check_type_size(uid_t uid_t)
 438 if(NOT uid_t)
 439   set(uid_t int)
 440 else(NOT uid_t)
 441   set(uid_t 0)
 442 endif(NOT uid_t)
 443
 444 check_type_size(gid_t gid_t)
 445 if(NOT gid_t)
 446   set(gid_t 1)
 447 else(NOT gid_t)
 448   set(gid_t 0)
 449 endif(NOT gid_t)
 450
 451 check_type_size(size_t size_t)
 452 if(NOT size_t)
 453   set(size_t int)
 454 else(NOT size_t)
 455   set(size_t 0)
 456 endif(NOT size_t)
 457
 458 check_type_size(off_t off_t)
 459 if(NOT off_t)
 460   set(off_t int)
 461 else(NOT off_t)
 462   set(off_t 0)
 463 endif(NOT off_t)
 464
 465 include(TestBigEndian)
 466 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 467
 468
 469
 470
 471 ########################################################################
 472 # Find external packages                                               #
 473 ########################################################################
 474 if(UNIX)
 475     if(GMX_PREFER_STATIC_LIBS)
 476         # On Linux .a is the static library suffix, on Mac OS X .lib can also
 477         # be used, so we'll add both to the preference list.
 478         SET(CMAKE_FIND_LIBRARY_SUFFIXES ".lib;.a" ${CMAKE_FIND_LIBRARY_SUFFIXES})
 479         if(SHARED_LIBS_DEFAULT)
 480             if(BUILD_SHARED_LIBS) #Warn the user about the combination. But don't overwrite the request.
 481                 message(WARNING "Static libraries requested, and shared Gromacs libraries requested.")
 482             elseif(NOT DEFINED BUILD_SHARED_LIBS) #Change default to OFF. Don't warn if it's already off.
 483                 message(WARNING "Static libraries requested, the GROMACS libraries will also be build static (BUILD_SHARED_LIBS=OFF)")
 484                 set(SHARED_LIBS_DEFAULT OFF)
 485             endif()
 486         endif()
 487     endif()
 488 endif()
 489 option(BUILD_SHARED_LIBS "Enable shared libraries (can be problematic with MPI, Windows)" ${SHARED_LIBS_DEFAULT})
 490
 491 option(GMX_XML "Use libxml2 to parse xml files" ON)
 492 if (GMX_XML)
 493   find_package(LibXml2)
 494   set(PKG_XML "")
 495   if(LIBXML2_FOUND)
 496     include_directories(${LIBXML2_INCLUDE_DIR})
 497     set(PKG_XML libxml-2.0)
 498     set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 499     set(HAVE_LIBXML2 1)
 500   endif(LIBXML2_FOUND)
 501 endif(GMX_XML)
 502
 503 option(GMX_GSL "Add support for gsl" OFF)
 504 if (GMX_GSL)
 505   find_package(gsl)
 506   set(PKG_GSL "")
 507   if(GSL_FOUND)
 508     include_directories(${GSL_INCLUDE_DIR})
 509     set(PKG_GSL gsl)
 510     set(HAVE_LIBGSL 1)
 511   endif(GSL_FOUND)
 512 endif (GMX_GSL)
 513
 514 option(GMX_X11 "Use X window system" OFF)
 515 if (GMX_X11)
 516         find_package(X11)
 517         # X11 includes/libraries are only set in the ngmx subdirectory!
 518         if(X11_FOUND)
 519         set(HAVE_X11 1)
 520         endif(X11_FOUND)
 521 endif(GMX_X11)
 522
 523 if(GMX_THREAD_MPI)
 524     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_THREAD_MPI")
 525     include(ThreadMPI)
 526     set(THREAD_MPI_LIB thread_mpi)
 527     set(GMX_MPI 1)
 528     string(TOUPPER ${GMX_FFT_LIBRARY} ${GMX_FFT_LIBRARY})
 529 endif(GMX_THREAD_MPI)
 530
 531 if(GMX_OPENMM)
 532     set(CUDA_BUILD_EMULATION OFF)
 533     find_package(CUDA 3.1 REQUIRED)
 534     add_definitions(-DGMX_OPENMM)
 535     if(CMAKE_BUILD_TYPE STREQUAL "DEBUG")
 536         set(CUDA_VERBOSE_BUILD ON)
 537     endif()
 538     find_package(OpenMM)
 539 endif(GMX_OPENMM)
 540
 541
 542 if(GMX_GPU)
 543     if(GMX_DOUBLE)
 544         message(WARNING "GPU acceleration is not available in double precision, disabled!")
 545         set(GMX_GPU OFF CACHE BOOL "Enable GPU acceleration" FORCE)
 546     endif()
 547 endif(GMX_GPU)
 548
 549 if(GMX_GPU)
 550
 551     # We support CUDA >=v3.2 on *nix, but <= v4.1 doesn't work with MSVC
 552     if(MSVC)
 553         find_package(CUDA 4.1)
 554     else()
 555         find_package(CUDA 3.2)
 556     endif()
 557
 558     if (NOT EXISTS ${CUDA_TOOLKIT_ROOT_DIR})
 559         message(FATAL_ERROR "
 560     mdrun supports native GPU acceleration on NVIDIA hardware with compute
 561     capability >=2.0. This requires the NVIDIA CUDA library, which was not
 562     found; the location can be hinted by setting CUDA_TOOLKIT_ROOT_DIR.
 563
 564     CPU or GPU acceleration can be selected at runtime, but if you are
 565     sure you can not make use of GPU acceleration, disable it by setting
 566     the CMake variable GMX_GPU=OFF.")
 567     endif()
 568
 569     if(NOT GMX_OPENMP)
 570         message(WARNING "
 571     In order to use GPU acceleration efficiently, mdrun requires OpenMP multithreding.
 572     Without OpenMP only a single CPU core per GPU can be used which is suboptimal.
 573     Note that with MPI multiple processes can be forced to use a single GPU, but this
 574     typically inefficient.")
 575     endif()
 576
 577     include(gmxManageNvccConfig)
 578
 579     # Check whether we can use atomic operations needed for polling wait for GPU
 580     # (to avoid the cudaStreamSynchronize + ECC bug).
 581     # With thread-MPI testing atomics has already been carried out, but without
 582     # thread-MPI we need to invoke the atomics test independently.
 583     if (NOT GMX_THREAD_MPI)
 584         set(TEST_TMPI_ATOMICS_ONLY ON CACHE INTERNAL
 585             "Test only the atomic operations of thread-MPI.")
 586         include(ThreadMPI)
 587     endif()
 588
 589     # we need this linker flag in case if we have ld >= 2.22 (typically with gcc 4.5+),
 590     # but it's too cumbersome to check the ld version and the flag should not hurt
 591     if(CMAKE_COMPILER_IS_GNUCC)
 592         set(GROMACS_LINKER_FLAGS "-Wl,--add-needed ${GROMACS_LINKER_FLAGS}")
 593     endif()
 594
 595     # annoyingly enough, FindCUDA leaves a few variables behind as non-advanced
 596     mark_as_advanced(CUDA_BUILD_CUBIN CUDA_BUILD_EMULATION CUDA_SDK_ROOT_DIR CUDA_VERBOSE_BUILD)
 597 endif()
 598
 599 if(APPLE)
 600    find_library(ACCELERATE_FRAMEWORK Accelerate)
 601    list(APPEND GMX_EXTRA_LIBRARIES ${ACCELERATE_FRAMEWORK})
 602 endif(APPLE)
 603
 604 if(CYGWIN)
 605     set(GMX_CYGWIN 1)
 606 endif(CYGWIN)
 607
 608 if(WIN32 AND NOT CYGWIN)
 609     set(GMX_NATIVE_WINDOWS 1)
 610 endif()
 611
 612 # only bother with finding git and using version.h if the source is a git repo
 613 if(EXISTS "${CMAKE_SOURCE_DIR}/.git")
 614     if(USE_VERSION_H)
 615         # We need at least git v1.5.3 be able to parse git's date output. If not
 616         # found or the version is too small, we can't generate version information.
 617         find_package(Git)
 618
 619         # Find out the git version
 620         if(GIT_FOUND AND NOT GIT_VERSION)
 621           execute_process(COMMAND ${GIT_EXECUTABLE} "--version"
 622             OUTPUT_VARIABLE _exec_out
 623             OUTPUT_STRIP_TRAILING_WHITESPACE)
 624           string(REGEX REPLACE "git version (.*)" "\\1" GIT_VERSION ${_exec_out})
 625           set(GIT_VERSION ${GIT_VERSION} CACHE STRING "Git version")
 626           mark_as_advanced(GIT_VERSION)
 627         endif()
 628
 629         if(NOT GIT_FOUND OR GIT_VERSION VERSION_LESS "1.5.3")
 630           message("No compatible git version found, won't be able to generate proper development version information.")
 631           set(USE_VERSION_H OFF)
 632         endif()
 633     endif()
 634 else()
 635     set(USE_VERSION_H OFF)
 636 endif()
 637
 638 ########################################################################
 639 # Generate development version info for cache
 640 ########################################################################
 641 # set(GEN_VERSION_INFO_INTERNAL "ON")
 642 # include(gmxGenerateVersionString)
 643
 644 ########################################################################
 645 # Our own GROMACS tests
 646 ########################################################################
 647
 648 add_definitions( -DHAVE_CONFIG_H )
 649 include_directories(${CMAKE_BINARY_DIR}/src)
 650 include_directories(${CMAKE_BINARY_DIR}/include)
 651 include_directories(${CMAKE_SOURCE_DIR}/include)
 652
 653 include(gmxTestInlineASM)
 654 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 655
 656 include(gmxSetBuildInformation)
 657 gmx_set_build_information()
 658 if(BUILD_CPU_FEATURES MATCHES "rdtscp")
 659     # The timestep counter headers do not include config.h
 660     add_definitions(-DHAVE_RDTSCP)
 661 endif(BUILD_CPU_FEATURES MATCHES "rdtscp")
 662
 663 include(gmxTestFloatFormat)
 664 gmx_test_float_format(GMX_FLOAT_FORMAT_IEEE754
 665                       GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER
 666                       GMX_IEEE754_BIG_ENDIAN_WORD_ORDER)
 667
 668 include(gmxTestLargeFiles)
 669 gmx_test_large_files(GMX_LARGEFILES)
 670
 671 include(gmxTestSignal)
 672 gmx_test_sigusr1(HAVE_SIGUSR1)
 673
 674 include(gmxTestInline)
 675 gmx_test_inline(INLINE_KEYWORD)
 676
 677 include(gmxTestRestrict)
 678 gmx_test_restrict(RESTRICT_KEYWORD)
 679
 680 include(gmxTestPipes)
 681 gmx_test_pipes(HAVE_PIPES)
 682
 683 include(gmxTestIsfinite)
 684 gmx_test_isfinite(HAVE_ISFINITE)
 685 gmx_test__isfinite(HAVE__ISFINITE)
 686 gmx_test__finite(HAVE__FINITE)
 687
 688 include(gmxTestXDR)
 689 gmx_test_xdr(GMX_SYSTEM_XDR)
 690 if(NOT GMX_SYSTEM_XDR)
 691     set(GMX_INTERNAL_XDR 1)
 692     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_INTERNAL_XDR")
 693 endif(NOT GMX_SYSTEM_XDR)
 694
 695 # Process nonbonded accelerated kernels settings
 696 string(TOUPPER ${GMX_ACCELERATION} ${GMX_ACCELERATION})
 697 if(${GMX_ACCELERATION} STREQUAL "NONE")
 698     # nothing to do
 699 elseif(${GMX_ACCELERATION} STREQUAL "SSE2")
 700
 701     GMX_TEST_CFLAG(GNU_SSE2_CFLAG "-msse2" GROMACS_C_FLAGS)
 702     if(NOT GNU_SSE2_CFLAG)
 703         GMX_TEST_CFLAG(MSVC_SSE2_CFLAG "/arch:SSE2" GROMACS_C_FLAGS)
 704     endif(NOT GNU_SSE2_CFLAG)
 705
 706     if (CMAKE_CXX_COMPILER_LOADED)
 707         GMX_TEST_CXXFLAG(GNU_SSE2_CXXFLAG "-msse2" GROMACS_CXX_FLAGS)
 708         if(NOT GNU_SSE2_CXXFLAG)
 709             GMX_TEST_CXXFLAG(MSVC_SSE2_CXXFLAG "/arch:SSE2" GROMACS_CXX_FLAGS)
 710         endif(NOT GNU_SSE2_CXXFLAG)
 711     endif()
 712
 713     # We dont warn for lacking SSE2 flag support, since that is probably standard today.
 714
 715     # Only test the include after we have tried to add the correct flag for SSE2 support
 716     check_include_file(emmintrin.h  HAVE_EMMINTRIN_H ${GROMACS_C_FLAGS})
 717
 718     if(NOT HAVE_EMMINTRIN_H)
 719         message(FATAL_ERROR "Cannot find emmintrin.h, which is required for SSE2 intrinsics support.")
 720     endif(NOT HAVE_EMMINTRIN_H)
 721
 722     # The user should not be able to set this orthogonally to the acceleration
 723     set(GMX_X86_SSE2 1)
 724     if (NOT ACCELERATION_QUIETLY)
 725       message(STATUS "Enabling SSE2 Gromacs acceleration, and it will help compiler optimization.")
 726     endif()
 727
 728 elseif(${GMX_ACCELERATION} STREQUAL "SSE4.1")
 729
 730     GMX_TEST_CFLAG(GNU_SSE4_CFLAG "-msse4.1" GROMACS_C_FLAGS)
 731     if (NOT GNU_SSE4_CFLAG)
 732         GMX_TEST_CFLAG(MSVC_SSE4_CFLAG "/arch:SSE4.1" GROMACS_C_FLAGS)
 733     endif(NOT GNU_SSE4_CFLAG)
 734     if (NOT GNU_SSE4_CFLAG AND NOT MSVC_SSE4_CFLAG)
 735         message(WARNING "No C SSE4.1 flag found. Consider a newer compiler, or disable SSE4.1 for slightly lower performance.")
 736         # Not surprising if we end up here! MSVC current does not support the SSE4.1 flag. However, it appears to accept SSE4.1
 737         # intrinsics when SSE2 support is enabled, so we try that instead.
 738         GMX_TEST_CFLAG(MSVC_SSE2_CFLAG "/arch:SSE2" GROMACS_C_FLAGS)
 739     endif(NOT GNU_SSE4_CFLAG AND NOT MSVC_SSE4_CFLAG)
 740
 741     if (CMAKE_CXX_COMPILER_LOADED)
 742         GMX_TEST_CXXFLAG(GNU_SSE4_CXXFLAG "-msse4.1" GROMACS_CXX_FLAG)
 743         if (NOT GNU_SSE4_CXXFLAG)
 744             GMX_TEST_CXXFLAG(MSVC_SSE4_CXXFLAG "/arch:SSE4.1" GROMACS_CXX_FLAGS)
 745         endif(NOT GNU_SSE4_CXXFLAG)
 746         if (NOT GNU_SSE4_CXXFLAG AND NOT MSVC_SSE4_CXXFLAG)
 747             message(WARNING "No C++ SSE4.1 flag found. Consider a newer compiler, or disable SSE4.1 for slightly lower performance.")
 748             # Not surprising if we end up here! MSVC current does not support the SSE4.1 flag. However, it appears to accept SSE4.1
 749             # intrinsics when SSE2 support is enabled, so we try that instead.
 750             GMX_TEST_CXXFLAG(MSVC_SSE2_CXXFLAG "/arch:SSE2" GROMACS_CXX_FLAGS)
 751         endif(NOT GNU_SSE4_CXXFLAG AND NOT MSVC_SSE4_CXXFLAG)
 752     endif()
 753
 754     # This must come after we have added the -msse4.1 flag on some platforms.
 755     check_include_file(smmintrin.h  HAVE_SMMINTRIN_H ${GROMACS_C_FLAGS})
 756
 757     if(NOT HAVE_SMMINTRIN_H)
 758         message(FATAL_ERROR "Cannot find smmintrin.h, which is required for SSE4.1 intrinsics support.")
 759     endif(NOT HAVE_SMMINTRIN_H)
 760
 761     # The user should not be able to set this orthogonally to the acceleration
 762     set(GMX_X86_SSE4_1 1)
 763     set(GMX_X86_SSE2   1)
 764     if (NOT ACCELERATION_QUIETLY)
 765       message(STATUS "Enabling SSE4.1 Gromacs acceleration, and it will help compiler optimization.")
 766     endif()
 767
 768 elseif(${GMX_ACCELERATION} STREQUAL "AVX_128_FMA" OR ${GMX_ACCELERATION} STREQUAL "AVX_256")
 769
 770     # Set the AVX compiler flag for both these choices!
 771
 772     GMX_TEST_CFLAG(GNU_AVX_CFLAG "-mavx" GROMACS_C_FLAGS)
 773     if (NOT GNU_AVX_CFLAG)
 774         GMX_TEST_CFLAG(MSVC_AVX_CFLAG "/arch:AVX" GROMACS_C_FLAGS)
 775     endif (NOT GNU_AVX_CFLAG)
 776     if (NOT GNU_AVX_CFLAG AND NOT MSVC_AVX_CFLAG)
 777         message(WARNING "No C AVX flag found. Consider a newer compiler, or disable AVX for much lower performance.")
 778     endif (NOT GNU_AVX_CFLAG AND NOT MSVC_AVX_CFLAG)
 779
 780     if (CMAKE_CXX_COMPILER_LOADED)
 781         GMX_TEST_CXXFLAG(GNU_AVX_CXXFLAG "-mavx" GROMACS_CXX_FLAGS)
 782         if (NOT GNU_AVX_CXXFLAG)
 783             GMX_TEST_CXXFLAG(MSVC_AVX_CXXFLAG "/arch:AVX" GROMACS_CXX_FLAGS)
 784         endif (NOT GNU_AVX_CXXFLAG)
 785         if (NOT GNU_AVX_CXXFLAG AND NOT MSVC_AVX_CXXFLAG)
 786             message(WARNING "No C++ AVX flag found. Consider a newer compiler, or disable AVX for much lower performance.")
 787         endif (NOT GNU_AVX_CXXFLAG AND NOT MSVC_AVX_CXXFLAG)
 788     endif()
 789
 790     # Set the FMA4 flags (MSVC doesn't require any)
 791     if(${GMX_ACCELERATION} STREQUAL "AVX_128_FMA" AND NOT MSVC)
 792         GMX_TEST_CFLAG(GNU_FMA_CFLAG "-mfma4" GROMACS_C_FLAGS)
 793         if (NOT GNU_FMA_CFLAG)
 794             message(WARNING "No C FMA4 flag found. Consider a newer compiler, or disable AVX_128_FMA for much lower performance.")
 795         endif(NOT GNU_FMA_CFLAG)
 796         if (CMAKE_CXX_COMPILER_LOADED)
 797             GMX_TEST_CXXFLAG(GNU_FMA_CXXFLAG "-mfma4" GROMACS_CXX_FLAGS)
 798             if (NOT GNU_FMA_CXXFLAG)
 799                 message(WARNING "No C++ FMA flag found. Consider a newer compiler, or disable AVX_128_FMA for much lower performance.")
 800             endif (NOT GNU_FMA_CXXFLAG)
 801         endif()
 802     endif()
 803
 804     # Only test the header after we have tried to add the flag for AVX support
 805     check_include_file(immintrin.h  HAVE_IMMINTRIN_H ${GROMACS_C_FLAGS})
 806
 807     if(NOT HAVE_IMMINTRIN_H)
 808         message(FATAL_ERROR "Cannot find immintrin.h, which is required for AVX intrinsics support. Consider switching compiler.")
 809     endif(NOT HAVE_IMMINTRIN_H)
 810
 811     # GCC requires x86intrin.h for FMA support. MSVC 2010 requires intrin.h for FMA support.
 812     check_include_file(x86intrin.h HAVE_X86INTRIN_H ${GROMACS_C_FLAGS})
 813     check_include_file(intrin.h HAVE_INTRIN_H ${GROMACS_C_FLAGS})
 814
 815     # The user should not be able to set this orthogonally to the acceleration
 816     set(GMX_X86_SSE4_1 1)
 817     set(GMX_X86_SSE2   1)
 818
 819     # But just enable one of the choices internally...
 820     if(${GMX_ACCELERATION} STREQUAL "AVX_128_FMA")
 821         set(GMX_X86_AVX_128_FMA 1)
 822         if (NOT ACCELERATION_QUIETLY)
 823           message(STATUS "Enabling 128-bit AVX Gromacs acceleration (with fused-multiply add), and it will help compiler optimization.")
 824         endif()
 825     else()
 826         # If we are not doing AVX_128, it must be AVX_256...
 827         set(GMX_X86_AVX_256 1)
 828         if (NOT ACCELERATION_QUIETLY)
 829           message(STATUS "Enabling 256-bit AVX Gromacs acceleration, and it will help compiler optimization.")
 830         endif()
 831     endif()
 832
 833 elseif(${GMX_ACCELERATION} STREQUAL "FORTRAN")
 834
 835 #    Fortran is temporarily disabled while we push in nbNxN kernels.
 836 #    We need to fake it a bit here to avoid jenkins build errors!
 837 #    add_definitions(-DGMX_FORTRAN)
 838
 839 elseif(${GMX_ACCELERATION} STREQUAL "BLUEGENE")
 840 # GMX_ACCELERATION=BlueGene should be set in the Toolchain-BlueGene?-???.cmake file
 841     if (NOT ACCELERATION_QUIETLY)
 842       message(STATUS "Configuring for BlueGene")
 843     endif()
 844     set(GMX_BLUEGENE 1)
 845     if (${CMAKE_SYSTEM_NAME} STREQUAL "BlueGeneL")
 846         set(SHARED_LIBS_DEFAULT OFF CACHE BOOL "Shared libraries not compatible with BlueGene/L, disabled!" FORCE)
 847         set(BUILD_SHARED_LIBS OFF CACHE BOOL "Shared libraries not compatible with BlueGene/L, disabled!" FORCE)
 848     endif (${CMAKE_SYSTEM_NAME} STREQUAL "BlueGeneL")
 849     set(GMX_SOFTWARE_INVSQRT OFF CACHE BOOL "Do not use software reciprocal square root on BlueGene" FORCE)
 850     set(GMX_POWERPC_INVSQRT ON CACHE BOOL "Use hardware reciprocal square root on BlueGene" FORCE)
 851     set(GMX_X11 OFF CACHE BOOL "X11 not compatible with BlueGene, disabled!" FORCE)
 852     set(GMX_THREAD_MPI OFF CACHE BOOL "Thread-MPI not compatible with BlueGene, disabled!" FORCE)
 853     set(GMX_MPI ON CACHE BOOL "Use MPI on BlueGene" FORCE)
 854 # Access to /etc/passwd is not available on the back end of BlueGene,
 855 # despite being detected by CMake. This can cause linker warnings
 856 # about harmless things in src/gmxlib/string2.h.
 857     set(HAVE_PWD_H OFF)
 858 # The automatic testing for endianness does not work for the BlueGene cross-compiler
 859     set(GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER 1 CACHE INTERNAL "BlueGene has big endian FP byte order (by default)" FORCE)
 860     set(GMX_IEEE754_BIG_ENDIAN_WORD_ORDER 1 CACHE INTERNAL "BlueGene has big endian FP word order (by default)" FORCE)
 861 elseif(${GMX_ACCELERATION} STREQUAL "POWER6")
 862     set(GMX_POWER6 1)
 863     set(GMX_SOFTWARE_INVSQRT OFF CACHE BOOL "Do not use software reciprocal square root on Power6" FORCE)
 864     set(GMX_POWERPC_INVSQRT ON CACHE BOOL "Use hardware reciprocal square root on Power6" FORCE)
 865 else(${GMX_ACCELERATION} STREQUAL "NONE")
 866     MESSAGE(FATAL_ERROR "Unrecognized option for accelerated kernels: ${GMX_ACCELERATION}. Pick one of None, SSE2, SSE4.1, AVX_128_FMA, AVX_256, Fortran, BlueGene, Power6")
 867 endif(${GMX_ACCELERATION} STREQUAL "NONE")
 868 set(ACCELERATION_QUIETLY TRUE CACHE INTERNAL "")
 869
 870 if(GMX_FORTRAN OR GMX_POWER6)
 871     if (GMX_THREAD_MPI)
 872         message(FATAL_ERROR "FORTRAN/POWER6 is incompatible with thread-MPI and only provides a speed-up on certain IBM compilers. Disable FORTRAN (or threads if you really want to use FORTRAN kernels).")
 873     endif(GMX_THREAD_MPI)
 874     enable_language(Fortran)
 875     include(FortranCInterface)
 876     discover_fortran_mangling(prefix isupper suffix extra_under_score found)
 877     if(extra_under_score)
 878         set(extrasuffix "_")
 879     endif(extra_under_score)
 880     if(prefix)
 881       set(prefix "${prefix} ##")
 882     endif(prefix)
 883     if(suffix)
 884       set(suffix "## ${suffix}")
 885       if(extrasuffix)
 886         set(extrasuffix "${suffix}${extrasuffix}")
 887       endif(extrasuffix)
 888     else(suffix)
 889       if(extrasuffix)
 890         # Don't know if this is needed, but it can't hurt
 891         set(extrasuffix "## ${extrasuffix}")
 892       endif(extrasuffix)
 893     endif(suffix)
 894
 895     if(isupper)
 896         set(F77_FUNCDEF   "${prefix} NAME ${suffix}")
 897         set(F77_FUNCDEF_  "${prefix} NAME ${extrasuffix}")
 898     else(isupper)
 899         set(F77_FUNCDEF   "${prefix} name ${suffix}")
 900         set(F77_FUNCDEF_  "${prefix} name ${extrasuffix}")
 901     endif(isupper)
 902 else(GMX_FORTRAN OR GMX_POWER6)
 903         set(F77_FUNCDEF   "name ## _")
 904         set(F77_FUNCDEF_  "name ## _")
 905 endif(GMX_FORTRAN OR GMX_POWER6)
 906
 907 # Process QM/MM Settings
 908 string(TOUPPER ${GMX_QMMM_PROGRAM} ${GMX_QMMM_PROGRAM})
 909 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 910     set(GMX_QMMM_GAUSSIAN 1)
 911 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 912     set(GMX_QMMM_MOPAC 1)
 913 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 914     set(GMX_QMMM_GAMESS 1)
 915 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 916     set(GMX_QMMM_ORCA 1)
 917 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 918     # nothing to do
 919 else(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 920     MESSAGE(FATAL_ERROR "Invalid QM/MM program option: ${GMX_QMMM_PROGRAM}. Choose one of: Gaussian, Mopac, Gamess, Orca, None")
 921 endif(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 922
 923 # Process FFT library settings - if not OpenMM build
 924 string(TOUPPER ${GMX_FFT_LIBRARY} ${GMX_FFT_LIBRARY})
 925 set(PKG_FFT "")
 926 set(PKG_FFT_LIBS "")
 927 if(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 928     if(GMX_DOUBLE)
 929         set(FFTW fftw)
 930     else(GMX_DOUBLE)
 931         set(FFTW fftwf)
 932     endif(GMX_DOUBLE)
 933     find_package(FFTW COMPONENTS ${FFTW})
 934     string(TOUPPER "${FFTW}" FFTW)
 935     set(PKG_FFT "${${FFTW}_PKG}")
 936     include_directories(${${FFTW}_INCLUDE_DIRS})
 937     set(FFT_LIBRARIES ${${FFTW}_LIBRARIES})
 938     if(NOT ${FFTW}_FOUND)
 939       MESSAGE(FATAL_ERROR "Cannot find FFTW3 (with correct precision - libfftw3f for single precision GROMACS or libfftw3 for double precision GROMACS). Fix it, choose another FFT library, or use the Gromacs built-in fftpack (slower)!")
 940     endif(NOT ${FFTW}_FOUND)
 941
 942     set(GMX_FFT_FFTW3 1)
 943
 944     if (NOT ${GMX_ACCELERATION} STREQUAL "NONE" AND NOT ${FFTW}_HAVE_SIMD)
 945       message(WARNING "The fftw library found is compiled without SIMD support, which makes it slow. Consider recompiling it or contact your admin")
 946     endif (NOT ${GMX_ACCELERATION} STREQUAL "NONE" AND NOT ${FFTW}_HAVE_SIMD)
 947
 948 elseif(${GMX_FFT_LIBRARY} STREQUAL "MKL")
 949 #    MESSAGE(STATUS "Using external FFT library - Intel MKL")
 950     find_package(MKL REQUIRED)
 951     include_directories(${MKL_INCLUDE_DIR})
 952     set(FFT_LIBRARIES ${MKL_LIBRARIES})
 953     set(PKG_FFT_LIBS ${MKL_LIBRARIES})
 954
 955     set(GMX_FFT_MKL 1)
 956     set(HAVE_MKL 1)
 957
 958 #elseif(${GMX_FFT_LIBRARY} STREQUAL "ACML")
 959 #    MESSAGE(STATUS "Using external FFT library - AMD core math library")
 960 #    set(GMX_FFT_ACML 1)
 961 elseif(${GMX_FFT_LIBRARY} STREQUAL "FFTPACK")
 962     MESSAGE(STATUS "Using internal FFT library - fftpack")
 963     set(GMX_FFT_FFTPACK 1)
 964 else(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 965     MESSAGE(FATAL_ERROR "Invalid FFT library setting: ${GMX_FFT_LIBRARY}. Choose one of: fftw3, mkl, fftpack")
 966 endif(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 967
 968 # enable threaded fftw3 if we've found it
 969 if(FFTW3_THREADS OR FFTW3F_THREADS)
 970     add_definitions(-DFFT5D_FFTW_THREADS)
 971 endif()
 972
 973 set(GMX_EXTERNAL_BLAS TRUE CACHE BOOL "Use external BLAS instead of built-in")
 974 set(GMX_EXTERNAL_LAPACK TRUE CACHE BOOL "Use external LAPACK instead of built-in")
 975 # MKL has BLAS/LAPACK routines
 976 if(NOT HAVE_MKL AND NOT ACCELERATE_FRAMEWORK)
 977   if(GMX_EXTERNAL_BLAS)
 978     if (GMX_BLAS_USER)
 979         list(APPEND GMX_EXTRA_LIBRARIES ${GMX_BLAS_USER})
 980     else(GMX_BLAS_USER)
 981         set(BLAS_FIND_QUIETLY ON)
 982         find_package(BLAS)
 983         if (BLAS_FOUND)
 984           list(APPEND GMX_EXTRA_LIBRARIES ${BLAS_LIBRARIES})
 985         else()
 986           MESSAGE(STATUS "Using internal BLAS library")
 987           set(GMX_EXTERNAL_BLAS FALSE CACHE BOOL "Use external BLAS instead of built-in" FORCE)
 988         endif()
 989     endif(GMX_BLAS_USER)
 990   endif(GMX_EXTERNAL_BLAS)
 991   if(GMX_EXTERNAL_LAPACK)
 992     if (GMX_LAPACK_USER)
 993         list(APPEND GMX_EXTRA_LIBRARIES ${GMX_LAPACK_USER})
 994     else(GMX_LAPACK_USER)
 995         set(LAPACK_FIND_QUIETLY ON)
 996         find_package(LAPACK)
 997         if (LAPACK_FOUND)
 998           list(APPEND GMX_EXTRA_LIBRARIES ${LAPACK_LIBRARIES})
 999         else()
1000           MESSAGE(STATUS "Using internal LAPACK library")
1001           set(GMX_EXTERNAL_LAPACK FALSE CACHE BOOL "Use external LAPACK instead of built-in" FORCE)
1002         endif()
1003     endif(GMX_LAPACK_USER)
1004   endif(GMX_EXTERNAL_LAPACK)
1005 endif()
1006 mark_as_advanced(GMX_EXTERNAL_LAPACK)
1007 mark_as_advanced(GMX_EXTERNAL_BLAS)
1008
1009 set(GMX_USE_PLUGINS OFF CACHE INTERNAL "Whether GROMACS will really try to compile support for VMD plugins")
1010
1011 if(GMX_LOAD_PLUGINS)
1012   if(CYGWIN OR NOT WIN32)
1013     # Native Windows does not have, nor need dlopen
1014     # Note that WIN32 is set with Cygwin, but Cygwin needs dlopen to use plug-ins
1015     include(gmxTestdlopen)
1016     gmx_test_dlopen(HAVE_DLOPEN)
1017   endif()
1018
1019   # so, should we use plug-ins?
1020   if((WIN32 AND NOT CYGWIN) OR (HAVE_DLOPEN AND BUILD_SHARED_LIBS))
1021     if(NOT VMD_QUIETLY)
1022       MESSAGE(STATUS
1023           "Found the ability to use plug-ins when building shared libaries, "
1024           "so will compile to use plug-ins (e.g. to read VMD-supported file "
1025           "formats).")
1026     endif()
1027     if(NOT GMX_VMD_PLUGIN_PATH)
1028       find_package(VMD)
1029     endif()
1030     set(GMX_USE_PLUGINS ON)
1031     list(APPEND GMX_EXTRA_LIBRARIES ${CMAKE_DL_LIBS}) # magic cross-platform pre-set variable for dlopen library
1032     set(PKG_DL_LIBS "-l${CMAKE_DL_LIBS}")
1033   else()
1034     set(PKG_DL_LIBS)
1035   endif()
1036 endif(GMX_LOAD_PLUGINS)
1037 set(VMD_QUIETLY TRUE CACHE INTERNAL "")
1038
1039 if(EXISTS "${CMAKE_SOURCE_DIR}/admin/.isreposource")
1040     if(NOT CMAKE_CROSSCOMPILING)
1041         option(GMX_BUILD_MANPAGES "Build man pages" ON)
1042     else()
1043         message(STATUS "Building the man pages is not available when "
1044             "cross-compiling the developer version from git")
1045     endif()
1046 else()
1047     #make sure source package contains all man pages
1048     if(NOT EXISTS "${CMAKE_SOURCE_DIR}/man/man1/ngmx.1")
1049         message(FATAL_ERROR "Man pages are missing from source package.")
1050     endif()
1051 endif()
1052 mark_as_advanced(GMX_BUILD_MANPAGES)
1053
1054 # Math and thread libraries must often come after all others when linking...
1055 if(HAVE_LIBM)
1056     list(APPEND GMX_EXTRA_LIBRARIES m)
1057 endif(HAVE_LIBM)
1058
1059 if(GMX_FAHCORE)
1060   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
1061       "Path to swindirect.h")
1062   include_directories(${COREWRAP_INCLUDE_DIR})
1063 endif(GMX_FAHCORE)
1064
1065 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
1066 # these are set after everything else
1067 if (NOT DEFINED GROMACS_C_FLAGS_SET)
1068     set(GROMACS_C_FLAGS_SET true CACHE INTERNAL "Whether to reset the C flags"
1069         FORCE)
1070     set(CMAKE_C_FLAGS "${GROMACS_C_FLAGS} ${CMAKE_C_FLAGS}" CACHE STRING
1071         "Flags used by the compiler during all build types" FORCE)
1072     if (CMAKE_CXX_COMPILER_LOADED)
1073         set(CMAKE_CXX_FLAGS "${GROMACS_CXX_FLAGS} ${CMAKE_CXX_FLAGS}" CACHE STRING
1074             "Flags used by the compiler during all build types" FORCE)
1075     endif()
1076     set(CMAKE_EXE_LINKER_FLAGS
1077         "${GROMACS_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}"
1078         CACHE STRING "Linker flags for creating executables" FORCE)
1079     set(CMAKE_SHARED_LINKER_FLAGS
1080         "${GROMACS_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS}"
1081         CACHE STRING "Linker flags for creating shared libraries" FORCE)
1082 endif (NOT DEFINED GROMACS_C_FLAGS_SET)
1083
1084 if(NOT GMX_OPENMP)
1085     #Unset all OpenMP flags in case OpenMP was disabled either by the user
1086     #or because it was only partially detected (e.g. only for C but not C++ compiler)
1087     unset(OpenMP_C_FLAGS CACHE)
1088     unset(OpenMP_CXX_FLAGS CACHE)
1089     unset(OpenMP_LINKER_FLAGS CACHE)
1090     unset(OpenMP_SHARED_LINKER_FLAGS)
1091 endif()
1092 ######################################
1093 # Output compiler and CFLAGS used
1094 ######################################
1095 execute_process(COMMAND ${CMAKE_C_COMPILER} --version RESULT_VARIABLE TMP_RESULT OUTPUT_VARIABLE CC_VERSION ERROR_VARIABLE CC_VERSION)
1096 #try executing just the compiler command if that failed...
1097 if(TMP_RESULT)
1098     execute_process(COMMAND ${CMAKE_C_COMPILER} RESULT_VARIABLE TMP_RESULT OUTPUT_VARIABLE CC_VERSION ERROR_VARIABLE CC_VERSION)
1099 endif()
1100 string(LENGTH "${CC_VERSION}" len)
1101 if(len)
1102     string(REGEX MATCH "[^\n]+" CC_VERSION "${CC_VERSION}")
1103 endif()
1104
1105 set(BUILD_COMPILER "@CMAKE_C_COMPILER@ @CMAKE_C_COMPILER_ID@ @CC_VERSION@")
1106 set(BUILD_CFLAGS "@CMAKE_C_FLAGS@")
1107 if(CMAKE_BUILD_TYPE STREQUAL "Debug")
1108     set(BUILD_CFLAGS "@BUILD_CFLAGS@ @CMAKE_C_FLAGS_DEBUG@")
1109 elseif(CMAKE_BUILD_TYPE STREQUAL "Release")
1110     set(BUILD_CFLAGS "@BUILD_CFLAGS@ @CMAKE_C_FLAGS_RELEASE@")
1111 elseif(CMAKE_BUILD_TYPE STREQUAL "MinSizeRel")
1112     set(BUILD_CFLAGS "@BUILD_CFLAGS@ @CMAKE_C_FLAGS_MINSIZEREL@")
1113 elseif(CMAKE_BUILD_TYPE STREQUAL "RelWithDebInfo")
1114     set(BUILD_CFLAGS "@BUILD_CFLAGS@ @CMAKE_C_FLAGS_RELWITHDEBINFO@")
1115 endif()
1116
1117
1118 ########################################################################
1119 # Specify install locations and which subdirectories to process        #
1120 ########################################################################
1121 if (GMX_USE_RELATIVE_INSTALL_PATH)
1122     set(GMX_INSTALL_PREFIX "" CACHE STRING "Prefix gets appended to CMAKE_INSTALL_PREFIX. For cpack it sets the root folder of the archive.")
1123     mark_as_advanced(GMX_INSTALL_PREFIX)
1124 else()
1125     set(GMX_INSTALL_PREFIX "${CMAKE_INSTALL_PREFIX}/")
1126 endif()
1127
1128 if ( NOT DEFINED GMXLIB )
1129     set(GMXLIB lib)
1130 endif()
1131 set(LIB_INSTALL_DIR "${GMX_INSTALL_PREFIX}${GMXLIB}")
1132 set(BIN_INSTALL_DIR  ${GMX_INSTALL_PREFIX}bin)
1133 set(DATA_INSTALL_DIR ${GMX_INSTALL_PREFIX}share/gromacs)
1134 set(MAN_INSTALL_DIR  ${GMX_INSTALL_PREFIX}share/man)
1135 set(INCL_INSTALL_DIR ${GMX_INSTALL_PREFIX}include)
1136
1137 set(GMXLIBDIR        ${DATA_INSTALL_DIR}/top)
1138
1139 ##################################################################
1140 # Shared library settings - Darwin uses INSTALL_NAME_DIR instead!
1141 ##################################################################
1142 if(NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin")
1143     set(CMAKE_SKIP_BUILD_RPATH  FALSE)
1144     set(CMAKE_BUILD_WITH_INSTALL_RPATH FALSE)
1145     set(CMAKE_INSTALL_RPATH "\\\$ORIGIN/../${GMXLIB}")
1146     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
1147 endif()
1148
1149 #COPYING file: Only necessary for binary distributions.
1150 #Simpler to always install.
1151 install(FILES COPYING DESTINATION ${DATA_INSTALL_DIR} COMPONENT data)
1152
1153 add_subdirectory(share)
1154 add_subdirectory(include)
1155 add_subdirectory(src)
1156 add_subdirectory(scripts)
1157
1158 #######################
1159 ## uninstall target
1160 #######################
1161     CONFIGURE_FILE(
1162                    "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
1163                    "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
1164                    IMMEDIATE @ONLY)
1165 ###########################
1166 ADD_CUSTOM_TARGET(uninstall
1167                   "${CMAKE_COMMAND}" -P
1168                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
1169 ###########################
1170
1171
1172 ########################################################################
1173 # Tests                                                                #
1174 ########################################################################
1175
1176 include(CTest)
1177 mark_as_advanced(BUILD_TESTING)
1178 IF(BUILD_TESTING)
1179         enable_testing()
1180         add_subdirectory(tests)
1181 ENDIF()
1182