CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2009,2010,2011,2012,2013,2014, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 cmake_minimum_required(VERSION 2.8.8)
  36
  37 # CMake modules/macros are in a subdirectory to keep this file cleaner
  38 # This needs to be set before project() in order to pick up toolchain files
  39 list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake ${CMAKE_CURRENT_SOURCE_DIR}/cmake/Platform)
  40
  41 project(Gromacs)
  42
  43 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  44 set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  45 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
  46
  47 # PROJECT_VERSION should have the following structure:
  48 # VERSION-dev[-SUFFIX] where the VERSION should have the for: vMajor.vMinor.vPatch
  49 #
  50 # The "-dev" suffix is important to keep because it makes possible to distinguish
  51 # between a build from official release and a build from git release branch on a
  52 # machine with no git.
  53 #
  54 # NOTE: when releasing the "-dev" suffix needs to be stripped off!
  55 set(PROJECT_VERSION "5.0-beta2-dev")
  56 # The version number of the regressiontest tarball against which this
  57 # git branch can be tested. Normally, this will be the version of the
  58 # last patch release. Comment the next line out for branches leading
  59 # to a major/minor release.
  60 set(REGRESSIONTEST_VERSION "5.0-beta1")
  61 set(CUSTOM_VERSION_STRING ""
  62     CACHE STRING "Custom version string (if empty, use hard-coded default)")
  63 mark_as_advanced(CUSTOM_VERSION_STRING)
  64 if (CUSTOM_VERSION_STRING)
  65     set(PROJECT_VERSION ${CUSTOM_VERSION_STRING})
  66 endif (CUSTOM_VERSION_STRING)
  67 set(LIBRARY_SOVERSION 0)
  68 set(LIBRARY_VERSION ${LIBRARY_SOVERSION}.0.0)
  69 # It is a bit irritating, but this has to be set separately for now!
  70 SET(CPACK_PACKAGE_VERSION_MAJOR "5")
  71 SET(CPACK_PACKAGE_VERSION_MINOR "0")
  72 #SET(CPACK_PACKAGE_VERSION_PATCH "0")
  73
  74 # The numerical gromacs version. It is 40600 for 4.6.0.
  75 # The #define GMX_VERSION in gromacs/version.h is set to this value.
  76 math(EXPR NUM_VERSION
  77     "${CPACK_PACKAGE_VERSION_MAJOR}*10000 + ${CPACK_PACKAGE_VERSION_MINOR}*100")
  78 if(CPACK_PACKAGE_VERSION_PATCH)
  79     math(EXPR NUM_VERSION
  80          "${NUM_VERSION} + ${CPACK_PACKAGE_VERSION_PATCH}")
  81 endif()
  82
  83 # The API version tracks the numerical Gromacs version (for now).
  84 # It is potentially different from the Gromacs version in the future, if
  85 # the programs/libraries diverge from the presumably more stable API.
  86 # The #define GMX_API_VERSION in version.h is set to this value to
  87 # provide backward compatibility of software written against the Gromacs API.
  88 set(API_VERSION ${NUM_VERSION})
  89
  90 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT AND UNIX)
  91     set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
  92 endif()
  93
  94 set(GMX_INSTALL_PREFIX "" CACHE STRING "Prefix gets appended to CMAKE_INSTALL_PREFIX. For cpack it sets the root folder of the archive.")
  95 mark_as_advanced(GMX_INSTALL_PREFIX)
  96
  97 include(gmxBuildTypeReference)
  98 include(gmxBuildTypeThreadSanitizer)
  99 include(gmxBuildTypeReleaseWithAssert)
 100
 101 if(NOT CMAKE_BUILD_TYPE)
 102     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel Reference RelWithAssert." FORCE)
 103     # There's no need to offer a user the choice of ThreadSanitizer
 104     # Set the possible values of build type for cmake-gui
 105     set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "Debug" "Release"
 106         "MinSizeRel" "RelWithDebInfo" "Reference" "RelWithAssert")
 107 endif()
 108 if(CMAKE_CONFIGURATION_TYPES)
 109     # Add appropriate GROMACS-specific build types for the Visual
 110     # Studio generator (Debug, Release, MinSizeRel and RelWithDebInfo
 111     # are already present by default).
 112     list(APPEND CMAKE_CONFIGURATION_TYPES "RelWithAssert" "Reference")
 113     list(REMOVE_DUPLICATES CMAKE_CONFIGURATION_TYPES)
 114     set(CMAKE_CONFIGURATION_TYPES "${CMAKE_CONFIGURATION_TYPES}" CACHE STRING
 115         "List of configuration types"
 116         FORCE)
 117 endif()
 118 set(build_types_with_explicit_flags RELEASE DEBUG RELWITHDEBUGINFO RELWITHASSERT MINSIZEREL)
 119
 120 enable_language(C)
 121 enable_language(CXX)
 122
 123 set(CPACK_PACKAGE_VERSION ${PROJECT_VERSION})
 124 set(CPACK_PACKAGE_VENDOR "gromacs.org")
 125 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Gromacs - a toolkit for high-performance molecular simulation")
 126 set(CPACK_RESOURCE_FILE_WELCOME "${CMAKE_SOURCE_DIR}/admin/InstallWelcome.txt")
 127 # Its GPL/LGPL, so they do not have to agree to a license for mere usage, but some installers require this...
 128 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_SOURCE_DIR}/COPYING")
 129 set(CPACK_RESOURCE_FILE_README "${CMAKE_SOURCE_DIR}/admin/InstallInfo.txt")
 130 set(CPACK_SOURCE_IGNORE_FILES "\\\\.isreposource$;\\\\.git/;\\\\.gitignore$")
 131 set(CPACK_PROJECT_CONFIG_FILE "${CMAKE_SOURCE_DIR}/CPackInit.cmake")
 132 set(CPACK_SOURCE_INSTALLED_DIRECTORIES "${CMAKE_SOURCE_DIR};/;${CMAKE_BINARY_DIR}/src/programs/completion;src/programs/completion;${CMAKE_BINARY_DIR}/share/man/man1;share/man/man1;${CMAKE_BINARY_DIR}/share/man/man7;share/man/man7;${CMAKE_BINARY_DIR}/share/html/final;share/html/final")
 133 set(CPACK_PACKAGE_CONTACT "gmx-users@gromacs.org")
 134
 135 #must come after all cpack settings!
 136 include(CPack)
 137
 138 # Set a default valgrind suppression file.
 139 # This unfortunately needs to duplicate information from CTest to work as
 140 # expected...
 141 set(MEMORYCHECK_SUPPRESSIONS_FILE
 142     "${CMAKE_SOURCE_DIR}/cmake/legacy_and_external.supp"
 143     CACHE FILEPATH
 144     "File that contains suppressions for the memory checker")
 145 include(CTest)
 146
 147 set(SOURCE_IS_GIT_REPOSITORY OFF)
 148 set(SOURCE_IS_SOURCE_DISTRIBUTION OFF)
 149 if(EXISTS "${CMAKE_SOURCE_DIR}/.git")
 150     set(SOURCE_IS_GIT_REPOSITORY ON)
 151 endif()
 152 if(NOT EXISTS "${CMAKE_SOURCE_DIR}/admin/.isreposource")
 153     set(SOURCE_IS_SOURCE_DISTRIBUTION ON)
 154 endif()
 155
 156 ########################################################################
 157 # Check and warn if cache generated on a different host is being reused
 158 ########################################################################
 159 if(CMAKE_HOST_UNIX)
 160     execute_process(COMMAND hostname
 161                     OUTPUT_VARIABLE TMP_HOSTNAME
 162                     OUTPUT_STRIP_TRAILING_WHITESPACE)
 163     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}")
 164         message(WARNING "
 165             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
 166             is being reused! This could lead to inconsitencies; therefore, it is
 167             recommended to regenerate the cache!")
 168     endif()
 169     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
 170             "Hostname of the machine where the cache was generated.")
 171 endif()
 172
 173 ########################################################################
 174 # User input options                                                   #
 175 ########################################################################
 176 include(gmxOptionUtilities)
 177
 178 set(CMAKE_PREFIX_PATH "" CACHE STRING "Extra locations to search for external libraries and tools (give directory without lib, bin, or include)")
 179
 180 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" OFF)
 181 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 182 option(GMX_THREAD_MPI  "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" ON)
 183 gmx_dependent_option(
 184     GMX_MPI_IN_PLACE
 185     "Enable MPI_IN_PLACE for MPIs that have it defined"
 186     ON
 187     GMX_MPI)
 188 mark_as_advanced(GMX_MPI_IN_PLACE)
 189 option(GMX_SOFTWARE_INVSQRT "Use GROMACS software 1/sqrt" ON)
 190 mark_as_advanced(GMX_SOFTWARE_INVSQRT)
 191 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 192 mark_as_advanced(GMX_FAHCORE)
 193
 194 option(GMX_COOL_QUOTES "Enable Gromacs cool quotes" ON)
 195 mark_as_advanced(GMX_COOL_QUOTES)
 196 gmx_add_cache_dependency(GMX_COOL_QUOTES BOOL "NOT GMX_FAHCORE" OFF)
 197
 198 # decide on GPU settings based on user-settings and GPU/CUDA detection
 199 include(gmxManageGPU)
 200
 201 # Detect the architecture the compiler is targetting, detect
 202 # SIMD instructions possibilities on that hardware, suggest SIMD instruction set
 203 # to use if none is specified, and populate the cache option for CPU
 204 # SIMD.
 205 include(gmxDetectTargetArchitecture)
 206 gmx_detect_target_architecture()
 207
 208 if(GMX_CPU_ACCELERATION)
 209     # Stay compatible with old Jenkins command line options for specific SIMD acceleration
 210     set(GMX_SIMD "${GMX_CPU_ACCELERATION}" CACHE STRING "SIMD instruction set level and compiler optimization" FORCE)
 211 endif(GMX_CPU_ACCELERATION)
 212
 213 if(NOT GMX_TARGET_MIC)
 214     include(gmxDetectSimd)
 215     gmx_detect_simd(GMX_SUGGESTED_SIMD)
 216 else()
 217     set(GMX_SUGGESTED_SIMD "None")
 218 endif()
 219
 220 gmx_option_multichoice(
 221     GMX_SIMD
 222     "SIMD instruction set for CPU kernels and compiler optimization"
 223     "${GMX_SUGGESTED_SIMD}"
 224     None SSE2 SSE4.1 AVX_128_FMA AVX_256 AVX2_256 IBM_QPX Sparc64_HPC_ACE Reference)
 225
 226 gmx_option_multichoice(
 227     GMX_FFT_LIBRARY
 228     "FFT library"
 229     "fftw3"
 230     fftw3 mkl "fftpack[built-in]")
 231 gmx_dependent_option(
 232     GMX_BUILD_OWN_FFTW
 233     "Download and build FFTW 3 during the GROMACS build process, rather than fall back on the really slow fftpack."
 234     OFF
 235     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 236 gmx_dependent_option(
 237     GMX_DISABLE_FFTW_MEASURE
 238     "Do not optimize FFTW setups (not needed with SSE)"
 239     OFF
 240     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 241 mark_as_advanced(GMX_BUILD_OWN_FFTW)
 242 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 243
 244 gmx_option_multichoice(
 245     GMX_QMMM_PROGRAM
 246     "QM package for QM/MM"
 247     None
 248     none gaussian mopac gamess orca)
 249
 250 gmx_dependent_cache_variable(GMX_SIMD_REF_FLOAT_WIDTH  "Reference SIMD single precision width" STRING "4" "GMX_SIMD STREQUAL REFERENCE")
 251 gmx_dependent_cache_variable(GMX_SIMD_REF_DOUBLE_WIDTH "Reference SIMD double precision width" STRING "2" "GMX_SIMD STREQUAL REFERENCE")
 252
 253 # This should be moved to a separate NBNXN cmake module when that code is cleaned up and modularized
 254
 255 if("${GMX_SIMD}" STREQUAL "REFERENCE")
 256     if(GMX_DOUBLE)
 257         set(KERNEL_WIDTH ${GMX_SIMD_REF_DOUBLE_WIDTH})
 258     else()
 259         set(KERNEL_WIDTH ${GMX_SIMD_REF_FLOAT_WIDTH})
 260     endif()
 261 endif()
 262
 263 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 264 mark_as_advanced(GMX_BROKEN_CALLOC)
 265 option(GMX_LOAD_PLUGINS "Compile with plugin support, needed to read VMD supported file formats" ON)
 266 mark_as_advanced(GMX_LOAD_PLUGINS)
 267
 268 option(GMX_GPU  "Enable GPU acceleration" ON)
 269 option(GMX_OPENMP "Enable OpenMP-based multithreading" ON)
 270
 271 option(GMX_USE_TNG "Use the TNG library for trajectory I/O" ON)
 272
 273 option(GMX_GIT_VERSION_INFO "Generate git version information" ${SOURCE_IS_GIT_REPOSITORY})
 274 mark_as_advanced(GMX_GIT_VERSION_INFO)
 275
 276 if(UNIX)
 277     option(GMX_SYMLINK_OLD_BINARY_NAMES "Create symbolic links for pre-5.0 binary names" ON)
 278 endif()
 279 option(GMX_BUILD_MDRUN_ONLY "Build and install only the mdrun binary" OFF)
 280
 281 option(GMX_CYCLE_SUBCOUNTERS "Enable cycle subcounters to get a more detailed cycle timings" OFF)
 282 mark_as_advanced(GMX_CYCLE_SUBCOUNTERS)
 283
 284 option(GMX_SKIP_DEFAULT_CFLAGS "Don't automatically add suggested/required Compiler flags." OFF)
 285 mark_as_advanced(GMX_SKIP_DEFAULT_CFLAGS)
 286
 287 option(GMX_BUILD_FOR_COVERAGE
 288        "Tune build for better code coverage metrics (e.g., disable asserts)"
 289        OFF)
 290 mark_as_advanced(GMX_BUILD_FOR_COVERAGE)
 291
 292
 293 ######################################################################
 294 # Detect OpenMP support
 295 ######################################################################
 296 # The OpenMP detection _must_ come before tests for other CFLAGS.
 297 include(gmxManageOpenMP)
 298
 299
 300
 301 ######################################################################
 302 # Compiler tests
 303 # These need to be done early (before further tests).
 304 #####################################################################
 305
 306 # The cmake/Check{C,CXX}CompilerFlag.cmake files in the GROMACS distribution
 307 # are used with permission from CMake v2.8.9 so that GROMACS can detect
 308 # invalid options with the Intel Compilers.
 309 # These files should be removed from the source tree when a CMake version that
 310 # includes the features in question becomes required for building GROMACS.
 311 include(CheckCCompilerFlag)
 312 include(CheckCXXCompilerFlag)
 313
 314
 315 include(gmxCFlags)
 316 gmx_c_flags()
 317
 318 # This variable should be used for additional compiler flags which are not
 319 # generated in gmxCFlags nor are SIMD or MPI related.
 320 set(EXTRA_C_FLAGS "")
 321 set(EXTRA_CXX_FLAGS "")
 322
 323 # Run through a number of tests for buggy compilers and other issues
 324 include(gmxTestCompilerProblems)
 325 gmx_test_compiler_problems()
 326
 327
 328 set(PKG_CFLAGS "")
 329 if(GMX_DOUBLE)
 330     add_definitions(-DGMX_DOUBLE)
 331     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_DOUBLE")
 332 endif(GMX_DOUBLE)
 333 if(GMX_SOFTWARE_INVSQRT)
 334   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_SOFTWARE_INVSQRT")
 335 endif(GMX_SOFTWARE_INVSQRT)
 336
 337
 338
 339 ########################################################################
 340 # Basic system tests (standard libraries, headers, functions, types)   #
 341 ########################################################################
 342 include(CheckIncludeFiles)
 343 include(CheckIncludeFileCXX)
 344 check_include_files(unistd.h     HAVE_UNISTD_H)
 345 check_include_files(pwd.h        HAVE_PWD_H)
 346 check_include_files(dirent.h     HAVE_DIRENT_H)
 347 check_include_files(time.h       HAVE_TIME_H)
 348 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 349 check_include_files(io.h         HAVE_IO_H)
 350 check_include_files(sched.h      HAVE_SCHED_H)
 351
 352 check_include_files(regex.h      HAVE_POSIX_REGEX)
 353 check_include_file_cxx(regex     HAVE_CXX11_REGEX)
 354 # TODO: It could be nice to inform the user if no regex support is found,
 355 # as selections won't be fully functional.
 356
 357 include(CheckFunctionExists)
 358 check_function_exists(posix_memalign    HAVE_POSIX_MEMALIGN)
 359 check_function_exists(memalign          HAVE_MEMALIGN)
 360 check_function_exists(_aligned_malloc   HAVE__ALIGNED_MALLOC)
 361 check_function_exists(gettimeofday      HAVE_GETTIMEOFDAY)
 362 check_function_exists(fsync             HAVE_FSYNC)
 363 check_function_exists(_fileno           HAVE__FILENO)
 364 check_function_exists(fileno            HAVE_FILENO)
 365 check_function_exists(_commit           HAVE__COMMIT)
 366 check_function_exists(sigaction         HAVE_SIGACTION)
 367 check_function_exists(sysconf           HAVE_SYSCONF)
 368 check_function_exists(sched_setaffinity HAVE_SCHED_SETAFFINITY)
 369 check_function_exists(sched_getaffinity HAVE_SCHED_GETAFFINITY)
 370 check_function_exists(rsqrt             HAVE_RSQRT)
 371 check_function_exists(rsqrtf            HAVE_RSQRTF)
 372 check_function_exists(sqrtf             HAVE_SQRTF)
 373
 374 include(CheckLibraryExists)
 375 check_library_exists(m sqrt "" HAVE_LIBM)
 376 check_library_exists(rt clock_gettime "" HAVE_CLOCK_GETTIME)
 377
 378 include(TestBigEndian)
 379 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 380
 381 # Management of GROMACS options for specific toolchains should go
 382 # here. Because the initial settings for some of the main options have
 383 # already happened, but things like library detection and MPI compiler
 384 # feature detection have not, the docstrings for any over-rides of
 385 # GROMACS defaults or user settings will make sense. Also, any
 386 # toolchain-related reasons for choosing whether to detect various
 387 # things can be sorted out now, before the detection takes place.
 388 if(${CMAKE_SYSTEM_NAME} MATCHES BlueGene)
 389     include(gmxManageBlueGene)
 390 endif()
 391
 392 ########################################################################
 393 #Process MPI settings
 394 ########################################################################
 395 include(gmxManageMPI)
 396
 397
 398 ########################################################################
 399 #Process shared/static library settings
 400 ########################################################################
 401 include(gmxManageSharedLibraries)
 402
 403
 404 ########################################################################
 405 # Find external packages                                               #
 406 ########################################################################
 407
 408 # Unconditionally find the package, as it is also required for unit
 409 # tests. This exports LIBXML2_FOUND, which we should not use because
 410 # it does not tell us that linking will succeed. Instead, we test that
 411 # next.
 412 find_package(LibXml2)
 413 include(gmxTestLibXml2)
 414 gmx_test_libxml2(HAVE_LIBXML2)
 415 option(GMX_XML "Use libxml2 to parse xml files (currently has no effect)" ${HAVE_LIBXML2})
 416 set(PKG_XML "")
 417 mark_as_advanced(GMX_XML)
 418 # Don't actually do anything, since libxml2 is currently not used by libgromacs
 419 #if(GMX_XML AND NOT HAVE_LIBXML2)
 420 #    message(FATAL_ERROR "libxml2 not found. Set GMX_XML=OFF to compile without XML support")
 421 #endif()
 422 #if(GMX_XML)
 423 #    include_directories(${LIBXML2_INCLUDE_DIR})
 424 #    set(PKG_XML libxml-2.0)
 425 #    set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 426 #endif(GMX_XML)
 427
 428 option(GMX_GSL "Add support for gsl" OFF)
 429 if (GMX_GSL)
 430   find_package(GSL)
 431   set(PKG_GSL "")
 432   if(GSL_FOUND)
 433     include_directories(${GSL_INCLUDE_DIR})
 434     set(PKG_GSL gsl)
 435     set(HAVE_LIBGSL 1)
 436   endif(GSL_FOUND)
 437 endif (GMX_GSL)
 438
 439 option(GMX_X11 "Use X window system" OFF)
 440 if (GMX_X11)
 441     find_package(X11)
 442     # X11 includes/libraries are only set in the ngmx subdirectory!
 443     if(NOT X11_FOUND)
 444         message(FATAL_ERROR
 445                 "X11 include files and/or libraries were not found. "
 446                 "Set GMX_X11=OFF to compile without X11 support. "
 447                 "gmx view will not be available.")
 448     endif()
 449     include_directories(${X11_INCLUDE_DIR})
 450 endif(GMX_X11)
 451
 452 include(ThreadMPI)
 453 set(THREAD_MPI_LIB thread_mpi)
 454 # Enable core threading facilities
 455 tmpi_enable_core("${CMAKE_SOURCE_DIR}/src/gromacs/legacyheaders")
 456 # Enable tMPI C++ support
 457 tmpi_enable_cxx()
 458 if(GMX_THREAD_MPI)
 459     # enable MPI functions
 460     tmpi_enable()
 461     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_THREAD_MPI")
 462     set(GMX_MPI 1)
 463     set(MPI_IN_PLACE_EXISTS 1)
 464 endif(GMX_THREAD_MPI)
 465 tmpi_get_source_list(THREAD_MPI_SRC)
 466 # If atomics are manually disabled a define is needed because atomics.h doesn't depend on config.h
 467 if (TMPI_ATOMICS_DISABLED)
 468    add_definitions(-DTMPI_ATOMICS_DISABLED)
 469 endif()
 470
 471 if(GMX_GPU)
 472     # now that we have detected the dependencies, do the second configure pass
 473     gmx_gpu_setup()
 474 endif(GMX_GPU)
 475
 476 if(CYGWIN)
 477     set(GMX_CYGWIN 1)
 478 endif(CYGWIN)
 479
 480 if(WIN32 AND NOT CYGWIN)
 481     set(GMX_NATIVE_WINDOWS 1)
 482     # This makes windows.h not declare min/max as macros that would break
 483     # C++ code using std::min/std::max.
 484     add_definitions(-DNOMINMAX)
 485 endif()
 486
 487 # only bother with finding git and using version.h if the source is a git repo
 488 if(GMX_GIT_VERSION_INFO)
 489     if (NOT SOURCE_IS_GIT_REPOSITORY)
 490         message(FATAL_ERROR
 491             "Cannot generate git version information from source tree not under git. "
 492             "Set GMX_GIT_VERSION_INFO=OFF to proceed.")
 493     endif ()
 494     # We need at least git v1.5.3 be able to parse git's date output. If not
 495     # found or the version is too small, we can't generate version information.
 496     find_package(Git)
 497
 498     if(NOT GIT_FOUND OR GIT_VERSION_STRING VERSION_LESS "1.5.3")
 499         message(FATAL_ERROR
 500             "No compatible git version found (>= 1.5.3 required). "
 501             "Won't be able to generate development version information. "
 502             "Set GMX_GIT_VERSION_INFO=OFF to proceed.")
 503     endif()
 504 endif()
 505
 506 # Detect boost unless GMX_EXTERNAL_BOOST is explicitly OFF
 507 # Used for default if GMX_EXTERNAL_BOOST is not defined (first CMake pass)
 508 if(NOT DEFINED GMX_EXTERNAL_BOOST OR GMX_EXTERNAL_BOOST)
 509     find_package(Boost 1.44.0)
 510     if(Boost_FOUND AND Boost_VERSION VERSION_LESS "104400")
 511         set(Boost_FOUND FALSE)
 512     endif()
 513     # Print the notification only on first run, when determining the default
 514     if(NOT DEFINED GMX_EXTERNAL_BOOST AND NOT Boost_FOUND)
 515         message("Boost >= 1.44 not found. Using minimal internal version. "
 516                 "This may cause trouble if you plan on compiling/linking other "
 517                 "software that uses Boost against Gromacs.")
 518     endif()
 519 endif()
 520 option(GMX_EXTERNAL_BOOST "Use external Boost instead of minimal built-in version"
 521        ${Boost_FOUND})
 522 if(GMX_EXTERNAL_BOOST AND NOT Boost_FOUND)
 523     message(FATAL_ERROR
 524         "Boost >= 1.44 not found. "
 525         "You can set GMX_EXTERNAL_BOOST=OFF to compile against minimal "
 526         "version of Boost included with Gromacs.")
 527 endif()
 528
 529 option(GMX_BUILD_UNITTESTS "Build unit tests with BUILD_TESTING (uses Google C++ Testing and Mocking Frameworks, requires libxml2)" ${HAVE_LIBXML2})
 530 mark_as_advanced(GMX_BUILD_UNITTESTS)
 531 gmx_add_cache_dependency(GMX_BUILD_UNITTESTS BOOL BUILD_TESTING OFF)
 532 if (GMX_BUILD_UNITTESTS AND NOT HAVE_LIBXML2)
 533     message(FATAL_ERROR
 534         "Cannot build unit tests without libxml2. "
 535         "Either set GMX_BUILD_UNITTESTS=OFF or tell CMake how to find a working version of libxml2.")
 536 endif()
 537
 538 ########################################################################
 539 # Generate development version info for cache
 540 ########################################################################
 541 # set(GEN_VERSION_INFO_INTERNAL "ON")
 542 # include(gmxGenerateVersionString)
 543
 544 ########################################################################
 545 # Our own GROMACS tests
 546 ########################################################################
 547
 548 add_definitions( -DHAVE_CONFIG_H )
 549 include_directories(${CMAKE_SOURCE_DIR}/src)
 550 # Required for config.h, maybe should only be set in src/CMakeLists.txt
 551 include_directories(${CMAKE_BINARY_DIR}/src)
 552 # Required for gmx_header_config_gen.h to be found before installation
 553 include_directories(${CMAKE_BINARY_DIR}/src/gromacs/utility)
 554 # Required for now to make old code compile
 555 include_directories(${CMAKE_SOURCE_DIR}/src/gromacs/legacyheaders)
 556
 557 include(gmxTestInlineASM)
 558 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 559
 560 include(gmxSetBuildInformation)
 561 gmx_set_build_information()
 562 # Turn on RDTSCP if:
 563 # - the build system's CPU supports it
 564 # - the acceleration is set to AVX as all AVX-capable CPUs support AVX (which
 565 #   at this point means that the user set it).
 566 # Note: it's better to not use the later set value of GMX_SIMD because
 567 # it reflects the system's capability of both compiling and running AVX code.
 568 # TODO: After merge with 5.0 one could implement a cache variable dependency
 569 # such that GMX_USE_RDTSCP can change if GMX_CPU_ACCELERATION is changed to AVX
 570 # after the first cmake pass.
 571 if (BUILD_CPU_FEATURES MATCHES "rdtscp" OR GMX_SIMD MATCHES "AVX")
 572     set(GMX_USE_RDTSCP_DEFAULT_VALUE ON)
 573 else()
 574     set(GMX_USE_RDTSCP_DEFAULT_VALUE OFF)
 575 endif()
 576 option(GMX_USE_RDTSCP "Use RDTSCP for better CPU-based timers (available on recent x86 CPUs; might need to be off when compiling for heterogeneous environments)" ${GMX_USE_RDTSCP_DEFAULT_VALUE})
 577 mark_as_advanced(GMX_USE_RDTSCP)
 578 if(GMX_USE_RDTSCP)
 579     set(HAVE_RDTSCP 1)
 580 endif()
 581
 582 include(gmxTestFloatFormat)
 583 gmx_test_float_format(GMX_FLOAT_FORMAT_IEEE754
 584                       GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER
 585                       GMX_IEEE754_BIG_ENDIAN_WORD_ORDER)
 586
 587 include(gmxTestLargeFiles)
 588 gmx_test_large_files(GMX_LARGEFILES)
 589
 590 include(gmxTestSignal)
 591 gmx_test_sigusr1(HAVE_SIGUSR1)
 592
 593 include(gmxTestInline)
 594 gmx_test_inline(INLINE_KEYWORD)
 595
 596 include(gmxTestRestrict)
 597 gmx_test_restrict(RESTRICT_KEYWORD)
 598
 599 include(gmxTestPipes)
 600 gmx_test_pipes(HAVE_PIPES)
 601
 602 include(gmxTestIsfinite)
 603 gmx_test_isfinite(HAVE_ISFINITE)
 604 gmx_test__isfinite(HAVE__ISFINITE)
 605 gmx_test__finite(HAVE__FINITE)
 606
 607 include(gmxTestCXX11)
 608 gmx_test_cxx11(GMX_CXX11_SUPPORTED GMX_CXX11_FLAGS)
 609 include(CMakeDependentOption)
 610 # nvcc does not support C++11 flags, so with GPUs we prefer to skip C++11 flags
 611 # entirely to keep the compilation environment uniform.
 612 cmake_dependent_option(GMX_CXX11
 613     "Use C++11 features"
 614     ON "GMX_CXX11_SUPPORTED AND NOT GMX_GPU" OFF)
 615 mark_as_advanced(GMX_CXX11)
 616 if(GMX_CXX11)
 617     set(EXTRA_CXX_FLAGS "${EXTRA_CXX_FLAGS} ${GMX_CXX11_FLAGS}")
 618 endif()
 619
 620
 621 include(gmxTestXDR)
 622 gmx_test_xdr(GMX_SYSTEM_XDR)
 623 if(NOT GMX_SYSTEM_XDR)
 624     set(GMX_INTERNAL_XDR 1)
 625 endif(NOT GMX_SYSTEM_XDR)
 626
 627
 628 ##################################################
 629 # Process SIMD instruction settings
 630 ##################################################
 631 # This checks what flags to add in order to
 632 # support the SIMD instructions we need, and sets
 633 # correct defines for the SIMD instructions supported.
 634 include(gmxTestSimd)
 635 gmx_test_simd()
 636
 637
 638 # Process QM/MM Settings
 639 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 640     set(GMX_QMMM_GAUSSIAN 1)
 641 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 642     set(GMX_QMMM_MOPAC 1)
 643 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 644     set(GMX_QMMM_GAMESS 1)
 645 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 646     set(GMX_QMMM_ORCA 1)
 647 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 648     # nothing to do
 649 else()
 650     gmx_invalid_option_value(GMX_QMMM_PROGRAM)
 651 endif()
 652
 653
 654 ##################################################
 655 # Process FFT library settings
 656 ##################################################
 657 include(gmxManageFFTLibraries)
 658
 659
 660 include(gmxManageLinearAlgebraLibraries)
 661
 662 # Whether GROMACS will really try to compile support for VMD plugins
 663 set(GMX_USE_PLUGINS OFF)
 664
 665 if(GMX_LOAD_PLUGINS)
 666   if(CYGWIN OR NOT WIN32)
 667     # Native Windows does not have, nor need dlopen
 668     # Note that WIN32 is set with Cygwin, but Cygwin needs dlopen to use plug-ins
 669     include(gmxTestdlopen)
 670     gmx_test_dlopen(HAVE_DLOPEN)
 671   endif()
 672
 673   # so, should we use plug-ins?
 674   if((WIN32 AND NOT CYGWIN) OR (HAVE_DLOPEN AND BUILD_SHARED_LIBS))
 675     if(NOT VMD_QUIETLY)
 676       MESSAGE(STATUS
 677           "Found the ability to use plug-ins when building shared libaries, "
 678           "so will compile to use plug-ins (e.g. to read VMD-supported file "
 679           "formats).")
 680     endif()
 681     if(NOT GMX_VMD_PLUGIN_PATH)
 682       find_package(VMD)
 683     endif()
 684     set(GMX_USE_PLUGINS ON)
 685     list(APPEND GMX_EXTRA_LIBRARIES ${CMAKE_DL_LIBS}) # magic cross-platform pre-set variable for dlopen library
 686     set(PKG_DL_LIBS "-l${CMAKE_DL_LIBS}")
 687   else()
 688     set(PKG_DL_LIBS)
 689   endif()
 690 endif(GMX_LOAD_PLUGINS)
 691 set(VMD_QUIETLY TRUE CACHE INTERNAL "")
 692
 693 # Link real-time library for POSIX timers. The check for clock_gettime
 694 # confirms the linkability of rt.
 695 if(HAVE_TIME_H AND HAVE_UNISTD_H AND HAVE_CLOCK_GETTIME)
 696     list(APPEND GMX_EXTRA_LIBRARIES rt)
 697 endif()
 698
 699 # Math and thread libraries must often come after all others when linking...
 700 if(HAVE_LIBM)
 701     list(APPEND GMX_EXTRA_LIBRARIES m)
 702 endif(HAVE_LIBM)
 703
 704 option(GMX_NACL "Configure for Native Client builds" OFF)
 705 if (GMX_NACL)
 706   list(APPEND GMX_EXTRA_LIBRARIES nosys)
 707   set(GMX_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -lnosys")
 708   set(GMX_NO_NICE 1)
 709   set(GMX_NO_RENAME 1)
 710 endif()
 711 mark_as_advanced(GMX_NACL)
 712
 713 if(GMX_FAHCORE)
 714   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 715       "Path to swindirect.h")
 716   include_directories(${COREWRAP_INCLUDE_DIR})
 717 endif(GMX_FAHCORE)
 718
 719 option(GMX_BUILD_HELP "Build man pages, HTML help, and completions automatically (requires that compiled binaries can be executed on the build host)" OFF)
 720 mark_as_advanced(GMX_BUILD_HELP)
 721 if (GMX_BUILD_HELP AND SOURCE_IS_SOURCE_DISTRIBUTION AND
 722     "${CMAKE_CURRENT_SOURCE_DIR}" STREQUAL "${CMAKE_CURRENT_BINARY_DIR}")
 723
 724     message(FATAL_ERROR
 725         "Rebuilding HTML and man pages is not supported for in-source "
 726         "builds from a source distribution. "
 727         "Set GMX_BUILD_HELP=OFF or do an out-of-source build to proceed.")
 728 endif()
 729
 730 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 731 # these are set after everything else
 732 if (NOT GMX_SKIP_DEFAULT_CFLAGS)
 733     set(CMAKE_C_FLAGS "${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${CMAKE_C_FLAGS}")
 734     set(CMAKE_CXX_FLAGS "${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${CMAKE_CXX_FLAGS}")
 735     set(CMAKE_EXE_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}")
 736     set(CMAKE_SHARED_LINKER_FLAGS "${MPI_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS}")
 737 else()
 738     message("Recommended flags which are not added because GMX_SKIP_DEFAULT_CFLAGS=yes:")
 739     message("CMAKE_C_FLAGS: ${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${GMXC_CFLAGS}")
 740     message("CMAKE_C_FLAGS_RELEASE: ${GMXC_CFLAGS_RELEASE}")
 741     message("CMAKE_C_FLAGS_DEBUG: ${GMXC_CFLAGS_DEBUG}")
 742     message("CMAKE_CXX_FLAGS: ${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${GMXC_CXXFLAGS}")
 743     message("CMAKE_CXX_FLAGS_RELEASE: ${GMXC_CXXFLAGS_RELEASE}")
 744     message("CMAKE_CXX_FLAGS_DEBUG: ${GMXC_CXXFLAGS_DEBUG}")
 745     message("CMAKE_EXE_LINKER_FLAGS: ${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS}")
 746     message("CMAKE_SHARED_LINKER_FLAGS: ${MPI_LINKER_FLAGS}")
 747 endif()
 748
 749 if(NOT GMX_OPENMP)
 750     #Unset all OpenMP flags in case OpenMP was disabled either by the user
 751     #or because it was only partially detected (e.g. only for C but not C++ compiler)
 752     unset(OpenMP_C_FLAGS CACHE)
 753     unset(OpenMP_CXX_FLAGS CACHE)
 754 else()
 755     set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} ${OpenMP_LINKER_FLAGS})
 756     set(GMX_SHARED_LINKER_FLAGS ${GMX_SHARED_LINKER_FLAGS} ${OpenMP_SHARED_LINKER_FLAGS})
 757 endif()
 758 set(PKG_CFLAGS "${PKG_CFLAGS} ${OpenMP_C_FLAGS}")
 759
 760 ########################################################################
 761 # Specify install locations
 762 ########################################################################
 763 set(GMX_LIB_INSTALL_DIR lib CACHE STRING
 764     "Library installation directory (default: lib)")
 765 set(GMX_DATA_INSTALL_DIR gromacs CACHE STRING
 766     "Data installation directory under share/ (default: gromacs)")
 767 mark_as_advanced(GMX_LIB_INSTALL_DIR GMX_DATA_INSTALL_DIR)
 768
 769 set(LIB_INSTALL_DIR  ${GMX_INSTALL_PREFIX}${GMX_LIB_INSTALL_DIR})
 770 set(BIN_INSTALL_DIR  ${GMX_INSTALL_PREFIX}bin)
 771 set(DATA_INSTALL_DIR ${GMX_INSTALL_PREFIX}share/${GMX_DATA_INSTALL_DIR})
 772 set(MAN_INSTALL_DIR  ${GMX_INSTALL_PREFIX}share/man)
 773 set(INCL_INSTALL_DIR ${GMX_INSTALL_PREFIX}include)
 774
 775 set(GMXLIB_SEARCH_DIR share/${GMX_DATA_INSTALL_DIR}/top)
 776 set(GMXLIB_FALLBACK   ${CMAKE_INSTALL_PREFIX}/${DATA_INSTALL_DIR}/top)
 777
 778 # Binary and library suffix options
 779 include(gmxManageSuffixes)
 780
 781 ##################################################################
 782 # Shared library settings
 783 ##################################################################
 784 if(NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin")
 785     if(GMX_LIB_INSTALL_DIR STREQUAL "lib")
 786         set(CMAKE_BUILD_WITH_INSTALL_RPATH TRUE)
 787     endif()
 788     set(CMAKE_INSTALL_RPATH "\$ORIGIN/../${GMX_LIB_INSTALL_DIR}")
 789     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 790 else()
 791     if(CMAKE_SYSTEM_VERSION VERSION_GREATER 8.0) #rpath supported for >10.4
 792         set(CMAKE_INSTALL_NAME_DIR "@rpath")
 793         set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} "-Wl,-rpath,@executable_path/../${GMX_LIB_INSTALL_DIR}")
 794     else()
 795         set(CMAKE_INSTALL_NAME_DIR "${CMAKE_INSTALL_PREFIX}/${LIB_INSTALL_DIR}")
 796     endif()
 797 endif()
 798
 799 #COPYING file: Only necessary for binary distributions.
 800 #Simpler to always install.
 801 install(FILES COPYING DESTINATION ${DATA_INSTALL_DIR} COMPONENT data)
 802
 803 if(GMX_EXTERNAL_BOOST)
 804     include_directories(${Boost_INCLUDE_DIRS})
 805     set(PKG_CFLAGS "${PKG_CFLAGS} -I${Boost_INCLUDE_DIRS}")
 806 else()
 807     include_directories(${CMAKE_SOURCE_DIR}/src/external/boost)
 808     # typeid not supported for minimal internal version
 809     # (would add significant amount of code)
 810     add_definitions(-DBOOST_NO_TYPEID)
 811     # TODO: Propagate the above settings to the installed CMakeFiles.txt template
 812     # (from share/template/)
 813     set(PKG_CFLAGS "${PKG_CFLAGS} -DBOOST_NO_TYPEID -I${CMAKE_INSTALL_PREFIX}/${INCL_INSTALL_DIR}/gromacs/external/boost")
 814     if (NOT GMX_BUILD_MDRUN_ONLY)
 815         install(DIRECTORY ${CMAKE_SOURCE_DIR}/src/external/boost/boost
 816                 DESTINATION ${INCL_INSTALL_DIR}/gromacs/external/boost
 817                 COMPONENT development)
 818     endif ()
 819 endif()
 820
 821 if(GMX_USE_TNG)
 822     find_package(ZLIB)
 823     include(gmxTestZLib)
 824     gmx_test_zlib(HAVE_ZLIB)
 825     set(TNG_BUILD_WITH_ZLIB ${HAVE_ZLIB} CACHE BOOL  "Build TNG with zlib compression")
 826     set(TNG_BUILD_FORTRAN OFF CACHE BOOL "Build Fortran compatible TNG library and examples for testing")
 827     set(TNG_BUILD_EXAMPLES OFF CACHE BOOL "Build examples showing usage of the TNG API")
 828     set(TNG_BUILD_COMPRESSION_TESTS OFF CACHE BOOL "Build tests of the TNG compression library")
 829     set(TNG_BUILD_DOCUMENTATION OFF CACHE BOOL "Use Doxygen to create the HTML based TNG API documentation")
 830     set(TNG_BUILD_TEST OFF CACHE BOOL "Build TNG testing binary.")
 831     add_subdirectory(${CMAKE_SOURCE_DIR}/src/external/tng_io)
 832     set(GMX_TNG_LIBRARIES tng_io)
 833 endif()
 834 mark_as_advanced(TNG_BUILD_FORTRAN)
 835 mark_as_advanced(TNG_BUILD_EXAMPLES)
 836 mark_as_advanced(TNG_BUILD_COMPRESSION_TESTS)
 837 mark_as_advanced(TNG_BUILD_DOCUMENTATION)
 838 mark_as_advanced(TNG_BUILD_TEST)
 839 mark_as_advanced(TNG_EXAMPLE_FILES_DIR)
 840
 841 if (GMX_BUILD_FOR_COVERAGE)
 842     # Code heavy with asserts makes conditional coverage close to useless metric,
 843     # as by design most of the false branches are impossible to trigger in
 844     # correctly functioning code.  And the benefit of testing those that could
 845     # be triggered by using an API against its specification isn't usually
 846     # worth the effort.
 847     add_definitions(-DNDEBUG -DBOOST_DISABLE_ASSERTS -DGMX_DISABLE_ASSERTS)
 848 endif ()
 849
 850 if (BUILD_TESTING)
 851     # "tests" target builds all the separate test binaries.
 852     add_custom_target(tests)
 853     # "run-ctest" is an internal target that actually runs the tests.
 854     # This is necessary to be able to add separate targets that execute as part
 855     # of 'make check', but are ensured to be executed after the actual tests.
 856     add_custom_target(run-ctest
 857                       COMMAND ${CMAKE_CTEST_COMMAND} --output-on-failure
 858                       COMMENT "Running all tests"
 859                       VERBATIM)
 860     add_dependencies(run-ctest tests)
 861     # "check" target builds and runs all tests.
 862     add_custom_target(check DEPENDS run-ctest)
 863 endif()
 864
 865 if (NOT GMX_BUILD_MDRUN_ONLY)
 866     add_subdirectory(doxygen)
 867     add_subdirectory(share)
 868     add_subdirectory(scripts)
 869 endif ()
 870 add_subdirectory(src)
 871
 872 if (BUILD_TESTING)
 873     add_subdirectory(tests)
 874 endif()
 875
 876 # Issue a warning if NVIDIA GPUs were detected, but CUDA was not found.
 877 # Don't bother the user after the first configure pass.
 878 if ((CUDA_NOTFOUND_AUTO AND GMX_DETECT_GPU_AVAILABLE) AND NOT GMX_GPU_DETECTION_DONE)
 879     message(WARNING "${CUDA_NOTFOUND_MESSAGE}")
 880 endif()
 881 set(GMX_GPU_DETECTION_DONE TRUE CACHE INTERNAL "Whether GPU detection has already been done")
 882
 883 #######################
 884 ## uninstall target
 885 #######################
 886     CONFIGURE_FILE(
 887                    "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 888                    "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
 889                    IMMEDIATE @ONLY)
 890 ###########################
 891 ADD_CUSTOM_TARGET(uninstall
 892                   "${CMAKE_COMMAND}" -P
 893                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
 894 ###########################
 895
 896 ########################################################################
 897 # Manual                                                               #
 898 ########################################################################
 899
 900 option(GMX_BUILD_MANUAL "Whether to try to configure to build the PDF manual" OFF)
 901 mark_as_advanced(GMX_BUILD_MANUAL)
 902 if(GMX_BUILD_MANUAL)
 903     # Make sure we only do detection of manual-building dependencies
 904     # when the user opted in for that.
 905     add_subdirectory(manual)
 906 endif()