CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2009,2010,2011,2012,2013,2014, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 cmake_minimum_required(VERSION 2.8.8)
  36
  37 # CMake modules/macros are in a subdirectory to keep this file cleaner
  38 # This needs to be set before project() in order to pick up toolchain files
  39 list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake ${CMAKE_CURRENT_SOURCE_DIR}/cmake/Platform)
  40
  41 project(Gromacs)
  42
  43 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  44 set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  45 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
  46
  47 # PROJECT_VERSION should have the following structure:
  48 # VERSION-dev[-SUFFIX] where the VERSION should have the for: vMajor.vMinor.vPatch
  49 #
  50 # The "-dev" suffix is important to keep because it makes possible to distinguish
  51 # between a build from official release and a build from git release branch on a
  52 # machine with no git.
  53 #
  54 # NOTE: when releasing the "-dev" suffix needs to be stripped off!
  55 # REGRESSIONTEST_VERSION and REGRESSIONTEST_BRANCH should always be
  56 # defined.
  57 set(PROJECT_VERSION "5.1-dev")
  58 # If this is a released tarball, "-dev" will not be present in
  59 # PROJECT_VERSION, and REGRESSIONTEST_VERSION specifies the version
  60 # number of the regressiontest tarball against which the code tarball
  61 # can be tested. This will be the version of the last patch release.
  62 set(REGRESSIONTEST_VERSION "5.0-rc1")
  63 # If this is not a released tarball, "-dev" will be present in
  64 # PROJECT_VERSION, and REGRESSIONTEST_BRANCH specifies the name of the
  65 # gerrit.gromacs.org branch whose HEAD can test this code, *if* this
  66 # code contains all recent fixes from the corresponding code branch.
  67 set(REGRESSIONTEST_BRANCH "refs/heads/master")
  68
  69 set(CUSTOM_VERSION_STRING ""
  70     CACHE STRING "Custom version string (if empty, use hard-coded default)")
  71 mark_as_advanced(CUSTOM_VERSION_STRING)
  72 if (CUSTOM_VERSION_STRING)
  73     set(PROJECT_VERSION ${CUSTOM_VERSION_STRING})
  74 endif()
  75 set(LIBRARY_SOVERSION 0)
  76 set(LIBRARY_VERSION ${LIBRARY_SOVERSION}.0.0)
  77 # It is a bit irritating, but this has to be set separately for now!
  78 SET(CPACK_PACKAGE_VERSION_MAJOR "5")
  79 SET(CPACK_PACKAGE_VERSION_MINOR "1")
  80 #SET(CPACK_PACKAGE_VERSION_PATCH "0")
  81
  82 # The numerical gromacs version. It is 40600 for 4.6.0.
  83 # The #define GMX_VERSION in gromacs/version.h is set to this value.
  84 math(EXPR NUM_VERSION
  85     "${CPACK_PACKAGE_VERSION_MAJOR}*10000 + ${CPACK_PACKAGE_VERSION_MINOR}*100")
  86 if(CPACK_PACKAGE_VERSION_PATCH)
  87     math(EXPR NUM_VERSION
  88          "${NUM_VERSION} + ${CPACK_PACKAGE_VERSION_PATCH}")
  89 endif()
  90
  91 # The API version tracks the numerical Gromacs version (for now).
  92 # It is potentially different from the Gromacs version in the future, if
  93 # the programs/libraries diverge from the presumably more stable API.
  94 # The #define GMX_API_VERSION in version.h is set to this value to
  95 # provide backward compatibility of software written against the Gromacs API.
  96 set(API_VERSION ${NUM_VERSION})
  97
  98 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT AND UNIX)
  99     set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
 100 endif()
 101
 102 set(GMX_INSTALL_PREFIX "" CACHE STRING "Prefix gets appended to CMAKE_INSTALL_PREFIX. For cpack it sets the root folder of the archive.")
 103 mark_as_advanced(GMX_INSTALL_PREFIX)
 104
 105 include(gmxBuildTypeReference)
 106 include(gmxBuildTypeProfile)
 107 include(gmxBuildTypeTSAN)
 108 include(gmxBuildTypeASAN)
 109 include(gmxBuildTypeReleaseWithAssert)
 110
 111 if(NOT CMAKE_BUILD_TYPE)
 112     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel Reference RelWithAssert Profile." FORCE)
 113     # There's no need to offer a user the choice of ThreadSanitizer
 114     # Set the possible values of build type for cmake-gui
 115     set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "Debug" "Release"
 116         "MinSizeRel" "RelWithDebInfo" "Reference" "RelWithAssert" "Profile")
 117 endif()
 118 if(CMAKE_CONFIGURATION_TYPES)
 119     # Add appropriate GROMACS-specific build types for the Visual
 120     # Studio generator (Debug, Release, MinSizeRel and RelWithDebInfo
 121     # are already present by default).
 122     list(APPEND CMAKE_CONFIGURATION_TYPES "RelWithAssert" "Reference")
 123     list(REMOVE_DUPLICATES CMAKE_CONFIGURATION_TYPES)
 124     set(CMAKE_CONFIGURATION_TYPES "${CMAKE_CONFIGURATION_TYPES}" CACHE STRING
 125         "List of configuration types"
 126         FORCE)
 127 endif()
 128 set(build_types_with_explicit_flags RELEASE DEBUG RELWITHDEBUGINFO RELWITHASSERT MINSIZEREL PROFILE)
 129
 130 enable_language(C)
 131 enable_language(CXX)
 132
 133 set(CPACK_PACKAGE_VERSION ${PROJECT_VERSION})
 134 set(CPACK_PACKAGE_VENDOR "gromacs.org")
 135 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Gromacs - a toolkit for high-performance molecular simulation")
 136 set(CPACK_RESOURCE_FILE_WELCOME "${CMAKE_SOURCE_DIR}/admin/InstallWelcome.txt")
 137 # Its GPL/LGPL, so they do not have to agree to a license for mere usage, but some installers require this...
 138 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_SOURCE_DIR}/COPYING")
 139 set(CPACK_RESOURCE_FILE_README "${CMAKE_SOURCE_DIR}/admin/InstallInfo.txt")
 140 set(CPACK_SOURCE_IGNORE_FILES "\\\\.isreposource$;\\\\.git/;\\\\.gitignore$")
 141 set(CPACK_PROJECT_CONFIG_FILE "${CMAKE_SOURCE_DIR}/CPackInit.cmake")
 142 set(CPACK_SOURCE_INSTALLED_DIRECTORIES "${CMAKE_SOURCE_DIR};/;${CMAKE_BINARY_DIR}/src/programs/completion;src/programs/completion;${CMAKE_BINARY_DIR}/share/man/man1;share/man/man1;${CMAKE_BINARY_DIR}/share/man/man7;share/man/man7;${CMAKE_BINARY_DIR}/share/html/final;share/html/final")
 143 set(CPACK_PACKAGE_CONTACT "gmx-users@gromacs.org")
 144
 145 #must come after all cpack settings!
 146 include(CPack)
 147
 148 # Set a default valgrind suppression file.
 149 # This unfortunately needs to duplicate information from CTest to work as
 150 # expected...
 151 set(MEMORYCHECK_SUPPRESSIONS_FILE
 152     "${CMAKE_SOURCE_DIR}/cmake/legacy_and_external.supp"
 153     CACHE FILEPATH
 154     "File that contains suppressions for the memory checker")
 155 include(CTest)
 156
 157 set(SOURCE_IS_GIT_REPOSITORY OFF)
 158 set(SOURCE_IS_SOURCE_DISTRIBUTION OFF)
 159 if(EXISTS "${CMAKE_SOURCE_DIR}/.git")
 160     set(SOURCE_IS_GIT_REPOSITORY ON)
 161 endif()
 162 if(NOT EXISTS "${CMAKE_SOURCE_DIR}/admin/.isreposource")
 163     set(SOURCE_IS_SOURCE_DISTRIBUTION ON)
 164 endif()
 165
 166 ########################################################################
 167 # Check and warn if cache generated on a different host is being reused
 168 ########################################################################
 169 if(CMAKE_HOST_UNIX)
 170     execute_process(COMMAND hostname
 171                     OUTPUT_VARIABLE TMP_HOSTNAME
 172                     OUTPUT_STRIP_TRAILING_WHITESPACE)
 173     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}")
 174         message(WARNING "
 175             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
 176             is being reused! This could lead to inconsitencies; therefore, it is
 177             recommended to regenerate the cache!")
 178     endif()
 179     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
 180             "Hostname of the machine where the cache was generated.")
 181 endif()
 182
 183 ########################################################################
 184 # User input options                                                   #
 185 ########################################################################
 186 include(gmxOptionUtilities)
 187
 188 set(CMAKE_PREFIX_PATH "" CACHE STRING "Extra locations to search for external libraries and tools (give directory without lib, bin, or include)")
 189
 190 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" OFF)
 191 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 192 option(GMX_THREAD_MPI  "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" ON)
 193 gmx_dependent_option(
 194     GMX_MPI_IN_PLACE
 195     "Enable MPI_IN_PLACE for MPIs that have it defined"
 196     ON
 197     GMX_MPI)
 198 mark_as_advanced(GMX_MPI_IN_PLACE)
 199 option(GMX_SOFTWARE_INVSQRT "Use GROMACS software 1/sqrt" ON)
 200 mark_as_advanced(GMX_SOFTWARE_INVSQRT)
 201 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 202 mark_as_advanced(GMX_FAHCORE)
 203
 204 option(GMX_COOL_QUOTES "Enable Gromacs cool quotes" ON)
 205 mark_as_advanced(GMX_COOL_QUOTES)
 206 gmx_add_cache_dependency(GMX_COOL_QUOTES BOOL "NOT GMX_FAHCORE" OFF)
 207
 208 # decide on GPU settings based on user-settings and GPU/CUDA detection
 209 include(gmxManageGPU)
 210
 211 # Detect the architecture the compiler is targetting, detect
 212 # SIMD instructions possibilities on that hardware, suggest SIMD instruction set
 213 # to use if none is specified, and populate the cache option for CPU
 214 # SIMD.
 215 include(gmxDetectTargetArchitecture)
 216 gmx_detect_target_architecture()
 217
 218 if(GMX_CPU_ACCELERATION)
 219     # Stay compatible with old Jenkins command line options for specific SIMD acceleration
 220     set(GMX_SIMD "${GMX_CPU_ACCELERATION}" CACHE STRING "SIMD instruction set level and compiler optimization" FORCE)
 221 endif()
 222
 223 if(NOT GMX_TARGET_MIC)
 224     include(gmxDetectSimd)
 225     gmx_detect_simd(GMX_SUGGESTED_SIMD)
 226 else()
 227     set(GMX_SUGGESTED_SIMD "None")
 228 endif()
 229
 230 gmx_option_multichoice(
 231     GMX_SIMD
 232     "SIMD instruction set for CPU kernels and compiler optimization"
 233     "${GMX_SUGGESTED_SIMD}"
 234     None SSE2 SSE4.1 AVX_128_FMA AVX_256 AVX2_256 IBM_QPX Sparc64_HPC_ACE Reference)
 235
 236 gmx_option_multichoice(
 237     GMX_FFT_LIBRARY
 238     "FFT library"
 239     "fftw3"
 240     fftw3 mkl "fftpack[built-in]")
 241 gmx_dependent_option(
 242     GMX_BUILD_OWN_FFTW
 243     "Download and build FFTW 3 during the GROMACS build process, rather than fall back on the really slow fftpack."
 244     OFF
 245     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 246 gmx_dependent_option(
 247     GMX_DISABLE_FFTW_MEASURE
 248     "Do not optimize FFTW setups (not needed with SSE)"
 249     OFF
 250     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 251 mark_as_advanced(GMX_BUILD_OWN_FFTW)
 252 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 253
 254 gmx_option_multichoice(
 255     GMX_QMMM_PROGRAM
 256     "QM package for QM/MM"
 257     None
 258     none gaussian mopac gamess orca)
 259
 260 gmx_dependent_cache_variable(GMX_SIMD_REF_FLOAT_WIDTH  "Reference SIMD single precision width" STRING "4" "GMX_SIMD STREQUAL REFERENCE")
 261 gmx_dependent_cache_variable(GMX_SIMD_REF_DOUBLE_WIDTH "Reference SIMD double precision width" STRING "2" "GMX_SIMD STREQUAL REFERENCE")
 262
 263 # This should be moved to a separate NBNXN cmake module when that code is cleaned up and modularized
 264
 265 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 266 mark_as_advanced(GMX_BROKEN_CALLOC)
 267 option(GMX_LOAD_PLUGINS "Compile with plugin support, needed to read VMD supported file formats" ON)
 268 mark_as_advanced(GMX_LOAD_PLUGINS)
 269
 270 option(GMX_GPU  "Enable GPU acceleration" ON)
 271 option(GMX_OPENMP "Enable OpenMP-based multithreading" ON)
 272
 273 option(GMX_USE_TNG "Use the TNG library for trajectory I/O" ON)
 274
 275 option(GMX_GIT_VERSION_INFO "Generate git version information" ${SOURCE_IS_GIT_REPOSITORY})
 276 mark_as_advanced(GMX_GIT_VERSION_INFO)
 277
 278 if(UNIX)
 279     option(GMX_SYMLINK_OLD_BINARY_NAMES "Create symbolic links for pre-5.0 binary names" ON)
 280 endif()
 281 option(GMX_BUILD_MDRUN_ONLY "Build and install only the mdrun binary" OFF)
 282
 283 option(GMX_CYCLE_SUBCOUNTERS "Enable cycle subcounters to get a more detailed cycle timings" OFF)
 284 mark_as_advanced(GMX_CYCLE_SUBCOUNTERS)
 285
 286 option(GMX_SKIP_DEFAULT_CFLAGS "Don't automatically add suggested/required Compiler flags." OFF)
 287 mark_as_advanced(GMX_SKIP_DEFAULT_CFLAGS)
 288
 289 option(GMX_BUILD_FOR_COVERAGE
 290        "Tune build for better code coverage metrics (e.g., disable asserts)"
 291        OFF)
 292 mark_as_advanced(GMX_BUILD_FOR_COVERAGE)
 293
 294
 295 ######################################################################
 296 # Detect OpenMP support
 297 ######################################################################
 298 # The OpenMP detection _must_ come before tests for other CFLAGS.
 299 include(gmxManageOpenMP)
 300
 301
 302
 303 ######################################################################
 304 # Compiler tests
 305 # These need to be done early (before further tests).
 306 #####################################################################
 307
 308 # The cmake/Check{C,CXX}CompilerFlag.cmake files in the GROMACS distribution
 309 # are used with permission from CMake v2.8.9 so that GROMACS can detect
 310 # invalid options with the Intel Compilers.
 311 # These files should be removed from the source tree when a CMake version that
 312 # includes the features in question becomes required for building GROMACS.
 313 include(CheckCCompilerFlag)
 314 include(CheckCXXCompilerFlag)
 315
 316
 317 include(gmxCFlags)
 318 gmx_c_flags()
 319
 320 # This variable should be used for additional compiler flags which are not
 321 # generated in gmxCFlags nor are SIMD or MPI related.
 322 set(EXTRA_C_FLAGS "")
 323 set(EXTRA_CXX_FLAGS "")
 324
 325 # Run through a number of tests for buggy compilers and other issues
 326 include(gmxTestCompilerProblems)
 327 gmx_test_compiler_problems()
 328
 329
 330 set(PKG_CFLAGS "")
 331 if(GMX_DOUBLE)
 332     add_definitions(-DGMX_DOUBLE)
 333     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_DOUBLE")
 334 endif()
 335 if(GMX_SOFTWARE_INVSQRT)
 336   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_SOFTWARE_INVSQRT")
 337 endif()
 338
 339 if(WIN32 AND NOT CYGWIN)
 340     set(GMX_WSOCKLIB_PATH CACHE PATH "Path to winsock (wsock32.lib) library.")
 341     mark_as_advanced(GMX_WSOCKLIB_PATH)
 342     find_library(WSOCK32_LIBRARY NAMES wsock32 PATHS ${GMX_WSOCKLIB_PATH})
 343     if(WSOCK32_LIBRARY)
 344         list(APPEND GMX_EXTRA_LIBRARIES ${WSOCK32_LIBRARY})
 345         add_definitions(-DGMX_HAVE_WINSOCK)
 346     else()
 347         message(STATUS "No winsock found. Cannot use interactive molecular dynamics (IMD).")
 348     endif(WSOCK32_LIBRARY)
 349 endif()
 350
 351
 352
 353 ########################################################################
 354 # Basic system tests (standard libraries, headers, functions, types)   #
 355 ########################################################################
 356 include(CheckIncludeFiles)
 357 include(CheckIncludeFileCXX)
 358 check_include_files(unistd.h     HAVE_UNISTD_H)
 359 check_include_files(pwd.h        HAVE_PWD_H)
 360 check_include_files(dirent.h     HAVE_DIRENT_H)
 361 check_include_files(time.h       HAVE_TIME_H)
 362 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 363 check_include_files(io.h         HAVE_IO_H)
 364 check_include_files(sched.h      HAVE_SCHED_H)
 365
 366 check_include_files(regex.h      HAVE_POSIX_REGEX)
 367 check_include_file_cxx(regex     HAVE_CXX11_REGEX)
 368 # TODO: It could be nice to inform the user if no regex support is found,
 369 # as selections won't be fully functional.
 370
 371 include(CheckFunctionExists)
 372 check_function_exists(posix_memalign    HAVE_POSIX_MEMALIGN)
 373 check_function_exists(memalign          HAVE_MEMALIGN)
 374 check_function_exists(_aligned_malloc   HAVE__ALIGNED_MALLOC)
 375 check_function_exists(gettimeofday      HAVE_GETTIMEOFDAY)
 376 check_function_exists(fsync             HAVE_FSYNC)
 377 check_function_exists(_fileno           HAVE__FILENO)
 378 check_function_exists(fileno            HAVE_FILENO)
 379 check_function_exists(_commit           HAVE__COMMIT)
 380 check_function_exists(sigaction         HAVE_SIGACTION)
 381 check_function_exists(sysconf           HAVE_SYSCONF)
 382 check_function_exists(sched_setaffinity HAVE_SCHED_SETAFFINITY)
 383 check_function_exists(sched_getaffinity HAVE_SCHED_GETAFFINITY)
 384 check_function_exists(rsqrt             HAVE_RSQRT)
 385 check_function_exists(rsqrtf            HAVE_RSQRTF)
 386 check_function_exists(sqrtf             HAVE_SQRTF)
 387
 388 include(CheckLibraryExists)
 389 check_library_exists(m sqrt "" HAVE_LIBM)
 390 check_library_exists(rt clock_gettime "" HAVE_CLOCK_GETTIME)
 391
 392 include(TestBigEndian)
 393 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 394
 395 # Management of GROMACS options for specific toolchains should go
 396 # here. Because the initial settings for some of the main options have
 397 # already happened, but things like library detection and MPI compiler
 398 # feature detection have not, the docstrings for any over-rides of
 399 # GROMACS defaults or user settings will make sense. Also, any
 400 # toolchain-related reasons for choosing whether to detect various
 401 # things can be sorted out now, before the detection takes place.
 402 if(${CMAKE_SYSTEM_NAME} MATCHES BlueGene)
 403     include(gmxManageBlueGene)
 404 endif()
 405
 406 ########################################################################
 407 #Process MPI settings
 408 ########################################################################
 409 include(gmxManageMPI)
 410
 411
 412 ########################################################################
 413 #Process shared/static library settings
 414 ########################################################################
 415 include(gmxManageSharedLibraries)
 416
 417
 418 ########################################################################
 419 # Find external packages                                               #
 420 ########################################################################
 421
 422 # Unconditionally find the package, as it is also required for unit
 423 # tests. This exports LIBXML2_FOUND, which we should not use because
 424 # it does not tell us that linking will succeed. Instead, we test that
 425 # next.
 426 find_package(LibXml2)
 427 include(gmxTestLibXml2)
 428 gmx_test_libxml2(HAVE_LIBXML2)
 429 option(GMX_XML "Use libxml2 to parse xml files (currently has no effect)" ${HAVE_LIBXML2})
 430 set(PKG_XML "")
 431 mark_as_advanced(GMX_XML)
 432 # Don't actually do anything, since libxml2 is currently not used by libgromacs
 433 #if(GMX_XML AND NOT HAVE_LIBXML2)
 434 #    message(FATAL_ERROR "libxml2 not found. Set GMX_XML=OFF to compile without XML support")
 435 #endif()
 436 #if(GMX_XML)
 437 #    include_directories(${LIBXML2_INCLUDE_DIR})
 438 #    set(PKG_XML libxml-2.0)
 439 #    set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 440 #endif()
 441
 442 option(GMX_EXTRAE "Add support for tracing using EXTRAE" OFF)
 443 mark_as_advanced(GMX_EXTRAE)
 444
 445 if (GMX_EXTRAE)
 446   find_package(EXTRAE)
 447   if(EXTRAE_FOUND)
 448     include_directories(${EXTRAE_INCLUDE_DIR})
 449     set(HAVE_EXTRAE 1)
 450   else()
 451     message(FATAL_ERROR "EXTRAE library was not found. Please add the correct path to CMAKE_PREFIX_PATH")
 452   endif()
 453 endif()
 454
 455 option(GMX_X11 "Use X window system" OFF)
 456 if (GMX_X11)
 457     find_package(X11)
 458     # X11 includes/libraries are only set in the ngmx subdirectory!
 459     if(NOT X11_FOUND)
 460         message(FATAL_ERROR
 461                 "X11 include files and/or libraries were not found. "
 462                 "Set GMX_X11=OFF to compile without X11 support. "
 463                 "gmx view will not be available.")
 464     endif()
 465     include_directories(${X11_INCLUDE_DIR})
 466 endif()
 467
 468 include(ThreadMPI)
 469 # Enable core threading facilities
 470 tmpi_enable_core("${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include")
 471 # Enable tMPI C++ support
 472 tmpi_enable_cxx()
 473 if(GMX_THREAD_MPI)
 474     # enable MPI functions
 475     tmpi_enable()
 476     set(GMX_MPI 1)
 477     set(MPI_IN_PLACE_EXISTS 1)
 478 endif()
 479 # If atomics are manually disabled a define is needed because atomics.h doesn't depend on config.h
 480 if (TMPI_ATOMICS_DISABLED)
 481    add_definitions(-DTMPI_ATOMICS_DISABLED)
 482 endif()
 483
 484 if(GMX_GPU)
 485     # now that we have detected the dependencies, do the second configure pass
 486     gmx_gpu_setup()
 487 endif()
 488
 489 if(CYGWIN)
 490     set(GMX_CYGWIN 1)
 491 endif()
 492
 493 if(WIN32 AND NOT CYGWIN)
 494     set(GMX_NATIVE_WINDOWS 1)
 495     # This makes windows.h not declare min/max as macros that would break
 496     # C++ code using std::min/std::max.
 497     add_definitions(-DNOMINMAX)
 498 endif()
 499
 500 # only bother with finding git and using version.h if the source is a git repo
 501 if(GMX_GIT_VERSION_INFO)
 502     if (NOT SOURCE_IS_GIT_REPOSITORY)
 503         message(FATAL_ERROR
 504             "Cannot generate git version information from source tree not under git. "
 505             "Set GMX_GIT_VERSION_INFO=OFF to proceed.")
 506     endif()
 507     # We need at least git v1.5.3 be able to parse git's date output. If not
 508     # found or the version is too small, we can't generate version information.
 509     find_package(Git)
 510
 511     if(NOT GIT_FOUND OR GIT_VERSION_STRING VERSION_LESS "1.5.3")
 512         message(FATAL_ERROR
 513             "No compatible git version found (>= 1.5.3 required). "
 514             "Won't be able to generate development version information. "
 515             "Set GMX_GIT_VERSION_INFO=OFF to proceed.")
 516     endif()
 517 endif()
 518
 519 # Detect boost unless GMX_EXTERNAL_BOOST is explicitly OFF
 520 # Used for default if GMX_EXTERNAL_BOOST is not defined (first CMake pass)
 521 if(NOT DEFINED GMX_EXTERNAL_BOOST OR GMX_EXTERNAL_BOOST)
 522     find_package(Boost 1.44.0)
 523     if(Boost_FOUND AND Boost_VERSION VERSION_LESS "104400")
 524         set(Boost_FOUND FALSE)
 525     endif()
 526     # Print the notification only on first run, when determining the default
 527     if(NOT DEFINED GMX_EXTERNAL_BOOST AND NOT Boost_FOUND)
 528         message("Boost >= 1.44 not found. Using minimal internal version. "
 529                 "This may cause trouble if you plan on compiling/linking other "
 530                 "software that uses Boost against Gromacs.")
 531     endif()
 532 endif()
 533 option(GMX_EXTERNAL_BOOST "Use external Boost instead of minimal built-in version"
 534        ${Boost_FOUND})
 535 if(GMX_EXTERNAL_BOOST AND NOT Boost_FOUND)
 536     message(FATAL_ERROR
 537         "Boost >= 1.44 not found. "
 538         "You can set GMX_EXTERNAL_BOOST=OFF to compile against minimal "
 539         "version of Boost included with Gromacs.")
 540 endif()
 541
 542 option(GMX_BUILD_UNITTESTS "Build unit tests with BUILD_TESTING (uses Google C++ Testing and Mocking Frameworks, requires libxml2)" ${HAVE_LIBXML2})
 543 mark_as_advanced(GMX_BUILD_UNITTESTS)
 544 gmx_add_cache_dependency(GMX_BUILD_UNITTESTS BOOL BUILD_TESTING OFF)
 545 if (GMX_BUILD_UNITTESTS AND NOT HAVE_LIBXML2)
 546     message(FATAL_ERROR
 547         "Cannot build unit tests without libxml2. "
 548         "Either set GMX_BUILD_UNITTESTS=OFF or tell CMake how to find a working version of libxml2.")
 549 endif()
 550
 551 ########################################################################
 552 # Generate development version info for cache
 553 ########################################################################
 554 # set(GEN_VERSION_INFO_INTERNAL "ON")
 555 # include(gmxGenerateVersionString)
 556
 557 ########################################################################
 558 # Our own GROMACS tests
 559 ########################################################################
 560
 561 add_definitions( -DHAVE_CONFIG_H )
 562 include_directories(${CMAKE_SOURCE_DIR}/src)
 563 include_directories(${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include)
 564 # Required for config.h, maybe should only be set in src/CMakeLists.txt
 565 include_directories(${CMAKE_BINARY_DIR}/src)
 566 # Required for gmx_header_config_gen.h to be found before installation
 567 include_directories(${CMAKE_BINARY_DIR}/src/gromacs/utility)
 568 # Required for now to make old code compile
 569 include_directories(${CMAKE_SOURCE_DIR}/src/gromacs/legacyheaders)
 570
 571 include(gmxTestInlineASM)
 572 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 573
 574 include(gmxSetBuildInformation)
 575 gmx_set_build_information()
 576 # Turn on RDTSCP if:
 577 # - the build system's CPU supports it
 578 # - the acceleration is set to AVX as all AVX-capable CPUs support AVX (which
 579 #   at this point means that the user set it).
 580 # Note: it's better to not use the later set value of GMX_SIMD because
 581 # it reflects the system's capability of both compiling and running AVX code.
 582 # TODO: After merge with 5.0 one could implement a cache variable dependency
 583 # such that GMX_USE_RDTSCP can change if GMX_CPU_ACCELERATION is changed to AVX
 584 # after the first cmake pass.
 585 if (BUILD_CPU_FEATURES MATCHES "rdtscp" OR GMX_SIMD MATCHES "AVX")
 586     set(GMX_USE_RDTSCP_DEFAULT_VALUE ON)
 587 else()
 588     set(GMX_USE_RDTSCP_DEFAULT_VALUE OFF)
 589 endif()
 590 option(GMX_USE_RDTSCP "Use RDTSCP for better CPU-based timers (available on recent x86 CPUs; might need to be off when compiling for heterogeneous environments)" ${GMX_USE_RDTSCP_DEFAULT_VALUE})
 591 mark_as_advanced(GMX_USE_RDTSCP)
 592 if(GMX_USE_RDTSCP)
 593     set(HAVE_RDTSCP 1)
 594 endif()
 595
 596 include(gmxTestFloatFormat)
 597 gmx_test_float_format(GMX_FLOAT_FORMAT_IEEE754
 598                       GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER
 599                       GMX_IEEE754_BIG_ENDIAN_WORD_ORDER)
 600
 601 include(gmxTestLargeFiles)
 602 gmx_test_large_files(GMX_LARGEFILES)
 603
 604 include(gmxTestSignal)
 605 gmx_test_sigusr1(HAVE_SIGUSR1)
 606
 607 include(gmxTestPipes)
 608 gmx_test_pipes(HAVE_PIPES)
 609
 610 include(gmxTestIsfinite)
 611 gmx_test_isfinite(HAVE_ISFINITE)
 612 gmx_test__isfinite(HAVE__ISFINITE)
 613 gmx_test__finite(HAVE__FINITE)
 614
 615 include(gmxTestCXX11)
 616 gmx_test_cxx11(GMX_CXX11_SUPPORTED GMX_CXX11_FLAGS)
 617 include(CMakeDependentOption)
 618 # nvcc does not support C++11 flags, so with GPUs we prefer to skip C++11 flags
 619 # entirely to keep the compilation environment uniform.
 620 cmake_dependent_option(GMX_CXX11
 621     "Use C++11 features"
 622     ON "GMX_CXX11_SUPPORTED AND NOT GMX_GPU" OFF)
 623 mark_as_advanced(GMX_CXX11)
 624 if(GMX_CXX11)
 625     set(EXTRA_CXX_FLAGS "${EXTRA_CXX_FLAGS} ${GMX_CXX11_FLAGS}")
 626 endif()
 627
 628
 629 include(gmxTestXDR)
 630 gmx_test_xdr(GMX_SYSTEM_XDR)
 631 if(NOT GMX_SYSTEM_XDR)
 632     set(GMX_INTERNAL_XDR 1)
 633 endif()
 634
 635
 636 ##################################################
 637 # Process SIMD instruction settings
 638 ##################################################
 639 # This checks what flags to add in order to
 640 # support the SIMD instructions we need, and sets
 641 # correct defines for the SIMD instructions supported.
 642 include(gmxTestSimd)
 643 gmx_test_simd()
 644
 645
 646 # Process QM/MM Settings
 647 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 648     set(GMX_QMMM_GAUSSIAN 1)
 649 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 650     set(GMX_QMMM_MOPAC 1)
 651 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 652     set(GMX_QMMM_GAMESS 1)
 653 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 654     set(GMX_QMMM_ORCA 1)
 655 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 656     # nothing to do
 657 else()
 658     gmx_invalid_option_value(GMX_QMMM_PROGRAM)
 659 endif()
 660
 661
 662 ##################################################
 663 # Process FFT library settings
 664 ##################################################
 665 include(gmxManageFFTLibraries)
 666
 667
 668 include(gmxManageLinearAlgebraLibraries)
 669
 670 # Whether GROMACS will really try to compile support for VMD plugins
 671 set(GMX_USE_PLUGINS OFF)
 672
 673 if(GMX_LOAD_PLUGINS)
 674   if(CYGWIN OR NOT WIN32)
 675     # Native Windows does not have, nor need dlopen
 676     # Note that WIN32 is set with Cygwin, but Cygwin needs dlopen to use plug-ins
 677     include(gmxTestdlopen)
 678     gmx_test_dlopen(HAVE_DLOPEN)
 679   endif()
 680
 681   # so, should we use plug-ins?
 682   if((WIN32 AND NOT CYGWIN) OR (HAVE_DLOPEN AND BUILD_SHARED_LIBS))
 683     if(NOT VMD_QUIETLY)
 684       MESSAGE(STATUS
 685           "Found the ability to use plug-ins when building shared libaries, "
 686           "so will compile to use plug-ins (e.g. to read VMD-supported file "
 687           "formats).")
 688     endif()
 689     if(NOT GMX_VMD_PLUGIN_PATH)
 690       find_package(VMD)
 691     endif()
 692     set(GMX_USE_PLUGINS ON)
 693     list(APPEND GMX_EXTRA_LIBRARIES ${CMAKE_DL_LIBS}) # magic cross-platform pre-set variable for dlopen library
 694     set(PKG_DL_LIBS "-l${CMAKE_DL_LIBS}")
 695   else()
 696     set(PKG_DL_LIBS)
 697   endif()
 698 endif()
 699 set(VMD_QUIETLY TRUE CACHE INTERNAL "")
 700
 701 # Link real-time library for POSIX timers. The check for clock_gettime
 702 # confirms the linkability of rt.
 703 if(HAVE_TIME_H AND HAVE_UNISTD_H AND HAVE_CLOCK_GETTIME)
 704     list(APPEND GMX_EXTRA_LIBRARIES rt)
 705 endif()
 706
 707 # Math and thread libraries must often come after all others when linking...
 708 if(HAVE_LIBM)
 709     list(APPEND GMX_EXTRA_LIBRARIES m)
 710 endif()
 711
 712 option(GMX_NACL "Configure for Native Client builds" OFF)
 713 if (GMX_NACL)
 714   list(APPEND GMX_EXTRA_LIBRARIES nosys)
 715   set(GMX_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -lnosys")
 716   set(GMX_NO_NICE 1)
 717   set(GMX_NO_RENAME 1)
 718 endif()
 719 mark_as_advanced(GMX_NACL)
 720
 721 if(GMX_FAHCORE)
 722   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 723       "Path to swindirect.h")
 724   include_directories(${COREWRAP_INCLUDE_DIR})
 725 endif()
 726
 727 option(GMX_BUILD_HELP "Build man pages, HTML help, and completions automatically (requires that compiled binaries can be executed on the build host)" OFF)
 728 mark_as_advanced(GMX_BUILD_HELP)
 729 if (GMX_BUILD_HELP AND SOURCE_IS_SOURCE_DISTRIBUTION AND
 730     "${CMAKE_CURRENT_SOURCE_DIR}" STREQUAL "${CMAKE_CURRENT_BINARY_DIR}")
 731
 732     message(FATAL_ERROR
 733         "Rebuilding HTML and man pages is not supported for in-source "
 734         "builds from a source distribution. "
 735         "Set GMX_BUILD_HELP=OFF or do an out-of-source build to proceed.")
 736 endif()
 737
 738 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 739 # these are set after everything else
 740 if (NOT GMX_SKIP_DEFAULT_CFLAGS)
 741     set(CMAKE_C_FLAGS "${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${CMAKE_C_FLAGS}")
 742     set(CMAKE_CXX_FLAGS "${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${CMAKE_CXX_FLAGS}")
 743     set(CMAKE_EXE_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}")
 744     set(CMAKE_SHARED_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS}")
 745 else()
 746     message("Recommended flags which are not added because GMX_SKIP_DEFAULT_CFLAGS=yes:")
 747     message("CMAKE_C_FLAGS: ${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${GMXC_CFLAGS}")
 748     message("CMAKE_C_FLAGS_RELEASE: ${GMXC_CFLAGS_RELEASE}")
 749     message("CMAKE_C_FLAGS_DEBUG: ${GMXC_CFLAGS_DEBUG}")
 750     message("CMAKE_CXX_FLAGS: ${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${GMXC_CXXFLAGS}")
 751     message("CMAKE_CXX_FLAGS_RELEASE: ${GMXC_CXXFLAGS_RELEASE}")
 752     message("CMAKE_CXX_FLAGS_DEBUG: ${GMXC_CXXFLAGS_DEBUG}")
 753     message("CMAKE_EXE_LINKER_FLAGS: ${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS}")
 754     message("CMAKE_SHARED_LINKER_FLAGS: ${MPI_LINKER_FLAGS}")
 755 endif()
 756
 757 if(NOT GMX_OPENMP)
 758     #Unset all OpenMP flags in case OpenMP was disabled either by the user
 759     #or because it was only partially detected (e.g. only for C but not C++ compiler)
 760     unset(OpenMP_C_FLAGS CACHE)
 761     unset(OpenMP_CXX_FLAGS CACHE)
 762 else()
 763     set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} ${OpenMP_LINKER_FLAGS})
 764     set(GMX_SHARED_LINKER_FLAGS ${GMX_SHARED_LINKER_FLAGS} ${OpenMP_SHARED_LINKER_FLAGS})
 765 endif()
 766 set(PKG_CFLAGS "${PKG_CFLAGS} ${OpenMP_C_FLAGS}")
 767
 768 ########################################################################
 769 # Specify install locations
 770 ########################################################################
 771 set(GMX_LIB_INSTALL_DIR lib CACHE STRING
 772     "Library installation directory (default: lib)")
 773 set(GMX_DATA_INSTALL_DIR gromacs CACHE STRING
 774     "Data installation directory under share/ (default: gromacs)")
 775 mark_as_advanced(GMX_LIB_INSTALL_DIR GMX_DATA_INSTALL_DIR)
 776
 777 set(LIB_INSTALL_DIR  ${GMX_INSTALL_PREFIX}${GMX_LIB_INSTALL_DIR})
 778 set(BIN_INSTALL_DIR  ${GMX_INSTALL_PREFIX}bin)
 779 set(DATA_INSTALL_DIR ${GMX_INSTALL_PREFIX}share/${GMX_DATA_INSTALL_DIR})
 780 set(MAN_INSTALL_DIR  ${GMX_INSTALL_PREFIX}share/man)
 781 set(INCL_INSTALL_DIR ${GMX_INSTALL_PREFIX}include)
 782
 783 set(GMXLIB_SEARCH_DIR share/${GMX_DATA_INSTALL_DIR}/top)
 784 set(GMXLIB_FALLBACK   ${CMAKE_INSTALL_PREFIX}/${DATA_INSTALL_DIR}/top)
 785
 786 # Binary and library suffix options
 787 include(gmxManageSuffixes)
 788
 789 ##################################################################
 790 # Shared library settings
 791 ##################################################################
 792 if(NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin")
 793     if(GMX_LIB_INSTALL_DIR STREQUAL "lib")
 794         set(CMAKE_BUILD_WITH_INSTALL_RPATH TRUE)
 795     endif()
 796     set(CMAKE_INSTALL_RPATH "\$ORIGIN/../${GMX_LIB_INSTALL_DIR}")
 797     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 798 else()
 799     if(CMAKE_SYSTEM_VERSION VERSION_GREATER 8.0) #rpath supported for >10.4
 800         set(CMAKE_INSTALL_NAME_DIR "@rpath")
 801         set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} "-Wl,-rpath,@executable_path/../${GMX_LIB_INSTALL_DIR}")
 802     else()
 803         set(CMAKE_INSTALL_NAME_DIR "${CMAKE_INSTALL_PREFIX}/${LIB_INSTALL_DIR}")
 804     endif()
 805 endif()
 806
 807 #COPYING file: Only necessary for binary distributions.
 808 #Simpler to always install.
 809 install(FILES COPYING DESTINATION ${DATA_INSTALL_DIR} COMPONENT data)
 810
 811 if(GMX_EXTERNAL_BOOST)
 812     include_directories(${Boost_INCLUDE_DIRS})
 813     set(PKG_CFLAGS "${PKG_CFLAGS} -I${Boost_INCLUDE_DIRS}")
 814 else()
 815     include_directories(${CMAKE_SOURCE_DIR}/src/external/boost)
 816     # typeid not supported for minimal internal version
 817     # (would add significant amount of code)
 818     add_definitions(-DBOOST_NO_TYPEID)
 819     # TODO: Propagate the above settings to the installed CMakeFiles.txt template
 820     # (from share/template/)
 821     set(PKG_CFLAGS "${PKG_CFLAGS} -DBOOST_NO_TYPEID -I${CMAKE_INSTALL_PREFIX}/${INCL_INSTALL_DIR}/gromacs/external/boost")
 822     if (NOT GMX_BUILD_MDRUN_ONLY)
 823         install(DIRECTORY ${CMAKE_SOURCE_DIR}/src/external/boost/boost
 824                 DESTINATION ${INCL_INSTALL_DIR}/gromacs/external/boost
 825                 COMPONENT development)
 826     endif()
 827 endif()
 828
 829 if(GMX_USE_TNG)
 830     find_package(ZLIB QUIET)
 831     include(gmxTestZLib)
 832     gmx_test_zlib(HAVE_ZLIB)
 833     set(TNG_BUILD_WITH_ZLIB ${HAVE_ZLIB} CACHE BOOL  "Build TNG with zlib compression")
 834     set(TNG_BUILD_FORTRAN OFF CACHE BOOL "Build Fortran compatible TNG library and examples for testing")
 835     set(TNG_BUILD_EXAMPLES OFF CACHE BOOL "Build examples showing usage of the TNG API")
 836     set(TNG_BUILD_COMPRESSION_TESTS OFF CACHE BOOL "Build tests of the TNG compression library")
 837     set(TNG_BUILD_DOCUMENTATION OFF CACHE BOOL "Use Doxygen to create the HTML based TNG API documentation")
 838     set(TNG_BUILD_TEST OFF CACHE BOOL "Build TNG testing binary.")
 839     add_subdirectory(${CMAKE_SOURCE_DIR}/src/external/tng_io)
 840     set(GMX_TNG_LIBRARIES tng_io)
 841 endif()
 842 mark_as_advanced(TNG_BUILD_FORTRAN)
 843 mark_as_advanced(TNG_BUILD_EXAMPLES)
 844 mark_as_advanced(TNG_BUILD_COMPRESSION_TESTS)
 845 mark_as_advanced(TNG_BUILD_DOCUMENTATION)
 846 mark_as_advanced(TNG_BUILD_TEST)
 847 mark_as_advanced(TNG_EXAMPLE_FILES_DIR)
 848
 849 if (GMX_BUILD_FOR_COVERAGE)
 850     # Code heavy with asserts makes conditional coverage close to useless metric,
 851     # as by design most of the false branches are impossible to trigger in
 852     # correctly functioning code.  And the benefit of testing those that could
 853     # be triggered by using an API against its specification isn't usually
 854     # worth the effort.
 855     add_definitions(-DNDEBUG -DBOOST_DISABLE_ASSERTS -DGMX_DISABLE_ASSERTS)
 856 endif()
 857
 858 if (BUILD_TESTING)
 859     # "tests" target builds all the separate test binaries.
 860     add_custom_target(tests)
 861     # "run-ctest" is an internal target that actually runs the tests.
 862     # This is necessary to be able to add separate targets that execute as part
 863     # of 'make check', but are ensured to be executed after the actual tests.
 864     add_custom_target(run-ctest
 865                       COMMAND ${CMAKE_CTEST_COMMAND} --output-on-failure
 866                       COMMENT "Running all tests"
 867                       VERBATIM)
 868     add_dependencies(run-ctest tests)
 869     # "check" target builds and runs all tests.
 870     add_custom_target(check DEPENDS run-ctest)
 871 endif()
 872
 873 if (NOT GMX_BUILD_MDRUN_ONLY)
 874     add_subdirectory(doxygen)
 875     add_subdirectory(share)
 876     add_subdirectory(scripts)
 877 endif()
 878 add_subdirectory(src)
 879
 880 if (BUILD_TESTING)
 881     add_subdirectory(tests)
 882 endif()
 883
 884 # Issue a warning if NVIDIA GPUs were detected, but CUDA was not found.
 885 # Don't bother the user after the first configure pass.
 886 if ((CUDA_NOTFOUND_AUTO AND GMX_DETECT_GPU_AVAILABLE) AND NOT GMX_GPU_DETECTION_DONE)
 887     message(WARNING "${CUDA_NOTFOUND_MESSAGE}")
 888 endif()
 889 set(GMX_GPU_DETECTION_DONE TRUE CACHE INTERNAL "Whether GPU detection has already been done")
 890
 891 #######################
 892 ## uninstall target
 893 #######################
 894     CONFIGURE_FILE(
 895                    "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 896                    "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
 897                    IMMEDIATE @ONLY)
 898 ###########################
 899 ADD_CUSTOM_TARGET(uninstall
 900                   "${CMAKE_COMMAND}" -P
 901                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
 902 ###########################
 903
 904 ########################################################################
 905 # Manual                                                               #
 906 ########################################################################
 907
 908 option(GMX_BUILD_MANUAL "Whether to try to configure to build the PDF manual" OFF)
 909 mark_as_advanced(GMX_BUILD_MANUAL)
 910 if(GMX_BUILD_MANUAL)
 911     # Make sure we only do detection of manual-building dependencies
 912     # when the user opted in for that.
 913     add_subdirectory(manual)
 914 endif()