CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.8)
   2 # Keep CMake suitably quiet on Cygwin
   3 set(CMAKE_LEGACY_CYGWIN_WIN32 0) # Remove when CMake >= 2.8.4 is required
   4
   5 project(Gromacs)
   6 include(Dart)
   7 mark_as_advanced(DART_ROOT)
   8
   9 # PROJECT_VERSION should have the following structure:
  10 # VERSION-dev[-SUFFIX] where the VERSION should have the for: vMajor.vMinor.vPatch
  11 #
  12 # The "-dev" suffix is important to keep because it makes possible to distinguish
  13 # between a build from official release and a build from git release branch on a
  14 # machine with no git.
  15 #
  16 # NOTE: when releasing the "-dev" suffix needs to be stripped off!
  17 set(PROJECT_VERSION "4.6-dev")
  18 set(CUSTOM_VERSION_STRING ""
  19     CACHE STRING "Custom version string (if empty, use hard-coded default)")
  20 mark_as_advanced(CUSTOM_VERSION_STRING)
  21 if (CUSTOM_VERSION_STRING)
  22     set(PROJECT_VERSION ${CUSTOM_VERSION_STRING})
  23 endif (CUSTOM_VERSION_STRING)
  24 set(SOVERSION 6)
  25 # It is a bit irritating, but this has to be set separately for now!
  26 SET(CPACK_PACKAGE_VERSION_MAJOR "4")
  27 SET(CPACK_PACKAGE_VERSION_MINOR "6")
  28 #SET(CPACK_PACKAGE_VERSION_PATCH "0")
  29
  30
  31 # Cmake modules/macros are in a subdirectory to keep this file cleaner
  32 set(CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake)
  33
  34 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
  35 set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
  36 endif()
  37
  38 if(NOT CMAKE_BUILD_TYPE)
  39     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel." FORCE)
  40 endif(NOT CMAKE_BUILD_TYPE)
  41
  42 enable_language(C)
  43
  44 set(CPACK_PACKAGE_VERSION ${PROJECT_VERSION})
  45 set(CPACK_PACKAGE_VENDOR "gromacs.org")
  46 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Gromacs - a toolkit for high-performance molecular simulation")
  47 set(CPACK_SET_DESTDIR "ON")
  48 set(CPACK_INCLUDE_TOPLEVEL_DIRECTORY 0)
  49 set(CPACK_RESOURCE_FILE_WELCOME "${CMAKE_SOURCE_DIR}/admin/InstallWelcome.txt")
  50 # Its GPL/LGPL, so they do not have to agree to a license for mere usage, but some installers require this...
  51 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_SOURCE_DIR}/admin/InstallLicense.txt")
  52 set(CPACK_RESOURCE_FILE_README "${CMAKE_SOURCE_DIR}/admin/InstallInfo.txt")
  53
  54 #must come after all cpack settings!
  55 include(CPack)
  56
  57 ########################################################################
  58 # Check and warn if cache generated on a different host is being reused
  59 ########################################################################
  60 if(CMAKE_HOST_UNIX)
  61     execute_process(COMMAND hostname
  62                     OUTPUT_VARIABLE TMP_HOSTNAME
  63                     OUTPUT_STRIP_TRAILING_WHITESPACE)
  64     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}")
  65         message(WARNING "
  66             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
  67             is being reused! This could lead to inconsitencies; therefore, it is
  68             recommended to regenerate the cache!")
  69     endif()
  70     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
  71             "Hostname of the machine where the cache was generated.")
  72 endif()
  73
  74 ########################################################################
  75 # Fix stupid flags on Windows
  76 ########################################################################
  77 SET(SHARED_LIBS_DEFAULT ON)
  78 IF( WIN32 AND NOT CYGWIN)
  79   option(GMX_PREFER_STATIC_LIBS "When finding libraries prefer static system libraries (MT instead of MD)!" ON)
  80   mark_as_advanced(GMX_PREFER_STATIC_LIBS)
  81   SET(SHARED_LIBS_DEFAULT OFF)  #is currently not working on Windows
  82
  83   IF (GMX_PREFER_STATIC_LIBS)
  84     #Only setting Debug and Release flags. Others configurations current not used.
  85     STRING(REPLACE /MD /MT CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE})
  86     SET(CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE} CACHE STRING "" FORCE)
  87     STRING(REPLACE /MD /MT CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG})
  88     SET(CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG} CACHE STRING "" FORCE)
  89     STRING(REPLACE /MD /MT CMAKE_CXX_FLAGS_RELEASE ${CMAKE_CXX_FLAGS_RELEASE})
  90     SET(CMAKE_CXX_FLAGS_RELEASE ${CMAKE_CXX_FLAGS_RELEASE} CACHE STRING "" FORCE)
  91     STRING(REPLACE /MD /MT CMAKE_CXX_FLAGS_DEBUG ${CMAKE_CXX_FLAGS_DEBUG})
  92     SET(CMAKE_CXX_FLAGS_DEBUG ${CMAKE_CXX_FLAGS_DEBUG} CACHE STRING "" FORCE)
  93   ENDIF()
  94
  95   #Workaround for cmake bug 13174. Replace deprecated options.
  96   IF( CMAKE_C_COMPILER_ID MATCHES "Intel" )
  97     STRING(REPLACE /GZ /RTC1 CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG})
  98     SET(CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG} CACHE STRING "" FORCE)
  99   ENDIF()
 100   IF( CMAKE_CXX_COMPILER_ID MATCHES "Intel" )
 101     STRING(REPLACE /GZ /RTC1 CMAKE_CXX_FLAGS_DEBUG ${CMAKE_CXX_FLAGS_DEBUG})
 102     STRING(REPLACE /GX /EHsc CMAKE_CXX_FLAGS_DEBUG ${CMAKE_CXX_FLAGS_DEBUG})
 103     SET(CMAKE_CXX_FLAGS_DEBUG ${CMAKE_CXX_FLAGS_DEBUG} CACHE STRING "" FORCE)
 104
 105     STRING(REPLACE /GX /EHsc CMAKE_CXX_FLAGS_RELEASE ${CMAKE_CXX_FLAGS_RELEASE})
 106     SET(CMAKE_CXX_FLAGS_RELEASE ${CMAKE_CXX_FLAGS_RELEASE} CACHE STRING "" FORCE)
 107   ENDIF()
 108 ENDIF()
 109
 110 ########################################################################
 111 # User input options                                                   #
 112 ########################################################################
 113 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" OFF)
 114 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 115 option(GMX_THREAD_MPI  "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" ON)
 116 option(GMX_SOFTWARE_INVSQRT "Use GROMACS software 1/sqrt" ON)
 117 mark_as_advanced(GMX_SOFTWARE_INVSQRT)
 118 option(GMX_POWERPC_INVSQRT "Use PowerPC hardware 1/sqrt" OFF)
 119 mark_as_advanced(GMX_POWERPC_INVSQRT)
 120 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 121 mark_as_advanced(GMX_FAHCORE)
 122 option(GMX_OPENMM "Accelerated execution on GPUs through the OpenMM library (rerun cmake after changing to see relevant options)" OFF)
 123 set(GMX_ACCELERATION "auto"
 124     CACHE STRING "Accelerated kernels. Pick one of: auto, none, SSE, BlueGene, Power6, ia64, altivec, fortran")
 125
 126 set(GMX_FFT_LIBRARY "fftw3"
 127     CACHE STRING "FFT library choices: fftw3,mkl,fftpack[built-in]")
 128 option(GMX_DISABLE_FFTW_MEASURE
 129        "Do not optimize FFTW setups (not needed with SSE)" OFF)
 130 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 131 set(GMX_QMMM_PROGRAM "none"
 132     CACHE STRING "QM package choices: none,gaussian,mopac,gamess,orca")
 133 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 134 mark_as_advanced(GMX_BROKEN_CALLOC)
 135 option(BUILD_SHARED_LIBS "Enable shared libraries (can be problematic with MPI, Windows)" ${SHARED_LIBS_DEFAULT})
 136 option(GMX_MPI_IN_PLACE "Enable MPI_IN_PLACE for MPIs that have it defined" ON)
 137 mark_as_advanced(GMX_MPI_IN_PLACE)
 138 option(GMX_LOAD_PLUGINS "Compile with plugin support, needed to read VMD supported file formats" ON)
 139 mark_as_advanced(GMX_LOAD_PLUGINS)
 140
 141
 142 option(GMX_IA32_ASM "Add SSE assembly files for IA32" OFF)
 143 mark_as_advanced(GMX_IA32_ASM)
 144 option(GMX_X86_64_ASM "Add SSE assembly files for X86_64" OFF)
 145 mark_as_advanced(GMX_X86_64_ASM)
 146
 147 option(GMX_OPENMP "Enable OpenMP-based mutithreading. " ON)
 148
 149 option(USE_VERSION_H "Generate development version string/information" ON)
 150 mark_as_advanced(USE_VERSION_H)
 151
 152 option(GMX_DEFAULT_SUFFIX "Use default suffixes for GROMACS binaries and libs (_d for double, _mpi for MPI; rerun cmake after changing to see relevant options)" ON)
 153
 154 if(UNIX AND NOT APPLE)
 155     option(GMX_PREFER_STATIC_LIBS "When finding libraries prefer \".a\" static archives (NOTE: this is enabled only for UNIX (excluding APPLE) platforms but it might not always work!" OFF)
 156     mark_as_advanced(GMX_PREFER_STATIC_LIBS)
 157 endif()
 158
 159
 160 ######################################################################
 161 # compiler tests
 162 # these need ot be done early (before further tests).
 163 #####################################################################
 164
 165 # cmake/Check{C,CXX}CompilerFlag.cmake are lifted from CMake git next
 166 # branch (proposed for v2.8.9) to be able to detect invalid options
 167 # with the Intel Compilers.
 168 # Remove these files from the source tree when a CMake version that
 169 # includes the features in question becomes required.
 170 include(CheckCCompilerFlag)
 171 include(CheckCXXCompilerFlag)
 172
 173 include(gmxCFlags)
 174 gmx_c_flags()
 175
 176
 177 ########################################################################
 178 # Set up binary and library suffixing
 179 ########################################################################
 180 set(GMX_BINARY_SUFFIX "" CACHE STRING "Suffix for GROMACS binaries (default: _d for double, _mpi for MPI, _mpi_d for MPI and double).")
 181 set(GMX_LIBS_SUFFIX ""
 182   CACHE STRING "Suffix for GROMACS libs (default: _d for double, _mpi for MPI, _mpi_d for MPI and double).")
 183 if (GMX_DEFAULT_SUFFIX)
 184   set(GMX_BINARY_SUFFIX "")
 185   set(GMX_LIBS_SUFFIX "")
 186   if (GMX_MPI)
 187     set(GMX_BINARY_SUFFIX "_mpi")
 188     set(GMX_LIBS_SUFFIX "_mpi")
 189   endif(GMX_MPI)
 190   if (GMX_DOUBLE)
 191     set (GMX_BINARY_SUFFIX "${GMX_BINARY_SUFFIX}_d")
 192     set (GMX_LIBS_SUFFIX "${GMX_LIBS_SUFFIX}_d")
 193   endif(GMX_DOUBLE)
 194   if (GMX_OPENMM)
 195     set (GMX_BINARY_SUFFIX "-gpu")
 196     set (GMX_LIBS_SUFFIX "_gpu")
 197   endif(GMX_OPENMM)
 198   mark_as_advanced(FORCE GMX_BINARY_SUFFIX GMX_LIBS_SUFFIX)
 199   if (NOT SUFFIX_QUIETLY)
 200     message(STATUS "Using default binary suffix: \"${GMX_BINARY_SUFFIX}\"")
 201     message(STATUS "Using default library suffix: \"${GMX_LIBS_SUFFIX}\"")
 202   endif (NOT SUFFIX_QUIETLY)
 203 else(GMX_DEFAULT_SUFFIX)
 204   mark_as_advanced(CLEAR GMX_BINARY_SUFFIX GMX_LIBS_SUFFIX)
 205   if (NOT SUFFIX_QUIETLY)
 206     message(STATUS "Using manually set binary suffix: \"${GMX_BINARY_SUFFIX}\"")
 207     message(STATUS "Using manually set library suffix: \"${GMX_LIBS_SUFFIX}\"")
 208   endif (NOT SUFFIX_QUIETLY)
 209 endif(GMX_DEFAULT_SUFFIX)
 210 set(SUFFIX_QUIETLY TRUE CACHE INTERNAL "")
 211
 212 set(PKG_CFLAGS "")
 213 if(GMX_DOUBLE)
 214     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_DOUBLE")
 215 endif(GMX_DOUBLE)
 216 if(GMX_SOFTWARE_INVSQRT)
 217   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_SOFTWARE_INVSQRT")
 218 endif(GMX_SOFTWARE_INVSQRT)
 219 if(GMX_POWERPC_INVSQRT)
 220   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_POWERPC_INVSQRT")
 221 endif(GMX_POWERPC_INVSQRT)
 222
 223 ########################################################################
 224 #Process MPI settings
 225 ########################################################################
 226 include(gmxManageMPI)
 227
 228 #######################################################################
 229 # Check for options incompatible with OpenMM build                    #
 230 #######################################################################
 231 if(GMX_OPENMM)
 232     # we'll use the built-in fft to avoid unnecessary dependencies
 233     string(TOUPPER ${GMX_FFT_LIBRARY} GMX_FFT_LIBRARY)
 234     if(NOT ${GMX_FFT_LIBRARY} STREQUAL "FFTPACK")
 235         message(STATUS "No external FFT libraries needed for the OpenMM build, switching to fftpack!")
 236         set(GMX_FFT_LIBRARY "fftpack" CACHE STRING
 237                 "No external FFT libraries needed for the OpenMM build, switching to  fftpack!" FORCE)
 238     endif()
 239     if(GMX_MPI)
 240         message(FATAL_ERROR "The OpenMM build is not compatible with MPI!")
 241     endif(GMX_MPI)
 242     if(GMX_THREAD_MPI)
 243         message(STATUS "Thread-MPI not compatible with OpenMM, disabled!")
 244         set(GMX_THREAD_MPI OFF CACHE BOOL
 245                 "Thread-MPI not compatible with OpenMM build, disabled!" FORCE)
 246     endif(GMX_THREAD_MPI)
 247     if(GMX_OPENMP)
 248         message(STATUS "OpenMP multithreading not compatible with OpenMM, disabled")
 249         set(GMX_OPENMP OFF CACHE BOOL
 250             "OpenMP multithreading not compatible with OpenMM, disabled!" FORCE)
 251     endif()
 252     if(GMX_SOFTWARE_INVSQRT)
 253         set(GMX_SOFTWARE_INVSQRT OFF CACHE STRING
 254                 "The OpenMM build does not need GROMACS software 1/sqrt!" FORCE)
 255     endif(GMX_SOFTWARE_INVSQRT)
 256     string(TOUPPER ${GMX_ACCELERATION} GMX_ACCELERATION)
 257     if(NOT GMX_ACCELERATION STREQUAL "NONE")
 258         message(STATUS "Switching off CPU-based acceleration, the OpenMM build does not support/need any!")
 259         set(GMX_ACCELERATION "none" CACHE STRING
 260                 "Switching off CPU-based acceleration, the OpenMM build does not support/need any!" FORCE)
 261     endif()
 262     if(GMX_FAHCORE)
 263         message(FATAL_ERROR "The OpenMM build does not support FAH build!")
 264     endif(GMX_FAHCORE)
 265     if(GMX_DOUBLE)
 266         message(FATAL_ERROR  "The OpenMM-build does not support double precision calculations!")
 267     endif()
 268     # mark as advanced the unused variables
 269     mark_as_advanced(FORCE GMX_ACCELERATION GMX_MPI GMX_FFT_LIBRARY
 270         GMX_QMMM_PROGRAM GMX_THREAD_MPI GMX_DOUBLE)
 271 else(GMX_OPENMM)
 272      mark_as_advanced(CLEAR GMX_ACCELERATION GMX_MPI GMX_FFT_LIBRARY
 273         GMX_QMMM_PROGRAM GMX_THREAD_MPI GMX_DOUBLE)
 274 endif(GMX_OPENMM)
 275
 276
 277 ########################################################################
 278 # Basic system tests (standard libraries, headers, functions, types)   #
 279 ########################################################################
 280 include(CheckIncludeFiles)
 281 check_include_files(string.h     HAVE_STRING_H)
 282 check_include_files(math.h       HAVE_MATH_H)
 283 check_include_files(limits.h     HAVE_LIMITS_H)
 284 check_include_files(memory.h     HAVE_MEMORY_H)
 285 check_include_files(unistd.h     HAVE_UNISTD_H)
 286 check_include_files(direct.h     HAVE_DIRECT_H)
 287 check_include_files(pwd.h        HAVE_PWD_H)
 288 check_include_files(stdint.h     HAVE_STDINT_H)
 289 check_include_files(stdlib.h     HAVE_STDLIB_H)
 290 check_include_files(pthread.h    HAVE_PTHREAD_H)
 291 check_include_files(dirent.h     HAVE_DIRENT_H)
 292 check_include_files(inttypes.h   HAVE_INTTYPES_H)
 293 check_include_files(regex.h      HAVE_REGEX_H)
 294 check_include_files(sys/types.h  HAVE_SYS_TYPES_H)
 295 check_include_files(sys/stat.h   HAVE_SYS_STAT_H)
 296 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 297 check_include_files(rpc/rpc.h    HAVE_RPC_RPC_H)
 298 check_include_files("rpc/rpc.h;rpc/xdr.h"    HAVE_RPC_XDR_H)
 299 # SSE support
 300 check_include_files(xmmintrin.h  HAVE_XMMINTRIN_H)
 301 check_include_files(emmintrin.h  HAVE_EMMINTRIN_H)
 302 check_include_files(pmmintrin.h  HAVE_PMMINTRIN_H)
 303 check_include_files(smmintrin.h  HAVE_SMMINTRIN_H)
 304 check_include_files(io.h                 HAVE_IO_H)
 305
 306
 307 include(CheckFunctionExists)
 308 check_function_exists(strcasecmp        HAVE_STRCASECMP)
 309 check_function_exists(strdup            HAVE_STRDUP)
 310 check_function_exists(vprintf           HAVE_VPRINTF)
 311 check_function_exists(memcmp            HAVE_MEMCMP)
 312 check_function_exists(posix_memalign    HAVE_POSIX_MEMALIGN)
 313 check_function_exists(memalign          HAVE_MEMALIGN)
 314 check_function_exists(_aligned_malloc   HAVE__ALIGNED_MALLOC)
 315 check_function_exists(gettimeofday      HAVE_GETTIMEOFDAY)
 316 check_function_exists(isnan             HAVE_ISNAN)
 317 check_function_exists(_isnan            HAVE__ISNAN)
 318 check_function_exists(fsync             HAVE_FSYNC)
 319 check_function_exists(_fileno           HAVE__FILENO)
 320 check_function_exists(fileno            HAVE_FILENO)
 321 check_function_exists(_commit           HAVE__COMMIT)
 322 check_function_exists(lstat             HAVE_LSTAT)
 323 check_function_exists(sigaction         HAVE_SIGACTION)
 324
 325 include(CheckLibraryExists)
 326 check_library_exists(m sqrt "" HAVE_LIBM)
 327 check_library_exists(m cbrt "" HAVE_CBRT)
 328
 329
 330 include(CheckTypeSize)
 331
 332 check_type_size("bool"          SIZEOF_BOOL) # will also set HAVE_BOOL
 333 check_type_size("int"           SIZEOF_INT)
 334 check_type_size("long int"      SIZEOF_LONG_INT)
 335 check_type_size("long long int" SIZEOF_LONG_LONG_INT)
 336 check_type_size("off_t"         SIZEOF_OFF_T)
 337 check_type_size("void *"        SIZEOF_VOIDP)
 338
 339 if (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 340     set(GMX_64_BIT TRUE)
 341 else (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 342     set(GMX_64_BIT FALSE)
 343 endif (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 344
 345 # Check for some basic types that we *need*, so set these to int if they are not present
 346 check_type_size(uid_t uid_t)
 347 if(NOT uid_t)
 348   set(uid_t int)
 349 else(NOT uid_t)
 350   set(uid_t 0)
 351 endif(NOT uid_t)
 352
 353 check_type_size(gid_t gid_t)
 354 if(NOT gid_t)
 355   set(gid_t 1)
 356 else(NOT gid_t)
 357   set(gid_t 0)
 358 endif(NOT gid_t)
 359
 360 check_type_size(size_t size_t)
 361 if(NOT size_t)
 362   set(size_t int)
 363 else(NOT size_t)
 364   set(size_t 0)
 365 endif(NOT size_t)
 366
 367 check_type_size(off_t off_t)
 368 if(NOT off_t)
 369   set(off_t int)
 370 else(NOT off_t)
 371   set(off_t 0)
 372 endif(NOT off_t)
 373
 374 include(TestBigEndian)
 375 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 376
 377
 378
 379
 380 ########################################################################
 381 # Find external packages                                               #
 382 ########################################################################
 383 if(UNIX AND NOT APPLE)
 384     if(GMX_PREFER_STATIC_LIBS)
 385         SET(CMAKE_FIND_LIBRARY_SUFFIXES .a ${CMAKE_FIND_LIBRARY_SUFFIXES})
 386         if(BUILD_SHARED_LIBS)
 387             message(WARNING "Static libraries requested, the GROMACS libraries will also be build static (BUILD_SHARED_LIBS=OFF)")
 388             set(BUILD_SHARED_LIBS OFF CACHE BOOL "Enable shared libraries (can be problematic with MPI, Windows)" FORCE)
 389         endif()
 390     endif()
 391 endif()
 392
 393 option(GMX_XML "Use libxml2 to parse xml files" ON)
 394 if (GMX_XML)
 395   find_package(LibXml2)
 396   set(PKG_XML "")
 397   if(LIBXML2_FOUND)
 398     include_directories(${LIBXML2_INCLUDE_DIR})
 399     set(PKG_XML libxml-2.0)
 400     set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 401     set(HAVE_LIBXML2 1)
 402   endif(LIBXML2_FOUND)
 403 endif(GMX_XML)
 404
 405 option(GMX_GSL "Add support for gsl" OFF)
 406 if (GMX_GSL)
 407   find_package(gsl)
 408   set(PKG_GSL "")
 409   if(GSL_FOUND)
 410     include_directories(${GSL_INCLUDE_DIR})
 411     set(PKG_GSL gsl)
 412     set(HAVE_LIBGSL 1)
 413   endif(GSL_FOUND)
 414 endif (GMX_GSL)
 415
 416 option(GMX_X11 "Use X window system" OFF)
 417 if (GMX_X11)
 418         find_package(X11)
 419         # X11 includes/libraries are only set in the ngmx subdirectory!
 420         if(X11_FOUND)
 421         set(HAVE_X11 1)
 422         endif(X11_FOUND)
 423 endif(GMX_X11)
 424
 425 if(GMX_THREAD_MPI)
 426     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_THREAD_MPI")
 427     include(ThreadMPI)
 428     set(THREAD_MPI_LIB thread_mpi)
 429     set(GMX_MPI 1)
 430     string(TOUPPER ${GMX_FFT_LIBRARY} ${GMX_FFT_LIBRARY})
 431 endif(GMX_THREAD_MPI)
 432
 433 if(GMX_OPENMM)
 434     set(CUDA_BUILD_EMULATION OFF)
 435     find_package(CUDA 3.1 REQUIRED)
 436     add_definitions(-DGMX_OPENMM)
 437     if(CMAKE_BUILD_TYPE STREQUAL "DEBUG")
 438         set(CUDA_VERBOSE_BUILD ON)
 439     endif()
 440     find_package(OpenMM)
 441 endif(GMX_OPENMM)
 442
 443 if(GMX_OPENMP)
 444     find_package(OpenMP REQUIRED)
 445     set(GROMACS_C_FLAGS "${OpenMP_C_FLAGS} ${GROMACS_C_FLAGS}")
 446     set(GROMACS_CXX_FLAGS "${OpenMP_CXX_FLAGS} ${GROMACS_CXX_FLAGS}")
 447     add_definitions(-DGMX_OPENMP)
 448 endif()
 449
 450 if(APPLE)
 451    find_library(ACCELERATE_FRAMEWORK Accelerate)
 452    list(APPEND GMX_EXTRA_LIBRARIES ${ACCELERATE_FRAMEWORK})
 453 endif(APPLE)
 454
 455 if(CYGWIN)
 456     set(GMX_CYGWIN 1)
 457 endif(CYGWIN)
 458
 459 if(WIN32 AND NOT CYGWIN)
 460     set(GMX_NATIVE_WINDOWS 1)
 461 endif()
 462
 463 # only bother with finding git and using version.h if the source is a git repo
 464 if(EXISTS "${CMAKE_SOURCE_DIR}/.git")
 465     if(USE_VERSION_H)
 466         # We need at least git v1.5.1 be able to parse git's date output. If not
 467         # found or the version is too small, we can't generate version information.
 468         find_package(Git)
 469
 470         # Find out the git version
 471         if(GIT_FOUND AND NOT GIT_VERSION)
 472           execute_process(COMMAND ${GIT_EXECUTABLE} "--version"
 473             OUTPUT_VARIABLE _exec_out
 474             OUTPUT_STRIP_TRAILING_WHITESPACE)
 475           string(REGEX REPLACE "git version (.*)" "\\1" GIT_VERSION ${_exec_out})
 476           set(GIT_VERSION ${GIT_VERSION} CACHE STRING "Git version")
 477           mark_as_advanced(GIT_VERSION)
 478         endif()
 479
 480         if(NOT GIT_FOUND OR GIT_VERSION VERSION_LESS "1.5.1")
 481           message("No compatible git version found, won't be able to generate proper development version information.")
 482           set(USE_VERSION_H OFF)
 483         endif()
 484     endif()
 485 else()
 486     set(USE_VERSION_H OFF)
 487 endif()
 488
 489 ########################################################################
 490 # Generate development version info for cache
 491 ########################################################################
 492 # set(GEN_VERSION_INFO_INTERNAL "ON")
 493 # include(gmxGenerateVersionString)
 494
 495 ########################################################################
 496 # Our own GROMACS tests
 497 ########################################################################
 498
 499 add_definitions( -DHAVE_CONFIG_H )
 500 include_directories(${CMAKE_BINARY_DIR}/src)
 501 include_directories(${CMAKE_BINARY_DIR}/include)
 502 include_directories(${CMAKE_SOURCE_DIR}/include)
 503
 504 include(gmxCheckBuildUserTime)
 505 gmx_check_build_user_time(BUILD_TIME BUILD_USER BUILD_MACHINE)
 506
 507 include(gmxTestFloatFormat)
 508 gmx_test_float_format(GMX_FLOAT_FORMAT_IEEE754
 509                       GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER
 510                       GMX_IEEE754_BIG_ENDIAN_WORD_ORDER)
 511
 512 include(gmxTestLargeFiles)
 513 gmx_test_large_files(GMX_LARGEFILES)
 514 check_function_exists(fseeko     HAVE_FSEEKO)
 515
 516 include(gmxTestSignal)
 517 gmx_test_sigusr1(HAVE_SIGUSR1)
 518
 519 include(gmxTestInline)
 520 gmx_test_inline(INLINE_KEYWORD)
 521
 522 include(gmxTestRestrict)
 523 gmx_test_inline(RESTRICT_KEYWORD)
 524
 525 include(gmxTestPipes)
 526 gmx_test_pipes(HAVE_PIPES)
 527
 528 include(gmxTestIsfinite)
 529 gmx_test_isfinite(HAVE_ISFINITE)
 530 gmx_test__isfinite(HAVE__ISFINITE)
 531 gmx_test__finite(HAVE__FINITE)
 532
 533 include(gmxTestInlineASM)
 534 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 535 gmx_test_inline_asm_msvc_x86(GMX_X86_MSVC_INLINE_ASM)
 536
 537 # turn on SSE if supported with reasonable defaults.
 538 if (${GMX_ACCELERATION} STREQUAL "auto" AND NOT GMX_OPENMM)
 539   if(CMAKE_SYSTEM_PROCESSOR MATCHES "^(i.86|x86|x64|x86_64|AMD64|amd64)" OR CYGWIN)
 540
 541     set(GMX_ACCELERATION "SSE" CACHE STRING "Accelerated kernels. Pick one of: auto, none, SSE, BlueGene, Power6, ia64, altivec, fortran" FORCE)
 542
 543     # Determine the assembler/compiler to use
 544   else()
 545     set(GMX_ACCELERATION "none" CACHE STRING "Accelerated kernels. Pick one of: auto, none, SSE, BlueGene, Power6, ia64, altivec, fortran" FORCE)
 546   endif()
 547 endif (${GMX_ACCELERATION} STREQUAL "auto" AND NOT GMX_OPENMM)
 548
 549 include(gmxTestXDR)
 550 gmx_test_xdr(GMX_SYSTEM_XDR)
 551 if(NOT GMX_SYSTEM_XDR)
 552     set(GMX_INTERNAL_XDR 1)
 553     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_INTERNAL_XDR")
 554 endif(NOT GMX_SYSTEM_XDR)
 555
 556 # Process nonbonded accelerated kernels settings
 557 string(TOUPPER ${GMX_ACCELERATION} ${GMX_ACCELERATION})
 558 if(${GMX_ACCELERATION} STREQUAL "NONE")
 559   # nothing to do
 560 elseif(${GMX_ACCELERATION} STREQUAL "SSE")
 561
 562     if (GMX_64_BIT)
 563       set(GMX_X86_64_ASM ON CACHE BOOL "Add SSE assembly files for x86_64" FORCE)
 564     else (GMX_64_BIT)
 565       set(GMX_IA32_ASM ON CACHE BOOL "Add SSE assembly files for i386" FORCE)
 566     endif (GMX_64_BIT)
 567
 568     if( WIN32 AND NOT CYGWIN )
 569       option(GMX_ASM_USEASM_NASM "Use Nasm for assembly instead of compiler (necessary on windows)" ON)
 570     else()
 571       option(GMX_ASM_USEASM_NASM "Use Nasm for assembly instead of compiler (necessary on windows)" OFF)
 572     endif()
 573         mark_as_advanced(GMX_ASM_USEASM_NASM)
 574
 575     if (NOT GMX_64_BIT)
 576         # for 32-bit compiles, we might need to turn on sse
 577         CHECK_C_COMPILER_FLAG("-msse2" XFLAGS_SSE)
 578         if (XFLAGS_SSE)
 579             set(GROMACS_C_FLAGS "-msse2 ${GROMACS_C_FLAGS}")
 580         endif (XFLAGS_SSE)
 581         CHECK_CXX_COMPILER_FLAG("-msse2" XXFLAGS_SSE)
 582         if (XXFLAGS_SSE)
 583             set(GROMACS_CXX_FLAGS "-msse2 ${GROMACS_CXX_FLAGS}")
 584         endif (XXFLAGS_SSE)
 585     endif (NOT GMX_64_BIT)
 586
 587     if(GMX_IA32_ASM)
 588       if(GMX_DOUBLE)
 589         set(GMX_IA32_SSE2 1)
 590       else()
 591        set(GMX_IA32_SSE 1)
 592       endif()
 593     elseif(GMX_X86_64_ASM)
 594       if(GMX_DOUBLE)
 595        set(GMX_X86_64_SSE2 1)
 596       else()
 597         set(GMX_X86_64_SSE 1)
 598       endif()
 599     endif()
 600
 601 #    if(HAVE_PMMINTRIN_H)
 602 #        set(GMX_SSE3 1)
 603 #    endif(HAVE_PMMINTRIN_H)
 604 #    if(HAVE_SMMINTRIN_H)
 605 #        set(GMX_SSE4_1 1)
 606 #    endif(HAVE_SMMINTRIN_H)
 607
 608 elseif(${GMX_ACCELERATION} STREQUAL "FORTRAN")
 609     set(GMX_FORTRAN 1)
 610     #these are switch on by default sometimes
 611     set(GMX_IA32_ASM 0)
 612     set(GMX_GMX_X86_64_ASM 0)
 613 elseif(${GMX_ACCELERATION} STREQUAL "BLUEGENE")
 614 # GMX_ACCELERATION=BlueGene should be set in the Toolchain-BlueGene?-???.cmake file
 615     message(STATUS "Configuring for BlueGene")
 616     set(GMX_BLUEGENE 1)
 617     if (${CMAKE_SYSTEM_NAME} STREQUAL "BlueGeneL")
 618         set(SHARED_LIBS_DEFAULT OFF CACHE BOOL "Shared libraries not compatible with BlueGene/L, disabled!" FORCE)
 619         set(BUILD_SHARED_LIBS OFF CACHE BOOL "Shared libraries not compatible with BlueGene/L, disabled!" FORCE)
 620     endif (${CMAKE_SYSTEM_NAME} STREQUAL "BlueGeneL")
 621     set(GMX_SOFTWARE_INVSQRT OFF CACHE BOOL "Do not use software reciprocal square root on BlueGene" FORCE)
 622     set(GMX_POWERPC_INVSQRT ON CACHE BOOL "Use hardware reciprocal square root on BlueGene" FORCE)
 623     set(GMX_X11 OFF CACHE BOOL "X11 not compatible with BlueGene, disabled!" FORCE)
 624     set(GMX_THREAD_MPI OFF CACHE BOOL "Thread-MPI not compatible with BlueGene, disabled!" FORCE)
 625     set(GMX_MPI ON CACHE BOOL "Use MPI on BlueGene" FORCE)
 626 elseif(${GMX_ACCELERATION} STREQUAL "POWER6")
 627     set(GMX_POWER6 1)
 628     set(GMX_SOFTWARE_INVSQRT OFF CACHE BOOL "Do not use software reciprocal square root on Power6" FORCE)
 629     set(GMX_POWERPC_INVSQRT ON CACHE BOOL "Use hardware reciprocal square root on Power6" FORCE)
 630 elseif(${GMX_ACCELERATION} STREQUAL "IA64")
 631     set(GMX_IA64_ASM 1)
 632     set(DISABLE_WATERWATER_NLIST 1)
 633     set(DISABLE_WATER_NLIST 1)
 634 elseif(${GMX_ACCELERATION} STREQUAL "ALTIVEC")
 635     check_include_files(altivec.h HAVE_ALTIVEC_H)
 636     if(HAVE_ALTIVEC_H)
 637         set(GMX_PPC_ALTIVEC 1)
 638     endif(HAVE_ALTIVEC_H)
 639 else(${GMX_ACCELERATION} STREQUAL "NONE")
 640     MESSAGE(FATAL_ERROR "Unrecognized option for accelerated kernels: ${GMX_ACCELERATION}. Pick one of auto, none, SSE, Fortran, BlueGene, Power6, ia64, altivec")
 641 endif(${GMX_ACCELERATION} STREQUAL "NONE")
 642
 643 if(GMX_FORTRAN OR GMX_POWER6)
 644     if (GMX_THREAD_MPI)
 645         message(FATAL_ERROR "FORTRAN/POWER6 is incompatible with thread-MPI and only provides a speed-up on certain IBM compilers. Disable FORTRAN (or threads if you really want to use FORTRAN kernels).")
 646     endif(GMX_THREAD_MPI)
 647     enable_language(Fortran)
 648     include(FortranCInterface)
 649     discover_fortran_mangling(prefix isupper suffix extra_under_score found)
 650     if(extra_under_score)
 651         set(extrasuffix "_")
 652     endif(extra_under_score)
 653     if(prefix)
 654       set(prefix "${prefix} ##")
 655     endif(prefix)
 656     if(suffix)
 657       set(suffix "## ${suffix}")
 658       if(extrasuffix)
 659         set(extrasuffix "${suffix}${extrasuffix}")
 660       endif(extrasuffix)
 661     else(suffix)
 662       if(extrasuffix)
 663         # Don't know if this is needed, but it can't hurt
 664         set(extrasuffix "## ${extrasuffix}")
 665       endif(extrasuffix)
 666     endif(suffix)
 667
 668     if(isupper)
 669         set(F77_FUNCDEF   "${prefix} NAME ${suffix}")
 670         set(F77_FUNCDEF_  "${prefix} NAME ${extrasuffix}")
 671     else(isupper)
 672         set(F77_FUNCDEF   "${prefix} name ${suffix}")
 673         set(F77_FUNCDEF_  "${prefix} name ${extrasuffix}")
 674     endif(isupper)
 675 else(GMX_FORTRAN OR GMX_POWER6)
 676         set(F77_FUNCDEF   "name ## _")
 677         set(F77_FUNCDEF_  "name ## _")
 678 endif(GMX_FORTRAN OR GMX_POWER6)
 679
 680 # Process QM/MM Settings
 681 string(TOUPPER ${GMX_QMMM_PROGRAM} ${GMX_QMMM_PROGRAM})
 682 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 683     set(GMX_QMMM_GAUSSIAN 1)
 684 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 685     set(GMX_QMMM_MOPAC 1)
 686 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 687     set(GMX_QMMM_GAMESS 1)
 688 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 689     set(GMX_QMMM_ORCA 1)
 690 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 691     # nothing to do
 692 else(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 693     MESSAGE(FATAL_ERROR "Invalid QM/MM program option: ${GMX_QMMM_PROGRAM}. Choose one of: Gaussian, Mopac, Gamess, Orca, None")
 694 endif(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 695
 696 # Process FFT library settings - if not OpenMM build
 697 string(TOUPPER ${GMX_FFT_LIBRARY} ${GMX_FFT_LIBRARY})
 698 set(PKG_FFT "")
 699 set(PKG_FFT_LIBS "")
 700 if(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 701     if(GMX_DOUBLE)
 702         find_package(FFTW 3 COMPONENTS fftw)
 703     else(GMX_DOUBLE)
 704         find_package(FFTW 3 COMPONENTS fftwf)
 705     endif(GMX_DOUBLE)
 706     if(NOT FFTW_FOUND)
 707       MESSAGE(FATAL_ERROR "Cannot find FFTW3 (with correct precision - libfftw3f for single precision GROMACS or libfftw3 for double precision GROMACS). Fix it, choose another FFT library, or use the Gromacs built-in fftpack (slower)!")
 708     endif(NOT FFTW_FOUND)
 709     include_directories(${FFTW_INCLUDE_DIRS})
 710     set(FFT_LIBRARIES ${FFTW_LIBRARIES})
 711     set(PKG_FFT "${FFTW_PKG}")
 712
 713     set(GMX_FFT_FFTW3 1)
 714
 715     if (${GMX_ACCELERATION} STREQUAL "SSE" AND NOT FFTW_HAVE_SSE)
 716       message(WARNING "The fftw library found is compiled without SSE support, which makes it slow. Consider recompiling it or contact your admin")
 717     endif (${GMX_ACCELERATION} STREQUAL "SSE" AND NOT FFTW_HAVE_SSE)
 718
 719 elseif(${GMX_FFT_LIBRARY} STREQUAL "MKL")
 720 #    MESSAGE(STATUS "Using external FFT library - Intel MKL")
 721     find_package(MKL REQUIRED)
 722     include_directories(${MKL_INCLUDE_DIR})
 723     set(FFT_LIBRARIES ${MKL_LIBRARIES})
 724     set(PKG_FFT_LIBS ${MKL_LIBRARIES})
 725
 726     set(GMX_FFT_MKL 1)
 727     set(HAVE_MKL 1)
 728
 729 #elseif(${GMX_FFT_LIBRARY} STREQUAL "ACML")
 730 #    MESSAGE(STATUS "Using external FFT library - AMD core math library")
 731 #    set(GMX_FFT_ACML 1)
 732 elseif(${GMX_FFT_LIBRARY} STREQUAL "FFTPACK")
 733     MESSAGE(STATUS "Using internal FFT library - fftpack")
 734     set(GMX_FFT_FFTPACK 1)
 735 else(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 736     MESSAGE(FATAL_ERROR "Invalid FFT library setting: ${GMX_FFT_LIBRARY}. Choose one of: fftw3, mkl, fftpack")
 737 endif(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 738
 739 # MKL has BLAS/LAPACK routines
 740 if(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 741   set(GMX_EXTERNAL_BLAS TRUE CACHE BOOL "Use external BLAS instead of built-in")
 742   set(GMX_EXTERNAL_LAPACK TRUE CACHE BOOL "Use external LAPACK instead of built-in")
 743 else(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 744   set(GMX_EXTERNAL_BLAS FALSE CACHE BOOL "Use external BLAS instead of built-in")
 745   set(GMX_EXTERNAL_LAPACK FALSE CACHE BOOL "Use external LAPACK instead of built-in")
 746   if(GMX_EXTERNAL_BLAS)
 747     #FindBLAS needs Fortran
 748     enable_language(Fortran)
 749     if (GMX_BLAS_USER)
 750         list(APPEND GMX_EXTRA_LIBRARIES ${GMX_BLAS_USER})
 751     else(GMX_BLAS_USER)
 752         find_package(BLAS REQUIRED)
 753         list(APPEND GMX_EXTRA_LIBRARIES ${BLAS_LIBRARIES})
 754     endif(GMX_BLAS_USER)
 755   endif(GMX_EXTERNAL_BLAS)
 756   if(GMX_EXTERNAL_LAPACK)
 757     #FindLAPACK needs Fortran
 758     enable_language(Fortran)
 759         if (GMX_LAPACK_USER)
 760         list(APPEND GMX_EXTRA_LIBRARIES ${GMX_LAPACK_USER})
 761         else(GMX_LAPACK_USER)
 762         find_package(LAPACK REQUIRED)
 763         list(APPEND GMX_EXTRA_LIBRARIES ${LAPACK_LIBRARIES})
 764     endif(GMX_LAPACK_USER)
 765   endif(GMX_EXTERNAL_LAPACK)
 766 endif(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 767 mark_as_advanced(GMX_EXTERNAL_LAPACK)
 768 mark_as_advanced(GMX_EXTERNAL_BLAS)
 769
 770 set(GMX_USE_PLUGINS OFF CACHE INTERNAL "Whether GROMACS will really try to compile support for VMD plugins")
 771 set(GMX_VMD_PLUGIN_PATH)
 772 mark_as_advanced(GMX_VMD_PLUGIN_PATH)
 773
 774 if(GMX_LOAD_PLUGINS)
 775   if(CYGWIN OR NOT WIN32)
 776     # Native Windows does not have, nor need dlopen
 777     # Note that WIN32 is set with Cygwin, but Cygwin needs dlopen to use plug-ins
 778     include(gmxTestdlopen)
 779     gmx_test_dlopen(HAVE_DLOPEN)
 780   endif()
 781
 782   find_package(VMD)
 783
 784   # Test for unsuitable versions of VMD
 785
 786   if(VMD_FOUND AND NOT GMX_VMD_PLUGIN_PATH)
 787     message(STATUS "Checking for suitable VMD version")
 788     exec_program(${VMD_EXECUTABLE}
 789       ARGS --help
 790       OUTPUT_VARIABLE VMD_HELP
 791       RETURN_VALUE VMD_EXEC_RETURN)
 792
 793     if(VMD_EXEC_RETURN EQUAL 0)
 794       # This is the accepted idiom for subexpression matching, unfortunately
 795       string(REGEX REPLACE ".*VMD for .*, version ([0-9]+\\.[0-9]*\\.?[0-9]*).*" "\\1" VMD_VERSION ${VMD_HELP})
 796       string(REGEX REPLACE ".*VMD for (.*), version .*" "\\1" VMD_ARCH ${VMD_HELP})
 797
 798       if(VMD_VERSION VERSION_LESS "1.8")
 799         MESSAGE(WARNING "Found VMD version ${VMD_VERSION}, but GROMACS needs at least 1.8")
 800         unset(VMD_EXECUTABLE)
 801         set(VMD_FOUND FALSE)
 802       else()
 803         message(STATUS "VMD version ${VMD_VERSION} is suitable")
 804         if(DEFINED ENV{VMDDIR})
 805           # This permits GROMACS to avoid hard-coding a fall-back
 806           # path that it can tell right now would be useless.
 807           set(GMX_VMD_PLUGIN_PATH "$ENV{VMDDIR}/plugins/${VMD_ARCH}/molfile" CACHE PATH "Path to VMD plugins for molfile I/O")
 808         else()
 809           set(GMX_VMD_PLUGIN_PATH "/usr/local/lib/vmd/plugins/*/molfile" CACHE PATH "Path to VMD plugins for molfile I/O")
 810         endif()
 811       endif()
 812
 813       # clean up
 814       unset(VMD_HELP)
 815       unset(VMD_VERSION)
 816       unset(VMD_ARCH)
 817     endif()
 818   endif()
 819
 820   # so, should we use plug-ins?
 821   if((WIN32 AND NOT CYGWIN) OR (HAVE_DLOPEN AND BUILD_SHARED_LIBS))
 822     if (NOT VMD_QUIETLY)
 823       MESSAGE(STATUS "Found the ability to use plug-ins when building shared libaries, so will compile to use plug-ins (e.g. to read VMD-supported file formats).")
 824     endif(NOT VMD_QUIETLY)
 825     set(GMX_USE_PLUGINS ON)
 826     list(APPEND GMX_EXTRA_LIBRARIES ${CMAKE_DL_LIBS}) # magic cross-platform pre-set variable for dlopen library
 827     set(PKG_DL_LIBS "-l${CMAKE_DL_LIBS}")
 828   else()
 829     set(PKG_DL_LIBS)
 830   endif()
 831 endif(GMX_LOAD_PLUGINS)
 832 set(VMD_QUIETLY TRUE CACHE INTERNAL "")
 833
 834 # Math and thread libraries must often come after all others when linking...
 835 if(HAVE_LIBM)
 836     list(APPEND GMX_EXTRA_LIBRARIES m)
 837 endif(HAVE_LIBM)
 838
 839 if(GMX_FAHCORE)
 840   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 841       "Path to swindirect.h")
 842   include_directories(${COREWRAP_INCLUDE_DIR})
 843 endif(GMX_FAHCORE)
 844
 845 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 846 # these are set after everything else
 847 if (NOT DEFINED GROMACS_C_FLAGS_SET)
 848     set(GROMACS_C_FLAGS_SET true CACHE INTERNAL "Whether to reset the C flags"
 849         FORCE)
 850     set(CMAKE_C_FLAGS "${GROMACS_C_FLAGS} ${CMAKE_C_FLAGS}" CACHE STRING
 851         "Flags used by the compiler during all build types" FORCE)
 852     set(CMAKE_CXX_FLAGS "${GROMACS_CXX_FLAGS} ${CMAKE_CXX_FLAGS}" CACHE STRING
 853         "Flags used by the compiler during all build types" FORCE)
 854     set(CMAKE_EXE_LINKER_FLAGS
 855         "${GROMACS_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}"
 856         CACHE STRING "Linker flags" FORCE)
 857 endif (NOT DEFINED GROMACS_C_FLAGS_SET)
 858
 859 ########################################################################
 860 # Specify install locations and which subdirectories to process        #
 861 ########################################################################
 862 if ( DEFINED GMXLIB )
 863     set(LIB_INSTALL_DIR "${CMAKE_INSTALL_PREFIX}/${GMXLIB}")
 864 else()
 865     set(LIB_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/lib)
 866 endif()
 867 set(BIN_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/bin)
 868 set(DATA_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/gromacs)
 869 set(MAN_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/share/man)
 870 set(INCL_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/include)
 871
 872 set(GMXLIBDIR        ${DATA_INSTALL_DIR}/top)
 873
 874 ##################################################################
 875 # Shared library settings - Darwin uses INSTALL_NAME_DIR instead!
 876 ##################################################################
 877 if(NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin")
 878     set(CMAKE_SKIP_BUILD_RPATH  FALSE)
 879     set(CMAKE_BUILD_WITH_INSTALL_RPATH FALSE)
 880     set(CMAKE_INSTALL_RPATH "${LIB_INSTALL_DIR}")
 881     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 882 endif()
 883
 884 add_subdirectory(share)
 885 add_subdirectory(include)
 886 add_subdirectory(man)
 887 add_subdirectory(src)
 888 add_subdirectory(scripts)
 889
 890 #######################
 891 ## uninstall target
 892 #######################
 893     CONFIGURE_FILE(
 894                    "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 895                    "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
 896                    IMMEDIATE @ONLY)
 897 ###########################
 898 ADD_CUSTOM_TARGET(uninstall
 899                   "${CMAKE_COMMAND}" -P
 900                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
 901 ###########################
 902
 903
 904 ########################################################################
 905 # Tests                                                                #
 906 ########################################################################
 907
 908 include(CTest)
 909 mark_as_advanced(BUILD_TESTING)
 910 IF(BUILD_TESTING)
 911         enable_testing()
 912         add_subdirectory(tests)
 913 ENDIF()
 914