CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2009,2010,2011,2012,2013,2014, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 cmake_minimum_required(VERSION 2.8.8)
  36 # When we require cmake >= 2.8.12, it will provide
  37 # CMAKE_MINIMUM_REQUIRED_VERSION automatically, but in the meantime we
  38 # need to set a variable, and it must have a different name.
  39 set(GMX_CMAKE_MINIMUM_REQUIRED_VERSION "2.8.8")
  40
  41 # CMake modules/macros are in a subdirectory to keep this file cleaner
  42 # This needs to be set before project() in order to pick up toolchain files
  43 list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake ${CMAKE_CURRENT_SOURCE_DIR}/cmake/Platform)
  44
  45 project(Gromacs)
  46
  47 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  48 set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  49 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
  50
  51 # PROJECT_VERSION should have the following structure:
  52 # VERSION-dev[-SUFFIX] where the VERSION should have the for: vMajor.vMinor.vPatch
  53 #
  54 # The "-dev" suffix is important to keep because it makes possible to distinguish
  55 # between a build from official release and a build from git release branch on a
  56 # machine with no git.
  57 #
  58 # NOTE: when releasing the "-dev" suffix needs to be stripped off!
  59 # REGRESSIONTEST_VERSION and REGRESSIONTEST_BRANCH should always be
  60 # defined.
  61 set(PROJECT_VERSION "5.0.1-dev")
  62 # If this is a released tarball, "-dev" will not be present in
  63 # PROJECT_VERSION, and REGRESSIONTEST_VERSION specifies the version
  64 # number of the regressiontest tarball against which the code tarball
  65 # can be tested. This will be the version of the last patch release.
  66 set(REGRESSIONTEST_VERSION "5.0.1-dev")
  67 # If this is not a released tarball, "-dev" will be present in
  68 # PROJECT_VERSION, and REGRESSIONTEST_BRANCH specifies the name of the
  69 # gerrit.gromacs.org branch whose HEAD can test this code, *if* this
  70 # code contains all recent fixes from the corresponding code branch.
  71 set(REGRESSIONTEST_BRANCH "refs/heads/release-5-0")
  72
  73 set(CUSTOM_VERSION_STRING ""
  74     CACHE STRING "Custom version string (if empty, use hard-coded default)")
  75 mark_as_advanced(CUSTOM_VERSION_STRING)
  76 if (CUSTOM_VERSION_STRING)
  77     set(PROJECT_VERSION ${CUSTOM_VERSION_STRING})
  78 endif()
  79 set(LIBRARY_SOVERSION 0)
  80 set(LIBRARY_VERSION ${LIBRARY_SOVERSION}.0.0)
  81 # It is a bit irritating, but this has to be set separately for now!
  82 SET(CPACK_PACKAGE_VERSION_MAJOR "5")
  83 SET(CPACK_PACKAGE_VERSION_MINOR "0")
  84 #SET(CPACK_PACKAGE_VERSION_PATCH "0")
  85
  86 # The numerical gromacs version. It is 40600 for 4.6.0.
  87 # The #define GMX_VERSION in gromacs/version.h is set to this value.
  88 math(EXPR NUM_VERSION
  89     "${CPACK_PACKAGE_VERSION_MAJOR}*10000 + ${CPACK_PACKAGE_VERSION_MINOR}*100")
  90 if(CPACK_PACKAGE_VERSION_PATCH)
  91     math(EXPR NUM_VERSION
  92          "${NUM_VERSION} + ${CPACK_PACKAGE_VERSION_PATCH}")
  93 endif()
  94
  95 # The API version tracks the numerical Gromacs version (for now).
  96 # It is potentially different from the Gromacs version in the future, if
  97 # the programs/libraries diverge from the presumably more stable API.
  98 # The #define GMX_API_VERSION in version.h is set to this value to
  99 # provide backward compatibility of software written against the Gromacs API.
 100 set(API_VERSION ${NUM_VERSION})
 101
 102 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT AND UNIX)
 103     set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
 104 endif()
 105
 106 include(gmxBuildTypeReference)
 107 include(gmxBuildTypeTSAN)
 108 include(gmxBuildTypeASAN)
 109 include(gmxBuildTypeReleaseWithAssert)
 110
 111 if(NOT CMAKE_BUILD_TYPE)
 112     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel Reference RelWithAssert." FORCE)
 113     # There's no need to offer a user the choice of ThreadSanitizer
 114     # Set the possible values of build type for cmake-gui
 115     set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "Debug" "Release"
 116         "MinSizeRel" "RelWithDebInfo" "Reference" "RelWithAssert")
 117 endif()
 118 if(CMAKE_CONFIGURATION_TYPES)
 119     # Add appropriate GROMACS-specific build types for the Visual
 120     # Studio generator (Debug, Release, MinSizeRel and RelWithDebInfo
 121     # are already present by default).
 122     list(APPEND CMAKE_CONFIGURATION_TYPES "RelWithAssert" "Reference")
 123     list(REMOVE_DUPLICATES CMAKE_CONFIGURATION_TYPES)
 124     set(CMAKE_CONFIGURATION_TYPES "${CMAKE_CONFIGURATION_TYPES}" CACHE STRING
 125         "List of configuration types"
 126         FORCE)
 127 endif()
 128 set(build_types_with_explicit_flags RELEASE DEBUG RELWITHDEBUGINFO RELWITHASSERT MINSIZEREL)
 129
 130 enable_language(C)
 131 enable_language(CXX)
 132
 133 set(CPACK_PACKAGE_VERSION ${PROJECT_VERSION})
 134 set(CPACK_PACKAGE_VENDOR "gromacs.org")
 135 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Gromacs - a toolkit for high-performance molecular simulation")
 136 set(CPACK_RESOURCE_FILE_WELCOME "${CMAKE_SOURCE_DIR}/admin/InstallWelcome.txt")
 137 # Its GPL/LGPL, so they do not have to agree to a license for mere usage, but some installers require this...
 138 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_SOURCE_DIR}/COPYING")
 139 set(CPACK_RESOURCE_FILE_README "${CMAKE_SOURCE_DIR}/admin/InstallInfo.txt")
 140 set(CPACK_SOURCE_IGNORE_FILES "\\\\.isreposource$;\\\\.git/;\\\\.gitignore$")
 141 set(CPACK_PROJECT_CONFIG_FILE "${CMAKE_SOURCE_DIR}/CPackInit.cmake")
 142 set(CPACK_SOURCE_INSTALLED_DIRECTORIES "${CMAKE_SOURCE_DIR};/;${CMAKE_BINARY_DIR}/src/programs/completion;src/programs/completion;${CMAKE_BINARY_DIR}/share/man/man1;share/man/man1;${CMAKE_BINARY_DIR}/share/man/man7;share/man/man7;${CMAKE_BINARY_DIR}/share/html/final;share/html/final")
 143 set(CPACK_PACKAGE_CONTACT "gmx-users@gromacs.org")
 144
 145 #must come after all cpack settings!
 146 include(CPack)
 147
 148 # Set a default valgrind suppression file.
 149 # This unfortunately needs to duplicate information from CTest to work as
 150 # expected...
 151 set(MEMORYCHECK_SUPPRESSIONS_FILE
 152     "${CMAKE_SOURCE_DIR}/cmake/legacy_and_external.supp"
 153     CACHE FILEPATH
 154     "File that contains suppressions for the memory checker")
 155 include(CTest)
 156
 157 set(SOURCE_IS_GIT_REPOSITORY OFF)
 158 set(SOURCE_IS_SOURCE_DISTRIBUTION OFF)
 159 if(EXISTS "${CMAKE_SOURCE_DIR}/.git")
 160     set(SOURCE_IS_GIT_REPOSITORY ON)
 161 endif()
 162 if(NOT EXISTS "${CMAKE_SOURCE_DIR}/admin/.isreposource")
 163     set(SOURCE_IS_SOURCE_DISTRIBUTION ON)
 164 endif()
 165
 166 ########################################################################
 167 # Check and warn if cache generated on a different host is being reused
 168 ########################################################################
 169 if(CMAKE_HOST_UNIX)
 170     execute_process(COMMAND hostname
 171                     OUTPUT_VARIABLE TMP_HOSTNAME
 172                     OUTPUT_STRIP_TRAILING_WHITESPACE)
 173     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}")
 174         message(WARNING "
 175             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
 176             is being reused! This could lead to inconsitencies; therefore, it is
 177             recommended to regenerate the cache!")
 178     endif()
 179     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
 180             "Hostname of the machine where the cache was generated.")
 181 endif()
 182
 183 ########################################################################
 184 # User input options                                                   #
 185 ########################################################################
 186 include(gmxOptionUtilities)
 187
 188 set(CMAKE_PREFIX_PATH "" CACHE STRING "Extra locations to search for external libraries and tools (give directory without lib, bin, or include)")
 189
 190 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" OFF)
 191 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 192 option(GMX_THREAD_MPI  "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" ON)
 193 gmx_dependent_option(
 194     GMX_MPI_IN_PLACE
 195     "Enable MPI_IN_PLACE for MPIs that have it defined"
 196     ON
 197     GMX_MPI)
 198 mark_as_advanced(GMX_MPI_IN_PLACE)
 199 option(GMX_SOFTWARE_INVSQRT "Use GROMACS software 1/sqrt" ON)
 200 mark_as_advanced(GMX_SOFTWARE_INVSQRT)
 201 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 202 mark_as_advanced(GMX_FAHCORE)
 203
 204 option(GMX_COOL_QUOTES "Enable Gromacs cool quotes" ON)
 205 mark_as_advanced(GMX_COOL_QUOTES)
 206 gmx_add_cache_dependency(GMX_COOL_QUOTES BOOL "NOT GMX_FAHCORE" OFF)
 207
 208 # Decide on GPU settings based on user-settings and GPU/CUDA detection.
 209 # We support CUDA >=v4.0 on *nix, but <= v4.1 doesn't work with MSVC
 210 if(MSVC)
 211     set(REQUIRED_CUDA_VERSION 4.1)
 212 else()
 213     set(REQUIRED_CUDA_VERSION 4.0)
 214 endif()
 215 set(REQUIRED_CUDA_COMPUTE_CAPABILITY 2.0)
 216 include(gmxManageGPU)
 217
 218 # Detect the architecture the compiler is targetting, detect
 219 # SIMD instructions possibilities on that hardware, suggest SIMD instruction set
 220 # to use if none is specified, and populate the cache option for CPU
 221 # SIMD.
 222 include(gmxDetectTargetArchitecture)
 223 gmx_detect_target_architecture()
 224
 225 if(GMX_CPU_ACCELERATION)
 226     # Stay compatible with old Jenkins command line options for specific SIMD acceleration
 227     set(GMX_SIMD "${GMX_CPU_ACCELERATION}" CACHE STRING "SIMD instruction set level and compiler optimization" FORCE)
 228     message("You set GMX_CPU_ACCELERATION, which is deprecated, and will be removed in a later version of GROMACS. It is replaced by GMX_SIMD. For now, copying the value from GMX_CPU_ACCELERATION to GMX_SIMD.")
 229     # TODO remove all references to GMX_CPU_ACCELERATION in master branch
 230 endif()
 231
 232 if(NOT GMX_TARGET_MIC)
 233     include(gmxDetectSimd)
 234     gmx_detect_simd(GMX_SUGGESTED_SIMD)
 235 else()
 236     set(GMX_SUGGESTED_SIMD "None")
 237 endif()
 238
 239 gmx_option_multichoice(
 240     GMX_SIMD
 241     "SIMD instruction set for CPU kernels and compiler optimization"
 242     "${GMX_SUGGESTED_SIMD}"
 243     None SSE2 SSE4.1 AVX_128_FMA AVX_256 AVX2_256 IBM_QPX Sparc64_HPC_ACE Reference)
 244
 245 gmx_option_multichoice(
 246     GMX_FFT_LIBRARY
 247     "FFT library"
 248     "fftw3"
 249     fftw3 mkl "fftpack[built-in]")
 250 gmx_dependent_option(
 251     GMX_BUILD_OWN_FFTW
 252     "Download and build FFTW 3 during the GROMACS build process, rather than fall back on the really slow fftpack."
 253     OFF
 254     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 255 gmx_dependent_option(
 256     GMX_DISABLE_FFTW_MEASURE
 257     "Do not optimize FFTW setups (not needed with SSE)"
 258     OFF
 259     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 260 mark_as_advanced(GMX_BUILD_OWN_FFTW)
 261 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 262
 263 gmx_option_multichoice(
 264     GMX_QMMM_PROGRAM
 265     "QM package for QM/MM"
 266     None
 267     none gaussian mopac gamess orca)
 268
 269 gmx_dependent_cache_variable(GMX_SIMD_REF_FLOAT_WIDTH  "Reference SIMD single precision width" STRING "4" "GMX_SIMD STREQUAL REFERENCE")
 270 gmx_dependent_cache_variable(GMX_SIMD_REF_DOUBLE_WIDTH "Reference SIMD double precision width" STRING "2" "GMX_SIMD STREQUAL REFERENCE")
 271
 272 # This should be moved to a separate NBNXN cmake module when that code is cleaned up and modularized
 273
 274 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 275 mark_as_advanced(GMX_BROKEN_CALLOC)
 276 option(GMX_LOAD_PLUGINS "Compile with plugin support, needed to read VMD supported file formats" ON)
 277 mark_as_advanced(GMX_LOAD_PLUGINS)
 278
 279 option(GMX_GPU  "Enable GPU acceleration" ON)
 280 option(GMX_OPENMP "Enable OpenMP-based multithreading" ON)
 281
 282 option(GMX_USE_TNG "Use the TNG library for trajectory I/O" ON)
 283
 284 option(GMX_GIT_VERSION_INFO "Generate git version information" ${SOURCE_IS_GIT_REPOSITORY})
 285 mark_as_advanced(GMX_GIT_VERSION_INFO)
 286
 287 if(UNIX)
 288     option(GMX_SYMLINK_OLD_BINARY_NAMES "Create symbolic links for pre-5.0 binary names" ON)
 289 endif()
 290 option(GMX_BUILD_MDRUN_ONLY "Build and install only the mdrun binary" OFF)
 291
 292 option(GMX_CYCLE_SUBCOUNTERS "Enable cycle subcounters to get a more detailed cycle timings" OFF)
 293 mark_as_advanced(GMX_CYCLE_SUBCOUNTERS)
 294
 295 option(GMX_SKIP_DEFAULT_CFLAGS "Don't automatically add suggested/required Compiler flags." OFF)
 296 mark_as_advanced(GMX_SKIP_DEFAULT_CFLAGS)
 297
 298 option(GMX_BUILD_FOR_COVERAGE
 299        "Tune build for better code coverage metrics (e.g., disable asserts)"
 300        OFF)
 301 mark_as_advanced(GMX_BUILD_FOR_COVERAGE)
 302
 303
 304 ######################################################################
 305 # Detect OpenMP support
 306 ######################################################################
 307 # The OpenMP detection _must_ come before tests for other CFLAGS.
 308 include(gmxManageOpenMP)
 309
 310
 311
 312 ######################################################################
 313 # Compiler tests
 314 # These need to be done early (before further tests).
 315 #####################################################################
 316
 317 # The cmake/Check{C,CXX}CompilerFlag.cmake files in the GROMACS distribution
 318 # are used with permission from CMake v2.8.9 so that GROMACS can detect
 319 # invalid options with the Intel Compilers.
 320 # These files should be removed from the source tree when a CMake version that
 321 # includes the features in question becomes required for building GROMACS.
 322 include(CheckCCompilerFlag)
 323 include(CheckCXXCompilerFlag)
 324
 325
 326 include(gmxCFlags)
 327 gmx_c_flags()
 328
 329 # This variable should be used for additional compiler flags which are not
 330 # generated in gmxCFlags nor are SIMD or MPI related.
 331 set(EXTRA_C_FLAGS "")
 332 set(EXTRA_CXX_FLAGS "")
 333
 334 # Run through a number of tests for buggy compilers and other issues
 335 include(gmxTestCompilerProblems)
 336 gmx_test_compiler_problems()
 337 # GMX_SIMD will not be set automatically until the second
 338 # pass (which is not strictly guaranteed to occur), so putting this
 339 # check here among logically-related tests is inefficient, but the
 340 # potential loss is likely zero.
 341 if(GMX_SIMD STREQUAL "AVX_256"
 342         AND CMAKE_COMPILER_IS_GNUCC
 343         AND (C_COMPILER_VERSION VERSION_EQUAL "4.6.1"
 344             OR CXX_COMPILER_VERSION VERSION_EQUAL "4.6.1"))
 345     message(FATAL_ERROR "gcc 4.6.1 has buggy support for AVX, and GROMACS mdrun will not work. If you want simulation performance, use a more recent compiler. Otherwise, use GMX_SIMD=SSE4.1")
 346     # See http://gcc.gnu.org/bugzilla/show_bug.cgi?id=49002
 347 endif()
 348
 349
 350
 351 set(PKG_CFLAGS "")
 352 if(GMX_DOUBLE)
 353     add_definitions(-DGMX_DOUBLE)
 354     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_DOUBLE")
 355 endif()
 356 if(GMX_SOFTWARE_INVSQRT)
 357   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_SOFTWARE_INVSQRT")
 358 endif()
 359
 360 if(WIN32 AND NOT CYGWIN)
 361     set(GMX_WSOCKLIB_PATH CACHE PATH "Path to winsock (wsock32.lib) library.")
 362     mark_as_advanced(GMX_WSOCKLIB_PATH)
 363     find_library(WSOCK32_LIBRARY NAMES wsock32 PATHS ${GMX_WSOCKLIB_PATH})
 364     if(WSOCK32_LIBRARY)
 365         list(APPEND GMX_EXTRA_LIBRARIES ${WSOCK32_LIBRARY})
 366         add_definitions(-DGMX_HAVE_WINSOCK)
 367     else()
 368         message(STATUS "No winsock found. Cannot use interactive molecular dynamics (IMD).")
 369     endif(WSOCK32_LIBRARY)
 370 endif()
 371
 372
 373
 374 ########################################################################
 375 # Basic system tests (standard libraries, headers, functions, types)   #
 376 ########################################################################
 377 include(CheckIncludeFiles)
 378 include(CheckIncludeFileCXX)
 379 check_include_files(unistd.h     HAVE_UNISTD_H)
 380 check_include_files(pwd.h        HAVE_PWD_H)
 381 check_include_files(dirent.h     HAVE_DIRENT_H)
 382 check_include_files(time.h       HAVE_TIME_H)
 383 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 384 check_include_files(io.h         HAVE_IO_H)
 385 check_include_files(sched.h      HAVE_SCHED_H)
 386
 387 check_include_files(regex.h      HAVE_POSIX_REGEX)
 388 check_include_file_cxx(regex     HAVE_CXX11_REGEX)
 389 # TODO: It could be nice to inform the user if no regex support is found,
 390 # as selections won't be fully functional.
 391
 392 include(CheckFunctionExists)
 393 check_function_exists(posix_memalign    HAVE_POSIX_MEMALIGN)
 394 check_function_exists(memalign          HAVE_MEMALIGN)
 395 check_function_exists(_aligned_malloc   HAVE__ALIGNED_MALLOC)
 396 check_function_exists(gettimeofday      HAVE_GETTIMEOFDAY)
 397 check_function_exists(fsync             HAVE_FSYNC)
 398 check_function_exists(_fileno           HAVE__FILENO)
 399 check_function_exists(fileno            HAVE_FILENO)
 400 check_function_exists(_commit           HAVE__COMMIT)
 401 check_function_exists(sigaction         HAVE_SIGACTION)
 402 check_function_exists(sysconf           HAVE_SYSCONF)
 403 check_function_exists(sched_setaffinity HAVE_SCHED_SETAFFINITY)
 404 check_function_exists(sched_getaffinity HAVE_SCHED_GETAFFINITY)
 405 check_function_exists(rsqrt             HAVE_RSQRT)
 406 check_function_exists(rsqrtf            HAVE_RSQRTF)
 407 check_function_exists(sqrtf             HAVE_SQRTF)
 408
 409 include(CheckLibraryExists)
 410 check_library_exists(m sqrt "" HAVE_LIBM)
 411 check_library_exists(rt clock_gettime "" HAVE_CLOCK_GETTIME)
 412
 413 include(TestBigEndian)
 414 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 415
 416 # Management of GROMACS options for specific toolchains should go
 417 # here. Because the initial settings for some of the main options have
 418 # already happened, but things like library detection and MPI compiler
 419 # feature detection have not, the docstrings for any over-rides of
 420 # GROMACS defaults or user settings will make sense. Also, any
 421 # toolchain-related reasons for choosing whether to detect various
 422 # things can be sorted out now, before the detection takes place.
 423 if(${CMAKE_SYSTEM_NAME} MATCHES BlueGene)
 424     include(gmxManageBlueGene)
 425 endif()
 426
 427 ########################################################################
 428 #Process MPI settings
 429 ########################################################################
 430 include(gmxManageMPI)
 431
 432
 433 ########################################################################
 434 #Process shared/static library settings
 435 ########################################################################
 436 include(gmxManageSharedLibraries)
 437
 438
 439 ########################################################################
 440 # Find external packages                                               #
 441 ########################################################################
 442
 443 # Unconditionally find the package, as it is also required for unit
 444 # tests. This exports LIBXML2_FOUND, which we should not use because
 445 # it does not tell us that linking will succeed. Instead, we test that
 446 # next.
 447 find_package(LibXml2)
 448 include(gmxTestLibXml2)
 449 gmx_test_libxml2(HAVE_LIBXML2)
 450 option(GMX_XML "Use libxml2 to parse xml files (currently has no effect)" ${HAVE_LIBXML2})
 451 set(PKG_XML "")
 452 mark_as_advanced(GMX_XML)
 453 # Don't actually do anything, since libxml2 is currently not used by libgromacs
 454 #if(GMX_XML AND NOT HAVE_LIBXML2)
 455 #    message(FATAL_ERROR "libxml2 not found. Set GMX_XML=OFF to compile without XML support")
 456 #endif()
 457 #if(GMX_XML)
 458 #    include_directories(${LIBXML2_INCLUDE_DIR})
 459 #    set(PKG_XML libxml-2.0)
 460 #    set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 461 #endif()
 462
 463 option(GMX_EXTRAE "Add support for tracing using EXTRAE" OFF)
 464 mark_as_advanced(GMX_EXTRAE)
 465
 466 if (GMX_EXTRAE)
 467   find_package(EXTRAE)
 468   if(EXTRAE_FOUND)
 469     include_directories(${EXTRAE_INCLUDE_DIR})
 470     set(HAVE_EXTRAE 1)
 471   else()
 472     message(FATAL_ERROR "EXTRAE library was not found. Please add the correct path to CMAKE_PREFIX_PATH")
 473   endif()
 474 endif()
 475
 476 option(GMX_X11 "Use X window system" OFF)
 477 if (GMX_X11)
 478     find_package(X11)
 479     # X11 includes/libraries are only set in the ngmx subdirectory!
 480     if(NOT X11_FOUND)
 481         message(FATAL_ERROR
 482                 "X11 include files and/or libraries were not found. "
 483                 "Set GMX_X11=OFF to compile without X11 support. "
 484                 "gmx view will not be available.")
 485     endif()
 486     include_directories(${X11_INCLUDE_DIR})
 487 endif()
 488
 489 include(ThreadMPI)
 490 # Enable core threading facilities
 491 tmpi_enable_core("${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include")
 492 # Enable tMPI C++ support
 493 tmpi_enable_cxx()
 494 if(GMX_THREAD_MPI)
 495     # enable MPI functions
 496     tmpi_enable()
 497     set(GMX_MPI 1)
 498     set(MPI_IN_PLACE_EXISTS 1)
 499 endif()
 500 # If atomics are manually disabled a define is needed because atomics.h doesn't depend on config.h
 501 if (TMPI_ATOMICS_DISABLED)
 502    add_definitions(-DTMPI_ATOMICS_DISABLED)
 503 endif()
 504
 505 if(GMX_GPU)
 506     # now that we have detected the dependencies, do the second configure pass
 507     gmx_gpu_setup()
 508 endif()
 509
 510 if(CYGWIN)
 511     set(GMX_CYGWIN 1)
 512 endif()
 513
 514 if(WIN32 AND NOT CYGWIN)
 515     set(GMX_NATIVE_WINDOWS 1)
 516     # This makes windows.h not declare min/max as macros that would break
 517     # C++ code using std::min/std::max.
 518     add_definitions(-DNOMINMAX)
 519 endif()
 520
 521 # only bother with finding git and using version.h if the source is a git repo
 522 if(GMX_GIT_VERSION_INFO)
 523     if (NOT SOURCE_IS_GIT_REPOSITORY)
 524         message(FATAL_ERROR
 525             "Cannot generate git version information from source tree not under git. "
 526             "Set GMX_GIT_VERSION_INFO=OFF to proceed.")
 527     endif()
 528     # We need at least git v1.5.3 be able to parse git's date output. If not
 529     # found or the version is too small, we can't generate version information.
 530     find_package(Git)
 531
 532     if(NOT GIT_FOUND OR GIT_VERSION_STRING VERSION_LESS "1.5.3")
 533         message(FATAL_ERROR
 534             "No compatible git version found (>= 1.5.3 required). "
 535             "Won't be able to generate development version information. "
 536             "Set GMX_GIT_VERSION_INFO=OFF to proceed.")
 537     endif()
 538 endif()
 539
 540 # Detect boost unless GMX_EXTERNAL_BOOST is explicitly OFF
 541 # Used for default if GMX_EXTERNAL_BOOST is not defined (first CMake pass)
 542 if(NOT DEFINED GMX_EXTERNAL_BOOST OR GMX_EXTERNAL_BOOST)
 543     find_package(Boost 1.44.0)
 544     if(Boost_FOUND AND Boost_VERSION VERSION_LESS "104400")
 545         set(Boost_FOUND FALSE)
 546     endif()
 547     # Print the notification only on first run, when determining the default
 548     if(NOT DEFINED GMX_EXTERNAL_BOOST AND NOT Boost_FOUND)
 549         message("Boost >= 1.44 not found. Using minimal internal version. "
 550                 "This may cause trouble if you plan on compiling/linking other "
 551                 "software that uses Boost against Gromacs.")
 552     endif()
 553 endif()
 554 option(GMX_EXTERNAL_BOOST "Use external Boost instead of minimal built-in version"
 555        ${Boost_FOUND})
 556 if(GMX_EXTERNAL_BOOST AND NOT Boost_FOUND)
 557     message(FATAL_ERROR
 558         "Boost >= 1.44 not found. "
 559         "You can set GMX_EXTERNAL_BOOST=OFF to compile against minimal "
 560         "version of Boost included with Gromacs.")
 561 endif()
 562
 563 if(NOT DEFINED GMX_BUILD_UNITTESTS AND NOT HAVE_LIBXML2)
 564     message(WARNING "libxml2 not found. Will build GROMACS without unit-tests. This is not recommended, because the unit-tests help to verify that GROMACS functions correctly. Most likely you are missing the libxml2-dev(el) package. After you installed it, set GMX_BUILD_UNITTESTS=ON.")
 565 endif()
 566 option(GMX_BUILD_UNITTESTS "Build unit tests with BUILD_TESTING (uses Google C++ Testing and Mocking Frameworks, requires libxml2)" ${HAVE_LIBXML2})
 567 mark_as_advanced(GMX_BUILD_UNITTESTS)
 568 gmx_add_cache_dependency(GMX_BUILD_UNITTESTS BOOL BUILD_TESTING OFF)
 569 if (GMX_BUILD_UNITTESTS AND NOT HAVE_LIBXML2)
 570     message(FATAL_ERROR
 571         "Cannot build unit tests without libxml2. "
 572         "Either set GMX_BUILD_UNITTESTS=OFF or tell CMake how to find a working version of libxml2.")
 573 endif()
 574
 575 ########################################################################
 576 # Generate development version info for cache
 577 ########################################################################
 578 # set(GEN_VERSION_INFO_INTERNAL "ON")
 579 # include(gmxGenerateVersionString)
 580
 581 ########################################################################
 582 # Our own GROMACS tests
 583 ########################################################################
 584
 585 add_definitions( -DHAVE_CONFIG_H )
 586 include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src)
 587 include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include)
 588 # Required for config.h, maybe should only be set in src/CMakeLists.txt
 589 include_directories(BEFORE ${CMAKE_BINARY_DIR}/src)
 590 # Required for gmx_header_config_gen.h to be found before installation
 591 include_directories(BEFORE ${CMAKE_BINARY_DIR}/src/gromacs/utility)
 592 # Required for now to make old code compile
 593 include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src/gromacs/legacyheaders)
 594
 595 include(gmxTestInlineASM)
 596 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 597
 598 include(gmxSetBuildInformation)
 599 gmx_set_build_information()
 600 # Turn on RDTSCP if:
 601 # - the build system's CPU supports it
 602 # - the acceleration is set to AVX as all AVX-capable CPUs support AVX (which
 603 #   at this point means that the user set it).
 604 # Note: it's better to not use the later set value of GMX_SIMD because
 605 # it reflects the system's capability of both compiling and running AVX code.
 606 # TODO: After merge with 5.0 one could implement a cache variable dependency
 607 # such that GMX_USE_RDTSCP can change if GMX_SIMD is changed to AVX
 608 # after the first cmake pass.
 609 if (BUILD_CPU_FEATURES MATCHES "rdtscp" OR GMX_SIMD MATCHES "AVX")
 610     set(GMX_USE_RDTSCP_DEFAULT_VALUE ON)
 611 else()
 612     set(GMX_USE_RDTSCP_DEFAULT_VALUE OFF)
 613 endif()
 614 option(GMX_USE_RDTSCP "Use RDTSCP for better CPU-based timers (available on recent x86 CPUs; might need to be off when compiling for heterogeneous environments)" ${GMX_USE_RDTSCP_DEFAULT_VALUE})
 615 mark_as_advanced(GMX_USE_RDTSCP)
 616 if(GMX_USE_RDTSCP)
 617     set(HAVE_RDTSCP 1)
 618 endif()
 619
 620 include(gmxTestFloatFormat)
 621 gmx_test_float_format(GMX_FLOAT_FORMAT_IEEE754
 622                       GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER
 623                       GMX_IEEE754_BIG_ENDIAN_WORD_ORDER)
 624
 625 include(gmxTestLargeFiles)
 626 gmx_test_large_files(GMX_LARGEFILES)
 627
 628 include(gmxTestSignal)
 629 gmx_test_sigusr1(HAVE_SIGUSR1)
 630
 631 include(gmxTestPipes)
 632 gmx_test_pipes(HAVE_PIPES)
 633
 634 include(gmxTestIsfinite)
 635 gmx_test_isfinite(HAVE_ISFINITE)
 636 gmx_test__isfinite(HAVE__ISFINITE)
 637 gmx_test__finite(HAVE__FINITE)
 638
 639 include(gmxTestCXX11)
 640 gmx_test_cxx11(GMX_CXX11_SUPPORTED GMX_CXX11_FLAGS)
 641 include(CMakeDependentOption)
 642 # nvcc does not support C++11 flags, so with GPUs we prefer to skip C++11 flags
 643 # entirely to keep the compilation environment uniform.
 644 cmake_dependent_option(GMX_CXX11
 645     "Use C++11 features"
 646     ON "GMX_CXX11_SUPPORTED AND NOT GMX_GPU" OFF)
 647 mark_as_advanced(GMX_CXX11)
 648 if(GMX_CXX11)
 649     set(EXTRA_CXX_FLAGS "${EXTRA_CXX_FLAGS} ${GMX_CXX11_FLAGS}")
 650 endif()
 651
 652
 653 include(gmxTestXDR)
 654 gmx_test_xdr(GMX_SYSTEM_XDR)
 655 if(NOT GMX_SYSTEM_XDR)
 656     set(GMX_INTERNAL_XDR 1)
 657 endif()
 658
 659
 660 ##################################################
 661 # Process SIMD instruction settings
 662 ##################################################
 663 # This checks what flags to add in order to
 664 # support the SIMD instructions we need, and sets
 665 # correct defines for the SIMD instructions supported.
 666 include(gmxTestSimd)
 667 gmx_test_simd()
 668
 669
 670 # Process QM/MM Settings
 671 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 672     set(GMX_QMMM_GAUSSIAN 1)
 673 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 674     set(GMX_QMMM_MOPAC 1)
 675 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 676     set(GMX_QMMM_GAMESS 1)
 677 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 678     set(GMX_QMMM_ORCA 1)
 679 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 680     # nothing to do
 681 else()
 682     gmx_invalid_option_value(GMX_QMMM_PROGRAM)
 683 endif()
 684
 685
 686 ##################################################
 687 # Process FFT library settings
 688 ##################################################
 689 include(gmxManageFFTLibraries)
 690
 691
 692 include(gmxManageLinearAlgebraLibraries)
 693
 694 # Whether GROMACS will really try to compile support for VMD plugins
 695 set(GMX_USE_PLUGINS OFF)
 696
 697 if(GMX_LOAD_PLUGINS)
 698   if(CYGWIN OR NOT WIN32)
 699     # Native Windows does not have, nor need dlopen
 700     # Note that WIN32 is set with Cygwin, but Cygwin needs dlopen to use plug-ins
 701     include(gmxTestdlopen)
 702     gmx_test_dlopen(HAVE_DLOPEN)
 703   endif()
 704
 705   # so, should we use plug-ins?
 706   if((WIN32 AND NOT CYGWIN) OR (HAVE_DLOPEN AND BUILD_SHARED_LIBS))
 707     if(NOT VMD_QUIETLY)
 708       MESSAGE(STATUS
 709           "Found the ability to use plug-ins when building shared libaries, "
 710           "so will compile to use plug-ins (e.g. to read VMD-supported file "
 711           "formats).")
 712     endif()
 713     if(NOT GMX_VMD_PLUGIN_PATH)
 714       find_package(VMD)
 715     endif()
 716     set(GMX_USE_PLUGINS ON)
 717     list(APPEND GMX_EXTRA_LIBRARIES ${CMAKE_DL_LIBS}) # magic cross-platform pre-set variable for dlopen library
 718     set(PKG_DL_LIBS "-l${CMAKE_DL_LIBS}")
 719   else()
 720     set(PKG_DL_LIBS)
 721   endif()
 722 endif()
 723 set(VMD_QUIETLY TRUE CACHE INTERNAL "")
 724
 725 # Link real-time library for POSIX timers. The check for clock_gettime
 726 # confirms the linkability of rt.
 727 if(HAVE_TIME_H AND HAVE_UNISTD_H AND HAVE_CLOCK_GETTIME)
 728     list(APPEND GMX_EXTRA_LIBRARIES rt)
 729 endif()
 730
 731 # Math and thread libraries must often come after all others when linking...
 732 if(HAVE_LIBM)
 733     list(APPEND GMX_EXTRA_LIBRARIES m)
 734 endif()
 735
 736 option(GMX_NACL "Configure for Native Client builds" OFF)
 737 if (GMX_NACL)
 738   list(APPEND GMX_EXTRA_LIBRARIES nosys)
 739   set(GMX_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -lnosys")
 740   set(GMX_NO_NICE 1)
 741   set(GMX_NO_RENAME 1)
 742 endif()
 743 mark_as_advanced(GMX_NACL)
 744
 745 if(GMX_FAHCORE)
 746   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 747       "Path to swindirect.h")
 748   include_directories(${COREWRAP_INCLUDE_DIR})
 749 endif()
 750
 751 option(GMX_BUILD_HELP "Build man pages, HTML help, and completions automatically (requires that compiled binaries can be executed on the build host)" OFF)
 752 mark_as_advanced(GMX_BUILD_HELP)
 753 if (GMX_BUILD_HELP AND SOURCE_IS_SOURCE_DISTRIBUTION AND
 754     "${CMAKE_CURRENT_SOURCE_DIR}" STREQUAL "${CMAKE_CURRENT_BINARY_DIR}")
 755
 756     message(FATAL_ERROR
 757         "Rebuilding HTML and man pages is not supported for in-source "
 758         "builds from a source distribution. "
 759         "Set GMX_BUILD_HELP=OFF or do an out-of-source build to proceed.")
 760 endif()
 761
 762 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 763 # these are set after everything else
 764 if (NOT GMX_SKIP_DEFAULT_CFLAGS)
 765     set(CMAKE_C_FLAGS "${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${CMAKE_C_FLAGS}")
 766     set(CMAKE_CXX_FLAGS "${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${CMAKE_CXX_FLAGS}")
 767     set(CMAKE_EXE_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}")
 768     set(CMAKE_SHARED_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS}")
 769 else()
 770     message("Recommended flags which are not added because GMX_SKIP_DEFAULT_CFLAGS=yes:")
 771     message("CMAKE_C_FLAGS: ${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${GMXC_CFLAGS}")
 772     message("CMAKE_C_FLAGS_RELEASE: ${GMXC_CFLAGS_RELEASE}")
 773     message("CMAKE_C_FLAGS_DEBUG: ${GMXC_CFLAGS_DEBUG}")
 774     message("CMAKE_CXX_FLAGS: ${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${GMXC_CXXFLAGS}")
 775     message("CMAKE_CXX_FLAGS_RELEASE: ${GMXC_CXXFLAGS_RELEASE}")
 776     message("CMAKE_CXX_FLAGS_DEBUG: ${GMXC_CXXFLAGS_DEBUG}")
 777     message("CMAKE_EXE_LINKER_FLAGS: ${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS}")
 778     message("CMAKE_SHARED_LINKER_FLAGS: ${MPI_LINKER_FLAGS}")
 779 endif()
 780
 781 if(NOT GMX_OPENMP)
 782     #Unset all OpenMP flags in case OpenMP was disabled either by the user
 783     #or because it was only partially detected (e.g. only for C but not C++ compiler)
 784     unset(OpenMP_C_FLAGS CACHE)
 785     unset(OpenMP_CXX_FLAGS CACHE)
 786 else()
 787     set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} ${OpenMP_LINKER_FLAGS})
 788     set(GMX_SHARED_LINKER_FLAGS ${GMX_SHARED_LINKER_FLAGS} ${OpenMP_SHARED_LINKER_FLAGS})
 789 endif()
 790 set(PKG_CFLAGS "${PKG_CFLAGS} ${OpenMP_C_FLAGS}")
 791
 792 ########################################################################
 793 # Specify install locations
 794 ########################################################################
 795 # Use GNUInstallDirs to set paths on multiarch systems.
 796 include(GNUInstallDirs)
 797
 798 # Customization for the installation tree paths.
 799 set(GMX_LIB_INSTALL_DIR ${CMAKE_INSTALL_LIBDIR} CACHE STRING
 800     "Library installation directory (default: ${CMAKE_INSTALL_LIBDIR})")
 801 set(GMX_DATA_INSTALL_DIR gromacs CACHE STRING
 802     "Data installation directory under share/ (default: gromacs)")
 803 mark_as_advanced(GMX_LIB_INSTALL_DIR GMX_DATA_INSTALL_DIR)
 804
 805 # These variables are used internally to provide a central location for
 806 # customizing the install locations.
 807 set(LIB_INSTALL_DIR  ${GMX_LIB_INSTALL_DIR})
 808 set(BIN_INSTALL_DIR  bin)
 809 set(DATA_INSTALL_DIR share/${GMX_DATA_INSTALL_DIR})
 810 set(MAN_INSTALL_DIR  share/man)
 811 set(INCL_INSTALL_DIR include)
 812
 813 # These variables get written into config.h for use in finding the data
 814 # directories.
 815 set(GMXLIB_SEARCH_DIR share/${GMX_DATA_INSTALL_DIR}/top)
 816 set(GMXLIB_FALLBACK   ${CMAKE_INSTALL_PREFIX}/${DATA_INSTALL_DIR}/top)
 817
 818 # Binary and library suffix options
 819 include(gmxManageSuffixes)
 820
 821 ################################################################
 822 # Shared library load path settings
 823 ################################################################
 824 # CMake supports RPATH on OS X only from 2.8.12 upwards.
 825 # CMAKE_SYSTEM_VERSION > 8.0 matches OS X 10.5 and above, where RPATH support
 826 # was added.
 827 if((NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin") OR
 828    ((CMAKE_SYSTEM_VERSION VERSION_GREATER 8.0) AND (NOT CMAKE_VERSION VERSION_LESS 2.8.12)))
 829     # The build folder always has bin/ and lib/; if we are also going to
 830     # install to lib/, then the installation RPATH works also in the build
 831     # tree.  This makes installation slightly faster (no need to rewrite the
 832     # RPATHs), and makes the binaries in the build tree relocatable.
 833     if(GMX_LIB_INSTALL_DIR STREQUAL "lib")
 834         set(CMAKE_BUILD_WITH_INSTALL_RPATH TRUE)
 835     endif()
 836     # Set the RPATH as relative to the executable location to make the
 837     # binaries relocatable.
 838     if(NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin")
 839         set(CMAKE_INSTALL_RPATH "\$ORIGIN/../${GMX_LIB_INSTALL_DIR}")
 840     else()
 841         set(CMAKE_INSTALL_RPATH "@executable_path/../${GMX_LIB_INSTALL_DIR}")
 842     endif()
 843     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 844     set(CMAKE_MACOSX_RPATH 1)
 845 else()
 846     # We are on Darwin/OSX, and CMake cannot handle RPATHs automatically.
 847     if(CMAKE_SYSTEM_VERSION VERSION_GREATER 8.0)
 848         # Set the RPATH options manually.
 849         set(CMAKE_INSTALL_NAME_DIR "@rpath")
 850         set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} "-Wl,-rpath,@executable_path/../${GMX_LIB_INSTALL_DIR}")
 851     else()
 852         # Use the old INSTALL_NAME_DIR mechanism if RPATH is not supported.
 853         set(CMAKE_INSTALL_NAME_DIR "${CMAKE_INSTALL_PREFIX}/${LIB_INSTALL_DIR}")
 854     endif()
 855 endif()
 856
 857 #COPYING file: Only necessary for binary distributions.
 858 #Simpler to always install.
 859 install(FILES COPYING DESTINATION ${DATA_INSTALL_DIR} COMPONENT data)
 860
 861 if(GMX_EXTERNAL_BOOST)
 862     include_directories(${Boost_INCLUDE_DIRS})
 863     set(PKG_CFLAGS "${PKG_CFLAGS} -I${Boost_INCLUDE_DIRS}")
 864 else()
 865     include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src/external/boost)
 866     # typeid not supported for minimal internal version
 867     # (would add significant amount of code)
 868     add_definitions(-DBOOST_NO_TYPEID)
 869     # TODO: Propagate the above settings to the installed CMakeFiles.txt template
 870     # (from share/template/)
 871     set(PKG_CFLAGS "${PKG_CFLAGS} -DBOOST_NO_TYPEID -I${CMAKE_INSTALL_PREFIX}/${INCL_INSTALL_DIR}/gromacs/external/boost")
 872     if (NOT GMX_BUILD_MDRUN_ONLY)
 873         install(DIRECTORY ${CMAKE_SOURCE_DIR}/src/external/boost/boost
 874                 DESTINATION ${INCL_INSTALL_DIR}/gromacs/external/boost
 875                 COMPONENT development)
 876     endif()
 877 endif()
 878
 879 if (GMX_BUILD_FOR_COVERAGE)
 880     # Code heavy with asserts makes conditional coverage close to useless metric,
 881     # as by design most of the false branches are impossible to trigger in
 882     # correctly functioning code.  And the benefit of testing those that could
 883     # be triggered by using an API against its specification isn't usually
 884     # worth the effort.
 885     add_definitions(-DNDEBUG -DBOOST_DISABLE_ASSERTS -DGMX_DISABLE_ASSERTS)
 886 endif()
 887
 888 if (BUILD_TESTING)
 889     # "tests" target builds all the separate test binaries.
 890     add_custom_target(tests)
 891     # "run-ctest" is an internal target that actually runs the tests.
 892     # This is necessary to be able to add separate targets that execute as part
 893     # of 'make check', but are ensured to be executed after the actual tests.
 894     add_custom_target(run-ctest
 895                       COMMAND ${CMAKE_CTEST_COMMAND} --output-on-failure
 896                       COMMENT "Running all tests"
 897                       VERBATIM)
 898     add_dependencies(run-ctest tests)
 899     # "check" target builds and runs all tests.
 900     add_custom_target(check DEPENDS run-ctest)
 901 endif()
 902
 903 if (NOT GMX_BUILD_MDRUN_ONLY)
 904     add_subdirectory(doxygen)
 905     add_subdirectory(install-guide)
 906     add_subdirectory(share)
 907     add_subdirectory(scripts)
 908 endif()
 909 add_subdirectory(src)
 910
 911 if (BUILD_TESTING)
 912     add_subdirectory(tests)
 913 endif()
 914
 915 # Issue a warning if NVIDIA GPUs were detected, but CUDA was not found.
 916 # Don't bother the user after the first configure pass.
 917 if ((CUDA_NOTFOUND_AUTO AND GMX_DETECT_GPU_AVAILABLE) AND NOT GMX_GPU_DETECTION_DONE)
 918     message(WARNING "${CUDA_NOTFOUND_MESSAGE}")
 919 endif()
 920 set(GMX_GPU_DETECTION_DONE TRUE CACHE INTERNAL "Whether GPU detection has already been done")
 921
 922 #######################
 923 ## uninstall target
 924 #######################
 925 CONFIGURE_FILE(   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 926                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
 927                   IMMEDIATE @ONLY)
 928 ###########################
 929 ADD_CUSTOM_TARGET(uninstall
 930                   "${CMAKE_COMMAND}" -P
 931                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
 932 ###########################
 933 set_directory_properties(PROPERTIES
 934             ADDITIONAL_MAKE_CLEAN_FILES "install_manifest.txt")
 935
 936 ########################################################################
 937 # Manual                                                               #
 938 ########################################################################
 939
 940 option(GMX_BUILD_MANUAL "Whether to try to configure to build the PDF manual" OFF)
 941 mark_as_advanced(GMX_BUILD_MANUAL)
 942 if(GMX_BUILD_MANUAL)
 943     # Make sure we only do detection of manual-building dependencies
 944     # when the user opted in for that.
 945     add_subdirectory(manual)
 946 endif()