CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2012,2013, by the GROMACS development team, led by
   5 # David van der Spoel, Berk Hess, Erik Lindahl, and including many
   6 # others, as listed in the AUTHORS file in the top-level source
   7 # directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34 #
  35 cmake_minimum_required(VERSION 2.8)
  36 # Keep CMake suitably quiet on Cygwin
  37 set(CMAKE_LEGACY_CYGWIN_WIN32 0) # Remove when CMake >= 2.8.4 is required
  38
  39 # Allows CPack to act differently for normal tools and mdrun (e.g. because of MPI)
  40 set(CPACK_COMPONENT_GROUP_TOOLS_DESCRIPTION "All GROMACS executable tools")
  41 set(CPACK_COMPONENT_GROUP_MDRUN_DESCRIPTION "GROMACS executable for running simulations")
  42
  43 # CMake modules/macros are in a subdirectory to keep this file cleaner
  44 # This needs to be set before project() in order to pick up toolchain files
  45 list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake ${CMAKE_CURRENT_SOURCE_DIR}/cmake/Platform)
  46
  47 project(Gromacs C)
  48 include(Dart)
  49 mark_as_advanced(DART_ROOT)
  50
  51 # PROJECT_VERSION should have the following structure:
  52 # VERSION-dev[-SUFFIX] where the VERSION should have the for: vMajor.vMinor.vPatch
  53 #
  54 # The "-dev" suffix is important to keep because it makes possible to distinguish
  55 # between a build from official release and a build from git release branch on a
  56 # machine with no git.
  57 #
  58 # NOTE: when releasing the "-dev" suffix needs to be stripped off!
  59 set(PROJECT_VERSION "4.6.4-dev")
  60 # The version number of the regressiontest tarball against which this
  61 # git branch can be tested. Normally, this will be the version of the
  62 # last patch release. Comment the next line out for branches leading
  63 # to a major/minor release.
  64 set(REGRESSIONTEST_VERSION "4.6.2")
  65 set(CUSTOM_VERSION_STRING ""
  66     CACHE STRING "Custom version string (if empty, use hard-coded default)")
  67 mark_as_advanced(CUSTOM_VERSION_STRING)
  68 if (CUSTOM_VERSION_STRING)
  69     set(PROJECT_VERSION ${CUSTOM_VERSION_STRING})
  70 endif (CUSTOM_VERSION_STRING)
  71 set(SOVERSION 8)
  72 # It is a bit irritating, but this has to be set separately for now!
  73 SET(CPACK_PACKAGE_VERSION_MAJOR "4")
  74 SET(CPACK_PACKAGE_VERSION_MINOR "6")
  75 SET(CPACK_PACKAGE_VERSION_PATCH "1")
  76
  77 # The numerical gromacs version. It is 40600 for 4.6.0.
  78 # The #define GMX_VERSION in gmx_header_config_h is set to this value.
  79 math(EXPR NUM_VERSION
  80     "${CPACK_PACKAGE_VERSION_MAJOR}*10000 + ${CPACK_PACKAGE_VERSION_MINOR}*100")
  81 if(CPACK_PACKAGE_VERSION_PATCH)
  82     math(EXPR NUM_VERSION
  83          "${NUM_VERSION} + ${CPACK_PACKAGE_VERSION_PATCH}")
  84 endif()
  85
  86 # The API version tracks the numerical Gromacs version (for now).
  87 # It is potentially different from the Gromacs version in the future, if
  88 # the programs/libraries diverge from the presumably more stable API.
  89 # The #define GMX_API_VERSION in version.h is set to this value to
  90 # provide backward compatibility of software written against the Gromacs API.
  91 set(API_VERSION ${NUM_VERSION})
  92
  93 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT AND UNIX)
  94 set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
  95 endif()
  96
  97 include(gmxBuildTypeReference)
  98
  99 if(NOT CMAKE_BUILD_TYPE)
 100     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel Reference." FORCE)
 101 endif(NOT CMAKE_BUILD_TYPE)
 102
 103 enable_language(C)
 104
 105 set(GMX_USE_RELATIVE_INSTALL_PATH OFF CACHE STRING "Use relative paths not absolute paths for cmake install. Has only an effect on cpack.")
 106 mark_as_advanced(GMX_USE_RELATIVE_INSTALL_PATH)
 107
 108 set(CPACK_PACKAGE_VERSION ${PROJECT_VERSION})
 109 set(CPACK_PACKAGE_VENDOR "gromacs.org")
 110 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Gromacs - a toolkit for high-performance molecular simulation")
 111 if (NOT GMX_USE_RELATIVE_INSTALL_PATH)
 112     set(CPACK_SET_DESTDIR "ON")
 113 endif()
 114 set(CPACK_RESOURCE_FILE_WELCOME "${CMAKE_SOURCE_DIR}/admin/InstallWelcome.txt")
 115 # Its GPL/LGPL, so they do not have to agree to a license for mere usage, but some installers require this...
 116 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_SOURCE_DIR}/COPYING")
 117 set(CPACK_RESOURCE_FILE_README "${CMAKE_SOURCE_DIR}/admin/InstallInfo.txt")
 118 set(CPACK_SOURCE_IGNORE_FILES "\\\\.isreposource$;\\\\.git/;\\\\.gitignore$")
 119 set(CPACK_PROJECT_CONFIG_FILE "${CMAKE_SOURCE_DIR}/CPackInit.cmake")
 120 SET(CPACK_SOURCE_INSTALLED_DIRECTORIES "${CMAKE_SOURCE_DIR};/;${CMAKE_BINARY_DIR}/man;man")
 121 set(CPACK_PACKAGE_CONTACT "gmx-users@gromacs.org")
 122
 123 #must come after all cpack settings!
 124 include(CPack)
 125
 126 ########################################################################
 127 # Check and warn if cache generated on a different host is being reused
 128 ########################################################################
 129 if(CMAKE_HOST_UNIX)
 130     execute_process(COMMAND hostname
 131                     OUTPUT_VARIABLE TMP_HOSTNAME
 132                     OUTPUT_STRIP_TRAILING_WHITESPACE)
 133     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}")
 134         message(WARNING "
 135             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
 136             is being reused! This could lead to inconsitencies; therefore, it is
 137             recommended to regenerate the cache!")
 138     endif()
 139     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
 140             "Hostname of the machine where the cache was generated.")
 141 endif()
 142
 143 ########################################################################
 144 # User input options - enable C++ - before any CXX flags are changed   #
 145 ########################################################################
 146
 147 # decide on GPU settings based on user-settings and GPU/CUDA detection
 148 include(gmxManageGPU)
 149
 150 option(GMX_FORCE_CXX "Enable C++ compilation even if not necessary" OFF)
 151 mark_as_advanced(GMX_FORCE_CXX)
 152
 153 option(GMX_COOL_QUOTES "Enable Gromacs cool quotes" ON)
 154 mark_as_advanced(GMX_COOL_QUOTES)
 155
 156 if(GMX_GPU OR GMX_FORCE_CXX OR GMX_OPENMM)
 157     enable_language(CXX)
 158 endif()
 159 set(CMAKE_PREFIX_PATH "" CACHE STRING "Extra locations to search for external libraries and tools (give directory without lib, bin, or include)")
 160
 161 ########################################################################
 162 # User input options                                                   #
 163 ########################################################################
 164 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" OFF)
 165 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 166 option(GMX_THREAD_MPI  "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" ON)
 167 option(GMX_SOFTWARE_INVSQRT "Use GROMACS software 1/sqrt" ON)
 168 mark_as_advanced(GMX_SOFTWARE_INVSQRT)
 169 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 170 mark_as_advanced(GMX_FAHCORE)
 171
 172 include(gmxDetectAcceleration)
 173 if(NOT DEFINED GMX_CPU_ACCELERATION)
 174     if(CMAKE_CROSSCOMPILING)
 175         if("${CMAKE_SYSTEM_NAME}" MATCHES "BlueGeneQ")
 176             set(GMX_SUGGESTED_CPU_ACCELERATION "IBM_QPX")
 177         else()
 178             set(GMX_SUGGESTED_CPU_ACCELERATION "None")
 179         endif()
 180     else(CMAKE_CROSSCOMPILING)
 181         gmx_detect_acceleration(GMX_SUGGESTED_CPU_ACCELERATION)
 182     endif(CMAKE_CROSSCOMPILING)
 183 endif(NOT DEFINED GMX_CPU_ACCELERATION)
 184
 185 set(GMX_CPU_ACCELERATION "@GMX_SUGGESTED_CPU_ACCELERATION@"
 186     CACHE STRING "Accelerated CPU kernels. Pick one of: None, SSE2, SSE4.1, AVX_128_FMA, AVX_256, IBM_QPX, Sparc64_HPC_ACE")
 187
 188 set(GMX_FFT_LIBRARY "fftw3"
 189     CACHE STRING "FFT library choices: fftw3,mkl,fftpack[built-in]")
 190 option(GMX_BUILD_OWN_FFTW "Download and build FFTW 3 during the GROMACS build process, rather than fall back on the really slow fftpack." OFF)
 191 mark_as_advanced(GMX_BUILD_OWN_FFTW)
 192 option(GMX_DISABLE_FFTW_MEASURE
 193        "Do not optimize FFTW setups (not needed with SSE)" OFF)
 194 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 195 set(GMX_QMMM_PROGRAM "none"
 196     CACHE STRING "QM package choices: none,gaussian,mopac,gamess,orca")
 197 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 198 mark_as_advanced(GMX_BROKEN_CALLOC)
 199 option(GMX_MPI_IN_PLACE "Enable MPI_IN_PLACE for MPIs that have it defined" ON)
 200 mark_as_advanced(GMX_MPI_IN_PLACE)
 201 option(GMX_LOAD_PLUGINS "Compile with plugin support, needed to read VMD supported file formats" ON)
 202 mark_as_advanced(GMX_LOAD_PLUGINS)
 203
 204 option(GMX_OPENMP "Enable OpenMP-based multithreading" ON)
 205
 206 option(USE_VERSION_H "Generate development version string/information" ON)
 207 mark_as_advanced(USE_VERSION_H)
 208
 209 option(GMX_DEFAULT_SUFFIX "Use default suffixes for GROMACS binaries and libs (_d for double, _mpi for MPI; rerun cmake after changing to see relevant options)" ON)
 210
 211 if(UNIX)
 212     option(GMX_PREFER_STATIC_LIBS "When finding libraries prefer static archives (not available on non-*nix platforms and it will only work if static versions of external dependencies are available and found)!" OFF)
 213     mark_as_advanced(GMX_PREFER_STATIC_LIBS)
 214 endif()
 215
 216 option(GMX_CYCLE_SUBCOUNTERS "Enable cycle subcounters to get a more detailed cycle timings" OFF)
 217 mark_as_advanced(GMX_CYCLE_SUBCOUNTERS)
 218
 219 option(GMX_SKIP_DEFAULT_CFLAGS "Don't automatically add suggested/required Compiler flags." OFF)
 220 mark_as_advanced(GMX_SKIP_DEFAULT_CFLAGS)
 221
 222 ######################################################################
 223 # Compiler tests
 224 # These need to be done early (before further tests).
 225 #####################################################################
 226
 227 # The cmake/Check{C,CXX}CompilerFlag.cmake files in the GROMACS distribution
 228 # are used with permission from CMake v2.8.9 so that GROMACS can detect
 229 # invalid options with the Intel Compilers.
 230 # These files should be removed from the source tree when a CMake version that
 231 # includes the features in question becomes required for building GROMACS.
 232 include(CheckCCompilerFlag)
 233 if(CMAKE_CXX_COMPILER_LOADED)
 234     include(CheckCXXCompilerFlag)
 235 endif()
 236
 237 # Get compiler version information, needs to be done early as check that depend
 238 # on compiler verison follow below.
 239 include(gmxGetCompilerInfo)
 240 get_compiler_version()
 241
 242 # First exclude compilers known to not work with OpenMP although claim to support it:
 243 # gcc 4.2.1 and gcc-llvm 4.2.1 (also claims to be 4.2.1) on Mac OS X
 244 # This fixes redmine 900 and needs to run before OpenMP flags are set below.
 245 if (CMAKE_SYSTEM_NAME STREQUAL "Darwin" AND
 246     (CMAKE_COMPILER_IS_GNUCC AND C_COMPILER_VERSION AND C_COMPILER_VERSION VERSION_LESS 4.3))
 247     message(STATUS "OpenMP multithreading not supported with gcc/llvm-gcc 4.2 on Mac OS X, disabled")
 248     set(GMX_OPENMP OFF CACHE BOOL
 249         "OpenMP multithreading not not supported with gcc/llvm-gcc 4.2 on Mac OS X, disabled!" FORCE)
 250 endif()
 251
 252 # OpenMP check must come before other CFLAGS!
 253 if(GMX_OPENMP)
 254     find_package(OpenMP)
 255     if(OPENMP_FOUND)
 256         # CMake on Windows doesn't support linker flags passed to target_link_libraries
 257         # (i.e. it treats /openmp as \openmp library file). Also, no OpenMP linker flags are needed.
 258         if(NOT (WIN32 AND NOT CYGWIN))
 259             if(CMAKE_COMPILER_IS_GNUCC AND GMX_PREFER_STATIC_OPENMP)
 260                 set(OpenMP_LINKER_FLAGS "-Wl,-static -lgomp -lrt -Wl,-Bdynamic -lpthread")
 261                 set(OpenMP_SHARED_LINKER_FLAGS "")
 262             else()
 263                 # Only set a linker flag if the user didn't set them manually
 264                 if(NOT DEFINED OpenMP_LINKER_FLAGS)
 265                     set(OpenMP_LINKER_FLAGS "${OpenMP_C_FLAGS}")
 266                 endif()
 267                 if(NOT DEFINED OpenMP_SHARED_LINKER_FLAGS)
 268                     set(OpenMP_SHARED_LINKER_FLAGS "${OpenMP_C_FLAGS}")
 269                 endif()
 270             endif()
 271         endif()
 272     else(OPENMP_FOUND)
 273         message(WARNING
 274                 "The compiler you are using does not support OpenMP parallelism. This might hurt your performance a lot, in particular with GPUs. Try using a more recent version, or a different compiler. For now, we are proceeding by turning off OpenMP.")
 275         set(GMX_OPENMP OFF CACHE STRING "Whether GROMACS will use OpenMP parallelism." FORCE)
 276     endif(OPENMP_FOUND)
 277 endif()
 278
 279
 280 include(gmxCFlags)
 281 gmx_c_flags()
 282
 283 # This variable should be used for additional compiler flags which are not
 284 # generated in gmxCFlags nor are acceleration or MPI related.
 285 set(EXTRA_C_FLAGS "")
 286
 287 # gcc 4.4.x is buggy and crashes when compiling some files with O3 and OpenMP on.
 288 # Detect here whether applying a workaround is needed and will apply it later
 289 # on the affected files.
 290 include(gmxGCC44O3BugWorkaround)
 291 gmx_check_gcc44_bug_workaround_needed(GMX_USE_GCC44_BUG_WORKAROUND)
 292
 293 # clang 3.0 is buggy for some unknown reason detected during adding
 294 # the SSE2 group kernels for GROMACS 4.6. If we ever work out what
 295 # that is, we should replace these tests with a compiler feature test,
 296 # update GROMACS Redmine task #1039 and perhaps report a clang bug.
 297 #
 298 # In the meantime, until we require CMake 2.8.10 we cannot rely on it to detect
 299 # the compiler version for us. So we need a manual check for clang 3.0.
 300 include(gmxDetectClang30)
 301 gmx_detect_clang_3_0(COMPILER_IS_CLANG_3_0)
 302 if(COMPILER_IS_CLANG_3_0)
 303     message(FATAL_ERROR "Your compiler is clang version 3.0, which is known to be buggy for GROMACS. Use a different compiler.")
 304 endif()
 305
 306 # clang <=3.2 contains a bug that causes incorrect code to be generated for the
 307 # vfmaddps instruction and therefore the bug is triggered with AVX_128_FMA.
 308 # (see: http://llvm.org/bugs/show_bug.cgi?id=15040).
 309 # We can work around this by not using the integrated assembler (except on OS X
 310 # which has an outdated assembler that does not support AVX instructions).
 311 if (${CMAKE_C_COMPILER_ID} MATCHES "Clang" AND C_COMPILER_VERSION VERSION_LESS "3.3")
 312     set(GMX_USE_CLANG_FMA_BUG_WORKAROUND TRUE)
 313 endif()
 314
 315 if (CMAKE_C_COMPILER_ID STREQUAL "PGI")
 316     message(WARNING "All tested PGI compiler versions (up to 12.9.0) generate binaries which produce incorrect results, or even fail to compile Gromacs. Highly recommended to use a different compiler. If you choose to use PGI, make sure to run the regressiontests.")
 317 endif()
 318
 319 if(CMAKE_C_COMPILER_ID MATCHES "Intel" AND C_COMPILER_VERSION VERSION_LESS "12.0.0")
 320     message(WARNING "Intel compilers before 12.0.0 are not routinely tested, so there may be problems. Version 11.1 with SSE4.1 is known to produce incorrect results. It is highly recommended to use a more up-to-date compiler. If you choose to use this version, make sure you run the regressiontests.")
 321 endif()
 322
 323 set(PKG_CFLAGS "")
 324 if(GMX_DOUBLE)
 325     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_DOUBLE")
 326 endif(GMX_DOUBLE)
 327 if(GMX_SOFTWARE_INVSQRT)
 328   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_SOFTWARE_INVSQRT")
 329 endif(GMX_SOFTWARE_INVSQRT)
 330
 331
 332
 333 ########################################################################
 334 # Basic system tests (standard libraries, headers, functions, types)   #
 335 ########################################################################
 336 include(CheckIncludeFiles)
 337 check_include_files(string.h     HAVE_STRING_H)
 338 check_include_files(math.h       HAVE_MATH_H)
 339 check_include_files(limits.h     HAVE_LIMITS_H)
 340 check_include_files(memory.h     HAVE_MEMORY_H)
 341 check_include_files(unistd.h     HAVE_UNISTD_H)
 342 check_include_files(direct.h     HAVE_DIRECT_H)
 343 check_include_files(pwd.h        HAVE_PWD_H)
 344 check_include_files(stdint.h     HAVE_STDINT_H)
 345 check_include_files(stdlib.h     HAVE_STDLIB_H)
 346 check_include_files(pthread.h    HAVE_PTHREAD_H)
 347 check_include_files(dirent.h     HAVE_DIRENT_H)
 348 check_include_files(inttypes.h   HAVE_INTTYPES_H)
 349 check_include_files(regex.h      HAVE_REGEX_H)
 350 check_include_files(sys/types.h  HAVE_SYS_TYPES_H)
 351 check_include_files(sys/stat.h   HAVE_SYS_STAT_H)
 352 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 353 check_include_files(rpc/rpc.h    HAVE_RPC_RPC_H)
 354 check_include_files("rpc/rpc.h;rpc/xdr.h"    HAVE_RPC_XDR_H)
 355 check_include_files(io.h                 HAVE_IO_H)
 356 check_include_files(sched.h      HAVE_SCHED_H)
 357
 358 include(CheckFunctionExists)
 359 check_function_exists(strcasecmp        HAVE_STRCASECMP)
 360 check_function_exists(strdup            HAVE_STRDUP)
 361 check_function_exists(vprintf           HAVE_VPRINTF)
 362 check_function_exists(memcmp            HAVE_MEMCMP)
 363 check_function_exists(posix_memalign    HAVE_POSIX_MEMALIGN)
 364 check_function_exists(memalign          HAVE_MEMALIGN)
 365 check_function_exists(_aligned_malloc   HAVE__ALIGNED_MALLOC)
 366 check_function_exists(gettimeofday      HAVE_GETTIMEOFDAY)
 367 check_function_exists(isnan             HAVE_ISNAN)
 368 check_function_exists(_isnan            HAVE__ISNAN)
 369 check_function_exists(fsync             HAVE_FSYNC)
 370 check_function_exists(_fileno           HAVE__FILENO)
 371 check_function_exists(fileno            HAVE_FILENO)
 372 check_function_exists(_commit           HAVE__COMMIT)
 373 check_function_exists(sigaction         HAVE_SIGACTION)
 374 check_function_exists(sysconf           HAVE_SYSCONF)
 375 check_function_exists(sched_setaffinity HAVE_SCHED_SETAFFINITY)
 376 check_function_exists(sched_getaffinity HAVE_SCHED_GETAFFINITY)
 377 check_function_exists(rsqrt             HAVE_RSQRT)
 378 check_function_exists(rsqrtf            HAVE_RSQRTF)
 379 check_function_exists(sqrtf             HAVE_SQRTF)
 380
 381 include(CheckLibraryExists)
 382 check_library_exists(m sqrt "" HAVE_LIBM)
 383 check_library_exists(m cbrt "" HAVE_CBRT)
 384
 385
 386 include(CheckTypeSize)
 387
 388 check_type_size("bool"          SIZEOF_BOOL) # will also set HAVE_BOOL
 389 check_type_size("int"           SIZEOF_INT)
 390 check_type_size("long int"      SIZEOF_LONG_INT)
 391 check_type_size("long long int" SIZEOF_LONG_LONG_INT)
 392 check_type_size("off_t"         SIZEOF_OFF_T)
 393 check_type_size("void *"        SIZEOF_VOIDP)
 394
 395 if (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 396     set(GMX_64_BIT TRUE)
 397 else (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 398     set(GMX_64_BIT FALSE)
 399 endif (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 400
 401 # Check for some basic types that we *need*, so set these to int if they are not present
 402 check_type_size(uid_t uid_t)
 403 if(NOT uid_t)
 404   set(uid_t int)
 405 else(NOT uid_t)
 406   set(uid_t 0)
 407 endif(NOT uid_t)
 408
 409 check_type_size(gid_t gid_t)
 410 if(NOT gid_t)
 411   set(gid_t 1)
 412 else(NOT gid_t)
 413   set(gid_t 0)
 414 endif(NOT gid_t)
 415
 416 check_type_size(size_t size_t)
 417 if(NOT size_t)
 418   set(size_t int)
 419 else(NOT size_t)
 420   set(size_t 0)
 421 endif(NOT size_t)
 422
 423 check_type_size(off_t off_t)
 424 if(NOT off_t)
 425   set(off_t int)
 426 else(NOT off_t)
 427   set(off_t 0)
 428 endif(NOT off_t)
 429
 430 include(TestBigEndian)
 431 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 432
 433
 434 if(APPLE OR CYGWIN OR ${CMAKE_SYSTEM_NAME} MATCHES "Linux|.*BSD")
 435     # Maybe Solaris should be here? Patch this if you know!
 436     SET(SHARED_LIBS_DEFAULT ON)
 437 elseif(WIN32 OR ${CMAKE_SYSTEM_NAME} MATCHES "BlueGene")
 438     # Support for shared libs on native Windows is a bit new. Its
 439     # default might change later if/when we sort things out. Also,
 440     # Cray should go here. What variable value can detect it?
 441     SET(SHARED_LIBS_DEFAULT OFF)
 442 else()
 443     message(STATUS "Defaulting to building static libraries")
 444     SET(SHARED_LIBS_DEFAULT OFF)
 445 endif()
 446
 447 # Management of GROMACS options for specific toolchains should go
 448 # here. Because the initial settings for some of the main options have
 449 # already happened, but things like library detection and MPI compiler
 450 # feature detection have not, the docstrings for any over-rides of
 451 # GROMACS defaults or user settings will make sense. Also, any
 452 # toolchain-related reasons for choosing whether to detect various
 453 # things can be sorted out now, before the detection takes place.
 454 if(${CMAKE_SYSTEM_NAME} MATCHES BlueGene)
 455     include(gmxManageBlueGene)
 456 endif()
 457
 458 if(UNIX AND GMX_PREFER_STATIC_LIBS AND SHARED_LIBS_DEFAULT)
 459     if(BUILD_SHARED_LIBS)
 460         # Warn the user about the combination. But don't overwrite the request.
 461         message(WARNING "Searching for static libraries requested, and building shared Gromacs libraries requested. This might cause problems linking later.")
 462     elseif(NOT DEFINED BUILD_SHARED_LIBS)
 463         # Change default to OFF. Don't warn if it's already off.
 464         message(WARNING "Searching for static libraries requested, so the GROMACS libraries will also be built statically (BUILD_SHARED_LIBS=OFF)")
 465         set(SHARED_LIBS_DEFAULT OFF)
 466     endif()
 467 endif()
 468
 469 # By now, all tool chains should have spoken up if they care about
 470 # the setting of SHARED_LIBS_DEFAULT.
 471 option(BUILD_SHARED_LIBS "Enable shared libraries (can be problematic e.g. with MPI, or on some HPC systems)" ${SHARED_LIBS_DEFAULT})
 472
 473 ########################################################################
 474 #Process MPI settings
 475 ########################################################################
 476 include(gmxManageMPI)
 477
 478 ########################################################################
 479 # Find external packages                                               #
 480 ########################################################################
 481 if(UNIX AND GMX_PREFER_STATIC_LIBS)
 482     # On Linux .a is the static library suffix, on Mac OS X .lib can also
 483     # be used, so we'll add both to the preference list.
 484     SET(CMAKE_FIND_LIBRARY_SUFFIXES ".lib;.a" ${CMAKE_FIND_LIBRARY_SUFFIXES})
 485 endif()
 486
 487 IF( WIN32 AND NOT CYGWIN)
 488   if (NOT BUILD_SHARED_LIBS)
 489       option(GMX_PREFER_STATIC_LIBS "When finding libraries prefer static system libraries (MT instead of MD)!" ON)
 490       if(NOT GMX_PREFER_STATIC_LIBS)
 491           message(WARNING "Shared system libraries requested, and static Gromacs libraries requested.")
 492       endif()
 493   else()
 494       option(GMX_PREFER_STATIC_LIBS "When finding libraries prefer static system libraries (MT instead of MD)!" OFF)
 495       if(GMX_PREFER_STATIC_LIBS)
 496           #this combination segfaults (illigal passing of file handles)
 497           message(FATAL_ERROR "Static system libraries requested, and shared Gromacs libraries requested.")
 498       endif()
 499       add_definitions(-DUSE_VISIBILITY -DTMPI_USE_VISIBILITY)
 500       set(PKG_CFLAGS "$PKG_CFLAGS -DUSE_VISIBILITY -DTMPI_USE_VISIBILITY")
 501   endif()
 502   mark_as_advanced(GMX_PREFER_STATIC_LIBS)
 503
 504   IF (GMX_PREFER_STATIC_LIBS)
 505       #Only setting Debug and Release flags. Others configurations are current not used.
 506       STRING(REPLACE /MD /MT CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE})
 507       STRING(REPLACE /MD /MT CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG})
 508       if(CMAKE_CXX_COMPILER_LOADED)
 509           STRING(REPLACE /MD /MT CMAKE_CXX_FLAGS_RELEASE ${CMAKE_CXX_FLAGS_RELEASE})
 510           STRING(REPLACE /MD /MT CMAKE_CXX_FLAGS_DEBUG ${CMAKE_CXX_FLAGS_DEBUG})
 511       endif()
 512   ENDIF()
 513   IF( CMAKE_C_COMPILER_ID MATCHES "Intel" )
 514     if(BUILD_SHARED_LIBS) #not sure why incremental building with shared libs doesn't work
 515         STRING(REPLACE "/INCREMENTAL:YES" "" CMAKE_SHARED_LINKER_FLAGS ${CMAKE_SHARED_LINKER_FLAGS})
 516     endif()
 517   ENDIF()
 518 ENDIF()
 519
 520 option(GMX_GSL "Add support for gsl" OFF)
 521 if (GMX_GSL)
 522   find_package(GSL)
 523   set(PKG_GSL "")
 524   if(GSL_FOUND)
 525     include_directories(${GSL_INCLUDE_DIR})
 526     set(PKG_GSL gsl)
 527     set(HAVE_LIBGSL 1)
 528   endif(GSL_FOUND)
 529 endif (GMX_GSL)
 530
 531 option(GMX_X11 "Use X window system" OFF)
 532 if (GMX_X11)
 533     find_package(X11)
 534     # X11 includes/libraries are only set in the ngmx subdirectory!
 535     if(NOT X11_FOUND)
 536         message(WARNING "X11 include files and/or libraries were not found. Will not build the GROMACS X11-binaries, such as ngmx")
 537     endif()
 538 endif(GMX_X11)
 539
 540 include(ThreadMPI)
 541 set(THREAD_MPI_LIB thread_mpi)
 542 # Enable core threading facilities
 543 tmpi_enable_core("${CMAKE_SOURCE_DIR}/include")
 544 # Enable tMPI C++ support
 545 # tmpi_enable_cxx()
 546 if(GMX_THREAD_MPI)
 547     # enable MPI functions
 548     tmpi_enable()
 549     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_THREAD_MPI")
 550     set(GMX_MPI 1)
 551 endif(GMX_THREAD_MPI)
 552 tmpi_get_source_list(THREAD_MPI_SRC)
 553
 554 if(GMX_GPU)
 555     # now that we have detected the dependencies, do the second configure pass
 556     gmx_gpu_setup()
 557 endif(GMX_GPU)
 558
 559 if(CYGWIN)
 560     set(GMX_CYGWIN 1)
 561 endif(CYGWIN)
 562
 563 if(WIN32 AND NOT CYGWIN)
 564     set(GMX_NATIVE_WINDOWS 1)
 565 endif()
 566
 567 # only bother with finding git and using version.h if the source is a git repo
 568 if(EXISTS "${CMAKE_SOURCE_DIR}/.git")
 569     if(USE_VERSION_H)
 570         # We need at least git v1.5.3 be able to parse git's date output. If not
 571         # found or the version is too small, we can't generate version information.
 572         find_package(Git)
 573
 574         # Find out the git version
 575         if(GIT_FOUND AND NOT GIT_VERSION)
 576           execute_process(COMMAND ${GIT_EXECUTABLE} "--version"
 577             OUTPUT_VARIABLE _exec_out
 578             OUTPUT_STRIP_TRAILING_WHITESPACE)
 579           string(REGEX REPLACE "git version (.*)" "\\1" GIT_VERSION ${_exec_out})
 580           set(GIT_VERSION ${GIT_VERSION} CACHE STRING "Git version")
 581           mark_as_advanced(GIT_VERSION)
 582         endif()
 583
 584         if(NOT GIT_FOUND OR GIT_VERSION VERSION_LESS "1.5.3")
 585           message("No compatible git version found, won't be able to generate proper development version information.")
 586           set(USE_VERSION_H OFF)
 587         endif()
 588     endif()
 589 else()
 590     set(USE_VERSION_H OFF)
 591 endif()
 592
 593 ########################################################################
 594 # Generate development version info for cache
 595 ########################################################################
 596 # set(GEN_VERSION_INFO_INTERNAL "ON")
 597 # include(gmxGenerateVersionString)
 598
 599 ########################################################################
 600 # Our own GROMACS tests
 601 ########################################################################
 602
 603 add_definitions( -DHAVE_CONFIG_H )
 604 include_directories(${CMAKE_BINARY_DIR}/src)
 605 include_directories(${CMAKE_BINARY_DIR}/include)
 606 include_directories(${CMAKE_SOURCE_DIR}/include)
 607
 608 include(gmxTestInlineASM)
 609 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 610
 611 include(gmxSetBuildInformation)
 612 gmx_set_build_information()
 613 if(BUILD_CPU_FEATURES MATCHES "rdtscp" AND NOT GMX_DISTRIBUTABLE_BUILD)
 614     # The timestep counter headers do not include config.h
 615     add_definitions(-DHAVE_RDTSCP)
 616 endif(BUILD_CPU_FEATURES MATCHES "rdtscp" AND NOT GMX_DISTRIBUTABLE_BUILD)
 617
 618 include(gmxTestFloatFormat)
 619 gmx_test_float_format(GMX_FLOAT_FORMAT_IEEE754
 620                       GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER
 621                       GMX_IEEE754_BIG_ENDIAN_WORD_ORDER)
 622
 623 include(gmxTestLargeFiles)
 624 gmx_test_large_files(GMX_LARGEFILES)
 625
 626 include(gmxTestSignal)
 627 gmx_test_sigusr1(HAVE_SIGUSR1)
 628
 629 include(gmxTestInline)
 630 gmx_test_inline(INLINE_KEYWORD)
 631
 632 include(gmxTestRestrict)
 633 gmx_test_restrict(RESTRICT_KEYWORD)
 634
 635 include(gmxTestPipes)
 636 gmx_test_pipes(HAVE_PIPES)
 637
 638 include(gmxTestIsfinite)
 639 gmx_test_isfinite(HAVE_ISFINITE)
 640 gmx_test__isfinite(HAVE__ISFINITE)
 641 gmx_test__finite(HAVE__FINITE)
 642
 643 include(gmxTestXDR)
 644 gmx_test_xdr(GMX_SYSTEM_XDR)
 645 if(NOT GMX_SYSTEM_XDR)
 646     set(GMX_INTERNAL_XDR 1)
 647     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_INTERNAL_XDR")
 648 endif(NOT GMX_SYSTEM_XDR)
 649
 650 # include avx test source, used if the AVX flags are set below
 651 include(gmxTestAVXMaskload)
 652
 653 # Process nonbonded accelerated kernels settings
 654 #
 655 # Note that for the backward-compatible x86 SIMD architectures, the
 656 # GMX_CPU_ACCELERATION determines the maximum level of the instruction
 657 # set used (e.g. GMX_CPU_ACCLERATION=SSE4.1 implies
 658 # SSE2). Accordingly, there are a set of CMake variables
 659 # GMX_<arch>_<feature-set> that are exported to the C code to specify
 660 # CPU features that should be used. This means that the logic for
 661 # requiring such backward compatibility is all located here.
 662 string(TOUPPER ${GMX_CPU_ACCELERATION} GMX_CPU_ACCELERATION)
 663 if(${GMX_CPU_ACCELERATION} STREQUAL "NONE")
 664     # nothing to do
 665 elseif(${GMX_CPU_ACCELERATION} STREQUAL "SSE2")
 666
 667     GMX_TEST_CFLAG(GNU_SSE2_CFLAG "-msse2" ACCELERATION_C_FLAGS)
 668     if(NOT GNU_SSE2_CFLAG AND GMX_NATIVE_WINDOWS)
 669         GMX_TEST_CFLAG(MSVC_SSE2_CFLAG "/arch:SSE2" ACCELERATION_C_FLAGS)
 670     endif(NOT GNU_SSE2_CFLAG AND GMX_NATIVE_WINDOWS)
 671
 672     if (CMAKE_CXX_COMPILER_LOADED)
 673         GMX_TEST_CXXFLAG(GNU_SSE2_CXXFLAG "-msse2" ACCELERATION_CXX_FLAGS)
 674         if(NOT GNU_SSE2_CXXFLAG AND GMX_NATIVE_WINDOWS)
 675             GMX_TEST_CXXFLAG(MSVC_SSE2_CXXFLAG "/arch:SSE2" ACCELERATION_CXX_FLAGS)
 676         endif(NOT GNU_SSE2_CXXFLAG AND GMX_NATIVE_WINDOWS)
 677     endif()
 678
 679     # We dont warn for lacking SSE2 flag support, since that is probably standard today.
 680
 681     # Only test the include after we have tried to add the correct flag for SSE2 support
 682     check_include_file(emmintrin.h  HAVE_EMMINTRIN_H ${ACCELERATION_C_FLAGS})
 683
 684     if(NOT HAVE_EMMINTRIN_H)
 685         message(FATAL_ERROR "Cannot find emmintrin.h, which is required for SSE2 intrinsics support.")
 686     endif(NOT HAVE_EMMINTRIN_H)
 687
 688     set(GMX_CPU_ACCELERATION_X86_SSE2 1)
 689     # The user should not be able to set this orthogonally to the acceleration
 690     set(GMX_X86_SSE2 1)
 691     if (NOT ACCELERATION_QUIETLY)
 692       message(STATUS "Enabling SSE2 Gromacs acceleration, and it will help compiler optimization.")
 693     endif()
 694
 695 elseif(${GMX_CPU_ACCELERATION} STREQUAL "SSE4.1")
 696
 697     GMX_TEST_CFLAG(GNU_SSE4_CFLAG "-msse4.1" ACCELERATION_C_FLAGS)
 698     if (NOT GNU_SSE4_CFLAG AND GMX_NATIVE_WINDOWS)
 699         GMX_TEST_CFLAG(MSVC_SSE4_CFLAG "/arch:SSE4.1" ACCELERATION_C_FLAGS)
 700     endif(NOT GNU_SSE4_CFLAG AND GMX_NATIVE_WINDOWS)
 701     if (NOT GNU_SSE4_CFLAG AND NOT MSVC_SSE4_CFLAG)
 702         # Not surprising if we end up here! MSVC current does not support the SSE4.1 flag. However, it appears to accept SSE4.1
 703         # intrinsics when SSE2 support is enabled, so we try that instead first.
 704         if (GMX_NATIVE_WINDOWS)
 705             GMX_TEST_CFLAG(MSVC_SSE2_CFLAG "/arch:SSE2" ACCELERATION_C_FLAGS)
 706             message(WARNING "Neither SSE4.1 or SSE2 seems to be supported by your Windows compiler. Something is likely broken.")
 707         else()
 708             message(WARNING "No C SSE4.1 flag found. Consider a newer compiler, or use SSE2 for slightly lower performance")
 709         endif()
 710     endif(NOT GNU_SSE4_CFLAG AND NOT MSVC_SSE4_CFLAG)
 711
 712     if (CMAKE_CXX_COMPILER_LOADED)
 713         GMX_TEST_CXXFLAG(GNU_SSE4_CXXFLAG "-msse4.1" ACCELERATION_CXX_FLAGS)
 714         if (NOT GNU_SSE4_CXXFLAG AND GMX_NATIVE_WINDOWS)
 715             GMX_TEST_CXXFLAG(MSVC_SSE4_CXXFLAG "/arch:SSE4.1" ACCELERATION_CXX_FLAGS)
 716         endif(NOT GNU_SSE4_CXXFLAG AND GMX_NATIVE_WINDOWS)
 717         if (NOT GNU_SSE4_CXXFLAG AND NOT MSVC_SSE4_CXXFLAG)
 718             message(WARNING "No C++ SSE4.1 flag found. Consider a newer compiler, or use SSE2 for slightly lower performance.")
 719             # Not surprising if we end up here! MSVC current does not support the SSE4.1 flag. However, it appears to accept SSE4.1
 720             # intrinsics when SSE2 support is enabled, so we try that instead.
 721             if (GMX_NATIVE_WINDOWS)
 722                 GMX_TEST_CXXFLAG(MSVC_SSE2_CXXFLAG "/arch:SSE2" ACCELERATION_CXX_FLAGS)
 723             endif()
 724         endif(NOT GNU_SSE4_CXXFLAG AND NOT MSVC_SSE4_CXXFLAG)
 725     endif()
 726
 727     # This must come after we have added the -msse4.1 flag on some platforms.
 728     check_include_file(smmintrin.h  HAVE_SMMINTRIN_H ${ACCELERATION_C_FLAGS})
 729
 730     if(NOT HAVE_SMMINTRIN_H)
 731         message(FATAL_ERROR "Cannot find smmintrin.h, which is required for SSE4.1 intrinsics support.")
 732     endif(NOT HAVE_SMMINTRIN_H)
 733
 734     set(GMX_CPU_ACCELERATION_X86_SSE4_1 1)
 735     # The user should not be able to set this orthogonally to the acceleration
 736     set(GMX_X86_SSE4_1 1)
 737     set(GMX_X86_SSE2   1)
 738     if (NOT ACCELERATION_QUIETLY)
 739       message(STATUS "Enabling SSE4.1 Gromacs acceleration, and it will help compiler optimization.")
 740     endif()
 741
 742     if(CMAKE_C_COMPILER_ID MATCHES "Intel" AND C_COMPILER_VERSION VERSION_EQUAL "11.1")
 743         message(FATAL_ERROR "You are using Intel compiler version 11.1, and that compiler is known to produce incorrect results with SSE4.1 acceleration. You need to use another compiler (e.g. icc 12 or newer) or different acceleration (probably slower simulations).")
 744     endif()
 745 elseif(${GMX_CPU_ACCELERATION} STREQUAL "AVX_128_FMA" OR ${GMX_CPU_ACCELERATION} STREQUAL "AVX_256")
 746
 747     # Set the AVX compiler flag for both these choices!
 748
 749     GMX_TEST_CFLAG(GNU_AVX_CFLAG "-mavx" ACCELERATION_C_FLAGS)
 750     if (NOT GNU_AVX_CFLAG AND GMX_NATIVE_WINDOWS)
 751         GMX_TEST_CFLAG(MSVC_AVX_CFLAG "/arch:AVX" ACCELERATION_C_FLAGS)
 752     endif (NOT GNU_AVX_CFLAG AND GMX_NATIVE_WINDOWS)
 753     if (NOT GNU_AVX_CFLAG AND NOT MSVC_AVX_CFLAG)
 754         message(WARNING "No C AVX flag found. Consider a newer compiler, or try SSE4.1 (lower performance) giving the -DGMX_CPU_ACCELERATION=SSE4.1 to cmake.")
 755     endif (NOT GNU_AVX_CFLAG AND NOT MSVC_AVX_CFLAG)
 756
 757     if (CMAKE_CXX_COMPILER_LOADED)
 758         GMX_TEST_CXXFLAG(GNU_AVX_CXXFLAG "-mavx" ACCELERATION_CXX_FLAGS)
 759         if (NOT GNU_AVX_CXXFLAG AND GMX_NATIVE_WINDOWS)
 760             GMX_TEST_CXXFLAG(MSVC_AVX_CXXFLAG "/arch:AVX" ACCELERATION_CXX_FLAGS)
 761         endif (NOT GNU_AVX_CXXFLAG AND GMX_NATIVE_WINDOWS)
 762         if (NOT GNU_AVX_CXXFLAG AND NOT MSVC_AVX_CXXFLAG)
 763             message(WARNING "No C++ AVX flag found. Consider a newer compiler, or try SSE4.1 (lower performance) giving the -DGMX_CPU_ACCELERATION=SSE4.1 to cmake.")
 764         endif (NOT GNU_AVX_CXXFLAG AND NOT MSVC_AVX_CXXFLAG)
 765     endif()
 766
 767     # Set the FMA4 flags (MSVC doesn't require any)
 768     if(${GMX_CPU_ACCELERATION} STREQUAL "AVX_128_FMA" AND NOT MSVC)
 769         GMX_TEST_CFLAG(GNU_FMA_CFLAG "-mfma4" ACCELERATION_C_FLAGS)
 770         if (NOT GNU_FMA_CFLAG)
 771             message(WARNING "No C FMA4 flag found. Consider a newer compiler, or try SSE4.1 (lower performance).")
 772         endif(NOT GNU_FMA_CFLAG)
 773         GMX_TEST_CFLAG(GNU_XOP_CFLAG "-mxop" ACCELERATION_C_FLAGS)
 774         # No big deal if we do not have xop, so no point yelling warnings about it.
 775         if (CMAKE_CXX_COMPILER_LOADED)
 776             GMX_TEST_CXXFLAG(GNU_FMA_CXXFLAG "-mfma4" ACCELERATION_CXX_FLAGS)
 777             if (NOT GNU_FMA_CXXFLAG)
 778                 message(WARNING "No C++ FMA flag found. Consider a newer compiler, or try SSE4.1 (lower performance).")
 779             endif (NOT GNU_FMA_CXXFLAG)
 780             GMX_TEST_CXXFLAG(GNU_XOP_CXXFLAG "-mxop" ACCELERATION_CXX_FLAGS)
 781             # No big deal if we do not have xop, so no point yelling warnings about it.
 782         endif()
 783     endif()
 784
 785     # Only test the header after we have tried to add the flag for AVX support
 786     check_include_file(immintrin.h  HAVE_IMMINTRIN_H ${ACCELERATION_C_FLAGS})
 787
 788     if(NOT HAVE_IMMINTRIN_H)
 789         message(FATAL_ERROR "Cannot find immintrin.h, which is required for AVX intrinsics support. Consider switching compiler.")
 790     endif(NOT HAVE_IMMINTRIN_H)
 791
 792     if(${GMX_CPU_ACCELERATION} STREQUAL "AVX_256")
 793         try_compile(TEST_AVX ${CMAKE_BINARY_DIR}
 794             "${CMAKE_SOURCE_DIR}/cmake/TestAVX.c"
 795             COMPILE_DEFINITIONS "${ACCELERATION_C_FLAGS}")
 796         if(NOT TEST_AVX)
 797             message(FATAL_ERROR "Cannot compile AVX intrinsics. Consider switching compiler.")
 798         endif()
 799     endif()
 800
 801     # GCC requires x86intrin.h for FMA support. MSVC 2010 requires intrin.h for FMA support.
 802     check_include_file(x86intrin.h HAVE_X86INTRIN_H ${ACCELERATION_C_FLAGS})
 803     check_include_file(intrin.h HAVE_INTRIN_H ${ACCELERATION_C_FLAGS})
 804
 805     # The user should not be able to set this orthogonally to the acceleration
 806     set(GMX_X86_SSE4_1 1)
 807     set(GMX_X86_SSE2   1)
 808
 809     # But just enable one of the choices internally...
 810     if(${GMX_CPU_ACCELERATION} STREQUAL "AVX_128_FMA")
 811         set(GMX_CPU_ACCELERATION_X86_AVX_128_FMA 1)
 812         set(GMX_X86_AVX_128_FMA 1)
 813         if (NOT ACCELERATION_QUIETLY)
 814           message(STATUS "Enabling 128-bit AVX Gromacs acceleration (with fused-multiply add), and it will help compiler optimization.")
 815         endif()
 816
 817         # We don't have the full compiler version string yet (BUILD_C_COMPILER),
 818         # so we can't distinguish vanilla and Apple clang, but catering for AMD
 819         # hackintoshes is not worth the effort.
 820         if (APPLE AND ${CMAKE_C_COMPILER_ID} STREQUAL "Clang")
 821             message(WARNING "Due to a known compiler bug, Clang up to version 3.2 (and Apple Clang up to version 4.1) produces incorrect code with AVX_128_FMA acceleration. As we can not work around this bug on OS X, you will have to select a different compiler or CPU acceleration.")
 822         endif()
 823
 824         if (GMX_USE_CLANG_FMA_BUG_WORKAROUND)
 825             # we assume that we have an external assembler that supports AVX
 826             message(STATUS "Clang ${C_COMPILER_VERSION} detected, enabling FMA bug workaround")
 827             set(EXTRA_C_FLAGS "${EXTRA_C_FLAGS} -no-integrated-as")
 828         endif()
 829
 830     else()
 831         # If we are not doing AVX_128, it must be AVX_256...
 832         set(GMX_CPU_ACCELERATION_X86_AVX_256 1)
 833         set(GMX_X86_AVX_256 1)
 834         if (NOT ACCELERATION_QUIETLY)
 835           message(STATUS "Enabling 256-bit AVX Gromacs acceleration, and it will help compiler optimization.")
 836         endif()
 837     endif()
 838
 839     # Unfortunately gcc-4.5.2 and gcc-4.6.0 has a bug where they use the wrong datatype for the formal
 840     # parameter of the mask for maskload/maskstore arguments. Check if this is present, since we can work around it.
 841     gmx_test_avx_gcc_maskload_bug(${ACCELERATION_C_FLAGS} GMX_X86_AVX_GCC_MASKLOAD_BUG)
 842
 843 elseif(${GMX_CPU_ACCELERATION} STREQUAL "IBM_QPX")
 844     # Used on BlueGene/Q
 845     if (CMAKE_C_COMPILER_ID MATCHES "XL")
 846         GMX_TEST_CFLAG(XLC_BLUEGENEQ_CFLAG "-qarch=qp -qtune=qp" ACCELERATION_C_FLAGS)
 847         try_compile(TEST_QPX ${CMAKE_BINARY_DIR}
 848             "${CMAKE_SOURCE_DIR}/cmake/TestQPX.c"
 849             COMPILE_DEFINITIONS "${ACCELERATION_C_FLAGS}")
 850         if(NOT TEST_QPX)
 851             message(FATAL_ERROR "Cannot compile the requested IBM QPX intrinsics.")
 852         endif()
 853     endif()
 854     if (CMAKE_CXX_COMPILER_ID MATCHES "XL" AND CMAKE_CXX_COMPILER_LOADED)
 855         GMX_TEST_CXXFLAG(XLC_BLUEGENEQ_CXXFLAG "-qarch=qp -qtune=qp" ACCELERATION_CXX_FLAGS)
 856         try_compile(TEST_QPX ${CMAKE_BINARY_DIR}
 857             "${CMAKE_SOURCE_DIR}/cmake/TestQPX.c"
 858             COMPILE_DEFINITIONS "${ACCELERATION_CXX_FLAGS}")
 859         if(NOT TEST_QPX)
 860             message(FATAL_ERROR "Cannot compile the requested IBM QPX intrinsics.")
 861         endif()
 862     endif()
 863
 864     if (TEST_QPX)
 865         message(WARNING "IBM QPX acceleration was selected and could be compiled, but the accelerated kernels are not yet available.")
 866         set(GMX_CPU_ACCELERATION_IBM_QPX 1)
 867     else()
 868         message(FATAL_ERROR "Cannot compile IBM QPX intrinsics without the XL compiler. If you are compiling for BlueGene/Q, use 'cmake .. -DCMAKE_TOOLCHAIN_FILE=BlueGeneQ-static-XL-C' to set up the tool chain.")
 869     endif()
 870 elseif(${GMX_CPU_ACCELERATION} STREQUAL "SPARC64_HPC_ACE")
 871     set(GMX_CPU_ACCELERATION_SPARC64_HPC_ACE 1)
 872 else(${GMX_CPU_ACCELERATION} STREQUAL "NONE")
 873     MESSAGE(FATAL_ERROR "Unrecognized option for accelerated kernels: ${GMX_CPU_ACCELERATION}. Pick one of None, SSE2, SSE4.1, AVX_128_FMA, AVX_256, IBM_QPX, Sparc64_HPC_ACE")
 874 endif(${GMX_CPU_ACCELERATION} STREQUAL "NONE")
 875 set(ACCELERATION_QUIETLY TRUE CACHE INTERNAL "")
 876
 877 # Process QM/MM Settings
 878 string(TOUPPER ${GMX_QMMM_PROGRAM} GMX_QMMM_PROGRAM)
 879 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 880     set(GMX_QMMM_GAUSSIAN 1)
 881 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 882     set(GMX_QMMM_MOPAC 1)
 883 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 884     set(GMX_QMMM_GAMESS 1)
 885 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 886     set(GMX_QMMM_ORCA 1)
 887 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 888     # nothing to do
 889 else(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 890     MESSAGE(FATAL_ERROR "Invalid QM/MM program option: ${GMX_QMMM_PROGRAM}. Choose one of: Gaussian, Mopac, Gamess, Orca, None")
 891 endif(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 892
 893 # Process FFT library settings
 894 string(TOUPPER ${GMX_FFT_LIBRARY} GMX_FFT_LIBRARY)
 895 set(PKG_FFT "")
 896 set(PKG_FFT_LIBS "")
 897 set(MKL_LIBRARIES_FORMAT_DESCRIPTION "Use full paths to library files, in the right order, and separated by semicolons.")
 898 set(MKL_LIBRARIES "" CACHE STRING "List of libraries for linking to MKL. Only used with GMX_FFT_LIBRARY=mkl. ${MKL_LIBRARIES_FORMAT_DESCRIPTION}")
 899 set(MKL_INCLUDE_DIR "" CACHE PATH "Path to mkl.h (non-inclusive). Only used with GMX_FFT_LIBRARY=mkl.")
 900 mark_as_advanced(FORCE MKL_LIBRARIES)
 901 mark_as_advanced(FORCE MKL_INCLUDE_DIR)
 902 if(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 903     if(GMX_DOUBLE)
 904         set(FFTW fftw)
 905     else()
 906         set(FFTW fftwf)
 907     endif()
 908
 909     if(GMX_BUILD_OWN_FFTW)
 910       add_subdirectory(src/contrib/fftw)
 911     else()
 912       find_package(FFTW COMPONENTS ${FFTW})
 913     endif()
 914
 915     string(TOUPPER "${FFTW}" FFTW)
 916     if(NOT ${FFTW}_FOUND)
 917       MESSAGE(FATAL_ERROR "Cannot find FFTW 3 (with correct precision - libfftw3f for single-precision GROMACS or libfftw3 for double-precision GROMACS). Either choose the right precision, choose another FFT(W) library (-DGMX_FFT_LIBRARY), enable the advanced option to let GROMACS build FFTW 3 for you (-DGMX_BUILD_OWN_FFTW=ON) , or use the really slow GROMACS built-in fftpack library (-DGMX_FFT_LIBRARY=fftpack).")
 918     endif()
 919
 920     set(PKG_FFT "${${FFTW}_PKG}")
 921     include_directories(${${FFTW}_INCLUDE_DIRS})
 922     set(FFT_LIBRARIES ${${FFTW}_LIBRARIES})
 923     set(GMX_FFT_FFTW3 1)
 924
 925     if ((${GMX_CPU_ACCELERATION} MATCHES "SSE" OR ${GMX_CPU_ACCELERATION} MATCHES "AVX") AND NOT ${FFTW}_HAVE_SIMD)
 926       message(WARNING "The fftw library found is compiled without SIMD support, which makes it slow. Consider recompiling it or contact your admin")
 927     endif()
 928
 929     if((${GMX_CPU_ACCELERATION} MATCHES "SSE" OR ${GMX_CPU_ACCELERATION} MATCHES "AVX") AND ${FFTW}_HAVE_AVX)
 930         # If we're not doing CPU acceleration, we don't care about FFTW performance on x86 either
 931         message(WARNING "The FFTW library was compiled with --enable-avx to enable AVX SIMD instructions. That might sound like a good idea for your processor, but for FFTW versions up to 3.3.3, these are slower than the SSE/SSE2 SIMD instructions for the way GROMACS uses FFTs. Limitations in the way FFTW allows GROMACS to measure performance make it awkward for either GROMACS or FFTW to make the decision for you based on runtime performance. You should compile a different FFTW library with --enable-sse or --enable-sse2. If you have a more recent FFTW, you may like to compare the performance of GROMACS with FFTW libraries compiled with and without --enable-avx. However, the GROMACS developers do not really expect the FFTW AVX optimization to help, because the performance is limited by memory access, not computation.")
 932     endif()
 933
 934     if(NOT "${GMX_FFT_LIBRARY}" STREQUAL "${GMX_FFT_LIBRARY_PREVIOUS_VALUE}")
 935         MESSAGE(STATUS "Using external FFT library - FFTW3")
 936     endif()
 937 elseif(${GMX_FFT_LIBRARY} STREQUAL "MKL")
 938     # Intel 11 and up makes life somewhat easy if you just want to use
 939     # all their stuff. It's not easy if you only want some of their
 940     # stuff...
 941     if (CMAKE_C_COMPILER_ID MATCHES "Intel" AND C_COMPILER_VERSION VERSION_GREATER "11")
 942         # The next line takes care of everything for MKL
 943         if (WIN32)
 944             set(FFT_LINKER_FLAGS "/Qmkl=sequential")
 945         else()
 946             set(FFT_LINKER_FLAGS "-mkl=sequential")
 947         endif()
 948         # Some versions of icc require this in order that mkl.h can be
 949         # found at compile time.
 950         set(EXTRA_C_FLAGS "${EXTRA_C_FLAGS} ${FFT_LINKER_FLAGS}")
 951
 952         set(MKL_ERROR_MESSAGE "Make sure you have configured your compiler so that ${FFT_LINKER_FLAGS} will work.")
 953     else()
 954         # The user will have to provide the set of magic libraries in
 955         # MKL_LIBRARIES, which we cache (non-advanced), so that they
 956         # don't have to keep specifying it, and can easily see that
 957         # CMake is still using that information.
 958         set(MKL_LIBRARIES "${MKL_LIBRARIES}" CACHE STRING "User-specified libraries for linking to MKL")
 959         mark_as_advanced(CLEAR MKL_LIBRARIES)
 960         include_directories(${MKL_INCLUDE_DIR})
 961         mark_as_advanced(CLEAR MKL_INCLUDE_DIR)
 962         set(FFT_LIBRARIES "${MKL_LIBRARIES}")
 963         set(MKL_ERROR_MESSAGE "The include path to mkl.h in MKL_INCLUDE_DIR, and the link libraries in MKL_LIBRARIES=${MKL_LIBRARIES} need to match what the MKL documentation says you need for your system. ${MKL_LIBRARIES_FORMAT_DESCRIPTION}")
 964         # Convert the semi-colon separated list to a list of
 965         # command-line linker arguments so that code using our
 966         # pkgconfig setup can use it.
 967         string(REGEX REPLACE ";" " " PKG_FFT_LIBS "${MKL_LIBRARIES}")
 968     endif()
 969
 970     # Check MKL works. If we were in a non-global scope, we wouldn't
 971     # have to play nicely.
 972     set(old_CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS}")
 973     set(CMAKE_REQUIRED_FLAGS "${FFT_LINKER_FLAGS}")
 974     set(old_CMAKE_REQUIRED_LIBRARIES "${CMAKE_REQUIRED_LIBRARIES}")
 975     set(CMAKE_REQUIRED_LIBRARIES "${FFT_LIBRARIES}")
 976
 977     check_function_exists(DftiCreateDescriptor TEST_MKL)
 978
 979     set(CMAKE_REQUIRED_FLAGS "${old_CMAKE_REQUIRED_FLAGS}")
 980     set(CMAKE_REQUIRED_LIBRARIES "${old_CMAKE_REQUIRED_LIBRARIES}")
 981
 982     if(NOT TEST_MKL)
 983         # Hack to help the user vary MKL settings until they work.
 984         # TODO Make this logic more useful.
 985         unset(TEST_MKL CACHE)
 986         message(FATAL_ERROR "Linking with MKL was requested, but was not successful. ${MKL_ERROR_MESSAGE}")
 987     endif()
 988
 989     # Set variables to signal that we have MKL available and should use it for FFTs.
 990     set(GMX_FFT_MKL 1)
 991     set(HAVE_LIBMKL 1)
 992
 993     if(NOT "${GMX_FFT_LIBRARY}" STREQUAL "${GMX_FFT_LIBRARY_PREVIOUS_VALUE}")
 994         MESSAGE(STATUS "Using external FFT library - Intel MKL")
 995     endif()
 996
 997 #elseif(${GMX_FFT_LIBRARY} STREQUAL "ACML")
 998 #    MESSAGE(STATUS "Using external FFT library - AMD core math library")
 999 #    set(GMX_FFT_ACML 1)
1000 elseif(${GMX_FFT_LIBRARY} STREQUAL "FFTPACK")
1001     set(GMX_FFT_FFTPACK 1)
1002     if(NOT "${GMX_FFT_LIBRARY}" STREQUAL "${GMX_FFT_LIBRARY_PREVIOUS_VALUE}")
1003         MESSAGE(STATUS "Using internal FFT library - fftpack")
1004     endif()
1005 else(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
1006     MESSAGE(FATAL_ERROR "Invalid FFT library setting: ${GMX_FFT_LIBRARY}. Choose one of: fftw3, mkl, fftpack")
1007 endif(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
1008 set(GMX_FFT_LIBRARY_PREVIOUS_VALUE ${GMX_FFT_LIBRARY} CACHE INTERNAL "Previous value for GMX_FFT_LIBRARY, so that we can detect when it changes.")
1009
1010 # enable threaded fftw3 if we've found it
1011 if(FFTW3_THREADS OR FFTW3F_THREADS)
1012     add_definitions(-DFFT5D_FFTW_THREADS)
1013 endif()
1014
1015 include(gmxManageLinearAlgebraLibraries)
1016
1017 set(GMX_USE_PLUGINS OFF CACHE INTERNAL "Whether GROMACS will really try to compile support for VMD plugins")
1018
1019 if(GMX_LOAD_PLUGINS)
1020   if(CYGWIN OR NOT WIN32)
1021     # Native Windows does not have, nor need dlopen
1022     # Note that WIN32 is set with Cygwin, but Cygwin needs dlopen to use plug-ins
1023     include(gmxTestdlopen)
1024     gmx_test_dlopen(HAVE_DLOPEN)
1025   endif()
1026
1027   # so, should we use plug-ins?
1028   if((WIN32 AND NOT CYGWIN) OR (HAVE_DLOPEN AND BUILD_SHARED_LIBS))
1029     if(NOT VMD_QUIETLY)
1030       MESSAGE(STATUS
1031           "Found the ability to use plug-ins when building shared libaries, "
1032           "so will compile to use plug-ins (e.g. to read VMD-supported file "
1033           "formats).")
1034     endif()
1035     if(NOT GMX_VMD_PLUGIN_PATH)
1036       find_package(VMD)
1037     endif()
1038     set(GMX_USE_PLUGINS ON)
1039     list(APPEND GMX_EXTRA_LIBRARIES ${CMAKE_DL_LIBS}) # magic cross-platform pre-set variable for dlopen library
1040     set(PKG_DL_LIBS "-l${CMAKE_DL_LIBS}")
1041   else()
1042     set(PKG_DL_LIBS)
1043   endif()
1044 endif(GMX_LOAD_PLUGINS)
1045 set(VMD_QUIETLY TRUE CACHE INTERNAL "")
1046
1047 if(EXISTS "${CMAKE_SOURCE_DIR}/admin/.isreposource")
1048     if(NOT CMAKE_CROSSCOMPILING)
1049         option(GMX_BUILD_MANPAGES "Build man pages" ON)
1050     else()
1051         message(STATUS "Building the man pages is not available when "
1052             "cross-compiling the developer version from git")
1053     endif()
1054 else()
1055     #make sure source package contains all man pages
1056     if(NOT EXISTS "${CMAKE_SOURCE_DIR}/man/man1/ngmx.1")
1057         message(FATAL_ERROR "Man pages are missing from source package.")
1058     endif()
1059 endif()
1060 mark_as_advanced(GMX_BUILD_MANPAGES)
1061
1062 # Math and thread libraries must often come after all others when linking...
1063 if(HAVE_LIBM)
1064     list(APPEND GMX_EXTRA_LIBRARIES m)
1065 endif(HAVE_LIBM)
1066
1067 if(GMX_FAHCORE)
1068   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
1069       "Path to swindirect.h")
1070   include_directories(${COREWRAP_INCLUDE_DIR})
1071   set_property(CACHE GMX_COOL_QUOTES PROPERTY VALUE OFF)
1072 endif(GMX_FAHCORE)
1073
1074 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
1075 # these are set after everything else
1076 if (NOT GMX_SKIP_DEFAULT_CFLAGS)
1077     set(CMAKE_C_FLAGS "${ACCELERATION_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${CMAKE_C_FLAGS}")
1078     set(CMAKE_CXX_FLAGS "${ACCELERATION_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${CMAKE_CXX_FLAGS}")
1079     set(CMAKE_EXE_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}")
1080     set(CMAKE_SHARED_LINKER_FLAGS "${MPI_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS}")
1081 else()
1082     message("Recommended flags which are not added because GMX_SKIP_DEFAULT_CFLAGS=yes:")
1083     message("CMAKE_C_FLAGS: ${ACCELERATION_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${GMXC_CFLAGS}")
1084     message("CMAKE_C_FLAGS_RELEASE: ${GMXC_CFLAGS_RELEASE}")
1085     message("CMAKE_C_FLAGS_DEBUG: ${GMXC_CFLAGS_DEBUG}")
1086     if(CMAKE_CXX_COMPILER_LOADED)
1087         message("CMAKE_CXX_FLAGS: ${ACCELERATION_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${GMXC_CXXFLAGS}")
1088         message("CMAKE_CXX_FLAGS_RELEASE: ${GMXC_CXXFLAGS_RELEASE}")
1089         message("CMAKE_CXX_FLAGS_DEBUG: ${GMXC_CXXFLAGS_DEBUG}")
1090     endif()
1091     message("CMAKE_EXE_LINKER_FLAGS: ${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS}")
1092     message("CMAKE_SHARED_LINKER_FLAGS: ${MPI_LINKER_FLAGS}")
1093 endif()
1094
1095 if(NOT GMX_OPENMP)
1096     #Unset all OpenMP flags in case OpenMP was disabled either by the user
1097     #or because it was only partially detected (e.g. only for C but not C++ compiler)
1098     unset(OpenMP_C_FLAGS CACHE)
1099     unset(OpenMP_CXX_FLAGS CACHE)
1100     unset(OpenMP_LINKER_FLAGS CACHE)
1101     unset(OpenMP_SHARED_LINKER_FLAGS)
1102 endif()
1103 set(PKG_CFLAGS "${PKG_CFLAGS} ${OpenMP_C_FLAGS}")
1104
1105 ######################################
1106 # Output compiler and CFLAGS used
1107 ######################################
1108 get_compiler_info(C BUILD_C_COMPILER BUILD_CFLAGS)
1109 if (CMAKE_CXX_COMPILER_LOADED)
1110     get_compiler_info(CXX BUILD_CXX_COMPILER BUILD_CXXFLAGS)
1111 endif ()
1112 if(GMX_GPU)
1113     get_cuda_compiler_info(CUDA_NVCC_COMPILER_INFO CUDA_NVCC_COMPILER_FLAGS)
1114 endif(GMX_GPU)
1115
1116
1117 ########################################################################
1118 # Specify install locations and which subdirectories to process        #
1119 ########################################################################
1120 if (GMX_USE_RELATIVE_INSTALL_PATH)
1121     set(GMX_INSTALL_PREFIX "" CACHE STRING "Prefix gets appended to CMAKE_INSTALL_PREFIX. For cpack it sets the root folder of the archive.")
1122     mark_as_advanced(GMX_INSTALL_PREFIX)
1123 else()
1124     set(GMX_INSTALL_PREFIX "${CMAKE_INSTALL_PREFIX}/")
1125 endif()
1126
1127 if ( NOT DEFINED GMXLIB )
1128     set(GMXLIB lib)
1129 endif()
1130 set(LIB_INSTALL_DIR "${GMX_INSTALL_PREFIX}${GMXLIB}")
1131 set(BIN_INSTALL_DIR  ${GMX_INSTALL_PREFIX}bin)
1132 set(DATA_INSTALL_DIR ${GMX_INSTALL_PREFIX}share/gromacs)
1133 set(MAN_INSTALL_DIR  ${GMX_INSTALL_PREFIX}share/man)
1134 set(INCL_INSTALL_DIR ${GMX_INSTALL_PREFIX}include)
1135
1136 set(GMXLIBDIR        ${DATA_INSTALL_DIR}/top)
1137
1138 ########################################################################
1139 # Set up binary and library suffixing
1140 ########################################################################
1141 set(GMX_BINARY_SUFFIX "" CACHE STRING "Suffix for GROMACS binaries (default: _d for double, _mpi for MPI, _mpi_d for MPI and double).")
1142 set(GMX_LIBS_SUFFIX ""
1143   CACHE STRING "Suffix for GROMACS libs (default: _d for double, _mpi for MPI, _mpi_d for MPI and double).")
1144 if (GMX_DEFAULT_SUFFIX)
1145   set(GMX_BINARY_SUFFIX "")
1146   set(GMX_LIBS_SUFFIX "")
1147   if (GMX_LIB_MPI)
1148     set(GMX_BINARY_SUFFIX "_mpi")
1149     set(GMX_LIBS_SUFFIX "_mpi")
1150   endif()
1151   if (GMX_DOUBLE)
1152     set (GMX_BINARY_SUFFIX "${GMX_BINARY_SUFFIX}_d")
1153     set (GMX_LIBS_SUFFIX "${GMX_LIBS_SUFFIX}_d")
1154   endif(GMX_DOUBLE)
1155   mark_as_advanced(FORCE GMX_BINARY_SUFFIX GMX_LIBS_SUFFIX)
1156   if (NOT SUFFIX_QUIETLY)
1157     message(STATUS "Using default binary suffix: \"${GMX_BINARY_SUFFIX}\"")
1158     message(STATUS "Using default library suffix: \"${GMX_LIBS_SUFFIX}\"")
1159   endif (NOT SUFFIX_QUIETLY)
1160 else(GMX_DEFAULT_SUFFIX)
1161   mark_as_advanced(CLEAR GMX_BINARY_SUFFIX GMX_LIBS_SUFFIX)
1162   if (NOT SUFFIX_QUIETLY)
1163     message(STATUS "Using manually set binary suffix: \"${GMX_BINARY_SUFFIX}\"")
1164     message(STATUS "Using manually set library suffix: \"${GMX_LIBS_SUFFIX}\"")
1165   endif (NOT SUFFIX_QUIETLY)
1166 endif(GMX_DEFAULT_SUFFIX)
1167 set(SUFFIX_QUIETLY TRUE CACHE INTERNAL "")
1168
1169 ##################################################################
1170 # Shared library settings - Darwin uses INSTALL_NAME_DIR instead!
1171 ##################################################################
1172 if(NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin")
1173     set(CMAKE_SKIP_BUILD_RPATH  FALSE)
1174     set(CMAKE_BUILD_WITH_INSTALL_RPATH FALSE)
1175     set(CMAKE_INSTALL_RPATH "\\\$ORIGIN/../${GMXLIB}")
1176     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
1177 endif()
1178
1179 #COPYING file: Only necessary for binary distributions.
1180 #Simpler to always install.
1181 install(FILES COPYING DESTINATION ${DATA_INSTALL_DIR} COMPONENT data)
1182
1183 add_subdirectory(share)
1184 add_subdirectory(include)
1185 add_subdirectory(src)
1186 add_subdirectory(scripts)
1187
1188 # Issue a warning if NVIDIA GPUs were detected, but CUDA was not found.
1189 # Don't bother the user after the first configure pass.
1190 if ((CUDA_NOTFOUND_AUTO AND GMX_DETECT_GPU_AVAILABLE) AND NOT GMX_GPU_DETECTION_DONE)
1191     message(WARNING "${CUDA_NOTFOUND_MESSAGE}")
1192     unset(CUDA_NOTFOUND_AUTO)
1193     unset(CUDA_NOTFOUND_MESSAGE)
1194 endif()
1195 set(GMX_GPU_DETECTION_DONE TRUE CACHE INTERNAL "Whether GPU detection has already been done")
1196
1197 #######################
1198 ## uninstall target
1199 #######################
1200     CONFIGURE_FILE(
1201                    "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
1202                    "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
1203                    IMMEDIATE @ONLY)
1204 ###########################
1205 ADD_CUSTOM_TARGET(uninstall
1206                   "${CMAKE_COMMAND}" -P
1207                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
1208 ###########################
1209
1210 ########################################################################
1211 # Tests                                                                #
1212 ########################################################################
1213
1214 include(CTest)
1215 mark_as_advanced(BUILD_TESTING)
1216 #gmxtests target builds all binaries required for running gmxtest
1217 add_custom_target(gmxtests DEPENDS grompp mdrun pdb2gmx gmxcheck editconf)
1218 IF(BUILD_TESTING)
1219     enable_testing()
1220     add_subdirectory(tests)
1221     if(REGRESSIONTEST_PATH)
1222         #check target builds all to run tests and the runs tests
1223         add_custom_target(check COMMAND ${CMAKE_CTEST_COMMAND} --output-on-failure)
1224         add_dependencies(check gmxtests)
1225     else()
1226         add_custom_target(check COMMAND ${CMAKE_COMMAND} -E echo "WARNING: No tests are run. Running the tests requires either of the cmake variables REGRESSIONTEST_PATH or REGRESSIONTEST_DOWNLOAD to be set.")
1227     endif()
1228 ENDIF()
1229