CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2009,2010,2011,2012,2013,2014, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 cmake_minimum_required(VERSION 2.8.8)
  36 # When we require cmake >= 2.8.12, it will provide
  37 # CMAKE_MINIMUM_REQUIRED_VERSION automatically, but in the meantime we
  38 # need to set a variable, and it must have a different name.
  39 set(GMX_CMAKE_MINIMUM_REQUIRED_VERSION "2.8.8")
  40
  41 # CMake modules/macros are in a subdirectory to keep this file cleaner
  42 # This needs to be set before project() in order to pick up toolchain files
  43 list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake ${CMAKE_CURRENT_SOURCE_DIR}/cmake/Platform)
  44
  45 project(Gromacs)
  46
  47 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  48 set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  49 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
  50
  51 # PROJECT_VERSION should have the following structure:
  52 # VERSION-dev[-SUFFIX] where the VERSION should have the for: vMajor.vMinor.vPatch
  53 #
  54 # The "-dev" suffix is important to keep because it makes possible to distinguish
  55 # between a build from official release and a build from git release branch on a
  56 # machine with no git.
  57 #
  58 # NOTE: when releasing the "-dev" suffix needs to be stripped off!
  59 # REGRESSIONTEST_VERSION and REGRESSIONTEST_BRANCH should always be
  60 # defined.
  61 set(PROJECT_VERSION "5.0.1-dev")
  62 # If this is a released tarball, "-dev" will not be present in
  63 # PROJECT_VERSION, and REGRESSIONTEST_VERSION specifies the version
  64 # number of the regressiontest tarball against which the code tarball
  65 # can be tested. This will be the version of the last patch release.
  66 set(REGRESSIONTEST_VERSION "5.0.1-dev")
  67 # If this is not a released tarball, "-dev" will be present in
  68 # PROJECT_VERSION, and REGRESSIONTEST_BRANCH specifies the name of the
  69 # gerrit.gromacs.org branch whose HEAD can test this code, *if* this
  70 # code contains all recent fixes from the corresponding code branch.
  71 set(REGRESSIONTEST_BRANCH "refs/heads/release-5-0")
  72
  73 set(CUSTOM_VERSION_STRING ""
  74     CACHE STRING "Custom version string (if empty, use hard-coded default)")
  75 mark_as_advanced(CUSTOM_VERSION_STRING)
  76 if (CUSTOM_VERSION_STRING)
  77     set(PROJECT_VERSION ${CUSTOM_VERSION_STRING})
  78 endif()
  79 set(LIBRARY_SOVERSION 0)
  80 set(LIBRARY_VERSION ${LIBRARY_SOVERSION}.0.0)
  81 # It is a bit irritating, but this has to be set separately for now!
  82 SET(CPACK_PACKAGE_VERSION_MAJOR "5")
  83 SET(CPACK_PACKAGE_VERSION_MINOR "0")
  84 #SET(CPACK_PACKAGE_VERSION_PATCH "0")
  85
  86 # The numerical gromacs version. It is 40600 for 4.6.0.
  87 # The #define GMX_VERSION in gromacs/version.h is set to this value.
  88 math(EXPR NUM_VERSION
  89     "${CPACK_PACKAGE_VERSION_MAJOR}*10000 + ${CPACK_PACKAGE_VERSION_MINOR}*100")
  90 if(CPACK_PACKAGE_VERSION_PATCH)
  91     math(EXPR NUM_VERSION
  92          "${NUM_VERSION} + ${CPACK_PACKAGE_VERSION_PATCH}")
  93 endif()
  94
  95 # The API version tracks the numerical Gromacs version (for now).
  96 # It is potentially different from the Gromacs version in the future, if
  97 # the programs/libraries diverge from the presumably more stable API.
  98 # The #define GMX_API_VERSION in version.h is set to this value to
  99 # provide backward compatibility of software written against the Gromacs API.
 100 set(API_VERSION ${NUM_VERSION})
 101
 102 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT AND UNIX)
 103     set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
 104 endif()
 105
 106 include(gmxBuildTypeReference)
 107 include(gmxBuildTypeTSAN)
 108 include(gmxBuildTypeASAN)
 109 include(gmxBuildTypeReleaseWithAssert)
 110
 111 if(NOT CMAKE_BUILD_TYPE)
 112     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel Reference RelWithAssert." FORCE)
 113     # There's no need to offer a user the choice of ThreadSanitizer
 114     # Set the possible values of build type for cmake-gui
 115     set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "Debug" "Release"
 116         "MinSizeRel" "RelWithDebInfo" "Reference" "RelWithAssert")
 117 endif()
 118 if(CMAKE_CONFIGURATION_TYPES)
 119     # Add appropriate GROMACS-specific build types for the Visual
 120     # Studio generator (Debug, Release, MinSizeRel and RelWithDebInfo
 121     # are already present by default).
 122     list(APPEND CMAKE_CONFIGURATION_TYPES "RelWithAssert" "Reference")
 123     list(REMOVE_DUPLICATES CMAKE_CONFIGURATION_TYPES)
 124     set(CMAKE_CONFIGURATION_TYPES "${CMAKE_CONFIGURATION_TYPES}" CACHE STRING
 125         "List of configuration types"
 126         FORCE)
 127 endif()
 128 set(build_types_with_explicit_flags RELEASE DEBUG RELWITHDEBUGINFO RELWITHASSERT MINSIZEREL)
 129
 130 enable_language(C)
 131 enable_language(CXX)
 132
 133 set(CPACK_PACKAGE_NAME "gromacs")
 134 set(CPACK_PACKAGE_VERSION ${PROJECT_VERSION})
 135 set(CPACK_SOURCE_PACKAGE_FILE_NAME "${CPACK_PACKAGE_NAME}-${CPACK_PACKAGE_VERSION}")
 136 set(CPACK_PACKAGE_VENDOR "gromacs.org")
 137 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Gromacs - a toolkit for high-performance molecular simulation")
 138 set(CPACK_RESOURCE_FILE_WELCOME "${CMAKE_SOURCE_DIR}/admin/InstallWelcome.txt")
 139 # Its GPL/LGPL, so they do not have to agree to a license for mere usage, but some installers require this...
 140 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_SOURCE_DIR}/COPYING")
 141 set(CPACK_RESOURCE_FILE_README "${CMAKE_SOURCE_DIR}/admin/InstallInfo.txt")
 142 set(CPACK_SOURCE_IGNORE_FILES "\\\\.isreposource$;\\\\.git/;\\\\.gitignore$;\\\\.gitattributes;")
 143 set(CPACK_PROJECT_CONFIG_FILE "${CMAKE_SOURCE_DIR}/CPackInit.cmake")
 144 # CPack source archives include only the directories we list here.
 145 # This variable is a list of pairs of names of source and destination
 146 # directories. Most of these are used for content GROMACS generates as
 147 # part of the configuration or build.
 148 set(CPACK_SOURCE_INSTALLED_DIRECTORIES "${CMAKE_SOURCE_DIR};/;${CMAKE_BINARY_DIR}/src/programs/completion;src/programs/completion;${CMAKE_BINARY_DIR}/share/man/man1;share/man/man1;${CMAKE_BINARY_DIR}/share/man/man7;share/man/man7;${CMAKE_BINARY_DIR}/share/html/final;share/html/final;${CMAKE_BINARY_DIR}/install-guide/final;/")
 149 set(CPACK_PACKAGE_CONTACT "gmx-users@gromacs.org")
 150
 151 #must come after all cpack settings!
 152 include(CPack)
 153
 154 # Set a default valgrind suppression file.
 155 # This unfortunately needs to duplicate information from CTest to work as
 156 # expected...
 157 set(MEMORYCHECK_SUPPRESSIONS_FILE
 158     "${CMAKE_SOURCE_DIR}/cmake/legacy_and_external.supp"
 159     CACHE FILEPATH
 160     "File that contains suppressions for the memory checker")
 161 include(CTest)
 162
 163 set(SOURCE_IS_GIT_REPOSITORY OFF)
 164 set(SOURCE_IS_SOURCE_DISTRIBUTION OFF)
 165 if(EXISTS "${CMAKE_SOURCE_DIR}/.git")
 166     set(SOURCE_IS_GIT_REPOSITORY ON)
 167 endif()
 168 if(NOT EXISTS "${CMAKE_SOURCE_DIR}/admin/.isreposource")
 169     set(SOURCE_IS_SOURCE_DISTRIBUTION ON)
 170 endif()
 171
 172 ########################################################################
 173 # Check and warn if cache generated on a different host is being reused
 174 ########################################################################
 175 if(CMAKE_HOST_UNIX)
 176     execute_process(COMMAND hostname
 177                     OUTPUT_VARIABLE TMP_HOSTNAME
 178                     OUTPUT_STRIP_TRAILING_WHITESPACE)
 179     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}")
 180         message(WARNING "
 181             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
 182             is being reused! This could lead to inconsitencies; therefore, it is
 183             recommended to regenerate the cache!")
 184     endif()
 185     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
 186             "Hostname of the machine where the cache was generated.")
 187 endif()
 188
 189 ########################################################################
 190 # User input options                                                   #
 191 ########################################################################
 192 include(gmxOptionUtilities)
 193
 194 set(CMAKE_PREFIX_PATH "" CACHE STRING "Extra locations to search for external libraries and tools (give directory without lib, bin, or include)")
 195
 196 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" OFF)
 197 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 198 option(GMX_THREAD_MPI  "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" ON)
 199 gmx_dependent_option(
 200     GMX_MPI_IN_PLACE
 201     "Enable MPI_IN_PLACE for MPIs that have it defined"
 202     ON
 203     GMX_MPI)
 204 mark_as_advanced(GMX_MPI_IN_PLACE)
 205 option(GMX_SOFTWARE_INVSQRT "Use GROMACS software 1/sqrt" ON)
 206 mark_as_advanced(GMX_SOFTWARE_INVSQRT)
 207 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 208 mark_as_advanced(GMX_FAHCORE)
 209
 210 option(GMX_COOL_QUOTES "Enable Gromacs cool quotes" ON)
 211 mark_as_advanced(GMX_COOL_QUOTES)
 212 gmx_add_cache_dependency(GMX_COOL_QUOTES BOOL "NOT GMX_FAHCORE" OFF)
 213
 214 # Decide on GPU settings based on user-settings and GPU/CUDA detection.
 215 # We support CUDA >=v4.0 on *nix, but <= v4.1 doesn't work with MSVC
 216 if(MSVC)
 217     set(REQUIRED_CUDA_VERSION 4.1)
 218 else()
 219     set(REQUIRED_CUDA_VERSION 4.0)
 220 endif()
 221 set(REQUIRED_CUDA_COMPUTE_CAPABILITY 2.0)
 222 include(gmxManageGPU)
 223
 224 # Detect the architecture the compiler is targetting, detect
 225 # SIMD instructions possibilities on that hardware, suggest SIMD instruction set
 226 # to use if none is specified, and populate the cache option for CPU
 227 # SIMD.
 228 include(gmxDetectTargetArchitecture)
 229 gmx_detect_target_architecture()
 230
 231 if(GMX_CPU_ACCELERATION)
 232     # Stay compatible with old Jenkins command line options for specific SIMD acceleration
 233     set(GMX_SIMD "${GMX_CPU_ACCELERATION}" CACHE STRING "SIMD instruction set level and compiler optimization" FORCE)
 234     message("You set GMX_CPU_ACCELERATION, which is deprecated, and will be removed in a later version of GROMACS. It is replaced by GMX_SIMD. For now, copying the value from GMX_CPU_ACCELERATION to GMX_SIMD.")
 235     # TODO remove all references to GMX_CPU_ACCELERATION in master branch
 236 endif()
 237
 238 if(NOT GMX_TARGET_MIC)
 239     include(gmxDetectSimd)
 240     gmx_detect_simd(GMX_SUGGESTED_SIMD)
 241 else()
 242     set(GMX_SUGGESTED_SIMD "None")
 243 endif()
 244
 245 gmx_option_multichoice(
 246     GMX_SIMD
 247     "SIMD instruction set for CPU kernels and compiler optimization"
 248     "${GMX_SUGGESTED_SIMD}"
 249     None SSE2 SSE4.1 AVX_128_FMA AVX_256 AVX2_256 IBM_QPX Sparc64_HPC_ACE Reference)
 250
 251 gmx_option_multichoice(
 252     GMX_FFT_LIBRARY
 253     "FFT library"
 254     "fftw3"
 255     fftw3 mkl "fftpack[built-in]")
 256 gmx_dependent_option(
 257     GMX_BUILD_OWN_FFTW
 258     "Download and build FFTW 3 during the GROMACS build process, rather than fall back on the really slow fftpack."
 259     OFF
 260     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 261 gmx_dependent_option(
 262     GMX_DISABLE_FFTW_MEASURE
 263     "Do not optimize FFTW setups (not needed with SSE)"
 264     OFF
 265     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 266 mark_as_advanced(GMX_BUILD_OWN_FFTW)
 267 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 268
 269 gmx_option_multichoice(
 270     GMX_QMMM_PROGRAM
 271     "QM package for QM/MM"
 272     None
 273     none gaussian mopac gamess orca)
 274
 275 gmx_dependent_cache_variable(GMX_SIMD_REF_FLOAT_WIDTH  "Reference SIMD single precision width" STRING "4" "GMX_SIMD STREQUAL REFERENCE")
 276 gmx_dependent_cache_variable(GMX_SIMD_REF_DOUBLE_WIDTH "Reference SIMD double precision width" STRING "2" "GMX_SIMD STREQUAL REFERENCE")
 277
 278 # This should be moved to a separate NBNXN cmake module when that code is cleaned up and modularized
 279
 280 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 281 mark_as_advanced(GMX_BROKEN_CALLOC)
 282 option(GMX_LOAD_PLUGINS "Compile with plugin support, needed to read VMD supported file formats" ON)
 283 mark_as_advanced(GMX_LOAD_PLUGINS)
 284
 285 option(GMX_GPU  "Enable GPU acceleration" ON)
 286 option(GMX_OPENMP "Enable OpenMP-based multithreading" ON)
 287
 288 option(GMX_USE_TNG "Use the TNG library for trajectory I/O" ON)
 289
 290 option(GMX_GIT_VERSION_INFO "Generate git version information" ${SOURCE_IS_GIT_REPOSITORY})
 291 mark_as_advanced(GMX_GIT_VERSION_INFO)
 292
 293 if(UNIX)
 294     option(GMX_SYMLINK_OLD_BINARY_NAMES "Create symbolic links for pre-5.0 binary names" ON)
 295 endif()
 296 option(GMX_BUILD_MDRUN_ONLY "Build and install only the mdrun binary" OFF)
 297
 298 option(GMX_CYCLE_SUBCOUNTERS "Enable cycle subcounters to get a more detailed cycle timings" OFF)
 299 mark_as_advanced(GMX_CYCLE_SUBCOUNTERS)
 300
 301 option(GMX_SKIP_DEFAULT_CFLAGS "Don't automatically add suggested/required Compiler flags." OFF)
 302 mark_as_advanced(GMX_SKIP_DEFAULT_CFLAGS)
 303
 304 option(GMX_BUILD_FOR_COVERAGE
 305        "Tune build for better code coverage metrics (e.g., disable asserts)"
 306        OFF)
 307 mark_as_advanced(GMX_BUILD_FOR_COVERAGE)
 308
 309
 310 ######################################################################
 311 # Detect OpenMP support
 312 ######################################################################
 313 # The OpenMP detection _must_ come before tests for other CFLAGS.
 314 include(gmxManageOpenMP)
 315
 316
 317
 318 ######################################################################
 319 # Compiler tests
 320 # These need to be done early (before further tests).
 321 #####################################################################
 322
 323 # The cmake/Check{C,CXX}CompilerFlag.cmake files in the GROMACS distribution
 324 # are used with permission from CMake v2.8.9 so that GROMACS can detect
 325 # invalid options with the Intel Compilers.
 326 # These files should be removed from the source tree when a CMake version that
 327 # includes the features in question becomes required for building GROMACS.
 328 include(CheckCCompilerFlag)
 329 include(CheckCXXCompilerFlag)
 330
 331
 332 include(gmxCFlags)
 333 gmx_c_flags()
 334
 335 # This variable should be used for additional compiler flags which are not
 336 # generated in gmxCFlags nor are SIMD or MPI related.
 337 set(EXTRA_C_FLAGS "")
 338 set(EXTRA_CXX_FLAGS "")
 339
 340 # Run through a number of tests for buggy compilers and other issues
 341 include(gmxTestCompilerProblems)
 342 gmx_test_compiler_problems()
 343 # GMX_SIMD will not be set automatically until the second
 344 # pass (which is not strictly guaranteed to occur), so putting this
 345 # check here among logically-related tests is inefficient, but the
 346 # potential loss is likely zero.
 347 if(GMX_SIMD STREQUAL "AVX_256"
 348         AND CMAKE_COMPILER_IS_GNUCC
 349         AND (C_COMPILER_VERSION VERSION_EQUAL "4.6.1"
 350             OR CXX_COMPILER_VERSION VERSION_EQUAL "4.6.1"))
 351     message(FATAL_ERROR "gcc 4.6.1 has buggy support for AVX, and GROMACS mdrun will not work. If you want simulation performance, use a more recent compiler. Otherwise, use GMX_SIMD=SSE4.1")
 352     # See http://gcc.gnu.org/bugzilla/show_bug.cgi?id=49002
 353 endif()
 354
 355
 356
 357 set(PKG_CFLAGS "")
 358 if(GMX_DOUBLE)
 359     add_definitions(-DGMX_DOUBLE)
 360     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_DOUBLE")
 361 endif()
 362 if(GMX_SOFTWARE_INVSQRT)
 363   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_SOFTWARE_INVSQRT")
 364 endif()
 365
 366 if(WIN32 AND NOT CYGWIN)
 367     set(GMX_WSOCKLIB_PATH CACHE PATH "Path to winsock (wsock32.lib) library.")
 368     mark_as_advanced(GMX_WSOCKLIB_PATH)
 369     find_library(WSOCK32_LIBRARY NAMES wsock32 PATHS ${GMX_WSOCKLIB_PATH})
 370     if(WSOCK32_LIBRARY)
 371         list(APPEND GMX_EXTRA_LIBRARIES ${WSOCK32_LIBRARY})
 372         add_definitions(-DGMX_HAVE_WINSOCK)
 373     else()
 374         message(STATUS "No winsock found. Cannot use interactive molecular dynamics (IMD).")
 375     endif(WSOCK32_LIBRARY)
 376 endif()
 377
 378
 379
 380 ########################################################################
 381 # Basic system tests (standard libraries, headers, functions, types)   #
 382 ########################################################################
 383 include(CheckIncludeFiles)
 384 include(CheckIncludeFileCXX)
 385 check_include_files(unistd.h     HAVE_UNISTD_H)
 386 check_include_files(pwd.h        HAVE_PWD_H)
 387 check_include_files(dirent.h     HAVE_DIRENT_H)
 388 check_include_files(time.h       HAVE_TIME_H)
 389 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 390 check_include_files(io.h         HAVE_IO_H)
 391 check_include_files(sched.h      HAVE_SCHED_H)
 392
 393 check_include_files(regex.h      HAVE_POSIX_REGEX)
 394 check_include_file_cxx(regex     HAVE_CXX11_REGEX)
 395 # TODO: It could be nice to inform the user if no regex support is found,
 396 # as selections won't be fully functional.
 397
 398 include(CheckFunctionExists)
 399 check_function_exists(posix_memalign    HAVE_POSIX_MEMALIGN)
 400 check_function_exists(memalign          HAVE_MEMALIGN)
 401 check_function_exists(_aligned_malloc   HAVE__ALIGNED_MALLOC)
 402 check_function_exists(gettimeofday      HAVE_GETTIMEOFDAY)
 403 check_function_exists(fsync             HAVE_FSYNC)
 404 check_function_exists(_fileno           HAVE__FILENO)
 405 check_function_exists(fileno            HAVE_FILENO)
 406 check_function_exists(_commit           HAVE__COMMIT)
 407 check_function_exists(sigaction         HAVE_SIGACTION)
 408 check_function_exists(sysconf           HAVE_SYSCONF)
 409 check_function_exists(sched_setaffinity HAVE_SCHED_SETAFFINITY)
 410 check_function_exists(sched_getaffinity HAVE_SCHED_GETAFFINITY)
 411 check_function_exists(rsqrt             HAVE_RSQRT)
 412 check_function_exists(rsqrtf            HAVE_RSQRTF)
 413 check_function_exists(sqrtf             HAVE_SQRTF)
 414
 415 include(CheckLibraryExists)
 416 check_library_exists(m sqrt "" HAVE_LIBM)
 417 check_library_exists(rt clock_gettime "" HAVE_CLOCK_GETTIME)
 418
 419 include(TestBigEndian)
 420 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 421
 422 # Management of GROMACS options for specific toolchains should go
 423 # here. Because the initial settings for some of the main options have
 424 # already happened, but things like library detection and MPI compiler
 425 # feature detection have not, the docstrings for any over-rides of
 426 # GROMACS defaults or user settings will make sense. Also, any
 427 # toolchain-related reasons for choosing whether to detect various
 428 # things can be sorted out now, before the detection takes place.
 429 if(${CMAKE_SYSTEM_NAME} MATCHES BlueGene)
 430     include(gmxManageBlueGene)
 431 endif()
 432
 433 ########################################################################
 434 #Process MPI settings
 435 ########################################################################
 436 include(gmxManageMPI)
 437
 438
 439 ########################################################################
 440 #Process shared/static library settings
 441 ########################################################################
 442 include(gmxManageSharedLibraries)
 443
 444
 445 ########################################################################
 446 # Find external packages                                               #
 447 ########################################################################
 448
 449 # Unconditionally find the package, as it is also required for unit
 450 # tests. This exports LIBXML2_FOUND, which we should not use because
 451 # it does not tell us that linking will succeed. Instead, we test that
 452 # next.
 453 if(DEFINED LIBXML2_LIBRARIES)
 454   set(LibXml2_FIND_QUIETLY TRUE)
 455 endif()
 456 find_package(LibXml2)
 457 include(gmxTestLibXml2)
 458 gmx_test_libxml2(HAVE_LIBXML2)
 459 option(GMX_XML "Use libxml2 to parse xml files (currently has no effect)" ${HAVE_LIBXML2})
 460 set(PKG_XML "")
 461 mark_as_advanced(GMX_XML)
 462 # Don't actually do anything, since libxml2 is currently not used by libgromacs
 463 #if(GMX_XML AND NOT HAVE_LIBXML2)
 464 #    message(FATAL_ERROR "libxml2 not found. Set GMX_XML=OFF to compile without XML support")
 465 #endif()
 466 #if(GMX_XML)
 467 #    include_directories(${LIBXML2_INCLUDE_DIR})
 468 #    set(PKG_XML libxml-2.0)
 469 #    set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 470 #endif()
 471
 472 option(GMX_EXTRAE "Add support for tracing using EXTRAE" OFF)
 473 mark_as_advanced(GMX_EXTRAE)
 474
 475 if (GMX_EXTRAE)
 476   find_package(EXTRAE)
 477   if(EXTRAE_FOUND)
 478     include_directories(${EXTRAE_INCLUDE_DIR})
 479     set(HAVE_EXTRAE 1)
 480   else()
 481     message(FATAL_ERROR "EXTRAE library was not found. Please add the correct path to CMAKE_PREFIX_PATH")
 482   endif()
 483 endif()
 484
 485 option(GMX_X11 "Use X window system" OFF)
 486 if (GMX_X11)
 487     find_package(X11)
 488     # X11 includes/libraries are only set in the ngmx subdirectory!
 489     if(NOT X11_FOUND)
 490         message(FATAL_ERROR
 491                 "X11 include files and/or libraries were not found. "
 492                 "Set GMX_X11=OFF to compile without X11 support. "
 493                 "gmx view will not be available.")
 494     endif()
 495     include_directories(${X11_INCLUDE_DIR})
 496 endif()
 497
 498 include(ThreadMPI)
 499 # Enable core threading facilities
 500 tmpi_enable_core("${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include")
 501 # Enable tMPI C++ support
 502 tmpi_enable_cxx()
 503 if(GMX_THREAD_MPI)
 504     # enable MPI functions
 505     tmpi_enable()
 506     set(GMX_MPI 1)
 507     set(MPI_IN_PLACE_EXISTS 1)
 508 endif()
 509 # If atomics are manually disabled a define is needed because atomics.h doesn't depend on config.h
 510 if (TMPI_ATOMICS_DISABLED)
 511    add_definitions(-DTMPI_ATOMICS_DISABLED)
 512 endif()
 513
 514 if(GMX_GPU)
 515     # now that we have detected the dependencies, do the second configure pass
 516     gmx_gpu_setup()
 517 endif()
 518
 519 if(CYGWIN)
 520     set(GMX_CYGWIN 1)
 521 endif()
 522
 523 if(WIN32 AND NOT CYGWIN)
 524     set(GMX_NATIVE_WINDOWS 1)
 525     # This makes windows.h not declare min/max as macros that would break
 526     # C++ code using std::min/std::max.
 527     add_definitions(-DNOMINMAX)
 528 endif()
 529
 530 # only bother with finding git and using version.h if the source is a git repo
 531 if(GMX_GIT_VERSION_INFO)
 532     if (NOT SOURCE_IS_GIT_REPOSITORY)
 533         message(FATAL_ERROR
 534             "Cannot generate git version information from source tree not under git. "
 535             "Set GMX_GIT_VERSION_INFO=OFF to proceed.")
 536     endif()
 537     # We need at least git v1.5.3 be able to parse git's date output. If not
 538     # found or the version is too small, we can't generate version information.
 539     find_package(Git)
 540
 541     if(NOT GIT_FOUND OR GIT_VERSION_STRING VERSION_LESS "1.5.3")
 542         message(FATAL_ERROR
 543             "No compatible git version found (>= 1.5.3 required). "
 544             "Won't be able to generate development version information. "
 545             "Set GMX_GIT_VERSION_INFO=OFF to proceed.")
 546     endif()
 547 endif()
 548
 549 # Detect boost unless GMX_EXTERNAL_BOOST is explicitly OFF
 550 # Used for default if GMX_EXTERNAL_BOOST is not defined (first CMake pass)
 551 if(NOT DEFINED GMX_EXTERNAL_BOOST OR GMX_EXTERNAL_BOOST)
 552     find_package(Boost 1.44.0)
 553     if(Boost_FOUND AND Boost_VERSION VERSION_LESS "104400")
 554         set(Boost_FOUND FALSE)
 555     endif()
 556     # Print the notification only on first run, when determining the default
 557     if(NOT DEFINED GMX_EXTERNAL_BOOST AND NOT Boost_FOUND)
 558         message("Boost >= 1.44 not found. Using minimal internal version. "
 559                 "This may cause trouble if you plan on compiling/linking other "
 560                 "software that uses Boost against Gromacs.")
 561     endif()
 562 endif()
 563 option(GMX_EXTERNAL_BOOST "Use external Boost instead of minimal built-in version"
 564        ${Boost_FOUND})
 565 if(GMX_EXTERNAL_BOOST AND NOT Boost_FOUND)
 566     message(FATAL_ERROR
 567         "Boost >= 1.44 not found. "
 568         "You can set GMX_EXTERNAL_BOOST=OFF to compile against minimal "
 569         "version of Boost included with Gromacs.")
 570 endif()
 571
 572 if(NOT DEFINED GMX_BUILD_UNITTESTS AND NOT HAVE_LIBXML2)
 573     message(WARNING "libxml2 not found. Will build GROMACS without unit-tests. This is not recommended, because the unit-tests help to verify that GROMACS functions correctly. Most likely you are missing the libxml2-dev(el) package. After you installed it, set GMX_BUILD_UNITTESTS=ON.")
 574 endif()
 575 option(GMX_BUILD_UNITTESTS "Build unit tests with BUILD_TESTING (uses Google C++ Testing and Mocking Frameworks, requires libxml2)" ${HAVE_LIBXML2})
 576 mark_as_advanced(GMX_BUILD_UNITTESTS)
 577 gmx_add_cache_dependency(GMX_BUILD_UNITTESTS BOOL BUILD_TESTING OFF)
 578 if (GMX_BUILD_UNITTESTS AND NOT HAVE_LIBXML2)
 579     message(FATAL_ERROR
 580         "Cannot build unit tests without libxml2. "
 581         "Either set GMX_BUILD_UNITTESTS=OFF or tell CMake how to find a working version of libxml2.")
 582 endif()
 583
 584 ########################################################################
 585 # Generate development version info for cache
 586 ########################################################################
 587 # set(GEN_VERSION_INFO_INTERNAL "ON")
 588 # include(gmxGenerateVersionString)
 589
 590 ########################################################################
 591 # Our own GROMACS tests
 592 ########################################################################
 593
 594 add_definitions( -DHAVE_CONFIG_H )
 595 include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src)
 596 include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include)
 597 # Required for config.h, maybe should only be set in src/CMakeLists.txt
 598 include_directories(BEFORE ${CMAKE_BINARY_DIR}/src)
 599 # Required for gmx_header_config_gen.h to be found before installation
 600 include_directories(BEFORE ${CMAKE_BINARY_DIR}/src/gromacs/utility)
 601 # Required for now to make old code compile
 602 include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src/gromacs/legacyheaders)
 603
 604 include(gmxTestInlineASM)
 605 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 606
 607 include(gmxSetBuildInformation)
 608 gmx_set_build_information()
 609 # Turn on RDTSCP if:
 610 # - the build system's CPU supports it
 611 # - the acceleration is set to AVX as all AVX-capable CPUs support AVX (which
 612 #   at this point means that the user set it).
 613 # Note: it's better to not use the later set value of GMX_SIMD because
 614 # it reflects the system's capability of both compiling and running AVX code.
 615 # TODO: After merge with 5.0 one could implement a cache variable dependency
 616 # such that GMX_USE_RDTSCP can change if GMX_SIMD is changed to AVX
 617 # after the first cmake pass.
 618 if (BUILD_CPU_FEATURES MATCHES "rdtscp" OR GMX_SIMD MATCHES "AVX")
 619     set(GMX_USE_RDTSCP_DEFAULT_VALUE ON)
 620 else()
 621     set(GMX_USE_RDTSCP_DEFAULT_VALUE OFF)
 622 endif()
 623 option(GMX_USE_RDTSCP "Use RDTSCP for better CPU-based timers (available on recent x86 CPUs; might need to be off when compiling for heterogeneous environments)" ${GMX_USE_RDTSCP_DEFAULT_VALUE})
 624 mark_as_advanced(GMX_USE_RDTSCP)
 625 if(GMX_USE_RDTSCP)
 626     set(HAVE_RDTSCP 1)
 627 endif()
 628
 629 include(gmxTestFloatFormat)
 630 gmx_test_float_format(GMX_FLOAT_FORMAT_IEEE754
 631                       GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER
 632                       GMX_IEEE754_BIG_ENDIAN_WORD_ORDER)
 633
 634 include(gmxTestLargeFiles)
 635 gmx_test_large_files(GMX_LARGEFILES)
 636
 637 include(gmxTestSignal)
 638 gmx_test_sigusr1(HAVE_SIGUSR1)
 639
 640 include(gmxTestPipes)
 641 gmx_test_pipes(HAVE_PIPES)
 642
 643 include(gmxTestIsfinite)
 644 gmx_test_isfinite(HAVE_ISFINITE)
 645 gmx_test__isfinite(HAVE__ISFINITE)
 646 gmx_test__finite(HAVE__FINITE)
 647
 648 include(gmxTestCXX11)
 649 gmx_test_cxx11(GMX_CXX11_SUPPORTED GMX_CXX11_FLAGS)
 650 include(CMakeDependentOption)
 651 # nvcc does not support C++11 flags, so with GPUs we prefer to skip C++11 flags
 652 # entirely to keep the compilation environment uniform.
 653 cmake_dependent_option(GMX_CXX11
 654     "Use C++11 features"
 655     ON "GMX_CXX11_SUPPORTED AND NOT GMX_GPU" OFF)
 656 mark_as_advanced(GMX_CXX11)
 657 if(GMX_CXX11)
 658     set(EXTRA_CXX_FLAGS "${EXTRA_CXX_FLAGS} ${GMX_CXX11_FLAGS}")
 659 endif()
 660
 661
 662 include(gmxTestXDR)
 663 gmx_test_xdr(GMX_SYSTEM_XDR)
 664 if(NOT GMX_SYSTEM_XDR)
 665     set(GMX_INTERNAL_XDR 1)
 666 endif()
 667
 668
 669 ##################################################
 670 # Process SIMD instruction settings
 671 ##################################################
 672 # This checks what flags to add in order to
 673 # support the SIMD instructions we need, and sets
 674 # correct defines for the SIMD instructions supported.
 675 include(gmxTestSimd)
 676 gmx_test_simd()
 677
 678
 679 # Process QM/MM Settings
 680 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 681     set(GMX_QMMM_GAUSSIAN 1)
 682 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 683     set(GMX_QMMM_MOPAC 1)
 684 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 685     set(GMX_QMMM_GAMESS 1)
 686 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 687     set(GMX_QMMM_ORCA 1)
 688 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 689     # nothing to do
 690 else()
 691     gmx_invalid_option_value(GMX_QMMM_PROGRAM)
 692 endif()
 693
 694
 695 ##################################################
 696 # Process FFT library settings
 697 ##################################################
 698 include(gmxManageFFTLibraries)
 699
 700
 701 include(gmxManageLinearAlgebraLibraries)
 702
 703 # Whether GROMACS will really try to compile support for VMD plugins
 704 set(GMX_USE_PLUGINS OFF)
 705
 706 if(GMX_LOAD_PLUGINS)
 707   if(CYGWIN OR NOT WIN32)
 708     # Native Windows does not have, nor need dlopen
 709     # Note that WIN32 is set with Cygwin, but Cygwin needs dlopen to use plug-ins
 710     include(gmxTestdlopen)
 711     gmx_test_dlopen(HAVE_DLOPEN)
 712   endif()
 713
 714   # so, should we use plug-ins?
 715   if((WIN32 AND NOT CYGWIN) OR (HAVE_DLOPEN AND BUILD_SHARED_LIBS))
 716     if(NOT VMD_QUIETLY)
 717       MESSAGE(STATUS
 718           "Found the ability to use plug-ins when building shared libaries, "
 719           "so will compile to use plug-ins (e.g. to read VMD-supported file "
 720           "formats).")
 721     endif()
 722     if(NOT GMX_VMD_PLUGIN_PATH)
 723       find_package(VMD)
 724     endif()
 725     set(GMX_USE_PLUGINS ON)
 726     list(APPEND GMX_EXTRA_LIBRARIES ${CMAKE_DL_LIBS}) # magic cross-platform pre-set variable for dlopen library
 727     set(PKG_DL_LIBS "-l${CMAKE_DL_LIBS}")
 728   else()
 729     set(PKG_DL_LIBS)
 730   endif()
 731 endif()
 732 set(VMD_QUIETLY TRUE CACHE INTERNAL "")
 733
 734 # Link real-time library for POSIX timers. The check for clock_gettime
 735 # confirms the linkability of rt.
 736 if(HAVE_TIME_H AND HAVE_UNISTD_H AND HAVE_CLOCK_GETTIME)
 737     list(APPEND GMX_EXTRA_LIBRARIES rt)
 738 endif()
 739
 740 # Math and thread libraries must often come after all others when linking...
 741 if(HAVE_LIBM)
 742     list(APPEND GMX_EXTRA_LIBRARIES m)
 743 endif()
 744
 745 option(GMX_NACL "Configure for Native Client builds" OFF)
 746 if (GMX_NACL)
 747   list(APPEND GMX_EXTRA_LIBRARIES nosys)
 748   set(GMX_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -lnosys")
 749   set(GMX_NO_NICE 1)
 750   set(GMX_NO_RENAME 1)
 751 endif()
 752 mark_as_advanced(GMX_NACL)
 753
 754 if(GMX_FAHCORE)
 755   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 756       "Path to swindirect.h")
 757   include_directories(${COREWRAP_INCLUDE_DIR})
 758 endif()
 759
 760 option(GMX_BUILD_HELP "Build man pages, HTML help, and completions automatically (requires that compiled binaries can be executed on the build host)" OFF)
 761 mark_as_advanced(GMX_BUILD_HELP)
 762 if (GMX_BUILD_HELP AND SOURCE_IS_SOURCE_DISTRIBUTION AND
 763     "${CMAKE_CURRENT_SOURCE_DIR}" STREQUAL "${CMAKE_CURRENT_BINARY_DIR}")
 764
 765     message(FATAL_ERROR
 766         "Rebuilding HTML and man pages is not supported for in-source "
 767         "builds from a source distribution. "
 768         "Set GMX_BUILD_HELP=OFF or do an out-of-source build to proceed.")
 769 endif()
 770
 771 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 772 # these are set after everything else
 773 if (NOT GMX_SKIP_DEFAULT_CFLAGS)
 774     set(CMAKE_C_FLAGS "${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${CMAKE_C_FLAGS}")
 775     set(CMAKE_CXX_FLAGS "${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${CMAKE_CXX_FLAGS}")
 776     set(CMAKE_EXE_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}")
 777     set(CMAKE_SHARED_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS}")
 778 else()
 779     message("Recommended flags which are not added because GMX_SKIP_DEFAULT_CFLAGS=yes:")
 780     message("CMAKE_C_FLAGS: ${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${GMXC_CFLAGS}")
 781     message("CMAKE_C_FLAGS_RELEASE: ${GMXC_CFLAGS_RELEASE}")
 782     message("CMAKE_C_FLAGS_DEBUG: ${GMXC_CFLAGS_DEBUG}")
 783     message("CMAKE_CXX_FLAGS: ${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${GMXC_CXXFLAGS}")
 784     message("CMAKE_CXX_FLAGS_RELEASE: ${GMXC_CXXFLAGS_RELEASE}")
 785     message("CMAKE_CXX_FLAGS_DEBUG: ${GMXC_CXXFLAGS_DEBUG}")
 786     message("CMAKE_EXE_LINKER_FLAGS: ${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS}")
 787     message("CMAKE_SHARED_LINKER_FLAGS: ${MPI_LINKER_FLAGS}")
 788 endif()
 789
 790 if(NOT GMX_OPENMP)
 791     #Unset all OpenMP flags in case OpenMP was disabled either by the user
 792     #or because it was only partially detected (e.g. only for C but not C++ compiler)
 793     unset(OpenMP_C_FLAGS CACHE)
 794     unset(OpenMP_CXX_FLAGS CACHE)
 795 else()
 796     set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} ${OpenMP_LINKER_FLAGS})
 797     set(GMX_SHARED_LINKER_FLAGS ${GMX_SHARED_LINKER_FLAGS} ${OpenMP_SHARED_LINKER_FLAGS})
 798 endif()
 799 set(PKG_CFLAGS "${PKG_CFLAGS} ${OpenMP_C_FLAGS}")
 800
 801 ########################################################################
 802 # Specify install locations
 803 ########################################################################
 804 # Use GNUInstallDirs to set paths on multiarch systems.
 805 include(GNUInstallDirs)
 806
 807 # Customization for the installation tree paths.
 808 set(GMX_LIB_INSTALL_DIR ${CMAKE_INSTALL_LIBDIR} CACHE STRING
 809     "Library installation directory (default: ${CMAKE_INSTALL_LIBDIR})")
 810 set(GMX_DATA_INSTALL_DIR gromacs CACHE STRING
 811     "Data installation directory under share/ (default: gromacs)")
 812 mark_as_advanced(GMX_LIB_INSTALL_DIR GMX_DATA_INSTALL_DIR)
 813
 814 # These variables are used internally to provide a central location for
 815 # customizing the install locations.
 816 set(LIB_INSTALL_DIR  ${GMX_LIB_INSTALL_DIR})
 817 set(BIN_INSTALL_DIR  bin)
 818 set(DATA_INSTALL_DIR share/${GMX_DATA_INSTALL_DIR})
 819 set(MAN_INSTALL_DIR  share/man)
 820 set(INCL_INSTALL_DIR include)
 821
 822 # These variables get written into config.h for use in finding the data
 823 # directories.
 824 set(GMXLIB_SEARCH_DIR share/${GMX_DATA_INSTALL_DIR}/top)
 825 set(GMXLIB_FALLBACK   ${CMAKE_INSTALL_PREFIX}/${DATA_INSTALL_DIR}/top)
 826
 827 # Binary and library suffix options
 828 include(gmxManageSuffixes)
 829
 830 ################################################################
 831 # Shared library load path settings
 832 ################################################################
 833 # CMake supports RPATH on OS X only from 2.8.12 upwards.
 834 # CMAKE_SYSTEM_VERSION > 8.0 matches OS X 10.5 and above, where RPATH support
 835 # was added.
 836 if((NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin") OR
 837    ((CMAKE_SYSTEM_VERSION VERSION_GREATER 8.0) AND (NOT CMAKE_VERSION VERSION_LESS 2.8.12)))
 838     # The build folder always has bin/ and lib/; if we are also going to
 839     # install to lib/, then the installation RPATH works also in the build
 840     # tree.  This makes installation slightly faster (no need to rewrite the
 841     # RPATHs), and makes the binaries in the build tree relocatable.
 842     if(GMX_LIB_INSTALL_DIR STREQUAL "lib")
 843         set(CMAKE_BUILD_WITH_INSTALL_RPATH TRUE)
 844     endif()
 845     # Set the RPATH as relative to the executable location to make the
 846     # binaries relocatable.
 847     if(NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin")
 848         set(CMAKE_INSTALL_RPATH "\$ORIGIN/../${GMX_LIB_INSTALL_DIR}")
 849     else()
 850         set(CMAKE_INSTALL_RPATH "@executable_path/../${GMX_LIB_INSTALL_DIR}")
 851     endif()
 852     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 853     set(CMAKE_MACOSX_RPATH 1)
 854 else()
 855     # We are on Darwin/OSX, and CMake cannot handle RPATHs automatically.
 856     if(CMAKE_SYSTEM_VERSION VERSION_GREATER 8.0)
 857         # Set the RPATH options manually.
 858         set(CMAKE_INSTALL_NAME_DIR "@rpath")
 859         set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} "-Wl,-rpath,@executable_path/../${GMX_LIB_INSTALL_DIR}")
 860     else()
 861         # Use the old INSTALL_NAME_DIR mechanism if RPATH is not supported.
 862         set(CMAKE_INSTALL_NAME_DIR "${CMAKE_INSTALL_PREFIX}/${LIB_INSTALL_DIR}")
 863     endif()
 864 endif()
 865
 866 #COPYING file: Only necessary for binary distributions.
 867 #Simpler to always install.
 868 install(FILES COPYING DESTINATION ${DATA_INSTALL_DIR} COMPONENT data)
 869
 870 if(GMX_EXTERNAL_BOOST)
 871     include_directories(${Boost_INCLUDE_DIRS})
 872     set(PKG_CFLAGS "${PKG_CFLAGS} -I${Boost_INCLUDE_DIRS}")
 873 else()
 874     include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src/external/boost)
 875     # typeid not supported for minimal internal version
 876     # (would add significant amount of code)
 877     add_definitions(-DBOOST_NO_TYPEID)
 878     # TODO: Propagate the above settings to the installed CMakeFiles.txt template
 879     # (from share/template/)
 880     set(PKG_CFLAGS "${PKG_CFLAGS} -DBOOST_NO_TYPEID -I${CMAKE_INSTALL_PREFIX}/${INCL_INSTALL_DIR}/gromacs/external/boost")
 881     if (NOT GMX_BUILD_MDRUN_ONLY)
 882         install(DIRECTORY ${CMAKE_SOURCE_DIR}/src/external/boost/boost
 883                 DESTINATION ${INCL_INSTALL_DIR}/gromacs/external/boost
 884                 COMPONENT development)
 885     endif()
 886 endif()
 887
 888 if (GMX_BUILD_FOR_COVERAGE)
 889     # Code heavy with asserts makes conditional coverage close to useless metric,
 890     # as by design most of the false branches are impossible to trigger in
 891     # correctly functioning code.  And the benefit of testing those that could
 892     # be triggered by using an API against its specification isn't usually
 893     # worth the effort.
 894     add_definitions(-DNDEBUG -DBOOST_DISABLE_ASSERTS -DGMX_DISABLE_ASSERTS)
 895 endif()
 896
 897 if (BUILD_TESTING)
 898     # "tests" target builds all the separate test binaries.
 899     add_custom_target(tests)
 900     # "run-ctest" is an internal target that actually runs the tests.
 901     # This is necessary to be able to add separate targets that execute as part
 902     # of 'make check', but are ensured to be executed after the actual tests.
 903     add_custom_target(run-ctest
 904                       COMMAND ${CMAKE_CTEST_COMMAND} --output-on-failure
 905                       COMMENT "Running all tests"
 906                       VERBATIM)
 907     add_dependencies(run-ctest tests)
 908     # "check" target builds and runs all tests.
 909     add_custom_target(check DEPENDS run-ctest)
 910 endif()
 911
 912 if (NOT GMX_BUILD_MDRUN_ONLY)
 913     add_subdirectory(doxygen)
 914     add_subdirectory(install-guide)
 915     add_subdirectory(share)
 916     add_subdirectory(scripts)
 917 endif()
 918 add_subdirectory(src)
 919
 920 if (BUILD_TESTING)
 921     add_subdirectory(tests)
 922 endif()
 923
 924 # Issue a warning if NVIDIA GPUs were detected, but CUDA was not found.
 925 # Don't bother the user after the first configure pass.
 926 if ((CUDA_NOTFOUND_AUTO AND GMX_DETECT_GPU_AVAILABLE) AND NOT GMX_GPU_DETECTION_DONE)
 927     message(WARNING "${CUDA_NOTFOUND_MESSAGE}")
 928 endif()
 929 set(GMX_GPU_DETECTION_DONE TRUE CACHE INTERNAL "Whether GPU detection has already been done")
 930
 931 #######################
 932 ## uninstall target
 933 #######################
 934 CONFIGURE_FILE(   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 935                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
 936                   IMMEDIATE @ONLY)
 937 ###########################
 938 ADD_CUSTOM_TARGET(uninstall
 939                   "${CMAKE_COMMAND}" -P
 940                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
 941 ###########################
 942 set_directory_properties(PROPERTIES
 943             ADDITIONAL_MAKE_CLEAN_FILES "install_manifest.txt")
 944
 945 ########################################################################
 946 # Manual                                                               #
 947 ########################################################################
 948
 949 option(GMX_BUILD_MANUAL "Whether to try to configure to build the PDF manual" OFF)
 950 mark_as_advanced(GMX_BUILD_MANUAL)
 951 if(GMX_BUILD_MANUAL)
 952     # Make sure we only do detection of manual-building dependencies
 953     # when the user opted in for that.
 954     add_subdirectory(manual)
 955 endif()