CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.8)
   2 # Keep CMake suitably quiet on Cygwin
   3 set(CMAKE_LEGACY_CYGWIN_WIN32 0) # Remove when CMake >= 2.8.4 is required
   4
   5 # override bugs on OS X where Cmake picks gcc (GNU) for C instead of system default cc (Clang).
   6 if(APPLE)
   7     set(CMAKE_C_COMPILER_INIT "cc")
   8 endif(APPLE)
   9
  10 project(Gromacs)
  11 include(Dart)
  12 mark_as_advanced(DART_ROOT)
  13
  14 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  15 set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  16 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
  17
  18 # PROJECT_VERSION should have the following structure:
  19 # VERSION-dev[-SUFFIX] where the VERSION should have the for: vMajor.vMinor.vPatch
  20 #
  21 # The "-dev" suffix is important to keep because it makes possible to distinguish
  22 # between a build from official release and a build from git release branch on a
  23 # machine with no git.
  24 #
  25 # NOTE: when releasing the "-dev" suffix needs to be stripped off!
  26 set(PROJECT_VERSION "5.0-dev")
  27 set(CUSTOM_VERSION_STRING ""
  28     CACHE STRING "Custom version string (if empty, use hard-coded default)")
  29 mark_as_advanced(CUSTOM_VERSION_STRING)
  30 if (CUSTOM_VERSION_STRING)
  31     set(PROJECT_VERSION ${CUSTOM_VERSION_STRING})
  32 endif (CUSTOM_VERSION_STRING)
  33 set(SOVERSION 6)
  34 # It is a bit irritating, but this has to be set separately for now!
  35 SET(CPACK_PACKAGE_VERSION_MAJOR "5")
  36 SET(CPACK_PACKAGE_VERSION_MINOR "0")
  37 #SET(CPACK_PACKAGE_VERSION_PATCH "0")
  38
  39
  40 # Cmake modules/macros are in a subdirectory to keep this file cleaner
  41 set(CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake)
  42
  43 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT AND UNIX)
  44 set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
  45 endif()
  46
  47 if (GMX_USE_RELATIVE_INSTALL_PATH)
  48     set(GMX_INSTALL_PREFIX "" CACHE STRING "Prefix gets appended to CMAKE_INSTALL_PREFIX. For cpack it sets the root folder of the archive.")
  49     mark_as_advanced(GMX_INSTALL_PREFIX)
  50 else()
  51     set(GMX_INSTALL_PREFIX "${CMAKE_INSTALL_PREFIX}/")
  52 endif()
  53
  54 if(NOT CMAKE_BUILD_TYPE)
  55     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel." FORCE)
  56 endif(NOT CMAKE_BUILD_TYPE)
  57
  58 enable_language(C)
  59 enable_language(CXX)
  60
  61 set(GMX_USE_RELATIVE_INSTALL_PATH OFF CACHE STRING "Use relative paths not absolute paths for cmake install. Has only an effect on cpack.")
  62 mark_as_advanced(GMX_USE_RELATIVE_INSTALL_PATH)
  63
  64 set(CPACK_PACKAGE_VERSION ${PROJECT_VERSION})
  65 set(CPACK_PACKAGE_VENDOR "gromacs.org")
  66 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Gromacs - a toolkit for high-performance molecular simulation")
  67 if (NOT GMX_USE_RELATIVE_INSTALL_PATH)
  68     set(CPACK_SET_DESTDIR "ON")
  69 endif()
  70 set(CPACK_RESOURCE_FILE_WELCOME "${CMAKE_SOURCE_DIR}/admin/InstallWelcome.txt")
  71 # Its GPL/LGPL, so they do not have to agree to a license for mere usage, but some installers require this...
  72 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_SOURCE_DIR}/admin/InstallLicense.txt")
  73 set(CPACK_RESOURCE_FILE_README "${CMAKE_SOURCE_DIR}/admin/InstallInfo.txt")
  74 set(CPACK_SOURCE_IGNORE_FILES ".isreposource;.git;.gitignore")
  75 set(CPACK_PROJECT_CONFIG_FILE "${CMAKE_SOURCE_DIR}/CPackInit.cmake")
  76 SET(CPACK_SOURCE_INSTALLED_DIRECTORIES "${CMAKE_SOURCE_DIR};/;${CMAKE_BINARY_DIR}/man;man")
  77
  78 #must come after all cpack settings!
  79 include(CPack)
  80
  81 ########################################################################
  82 # Check and warn if cache generated on a different host is being reused
  83 ########################################################################
  84 if(CMAKE_HOST_UNIX)
  85     execute_process(COMMAND hostname
  86                     OUTPUT_VARIABLE TMP_HOSTNAME
  87                     OUTPUT_STRIP_TRAILING_WHITESPACE)
  88     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}")
  89         message(WARNING "
  90             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
  91             is being reused! This could lead to inconsitencies; therefore, it is
  92             recommended to regenerate the cache!")
  93     endif()
  94     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
  95             "Hostname of the machine where the cache was generated.")
  96 endif()
  97
  98 ########################################################################
  99 # Fix stupid flags on Windows
 100 ########################################################################
 101 SET(SHARED_LIBS_DEFAULT ON)
 102 IF( WIN32 AND NOT CYGWIN)
 103   option(GMX_PREFER_STATIC_LIBS "When finding libraries prefer static system libraries (MT instead of MD)!" ON)
 104   mark_as_advanced(GMX_PREFER_STATIC_LIBS)
 105   SET(SHARED_LIBS_DEFAULT OFF)  #is currently not working on Windows
 106   # This makes windows.h not declare min/max as macros that would break
 107   # C++ code using std::min/std::max.
 108   add_definitions(-DNOMINMAX)
 109
 110   IF (GMX_PREFER_STATIC_LIBS)
 111     #Only setting Debug and Release flags. Others configurations current not used.
 112     STRING(REPLACE /MD /MT CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE})
 113     SET(CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE} CACHE STRING "" FORCE)
 114     STRING(REPLACE /MD /MT CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG})
 115     SET(CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG} CACHE STRING "" FORCE)
 116     STRING(REPLACE /MD /MT CMAKE_CXX_FLAGS_RELEASE ${CMAKE_CXX_FLAGS_RELEASE})
 117     SET(CMAKE_CXX_FLAGS_RELEASE ${CMAKE_CXX_FLAGS_RELEASE} CACHE STRING "" FORCE)
 118     STRING(REPLACE /MD /MT CMAKE_CXX_FLAGS_DEBUG ${CMAKE_CXX_FLAGS_DEBUG})
 119     SET(CMAKE_CXX_FLAGS_DEBUG ${CMAKE_CXX_FLAGS_DEBUG} CACHE STRING "" FORCE)
 120   ENDIF()
 121
 122   #Workaround for cmake bug 13174. Replace deprecated options.
 123   IF( CMAKE_C_COMPILER_ID MATCHES "Intel" )
 124     STRING(REPLACE /GZ /RTC1 CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG})
 125     SET(CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG} CACHE STRING "" FORCE)
 126   ENDIF()
 127   IF( CMAKE_CXX_COMPILER_ID MATCHES "Intel" )
 128     STRING(REPLACE /GZ /RTC1 CMAKE_CXX_FLAGS_DEBUG ${CMAKE_CXX_FLAGS_DEBUG})
 129     STRING(REPLACE /GX /EHsc CMAKE_CXX_FLAGS_DEBUG ${CMAKE_CXX_FLAGS_DEBUG})
 130     SET(CMAKE_CXX_FLAGS_DEBUG ${CMAKE_CXX_FLAGS_DEBUG} CACHE STRING "" FORCE)
 131
 132     STRING(REPLACE /GX /EHsc CMAKE_CXX_FLAGS_RELEASE ${CMAKE_CXX_FLAGS_RELEASE})
 133     SET(CMAKE_CXX_FLAGS_RELEASE ${CMAKE_CXX_FLAGS_RELEASE} CACHE STRING "" FORCE)
 134   ENDIF()
 135 ENDIF()
 136
 137 ########################################################################
 138 # User input options                                                   #
 139 ########################################################################
 140 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" OFF)
 141 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 142 option(GMX_THREAD_MPI  "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" ON)
 143 option(GMX_SOFTWARE_INVSQRT "Use GROMACS software 1/sqrt" ON)
 144 mark_as_advanced(GMX_SOFTWARE_INVSQRT)
 145 option(GMX_POWERPC_INVSQRT "Use PowerPC hardware 1/sqrt" OFF)
 146 mark_as_advanced(GMX_POWERPC_INVSQRT)
 147 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 148 mark_as_advanced(GMX_FAHCORE)
 149 option(GMX_OPENMM "Accelerated execution on GPUs through the OpenMM library (rerun cmake after changing to see relevant options)" OFF)
 150
 151 include(gmxDetectAcceleration)
 152 if(NOT DEFINED GMX_ACCELERATION)
 153     if(CMAKE_CROSSCOMPILING)
 154         set(GMX_SUGGESTED_ACCELERATION "None")
 155     else(CMAKE_CROSSCOMPILING)
 156         gmx_detect_acceleration(GMX_SUGGESTED_ACCELERATION)
 157     endif(CMAKE_CROSSCOMPILING)
 158 endif(NOT DEFINED GMX_ACCELERATION)
 159
 160 set(GMX_ACCELERATION "@GMX_SUGGESTED_ACCELERATION@"
 161     CACHE STRING "Accelerated kernels. Pick one of: None, SSE2, SSE4.1, AVX_128_FMA, AVX_256, BlueGene, Power6, Fortran")
 162
 163 set(GMX_FFT_LIBRARY "fftw3"
 164     CACHE STRING "FFT library choices: fftw3,mkl,fftpack[built-in]")
 165 option(GMX_DISABLE_FFTW_MEASURE
 166        "Do not optimize FFTW setups (not needed with SSE)" OFF)
 167 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 168 set(GMX_QMMM_PROGRAM "none"
 169     CACHE STRING "QM package choices: none,gaussian,mopac,gamess,orca")
 170 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 171 mark_as_advanced(GMX_BROKEN_CALLOC)
 172 option(GMX_MPI_IN_PLACE "Enable MPI_IN_PLACE for MPIs that have it defined" ON)
 173 mark_as_advanced(GMX_MPI_IN_PLACE)
 174 option(GMX_LOAD_PLUGINS "Compile with plugin support, needed to read VMD supported file formats" ON)
 175 mark_as_advanced(GMX_LOAD_PLUGINS)
 176
 177 option(GMX_OPENMP "Enable OpenMP-based mutithreading. " ON)
 178
 179 option(USE_VERSION_H "Generate development version string/information" ON)
 180 mark_as_advanced(USE_VERSION_H)
 181
 182 option(GMX_DEFAULT_SUFFIX "Use default suffixes for GROMACS binaries and libs (_d for double, _mpi for MPI; rerun cmake after changing to see relevant options)" ON)
 183
 184 if(UNIX AND NOT APPLE)
 185     option(GMX_PREFER_STATIC_LIBS "When finding libraries prefer \".a\" static archives (NOTE: this is enabled only for UNIX (excluding APPLE) platforms but it might not always work!" OFF)
 186     mark_as_advanced(GMX_PREFER_STATIC_LIBS)
 187 endif()
 188
 189
 190 ######################################################################
 191 # compiler tests
 192 # these need ot be done early (before further tests).
 193 #####################################################################
 194
 195 # cmake/Check{C,CXX}CompilerFlag.cmake are lifted from CMake git next
 196 # branch (proposed for v2.8.9) to be able to detect invalid options
 197 # with the Intel Compilers.
 198 # Remove these files from the source tree when a CMake version that
 199 # includes the features in question becomes required.
 200 include(CheckCCompilerFlag)
 201 include(CheckCXXCompilerFlag)
 202
 203 # OpenMP check must come before other CFLAGS!
 204 if(GMX_OPENMP)
 205     find_package(OpenMP)
 206     if(OPENMP_FOUND)
 207         #- only set linker flag, if user didn't set them manual
 208         #- cmake on windows doesn't support linker flags passed to target_link_libraries
 209         #  (cmake treats /openmp as \openmp library file) and no openmp linker flags are needed
 210         if(NOT (WIN32 AND NOT CYGWIN))
 211             if(CMAKE_COMPILER_IS_GNUCC AND GMX_PREFER_STATIC_OPENMP)
 212                 set(OpenMP_LINKER_FLAGS "-Wl,-static -lgomp -lrt -Wl,-Bdynamic -lpthread")
 213                 set(OpenMP_SHARED_LINKER_FLAGS "")
 214             else()
 215                 if(NOT DEFINED OpenMP_LINKER_FLAGS)
 216                     set(OpenMP_LINKER_FLAGS "${OpenMP_C_FLAGS}")
 217                 endif()
 218                 if(NOT DEFINED OpenMP_SHARED_LINKER_FLAGS)
 219                     set(OpenMP_SHARED_LINKER_FLAGS "${OpenMP_C_FLAGS}")
 220                 endif()
 221             endif()
 222         endif()
 223     else(OPENMP_FOUND)
 224         message(WARNING
 225                 "Compiler not supporting OpenMP. This might hurt your performance a lot, "
 226                 "in particular with GPUs. Try using a different compiler (Intel is good on x86) "
 227                 "if you can - for now we are proceeding by turning off OpenMP.")
 228         set(GMX_OPENMP OFF CACHE STRING "Compiler does not support OpenMP." FORCE)
 229     endif(OPENMP_FOUND)
 230 endif()
 231
 232
 233 include(gmxCFlags)
 234 gmx_c_flags()
 235
 236 ########################################################################
 237 # Set up binary and library suffixing
 238 ########################################################################
 239 set(GMX_BINARY_SUFFIX "" CACHE STRING "Suffix for GROMACS binaries (default: _d for double, _mpi for MPI, _mpi_d for MPI and double).")
 240 set(GMX_LIBS_SUFFIX ""
 241   CACHE STRING "Suffix for GROMACS libs (default: _d for double, _mpi for MPI, _mpi_d for MPI and double).")
 242 if (GMX_DEFAULT_SUFFIX)
 243   set(GMX_BINARY_SUFFIX "")
 244   set(GMX_LIBS_SUFFIX "")
 245   if (GMX_MPI)
 246     set(GMX_BINARY_SUFFIX "_mpi")
 247     set(GMX_LIBS_SUFFIX "_mpi")
 248   endif(GMX_MPI)
 249   if (GMX_DOUBLE)
 250     set (GMX_BINARY_SUFFIX "${GMX_BINARY_SUFFIX}_d")
 251     set (GMX_LIBS_SUFFIX "${GMX_LIBS_SUFFIX}_d")
 252   endif(GMX_DOUBLE)
 253   if (GMX_OPENMM)
 254     set (GMX_BINARY_SUFFIX "-openmm")
 255     set (GMX_LIBS_SUFFIX "_openmm")
 256   endif(GMX_OPENMM)
 257   mark_as_advanced(FORCE GMX_BINARY_SUFFIX GMX_LIBS_SUFFIX)
 258   if (NOT SUFFIX_QUIETLY)
 259     message(STATUS "Using default binary suffix: \"${GMX_BINARY_SUFFIX}\"")
 260     message(STATUS "Using default library suffix: \"${GMX_LIBS_SUFFIX}\"")
 261   endif (NOT SUFFIX_QUIETLY)
 262 else(GMX_DEFAULT_SUFFIX)
 263   mark_as_advanced(CLEAR GMX_BINARY_SUFFIX GMX_LIBS_SUFFIX)
 264   if (NOT SUFFIX_QUIETLY)
 265     message(STATUS "Using manually set binary suffix: \"${GMX_BINARY_SUFFIX}\"")
 266     message(STATUS "Using manually set library suffix: \"${GMX_LIBS_SUFFIX}\"")
 267   endif (NOT SUFFIX_QUIETLY)
 268 endif(GMX_DEFAULT_SUFFIX)
 269 set(SUFFIX_QUIETLY TRUE CACHE INTERNAL "")
 270
 271 set(PKG_CFLAGS "")
 272 if(GMX_DOUBLE)
 273     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_DOUBLE")
 274 endif(GMX_DOUBLE)
 275 if(GMX_SOFTWARE_INVSQRT)
 276   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_SOFTWARE_INVSQRT")
 277 endif(GMX_SOFTWARE_INVSQRT)
 278 if(GMX_POWERPC_INVSQRT)
 279   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_POWERPC_INVSQRT")
 280 endif(GMX_POWERPC_INVSQRT)
 281
 282 ########################################################################
 283 #Process MPI settings
 284 ########################################################################
 285 include(gmxManageMPI)
 286
 287 #######################################################################
 288 # Check for options incompatible with OpenMM build                    #
 289 #######################################################################
 290 if(GMX_OPENMM)
 291     # we'll use the built-in fft to avoid unnecessary dependencies
 292     string(TOUPPER ${GMX_FFT_LIBRARY} GMX_FFT_LIBRARY)
 293     if(NOT ${GMX_FFT_LIBRARY} STREQUAL "FFTPACK")
 294         message(STATUS "No external FFT libraries needed for the OpenMM build, switching to fftpack!")
 295         set(GMX_FFT_LIBRARY "fftpack" CACHE STRING
 296                 "No external FFT libraries needed for the OpenMM build, switching to  fftpack!" FORCE)
 297     endif()
 298     if(GMX_MPI)
 299         message(FATAL_ERROR "The OpenMM build is not compatible with MPI!")
 300     endif(GMX_MPI)
 301     if(GMX_THREAD_MPI)
 302         message(STATUS "Thread-MPI not compatible with OpenMM, disabled!")
 303         set(GMX_THREAD_MPI OFF CACHE BOOL
 304                 "Thread-MPI not compatible with OpenMM build, disabled!" FORCE)
 305     endif(GMX_THREAD_MPI)
 306     if(GMX_OPENMP)
 307         message(STATUS "OpenMP multithreading not compatible with OpenMM, disabled")
 308         set(GMX_OPENMP OFF CACHE BOOL
 309             "OpenMP multithreading not compatible with OpenMM, disabled!" FORCE)
 310     endif()
 311     if(GMX_SOFTWARE_INVSQRT)
 312         set(GMX_SOFTWARE_INVSQRT OFF CACHE STRING
 313                 "The OpenMM build does not need GROMACS software 1/sqrt!" FORCE)
 314     endif(GMX_SOFTWARE_INVSQRT)
 315     string(TOUPPER ${GMX_ACCELERATION} GMX_ACCELERATION)
 316     if(NOT GMX_ACCELERATION STREQUAL "NONE")
 317         message(STATUS "Switching off CPU-based acceleration, the OpenMM build does not support/need any!")
 318         set(GMX_ACCELERATION "none" CACHE STRING
 319                 "Switching off CPU-based acceleration, the OpenMM build does not support/need any!" FORCE)
 320     endif()
 321     if(GMX_FAHCORE)
 322         message(FATAL_ERROR "The OpenMM build does not support FAH build!")
 323     endif(GMX_FAHCORE)
 324     if(GMX_DOUBLE)
 325         message(FATAL_ERROR  "The OpenMM-build does not support double precision calculations!")
 326     endif()
 327     # mark as advanced the unused variables
 328     mark_as_advanced(FORCE GMX_ACCELERATION GMX_MPI GMX_FFT_LIBRARY
 329         GMX_QMMM_PROGRAM GMX_THREAD_MPI GMX_DOUBLE)
 330 else(GMX_OPENMM)
 331      mark_as_advanced(CLEAR GMX_ACCELERATION GMX_MPI GMX_FFT_LIBRARY
 332         GMX_QMMM_PROGRAM GMX_THREAD_MPI GMX_DOUBLE)
 333 endif(GMX_OPENMM)
 334
 335
 336
 337
 338 ########################################################################
 339 # Basic system tests (standard libraries, headers, functions, types)   #
 340 ########################################################################
 341 include(CheckIncludeFiles)
 342 check_include_files(unistd.h     HAVE_UNISTD_H)
 343 check_include_files(pwd.h        HAVE_PWD_H)
 344 check_include_files(pthread.h    HAVE_PTHREAD_H)
 345 check_include_files(dirent.h     HAVE_DIRENT_H)
 346 check_include_files(regex.h      HAVE_REGEX_H)
 347 check_include_files(sys/types.h  HAVE_SYS_TYPES_H)
 348 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 349 check_include_files(io.h                 HAVE_IO_H)
 350
 351
 352 include(CheckFunctionExists)
 353 check_function_exists(strdup            HAVE_STRDUP)
 354 check_function_exists(posix_memalign    HAVE_POSIX_MEMALIGN)
 355 check_function_exists(memalign          HAVE_MEMALIGN)
 356 check_function_exists(_aligned_malloc   HAVE__ALIGNED_MALLOC)
 357 check_function_exists(gettimeofday      HAVE_GETTIMEOFDAY)
 358 check_function_exists(fsync             HAVE_FSYNC)
 359 check_function_exists(_fileno           HAVE__FILENO)
 360 check_function_exists(fileno            HAVE_FILENO)
 361 check_function_exists(_commit           HAVE__COMMIT)
 362 check_function_exists(lstat             HAVE_LSTAT)
 363 check_function_exists(sigaction         HAVE_SIGACTION)
 364
 365 include(CheckLibraryExists)
 366 check_library_exists(m sqrt "" HAVE_LIBM)
 367 check_library_exists(m cbrt "" HAVE_CBRT)
 368
 369
 370 include(CheckTypeSize)
 371
 372 check_type_size("int"           SIZEOF_INT)
 373 check_type_size("long int"      SIZEOF_LONG_INT)
 374 check_type_size("long long int" SIZEOF_LONG_LONG_INT)
 375 check_type_size("off_t"         SIZEOF_OFF_T)
 376 check_type_size("void *"        SIZEOF_VOIDP)
 377
 378 if (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 379     set(GMX_64_BIT TRUE)
 380 else (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 381     set(GMX_64_BIT FALSE)
 382 endif (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 383
 384 include(TestBigEndian)
 385 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 386
 387
 388
 389
 390 ########################################################################
 391 # Find external packages                                               #
 392 ########################################################################
 393 if(UNIX AND NOT APPLE)
 394     if(GMX_PREFER_STATIC_LIBS)
 395         SET(CMAKE_FIND_LIBRARY_SUFFIXES .a ${CMAKE_FIND_LIBRARY_SUFFIXES})
 396         if(SHARED_LIBS_DEFAULT)
 397             if(BUILD_SHARED_LIBS) #Warn the user about the combination. But don't overwrite the request.
 398                 message(WARNING "Static libraries requested, and shared Gromacs libraries requested.")
 399             elseif(NOT DEFINED BUILD_SHARED_LIBS) #Change default to OFF. Don't warn if it's already off.
 400                 message(WARNING "Static libraries requested, the GROMACS libraries will also be build static (BUILD_SHARED_LIBS=OFF)")
 401                 set(SHARED_LIBS_DEFAULT OFF)
 402             endif()
 403         endif()
 404     endif()
 405 endif()
 406 option(BUILD_SHARED_LIBS "Enable shared libraries (can be problematic with MPI, Windows)" ${SHARED_LIBS_DEFAULT})
 407
 408 option(GMX_XML "Use libxml2 to parse xml files" ON)
 409 if (GMX_XML)
 410   find_package(LibXml2)
 411   set(PKG_XML "")
 412   if(LIBXML2_FOUND)
 413     include_directories(${LIBXML2_INCLUDE_DIR})
 414     set(PKG_XML libxml-2.0)
 415     set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 416   endif(LIBXML2_FOUND)
 417 endif(GMX_XML)
 418
 419 option(GMX_GSL "Add support for gsl" OFF)
 420 if (GMX_GSL)
 421   find_package(gsl)
 422   set(PKG_GSL "")
 423   if(GSL_FOUND)
 424     include_directories(${GSL_INCLUDE_DIR})
 425     set(PKG_GSL gsl)
 426     set(HAVE_LIBGSL 1)
 427   endif(GSL_FOUND)
 428 endif (GMX_GSL)
 429
 430 option(GMX_X11 "Use X window system" OFF)
 431 if (GMX_X11)
 432         find_package(X11)
 433         # X11 includes/libraries are only set in the ngmx subdirectory!
 434         if(X11_FOUND)
 435         set(HAVE_X11 1)
 436         endif(X11_FOUND)
 437 endif(GMX_X11)
 438
 439 include(ThreadMPI)
 440 set(THREAD_MPI_LIB thread_mpi)
 441 if(GMX_THREAD_MPI)
 442     tmpi_get_source_list(THREAD_MPI_SRC CXX)
 443     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_THREAD_MPI")
 444     set(GMX_MPI 1)
 445 else(GMX_THREAD_MPI)
 446     tmpi_get_source_list(THREAD_MPI_SRC CXX NOMPI)
 447 endif(GMX_THREAD_MPI)
 448
 449 if(GMX_OPENMM)
 450     set(CUDA_BUILD_EMULATION OFF)
 451     find_package(CUDA 3.1 REQUIRED)
 452     add_definitions(-DGMX_OPENMM)
 453     if(CMAKE_BUILD_TYPE STREQUAL "DEBUG")
 454         set(CUDA_VERBOSE_BUILD ON)
 455     endif()
 456     find_package(OpenMM)
 457 endif(GMX_OPENMM)
 458
 459
 460 if(APPLE)
 461    find_library(ACCELERATE_FRAMEWORK Accelerate)
 462    list(APPEND GMX_EXTRA_LIBRARIES ${ACCELERATE_FRAMEWORK})
 463 endif(APPLE)
 464
 465 if(CYGWIN)
 466     set(GMX_CYGWIN 1)
 467 endif(CYGWIN)
 468
 469 if(WIN32 AND NOT CYGWIN)
 470     set(GMX_NATIVE_WINDOWS 1)
 471 endif()
 472
 473 # only bother with finding git and using version.h if the source is a git repo
 474 if(EXISTS "${CMAKE_SOURCE_DIR}/.git")
 475     if(USE_VERSION_H)
 476         # We need at least git v1.5.3 be able to parse git's date output. If not
 477         # found or the version is too small, we can't generate version information.
 478         find_package(Git)
 479
 480         # Find out the git version
 481         if(GIT_FOUND AND NOT GIT_VERSION)
 482           execute_process(COMMAND ${GIT_EXECUTABLE} "--version"
 483             OUTPUT_VARIABLE _exec_out
 484             OUTPUT_STRIP_TRAILING_WHITESPACE)
 485           string(REGEX REPLACE "git version (.*)" "\\1" GIT_VERSION ${_exec_out})
 486           set(GIT_VERSION ${GIT_VERSION} CACHE STRING "Git version")
 487           mark_as_advanced(GIT_VERSION)
 488         endif()
 489
 490         if(NOT GIT_FOUND OR GIT_VERSION VERSION_LESS "1.5.3")
 491           message("No compatible git version found, won't be able to generate proper development version information.")
 492           set(USE_VERSION_H OFF)
 493         endif()
 494     endif()
 495 else()
 496     set(USE_VERSION_H OFF)
 497 endif()
 498
 499 option(GMX_INTERNAL_BOOST "Use minimal internal version of boost" OFF)
 500 if ( NOT GMX_INTERNAL_BOOST )
 501   find_package( Boost 1.44.0 )
 502 else ( NOT GMX_INTERNAL_BOOST )
 503   set (Boost_FOUND FALSE)
 504 endif( NOT GMX_INTERNAL_BOOST )
 505
 506 if(Boost_FOUND AND NOT Boost_VERSION VERSION_LESS "104400" )
 507   include_directories(${Boost_INCLUDE_DIRS})
 508 else()
 509   if(NOT BOOST_QUIETLY)
 510     message("Boost >= 1.44 not found. Using minimal internal version. Not recommended if GROMACS is used as library!")
 511   endif()
 512   include_directories(${CMAKE_SOURCE_DIR}/src/external/boost)
 513   add_definitions( -DBOOST_NO_TYPEID )  #TYPEID not supported for minimal internal version (would add significant more code)
 514   # TODO: Propagate the above settings to the installed CMakeFiles.txt template
 515   # (from share/template/)
 516   # TODO: Reorder stuff such that INCL_INSTALL_DIR could be used here
 517   set(PKG_CFLAGS "${PKG_CFLAGS} -DBOOST_NO_TYPEID -I${GMX_INSTALL_PREFIX}include/gromacs/external/boost")
 518   install(DIRECTORY ${CMAKE_SOURCE_DIR}/src/external/boost/boost
 519           DESTINATION ${GMX_INSTALL_PREFIX}include/gromacs/external/boost
 520           COMPONENT development)
 521 endif()
 522 set(BOOST_QUIETLY TRUE CACHE INTERNAL "")
 523
 524 if (LIBXML2_FOUND)
 525     option(GMX_BUILD_UNITTESTS "Build unit tests with BUILD_TESTING (uses Google C++ Testing and Mocking Frameworks, requires libxml2)" ON)
 526 else (LIBXML2_FOUND)
 527     set(GMX_BUILD_UNITTESTS OFF)
 528 endif (LIBXML2_FOUND)
 529 mark_as_advanced(GMX_BUILD_UNITTESTS)
 530 set(MEMORYCHECK_SUPPRESSIONS_FILE ${CMAKE_SOURCE_DIR}/cmake/legacy_and_external.supp)
 531
 532 ########################################################################
 533 # Generate development version info for cache
 534 ########################################################################
 535 # set(GEN_VERSION_INFO_INTERNAL "ON")
 536 # include(gmxGenerateVersionString)
 537
 538 ########################################################################
 539 # Our own GROMACS tests
 540 ########################################################################
 541
 542 add_definitions( -DHAVE_CONFIG_H )
 543 include_directories(${CMAKE_SOURCE_DIR}/src)
 544 # Required for config.h, maybe should only be set in src/CMakeLists.txt
 545 include_directories(${CMAKE_BINARY_DIR}/src)
 546 # Required for gmx_header_config_gen.h to be found before installation
 547 include_directories(${CMAKE_BINARY_DIR}/src/gromacs/utility)
 548 # Required for now to make old code compile
 549 include_directories(${CMAKE_SOURCE_DIR}/src/gromacs/legacyheaders)
 550
 551 include(gmxTestInlineASM)
 552 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 553
 554 include(gmxSetBuildInformation)
 555 gmx_set_build_information()
 556 if(BUILD_CPU_FEATURES MATCHES "rdtscp")
 557     # The timestep counter headers do not include config.h
 558     add_definitions(-DHAVE_RDTSCP)
 559 endif(BUILD_CPU_FEATURES MATCHES "rdtscp")
 560
 561 include(gmxTestFloatFormat)
 562 gmx_test_float_format(GMX_FLOAT_FORMAT_IEEE754
 563                       GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER
 564                       GMX_IEEE754_BIG_ENDIAN_WORD_ORDER)
 565
 566 include(gmxTestLargeFiles)
 567 gmx_test_large_files(GMX_LARGEFILES)
 568 check_function_exists(fseeko     HAVE_FSEEKO)
 569
 570 include(gmxTestSignal)
 571 gmx_test_sigusr1(HAVE_SIGUSR1)
 572
 573 include(gmxTestInline)
 574 gmx_test_inline(INLINE_KEYWORD)
 575
 576 include(gmxTestPipes)
 577 gmx_test_pipes(HAVE_PIPES)
 578
 579 include(gmxTestIsfinite)
 580 gmx_test_isfinite(HAVE_ISFINITE)
 581 gmx_test__isfinite(HAVE__ISFINITE)
 582 gmx_test__finite(HAVE__FINITE)
 583
 584 include(gmxTestCXX11)
 585 gmx_test_cxx11(GMX_CXX11 CXX11_FLAG)
 586 set(GROMACS_CXX_FLAGS "${CXX11_FLAG} ${GROMACS_CXX_FLAGS}")
 587
 588 include(gmxTestXDR)
 589 gmx_test_xdr(GMX_SYSTEM_XDR)
 590 if(NOT GMX_SYSTEM_XDR)
 591     set(GMX_INTERNAL_XDR 1)
 592     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_INTERNAL_XDR")
 593 endif(NOT GMX_SYSTEM_XDR)
 594
 595 # Process nonbonded accelerated kernels settings
 596 string(TOUPPER ${GMX_ACCELERATION} ${GMX_ACCELERATION})
 597 if(${GMX_ACCELERATION} STREQUAL "NONE")
 598     # nothing to do
 599 elseif(${GMX_ACCELERATION} STREQUAL "SSE2")
 600
 601     GMX_TEST_CFLAG(GNU_SSE2_CFLAG "-msse2" GROMACS_C_FLAGS)
 602     if(NOT GNU_SSE2_CFLAG)
 603         GMX_TEST_CFLAG(MSVC_SSE2_CFLAG "/arch:SSE2" GROMACS_C_FLAGS)
 604     endif(NOT GNU_SSE2_CFLAG)
 605
 606     GMX_TEST_CXXFLAG(GNU_SSE2_CXXFLAG "-msse2" GROMACS_CXX_FLAGS)
 607     if(NOT GNU_SSE2_CXXFLAG)
 608         GMX_TEST_CXXFLAG(MSVC_SSE2_CXXFLAG "/arch:SSE2" GROMACS_CXX_FLAGS)
 609     endif(NOT GNU_SSE2_CXXFLAG)
 610
 611     # We dont warn for lacking SSE2 flag support, since that is probably standard today.
 612
 613     # Only test the include after we have tried to add the correct flag for SSE2 support
 614     check_include_file(emmintrin.h  HAVE_EMMINTRIN_H ${GROMACS_C_FLAGS})
 615
 616     if(NOT HAVE_EMMINTRIN_H)
 617         message(FATAL_ERROR "Cannot find emmintrin.h, which is required for SSE2 intrinsics support.")
 618     endif(NOT HAVE_EMMINTRIN_H)
 619
 620     # The user should not be able to set this orthogonally to the acceleration
 621     set(GMX_X86_SSE2 1)
 622     if (NOT ACCELERATION_QUIETLY)
 623       message(STATUS "Enabling SSE2 Gromacs acceleration, and it will help compiler optimization.")
 624     endif()
 625
 626 elseif(${GMX_ACCELERATION} STREQUAL "SSE4.1")
 627
 628     GMX_TEST_CFLAG(GNU_SSE4_CFLAG "-msse4.1" GROMACS_C_FLAGS)
 629     if (NOT GNU_SSE4_CFLAG)
 630         GMX_TEST_CFLAG(MSVC_SSE4_CFLAG "/arch:SSE4.1" GROMACS_C_FLAGS)
 631     endif(NOT GNU_SSE4_CFLAG)
 632     if (NOT GNU_SSE4_CFLAG AND NOT MSVC_SSE4_CFLAG)
 633         message(WARNING "No C SSE4.1 flag found. Consider a newer compiler, or disable SSE4.1 for slightly lower performance.")
 634         # Not surprising if we end up here! MSVC current does not support the SSE4.1 flag. However, it appears to accept SSE4.1
 635         # intrinsics when SSE2 support is enabled, so we try that instead.
 636         GMX_TEST_CFLAG(MSVC_SSE2_CFLAG "/arch:SSE2" GROMACS_C_FLAGS)
 637     endif(NOT GNU_SSE4_CFLAG AND NOT MSVC_SSE4_CFLAG)
 638
 639     GMX_TEST_CXXFLAG(GNU_SSE4_CXXFLAG "-msse4.1" GROMACS_CXX_FLAG)
 640     if (NOT GNU_SSE4_CXXFLAG)
 641        GMX_TEST_CXXFLAG(MSVC_SSE4_CXXFLAG "/arch:SSE4.1" GROMACS_CXX_FLAGS)
 642     endif(NOT GNU_SSE4_CXXFLAG)
 643     if (NOT GNU_SSE4_CXXFLAG AND NOT MSVC_SSE4_CXXFLAG)
 644         message(WARNING "No C++ SSE4.1 flag found. Consider a newer compiler, or disable SSE4.1 for slightly lower performance.")
 645         # Not surprising if we end up here! MSVC current does not support the SSE4.1 flag. However, it appears to accept SSE4.1
 646         # intrinsics when SSE2 support is enabled, so we try that instead.
 647         GMX_TEST_CXXFLAG(MSVC_SSE2_CXXFLAG "/arch:SSE2" GROMACS_CXX_FLAGS)
 648     endif(NOT GNU_SSE4_CXXFLAG AND NOT MSVC_SSE4_CXXFLAG)
 649
 650     # This must come after we have added the -msse4.1 flag on some platforms.
 651     check_include_file(smmintrin.h  HAVE_SMMINTRIN_H ${GROMACS_C_FLAGS})
 652
 653     if(NOT HAVE_SMMINTRIN_H)
 654         message(FATAL_ERROR "Cannot find smmintrin.h, which is required for SSE4.1 intrinsics support.")
 655     endif(NOT HAVE_SMMINTRIN_H)
 656
 657     # The user should not be able to set this orthogonally to the acceleration
 658     set(GMX_X86_SSE4_1 1)
 659     set(GMX_X86_SSE2   1)
 660     if (NOT ACCELERATION_QUIETLY)
 661       message(STATUS "Enabling SSE4.1 Gromacs acceleration, and it will help compiler optimization.")
 662     endif()
 663
 664 elseif(${GMX_ACCELERATION} STREQUAL "AVX_128_FMA" OR ${GMX_ACCELERATION} STREQUAL "AVX_256")
 665
 666     # Set the AVX compiler flag for both these choices!
 667
 668     GMX_TEST_CFLAG(GNU_AVX_CFLAG "-mavx" GROMACS_C_FLAGS)
 669     if (NOT GNU_AVX_CFLAG)
 670         GMX_TEST_CFLAG(MSVC_AVX_CFLAG "/arch:AVX" GROMACS_C_FLAGS)
 671     endif (NOT GNU_AVX_CFLAG)
 672     if (NOT GNU_AVX_CFLAG AND NOT MSVC_AVX_CFLAG)
 673         message(WARNING "No C AVX flag found. Consider a newer compiler, or disable AVX for much lower performance.")
 674     endif (NOT GNU_AVX_CFLAG AND NOT MSVC_AVX_CFLAG)
 675
 676     GMX_TEST_CXXFLAG(GNU_AVX_CXXFLAG "-mavx" GROMACS_CXX_FLAGS)
 677     if (NOT GNU_AVX_CXXFLAG)
 678        GMX_TEST_CXXFLAG(MSVC_AVX_CXXFLAG "/arch:AVX" GROMACS_CXX_FLAGS)
 679     endif (NOT GNU_AVX_CXXFLAG)
 680     if (NOT GNU_AVX_CXXFLAG AND NOT MSVC_AVX_CXXFLAG)
 681        message(WARNING "No C++ AVX flag found. Consider a newer compiler, or disable AVX for much lower performance.")
 682     endif (NOT GNU_AVX_CXXFLAG AND NOT MSVC_AVX_CXXFLAG)
 683
 684     # Only test the header after we have tried to add the flag for AVX support
 685     check_include_file(immintrin.h  HAVE_IMMINTRIN_H ${GROMACS_C_FLAGS})
 686
 687     if(NOT HAVE_IMMINTRIN_H)
 688         message(FATAL_ERROR "Cannot find immintrin.h, which is required for AVX intrinsics support. Consider switching compiler.")
 689     endif(NOT HAVE_IMMINTRIN_H)
 690
 691     # AMD says we should include x86intrin.h for FMA support, but MSVC seems to do fine without it, so don't require it.
 692     check_include_file(x86intrin.h HAVE_X86INTRIN_H ${GROMACS_C_FLAGS})
 693
 694     # The user should not be able to set this orthogonally to the acceleration
 695     set(GMX_X86_SSE4_1 1)
 696     set(GMX_X86_SSE2   1)
 697
 698     # But just enable one of the choices internally...
 699     if(${GMX_ACCELERATION} STREQUAL "AVX_128_FMA")
 700         set(GMX_X86_AVX_128_FMA 1)
 701         if (NOT ACCELERATION_QUIETLY)
 702           message(STATUS "Enabling 128-bit AVX Gromacs acceleration (with fused-multiply add), and it will help compiler optimization.")
 703         endif()
 704     else()
 705         # If we are not doing AVX_128, it must be AVX_256...
 706         set(GMX_X86_AVX_256 1)
 707         if (NOT ACCELERATION_QUIETLY)
 708           message(STATUS "Enabling 256-bit AVX Gromacs acceleration, and it will help compiler optimization.")
 709         endif()
 710     endif()
 711
 712 elseif(${GMX_ACCELERATION} STREQUAL "FORTRAN")
 713
 714 #    Fortran is temporarily disabled while we push in nbNxN kernels.
 715 #    We need to fake it a bit here to avoid jenkins build errors!
 716 #    add_definitions(-DGMX_FORTRAN)
 717
 718 elseif(${GMX_ACCELERATION} STREQUAL "BLUEGENE")
 719 # GMX_ACCELERATION=BlueGene should be set in the Toolchain-BlueGene?-???.cmake file
 720     if (NOT ACCELERATION_QUIETLY)
 721       message(STATUS "Configuring for BlueGene")
 722     endif()
 723     set(GMX_BLUEGENE 1)
 724     if (${CMAKE_SYSTEM_NAME} STREQUAL "BlueGeneL")
 725         set(SHARED_LIBS_DEFAULT OFF CACHE BOOL "Shared libraries not compatible with BlueGene/L, disabled!" FORCE)
 726         set(BUILD_SHARED_LIBS OFF CACHE BOOL "Shared libraries not compatible with BlueGene/L, disabled!" FORCE)
 727     endif (${CMAKE_SYSTEM_NAME} STREQUAL "BlueGeneL")
 728     set(GMX_SOFTWARE_INVSQRT OFF CACHE BOOL "Do not use software reciprocal square root on BlueGene" FORCE)
 729     set(GMX_POWERPC_INVSQRT ON CACHE BOOL "Use hardware reciprocal square root on BlueGene" FORCE)
 730     set(GMX_X11 OFF CACHE BOOL "X11 not compatible with BlueGene, disabled!" FORCE)
 731     set(GMX_THREAD_MPI OFF CACHE BOOL "Thread-MPI not compatible with BlueGene, disabled!" FORCE)
 732     set(GMX_MPI ON CACHE BOOL "Use MPI on BlueGene" FORCE)
 733 # Access to /etc/passwd is not available on the back end of BlueGene,
 734 # despite being detected by CMake. This can cause linker warnings
 735 # about harmless things in src/gmxlib/string2.h.
 736     set(HAVE_PWD_H OFF)
 737 # The automatic testing for endianness does not work for the BlueGene cross-compiler
 738     set(GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER 1 CACHE INTERNAL "BlueGene has big endian FP byte order (by default)" FORCE)
 739     set(GMX_IEEE754_BIG_ENDIAN_WORD_ORDER 1 CACHE INTERNAL "BlueGene has big endian FP word order (by default)" FORCE)
 740 elseif(${GMX_ACCELERATION} STREQUAL "POWER6")
 741     set(GMX_POWER6 1)
 742     set(GMX_SOFTWARE_INVSQRT OFF CACHE BOOL "Do not use software reciprocal square root on Power6" FORCE)
 743     set(GMX_POWERPC_INVSQRT ON CACHE BOOL "Use hardware reciprocal square root on Power6" FORCE)
 744 else(${GMX_ACCELERATION} STREQUAL "NONE")
 745     MESSAGE(FATAL_ERROR "Unrecognized option for accelerated kernels: ${GMX_ACCELERATION}. Pick one of None, SSE2, SSE4.1, AVX_128_FMA, AVX_256, Fortran, BlueGene, Power6")
 746 endif(${GMX_ACCELERATION} STREQUAL "NONE")
 747 set(ACCELERATION_QUIETLY TRUE CACHE INTERNAL "")
 748
 749 if(GMX_FORTRAN OR GMX_POWER6)
 750     if (GMX_THREAD_MPI)
 751         message(FATAL_ERROR "FORTRAN/POWER6 is incompatible with thread-MPI and only provides a speed-up on certain IBM compilers. Disable FORTRAN (or threads if you really want to use FORTRAN kernels).")
 752     endif(GMX_THREAD_MPI)
 753     enable_language(Fortran)
 754     include(FortranCInterface)
 755     discover_fortran_mangling(prefix isupper suffix extra_under_score found)
 756     if(extra_under_score)
 757         set(extrasuffix "_")
 758     endif(extra_under_score)
 759     if(prefix)
 760       set(prefix "${prefix} ##")
 761     endif(prefix)
 762     if(suffix)
 763       set(suffix "## ${suffix}")
 764       if(extrasuffix)
 765         set(extrasuffix "${suffix}${extrasuffix}")
 766       endif(extrasuffix)
 767     else(suffix)
 768       if(extrasuffix)
 769         # Don't know if this is needed, but it can't hurt
 770         set(extrasuffix "## ${extrasuffix}")
 771       endif(extrasuffix)
 772     endif(suffix)
 773
 774     if(isupper)
 775         set(F77_FUNCDEF   "${prefix} NAME ${suffix}")
 776         # The underscored versions are not currently used.
 777         #set(F77_FUNCDEF_  "${prefix} NAME ${extrasuffix}")
 778     else(isupper)
 779         set(F77_FUNCDEF   "${prefix} name ${suffix}")
 780         #set(F77_FUNCDEF_  "${prefix} name ${extrasuffix}")
 781     endif(isupper)
 782 else(GMX_FORTRAN OR GMX_POWER6)
 783         set(F77_FUNCDEF   "name ## _")
 784         #set(F77_FUNCDEF_  "name ## _")
 785 endif(GMX_FORTRAN OR GMX_POWER6)
 786
 787 # Process QM/MM Settings
 788 string(TOUPPER ${GMX_QMMM_PROGRAM} ${GMX_QMMM_PROGRAM})
 789 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 790     set(GMX_QMMM_GAUSSIAN 1)
 791 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 792     set(GMX_QMMM_MOPAC 1)
 793 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 794     set(GMX_QMMM_GAMESS 1)
 795 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 796     set(GMX_QMMM_ORCA 1)
 797 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 798     # nothing to do
 799 else(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 800     MESSAGE(FATAL_ERROR "Invalid QM/MM program option: ${GMX_QMMM_PROGRAM}. Choose one of: Gaussian, Mopac, Gamess, Orca, None")
 801 endif(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 802
 803 # Process FFT library settings - if not OpenMM build
 804 string(TOUPPER ${GMX_FFT_LIBRARY} ${GMX_FFT_LIBRARY})
 805 set(PKG_FFT "")
 806 set(PKG_FFT_LIBS "")
 807 if(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 808     if(GMX_DOUBLE)
 809         find_package(FFTW 3 COMPONENTS fftw)
 810     else(GMX_DOUBLE)
 811         find_package(FFTW 3 COMPONENTS fftwf)
 812     endif(GMX_DOUBLE)
 813     if(NOT FFTW_FOUND)
 814       MESSAGE(FATAL_ERROR "Cannot find FFTW3 (with correct precision - libfftw3f for single precision GROMACS or libfftw3 for double precision GROMACS). Fix it, choose another FFT library, or use the Gromacs built-in fftpack (slower)!")
 815     endif(NOT FFTW_FOUND)
 816     include_directories(${FFTW_INCLUDE_DIRS})
 817     set(FFT_LIBRARIES ${FFTW_LIBRARIES})
 818     set(PKG_FFT "${FFTW_PKG}")
 819
 820     set(GMX_FFT_FFTW3 1)
 821
 822     if (${GMX_ACCELERATION} STREQUAL "SSE" AND NOT FFTW_HAVE_SSE)
 823       message(WARNING "The fftw library found is compiled without SSE support, which makes it slow. Consider recompiling it or contact your admin")
 824     endif (${GMX_ACCELERATION} STREQUAL "SSE" AND NOT FFTW_HAVE_SSE)
 825
 826 elseif(${GMX_FFT_LIBRARY} STREQUAL "MKL")
 827 #    MESSAGE(STATUS "Using external FFT library - Intel MKL")
 828     find_package(MKL REQUIRED)
 829     include_directories(${MKL_INCLUDE_DIR})
 830     set(FFT_LIBRARIES ${MKL_LIBRARIES})
 831     set(PKG_FFT_LIBS ${MKL_LIBRARIES})
 832
 833     set(GMX_FFT_MKL 1)
 834     set(HAVE_MKL 1)
 835
 836 #elseif(${GMX_FFT_LIBRARY} STREQUAL "ACML")
 837 #    MESSAGE(STATUS "Using external FFT library - AMD core math library")
 838 #    set(GMX_FFT_ACML 1)
 839 elseif(${GMX_FFT_LIBRARY} STREQUAL "FFTPACK")
 840     MESSAGE(STATUS "Using internal FFT library - fftpack")
 841     set(GMX_FFT_FFTPACK 1)
 842 else(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 843     MESSAGE(FATAL_ERROR "Invalid FFT library setting: ${GMX_FFT_LIBRARY}. Choose one of: fftw3, mkl, fftpack")
 844 endif(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 845
 846 set(GMX_EXTERNAL_BLAS TRUE CACHE BOOL "Use external BLAS instead of built-in")
 847 set(GMX_EXTERNAL_LAPACK TRUE CACHE BOOL "Use external LAPACK instead of built-in")
 848 # MKL has BLAS/LAPACK routines
 849 if(NOT HAVE_MKL AND NOT ACCELERATE_FRAMEWORK)
 850   if(GMX_EXTERNAL_BLAS)
 851     if (GMX_BLAS_USER)
 852         list(APPEND GMX_EXTRA_LIBRARIES ${GMX_BLAS_USER})
 853     else(GMX_BLAS_USER)
 854         set(BLAS_FIND_QUIETLY ON)
 855         find_package(BLAS)
 856         if (BLAS_FOUND)
 857           list(APPEND GMX_EXTRA_LIBRARIES ${BLAS_LIBRARIES})
 858         else()
 859           MESSAGE(STATUS "Using internal BLAS library")
 860           set(GMX_EXTERNAL_BLAS FALSE CACHE BOOL "Use external BLAS instead of built-in" FORCE)
 861         endif()
 862     endif(GMX_BLAS_USER)
 863   endif(GMX_EXTERNAL_BLAS)
 864   if(GMX_EXTERNAL_LAPACK)
 865     if (GMX_LAPACK_USER)
 866         list(APPEND GMX_EXTRA_LIBRARIES ${GMX_LAPACK_USER})
 867     else(GMX_LAPACK_USER)
 868         set(LAPACK_FIND_QUIETLY ON)
 869         find_package(LAPACK)
 870         if (LAPACK_FOUND)
 871           list(APPEND GMX_EXTRA_LIBRARIES ${LAPACK_LIBRARIES})
 872         else()
 873           MESSAGE(STATUS "Using internal LAPACK library")
 874           set(GMX_EXTERNAL_LAPACK FALSE CACHE BOOL "Use external LAPACK instead of built-in" FORCE)
 875         endif()
 876     endif(GMX_LAPACK_USER)
 877   endif(GMX_EXTERNAL_LAPACK)
 878 endif()
 879 mark_as_advanced(GMX_EXTERNAL_LAPACK)
 880 mark_as_advanced(GMX_EXTERNAL_BLAS)
 881
 882 set(GMX_USE_PLUGINS OFF CACHE INTERNAL "Whether GROMACS will really try to compile support for VMD plugins")
 883
 884 if(GMX_LOAD_PLUGINS)
 885   if(CYGWIN OR NOT WIN32)
 886     # Native Windows does not have, nor need dlopen
 887     # Note that WIN32 is set with Cygwin, but Cygwin needs dlopen to use plug-ins
 888     include(gmxTestdlopen)
 889     gmx_test_dlopen(HAVE_DLOPEN)
 890   endif()
 891
 892   # so, should we use plug-ins?
 893   if((WIN32 AND NOT CYGWIN) OR (HAVE_DLOPEN AND BUILD_SHARED_LIBS))
 894     if(NOT VMD_QUIETLY)
 895       MESSAGE(STATUS
 896           "Found the ability to use plug-ins when building shared libaries, "
 897           "so will compile to use plug-ins (e.g. to read VMD-supported file "
 898           "formats).")
 899     endif()
 900     if(NOT GMX_VMD_PLUGIN_PATH)
 901       find_package(VMD)
 902     endif()
 903     set(GMX_USE_PLUGINS ON)
 904     list(APPEND GMX_EXTRA_LIBRARIES ${CMAKE_DL_LIBS}) # magic cross-platform pre-set variable for dlopen library
 905     set(PKG_DL_LIBS "-l${CMAKE_DL_LIBS}")
 906   else()
 907     set(PKG_DL_LIBS)
 908   endif()
 909 endif(GMX_LOAD_PLUGINS)
 910 set(VMD_QUIETLY TRUE CACHE INTERNAL "")
 911
 912 if(EXISTS "${CMAKE_SOURCE_DIR}/admin/.isreposource")
 913     if(NOT CMAKE_CROSSCOMPILING)
 914         option(GMX_BUILD_MANPAGES "Build man pages" ON)
 915     else()
 916         message(STATUS "Building the man pages is not available when "
 917             "cross-compiling the developer version from git")
 918     endif()
 919 else()
 920     #make sure source package contains all man pages
 921     if(NOT EXISTS "${CMAKE_SOURCE_DIR}/man/man1/ngmx.1")
 922         message(FATAL_ERROR "Man pages are missing from source package.")
 923     endif()
 924 endif()
 925 mark_as_advanced(GMX_BUILD_MANPAGES)
 926
 927 # Math and thread libraries must often come after all others when linking...
 928 if(HAVE_LIBM)
 929     list(APPEND GMX_EXTRA_LIBRARIES m)
 930 endif(HAVE_LIBM)
 931
 932 if(GMX_FAHCORE)
 933   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 934       "Path to swindirect.h")
 935   include_directories(${COREWRAP_INCLUDE_DIR})
 936 endif(GMX_FAHCORE)
 937
 938 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 939 # these are set after everything else
 940 if (NOT DEFINED GROMACS_C_FLAGS_SET)
 941     set(GROMACS_C_FLAGS_SET true CACHE INTERNAL "Whether to reset the C flags"
 942         FORCE)
 943     set(CMAKE_C_FLAGS "${GROMACS_C_FLAGS} ${CMAKE_C_FLAGS}" CACHE STRING
 944         "Flags used by the compiler during all build types" FORCE)
 945     set(CMAKE_CXX_FLAGS "${GROMACS_CXX_FLAGS} ${CMAKE_CXX_FLAGS}" CACHE STRING
 946         "Flags used by the compiler during all build types" FORCE)
 947     set(CMAKE_EXE_LINKER_FLAGS
 948         "${GROMACS_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}"
 949         CACHE STRING "Linker flags for creating executables" FORCE)
 950     set(CMAKE_SHARED_LINKER_FLAGS
 951         "${GROMACS_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS}"
 952         CACHE STRING "Linker flags for creating shared libraries" FORCE)
 953 endif (NOT DEFINED GROMACS_C_FLAGS_SET)
 954
 955 ######################################
 956 # Output compiler and CFLAGS used
 957 ######################################
 958 execute_process(COMMAND ${CMAKE_C_COMPILER} --version RESULT_VARIABLE TMP_RESULT OUTPUT_VARIABLE CC_VERSION ERROR_VARIABLE CC_VERSION)
 959 #try executing just the compiler command if that failed...
 960 if(TMP_RESULT)
 961     execute_process(COMMAND ${CMAKE_C_COMPILER} RESULT_VARIABLE TMP_RESULT OUTPUT_VARIABLE CC_VERSION ERROR_VARIABLE CC_VERSION)
 962 endif()
 963 string(LENGTH "${CC_VERSION}" len)
 964 if(len)
 965     string(REGEX MATCH "[^\n]*" CC_VERSION "${CC_VERSION}")
 966 endif()
 967
 968 set(BUILD_COMPILER "@CMAKE_C_COMPILER@ @CMAKE_C_COMPILER_ID@ @CC_VERSION@")
 969 set(BUILD_CFLAGS "@CMAKE_C_FLAGS@")
 970 if(CMAKE_BUILD_TYPE STREQUAL "Debug")
 971     set(BUILD_CFLAGS "@BUILD_CFLAGS@ @CMAKE_C_FLAGS_DEBUG@")
 972 elseif(CMAKE_BUILD_TYPE STREQUAL "Release")
 973     set(BUILD_CFLAGS "@BUILD_CFLAGS@ @CMAKE_C_FLAGS_RELEASE@")
 974 elseif(CMAKE_BUILD_TYPE STREQUAL "MinSizeRel")
 975     set(BUILD_CFLAGS "@BUILD_CFLAGS@ @CMAKE_C_FLAGS_MINSIZEREL@")
 976 elseif(CMAKE_BUILD_TYPE STREQUAL "RelWithDebInfo")
 977     set(BUILD_CFLAGS "@BUILD_CFLAGS@ @CMAKE_C_FLAGS_RELWITHDEBINFO@")
 978 endif()
 979
 980
 981 ########################################################################
 982 # Specify install locations and which subdirectories to process        #
 983 ########################################################################
 984 if ( NOT DEFINED GMXLIB )
 985     set(GMXLIB lib)
 986 endif()
 987 set(LIB_INSTALL_DIR "${GMX_INSTALL_PREFIX}${GMXLIB}")
 988 set(BIN_INSTALL_DIR  ${GMX_INSTALL_PREFIX}bin)
 989 set(DATA_INSTALL_DIR ${GMX_INSTALL_PREFIX}share/gromacs)
 990 set(MAN_INSTALL_DIR  ${GMX_INSTALL_PREFIX}share/man)
 991 set(INCL_INSTALL_DIR ${GMX_INSTALL_PREFIX}include)
 992
 993 set(GMXLIBDIR        ${DATA_INSTALL_DIR}/top)
 994
 995 ##################################################################
 996 # Shared library settings - Darwin uses INSTALL_NAME_DIR instead!
 997 ##################################################################
 998 if(NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin")
 999     set(CMAKE_SKIP_BUILD_RPATH  FALSE)
1000     set(CMAKE_BUILD_WITH_INSTALL_RPATH FALSE)
1001     set(CMAKE_INSTALL_RPATH "\\\$ORIGIN/../${GMXLIB}")
1002     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
1003 endif()
1004
1005 add_subdirectory(doxygen)
1006 add_subdirectory(share)
1007 add_subdirectory(src)
1008 add_subdirectory(scripts)
1009
1010 #######################
1011 ## uninstall target
1012 #######################
1013     CONFIGURE_FILE(
1014                    "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
1015                    "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
1016                    IMMEDIATE @ONLY)
1017 ###########################
1018 ADD_CUSTOM_TARGET(uninstall
1019                   "${CMAKE_COMMAND}" -P
1020                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
1021 ###########################
1022
1023
1024 ########################################################################
1025 # Tests                                                                #
1026 ########################################################################
1027
1028 include(CTest)
1029 mark_as_advanced(BUILD_TESTING)
1030 IF(BUILD_TESTING)
1031     enable_testing()
1032     add_subdirectory(tests)
1033 ENDIF()
1034