CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2009,2010,2011,2012,2013,2014, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 cmake_minimum_required(VERSION 2.8.8)
  36 # When we require cmake >= 2.8.12, it will provide
  37 # CMAKE_MINIMUM_REQUIRED_VERSION automatically, but in the meantime we
  38 # need to set a variable, and it must have a different name.
  39 set(GMX_CMAKE_MINIMUM_REQUIRED_VERSION "2.8.8")
  40
  41 # CMake modules/macros are in a subdirectory to keep this file cleaner
  42 # This needs to be set before project() in order to pick up toolchain files
  43 list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake ${CMAKE_CURRENT_SOURCE_DIR}/cmake/Platform)
  44
  45 project(Gromacs)
  46
  47 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  48 set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  49 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
  50
  51 # PROJECT_VERSION should have the following structure:
  52 # VERSION-dev[-SUFFIX] where the VERSION should have the for: vMajor.vMinor.vPatch
  53 #
  54 # The "-dev" suffix is important to keep because it makes possible to distinguish
  55 # between a build from official release and a build from git release branch on a
  56 # machine with no git.
  57 #
  58 # NOTE: when releasing the "-dev" suffix needs to be stripped off!
  59 # REGRESSIONTEST_VERSION and REGRESSIONTEST_BRANCH should always be
  60 # defined.
  61 set(PROJECT_VERSION "5.0.1-dev")
  62 # If this is a released tarball, "-dev" will not be present in
  63 # PROJECT_VERSION, and REGRESSIONTEST_VERSION specifies the version
  64 # number of the regressiontest tarball against which the code tarball
  65 # can be tested. This will be the version of the last patch release.
  66 set(REGRESSIONTEST_VERSION "5.0.1-dev")
  67 # If this is not a released tarball, "-dev" will be present in
  68 # PROJECT_VERSION, and REGRESSIONTEST_BRANCH specifies the name of the
  69 # gerrit.gromacs.org branch whose HEAD can test this code, *if* this
  70 # code contains all recent fixes from the corresponding code branch.
  71 set(REGRESSIONTEST_BRANCH "refs/heads/release-5-0")
  72
  73 set(CUSTOM_VERSION_STRING ""
  74     CACHE STRING "Custom version string (if empty, use hard-coded default)")
  75 mark_as_advanced(CUSTOM_VERSION_STRING)
  76 if (CUSTOM_VERSION_STRING)
  77     set(PROJECT_VERSION ${CUSTOM_VERSION_STRING})
  78 endif()
  79 set(LIBRARY_SOVERSION 0)
  80 set(LIBRARY_VERSION ${LIBRARY_SOVERSION}.0.0)
  81 # It is a bit irritating, but this has to be set separately for now!
  82 SET(CPACK_PACKAGE_VERSION_MAJOR "5")
  83 SET(CPACK_PACKAGE_VERSION_MINOR "0")
  84 #SET(CPACK_PACKAGE_VERSION_PATCH "0")
  85
  86 # The numerical gromacs version. It is 40600 for 4.6.0.
  87 # The #define GMX_VERSION in gromacs/version.h is set to this value.
  88 math(EXPR NUM_VERSION
  89     "${CPACK_PACKAGE_VERSION_MAJOR}*10000 + ${CPACK_PACKAGE_VERSION_MINOR}*100")
  90 if(CPACK_PACKAGE_VERSION_PATCH)
  91     math(EXPR NUM_VERSION
  92          "${NUM_VERSION} + ${CPACK_PACKAGE_VERSION_PATCH}")
  93 endif()
  94
  95 # The API version tracks the numerical Gromacs version (for now).
  96 # It is potentially different from the Gromacs version in the future, if
  97 # the programs/libraries diverge from the presumably more stable API.
  98 # The #define GMX_API_VERSION in version.h is set to this value to
  99 # provide backward compatibility of software written against the Gromacs API.
 100 set(API_VERSION ${NUM_VERSION})
 101
 102 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT AND UNIX)
 103     set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
 104 endif()
 105
 106 include(gmxBuildTypeReference)
 107 include(gmxBuildTypeTSAN)
 108 include(gmxBuildTypeASAN)
 109 include(gmxBuildTypeReleaseWithAssert)
 110
 111 if(NOT CMAKE_BUILD_TYPE)
 112     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel Reference RelWithAssert." FORCE)
 113     # There's no need to offer a user the choice of ThreadSanitizer
 114     # Set the possible values of build type for cmake-gui
 115     set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "Debug" "Release"
 116         "MinSizeRel" "RelWithDebInfo" "Reference" "RelWithAssert")
 117 endif()
 118 if(CMAKE_CONFIGURATION_TYPES)
 119     # Add appropriate GROMACS-specific build types for the Visual
 120     # Studio generator (Debug, Release, MinSizeRel and RelWithDebInfo
 121     # are already present by default).
 122     list(APPEND CMAKE_CONFIGURATION_TYPES "RelWithAssert" "Reference")
 123     list(REMOVE_DUPLICATES CMAKE_CONFIGURATION_TYPES)
 124     set(CMAKE_CONFIGURATION_TYPES "${CMAKE_CONFIGURATION_TYPES}" CACHE STRING
 125         "List of configuration types"
 126         FORCE)
 127 endif()
 128 set(build_types_with_explicit_flags RELEASE DEBUG RELWITHDEBUGINFO RELWITHASSERT MINSIZEREL)
 129
 130 enable_language(C)
 131 enable_language(CXX)
 132
 133 set(CPACK_PACKAGE_VERSION ${PROJECT_VERSION})
 134 set(CPACK_PACKAGE_VENDOR "gromacs.org")
 135 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Gromacs - a toolkit for high-performance molecular simulation")
 136 set(CPACK_RESOURCE_FILE_WELCOME "${CMAKE_SOURCE_DIR}/admin/InstallWelcome.txt")
 137 # Its GPL/LGPL, so they do not have to agree to a license for mere usage, but some installers require this...
 138 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_SOURCE_DIR}/COPYING")
 139 set(CPACK_RESOURCE_FILE_README "${CMAKE_SOURCE_DIR}/admin/InstallInfo.txt")
 140 set(CPACK_SOURCE_IGNORE_FILES "\\\\.isreposource$;\\\\.git/;\\\\.gitignore$;\\\\.gitattributes;")
 141 set(CPACK_PROJECT_CONFIG_FILE "${CMAKE_SOURCE_DIR}/CPackInit.cmake")
 142 # CPack source archives include only the directories we list here.
 143 # This variable is a list of pairs of names of source and destination
 144 # directories. Most of these are used for content GROMACS generates as
 145 # part of the configuration or build.
 146 set(CPACK_SOURCE_INSTALLED_DIRECTORIES "${CMAKE_SOURCE_DIR};/;${CMAKE_BINARY_DIR}/src/programs/completion;src/programs/completion;${CMAKE_BINARY_DIR}/share/man/man1;share/man/man1;${CMAKE_BINARY_DIR}/share/man/man7;share/man/man7;${CMAKE_BINARY_DIR}/share/html/final;share/html/final;${CMAKE_BINARY_DIR}/install-guide/final;/")
 147 set(CPACK_PACKAGE_CONTACT "gmx-users@gromacs.org")
 148
 149 #must come after all cpack settings!
 150 include(CPack)
 151
 152 # Set a default valgrind suppression file.
 153 # This unfortunately needs to duplicate information from CTest to work as
 154 # expected...
 155 set(MEMORYCHECK_SUPPRESSIONS_FILE
 156     "${CMAKE_SOURCE_DIR}/cmake/legacy_and_external.supp"
 157     CACHE FILEPATH
 158     "File that contains suppressions for the memory checker")
 159 include(CTest)
 160
 161 set(SOURCE_IS_GIT_REPOSITORY OFF)
 162 set(SOURCE_IS_SOURCE_DISTRIBUTION OFF)
 163 if(EXISTS "${CMAKE_SOURCE_DIR}/.git")
 164     set(SOURCE_IS_GIT_REPOSITORY ON)
 165 endif()
 166 if(NOT EXISTS "${CMAKE_SOURCE_DIR}/admin/.isreposource")
 167     set(SOURCE_IS_SOURCE_DISTRIBUTION ON)
 168 endif()
 169
 170 ########################################################################
 171 # Check and warn if cache generated on a different host is being reused
 172 ########################################################################
 173 if(CMAKE_HOST_UNIX)
 174     execute_process(COMMAND hostname
 175                     OUTPUT_VARIABLE TMP_HOSTNAME
 176                     OUTPUT_STRIP_TRAILING_WHITESPACE)
 177     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}")
 178         message(WARNING "
 179             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
 180             is being reused! This could lead to inconsitencies; therefore, it is
 181             recommended to regenerate the cache!")
 182     endif()
 183     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
 184             "Hostname of the machine where the cache was generated.")
 185 endif()
 186
 187 ########################################################################
 188 # User input options                                                   #
 189 ########################################################################
 190 include(gmxOptionUtilities)
 191
 192 set(CMAKE_PREFIX_PATH "" CACHE STRING "Extra locations to search for external libraries and tools (give directory without lib, bin, or include)")
 193
 194 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" OFF)
 195 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 196 option(GMX_THREAD_MPI  "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" ON)
 197 gmx_dependent_option(
 198     GMX_MPI_IN_PLACE
 199     "Enable MPI_IN_PLACE for MPIs that have it defined"
 200     ON
 201     GMX_MPI)
 202 mark_as_advanced(GMX_MPI_IN_PLACE)
 203 option(GMX_SOFTWARE_INVSQRT "Use GROMACS software 1/sqrt" ON)
 204 mark_as_advanced(GMX_SOFTWARE_INVSQRT)
 205 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 206 mark_as_advanced(GMX_FAHCORE)
 207
 208 option(GMX_COOL_QUOTES "Enable Gromacs cool quotes" ON)
 209 mark_as_advanced(GMX_COOL_QUOTES)
 210 gmx_add_cache_dependency(GMX_COOL_QUOTES BOOL "NOT GMX_FAHCORE" OFF)
 211
 212 # Decide on GPU settings based on user-settings and GPU/CUDA detection.
 213 # We support CUDA >=v4.0 on *nix, but <= v4.1 doesn't work with MSVC
 214 if(MSVC)
 215     set(REQUIRED_CUDA_VERSION 4.1)
 216 else()
 217     set(REQUIRED_CUDA_VERSION 4.0)
 218 endif()
 219 set(REQUIRED_CUDA_COMPUTE_CAPABILITY 2.0)
 220 include(gmxManageGPU)
 221
 222 # Detect the architecture the compiler is targetting, detect
 223 # SIMD instructions possibilities on that hardware, suggest SIMD instruction set
 224 # to use if none is specified, and populate the cache option for CPU
 225 # SIMD.
 226 include(gmxDetectTargetArchitecture)
 227 gmx_detect_target_architecture()
 228
 229 if(GMX_CPU_ACCELERATION)
 230     # Stay compatible with old Jenkins command line options for specific SIMD acceleration
 231     set(GMX_SIMD "${GMX_CPU_ACCELERATION}" CACHE STRING "SIMD instruction set level and compiler optimization" FORCE)
 232     message("You set GMX_CPU_ACCELERATION, which is deprecated, and will be removed in a later version of GROMACS. It is replaced by GMX_SIMD. For now, copying the value from GMX_CPU_ACCELERATION to GMX_SIMD.")
 233     # TODO remove all references to GMX_CPU_ACCELERATION in master branch
 234 endif()
 235
 236 if(NOT GMX_TARGET_MIC)
 237     include(gmxDetectSimd)
 238     gmx_detect_simd(GMX_SUGGESTED_SIMD)
 239 else()
 240     set(GMX_SUGGESTED_SIMD "None")
 241 endif()
 242
 243 gmx_option_multichoice(
 244     GMX_SIMD
 245     "SIMD instruction set for CPU kernels and compiler optimization"
 246     "${GMX_SUGGESTED_SIMD}"
 247     None SSE2 SSE4.1 AVX_128_FMA AVX_256 AVX2_256 IBM_QPX Sparc64_HPC_ACE Reference)
 248
 249 gmx_option_multichoice(
 250     GMX_FFT_LIBRARY
 251     "FFT library"
 252     "fftw3"
 253     fftw3 mkl "fftpack[built-in]")
 254 gmx_dependent_option(
 255     GMX_BUILD_OWN_FFTW
 256     "Download and build FFTW 3 during the GROMACS build process, rather than fall back on the really slow fftpack."
 257     OFF
 258     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 259 gmx_dependent_option(
 260     GMX_DISABLE_FFTW_MEASURE
 261     "Do not optimize FFTW setups (not needed with SSE)"
 262     OFF
 263     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 264 mark_as_advanced(GMX_BUILD_OWN_FFTW)
 265 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 266
 267 gmx_option_multichoice(
 268     GMX_QMMM_PROGRAM
 269     "QM package for QM/MM"
 270     None
 271     none gaussian mopac gamess orca)
 272
 273 gmx_dependent_cache_variable(GMX_SIMD_REF_FLOAT_WIDTH  "Reference SIMD single precision width" STRING "4" "GMX_SIMD STREQUAL REFERENCE")
 274 gmx_dependent_cache_variable(GMX_SIMD_REF_DOUBLE_WIDTH "Reference SIMD double precision width" STRING "2" "GMX_SIMD STREQUAL REFERENCE")
 275
 276 # This should be moved to a separate NBNXN cmake module when that code is cleaned up and modularized
 277
 278 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 279 mark_as_advanced(GMX_BROKEN_CALLOC)
 280 option(GMX_LOAD_PLUGINS "Compile with plugin support, needed to read VMD supported file formats" ON)
 281 mark_as_advanced(GMX_LOAD_PLUGINS)
 282
 283 option(GMX_GPU  "Enable GPU acceleration" ON)
 284 option(GMX_OPENMP "Enable OpenMP-based multithreading" ON)
 285
 286 option(GMX_USE_TNG "Use the TNG library for trajectory I/O" ON)
 287
 288 option(GMX_GIT_VERSION_INFO "Generate git version information" ${SOURCE_IS_GIT_REPOSITORY})
 289 mark_as_advanced(GMX_GIT_VERSION_INFO)
 290
 291 if(UNIX)
 292     option(GMX_SYMLINK_OLD_BINARY_NAMES "Create symbolic links for pre-5.0 binary names" ON)
 293 endif()
 294 option(GMX_BUILD_MDRUN_ONLY "Build and install only the mdrun binary" OFF)
 295
 296 option(GMX_CYCLE_SUBCOUNTERS "Enable cycle subcounters to get a more detailed cycle timings" OFF)
 297 mark_as_advanced(GMX_CYCLE_SUBCOUNTERS)
 298
 299 option(GMX_SKIP_DEFAULT_CFLAGS "Don't automatically add suggested/required Compiler flags." OFF)
 300 mark_as_advanced(GMX_SKIP_DEFAULT_CFLAGS)
 301
 302 option(GMX_BUILD_FOR_COVERAGE
 303        "Tune build for better code coverage metrics (e.g., disable asserts)"
 304        OFF)
 305 mark_as_advanced(GMX_BUILD_FOR_COVERAGE)
 306
 307
 308 ######################################################################
 309 # Detect OpenMP support
 310 ######################################################################
 311 # The OpenMP detection _must_ come before tests for other CFLAGS.
 312 include(gmxManageOpenMP)
 313
 314
 315
 316 ######################################################################
 317 # Compiler tests
 318 # These need to be done early (before further tests).
 319 #####################################################################
 320
 321 # The cmake/Check{C,CXX}CompilerFlag.cmake files in the GROMACS distribution
 322 # are used with permission from CMake v2.8.9 so that GROMACS can detect
 323 # invalid options with the Intel Compilers.
 324 # These files should be removed from the source tree when a CMake version that
 325 # includes the features in question becomes required for building GROMACS.
 326 include(CheckCCompilerFlag)
 327 include(CheckCXXCompilerFlag)
 328
 329
 330 include(gmxCFlags)
 331 gmx_c_flags()
 332
 333 # This variable should be used for additional compiler flags which are not
 334 # generated in gmxCFlags nor are SIMD or MPI related.
 335 set(EXTRA_C_FLAGS "")
 336 set(EXTRA_CXX_FLAGS "")
 337
 338 # Run through a number of tests for buggy compilers and other issues
 339 include(gmxTestCompilerProblems)
 340 gmx_test_compiler_problems()
 341 # GMX_SIMD will not be set automatically until the second
 342 # pass (which is not strictly guaranteed to occur), so putting this
 343 # check here among logically-related tests is inefficient, but the
 344 # potential loss is likely zero.
 345 if(GMX_SIMD STREQUAL "AVX_256"
 346         AND CMAKE_COMPILER_IS_GNUCC
 347         AND (C_COMPILER_VERSION VERSION_EQUAL "4.6.1"
 348             OR CXX_COMPILER_VERSION VERSION_EQUAL "4.6.1"))
 349     message(FATAL_ERROR "gcc 4.6.1 has buggy support for AVX, and GROMACS mdrun will not work. If you want simulation performance, use a more recent compiler. Otherwise, use GMX_SIMD=SSE4.1")
 350     # See http://gcc.gnu.org/bugzilla/show_bug.cgi?id=49002
 351 endif()
 352
 353
 354
 355 set(PKG_CFLAGS "")
 356 if(GMX_DOUBLE)
 357     add_definitions(-DGMX_DOUBLE)
 358     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_DOUBLE")
 359 endif()
 360 if(GMX_SOFTWARE_INVSQRT)
 361   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_SOFTWARE_INVSQRT")
 362 endif()
 363
 364 if(WIN32 AND NOT CYGWIN)
 365     set(GMX_WSOCKLIB_PATH CACHE PATH "Path to winsock (wsock32.lib) library.")
 366     mark_as_advanced(GMX_WSOCKLIB_PATH)
 367     find_library(WSOCK32_LIBRARY NAMES wsock32 PATHS ${GMX_WSOCKLIB_PATH})
 368     if(WSOCK32_LIBRARY)
 369         list(APPEND GMX_EXTRA_LIBRARIES ${WSOCK32_LIBRARY})
 370         add_definitions(-DGMX_HAVE_WINSOCK)
 371     else()
 372         message(STATUS "No winsock found. Cannot use interactive molecular dynamics (IMD).")
 373     endif(WSOCK32_LIBRARY)
 374 endif()
 375
 376
 377
 378 ########################################################################
 379 # Basic system tests (standard libraries, headers, functions, types)   #
 380 ########################################################################
 381 include(CheckIncludeFiles)
 382 include(CheckIncludeFileCXX)
 383 check_include_files(unistd.h     HAVE_UNISTD_H)
 384 check_include_files(pwd.h        HAVE_PWD_H)
 385 check_include_files(dirent.h     HAVE_DIRENT_H)
 386 check_include_files(time.h       HAVE_TIME_H)
 387 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 388 check_include_files(io.h         HAVE_IO_H)
 389 check_include_files(sched.h      HAVE_SCHED_H)
 390
 391 check_include_files(regex.h      HAVE_POSIX_REGEX)
 392 check_include_file_cxx(regex     HAVE_CXX11_REGEX)
 393 # TODO: It could be nice to inform the user if no regex support is found,
 394 # as selections won't be fully functional.
 395
 396 include(CheckFunctionExists)
 397 check_function_exists(posix_memalign    HAVE_POSIX_MEMALIGN)
 398 check_function_exists(memalign          HAVE_MEMALIGN)
 399 check_function_exists(_aligned_malloc   HAVE__ALIGNED_MALLOC)
 400 check_function_exists(gettimeofday      HAVE_GETTIMEOFDAY)
 401 check_function_exists(fsync             HAVE_FSYNC)
 402 check_function_exists(_fileno           HAVE__FILENO)
 403 check_function_exists(fileno            HAVE_FILENO)
 404 check_function_exists(_commit           HAVE__COMMIT)
 405 check_function_exists(sigaction         HAVE_SIGACTION)
 406 check_function_exists(sysconf           HAVE_SYSCONF)
 407 check_function_exists(sched_setaffinity HAVE_SCHED_SETAFFINITY)
 408 check_function_exists(sched_getaffinity HAVE_SCHED_GETAFFINITY)
 409 check_function_exists(rsqrt             HAVE_RSQRT)
 410 check_function_exists(rsqrtf            HAVE_RSQRTF)
 411 check_function_exists(sqrtf             HAVE_SQRTF)
 412
 413 include(CheckLibraryExists)
 414 check_library_exists(m sqrt "" HAVE_LIBM)
 415 check_library_exists(rt clock_gettime "" HAVE_CLOCK_GETTIME)
 416
 417 include(TestBigEndian)
 418 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 419
 420 # Management of GROMACS options for specific toolchains should go
 421 # here. Because the initial settings for some of the main options have
 422 # already happened, but things like library detection and MPI compiler
 423 # feature detection have not, the docstrings for any over-rides of
 424 # GROMACS defaults or user settings will make sense. Also, any
 425 # toolchain-related reasons for choosing whether to detect various
 426 # things can be sorted out now, before the detection takes place.
 427 if(${CMAKE_SYSTEM_NAME} MATCHES BlueGene)
 428     include(gmxManageBlueGene)
 429 endif()
 430
 431 ########################################################################
 432 #Process MPI settings
 433 ########################################################################
 434 include(gmxManageMPI)
 435
 436
 437 ########################################################################
 438 #Process shared/static library settings
 439 ########################################################################
 440 include(gmxManageSharedLibraries)
 441
 442
 443 ########################################################################
 444 # Find external packages                                               #
 445 ########################################################################
 446
 447 # Unconditionally find the package, as it is also required for unit
 448 # tests. This exports LIBXML2_FOUND, which we should not use because
 449 # it does not tell us that linking will succeed. Instead, we test that
 450 # next.
 451 if(DEFINED LIBXML2_LIBRARIES)
 452   set(LibXml2_FIND_QUIETLY TRUE)
 453 endif()
 454 find_package(LibXml2)
 455 include(gmxTestLibXml2)
 456 gmx_test_libxml2(HAVE_LIBXML2)
 457 option(GMX_XML "Use libxml2 to parse xml files (currently has no effect)" ${HAVE_LIBXML2})
 458 set(PKG_XML "")
 459 mark_as_advanced(GMX_XML)
 460 # Don't actually do anything, since libxml2 is currently not used by libgromacs
 461 #if(GMX_XML AND NOT HAVE_LIBXML2)
 462 #    message(FATAL_ERROR "libxml2 not found. Set GMX_XML=OFF to compile without XML support")
 463 #endif()
 464 #if(GMX_XML)
 465 #    include_directories(${LIBXML2_INCLUDE_DIR})
 466 #    set(PKG_XML libxml-2.0)
 467 #    set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 468 #endif()
 469
 470 option(GMX_EXTRAE "Add support for tracing using EXTRAE" OFF)
 471 mark_as_advanced(GMX_EXTRAE)
 472
 473 if (GMX_EXTRAE)
 474   find_package(EXTRAE)
 475   if(EXTRAE_FOUND)
 476     include_directories(${EXTRAE_INCLUDE_DIR})
 477     set(HAVE_EXTRAE 1)
 478   else()
 479     message(FATAL_ERROR "EXTRAE library was not found. Please add the correct path to CMAKE_PREFIX_PATH")
 480   endif()
 481 endif()
 482
 483 option(GMX_X11 "Use X window system" OFF)
 484 if (GMX_X11)
 485     find_package(X11)
 486     # X11 includes/libraries are only set in the ngmx subdirectory!
 487     if(NOT X11_FOUND)
 488         message(FATAL_ERROR
 489                 "X11 include files and/or libraries were not found. "
 490                 "Set GMX_X11=OFF to compile without X11 support. "
 491                 "gmx view will not be available.")
 492     endif()
 493     include_directories(${X11_INCLUDE_DIR})
 494 endif()
 495
 496 include(ThreadMPI)
 497 # Enable core threading facilities
 498 tmpi_enable_core("${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include")
 499 # Enable tMPI C++ support
 500 tmpi_enable_cxx()
 501 if(GMX_THREAD_MPI)
 502     # enable MPI functions
 503     tmpi_enable()
 504     set(GMX_MPI 1)
 505     set(MPI_IN_PLACE_EXISTS 1)
 506 endif()
 507 # If atomics are manually disabled a define is needed because atomics.h doesn't depend on config.h
 508 if (TMPI_ATOMICS_DISABLED)
 509    add_definitions(-DTMPI_ATOMICS_DISABLED)
 510 endif()
 511
 512 if(GMX_GPU)
 513     # now that we have detected the dependencies, do the second configure pass
 514     gmx_gpu_setup()
 515 endif()
 516
 517 if(CYGWIN)
 518     set(GMX_CYGWIN 1)
 519 endif()
 520
 521 if(WIN32 AND NOT CYGWIN)
 522     set(GMX_NATIVE_WINDOWS 1)
 523     # This makes windows.h not declare min/max as macros that would break
 524     # C++ code using std::min/std::max.
 525     add_definitions(-DNOMINMAX)
 526 endif()
 527
 528 # only bother with finding git and using version.h if the source is a git repo
 529 if(GMX_GIT_VERSION_INFO)
 530     if (NOT SOURCE_IS_GIT_REPOSITORY)
 531         message(FATAL_ERROR
 532             "Cannot generate git version information from source tree not under git. "
 533             "Set GMX_GIT_VERSION_INFO=OFF to proceed.")
 534     endif()
 535     # We need at least git v1.5.3 be able to parse git's date output. If not
 536     # found or the version is too small, we can't generate version information.
 537     find_package(Git)
 538
 539     if(NOT GIT_FOUND OR GIT_VERSION_STRING VERSION_LESS "1.5.3")
 540         message(FATAL_ERROR
 541             "No compatible git version found (>= 1.5.3 required). "
 542             "Won't be able to generate development version information. "
 543             "Set GMX_GIT_VERSION_INFO=OFF to proceed.")
 544     endif()
 545 endif()
 546
 547 # Detect boost unless GMX_EXTERNAL_BOOST is explicitly OFF
 548 # Used for default if GMX_EXTERNAL_BOOST is not defined (first CMake pass)
 549 if(NOT DEFINED GMX_EXTERNAL_BOOST OR GMX_EXTERNAL_BOOST)
 550     find_package(Boost 1.44.0)
 551     if(Boost_FOUND AND Boost_VERSION VERSION_LESS "104400")
 552         set(Boost_FOUND FALSE)
 553     endif()
 554     # Print the notification only on first run, when determining the default
 555     if(NOT DEFINED GMX_EXTERNAL_BOOST AND NOT Boost_FOUND)
 556         message("Boost >= 1.44 not found. Using minimal internal version. "
 557                 "This may cause trouble if you plan on compiling/linking other "
 558                 "software that uses Boost against Gromacs.")
 559     endif()
 560 endif()
 561 option(GMX_EXTERNAL_BOOST "Use external Boost instead of minimal built-in version"
 562        ${Boost_FOUND})
 563 if(GMX_EXTERNAL_BOOST AND NOT Boost_FOUND)
 564     message(FATAL_ERROR
 565         "Boost >= 1.44 not found. "
 566         "You can set GMX_EXTERNAL_BOOST=OFF to compile against minimal "
 567         "version of Boost included with Gromacs.")
 568 endif()
 569
 570 if(NOT DEFINED GMX_BUILD_UNITTESTS AND NOT HAVE_LIBXML2)
 571     message(WARNING "libxml2 not found. Will build GROMACS without unit-tests. This is not recommended, because the unit-tests help to verify that GROMACS functions correctly. Most likely you are missing the libxml2-dev(el) package. After you installed it, set GMX_BUILD_UNITTESTS=ON.")
 572 endif()
 573 option(GMX_BUILD_UNITTESTS "Build unit tests with BUILD_TESTING (uses Google C++ Testing and Mocking Frameworks, requires libxml2)" ${HAVE_LIBXML2})
 574 mark_as_advanced(GMX_BUILD_UNITTESTS)
 575 gmx_add_cache_dependency(GMX_BUILD_UNITTESTS BOOL BUILD_TESTING OFF)
 576 if (GMX_BUILD_UNITTESTS AND NOT HAVE_LIBXML2)
 577     message(FATAL_ERROR
 578         "Cannot build unit tests without libxml2. "
 579         "Either set GMX_BUILD_UNITTESTS=OFF or tell CMake how to find a working version of libxml2.")
 580 endif()
 581
 582 ########################################################################
 583 # Generate development version info for cache
 584 ########################################################################
 585 # set(GEN_VERSION_INFO_INTERNAL "ON")
 586 # include(gmxGenerateVersionString)
 587
 588 ########################################################################
 589 # Our own GROMACS tests
 590 ########################################################################
 591
 592 add_definitions( -DHAVE_CONFIG_H )
 593 include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src)
 594 include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include)
 595 # Required for config.h, maybe should only be set in src/CMakeLists.txt
 596 include_directories(BEFORE ${CMAKE_BINARY_DIR}/src)
 597 # Required for gmx_header_config_gen.h to be found before installation
 598 include_directories(BEFORE ${CMAKE_BINARY_DIR}/src/gromacs/utility)
 599 # Required for now to make old code compile
 600 include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src/gromacs/legacyheaders)
 601
 602 include(gmxTestInlineASM)
 603 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 604
 605 include(gmxSetBuildInformation)
 606 gmx_set_build_information()
 607 # Turn on RDTSCP if:
 608 # - the build system's CPU supports it
 609 # - the acceleration is set to AVX as all AVX-capable CPUs support AVX (which
 610 #   at this point means that the user set it).
 611 # Note: it's better to not use the later set value of GMX_SIMD because
 612 # it reflects the system's capability of both compiling and running AVX code.
 613 # TODO: After merge with 5.0 one could implement a cache variable dependency
 614 # such that GMX_USE_RDTSCP can change if GMX_SIMD is changed to AVX
 615 # after the first cmake pass.
 616 if (BUILD_CPU_FEATURES MATCHES "rdtscp" OR GMX_SIMD MATCHES "AVX")
 617     set(GMX_USE_RDTSCP_DEFAULT_VALUE ON)
 618 else()
 619     set(GMX_USE_RDTSCP_DEFAULT_VALUE OFF)
 620 endif()
 621 option(GMX_USE_RDTSCP "Use RDTSCP for better CPU-based timers (available on recent x86 CPUs; might need to be off when compiling for heterogeneous environments)" ${GMX_USE_RDTSCP_DEFAULT_VALUE})
 622 mark_as_advanced(GMX_USE_RDTSCP)
 623 if(GMX_USE_RDTSCP)
 624     set(HAVE_RDTSCP 1)
 625 endif()
 626
 627 include(gmxTestFloatFormat)
 628 gmx_test_float_format(GMX_FLOAT_FORMAT_IEEE754
 629                       GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER
 630                       GMX_IEEE754_BIG_ENDIAN_WORD_ORDER)
 631
 632 include(gmxTestLargeFiles)
 633 gmx_test_large_files(GMX_LARGEFILES)
 634
 635 include(gmxTestSignal)
 636 gmx_test_sigusr1(HAVE_SIGUSR1)
 637
 638 include(gmxTestPipes)
 639 gmx_test_pipes(HAVE_PIPES)
 640
 641 include(gmxTestIsfinite)
 642 gmx_test_isfinite(HAVE_ISFINITE)
 643 gmx_test__isfinite(HAVE__ISFINITE)
 644 gmx_test__finite(HAVE__FINITE)
 645
 646 include(gmxTestCXX11)
 647 gmx_test_cxx11(GMX_CXX11_SUPPORTED GMX_CXX11_FLAGS)
 648 include(CMakeDependentOption)
 649 # nvcc does not support C++11 flags, so with GPUs we prefer to skip C++11 flags
 650 # entirely to keep the compilation environment uniform.
 651 cmake_dependent_option(GMX_CXX11
 652     "Use C++11 features"
 653     ON "GMX_CXX11_SUPPORTED AND NOT GMX_GPU" OFF)
 654 mark_as_advanced(GMX_CXX11)
 655 if(GMX_CXX11)
 656     set(EXTRA_CXX_FLAGS "${EXTRA_CXX_FLAGS} ${GMX_CXX11_FLAGS}")
 657 endif()
 658
 659
 660 include(gmxTestXDR)
 661 gmx_test_xdr(GMX_SYSTEM_XDR)
 662 if(NOT GMX_SYSTEM_XDR)
 663     set(GMX_INTERNAL_XDR 1)
 664 endif()
 665
 666
 667 ##################################################
 668 # Process SIMD instruction settings
 669 ##################################################
 670 # This checks what flags to add in order to
 671 # support the SIMD instructions we need, and sets
 672 # correct defines for the SIMD instructions supported.
 673 include(gmxTestSimd)
 674 gmx_test_simd()
 675
 676
 677 # Process QM/MM Settings
 678 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 679     set(GMX_QMMM_GAUSSIAN 1)
 680 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 681     set(GMX_QMMM_MOPAC 1)
 682 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 683     set(GMX_QMMM_GAMESS 1)
 684 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 685     set(GMX_QMMM_ORCA 1)
 686 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 687     # nothing to do
 688 else()
 689     gmx_invalid_option_value(GMX_QMMM_PROGRAM)
 690 endif()
 691
 692
 693 ##################################################
 694 # Process FFT library settings
 695 ##################################################
 696 include(gmxManageFFTLibraries)
 697
 698
 699 include(gmxManageLinearAlgebraLibraries)
 700
 701 # Whether GROMACS will really try to compile support for VMD plugins
 702 set(GMX_USE_PLUGINS OFF)
 703
 704 if(GMX_LOAD_PLUGINS)
 705   if(CYGWIN OR NOT WIN32)
 706     # Native Windows does not have, nor need dlopen
 707     # Note that WIN32 is set with Cygwin, but Cygwin needs dlopen to use plug-ins
 708     include(gmxTestdlopen)
 709     gmx_test_dlopen(HAVE_DLOPEN)
 710   endif()
 711
 712   # so, should we use plug-ins?
 713   if((WIN32 AND NOT CYGWIN) OR (HAVE_DLOPEN AND BUILD_SHARED_LIBS))
 714     if(NOT VMD_QUIETLY)
 715       MESSAGE(STATUS
 716           "Found the ability to use plug-ins when building shared libaries, "
 717           "so will compile to use plug-ins (e.g. to read VMD-supported file "
 718           "formats).")
 719     endif()
 720     if(NOT GMX_VMD_PLUGIN_PATH)
 721       find_package(VMD)
 722     endif()
 723     set(GMX_USE_PLUGINS ON)
 724     list(APPEND GMX_EXTRA_LIBRARIES ${CMAKE_DL_LIBS}) # magic cross-platform pre-set variable for dlopen library
 725     set(PKG_DL_LIBS "-l${CMAKE_DL_LIBS}")
 726   else()
 727     set(PKG_DL_LIBS)
 728   endif()
 729 endif()
 730 set(VMD_QUIETLY TRUE CACHE INTERNAL "")
 731
 732 # Link real-time library for POSIX timers. The check for clock_gettime
 733 # confirms the linkability of rt.
 734 if(HAVE_TIME_H AND HAVE_UNISTD_H AND HAVE_CLOCK_GETTIME)
 735     list(APPEND GMX_EXTRA_LIBRARIES rt)
 736 endif()
 737
 738 # Math and thread libraries must often come after all others when linking...
 739 if(HAVE_LIBM)
 740     list(APPEND GMX_EXTRA_LIBRARIES m)
 741 endif()
 742
 743 option(GMX_NACL "Configure for Native Client builds" OFF)
 744 if (GMX_NACL)
 745   list(APPEND GMX_EXTRA_LIBRARIES nosys)
 746   set(GMX_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -lnosys")
 747   set(GMX_NO_NICE 1)
 748   set(GMX_NO_RENAME 1)
 749 endif()
 750 mark_as_advanced(GMX_NACL)
 751
 752 if(GMX_FAHCORE)
 753   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 754       "Path to swindirect.h")
 755   include_directories(${COREWRAP_INCLUDE_DIR})
 756 endif()
 757
 758 option(GMX_BUILD_HELP "Build man pages, HTML help, and completions automatically (requires that compiled binaries can be executed on the build host)" OFF)
 759 mark_as_advanced(GMX_BUILD_HELP)
 760 if (GMX_BUILD_HELP AND SOURCE_IS_SOURCE_DISTRIBUTION AND
 761     "${CMAKE_CURRENT_SOURCE_DIR}" STREQUAL "${CMAKE_CURRENT_BINARY_DIR}")
 762
 763     message(FATAL_ERROR
 764         "Rebuilding HTML and man pages is not supported for in-source "
 765         "builds from a source distribution. "
 766         "Set GMX_BUILD_HELP=OFF or do an out-of-source build to proceed.")
 767 endif()
 768
 769 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 770 # these are set after everything else
 771 if (NOT GMX_SKIP_DEFAULT_CFLAGS)
 772     set(CMAKE_C_FLAGS "${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${CMAKE_C_FLAGS}")
 773     set(CMAKE_CXX_FLAGS "${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${CMAKE_CXX_FLAGS}")
 774     set(CMAKE_EXE_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}")
 775     set(CMAKE_SHARED_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS}")
 776 else()
 777     message("Recommended flags which are not added because GMX_SKIP_DEFAULT_CFLAGS=yes:")
 778     message("CMAKE_C_FLAGS: ${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${GMXC_CFLAGS}")
 779     message("CMAKE_C_FLAGS_RELEASE: ${GMXC_CFLAGS_RELEASE}")
 780     message("CMAKE_C_FLAGS_DEBUG: ${GMXC_CFLAGS_DEBUG}")
 781     message("CMAKE_CXX_FLAGS: ${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${GMXC_CXXFLAGS}")
 782     message("CMAKE_CXX_FLAGS_RELEASE: ${GMXC_CXXFLAGS_RELEASE}")
 783     message("CMAKE_CXX_FLAGS_DEBUG: ${GMXC_CXXFLAGS_DEBUG}")
 784     message("CMAKE_EXE_LINKER_FLAGS: ${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS}")
 785     message("CMAKE_SHARED_LINKER_FLAGS: ${MPI_LINKER_FLAGS}")
 786 endif()
 787
 788 if(NOT GMX_OPENMP)
 789     #Unset all OpenMP flags in case OpenMP was disabled either by the user
 790     #or because it was only partially detected (e.g. only for C but not C++ compiler)
 791     unset(OpenMP_C_FLAGS CACHE)
 792     unset(OpenMP_CXX_FLAGS CACHE)
 793 else()
 794     set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} ${OpenMP_LINKER_FLAGS})
 795     set(GMX_SHARED_LINKER_FLAGS ${GMX_SHARED_LINKER_FLAGS} ${OpenMP_SHARED_LINKER_FLAGS})
 796 endif()
 797 set(PKG_CFLAGS "${PKG_CFLAGS} ${OpenMP_C_FLAGS}")
 798
 799 ########################################################################
 800 # Specify install locations
 801 ########################################################################
 802 # Use GNUInstallDirs to set paths on multiarch systems.
 803 include(GNUInstallDirs)
 804
 805 # Customization for the installation tree paths.
 806 set(GMX_LIB_INSTALL_DIR ${CMAKE_INSTALL_LIBDIR} CACHE STRING
 807     "Library installation directory (default: ${CMAKE_INSTALL_LIBDIR})")
 808 set(GMX_DATA_INSTALL_DIR gromacs CACHE STRING
 809     "Data installation directory under share/ (default: gromacs)")
 810 mark_as_advanced(GMX_LIB_INSTALL_DIR GMX_DATA_INSTALL_DIR)
 811
 812 # These variables are used internally to provide a central location for
 813 # customizing the install locations.
 814 set(LIB_INSTALL_DIR  ${GMX_LIB_INSTALL_DIR})
 815 set(BIN_INSTALL_DIR  bin)
 816 set(DATA_INSTALL_DIR share/${GMX_DATA_INSTALL_DIR})
 817 set(MAN_INSTALL_DIR  share/man)
 818 set(INCL_INSTALL_DIR include)
 819
 820 # These variables get written into config.h for use in finding the data
 821 # directories.
 822 set(GMXLIB_SEARCH_DIR share/${GMX_DATA_INSTALL_DIR}/top)
 823 set(GMXLIB_FALLBACK   ${CMAKE_INSTALL_PREFIX}/${DATA_INSTALL_DIR}/top)
 824
 825 # Binary and library suffix options
 826 include(gmxManageSuffixes)
 827
 828 ################################################################
 829 # Shared library load path settings
 830 ################################################################
 831 # CMake supports RPATH on OS X only from 2.8.12 upwards.
 832 # CMAKE_SYSTEM_VERSION > 8.0 matches OS X 10.5 and above, where RPATH support
 833 # was added.
 834 if((NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin") OR
 835    ((CMAKE_SYSTEM_VERSION VERSION_GREATER 8.0) AND (NOT CMAKE_VERSION VERSION_LESS 2.8.12)))
 836     # The build folder always has bin/ and lib/; if we are also going to
 837     # install to lib/, then the installation RPATH works also in the build
 838     # tree.  This makes installation slightly faster (no need to rewrite the
 839     # RPATHs), and makes the binaries in the build tree relocatable.
 840     if(GMX_LIB_INSTALL_DIR STREQUAL "lib")
 841         set(CMAKE_BUILD_WITH_INSTALL_RPATH TRUE)
 842     endif()
 843     # Set the RPATH as relative to the executable location to make the
 844     # binaries relocatable.
 845     if(NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin")
 846         set(CMAKE_INSTALL_RPATH "\$ORIGIN/../${GMX_LIB_INSTALL_DIR}")
 847     else()
 848         set(CMAKE_INSTALL_RPATH "@executable_path/../${GMX_LIB_INSTALL_DIR}")
 849     endif()
 850     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 851     set(CMAKE_MACOSX_RPATH 1)
 852 else()
 853     # We are on Darwin/OSX, and CMake cannot handle RPATHs automatically.
 854     if(CMAKE_SYSTEM_VERSION VERSION_GREATER 8.0)
 855         # Set the RPATH options manually.
 856         set(CMAKE_INSTALL_NAME_DIR "@rpath")
 857         set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} "-Wl,-rpath,@executable_path/../${GMX_LIB_INSTALL_DIR}")
 858     else()
 859         # Use the old INSTALL_NAME_DIR mechanism if RPATH is not supported.
 860         set(CMAKE_INSTALL_NAME_DIR "${CMAKE_INSTALL_PREFIX}/${LIB_INSTALL_DIR}")
 861     endif()
 862 endif()
 863
 864 #COPYING file: Only necessary for binary distributions.
 865 #Simpler to always install.
 866 install(FILES COPYING DESTINATION ${DATA_INSTALL_DIR} COMPONENT data)
 867
 868 if(GMX_EXTERNAL_BOOST)
 869     include_directories(${Boost_INCLUDE_DIRS})
 870     set(PKG_CFLAGS "${PKG_CFLAGS} -I${Boost_INCLUDE_DIRS}")
 871 else()
 872     include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src/external/boost)
 873     # typeid not supported for minimal internal version
 874     # (would add significant amount of code)
 875     add_definitions(-DBOOST_NO_TYPEID)
 876     # TODO: Propagate the above settings to the installed CMakeFiles.txt template
 877     # (from share/template/)
 878     set(PKG_CFLAGS "${PKG_CFLAGS} -DBOOST_NO_TYPEID -I${CMAKE_INSTALL_PREFIX}/${INCL_INSTALL_DIR}/gromacs/external/boost")
 879     if (NOT GMX_BUILD_MDRUN_ONLY)
 880         install(DIRECTORY ${CMAKE_SOURCE_DIR}/src/external/boost/boost
 881                 DESTINATION ${INCL_INSTALL_DIR}/gromacs/external/boost
 882                 COMPONENT development)
 883     endif()
 884 endif()
 885
 886 if (GMX_BUILD_FOR_COVERAGE)
 887     # Code heavy with asserts makes conditional coverage close to useless metric,
 888     # as by design most of the false branches are impossible to trigger in
 889     # correctly functioning code.  And the benefit of testing those that could
 890     # be triggered by using an API against its specification isn't usually
 891     # worth the effort.
 892     add_definitions(-DNDEBUG -DBOOST_DISABLE_ASSERTS -DGMX_DISABLE_ASSERTS)
 893 endif()
 894
 895 if (BUILD_TESTING)
 896     # "tests" target builds all the separate test binaries.
 897     add_custom_target(tests)
 898     # "run-ctest" is an internal target that actually runs the tests.
 899     # This is necessary to be able to add separate targets that execute as part
 900     # of 'make check', but are ensured to be executed after the actual tests.
 901     add_custom_target(run-ctest
 902                       COMMAND ${CMAKE_CTEST_COMMAND} --output-on-failure
 903                       COMMENT "Running all tests"
 904                       VERBATIM)
 905     add_dependencies(run-ctest tests)
 906     # "check" target builds and runs all tests.
 907     add_custom_target(check DEPENDS run-ctest)
 908 endif()
 909
 910 if (NOT GMX_BUILD_MDRUN_ONLY)
 911     add_subdirectory(doxygen)
 912     add_subdirectory(install-guide)
 913     add_subdirectory(share)
 914     add_subdirectory(scripts)
 915 endif()
 916 add_subdirectory(src)
 917
 918 if (BUILD_TESTING)
 919     add_subdirectory(tests)
 920 endif()
 921
 922 # Issue a warning if NVIDIA GPUs were detected, but CUDA was not found.
 923 # Don't bother the user after the first configure pass.
 924 if ((CUDA_NOTFOUND_AUTO AND GMX_DETECT_GPU_AVAILABLE) AND NOT GMX_GPU_DETECTION_DONE)
 925     message(WARNING "${CUDA_NOTFOUND_MESSAGE}")
 926 endif()
 927 set(GMX_GPU_DETECTION_DONE TRUE CACHE INTERNAL "Whether GPU detection has already been done")
 928
 929 #######################
 930 ## uninstall target
 931 #######################
 932 CONFIGURE_FILE(   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 933                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
 934                   IMMEDIATE @ONLY)
 935 ###########################
 936 ADD_CUSTOM_TARGET(uninstall
 937                   "${CMAKE_COMMAND}" -P
 938                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
 939 ###########################
 940 set_directory_properties(PROPERTIES
 941             ADDITIONAL_MAKE_CLEAN_FILES "install_manifest.txt")
 942
 943 ########################################################################
 944 # Manual                                                               #
 945 ########################################################################
 946
 947 option(GMX_BUILD_MANUAL "Whether to try to configure to build the PDF manual" OFF)
 948 mark_as_advanced(GMX_BUILD_MANUAL)
 949 if(GMX_BUILD_MANUAL)
 950     # Make sure we only do detection of manual-building dependencies
 951     # when the user opted in for that.
 952     add_subdirectory(manual)
 953 endif()