CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.8)
   2 # Keep CMake suitably quiet on Cygwin
   3 set(CMAKE_LEGACY_CYGWIN_WIN32 0) # Remove when CMake >= 2.8.4 is required
   4
   5 project(Gromacs)
   6 include(Dart)
   7 mark_as_advanced(DART_ROOT)
   8
   9 # PROJECT_VERSION should have the following structure:
  10 # VERSION-dev[-SUFFIX] where the VERSION should have the for: vMajor.vMinor.vPatch
  11 #
  12 # The "-dev" suffix is important to keep because it makes possible to distinguish
  13 # between a build from official release and a build from git release branch on a
  14 # machine with no git.
  15 #
  16 # NOTE: when releasing the "-dev" suffix needs to be stripped off!
  17 set(PROJECT_VERSION "4.6-dev")
  18 set(CUSTOM_VERSION_STRING ""
  19     CACHE STRING "Custom version string (if empty, use hard-coded default)")
  20 mark_as_advanced(CUSTOM_VERSION_STRING)
  21 if (CUSTOM_VERSION_STRING)
  22     set(PROJECT_VERSION ${CUSTOM_VERSION_STRING})
  23 endif (CUSTOM_VERSION_STRING)
  24 set(SOVERSION 6)
  25 # It is a bit irritating, but this has to be set separately for now!
  26 SET(CPACK_PACKAGE_VERSION_MAJOR "4")
  27 SET(CPACK_PACKAGE_VERSION_MINOR "6")
  28 #SET(CPACK_PACKAGE_VERSION_PATCH "0")
  29
  30
  31 # Cmake modules/macros are in a subdirectory to keep this file cleaner
  32 set(CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake)
  33
  34 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
  35 set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
  36 endif()
  37
  38 if(NOT CMAKE_BUILD_TYPE)
  39     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel." FORCE)
  40 endif(NOT CMAKE_BUILD_TYPE)
  41
  42 enable_language(C)
  43
  44 set(CPACK_PACKAGE_VERSION ${PROJECT_VERSION})
  45 set(CPACK_PACKAGE_VENDOR "gromacs.org")
  46 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Gromacs - a toolkit for high-performance molecular simulation")
  47 set(CPACK_SET_DESTDIR "ON")
  48 set(CPACK_INCLUDE_TOPLEVEL_DIRECTORY 0)
  49 set(CPACK_RESOURCE_FILE_WELCOME "${CMAKE_SOURCE_DIR}/admin/InstallWelcome.txt")
  50 # Its GPL/LGPL, so they do not have to agree to a license for mere usage, but some installers require this...
  51 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_SOURCE_DIR}/admin/InstallLicense.txt")
  52 set(CPACK_RESOURCE_FILE_README "${CMAKE_SOURCE_DIR}/admin/InstallInfo.txt")
  53
  54 #must come after all cpack settings!
  55 include(CPack)
  56
  57 ########################################################################
  58 # Check and warn if cache generated on a different host is being reused
  59 ########################################################################
  60 if(CMAKE_HOST_UNIX)
  61     execute_process(COMMAND hostname
  62                     OUTPUT_VARIABLE TMP_HOSTNAME
  63                     OUTPUT_STRIP_TRAILING_WHITESPACE)
  64     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}")
  65         message(WARNING "
  66             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
  67             is being reused! This could lead to inconsitencies; therefore, it is
  68             recommended to regenerate the cache!")
  69     endif()
  70     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
  71             "Hostname of the machine where the cache was generated.")
  72 endif()
  73
  74 ########################################################################
  75 # Fix stupid flags on Windows
  76 ########################################################################
  77 SET(SHARED_LIBS_DEFAULT ON)
  78 IF( (CMAKE_GENERATOR MATCHES "Visual Studio" OR CMAKE_GENERATOR MATCHES "NMake") AND MSVC )
  79     STRING(REPLACE /MD /MT CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE})
  80     SET(CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE} CACHE STRING "" FORCE)
  81     STRING(REPLACE /MD /MT CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG})
  82     SET(CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG} CACHE STRING "" FORCE)
  83     SET(SHARED_LIBS_DEFAULT OFF)
  84 ENDIF()
  85
  86 IF(CMAKE_GENERATOR MATCHES "NMake" AND CMAKE_C_COMPILER_ID MATCHES "Intel")
  87     STRING(REPLACE /GZ /RTC1 CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE})
  88     SET(CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE} CACHE STRING "" FORCE)
  89     STRING(REPLACE /GZ /RTC1 CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG})
  90     SET(CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG} CACHE STRING "" FORCE)
  91     SET(SHARED_LIBS_DEFAULT OFF)
  92 ENDIF()
  93
  94 set(GMX_EXTRA_LIBRARIES)
  95
  96
  97
  98 ######################################################################
  99 # compiler tests
 100 # these need ot be done early (before further tests).
 101 #####################################################################
 102
 103 include(CheckCCompilerFlag)
 104 include(CheckCXXCompilerFlag)
 105
 106 include(gmxCFlags)
 107 gmx_c_flags()
 108
 109 ########################################################################
 110 # User input options                                                   #
 111 ########################################################################
 112 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" OFF)
 113 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 114 option(GMX_THREAD_MPI  "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" ON)
 115 option(GMX_SOFTWARE_INVSQRT "Use GROMACS software 1/sqrt" ON)
 116 mark_as_advanced(GMX_SOFTWARE_INVSQRT)
 117 option(GMX_POWERPC_INVSQRT "Use PowerPC hardware 1/sqrt" OFF)
 118 mark_as_advanced(GMX_POWERPC_INVSQRT)
 119 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 120 mark_as_advanced(GMX_FAHCORE)
 121 option(GMX_OPENMM "Accelerated execution on GPUs through the OpenMM library (rerun cmake after changing to see relevant options)" OFF)
 122 set(GMX_ACCELERATION "auto"
 123     CACHE STRING "Accelerated kernels. Pick one of: auto, none, SSE, BlueGene, Power6, ia64, altivec, fortran")
 124
 125 set(GMX_FFT_LIBRARY "fftw3"
 126     CACHE STRING "FFT library choices: fftw3,mkl,fftpack[built-in]")
 127 option(GMX_DISABLE_FFTW_MEASURE
 128        "Do not optimize FFTW setups (not needed with SSE)" OFF)
 129 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 130 set(GMX_QMMM_PROGRAM "none"
 131     CACHE STRING "QM package choices: none,gaussian,mopac,gamess,orca")
 132 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 133 mark_as_advanced(GMX_BROKEN_CALLOC)
 134 option(BUILD_SHARED_LIBS "Enable shared libraries (can be problematic with MPI, Windows)" ${SHARED_LIBS_DEFAULT})
 135 option(GMX_MPI_IN_PLACE "Enable MPI_IN_PLACE for MPIs that have it defined" ON)
 136 mark_as_advanced(GMX_MPI_IN_PLACE)
 137 option(GMX_LOAD_PLUGINS "Compile with plugin support, needed to read VMD supported file formats" ON)
 138 mark_as_advanced(GMX_LOAD_PLUGINS)
 139
 140
 141 option(GMX_IA32_ASM "Add SSE assembly files for IA32" OFF)
 142 mark_as_advanced(GMX_IA32_ASM)
 143 option(GMX_X86_64_ASM "Add SSE assembly files for X86_64" OFF)
 144 mark_as_advanced(GMX_X86_64_ASM)
 145
 146 option(GMX_OPENMP "Enable OpenMP-based mutithreading. " ON)
 147
 148 option(USE_VERSION_H "Generate development version string/information" ON)
 149 mark_as_advanced(USE_VERSION_H)
 150
 151 option(GMX_DEFAULT_SUFFIX "Use default suffixes for GROMACS binaries and libs (_d for double, _mpi for MPI; rerun cmake after changing to see relevant options)" ON)
 152
 153 if(UNIX AND NOT APPLE)
 154     option(GMX_PREFER_STATIC_LIBS "When finding libraries prefer \".a\" static archives (NOTE: this is enabled only for UNIX (excluding APPLE) platforms but it might not always work!" OFF)
 155     mark_as_advanced(GMX_PREFER_STATIC_LIBS)
 156 endif()
 157
 158 ########################################################################
 159 # Set up binary and library suffixing
 160 ########################################################################
 161 set(GMX_BINARY_SUFFIX "" CACHE STRING "Suffix for GROMACS binaries (default: _d for double, _mpi for MPI, _mpi_d for MPI and double).")
 162 set(GMX_LIBS_SUFFIX ""
 163   CACHE STRING "Suffix for GROMACS libs (default: _d for double, _mpi for MPI, _mpi_d for MPI and double).")
 164 if (GMX_DEFAULT_SUFFIX)
 165   set(GMX_BINARY_SUFFIX "")
 166   set(GMX_LIBS_SUFFIX "")
 167   if (GMX_MPI)
 168     set(GMX_BINARY_SUFFIX "_mpi")
 169     set(GMX_LIBS_SUFFIX "_mpi")
 170   endif(GMX_MPI)
 171   if (GMX_DOUBLE)
 172     set (GMX_BINARY_SUFFIX "${GMX_BINARY_SUFFIX}_d")
 173     set (GMX_LIBS_SUFFIX "${GMX_LIBS_SUFFIX}_d")
 174   endif(GMX_DOUBLE)
 175   if (GMX_OPENMM)
 176     set (GMX_BINARY_SUFFIX "-gpu")
 177     set (GMX_LIBS_SUFFIX "_gpu")
 178   endif(GMX_OPENMM)
 179   mark_as_advanced(FORCE GMX_BINARY_SUFFIX GMX_LIBS_SUFFIX)
 180   if (NOT SUFFIX_QUIETLY)
 181     message(STATUS "Using default binary suffix: \"${GMX_BINARY_SUFFIX}\"")
 182     message(STATUS "Using default library suffix: \"${GMX_LIBS_SUFFIX}\"")
 183   endif (NOT SUFFIX_QUIETLY)
 184 else(GMX_DEFAULT_SUFFIX)
 185   mark_as_advanced(CLEAR GMX_BINARY_SUFFIX GMX_LIBS_SUFFIX)
 186   if (NOT SUFFIX_QUIETLY)
 187     message(STATUS "Using manually set binary suffix: \"${GMX_BINARY_SUFFIX}\"")
 188     message(STATUS "Using manually set library suffix: \"${GMX_LIBS_SUFFIX}\"")
 189   endif (NOT SUFFIX_QUIETLY)
 190 endif(GMX_DEFAULT_SUFFIX)
 191 set(SUFFIX_QUIETLY TRUE CACHE INTERNAL "")
 192
 193 set(PKG_CFLAGS "")
 194 if(GMX_DOUBLE)
 195     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_DOUBLE")
 196 endif(GMX_DOUBLE)
 197 if(GMX_SOFTWARE_INVSQRT)
 198   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_SOFTWARE_INVSQRT")
 199 endif(GMX_SOFTWARE_INVSQRT)
 200 if(GMX_POWERPC_INVSQRT)
 201   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_POWERPC_INVSQRT")
 202 endif(GMX_POWERPC_INVSQRT)
 203
 204 ########################################################################
 205 #Process MPI settings
 206 ########################################################################
 207 include(gmxManageMPI)
 208
 209 #######################################################################
 210 # Check for options incompatible with OpenMM build                    #
 211 #######################################################################
 212 if(GMX_OPENMM)
 213     cmake_minimum_required(VERSION 2.6.4)
 214     # we'll use the built-in fft to avoid unnecessary dependencies
 215     string(TOUPPER ${GMX_FFT_LIBRARY} GMX_FFT_LIBRARY)
 216     if(NOT ${GMX_FFT_LIBRARY} STREQUAL "FFTPACK")
 217         message(STATUS "No external FFT libraries needed for the OpenMM build, switching to fftpack!")
 218         set(GMX_FFT_LIBRARY "fftpack" CACHE STRING
 219                 "No external FFT libraries needed for the OpenMM build, switching to  fftpack!" FORCE)
 220     endif()
 221     if(GMX_MPI)
 222         message(FATAL_ERROR "The OpenMM build is not compatible with MPI!")
 223     endif(GMX_MPI)
 224     if(GMX_THREAD_MPI)
 225         message(STATUS "Thread-MPI not compatible with OpenMM, disabled!")
 226         set(GMX_THREAD_MPI OFF CACHE BOOL
 227                 "Thread-MPI not compatible with OpenMM build, disabled!" FORCE)
 228     endif(GMX_THREAD_MPI)
 229     if(GMX_OPENMP)
 230         message(STATUS "OpenMP multithreading not compatible with OpenMM, disabled")
 231         set(GMX_OPENMP OFF CACHE BOOL
 232             "OpenMP multithreading not compatible with OpenMM, disabled!" FORCE)
 233     endif()
 234     if(GMX_SOFTWARE_INVSQRT)
 235         set(GMX_SOFTWARE_INVSQRT OFF CACHE STRING
 236                 "The OpenMM build does not need GROMACS software 1/sqrt!" FORCE)
 237     endif(GMX_SOFTWARE_INVSQRT)
 238     string(TOUPPER ${GMX_ACCELERATION} GMX_ACCELERATION)
 239     if(NOT GMX_ACCELERATION STREQUAL "NONE")
 240         message(STATUS "Switching off CPU-based acceleration, the OpenMM build does not support/need any!")
 241         set(GMX_ACCELERATION "none" CACHE STRING
 242                 "Switching off CPU-based acceleration, the OpenMM build does not support/need any!" FORCE)
 243     endif()
 244     if(GMX_FAHCORE)
 245         message(FATAL_ERROR "The OpenMM build does not support FAH build!")
 246     endif(GMX_FAHCORE)
 247     if(GMX_DOUBLE)
 248         message(FATAL_ERROR  "The OpenMM-build does not support double precision calculations!")
 249     endif()
 250     # mark as advanced the unused variables
 251     mark_as_advanced(FORCE GMX_ACCELERATION GMX_MPI GMX_FFT_LIBRARY
 252         GMX_QMMM_PROGRAM GMX_THREAD_MPI GMX_DOUBLE)
 253 else(GMX_OPENMM)
 254      mark_as_advanced(CLEAR GMX_ACCELERATION GMX_MPI GMX_FFT_LIBRARY
 255         GMX_QMMM_PROGRAM GMX_THREAD_MPI GMX_DOUBLE)
 256 endif(GMX_OPENMM)
 257
 258
 259 ########################################################################
 260 # Basic system tests (standard libraries, headers, functions, types)   #
 261 ########################################################################
 262 include(CheckIncludeFiles)
 263 check_include_files(string.h     HAVE_STRING_H)
 264 check_include_files(math.h       HAVE_MATH_H)
 265 check_include_files(limits.h     HAVE_LIMITS_H)
 266 check_include_files(memory.h     HAVE_MEMORY_H)
 267 check_include_files(unistd.h     HAVE_UNISTD_H)
 268 check_include_files(direct.h     HAVE_DIRECT_H)
 269 check_include_files(pwd.h        HAVE_PWD_H)
 270 check_include_files(stdint.h     HAVE_STDINT_H)
 271 check_include_files(stdlib.h     HAVE_STDLIB_H)
 272 check_include_files(pthread.h    HAVE_PTHREAD_H)
 273 check_include_files(dirent.h     HAVE_DIRENT_H)
 274 check_include_files(inttypes.h   HAVE_INTTYPES_H)
 275 check_include_files(regex.h      HAVE_REGEX_H)
 276 check_include_files(sys/types.h  HAVE_SYS_TYPES_H)
 277 check_include_files(sys/stat.h   HAVE_SYS_STAT_H)
 278 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 279 check_include_files(rpc/rpc.h    HAVE_RPC_RPC_H)
 280 check_include_files("rpc/rpc.h;rpc/xdr.h"    HAVE_RPC_XDR_H)
 281 # SSE support
 282 check_include_files(xmmintrin.h  HAVE_XMMINTRIN_H)
 283 check_include_files(emmintrin.h  HAVE_EMMINTRIN_H)
 284 check_include_files(pmmintrin.h  HAVE_PMMINTRIN_H)
 285 check_include_files(smmintrin.h  HAVE_SMMINTRIN_H)
 286 check_include_files(io.h                 HAVE_IO_H)
 287
 288
 289 include(CheckFunctionExists)
 290 check_function_exists(strcasecmp        HAVE_STRCASECMP)
 291 check_function_exists(strdup            HAVE_STRDUP)
 292 check_function_exists(vprintf           HAVE_VPRINTF)
 293 check_function_exists(memcmp            HAVE_MEMCMP)
 294 check_function_exists(posix_memalign    HAVE_POSIX_MEMALIGN)
 295 check_function_exists(memalign          HAVE_MEMALIGN)
 296 check_function_exists(_aligned_malloc   HAVE__ALIGNED_MALLOC)
 297 check_function_exists(gettimeofday      HAVE_GETTIMEOFDAY)
 298 check_function_exists(isnan             HAVE_ISNAN)
 299 check_function_exists(_isnan            HAVE__ISNAN)
 300 check_function_exists(fsync             HAVE_FSYNC)
 301 check_function_exists(_fileno           HAVE__FILENO)
 302 check_function_exists(fileno            HAVE_FILENO)
 303 check_function_exists(_commit           HAVE__COMMIT)
 304 check_function_exists(sigaction         HAVE_SIGACTION)
 305
 306 include(CheckLibraryExists)
 307 check_library_exists(m sqrt "" HAVE_LIBM)
 308 check_library_exists(m cbrt "" HAVE_CBRT)
 309
 310
 311 include(CheckTypeSize)
 312
 313 check_type_size("bool"          SIZEOF_BOOL) # will also set HAVE_BOOL
 314 check_type_size("int"           SIZEOF_INT)
 315 check_type_size("long int"      SIZEOF_LONG_INT)
 316 check_type_size("long long int" SIZEOF_LONG_LONG_INT)
 317 check_type_size("off_t"         SIZEOF_OFF_T)
 318 check_type_size("void *"        SIZEOF_VOIDP)
 319
 320 if (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 321     set(GMX_64_BIT TRUE)
 322 else (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 323     set(GMX_64_BIT FALSE)
 324 endif (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 325
 326 # Check for some basic types that we *need*, so set these to int if they are not present
 327 check_type_size(uid_t uid_t)
 328 if(NOT uid_t)
 329   set(uid_t int)
 330 else(NOT uid_t)
 331   set(uid_t 0)
 332 endif(NOT uid_t)
 333
 334 check_type_size(gid_t gid_t)
 335 if(NOT gid_t)
 336   set(gid_t 1)
 337 else(NOT gid_t)
 338   set(gid_t 0)
 339 endif(NOT gid_t)
 340
 341 check_type_size(size_t size_t)
 342 if(NOT size_t)
 343   set(size_t int)
 344 else(NOT size_t)
 345   set(size_t 0)
 346 endif(NOT size_t)
 347
 348 check_type_size(off_t off_t)
 349 if(NOT off_t)
 350   set(off_t int)
 351 else(NOT off_t)
 352   set(off_t 0)
 353 endif(NOT off_t)
 354
 355 include(TestBigEndian)
 356 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 357
 358
 359
 360
 361 ########################################################################
 362 # Find external packages                                               #
 363 ########################################################################
 364 if(UNIX AND NOT APPLE)
 365     if(GMX_PREFER_STATIC_LIBS)
 366         SET(CMAKE_FIND_LIBRARY_SUFFIXES .a ${CMAKE_FIND_LIBRARY_SUFFIXES})
 367         if(BUILD_SHARED_LIBS)
 368             message(WARNING "Static libraries requested, the GROMACS libraries will also be build static (BUILD_SHARED_LIBS=OFF)")
 369             set(BUILD_SHARED_LIBS OFF CACHE BOOL "Enable shared libraries (can be problematic with MPI, Windows)" FORCE)
 370         endif()
 371     endif()
 372 endif()
 373
 374 option(GMX_XML "Use libxml2 to parse xml files" ON)
 375 if (GMX_XML)
 376   find_package(LibXml2)
 377   set(PKG_XML "")
 378   if(LIBXML2_FOUND)
 379     include_directories(${LIBXML2_INCLUDE_DIR})
 380     set(PKG_XML libxml-2.0)
 381     set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 382     set(HAVE_LIBXML2 1)
 383   endif(LIBXML2_FOUND)
 384 endif(GMX_XML)
 385
 386 option(GMX_GSL "Add support for gsl" OFF)
 387 if (GMX_GSL)
 388   find_package(gsl)
 389   set(PKG_GSL "")
 390   if(GSL_FOUND)
 391     include_directories(${GSL_INCLUDE_DIR})
 392     set(PKG_GSL gsl)
 393     set(HAVE_LIBGSL 1)
 394   endif(GSL_FOUND)
 395 endif (GMX_GSL)
 396
 397 option(GMX_X11 "Use X window system" OFF)
 398 if (GMX_X11)
 399         find_package(X11)
 400         # X11 includes/libraries are only set in the ngmx subdirectory!
 401         if(X11_FOUND)
 402         set(HAVE_X11 1)
 403         endif(X11_FOUND)
 404 endif(GMX_X11)
 405
 406 if(GMX_THREAD_MPI)
 407     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_THREAD_MPI")
 408     include(ThreadMPI)
 409     set(THREAD_MPI_LIB thread_mpi)
 410     set(GMX_MPI 1)
 411     string(TOUPPER ${GMX_FFT_LIBRARY} ${GMX_FFT_LIBRARY})
 412 endif(GMX_THREAD_MPI)
 413
 414 if(GMX_OPENMM)
 415     set(CUDA_BUILD_EMULATION OFF)
 416     find_package(CUDA 3.1 REQUIRED)
 417     add_definitions(-DGMX_OPENMM)
 418     if(CMAKE_BUILD_TYPE STREQUAL "DEBUG")
 419         set(CUDA_VERBOSE_BUILD ON)
 420     endif()
 421     find_package(OpenMM)
 422 endif(GMX_OPENMM)
 423
 424 if(GMX_OPENMP)
 425     find_package(OpenMP REQUIRED)
 426     set(GROMACS_C_FLAGS "${OpenMP_C_FLAGS} ${GROMACS_C_FLAGS}")
 427     set(GROMACS_CXX_FLAGS "${OpenMP_CXX_FLAGS} ${GROMACS_CXX_FLAGS}")
 428     add_definitions(-DGMX_OPENMP)
 429 endif()
 430
 431 if(APPLE)
 432    find_library(ACCELERATE_FRAMEWORK Accelerate)
 433    list(APPEND GMX_EXTRA_LIBRARIES ${ACCELERATE_FRAMEWORK})
 434 endif(APPLE)
 435
 436 if(CYGWIN)
 437     set(GMX_CYGWIN 1)
 438 endif(CYGWIN)
 439
 440 if(WIN32 AND NOT CYGWIN)
 441     set(GMX_NATIVE_WINDOWS 1)
 442 endif()
 443
 444 # only bother with finding git and using version.h if the source is a git repo
 445 if(EXISTS "${CMAKE_SOURCE_DIR}/.git")
 446     if(USE_VERSION_H)
 447         # We need at least git v1.5.1 be able to parse git's date output. If not
 448         # found or the version is too small, we can't generate version information.
 449         find_package(Git)
 450
 451         # Find out the git version
 452         if(GIT_FOUND AND NOT GIT_VERSION)
 453           execute_process(COMMAND ${GIT_EXECUTABLE} "--version"
 454             OUTPUT_VARIABLE _exec_out
 455             OUTPUT_STRIP_TRAILING_WHITESPACE)
 456           string(REGEX REPLACE "git version (.*)" "\\1" GIT_VERSION ${_exec_out})
 457           set(GIT_VERSION ${GIT_VERSION} CACHE STRING "Git version")
 458           mark_as_advanced(GIT_VERSION)
 459         endif()
 460
 461         if(NOT GIT_FOUND OR GIT_VERSION VERSION_LESS "1.5.1")
 462           message("No compatible git version found, won't be able to generate proper development version information.")
 463           set(USE_VERSION_H OFF)
 464         endif()
 465     endif()
 466 else()
 467     set(USE_VERSION_H OFF)
 468 endif()
 469
 470 ########################################################################
 471 # Generate development version info for cache
 472 ########################################################################
 473 # set(GEN_VERSION_INFO_INTERNAL "ON")
 474 # include(gmxGenerateVersionString)
 475
 476 ########################################################################
 477 # Our own GROMACS tests
 478 ########################################################################
 479
 480 add_definitions( -DHAVE_CONFIG_H )
 481 include_directories(${CMAKE_BINARY_DIR}/src)
 482 include_directories(${CMAKE_BINARY_DIR}/include)
 483 include_directories(${CMAKE_SOURCE_DIR}/include)
 484
 485 include(gmxCheckBuildUserTime)
 486 gmx_check_build_user_time(BUILD_TIME BUILD_USER BUILD_MACHINE)
 487
 488 include(gmxTestFloatFormat)
 489 gmx_test_float_format(GMX_FLOAT_FORMAT_IEEE754
 490                       GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER
 491                       GMX_IEEE754_BIG_ENDIAN_WORD_ORDER)
 492
 493 include(gmxTestLargeFiles)
 494 gmx_test_large_files(GMX_LARGEFILES)
 495 check_function_exists(fseeko     HAVE_FSEEKO)
 496
 497 include(gmxTestSignal)
 498 gmx_test_sigusr1(HAVE_SIGUSR1)
 499
 500 include(gmxTestInline)
 501 gmx_test_inline(INLINE_KEYWORD)
 502
 503 include(gmxTestRestrict)
 504 gmx_test_inline(RESTRICT_KEYWORD)
 505
 506 include(gmxTestPipes)
 507 gmx_test_pipes(HAVE_PIPES)
 508
 509 include(gmxTestIsfinite)
 510 gmx_test_isfinite(HAVE_ISFINITE)
 511 gmx_test__isfinite(HAVE__ISFINITE)
 512 gmx_test__finite(HAVE__FINITE)
 513
 514 include(gmxTestInlineASM)
 515 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 516 gmx_test_inline_asm_msvc_x86(GMX_X86_MSVC_INLINE_ASM)
 517
 518 # turn on SSE if supported with reasonable defaults.
 519 if (${GMX_ACCELERATION} STREQUAL "auto" AND NOT GMX_OPENMM)
 520   if(CMAKE_SYSTEM_PROCESSOR MATCHES "^(i.86|x86|x64|x86_64|AMD64|amd64)" OR CYGWIN)
 521
 522     set(GMX_ACCELERATION "SSE" CACHE STRING "Accelerated kernels. Pick one of: auto, none, SSE, BlueGene, Power6, ia64, altivec, fortran" FORCE)
 523
 524     # Determine the assembler/compiler to use
 525   else()
 526     set(GMX_ACCELERATION "none" CACHE STRING "Accelerated kernels. Pick one of: auto, none, SSE, BlueGene, Power6, ia64, altivec, fortran" FORCE)
 527   endif()
 528 endif (${GMX_ACCELERATION} STREQUAL "auto" AND NOT GMX_OPENMM)
 529
 530 include(gmxTestXDR)
 531 gmx_test_xdr(GMX_SYSTEM_XDR)
 532 if(NOT GMX_SYSTEM_XDR)
 533     set(GMX_INTERNAL_XDR 1)
 534     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_INTERNAL_XDR")
 535 endif(NOT GMX_SYSTEM_XDR)
 536
 537 # Process nonbonded accelerated kernels settings
 538 string(TOUPPER ${GMX_ACCELERATION} ${GMX_ACCELERATION})
 539 if(${GMX_ACCELERATION} STREQUAL "NONE")
 540   # nothing to do
 541 elseif(${GMX_ACCELERATION} STREQUAL "SSE")
 542
 543     if (GMX_64_BIT)
 544       set(GMX_X86_64_ASM ON CACHE BOOL "Add SSE assembly files for x86_64" FORCE)
 545     else (GMX_64_BIT)
 546       set(GMX_IA32_ASM ON CACHE BOOL "Add SSE assembly files for i386" FORCE)
 547     endif (GMX_64_BIT)
 548
 549     if(CMAKE_GENERATOR MATCHES "Visual Studio" OR CMAKE_GENERATOR MATCHES NMake )
 550       option(GMX_ASM_USEASM_NASM "Use Nasm for assembly instead of compiler (necessary on windows)" ON)
 551     else()
 552       option(GMX_ASM_USEASM_NASM "Use Nasm for assembly instead of compiler (necessary on windows)" OFF)
 553     endif()
 554         mark_as_advanced(GMX_ASM_USEASM_NASM)
 555
 556     if (NOT GMX_64_BIT)
 557         # for 32-bit compiles, we might need to turn on sse
 558         CHECK_C_COMPILER_FLAG("-msse2" XFLAGS_SSE)
 559         if (XFLAGS_SSE)
 560             set(GROMACS_C_FLAGS "-msse2 ${GROMACS_C_FLAGS}")
 561         endif (XFLAGS_SSE)
 562         CHECK_CXX_COMPILER_FLAG("-msse2" XXFLAGS_SSE)
 563         if (XXFLAGS_SSE)
 564             set(GROMACS_CXX_FLAGS "-msse2 ${GROMACS_CXX_FLAGS}")
 565         endif (XXFLAGS_SSE)
 566     endif (NOT GMX_64_BIT)
 567
 568     if(GMX_IA32_ASM)
 569       if(GMX_DOUBLE)
 570         set(GMX_IA32_SSE2 1)
 571       else()
 572        set(GMX_IA32_SSE 1)
 573       endif()
 574     elseif(GMX_X86_64_ASM)
 575       if(GMX_DOUBLE)
 576        set(GMX_X86_64_SSE2 1)
 577       else()
 578         set(GMX_X86_64_SSE 1)
 579       endif()
 580     endif()
 581
 582 #    if(HAVE_PMMINTRIN_H)
 583 #        set(GMX_SSE3 1)
 584 #    endif(HAVE_PMMINTRIN_H)
 585 #    if(HAVE_SMMINTRIN_H)
 586 #        set(GMX_SSE4_1 1)
 587 #    endif(HAVE_SMMINTRIN_H)
 588
 589 elseif(${GMX_ACCELERATION} STREQUAL "FORTRAN")
 590     set(GMX_FORTRAN 1)
 591     #these are switch on by default sometimes
 592     set(GMX_IA32_ASM 0)
 593     set(GMX_GMX_X86_64_ASM 0)
 594 elseif(${GMX_ACCELERATION} STREQUAL "BLUEGENE")
 595 # GMX_ACCELERATION=BlueGene should be set in the Toolchain-BlueGene?-???.cmake file
 596     message(STATUS "Configuring for BlueGene")
 597     set(GMX_BLUEGENE 1)
 598     if (${CMAKE_SYSTEM_NAME} STREQUAL "BlueGeneL")
 599         set(SHARED_LIBS_DEFAULT OFF CACHE BOOL "Shared libraries not compatible with BlueGene/L, disabled!" FORCE)
 600         set(BUILD_SHARED_LIBS OFF CACHE BOOL "Shared libraries not compatible with BlueGene/L, disabled!" FORCE)
 601     endif (${CMAKE_SYSTEM_NAME} STREQUAL "BlueGeneL")
 602     set(GMX_SOFTWARE_INVSQRT OFF CACHE BOOL "Do not use software reciprocal square root on BlueGene" FORCE)
 603     set(GMX_POWERPC_INVSQRT ON CACHE BOOL "Use hardware reciprocal square root on BlueGene" FORCE)
 604     set(GMX_X11 OFF CACHE BOOL "X11 not compatible with BlueGene, disabled!" FORCE)
 605     set(GMX_THREAD_MPI OFF CACHE BOOL "Thread-MPI not compatible with BlueGene, disabled!" FORCE)
 606     set(GMX_MPI ON CACHE BOOL "Use MPI on BlueGene" FORCE)
 607 elseif(${GMX_ACCELERATION} STREQUAL "POWER6")
 608     set(GMX_POWER6 1)
 609     set(GMX_SOFTWARE_INVSQRT OFF CACHE BOOL "Do not use software reciprocal square root on Power6" FORCE)
 610     set(GMX_POWERPC_INVSQRT ON CACHE BOOL "Use hardware reciprocal square root on Power6" FORCE)
 611 elseif(${GMX_ACCELERATION} STREQUAL "IA64")
 612     set(GMX_IA64_ASM 1)
 613     set(DISABLE_WATERWATER_NLIST 1)
 614     set(DISABLE_WATER_NLIST 1)
 615 elseif(${GMX_ACCELERATION} STREQUAL "ALTIVEC")
 616     check_include_files(altivec.h HAVE_ALTIVEC_H)
 617     if(HAVE_ALTIVEC_H)
 618         set(GMX_PPC_ALTIVEC 1)
 619     endif(HAVE_ALTIVEC_H)
 620 else(${GMX_ACCELERATION} STREQUAL "NONE")
 621     MESSAGE(FATAL_ERROR "Unrecognized option for accelerated kernels: ${GMX_ACCELERATION}. Pick one of auto, none, SSE, Fortran, BlueGene, Power6, ia64, altivec")
 622 endif(${GMX_ACCELERATION} STREQUAL "NONE")
 623
 624 if(GMX_FORTRAN OR GMX_POWER6)
 625     if (GMX_THREAD_MPI)
 626         message(FATAL_ERROR "FORTRAN/POWER6 is incompatible with thread-MPI and only provides a speed-up on certain IBM compilers. Disable FORTRAN (or threads if you really want to use FORTRAN kernels).")
 627     endif(GMX_THREAD_MPI)
 628     enable_language(Fortran)
 629     include(FortranCInterface)
 630     discover_fortran_mangling(prefix isupper suffix extra_under_score found)
 631     if(extra_under_score)
 632         set(extrasuffix "_")
 633     endif(extra_under_score)
 634     if(prefix)
 635       set(prefix "${prefix} ##")
 636     endif(prefix)
 637     if(suffix)
 638       set(suffix "## ${suffix}")
 639       if(extrasuffix)
 640         set(extrasuffix "${suffix}${extrasuffix}")
 641       endif(extrasuffix)
 642     else(suffix)
 643       if(extrasuffix)
 644         # Don't know if this is needed, but it can't hurt
 645         set(extrasuffix "## ${extrasuffix}")
 646       endif(extrasuffix)
 647     endif(suffix)
 648
 649     if(isupper)
 650         set(F77_FUNCDEF   "${prefix} NAME ${suffix}")
 651         set(F77_FUNCDEF_  "${prefix} NAME ${extrasuffix}")
 652     else(isupper)
 653         set(F77_FUNCDEF   "${prefix} name ${suffix}")
 654         set(F77_FUNCDEF_  "${prefix} name ${extrasuffix}")
 655     endif(isupper)
 656 else(GMX_FORTRAN OR GMX_POWER6)
 657         set(F77_FUNCDEF   "name ## _")
 658         set(F77_FUNCDEF_  "name ## _")
 659 endif(GMX_FORTRAN OR GMX_POWER6)
 660
 661 # Process QM/MM Settings
 662 string(TOUPPER ${GMX_QMMM_PROGRAM} ${GMX_QMMM_PROGRAM})
 663 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 664     set(GMX_QMMM_GAUSSIAN 1)
 665 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 666     set(GMX_QMMM_MOPAC 1)
 667 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 668     set(GMX_QMMM_GAMESS 1)
 669 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 670     set(GMX_QMMM_ORCA 1)
 671 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 672     # nothing to do
 673 else(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 674     MESSAGE(FATAL_ERROR "Invalid QM/MM program option: ${GMX_QMMM_PROGRAM}. Choose one of: Gaussian, Mopac, Gamess, Orca, None")
 675 endif(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 676
 677 # Process FFT library settings - if not OpenMM build
 678 string(TOUPPER ${GMX_FFT_LIBRARY} ${GMX_FFT_LIBRARY})
 679 set(PKG_FFT "")
 680 set(PKG_FFT_LIBS "")
 681 if(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 682     if(GMX_DOUBLE)
 683         find_package(FFTW 3 COMPONENTS fftw)
 684     else(GMX_DOUBLE)
 685         find_package(FFTW 3 COMPONENTS fftwf)
 686     endif(GMX_DOUBLE)
 687     if(NOT FFTW_FOUND)
 688       MESSAGE(FATAL_ERROR "Cannot find FFTW3 (with correct precision - libfftw3f for single precision GROMACS or libfftw3 for double precision GROMACS). Fix it, choose another FFT library, or use the Gromacs built-in fftpack (slower)!")
 689     endif(NOT FFTW_FOUND)
 690     include_directories(${FFTW_INCLUDE_DIRS})
 691     set(FFT_LIBRARIES ${FFTW_LIBRARIES})
 692     set(PKG_FFT "${FFTW_PKG}")
 693
 694     set(GMX_FFT_FFTW3 1)
 695
 696     if (${GMX_ACCELERATION} STREQUAL "SSE" AND NOT FFTW_HAVE_SSE)
 697       message(WARNING "The fftw library found is compiled without SSE support, which makes it slow. Consider recompiling it or contact your admin")
 698     endif (${GMX_ACCELERATION} STREQUAL "SSE" AND NOT FFTW_HAVE_SSE)
 699
 700 elseif(${GMX_FFT_LIBRARY} STREQUAL "MKL")
 701 #    MESSAGE(STATUS "Using external FFT library - Intel MKL")
 702     find_package(MKL REQUIRED)
 703     include_directories(${MKL_INCLUDE_DIR})
 704     set(FFT_LIBRARIES ${MKL_LIBRARIES})
 705     set(PKG_FFT_LIBS ${MKL_LIBRARIES})
 706
 707     set(GMX_FFT_MKL 1)
 708     set(HAVE_MKL 1)
 709
 710 #elseif(${GMX_FFT_LIBRARY} STREQUAL "ACML")
 711 #    MESSAGE(STATUS "Using external FFT library - AMD core math library")
 712 #    set(GMX_FFT_ACML 1)
 713 elseif(${GMX_FFT_LIBRARY} STREQUAL "FFTPACK")
 714     MESSAGE(STATUS "Using internal FFT library - fftpack")
 715     set(GMX_FFT_FFTPACK 1)
 716 else(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 717     MESSAGE(FATAL_ERROR "Invalid FFT library setting: ${GMX_FFT_LIBRARY}. Choose one of: fftw3, mkl, fftpack")
 718 endif(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 719
 720 # MKL has BLAS/LAPACK routines
 721 if(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 722   set(GMX_EXTERNAL_BLAS TRUE CACHE BOOL "Use external BLAS instead of built-in")
 723   set(GMX_EXTERNAL_LAPACK TRUE CACHE BOOL "Use external LAPACK instead of built-in")
 724 else(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 725   set(GMX_EXTERNAL_BLAS FALSE CACHE BOOL "Use external BLAS instead of built-in")
 726   set(GMX_EXTERNAL_LAPACK FALSE CACHE BOOL "Use external LAPACK instead of built-in")
 727   if(GMX_EXTERNAL_BLAS)
 728     #FindBLAS needs Fortran
 729     enable_language(Fortran)
 730     if (GMX_BLAS_USER)
 731         list(APPEND GMX_EXTRA_LIBRARIES ${GMX_BLAS_USER})
 732     else(GMX_BLAS_USER)
 733         find_package(BLAS REQUIRED)
 734         list(APPEND GMX_EXTRA_LIBRARIES ${BLAS_LIBRARIES})
 735     endif(GMX_BLAS_USER)
 736   endif(GMX_EXTERNAL_BLAS)
 737   if(GMX_EXTERNAL_LAPACK)
 738     #FindLAPACK needs Fortran
 739     enable_language(Fortran)
 740         if (GMX_LAPACK_USER)
 741         list(APPEND GMX_EXTRA_LIBRARIES ${GMX_LAPACK_USER})
 742         else(GMX_LAPACK_USER)
 743         find_package(LAPACK REQUIRED)
 744         list(APPEND GMX_EXTRA_LIBRARIES ${LAPACK_LIBRARIES})
 745     endif(GMX_LAPACK_USER)
 746   endif(GMX_EXTERNAL_LAPACK)
 747 endif(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 748 mark_as_advanced(GMX_EXTERNAL_LAPACK)
 749 mark_as_advanced(GMX_EXTERNAL_BLAS)
 750
 751 set(GMX_USE_PLUGINS OFF CACHE INTERNAL "Whether GROMACS will really try to compile support for VMD plugins")
 752 set(GMX_VMD_PLUGIN_PATH)
 753 mark_as_advanced(GMX_VMD_PLUGIN_PATH)
 754
 755 if(GMX_LOAD_PLUGINS)
 756   if(CYGWIN OR NOT WIN32)
 757     # Native Windows does not have, nor need dlopen
 758     # Note that WIN32 is set with Cygwin, but Cygwin needs dlopen to use plug-ins
 759     include(gmxTestdlopen)
 760     gmx_test_dlopen(HAVE_DLOPEN)
 761   endif()
 762
 763   find_package(VMD)
 764
 765   # Test for unsuitable versions of VMD
 766
 767   if(VMD_FOUND AND NOT GMX_VMD_PLUGIN_PATH)
 768     message(STATUS "Checking for suitable VMD version")
 769     exec_program(${VMD_EXECUTABLE}
 770       ARGS --help
 771       OUTPUT_VARIABLE VMD_HELP
 772       RETURN_VALUE VMD_EXEC_RETURN)
 773
 774     if(VMD_EXEC_RETURN EQUAL 0)
 775       # This is the accepted idiom for subexpression matching, unfortunately
 776       string(REGEX REPLACE ".*VMD for .*, version ([0-9]+\\.[0-9]*\\.?[0-9]*).*" "\\1" VMD_VERSION ${VMD_HELP})
 777       string(REGEX REPLACE ".*VMD for (.*), version .*" "\\1" VMD_ARCH ${VMD_HELP})
 778
 779       if(VMD_VERSION VERSION_LESS "1.8")
 780         MESSAGE(WARNING "Found VMD version ${VMD_VERSION}, but GROMACS needs at least 1.8")
 781         unset(VMD_EXECUTABLE)
 782         set(VMD_FOUND FALSE)
 783       else()
 784         message(STATUS "VMD version ${VMD_VERSION} is suitable")
 785         if(DEFINED ENV{VMDDIR})
 786           # This permits GROMACS to avoid hard-coding a fall-back
 787           # path that it can tell right now would be useless.
 788           set(GMX_VMD_PLUGIN_PATH "$ENV{VMDDIR}/plugins/${VMD_ARCH}/molfile" CACHE PATH "Path to VMD plugins for molfile I/O")
 789         else()
 790           set(GMX_VMD_PLUGIN_PATH "/usr/local/lib/vmd/plugins/*/molfile" CACHE PATH "Path to VMD plugins for molfile I/O")
 791         endif()
 792       endif()
 793
 794       # clean up
 795       unset(VMD_HELP)
 796       unset(VMD_VERSION)
 797       unset(VMD_ARCH)
 798     endif()
 799   endif()
 800
 801   # so, should we use plug-ins?
 802   if((WIN32 AND NOT CYGWIN) OR (HAVE_DLOPEN AND BUILD_SHARED_LIBS))
 803     if (NOT VMD_QUIETLY)
 804       MESSAGE(STATUS "Found the ability to use plug-ins when building shared libaries, so will compile to use plug-ins (e.g. to read VMD-supported file formats).")
 805     endif(NOT VMD_QUIETLY)
 806     set(GMX_USE_PLUGINS ON)
 807     list(APPEND GMX_EXTRA_LIBRARIES ${CMAKE_DL_LIBS}) # magic cross-platform pre-set variable for dlopen library
 808     set(PKG_DL_LIBS "-l${CMAKE_DL_LIBS}")
 809   else()
 810     set(PKG_DL_LIBS)
 811   endif()
 812 endif(GMX_LOAD_PLUGINS)
 813 set(VMD_QUIETLY TRUE CACHE INTERNAL "")
 814
 815 # Math and thread libraries must often come after all others when linking...
 816 if(HAVE_LIBM)
 817     list(APPEND GMX_EXTRA_LIBRARIES m)
 818 endif(HAVE_LIBM)
 819
 820 if(GMX_FAHCORE)
 821   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 822       "Path to swindirect.h")
 823   include_directories(${COREWRAP_INCLUDE_DIR})
 824 endif(GMX_FAHCORE)
 825
 826 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 827 # these are set after everything else
 828 if (NOT DEFINED GROMACS_C_FLAGS_SET)
 829     set(GROMACS_C_FLAGS_SET true CACHE INTERNAL "Whether to reset the C flags"
 830         FORCE)
 831     set(CMAKE_C_FLAGS "${GROMACS_C_FLAGS} ${CMAKE_C_FLAGS}" CACHE STRING
 832         "Flags used by the compiler during all build types" FORCE)
 833     set(CMAKE_CXX_FLAGS "${GROMACS_CXX_FLAGS} ${CMAKE_CXX_FLAGS}" CACHE STRING
 834         "Flags used by the compiler during all build types" FORCE)
 835     set(CMAKE_EXE_LINKER_FLAGS
 836         "${GROMACS_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}"
 837         CACHE STRING "Linker flags" FORCE)
 838 endif (NOT DEFINED GROMACS_C_FLAGS_SET)
 839
 840 ########################################################################
 841 # Specify install locations and which subdirectories to process        #
 842 ########################################################################
 843 if ( DEFINED GMXLIB )
 844     set(LIB_INSTALL_DIR "${CMAKE_INSTALL_PREFIX}/${GMXLIB}")
 845 else()
 846     set(LIB_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/lib)
 847 endif()
 848 set(BIN_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/bin)
 849 set(DATA_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/gromacs)
 850 set(MAN_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/share/man)
 851 set(INCL_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/include)
 852
 853 set(GMXLIBDIR        ${DATA_INSTALL_DIR}/top)
 854
 855 ##################################################################
 856 # Shared library settings - Darwin uses INSTALL_NAME_DIR instead!
 857 ##################################################################
 858 if(NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin")
 859     set(CMAKE_SKIP_BUILD_RPATH  FALSE)
 860     set(CMAKE_BUILD_WITH_INSTALL_RPATH FALSE)
 861     set(CMAKE_INSTALL_RPATH "${LIB_INSTALL_DIR}")
 862     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 863 endif()
 864
 865 add_subdirectory(share)
 866 add_subdirectory(include)
 867 add_subdirectory(man)
 868 add_subdirectory(src)
 869 add_subdirectory(scripts)
 870
 871 #######################
 872 ## uninstall target
 873 #######################
 874     CONFIGURE_FILE(
 875                    "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 876                    "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
 877                    IMMEDIATE @ONLY)
 878 ###########################
 879 ADD_CUSTOM_TARGET(uninstall
 880                   "${CMAKE_COMMAND}" -P
 881                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
 882 ###########################
 883
 884
 885 ########################################################################
 886 # Tests                                                                #
 887 ########################################################################
 888
 889 include(CTest)
 890 mark_as_advanced(BUILD_TESTING)
 891 IF(BUILD_TESTING)
 892         enable_testing()
 893         add_subdirectory(tests)
 894 ENDIF()
 895