CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.8)
   2 # Keep CMake suitably quiet on Cygwin
   3 set(CMAKE_LEGACY_CYGWIN_WIN32 0) # Remove when CMake >= 2.8.4 is required
   4
   5 # override bugs on OS X where Cmake picks gcc (GNU) for C instead of system default cc (Clang).
   6 if(APPLE)
   7     set(CMAKE_C_COMPILER_INIT "cc")
   8 endif(APPLE)
   9
  10 project(Gromacs)
  11 include(Dart)
  12 mark_as_advanced(DART_ROOT)
  13
  14 # PROJECT_VERSION should have the following structure:
  15 # VERSION-dev[-SUFFIX] where the VERSION should have the for: vMajor.vMinor.vPatch
  16 #
  17 # The "-dev" suffix is important to keep because it makes possible to distinguish
  18 # between a build from official release and a build from git release branch on a
  19 # machine with no git.
  20 #
  21 # NOTE: when releasing the "-dev" suffix needs to be stripped off!
  22 set(PROJECT_VERSION "4.6-dev")
  23 set(CUSTOM_VERSION_STRING ""
  24     CACHE STRING "Custom version string (if empty, use hard-coded default)")
  25 mark_as_advanced(CUSTOM_VERSION_STRING)
  26 if (CUSTOM_VERSION_STRING)
  27     set(PROJECT_VERSION ${CUSTOM_VERSION_STRING})
  28 endif (CUSTOM_VERSION_STRING)
  29 set(SOVERSION 6)
  30 # It is a bit irritating, but this has to be set separately for now!
  31 SET(CPACK_PACKAGE_VERSION_MAJOR "4")
  32 SET(CPACK_PACKAGE_VERSION_MINOR "6")
  33 #SET(CPACK_PACKAGE_VERSION_PATCH "0")
  34
  35
  36 # Cmake modules/macros are in a subdirectory to keep this file cleaner
  37 set(CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake)
  38
  39 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT AND UNIX)
  40 set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
  41 endif()
  42
  43 if(NOT CMAKE_BUILD_TYPE)
  44     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel." FORCE)
  45 endif(NOT CMAKE_BUILD_TYPE)
  46
  47 enable_language(C)
  48
  49 set(GMX_USE_RELATIVE_INSTALL_PATH OFF CACHE STRING "Use relative paths not absolute paths for cmake install. Has only an effect on cpack.")
  50 mark_as_advanced(GMX_USE_RELATIVE_INSTALL_PATH)
  51
  52 set(CPACK_PACKAGE_VERSION ${PROJECT_VERSION})
  53 set(CPACK_PACKAGE_VENDOR "gromacs.org")
  54 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Gromacs - a toolkit for high-performance molecular simulation")
  55 if (NOT GMX_USE_RELATIVE_INSTALL_PATH)
  56     set(CPACK_SET_DESTDIR "ON")
  57 endif()
  58 set(CPACK_RESOURCE_FILE_WELCOME "${CMAKE_SOURCE_DIR}/admin/InstallWelcome.txt")
  59 # Its GPL/LGPL, so they do not have to agree to a license for mere usage, but some installers require this...
  60 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_SOURCE_DIR}/admin/InstallLicense.txt")
  61 set(CPACK_RESOURCE_FILE_README "${CMAKE_SOURCE_DIR}/admin/InstallInfo.txt")
  62 set(CPACK_SOURCE_IGNORE_FILES ".isreposource;.git;.gitignore")
  63 set(CPACK_PROJECT_CONFIG_FILE "${CMAKE_SOURCE_DIR}/CPackInit.cmake")
  64 SET(CPACK_SOURCE_INSTALLED_DIRECTORIES "${CMAKE_SOURCE_DIR};/;${CMAKE_BINARY_DIR}/man;man")
  65
  66 #must come after all cpack settings!
  67 include(CPack)
  68
  69 ########################################################################
  70 # Check and warn if cache generated on a different host is being reused
  71 ########################################################################
  72 if(CMAKE_HOST_UNIX)
  73     execute_process(COMMAND hostname
  74                     OUTPUT_VARIABLE TMP_HOSTNAME
  75                     OUTPUT_STRIP_TRAILING_WHITESPACE)
  76     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}")
  77         message(WARNING "
  78             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
  79             is being reused! This could lead to inconsitencies; therefore, it is
  80             recommended to regenerate the cache!")
  81     endif()
  82     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
  83             "Hostname of the machine where the cache was generated.")
  84 endif()
  85
  86 ########################################################################
  87 # Fix stupid flags on Windows
  88 ########################################################################
  89 SET(SHARED_LIBS_DEFAULT ON)
  90 IF( WIN32 AND NOT CYGWIN)
  91   option(GMX_PREFER_STATIC_LIBS "When finding libraries prefer static system libraries (MT instead of MD)!" ON)
  92   mark_as_advanced(GMX_PREFER_STATIC_LIBS)
  93   SET(SHARED_LIBS_DEFAULT OFF)  #is currently not working on Windows
  94
  95   IF (GMX_PREFER_STATIC_LIBS)
  96     #Only setting Debug and Release flags. Others configurations current not used.
  97     STRING(REPLACE /MD /MT CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE})
  98     SET(CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE} CACHE STRING "" FORCE)
  99     STRING(REPLACE /MD /MT CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG})
 100     SET(CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG} CACHE STRING "" FORCE)
 101     STRING(REPLACE /MD /MT CMAKE_CXX_FLAGS_RELEASE ${CMAKE_CXX_FLAGS_RELEASE})
 102     SET(CMAKE_CXX_FLAGS_RELEASE ${CMAKE_CXX_FLAGS_RELEASE} CACHE STRING "" FORCE)
 103     STRING(REPLACE /MD /MT CMAKE_CXX_FLAGS_DEBUG ${CMAKE_CXX_FLAGS_DEBUG})
 104     SET(CMAKE_CXX_FLAGS_DEBUG ${CMAKE_CXX_FLAGS_DEBUG} CACHE STRING "" FORCE)
 105   ENDIF()
 106
 107   #Workaround for cmake bug 13174. Replace deprecated options.
 108   IF( CMAKE_C_COMPILER_ID MATCHES "Intel" )
 109     STRING(REPLACE /GZ /RTC1 CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG})
 110     SET(CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG} CACHE STRING "" FORCE)
 111   ENDIF()
 112   IF( CMAKE_CXX_COMPILER_ID MATCHES "Intel" )
 113     STRING(REPLACE /GZ /RTC1 CMAKE_CXX_FLAGS_DEBUG ${CMAKE_CXX_FLAGS_DEBUG})
 114     STRING(REPLACE /GX /EHsc CMAKE_CXX_FLAGS_DEBUG ${CMAKE_CXX_FLAGS_DEBUG})
 115     SET(CMAKE_CXX_FLAGS_DEBUG ${CMAKE_CXX_FLAGS_DEBUG} CACHE STRING "" FORCE)
 116
 117     STRING(REPLACE /GX /EHsc CMAKE_CXX_FLAGS_RELEASE ${CMAKE_CXX_FLAGS_RELEASE})
 118     SET(CMAKE_CXX_FLAGS_RELEASE ${CMAKE_CXX_FLAGS_RELEASE} CACHE STRING "" FORCE)
 119   ENDIF()
 120 ENDIF()
 121
 122 ########################################################################
 123 # User input options                                                   #
 124 ########################################################################
 125 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" OFF)
 126 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 127 option(GMX_THREAD_MPI  "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" ON)
 128 option(GMX_SOFTWARE_INVSQRT "Use GROMACS software 1/sqrt" ON)
 129 mark_as_advanced(GMX_SOFTWARE_INVSQRT)
 130 option(GMX_POWERPC_INVSQRT "Use PowerPC hardware 1/sqrt" OFF)
 131 mark_as_advanced(GMX_POWERPC_INVSQRT)
 132 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 133 mark_as_advanced(GMX_FAHCORE)
 134 option(GMX_OPENMM "Accelerated execution on GPUs through the OpenMM library (rerun cmake after changing to see relevant options)" OFF)
 135
 136 include(gmxDetectAcceleration)
 137 if(NOT DEFINED GMX_ACCELERATION)
 138     if(CMAKE_CROSSCOMPILING)
 139         set(GMX_SUGGESTED_ACCELERATION "None")
 140     else(CMAKE_CROSSCOMPILING)
 141         gmx_detect_acceleration(GMX_SUGGESTED_ACCELERATION)
 142     endif(CMAKE_CROSSCOMPILING)
 143 endif(NOT DEFINED GMX_ACCELERATION)
 144
 145 set(GMX_ACCELERATION "@GMX_SUGGESTED_ACCELERATION@"
 146     CACHE STRING "Accelerated kernels. Pick one of: None, SSE2, SSE4.1, AVX_128_FMA, AVX_256, BlueGene, Power6, Fortran")
 147
 148 set(GMX_FFT_LIBRARY "fftw3"
 149     CACHE STRING "FFT library choices: fftw3,mkl,fftpack[built-in]")
 150 option(GMX_DISABLE_FFTW_MEASURE
 151        "Do not optimize FFTW setups (not needed with SSE)" OFF)
 152 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 153 set(GMX_QMMM_PROGRAM "none"
 154     CACHE STRING "QM package choices: none,gaussian,mopac,gamess,orca")
 155 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 156 mark_as_advanced(GMX_BROKEN_CALLOC)
 157 option(GMX_MPI_IN_PLACE "Enable MPI_IN_PLACE for MPIs that have it defined" ON)
 158 mark_as_advanced(GMX_MPI_IN_PLACE)
 159 option(GMX_LOAD_PLUGINS "Compile with plugin support, needed to read VMD supported file formats" ON)
 160 mark_as_advanced(GMX_LOAD_PLUGINS)
 161
 162 option(GMX_OPENMP "Enable OpenMP-based mutithreading. " ON)
 163
 164 option(USE_VERSION_H "Generate development version string/information" ON)
 165 mark_as_advanced(USE_VERSION_H)
 166
 167 option(GMX_DEFAULT_SUFFIX "Use default suffixes for GROMACS binaries and libs (_d for double, _mpi for MPI; rerun cmake after changing to see relevant options)" ON)
 168
 169 if(UNIX AND NOT APPLE)
 170     option(GMX_PREFER_STATIC_LIBS "When finding libraries prefer \".a\" static archives (NOTE: this is enabled only for UNIX (excluding APPLE) platforms but it might not always work!" OFF)
 171     mark_as_advanced(GMX_PREFER_STATIC_LIBS)
 172 endif()
 173
 174
 175 ######################################################################
 176 # compiler tests
 177 # these need ot be done early (before further tests).
 178 #####################################################################
 179
 180 # cmake/Check{C,CXX}CompilerFlag.cmake are lifted from CMake git next
 181 # branch (proposed for v2.8.9) to be able to detect invalid options
 182 # with the Intel Compilers.
 183 # Remove these files from the source tree when a CMake version that
 184 # includes the features in question becomes required.
 185 include(CheckCCompilerFlag)
 186 include(CheckCXXCompilerFlag)
 187
 188 # OpenMP check must come before other CFLAGS!
 189 if(GMX_OPENMP)
 190     find_package(OpenMP)
 191     if(OPENMP_FOUND)
 192         set(GROMACS_C_FLAGS "${OpenMP_C_FLAGS} ${GROMACS_C_FLAGS}")
 193         set(GROMACS_CXX_FLAGS "${OpenMP_CXX_FLAGS} ${GROMACS_CXX_FLAGS}")
 194     else(OPENMP_FOUND)
 195         message(WARNING
 196                 "Compiler not supporting OpenMP. This might hurt your performance a lot, "
 197                 "in particular with GPUs. Try using a different compiler (Intel is good on x86) "
 198                 "if you can - for now we are proceeding by turning off OpenMP.")
 199         set(GMX_OPENMP OFF CACHE STRING "Compiler does not support OpenMP." FORCE)
 200     endif(OPENMP_FOUND)
 201 endif()
 202
 203
 204 include(gmxCFlags)
 205 gmx_c_flags()
 206
 207 ########################################################################
 208 # Set up binary and library suffixing
 209 ########################################################################
 210 set(GMX_BINARY_SUFFIX "" CACHE STRING "Suffix for GROMACS binaries (default: _d for double, _mpi for MPI, _mpi_d for MPI and double).")
 211 set(GMX_LIBS_SUFFIX ""
 212   CACHE STRING "Suffix for GROMACS libs (default: _d for double, _mpi for MPI, _mpi_d for MPI and double).")
 213 if (GMX_DEFAULT_SUFFIX)
 214   set(GMX_BINARY_SUFFIX "")
 215   set(GMX_LIBS_SUFFIX "")
 216   if (GMX_MPI)
 217     set(GMX_BINARY_SUFFIX "_mpi")
 218     set(GMX_LIBS_SUFFIX "_mpi")
 219   endif(GMX_MPI)
 220   if (GMX_DOUBLE)
 221     set (GMX_BINARY_SUFFIX "${GMX_BINARY_SUFFIX}_d")
 222     set (GMX_LIBS_SUFFIX "${GMX_LIBS_SUFFIX}_d")
 223   endif(GMX_DOUBLE)
 224   if (GMX_OPENMM)
 225     set (GMX_BINARY_SUFFIX "-openmm")
 226     set (GMX_LIBS_SUFFIX "_openmm")
 227   endif(GMX_OPENMM)
 228   mark_as_advanced(FORCE GMX_BINARY_SUFFIX GMX_LIBS_SUFFIX)
 229   if (NOT SUFFIX_QUIETLY)
 230     message(STATUS "Using default binary suffix: \"${GMX_BINARY_SUFFIX}\"")
 231     message(STATUS "Using default library suffix: \"${GMX_LIBS_SUFFIX}\"")
 232   endif (NOT SUFFIX_QUIETLY)
 233 else(GMX_DEFAULT_SUFFIX)
 234   mark_as_advanced(CLEAR GMX_BINARY_SUFFIX GMX_LIBS_SUFFIX)
 235   if (NOT SUFFIX_QUIETLY)
 236     message(STATUS "Using manually set binary suffix: \"${GMX_BINARY_SUFFIX}\"")
 237     message(STATUS "Using manually set library suffix: \"${GMX_LIBS_SUFFIX}\"")
 238   endif (NOT SUFFIX_QUIETLY)
 239 endif(GMX_DEFAULT_SUFFIX)
 240 set(SUFFIX_QUIETLY TRUE CACHE INTERNAL "")
 241
 242 set(PKG_CFLAGS "")
 243 if(GMX_DOUBLE)
 244     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_DOUBLE")
 245 endif(GMX_DOUBLE)
 246 if(GMX_SOFTWARE_INVSQRT)
 247   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_SOFTWARE_INVSQRT")
 248 endif(GMX_SOFTWARE_INVSQRT)
 249 if(GMX_POWERPC_INVSQRT)
 250   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_POWERPC_INVSQRT")
 251 endif(GMX_POWERPC_INVSQRT)
 252
 253 ########################################################################
 254 #Process MPI settings
 255 ########################################################################
 256 include(gmxManageMPI)
 257
 258 #######################################################################
 259 # Check for options incompatible with OpenMM build                    #
 260 #######################################################################
 261 if(GMX_OPENMM)
 262     # we'll use the built-in fft to avoid unnecessary dependencies
 263     string(TOUPPER ${GMX_FFT_LIBRARY} GMX_FFT_LIBRARY)
 264     if(NOT ${GMX_FFT_LIBRARY} STREQUAL "FFTPACK")
 265         message(STATUS "No external FFT libraries needed for the OpenMM build, switching to fftpack!")
 266         set(GMX_FFT_LIBRARY "fftpack" CACHE STRING
 267                 "No external FFT libraries needed for the OpenMM build, switching to  fftpack!" FORCE)
 268     endif()
 269     if(GMX_MPI)
 270         message(FATAL_ERROR "The OpenMM build is not compatible with MPI!")
 271     endif(GMX_MPI)
 272     if(GMX_THREAD_MPI)
 273         message(STATUS "Thread-MPI not compatible with OpenMM, disabled!")
 274         set(GMX_THREAD_MPI OFF CACHE BOOL
 275                 "Thread-MPI not compatible with OpenMM build, disabled!" FORCE)
 276     endif(GMX_THREAD_MPI)
 277     if(GMX_OPENMP)
 278         message(STATUS "OpenMP multithreading not compatible with OpenMM, disabled")
 279         set(GMX_OPENMP OFF CACHE BOOL
 280             "OpenMP multithreading not compatible with OpenMM, disabled!" FORCE)
 281     endif()
 282     if(GMX_SOFTWARE_INVSQRT)
 283         set(GMX_SOFTWARE_INVSQRT OFF CACHE STRING
 284                 "The OpenMM build does not need GROMACS software 1/sqrt!" FORCE)
 285     endif(GMX_SOFTWARE_INVSQRT)
 286     string(TOUPPER ${GMX_ACCELERATION} GMX_ACCELERATION)
 287     if(NOT GMX_ACCELERATION STREQUAL "NONE")
 288         message(STATUS "Switching off CPU-based acceleration, the OpenMM build does not support/need any!")
 289         set(GMX_ACCELERATION "none" CACHE STRING
 290                 "Switching off CPU-based acceleration, the OpenMM build does not support/need any!" FORCE)
 291     endif()
 292     if(GMX_FAHCORE)
 293         message(FATAL_ERROR "The OpenMM build does not support FAH build!")
 294     endif(GMX_FAHCORE)
 295     if(GMX_DOUBLE)
 296         message(FATAL_ERROR  "The OpenMM-build does not support double precision calculations!")
 297     endif()
 298     # mark as advanced the unused variables
 299     mark_as_advanced(FORCE GMX_ACCELERATION GMX_MPI GMX_FFT_LIBRARY
 300         GMX_QMMM_PROGRAM GMX_THREAD_MPI GMX_DOUBLE)
 301 else(GMX_OPENMM)
 302      mark_as_advanced(CLEAR GMX_ACCELERATION GMX_MPI GMX_FFT_LIBRARY
 303         GMX_QMMM_PROGRAM GMX_THREAD_MPI GMX_DOUBLE)
 304 endif(GMX_OPENMM)
 305
 306
 307
 308
 309 ########################################################################
 310 # Basic system tests (standard libraries, headers, functions, types)   #
 311 ########################################################################
 312 include(CheckIncludeFiles)
 313 check_include_files(string.h     HAVE_STRING_H)
 314 check_include_files(math.h       HAVE_MATH_H)
 315 check_include_files(limits.h     HAVE_LIMITS_H)
 316 check_include_files(memory.h     HAVE_MEMORY_H)
 317 check_include_files(unistd.h     HAVE_UNISTD_H)
 318 check_include_files(direct.h     HAVE_DIRECT_H)
 319 check_include_files(pwd.h        HAVE_PWD_H)
 320 check_include_files(stdint.h     HAVE_STDINT_H)
 321 check_include_files(stdlib.h     HAVE_STDLIB_H)
 322 check_include_files(pthread.h    HAVE_PTHREAD_H)
 323 check_include_files(dirent.h     HAVE_DIRENT_H)
 324 check_include_files(inttypes.h   HAVE_INTTYPES_H)
 325 check_include_files(regex.h      HAVE_REGEX_H)
 326 check_include_files(sys/types.h  HAVE_SYS_TYPES_H)
 327 check_include_files(sys/stat.h   HAVE_SYS_STAT_H)
 328 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 329 check_include_files(rpc/rpc.h    HAVE_RPC_RPC_H)
 330 check_include_files("rpc/rpc.h;rpc/xdr.h"    HAVE_RPC_XDR_H)
 331 check_include_files(io.h                 HAVE_IO_H)
 332
 333
 334 include(CheckFunctionExists)
 335 check_function_exists(strcasecmp        HAVE_STRCASECMP)
 336 check_function_exists(strdup            HAVE_STRDUP)
 337 check_function_exists(vprintf           HAVE_VPRINTF)
 338 check_function_exists(memcmp            HAVE_MEMCMP)
 339 check_function_exists(posix_memalign    HAVE_POSIX_MEMALIGN)
 340 check_function_exists(memalign          HAVE_MEMALIGN)
 341 check_function_exists(_aligned_malloc   HAVE__ALIGNED_MALLOC)
 342 check_function_exists(gettimeofday      HAVE_GETTIMEOFDAY)
 343 check_function_exists(isnan             HAVE_ISNAN)
 344 check_function_exists(_isnan            HAVE__ISNAN)
 345 check_function_exists(fsync             HAVE_FSYNC)
 346 check_function_exists(_fileno           HAVE__FILENO)
 347 check_function_exists(fileno            HAVE_FILENO)
 348 check_function_exists(_commit           HAVE__COMMIT)
 349 check_function_exists(lstat             HAVE_LSTAT)
 350 check_function_exists(sigaction         HAVE_SIGACTION)
 351
 352 include(CheckLibraryExists)
 353 check_library_exists(m sqrt "" HAVE_LIBM)
 354 check_library_exists(m cbrt "" HAVE_CBRT)
 355
 356
 357 include(CheckTypeSize)
 358
 359 check_type_size("bool"          SIZEOF_BOOL) # will also set HAVE_BOOL
 360 check_type_size("int"           SIZEOF_INT)
 361 check_type_size("long int"      SIZEOF_LONG_INT)
 362 check_type_size("long long int" SIZEOF_LONG_LONG_INT)
 363 check_type_size("off_t"         SIZEOF_OFF_T)
 364 check_type_size("void *"        SIZEOF_VOIDP)
 365
 366 if (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 367     set(GMX_64_BIT TRUE)
 368 else (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 369     set(GMX_64_BIT FALSE)
 370 endif (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 371
 372 # Check for some basic types that we *need*, so set these to int if they are not present
 373 check_type_size(uid_t uid_t)
 374 if(NOT uid_t)
 375   set(uid_t int)
 376 else(NOT uid_t)
 377   set(uid_t 0)
 378 endif(NOT uid_t)
 379
 380 check_type_size(gid_t gid_t)
 381 if(NOT gid_t)
 382   set(gid_t 1)
 383 else(NOT gid_t)
 384   set(gid_t 0)
 385 endif(NOT gid_t)
 386
 387 check_type_size(size_t size_t)
 388 if(NOT size_t)
 389   set(size_t int)
 390 else(NOT size_t)
 391   set(size_t 0)
 392 endif(NOT size_t)
 393
 394 check_type_size(off_t off_t)
 395 if(NOT off_t)
 396   set(off_t int)
 397 else(NOT off_t)
 398   set(off_t 0)
 399 endif(NOT off_t)
 400
 401 include(TestBigEndian)
 402 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 403
 404
 405
 406
 407 ########################################################################
 408 # Find external packages                                               #
 409 ########################################################################
 410 if(UNIX AND NOT APPLE)
 411     if(GMX_PREFER_STATIC_LIBS)
 412         SET(CMAKE_FIND_LIBRARY_SUFFIXES .a ${CMAKE_FIND_LIBRARY_SUFFIXES})
 413         if(SHARED_LIBS_DEFAULT)
 414             if(BUILD_SHARED_LIBS) #Warn the user about the combination. But don't overwrite the request.
 415                 message(WARNING "Static libraries requested, and shared Gromacs libraries requested.")
 416             elseif(NOT DEFINED BUILD_SHARED_LIBS) #Change default to OFF. Don't warn if it's already off.
 417                 message(WARNING "Static libraries requested, the GROMACS libraries will also be build static (BUILD_SHARED_LIBS=OFF)")
 418                 set(SHARED_LIBS_DEFAULT OFF)
 419             endif()
 420         endif()
 421     endif()
 422 endif()
 423 option(BUILD_SHARED_LIBS "Enable shared libraries (can be problematic with MPI, Windows)" ${SHARED_LIBS_DEFAULT})
 424
 425 option(GMX_XML "Use libxml2 to parse xml files" ON)
 426 if (GMX_XML)
 427   find_package(LibXml2)
 428   set(PKG_XML "")
 429   if(LIBXML2_FOUND)
 430     include_directories(${LIBXML2_INCLUDE_DIR})
 431     set(PKG_XML libxml-2.0)
 432     set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 433     set(HAVE_LIBXML2 1)
 434   endif(LIBXML2_FOUND)
 435 endif(GMX_XML)
 436
 437 option(GMX_GSL "Add support for gsl" OFF)
 438 if (GMX_GSL)
 439   find_package(gsl)
 440   set(PKG_GSL "")
 441   if(GSL_FOUND)
 442     include_directories(${GSL_INCLUDE_DIR})
 443     set(PKG_GSL gsl)
 444     set(HAVE_LIBGSL 1)
 445   endif(GSL_FOUND)
 446 endif (GMX_GSL)
 447
 448 option(GMX_X11 "Use X window system" OFF)
 449 if (GMX_X11)
 450         find_package(X11)
 451         # X11 includes/libraries are only set in the ngmx subdirectory!
 452         if(X11_FOUND)
 453         set(HAVE_X11 1)
 454         endif(X11_FOUND)
 455 endif(GMX_X11)
 456
 457 if(GMX_THREAD_MPI)
 458     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_THREAD_MPI")
 459     include(ThreadMPI)
 460     set(THREAD_MPI_LIB thread_mpi)
 461     set(GMX_MPI 1)
 462     string(TOUPPER ${GMX_FFT_LIBRARY} ${GMX_FFT_LIBRARY})
 463 endif(GMX_THREAD_MPI)
 464
 465 if(GMX_OPENMM)
 466     set(CUDA_BUILD_EMULATION OFF)
 467     find_package(CUDA 3.1 REQUIRED)
 468     add_definitions(-DGMX_OPENMM)
 469     if(CMAKE_BUILD_TYPE STREQUAL "DEBUG")
 470         set(CUDA_VERBOSE_BUILD ON)
 471     endif()
 472     find_package(OpenMM)
 473 endif(GMX_OPENMM)
 474
 475
 476 if(APPLE)
 477    find_library(ACCELERATE_FRAMEWORK Accelerate)
 478    list(APPEND GMX_EXTRA_LIBRARIES ${ACCELERATE_FRAMEWORK})
 479 endif(APPLE)
 480
 481 if(CYGWIN)
 482     set(GMX_CYGWIN 1)
 483 endif(CYGWIN)
 484
 485 if(WIN32 AND NOT CYGWIN)
 486     set(GMX_NATIVE_WINDOWS 1)
 487 endif()
 488
 489 # only bother with finding git and using version.h if the source is a git repo
 490 if(EXISTS "${CMAKE_SOURCE_DIR}/.git")
 491     if(USE_VERSION_H)
 492         # We need at least git v1.5.3 be able to parse git's date output. If not
 493         # found or the version is too small, we can't generate version information.
 494         find_package(Git)
 495
 496         # Find out the git version
 497         if(GIT_FOUND AND NOT GIT_VERSION)
 498           execute_process(COMMAND ${GIT_EXECUTABLE} "--version"
 499             OUTPUT_VARIABLE _exec_out
 500             OUTPUT_STRIP_TRAILING_WHITESPACE)
 501           string(REGEX REPLACE "git version (.*)" "\\1" GIT_VERSION ${_exec_out})
 502           set(GIT_VERSION ${GIT_VERSION} CACHE STRING "Git version")
 503           mark_as_advanced(GIT_VERSION)
 504         endif()
 505
 506         if(NOT GIT_FOUND OR GIT_VERSION VERSION_LESS "1.5.3")
 507           message("No compatible git version found, won't be able to generate proper development version information.")
 508           set(USE_VERSION_H OFF)
 509         endif()
 510     endif()
 511 else()
 512     set(USE_VERSION_H OFF)
 513 endif()
 514
 515 ########################################################################
 516 # Generate development version info for cache
 517 ########################################################################
 518 # set(GEN_VERSION_INFO_INTERNAL "ON")
 519 # include(gmxGenerateVersionString)
 520
 521 ########################################################################
 522 # Our own GROMACS tests
 523 ########################################################################
 524
 525 add_definitions( -DHAVE_CONFIG_H )
 526 include_directories(${CMAKE_BINARY_DIR}/src)
 527 include_directories(${CMAKE_BINARY_DIR}/include)
 528 include_directories(${CMAKE_SOURCE_DIR}/include)
 529
 530 include(gmxTestInlineASM)
 531 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 532
 533 include(gmxSetBuildInformation)
 534 gmx_set_build_information()
 535 if(BUILD_CPU_FEATURES MATCHES "rdtscp")
 536     # The timestep counter headers do not include config.h
 537     add_definitions(-DHAVE_RDTSCP)
 538 endif(BUILD_CPU_FEATURES MATCHES "rdtscp")
 539
 540 include(gmxTestFloatFormat)
 541 gmx_test_float_format(GMX_FLOAT_FORMAT_IEEE754
 542                       GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER
 543                       GMX_IEEE754_BIG_ENDIAN_WORD_ORDER)
 544
 545 include(gmxTestLargeFiles)
 546 gmx_test_large_files(GMX_LARGEFILES)
 547 check_function_exists(fseeko     HAVE_FSEEKO)
 548
 549 include(gmxTestSignal)
 550 gmx_test_sigusr1(HAVE_SIGUSR1)
 551
 552 include(gmxTestInline)
 553 gmx_test_inline(INLINE_KEYWORD)
 554
 555 include(gmxTestRestrict)
 556 gmx_test_inline(RESTRICT_KEYWORD)
 557
 558 include(gmxTestPipes)
 559 gmx_test_pipes(HAVE_PIPES)
 560
 561 include(gmxTestIsfinite)
 562 gmx_test_isfinite(HAVE_ISFINITE)
 563 gmx_test__isfinite(HAVE__ISFINITE)
 564 gmx_test__finite(HAVE__FINITE)
 565
 566 include(gmxTestXDR)
 567 gmx_test_xdr(GMX_SYSTEM_XDR)
 568 if(NOT GMX_SYSTEM_XDR)
 569     set(GMX_INTERNAL_XDR 1)
 570     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_INTERNAL_XDR")
 571 endif(NOT GMX_SYSTEM_XDR)
 572
 573 # Process nonbonded accelerated kernels settings
 574 string(TOUPPER ${GMX_ACCELERATION} ${GMX_ACCELERATION})
 575 if(${GMX_ACCELERATION} STREQUAL "NONE")
 576     # nothing to do
 577 elseif(${GMX_ACCELERATION} STREQUAL "SSE2")
 578
 579     GMX_TEST_CFLAG(GNU_SSE2_CFLAG "-msse2" GROMACS_C_FLAGS)
 580     if(NOT GNU_SSE2_CFLAG)
 581         GMX_TEST_CFLAG(MSVC_SSE2_CFLAG "/arch:SSE2" GROMACS_C_FLAGS)
 582     endif(NOT GNU_SSE2_CFLAG)
 583
 584     GMX_TEST_CXXFLAG(GNU_SSE2_CXXFLAG "-msse2" GROMACS_CXX_FLAGS)
 585     if(NOT GNU_SSE2_CXXFLAG)
 586         GMX_TEST_CXXFLAG(MSVC_SSE2_CXXFLAG "/arch:SSE2" GROMACS_CXX_FLAGS)
 587     endif(NOT GNU_SSE2_CXXFLAG)
 588
 589     # We dont warn for lacking SSE2 flag support, since that is probably standard today.
 590
 591     # Only test the include after we have tried to add the correct flag for SSE2 support
 592     check_include_file(emmintrin.h  HAVE_EMMINTRIN_H ${GROMACS_C_FLAGS})
 593
 594     if(NOT HAVE_EMMINTRIN_H)
 595         message(FATAL_ERROR "Cannot find emmintrin.h, which is required for SSE2 intrinsics support.")
 596     endif(NOT HAVE_EMMINTRIN_H)
 597
 598     # The user should not be able to set this orthogonally to the acceleration
 599     set(GMX_X86_SSE2 1)
 600     if (NOT ACCELERATION_QUIETLY)
 601       message(STATUS "Enabling SSE2 Gromacs acceleration, and it will help compiler optimization.")
 602     endif()
 603
 604 elseif(${GMX_ACCELERATION} STREQUAL "SSE4.1")
 605
 606     GMX_TEST_CFLAG(GNU_SSE4_CFLAG "-msse4.1" GROMACS_C_FLAGS)
 607     if (NOT GNU_SSE4_CFLAG)
 608         GMX_TEST_CFLAG(MSVC_SSE4_CFLAG "/arch:SSE4.1" GROMACS_C_FLAGS)
 609     endif(NOT GNU_SSE4_CFLAG)
 610     if (NOT GNU_SSE4_CFLAG AND NOT MSVC_SSE4_CFLAG)
 611         message(WARNING "No C SSE4.1 flag found. Consider a newer compiler, or disable SSE4.1 for slightly lower performance.")
 612         # Not surprising if we end up here! MSVC current does not support the SSE4.1 flag. However, it appears to accept SSE4.1
 613         # intrinsics when SSE2 support is enabled, so we try that instead.
 614         GMX_TEST_CFLAG(MSVC_SSE2_CFLAG "/arch:SSE2" GROMACS_C_FLAGS)
 615     endif(NOT GNU_SSE4_CFLAG AND NOT MSVC_SSE4_CFLAG)
 616
 617     GMX_TEST_CXXFLAG(GNU_SSE4_CXXFLAG "-msse4.1" GROMACS_CXX_FLAG)
 618     if (NOT GNU_SSE4_CXXFLAG)
 619        GMX_TEST_CXXFLAG(MSVC_SSE4_CXXFLAG "/arch:SSE4.1" GROMACS_CXX_FLAGS)
 620     endif(NOT GNU_SSE4_CXXFLAG)
 621     if (NOT GNU_SSE4_CXXFLAG AND NOT MSVC_SSE4_CXXFLAG)
 622         message(WARNING "No C++ SSE4.1 flag found. Consider a newer compiler, or disable SSE4.1 for slightly lower performance.")
 623         # Not surprising if we end up here! MSVC current does not support the SSE4.1 flag. However, it appears to accept SSE4.1
 624         # intrinsics when SSE2 support is enabled, so we try that instead.
 625         GMX_TEST_CXXFLAG(MSVC_SSE2_CXXFLAG "/arch:SSE2" GROMACS_CXX_FLAGS)
 626     endif(NOT GNU_SSE4_CXXFLAG AND NOT MSVC_SSE4_CXXFLAG)
 627
 628     # This must come after we have added the -msse4.1 flag on some platforms.
 629     check_include_file(smmintrin.h  HAVE_SMMINTRIN_H ${GROMACS_C_FLAGS})
 630
 631     if(NOT HAVE_SMMINTRIN_H)
 632         message(FATAL_ERROR "Cannot find smmintrin.h, which is required for SSE4.1 intrinsics support.")
 633     endif(NOT HAVE_SMMINTRIN_H)
 634
 635     # The user should not be able to set this orthogonally to the acceleration
 636     set(GMX_X86_SSE4_1 1)
 637     set(GMX_X86_SSE2   1)
 638     if (NOT ACCELERATION_QUIETLY)
 639       message(STATUS "Enabling SSE4.1 Gromacs acceleration, and it will help compiler optimization.")
 640     endif()
 641
 642 elseif(${GMX_ACCELERATION} STREQUAL "AVX_128_FMA" OR ${GMX_ACCELERATION} STREQUAL "AVX_256")
 643
 644     # Set the AVX compiler flag for both these choices!
 645
 646     GMX_TEST_CFLAG(GNU_AVX_CFLAG "-mavx" GROMACS_C_FLAGS)
 647     if (NOT GNU_AVX_CFLAG)
 648         GMX_TEST_CFLAG(MSVC_AVX_CFLAG "/arch:AVX" GROMACS_C_FLAGS)
 649     endif (NOT GNU_AVX_CFLAG)
 650     if (NOT GNU_AVX_CFLAG AND NOT MSVC_AVX_CFLAG)
 651         message(WARNING "No C AVX flag found. Consider a newer compiler, or disable AVX for much lower performance.")
 652     endif (NOT GNU_AVX_CFLAG AND NOT MSVC_AVX_CFLAG)
 653
 654     GMX_TEST_CXXFLAG(GNU_AVX_CXXFLAG "-mavx" GROMACS_CXX_FLAGS)
 655     if (NOT GNU_AVX_CXXFLAG)
 656        GMX_TEST_CXXFLAG(MSVC_AVX_CXXFLAG "/arch:AVX" GROMACS_CXX_FLAGS)
 657     endif (NOT GNU_AVX_CXXFLAG)
 658     if (NOT GNU_AVX_CXXFLAG AND NOT MSVC_AVX_CXXFLAG)
 659        message(WARNING "No C++ AVX flag found. Consider a newer compiler, or disable AVX for much lower performance.")
 660     endif (NOT GNU_AVX_CXXFLAG AND NOT MSVC_AVX_CXXFLAG)
 661
 662     # Only test the header after we have tried to add the flag for AVX support
 663     check_include_file(immintrin.h  HAVE_IMMINTRIN_H ${GROMACS_C_FLAGS})
 664
 665     if(NOT HAVE_IMMINTRIN_H)
 666         message(FATAL_ERROR "Cannot find immintrin.h, which is required for AVX intrinsics support. Consider switching compiler.")
 667     endif(NOT HAVE_IMMINTRIN_H)
 668
 669     # AMD says we should include x86intrin.h for FMA support, but MSVC seems to do fine without it, so don't require it.
 670     check_include_file(x86intrin.h HAVE_X86INTRIN_H ${GROMACS_C_FLAGS})
 671
 672     # The user should not be able to set this orthogonally to the acceleration
 673     set(GMX_X86_SSE4_1 1)
 674     set(GMX_X86_SSE2   1)
 675
 676     # But just enable one of the choices internally...
 677     if(${GMX_ACCELERATION} STREQUAL "AVX_128_FMA")
 678         set(GMX_X86_AVX_128_FMA 1)
 679         if (NOT ACCELERATION_QUIETLY)
 680           message(STATUS "Enabling 128-bit AVX Gromacs acceleration (with fused-multiply add), and it will help compiler optimization.")
 681         endif()
 682     else()
 683         # If we are not doing AVX_128, it must be AVX_256...
 684         set(GMX_X86_AVX_256 1)
 685         if (NOT ACCELERATION_QUIETLY)
 686           message(STATUS "Enabling 256-bit AVX Gromacs acceleration, and it will help compiler optimization.")
 687         endif()
 688     endif()
 689
 690 elseif(${GMX_ACCELERATION} STREQUAL "FORTRAN")
 691
 692 #    Fortran is temporarily disabled while we push in nbNxN kernels.
 693 #    We need to fake it a bit here to avoid jenkins build errors!
 694 #    add_definitions(-DGMX_FORTRAN)
 695
 696 elseif(${GMX_ACCELERATION} STREQUAL "BLUEGENE")
 697 # GMX_ACCELERATION=BlueGene should be set in the Toolchain-BlueGene?-???.cmake file
 698     if (NOT ACCELERATION_QUIETLY)
 699       message(STATUS "Configuring for BlueGene")
 700     endif()
 701     set(GMX_BLUEGENE 1)
 702     if (${CMAKE_SYSTEM_NAME} STREQUAL "BlueGeneL")
 703         set(SHARED_LIBS_DEFAULT OFF CACHE BOOL "Shared libraries not compatible with BlueGene/L, disabled!" FORCE)
 704         set(BUILD_SHARED_LIBS OFF CACHE BOOL "Shared libraries not compatible with BlueGene/L, disabled!" FORCE)
 705     endif (${CMAKE_SYSTEM_NAME} STREQUAL "BlueGeneL")
 706     set(GMX_SOFTWARE_INVSQRT OFF CACHE BOOL "Do not use software reciprocal square root on BlueGene" FORCE)
 707     set(GMX_POWERPC_INVSQRT ON CACHE BOOL "Use hardware reciprocal square root on BlueGene" FORCE)
 708     set(GMX_X11 OFF CACHE BOOL "X11 not compatible with BlueGene, disabled!" FORCE)
 709     set(GMX_THREAD_MPI OFF CACHE BOOL "Thread-MPI not compatible with BlueGene, disabled!" FORCE)
 710     set(GMX_MPI ON CACHE BOOL "Use MPI on BlueGene" FORCE)
 711 # Access to /etc/passwd is not available on the back end of BlueGene,
 712 # despite being detected by CMake. This can cause linker warnings
 713 # about harmless things in src/gmxlib/string2.h.
 714     set(HAVE_PWD_H OFF)
 715 # The automatic testing for endianness does not work for the BlueGene cross-compiler
 716     set(GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER 1 CACHE INTERNAL "BlueGene has big endian FP byte order (by default)" FORCE)
 717     set(GMX_IEEE754_BIG_ENDIAN_WORD_ORDER 1 CACHE INTERNAL "BlueGene has big endian FP word order (by default)" FORCE)
 718 elseif(${GMX_ACCELERATION} STREQUAL "POWER6")
 719     set(GMX_POWER6 1)
 720     set(GMX_SOFTWARE_INVSQRT OFF CACHE BOOL "Do not use software reciprocal square root on Power6" FORCE)
 721     set(GMX_POWERPC_INVSQRT ON CACHE BOOL "Use hardware reciprocal square root on Power6" FORCE)
 722 else(${GMX_ACCELERATION} STREQUAL "NONE")
 723     MESSAGE(FATAL_ERROR "Unrecognized option for accelerated kernels: ${GMX_ACCELERATION}. Pick one of None, SSE2, SSE4.1, AVX_128_FMA, AVX_256, Fortran, BlueGene, Power6")
 724 endif(${GMX_ACCELERATION} STREQUAL "NONE")
 725 set(ACCELERATION_QUIETLY TRUE CACHE INTERNAL "")
 726
 727 if(GMX_FORTRAN OR GMX_POWER6)
 728     if (GMX_THREAD_MPI)
 729         message(FATAL_ERROR "FORTRAN/POWER6 is incompatible with thread-MPI and only provides a speed-up on certain IBM compilers. Disable FORTRAN (or threads if you really want to use FORTRAN kernels).")
 730     endif(GMX_THREAD_MPI)
 731     enable_language(Fortran)
 732     include(FortranCInterface)
 733     discover_fortran_mangling(prefix isupper suffix extra_under_score found)
 734     if(extra_under_score)
 735         set(extrasuffix "_")
 736     endif(extra_under_score)
 737     if(prefix)
 738       set(prefix "${prefix} ##")
 739     endif(prefix)
 740     if(suffix)
 741       set(suffix "## ${suffix}")
 742       if(extrasuffix)
 743         set(extrasuffix "${suffix}${extrasuffix}")
 744       endif(extrasuffix)
 745     else(suffix)
 746       if(extrasuffix)
 747         # Don't know if this is needed, but it can't hurt
 748         set(extrasuffix "## ${extrasuffix}")
 749       endif(extrasuffix)
 750     endif(suffix)
 751
 752     if(isupper)
 753         set(F77_FUNCDEF   "${prefix} NAME ${suffix}")
 754         set(F77_FUNCDEF_  "${prefix} NAME ${extrasuffix}")
 755     else(isupper)
 756         set(F77_FUNCDEF   "${prefix} name ${suffix}")
 757         set(F77_FUNCDEF_  "${prefix} name ${extrasuffix}")
 758     endif(isupper)
 759 else(GMX_FORTRAN OR GMX_POWER6)
 760         set(F77_FUNCDEF   "name ## _")
 761         set(F77_FUNCDEF_  "name ## _")
 762 endif(GMX_FORTRAN OR GMX_POWER6)
 763
 764 # Process QM/MM Settings
 765 string(TOUPPER ${GMX_QMMM_PROGRAM} ${GMX_QMMM_PROGRAM})
 766 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 767     set(GMX_QMMM_GAUSSIAN 1)
 768 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 769     set(GMX_QMMM_MOPAC 1)
 770 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 771     set(GMX_QMMM_GAMESS 1)
 772 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 773     set(GMX_QMMM_ORCA 1)
 774 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 775     # nothing to do
 776 else(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 777     MESSAGE(FATAL_ERROR "Invalid QM/MM program option: ${GMX_QMMM_PROGRAM}. Choose one of: Gaussian, Mopac, Gamess, Orca, None")
 778 endif(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 779
 780 # Process FFT library settings - if not OpenMM build
 781 string(TOUPPER ${GMX_FFT_LIBRARY} ${GMX_FFT_LIBRARY})
 782 set(PKG_FFT "")
 783 set(PKG_FFT_LIBS "")
 784 if(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 785     if(GMX_DOUBLE)
 786         find_package(FFTW 3 COMPONENTS fftw)
 787     else(GMX_DOUBLE)
 788         find_package(FFTW 3 COMPONENTS fftwf)
 789     endif(GMX_DOUBLE)
 790     if(NOT FFTW_FOUND)
 791       MESSAGE(FATAL_ERROR "Cannot find FFTW3 (with correct precision - libfftw3f for single precision GROMACS or libfftw3 for double precision GROMACS). Fix it, choose another FFT library, or use the Gromacs built-in fftpack (slower)!")
 792     endif(NOT FFTW_FOUND)
 793     include_directories(${FFTW_INCLUDE_DIRS})
 794     set(FFT_LIBRARIES ${FFTW_LIBRARIES})
 795     set(PKG_FFT "${FFTW_PKG}")
 796
 797     set(GMX_FFT_FFTW3 1)
 798
 799     if (${GMX_ACCELERATION} STREQUAL "SSE" AND NOT FFTW_HAVE_SSE)
 800       message(WARNING "The fftw library found is compiled without SSE support, which makes it slow. Consider recompiling it or contact your admin")
 801     endif (${GMX_ACCELERATION} STREQUAL "SSE" AND NOT FFTW_HAVE_SSE)
 802
 803 elseif(${GMX_FFT_LIBRARY} STREQUAL "MKL")
 804 #    MESSAGE(STATUS "Using external FFT library - Intel MKL")
 805     find_package(MKL REQUIRED)
 806     include_directories(${MKL_INCLUDE_DIR})
 807     set(FFT_LIBRARIES ${MKL_LIBRARIES})
 808     set(PKG_FFT_LIBS ${MKL_LIBRARIES})
 809
 810     set(GMX_FFT_MKL 1)
 811     set(HAVE_MKL 1)
 812
 813 #elseif(${GMX_FFT_LIBRARY} STREQUAL "ACML")
 814 #    MESSAGE(STATUS "Using external FFT library - AMD core math library")
 815 #    set(GMX_FFT_ACML 1)
 816 elseif(${GMX_FFT_LIBRARY} STREQUAL "FFTPACK")
 817     MESSAGE(STATUS "Using internal FFT library - fftpack")
 818     set(GMX_FFT_FFTPACK 1)
 819 else(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 820     MESSAGE(FATAL_ERROR "Invalid FFT library setting: ${GMX_FFT_LIBRARY}. Choose one of: fftw3, mkl, fftpack")
 821 endif(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 822
 823 set(GMX_EXTERNAL_BLAS TRUE CACHE BOOL "Use external BLAS instead of built-in")
 824 set(GMX_EXTERNAL_LAPACK TRUE CACHE BOOL "Use external LAPACK instead of built-in")
 825 # MKL has BLAS/LAPACK routines
 826 if(NOT HAVE_MKL AND NOT ACCELERATE_FRAMEWORK)
 827   if(GMX_EXTERNAL_BLAS)
 828     if (GMX_BLAS_USER)
 829         list(APPEND GMX_EXTRA_LIBRARIES ${GMX_BLAS_USER})
 830     else(GMX_BLAS_USER)
 831         set(BLAS_FIND_QUIETLY ON)
 832         find_package(BLAS)
 833         if (BLAS_FOUND)
 834           list(APPEND GMX_EXTRA_LIBRARIES ${BLAS_LIBRARIES})
 835         else()
 836           MESSAGE(STATUS "Using internal BLAS library")
 837           set(GMX_EXTERNAL_BLAS FALSE CACHE BOOL "Use external BLAS instead of built-in" FORCE)
 838         endif()
 839     endif(GMX_BLAS_USER)
 840   endif(GMX_EXTERNAL_BLAS)
 841   if(GMX_EXTERNAL_LAPACK)
 842     if (GMX_LAPACK_USER)
 843         list(APPEND GMX_EXTRA_LIBRARIES ${GMX_LAPACK_USER})
 844     else(GMX_LAPACK_USER)
 845         set(LAPACK_FIND_QUIETLY ON)
 846         find_package(LAPACK)
 847         if (LAPACK_FOUND)
 848           list(APPEND GMX_EXTRA_LIBRARIES ${LAPACK_LIBRARIES})
 849         else()
 850           MESSAGE(STATUS "Using internal LAPACK library")
 851           set(GMX_EXTERNAL_LAPACK FALSE CACHE BOOL "Use external LAPACK instead of built-in" FORCE)
 852         endif()
 853     endif(GMX_LAPACK_USER)
 854   endif(GMX_EXTERNAL_LAPACK)
 855 endif()
 856 mark_as_advanced(GMX_EXTERNAL_LAPACK)
 857 mark_as_advanced(GMX_EXTERNAL_BLAS)
 858
 859 set(GMX_USE_PLUGINS OFF CACHE INTERNAL "Whether GROMACS will really try to compile support for VMD plugins")
 860
 861 if(GMX_LOAD_PLUGINS)
 862   if(CYGWIN OR NOT WIN32)
 863     # Native Windows does not have, nor need dlopen
 864     # Note that WIN32 is set with Cygwin, but Cygwin needs dlopen to use plug-ins
 865     include(gmxTestdlopen)
 866     gmx_test_dlopen(HAVE_DLOPEN)
 867   endif()
 868
 869   # so, should we use plug-ins?
 870   if((WIN32 AND NOT CYGWIN) OR (HAVE_DLOPEN AND BUILD_SHARED_LIBS))
 871     if(NOT VMD_QUIETLY)
 872       MESSAGE(STATUS
 873           "Found the ability to use plug-ins when building shared libaries, "
 874           "so will compile to use plug-ins (e.g. to read VMD-supported file "
 875           "formats).")
 876     endif()
 877     if(NOT GMX_VMD_PLUGIN_PATH)
 878       find_package(VMD)
 879     endif()
 880     set(GMX_USE_PLUGINS ON)
 881     list(APPEND GMX_EXTRA_LIBRARIES ${CMAKE_DL_LIBS}) # magic cross-platform pre-set variable for dlopen library
 882     set(PKG_DL_LIBS "-l${CMAKE_DL_LIBS}")
 883   else()
 884     set(PKG_DL_LIBS)
 885   endif()
 886 endif(GMX_LOAD_PLUGINS)
 887 set(VMD_QUIETLY TRUE CACHE INTERNAL "")
 888
 889 if(EXISTS "${CMAKE_SOURCE_DIR}/admin/.isreposource")
 890     if(NOT CMAKE_CROSSCOMPILING)
 891         option(GMX_BUILD_MANPAGES "Build man pages" ON)
 892     else()
 893         message(STATUS "Building the man pages is not available when "
 894             "cross-compiling the developer version from git")
 895     endif()
 896 else()
 897     #make sure source package contains all man pages
 898     if(NOT EXISTS "${CMAKE_SOURCE_DIR}/man/man1/ngmx.1")
 899         message(FATAL_ERROR "Man pages are missing from source package.")
 900     endif()
 901 endif()
 902 mark_as_advanced(GMX_BUILD_MANPAGES)
 903
 904 # Math and thread libraries must often come after all others when linking...
 905 if(HAVE_LIBM)
 906     list(APPEND GMX_EXTRA_LIBRARIES m)
 907 endif(HAVE_LIBM)
 908
 909 if(GMX_FAHCORE)
 910   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 911       "Path to swindirect.h")
 912   include_directories(${COREWRAP_INCLUDE_DIR})
 913 endif(GMX_FAHCORE)
 914
 915 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 916 # these are set after everything else
 917 if (NOT DEFINED GROMACS_C_FLAGS_SET)
 918     set(GROMACS_C_FLAGS_SET true CACHE INTERNAL "Whether to reset the C flags"
 919         FORCE)
 920     set(CMAKE_C_FLAGS "${GROMACS_C_FLAGS} ${CMAKE_C_FLAGS}" CACHE STRING
 921         "Flags used by the compiler during all build types" FORCE)
 922     set(CMAKE_CXX_FLAGS "${GROMACS_CXX_FLAGS} ${CMAKE_CXX_FLAGS}" CACHE STRING
 923         "Flags used by the compiler during all build types" FORCE)
 924     set(CMAKE_EXE_LINKER_FLAGS
 925         "${GROMACS_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}"
 926         CACHE STRING "Linker flags" FORCE)
 927 endif (NOT DEFINED GROMACS_C_FLAGS_SET)
 928
 929 ######################################
 930 # Output compiler and CFLAGS used
 931 ######################################
 932 execute_process(COMMAND ${CMAKE_C_COMPILER} --version RESULT_VARIABLE TMP_RESULT OUTPUT_VARIABLE CC_VERSION ERROR_VARIABLE CC_VERSION)
 933 #try executing just the compiler command if that failed...
 934 if(TMP_RESULT)
 935     execute_process(COMMAND ${CMAKE_C_COMPILER} RESULT_VARIABLE TMP_RESULT OUTPUT_VARIABLE CC_VERSION ERROR_VARIABLE CC_VERSION)
 936 endif()
 937 string(LENGTH "${CC_VERSION}" len)
 938 if(len)
 939     string(REGEX MATCH "[^\n]*" CC_VERSION "${CC_VERSION}")
 940 endif()
 941
 942 set(BUILD_COMPILER "@CMAKE_C_COMPILER@ @CMAKE_C_COMPILER_ID@ @CC_VERSION@")
 943 set(BUILD_CFLAGS "@CMAKE_C_FLAGS@")
 944 if(CMAKE_BUILD_TYPE STREQUAL "Debug")
 945     set(BUILD_CFLAGS "@BUILD_CFLAGS@ @CMAKE_C_FLAGS_DEBUG@")
 946 elseif(CMAKE_BUILD_TYPE STREQUAL "Release")
 947     set(BUILD_CFLAGS "@BUILD_CFLAGS@ @CMAKE_C_FLAGS_RELEASE@")
 948 elseif(CMAKE_BUILD_TYPE STREQUAL "MinSizeRel")
 949     set(BUILD_CFLAGS "@BUILD_CFLAGS@ @CMAKE_C_FLAGS_MINSIZEREL@")
 950 elseif(CMAKE_BUILD_TYPE STREQUAL "RelWithDebInfo")
 951     set(BUILD_CFLAGS "@BUILD_CFLAGS@ @CMAKE_C_FLAGS_RELWITHDEBINFO@")
 952 endif()
 953
 954
 955 ########################################################################
 956 # Specify install locations and which subdirectories to process        #
 957 ########################################################################
 958 if (GMX_USE_RELATIVE_INSTALL_PATH)
 959     set(GMX_INSTALL_PREFIX "" CACHE STRING "Prefix gets appended to CMAKE_INSTALL_PREFIX. For cpack it sets the root folder of the archive.")
 960     mark_as_advanced(GMX_INSTALL_PREFIX)
 961 else()
 962     set(GMX_INSTALL_PREFIX "${CMAKE_INSTALL_PREFIX}/")
 963 endif()
 964
 965 if ( NOT DEFINED GMXLIB )
 966     set(GMXLIB lib)
 967 endif()
 968 set(LIB_INSTALL_DIR "${GMX_INSTALL_PREFIX}${GMXLIB}")
 969 set(BIN_INSTALL_DIR  ${GMX_INSTALL_PREFIX}bin)
 970 set(DATA_INSTALL_DIR ${GMX_INSTALL_PREFIX}share/gromacs)
 971 set(MAN_INSTALL_DIR  ${GMX_INSTALL_PREFIX}share/man)
 972 set(INCL_INSTALL_DIR ${GMX_INSTALL_PREFIX}include)
 973
 974 set(GMXLIBDIR        ${DATA_INSTALL_DIR}/top)
 975
 976 ##################################################################
 977 # Shared library settings - Darwin uses INSTALL_NAME_DIR instead!
 978 ##################################################################
 979 if(NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin")
 980     set(CMAKE_SKIP_BUILD_RPATH  FALSE)
 981     set(CMAKE_BUILD_WITH_INSTALL_RPATH FALSE)
 982     set(CMAKE_INSTALL_RPATH "\\\$ORIGIN/../${GMXLIB}")
 983     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 984 endif()
 985
 986 add_subdirectory(share)
 987 add_subdirectory(include)
 988 add_subdirectory(src)
 989 add_subdirectory(scripts)
 990
 991 #######################
 992 ## uninstall target
 993 #######################
 994     CONFIGURE_FILE(
 995                    "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 996                    "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
 997                    IMMEDIATE @ONLY)
 998 ###########################
 999 ADD_CUSTOM_TARGET(uninstall
1000                   "${CMAKE_COMMAND}" -P
1001                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
1002 ###########################
1003
1004
1005 ########################################################################
1006 # Tests                                                                #
1007 ########################################################################
1008
1009 include(CTest)
1010 mark_as_advanced(BUILD_TESTING)
1011 IF(BUILD_TESTING)
1012         enable_testing()
1013         add_subdirectory(tests)
1014 ENDIF()
1015