CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.6)
   2
   3 project(Gromacs)
   4 include(Dart)
   5 mark_as_advanced(DART_ROOT)
   6
   7 # PROJECT_VERSION should have the following structure:
   8 # VERSION-dev[-SUFFIX] where the VERSION should have the for: vMajor.vMinor.vPatch
   9 #
  10 # The "-dev" suffix is important to keep because it makes possible to distinguish
  11 # between a build from official release and a build from git release branch on a
  12 # machine with no git.
  13 #
  14 # NOTE: when releasing the "-dev" suffix needs to be stripped off!
  15 set(PROJECT_VERSION "4.5.5-dev")
  16 set(CUSTOM_VERSION_STRING ""
  17     CACHE STRING "Custom version string (if empty, use hard-coded default)")
  18 mark_as_advanced(CUSTOM_VERSION_STRING)
  19 if (CUSTOM_VERSION_STRING)
  20     set(PROJECT_VERSION ${CUSTOM_VERSION_STRING})
  21 endif (CUSTOM_VERSION_STRING)
  22 set(SOVERSION 6)
  23 # It is a bit irritating, but this has to be set separately for now!
  24 SET(CPACK_PACKAGE_VERSION_MAJOR "4")
  25 SET(CPACK_PACKAGE_VERSION_MINOR "5")
  26 SET(CPACK_PACKAGE_VERSION_PATCH "5")
  27
  28
  29 # Cmake modules/macros are in a subdirectory to keep this file cleaner
  30 set(CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake)
  31
  32 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
  33 set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
  34 endif()
  35
  36 if(NOT CMAKE_BUILD_TYPE)
  37     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel." FORCE)
  38 endif(NOT CMAKE_BUILD_TYPE)
  39
  40 enable_language(C)
  41
  42 set(CPACK_PACKAGE_VERSION ${PROJECT_VERSION})
  43 set(CPACK_PACKAGE_VENDOR "gromacs.org")
  44 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Gromacs - a toolkit for high-performance molecular simulation")
  45 set(CPACK_SET_DESTDIR "ON")
  46 set(CPACK_INCLUDE_TOPLEVEL_DIRECTORY 0)
  47 set(CPACK_RESOURCE_FILE_WELCOME "${CMAKE_SOURCE_DIR}/admin/InstallWelcome.txt")
  48 # Its GPL/LGPL, so they do not have to agree to a license for mere usage, but some installers require this...
  49 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_SOURCE_DIR}/admin/InstallLicense.txt")
  50 set(CPACK_RESOURCE_FILE_README "${CMAKE_SOURCE_DIR}/admin/InstallInfo.txt")
  51
  52 #must come after all cpack settings!
  53 include(CPack)
  54
  55 ########################################################################
  56 # Check and warn if cache generated on a different host is being reused
  57 ########################################################################
  58 if(CMAKE_HOST_UNIX)
  59     execute_process(COMMAND hostname
  60                     OUTPUT_VARIABLE TMP_HOSTNAME
  61                     OUTPUT_STRIP_TRAILING_WHITESPACE)
  62     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}")
  63         message(WARNING "
  64             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
  65             is being reused! This could lead to inconsitencies; therefore, it is
  66             recommended to regenerate the cache!")
  67     endif()
  68     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
  69             "Hostname of the machine where the cache was generated.")
  70 endif()
  71
  72 ########################################################################
  73 # Fix stupid flags on MSVC
  74 ########################################################################
  75 SET(SHARED_LIBS_DEFAULT ON)
  76 IF(CMAKE_GENERATOR MATCHES "Visual Studio")
  77     STRING(REPLACE /MD /MT CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE})
  78     SET(CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE} CACHE STRING "" FORCE)
  79     STRING(REPLACE /MD /MT CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG})
  80     SET(CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG} CACHE STRING "" FORCE)
  81     SET(SHARED_LIBS_DEFAULT OFF)
  82 ENDIF(CMAKE_GENERATOR MATCHES "Visual Studio")
  83
  84 set(GMX_EXTRA_LIBRARIES)
  85
  86
  87
  88 ######################################################################
  89 # compiler tests
  90 # these need ot be done early (before further tests).
  91 #####################################################################
  92
  93 include(CheckCCompilerFlag)
  94 include(CheckCXXCompilerFlag)
  95
  96 include(gmxCFlags)
  97 gmx_c_flags()
  98
  99 ########################################################################
 100 # User input options                                                   #
 101 ########################################################################
 102 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" OFF)
 103 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 104 option(GMX_THREADS    "Build a parallel (thread-based) version of GROMACS (cannot be combined with MPI yet)" ON)
 105 option(GMX_SOFTWARE_INVSQRT "Use GROMACS software 1/sqrt" ON)
 106 mark_as_advanced(GMX_SOFTWARE_INVSQRT)
 107 option(GMX_POWERPC_INVSQRT "Use PowerPC hardware 1/sqrt" OFF)
 108 mark_as_advanced(GMX_POWERPC_INVSQRT)
 109 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 110 mark_as_advanced(GMX_FAHCORE)
 111 option(GMX_OPENMM "Accelerated execution on GPUs through the OpenMM library (rerun cmake after changing to see relevant options)" OFF)
 112 set(GMX_ACCELERATION "auto"
 113     CACHE STRING "Accelerated kernels. Pick one of: auto, none, SSE, BlueGene, Power6, ia64, altivec, fortran")
 114
 115 set(GMX_FFT_LIBRARY "fftw3"
 116     CACHE STRING "FFT library choices: fftw3,fftw2,mkl,fftpack[built-in]")
 117 option(GMX_DISABLE_FFTW_MEASURE
 118        "Do not optimize FFTW setups (not needed with SSE)" OFF)
 119 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 120 set(GMX_QMMM_PROGRAM "none"
 121     CACHE STRING "QM package choices: none,gaussian,mopac,gamess,orca")
 122 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 123 mark_as_advanced(GMX_BROKEN_CALLOC)
 124 option(BUILD_SHARED_LIBS "Enable shared libraries (can be problematic with MPI, Windows)" ${SHARED_LIBS_DEFAULT})
 125 option(GMX_MPI_IN_PLACE "Enable MPI_IN_PLACE for MPIs that have it defined" ON)
 126 mark_as_advanced(GMX_MPI_IN_PLACE)
 127 option(GMX_DLOPEN "Compile with dlopen, needed to read VMD supported file formats" ON)
 128 mark_as_advanced(GMX_DLOPEN)
 129
 130
 131 option(GMX_IA32_ASM "Add SSE assembly files for IA32" OFF)
 132 mark_as_advanced(GMX_IA32_ASM)
 133 option(GMX_X86_64_ASM "Add SSE assembly files for X86_64" OFF)
 134 mark_as_advanced(GMX_X86_64_ASM)
 135
 136 option(USE_VERSION_H "Generate development version string/information" ON)
 137 mark_as_advanced(USE_VERSION_H)
 138
 139 option(GMX_DEFAULT_SUFFIX "Use default suffixes for GROMACS binaries and libs (_d for double, _mpi for MPI; rerun cmake after changing to see relevant options)" ON)
 140
 141 if(UNIX AND NOT APPLE)
 142     option(GMX_PREFER_STATIC_LIBS "When finding libraries prefer \".a\" static archives (NOTE: this is enabled only for UNIX (excluding APPLE) platforms but it might not always work!" OFF)
 143     mark_as_advanced(GMX_PREFER_STATIC_LIBS)
 144 endif()
 145
 146 ########################################################################
 147 # Set up binary and library suffixing
 148 ########################################################################
 149 set(GMX_BINARY_SUFFIX "" CACHE STRING "Suffix for GROMACS binaries (default: _d for double, _mpi for MPI, _mpi_d for MPI and double).")
 150 set(GMX_LIBS_SUFFIX ""
 151   CACHE STRING "Suffix for GROMACS libs (default: _d for double, _mpi for MPI, _mpi_d for MPI and double).")
 152 if (GMX_DEFAULT_SUFFIX)
 153   set(GMX_BINARY_SUFFIX "")
 154   set(GMX_LIBS_SUFFIX "")
 155   if (GMX_MPI)
 156     set(GMX_BINARY_SUFFIX "_mpi")
 157     set(GMX_LIBS_SUFFIX "_mpi")
 158   endif(GMX_MPI)
 159   if (GMX_DOUBLE)
 160     set (GMX_BINARY_SUFFIX "${GMX_BINARY_SUFFIX}_d")
 161     set (GMX_LIBS_SUFFIX "${GMX_LIBS_SUFFIX}_d")
 162   endif(GMX_DOUBLE)
 163   if (GMX_OPENMM)
 164     set (GMX_BINARY_SUFFIX "-gpu")
 165     set (GMX_LIBS_SUFFIX "_gpu")
 166   endif(GMX_OPENMM)
 167   mark_as_advanced(FORCE GMX_BINARY_SUFFIX GMX_LIBS_SUFFIX)
 168   message(STATUS "Using default binary suffix: \"${GMX_BINARY_SUFFIX}\"")
 169   message(STATUS "Using default library suffix: \"${GMX_LIBS_SUFFIX}\"")
 170 else(GMX_DEFAULT_SUFFIX)
 171   mark_as_advanced(CLEAR GMX_BINARY_SUFFIX GMX_LIBS_SUFFIX)
 172   message(STATUS "Using manually set binary suffix: \"${GMX_BINARY_SUFFIX}\"")
 173   message(STATUS "Using manually set library suffix: \"${GMX_LIBS_SUFFIX}\"")
 174 endif(GMX_DEFAULT_SUFFIX)
 175
 176 set(PKG_CFLAGS "")
 177 if(GMX_DOUBLE)
 178     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_DOUBLE")
 179 endif(GMX_DOUBLE)
 180 if(GMX_SOFTWARE_INVSQRT)
 181   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_SOFTWARE_INVSQRT")
 182 endif(GMX_SOFTWARE_INVSQRT)
 183 if(GMX_POWERPC_INVSQRT)
 184   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_POWERPC_INVSQRT")
 185 endif(GMX_POWERPC_INVSQRT)
 186
 187 ########################################################################
 188 #Process MPI settings
 189 ########################################################################
 190 include(CheckCSourceCompiles) # for gmxTestMPI_IN_PLACE
 191 if(GMX_MPI)
 192     if(GMX_THREADS)
 193         #message(FATAL_ERROR "Thread-based parallelization conflicts with MPI.")
 194         set(GMX_THREADS OFF CACHE BOOL
 195             "Thread-based parallelization conflicts with MPI." FORCE)
 196     endif(GMX_THREADS)
 197     find_package(MPI)
 198     if(MPI_FOUND)
 199         set(GROMACS_C_FLAGS ${GROMACS_FLAGS} ${MPI_COMPILE_FLAGS})
 200         set(GROMACS_LINKER_FLAGS ${GROMACS_LINKER_FLAGS} ${MPI_LINK_FLAGS})
 201
 202         include_directories(${MPI_INCLUDE_PATH})
 203         list(APPEND GMX_EXTRA_LIBRARIES ${MPI_LIBRARIES})
 204         add_definitions( -DMPI ) #for FAHCORE
 205         include(gmxTestMPI_IN_PLACE)
 206         if (GMX_MPI_IN_PLACE)
 207             gmx_test_mpi_in_place(MPI_IN_PLACE_EXISTS)
 208         endif (GMX_MPI_IN_PLACE)
 209
 210         # test for unsuitable versions of OpenMPI
 211         exec_program(${MPIEXEC}
 212           ARGS --version
 213           OUTPUT_VARIABLE MPI_TYPE
 214           RETURN_VALUE MPI_EXEC_RETURN)
 215         if(MPI_EXEC_RETURN EQUAL 0)
 216           if(MPI_TYPE MATCHES "Open MPI|OpenRTE")
 217             string(REGEX MATCH "[0-9]+\\.[0-9]*\\.?[0-9]*" MPI_VERSION ${MPI_TYPE})
 218             if(MPI_VERSION VERSION_LESS "1.4.1")
 219               MESSAGE(WARNING "
 220             There are known problems with OpenMPI version < 1.4.1.
 221             Please consider updating your OpenMPI.")
 222             endif(MPI_VERSION VERSION_LESS "1.4.1")
 223             unset(MPI_VERSION)
 224           else(MPI_TYPE MATCHES "Open MPI|OpenRTE")
 225             # This is not OpenMPI, so give the old generic warning message
 226             MESSAGE(WARNING "
 227             There are known problems with some MPI implementations:
 228                      MVAPICH2 version <= 1.4.1
 229             Please consider updating your MPI if applicable.")
 230           endif(MPI_TYPE MATCHES "Open MPI|OpenRTE")
 231           unset(MPI_TYPE)
 232         endif(MPI_EXEC_RETURN EQUAL 0)
 233     else(MPI_FOUND)
 234         message(FATAL_ERROR "MPI support requested, but no MPI compiler found.")
 235     endif(MPI_FOUND)
 236     include(gmxTestCatamount)
 237     gmx_test_catamount(GMX_CRAY_XT3)
 238     if(GMX_CRAY_XT3)
 239         set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_CRAY_XT3")
 240         set(GMX_NO_SYSTEM 1)
 241         set(GMX_NO_NICE 1)
 242     endif(GMX_CRAY_XT3)
 243     set(GMX_LIB_MPI 1)
 244     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_LIB_MPI")
 245 endif(GMX_MPI)
 246
 247
 248 #######################################################################
 249 # Check for options incompatible with OpenMM build                    #
 250 #######################################################################
 251 if(GMX_OPENMM)
 252     cmake_minimum_required(VERSION 2.6.4)
 253     # we'll use the built-in fft to avoid unnecessary dependencies
 254     string(TOUPPER ${GMX_FFT_LIBRARY} GMX_FFT_LIBRARY)
 255     if(NOT ${GMX_FFT_LIBRARY} STREQUAL "FFTPACK")
 256         message(STATUS "No external FFT libraries needed for the OpenMM build, switching to fftpack!")
 257         set(GMX_FFT_LIBRARY "fftpack" CACHE STRING
 258                 "No external FFT libraries needed for the OpenMM build, switching to  fftpack!" FORCE)
 259     endif()
 260     if(GMX_MPI)
 261         message(FATAL_ERROR "The OpenMM build is not compatible with MPI!")
 262     endif(GMX_MPI)
 263     if(GMX_THREADS)
 264         message(STATUS "Threads are  not compatible with OpenMM build, disabled!")
 265         set(GMX_THREADS OFF CACHE BOOL
 266                 "Threads are not compatible with OpenMM build, disabled!" FORCE)
 267     endif(GMX_THREADS)
 268     if(GMX_SOFTWARE_INVSQRT)
 269         set(GMX_SOFTWARE_INVSQRT OFF CACHE STRING
 270                 "The OpenMM build does not need GROMACS software 1/sqrt!" FORCE)
 271     endif(GMX_SOFTWARE_INVSQRT)
 272     string(TOUPPER ${GMX_ACCELERATION} GMX_ACCELERATION)
 273     if(NOT GMX_ACCELERATION STREQUAL "NONE")
 274         message(STATUS "Switching off CPU-based acceleration, the OpenMM build does not support/need any!")
 275         set(GMX_ACCELERATION "none" CACHE STRING
 276                 "Switching off CPU-based acceleration, the OpenMM build does not support/need any!" FORCE)
 277     endif()
 278     if(GMX_FAHCORE)
 279         message(FATAL_ERROR "The OpenMM build does not support FAH build!")
 280     endif(GMX_FAHCORE)
 281     if(GMX_DOUBLE)
 282         message(FATAL_ERROR  "The OpenMM-build does not support double precision calculations!")
 283     endif()
 284     # mark as advanced the unused variables
 285     mark_as_advanced(FORCE GMX_ACCELERATION GMX_MPI GMX_FFT_LIBRARY
 286         GMX_QMMM_PROGRAM GMX_THREADS GMX_DOUBLE)
 287 else(GMX_OPENMM)
 288      mark_as_advanced(CLEAR GMX_ACCELERATION GMX_MPI GMX_FFT_LIBRARY
 289         GMX_QMMM_PROGRAM GMX_THREADS GMX_DOUBLE)
 290 endif(GMX_OPENMM)
 291
 292
 293 ########################################################################
 294 # Basic system tests (standard libraries, headers, functions, types)   #
 295 ########################################################################
 296 include(CheckIncludeFiles)
 297 check_include_files(string.h     HAVE_STRING_H)
 298 check_include_files(math.h       HAVE_MATH_H)
 299 check_include_files(limits.h     HAVE_LIMITS_H)
 300 check_include_files(memory.h     HAVE_MEMORY_H)
 301 check_include_files(unistd.h     HAVE_UNISTD_H)
 302 check_include_files(direct.h     HAVE_DIRECT_H)
 303 check_include_files(pwd.h        HAVE_PWD_H)
 304 check_include_files(stdint.h     HAVE_STDINT_H)
 305 check_include_files(stdlib.h     HAVE_STDLIB_H)
 306 check_include_files(pthread.h    HAVE_PTHREAD_H)
 307 check_include_files(dirent.h     HAVE_DIRENT_H)
 308 check_include_files(inttypes.h   HAVE_INTTYPES_H)
 309 check_include_files(regex.h      HAVE_REGEX_H)
 310 check_include_files(sys/types.h  HAVE_SYS_TYPES_H)
 311 check_include_files(sys/stat.h   HAVE_SYS_STAT_H)
 312 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 313 check_include_files(rpc/rpc.h    HAVE_RPC_RPC_H)
 314 check_include_files("rpc/rpc.h;rpc/xdr.h"    HAVE_RPC_XDR_H)
 315 # SSE support
 316 check_include_files(xmmintrin.h  HAVE_XMMINTRIN_H)
 317 check_include_files(emmintrin.h  HAVE_EMMINTRIN_H)
 318 check_include_files(pmmintrin.h  HAVE_PMMINTRIN_H)
 319 check_include_files(smmintrin.h  HAVE_SMMINTRIN_H)
 320 check_include_files(io.h                 HAVE_IO_H)
 321
 322
 323 include(CheckFunctionExists)
 324 check_function_exists(strcasecmp        HAVE_STRCASECMP)
 325 check_function_exists(strdup            HAVE_STRDUP)
 326 check_function_exists(vprintf           HAVE_VPRINTF)
 327 check_function_exists(memcmp            HAVE_MEMCMP)
 328 check_function_exists(posix_memalign    HAVE_POSIX_MEMALIGN)
 329 check_function_exists(memalign          HAVE_MEMALIGN)
 330 check_function_exists(_aligned_malloc   HAVE__ALIGNED_MALLOC)
 331 check_function_exists(gettimeofday      HAVE_GETTIMEOFDAY)
 332 check_function_exists(isnan             HAVE_ISNAN)
 333 check_function_exists(_isnan            HAVE__ISNAN)
 334 check_function_exists(isfinite          HAVE_ISFINITE)
 335 check_function_exists(_isfinite         HAVE__ISFINITE)
 336 check_function_exists(fsync             HAVE_FSYNC)
 337 check_function_exists(_fileno           HAVE__FILENO)
 338 check_function_exists(fileno            HAVE_FILENO)
 339 check_function_exists(_commit           HAVE__COMMIT)
 340
 341 include(CheckLibraryExists)
 342 check_library_exists(m sqrt "" HAVE_LIBM)
 343 check_library_exists(m cbrt "" HAVE_CBRT)
 344
 345
 346 include(CheckTypeSize)
 347
 348 check_type_size("bool"          SIZEOF_BOOL) # will also set HAVE_BOOL
 349 check_type_size("int"           SIZEOF_INT)
 350 check_type_size("long int"      SIZEOF_LONG_INT)
 351 check_type_size("long long int" SIZEOF_LONG_LONG_INT)
 352 check_type_size("off_t"         SIZEOF_OFF_T)
 353 check_type_size("void *"        SIZEOF_VOIDP)
 354
 355 if (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 356     set(GMX_64_BIT TRUE)
 357 else (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 358     set(GMX_64_BIT FALSE)
 359 endif (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 360
 361 # Check for some basic types that we *need*, so set these to int if they are not present
 362 check_type_size(uid_t uid_t)
 363 if(NOT uid_t)
 364   set(uid_t int)
 365 else(NOT uid_t)
 366   set(uid_t 0)
 367 endif(NOT uid_t)
 368
 369 check_type_size(gid_t gid_t)
 370 if(NOT gid_t)
 371   set(gid_t 1)
 372 else(NOT gid_t)
 373   set(gid_t 0)
 374 endif(NOT gid_t)
 375
 376 check_type_size(size_t size_t)
 377 if(NOT size_t)
 378   set(size_t int)
 379 else(NOT size_t)
 380   set(size_t 0)
 381 endif(NOT size_t)
 382
 383 check_type_size(off_t off_t)
 384 if(NOT off_t)
 385   set(off_t int)
 386 else(NOT off_t)
 387   set(off_t 0)
 388 endif(NOT off_t)
 389
 390 include(TestBigEndian)
 391 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 392
 393
 394
 395
 396 ########################################################################
 397 # Find external packages                                               #
 398 ########################################################################
 399 if(UNIX AND NOT APPLE)
 400     if(GMX_PREFER_STATIC_LIBS)
 401         SET(CMAKE_FIND_LIBRARY_SUFFIXES .a ${CMAKE_FIND_LIBRARY_SUFFIXES})
 402         if(BUILD_SHARED_LIBS)
 403             message(WARNING "Static libraries requested, the GROMACS libraries will also be build static (BUILD_SHARED_LIBS=OFF)")
 404             set(BUILD_SHARED_LIBS OFF CACHE BOOL "Enable shared libraries (can be problematic with MPI, Windows)" FORCE)
 405         endif()
 406     endif()
 407 endif()
 408
 409 option(GMX_XML "Use libxml2 to parse xml files" ON)
 410 if (GMX_XML)
 411   find_package(LibXml2)
 412   set(PKG_XML "")
 413   if(LIBXML2_FOUND)
 414     include_directories(${LIBXML2_INCLUDE_DIR})
 415     set(PKG_XML libxml-2.0)
 416     set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 417     set(HAVE_LIBXML2 1)
 418   endif(LIBXML2_FOUND)
 419 endif(GMX_XML)
 420
 421 option(GMX_GSL "Add support for gsl" OFF)
 422 if (GMX_GSL)
 423   find_package(gsl)
 424   set(PKG_GSL "")
 425   if(GSL_FOUND)
 426     include_directories(${GSL_INCLUDE_DIR})
 427     set(PKG_GSL gsl)
 428     set(HAVE_LIBGSL 1)
 429   endif(GSL_FOUND)
 430 endif (GMX_GSL)
 431
 432 option(GMX_X11 "Use X window system" OFF)
 433 if (GMX_X11)
 434         find_package(X11)
 435         # X11 includes/libraries are only set in the ngmx subdirectory!
 436         if(X11_FOUND)
 437         set(HAVE_X11 1)
 438         endif(X11_FOUND)
 439 endif(GMX_X11)
 440
 441 if(GMX_THREADS)
 442     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_THREADS")
 443     include(ThreadMPI)
 444     set(THREAD_MPI_LIB thread_mpi)
 445     set(GMX_MPI 1)
 446     string(TOUPPER ${GMX_FFT_LIBRARY} ${GMX_FFT_LIBRARY})
 447     if(${GMX_FFT_LIBRARY} STREQUAL "FFTW2")
 448         message(FATAL_ERROR "FFTW2 can't be used with threads. Try fftw3 or mkl.")
 449     endif()
 450 endif(GMX_THREADS)
 451
 452 if(GMX_OPENMM)
 453     set(CUDA_BUILD_EMULATION OFF)
 454     find_package(CUDA 3.1 REQUIRED)
 455     add_definitions(-DGMX_OPENMM)
 456     if(CMAKE_BUILD_TYPE STREQUAL "DEBUG")
 457         set(CUDA_VERBOSE_BUILD ON)
 458     endif()
 459     find_package(OpenMM)
 460 endif(GMX_OPENMM)
 461
 462 if(APPLE)
 463    find_library(ACCELERATE_FRAMEWORK Accelerate)
 464    list(APPEND GMX_EXTRA_LIBRARIES ${ACCELERATE_FRAMEWORK})
 465 endif(APPLE)
 466
 467 if(CYGWIN)
 468     set(GMX_CYGWIN 1)
 469 endif(CYGWIN)
 470
 471 # only bother with finding git and using version.h if the source is a git repo
 472 if(EXISTS "${CMAKE_SOURCE_DIR}/.git")
 473     if(USE_VERSION_H)
 474         # We need at least git v1.5.1 be able to parse git's date output. If not
 475         # fund or the version is too small, we can't generate version information.
 476         find_package(Git 1.5.1)
 477         # this should at some point become VERSION_LESS
 478         if(NOT Git_FOUND OR Git_VERSION STRLESS "1.5.1")
 479             message("No compatible git version found, won't be able to generate proper development version information.")
 480             set(USE_VERSION_H OFF)
 481         endif()
 482     endif()
 483 else()
 484     set(USE_VERSION_H OFF)
 485 endif()
 486
 487 if (GMX_DLOPEN)
 488     list(APPEND GMX_EXTRA_LIBRARIES ${CMAKE_DL_LIBS})
 489     set(PKG_DL_LIBS "-l${CMAKE_DL_LIBS}")
 490 else(GMX_DLOPEN)
 491     set(PKG_DL_LIBS)
 492 endif (GMX_DLOPEN)
 493
 494 ########################################################################
 495 # Generate development version info for cache
 496 ########################################################################
 497 # set(GEN_VERSION_INFO_INTERNAL "ON")
 498 # include(gmxGenerateVersionString)
 499
 500 ########################################################################
 501 # Our own GROMACS tests
 502 ########################################################################
 503
 504 add_definitions( -DHAVE_CONFIG_H )
 505 include_directories(${CMAKE_BINARY_DIR}/src)
 506 include_directories(${CMAKE_SOURCE_DIR}/include)
 507
 508 include(gmxCheckBuildUserTime)
 509 gmx_check_build_user_time(BUILD_TIME BUILD_USER BUILD_MACHINE)
 510
 511 include(gmxTestFloatFormat)
 512 gmx_test_float_format(GMX_FLOAT_FORMAT_IEEE754
 513                       GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER
 514                       GMX_IEEE754_BIG_ENDIAN_WORD_ORDER)
 515
 516 include(gmxTestLargeFiles)
 517 gmx_test_large_files(GMX_LARGEFILES)
 518 check_function_exists(fseeko     HAVE_FSEEKO)
 519
 520 include(gmxTestSignal)
 521 gmx_test_retsigtype(RETSIGTYPE)
 522 gmx_test_sigusr1(HAVE_SIGUSR1)
 523
 524 include(gmxTestInline)
 525 gmx_test_inline(INLINE_KEYWORD)
 526
 527 include(gmxTestRestrict)
 528 gmx_test_inline(RESTRICT_KEYWORD)
 529
 530 include(gmxTestPipes)
 531 gmx_test_pipes(HAVE_PIPES)
 532
 533 include(gmxTestInlineASM)
 534 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 535 gmx_test_inline_asm_msvc_x86(GMX_X86_MSVC_INLINE_ASM)
 536
 537 # turn on SSE if supported with reasonable defaults.
 538 if (${GMX_ACCELERATION} STREQUAL "auto" AND NOT GMX_OPENMM)
 539   if(CMAKE_SYSTEM_PROCESSOR MATCHES "^(i.86|x86|x64|x86_64|AMD64|amd64)")
 540
 541     set(GMX_ACCELERATION "SSE" CACHE STRING "Accelerated kernels. Pick one of: auto, none, SSE, BlueGene, Power6, ia64, altivec, fortran" FORCE)
 542
 543     if (GMX_64_BIT)
 544       set(GMX_X86_64_ASM ON CACHE BOOL "Add SSE assembly files for x86_64" FORCE)
 545     else (GMX_64_BIT)
 546       set(GMX_IA32_ASM ON CACHE BOOL "Add SSE assembly files for i386" FORCE)
 547     endif (GMX_64_BIT)
 548
 549     # Determine the assembler/compiler to use
 550   else()
 551     set(GMX_ACCELERATION "none" CACHE STRING "Accelerated kernels. Pick one of: auto, none, SSE, BlueGene, Power6, ia64, altivec, fortran" FORCE)
 552   endif()
 553 endif (${GMX_ACCELERATION} STREQUAL "auto" AND NOT GMX_OPENMM)
 554
 555 include(gmxTestXDR)
 556 gmx_test_xdr(GMX_SYSTEM_XDR)
 557 if(NOT GMX_SYSTEM_XDR)
 558     set(GMX_INTERNAL_XDR 1)
 559     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_INTERNAL_XDR")
 560 endif(NOT GMX_SYSTEM_XDR)
 561
 562 # Process nonbonded accelerated kernels settings
 563 string(TOUPPER ${GMX_ACCELERATION} ${GMX_ACCELERATION})
 564 if(${GMX_ACCELERATION} STREQUAL "NONE")
 565   # nothing to do
 566 elseif(${GMX_ACCELERATION} STREQUAL "SSE")
 567
 568     if(CMAKE_GENERATOR MATCHES "Visual Studio")
 569       option(GMX_ASM_USEASM-NASM "Use Nasm for assembly instead of compiler (necessary on windows)" ON)
 570     else()
 571       option(GMX_ASM_USEASM-NASM "Use Nasm for assembly instead of compiler (necessary on windows)" OFF)
 572     endif()
 573         mark_as_advanced(GMX_ASM_USEASM-NASM)
 574
 575     if (NOT GMX_64_BIT)
 576         # for 32-bit compiles, we might need to turn on sse
 577         CHECK_C_COMPILER_FLAG("-msse2" XFLAGS_SSE)
 578         if (XFLAGS_SSE)
 579             set(GROMACS_C_FLAGS "-msse2 ${GROMACS_C_FLAGS}")
 580         endif (XFLAGS_SSE)
 581         CHECK_CXX_COMPILER_FLAG("-msse2" XXFLAGS_SSE)
 582         if (XXFLAGS_SSE)
 583             set(GROMACS_CXX_FLAGS "-msse2 ${GROMACS_CXX_FLAGS}")
 584         endif (XXFLAGS_SSE)
 585     endif (NOT GMX_64_BIT)
 586
 587     if(GMX_IA32_ASM)
 588       if(GMX_DOUBLE)
 589         set(GMX_IA32_SSE2 1)
 590       else()
 591        set(GMX_IA32_SSE 1)
 592       endif()
 593     elseif(GMX_X86_64_ASM)
 594       if(GMX_DOUBLE)
 595        set(GMX_X86_64_SSE2 1)
 596       else()
 597         set(GMX_X86_64_SSE 1)
 598       endif()
 599     endif()
 600
 601 #    if(HAVE_PMMINTRIN_H)
 602 #        set(GMX_SSE3 1)
 603 #    endif(HAVE_PMMINTRIN_H)
 604 #    if(HAVE_SMMINTRIN_H)
 605 #        set(GMX_SSE4_1 1)
 606 #    endif(HAVE_SMMINTRIN_H)
 607
 608 elseif(${GMX_ACCELERATION} STREQUAL "FORTRAN")
 609     set(GMX_FORTRAN 1)
 610     #these are switch on by default sometimes
 611     set(GMX_IA32_ASM 0)
 612     set(GMX_GMX_X86_64_ASM 0)
 613 elseif(${GMX_ACCELERATION} STREQUAL "BLUEGENE")
 614 # GMX_ACCELERATION=BlueGene should be set in the Toolchain-BlueGene?-???.cmake file
 615     message(STATUS "Configuring for BlueGene")
 616     set(GMX_BLUEGENE 1)
 617     if (${CMAKE_SYSTEM_NAME} STREQUAL "BlueGeneL")
 618         set(SHARED_LIBS_DEFAULT OFF CACHE BOOL "Shared libraries not compatible with BlueGene/L, disabled!" FORCE)
 619         set(BUILD_SHARED_LIBS OFF CACHE BOOL "Shared libraries not compatible with BlueGene/L, disabled!" FORCE)
 620     endif (${CMAKE_SYSTEM_NAME} STREQUAL "BlueGeneL")
 621     set(GMX_SOFTWARE_INVSQRT OFF CACHE BOOL "Do not use software reciprocal square root on BlueGene" FORCE)
 622     set(GMX_POWERPC_INVSQRT ON CACHE BOOL "Use hardware reciprocal square root on BlueGene" FORCE)
 623     set(GMX_X11 OFF CACHE BOOL "X11 not compatible with BlueGene, disabled!" FORCE)
 624     set(GMX_THREADS OFF CACHE BOOL "Threads not compatible with BlueGene, disabled!" FORCE)
 625     set(GMX_MPI ON CACHE BOOL "Use MPI on BlueGene" FORCE)
 626     set(GMX_EXTERNAL_BLAS TRUE CACHE BOOL "Use MASSV for BLAS on BlueGene" FORCE)
 627     set(GMX_EXTERNAL_LAPACK TRUE CACHE BOOL "Use MASSV for LAPACK on BlueGene" FORCE)
 628     list(APPEND GMX_EXTRA_LIBRARIES massv)
 629 elseif(${GMX_ACCELERATION} STREQUAL "POWER6")
 630     set(GMX_POWER6 1)
 631     set(GMX_SOFTWARE_INVSQRT OFF CACHE BOOL "Do not use software reciprocal square root on Power6" FORCE)
 632     set(GMX_POWERPC_INVSQRT ON CACHE BOOL "Use hardware reciprocal square root on Power6" FORCE)
 633 elseif(${GMX_ACCELERATION} STREQUAL "IA64")
 634     set(GMX_IA64_ASM 1)
 635     set(DISABLE_WATERWATER_NLIST 1)
 636     set(DISABLE_WATER_NLIST 1)
 637 elseif(${GMX_ACCELERATION} STREQUAL "ALTIVEC")
 638     check_include_files(altivec.h HAVE_ALTIVEC_H)
 639     if(HAVE_ALTIVEC_H)
 640         set(GMX_PPC_ALTIVEC 1)
 641     endif(HAVE_ALTIVEC_H)
 642 else(${GMX_ACCELERATION} STREQUAL "NONE")
 643     MESSAGE(FATAL_ERROR "Unrecognized option for accelerated kernels: ${GMX_ACCELERATION}. Pick one of auto, none, SSE, Fortran, BlueGene, Power6, ia64, altivec")
 644 endif(${GMX_ACCELERATION} STREQUAL "NONE")
 645
 646 if(GMX_FORTRAN OR GMX_POWER6)
 647     if (GMX_THREADS)
 648         message(FATAL_ERROR "FORTRAN/POWER6 is incompatible with threads and only provides a speed-up on certain IBM compilers. Disable FORTRAN (or threads if you really want to use FORTRAN kernels).")
 649     endif(GMX_THREADS)
 650     enable_language(Fortran)
 651     include(FortranCInterface)
 652     discover_fortran_mangling(prefix isupper suffix extra_under_score found)
 653     if(extra_under_score)
 654         set(extrasuffix "_")
 655     endif(extra_under_score)
 656     if(prefix)
 657       set(prefix "${prefix} ##")
 658     endif(prefix)
 659     if(suffix)
 660       set(suffix "## ${suffix}")
 661       if(extrasuffix)
 662         set(extrasuffix "${suffix}${extrasuffix}")
 663       endif(extrasuffix)
 664     else(suffix)
 665       if(extrasuffix)
 666         # Don't know if this is needed, but it can't hurt
 667         set(extrasuffix "## ${extrasuffix}")
 668       endif(extrasuffix)
 669     endif(suffix)
 670
 671     if(isupper)
 672         set(F77_FUNCDEF   "${prefix} NAME ${suffix}")
 673         set(F77_FUNCDEF_  "${prefix} NAME ${extrasuffix}")
 674     else(isupper)
 675         set(F77_FUNCDEF   "${prefix} name ${suffix}")
 676         set(F77_FUNCDEF_  "${prefix} name ${extrasuffix}")
 677     endif(isupper)
 678 else(GMX_FORTRAN OR GMX_POWER6)
 679         set(F77_FUNCDEF   "name ## _")
 680         set(F77_FUNCDEF_  "name ## _")
 681 endif(GMX_FORTRAN OR GMX_POWER6)
 682
 683 # Process QM/MM Settings
 684 string(TOUPPER ${GMX_QMMM_PROGRAM} ${GMX_QMMM_PROGRAM})
 685 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 686     set(GMX_QMMM_GAUSSIAN 1)
 687 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 688     set(GMX_QMMM_MOPAC 1)
 689 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 690     set(GMX_QMMM_GAMESS 1)
 691 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 692     set(GMX_QMMM_ORCA 1)
 693 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 694     # nothing to do
 695 else(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 696     MESSAGE(FATAL_ERROR "Invalid QM/MM program option: ${GMX_QMMM_PROGRAM}. Choose one of: Gaussian, Mopac, Gamess, Orca, None")
 697 endif(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 698
 699 # Process FFT library settings - if not OpenMM build
 700 string(TOUPPER ${GMX_FFT_LIBRARY} ${GMX_FFT_LIBRARY})
 701 set(PKG_FFT "")
 702 set(PKG_FFT_LIBS "")
 703 if(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 704 #    MESSAGE(STATUS "Using external FFT library - fftw3")
 705     if(GMX_DOUBLE)
 706         find_package(FFTW3 REQUIRED)
 707                 include_directories(${FFTW3_INCLUDE_DIR})
 708         set(FFT_LIBRARIES ${FFTW3_LIBRARIES})
 709         set(PKG_FFT "fftw3")
 710     else(GMX_DOUBLE)
 711         find_package(FFTW3F REQUIRED)
 712         include_directories(${FFTW3F_INCLUDE_DIR})
 713         set(FFT_LIBRARIES ${FFTW3F_LIBRARIES})
 714         set(PKG_FFT "fftw3f")
 715     endif(GMX_DOUBLE)
 716
 717     if(NOT FFTW3_FOUND AND NOT FFTW3F_FOUND)
 718         MESSAGE(FATAL_ERROR "Cannot find fftw3 (with correct precision). Fix it, choose another FFT library, or use the Gromacs built-in fftpack (slower)!")
 719     endif(NOT FFTW3_FOUND AND NOT FFTW3F_FOUND)
 720
 721     set(GMX_FFT_FFTW3 1)
 722
 723 elseif(${GMX_FFT_LIBRARY} STREQUAL "FFTW2")
 724 #    MESSAGE(STATUS "Using external FFT library - fftw2")
 725     if(GMX_DOUBLE)
 726         find_package(FFTW2 REQUIRED)
 727     else(GMX_DOUBLE)
 728         find_package(FFTW2F REQUIRED)
 729     endif(GMX_DOUBLE)
 730
 731     if(NOT FFTW2_FOUND)
 732            MESSAGE(FATAL_ERROR "Cannot find fftw2 (with correct precision). Fix it, choose another FFT library, or use the Gromacs built-in fftpack (slower)!")
 733     endif(NOT FFTW2_FOUND)
 734     include_directories(${FFTW2_INCLUDE_DIR})
 735     set(FFT_LIBRARIES ${FFTW2_LIBRARIES})
 736     set(PKG_FFT_LIBS ${FFTW2_LIBRARIES})
 737
 738     if("${FFTW2_LIBRARIES}" MATCHES "dfftw")
 739         set(FFTW2_NAME_DFFTW 1)
 740     elseif("${FFTW2_LIBRARIES}" MATCHES "sfftw")
 741         set(FFTW2_NAME_SFFTW 1)
 742     else("${FFTW2_LIBRARIES}" MATCHES "dfftw")
 743         set(FFTW2_NAME_FFTW 1)
 744     endif("${FFTW2_LIBRARIES}" MATCHES "dfftw")
 745
 746     set(GMX_FFT_FFTW2 1)
 747 elseif(${GMX_FFT_LIBRARY} STREQUAL "MKL")
 748 #    MESSAGE(STATUS "Using external FFT library - Intel MKL")
 749     find_package(MKL REQUIRED)
 750     include_directories(${MKL_INCLUDE_DIR})
 751     set(FFT_LIBRARIES ${MKL_LIBRARIES})
 752     set(PKG_FFT_LIBS ${MKL_LIBRARIES})
 753
 754     set(GMX_FFT_MKL 1)
 755     set(HAVE_MKL 1)
 756
 757 #elseif(${GMX_FFT_LIBRARY} STREQUAL "ACML")
 758 #    MESSAGE(STATUS "Using external FFT library - AMD core math library")
 759 #    set(GMX_FFT_ACML 1)
 760 elseif(${GMX_FFT_LIBRARY} STREQUAL "FFTPACK")
 761     MESSAGE(STATUS "Using internal FFT library - fftpack")
 762     set(GMX_FFT_FFTPACK 1)
 763 else(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 764     MESSAGE(FATAL_ERROR "Invalid FFT library setting: ${GMX_FFT_LIBRARY}. Choose one of: fftw3, fftw2, mkl, acml, fftpack")
 765 endif(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 766
 767 # MKL has BLAS/LAPACK routines
 768 if(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 769   set(GMX_EXTERNAL_BLAS TRUE CACHE BOOL "Use external BLAS instead of built-in")
 770   set(GMX_EXTERNAL_LAPACK TRUE CACHE BOOL "Use external LAPACK instead of built-in")
 771 else(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 772   set(GMX_EXTERNAL_BLAS FALSE CACHE BOOL "Use external BLAS instead of built-in")
 773   set(GMX_EXTERNAL_LAPACK FALSE CACHE BOOL "Use external LAPACK instead of built-in")
 774   if(GMX_EXTERNAL_BLAS)
 775     #FindBLAS needs Fortran
 776     enable_language(Fortran)
 777     if (GMX_BLAS_USER)
 778         list(APPEND GMX_EXTRA_LIBRARIES ${GMX_BLAS_USER})
 779     else(GMX_BLAS_USER)
 780         find_package(BLAS REQUIRED)
 781         list(APPEND GMX_EXTRA_LIBRARIES ${BLAS_LIBRARIES})
 782     endif(GMX_BLAS_USER)
 783   endif(GMX_EXTERNAL_BLAS)
 784   if(GMX_EXTERNAL_LAPACK)
 785     #FindLAPACK needs Fortran
 786     enable_language(Fortran)
 787         if (GMX_LAPACK_USER)
 788         list(APPEND GMX_EXTRA_LIBRARIES ${GMX_LAPACK_USER})
 789         else(GMX_LAPACK_USER)
 790         find_package(LAPACK REQUIRED)
 791         list(APPEND GMX_EXTRA_LIBRARIES ${LAPACK_LIBRARIES})
 792     endif(GMX_LAPACK_USER)
 793   endif(GMX_EXTERNAL_LAPACK)
 794 endif(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 795 mark_as_advanced(GMX_EXTERNAL_LAPACK)
 796 mark_as_advanced(GMX_EXTERNAL_BLAS)
 797
 798 # Math and thread libraries must often come after all others when linking...
 799 if(HAVE_LIBM)
 800     list(APPEND GMX_EXTRA_LIBRARIES m)
 801 endif(HAVE_LIBM)
 802
 803 if(GMX_FAHCORE)
 804   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 805       "Path to swindirect.h")
 806   include_directories(${COREWRAP_INCLUDE_DIR})
 807 endif(GMX_FAHCORE)
 808
 809 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 810 # these are set after everything else
 811 if (NOT DEFINED GROMACS_C_FLAGS_SET)
 812     set(GROMACS_C_FLAGS_SET true CACHE INTERNAL "Whether to reset the C flags"
 813         FORCE)
 814     set(CMAKE_C_FLAGS "${GROMACS_C_FLAGS} ${CMAKE_C_FLAGS}" CACHE STRING
 815         "Flags used by the compiler during all build types" FORCE)
 816     set(CMAKE_CXX_FLAGS "${GROMACS_CXX_FLAGS} ${CMAKE_CXX_FLAGS}" CACHE STRING
 817         "Flags used by the compiler during all build types" FORCE)
 818     set(CMAKE_EXE_LINKER_FLAGS
 819         "${GROMACS_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}"
 820         CACHE STRING "Linker flags" FORCE)
 821 endif (NOT DEFINED GROMACS_C_FLAGS_SET)
 822
 823 ########################################################################
 824 # Specify install locations and which subdirectories to process        #
 825 ########################################################################
 826 if ( DEFINED GMXLIB )
 827     set(LIB_INSTALL_DIR "${CMAKE_INSTALL_PREFIX}/${GMXLIB}")
 828 else()
 829     set(LIB_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/lib)
 830 endif()
 831 set(BIN_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/bin)
 832 set(DATA_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/gromacs)
 833 set(MAN_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/share/man)
 834 set(INCL_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/include)
 835
 836 set(GMXLIBDIR        ${DATA_INSTALL_DIR}/top)
 837
 838 ##################################################################
 839 # Shared library settings - Darwin uses INSTALL_NAME_DIR instead!
 840 ##################################################################
 841 if(NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin")
 842     set(CMAKE_SKIP_BUILD_RPATH  FALSE)
 843     set(CMAKE_BUILD_WITH_INSTALL_RPATH FALSE)
 844     set(CMAKE_INSTALL_RPATH "${LIB_INSTALL_DIR}")
 845     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 846 endif()
 847
 848 add_subdirectory(share)
 849 add_subdirectory(include)
 850 add_subdirectory(man)
 851 add_subdirectory(src)
 852 add_subdirectory(scripts)
 853
 854 #######################
 855 ## uninstall target
 856 #######################
 857     CONFIGURE_FILE(
 858                    "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 859                    "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
 860                    IMMEDIATE @ONLY)
 861 ###########################
 862 ADD_CUSTOM_TARGET(uninstall
 863                   "${CMAKE_COMMAND}" -P
 864                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
 865 ###########################
 866
 867
 868 ########################################################################
 869 # Tests                                                                #
 870 ########################################################################
 871
 872 include(CTest)
 873 mark_as_advanced(BUILD_TESTING)
 874 IF(BUILD_TESTING)
 875         enable_testing()
 876         add_test(TestBuildAll make)
 877         add_subdirectory(tests)
 878 ENDIF()
 879