CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.6)
   2 # Keep CMake suitably quiet on Cygwin
   3 set(CMAKE_LEGACY_CYGWIN_WIN32 0) # Remove when CMake >= 2.8.4 is required
   4
   5 project(Gromacs)
   6 include(Dart)
   7 mark_as_advanced(DART_ROOT)
   8
   9 # PROJECT_VERSION should have the following structure:
  10 # VERSION-dev[-SUFFIX] where the VERSION should have the for: vMajor.vMinor.vPatch
  11 #
  12 # The "-dev" suffix is important to keep because it makes possible to distinguish
  13 # between a build from official release and a build from git release branch on a
  14 # machine with no git.
  15 #
  16 # NOTE: when releasing the "-dev" suffix needs to be stripped off!
  17 set(PROJECT_VERSION "4.5.6-dev")
  18 set(CUSTOM_VERSION_STRING ""
  19     CACHE STRING "Custom version string (if empty, use hard-coded default)")
  20 mark_as_advanced(CUSTOM_VERSION_STRING)
  21 if (CUSTOM_VERSION_STRING)
  22     set(PROJECT_VERSION ${CUSTOM_VERSION_STRING})
  23 endif (CUSTOM_VERSION_STRING)
  24 set(SOVERSION 7)
  25 # It is a bit irritating, but this has to be set separately for now!
  26 SET(CPACK_PACKAGE_VERSION_MAJOR "4")
  27 SET(CPACK_PACKAGE_VERSION_MINOR "5")
  28 SET(CPACK_PACKAGE_VERSION_PATCH "6")
  29
  30
  31 # Cmake modules/macros are in a subdirectory to keep this file cleaner
  32 set(CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake)
  33
  34 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
  35 set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
  36 endif()
  37
  38 if(NOT CMAKE_BUILD_TYPE)
  39     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel." FORCE)
  40 endif(NOT CMAKE_BUILD_TYPE)
  41
  42 enable_language(C)
  43
  44 set(CPACK_PACKAGE_VERSION ${PROJECT_VERSION})
  45 set(CPACK_PACKAGE_VENDOR "gromacs.org")
  46 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Gromacs - a toolkit for high-performance molecular simulation")
  47 set(CPACK_SET_DESTDIR "ON")
  48 set(CPACK_INCLUDE_TOPLEVEL_DIRECTORY 0)
  49 set(CPACK_RESOURCE_FILE_WELCOME "${CMAKE_SOURCE_DIR}/admin/InstallWelcome.txt")
  50 # Its GPL/LGPL, so they do not have to agree to a license for mere usage, but some installers require this...
  51 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_SOURCE_DIR}/admin/InstallLicense.txt")
  52 set(CPACK_RESOURCE_FILE_README "${CMAKE_SOURCE_DIR}/admin/InstallInfo.txt")
  53
  54 #must come after all cpack settings!
  55 include(CPack)
  56
  57 ########################################################################
  58 # Check and warn if cache generated on a different host is being reused
  59 ########################################################################
  60 if(CMAKE_HOST_UNIX)
  61     execute_process(COMMAND hostname
  62                     OUTPUT_VARIABLE TMP_HOSTNAME
  63                     OUTPUT_STRIP_TRAILING_WHITESPACE)
  64     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}")
  65         message(WARNING "
  66             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
  67             is being reused! This could lead to inconsitencies; therefore, it is
  68             recommended to regenerate the cache!")
  69     endif()
  70     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
  71             "Hostname of the machine where the cache was generated.")
  72 endif()
  73
  74 ########################################################################
  75 # Fix stupid flags on Windows
  76 ########################################################################
  77 SET(SHARED_LIBS_DEFAULT ON)
  78 IF( MSVC )
  79     STRING(REPLACE /MD /MT CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE})
  80     SET(CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE} CACHE STRING "" FORCE)
  81     STRING(REPLACE /MD /MT CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG})
  82     SET(CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG} CACHE STRING "" FORCE)
  83     SET(SHARED_LIBS_DEFAULT OFF)
  84 ENDIF()
  85
  86 IF( WIN32 AND NOT CYGWIN AND CMAKE_C_COMPILER_ID MATCHES "Intel" )
  87     STRING(REPLACE /GZ /RTC1 CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE})
  88     SET(CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE} CACHE STRING "" FORCE)
  89     STRING(REPLACE /GZ /RTC1 CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG})
  90     SET(CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG} CACHE STRING "" FORCE)
  91     SET(SHARED_LIBS_DEFAULT OFF)
  92 ENDIF()
  93
  94 set(GMX_EXTRA_LIBRARIES)
  95
  96
  97
  98 ######################################################################
  99 # compiler tests
 100 # these need ot be done early (before further tests).
 101 #####################################################################
 102
 103 include(CheckCCompilerFlag)
 104 include(CheckCXXCompilerFlag)
 105
 106 include(gmxCFlags)
 107 gmx_c_flags()
 108
 109 ########################################################################
 110 # User input options                                                   #
 111 ########################################################################
 112 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" OFF)
 113 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 114 option(GMX_THREADS    "Build a parallel (thread-based) version of GROMACS (cannot be combined with MPI yet)" ON)
 115 option(GMX_SOFTWARE_INVSQRT "Use GROMACS software 1/sqrt" ON)
 116 mark_as_advanced(GMX_SOFTWARE_INVSQRT)
 117 option(GMX_POWERPC_INVSQRT "Use PowerPC hardware 1/sqrt" OFF)
 118 mark_as_advanced(GMX_POWERPC_INVSQRT)
 119 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 120 mark_as_advanced(GMX_FAHCORE)
 121 option(GMX_OPENMM "Accelerated execution on GPUs through the OpenMM library (rerun cmake after changing to see relevant options)" OFF)
 122 set(GMX_ACCELERATION "auto"
 123     CACHE STRING "Accelerated kernels. Pick one of: auto, none, SSE, BlueGene, Power6, ia64, altivec, fortran")
 124
 125 set(GMX_FFT_LIBRARY "fftw3"
 126     CACHE STRING "FFT library choices: fftw3,fftw2,mkl,fftpack[built-in]")
 127 option(GMX_DISABLE_FFTW_MEASURE
 128        "Do not optimize FFTW setups (not needed with SSE)" OFF)
 129 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 130 set(GMX_QMMM_PROGRAM "none"
 131     CACHE STRING "QM package choices: none,gaussian,mopac,gamess,orca")
 132 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 133 mark_as_advanced(GMX_BROKEN_CALLOC)
 134 option(BUILD_SHARED_LIBS "Enable shared libraries (can be problematic with MPI, Windows)" ${SHARED_LIBS_DEFAULT})
 135 option(GMX_MPI_IN_PLACE "Enable MPI_IN_PLACE for MPIs that have it defined" ON)
 136 mark_as_advanced(GMX_MPI_IN_PLACE)
 137 option(GMX_DLOPEN "Compile with dlopen, needed to read VMD supported file formats" ON)
 138 mark_as_advanced(GMX_DLOPEN)
 139
 140
 141 option(GMX_IA32_ASM "Add SSE assembly files for IA32" OFF)
 142 mark_as_advanced(GMX_IA32_ASM)
 143 option(GMX_X86_64_ASM "Add SSE assembly files for X86_64" OFF)
 144 mark_as_advanced(GMX_X86_64_ASM)
 145
 146 option(USE_VERSION_H "Generate development version string/information" ON)
 147 mark_as_advanced(USE_VERSION_H)
 148
 149 option(GMX_DEFAULT_SUFFIX "Use default suffixes for GROMACS binaries and libs (_d for double, _mpi for MPI; rerun cmake after changing to see relevant options)" ON)
 150
 151 if(UNIX AND NOT APPLE)
 152     option(GMX_PREFER_STATIC_LIBS "When finding libraries prefer \".a\" static archives (NOTE: this is enabled only for UNIX (excluding APPLE) platforms but it might not always work!" OFF)
 153     mark_as_advanced(GMX_PREFER_STATIC_LIBS)
 154 endif()
 155
 156 ########################################################################
 157 # Set up binary and library suffixing
 158 ########################################################################
 159 set(GMX_BINARY_SUFFIX "" CACHE STRING "Suffix for GROMACS binaries (default: _d for double, _mpi for MPI, _mpi_d for MPI and double).")
 160 set(GMX_LIBS_SUFFIX ""
 161   CACHE STRING "Suffix for GROMACS libs (default: _d for double, _mpi for MPI, _mpi_d for MPI and double).")
 162 if (GMX_DEFAULT_SUFFIX)
 163   set(GMX_BINARY_SUFFIX "")
 164   set(GMX_LIBS_SUFFIX "")
 165   if (GMX_MPI)
 166     set(GMX_BINARY_SUFFIX "_mpi")
 167     set(GMX_LIBS_SUFFIX "_mpi")
 168   endif(GMX_MPI)
 169   if (GMX_DOUBLE)
 170     set (GMX_BINARY_SUFFIX "${GMX_BINARY_SUFFIX}_d")
 171     set (GMX_LIBS_SUFFIX "${GMX_LIBS_SUFFIX}_d")
 172   endif(GMX_DOUBLE)
 173   if (GMX_OPENMM)
 174     set (GMX_BINARY_SUFFIX "-gpu")
 175     set (GMX_LIBS_SUFFIX "_gpu")
 176   endif(GMX_OPENMM)
 177   mark_as_advanced(FORCE GMX_BINARY_SUFFIX GMX_LIBS_SUFFIX)
 178   message(STATUS "Using default binary suffix: \"${GMX_BINARY_SUFFIX}\"")
 179   message(STATUS "Using default library suffix: \"${GMX_LIBS_SUFFIX}\"")
 180 else(GMX_DEFAULT_SUFFIX)
 181   mark_as_advanced(CLEAR GMX_BINARY_SUFFIX GMX_LIBS_SUFFIX)
 182   message(STATUS "Using manually set binary suffix: \"${GMX_BINARY_SUFFIX}\"")
 183   message(STATUS "Using manually set library suffix: \"${GMX_LIBS_SUFFIX}\"")
 184 endif(GMX_DEFAULT_SUFFIX)
 185
 186 set(PKG_CFLAGS "")
 187 if(GMX_DOUBLE)
 188     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_DOUBLE")
 189 endif(GMX_DOUBLE)
 190 if(GMX_SOFTWARE_INVSQRT)
 191   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_SOFTWARE_INVSQRT")
 192 endif(GMX_SOFTWARE_INVSQRT)
 193 if(GMX_POWERPC_INVSQRT)
 194   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_POWERPC_INVSQRT")
 195 endif(GMX_POWERPC_INVSQRT)
 196
 197 ########################################################################
 198 #Process MPI settings
 199 ########################################################################
 200 include(CheckCSourceCompiles) # for gmxTestMPI_IN_PLACE
 201 if(GMX_MPI)
 202     if(GMX_THREADS)
 203         #message(FATAL_ERROR "Thread-based parallelization conflicts with MPI.")
 204         set(GMX_THREADS OFF CACHE BOOL
 205             "Thread-based parallelization conflicts with MPI." FORCE)
 206     endif(GMX_THREADS)
 207     find_package(MPI)
 208     if(MPI_FOUND)
 209         set(GROMACS_C_FLAGS ${GROMACS_FLAGS} ${MPI_COMPILE_FLAGS})
 210         set(GROMACS_LINKER_FLAGS ${GROMACS_LINKER_FLAGS} ${MPI_LINK_FLAGS})
 211
 212         include_directories(${MPI_INCLUDE_PATH})
 213         list(APPEND GMX_EXTRA_LIBRARIES ${MPI_LIBRARIES})
 214         if(GMX_FAHCORE)
 215             add_definitions( -DMPI ) #for FAHCORE
 216         endif(GMX_FAHCORE)
 217         include(gmxTestMPI_IN_PLACE)
 218         if (GMX_MPI_IN_PLACE)
 219             gmx_test_mpi_in_place(MPI_IN_PLACE_EXISTS)
 220         endif (GMX_MPI_IN_PLACE)
 221
 222         # test for unsuitable versions of OpenMPI
 223         exec_program(${MPIEXEC}
 224           ARGS --version
 225           OUTPUT_VARIABLE MPI_TYPE
 226           RETURN_VALUE MPI_EXEC_RETURN)
 227         if(MPI_EXEC_RETURN EQUAL 0)
 228           if(MPI_TYPE MATCHES "Open MPI|OpenRTE")
 229             string(REGEX MATCH "[0-9]+\\.[0-9]*\\.?[0-9]*" MPI_VERSION ${MPI_TYPE})
 230             if(MPI_VERSION VERSION_LESS "1.4.1")
 231               MESSAGE(WARNING "
 232             There are known problems with OpenMPI version < 1.4.1.
 233             Please consider updating your OpenMPI.")
 234             endif(MPI_VERSION VERSION_LESS "1.4.1")
 235             unset(MPI_VERSION)
 236           else(MPI_TYPE MATCHES "Open MPI|OpenRTE")
 237             # This is not OpenMPI, so give the old generic warning message
 238             MESSAGE(WARNING "
 239             There are known problems with some MPI implementations:
 240                      MVAPICH2 version <= 1.4.1
 241             Please consider updating your MPI if applicable.")
 242           endif(MPI_TYPE MATCHES "Open MPI|OpenRTE")
 243           unset(MPI_TYPE)
 244         endif(MPI_EXEC_RETURN EQUAL 0)
 245     else(MPI_FOUND)
 246         message(FATAL_ERROR "MPI support requested, but no MPI compiler found.")
 247     endif(MPI_FOUND)
 248     include(gmxTestCatamount)
 249     gmx_test_catamount(GMX_CRAY_XT3)
 250     if(GMX_CRAY_XT3)
 251         set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_CRAY_XT3")
 252         set(GMX_NO_SYSTEM 1)
 253         set(GMX_NO_NICE 1)
 254     endif(GMX_CRAY_XT3)
 255     set(GMX_LIB_MPI 1)
 256     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_LIB_MPI")
 257 endif(GMX_MPI)
 258
 259
 260 #######################################################################
 261 # Check for options incompatible with OpenMM build                    #
 262 #######################################################################
 263 if(GMX_OPENMM)
 264     cmake_minimum_required(VERSION 2.6.4)
 265     # we'll use the built-in fft to avoid unnecessary dependencies
 266     string(TOUPPER ${GMX_FFT_LIBRARY} GMX_FFT_LIBRARY)
 267     if(NOT ${GMX_FFT_LIBRARY} STREQUAL "FFTPACK")
 268         message(STATUS "No external FFT libraries needed for the OpenMM build, switching to fftpack!")
 269         set(GMX_FFT_LIBRARY "fftpack" CACHE STRING
 270                 "No external FFT libraries needed for the OpenMM build, switching to  fftpack!" FORCE)
 271     endif()
 272     if(GMX_MPI)
 273         message(FATAL_ERROR "The OpenMM build is not compatible with MPI!")
 274     endif(GMX_MPI)
 275     if(GMX_THREADS)
 276         message(STATUS "Threads are  not compatible with OpenMM build, disabled!")
 277         set(GMX_THREADS OFF CACHE BOOL
 278                 "Threads are not compatible with OpenMM build, disabled!" FORCE)
 279     endif(GMX_THREADS)
 280     if(GMX_SOFTWARE_INVSQRT)
 281         set(GMX_SOFTWARE_INVSQRT OFF CACHE STRING
 282                 "The OpenMM build does not need GROMACS software 1/sqrt!" FORCE)
 283     endif(GMX_SOFTWARE_INVSQRT)
 284     string(TOUPPER ${GMX_ACCELERATION} GMX_ACCELERATION)
 285     if(NOT GMX_ACCELERATION STREQUAL "NONE")
 286         message(STATUS "Switching off CPU-based acceleration, the OpenMM build does not support/need any!")
 287         set(GMX_ACCELERATION "none" CACHE STRING
 288                 "Switching off CPU-based acceleration, the OpenMM build does not support/need any!" FORCE)
 289     endif()
 290     if(GMX_FAHCORE)
 291         message(FATAL_ERROR "The OpenMM build does not support FAH build!")
 292     endif(GMX_FAHCORE)
 293     if(GMX_DOUBLE)
 294         message(FATAL_ERROR  "The OpenMM-build does not support double precision calculations!")
 295     endif()
 296     # mark as advanced the unused variables
 297     mark_as_advanced(FORCE GMX_ACCELERATION GMX_MPI GMX_FFT_LIBRARY
 298         GMX_QMMM_PROGRAM GMX_THREADS GMX_DOUBLE)
 299 else(GMX_OPENMM)
 300      mark_as_advanced(CLEAR GMX_ACCELERATION GMX_MPI GMX_FFT_LIBRARY
 301         GMX_QMMM_PROGRAM GMX_THREADS GMX_DOUBLE)
 302 endif(GMX_OPENMM)
 303
 304
 305 ########################################################################
 306 # Basic system tests (standard libraries, headers, functions, types)   #
 307 ########################################################################
 308 include(CheckIncludeFiles)
 309 check_include_files(string.h     HAVE_STRING_H)
 310 check_include_files(math.h       HAVE_MATH_H)
 311 check_include_files(limits.h     HAVE_LIMITS_H)
 312 check_include_files(memory.h     HAVE_MEMORY_H)
 313 check_include_files(unistd.h     HAVE_UNISTD_H)
 314 check_include_files(direct.h     HAVE_DIRECT_H)
 315 check_include_files(pwd.h        HAVE_PWD_H)
 316 check_include_files(stdint.h     HAVE_STDINT_H)
 317 check_include_files(stdlib.h     HAVE_STDLIB_H)
 318 check_include_files(pthread.h    HAVE_PTHREAD_H)
 319 check_include_files(dirent.h     HAVE_DIRENT_H)
 320 check_include_files(inttypes.h   HAVE_INTTYPES_H)
 321 check_include_files(regex.h      HAVE_REGEX_H)
 322 check_include_files(sys/types.h  HAVE_SYS_TYPES_H)
 323 check_include_files(sys/stat.h   HAVE_SYS_STAT_H)
 324 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 325 check_include_files(rpc/rpc.h    HAVE_RPC_RPC_H)
 326 check_include_files("rpc/rpc.h;rpc/xdr.h"    HAVE_RPC_XDR_H)
 327 # SSE support
 328 check_include_files(xmmintrin.h  HAVE_XMMINTRIN_H)
 329 check_include_files(emmintrin.h  HAVE_EMMINTRIN_H)
 330 check_include_files(pmmintrin.h  HAVE_PMMINTRIN_H)
 331 check_include_files(smmintrin.h  HAVE_SMMINTRIN_H)
 332 check_include_files(io.h                 HAVE_IO_H)
 333
 334
 335 include(CheckFunctionExists)
 336 check_function_exists(strcasecmp        HAVE_STRCASECMP)
 337 check_function_exists(strdup            HAVE_STRDUP)
 338 check_function_exists(vprintf           HAVE_VPRINTF)
 339 check_function_exists(memcmp            HAVE_MEMCMP)
 340 check_function_exists(posix_memalign    HAVE_POSIX_MEMALIGN)
 341 check_function_exists(memalign          HAVE_MEMALIGN)
 342 check_function_exists(_aligned_malloc   HAVE__ALIGNED_MALLOC)
 343 check_function_exists(gettimeofday      HAVE_GETTIMEOFDAY)
 344 check_function_exists(isnan             HAVE_ISNAN)
 345 check_function_exists(_isnan            HAVE__ISNAN)
 346 check_function_exists(fsync             HAVE_FSYNC)
 347 check_function_exists(_fileno           HAVE__FILENO)
 348 check_function_exists(fileno            HAVE_FILENO)
 349 check_function_exists(_commit           HAVE__COMMIT)
 350
 351 include(CheckLibraryExists)
 352 check_library_exists(m sqrt "" HAVE_LIBM)
 353 check_library_exists(m cbrt "" HAVE_CBRT)
 354
 355
 356 include(CheckTypeSize)
 357
 358 check_type_size("bool"          SIZEOF_BOOL) # will also set HAVE_BOOL
 359 check_type_size("int"           SIZEOF_INT)
 360 check_type_size("long int"      SIZEOF_LONG_INT)
 361 check_type_size("long long int" SIZEOF_LONG_LONG_INT)
 362 check_type_size("off_t"         SIZEOF_OFF_T)
 363 check_type_size("void *"        SIZEOF_VOIDP)
 364
 365 if (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 366     set(GMX_64_BIT TRUE)
 367 else (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 368     set(GMX_64_BIT FALSE)
 369 endif (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 370
 371 # Check for some basic types that we *need*, so set these to int if they are not present
 372 check_type_size(uid_t uid_t)
 373 if(NOT uid_t)
 374   set(uid_t int)
 375 else(NOT uid_t)
 376   set(uid_t 0)
 377 endif(NOT uid_t)
 378
 379 check_type_size(gid_t gid_t)
 380 if(NOT gid_t)
 381   set(gid_t 1)
 382 else(NOT gid_t)
 383   set(gid_t 0)
 384 endif(NOT gid_t)
 385
 386 check_type_size(size_t size_t)
 387 if(NOT size_t)
 388   set(size_t int)
 389 else(NOT size_t)
 390   set(size_t 0)
 391 endif(NOT size_t)
 392
 393 check_type_size(off_t off_t)
 394 if(NOT off_t)
 395   set(off_t int)
 396 else(NOT off_t)
 397   set(off_t 0)
 398 endif(NOT off_t)
 399
 400 include(TestBigEndian)
 401 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 402
 403
 404
 405
 406 ########################################################################
 407 # Find external packages                                               #
 408 ########################################################################
 409 if(UNIX AND NOT APPLE)
 410     if(GMX_PREFER_STATIC_LIBS)
 411         SET(CMAKE_FIND_LIBRARY_SUFFIXES .a ${CMAKE_FIND_LIBRARY_SUFFIXES})
 412         if(BUILD_SHARED_LIBS)
 413             message(WARNING "Static libraries requested, the GROMACS libraries will also be build static (BUILD_SHARED_LIBS=OFF)")
 414             set(BUILD_SHARED_LIBS OFF CACHE BOOL "Enable shared libraries (can be problematic with MPI, Windows)" FORCE)
 415         endif()
 416     endif()
 417 endif()
 418
 419 option(GMX_XML "Use libxml2 to parse xml files" ON)
 420 if (GMX_XML)
 421   find_package(LibXml2)
 422   set(PKG_XML "")
 423   if(LIBXML2_FOUND)
 424     include_directories(${LIBXML2_INCLUDE_DIR})
 425     set(PKG_XML libxml-2.0)
 426     set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 427     set(HAVE_LIBXML2 1)
 428   endif(LIBXML2_FOUND)
 429 endif(GMX_XML)
 430
 431 option(GMX_GSL "Add support for gsl" OFF)
 432 if (GMX_GSL)
 433   find_package(gsl)
 434   set(PKG_GSL "")
 435   if(GSL_FOUND)
 436     include_directories(${GSL_INCLUDE_DIR})
 437     set(PKG_GSL gsl)
 438     set(HAVE_LIBGSL 1)
 439   endif(GSL_FOUND)
 440 endif (GMX_GSL)
 441
 442 option(GMX_X11 "Use X window system" OFF)
 443 if (GMX_X11)
 444         find_package(X11)
 445         # X11 includes/libraries are only set in the ngmx subdirectory!
 446         if(X11_FOUND)
 447         set(HAVE_X11 1)
 448         endif(X11_FOUND)
 449 endif(GMX_X11)
 450
 451 if(GMX_THREADS)
 452     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_THREADS")
 453     include(ThreadMPI)
 454     set(THREAD_MPI_LIB thread_mpi)
 455     set(GMX_MPI 1)
 456     string(TOUPPER ${GMX_FFT_LIBRARY} ${GMX_FFT_LIBRARY})
 457     if(${GMX_FFT_LIBRARY} STREQUAL "FFTW2")
 458         message(FATAL_ERROR "FFTW2 can't be used with threads. Try fftw3 or mkl.")
 459     endif()
 460 endif(GMX_THREADS)
 461
 462 if(GMX_OPENMM)
 463     set(CUDA_BUILD_EMULATION OFF)
 464     find_package(CUDA 3.1 REQUIRED)
 465     add_definitions(-DGMX_OPENMM)
 466     if(CMAKE_BUILD_TYPE STREQUAL "DEBUG")
 467         set(CUDA_VERBOSE_BUILD ON)
 468     endif()
 469     find_package(OpenMM)
 470 endif(GMX_OPENMM)
 471
 472 if(APPLE)
 473    find_library(ACCELERATE_FRAMEWORK Accelerate)
 474    list(APPEND GMX_EXTRA_LIBRARIES ${ACCELERATE_FRAMEWORK})
 475 endif(APPLE)
 476
 477 if(CYGWIN)
 478     set(GMX_CYGWIN 1)
 479 endif(CYGWIN)
 480
 481 # only bother with finding git and using version.h if the source is a git repo
 482 if(EXISTS "${CMAKE_SOURCE_DIR}/.git")
 483     if(USE_VERSION_H)
 484         # We need at least git v1.5.3 be able to parse git's date output. If not
 485         # fund or the version is too small, we can't generate version information.
 486         find_package(Git 1.5.3)
 487         # this should at some point become VERSION_LESS
 488         if(NOT Git_FOUND OR Git_VERSION STRLESS "1.5.3")
 489             message("No compatible git version found, won't be able to generate proper development version information.")
 490             set(USE_VERSION_H OFF)
 491         endif()
 492     endif()
 493 else()
 494     set(USE_VERSION_H OFF)
 495 endif()
 496
 497 if (GMX_DLOPEN)
 498     list(APPEND GMX_EXTRA_LIBRARIES ${CMAKE_DL_LIBS})
 499     set(PKG_DL_LIBS "-l${CMAKE_DL_LIBS}")
 500 else(GMX_DLOPEN)
 501     set(PKG_DL_LIBS)
 502 endif (GMX_DLOPEN)
 503
 504 ########################################################################
 505 # Generate development version info for cache
 506 ########################################################################
 507 # set(GEN_VERSION_INFO_INTERNAL "ON")
 508 # include(gmxGenerateVersionString)
 509
 510 ########################################################################
 511 # Our own GROMACS tests
 512 ########################################################################
 513
 514 add_definitions( -DHAVE_CONFIG_H )
 515 include_directories(${CMAKE_BINARY_DIR}/src)
 516 include_directories(${CMAKE_SOURCE_DIR}/include)
 517
 518 include(gmxCheckBuildUserTime)
 519 gmx_check_build_user_time(BUILD_TIME BUILD_USER BUILD_MACHINE)
 520
 521 include(gmxTestFloatFormat)
 522 gmx_test_float_format(GMX_FLOAT_FORMAT_IEEE754
 523                       GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER
 524                       GMX_IEEE754_BIG_ENDIAN_WORD_ORDER)
 525
 526 include(gmxTestLargeFiles)
 527 gmx_test_large_files(GMX_LARGEFILES)
 528
 529 include(gmxTestSignal)
 530 gmx_test_retsigtype(RETSIGTYPE)
 531 gmx_test_sigusr1(HAVE_SIGUSR1)
 532
 533 include(gmxTestInline)
 534 gmx_test_inline(INLINE_KEYWORD)
 535
 536 include(gmxTestRestrict)
 537 gmx_test_inline(RESTRICT_KEYWORD)
 538
 539 include(gmxTestPipes)
 540 gmx_test_pipes(HAVE_PIPES)
 541
 542 include(gmxTestIsfinite)
 543 gmx_test_isfinite(HAVE_ISFINITE)
 544 gmx_test__isfinite(HAVE__ISFINITE)
 545 gmx_test__finite(HAVE__FINITE)
 546
 547 include(gmxTestInlineASM)
 548 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 549 gmx_test_inline_asm_msvc_x86(GMX_X86_MSVC_INLINE_ASM)
 550
 551 # turn on SSE if supported with reasonable defaults.
 552 if (${GMX_ACCELERATION} STREQUAL "auto" AND NOT GMX_OPENMM)
 553   if(CMAKE_SYSTEM_PROCESSOR MATCHES "^(i.86|x86|x64|x86_64|AMD64|amd64)" OR CYGWIN)
 554
 555     set(GMX_ACCELERATION "SSE" CACHE STRING "Accelerated kernels. Pick one of: auto, none, SSE, BlueGene, Power6, ia64, altivec, fortran" FORCE)
 556
 557     # Determine the assembler/compiler to use
 558   else()
 559     set(GMX_ACCELERATION "none" CACHE STRING "Accelerated kernels. Pick one of: auto, none, SSE, BlueGene, Power6, ia64, altivec, fortran" FORCE)
 560   endif()
 561 endif (${GMX_ACCELERATION} STREQUAL "auto" AND NOT GMX_OPENMM)
 562
 563 include(gmxTestXDR)
 564 gmx_test_xdr(GMX_SYSTEM_XDR)
 565 if(NOT GMX_SYSTEM_XDR)
 566     set(GMX_INTERNAL_XDR 1)
 567     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_INTERNAL_XDR")
 568 endif(NOT GMX_SYSTEM_XDR)
 569
 570 # Process nonbonded accelerated kernels settings
 571 string(TOUPPER ${GMX_ACCELERATION} ${GMX_ACCELERATION})
 572 if(${GMX_ACCELERATION} STREQUAL "NONE")
 573   # nothing to do
 574 elseif(${GMX_ACCELERATION} STREQUAL "SSE")
 575
 576     if (GMX_64_BIT)
 577       set(GMX_X86_64_ASM ON CACHE BOOL "Add SSE assembly files for x86_64" FORCE)
 578     else (GMX_64_BIT)
 579       set(GMX_IA32_ASM ON CACHE BOOL "Add SSE assembly files for i386" FORCE)
 580     endif (GMX_64_BIT)
 581
 582     if( WIN32 AND NOT CYGWIN )
 583       option(GMX_ASM_USEASM_NASM "Use Nasm for assembly instead of compiler (necessary on windows)" ON)
 584     else()
 585       option(GMX_ASM_USEASM_NASM "Use Nasm for assembly instead of compiler (necessary on windows)" OFF)
 586     endif()
 587         mark_as_advanced(GMX_ASM_USEASM_NASM)
 588
 589     if (NOT GMX_64_BIT)
 590         # for 32-bit compiles, we might need to turn on sse
 591         CHECK_C_COMPILER_FLAG("-msse2" XFLAGS_SSE)
 592         if (XFLAGS_SSE)
 593             set(GROMACS_C_FLAGS "-msse2 ${GROMACS_C_FLAGS}")
 594         endif (XFLAGS_SSE)
 595         CHECK_CXX_COMPILER_FLAG("-msse2" XXFLAGS_SSE)
 596         if (XXFLAGS_SSE)
 597             set(GROMACS_CXX_FLAGS "-msse2 ${GROMACS_CXX_FLAGS}")
 598         endif (XXFLAGS_SSE)
 599     endif (NOT GMX_64_BIT)
 600
 601     if(GMX_IA32_ASM)
 602       if(GMX_DOUBLE)
 603         set(GMX_IA32_SSE2 1)
 604       else()
 605        set(GMX_IA32_SSE 1)
 606       endif()
 607     elseif(GMX_X86_64_ASM)
 608       if(GMX_DOUBLE)
 609        set(GMX_X86_64_SSE2 1)
 610       else()
 611         set(GMX_X86_64_SSE 1)
 612       endif()
 613     endif()
 614
 615 #    if(HAVE_PMMINTRIN_H)
 616 #        set(GMX_SSE3 1)
 617 #    endif(HAVE_PMMINTRIN_H)
 618 #    if(HAVE_SMMINTRIN_H)
 619 #        set(GMX_SSE4_1 1)
 620 #    endif(HAVE_SMMINTRIN_H)
 621
 622 elseif(${GMX_ACCELERATION} STREQUAL "FORTRAN")
 623     set(GMX_FORTRAN 1)
 624     #these are switch on by default sometimes
 625     set(GMX_IA32_ASM 0)
 626     set(GMX_GMX_X86_64_ASM 0)
 627 elseif(${GMX_ACCELERATION} STREQUAL "BLUEGENE")
 628 # GMX_ACCELERATION=BlueGene should be set in the Toolchain-BlueGene?-???.cmake file
 629     message(STATUS "Configuring for BlueGene")
 630     set(GMX_BLUEGENE 1)
 631     if (${CMAKE_SYSTEM_NAME} STREQUAL "BlueGeneL")
 632         set(SHARED_LIBS_DEFAULT OFF CACHE BOOL "Shared libraries not compatible with BlueGene/L, disabled!" FORCE)
 633         set(BUILD_SHARED_LIBS OFF CACHE BOOL "Shared libraries not compatible with BlueGene/L, disabled!" FORCE)
 634     endif (${CMAKE_SYSTEM_NAME} STREQUAL "BlueGeneL")
 635     set(GMX_SOFTWARE_INVSQRT OFF CACHE BOOL "Do not use software reciprocal square root on BlueGene" FORCE)
 636     set(GMX_POWERPC_INVSQRT ON CACHE BOOL "Use hardware reciprocal square root on BlueGene" FORCE)
 637     set(GMX_X11 OFF CACHE BOOL "X11 not compatible with BlueGene, disabled!" FORCE)
 638     set(GMX_THREADS OFF CACHE BOOL "Threads not compatible with BlueGene, disabled!" FORCE)
 639     set(GMX_MPI ON CACHE BOOL "Use MPI on BlueGene" FORCE)
 640 # Access to /etc/passwd is not available on the back end of BlueGene,
 641 # despite being detected by CMake. This can cause linker warnings
 642 # about harmless things in src/gmxlib/string2.h.
 643     set(HAVE_PWD_H OFF)
 644 # The automatic testing for endianness does not work for the BlueGene cross-compiler
 645     set(GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER 1 CACHE INTERNAL "BlueGene has big endian FP byte order (by default)" FORCE)
 646     set(GMX_IEEE754_BIG_ENDIAN_WORD_ORDER 1 CACHE INTERNAL "BlueGene has big endian FP word order (by default)" FORCE)
 647 elseif(${GMX_ACCELERATION} STREQUAL "POWER6")
 648     set(GMX_POWER6 1)
 649     set(GMX_SOFTWARE_INVSQRT OFF CACHE BOOL "Do not use software reciprocal square root on Power6" FORCE)
 650     set(GMX_POWERPC_INVSQRT ON CACHE BOOL "Use hardware reciprocal square root on Power6" FORCE)
 651 elseif(${GMX_ACCELERATION} STREQUAL "IA64")
 652     set(GMX_IA64_ASM 1)
 653     set(DISABLE_WATERWATER_NLIST 1)
 654     set(DISABLE_WATER_NLIST 1)
 655 elseif(${GMX_ACCELERATION} STREQUAL "ALTIVEC")
 656     check_include_files(altivec.h HAVE_ALTIVEC_H)
 657     if(HAVE_ALTIVEC_H)
 658         set(GMX_PPC_ALTIVEC 1)
 659     endif(HAVE_ALTIVEC_H)
 660 else(${GMX_ACCELERATION} STREQUAL "NONE")
 661     MESSAGE(FATAL_ERROR "Unrecognized option for accelerated kernels: ${GMX_ACCELERATION}. Pick one of auto, none, SSE, Fortran, BlueGene, Power6, ia64, altivec")
 662 endif(${GMX_ACCELERATION} STREQUAL "NONE")
 663
 664 if(GMX_FORTRAN OR GMX_POWER6)
 665     if (GMX_THREADS)
 666         message(FATAL_ERROR "FORTRAN/POWER6 is incompatible with threads and only provides a speed-up on certain IBM compilers. Disable FORTRAN (or threads if you really want to use FORTRAN kernels).")
 667     endif(GMX_THREADS)
 668     enable_language(Fortran)
 669     include(FortranCInterface)
 670     discover_fortran_mangling(prefix isupper suffix extra_under_score found)
 671     if(extra_under_score)
 672         set(extrasuffix "_")
 673     endif(extra_under_score)
 674     if(prefix)
 675       set(prefix "${prefix} ##")
 676     endif(prefix)
 677     if(suffix)
 678       set(suffix "## ${suffix}")
 679       if(extrasuffix)
 680         set(extrasuffix "${suffix}${extrasuffix}")
 681       endif(extrasuffix)
 682     else(suffix)
 683       if(extrasuffix)
 684         # Don't know if this is needed, but it can't hurt
 685         set(extrasuffix "## ${extrasuffix}")
 686       endif(extrasuffix)
 687     endif(suffix)
 688
 689     if(isupper)
 690         set(F77_FUNCDEF   "${prefix} NAME ${suffix}")
 691         set(F77_FUNCDEF_  "${prefix} NAME ${extrasuffix}")
 692     else(isupper)
 693         set(F77_FUNCDEF   "${prefix} name ${suffix}")
 694         set(F77_FUNCDEF_  "${prefix} name ${extrasuffix}")
 695     endif(isupper)
 696 else(GMX_FORTRAN OR GMX_POWER6)
 697         set(F77_FUNCDEF   "name ## _")
 698         set(F77_FUNCDEF_  "name ## _")
 699 endif(GMX_FORTRAN OR GMX_POWER6)
 700
 701 # Process QM/MM Settings
 702 string(TOUPPER ${GMX_QMMM_PROGRAM} ${GMX_QMMM_PROGRAM})
 703 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 704     set(GMX_QMMM_GAUSSIAN 1)
 705 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 706     set(GMX_QMMM_MOPAC 1)
 707 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 708     set(GMX_QMMM_GAMESS 1)
 709 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 710     set(GMX_QMMM_ORCA 1)
 711 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 712     # nothing to do
 713 else(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 714     MESSAGE(FATAL_ERROR "Invalid QM/MM program option: ${GMX_QMMM_PROGRAM}. Choose one of: Gaussian, Mopac, Gamess, Orca, None")
 715 endif(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 716
 717 # Process FFT library settings - if not OpenMM build
 718 string(TOUPPER ${GMX_FFT_LIBRARY} ${GMX_FFT_LIBRARY})
 719 set(PKG_FFT "")
 720 set(PKG_FFT_LIBS "")
 721 if(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 722 #    MESSAGE(STATUS "Using external FFT library - fftw3")
 723     if(GMX_DOUBLE)
 724         find_package(FFTW3 REQUIRED)
 725                 include_directories(${FFTW3_INCLUDE_DIR})
 726         set(FFT_LIBRARIES ${FFTW3_LIBRARIES})
 727         set(PKG_FFT "fftw3")
 728     else(GMX_DOUBLE)
 729         find_package(FFTW3F REQUIRED)
 730         include_directories(${FFTW3F_INCLUDE_DIR})
 731         set(FFT_LIBRARIES ${FFTW3F_LIBRARIES})
 732         set(PKG_FFT "fftw3f")
 733     endif(GMX_DOUBLE)
 734
 735     if(NOT FFTW3_FOUND AND NOT FFTW3F_FOUND)
 736         MESSAGE(FATAL_ERROR "Cannot find fftw3 (with correct precision). Fix it, choose another FFT library, or use the Gromacs built-in fftpack (slower)!")
 737     endif(NOT FFTW3_FOUND AND NOT FFTW3F_FOUND)
 738
 739     set(GMX_FFT_FFTW3 1)
 740
 741 elseif(${GMX_FFT_LIBRARY} STREQUAL "FFTW2")
 742 #    MESSAGE(STATUS "Using external FFT library - fftw2")
 743     if(GMX_DOUBLE)
 744         find_package(FFTW2 REQUIRED)
 745     else(GMX_DOUBLE)
 746         find_package(FFTW2F REQUIRED)
 747     endif(GMX_DOUBLE)
 748
 749     if(NOT FFTW2_FOUND)
 750            MESSAGE(FATAL_ERROR "Cannot find fftw2 (with correct precision). Fix it, choose another FFT library, or use the Gromacs built-in fftpack (slower)!")
 751     endif(NOT FFTW2_FOUND)
 752     include_directories(${FFTW2_INCLUDE_DIR})
 753     set(FFT_LIBRARIES ${FFTW2_LIBRARIES})
 754     set(PKG_FFT_LIBS ${FFTW2_LIBRARIES})
 755
 756     if("${FFTW2_LIBRARIES}" MATCHES "dfftw")
 757         set(FFTW2_NAME_DFFTW 1)
 758     elseif("${FFTW2_LIBRARIES}" MATCHES "sfftw")
 759         set(FFTW2_NAME_SFFTW 1)
 760     else("${FFTW2_LIBRARIES}" MATCHES "dfftw")
 761         set(FFTW2_NAME_FFTW 1)
 762     endif("${FFTW2_LIBRARIES}" MATCHES "dfftw")
 763
 764     set(GMX_FFT_FFTW2 1)
 765 elseif(${GMX_FFT_LIBRARY} STREQUAL "MKL")
 766 #    MESSAGE(STATUS "Using external FFT library - Intel MKL")
 767     find_package(MKL REQUIRED)
 768     include_directories(${MKL_INCLUDE_DIR})
 769     set(FFT_LIBRARIES ${MKL_LIBRARIES})
 770     set(PKG_FFT_LIBS ${MKL_LIBRARIES})
 771
 772     set(GMX_FFT_MKL 1)
 773     set(HAVE_MKL 1)
 774
 775 #elseif(${GMX_FFT_LIBRARY} STREQUAL "ACML")
 776 #    MESSAGE(STATUS "Using external FFT library - AMD core math library")
 777 #    set(GMX_FFT_ACML 1)
 778 elseif(${GMX_FFT_LIBRARY} STREQUAL "FFTPACK")
 779     MESSAGE(STATUS "Using internal FFT library - fftpack")
 780     set(GMX_FFT_FFTPACK 1)
 781 else(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 782     MESSAGE(FATAL_ERROR "Invalid FFT library setting: ${GMX_FFT_LIBRARY}. Choose one of: fftw3, fftw2, mkl, acml, fftpack")
 783 endif(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 784
 785 # MKL has BLAS/LAPACK routines
 786 if(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 787   set(GMX_EXTERNAL_BLAS TRUE CACHE BOOL "Use external BLAS instead of built-in")
 788   set(GMX_EXTERNAL_LAPACK TRUE CACHE BOOL "Use external LAPACK instead of built-in")
 789 else(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 790   set(GMX_EXTERNAL_BLAS FALSE CACHE BOOL "Use external BLAS instead of built-in")
 791   set(GMX_EXTERNAL_LAPACK FALSE CACHE BOOL "Use external LAPACK instead of built-in")
 792   if(GMX_EXTERNAL_BLAS)
 793     #FindBLAS needs Fortran
 794     enable_language(Fortran)
 795     if (GMX_BLAS_USER)
 796         list(APPEND GMX_EXTRA_LIBRARIES ${GMX_BLAS_USER})
 797     else(GMX_BLAS_USER)
 798         find_package(BLAS REQUIRED)
 799         list(APPEND GMX_EXTRA_LIBRARIES ${BLAS_LIBRARIES})
 800     endif(GMX_BLAS_USER)
 801   endif(GMX_EXTERNAL_BLAS)
 802   if(GMX_EXTERNAL_LAPACK)
 803     #FindLAPACK needs Fortran
 804     enable_language(Fortran)
 805         if (GMX_LAPACK_USER)
 806         list(APPEND GMX_EXTRA_LIBRARIES ${GMX_LAPACK_USER})
 807         else(GMX_LAPACK_USER)
 808         find_package(LAPACK REQUIRED)
 809         list(APPEND GMX_EXTRA_LIBRARIES ${LAPACK_LIBRARIES})
 810     endif(GMX_LAPACK_USER)
 811   endif(GMX_EXTERNAL_LAPACK)
 812 endif(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 813 mark_as_advanced(GMX_EXTERNAL_LAPACK)
 814 mark_as_advanced(GMX_EXTERNAL_BLAS)
 815
 816 # Math and thread libraries must often come after all others when linking...
 817 if(HAVE_LIBM)
 818     list(APPEND GMX_EXTRA_LIBRARIES m)
 819 endif(HAVE_LIBM)
 820
 821 if(GMX_FAHCORE)
 822   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 823       "Path to swindirect.h")
 824   include_directories(${COREWRAP_INCLUDE_DIR})
 825 endif(GMX_FAHCORE)
 826
 827 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 828 # these are set after everything else
 829 if (NOT DEFINED GROMACS_C_FLAGS_SET)
 830     set(GROMACS_C_FLAGS_SET true CACHE INTERNAL "Whether to reset the C flags"
 831         FORCE)
 832     set(CMAKE_C_FLAGS "${GROMACS_C_FLAGS} ${CMAKE_C_FLAGS}" CACHE STRING
 833         "Flags used by the compiler during all build types" FORCE)
 834     set(CMAKE_CXX_FLAGS "${GROMACS_CXX_FLAGS} ${CMAKE_CXX_FLAGS}" CACHE STRING
 835         "Flags used by the compiler during all build types" FORCE)
 836     set(CMAKE_EXE_LINKER_FLAGS
 837         "${GROMACS_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}"
 838         CACHE STRING "Linker flags" FORCE)
 839 endif (NOT DEFINED GROMACS_C_FLAGS_SET)
 840
 841 ########################################################################
 842 # Specify install locations and which subdirectories to process        #
 843 ########################################################################
 844 if ( DEFINED GMXLIB )
 845     set(LIB_INSTALL_DIR "${CMAKE_INSTALL_PREFIX}/${GMXLIB}")
 846 else()
 847     set(LIB_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/lib)
 848 endif()
 849 set(BIN_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/bin)
 850 set(DATA_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/gromacs)
 851 set(MAN_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/share/man)
 852 set(INCL_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/include)
 853
 854 set(GMXLIBDIR        ${DATA_INSTALL_DIR}/top)
 855
 856 ##################################################################
 857 # Shared library settings - Darwin uses INSTALL_NAME_DIR instead!
 858 ##################################################################
 859 if(NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin")
 860     set(CMAKE_SKIP_BUILD_RPATH  FALSE)
 861     set(CMAKE_BUILD_WITH_INSTALL_RPATH FALSE)
 862     set(CMAKE_INSTALL_RPATH "${LIB_INSTALL_DIR}")
 863     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 864 endif()
 865
 866 add_subdirectory(share)
 867 add_subdirectory(include)
 868 add_subdirectory(man)
 869 add_subdirectory(src)
 870 add_subdirectory(scripts)
 871
 872 #######################
 873 ## uninstall target
 874 #######################
 875     CONFIGURE_FILE(
 876                    "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 877                    "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
 878                    IMMEDIATE @ONLY)
 879 ###########################
 880 ADD_CUSTOM_TARGET(uninstall
 881                   "${CMAKE_COMMAND}" -P
 882                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
 883 ###########################
 884
 885
 886 ########################################################################
 887 # Tests                                                                #
 888 ########################################################################
 889
 890 include(CTest)
 891 mark_as_advanced(BUILD_TESTING)
 892 IF(BUILD_TESTING)
 893         enable_testing()
 894         add_subdirectory(tests)
 895 ENDIF()
 896